AS書類を書式で分解して再構成

Posted on 1月 12 by Takaaki Naganoya

AppleScriptの書類を読み込んでNSAttributedStringに変換し、書式情報にもとづいてNSDictionary in NSArrayに変換。この状態でデータ抽出などを行なっていたのですが、このデータをもとにNSAttributedStringに再構成するAppleScriptです。

本Scriptの通しの処理内容としては、読み込んだAppleScriptを書式情報をもとに分解して、再構成するという……大豆から豆腐を作って、豆腐を崩して豆を得る、みたいな内容です。

NSAttributedStringを再構成する部分の処理を書いていなかったので、必要に迫られて書いてみました。

AppleScript構文色分け設定情報をもとに処理するため、色分け設定で複数の構文要素で同じ色を指定している場合にはエラーを返します。単にNSAttributedStringを解釈して再構成する、といった処理であればAppleScript構文色分け設定へのアクセス自体は必要ないところですが、すでに不可分なレベルで組み込まれているため、現状ではそのままです。

いっそ、こうした処理をする前にplistをバックアップし、必要な情報を書き込んだplistを設定ファイルとして使用するといった処理を行った方がいいのかもしれません。これまでは、「そんな処理はとても行えない」と判断していましたが、よくよく考えればとくに苦労せずに実現できそうです。

AppleScript名：AS書類を書式で分解して再構成.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/01/12
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property asCol : {}

set asCol to getAppleScriptSourceColors() of me –AppleScript構文色分け設定をplistから読み込む

set aFile to POSIX path of (choose file of type {"com.apple.applescript.script", "com.apple.applescript.script-bundle"})
set aURL to |NSURL|’s fileURLWithPath:(aFile)
set theScript to current application’s OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
set styledText to theScript’s richTextSource()

–Styled TextをDictionarry in Listに
set sRes to getAttributeRunsFromAttrStringRBO(styledText) of styleTextToDict

–Dictionarry in ListをStyled Textに再構成
set bRes to retAttributedStringFromAttrDict(sRes) of attrDictToAttrStr

script styleTextToDict
　　use AppleScript
　　use framework "Foundation"
　　use framework "AppKit"
　　use scripting additions
　　property parent : AppleScript
　　
　　–Styled Textを
　　on getAttributeRunsFromAttrStringRBO(theStyledText)
　　　　script aSpd
　　　　　　property styleList : {}
　　　　end script
　　　　
　　　　set (styleList of aSpd) to {} —for output
　　　　
　　　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　　　
　　　　set theLength to theStyledText’s |length|()
　　　　set startIndex to 0
　　　　set aCount to 0
　　　　
　　　　repeat until (startIndex = theLength)
　　　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　　　
　　　　　　–String　　
　　　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　　　set strLen to (length of aText)
　　　　　　
　　　　　　–Color
　　　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　　　if aColor is not equal to missing value then
　　　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　　　
　　　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　　　
　　　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　　　else
　　　　　　　　set colList to {0, 0, 0}
　　　　　　　　set colStrForFind to "0 0 0"
　　　　　　end if
　　　　　　
　　　　　　–Font
　　　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　　　if aFont is not equal to missing value then
　　　　　　　　set aDFontName to aFont’s displayName()
　　　　　　　　set aDFontSize to aFont’s pointSize()
　　　　　　end if
　　　　　　
　　　　　　–Range
　　　　　　set the end of (styleList of aSpd) to {stringVal:aText, atrIndex:aCount, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize}
　　　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　　　
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　　　
　　　　return (styleList of aSpd)
　　　　
　　end getAttributeRunsFromAttrStringRBO
　　
　　–NSColorからRGBの値を取り出す
　　on retColListFromNSColor(aCol, aMAX as integer)
　　　　using terms from scripting additions
　　　　　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　　　　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　　　　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　　　end using terms from
　　　　if aRed > aMAX then set aRed to aMAX
　　　　if aGreen > aMAX then set aGreen to aMAX
　　　　if aBlue > aMAX then set aBlue to aMAX
　　　　
　　　　return {aRed, aGreen, aBlue}
　　end retColListFromNSColor
　　
　　–aMaxValを最大値とする数値でNSColorを作成して返す
　　on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　　　set aRedCocoa to (redValue / aMaxVal) as real
　　　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　　　return aColor
　　end makeNSColorFromRGBAval
　　
end script

script attrDictToAttrStr
　　use AppleScript
　　use framework "Foundation"
　　use framework "AppKit"
　　use scripting additions
　　property parent : AppleScript
　　
　　–書式つきテキストを組み立てる（メイン側）
　　on retAttributedStringFromAttrDict(attrRes)
　　　　script aSpd
　　　　　　property styleList : {}
　　　　end script
　　　　
　　　　set (styleList of aSpd) to {} —for output
　　　　
　　　　set allAttrStr to NSMutableAttributedString’s alloc()’s init()
　　　　
　　　　repeat with i in attrRes
　　　　　　set j to contents of i
　　　　　　set tmpAttrStr to makeRTFfromParameters(stringVal of j, fontName of j, fontSize of j, colorVal of j) of me
　　　　　　
　　　　　　(allAttrStr’s appendAttributedString:tmpAttrStr)
　　　　end repeat
　　　　
　　　　return allAttrStr
　　end retAttributedStringFromAttrDict
　　
　　–書式つきテキストを組み立てる（パーツ組み立て用サブ側）
　　on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aColorList as list)
　　　　–Font & Size
　　　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　　　set aKey1 to (NSFontAttributeName)
　　　　
　　　　–Color
　　　　copy aColorList to {rCol, gCol, bCOl}
　　　　set aVal2 to makeNSColorFromRGBAval(rCol, gCol, bCOl, 255, 255) of asCol
　　　　set aKey2 to (NSForegroundColorAttributeName)
　　　　
　　　　set keyList to {aKey1, aKey2}
　　　　set valList to {aVal1, aVal2}
　　　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　　　
　　　　–Text
　　　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　　　return attrStr
　　end makeRTFfromParameters
　　
　　
　　–aMaxValを最大値とする数値でNSColorを作成して返す
　　on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　　　set aRedCocoa to (redValue / aMaxVal) as real
　　　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　　　return aColor
　　end makeNSColorFromRGBAval
　　
end script

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceColors()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set colList to {}
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set aColRec to {redValue:rVal, greenValue:gVal, blueValue:bVal, fontName:aFontName, fontSize:aFontSize}
　　　　
　　　　set the end of colList to aColRec
　　end repeat
　　
　　return colList
end getAppleScriptSourceColors

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　using terms from scripting additions
　　　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　end using terms from
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

★Click Here to Open This Script　

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定（v2）

Posted on 7月 17, 2020 by Takaaki Naganoya

アラートダイアログ上にボタンタイプのチェックボックスを並べて、選択したボタンのタイトルを選択するAppleScriptです。

書類の印刷対象を、こまかくページ指定するために作成した部品です。

ヘルプボタンにより、全ボタンの選択/非選択状態を作り出せます。

▲macOS 15.3上で、本Scriptの改修版を動かしたところ、クリックした箇所が見てわかるようになった

AppleScript名：アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定 v2.scpt

— Created 2020-07-17 by Takaaki Naganoya
— Modified 2024-12-23 by Takaaki Naganoya
— 2020-2024 Piyomaru Software

set aRes to selectByCheckbox("Select each printout page", "Selected pages are the target", 64, "Helvetica") of chooseSeqNum

script chooseSeqNum
　　
　　use AppleScript version "2.5"
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　
　　property NSFont : a reference to current application’s NSFont
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSButton : a reference to current application’s NSButton
　　property NSOnState : a reference to current application’s NSOnState
　　property NSOffState : a reference to current application’s NSOffState
　　property NSTextField : a reference to current application’s NSTextField
　　property NSButtonTypeToggle : a reference to current application’s NSButtonTypeToggle
　　property NSButtonTypePushOnPushOff : a reference to current application’s NSButtonTypePushOnPushOff
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
　　property NSMutableDictionary : a reference to current application’s NSMutableDictionary
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSFontAttributeName : a reference to current application’s NSFontAttributeName
　　property NSKernAttributeName : a reference to current application’s NSKernAttributeName
　　property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
　　property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
　　property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
　　property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
　　property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
　　property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
　　
　　property theResult : 0
　　property returnCode : 0
　　property cList : {} –Checkbox button object array
　　property bArray : {}
　　
　　
　　on selectByCheckbox(aMainMessage, aSubMessage, aMaxPage, myFont)
　　　　set paramObj to {myMessage:aMainMessage, mySubMessage:aSubMessage, maxPage:aMaxPage, fontName:myFont}
　　　　–my chooseItemByCheckBox:paramObj –for Debugging
　　　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　　　–> {1, 3, 5, 7, 9, 11}
　　　　return cList
　　end selectByCheckbox
　　
　　on chooseItemByCheckBox:(paramObj)
　　　　set aMainMes to (myMessage of paramObj) as string
　　　　set aSubMes to (mySubMessage of paramObj) as string
　　　　set aMaxPage to (maxPage of paramObj) as integer
　　　　set aFontName to (fontName of paramObj) as string
　　　　
　　　　set cList to {}
　　　　
　　　　set colNum to 10
　　　　set rowNum to (aMaxPage div 10) + 1
　　　　set aLen to (colNum * rowNum)
　　　　
　　　　set aButtonCellWidth to 56
　　　　set aButtonCellHeight to 40
　　　　
　　　　set viewWidth to aButtonCellWidth * colNum
　　　　set viewHeight to aButtonCellHeight * (rowNum + 1)
　　　　
　　　　–define the matrix size where you’ll put the radio buttons
　　　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　　　
　　　　set aCount to 1
　　　　set aFontSize to 24
　　　　set bArray to current application’s NSMutableArray’s new()
　　　　
　　　　–Make Header (Month, Year)
　　　　set aCalList to makeSeqNumList(1, aMaxPage) of me
　　　　set aCount to 1
　　　　
　　　　
　　　　–Make Calendar (Calendar Body)
　　　　repeat with y from 1 to rowNum
　　　　　　repeat with x from 1 to colNum
　　　　　　　　–try
　　　　　　　　set j to (contents of item aCount of aCalList)
　　　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　　　
　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize))
　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), aFontName, aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeToggle))
　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　
　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　
　　　　　　　　set aCount to aCount + 1
　　　　　　　　if aCount > aMaxPage then exit repeat
　　　　　　　　–end try
　　　　　　end repeat
　　　　　　if aCount > aMaxPage then exit repeat
　　　　end repeat
　　　　
　　　　–Select the first radio button item
　　　　–(tmpArray’s objectAtIndex:0)’s setState:(current application’s NSOnState)
　　　　set my theResult to {}
　　　　
　　　　(aView’s setSubviews:bArray)
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aView
　　　　　　
　　　　　　–for Help Button
　　　　　　its setShowsHelp:(true)
　　　　　　its setDelegate:(me)
　　　　　　
　　　　end tell
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode as number) = 1001 then error number -128
　　　　
　　　　set bNumList to (bArray’s valueForKeyPath:"state") as list
　　　　–set cList to {}
　　　　repeat with i from 1 to aMaxPage
　　　　　　set aFlag to (contents of item i of bNumList) as boolean
　　　　　　if aFlag = true then
　　　　　　　　set the end of cList to contents of i
　　　　　　end if
　　　　end repeat
　　　　
　　　　copy cList to bArray
　　end chooseItemByCheckBox:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to aParam’s runModal()
　　end doModal:
　　
　　
　　
　　on clicked:aParam
　　　　set aTag to (tag of aParam) as integer
　　　　–clicked
　　　　if aTag is not in (my theResult) then
　　　　　　set the end of (my theResult) to aTag
　　　　else
　　　　　　set theResult to my deleteItem:aTag fromList:theResult
　　　　end if
　　end clicked:
　　
　　
　　
　　on deleteItem:anItem fromList:theList
　　　　set theArray to NSMutableArray’s arrayWithArray:theList
　　　　theArray’s removeObject:anItem
　　　　return theArray as list
　　end deleteItem:fromList:
　　
　　
　　
　　–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
　　on sort1DNumList:theList ascOrder:aBool
　　　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　　　return (sortedList) as list
　　end sort1DNumList:ascOrder:
　　
　　
　　–Help Button Clicked Event Handler
　　on alertShowHelp:aNotification
　　　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　　　set bRes to (button returned of aRes) as string
　　　　
　　　　if bRes = "All Off" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　　　end repeat
　　　　　　
　　　　else if bRes = "All On" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　　　set the end of theResult to i + 1
　　　　　　end repeat
　　　　end if
　　　　
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　
　　–書式つきテキストを組み立てる
　　on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　　　set aKey1 to (NSFontAttributeName)
　　　　
　　　　set aVal2 to NSColor’s blackColor()
　　　　set aKey2 to (NSForegroundColorAttributeName)
　　　　
　　　　set aVal3 to aKerning
　　　　set akey3 to (NSKernAttributeName)
　　　　
　　　　set aVal4 to 0
　　　　set akey4 to (NSUnderlineStyleAttributeName)
　　　　
　　　　set aVal5 to 2 –all ligature ON
　　　　set akey5 to (NSLigatureAttributeName)
　　　　
　　　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　　　set akey7 to (NSParagraphStyleAttributeName)
　　　　
　　　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　　　
　　　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　　　return attrStr
　　end makeRTFfromParameters
　　
　　
　　on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aNSString’s setEditable:(editableF)
　　　　aNSString’s setStringValue:(setVal)
　　　　aNSString’s setDrawsBackground:(backgroundF)
　　　　aNSString’s setBordered:(borderedF)
　　　　return aNSString
　　end makeNSTextField
　　
　　
　　
　　on makeSeqNumList(fromNum as integer, toNum as integer)
　　　　script spd
　　　　　　property aList : {}
　　　　end script
　　　　
　　　　set aList of spd to {}
　　　　
　　　　repeat with i from fromNum to toNum
　　　　　　set the end of (aList of spd) to i
　　　　end repeat
　　　　
　　　　return (aList of spd)
　　end makeSeqNumList
　　
　　
end script

★Click Here to Open This Script　

NSURLSessionでREST API呼び出しv4.4.2a

Posted on 4月 3, 2020 by Takaaki Naganoya

REST API呼び出しに欠かせない部品をアップデートしました。URLキャッシュが効くようになったような気がします。

–> GET method REST API v4.4.1
–> GET method REST API v4.4
–> GET method REST API v4.3
–> GET method REST API v4.1
–> GET method REST API v4

前バージョンではmacOS 10.15上でクラッシュしないかわりにURLキャッシュが効かないという特徴がありました。ただ、edama2さんと協議した結果、macOS 10.15上でクラッシュする原因と考えられていた内容にあまり根拠がないことがわかってきました（人ごとではなく自分のことなのですが）。

可能な範囲でトライアル＆エラーで調査を行なったところ、本バージョンのような処理に落ち着きました。AppleScriptからのCocoa利用については明確にドキュメントがAppleから出ているわけではないので、すでに存在するObjective-Cのプログラムの処理を参考にしつつ、Objective-CからAppleScriptへの置き換えが可能かを検討しています。

URLキャッシュについては、（当然のことながら）処理１回目には効きません。なぜか２回目も効きません。３回目とか４回目あたりから効いていることが実感できる感じです（回数ではなく、前回処理時からの経過時間を見ているのかも？　GUIアプリケーションに入れて使うと２回目から効いたりします）。URLキャッシュが効いていない場合には1.5秒ぐらい、URLキャッシュが効き出すと0.02秒ぐらいで結果が返ってきています。

macOS 10.13/14/15で検証を行い、繰り返し処理を行ってもクラッシュしないことを確認しています。ただ、動作保証するというレベルではないので（本Blog掲載のScriptすべてそうですが）、問題があったら知らせてください。

ためしに、Xcode上で作成したGUIベースのAppleScriptアプリケーションに本処理を導入したところ、REST APIへの問い合わせがキャッシュされて著しい高速化を実現できました。

AppleScript名：GET method REST API v4.4.2a_wikipedia.scptd

— Created 2019-05-02 by Takaaki Naganoya
— Modified 2020-04-03 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLCache : a reference to current application’s NSURLCache
property NSURLSession : a reference to current application’s NSURLSession
property NSMutableData : a reference to current application’s NSMutableData
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSOperationQueue : a reference to current application’s NSOperationQueue
property NSURLComponents : a reference to current application’s NSURLComponents
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration
property NSURLRequestReturnCacheDataElseLoad : a reference to current application’s NSURLRequestReturnCacheDataElseLoad

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false
property aSession : missing value
property aCache : missing value

on run
　　set retData to missing value
　　set drecF to false
　　set aSession to missing value
　　
　　set aQueryKeyTitle to "AppleScript"
　　set aRes to getWikiText(aQueryKeyTitle) of me
　　return aRes
end run

on getWikiText(aQueryKeyTitle)
　　set reqURLStr to "https://en.wikipedia.org/w/api.php"
　　set aRec to {action:"parse", page:aQueryKeyTitle, |prop|:"wikitext", format:"json"}
　　set aURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set aRes to callRestGETAPIAndParseResults(aURL, 5) of me
　　if aRes = missing value then return false
　　
　　set bRes to (aRes’s valueForKeyPath:"parse.wikitext.*") as string
　　return bRes
end getWikiText

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set (my retData) to NSMutableData’s alloc()’s init()
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　–if my aCache = missing value then
　　set cachePath to (POSIX path of (path to library folder from user domain)) & "/Caches/AppleScriptURLCache"
　　set my aCache to NSURLCache’s alloc()’s initWithMemoryCapacity:512000 diskCapacity:1024 * 1024 * 5 diskPath:cachePath
　　–end if
　　NSURLCache’s setSharedURLCache:(my aCache)
　　
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　aConfig’s setRequestCachePolicy:(NSURLRequestReturnCacheDataElseLoad)
　　
　　aConfig’s setURLCache:(my aCache)
　　
　　–どちらでも速度差がない
　　set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(NSOperationQueue’s mainQueue())
　　–set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　aTask’s resume() –Start URL Session
　　
　　repeat (1000 * timeoutSec) times
　　　　if (my drecF) is not equal to false then
　　　　　　exit repeat
　　　　end if
　　　　delay "0.001" as real
　　end repeat
　　
　　–delegateの無効化
　　my aSession’s finishTasksAndInvalidate()
　　set my aSession to missing value
　　
　　return my parseSessionResults()
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　(my retData)’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

on URLSession:tmpSession task:tmpTask didCompleteWithError:tmpError
　　if tmpError = missing value then
　　　　set (my drecF) to true
　　else
　　　　error "Donwload Failed"
　　end if
end URLSession:task:didCompleteWithError:

on parseSessionResults()
　　set resStr to NSString’s alloc()’s initWithData:(my retData) encoding:(NSUTF8StringEncoding)
　　set jsonString to NSString’s stringWithString:(resStr)
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　return aJsonDict
end parseSessionResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

NSURLSessionでREST API呼び出しv4.4.1

Posted on 4月 2, 2020 by Takaaki Naganoya

REST API呼び出しに欠かせない部品をアップデートしました。macOS 10.15でクラッシュしないように書き換えています。

–> GET method REST API v4.4
–> GET method REST API v4.3
–> GET method REST API v4.1
–> GET method REST API v4

前バージョンではmacOS 10.15上でクラッシュするかわりにmacOS 10.14上で高速という特徴がありました。ただ、macOS 10.15上でクラッシュしないように調整を行っていくと、処理速度については別段速くもなく（キャッシュがヒットしていない雰囲気）、よりいっそうキャッシュについて調べる必要が出てきています。

一応、キャッシュの作り方については調べてみたものの、

キャッシュが効いている雰囲気がまったくありません。

キャッシュの内容を確認してみると、からっぽですね（＾ー＾；　もう少し（時間のあるときに）キャッシュの連携などを調べておくといいのかもしれません。最低限、macOS 10.15でクラッシュしなくなったので、NSURLConnectionを呼び出してリジェクトを喰らわないように準備しておくという感じでしょうか。

AppleScript名：GET method REST API v4.4.1_wikipedia.scptd

— Created 2019-05-02 by Takaaki Naganoya
— Modified 2020-04-02 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSMutableData : a reference to current application’s NSMutableData
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false
property aSession : missing value
property aCache : missing value

on getWikiText(aQueryKeyTitle)
　　set reqURLStr to "https://en.wikipedia.org/w/api.php"
　　set aRec to {action:"parse", page:aQueryKeyTitle, |prop|:"wikitext", format:"json"}
　　set aURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set aRes to callRestGETAPIAndParseResults(aURL, 5) of me
　　if aRes = missing value then return "Error"
　　
　　set bRes to (aRes’s valueForKeyPath:"parse.wikitext.*") as string
　　return bRes
end getWikiText

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set (my retData) to NSMutableData’s alloc()’s init()
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　–if my aCache = missing value then
　　set cachePath to (POSIX path of (path to library folder from user domain)) & "/Caches/AppleScriptURLCache"
　　set my aCache to current application’s NSURLCache’s alloc()’s initWithMemoryCapacity:512000 diskCapacity:1024 * 1024 * 5 diskPath:cachePath
　　–end if
　　current application’s NSURLCache’s setSharedURLCache:(my aCache)
　　
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set v2 to system attribute "sys2" –> 14
　　if v2 < 15 then
　　　　–macOS 10.14まで
　　　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　else
　　　　–macOS 10.15以降。10.15でdefaultSessionConfigurationを使うとクラッシュしやすい？？？
　　　　set identifier to "BackgroundSessionConfiguration"
　　　　set aConfig to NSURLSessionConfiguration’s backgroundSessionConfiguration:(identifier)
　　end if
　　
　　aConfig’s setRequestCachePolicy:(current application’s NSURLRequestReturnCacheDataElseLoad)
　　
　　aConfig’s setURLCache:(my aCache)
　　–aConfig’s setTimeoutIntervalForRequest:0.5
　　–aConfig’s setTimeoutIntervalForResource:timeoutSec
　　–aConfig’s setWaitsForConnectivity:false
　　
　　–どちらでも速度差がない
　　set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(current application’s NSOperationQueue’s mainQueue())
　　–set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　aTask’s resume() –Start URL Session
　　
　　repeat (1000 * timeoutSec) times
　　　　if (my drecF) is not equal to false then
　　　　　　exit repeat
　　　　end if
　　　　delay "0.001" as real
　　end repeat
　　
　　–aSession’s invalidateAndCancel() –delegateの無効化
　　my aSession’s finishTasksAndInvalidate()
　　set my aSession to missing value
　　
　　return my parseSessionResults()
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　(my retData)’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

on URLSession:tmpSession dataTask:tmpTask willCacheResponse:cacheRes completionHandler:aHandler
　　set (my drecF) to true
end URLSession:dataTask:willCacheResponse:completionHandler:

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

NSURLSessionでREST API呼び出しv4.4

Posted on 3月 29, 2020 by Takaaki Naganoya

REST API呼び出しに欠かせない部品をアップデートしました。

–> GET method REST API v4.3
–> GET method REST API v4.1
–> GET method REST API v4

従来、NSURLConnectionを使って同期処理を行っていましたが、これがDepreceted扱いになりました。すぐになくなることはありませんが、いつかなくなる可能性があります。

このため、NSURLConnectionから動作原理の異なるNSURLSessionを使うよう移行する必要があります（curlコマンドを利用するというルートもあります）。

とはいえ、blocks構文の使えないAppleScriptでこのNSURLSessionを使えるようにするのは大変です。非同期通信を行うNSURLSessionを非同期処理のしにくいAppleScriptで、同期処理っぽく書かなくてはなりません。

NSURLSessionによる通信では、サーバーとの間で何回かのやりとりがあって、データを小分けに複数回受信する必要がありました。NSMutableDataというオブジェクトの存在を知ったのでいい感じに処理できるようになってきました。

NSURLSessionのメリットとして喧伝されている非同期処理は、AppleScriptから呼び出しているかぎりはそれほどメリットになりません。もう少し使い込めば活用できるかもしれませんが、まだそういう段階にはありません。

NSURLSessionの導入によって得られるメリットで最大のものは、キャッシュ機構です。NSURLConnectionでもキャッシュ機構は利用できましたが、NSURLSessionではよりAPIに深く統合されているものと理解しました。

キャッシュの効き方については、設定で何段階かに設定できるとAppleのオンラインドキュメントに書かれています。本Scriptでは、キャッシュ優先でキャッシュが存在している場合にはキャッシュ内のデータを返し、キャッシュが存在していない場合にはWebサーバーに問い合わせを行うように設定しています。

キャッシュが効いている状況なら、NSURLConnectionで1.8秒ぐらいの処理がNSURLSessionで0.1秒程度と大幅に速く処理できます。キャッシュが効いていない状況（初回実行時）だと、NSURLSessionのほうがやや処理に時間がかかるぐらいです。

処理結果について、NSURLConnection版とNSURLSession版で結果の比較を行ってみましたが、とくに差異は見られませんでした。

本サンプルScriptでは、Wikipedia（英語版）へのキーワードの問い合わせを行います。NSURLConnection版では複数回実行しても同じぐらいの速度で実行されますが、NSURLSession版では２度目から早く終わります（Script Debugger上で動かすと秒以下の精度の時間がわかります）。

macOS 10.14上で作ってmacOS 10.14.6/10.13.6上で動作確認しています（スクリプトエディタ、Script Debuggerで動作確認）。ただし、macOS 10.15上だとクラッシュします。Xcodeのプロジェクトに入れてみましたが、同様にmacOS 10.15上ではクラッシュします。

ただし、自分のmacOS 10.14.6環境はSIP解除しているのと、macOS 10.15環境のクラッシュログにSIP関連のメッセージが残っているので、OSバージョンではなくSIPのためかもしれません（macOS 10.14.6でもSIPを有効にするとクラッシュするかもしれない　＆　macOS 10.15.xでもSIPを無効にするとクラッシュしないかもしれない）。

AppleScript名：GET method REST API v4.4_wikipedia

— Created 2019-05-02 by Takaaki Naganoya
— Modified 2020-03-29 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false

set aQueryKeyTitle to "Steve Jobs" –キーワードの正規化が必要（"戦場の絆"→"機動戦士ガンダム戦場の絆" ）
set reqURLStr to "https://en.wikipedia.org/w/api.php"
set aRec to {action:"parse", page:aQueryKeyTitle, |prop|:"wikitext", format:"json"}
set aURL to retURLwithParams(reqURLStr, aRec) of me

set aRes to callRestGETAPIAndParseResults(aURL, 10) of me
set bRes to (aRes’s valueForKeyPath:"parse.wikitext.*") as string
return bRes

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set (my retData) to NSMutableData’s alloc()’s init()
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　aConfig’s setRequestCachePolicy:(current application’s NSURLRequestReturnCacheDataElseLoad)
　　set aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　aTask’s resume() –Start URL Session
　　
　　repeat (10 * timeoutSec) times
　　　　if (my drecF) = true then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　return my parseSessionResults()
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　(my retData)’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

on URLSession:tmpSession dataTask:tmpTask didCompleteWithError:tmpError
　　set (my drecF) to true
end URLSession:dataTask:didCompleteWithError:

on URLSession:tmpSession dataTask:tmpTask willCacheResponse:cacheRes completionHandler:aHandler
　　set (my drecF) to true
end URLSession:dataTask:willCacheResponse:completionHandler:

on urlencodeStr(aStr)
　　set aString to current application’s NSString’s stringWithString:aStr
　　set aString to (aString’s stringByAddingPercentEncodingWithAllowedCharacters:(current application’s NSCharacterSet’s URLQueryAllowedCharacterSet())) as text
　　return aString
end urlencodeStr

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　set bList to filteredArray as {list, missing value}
　　return bList
end filterRecListByLabel1

★Click Here to Open This Script　

AppleScript名：GET method REST API_wikipedia

— Created 2016-03-03 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aRes to callRestGETAPIAndParseResults(aURL, 10) of me
set aRESTres to json of aRes
set bRes to (aRESTres’s valueForKeyPath:"parse.wikitext.*") as string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL, timeoutSec)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code
　　set dRes to contents of second item of resList
　　set resCode to (dRes’s statusCode()) as integer
　　
　　–Get Response Header
　　set resHeaders to (dRes’s allHeaderFields()) as record
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
　　
end callRestGETAPIAndParseResults

★Click Here to Open This Script　

WebKit Utilities v2

Posted on 3月 16, 2020 by Takaaki Naganoya

AppleScriptで指定URLのページを表示する「WebKit Utilities」がmacOS 10.13以降の環境で動かなくなっていたので、書き換えて動くようにしておきました。

–> Download WebKit Utilities_archive v2

これ自体が役に立ったということはなく、単にAppleScript Librariesの書き方のサンプルと理解しています。Webサイトの表示を行うよりも１枚ものの画像やPDFにレンダリングする処理のほうがバッチ処理の中では相性がいいと思います。

また、このScriptはWkWebViewではなく古いWebViewを使っているので、じきに動かなくなります。

AppleScript名：WebKit Utilitiesで指定URLをウィンドウ表示

— Created 2017-03-24 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use webLib : script "WebKit Utilities"

set targetURL to "http://www.piyocast.com/"
display URL targetURL window size {1024, 1024}

★Click Here to Open This Script　

AppleScript名：WebKit Utilities

— An example AppleScript/Objective-C library that uses the WebKit framework.

use AppleScript
use framework "AppKit"
use framework "WebKit"

property NSURL : a reference to current application’s NSURL
property WebView : a reference to current application’s WebView
property NSScreen : a reference to current application’s NSScreen
property NSThread : a reference to current application’s NSThread
property NSWindow : a reference to current application’s NSWindow
property NSURLRequest : a reference to current application’s NSURLRequest
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

on _DisplayWebWindowWithURL:theURLString windowSize:theWindowSize
　　— Create and display a horizontally centered window with a WebView
　　
　　set {thisWindowWidth, thisWindowHeight} to theWindowSize
　　set screenBounds to the NSScreen’s mainScreen’s visibleFrame as any
　　
　　if class of screenBounds = record then
　　　　set screenWidth to screenBounds’s |size|’s width
　　　　set screenHeight to screenBounds’s |size|’s height
　　　　set windowLeft to ((screenWidth – thisWindowWidth) / 2) + (screenBounds’s origin’s x)
　　　　set windowBottom to screenHeight – thisWindowHeight + (screenBounds’s origin’s y) – 40
　　else
　　　　copy screenBounds to {{originX, originY}, {screenWidth, screenHeight}}
　　　　set windowLeft to ((screenWidth – thisWindowWidth) / 2) + originX
　　　　set windowBottom to screenHeight – thisWindowHeight + originY – 40
　　end if
　　
　　set theStyleMask to (get current application’s NSTitledWindowMask) + (get current application’s NSClosableWindowMask) + (get current application’s NSMiniaturizableWindowMask) + (get current application’s NSResizableWindowMask)
　　set webWindow to NSWindow’s alloc()’s initWithContentRect:(current application’s NSMakeRect(windowLeft, windowBottom, thisWindowWidth, thisWindowHeight)) ¬
　　　　styleMask:theStyleMask backing:(current application’s NSBackingStoreBuffered) defer:false
　　— set webWindow’s title to "WebView Created with AppleScript – " & theURLString
　　
　　set theWebView to WebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, thisWindowWidth, thisWindowHeight)) ¬
　　　　frameName:"WebKit Frame" groupName:"WebKit Group"
　　set webWindow’s contentView to theWebView
　　
　　tell webWindow to makeKeyAndOrderFront:(missing value)
　　
　　— Start loading the URL
　　
　　set theURL to NSURL’s URLWithString:theURLString
　　set theURLRequest to NSURLRequest’s requestWithURL:theURL
　　tell theWebView’s mainFrame to loadRequest:theURLRequest
　　
　　webWindow
end _DisplayWebWindowWithURL:windowSize:

— The following two handlers exist to deal with running on a background thread.
— If we’re on a background thread, we have to run the UI code on the main thread.

on _DisplayWebWindowMainThread:parameterDictionary
　　try
　　　　set theURLString to parameterDictionary’s objectForKey:"url string"
　　　　set theWindowSize to parameterDictionary’s objectForKey:"window size"
　　　　
　　　　set webWindow to my _DisplayWebWindowWithURL:theURLString windowSize:theWindowSize
　　　　
　　　　tell parameterDictionary to setObject:webWindow forKey:"result"
　　on error errMsg number errNum
　　　　using terms from scripting additions
　　　　　　display alert "Error!" message errMsg & " (" & errNum & ")"
　　　　end using terms from
　　　　tell parameterDictionary to setObject:{errMsg, errNum} forKey:"error"
　　end try
end _DisplayWebWindowMainThread:

on display URL theURLString window size theWindowSize
　　— All UI methods must be invoked on the main thread.
　　if (NSThread’s isMainThread) then
　　　　my _DisplayWebWindowWithURL:theURLString windowSize:theWindowSize
　　else
　　　　— Parameters, results and error information are communicated between threads via a dictionary.
　　　　set parameterDictionary to NSMutableDictionary’s dictionary()
　　　　tell parameterDictionary to setObject:theURLString forKey:"url string"
　　　　tell parameterDictionary to setObject:theWindowSize forKey:"window size"
　　　　
　　　　its performSelectorOnMainThread:"_DisplayWebWindowMainThread:" withObject:parameterDictionary waitUntilDone:true
　　　　
　　　　— Propagate errors from the other thread
　　　　
　　　　set errInfo to parameterDictionary’s objectForKey:"error"
　　　　if errInfo is not missing value then error errInfo’s first item number errInfo’s second item
　　　　
　　　　parameterDictionary’s objectForKey:"result"
　　end if
end display URL

★Click Here to Open This Script　

指定のフォントとサイズに該当するテキストを抽出する v3

Posted on 12月 1, 2019 by Takaaki Naganoya

指定のRTFファイルから書式情報を取得し、フォント名とフォントサイズのペアをスタイルを反映させたポップアップメニューで選択。RTFの内容を解析したのち、ダイアログが表示されます（ここの所要時間は読ませるRTFのサイズ次第）。ポップアップメニューで書式を選ぶと、すぐさま抽出した箇所をすべてまとめて表示します。

–> Watch Demo Movie

–> Download Script Bundle with Sample data

ダイアログ表示前に書式ごとの抽出を完了し、個別のTabViewに抽出後の文字データを展開しておくので、ポップアップメニューから選択すると、展開ずみのデータを入れてあるTabViewに表示を切り替えるだけ。切り替え時に計算は行わないため、すぐに抽出ずみの文字データが表示されるという寸法です。

今回は短いサンプルデータを処理してみましたが、サンプル抽出時にあらかじめ範囲指定するなどして、データ処理規模を限定することで処理時間を稼ぐこともできることでしょう。

テキストエディットでオープン中のRTF書類のパスを取得して、それを処理対象にしてもいいでしょう。

ただし、やっつけで作ったのでスクリプトエディタ上でCommand-Control-Rで実行しないと動きません（メインスレッド実行をプログラムで強制しても、途中でクラッシュしてしまいます）。それほど時間もかけずに作ったやっつけプログラムなので、あまり原因追求も行えずそのままです。

AppleScript名：アラートダイアログ＋Tab View v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/16
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use rtfLib : script "readStyledTextLib"
use parseLib : script "parseAttrLib"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSMenu : a reference to current application’s NSMenu
property NSArray : a reference to current application’s NSArray
property NSTabView : a reference to current application’s NSTabView
property NSPredicate : a reference to current application’s NSPredicate
property NSTextView : a reference to current application’s NSTextView
property NSMenuItem : a reference to current application’s NSMenuItem
property NSTabViewItem : a reference to current application’s NSTabViewItem
property NSPopUpButton : a reference to current application’s NSPopUpButton
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSStrokeWidthAttributeName : a reference to current application’s NSStrokeWidthAttributeName
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property TabPosition : 4 —0=Top, 1=Left, 2=Bottom, 3=Right, 4=None

property returnCode : 0

property aTabV : missing value
property selectedNum : {}

set aFile to choose file of type {"public.rtf"}

set aStyledStr to readRTFfile(aFile) of rtfLib
set paramObj to {myMessage:"Select Style", mySubMessage:"Select style you want to filter", viewWidth:800, viewHeight:400, myStyledStr:aStyledStr}

my dispTabViewWithAlertdialog:paramObj –for debug
–my performSelectorOnMainThread:"dispTabViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
return selectedNum

on dispTabViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set aWidth to (viewWidth of paramObj) as integer –TextView width
　　set aHeight to (viewHeight of paramObj) as integer –TextView height
　　set aStyledStr to (myStyledStr of paramObj)
　　
　　set attrResTmp to getAttributeRunsFromAttrString(aStyledStr) of parseLib
　　set attrList to attributes of attrResTmp
　　set menuStyle to menuList of attrResTmp
　　
　　set selectedNum to {}
　　
　　set aView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　–Ppopup Buttonをつくる
　　set a1Button to NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 20, 400, 20)) pullsDown:false
　　a1Button’s removeAllItems()
　　
　　–WYSIWHG popup menuをつくる
　　set a1Menu to NSMenu’s alloc()’s init()
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set aTitle to (tmpFont & " " & tmpSize as string) & " point"
　　　　set aMenuItem to (NSMenuItem’s alloc()’s initWithTitle:aTitle action:"actionHandler:" keyEquivalent:"")
　　　　
　　　　set attributedTitle to makeRTFfromParameters(aTitle, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　
　　　　(aMenuItem’s setEnabled:true)
　　　　(aMenuItem’s setTarget:me)
　　　　(aMenuItem’s setTag:(i as string))
　　　　(aMenuItem’s setAttributedTitle:(attributedTitle))
　　　　(a1Menu’s addItem:aMenuItem)
　　end repeat
　　
　　–Ppopup Buttonにmenuをつける
　　a1Button’s setMenu:a1Menu
　　
　　–Make Tab View
　　set aTabV to NSTabView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 30))
　　aTabV’s setTabViewType:(TabPosition)
　　
　　
　　–TabViewに中身を入れる
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set tmpKey to (tmpFont as string) & "/" & (tmpSize as string)
　　　　set tmpArry to filterRecListByLabel1(attrList, "styleKey2 == ’" & tmpKey & "’") of me
　　　　set tmpStr to (tmpArry’s valueForKeyPath:"stringVal") as list
　　　　
　　　　set aTVItem to (NSTabViewItem’s alloc()’s initWithIdentifier:(i as string))
　　　　(aTVItem’s setLabel:(i as string))
　　　　
　　　　
　　　　set aTextView to (NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth – 10, aHeight – 10)))
　　　　(aTextView’s setRichText:true)
　　　　set tmpAttr to makeRTFfromParameters(tmpStr as string, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　(aTextView’s textStorage()’s appendAttributedString:tmpAttr)
　　　　
　　　　(aTVItem’s setView:aTextView)
　　　　
　　　　(aTabV’s addTabViewItem:aTVItem)
　　end repeat
　　
　　
　　aView’s setSubviews:{a1Button, aTabV}
　　aView’s setNeedsDisplay:true
　　
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aView)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　end tell
　　
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set selectedNum to contents of item ((a1Button’s indexOfSelectedItem()) + 1) of menuStyle
end dispTabViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–Popup Action Handler
on actionHandler:sender
　　set aTag to tag of sender as integer
　　aTabV’s selectTabViewItemAtIndex:(aTag – 1)
end actionHandler:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, aFontName as string, aFontSize as real, aColor)
　　–フォント
　　set aVal1 to NSFont’s fontWithName:(aFontName) |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　–色
　　set aVal2 to aColor
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　–カーニング
　　set aVal3 to 0.0
　　set akey3 to (NSKernAttributeName)
　　
　　–アンダーライン
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　–リガチャ
　　–set aVal5 to 2 –全てのリガチャを有効にする
　　–set akey5 to ( NSLigatureAttributeName)
　　
　　–枠線（アウトライン）
　　–set aVal6 to outlineNum
　　–set akey6 to ( NSStrokeWidthAttributeName)
　　
　　
　　set keyList to {aKey1, aKey2, akey3, akey4}
　　set valList to {aVal1, aVal2, aVal3, aVal4}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　set bList to filteredArray
　　return bList
end filterRecListByLabel1

★Click Here to Open This Script　

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

Posted on 11月 13, 2019 by Takaaki Naganoya

アラートダイアログ上に指定月のカレンダー１か月分を表示してユーザーの日付選択（複数可）をもとめるAppleScriptです。

NSDatePickerを用いて日付選択のダイアログを作っていたら、日付がとても小さくて現代のMacの画面解像度にとても合っておらず、もっと大きめのカレンダーで選択したいと考えて作ったものです。

（１）カレンダーの表示サイズを大型化

現代のMacの画面にNSDatePickerをそのまま表示すると、とても小さくて見ていられないので、表示サイズを自由に変えられるカレンダー選択部品を作ってみました。どれか１つの日付を選択するものではなく、複数の日付を選択して、リストで結果を返してきます。

▲画面上で見やすいようにカレンダー部品を大型化

（２）選択無効日指定

あらかじめ、日付選択の対象外とする日付を指定できるようにしました。

（３）過去日付の選択無効

過去の日付を表示・選択できないようにする指定です。

▲過去日付を無効に指定すると、現在日時よりも過去の日付は選択できない

（４）曜日を現在のLocale情報から変更

曜日に用いる文字列を現在のLocale情報から取得するようにしてみました。本来であれば、日曜日はじまり「ではない」カレンダーを用いている場所もあるので（香港とかフランスとか？）、どの曜日から表示開始するかを自由選択にしたいところですが、そこまでは作り込んでいません。

▲Localeに合わせた曜日が表示される（ただし、年/月は固定フォーマット）

実用性を考えれば、Calendar.appのように日付選択とスケジュール確認が行えるものが望ましいのですが、そこまで作り込む手間をかけるほどのものでもないですし、表示対象月の移動を行おうとしてclickイベントを拾いつつカレンダー再描画に失敗した「残骸」です。見た目はいいのに完成度がいまひとつというあたりが残念です。

AppleScript名：アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

— Created 2019-10-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSButton : a reference to current application’s NSButton
property NSOnState : a reference to current application’s NSOnState
property NSOffState : a reference to current application’s NSOffState
property NSTextField : a reference to current application’s NSTextField
property NSMutableArray : a reference to current application’s NSMutableArray
property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property theResult : 0
property returnCode : 0
property bArray : {} –Checkbox button object array

property tYear : 0
property tMonth : 0
property theAlert : missing value
property theView : missing value

on run
　　set tYear to 2019
　　set tMonth to 11
　　set ignoreP to true
　　set ndList to {2, 3, 4, 9, 10, 13, 16, 17, 23, 24, 25, 30} –選択表示させない日付
　　set paramObj to {myMessage:"", mySubMessage:"適切な日付を以下からえらんでください", targetYear:tYear, targetMonth:tMonth, nodisp:ndList, ignorePast:ignoreP}
　　
　　–Detect Past Date Error
　　set curDate to current date
　　set dLimit to getMlen(tYear, tMonth) of me
　　set tmpDate to getDateInternational(tYear, tMonth, dLimit) of me
　　if (tmpDate < curDate) and (ignoreP = true) then error (("Target month is past (" & tYear as string) & "/" & tMonth as string) & "/1 is past. Today is " & date string of curDate & ")"
　　
　　–my chooseItemByCheckBox:paramObj –for Debugging
　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　return my sort1DNumList:(my theResult) ascOrder:true
　　–> {1, 3, 5, 7, 9, 11}
end run

on chooseItemByCheckBox:(paramObj)
　　set aMainMes to (myMessage of paramObj) as string
　　set aSubMes to (mySubMessage of paramObj) as string
　　set aMatList to (matrixTitleList of paramObj) as list
　　set tYear to (targetYear of paramObj) as integer
　　set tMonth to (targetMonth of paramObj) as integer
　　set noDispList to (nodisp of paramObj) as list
　　set ignoreP to (ignorePast of paramObj) as boolean
　　
　　if aMainMes = "" then
　　　　set aMainMes to "日付を選択してください"
　　end if
　　
　　set theView to makeCalendarView(tYear, tMonth, noDispList, ignoreP) of me
　　
　　–Select the first radio button item
　　set my theResult to {}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　　　
　　　　–for Help Button
　　　　–its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　set aWin to its |window|()
　　end tell
　　
　　aWin’s setLevel:(current application’s NSFloatingWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end chooseItemByCheckBox:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to (tag of aParam) as integer
　　
　　–clicked
　　if aTag is not in (my theResult) then
　　　　set the end of (my theResult) to aTag
　　else
　　　　set theResult to my deleteItem:aTag fromList:theResult
　　end if
end clicked:

on deleteItem:anItem fromList:theList
　　set theArray to NSMutableArray’s arrayWithArray:theList
　　theArray’s removeObject:anItem
　　return theArray as list
end deleteItem:fromList:

–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DNumList:theList ascOrder:aBool
　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　return (sortedList) as list
end sort1DNumList:ascOrder:

–Help Button Clicked Event Handler
on alertShowHelp:aNotification
　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　set bRes to (button returned of aRes) as string
　　
　　if bRes = "All Off" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　end repeat
　　　　
　　else if bRes = "All On" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　set the end of theResult to i + 1
　　　　end repeat
　　end if
　　
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　set aVal2 to NSColor’s blackColor()
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　set aVal3 to aKerning
　　set akey3 to (NSKernAttributeName)
　　
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　set aVal5 to 2 –all ligature ON
　　set akey5 to (NSLigatureAttributeName)
　　
　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　set akey7 to (NSParagraphStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–指定月のカレンダーを1D List(7 days x 6 weeks) で返す
on retListCalendar(tYear, tMonth)
　　set mLen to getMlen(tYear, tMonth) of me
　　set aList to {}
　　
　　set fDat to getDateInternational(tYear, tMonth, 1) of me
　　tell current application
　　　　set aOffset to (weekday of fDat) as number
　　end tell
　　
　　–header gap
　　repeat (aOffset – 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　–calendar body
　　repeat with i from 1 to mLen
　　　　set the end of aList to (i as string)
　　end repeat
　　
　　–footer gap
　　repeat (42 – aOffset – mLen + 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　return aList
end retListCalendar

–現在のカレンダーで指定年月の日数を返す（国際化対応版）
on getMlen(aYear as integer, aMonth as integer)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar()
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　return |length| of theResult
end getMlen

–ローカライズされた曜日名称を返す
on getLocalizedDaynames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols() as list
　　return dayNames
end getLocalizedDaynames

–ローカライズされた月名称を返す
on getLocalizedMonthnames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set monthNames to df’s standaloneMonthSymbols() as list
　　return monthNames
end getLocalizedMonthnames

–ローカライズされた曜日の名称を返す
on getLocalizedWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s weekdaySymbols()
　　return dayNames as list
end getLocalizedWeekdaySymbol

–ローカライズされた曜日の名称（短縮版）を返す
on getLocalizedShortWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s shortWeekdaySymbols()
　　return dayNames as list
end getLocalizedShortWeekdaySymbol

–ローカライズされた曜日の名称（短縮記号）を返す
on getLocalizedVeryShortWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s veryShortWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryShortWeekdaySymbol

–ローカライズされた曜日の名称を返す
on getLocalizedVeryStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryStandaloneWeekdaySymbols

–ローカライズされた曜日の名称を返す
on getLocalizedShortStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s shortStandaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedShortStandaloneWeekdaySymbols

–ローカライズされた曜日の名称を返す
on getLocalizedVeryShortStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s veryShortStandaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryShortStandaloneWeekdaySymbols

–カレンダー表示ビューを作成
on makeCalendarView(tYear as integer, tMonth as integer, noDispList as list, ignoreP as boolean)
　　set colNum to 7
　　set rowNum to 8
　　set aLen to (colNum * rowNum)
　　
　　set aButtonCellWidth to 70 –56
　　set aButtonCellHeight to 40
　　
　　set viewWidth to aButtonCellWidth * colNum
　　set viewHeight to aButtonCellHeight * rowNum
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　
　　set aCount to 1
　　set aFontSize to 30
　　set bArray to current application’s NSMutableArray’s new()
　　
　　–Make Header (Month, Year)
　　set x to 1
　　set tmpB to (NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * (aButtonCellHeight), aButtonCellWidth * 4, aButtonCellHeight)))
　　(tmpB’s setEditable:false)
　　(tmpB’s setBordered:false)
　　(tmpB’s setDrawsBackground:false)
　　(tmpB’s setAlignment:(current application’s NSLeftTextAlignment))
　　(tmpB’s setStringValue:((tYear as string) & " / " & tMonth as string))
　　(tmpB’s setFont:(NSFont’s fontWithName:"Times-Roman" |size|:40))
　　(bArray’s addObject:tmpB)
　　
　　set aCount to aCount + 1
　　
　　
　　–Make Header (Weekday)
　　set curLocale to current application’s NSLocale’s currentLocale()
　　set aDS10 to (curLocale’s objectForKey:(current application’s NSLocaleIdentifier)) as string
　　set wdList to getLocalizedShortStandaloneWeekdaySymbols(aDS10) of me
　　set y to 2
　　
　　repeat with x from 1 to 7
　　　　set j to contents of item x of wdList
　　　　set tmpB to (NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum – 1) * (aButtonCellHeight), aButtonCellWidth, aButtonCellHeight / 2)))
　　　　(tmpB’s setEditable:false)
　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　(tmpB’s setStringValue:(j))
　　　　(bArray’s addObject:tmpB)
　　end repeat
　　
　　set aCalList to retListCalendar(tYear, tMonth) of me
　　set aCount to 1
　　
　　
　　–Make Calendar (Calendar Body)
　　set curDat to current date
　　
　　repeat with y from 3 to rowNum
　　　　repeat with x from 1 to colNum
　　　　　　set j to contents of item aCount of aCalList
　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum – 2) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　
　　　　　　set tmpDate to getDateInternational(tYear, tMonth, j as integer) of me
　　　　　　set tmpF to (tmpDate < curDat) as boolean
　　　　　　
　　　　　　if ignoreP = false then
　　　　　　　　set dispF to true
　　　　　　else if ignoreP = true and tmpF = false then
　　　　　　　　set dispF to true
　　　　　　else
　　　　　　　　set dispF to false
　　　　　　end if
　　　　　　
　　　　　　if (j as integer) is not in noDispList then
　　　　　　　　if (dispF = true) then
　　　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:"ArialMT" |size|:aFontSize))
　　　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), "ArialMT", aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeOnOff))
　　　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　　　if j is not equal to "" then
　　　　　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　end if
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　end repeat
　　
　　(aView’s setSubviews:bArray)
　　return aView
end makeCalendarView

★Click Here to Open This Script　

指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

Posted on 11月 13, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションからすべてのLocaleを取得し、ダイアログ選択したLocale内のすべてのstringsファイルを読み込んでNSDictionary化して指定のキーワードを含むものを抽出するAppleScriptです。

指定キーワードが含まれていた場合には、

キー, 値, stringsファイルのパス

をリストで返します。調査のための下調べを行うものです。

AppleScript名：指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants

set targID to "com.apple.Finder"
set targWords to "のコピー"

set bRes to getLocalizationsFromBundleID(targID) of me
–>　　{"de", "he", "en_AU", "ar", "el", "ja", "en", "uk", "es_419", "zh_CN", "es", "da", "it", "sk", "pt_PT", "ms", "sv", "cs", "ko", "Base", "no", "hu", "zh_HK", "tr", "pl", "zh_TW", "en_GB", "vi", "ru", "fr_CA", "fr", "fi", "id", "nl", "th", "pt", "ro", "hr", "hi", "ca"}

–Select Localization
set curLang to first item of (choose from list bRes)

–Get All strings file path within a bundle
set aPath to retPathFromBundleID(targID) of me
set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

–Get Every Key & Value pair then filter target keyword
set aMDict to NSMutableDictionary’s new()
set hitList to {}
repeat with ii in sList
　　set jj to contents of ii
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:jj)
　　(aMDict’s addEntriesFromDictionary:aDict)
　　
　　set kList to aMDict’s allKeys() as list
　　set vList to aMDict’s allValues() as list
　　
　　set kCount to 1
　　repeat with i in vList
　　　　set j to contents of i
　　　　if j contains targWords then
　　　　　　set the end of hitList to {contents of item kCount of kList, j, jj}
　　　　end if
　　　　set kCount to kCount + 1
　　end repeat
　　
end repeat

return hitList
–> {{"PW5_V2", "^0項目のコピーの準備中", "/System/Library/CoreServices/Finder.app/Contents/Resources/Japanese.lproj/Localizable.strings"}, …}

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　

指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する

Posted on 11月 13, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションのバンドル中（/Contents/Resources/）のすべてのLocalizationに存在する指定のstringsファイル内で、指定キーの値を取得するAppleScriptです。

macOSの日本語環境では、Finder上でコピーしたファイルのファイル名の後方に「のコピー」といった文字列が追記されますが、他のLocaleでどのような文字列が使用されているか調査するために作成したものです。

AppleScript名：指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/12
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set targID to "com.apple.Finder"
set targFile to "Localizable.strings"
set targKey to "N4_V2"
set vList to getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey) of me
–> {{"he", "עותק של ^=1 ^=0"}, {"en_AU", "^=1 copy ^=0"}, {"ar", "نسخة ^=0 من ^=1"}, {"el", "^=1 αντίγραφο ^=0"}, {"uk", "^=1 копія ^=0"}, {"English", "^=1 copy ^=0"}, {"es_419", "Copia de ^=1 ^=0"}, {"zh_CN", "^=1的副本 ^=0"}, {"Dutch", "^=1 kopie ^=0"}, {"da", "^=1-kopi ^=0"}, {"sk", "^=1 – kópia ^=0"}, {"pt_PT", "^=1 – cópia ^=0"}, {"German", "^=1 Kopie ^=0"}, {"ms", "salinan ^=0 ^=1"}, {"sv", "^=1 (kopia ^=0)"}, {"cs", "^=1 (kopie ^=0)"}, {"ko", "^=1 복사본 ^=0"}, {"no", "^=1-kopi ^=0"}, {"hu", "^=1 másolat ^=0"}, {"zh_HK", "^=1 副本 ^=0"}, {"Spanish", "^=1 copia ^=0"}, {"tr", "^=1 kopyası ^=0"}, {"pl", "^=1-kopia ^=0"}, {"zh_TW", "^=1 拷貝 ^=0"}, {"en_GB", "^=1 copy ^=0"}, {"French", "^=1 copie ^=0"}, {"vi", "Bản sao ^=1 ^=0"}, {"ru", "^=1 — копия ^=0"}, {"fr_CA", "^=1 copie ^=0"}, {"fi", "^=1 kopio ^=0"}, {"id", "Salinan ^=1 ^=0"}, {"th", "^=1 สำเนา ^=0"}, {"pt", "^=1 – cópia ^=0"}, {"ro", "^=1 – copie ^=0"}, {"Japanese", "^=1のコピー^=0"}, {"hr", "^=1 kopija ^=0"}, {"hi", "^=1 कॉपी ^=0"}, {"Italian", "^=1 copia ^=0"}, {"ca", "^=1 còpia ^=0"}}

on getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey)
　　–Get App Path
　　set aPath to retPathFromBundleID(targID) of me
　　
　　–Get all Localizations
　　set bRes to getLocalizationsFromBundleID(targID) of me
　　
　　set hitList to {}
　　
　　–Loop with Localizations in an application bundle
　　repeat with iii in bRes
　　　　set jjj to contents of iii
　　　　set allPath to aPath & "/Contents/Resources/" & jjj & ".lproj/" & targFile
　　　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:allPath)
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　set the end of hitList to {jjj, aVal as string}
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return hitList
end getAValInASpecifiedStringFileOfAllLocaleInABundle

★Click Here to Open This Script　

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

Posted on 9月 21, 2019 by Takaaki Naganoya

バンドルIDで指定したアプリケーションのResourcesフォルダ中の、指定ロケールのstringsファイルをすべて読み込んでkeyを取り出すAppleScriptです。

アプリケーション内の指定のローカライズしたメッセージ（テキスト）の内容を取り出すことはできますが、そのためにはキーを知っておく必要があります。そのキーを取り出してローカライズされた文字列を取り出すため、キーを調査してみました。

これをそのまま何かのツールなりScriptに使うというものではなく、いわゆる「下調べ」のためのScriptの部品です。

ほぼ、ありもののルーチンを再利用しただけのプログラムでできていますが、ありものはありもので、数千本のAppleScriptのストックからそれを探し出してくるのも一苦労です。

アプリケーションバンドル内のResourcesフォルダ以下の（各lprojフォルダ以下の）stringsファイルの中身はまんま（シリアライズした）NSDictionaryなので、そのままDictionaryに読み込んでallkey()などのメソッドを実行できます。昔のstringsファイルはテキストファイルだったような気がしますが、テキストファイルだとparseしないといけないんで、ビルド時にparseしておいてDictionaryの状態でファイルに書いておくのは正しいと思います。

Xcode 8あたりから、アプリケーションのローカライズのルールが変更になったようで、基本となる言語環境がBase.lprojになり、英語はen.lprojといった１ローカライズ言語という位置付けに変更になりました。

NSLocalizedStringFromTableInBundleを使ってアクセスしようかとも思ったのですが、こちらはまだ目的を達成できていません。

▲Xcode 11上で実験的に作成したAppleScriptアプリケーションのバンドル構造（左）。ローカライズしていない状態だとEnglishではなくBase.lprojが作成される。右はKeynote.app/Contents/Resources/ja.lprojフォルダの内容。stringsファイルが大量に存在している

AppleScript名：指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す.scptd

set targID to "com.apple.iWork.Keynote"

set curLang to first item of (choose from list bRes)
set aPath to retPathFromBundleID(targID) of me

set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

set aMDict to NSMutableDictionary’s new()

repeat with i in sList
　　set j to contents of i
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:j)
　　(aMDict’s addEntriesFromDictionary:aDict)
end repeat

return aMDict’s allKeys() as list
–> {"Interactive Bubble Chart", "Rehearse Slideshow", "PMT_ARGUMENT_1", "ACCRINTM_ARGUMENT_4_MODE_0", "Truck_378",….}

★Click Here to Open This Script　

2つのレコードのキーの重複を計算

Posted on 9月 7, 2019 by Takaaki Naganoya

2つのレコードのキーの重複を検出するAppleScriptです。

こういう処理がお手軽にできるようになったので、macOS 10.10以降のAppleScriptでないとプログラムが組めなくなっている今日このごろ。死ぬほど努力してOld Style AppleScript（Cocoaの機能を使わない）だけで組めないこともないですが、それだけで半日は費やして数百行のプログラムになってしまいそうです。

というわけで、Cocoaの機能を利用した「ありもの」のルーチンを組み合わせるだけでほぼ完成。２つのレコードのキーの重複計算を行います。

どういう用途で使うかといえば、パラメータつきのURLに対して追加パラメータを付加したい場合です。URLからレコード形式でパラメータを分離し、追加パラメータ（レコード形式）を足し算する「前」に、２つのレコード間で重複キーがないかチェックする、という用途です。

では、２つのレコードの加算はどーするのか？　という話になりますが、それは単に&演算子で加算するだけです。

set aRec to {abc:"1", bcd:"2"}
set bRec to {ccc:"0", ddd:"9"}
set cRec to aRec & bRec
–> {abc:"1", bcd:"2", ccc:"0", ddd:"9"}

★Click Here to Open This Script　

AppleScript名：2つのレコードのキーの重複を計算.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/06
—
–　　Copyright © 2019 jp.piyomarusoft, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSSet : a reference to current application’s NSSet
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

set aRec to {autoplay:"1", hd:"9"}
set bRec to {v:"GP_tVXTYdmY", t:"120", hd:"3"}

set dupKeys to detectDuplicateKeysInTwoRecords(aRec, bRec) of me
–> {"hd"}

on detectDuplicateKeysInTwoRecords(aRec, bRec)
　　set aDict to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set bDict to NSMutableDictionary’s dictionaryWithDictionary:bRec
　　
　　set aKeyList to (aDict’s allKeys()) as list
　　set bKeyList to (bDict’s allKeys()) as list
　　
　　set allKeyList to aKeyList & bKeyList
　　
　　set aRes to returnDuplicatesOnly(allKeyList) of me
　　return aRes
end detectDuplicateKeysInTwoRecords

–1D Listから重複項目のみ返す
on returnDuplicatesOnly(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　

指定のAppleScriptテキストを構文確認して指定の構文要素が入っていないかチェック

Posted on 7月 31, 2019 by Takaaki Naganoya

指定のテキストをAppleScriptとみなして構文確認して、指定の構文要素が入っていないかチェックするAppleScriptです。

AppleScriptにeval関数はないので、文字列として与えたAppleScriptをその場で実行する「run script」コマンドをevalがわりに使っています。

文字列をそのままrun scriptするのは（一応いろいろ保護機能はあるものの）、セキュリティ的にリスクの高い操作になってしまいます。

▲こんなのがrun scriptコマンドで実行されてしまったらと思うとゾッとします。ためしに実行してみたら、実行権限がないので実行できないエラーになりました

そこで、文字列をいったんAppleScriptとして評価（構文確認）し、コマンドなどの危険と思われる構文要素が入っていないかどうかチェックする処理を書いて使っています。

これら、「コマンド」および「追加コマンド」といった構文要素が入っていたらtrueを返します。

本Scriptをライブラリ化して組み込むことで、少ない記述量で対象の文字列をそのままrun scriptしてよいかどうか判定できるようにしています。

–> Download checkDanger(with Library in its bundle)

▲実際にテキストをAppleScriptとして評価して構文要素を検出し、このようにコマンド部分（AppleScriptのdo shell scriptコマンド）が入っていることを検知できる

AppleScript名：指定のAppleScriptテキストを構文確認して指定の構文要素が入っていないかチェック.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/31
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "AppKit"
use framework "OSAKit"
use attrLib : script "asAttrRecLib"

property NSArray : a reference to current application’s NSArray
property OSANull : a reference to current application’s OSANull
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property OSALanguageInstance : a reference to current application’s OSALanguageInstance

script spd
　　property fArray : {}
　　property outList : {}
　　property resStr : {}
end script

on run
　　set theSource to "do shell script ＼"rm -f *.*＼""
　　set aRes to chkTargLexicalElementsFromCompiledScriptAttribute(theSource, {9, 14}) of me –{Command, External Command}
　　–> true : 指定の構文要素が入っていた
　　
　　set theSource to "{{aName:＼"piyoko＼", aVal:100}, {aName:＼"piyomaru＼", aVal:80}, {aName:＼"piyoo＼", aVal:10}, {aName:＼"Gundamo＼", aVal:10}}"
　　set bRes to chkTargLexicalElementsFromCompiledScriptAttribute(theSource, {9, 14}) of me –{Command, External Command}
　　–> false : 指定の構文要素は入っていなかった
end run

–AppleScriptのソーステキストをコンパイルして、指定の構文要素が含まれているかチェックする
on chkTargLexicalElementsFromCompiledScriptAttribute(theSource as string, targLexicalElements as list)
　　
　　–AppleScriptの構文色分け情報を取得
　　set ccRes to getAppleScriptSourceColors() of me
　　set cRes to chkASLexicalFormatColorConfliction(ccRes) of me –構文色分けの重複色チェック
　　if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"
　　
　　–検索用の色情報を作成
　　set colTargList to {}
　　repeat with i in targLexicalElements
　　　　set commentCol to contents of item i of ccRes –Variable and Sub-routine name
　　　　set searchVal to (redValue of commentCol as string) & " " & (greenValue of commentCol as string) & " " & (blueValue of commentCol as string) –for filtering
　　　　set the end of colTargList to searchVal
　　end repeat
　　
　　
　　–与えられたテキストをAppleScriptとして評価し構文色分け情報をもとにStyle Runs的なDictionary化して返す
　　set aRitch to compileASSourcetextAndReturnStyledText(theSource) of me
　　
　　
　　–書式付きテキストからstyle runs的な書式リストを作成
　　set anAttrList to getAttributeRunsFromAttrString(aRitch) of attrLib
　　
　　set bList to filterRecListByLabelAndSublist(anAttrList, "colorStr IN %@", colTargList) of me
　　
　　return not (bList as list = {}) as boolean
　　
end chkTargLexicalElementsFromCompiledScriptAttribute

on retDelimedText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retDelimedText

——-

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceNSColorsDict()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set aDict to NSMutableDictionary’s alloc()’s init()
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set colIndStr to (rVal as string) & " " & (gVal as string) & " " & (bVal as string)
　　　　set tmpColDat to {numList:{rVal, gVal, bVal}, strInd:colIndStr}
　　　　–(aDict’s addObject:tmpColDat forKey:theColor)
　　　　(aDict’s addObject:{rVal, gVal, bVal} forKey:theColor)
　　end repeat
　　
　　return aDict
end getAppleScriptSourceNSColorsDict

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aSpace to (aCol’s colorSpaceName()) as string
　　–set aSpace to (aCol’s type()) as integer
　　
　　if aSpace is in {"NSDeviceRGBColorSpace", "NSCalibratedRGBColorSpace"} then
　　　　copy aCol to cCol
　　else
　　　　–RGB以外の色空間の色は、RGBに変換
　　　　–CMYKとグレースケールは同一メソッドでRGBに変換できることを確認済み
　　　　set cCol to aCol’s colorUsingColorSpaceName:"NSCalibratedRGBColorSpace"
　　　　if cCol = missing value then error "Color Space Conversion Error (" & aSpace & " to NSCalibratedRGBColorSpace)"
　　end if
　　
　　set aRed to round ((cCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((cCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((cCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue} as list
end retColListFromNSColor

–AS書式で配色に重複がないかどうかチェック
on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on returnDuplicatesOnly(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

–テキスト形式のAppleScriptをコンパイルして書式付きテキスト（NSAttributedString）を返す
on compileASSourcetextAndReturnStyledText(theSource)
　　— create a new AppleScript instance
　　set anOSALanguageInstance to OSALanguage’s languageForName:"AppleScript"
　　
　　set theScript to OSAScript’s alloc()’s initWithSource:theSource fromURL:(missing value) languageInstance:anOSALanguageInstance usingStorageOptions:(OSANull)
　　set {theResult, theError} to theScript’s compileAndReturnError:(reference)
　　
　　if theResult as boolean is false then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　return styledSourceText
end compileASSourcetextAndReturnStyledText

–文字置換
on repChar(origText as string, targChar as string, repChar as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

–リストに入れたレコードを、指定の属性ラベルの値で抽出。値が別途指定のリストの中に存在していることが条件
on filterRecListByLabelAndSublist(aRecList as list, aPredicate as string, aSubList as list)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set aSubArray to NSArray’s arrayWithArray:aSubList
　　
　　–抽出
　　set aPredicate to NSPredicate’s predicateWithFormat_(aPredicate, aSubArray)
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　
　　return filteredArray as list
end filterRecListByLabelAndSublist

★Click Here to Open This Script　

Cocoa ObjectをキーにしたDictionaryから合致するObjectを取得

Posted on 7月 7, 2019 by Takaaki Naganoya

Cocoa ObjectをキーにしたDictionaryから、Cocoa Objectでキー検索を行い、キーが合致する要素に定義されているオブジェクトを取得するAppleScriptです。

AppleScriptのrecord型変数は、本当に基本的な機能しか用意されておらず、

{keyLabel1:value1, keyLabel2:value2, keyLabel3:value3 }

のような、キーとなるラベルには「空白文字や使用禁止文字を含まない」文字しか使えませんし、キーに何らかのオブジェクトを指定することはできません。

そんな中、macOS 10.10でCocoa Scriptingが標準搭載されたため、CocoaのNSDictionaryを調べて「へー、キーにオブジェクトが使えるのか！」などと喜んでいました（macOS 10.10が出た頃）。

{Cocoa Object 1:value1, Cocoa Object 2:value2, Cocoa Object 3:value3 }

{Cocoa Object 1:some object 1, Cocoa Object 2:some object 2, Cocoa Object 3:some object 3 }

ちょうどそういう（CocoaオブジェクトをキーにしたDictionaryの検索）プログラムを組もうとして、Dictionaryから「valueForKey:」でvalueを取り出そうとして（エラーに遭遇して）試行錯誤していました。

(NSDictionary) {
	NSCalibratedRGBColorSpace 0 1 0 1:"Green",
	NSCalibratedRGBColorSpace 0 0 1 1:"Blue",
	NSCalibratedRGBColorSpace 1 0 0 1:"Red"
}

実際にはこれは「objectForKey:」で取り出さないとエラーになってしまうんですね。その確認のために書いた基礎確認用のAppleScriptです。やっぱり、基礎の再確認はとても大事です。

AppleScript名：Cocoa ObjectをキーにしたDictionaryから合致するObjectを取得

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/06
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCol to current application’s NSColor’s redColor()
set bCol to current application’s NSColor’s greenColor()
set cCol to current application’s NSColor’s blueColor()

set aDict to current application’s NSMutableDictionary’s new()
aDict’s addObject:"Red" forKey:aCol
aDict’s addObject:"Green" forKey:bCol
aDict’s addObject:"Blue" forKey:cCol

set dCol to current application’s NSColor’s blueColor()

set aRes to (aDict’s objectForKey:dCol) as string
–> "Blue"

★Click Here to Open This Script　

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

Posted on 3月 29, 2019 by Takaaki Naganoya

英語版の花文字テキストを作成してテキストエディタ（CotEditor）に出力するAppleScriptです。

描画用の英単語と、塗りつぶし用の英単語を別々に指定できます。invertFをtrueに設定すると、白黒反転出力を行います。

おおもとの元ネタは、大型計算機を大勢のユーザーで共有していた時代（ぱそこん登場前）、計算結果を高速プリンタの帳票に出力するようになっていたころにさかのぼります。どのユーザーの計算結果かを大量のプリンタの出力結果の中から仕分けるため、印刷出力の１ページ目をユーザー名などの情報を印字した「バナー」として使用。

そのさい、ドットインパクトプリンターだったので、決められた固定ドット数の文字しか印字できないため、英数字を組み合わせて擬似的に大きな文字でバナーを印刷していたことに端を発します。

その時代の「残り香」ともいえるバナーがパソコンの電子メールやBBSの時代にお遊びの「花文字」として引き継がれ、原始的なアスキーアートの一種として楽しまれてきました。

いまでも、shell commandの「banner」コマンドにその末裔を見ることができます。

先週のmacOS nativeのデモ時に「祝」という花文字を「呪」の文字で出力するという、定番の持ちネタを披露したところ、たいへんウケておりました。

ただ、これを海外のScripter向けにそのままデモしても受けません。

この、花文字テキストを出力するプログラムの英語版としては、love.scptといういにしえのデータをそのまま使いまわしたものがありますが、描画パターンを数値データで保持しているため、異なるパターンを表示させることはできません。

そこで、日本語版の花文字テキスト出力プログラムに若干手をくわえ、英単語の出力が行えるようにしてみました。

テキストの出力はCotEditorに対して行なっていますが、新規書類を指定文字で作成する程度なので、AppleScriptに対応しているテキストエディタならどれでも作り変えられます。また、表示を等幅フォントにしておく必要があります（あとから指定してもOK）。

AppleScript名：指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

— Created 2017-12-12 by Takaaki Naganoya
— Modified 2019-03-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSColorSpace : a reference to current application’s NSColorSpace
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSFontManager : a reference to current application’s NSFontManager
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property fillCharList : {}
property fillCharCounter : 1

set aString to "Love"
set bString to "hate"
set hanaSize to 24
set thisFont to selectAFont(first character of aString) of me
if thisFont = false then return –Cancel

–花文字文字列を作成
set fRes to getEnglishHanamojiStr(hanaSize, thisFont, aString, bString, 0.7, true, true) of me
makeNewDocument given parameter:fRes

–花文字文字列を計算して返す
on getEnglishHanamojiStr(aFontSize as real, aFontName as string, aString as string, fillString as string, aThread as real, incFontName as boolean, invertF as boolean)
　　
　　set my fillCharList to characters of fillString
　　set my fillCharCounter to 1
　　
　　–指定文字コードが指定フォント中に存在するかチェック
　　repeat with i in (characters of aString)
　　　　set fRes to retGlyphsInFont(aFontName, id of i) of me
　　　　if fRes = false then return false
　　end repeat
　　
　　set aThreadShould to 768 * aThread
　　if (chkMultiByteChar(first character of aString) of me) = false then
　　　　set spaceChar to string id 12288 –全角スペース（UTF-16）
　　else
　　　　set spaceChar to string id 32 –半角スペース
　　end if
　　
　　set fillColor to NSColor’s whiteColor –塗り色
　　set bString to aString & " " –処理内容の帳尻合わせ（そのままだと右端が欠けるのでスペースを入れた）
　　set anAssrStr to makeRTFfromParameters(bString, aFontName, aFontSize, -2, (aFontSize * 1.2)) of me
　　set aSize to anAssrStr’s |size|()
　　
　　if class of aSize = record then
　　　　set attrStrWidth to width of aSize
　　　　set attrStrHeight to height of aSize
　　else if class of aSize = list then –macOS 10.13.xのバグ回避
　　　　copy aSize to {attrStrWidth, attrStrHeight}
　　end if
　　
　　set {xPos, yPos} to {0, 0}
　　
　　set tmpImg1 to makeImageWithFilledColor(attrStrWidth, attrStrHeight, fillColor) of me
　　set tmpImg2 to drawAttributedStringsOnImage(tmpImg1, anAssrStr, xPos, yPos) of me
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:(tmpImg2’s TIFFRepresentation())
　　
　　–画像から順次指定座標の色データを拾って花文字listに反映
　　set strList to {}
　　repeat with y from 1 to attrStrHeight – 1
　　　　
　　　　set strListX to {}
　　　　repeat with x from 0 to attrStrWidth – 1
　　　　　　set tmpCol to getColorFromRawImage(aRawimg, x, y) of me
　　　　　　
　　　　　　if invertF = false then
　　　　　　　　
　　　　　　　　–通常描画（invert = false）時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　else
　　　　　　　　–白黒反転（invert = true)時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　end if
　　　　end repeat
　　　　set the end of strList to strListX
　　end repeat
　　
　　–2D List→Text
　　set aRes to list2dToStringByUsingDelimiters(strList, "", return) of me
　　
　　if incFontName = true then
　　　　set fName to getDisplayedNameOfFont(aFontName) of me
　　　　set aRes to "Font=" & fName & return & return & aRes
　　end if
　　
　　return aRes
end getEnglishHanamojiStr

on getChar()
　　set retChar to item (my fillCharCounter) of (my fillCharList)
　　if (my fillCharCounter) = length of (my fillCharList) then
　　　　set (my fillCharCounter) to 1
　　else
　　　　set (my fillCharCounter) to (my fillCharCounter) + 1
　　end if
　　return retChar
end getChar

–指定Raw画像中の指定座標のピクセルの色をRGBで取り出す
on getColorFromRawImage(aRawimg, x as real, y as real)
　　set aRatio to getImageRatio() of me –Retina Display対応
　　set origColor to (aRawimg’s colorAtX:(x * aRatio) y:(y * aRatio))
　　
　　set srgbColSpace to NSColorSpace’s deviceRGBColorSpace
　　if srgbColSpace = missing value then return false
　　
　　set aColor to (origColor’s colorUsingColorSpace:srgbColSpace)
　　
　　set aRed to (aColor’s redComponent()) * 255
　　set aGreen to (aColor’s greenComponent()) * 255
　　set aBlue to (aColor’s blueComponent()) * 255
　　
　　return {aRed as integer, aGreen as integer, aBlue as integer}
end getColorFromRawImage

–画像のうえに指定のスタイル付きテキストを描画して画像を返す
on drawAttributedStringsOnImage(anImage, anAssrStr, xPos as real, yPos as real)
　　anImage’s lockFocus()
　　anAssrStr’s drawAtPoint:(current application’s NSMakePoint(xPos, yPos))
　　anImage’s unlockFocus()
　　return anImage
end drawAttributedStringsOnImage

–指定サイズの画像を作成し、背景を指定色で塗る
on makeImageWithFilledColor(aWidth as real, aHeight as real, fillColor)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　set aRatio to getImageRatio() of me –Retina Display対応
　　
　　anImage’s lockFocus()
　　set theRect to {{x:0, y:0}, {width:aWidth * aRatio, height:aHeight * aRatio}}
　　set theNSBezierPath to NSBezierPath’s bezierPath
　　theNSBezierPath’s appendBezierPathWithRect:theRect
　　fillColor’s |set|()
　　theNSBezierPath’s fill()
　　anImage’s unlockFocus()
　　
　　return anImage
end makeImageWithFilledColor

–2D Listをアイテム間および行間のデリミタを個別に指定してテキスト変換
on list2dToStringByUsingDelimiters(aList as list, itemDelimiter, lineDelimiter)
　　set outList to {}
　　repeat with i in aList
　　　　set aStr to listToStringUsingTextItemDelimiter(i, itemDelimiter) of me
　　　　set the end of outList to aStr
　　end repeat
　　
　　set bStr to listToStringUsingTextItemDelimiter(outList, lineDelimiter) of me
　　return bStr
end list2dToStringByUsingDelimiters

on listToStringUsingTextItemDelimiter(sourceList as list, textItemDelimiter)
　　set CocoaArray to NSArray’s arrayWithArray:sourceList
　　set CocoaString to CocoaArray’s componentsJoinedByString:textItemDelimiter
　　return (CocoaString as string)
end listToStringUsingTextItemDelimiter

–ユーザー環境にインストールされているすべてのフォントのPostScript名とグリフ数を返す
on getEveryFontPSNameANdGlyphsNum(aStr)
　　set aFontList to NSFontManager’s sharedFontManager()’s availableFonts()
　　set thePred to NSPredicate’s predicateWithFormat:"NOT SELF BEGINSWITH ’.’"
　　set aFontList to (aFontList’s filteredArrayUsingPredicate:thePred) as list
　　
　　set aList to {}
　　repeat with i in aFontList
　　　　set aName to contents of i
　　　　set aNum to countNumberOfGlyphsInFont(aName) of me
　　　　set dName to getDisplayedNameOfFont(aName) of me
　　　　
　　　　set fRes to retGlyphsInFont(aName, id of aStr) of me
　　　　if fRes = true then
　　　　　　set the end of aList to {fontName:aName, fontNum:aNum, dispName:dName}
　　　　end if
　　end repeat
　　
　　return aList
end getEveryFontPSNameANdGlyphsNum

–指定Postscript名称のフォントに定義されている文字数を数えて返す
on countNumberOfGlyphsInFont(fontName as string)
　　set aFont to NSFont’s fontWithName:fontName |size|:9.0
　　if aFont = missing value then return false
　　set aProp to aFont’s numberOfGlyphs()
　　return aProp as number
end countNumberOfGlyphsInFont

–フォントのPostScript NameからDisplayed Nameを取得
on getDisplayedNameOfFont(aName as string)
　　set aFont to NSFont’s fontWithName:aName |size|:9.0
　　set aDispName to (aFont’s displayName()) as string
　　return aDispName
end getDisplayedNameOfFont

–全角文字が存在するか
on chkMultiByteChar(checkString as string)
　　set aStr to NSString’s stringWithString:checkString
　　set aRes to aStr’s canBeConvertedToEncoding:(current application’s NSASCIIStringEncoding)
　　return (aRes as boolean)
end chkMultiByteChar

–指定名称のフォントに指定の文字コードが含まれているかチェック
on retGlyphsInFont(fontName as string, strCode as integer)
　　set aFont to NSFont’s fontWithName:fontName |size|:24.0
　　if aFont = missing value then return false
　　set aSet to aFont’s coveredCharacterSet()
　　set aRes to (aSet’s characterIsMember:strCode) as boolean
　　return aRes as list of string or string –as anything
end retGlyphsInFont

on selectAFont(aString)
　　set fRes to getEveryFontPSNameANdGlyphsNum(aString) of me
　　set theArray to NSArray’s arrayWithArray:fRes
　　set thePred to NSPredicate’s predicateWithFormat:"fontNum > 10000"
　　set bArray to ((theArray’s filteredArrayUsingPredicate:thePred)’s valueForKeyPath:"dispName") as list
　　set thisFont to choose from list bArray
　　return thisFont
end selectAFont

–Retina Display対応ルーチン
on getImageRatio()
　　set retinaF to detectRetinaDisplay() of me
　　if retinaF = true then
　　　　return 2.0 as real
　　else
　　　　return 1.0 as real
　　end if
end getImageRatio

on detectRetinaDisplay()
　　set dispList to current application’s NSScreen’s screens()
　　set retinaF to false
　　
　　repeat with i in dispList
　　　　set j to contents of i
　　　　set aDepth to j’s backingScaleFactor()
　　　　if aDepth > 1.0 then
　　　　　　set retinaF to true
　　　　end if
　　end repeat
　　
　　return retinaF
end detectRetinaDisplay

on makeNewDocument given parameter:aStr
　　tell application id "com.coteditor.CotEditor"
　　　　activate
　　　　set newDoc to make new document
　　　　tell newDoc
　　　　　　set contents to aStr
　　　　end tell
　　end tell
end makeNewDocument

★Click Here to Open This Script　

「戦場の絆」の日本国内の設置店舗数をカウント

Posted on 3月 3, 2019 by Takaaki Naganoya

アーケードゲーム「戦場の絆」が設置されている日本国内のゲームセンターの件数をカウントするAppleScriptです。

指定ページを取得し、本文内容をプレーンテキスト化して正規表現でデータ抽出して加算を行うという処理内容です。

部品がありきたりなので、新規作成部分はほとんどありません（メイン部分だけ）。

AppleScript名：戦場の絆の日本国内の設置店舗数をカウント.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/03
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSAttributedString : a reference to current application’s NSAttributedString
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSUnicodeStringEncoding : a reference to current application’s NSUnicodeStringEncoding

set aTotal to 0

–「戦場の絆」公式ページに掲載されている店舗一覧の都道府県別コード
set areaList to {"JP-01", "JP-02", "JP-03", "JP-04", "JP-05", "JP-06", "JP-07", "JP-08", "JP-09", "JP-10", "JP-11", "JP-12", "JP-13", "JP-14", "JP-15", "JP-16", "JP-17", "JP-18", "JP-19", "JP-20", "JP-21", "JP-22", "JP-23", "JP-24", "JP-25", "JP-26", "JP-27", "JP-28", "JP-29", "JP-30", "JP-31", "JP-32", "JP-33", "JP-34", "JP-35", "JP-36", "JP-37", "JP-38", "JP-39", "JP-40", "JP-41", "JP-42", "JP-43", "JP-44", "JP-45", "JP-46", "JP-47"}

–「戦場の絆」公式ページに掲載されている店舗一覧のBase URL
set baseURL to "https://gundam-kizuna.jp/locations/list"

–都道府県コードでループ
repeat with i in areaList
　　–店舗一覧の都道府県別ページをダウンロード
　　set j to contents of i
　　set aRec to {area:j}
　　set aRes to retURLwithParams(baseURL, aRec) of me
　　set shellText to "curl -s " & aRes
　　set htmlRes to (do shell script shellText)
　　set aPlainText to (HTMLDecode(htmlRes) of me)
　　
　　–店舗件数が入っている箇所を抽出して加算
　　set aList to paragraphs of aPlainText
　　set anArray to (NSArray’s arrayWithArray:aList)
　　set aPred to (NSPredicate’s predicateWithFormat:"SELF MATCHES ’[0-9]{1,3}件の店舗が見つかりました。’")
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　
　　if bRes is not equal to {} then
　　　　set a to repChar(contents of first item of bRes, "件の店舗が見つかりました。", "") of me
　　　　try
　　　　　　set aNum to a as integer
　　　　　　set aTotal to aTotal + aNum
　　　　on error
　　　　　　log {"Error in ", j}
　　　　end try
　　end if
end repeat

return aTotal
–> 622 (2019/3/3)

(*
set countryList to {"HKG", "TWN"}–香港と台湾の店舗のコード
set baseURL2 to "https://gundam-kizuna.jp/locations/list"
*)

–パラメータつきURLを作成
on retURLwithParams(aBaseURL as string, aRec as record)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　set bLen to length of aValList
　　if aLen is not equal to bLen then return false
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to (contents of item i of aKeyList) as string
　　　　set aVal to (contents of item i of aValList) as string
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

–テキストをHTMLとして解釈しプレーンテキスト化
on HTMLDecode(HTMLString)
　　set theString to NSString’s stringWithString:HTMLString
　　set theData to theString’s dataUsingEncoding:(current application’s NSUnicodeStringEncoding)
　　set attStr to NSAttributedString’s alloc()’s initWithHTML:theData documentAttributes:(missing value)
　　set aStr to attStr’s |string|()
　　return aStr as string
end HTMLDecode

–文字置換
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

★Click Here to Open This Script　

(POST) Google Translate APIで翻訳

Posted on 12月 10, 2018 by Takaaki Naganoya

Google Translate API（REST API）を呼び出して、指定のテキストを別の言語に翻訳するAppleScriptです。

Google Cloud Consoleにお持ちのGoogleアカウントでログインし、プロジェクトを作成して、プロジェクト用のAPIを個別に許可（この場合にはGoogle Translate API）し、API Keyを発行してScript中に記述して呼び出します（retAPIKeyハンドラ中にハードコーディングするのが嫌であれば、Keychainに登録して呼び出すことも可能です）。

処理内容自体は、REST API呼び出しのいつものやつなんでとくに解説はしません。コピペで作れるぐらい退屈で簡単です（本Scriptも呼び出せることを確認するだけして放置していました）。

ただ、本Scriptは同期処理用のNSURLConnectionを使って呼び出しているバージョンで、このNSURLConnectionが将来的に廃止される見込みなので、curlコマンドで呼び出すか、NSURLSessionを使って呼び出すように書き換えるか、といったところです。

単体だとただ翻訳できるだけで、あまり面白味はありません。本ScriptはMicrosoft Azure Computer Vision APIで画像認識を行なったときに、その画像認識テキストが英文で返ってきており、その内容を日本語に自動翻訳するときに使用してみました。翻訳精度は悪くないと思うのですが、画像のシーン認識テキストの英文がいまひとつだったので、「英文で出力してくれた方がまだわかりやすい」というところで、個人的にはあまり活躍していません。

Translate APIを売り物の本の翻訳に使うことが許可されていないなど、利用許諾が割と厳しいので使いどころが多そうに見えつつもそうでもない、といったところでしょうか。

AppleScript名：(POST) Google Translate APIで翻訳

— Created 2016-03-03 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSURLConnection : a reference to current application’s NSURLConnection
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

set aSentense to "a birthday cake with lit candles"
set bSentense to retTranslatedString("en", "ja", aSentense) of me
–> "キャンドルライト付きの誕生日ケーキ"–Japanese

set cSentense to retTranslatedString("en", "de", aSentense) of me
–> "eine Geburtstagstorte mit brennenden Kerzen"–Deutsch

on retTranslatedString(fromLang, toLang, aSentense)
　　set myAPIKey to retAPIKey() of me
　　set aRec to {|key|:myAPIKey, source:fromLang, |format|:"text", target:toLang, q:aSentense}
　　set aURL to "https://www.googleapis.com/language/translate/v2"
　　set bURL to retURLwithParams(aURL, aRec) of me
　　set aRes to callRestPOSTAPIAndParseResults(bURL) of me
　　
　　set aRESCode to responseCode of aRes
　　if aRESCode is not equal to 200 then return ""
　　set aRESHeader to responseHeader of aRes
　　set aRESTres to (translatedText of (first item of translations of |data| of json of aRes)) as string
　　return aRESTres
end retTranslatedString

–POST methodのREST APIを呼ぶ
on callRestPOSTAPIAndParseResults(aURL)
　　set aRequest to NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"POST"
　　aRequest’s setValue:"application/x-www-form-urlencoded" forHTTPHeaderField:"Content-Type"
　　
　　set aRes to NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to NSString’s alloc()’s initWithData:bRes encoding:(NSUTF8StringEncoding)
　　
　　set jsonString to NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestPOSTAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) –as text
　　
　　return aURL
end retURLwithParams

on retAPIKey()
　　return "XXxxXxXXXxXxX-XxXXxXXXxxxxXXXXxXxXXxXXX"
end retAPIKey

★Click Here to Open This Script　

teratailの指定IDのユーザー情報を取得する_curl

Posted on 11月 27, 2018 by Takaaki Naganoya

プログラミング系質問サイトteratailのREST APIを呼び出して、指定ユーザー名の情報を取得するAppleScriptです。

TeratailのREST APIは、タグ、ユーザー、質問の３ジャンルの情報取得を行えるように整備されており、特定カテゴリ（タグで分類）の新規質問が投稿されたかどうかを定期的に確認するようなAppleScriptを作って運用することもできます（そこまでやっていないですけれども）。

REST API呼び出しにはNSURLConnectionからNSURLSessionに移行していますが、どうもNSURLSessionだと呼び出せない（AppleScriptからの呼び出し処理が完了しない）サービスがあったりするので、結局shellのcurlコマンドを呼び出すのが手短にすむケースが多いようです。

Teratailの場合も、NSURLSessionで呼び出せるAPIもあれば、結果が返ってこないAPIもあり、NSURLConnectionよりも使い勝手がよくないと感じています（個人の感想です）。

このあたり、将来的なmacOSのアップデートでNSURLConnectionが使えなくなる日が来るのかもしれませんが、curlコマンドを使うように集約するべきなのか、NSURLSessionで書き換えるべきなのか悩ましいところです。

AppleScript名：teratailの指定IDのユーザー情報を取得する_curl

— Created 2018-11-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

set aUserRes to searchOneUserByDisplayName("Piyomaru") of me
–> {meta:{limit:20, message:"success", hit_num:1, total_page:1, page:1}, users:{{score:43, photo:"https://teratail.storage.googleapis.com/uploads/avatars/u6/66639/MSIS21by_thumbnail.jpg", display_name:"Piyomaru"}}}

on searchOneUserByDisplayName(aName)
　　set aRec to {q:aName}
　　set reqURLStr to "https://teratail.com/api/v1/users/search"
　　set bURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set tmpData to (do shell script "curl -X GET ＼"" & bURL & "＼"")
　　set jsonString to NSString’s stringWithString:tmpData
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　if aJsonDict = missing value then return false
　　return (aJsonDict as record)
end searchOneUserByDisplayName

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

NLLanguageRecognizerで自然言語の推定 v4

Posted on 11月 13, 2018 by Takaaki Naganoya

macOS 10.14であらたに搭載されたNaturalLanguage.frameworkにアクセスして、自然言語テキストが「何語」かを推定し、指定数の言語ごとにその推測した確率を求めるAppleScriptです。

NLLanguageRecognizerで、言語推定時に「言語Aと言語Bのみ考慮してね」と指定し、それぞれに数値による重み付け（0.0〜1.0）を指定できます。

ただ、重み付けを指定してもダメな時はダメなようで……日本語の文章に多めにアルファベットが入っている場合にはまったく日本語と判定されません。

AppleScript名：NLLanguageRecognizerで自然言語の推定 v4

— Created 2018-11-13 by Takaaki Naganoya
use AppleScript version "2.7" — Mojave (10.14) or later
use framework "Foundation"
use framework "NaturalLanguage"
use scripting additions

property NLLanguageEnglish : a reference to current application’s NLLanguageEnglish
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NLLanguageJapanese : a reference to current application’s NLLanguageJapanese
property NLLanguageRecognizer : a reference to current application’s NLLanguageRecognizer

set aNL to NLLanguageRecognizer’s alloc()’s init()

–言語ごとに可能性の重み付けを行って、言語推定

–言語推定の可能性ヒントデータを指定。日本語が99.9％、英語は0.1％の可能性として指定
set hintDict to NSMutableDictionary’s dictionaryWithObjects:{1.0E-3, 0.999} forKeys:{NLLanguageEnglish, NLLanguageJapanese}
–> (*(NSDictionary) {en:0.01, ja:0.99}*) –recordで作ってScriptingBridge経由でNSDictionaryに自動変換させてもよかったが、recordでは属性ラベルにハイフンなどは使えないのでこれでいいのだ
set hintRes3 to (aNL’s setLanguageHints:hintDict)

aNL’s processString:"AppleScriptで日本語を処理するよ。"
set langRes4 to (aNL’s languageHypothesesWithMaximum:2) as record
–> {en:1.0}– アルファベットの文字量が多いので、英語と判断されたよ！　（＞_＜）

aNL’s processString:"AppleScriptで日本語を処理するぴよ。"
set langRes5 to (aNL’s languageHypothesesWithMaximum:2) as record
–> {ja:1.0}– 「よ」を「ぴよ」に書き換えたら日本語の文字の量が増えて日本語と判定されたよ！　（＾ー＾）

★Click Here to Open This Script　

QuartzComoserでグラフ表示てすと v6

Posted on 11月 4, 2018 by Takaaki Naganoya

QuartzComposerのグラフに任意のデータを指定してウィンドウ表示するAppleScriptです。

スクリプトバンドル内の「Chart.qtz」を読み出して表示しているため、QuartzComposer入りのスクリプトバンドルを用意しておきましたので、ダウンロードしてお試しください。

–> Download qtc_disp_v6

オリジナルはControl＋Command＋Rで実行する必要がありましたが、本Scriptではその必要がありません。ちなみに、一般的なQuartzComposerのようにマウスでグリグリ回せるとかいうことはありません。パラメータを反映して静止画として表示されるだけです（Xcode上で作成したAppleScriptのGUIアプリケーションであれば、普通に回せます）。

macOS 10.14上で実行してみたところ、スクリプトエディタではCompositionが表示されませんでしたが、Script Debugger上で実行したかぎりでは実行されました。Framework宣言で足りないものがあるのでしょうか？

備考：QuartzComposerはmacOS 10.15でDeprecated扱いになりました

AppleScript名：QuartzComoserでグラフ表示てすと v6

— Created 2015-11-03 by Takaaki Naganoya
— Modified 2018-11-04 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "Quartz"
use framework "AppKit"

property NSColor : a reference to current application’s NSColor
property QCView : a reference to current application’s QCView
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property NSWindow : a reference to current application’s NSWindow
property NSNumber : a reference to current application’s NSNumber
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSMutableArray : a reference to current application’s NSMutableArray
property NSWindowController : a reference to current application’s NSWindowController
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSWindowCloseButton : a reference to current application’s NSWindowCloseButton
property NSNormalWindowLevel : a reference to current application’s NSNormalWindowLevel
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered

set chartData to NSMutableArray’s new()
chartData’s addObject:(my recWithLabels:{"label", "value"} andValues:{"練馬区", 3})
chartData’s addObject:(my recWithLabels:{"label", "value"} andValues:{"青梅市", 1})
chartData’s addObject:(my recWithLabels:{"label", "value"} andValues:{"中野区", 2})

my performSelectorOnMainThread:"dispQuartzComposerWindow:" withObject:(chartData) waitUntilDone:true

on dispQuartzComposerWindow:chartData
　　–上記データの最大値を求める
　　set aMaxRec to chartData’s filteredArrayUsingPredicate:(NSPredicate’s predicateWithFormat_("SELF.value == %@.@max.value", chartData))
　　set aMax to value of aMaxRec
　　set aMaxVal to (first item of aMax) as integer
　　
　　–Scalingの最大値を求める
　　if aMaxVal ≥ 10 then
　　　　set aScaleMax to (10 div aMaxVal)
　　　　set aScaleMin to aScaleMax div 10
　　else
　　　　set aScaleMax to (10 / aMaxVal)
　　　　set aScaleMin to 1
　　end if
　　
　　try
　　　　set aPath to path to resource "Chart.qtz"
　　on error
　　　　return
　　end try
　　
　　set qtPath to NSString’s stringWithString:(POSIX path of aPath)
　　
　　set aView to QCView’s alloc()’s init()
　　set qtRes to (aView’s loadCompositionFromFile:qtPath)
　　
　　aView’s setValue:chartData forInputKey:"Data"
　　aView’s setValue:(NSNumber’s numberWithFloat:(0.5)) forInputKey:"Scale"
　　aView’s setValue:(NSNumber’s numberWithFloat:(0.2)) forInputKey:"Spacing"
　　aView’s setAutostartsRendering:true
　　
　　set maXFrameRate to aView’s maxRenderingFrameRate()
　　
　　(aView’s setValue:(NSNumber’s numberWithFloat:aScaleMax / 10) forInputKey:"Scale")
　　
　　set aWin to (my makeWinWithView(aView, 800, 600, "AppleScript Composition Test"))
　　
　　set wController to NSWindowController’s alloc()
　　wController’s initWithWindow:aWin
　　aWin’s makeFirstResponder:aView
　　wController’s showWindow:me
　　
　　aWin’s makeKeyAndOrderFront:me
　　
　　delay 5
　　
　　my closeWin:aWin
　　aView’s stopRendering() –レンダリング停止
　　
end dispQuartzComposerWindow:

–make Window for Display
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　
　　set aBacking to NSTitledWindowMask
　　
　　set aDefer to NSBackingStoreBuffered
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　aWin’s setBackgroundColor:(NSColor’s whiteColor())
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSNormalWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　aWin’s makeKeyAndOrderFront:(me)
　　–aWin’s movableByWindowBackground:true
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　–Set Close Button　　
　　set closeButton to NSWindow’s standardWindowButton:(NSWindowCloseButton) forStyleMask:(NSTitledWindowMask)
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aWindow
　　repeat with n from 10 to 1 by -1
　　　　(aWindow’s setAlphaValue:n / 10)
　　　　delay 0.01
　　end repeat
　　aWindow’s |close|()
end closeWin:

on recWithLabels:theKeys andValues:theValues
　　return (NSDictionary’s dictionaryWithObjects:theValues forKeys:theKeys) as record
end recWithLabels:andValues:

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSMutableDictionary

AS書類を書式で分解して再構成

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定（v2）

NSURLSessionでREST API呼び出しv4.4.2a

NSURLSessionでREST API呼び出しv4.4.1

NSURLSessionでREST API呼び出しv4.4

WebKit Utilities v2

指定のフォントとサイズに該当するテキストを抽出する v3

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

（１）カレンダーの表示サイズを大型化

（２）選択無効日指定

（３）過去日付の選択無効

（４）曜日を現在のLocale情報から変更

指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

指定のAppleScriptテキストを構文確認して指定の構文要素が入っていないかチェック

Cocoa ObjectをキーにしたDictionaryから合致するObjectを取得

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

(POST) Google Translate APIで翻訳

teratailの指定IDのユーザー情報を取得する_curl

NLLanguageRecognizerで自然言語の推定 v4

QuartzComoserでグラフ表示てすと v6