画像に円を塗る

Posted on 2月 11, 2020 by Takaaki Naganoya

作成した画像（NSImage）に円を塗るAppleScriptです。

最近、６角形の図形ばかり塗りつぶしていましたが、「円に変えるとどうなんだろう？」と考えて、本ルーチンを試作してみました。

ためしに、６角形ではなく円で塗りつぶしてみたものの、そんなにイケていない感じがします。

AppleScript名：画像に円を塗る.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/02/11
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property aRadius : 40

set aFile to POSIX path of (choose file name)
if aFile does not end with ".png" then
　　set aFile to aFile & ".png"
end if

set aColor to current application’s NSColor’s redColor()

set aImage to current application’s NSImage’s alloc()’s initWithSize:{300, 300}

repeat with y from 0 to 300 by aRadius + 4
　　repeat with x from 0 to 300 by aRadius + 4
　　　　my drawCircleOnNSIMage(aImage, aRadius, x, y, aColor)
　　end repeat
end repeat

set sRes to my saveNSImageAtPathAsPNG(aImage, aFile)

#　　MARK: Call By Reference
on drawCircleOnNSIMage(aImage, aRadius, aXpos, aYpos, aColor)
　　set aBezier to generateCircle(aRadius, aXpos, aYpos) of me
　　(aImage)’s lockFocus()
　　aColor’s |set|()
　　aBezier’s fill() –ぬりつぶし
　　(aImage)’s unlockFocus()
end drawCircleOnNSIMage

#　　MARK: circleのBezier曲線を作成して返す
on generateCircle(theRadius, x, y)
　　set aRect to current application’s NSMakeRect(x, y, theRadius, theRadius)
　　set aCirCle to current application’s NSBezierPath’s bezierPath()
　　aCirCle’s appendBezierPathWithOvalInRect:aRect
　　return aCirCle
end generateCircle

# NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to current application’s NSBitmapImageRep’s imageRepWithData:imageRep
　　set pathString to current application’s NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　set myNewImageData to (aRawimg’s representationUsingType:(current application’s NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

画像の指定エリアを透明色塗りつぶし（矩形切り抜き）

Posted on 2月 3, 2020 by Takaaki Naganoya

指定画像の指定エリア（矩形）を透明色で塗りつぶすAppleScriptです。透明色で塗りつぶす＝矩形で切り抜いたようなかっこうになります。

画像（NSImage）を指定色で塗りつぶすという処理はよく見かけるものですが、clearColor()（透明色）で塗りつぶすという処理を行うとどうなるかといえば…………何も起こりません。

透明色でNSImageを塗りつぶすという処理は、たいへんに「ありそう」な処理ですが、なかなか見つからない。

さんざん探し回ったのですが、自分には見つけられませんでした。ちょうどEdama2さんに相談してみたところ、こういう処理を探し出してもらえました（ありがとうございますー）。ただ、見つけてきた処理そのままでは思い通りの結果にならなかったので、修正が必要であったとのこと。

透明塗りつぶし（切り抜き）の指定座標はCocoaの座標系をそのまま利用しているので、左下が原点です。

NSBezierPathで切り抜き（透明色で塗りつぶし）できるといいのになーという感じではあります。

AppleScript名：画像の指定エリアを透明色塗りつぶし（矩形切り抜き）

— Created 2017-11-19 by Takaaki Naganoya
— Modified 2018-02-14 by Takaaki Naganoya
— Modified 2020-02-03 by Edama2 & Takaaki Naganoya
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSScreen : a reference to current application’s NSScreen
property NSBezierPath : a reference to current application’s NSBezierPath
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSCompositeClear : a reference to current application’s NSCompositeClear
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep

–切り抜きエリア（複数）
set drawList to {{origin:{x:0, y:0}, |size|:{width:200, height:100}}, {origin:{x:100, y:100}, |size|:{width:50, height:50}}}

set imgPath to POSIX path of (choose file of type {"public.image"})
set anImage to NSImage’s alloc()’s initWithContentsOfFile:imgPath

set fillColor to (NSColor’s colorWithCalibratedRed:1.0 green:0.0 blue:0.0 alpha:0.9)

–透明色塗りつぶし処理呼び出し
set resImage to drawImageWithClearColorFill(anImage, drawList) of me

set aUUIDstr to (NSUUID’s UUID()’s UUIDString()) as string
set aPath to ((NSString’s stringWithString:imgPath)’s stringByDeletingLastPathComponent()’s stringByAppendingPathComponent:aUUIDstr)’s stringByAppendingPathExtension:"png"

set fRes to saveImageRepAtPathAsPNG(resImage, aPath) of me

on drawImageWithClearColorFill(anImage, drawList)
　　set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
　　–>　　2.0 (Retina) / 1.0 (Non Retina)
　　
　　set aClearCol to NSColor’s clearColor()
　　set op to current application’s NSCompositeClear
　　
　　anImage’s lockFocus() –描画開始
　　
　　repeat with i in drawList
　　　　set origX to (x of origin of i) / retinaF
　　　　set origY to (y of origin of i) / retinaF
　　　　set sizeX to (width of |size| of i) / retinaF
　　　　set sizeY to (height of |size| of i) / retinaF
　　　　
　　　　–Draw Clear Color
　　　　–http://www.drissman.com/blog/archives/2009/10/09/nsrectfill_and_nscolor_clearcolor.html
　　　　set theRect to {{x:origX, y:origY}, {width:sizeX, height:sizeY}}
　　　　aClearCol’s |set|()
　　　　current application’s NSRectFillUsingOperation(theRect, op)
　　end repeat
　　
　　anImage’s unlockFocus() –描画ここまで
　　
　　return anImage –returns NSImage
end drawImageWithClearColorFill

–画像を指定パスにPNG形式で保存
on saveImageRepAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　return (myNewImageData’s writeToFile:newPath atomically:true) as boolean
end saveImageRepAtPathAsPNG

★Click Here to Open This Script　

見えてきたSIM入りMacの可能性？ CoreTelephony

Posted on 2月 1, 2020 by Takaaki Naganoya

OSのアップデートがあるたびに調査している「CoreTelephony.framework」の調査を行なってみました。

最初（macOS 10.10のころ？）はFrameworkのダミーがあるだけで、use framework “CoreTelephony”などと書いても、エラーになるだけでした。

次いで、use framework “Coretelephony”が通るようになったものの、中身が用意されていない時代が長く続き、とうとうmacOS 10.15で実際にオブジェクトを生成して情報が取れるようになりました。macOS 10.14では本Scriptは動きません。動作するのは10.15以降のみです。

VOIP経由で通話ができるという情報が取れるようになっただけですが、通話に使えるほど待ち受け時間が長いマシン（ARM CPU搭載）の開発が最終段階に到達したのか、あるいはARM CPU搭載のiPadのようなマシンにmacOSを搭載することを検討しているのか、それ以外の何かを用意しているのかは不明です。

ただひとつ言えることは、macOS上でCoreTelephony.frameworkのフルセットが、ようやく動いて、BridgeSupportのファイルまで用意された（＝AppleScriptから呼べるようになった）ということです。

struct name='CTError' type64='{_CTError="domain"i"error"i}'
constant name='CTCallStateConnected' type64='@'
constant name='CTCallStateDialing' type64='@'
constant name='CTCallStateDisconnected' type64='@'
constant name='CTCallStateIncoming' type64='@'
constant name='CTRadioAccessTechnologyCDMA1x' type64='@'
constant name='CTRadioAccessTechnologyCDMAEVDORev0' type64='@'
constant name='CTRadioAccessTechnologyCDMAEVDORevA' type64='@'
constant name='CTRadioAccessTechnologyCDMAEVDORevB' type64='@'
constant name='CTRadioAccessTechnologyDidChangeNotification' type64='@'
constant name='CTRadioAccessTechnologyEdge' type64='@'
constant name='CTRadioAccessTechnologyGPRS' type64='@'
constant name='CTRadioAccessTechnologyHSDPA' type64='@'
constant name='CTRadioAccessTechnologyHSUPA' type64='@'
constant name='CTRadioAccessTechnologyLTE' type64='@'
constant name='CTRadioAccessTechnologyWCDMA' type64='@'
constant name='CTRadioAccessTechnologyeHRPD' type64='@'
constant name='CTServiceRadioAccessTechnologyDidChangeNotification' type64='@'
constant name='CTSubscriberTokenRefreshed' type64='@'
enum name='kCTErrorDomainMach' value64='2'
enum name='kCTErrorDomainNoError' value64='0'
enum name='kCTErrorDomainPOSIX' value64='1'
class name='CTCarrier'
method selector='allowsVOIP'
retval type64='B'

下記ScriptはMac mini 2014にBluetooth経由でiPhoneを接続した状態で実行したものです。この記事を書いたあたりで「ARM Macはあり得る」と感じるようになっていました（半信半疑ですが）。

AppleScript名：電話関連情報を取得するじっけん

— Created 2016-09-30 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.7"
use scripting additions
use framework "Foundation"
use framework "CoreTelephony"

–macOS 10.15ではじめて呼び出せた
set telephony to current application’s CTTelephonyNetworkInfo’s alloc()’s init()
–set telephony to current application’s CTTelephonyNetworkInfo’s new()

set cRes to telephony’s subscriberCellularProvider()
–> missing value

set sRes to telephony’s serviceCurrentRadioAccessTechnology()
–> missing value

set sRes2 to telephony’s serviceSubscriberCellularProviders()
–> missing value

set sRes3 to telephony’s serviceSubscriberCellularProvidersDidUpdateNotifier()
–> missing value

set sRes3 to telephony’s dataServiceIdentifier()
–> missing value

set aCarrier to current application’s CTCarrier’s alloc()’s init()
–>
(*
CTCarrier (0x6000034d5bf0) {
　　Carrier name: [<nil>]
　　Mobile Country Code: [<nil>]
　　Mobile Network Code:[<nil>]
　　ISO Country Code:[<nil>]
　　Allows VOIP? [YES]
}
*)

set vRes to aCarrier’s allowsVOIP()
–> true

★Click Here to Open This Script　

追記：2020/12/17に同一機体でmacOS 11.1環境で同じScriptを実行した際の結果を反映させてみました。

この時点でARM Mac＝M1 Macが登場して、市販もはじまっている状況ですが、SIM入りMacは登場していません。iPad Proのような筐体でMx系CPUを搭載したタブレット的な「Mac Pad」のようなマシンが出てくるものと予測していますが、どうなることやら。

AppleScript名：電話関連情報を取得するじっけん.scptd

— Created 2016-09-30 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.7"
use scripting additions
use framework "Foundation"
use framework "CoreTelephony"

set cRes to telephony’s subscriberCellularProvider()
–> missing value–10.15
–> missing value–11.1

set sRes to telephony’s serviceCurrentRadioAccessTechnology()
–> missing value–10.15
–> (NSDictionary) {}–11.x

set sRes2 to telephony’s serviceSubscriberCellularProviders()
–> missing value–10.15
–> (NSDictionary) {}–11.x

set sRes3 to telephony’s serviceSubscriberCellularProvidersDidUpdateNotifier()
–> missing value–10.15
–> missing value–11.x

set sRes3 to telephony’s dataServiceIdentifier()
–> missing value–10.15
–> missing value–11.x

set aCarrier to current application’s CTCarrier’s alloc()’s init()
–>
(*
–macOS 10.15
CTCarrier (0x6000034d5bf0) {
　　Carrier name: [<nil>]
　　Mobile Country Code: [<nil>]
　　Mobile Network Code:[<nil>]
　　ISO Country Code:[<nil>]
　　Allows VOIP? [YES]
}

–macOS 11.1
CTCarrier (0x600000a7c300) {
　　Carrier name: [<nil>]
　　Mobile Country Code: [<nil>]
　　Mobile Network Code:[<nil>]
　　ISO Country Code:[<nil>]
　　Allows VOIP? [YES]
}

set vRes to aCarrier’s allowsVOIP()
–> true–10.15
–> true–11.x

★Click Here to Open This Script　

eppcで他のMac上のアプリケーション操作

Posted on 1月 26, 2020 by Takaaki Naganoya

MacScripterのフォーラムでeppcについての質問があったので回答していました。eppcを用いて、ネットワーク上の他のMacを操作する件についての話でした。

eppcは、Remote AppleEventのプロトコル表記であり、自分のマシン上のアプリケーションだと、

application "Finder"

と表記しますが、他のMac上のアプリケーションだと、

application "Finder" of machine "eppc://user:password@machineName.local"

という表記になります。パスワードを書いておかないとダイアログで問い合わせが行われるので、書かなくてもいいです（パスワードが丸裸で書いてあるのは不用心なので、テスト時以外はおすすめしません）。

自分の認識では、ネットワーク上の他のマシンの操作については、

のような認識でした。この認識は間違っているわけではなく、リモートのアプリケーション操作はリモート側のアプレットに行わせるようにして、自分からはリモート側のアプレットのハンドラを呼び出すのがリモートアプリケーション操作の基本的な「作法」です。

GUIアプリケーションを直接操作するのは無理だけど、AppleScriptアプレットを常駐させておいて、アプレットのハンドラを呼び出すことで、各リモートマシン上のアプリケーションを操作できる、と。

で、これが他のメンバーのコメントで（リモートアプリケーションのダイレクト呼び出しは）「macOS 10.15でもできるぞ」という話が出てきて、腰を抜かしました。現状の自分のマシン環境（古いのばっかりですが）で検証してみたところ、たしかに（若干の癖はありますが）、GUIアプリケーションを直接操作できて驚きました（セキュリティ上の制約がいろいろあるので、ローカルでできることすべてがリモートアプリケーションに直接司令できるわけではありません）。

▲テストに用いたMac OS X 10.6.8環境

▲テストに用いたMac OS X 10.7.5環境

▲テストに用いたMac OS X 10.13.6環境

Mac OS X 10.6からmacOS 10.12あたり（厳密には確認できていない）の環境では、明確にリモートAppleEventに制約が加わっていました。

ところが、macOS 10.13あたり（10.12かも。このあたり未確認）から、eppcでGUIアプリケーションの操作ができることが確認できました。

macOS Version	Direct eppc to GUI Apps
10.0	（No AppleScript Env）
10.1	Works????
10.2	Works
10.3	Works
10.4	Works
10.5	(???)
10.6	Not Work
10.7	Not Work
10.8	Not Work
10.9	Not Work
10.1	Not Work
10.11	Not Work
10.12	(??? Maybe not work)
10.13	Works
10.14	Works
10.15	Works

eppcのポート

eppcがTCP/IPのどこのポート番号を用いているかは、/etc/servicesを見ると書いてあります。

eppc            3031/udp    # Remote AppleEvents/PPC Toolbox
eppc            3031/tcp    # Remote AppleEvents/PPC Toolbox

なので、VPN接続時にこれらのポートが開いていれば、相手側のマシンをAppleScriptで遠隔操作できることになります（実際には、ファイル共有とかいろいろその他の付随するポートを開けておく必要があるわけですが）。

リモート操作の傾向

ただし、ローカルマシン上のアプリケーションを操作するのと比較して、いくつかの挙動の違いも見られます。

（１）アプリケーションの直接的な起動が効かない

各GUIアプリケーションに「activate」とか「launch」コマンドを送っても無視されます。リモートマシン上でいったんアプリケーションが起動した後に「activate」で最前面に持ってくることは可能ですが、起動していない状態でactivateを実行しても、起動は行われません。

AppleScript名：他のマシン上でSafariを起動

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Finder"
　　tell application "Finder" of machine RemoteMachine
　　　　open application file id "com.apple.Safari"
　　end tell
end using terms from

★Click Here to Open This Script　

Finder経由でBundle IDを指定して「application fileをオープンする」という指定であれば、たしかにアプリケーションが起動します。

（２）System Eventsの操作に難あり

面白くなっていろいろリモートアプリケーションを操作していてわかってきたのですが、初期状態だとSystem Eventsが起動していない状態です。いえ、ローカルでもSystem Eventsは常時起動してはいないんでしょうけれど、命令を発行すると自動で起動されます。

この自動起動とか明示的に指定して起動といった操作が受け付けられないので、Finder経由で間接的にapplication fileのオープンというかたちでSystem Eventsの起動を行い、処理を依頼します。

このリモートマシン上のSystem Eventsはしばらく処理が行われないと自動で終了するようなので、何かまとまった処理をSystem Eventsに行わせる前には明示的に起動を司令しておくべきなんでしょう。

AppleScript名：他のマシン上のSystem Eventsを起動する

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Finder"
　　tell application "Finder" of machine RemoteMachine
　　　　open application file id "com.apple.SystemEvents"
　　end tell
end using terms from

★Click Here to Open This Script　

（３）けっこう動く

GUIアプリケーションの代表としてSafariを実際に操作してみたところ、

Safariのバージョン名の取得、できました。

AppleScript名：他のマシン上で起動しているアプリケーションのバージョンを取得

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Safari"
　　tell application "Safari" of machine RemoteMachine
　　　　version
　　end tell
end using terms from

★Click Here to Open This Script　

Safariの新規ウィンドウの作成、できました。

AppleScript名：他のマシン上で起動しているSafariで新規ウィンドウ作成

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Safari"
　　tell application "Safari" of machine RemoteMachine
　　　　make new document
　　end tell
end using terms from

★Click Here to Open This Script　

SafariのウィンドウのURLの取得、できました。

AppleScript名：他のマシン上で起動しているSafariの最前面のウィンドウのURLを取得

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Safari"
　　tell application "Safari" of machine RemoteMachine
　　　　set aURL to URL of front document
　　end tell
end using terms from

★Click Here to Open This Script　

SafariのウィンドウのURLの書き換え、できました。

AppleScript名：他のマシン上で起動しているSafariのウィンドウのURLを書き換える

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Safari"
　　tell application "Safari" of machine RemoteMachine
　　　　set URL of document 1 to "http://piyocast.com/as/"
　　end tell
end using terms from

★Click Here to Open This Script　

Safariの最前面のウィンドウの内容をメールに転送、できました。

AppleScript名：他のマシン上で起動しているSafariの最前面の内容をメール

set RemoteMachine to "eppc://me@MacMini2014.local"

using terms from application "Safari"
　　tell application "Safari" of machine RemoteMachine
　　　　make new document
　　　　set URL of front document to "http://www.apple.com"
　　　　delay 3 –wait for page loading
　　　　email contents of front document
　　end tell
end using terms from

★Click Here to Open This Script　

Safariのページローディング検出はいろいろ蓄積されているノウハウもありますが、do javascriptコマンドが問題なく動くレベルまで信用できるのかわからなかったので、delayで単純に時間待ちしています。

実際に動かしてみて、自分がビビるぐらいeppcでリモートアプリケーションの操作ができてしまいました。SIPだとかアプリケーション権限だとかでセキュリティ機能でがんじがらめにされている今日このごろですが、eppc経由でリモートマシン上のアプリケーション操作が緩和されている事実にビビりました。

これはおそらくですが、Xcode上のリモートデバッグとか、そういうあたりの機能の実装時に機能がeppcまわりの機能が再実装されたかコメントアウトしていた箇所が復活したかという話に見えます。

元号変換v42

Posted on 1月 23, 2020 by Takaaki Naganoya

西暦→和暦の元号を求めるAppleScriptの改修版です。

前バージョンでは、1868年から1887年までの計算が１日ズレるとか（dateオブジェクトの仕様）、明治の計算が合っていなかったので、その点を修正しました。

前バージョンまでは文字列で与えられた日付をいったんdateオブジェクトに変換していました。これは、”2020/11/31″といった正しくない日付が与えられた場合に、”2020/12/1″と妥当な解釈をし直すための処理でした。つまり、エラー対策のためだけにいったんdateオブジェクトに変換していたわけです。

これさえ行わなければ、とくにdateオブジェクトまわりの問題（before1887）は発生しません。dateオブジェクトとして解釈を行わず、単なる文字列を年、月、日に分解して、大小判定するだけの処理に置き換えました（11/31といったカレンダー的におかしな記述は無視）。

明治の計算についてもごにょごにょして修正してみました。

dateとしての年、月、日の妥当性チェックを行いたい場合には、月が1〜12、日が1〜31といった値の範囲チェックを追加で行うぐらいでしょうか。

AppleScript名：元号変換v42

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/23
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

set outList to {}
repeat with i from 1867 to 2021
　　set aStr to (i as string) & "/1/25"
　　set {aGengoStr, aGengoNum} to retJapaneseGengo(aStr) of JGengoKit
　　set the end of outList to {i, aGengoStr, aGengoNum}
end repeat

return outList
–> {{1867, "(改暦前)", false}, {1868, "明治", 1}, {1869, "明治", 2}, {1870, "明治", 3}, {1871, "明治", 4}, {1872, "明治", 5}, {1873, "明治", 6}, {1874, "明治", 7}, {1875, "明治", 8}, {1876, "明治", 9}, {1877, "明治", 10}, {1878, "明治", 11}, {1879, "明治", 12}, {1880, "明治", 13}, {1881, "明治", 14}, {1882, "明治", 15}, {1883, "明治", 16}, {1884, "明治", 17}, {1885, "明治", 18}, {1886, "明治", 19}, {1887, "明治", 20}, {1888, "明治", 21}, {1889, "明治", 22}, {1890, "明治", 23}, {1891, "明治", 24}, {1892, "明治", 25}, {1893, "明治", 26}, {1894, "明治", 27}, {1895, "明治", 28}, {1896, "明治", 29}, {1897, "明治", 30}, {1898, "明治", 31}, {1899, "明治", 32}, {1900, "明治", 33}, {1901, "明治", 34}, {1902, "明治", 35}, {1903, "明治", 36}, {1904, "明治", 37}, {1905, "明治", 38}, {1906, "明治", 39}, {1907, "明治", 40}, {1908, "明治", 41}, {1909, "明治", 42}, {1910, "明治", 43}, {1911, "明治", 44}, {1912, "明治", 45}, {1913, "大正", 2}, {1914, "大正", 3}, {1915, "大正", 4}, {1916, "大正", 5}, {1917, "大正", 6}, {1918, "大正", 7}, {1919, "大正", 8}, {1920, "大正", 9}, {1921, "大正", 10}, {1922, "大正", 11}, {1923, "大正", 12}, {1924, "大正", 13}, {1925, "大正", 14}, {1926, "大正", 15}, {1927, "昭和", 2}, {1928, "昭和", 3}, {1929, "昭和", 4}, {1930, "昭和", 5}, {1931, "昭和", 6}, {1932, "昭和", 7}, {1933, "昭和", 8}, {1934, "昭和", 9}, {1935, "昭和", 10}, {1936, "昭和", 11}, {1937, "昭和", 12}, {1938, "昭和", 13}, {1939, "昭和", 14}, {1940, "昭和", 15}, {1941, "昭和", 16}, {1942, "昭和", 17}, {1943, "昭和", 18}, {1944, "昭和", 19}, {1945, "昭和", 20}, {1946, "昭和", 21}, {1947, "昭和", 22}, {1948, "昭和", 23}, {1949, "昭和", 24}, {1950, "昭和", 25}, {1951, "昭和", 26}, {1952, "昭和", 27}, {1953, "昭和", 28}, {1954, "昭和", 29}, {1955, "昭和", 30}, {1956, "昭和", 31}, {1957, "昭和", 32}, {1958, "昭和", 33}, {1959, "昭和", 34}, {1960, "昭和", 35}, {1961, "昭和", 36}, {1962, "昭和", 37}, {1963, "昭和", 38}, {1964, "昭和", 39}, {1965, "昭和", 40}, {1966, "昭和", 41}, {1967, "昭和", 42}, {1968, "昭和", 43}, {1969, "昭和", 44}, {1970, "昭和", 45}, {1971, "昭和", 46}, {1972, "昭和", 47}, {1973, "昭和", 48}, {1974, "昭和", 49}, {1975, "昭和", 50}, {1976, "昭和", 51}, {1977, "昭和", 52}, {1978, "昭和", 53}, {1979, "昭和", 54}, {1980, "昭和", 55}, {1981, "昭和", 56}, {1982, "昭和", 57}, {1983, "昭和", 58}, {1984, "昭和", 59}, {1985, "昭和", 60}, {1986, "昭和", 61}, {1987, "昭和", 62}, {1988, "昭和", 63}, {1989, "平成", 1}, {1990, "平成", 2}, {1991, "平成", 3}, {1992, "平成", 4}, {1993, "平成", 5}, {1994, "平成", 6}, {1995, "平成", 7}, {1996, "平成", 8}, {1997, "平成", 9}, {1998, "平成", 10}, {1999, "平成", 11}, {2000, "平成", 12}, {2001, "平成", 13}, {2002, "平成", 14}, {2003, "平成", 15}, {2004, "平成", 16}, {2005, "平成", 17}, {2006, "平成", 18}, {2007, "平成", 19}, {2008, "平成", 20}, {2009, "平成", 21}, {2010, "平成", 22}, {2011, "平成", 23}, {2012, "平成", 24}, {2013, "平成", 25}, {2014, "平成", 26}, {2015, "平成", 27}, {2016, "平成", 28}, {2017, "平成", 29}, {2018, "平成", 30}, {2019, "平成", 31}, {2020, "令和", 2}, {2021, "令和", 3}}

script JGengoKit
　　on retJapaneseGengo(aDate as string)
　　　　set dList to parseByDelim(aDate, "/") of me
　　　　if length of dList is not equal to 3 then error "Date Format Error"
　　　　
　　　　copy dList to {aYear, aMonth, aDay}
　　　　
　　　　tell current application
　　　　　　
　　　　　　set aStr to retZeroPaddingText(aYear, 4) of me & retZeroPaddingText(aMonth, 2) of me & retZeroPaddingText(aDay, 2) of me
　　　　　　
　　　　　　set aGengo to ""
　　　　　　if aStr ≥ "20190501" then
　　　　　　　　set aGengo to "令和"
　　　　　　　　set aGengoNum to aYear – 2019 + 1
　　　　　　else if aStr ≥ "19890108" then
　　　　　　　　set aGengo to "平成"
　　　　　　　　set aGengoNum to aYear – 1989 + 1
　　　　　　else if aStr ≥ "19261225" then
　　　　　　　　set aGengo to "昭和"
　　　　　　　　set aGengoNum to aYear – 1926 + 1
　　　　　　else if aStr ≥ "19120730" then
　　　　　　　　set aGengo to "大正"
　　　　　　　　set aGengoNum to aYear – 1912 + 1
　　　　　　else if aStr ≥ "18680125" then
　　　　　　　　set aGengo to "明治"
　　　　　　　　if aYear = 1868 then
　　　　　　　　　　set aGengoNum to 1
　　　　　　　　else if (aYear ≥ 1869) or (aYear ≤ 1912) then
　　　　　　　　　　set aGengoNum to aYear – 1867
　　　　　　　　end if
　　　　　　else
　　　　　　　　–日本では明治以降に太陽暦を導入したのでそれ以前は意味がない？
　　　　　　　　set aGengo to "(改暦前)"
　　　　　　　　set aGengoNum to false
　　　　　　end if
　　　　　　
　　　　　　return {aGengo, aGengoNum}
　　　　end tell
　　end retJapaneseGengo
　　
　　–数値にゼロパディングしたテキストを返す
　　on retZeroPaddingText(aNum, aLen)
　　　　set tText to ("0000000000" & aNum as text)
　　　　set tCount to length of tText
　　　　set resText to text (tCount – aLen + 1) thru tCount of tText
　　　　return resText
　　end retZeroPaddingText
　　
　　on parseByDelim(aData, aDelim)
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to aDelim
　　　　set dList to text items of aData
　　　　set AppleScript’s text item delimiters to curDelim
　　　　return dList
　　end parseByDelim
end script

★Click Here to Open This Script　

1867/1/1〜1887/12/31までの範囲のdateオブジェクトからyear, month, dayを取り出すと-1日される？

Posted on 1月 22, 2020 by Takaaki Naganoya

過去のdateオブジェクトを検証する機会があり（明治の元号計算が合っていない件）、いろいろ検証していたところ、1867/1/1から1887/12/1までのdateオブジェクトからyear,month,dayを個別に取り出すと、dayが-1されるという現象が観測されました。

→ 本現象の発生メカニズムはこちら

西暦から和暦に変換する処理で、明治の年が合わないという（自分のプログラム由来の）問題を検討していました。この問題の洗い出しのため、「日」単位で順次和暦変換していたら、そのちょうど（明治→大正など）改元の境目の日付で（原因不明の）計算ミスが起こっていました。

1868/1/25からは明治時代、という判定は行えても、その1868/1/25というdateオブジェクトからYear, Month, Dayの各要素を取り出すと1868, 1, 24という結果に。

以前から「大昔の日付を扱うと問題がありそう」だとは思っていましたが、このように具体的な現象として観測したのは（個人的には）初めてでした（単に覚えていないだけかも）。

確認したのはmacOS 10.14.6とmacOS 10.15.3beta、macOS 10.13.6上ですが、どれも同じ結果になるようです。

＃　追試で、OS X 10.7.5でも試してみたところ、同じ結果になりました
＃　OS X 10.6.8では確認されませんでした

未来のdateオブジェクトは2050年ぐらいまでチェックしてみたものの、問題はありませんでした。

過去に遡ってうるう日が設定されたとかいう話なんでしょうか？　そういう話は聞いたことがないのですが、、、

日本においては太陽暦（グレゴリオ暦）を導入したのが明治元年（1868/1/25〜）なので、それ以前の日付をグレゴリオ歴で求めてもいまひとつ実用性がない（？）　ともいえますが、少なくとも1868年から1887年までの間のdateオブジェクトから各種の値の取り出しが期待どおりに行われないのは問題といえるでしょう。

多分、もっと昔の日付も同様にdateオブジェクトからの値取り出しを行うと問題が出ると思われますが、前述のような理由からそこまでの日付を計算させることもないだろうかと。

＃　ふだん使っているgetMLenInternationalに問題があるのかと考えて、昔使っていたgetMLenを引っ張り出してきましたが、こちらはずいぶんと記法がお可愛らしい感じで、、、、

ただ、この件は気がつかなかっただけで、ずいぶん昔から存在している話なのかも？？？？

▲Classic Mac OS 8.6では確認できませんでした（SheepShaver上で動作）この時代にはmonthをas numberで数値にcastできませんでした

AppleScript名：dateTest.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/22
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

script spd
　　property mList : {}
end script

set (mList of spd) to {}
repeat with y from 1867 to 1888
　　repeat with m from 1 to 12
　　　　set aLen to getMlen(y, m) of me
　　　　repeat with d from 1 to aLen
　　　　　　set aTmpStr to (y as string) & "/" & (m as string) & "/" & (d as string)
　　　　　　set aTmpD to date aTmpStr
　　　　　　
　　　　　　set tmpY to year of aTmpD
　　　　　　set tmpM to month of aTmpD as number
　　　　　　set tmpD to day of aTmpD
　　　　　　
　　　　　　if (tmpY is not equal to y) or (tmpM is not equal to m) or (tmpD is not equal to d) then
　　　　　　　　set the end of (mList of spd) to {aTmpD, tmpY, tmpM, tmpD}
　　　　　　end if
　　　　end repeat
　　end repeat
end repeat

return (mList of spd)
–> {{date "1867年1月1日火曜日 0:00:00", 1866, 12, 31}, …… {date "1887年12月31日土曜日 0:00:00", 1887, 12, 30}}

–現在のカレンダーで指定年月の日数を返す
on getMlenInternational(aYear as integer, aMonth as integer)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar() — do *not* use initWithCalendarIdentifier:
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　return |length| of theResult
end getMlenInternational

–指定年の指定月の日数を求める
on getMlen(aYear, aMonth)
　　set aYear to aYear as number
　　set aMonth to aMonth as number
　　
　　set aDat to (aYear as text) & "/" & (aMonth as text) & "/1"
　　if aMonth is 12 then
　　　　set eDat to ((aYear + 1) as text) & "/" & (1 as text) & "/1"
　　else
　　　　set eDat to ((aYear as text) & "/" & (aMonth + 1) as text) & "/1"
　　end if
　　
　　set eDat to date eDat
　　set eDat to eDat – 1
　　
　　set mLen to day of eDat
　　return mLen
end getMlen

★Click Here to Open This Script　

Keynoteで選択中の画像を特定する

Posted on 1月 22, 2020 by Takaaki Naganoya

Keynoteの書類上で選択中のオブジェクト（image）を特定するAppleScriptです。

Keynoteには、選択中のオブジェクトを求めるという重要な機能「selection」が実装されていません。一応、最新版のKeynoteには「selection」の予約語が存在しているものの、slide中の選択オブジェクトではなく「選択中のスライド」が返ってきます。current slideとほぼ同じ動作です。これでは実用性がいまひとつです。

ないと困るselection（get selected object）ですが、実装されていないのは仕方ありません。

そのものズバリの機能が存在していないものの、他のやりかたで選択中の画像を特定してみました。数が少なかったり重複するものが存在していない場合には有効のようです。

本Scriptでは、Keynote書類上で選択中の画像があるという前提の上で、GUI Scripting経由でコピーを行い、選択対象をクリップボードに入れます。このクリップボード内の画像のサイズを取得。次に、現在のKeynote書類の現在のスライド（ページ）上の画像（imageオブジェクト）のサイズを取得し、順次照合。同じサイズのものがあれば、それが選択中のオブジェクトであると類推します。

かなり穴の多いロジックですが、最初の一歩としては悪くないでしょう。とりあえずは、サイズで比較を行い、同一のものがあれば画像同士の類似性を計算するといった方法も検討できそうです。

お手上げになってしまうのは、画像サイズや内容ともに同一のものが複数あった場合です。その場合を除けば割と識別できそうに思えます。

また、ながらく調査を行なってきた「ローカライズ言語に依存しないGUI Scripting」を用いて選択中のオブジェクトのコピーができるとよさそうです。

AppleScript名：Keynoteで選択中の画像を特定する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/22
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.7"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set kRes to getSelectedImage() of me
–> image 3 of slide 24 of document id "534F4E65-4459-4B00-95D4-34C3E020467E"

on getSelectedImage()
　　my executeKeynoteItemCopy() –Execute Copy From Menu
　　
　　–クリップボードの内容をNSImageに
　　set aNSIMage to my getClipboardASImage()
　　if aNSIMage = false then
　　　　return false
　　end if
　　
　　–クリップボード中のNSImageのサイズを取得
　　set aSize to aNSIMage’s |size|()
　　set selWidth to (aSize’s width) as real
　　set selHeight to (aSize’s height) as real
　　
　　–Keynoteの最前面のドキュメントの現在のスライド上の画像からサイズを取得してクリップボード内の画像サイズと照合する
　　tell application "Keynote"
　　　　tell front document
　　　　　　tell current slide
　　　　　　　　set iList to every image
　　　　　　　　
　　　　　　　　repeat with i in iList
　　　　　　　　　　set myHeight to (height of i) as real
　　　　　　　　　　set myWidth to (width of i) as real
　　　　　　　　　　if {myWidth, myHeight} = {selWidth, selHeight} then
　　　　　　　　　　　　return contents of i
　　　　　　　　　　end if
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
　　return false
end getSelectedImage

— クリップボードの内容をNSImageとして取り出して返す
on getClipboardASImage()
　　set theNSPasteboard to current application’s NSPasteboard’s generalPasteboard()
　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({current application’s NSImage}) options:(missing value)
　　if theAttributedStringNSArray = {} then return false
　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　return theNSAttributedString
end getClipboardASImage

on executeKeynoteItemCopy()
　　activate application "Keynote"
　　tell application "System Events"
　　　　tell process "Keynote"
　　　　　　–click menu item "Copy" of menu 1 of menu bar item "Edit" of menu bar 1
　　　　　　click menu item "コピー" of menu 1 of menu bar item "編集" of menu bar 1
　　　　end tell
　　end tell
end executeKeynoteItemCopy

★Click Here to Open This Script　

AirSharingLib Script Library

Posted on 1月 22, 2020 by Takaaki Naganoya

AppleScriptからAirDrop経由で他のMacやiPhone、iPadなどのiOSデバイスとファイル共有するAppleScript Library「AirSharingLib」v1.0です。

–> Download airsharinglib(To ~/Library/Script Libraries/)

もともとの内容はhttp://www.macosautomation.comに掲載されている「Sharing Utilities」ですが、現在のmacOS用に一部書き換えたのと、WiFiの強制パワーオンなどの機能を追加しています。

AirDrop経由のファイル共有については、さまざまな場面で必要になりますし、複数ファイルを指定してAirDrop共有するのはGUI側（Finder側）から行うのはなかなか操作が煩わしいので、AppleScriptから操作できると便利です。

そうしたAirDrop共有のためのAppleScriptライブラリが存在していることは重要なのですが、Sharing Utilityだといまひとつ古くなりすぎているので、さまざまなプログラムで参照するのに問題が出てくるように感じていました。

そのため、あらためてSharing Utilityとは別のライブラリをでっち上げた次第です。

AppleScript名：sample1

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/20
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
–　　http://www.piyocast.com
use AppleScript version "2.7" –10.13 or later
use framework "Foundation"
use scripting additions
use airLib : script "AirSharingLib"

set fileList to (choose file with prompt "You can select multiple files with folding [SHIFT] key" with multiple selections allowed)

share with air fileList

★Click Here to Open This Script　

自然言語テキストから複数の日付情報を抽出

Posted on 1月 21, 2020 by Takaaki Naganoya

自然言語テキストから日付の情報（複数可）を抽出するAppleScriptです。

URLやメールアドレスの抽出では、複数のデータをNSDataDetectorで抽出するAppleScriptは書いてありましたが、日付情報の抽出を行うものはなかったので、書いておきました。

AppleScript名：自然言語テキストから複数の日付情報（複数）を抽出して日付のリストを返す.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/21
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set theDate to getDatesIn("本テキストには次の火曜日という日付情報を含んでいる。明日かもしれない。次の木曜日もそうだ。") of me
–> {date "2020年1月28日火曜日 12:00:00", date "2020年1月22日水曜日 12:00:00", date "2020年1月23日木曜日 12:00:00"}

set theDate to getDatesIn("This text contains next Tuesday. The date may be tomorrow. Next Wednesday happen.") of me
–> {date "2020年1月28日火曜日 12:00:00", date "2020年1月22日水曜日 12:00:00", date "2020年1月29日水曜日 12:00:00"}

on getDatesIn(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　set theDetector to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(missing value)
　　set theMatchs to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　if theMatchs = missing value then error "No date found with String:" & aString
　　set dRes to theMatchs’s valueForKeyPath:"date"
　　return dRes as list
end getDatesIn

★Click Here to Open This Script　

AppleScript名：自然言語テキストから複数の日付情報（複数）を抽出して日付と当該箇所のリストを返す v2.scptd

set theDate to getDatesAndOrigStringsIn("本テキストには次の火曜日という日付情報を含んでいる。明日かもしれない。次の木曜日もそうだ。") of me
–> {{originalStr:"次の火曜日", detectDate:date "2020年1月28日火曜日 12:00:00"}, {originalStr:"明日", detectDate:date "2020年1月22日水曜日 12:00:00"}, {originalStr:"次の木曜日", detectDate:date "2020年1月23日木曜日 12:00:00"}}

set theDate to getDatesAndOrigStringsIn("This text contains next Tuesday. The date may be tomorrow. Next Wednesday happen.") of me
–> {{originalStr:"next Tuesday", detectDate:date "2020年1月28日火曜日 12:00:00"}, {originalStr:"tomorrow", detectDate:date "2020年1月22日水曜日 12:00:00"}, {originalStr:"Next Wednesday", detectDate:date "2020年1月29日水曜日 12:00:00"}}

on getDatesAndOrigStringsIn(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　set theDetector to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(missing value)
　　set theMatchs to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　if theMatchs = missing value then error "No date found with String:" & aString
　　set dRes to (theMatchs’s valueForKeyPath:"date") as list
　　set rRes to (theMatchs’s valueForKeyPath:"range") as list
　　
　　set allRes to {}
　　set aLen to length of dRes
　　repeat with i from 1 to aLen
　　　　set aSubStr to (anNSString’s substringWithRange:(item i of rRes))
　　　　set dDate to contents of item i of dRes
　　　　set the end of allRes to {originalStr:aSubStr as string, detectDate:dDate}
　　end repeat
　　
　　return allRes
end getDatesAndOrigStringsIn

★Click Here to Open This Script　

Numbersで書類Aのすべてのシートの表1を、書類Bの現在のシートの表１にまとめる

Posted on 1月 21, 2020 by Takaaki Naganoya

Numbersでオープン中の複数の書類があったときに、書類Aのすべてのシートの表１を、書類Bの現在のシートの表１にまとめるAppleScriptです。

さすがに、機械的な作業すぎて手で行う気にはなれなかったので、ありもののScriptを利用して作ってみました。

こういう用途のために作っておいたライブラリ「choose multiple list」を利用しています。

▲データ取得元

▲データ集約先

▲ダイアログで「データ取得元」と「データ集約先」を選択

BridgePlus内蔵のFrameworkがmacOS 10.14/10.15に邪魔されて認識されない環境では動かせないかもしれません。このあたり、SIP解除するしかないと思わせるものがあります。

ライブラリで複雑な選択を行えるUI部品を作っておいたおかげで、これだけ込み入った動作を行うAppleScriptを書きましたが、Cocoaの機能はほぼ使っていません（getDataFromNumbersDocは作り置きしておいた、頻出ルーチンなので使いまわしています）。choose multiple listライブラリは、こういう用途のために作っておいたものであり、まさにそのぴったりな用途であったといえるでしょう。

AppleScript名：書類Aのすべてのシートの表1を、書類Bの現在のシートの表１にまとめる.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/20
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use scripting additions
use bPlus : script "BridgePlus"
use mulList : script "choose multiple list"

script spd
　　property allData : {}
end script

set (allData of spd) to {}

set {aName, bName} to getTargetDocNames() of me

–「データ取得元」のNumbers書類のすべてのシートの表１から2D Listでデータ取得
tell application "Numbers"
　　tell document aName
　　　　set sList to name of every sheet
　　　　repeat with i in sList
　　　　　　set tmp2DDat to getDataFromNumbersDoc(aName, i) of me
　　　　　　set (allData of spd) to (allData of spd) & tmp2DDat
　　　　end repeat
　　end tell
end tell

set aHeight to length of (allData of spd)
set aWidth to length of item 1 of (allData of spd)

–「データ集約先」のNumbers書類の現在のシートの表１にまとめた2D Listを展開する（巨大すぎると時間がかかるので、CSV書き出ししてオープンするなどの別の方法を採るべき）
tell application "Numbers"
　　tell document bName
　　　　tell active sheet
　　　　　　set tRes to make new table with properties {row count:aHeight + 1, column count:aWidth}
　　　　end tell
　　end tell
end tell

fillCurrentTable(bName, (allData of spd)) of me

–Numbersの書類の現在のシートを、指定の２次元配列でfillする
on fillCurrentTable(docName, aList)
　　set aLen to length of aList
　　set aWidth to length of first item of aList
　　
　　tell application "Numbers"
　　　　tell document docName
　　　　　　tell active sheet
　　　　　　　　tell table 1
　　　　　　　　　　repeat with i from 1 to aLen
　　　　　　　　　　　　tell row (i + 1)
　　　　　　　　　　　　　　set aRowList to contents of item i of aList
　　　　　　　　　　　　　　repeat with ii from 1 to aWidth
　　　　　　　　　　　　　　　　tell cell ii
　　　　　　　　　　　　　　　　　　set aTmpData to contents of item ii of aRowList
　　　　　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　　　　　set value to aTmpData
　　　　　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　　　end repeat
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
end fillCurrentTable

–Numbersでオープン中の書類の名称一覧からデータ取得元とデータ集約先の書類名をダイアログで選択
on getTargetDocNames()
　　tell application "Numbers"
　　　　set nList to name of every document
　　end tell
　　
　　set selList to {nList, nList}
　　set tList to {"データ取得元", "データ集約先"}
　　
　　set {aRes, bRes} to choose multiple list selList main message "各Numbers書類の役割を選択してください" sub message "「データ取得元」のデータを順次、「データ集約先」の表1に連結します" with title lists tList height 140 width 400 return type item contents without allow same items
　　return {aRes, bRes}
end getTargetDocNames

–Numbersでオープン中の書類の選択中のシートの表1からデータを取得して2D Listに
on getDataFromNumbersDoc(aDocName, sheetName)
　　
　　load framework
　　
　　tell application "Numbers"
　　　　if (count (every document)) = 0 then return false
　　　　
　　　　tell document aDocName
　　　　　　if (count (every sheet)) = 0 then return false
　　　　　　
　　　　　　tell sheet sheetName
　　　　　　　　tell table 1
　　　　　　　　　　set colCount to column count
　　　　　　　　　　set rowCount to row count
　　　　　　　　　　set headerCount to header row count
　　　　　　　　　　set footerCount to footer row count
　　　　　　　　　　
　　　　　　　　　　set dList to value of every cell of cell range
　　　　　　　　end tell
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
　　
　　–Convert 1D List to 2D List
　　set bList to (current application’s SMSForder’s subarraysFrom:dList groupedBy:colCount |error|:(missing value)) as list
　　set sItem to 1 + headerCount
　　set eItem to rowCount – footerCount
　　set cList to items sItem thru eItem of bList
　　
　　return cList
　　
end getDataFromNumbersDoc

★Click Here to Open This Script　

BlogアーカイブのMarkdown書類をリネーム。親、親+1階層フォルダをMM, YYYYとみなして反映

Posted on 1月 19, 2020 by Takaaki Naganoya

Finderで選択中のファイルすべてに対して、親フォルダ名、親＋1階層のフォルダ名を反映させたファイル名をつけるAppleScriptです。

Blogアーカイブ本を作るのに、こうした道具を作って使っています。一度書いておけば、２度目からは大幅に時間を短縮できます。最初のファイルから拡張子を取得してそれを後続のファイルすべてに適用するため、同一種類のファイルである必要があります。自分用のツールならではの手抜きといったところでしょうか。

AppleScript名：BlogアーカイブのMarkdown書類をリネーム。親、親+1階層フォルダをMM, YYYYとみなして反映 .scptd

— Created 2020-01-18 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

–選択ファイルを取得
tell application "Finder"
　　set aSel to selection as alias list –Select documents to Rename
end tell

set aCount to 10 –start
set aStep to 10
set aDigit to 3

–パス情報を取得
set aFirst to first item of aSel
set aPOSIX to POSIX path of aFirst
set aPathStr to (current application’s NSString’s stringWithString:aPOSIX)
set aDateComList to aPathStr’s pathComponents() –ディレクトリごとにパス情報を分割してリスト化
set aExt to aPathStr’s pathExtension() –拡張子

set aYear to (item -3 of aDateComList) as string –親の親フォルダ名
set aMonth to (item -2 of aDateComList) as string –親フォルダ名

–リネーム（数百項目を超える場合にはFinderでは遅すぎるのでNSFileManagerで処理）
tell application "Finder"
　　repeat with i in aSel
　　　　set aTEXT to numToZeroPaddingStr(aCount, aDigit, "0") of me –3 digit
　　　　set aName to aYear & aMonth & aTEXT & "." & aExt
　　　　set name of i to aName
　　　　set aCount to aCount + aStep
　　end repeat
end tell

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

AppleScriptを実行中のランタイムプログラム名を取得する

Posted on 1月 18, 2020 by Takaaki Naganoya

AppleScriptのランタイムプログラム名（ランタイム名）を取得するAppleScriptです。AppleScript自身が「何によって」実行されているか、その実行プログラム名を取得するものです。

AppleScriptには何種類かランタイム環境が存在し、ランタイム環境ごとに若干の動作が変わってくることが知られています。

ランタイム環境ごとにどこが違うといえば、Finderからのselectionを取得できるとかできないとか（AppleScript Studioがこれに該当。もうありませんけれども）、GUI Scriptingの権限の認証を得られるとか得られないとか。ウィンドウを動的に生成して表示したときに最前面に表示できるとかできないとか（Script Menuがこれに該当）。明示的にメインスレッドで実行する機能がないとか（Script Debuggerがこれに該当）。そういうところです（ほかにもあるかもしれない）。

過去に作ったAppleScriptを確認していたところ、プロセス名を取得するだけの使えないプログラムだと思っていたものが、実は「ランタイムプログラムのプログラム名」を取得できるというスゲーものであることを再発見しました。

ながらく、ランタイムプログラム名をAppleScript側から取得する必要性を感じていたため、この機会に調べてみることに。プログラム自体は些細な（↓）ものです。

AppleScript名：ランタイム環境名の表示

— Created 2015-09-08 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set procInfo to current application’s NSProcessInfo’s processInfo()
set aName to procInfo’s processName() as string
display dialog aName

★Click Here to Open This Script　

Script Editor上で実行

–> “Script Editor”

Script Debugger上で実行

–> “Script Debugger”

ASObjC Explorer 4上で実行

–> “ASObjC Explorer 4”

Automator上で実行

–> “Automator”
これには驚きました。特別のランタイムプログラムが使われているのか、それとも単に親プロセスとしてのAutomatorが返ってきているのかは不明ですが、識別できるということには意義がありそうです。

Script Menu上で実行

–> “osascript”
これは、よく知られていることなのでとくに驚きはありません。テストを実施したのはmacOS 10.14.6上で、Script Menuは「スクリプトメニュー」という別アプリケーション（/System/Library/CoreServices/ にある）に変更になったOSバージョンですが、ランタイムにosascriptを使い続けていることを確認することになりました（それ以前のOSと挙動が同じなのでそうだと思っていましたけれども）。

Folder Action上で実行

–> “osascript”
Folder Actionは、macOS標準搭載のフォルダ監視機能です。監視対象のフォルダにファイルが追加されたり、移動されたり、フォルダそのものがオープンしたりするとその対象ファイル/フォルダで指定のAppleScriptを実行します。よく、ドラッグ＆ドロップで処理を受け付けたり、ネットワーク経由でファイルを受信した場合にAppleScriptを実行するような使われ方をします。
Folder Action Disptcherが実行しているとばかり思っていたのですが、実際に確認したらosascriptでした。ちなみに、Folder ActionはmacOS 10.11でフルに書き換えられてそれ以前とは別物になっています。以前は数秒に一度対象フォルダをチェックする方式でしたが、10.11以降はFSEventsを利用して随時監視対象フォルダへの変更を受け付けます。

Switch Control上で実行

–> “osascript”
障害者向けの機能としてmacOSに標準装備されている、フローティングパレットからAppleScriptを呼び出せる機能である「Switch Control」。手を使わずに操作したり、他のコントローラで操作するような標準的ではない使い方をサポートするための機構ですが、普通に普通の人が使っても役立ちます。　
Switch ControlでAppleScriptを実行する場合のランタイムプログラムはosascriptです。

CotEditor上で実行

–> “osascript”
これは、CotEditorのソースを読んで確認してありました。ここだけ割と手抜き実装ですが、それでも複数のOSA言語に対応できたりと機能的には悪くはありません。むしろ、osascript側のランタイム環境が他の環境よりも一段落ちることに問題が、、、、GUI Scriptingの権限を取得できないこととか、このCotEditorのメニューから実行するとREST APIが呼び出せないとか。同じosascript系でもScript Menuのほうが制約が少ないのは、おそらくアプリケーション自体に許可されている条件の違いによるものでしょう。

FileMaker Pro上でスクリプトステップ「AppleScriptを実行」を実行

–> “FileMaker Pro”
FileMaker Proはランタイムアプリケーションが廃止され、FileMaker Pro AdvancedもFileMaker Proに一本化されたので、v19以降はFileMaker Proは「FileMaker Pro」というランタイムのみでしょう。v19でもFileMaker Pro自体はSandbox化されていないため、微妙にセキュリティ上の制約が少ない＝自由度の高いランタイム環境として残っていくことでしょう。

Script EditorからApplet書き出しして実行

–> “applet”
取得できたらいいなぐらいの気持ちで試してみたものの、これが識別できるのはうれしい誤算です。書き出したAppleScript Applet名は「Appletでランタイム名を取得」であったため、この「applet」というものとは異なります（ねんのため）。

AutomatorからApplet書き出しして実行

–> “Application Stub”
見たことのない名前が、、、、やっぱり、これも別ランタイムなんですね、、、、

Script DebuggerからApplet(Enhanced)で書き出しして実行

–> “FancyDroplet”
Appleの標準ランタイムとはあきらかに別物（Enhanced）なので、たぶん別の名前がついているだろうとは思っていましたが、そういう名前でしたか。名前が予想外だったので驚かされましたが、識別できることに意義があります。

Cocoa-AppleScript Appletを実行

–> “CocoaApplet”
Script Editor上で作成できる、通常のAppleScriptとXcode上で作成するCocoa-Applicationの中間的な性格を持つ「Cocoa-AppleScript Applet」でランタイムプログラム名を取得したらこうなりました。

もちろん、実行プログラム名はまったく別の「ランタイム名を表示するだけのCocoa-AppleScript Applet」というものです。

ショートカットで「AppleScriptを実行」アクションを実行

–> “MacHelper”

macOS 12で搭載されたショートカット.app（Shortcuts.app）および不可視プロセスのAppleScriptの補助専用アプリケーション「Shortcuts Events.app」上で、アクション「AppleScriptを実行」でAppleScriptを実行するときのランタイム名は、「MacHelper」です。意外なところで、ユーザーディレクトリ以下にインストールされたAppleScriptライブラリをこのMacHelper環境は認識します。

→ macOS 13上では、ショートカット.app（Shortcuts.app）およびShortcuts Events.app上のランタイム名が「ShortcutsMacHelper」に変更されました。

RedSweater Software「FastScripts」からAppleScriptを実行

red sweater softwareによるメニュー常駐型Script Menuソフトウェア「FastScripts」から実行したときのランタイム名は「FascScripts Script Runner」です。

Knurling Group「Service Station」からAppleScriptを実行

Knurling Groupによるコンテクストメニューのカスタマイズ・ソフトウェア「Service Station」から実行したときのランタイム名は「osascript」です。

ランタイム名が得られることで実現できること

これらのほか、各アプリケーション内でAppleScript呼び出し機能を有するもの（ファイルメーカー、Mail.appなど）でランタイムプログラム名を取得すると有益な情報が得られることでしょう。

これは、地球上にいる人類が観測衛星を打ち上げて「ここは銀河系だ」と観測できるぐらいすごいことなので、割と意義深いものです。実行中のAppleScriptが、「いま、何のプログラムによって自分自身が実行されている」かという情報を取得できます。

ランタイムプログラムの名称取得については、いくつかのAppleScript実行方法を試してみましたが、得られる名前に違いがないことを確認しています。

直接AppleScriptを動かす方法に加え、間接的にAppleScriptを動かす方法も試してみましたが、同じ結果が得られました。

つまり、動的にOSAScriptViewを生成して実行しようが、NSAppleScriptで実行しようが、AppleScriptの「run script」コマンドで実行しようが、取得されるランタイム名には差がありません。

これで、ランタイム環境のプロセスの親プロセスの情報が取得できると、Terminal.app上から起動したosascriptコマンドで呼び出したのか、Script Menu上から呼び出したのかという状況をAppleScript側で認識できることになることでしょう。

ランタイム環境を識別した上で、各環境で実行できない処理を行わないとか、ランタイム環境ごとに処理を分岐できるようになることでしょう。

ちょうど、Edama2さんと「ランタイム環境ごとに若干の挙動の違いが見られるし、利用できるCocoaの機能にも違いがあるから、ランタイム環境ごとに認識コードでも振ってみようか」などと相談していたので、渡りに船でした。

display drop dialog Script Library

Posted on 1月 16, 2020 by Takaaki Naganoya

指定UTIのファイルのFinderからのドラッグ＆ドロップを受け付けるAppleScript Libraries「display drop dialog」をリリース、フリー配布いたします。

＃本ライブラリはEdama2さんのScriptに若干の改変を行い、sdefをつけてパラメータのエラー処理を行い、コードサインしてライブラリ化したものです

–> Download display drop dialog Script Library (To ~/Library/Script Libraries/)

本ライブラリは、指定UTIの書類のドラッグ＆ドロップを受け付けるダイアログをAppleScriptから手軽に使えるようにするものです。macOS 10.14以降で動作します。

現在のAppleのTim Cook体制は、セキュリティ強化の美名のもとに「動かないコンピュータ」を目指し、各種機能を阻害する方向に進んでいます。

AppleScriptの世界はその中でも自由度が比較的高い状態にありますが、それでもmacOS 10.12以降では、AppleScriptドロップレットにFinderからドラッグ＆ドロップしても、Finderの拡張属性（Xattr）がついたファイルは無視されたりと、なかなか困ります。

そこで、Finderからのドラッグ＆ドロップ操作を通常の（Applet書き出ししていない）AppleScript、とくにScript Menuから呼び出す形式のAppleScriptで使えるようにすることを目的として本ライブラリを作成しました。

本ライブラリを用いることで、ドロップレットを作らなくても、Script Menuから呼び出した普通のAppleScriptにファイルのドラッグ＆ドロップの受信機能を追加できます。セキュリティと機能性（ドラッグ＆ドロップ）を両立させるため、すべてのScripterに欠かすことのできないライブラリになるものと期待しています。

本ライブラリのAppleScript用語辞書には実行イメージ（画面キャプチャ）およびサンプルScriptを入れてあり、実行時の様子やサンプルスクリプト（本Blogと同様のワンクリックで内容が転送されるリンクつき）を確認できるようになっています。

AppleScript名：accept AppleScript documents

use dropLib : script "display drop dialog"

set aMainMes to "Drop AppleScript"
set aSubMes to "Drag and Drop AppleScript files here"
set aUTI to "com.apple.applescript.script"
set execButtonTitle to "Execute"
set aRes to (display drop dialog aUTI main message aMainMes sub message aSubMes with initial folder "" OK button title execButtonTitle)
–> {alias "Machintosh HD:Users:me:Documents:display drop dialog:accept PNG images.scpt", alias "Machintosh HD:Users: me:Documentsaccept Markdown documents.scpt"}

★Click Here to Open This Script　

AppleScript名：accept Markdown documents

use dropLib : script "display drop dialog"

set aMainMes to "Drop Markdown Documents"
set aSubMes to "Drag and Drop Markdown documents here"
set aUTI to "net.daringfireball.markdown"
set execButtonTitle to "Execute"
set aRes to (display drop dialog aUTI main message aMainMes sub message aSubMes with initial folder "" OK button title execButtonTitle)
–> {alias "Machintosh HD:Users:me:Documents::–Book 11 「Blog Archives vol5 2013-2014」:2013:01:201301013.md", alias "Machintosh HD:Users:me:Documents::–Book 11 「Blog Archives vol5 2013-2014」:2013:01:201301012.md"}

★Click Here to Open This Script　

AppleScript名：accept PNG images with initial folder contents

use scripting additions
use dropLib : script "display drop dialog"

set aMainMes to "Drop PNG"
set aSubMes to "Drag and Drop png images here"
set aUTI to "public.png"
set execButtonTitle to "Execute"
set iFolder to path to pictures folder –At first, PNG files in this folder is displayed
set aRes to (display drop dialog aUTI main message aMainMes sub message aSubMes with initial folder iFolder OK button title execButtonTitle)
–> {alias "Machintosh HD:Users:me:Pictures:1015sedhelp2.png", alias "Machintosh HD:Users:me:Pictures:574G01.png", alias "Machintosh HD:Users:me:Pictures:macDown1.png", alias "Machintosh HD:Users:me:Pictures: 2017-09-27 19.33.53.png", alias "Machintosh HD:Users:me:Pictures:2018-11-01 10.54.06.png"

★Click Here to Open This Script　

Numbersでオープン中の最前面の書類のすべてのシートの表1の行数合計を計算する

Posted on 1月 15, 2020 by Takaaki Naganoya

Numbersでオープン中の最前面の書類のすべてのシートの表1の行数の合計を計算するAppleScriptです。

Blogアーカイブ本作成のために書いたものです。

この記事数をカウントするために使いました。

AppleScript名：Numbersでオープン中の最前面の書類のすべてのシートの表1の行数合計を計算する

set aCount to 0

tell application "Numbers"
　　tell front document
　　　　set sList to every sheet
　　　　repeat with i in sList
　　　　　　tell i
　　　　　　　　try
　　　　　　　　　　set tmpC to count every row of table 1
　　　　　　　　　　set aCount to aCount + tmpC
　　　　　　　　end try
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

return aCount

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

Posted on 1月 15, 2020 by Takaaki Naganoya

Edama2さんからの投稿Scriptです。アラートダイアログ中に各種GUI部品を詰め込む「箱庭インタフェース」シリーズ。テーブルビューを表示して、Finderからのアプリケーションのドラッグ＆ドロップを受け付けるAppleScriptです。

–> Download Editable & Executable Script Bundle Document

カスタムクラスの作り方がわかったので、懲りずにTable Viewネタです。
Thanks  Shane Stanley!

アプリケーションフォルダ直下のアプリを、NSValueTransformerを使ってコラムにローカライズ名とアイコンを表示するのと、finderからのドラッグ＆ドロップでアイテムの追加です。
追加時に重複チェックをしているので試す時はユーティリティフォルダか別の場所にあるアプリで試してください。

本Scriptは自分も作りたいと思いつつも調査が進んでいなかったものですが、TableViewでFinderからのドラッグ＆ドロップを受け付けます。

これを鍛えて再利用しやすい部品に育てることで、ドロップレットの代替品にできると思っています。macOS 10.12以降、Finder上のファイルをAppleScriptドロップレットにドラッグ＆ドロップで処理させても、OS側がダウンロードファイルにつけた拡張属性（Xattr）「com.apple.quarantine」がついているとドロップレット側で処理できなかったりします（回避方法はありますけれども）。

このドロップレットという仕組みを使わずに、同様にドラッグ＆ドロップによる処理を手軽にできる代替インタフェースとしてこのようなものを考えていた次第です。自分で作らなくてもEdama2さんが作ってくださったので助かりました、、、、

AppleScript名：アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

on run
　　my main()
end run
on main()
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　#
　　set aFolder to path to applications folder
　　set aPath to aFolder’s POSIX path
　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　
　　set filePaths to filePaths as list
　　set thisFileType to "com.apple.application-bundle"
　　
　　set fileURLs to {}
　　repeat with anItem in filePaths
　　　　
　　　　set aPath to anItem’s contents’s POSIX path
　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　
　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　
　　　　if (aUTI as text) is thisFileType then
　　　　　　set fileURLs’s end to aURL
　　　　end if
　　end repeat
　　
　　set optionRec to {fileURLs:fileURLs, fileType:thisFileType}
　　
　　set aMainMes to "アプリケーションの選択"
　　set aSubMes to "適切なものを以下からえらんでください"
　　set dateObj to my chooseItemByTableView(aMainMes, aSubMes, optionRec)
end main

# アラートダイアログでtableviewを表示
on chooseItemByTableView(aMainMes, aSubMes, optionRec)
　　### set up view
　　set {theView, makeObj} to my makeContentView(optionRec)
　　
　　set paramObj to {myMessage:aMainMes, mySubMessage:aSubMes, setView:theView, myOption:makeObj}
　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　
　　if (my _retrieve_data) is missing value then error number -128
　　return (my _retrieve_data)
end chooseItemByTableView

## retrieve date
on raizeAlert:paramObj
　　set mesText to paramObj’s myMessage
　　set infoText to paramObj’s mySubMessage
　　set theView to paramObj’s setView
　　set aTableObj to paramObj’s myOption
　　
　　global _retrieve_data
　　set _retrieve_data to missing value
　　
　　### set up alert
　　tell current application’s NSAlert’s new()
　　　　setMessageText_(mesText)
　　　　setInformativeText_(infoText)
　　　　addButtonWithTitle_("OK")
　　　　addButtonWithTitle_("Cancel")
　　　　setAccessoryView_(theView)
　　　　tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
　　　　#### show alert in modal loop
　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell
　　
　　### retrieve date
　　set aIndexSet to aTableObj’s selectedRowIndexes()
　　
　　set chooseItems to ((aTableObj’s dataSource())’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　set _retrieve_data to {}
　　repeat with anItem in chooseItems
　　　　set _retrieve_data’s end to anItem’s fileURL
　　end repeat
end raizeAlert:

## ContentView を作成
on makeContentView(paramObj)
　　## 準備
　　set fileURLs to (paramObj’s fileURLs) as list
　　set thisFileType to (paramObj’s fileType) as text
　　
　　set keyrec to {column1:"Name"}
　　set keyDict to (current application’s NSDictionary’s dictionaryWithDictionary:keyrec)
　　
　　set theDataSource to current application’s YKZArrayController’s new()
　　
　　## NSTableView
　　tell current application’s NSTableView’s alloc()
　　　　tell initWithFrame_(current application’s CGRectZero)
　　　　　　setAllowsEmptySelection_(false)
　　　　　　setAllowsMultipleSelection_(true)
　　　　　　setDataSource_(theDataSource)
　　　　　　setDelegate_(theDataSource)
　　　　　　setDoubleAction_("doubleAction:")
　　　　　　setGridStyleMask_(current application’s NSTableViewSolidVerticalGridLineMask)
　　　　　　setSelectionHighlightStyle_(current application’s NSTableViewSelectionHighlightStyleRegular)
　　　　　　setTarget_(theDataSource)
　　　　　　setUsesAlternatingRowBackgroundColors_(true)
　　　　　　
　　　　　　set thisRowHeight to rowHeight() as integer
　　　　　　set theDataSource’s _table_view to it
　　　　end tell
　　end tell
　　
　　# data sourceに追加
　　tell (theDataSource)
　　　　awakeFromNib()
　　　　set its _file_type to thisFileType
　　　　
　　　　repeat with aURL in fileURLs
　　　　　　addObject_({fileURL:aURL})
　　　　end repeat
　　　　
　　　　setSelectionIndex_(0)
　　end tell
　　
　　## NSTableColumn
　　### Columnの並び順を指定する
　　set viewWidth to 320
　　set columnsCount to keyDict’s |count|()
　　repeat with colNum from 1 to columnsCount
　　　　
　　　　set keyName to "column" & colNum as text
　　　　set aTitle to (keyDict’s objectForKey:keyName)
　　　　
　　　　tell (current application’s NSTableColumn’s alloc()’s initWithIdentifier:(colNum as text))
　　　　　　tell headerCell()
　　　　　　　　setStringValue_(aTitle)
　　　　　　　　set thisHeaderHeight to cellSize()’s height
　　　　　　end tell
　　　　　　
　　　　　　### Columnの横幅を指定
　　　　　　setWidth_(viewWidth)
　　　　　　
　　　　　　### バインディングのオプション
　　　　　　— ソートを無効にする
　　　　　　set anObj to (current application’s NSNumber’s numberWithBool:false)
　　　　　　set aKey to current application’s NSCreatesSortDescriptorBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　
　　　　　　### 表示内容をNSArrayControllerにバインディング
　　　　　　bind_toObject_withKeyPath_options_(current application’s NSValueBinding, theDataSource, "arrangedObjects", bOptions)
　　　　　　
　　　　　　(theDataSource’s _table_view’s addTableColumn:it)
　　　　end tell
　　　　
　　end repeat
　　
　　## NSScrollView
　　### Viewの高さを計算
　　set rowCount to 12 –> 行数を固定
　　set viewHeight to (thisRowHeight + 2) * rowCount + thisHeaderHeight –> 2を足さないと高さが合わない
　　set vSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　
　　### Viewを作成
　　tell current application’s NSScrollView’s alloc()
　　　　tell initWithFrame_(vSize)
　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　setDocumentView_(theDataSource’s _table_view)
　　　　　　–setHasHorizontalScroller_(true)
　　　　　　setHasVerticalScroller_(true)
　　　　　　set aScroll to it
　　　　end tell
　　end tell
　　
　　return {aScroll, theDataSource’s _table_view}
end makeContentView

★Click Here to Open This Script　

AppleScript名：subClasses

#MARK: – NSValueTransformer
script YKZURLToIcon
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSImage –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set iconImage to current application’s NSWorkspace’s sharedWorkspace’s iconForFile:appPath
　　　　return iconImage
　　end transformedValue:
end script

script YKZURLToDisplayedName
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set displayedName to current application’s NSFileManager’s defaultManager’s displayNameAtPath:appPath
　　　　return displayedName
　　end transformedValue:
end script

#MARK: – Array Controller
script YKZArrayController
　　property parent : class "NSArrayController"
　　
　　#MARK: IBOutlets
　　property _table_view : missing value
　　#MARK:
　　property _data_type : do shell script "uuidgen"
　　property _file_type : ""
　　
　　on awakeFromNib()
　　　　–log "YKZArrayController – awakeFromNib"
　　　　tell _table_view
　　　　　　registerForDraggedTypes_({current application’s NSFilenamesPboardType, _data_type})
　　　　　　setDraggingSourceOperationMask_forLocal_(current application’s NSDragOperationCopy, false)
　　　　end tell
　　　　
　　　　#Transformerの登録
　　　　set tNames to {}
　　　　set tNames’s end to "YKZURLToIcon"
　　　　set tNames’s end to "YKZURLToDisplayedName"
　　　　repeat with aTransformer in tNames
　　　　　　set theTransformer to current application’s class aTransformer’s new()
　　　　　　(current application’s NSValueTransformer’s setValueTransformer:theTransformer forName:aTransformer)
　　　　end repeat
　　end awakeFromNib
　　
　　#MARK: Data Source Overrides
　　on numberOfRowsInTableView:aTableView
　　　　return my content()’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aTableView viewForTableColumn:aColumn row:aRow
　　　　–log "viewForTableColumn"
　　　　
　　　　set aCellView to aTableView’s makeViewWithIdentifier:"YKZTableCellView" owner:me
　　　　–set isNull to aCellView’s isEqual:(current application’s NSNull’s |null|())
　　　　–log isNull as text
　　　　
　　　　if aCellView is missing value then
　　　　　　
　　　　　　set frameRect to current application’s NSMakeRect(0, 0, aColumn’s width, aTableView’s rowHeight())
　　　　　　set aCellView to current application’s YKZTableCellView’s alloc’s initWithFrame:frameRect
　　　　　　
　　　　　　set anObj to "YKZURLToIcon"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s imageView())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToDisplayedName"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s textField())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　end if
　　　　
　　　　return aCellView
　　end tableView:viewForTableColumn:row:
　　
　　# テーブル内のセルが編集できるか
　　on tableView:aTableView shouldEditTableColumn:aColumn row:aRow
　　　　return false
　　end tableView:shouldEditTableColumn:row:
　　
　　# テーブル内をダブルクリックしたらOKボタンを押す
　　on doubleAction:sender
　　　　log "doubleAction"
　　　　## ヘッダをクリックした時は何もしない
　　　　if (sender’s clickedRow()) is -1 then return
　　　　
　　　　set theEvent to current application’s NSEvent’s ¬
　　　　　　keyEventWithType:(current application’s NSEventTypeKeyDown) ¬
　　　　　　　　location:(current application’s NSZeroPoint) ¬
　　　　　　　　modifierFlags:0 ¬
　　　　　　　　timestamp:0.0 ¬
　　　　　　　　windowNumber:(sender’s |window|()’s windowNumber()) ¬
　　　　　　　　context:(current application’s NSGraphicsContext’s currentContext()) ¬
　　　　　　　　|characters|:return ¬
　　　　　　　　charactersIgnoringModifiers:(missing value) ¬
　　　　　　　　isARepeat:false ¬
　　　　　　　　keyCode:0
　　　　current application’s NSApp’s postEvent:theEvent atStart:(not false)
　　end doubleAction:
　　
　　#MARK: Drag Operation Method
　　#ドラッグを開始（ペーストボードに書き込む）
　　on tableView:aTableView writeRowsWithIndexes:rowIndexes toPasteboard:pboard
　　　　–log "writeRowsWithIndexes"
　　　　set aData to current application’s NSKeyedArchiver’s archivedDataWithRootObject:rowIndexes
　　　　pboard’s declareTypes:{_data_type} owner:(missing value)
　　　　pboard’s setData:aData forType:_data_type
　　　　return true
　　end tableView:writeRowsWithIndexes:toPasteboard:
　　#ドラッグ途中
　　on tableView:aTableView validateDrop:info proposedRow:row proposedDropOperation:operation
　　　　–log "validateDrop"
　　　　#列の間にドラッグ
　　　　if (operation is current application’s NSTableViewDropAbove) then
　　　　　　return current application’s NSDragOperationMove
　　　　end if
　　　　#項目の上にドラッグ
　　　　set aTypes to info’s draggingPasteboard’s types()
　　　　if (aTypes’s containsObject:_data_type) as boolean then
　　　　　　return current application’s NSDragOperationNone
　　　　end if
　　　　return current application’s NSDragOperationNone
　　end tableView:validateDrop:proposedRow:proposedDropOperation:
　　#ドラッグ終了
　　on tableView:aTableView acceptDrop:info row:row dropOperation:operation
　　　　–log "acceptDrop"
　　　　#
　　　　set pboard to info’s draggingPasteboard()
　　　　set aTypes to pboard’s types()
　　　　
　　　　if (aTypes’s containsObject:_data_type) as boolean then
　　　　　　
　　　　　　set rowData to pboard’s dataForType:_data_type
　　　　　　set rowIndexes to current application’s NSKeyedUnarchiver’s unarchiveObjectWithData:rowData
　　　　　　
　　　　　　if (rowIndexes’s firstIndex()) < row then
　　　　　　　　set row to row – (rowIndexes’s |count|())
　　　　　　end if
　　　　　　
　　　　　　set aRange to current application’s NSMakeRange(row, rowIndexes’s |count|())
　　　　　　set aIndexSet to current application’s NSIndexSet’s indexSetWithIndexesInRange:aRange
　　　　　　
　　　　　　set anObj to ((my content())’s objectsAtIndexes:rowIndexes)
　　　　　　my removeObjects:anObj
　　　　　　my insertObjects:anObj atArrangedObjectIndexes:aIndexSet
　　　　　　my rearrangeObjects()
　　　　　　
　　　　else
　　　　　　set pathList to pboard’s propertyListForType:(current application’s NSFilenamesPboardType)
　　　　　　–log result as list
　　　　　　repeat with aPath in pathList
　　　　　　　　set isAdd to addItem_({filePath:aPath, atIndex:row})
　　　　　　　　if isAdd then beep
　　　　　　end repeat
　　　　　　
　　　　end if
　　　　return true
　　end tableView:acceptDrop:row:dropOperation:
　　
　　#追加する
　　on addItem:sender –> {filePath:aPath, atIndex:aIndex}
　　　　–log "addItem:"
　　　　set isAdd to false
　　　　
　　　　#missing valueの時は最後に追加
　　　　set {filePath:aPath, atIndex:aIndex} to sender
　　　　if aIndex is missing value then
　　　　　　set aIndex to my content()’s |count|() as number
　　　　end if
　　　　
　　　　#URLに変換
　　　　set appURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　#アプリケーション以外は追加しない
　　　　set {aResult, aUTI, aError} to (appURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　log aUTI
　　　　if (aUTI as text) is not (my _file_type as text) then return isAdd
　　　　
　　　　#すでにあるか確認
　　　　set bList to my content() as list
　　　　repeat with aRecord in bList
　　　　　　if ((appURL’s isEqual:(aRecord’s fileURL)) as boolean) then
　　　　　　　　set isAdd to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　#なければ追加
　　　　if not isAdd then
　　　　　　set anObj to {fileURL:appURL}
　　　　　　(my insertObject:anObj atArrangedObjectIndex:aIndex)
　　　　end if
　　　　return isAdd
　　end addItem:
end script

#MARK: – NSTableCellView
script YKZTableCellView
　　property parent : class "NSTableCellView"
　　
　　on initWithFrame:rect
　　　　–log "initWithFrame"
　　　　continue initWithFrame:rect
　　　　
　　　　setAutoresizingMask_(current application’s NSViewWidthSizable)
　　　　
　　　　tell current application’s NSImageView’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(0, 0, 16, 16))
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　
　　　　　　　　my setImageView:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(20, 2, 200, 14))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　
　　　　　　　　my setTextField:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return me
　　end initWithFrame:
end script

★Click Here to Open This Script　

Numbersで各シート名称を置換

Posted on 1月 15, 2020 by Takaaki Naganoya

Numbersでオープン中の最前面の書類中にあるすべてのシートの名前を置換するAppleScriptです。

内容は簡単ですが、Numbersにそうした機能が存在しないので、作っておくと便利です。アーカイブ本を作るのに、こうした（↓）資料を作る必要があるわけですが、そのためにこうしたこまごまとしたScriptをその場で作って作業の効率化を図っています。

▲上の画像あくまでは処理イメージなので、厳密に同一データの処理前・処理後の画面スナップショットではありません。各シートの名称の一部の文字列（YYYY部分）のみ置換されていることをご確認ください

AppleScript名：Numbersで各シート名称を置換

tell application "Numbers"
　　tell front document
　　　　set tList to every sheet
　　　　repeat with i in tList
　　　　　　tell i
　　　　　　　　set aName to name
　　　　　　　　set bName to replaceText(aName, "2011_", "2013_") of me
　　　　　　　　set name to bName
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

–任意のデータから特定の文字列を置換
on replaceText(origData, origText, repText)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to {origText}
　　set origData to text items of origData
　　set AppleScript’s text item delimiters to {repText}
　　set origData to origData as text
　　set AppleScript’s text item delimiters to curDelim
　　return origData
end replaceText

★Click Here to Open This Script　

RoundWindow v2

Posted on 1月 12, 2020 by Takaaki Naganoya

Edama2さんと「無理だよねー」「そうそう、絶対無理〜」などとメールで言っていたら、Shane Stanleyから届いた「できるよ」という衝撃のメール。

スクリプトエディタ上で記述する通常のAppleScriptで、CocoaのCustom Class宣言と呼び出しができるとのこと。

自分で動作確認してみるまで、半信半疑でしたが、、、、できますねこれは、、、

–> Download Editable and Executable Script Bundle

冗談半分で思いついたことを試してみたらできてしまったり、冗談半分でできるわけないよねと念のために書いておいたことが世界の誰かの目に止まったりと、「冗談半分」ってけっこう重要なことだと思えてきました。

以下、Shane Stanleyの説明による、その書き換え手順です。

（１）Subclassファイル（複数可）をXcode上のプロジェクトで書くようなスタイルで書く

こういう（↑）スタイルですね。かならずscript宣言しつつ、parent属性を宣言しておくところがXcode上のAppleScriptアプリケーションのスタイルです。あとで動作確認して、アプリケーションの起動や終了に関するイベントハンドラを書いておいたのは無駄（実行されない）ではないかとも思われました。

（２）実行するメインのScriptのResourcesフォルダ内にSubclassファイルを入れる

普通、AppleScriptのファイルが入る/Contents/Resources/Scripts/でも、ライブラリを入れておく/Contents/Resources/Script Libraries/でもなく、/Contents/Resources/の直下に入れます。ファイル名はオリジナルのEdama2さんのものをそのまま採用していますが、割となんでもいいようです。Custom Classファイルは分割してもいいし、このサンプルのようにまとめてもいいんでしょう。

＃　追加実験してみたところ、Resourcesフォルダ以下の/Scriptsや/Script Libraries/フォルダと重複しない名称の別フォルダ（例：/Classes/）に入れておいても大丈夫でした

（３）use framework “AppleScriptObjC”の宣言文を追加

見たことのない光景ですが、書くことについてはとくに障害はありません。AppKit.Frameworkもuse宣言しておいたほうがよかったかもしれません。

（４）メインスクリプトの実行時に以下の処理を実行

set theBundle to current application’s NSBundle’s bundleWithPath:pathToFolderWithScripts
theBundle’s loadAppleScriptObjectiveCScripts()

★Click Here to Open This Script　

試行錯誤して、上記の「pathToFolderWithScripts」にバンドル内の/Contents/Resources/を入れて実行すればよいことが理解できました。

以上の変更を加えて、ためしにスクリプトエディタ＆Script Debugger上で実行してみたところ、改変前と変わりなく実行できてしまいました（冒頭のスクリーンショット）。

いや、これはめちゃくちゃすごいですよ！！　何がすごいって、CocoaのCustom Classをスクリプトライブラリ中に入れて呼び出せるということで、けっこう無茶な箱庭インタフェースが作れてしまう予感が、、、、。

そして、AppleScriptObjC（AppleScriptObjC.frameworkより）でスクリプトエディタの「.scpt」形式のファイルを読み込んで実行できてしまったということは、Xcode上のAppleScriptアプリケーション内のScriptもテキスト形式だけでなく、スクリプトエディタで編集できる.scpt形式のファイルを突っ込んで編集できる可能性が見えてきました。

ただ、テキスト形式になっていないと、Interface Builderとの連携のあたりで問題になりそうな気もします。

AppleScript名：customClassTest.scptd

—
–　　Created by: Edama2 2020/01/10
–　　Adviced by: Shane Stanley 2020/01/11
–　　Modified by: Takaaki Naganoya 2020/01/12
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

property _clock_text_view : missing value –> 時計用の文字列
property _clock_timer : missing value –> 時計用のNSTimer

–Script Bundle内のResourcesフォルダを求める
set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
theBundle’s loadAppleScriptObjectiveCScripts()

my performSelectorOnMainThread:"raizeWindow:" withObject:(missing value) waitUntilDone:true

# ウィンドウを作成
on raizeWindow:aParam
　　
　　# 時計用の文字を作成
　　tell current application’s NSTextView’s alloc()
　　　　tell initWithFrame_(current application’s NSMakeRect(35, 120, 300, 40))
　　　　　　setRichText_(true)
　　　　　　useAllLigatures_(true)
　　　　　　setTextColor_(current application’s NSColor’s whiteColor())
　　　　　　setFont_(current application’s NSFont’s fontWithName:"Arial-Black" |size|:48)
　　　　　　setBackgroundColor_(current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.0)
　　　　　　setAlphaValue_(1.0)
　　　　　　setEditable_(false)
　　　　　　–setString_("00:00:00")
　　　　　　
　　　　　　set my _clock_text_view to it
　　　　end tell
　　end tell
　　
　　# 時計を更新するNSTimerを作成
　　set my _clock_timer to current application’s NSTimer’s scheduledTimerWithTimeInterval:1 target:me selector:"idleHandler:" userInfo:(missing value) repeats:true
　　
　　# 丸いViewを作成
　　set aFrame to current application’s NSMakeRect(0, 0, 300, 300)
　　tell current application’s RoundView’s alloc()
　　　　tell initWithFrame_(aFrame)
　　　　　　setNeedsDisplay_(true)
　　　　　　setSubviews_({my _clock_text_view})
　　　　　　set customView to it
　　　　end tell
　　end tell
　　
　　#スクリーンのサイズを調べる
　　set aScreen to current application’s NSScreen’s mainScreen()
　　
　　# Window
　　set aBacking to current application’s NSWindowStyleMaskBorderless
　　–set aBacking to current application’s NSBorderlessWindowMask
　　set aDefer to current application’s NSBackingStoreBuffered
　　
　　tell current application’s CustomWindow’s alloc()
　　　　tell initWithContentRect_styleMask_backing_defer_screen_(aFrame, aBacking, aDefer, false, aScreen)
　　　　　　–setTitle_(uniqueName) –>タイトル
　　　　　　setBackgroundColor_(current application’s NSColor’s clearColor()) — Grammar Police –>背景色
　　　　　　setContentView_(customView) –>内容ビューのセット
　　　　　　setDelegate_(me) –>デリゲート
　　　　　　setDisplaysWhenScreenProfileChanges_(true) –>スクリーンプロファイルが変更されたときウインドウの内容をアップデートするか
　　　　　　setHasShadow_(true) –>ウインドウに影があるか
　　　　　　setIgnoresMouseEvents_(false) –>マウスイベントを無視するか
　　　　　　–setLevel_((current application’s NSScreenSaverWindowLevel) + 1) –>ウインドウの前後関係の位置
　　　　　　setOpaque_(false) –>ウインドウを不透明にするか
　　　　　　setReleasedWhenClosed_(true) –>閉じたときにメモリを解放するか
　　　　　　
　　　　　　#
　　　　　　|center|()
　　　　　　makeKeyAndOrderFront_(me) –>キーウインドウにして前面に持ってくる
　　　　　　–setFrame_display_(aFrame, true) –>表示
　　　　end tell
　　end tell
end raizeWindow:

#タイマー割り込み
on idleHandler:aSender
　　set mesStr to time string of (current date)
　　(my _clock_text_view)’s setString:mesStr
end idleHandler:

★Click Here to Open This Script　

AppleScript名：CocoaAppletAppDelegate.scpt

script CocoaAppletAppDelegate
　　property parent : class "NSObject"
　　
　　on applicationWillFinishLaunching:aNotification
　　　　—
　　end applicationWillFinishLaunching:
　　
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
end script

script CustomWindow
　　property parent : class "NSWindow"
　　property canBecomeKeyWindow : true
　　
　　property _initial_location : missing value
　　
　　on mouseDown:theEvent
　　　　set my _initial_location to theEvent’s locationInWindow()
　　end mouseDown:
　　
　　on mouseDragged:theEvent
　　　　–set res to display dialog "mouseDragged" buttons {"OK"} default button "OK"
　　　　try
　　　　　　set screenVisibleFrame to current application’s NSScreen’s mainScreen()’s visibleFrame()
　　　　　　set screenVisibleFrame to my myHandler(screenVisibleFrame)
　　　　　　set windowFrame to my frame()
　　　　　　set windowFrame to my myHandler(windowFrame)
　　　　　　set newOrigin to windowFrame’s origin
　　　　　　
　　　　　　set currentLocation to theEvent’s locationInWindow()
　　　　　　set newOrigin’s x to (newOrigin’s x) + ((currentLocation’s x) – (_initial_location’s x))
　　　　　　set newOrigin’s y to (newOrigin’s y) + ((currentLocation’s y) – (_initial_location’s y))
　　　　　　
　　　　　　set tmpY to ((newOrigin’s y) + (windowFrame’s |size|’s height))
　　　　　　set screenY to (screenVisibleFrame’s origin’s y) + (screenVisibleFrame’s |size|’s height)
　　　　　　if tmpY > screenY then
　　　　　　　　set newOrigin’s y to (screenVisibleFrame’s origin’s y) + ((screenVisibleFrame’s |size|’s height) – (windowFrame’s |size|’s height))
　　　　　　end if
　　　　　　
　　　　　　my setFrameOrigin:newOrigin
　　　　on error error_message number error_number
　　　　　　set error_text to "Error: " & error_number & ". " & error_message
　　　　　　display dialog error_text buttons {"OK"} default button 1
　　　　　　return error_text
　　　　end try
　　　　
　　end mouseDragged:
　　
　　on myHandler(aFrame)
　　　　if class of aFrame is list then
　　　　　　set {{theX, theY}, {theWidth, theHeight}} to aFrame
　　　　　　set aFrame to {origin:{x:theX, y:theY}, |size|:{width:theWidth, height:theHeight}}
　　　　　　–set aFrame to current application’s NSMakeRect(theX, theY, theWidth, theHeight)
　　　　end if
　　　　return aFrame
　　end myHandler
end script

script RoundView
　　property parent : class "NSView"
　　
　　on drawRect:rect
　　　　set aFrame to my frame()
　　　　set myColor to current application’s NSColor’s redColor()
　　　　
　　　　tell current application’s NSBezierPath
　　　　　　tell bezierPathWithOvalInRect_(aFrame)
　　　　　　　　myColor’s |set|()
　　　　　　　　fill()
　　　　　　end tell
　　　　end tell
　　end drawRect:
end script

★Click Here to Open This Script　

RoundWindow

Posted on 1月 10, 2020 by Takaaki Naganoya

本Scriptは、Edama2さんから投稿していただいたものです。Cocoa AppleScript AppletでCustom Classを宣言して作られた、丸いウィンドウ（透明ウィンドウの上に丸いグラフィックを描画）を表示して、タイマー割り込みで時計を表示するAppleScriptです。

–> Download Editable and Executable Applet

AppleScriptのランタイム環境はいくつかあり、それぞれに「できること」と「できないこと」、「手軽さ」などが異なります。

（１）スクリプトエディタ上で記述、実行する環境
一番セキュリティ上の制約が緩く、できることの多い環境です。

（２）Script Debugger上で記述、実行する環境
Cocoaのイベントやオブジェクトのログ表示などができる環境です。

（３）Applet環境
AppleScriptの実行ファイルです。

（４）Script Menu環境
macOS標準装備の、メニューからAppleScriptを実行できる環境です。

さらに、Cocoa Scriptingの機能に着目してみると、見え方が変わります。

本Scriptを記述している「Cocoa AppleScript Applet」環境（上の図の赤い部分）は、スクリプトエディタ上で記述する通常のAppleScriptと、Xcode上で記述するCocoaアプリケーションの中間的な性格を持つものです。スクリプトエディタ上で直接は動かせず、アプレット形式で動作させることになりますが、スクリプトエディタ上で動かすよりも、よりCocoaの機能が利用できます。

Cocoa AppleScript Appletでは、アプリケーション（Applet）起動や終了の最中で発生するイベントを利用できますし、本ScriptのようにCocoaのCustom Classを宣言できます。これは、普通のスクリプトエディタ上で記述する（本Blogの大部分のScriptのような）Scriptではできない真似です。
→ Shane Stanleyからツッコミが入って、手の込んだ作業を行うとできるとかで（テンプレートそのままでは無理）、後で実際に試してみます

タイトルは「丸いウィンドウと時計の表示」
NSWindowのカスタムクラスを使ったタイトルバーなしのドラッグで移動できる丸いウィンドウとオマケに時計を表示したものです。
初心者受けしそうなやつです。
問題はそこではなく、
XcodeやCocoa applescript appletから実行するASOCだとカスタムクラスが作れるけど、
ノーマルのapplescriptから実行するASOCではカスタムクラスが作れないということです。
表現がややこしいですが...。
ノーマルのapplescriptからカスタムクラスを作ると、ただのスクリプトオブジェクトにしかなりません。
誰かうまい解決方法を知っている人がいたら教えてください。

ちょうど、こういう資料をまとめていたので補足説明に役立ってしまいました。スクリプトエディタ上で記述する通常のAppleScriptでもCustom Cocoa Classが宣言できると便利そうですが、どんなもんでしょうか？　

Custom Classは便利なので使いたくなる一方、AppleScriptのインタプリタ上で実行するため、Objective-Cなどで書くのと同じような感覚で使うと「遅くて使えない」という話になると思いますが、このEdama2さんのサンプルぐらいの使いかたであれば、ちょうどいいんじゃないかというところです。

歴史的にみると、Cocoa-AppleScript Appletは、Xcode上で記述するCocoa-Applicationを簡略化してスクリプトエディタ上でCocoa Scriptingを手軽に使えるように手直しした「途中」の環境といえます。

Cocoa-AppleScript Appletは、GUIが手軽に作れるわけでもなく、スクリプトエディタ上で直接実行やログ表示ができるわけでもなありません。マスターしたところで最終到達点がCocoaアプリケーションほど高くなく、編集や習熟もしづらいことから「中途半端」「使えない」という評価になっていました（自分も使っていませんでした）。

その後、Cocoa-AppleScript Appletの機能要素をさらにダウンサイジングして、スクリプトエディタ上で手軽に記述・実行ができるように進化したのが現在・広くつかわれているCocoa Scripting環境です。

ただ、使いやすくなって広く使われるようになったはいいものの、「Xcodeを使うまでもないが、もうちょっとCocoaの機能が利用できないか？」という意見も出るようになり、Cocoa-AppleScript Appletを再評価してもいいんじゃないかと考えるようになってきてはいます。

ちなみに、本Cocoa-AppleScript AppletでCustom Classを宣言しているのと同じような書き方で、通常のCocoa Scriptingの環境で動かすような変更を加えたScriptもEdama2さんが試していますが、それは「動かない」ということで結論が出ています。

AppleScript名：CocoaAppletAppDelegate.scpt

script CocoaAppletAppDelegate
　　property parent : class "NSObject"
　　
　　property _clock_text_view : missing value –> 時計用の文字列
　　property _clock_timer : missing value –> 時計用のNSTimer
　　
　　on applicationWillFinishLaunching:aNotification
　　　　my raizeWindow()
　　end applicationWillFinishLaunching:
　　
　　on applicationShouldTerminate:sender
　　　　my _clock_timer’s invalidate()
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　# ウィンドウを作成
　　on raizeWindow()
　　　　
　　　　# 時計用の文字を作成
　　　　tell current application’s NSTextView’s alloc()
　　　　　　tell initWithFrame_(current application’s NSMakeRect(35, 120, 300, 40))
　　　　　　　　setRichText_(true)
　　　　　　　　useAllLigatures_(true)
　　　　　　　　setTextColor_(current application’s NSColor’s whiteColor())
　　　　　　　　setFont_(current application’s NSFont’s fontWithName:"Arial-Black" |size|:48)
　　　　　　　　setBackgroundColor_(current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.0)
　　　　　　　　setAlphaValue_(1.0)
　　　　　　　　setEditable_(false)
　　　　　　　　–setString_("00:00:00")
　　　　　　　　
　　　　　　　　set my _clock_text_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# 時計を更新するNSTimerを作成
　　　　set my _clock_timer to current application’s NSTimer’s scheduledTimerWithTimeInterval:1 target:me selector:"idleHandler:" userInfo:(missing value) repeats:true
　　　　
　　　　
　　　　# 丸いViewを作成
　　　　set aFrame to current application’s NSMakeRect(0, 0, 300, 300)
　　　　tell current application’s RoundView’s alloc()
　　　　　　tell initWithFrame_(aFrame)
　　　　　　　　setNeedsDisplay_(true)
　　　　　　　　setSubviews_({my _clock_text_view})
　　　　　　　　set customView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　#スクリーンのサイズを調べる
　　　　set aScreen to current application’s NSScreen’s mainScreen()
　　　　
　　　　# Window
　　　　set aBacking to current application’s NSWindowStyleMaskBorderless
　　　　–set aBacking to current application’s NSBorderlessWindowMask
　　　　set aDefer to current application’s NSBackingStoreBuffered
　　　　tell current application’s CustomWindow’s alloc()
　　　　　　tell initWithContentRect_styleMask_backing_defer_screen_(aFrame, aBacking, aDefer, false, aScreen)
　　　　　　　　–setTitle_(uniqueName) –>タイトル
　　　　　　　　setBackgroundColor_(current application’s NSColor’s clearColor()) –>背景色
　　　　　　　　setContentView_(customView) –>内容ビューのセット
　　　　　　　　setDelegate_(me) –>デリゲート
　　　　　　　　setDisplaysWhenScreenProfileChanges_(true) –>スクリーンプロファイルが変更されたときウインドウの内容をアップデートするか
　　　　　　　　setHasShadow_(true) –>ウインドウに影があるか
　　　　　　　　setIgnoresMouseEvents_(false) –>マウスイベントを無視するか
　　　　　　　　–setLevel_((current application’s NSScreenSaverWindowLevel) + 1) –>ウインドウの前後関係の位置
　　　　　　　　setOpaque_(false) –>ウインドウを不透明にするか
　　　　　　　　setReleasedWhenClosed_(true) –>閉じたときにメモリを解放するか
　　　　　　　　
　　　　　　　　#
　　　　　　　　|center|()
　　　　　　　　makeKeyAndOrderFront_(me) –>キーウインドウにして前面に持ってくる
　　　　　　　　–setFrame_display_(aFrame, true) –>表示
　　　　　　end tell
　　　　end tell
　　end raizeWindow
　　
　　#タイマー割り込み
　　on idleHandler:aSender
　　　　set mesStr to time string of (current date)
　　　　(my _clock_text_view)’s setString:mesStr
　　end idleHandler:
end script

★Click Here to Open This Script　

AppleScript, my(me), it

Posted on 1月 8, 2020 by Takaaki Naganoya

AppleScript：トップレベルObject。不変
my（me）：現在のScript Object。可変
it：現在のアプリケーションObject。可変

AppleScript > my(me) ≧ it

というレベルになっていることもよく理解できました。

ただ、サンプルが自分的にいまひとつわかりやすくなかったので、自分用に書き換えてみました。バージョン取得ではなく、「名前を取得」しないといまひとつ分からないんじゃないでしょうか。

AppleScript名：testScript

me
–> «script»–実行中のAppleScript書類（Script Object）

AppleScript
–> «script AppleScript»

it
–> «script»–current target object

tell application "Finder"
　　it
　　–> application "Finder"–current target object
　　
　　–testMe() –> error "Finderでエラーが起きました: testMeを続けることができません。" number -1708
　　testMe() of me
　　testMe() of aTEST of me
　　testMe() of bTEST of aTEST of me
end tell

on testMe()
　　set aName to name of me
　　–> "testScript"
　　display dialog aName –Name of this AppleScript document file
end testMe

script aTEST
　　on testMe()
　　　　set aName to name of me
　　　　–> "aTEST"
　　　　display dialog aName –Name of this script object (aTEST)
　　end testMe
　　
　　script bTEST
　　　　on testMe()
　　　　　　set aName to name of me
　　　　　　–> "bTEST"
　　　　　　display dialog aName –Name of this script object (bTEST)
　　　　end testMe
　　end script
end script

★Click Here to Open This Script　

最前面のアプリケーションの用語辞書を表示する v4

Posted on 1月 8, 2020 by Takaaki Naganoya

最前面のアプリケーションのAppleScript用語辞書をオープンするAppleScriptです。

macOS標準装備のScript Menuに入れて呼び出すことを前提に作りました。はるかかなた昔に作って、OSバージョンが上がるごとに細かい改修を行なって使い続けているものです。

この手のScriptは日常的にAppleScriptを書いている人間なら、たいてい書いてみたことがあるはずです。しかし、あまり生真面目なアプローチでアプリケーションバンドル中のsdefのパスを求めてオープンといった処理を行っていると、「例外」にブチ当たって困惑します。

sdefファイルを直接持っていないAdobe Creative Cloud製品です。InDesignあたりがそうなんですが、直接sdefを保持しておらず、どうやら実行時に動的に組み立てるようで、絶体パス（absolute path）で指定してもsdefをオープンできません。

また、Microsoft Office系アプリケーションのsdefも、外部の（OS側のsdef）テンプレートをincludeするようなので、生真面目に対象アプリケーションのInfo.plistの情報をもとにアプリケーションバンドル中のsdefファイルをオープンするように処理すると、sdefの一部のみを表示するようになってしまって、sdef全体を表示することができません。

そうしたもろもろの問題に当たって、結局アプリケーションそのものをScript Editorでオープンするように指定しています。

AppleScript名：–このアプリケーションの用語辞書を表示する v4

— Created 2017-07-23 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

–最前面のプロセスのファイルパスを取得する
set aFile to path to frontmost application
set aRec to (getAppPropertyFromInfoPlist(aFile, "NSAppleScriptEnabled") of me) as boolean

–スクリプト用語辞書をScript Editorでオープンする手順
if aRec = true then
　　–OS X 10.10でScript Editor側からアプリケーションをオープンしてもダメだったので、Finder側からScript Editorで指定アプリをオープンすることに
　　try
　　　　tell application "Finder"
　　　　　　set apFile to (application file id "com.apple.scripteditor2") as alias
　　　　　　open aFile using application file apFile
　　　　end tell
　　on error
　　　　tell application id "com.apple.scripteditor2"
　　　　　　open aFile
　　　　end tell
　　end try
　　
　　tell application id "com.apple.scripteditor2" to activate
　　
else
　　display dialog "本アプリケーションは、各種OSA言語によるコントロールに対応していません。" buttons {"OK"} default button 1 with icon 2 with title "Scripting非対応"
end if

on getAppPropertyFromInfoPlist(aP, aPropertyLabel)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aP)
　　set aBundle to current application’s NSBundle’s bundleWithURL:aURL
　　set aDict to aBundle’s infoDictionary()
　　
　　set aRes to aDict’s valueForKey:aPropertyLabel
　　if aRes is not equal to missing value then
　　　　set aRes to aRes as anything
　　end if
　　
　　return aRes
end getAppPropertyFromInfoPlist

★Click Here to Open This Script　