クリップボードに入れたIllustratorのオブジェクトをQRコード認識 v2

Posted on 7月 28, 2019 by Takaaki Naganoya

Adobe Illustrator書類上にある、QRコードのオブジェクトをクリップボード経由でNSImageに変換してQRコード認識するAppleScriptです。QRコード認識には、OS内蔵のCoreImageの機能を使っています。

＃　実行前にAI書類上のQRコードオブジェクトを選択してコピー（Command-C）を実行してあることを前提条件としています。QRコードっぽいものであれば、別にAI書類上のオブジェクトでなくてもかまいません

昨日のScriptで、「そういえばなんでZXingObjCを使っているんだっけ？」と疑問を抱きました。理由ははっきりしています。CIDetectorではそのまま認識させてみたら認識しなかったためです。

QRコードやJANコード画像認識ソフトウェアは、割といろいろ条件がそろわないと認識してくれません。いわく、画像の大きさ、画像の解像度、画像の向き、コントラスト比、その他いろいろ。

スマホのカメラで認識する際にはユーザーが認識するまでいろいろ条件を変えて試行錯誤するので、ソフトウェアの力だけで認識させているわけではありません。いわば、人間をスマホの周辺機器として使用している状態です。

一方、静止画をソフトウェアで認識処理するさいには、人間が行っているフィードバック動作をソフトウェア側で行わなくてはなりません。

macOS内蔵のCIDetectorは、どうやら画像サイズに敏感なようで、いろいろリサイズして認識するかどうかチェックしなくてはなりません。逆に、最初からQRコードではないとわかっている画像を、しつこくQRコード認識し直しても時間の無駄です。

とりあえず、認識対象を2倍から4倍まで拡大して認識をリトライしています。実際にやってみたら、1倍では認識しなくても2倍で認識してくれました。実際に処理するデータ次第ですが、4倍まで試さなくても大丈夫なケースも多いことでしょう。

AppleScript名：rocogClipAsQR_v2.scptd

— Created 2019-07-28 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "CoreImage"

property CIImage : a reference to current application’s CIImage
property NSImage : a reference to current application’s NSImage
property CIDetector : a reference to current application’s CIDetector
property NSZeroRect : a reference to current application’s NSZeroRect
property NSDictionary : a reference to current application’s NSDictionary
property NSPasteboard : a reference to current application’s NSPasteboard
property NSCompositeCopy : a reference to current application’s NSCompositeCopy
property NSGraphicsContext : a reference to current application’s NSGraphicsContext
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property CIDetectorAccuracy : a reference to current application’s CIDetectorAccuracy
property CIDetectorTypeQRCode : a reference to current application’s CIDetectorTypeQRCode
property CIDetectorAccuracyHigh : a reference to current application’s CIDetectorAccuracyHigh
property NSImageInterpolationNone : a reference to current application’s NSImageInterpolationNone
property CIDetectorImageOrientation : a reference to current application’s CIDetectorImageOrientation
property NSCalibratedRGBColorSpace : a reference to current application’s NSCalibratedRGBColorSpace

set aRes to recogPasteboardASQR() of me

–クリップボードの内容をNSImageに
on recogPasteboardASQR()
　　set aNSIMage to getClipboardASImage() of me
　　if aNSIMage = false then return false
　　
　　set aRes to recogNSImageAsQRcodes(aNSIMage) of me –11: kBarcodeFormatQRCode
　　if aRes is not equal to {} then return aRes
　　
　　–ループでQRコードとおぼしきイメージを拡大しつつQRコード認識
　　repeat with i from 2 to 4 –ここはチューニングの余地がある
　　　　set bNSIMage to (my resizeNSImageWithoutAntlialias:aNSIMage toScale:(i as real))
　　　　set aRes to recogNSImageAsQRcodes(bNSIMage) of me
　　　　if aRes is not equal to {} then return aRes
　　end repeat
　　
　　return false
end recogPasteboardASQR

–NSImageをバーコードとして認識する
on recogNSImageAsQRcodes(aNSIMage)
　　set imageRef to convNSImageToCIimage(aNSIMage) of me
　　
　　— 検出器のオプションを NSDictonary で作成
　　set optDic1 to NSDictionary’s dictionaryWithObject:(CIDetectorAccuracyHigh) forKey:(CIDetectorAccuracy)
　　set faceDetector to CIDetector’s detectorOfType:(CIDetectorTypeQRCode) context:(missing value) options:optDic1
　　
　　— QRコードの検出を行う際のオプションを NSDictonary で作成
　　set optDic2 to NSDictionary’s dictionaryWithObject:(CIDetectorImageOrientation) forKey:"Orientation"
　　
　　— QRコード検出を実行
　　set faceArray to faceDetector’s featuresInImage:imageRef options:optDic2
　　set fList to {}
　　
　　— 検出されたQRコードの位置とサイズをログに出力
　　repeat with i from 1 to (count of faceArray)
　　　　set face to item i of faceArray
　　　　set bRec to (face’s messageString()) as string
　　　　–set cRec to retURLdecodedStrings(bRec) of me –URLエンコード対策
　　　　set the end of fList to bRec
　　end repeat
　　
　　return fList
end recogNSImageAsQRcodes

— クリップボードの内容をNSImageとして取り出して返す
on getClipboardASImage()
　　set theNSPasteboard to NSPasteboard’s generalPasteboard()
　　set anArray to theNSPasteboard’s readObjectsForClasses:({NSImage}) options:(missing value)
　　if anArray = missing value or (anArray as list) = {} then return false
　　set aRes to anArray’s objectAtIndex:0
　　return aRes
end getClipboardASImage

—
on convNSImageToCIimage(aNSIMage)
　　set tiffDat to aNSIMage’s TIFFRepresentation()
　　set aRep to NSBitmapImageRep’s imageRepWithData:tiffDat
　　set newImg to CIImage’s alloc()’s initWithBitmapImageRep:aRep
　　return newImg
end convNSImageToCIimage

–NSImageを指定倍率で拡大（アンチエイリアス解除状態で）
on resizeNSImageWithoutAntlialias:aSourceImg toScale:imgScale
　　set aSize to aSourceImg’s |size|()
　　set aWidth to (aSize’s width) * imgScale
　　set aHeight to (aSize’s height) * imgScale
　　
　　set aRep to NSBitmapImageRep’s alloc()’s initWithBitmapDataPlanes:(missing value) pixelsWide:aWidth pixelsHigh:aHeight bitsPerSample:8 samplesPerPixel:4 hasAlpha:true isPlanar:false colorSpaceName:(NSCalibratedRGBColorSpace) bytesPerRow:0 bitsPerPixel:0
　　
　　set newSize to {width:aWidth, height:aHeight}
　　aRep’s setSize:newSize
　　
　　NSGraphicsContext’s saveGraphicsState()
　　
　　set theContext to NSGraphicsContext’s graphicsContextWithBitmapImageRep:aRep
　　NSGraphicsContext’s setCurrentContext:theContext
　　theContext’s setShouldAntialias:false
　　theContext’s setImageInterpolation:(NSImageInterpolationNone)
　　
　　aSourceImg’s drawInRect:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) fromRect:(NSZeroRect) operation:(NSCompositeCopy) fraction:(1.0)
　　
　　NSGraphicsContext’s restoreGraphicsState()
　　
　　set newImg to NSImage’s alloc()’s initWithSize:newSize
　　newImg’s addRepresentation:aRep
　　
　　return newImg
end resizeNSImageWithoutAntlialias:toScale:

★Click Here to Open This Script　

(Visited 109 times, 1 visits today)

クリップボードに入れたIllustratorのオブジェクトをQRコード認識

Posted on 7月 27, 2019 by Takaaki Naganoya

Adobe Illustrator書類上にある、QRコードのオブジェクトをクリップボード経由でNSImageに変換してQRコード認識するAppleScriptです。QRコード認識には、オープンソースのZXingObjCをCocoa Framework化したものを使っています。

–> Download recogClipAsQR.scptd (Including Framework)

ことのはじまりは、Adobe Illustrator書類上になにがしかのプラグインで作成されたとおぼしきQRコードのオブジェクトが配置されていたことです。これをデコードして内容が正しいか、デコードしたURLは実在するものかといったチェックをする必要がありました（もっと大きなプログラムの一部として）。

これはけっこうな難問でした。AI書類全体をPDFや他の形式の画像として書き出したものを認識させてみたものの、なかなかQRコードとして認識してくれません。

いろいろ試行錯誤していくうちに、AI書類を構成する各部品ごとに画像書き出しして認識させると、QRコードとして認識したりしました。

結局、AI書類上の各種オブジェクト（QRコードはグループ化されていたので、group item）にアクセスし、クリップボード経由で（いったんコピーして）画像に書き出すと認識してくれました。

ファイルに書き出すオーバーヘッドを減らしたかったので、クリップボードの内容をそのままNSImageとして取得。ここで、AppleScriptの標準搭載命令（the clipboard）からCocoaのNSPasteBoardを使うように変更したことで、大幅なスピードアップを図れました。クリップボード経由でデータ変換するやりかたは、データが小さければ手軽かつ便利でいいのですが、データが大きくなると処理に時間がかかってたいへんです。主にClassic Mac OSの時代によく使われていた方法でもあります（macOS上でもごくたまに使いますが、こういうやり方をなくそうというのがClassic Mac OSからMac OS Xへの移行時のScripter間の共通認識だったので、なるべく避けていたんですね）。

かくして、Adobe Illustrator上でコピーしておいたQRコードのオブジェクトを、クリップボード（ペーストボード）経由でQRコードとしてデコードするものができ、便利に使っています。

本Scriptは、

macOS 10.12.x：スクリプトエディタ、Script Debugger
macOS 10.13.x：スクリプトエディタ、Script Debugger
macOS 10.14.x：Script Debugger、マシンのSIPを解除してあればスクリプトエディタ上でも動作

という環境で動作します。macOS 10.14.x上でSIPを解除していない状態でも、アプレット書き出しした状態であればバンドル内のFrameworkを読み込んで動作します。

AppleScript名：recogClipAsQR.scptd

— Created 2019-07-20 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "ZXingObjC" –https://github.com/TheLevelUp/ZXingObjC

property NSImage : a reference to current application’s NSImage
property NSPasteboard : a reference to current application’s NSPasteboard
property ZXDecodeHints : a reference to current application’s ZXDecodeHints
property ZXBinaryBitmap : a reference to current application’s ZXBinaryBitmap
property ZXHybridBinarizer : a reference to current application’s ZXHybridBinarizer
property ZXMultiFormatReader : a reference to current application’s ZXMultiFormatReader
property ZXCGImageLuminanceSource : a reference to current application’s ZXCGImageLuminanceSource

set qrRes to recogClipboardASQR() of me
–> {"http://xxxxxxxxxxxxxxxxxxx", 11}

–クリップボードの内容をNSImageに
on recogClipboardASQR()
　　set aNSIMage to my getClipboardASImage()
　　if aNSIMage = false then return false
　　set aRes to recogNSIMageAsBarcodes(aNSIMage, 11) of me –11: kBarcodeFormatQRCode
　　return aRes
end recogClipboardASQR

–NSImageをQRコードとして認識する
on recogNSIMageAsBarcodes(aNSIMage, aHintType)
　　set aSource to ZXCGImageLuminanceSource’s alloc()’s initWithNSImage:(aNSIMage)
　　set aBitmap to ZXBinaryBitmap’s binaryBitmapWithBinarizer:(ZXHybridBinarizer’s binarizerWithSource:(aSource))
　　
　　–https://github.com/zxingify/zxingify-objc/blob/master/ZXingObjC/core/ZXBarcodeFormat.h
　　set aHints to ZXDecodeHints’s hints()
　　aHints’s addPossibleFormat:(aHintType)
　　
　　set aReader to ZXMultiFormatReader’s reader()
　　set aResult to aReader’s decode:(aBitmap) hints:(aHints) |error|:(missing value)
　　
　　if aResult is equal to missing value then return false
　　set aCon to (aResult’s |text|()) as string
　　set aFormat to aResult’s barcodeFormat()
　　
　　return {aCon, aFormat}
end recogNSIMageAsBarcodes

★Click Here to Open This Script　

(Visited 303 times, 1 visits today)

Keynoteスライドの末尾にQRコードのスライドを追加

Posted on 5月 17, 2018 by Takaaki Naganoya

指定の連絡先情報のQRコード画像を作成して、現在オープン中のKeynoteのスライドの末尾に追加するAppleScriptです。

–> Watch Demo Movie

このAppleScriptでは、ただ固定の文字列をQRコード画像化していますが、Contacts（連絡先）から自分の連絡先の情報を取得して、そこからQRコード画像を作成すると、より「AppleScriptらしい」自動処理になると思います。

さらに、このKeynoteのスライドからPDFを書き出して、Slide Shareに自動アップロードし、そのURLもQRコード画像の中に入れると文句のつけようがありません。

AppleScriptによる自動化で「単なる１つのコマンドをScriptから呼び出すだけ」のものを大量に見かけますが、それだとほとんど意味がありません。複数のアプリケーションや複数のサービスを呼び出してそれらを連携させてはじめて「自動化する意味がある」内容になります。

AppleScript名：Keynoteスライドの末尾にQRコードのスライドを追加

— Created 2018-05-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "QuartzCore"

–QRCodeを作成
set a to "MEMORY:Piyomaru Software
NAME1:長野谷隆昌
NAME2:ながのや　たかあき
TEL1:080-xxxx-xxxxx
MAIL1:maro@piyocast.com
TEL2:080-xxxx-xxxxx
MAIL2:maro@xxxxxxxxx
MECARD:N:長野谷,隆昌;SOUND:ながのや,たかあき;TEL:080-9999-9999;TEL:03-9999-9999;EMAIL:maro@piyocast.com;EMAIL:maro@xxxxx.xxxxx;NOTE:ぴよまる;;"

set savedPath to makeQRCodeImageOnDesktop(a) of me
set savedFile to (POSIX file savedPath)
set savedAlias to savedFile as alias

tell application "Keynote"
　　tell front document
　　　　set endSlide to make new slide at end
　　　　
　　　　set blankMaster to master slide "空白" –"Blank" in Japanese. This string is *localized*
　　　　
　　　　tell endSlide
　　　　　　set base slide to blankMaster
　　　　　　set thisImage to make new image with properties {file:savedAlias}
　　　　end tell
　　end tell
end tell

do shell script "rm -f " & quoted form of savedPath

on makeQRCodeImageOnDesktop(aData)
　　set aStr to current application’s NSString’s stringWithString:aData
　　set strData to aStr’s dataUsingEncoding:(current application’s NSShiftJISStringEncoding) –シフトJISにエンコード
　　set qrFilter to current application’s CIFilter’s filterWithName:"CIQRCodeGenerator"
　　qrFilter’s setValue:strData forKey:"inputMessage"
　　qrFilter’s setValue:"H" forKey:"inputCorrectionLevel"
　　set anImage to qrFilter’s outputImage()
　　
　　set convImg to convCIimageToNSImage(anImage) of me
　　
　　–NSImageを拡大（アンチエイリアス解除で）
　　set resizedImg to my resizeNSImageWithoutAntlialias:convImg toScale:6.0
　　
　　–デスクトップに保存
　　set aDesktopPath to (current application’s NSProcessInfo’s processInfo()’s environment()’s objectForKey:("HOME"))’s stringByAppendingString:"/Desktop/"
　　set savePath to aDesktopPath’s stringByAppendingString:((current application’s NSUUID’s UUID()’s UUIDString())’s stringByAppendingString:".png")
　　saveNSImageAtPathAsPNG(resizedImg, savePath) of me
　　
　　return savePath as string
end makeQRCodeImageOnDesktop

on convCIimageToNSImage(aCIImage)
　　set aRep to current application’s NSBitmapImageRep’s alloc()’s initWithCIImage:aCIImage
　　set tmpSize to aRep’s |size|()
　　set newImg to current application’s NSImage’s alloc()’s initWithSize:tmpSize
　　newImg’s addRepresentation:aRep
　　return newImg
end convCIimageToNSImage

on convNSImageToCIimage(aNSImage)
　　set tiffDat to aNSImage’s TIFFRepresentation()
　　set aRep to current application’s NSBitmapImageRep’s imageRepWithData:tiffDat
　　set newImg to current application’s CIImage’s alloc()’s initWithBitmapImageRep:aRep
　　return newImg as string
end convNSImageToCIimage

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to current application’s NSBitmapImageRep’s imageRepWithData:imageRep
　　set pathString to current application’s NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　set myNewImageData to (aRawimg’s representationUsingType:(current application’s NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

–NSImageを指定倍率で拡大（アンチエイリアス解除状態で）–By Shane Stanley
on resizeNSImageWithoutAntlialias:aSourceImg toScale:imgScale
　　set aSize to aSourceImg’s |size|()
　　set aWidth to (aSize’s width) * imgScale
　　set aHeight to (aSize’s height) * imgScale
　　
　　set aRep to current application’s NSBitmapImageRep’s alloc()’s initWithBitmapDataPlanes:(missing value) pixelsWide:aWidth pixelsHigh:aHeight bitsPerSample:8 samplesPerPixel:4 hasAlpha:true isPlanar:false colorSpaceName:(current application’s NSCalibratedRGBColorSpace) bytesPerRow:0 bitsPerPixel:0
　　
　　set newSize to {width:aWidth, height:aHeight}
　　aRep’s setSize:newSize
　　
　　current application’s NSGraphicsContext’s saveGraphicsState()
　　
　　set theContext to current application’s NSGraphicsContext’s graphicsContextWithBitmapImageRep:aRep
　　current application’s NSGraphicsContext’s setCurrentContext:theContext
　　theContext’s setShouldAntialias:false
　　theContext’s setImageInterpolation:(current application’s NSImageInterpolationNone)
　　
　　aSourceImg’s drawInRect:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) fromRect:(current application’s NSZeroRect) operation:(current application’s NSCompositeCopy) fraction:(1.0)
　　
　　current application’s NSGraphicsContext’s restoreGraphicsState()
　　
　　set newImg to current application’s NSImage’s alloc()’s initWithSize:newSize
　　newImg’s addRepresentation:aRep
　　
　　return newImg
end resizeNSImageWithoutAntlialias:toScale:

★Click Here to Open This Script　

(Visited 626 times, 1 visits today)

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: QR Code

クリップボードに入れたIllustratorのオブジェクトをQRコード認識

Keynoteスライドの末尾にQRコードのスライドを追加