Xcodeで編集中のAppleScriptのプログラムを構文確認（コンパイルと表記されている、構文チェックと中間コードへの変換チェック、省略表記の展開など）するAppleScriptです。
本ScriptはXcode 9.2＋macOS 10.12.6でテストしたものです。macOS 10.14＋Xcode 10.2で実行したところ、file documentのnameに「– Edited」という入っていてはいけない文字列が入っていたり（それはWindowのtitleであってdocumentのnameじゃないだろう、、、、）、AppleScriptからXcodeを（データ書き込み）操作するとXcodeがクラッシュしたりと、まともに動作していない印象です。
Xcode 10.1＋macOS 10.13.6で動かしたぶんには、Xcode上の表示は更新されていないものの、プロジェクト内の他のファイルをいったん表示させたあとに再度Scriptを表示させると書き換わっていました。Xcode 10.2＋macOS 10.14.4の組み合わせでおかしな動きを行なっているようです。
XcodeのテキストエディタはAppleScriptの構文色分けを反映して表示しませんし、編集中にコンパイル（構文確認）するための機能がありません。インデント合わせやtellブロックやifブロックのネスティングの確認なども行えないため、記述のための最低限の機能を備えておらず、まともにプログラムを書くのであればScript Debuggerの併用は必須といえます。
先日のmacOS Nativeのミーティングにて、プレーンテキストエディタであるCotEditor上に記述したテキストのAppleScriptをコンパイル（構文確認）し、実際に実行して結果をCotEditor上の新規書類に出力するデモを実施。
このデモ内容は、はるかかなた昔から行なってきたものであり、CotEditorにかぎらず、あまねくどんなテキストエディタに対しても実行できるものです。macOS標準搭載のテキストエディットに対してすら同様のScriptを実行できます。
……と、振り返っていたときに、冒頭の「機能が致命的に足りない」Xcodeのテキストエディタのことを思い出したのです。
Xcodeのテキストエディタは（AppleScriptにとっては）致命的に機能が足りない欠陥品ですが、欠陥品には欠陥品なりの扱いをすればよいのではないかと気づきました。Xcodeに対してAppleScriptを実行することで、ソースを取得し、AppleScriptでAppleScriptをコンパイルし、Xcodeに書き戻してやればよいのではないか、と。
ずいぶんと昔に書いたXcode操作のScriptに若干のルーチンを足して動かしてみたところ、想像どおりうまく動きました。
ただし、少々のテストを行なっただけなので、実際にもっと使い込んでみる必要性を感じます。また、Xcode側が不可思議な挙動を行うため、Xcode上でAppleScriptを記述する場合には、依然としてScript Debugger必須です。
ちなみに、XcodeのAppleScriptサポート機能はいまひとつ不思議な挙動を行います。tellブロックでオブジェクト（documentとか）をくくり、その内側でオブジェクトに対する操作を行おうとするとエラー。tellブロックを正常に認識せず、tellブロック内でもそのオブジェクトへの参照を「of it」のように書く必要があります（実は、CotEditorもこのタイプ）。
最近、そのような不思議な挙動を行うアプリケーションがいくつか見られたため、「はいはい。君はof itが必要な人なんだね」と乗り切りましたが、これに気づかないと永遠にXcodeのまともなScriptは書けません。要注意です。
| AppleScript名：最前面のAS sourceを構文確認.scptd |
— Created 2018-05-19 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "OSAKit"
property OSAScript : a reference to current application’s OSAScript
property OSALanguage : a reference to current application’s OSALanguage
property OSALanguageInstance : a reference to current application’s OSALanguageInstance
property targX : 1024 –View Width
property targY : 2048 –View Height
tell application "Xcode"
–最前面のWindowの情報を取得
set winProp to properties of front window
set aDoc to document of winProp –Xcode のworkspace document（xcodeproj）
–> workspace document "WKWebViewDemo.xcodeproj" of application "Xcode"
set docProp to properties of aDoc
set xcodeDocPath to path of docProp
–> "/Users/me/Documents/Objective-C/WKWebViewDemo_MAC-master/WKWebViewDemo.xcodeproj"
set aFileDoc to name of winProp
–> "ViewController.m"
try
set aDoc to file document aFileDoc
–> source document "ViewController.m" of application "Xcode"
on error
–Storyboard/Xib file/info.plist/Assetsなどを表示中の場合にはエラーになる
return false
end try
set aDocPath to path of aDoc
–> "/Users/me/Documents/Objective-C/WKWebViewDemo_MAC-master/WKWebViewDemo/ViewController.m"
end tell
if aDocPath does not end with ".applescript" then
display notification "Front Xcode document does not seem an AppleScriptObjC source"
return
end if
set theSource to read ((POSIX file aDocPath) as alias) as «class utf8»
set aRes to retComiledAppleScriptString(theSource, "AppleScript") of me
tell application "Xcode"
tell aDoc
set text of it to aRes
end tell
end tell
–Compile AppleScript Source
on retComiledAppleScriptString(aStr as string, osalangName as string)
set osaCon to current application’s OSAScriptController’s alloc()’s init()
set osaView to current application’s OSAScriptView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, targX, targY))
osaCon’s setScriptView:osaView
osaCon’s setLanguage:(OSALanguage’s languageForName:osalangName)
osaView’s setString:aStr
osaCon’s compileScript:(missing value) –Compile（構文確認）
set aRes to (osaView’s |string|()) as string
return aRes
end retComiledAppleScriptString
|
|
★Click Here to Open This Script
|
