マンデルブロ集合を文字で描画してRTFとして組み立ててテキストエディットでオープン

Posted on 8月 6 by Takaaki Naganoya

マンデルブロ集合を文字で組み立てて、デスクトップフォルダにRTF形式で保存して、テキストエディットでオープンして表示するAppleScriptです。

Courier Newはどの環境にも入っているフォントだと思っていますが、ない場合には別の等幅フォントのPostScript名に変更してください。また、フォントサイズや描画色を変更してみるといいかもしれません。

ちなみに、実用性はまっっっっったくありません。昔は計算に数分かかったのに、いまだとインタプリタ型の言語で動かしても1秒以下なんだ、へーという納得ができる程度です。

AppleScript名：マンデルブロ集合を描画してRTFとして組み立ててテキストエディットでオープン.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/08/06
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—
use AppleScript
use framework "Foundation"
use framework "AppKit"
use scripting additions

set outStr to generateMandel() of me
set anAssrStr to makeRTFfromParameters(outStr, "CourierNewPSMT", 12) of me

–結果のRTFをデスクトップ上に書き出す。ファイル名はUUID.rtf
set thePath to (POSIX path of (path to desktop)) & (do shell script "uuidgen") & ".rtf"
set aRes to my saveStyledTextAsRTF(thePath, anAssrStr)

set targAlias to (POSIX file (thePath as string)) as alias

tell application "TextEdit"
　　activate
　　open targAlias
end tell

–スタイル付きテキストを指定パス（POSIX path）にRTFで書き出し
on saveStyledTextAsRTF(targPath, aStyledString)
　　set targPathNSString to NSString’s stringWithString:targPath
　　set bstyledLength to aStyledString’s |string|()’s |length|()
　　set bDict to NSDictionary’s dictionaryWithObject:"NSRTFTextDocumentType" forKey:(NSDocumentTypeDocumentAttribute)
　　set bRTF to aStyledString’s RTFFromRange:(current application’s NSMakeRange(0, bstyledLength)) documentAttributes:bDict
　　return (bRTF’s writeToFile:targPath atomically:true) as boolean
end saveStyledTextAsRTF

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, aFontName as string, aFontSize as real)
　　set aVal1 to NSFont’s fontWithName:aFontName |size|:aFontSize
　　set aKey1 to (current application’s NSFontAttributeName)
　　
　　set aVal2 to NSColor’s cyanColor()
　　set aKey2 to (current application’s NSForegroundColorAttributeName)
　　
　　set aVal3 to 0.0
　　set akey3 to (current application’s NSKernAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3}
　　set valList to {aVal1, aVal2, aVal3}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–マンデルブロ集合を文字で描画して返す
on generateMandel()
　　set outStr to ""
　　
　　repeat with y from -12 to 12 by 1
　　　　
　　　　repeat with x from -39 to 39 by 1
　　　　　　
　　　　　　set ca to x * 0.0458
　　　　　　set cb to y * 0.08333
　　　　　　
　　　　　　set a to ca
　　　　　　set b to cb
　　　　　　
　　　　　　repeat with i from 0 to 15 by 1
　　　　　　　　set t to (a * a) – (b * b) + ca
　　　　　　　　set b to (2 * a * b) + cb
　　　　　　　　
　　　　　　　　set a to t
　　　　　　　　
　　　　　　　　if ((a * a) + (b * b)) > 4 then exit repeat
　　　　　　end repeat
　　　　　　
　　　　　　
　　　　　　if ((a * a) + (b * b)) ≤ 4 then
　　　　　　　　set outStr to outStr & " "
　　　　　　else
　　　　　　　　if i > 9 then set i to i + 7
　　　　　　　　set outStr to outStr & string id (48 + i)
　　　　　　end if
　　　　　　
　　　　end repeat
　　　　
　　　　set outStr to outStr & return
　　end repeat
　　
　　return outStr
end generateMandel

★Click Here to Open This Script　

NSAttributedStringにtab指定つきparagraph styleを指定

Posted on 12月 31, 2021 by Takaaki Naganoya

書式付きテキスト（NSAttributedString）にパラグラフスタイルを指定して、tab指定を行い、tab展開を行うテストです。

Keynote/Pagesなどのテキストアイテムで、中にタブを含むスタイル付きテキストだった場合に、スタイル付きテキストの幅を計算したら大きな誤差が生じていたため、タブを展開して近似するサイズを取得できないかと考え、試してみたものです。

いまひとつ、まだしっくり来ていません。

AppleScript名：Attributed Stringにparagraph styleを指定してtab指定.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/12/27
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aStr to "Piyomaru Software　　100　　200　　10　　20"
set anAssrStr to makeRTFfromParameters(aStr, 3.0, 16, "HelveticaNeue") of me

set aTabStops to {90, 400, 500, 600, 700}
set aStyle to makeParagraphStyle(aTabStops) of me

anAssrStr’s addAttribute:(current application’s NSParagraphStyleAttributeName) value:aStyle range:(current application’s NSMakeRange(0, (anAssrStr’s |length|())))
return anAssrStr

–Make Paragraph Style
on makeParagraphStyle(tList as list)
　　set tabList to {}
　　repeat with i in tList
　　　　set the end of tabList to (current application’s NSTextTab’s alloc()’s initWithTextAlignment:(current application’s NSTextAlignmentLeft) location:i options:(missing value))
　　end repeat
　　
　　set aParagraphStyle to (current application’s NSParagraphStyle’s defaultParagraphStyle())’s mutableCopy()
　　aParagraphStyle’s setTabStops:tabList
　　return aParagraphStyle
end makeParagraphStyle

–Make Attributed String
on makeRTFfromParameters(aStr as string, outlineNum as real, aFontSize as real, aFontName as string)
　　set aVal1 to current application’s NSFont’s fontWithName:aFontName |size|:aFontSize
　　set aKey1 to (current application’s NSFontAttributeName)
　　set aVal2 to current application’s NSColor’s redColor()
　　set aKey2 to (current application’s NSForegroundColorAttributeName)
　　set aVal3 to 1.0
　　set akey3 to (current application’s NSKernAttributeName)
　　set aVal4 to 0
　　set akey4 to (current application’s NSUnderlineStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4}
　　set valList to {aVal1, aVal2, aVal3, aVal4}
　　set attrsDictionary to current application’s NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to current application’s NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

★Click Here to Open This Script　

Pagesのテキストアイテム内の文字の実際の幅でリサイズ

Posted on 12月 25, 2021 by Takaaki Naganoya

Pagesでオープン中の最前面の書類の上に載っている（Pagesの仕様でページ指定はできない）テキストアイテムから、テキスト、フォント、フォントサイズを取得し、その内容でスタイル付きテキストを作成して画面上に描画するサイズを取得し、その幅でテキストアイテムをリサイズするAppleScriptです。

macOS 12.2beta＋Pages 11.2で動作確認しています。

▲処理前（内容は妄想にもとづくもので、本物ではありません）

▲処理後（内容は妄想にもとづくもので、本物ではありません）

Pages上のタブの指定までスタイル付きテキスト内で再現できていないためか、中身の幅よりも外側のテキストアイテム（枠）が小さくなってしまうケースが見られますが、もう少し枠のリサイズを余裕を持って（大きめに）指定すると回避できます。

AppleScript名：Pagesのテキストアイテム内の文字の実際の幅でリサイズ

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/12/25
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSString : a reference to current application’s NSString
property NSDictionary : a reference to current application’s NSDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName

tell application "Pages"
　　tell front document
　　　　set tList to every text item
　　　　if tList = {} then return
　　　　
　　　　repeat with i in tList
　　　　　　set j to contents of i
　　　　　　
　　　　　　tell j
　　　　　　　　set tmpFontName to font of its object text
　　　　　　　　set tmpFontSize to size of its object text
　　　　　　　　set tmpText to (its object text as string) & "　"
　　　　　　　　
　　　　　　　　set aSize to getSizeFromAttributedText(tmpText, tmpFontName, tmpFontSize) of me
　　　　　　　　set aWidth to |width| of aSize
　　　　　　　　set bWidth to aWidth + 10
　　　　　　　　
　　　　　　　　set its width to bWidth
　　　　　　end tell
　　　　　　
　　　　end repeat
　　end tell
end tell

–指定のテキスト、フォント名、フォントサイズでAttributed Stringを組み立ててサイズを取得する
on getSizeFromAttributedText(aText as string, aFont as string, aFSize as real)
　　set aFont to NSFont’s fontWithName:aFont |size|:aFSize
　　set aStr to NSString’s stringWithString:aText
　　set aSize to aStr’s sizeWithAttributes:(NSDictionary’s dictionaryWithObjects:{aFont} forKeys:{NSFontAttributeName})
　　return aSize
end getSizeFromAttributedText

★Click Here to Open This Script　

FileMaker Proのテキストフィールドにスタイル付きテキストを代入

Posted on 1月 5, 2021 by Takaaki Naganoya

FileMaker Proのテキストフィールドにスタイル付きテキストを代入するAppleScriptです。

FileMaker Proには、v4の頃からかわらないとてもユニークな特徴があります。それは、テキストフィールドに書式つきテキストを突っ込めることです。こんなことができるデータベースは他に類を見ません。

＃　書式付きテキストのほかに書式を持たないシャドーフィールドでも持たせているんじゃないかと推測

スタイル付きテキストについては、ワープロなどのソフトウェアを併用して作成する方法もありますが、AppleScriptだけで作成できれば、FileMaker Proのスクリプトステップ内に突っ込むことができて便利です。

ただし、当のAppleScript自体のスタイル付きテキストの作成能力に関しては昔から残念なレベルでした（Classic MacOS時代にはOSAXで作れたような気も）。風向きが変わってきたのは、macOS 10.10でCocoa呼び出しがすべてのランタイム環境で使えるようになったあたりです。当然、FileMaker Proのスクリプトステップ内でも呼べるようになっていました。

残念なことにmacOS 10.10登場当時、FileMaker Proが32ビットアプリケーションだったため、FileMaker Proのスクリプトステップ「AppleScriptを実行」の中で呼び出せるFrameworkも32ビットに限られていました。Cocoa Frameworkの多くは32bitアプリケーションからも呼び出せるようになっていましたが、そうでないものも多々ありました。

FileMaker Pro v12で64ビット化され、中に記述したAppleScriptからも64bit Frameworkを呼べるようになりました。

本Scriptはあくまでも実験的なものですが、AppleScriptからCocoaの機能を呼び出して自由にスタイル付きテキストを作成し、それをクリップボード経由でFileMaker Pro側に受け渡します。FileMaker Pro側では指定のフィールドに対してクリップボードの内容を「貼り付け」コマンドで代入します。

▲指定フォント、指定サイズ、指定テキストでスタイル付きテキストを生成してフィールドに代入

▲FileMaker Pro側にクリップボードから内容を受け取ってフィールドに入れるFileMaker Script

代入先のフィールド名については、FileMaker Proのスクリプト呼び出しをAppleScriptの「do script」コマンド経由で行う場合には、パラメータの指定ができないため、一切指定できません。

……ただし、AppleScriptからURL Event経由でもFileMaker Pro側のスクリプト実行ができ、その場合にはパラメータの受け渡しができます。そのため、URL Event経由で呼び出せば「クリップボードに入っているスタイル付きテキストの受け渡し先フィールド名」を随時指定することも可能です。

＃　FileMaker Proのdo scriptコマンドに素直にパラメータを受け渡す機能を付けてほしい

そろそろFileMaker Proのお試し版の期限が切れるので、FileMaker Pro関連のScriptingのまとまった情報について本Blog上への投稿は行えません。まとまった情報については、電子ブック新刊「FileMaker Pro Scripting Book」（予定）をお買い求めください。

AppleScript名：テキストフィールドにスタイル付きテキスト.scpt

— Created 2020-12-29 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set attrStr to makeRTFfromParameters("ぴよまるソフトウェアだよーーん", 3.0, 72) of me
(my restoreClipboard:{attrStr})

tell application "FileMaker Pro"
　　tell database 1
　　　　do script "getAttrFromClipboard" –クリップボードの内容をtextFieldにペーストする
　　end tell
end tell

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, outlineNum as real, aFontSize as real)
　　–フォント
　　set aVal1 to current application’s NSFont’s fontWithName:"HiraKakuStdN-W8" |size|:aFontSize
　　set aKey1 to (current application’s NSFontAttributeName)
　　
　　–色
　　set aVal2 to current application’s NSColor’s blackColor()
　　set aKey2 to (current application’s NSForegroundColorAttributeName)
　　
　　–カーニング
　　set aVal3 to -2.0
　　set akey3 to (current application’s NSKernAttributeName)
　　
　　–アンダーライン
　　set aVal4 to 0
　　set akey4 to (current application’s NSUnderlineStyleAttributeName)
　　
　　–リガチャ
　　set aVal5 to 2 –全てのリガチャを有効にする
　　set akey5 to (current application’s NSLigatureAttributeName)
　　
　　–枠線（アウトライン）
　　set aVal6 to outlineNum
　　set akey6 to (current application’s NSStrokeWidthAttributeName)
　　
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey6}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aVal6}
　　set attrsDictionary to current application’s NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to current application’s NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–クリップボードに内容を設定する
on restoreClipboard:theArray
　　— get pasteboard
　　set thePasteboard to current application’s NSPasteboard’s generalPasteboard()
　　
　　— clear it, then write new contents
　　thePasteboard’s clearContents()
　　thePasteboard’s writeObjects:theArray
end restoreClipboard:

★Click Here to Open This Script　

クリップボードに入ったStyled Stringからフォントとサイズと文字内容の情報を取得

Posted on 1月 4, 2021 by Takaaki Naganoya

クリップボードに入ったStyled Stringから、フォント名とサイズと文字内容の情報を取得するAppleScriptです。

Keynoteのテキストオブジェクトのフォント名（フォントファミリー）を置換するAppleScriptを作ったときに、Keynoteが「選択中のオブジェクト」を取得する機能がないために、テキストオブジェクトの中（object text）をコピーして、AppleScript側にその情報を引き渡す必要がありました。

▲年末にコンテスト応募のために久しぶりにFileMaker Proにまとまった時間さわったので、そのノウハウを整理してまとめた本を作成中

こんなKeynote書類があったときに、タイトル部分の書式情報に該当するText Objectのみフォントを一括変更する、という処理です。

KeynoteのAppleScript用語辞書に、選択中のオブジェクトに対してアクセスできるオブジェクト（「selected items」のような）が定義されていれば、クリップボード経由で情報を受け取るような野蛮な処理はしないで済むのですが、、、、、

AppleScript名：クリップボードに入ったStyled Stringからフォントとサイズと文字内容の情報を取得.scptd

— Created 2021-01-03 by Takaaki Naganoya
— 2021 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSDictionary : a reference to current application’s NSDictionary
property NSPasteboard : a reference to current application’s NSPasteboard
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor
property NSAttributedString : a reference to current application’s NSAttributedString
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

–クリップボード内にスタイル付きテキストが入っているかチェック
set cRes to clipboard info for «class RTF »
if cRes = {} then return

–クリップボードに入っているスタイル付きテキストから情報を取得
set {aFontName, aFontSZNum, aString} to getFontNameAndSizeFromClipboard() of me
–> {"DINCondensed-Bold", 170.0, "FileMaker Pro Scripting Book"}

–クリップボードの内容を書式つきテキストとして解釈
on getFontNameAndSizeFromClipboard()
　　–クリップボードの内容を文字列として取得
　　using terms from scripting additions
　　　　set aStr to (the clipboard) as string
　　end using terms from
　　
　　if aStr = "" then
　　　　display dialog "No Data in Clipboard" buttons {"OK"} default button 1
　　　　return
　　end if
　　
　　–クリップボードの内容をStyled Stringで取得して最頻出フォントを取得
　　set clipboardAttrStr to getClipboardASStyledText() of me
　　if clipboardAttrStr = missing value then
　　　　display dialog "Can not get clipboard as Styled String" buttons {"OK"} default button 1
　　　　return
　　end if
　　set attrList to getAttributeRunsFromAttrString(clipboardAttrStr) of me
　　
　　set anArray to ((NSArray’s arrayWithArray:attrList)’s valueForKeyPath:"fontName") as {list, string}
　　set aFontList to (countItemsByItsAppearance(anArray) of me)
　　set aFontName to theName of first item of aFontList
　　
　　set fSizes to ((NSArray’s arrayWithArray:attrList)’s valueForKeyPath:"fontSize") as {list, real}
　　set aFontSZList to (countItemsByItsAppearance(fSizes) of me)
　　set aFontSZNum to theName of first item of aFontSZList
　　
　　set aString to ((NSArray’s arrayWithArray:attrList)’s valueForKeyPath:"stringVal") as string
　　
　　return {aFontName, aFontSZNum, aString}
end getFontNameAndSizeFromClipboard

–1D Listを文字列長でソート v2
on sort1DListByIndicatedStringLength(aList as list, aSortKey as string, sortOrder as boolean)
　　set aArray to NSArray’s arrayWithArray:aList
　　set descLabel1 to NSString’s stringWithString:(aSortKey & ".length")
　　set descLabel2 to NSString’s stringWithString:aSortKey
　　set desc1 to NSSortDescriptor’s sortDescriptorWithKey:descLabel1 ascending:sortOrder
　　set desc2 to NSSortDescriptor’s sortDescriptorWithKey:descLabel2 ascending:true selector:"localizedCaseInsensitiveCompare:"
　　set bArray to aArray’s sortedArrayUsingDescriptors:{desc1, desc2}
　　return bArray as list
end sort1DListByIndicatedStringLength

–リストを指定デリミタをはさんでテキスト化
on retStrFromArrayWithDelimiter(aList as list, aDelim as string)
　　set anArray to NSArray’s arrayWithArray:aList
　　set aRes to anArray’s componentsJoinedByString:aDelim
　　return aRes as text
end retStrFromArrayWithDelimiter

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　set aVal2 to NSColor’s blackColor()
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　set aVal3 to aKerning
　　set akey3 to (NSKernAttributeName)
　　
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　set aVal5 to 2 –all ligature ON
　　set akey5 to (NSLigatureAttributeName)
　　
　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　set akey7 to (NSParagraphStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

— クリップボードの内容をNSAttributedStringとして取り出して返す
on getClipboardASStyledText()
　　set theNSPasteboard to NSPasteboard’s generalPasteboard()
　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({NSAttributedString}) options:(missing value)
　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　return theNSAttributedString
end getClipboardASStyledText

–指定のNSAttributedStringから書式情報をlist of recordで取得
on getAttributeRunsFromAttrString(theStyledText)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer}
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string)
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s fontName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize}
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　end repeat
　　
　　return (styleList of aSpd)
end getAttributeRunsFromAttrString

–1D Listをアイテムの出現頻度順でソートして返す
on countItemsByItsAppearance(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bArray to NSMutableArray’s array()
　　set theEnumerator to aSet’s objectEnumerator()
　　
　　repeat
　　　　set aValue to theEnumerator’s nextObject()
　　　　if aValue is missing value then exit repeat
　　　　bArray’s addObject:(NSDictionary’s dictionaryWithObjects:{aValue, (aSet’s countForObject:aValue)} forKeys:{"theName", "numberOfTimes"})
　　end repeat
　　
　　set theDesc to NSSortDescriptor’s sortDescriptorWithKey:"numberOfTimes" ascending:false
　　bArray’s sortUsingDescriptors:{theDesc}
　　
　　return bArray as list
end countItemsByItsAppearance

★Click Here to Open This Script　

インライン画像つきスタイル付きテキストの作成 v1b

Posted on 7月 22, 2020 by Takaaki Naganoya

スタイル付きテキストの中に画像を入れるAppleScriptです。

–> Download Script bundle with Library

▲上左：macOS 10.13、上右：macOS 10.14、下左：macOS 10.15

画像をNSTextAttachmentに入れてNSAttributedStringに追加するのが本来の処理方法ですが、macOS 10.13と10.14ではNSTextAttachment中の画像が上下逆になるというバグを見つけてしまいました（10.15以降では修正されています）。

ただし、これは全言語共通のバグなので回避方法が紹介されていました。NSTextAttachmentCell経由で画像を突っ込む方法が紹介されています。

これにもとづいて修正＋Shane Stanleyからのアドバイスで書き換えたのがこのScriptです。

AppleScript名：インライン画像つきスタイル付きテキストの作成 v1b.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/07/22
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions
use tvLib : script "tvLib"

set anImage to (current application’s NSImage’s imageNamed:(current application’s NSImageNameComputer))

set anAttachment to current application’s NSTextAttachment’s alloc()’s init()
anAttachment’s attachmentCell()’s setImage:anImage
anAttachment’s setBounds:(current application’s NSMakeRect(0, 0, 32, 32))

set img1Str to current application’s NSAttributedString’s attributedStringWithAttachment:anAttachment

set anAssrStr to makeRTFfromParameters("Piyomaru Software", 32, "Times") of me

img1Str’s appendAttributedString:anAssrStr

dispAttrStr("Main message", "Sub message", img1Str, 400, 80) of tvLib

on makeRTFfromParameters(aStr as string, aFontSize as real, aFontName as string)
　　set aVal1 to current application’s NSFont’s fontWithName:aFontName |size|:aFontSize
　　set aKey1 to (current application’s NSFontAttributeName)
　　
　　set aVal2 to current application’s NSColor’s blackColor()
　　set aKey2 to (current application’s NSForegroundColorAttributeName)
　　
　　set aVal3 to 0
　　set akey3 to (current application’s NSKernAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3}
　　set valList to {aVal1, aVal2, aVal3}
　　set attrsDictionary to current application’s NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to current application’s NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

★Click Here to Open This Script　

choose style lib

Posted on 12月 9, 2019 by Takaaki Naganoya

指定のRTFから書式スタイル名（フォント名、フォントサイズ）を抽出し、そのスタイルをダイアログ上にポップアップメニューで一覧表示し、指定スタイル該当箇所を抽出したプレビュー表示を行いつつ、選択スタイル関連の情報を取得できるAppleScriptライブラリです。動作環境は、macOS 10.13以降です。

–> Download chooseStyleLib(library and sample RTF. Library have to install to ~/Library/Script Libraries)

前バージョンは正常動作するランタイム環境が限定されており、スクリプトエディタ上でCommand-Control-Rで実行する必要がありましたが、このライブラリ版ではScript Debugger上でもScript Menuからでも実行できますし、AppleScript用語辞書（sdef）を書いたので、簡潔かつ手軽に呼び出せるようになりました。

また、AppleScript用語辞書には本Blogと同様の色分け記述で、「★Click Here to Open This Script」をクリックすれば内容がスクリプトエディタに転送されるURLリンク入りのSample Scriptを掲載し、さらに本Blog上の画面キャプチャをリンクしてあるため、実行時の画面イメージも把握できるようになっています。

まんべんなく、すべてのコマンドにSample Scriptを掲載しています。

前バージョンではポップアップメニューにスタイルを適用してWYSIWYGメニューを作成していました。クリックしてメニュー表示を行なっているときにはスタイルが表示されていい感じでしたが、クリックしていない時にはボタンのサイズよりも大きいサイズは欠けて表示されるので、実用性がいまひとつ。そのため、本バージョンではWYSIWYGメニューの機能は省略しました。

ポップアップしていない時にはWYSIWYG表示にならないように機能を両立できるとよかったのですが、、、、

また、前バージョン同様に、「巨大なRTFを指定された場合でも足切りをしない」ようになっているので、あまり巨大なRTFを指定しないようにしてください。

choose style fromコマンド

指定のRTFからスタイル{フォント名,フォントサイズ}を抽出し、ダイアログ上のポップアップメニューで選択したスタイル{フォント名,フォントサイズ}を返します。

AppleScript name：sample1 choose style from.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/12/08
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
–　　http://piyocast.com/as/
use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use scripting additions
use chooseStyle : script "chooseStyle"

set aFile to choose file of type {"public.rtf"}

set bRes to choose style from aFile main message "Select Style" sub message "Select style you want to filter" width 400 height 200
–> {"HelveticaNeue-Bold", 16.0}

★Click Here to Open This Script　

choose contens by style fromコマンド

指定のRTFからスタイル{フォント名,フォントサイズ}を抽出し、ダイアログ上のポップアップメニューで選択したスタイルの該当箇所のテキストを返します。

AppleScript name：sample2 choose contens by style from.scptd

set aFile to choose file of type {"public.rtf"}

set fRes to choose contens by style from aFile main message "Select Style" sub message "Select style you want to filter" width 400 height 300
–> "Built-in filters"–text returns

★Click Here to Open This Script　

filter by styleコマンド

指定のRTFファイルから指定のスタイル{フォント名,フォントサイズ}で指定した箇所のテキストを返します。本コマンドはダイアログ表示を行わず、ただRTFからテキスト抽出するだけです。

AppleScript name：sample3 filter by style.scptd

set aFile to choose file of type {"public.rtf"}

set bRes to choose style from aFile main message "Select Style" sub message "Select style you want to filter" width 400 height 200
–> {"HelveticaNeue-Bold", 16.0}

copy bRes to {fName, fSize}

set aRes to filter by style aFile font name fName font size fSize
–>"Built-in filters"

★Click Here to Open This Script　

extract stylesコマンド

指定のRTFファイルからすべてのスタイル{フォント名,フォントサイズ}を抽出します。本コマンドもダイアログ表示は行いません。

AppleScript name：sample4 extract styles.scptd

set aFile to choose file of type {"public.rtf"}
return extract styles aFile
–> {{"HelveticaNeue-Bold", 24.0}, {"HelveticaNeue", 16.0}, {"HelveticaNeue-Bold", 20.0}, {"HelveticaNeue-Bold", 16.0}, {"HelveticaNeue-Italic", 16.0}, {"LucidaGrande", 16.0}, {"Menlo-Regular", 13.6}}

★Click Here to Open This Script　

指定のフォントとサイズに該当するテキストを抽出する v3

Posted on 12月 1, 2019 by Takaaki Naganoya

指定のRTFファイルから書式情報を取得し、フォント名とフォントサイズのペアをスタイルを反映させたポップアップメニューで選択。RTFの内容を解析したのち、ダイアログが表示されます（ここの所要時間は読ませるRTFのサイズ次第）。ポップアップメニューで書式を選ぶと、すぐさま抽出した箇所をすべてまとめて表示します。

–> Watch Demo Movie

–> Download Script Bundle with Sample data

ダイアログ表示前に書式ごとの抽出を完了し、個別のTabViewに抽出後の文字データを展開しておくので、ポップアップメニューから選択すると、展開ずみのデータを入れてあるTabViewに表示を切り替えるだけ。切り替え時に計算は行わないため、すぐに抽出ずみの文字データが表示されるという寸法です。

今回は短いサンプルデータを処理してみましたが、サンプル抽出時にあらかじめ範囲指定するなどして、データ処理規模を限定することで処理時間を稼ぐこともできることでしょう。

テキストエディットでオープン中のRTF書類のパスを取得して、それを処理対象にしてもいいでしょう。

ただし、やっつけで作ったのでスクリプトエディタ上でCommand-Control-Rで実行しないと動きません（メインスレッド実行をプログラムで強制しても、途中でクラッシュしてしまいます）。それほど時間もかけずに作ったやっつけプログラムなので、あまり原因追求も行えずそのままです。

AppleScript名：アラートダイアログ＋Tab View v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/16
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use rtfLib : script "readStyledTextLib"
use parseLib : script "parseAttrLib"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSMenu : a reference to current application’s NSMenu
property NSArray : a reference to current application’s NSArray
property NSTabView : a reference to current application’s NSTabView
property NSPredicate : a reference to current application’s NSPredicate
property NSTextView : a reference to current application’s NSTextView
property NSMenuItem : a reference to current application’s NSMenuItem
property NSTabViewItem : a reference to current application’s NSTabViewItem
property NSPopUpButton : a reference to current application’s NSPopUpButton
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSStrokeWidthAttributeName : a reference to current application’s NSStrokeWidthAttributeName
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property TabPosition : 4 —0=Top, 1=Left, 2=Bottom, 3=Right, 4=None

property returnCode : 0

property aTabV : missing value
property selectedNum : {}

set aFile to choose file of type {"public.rtf"}

set aStyledStr to readRTFfile(aFile) of rtfLib
set paramObj to {myMessage:"Select Style", mySubMessage:"Select style you want to filter", viewWidth:800, viewHeight:400, myStyledStr:aStyledStr}

my dispTabViewWithAlertdialog:paramObj –for debug
–my performSelectorOnMainThread:"dispTabViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
return selectedNum

on dispTabViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set aWidth to (viewWidth of paramObj) as integer –TextView width
　　set aHeight to (viewHeight of paramObj) as integer –TextView height
　　set aStyledStr to (myStyledStr of paramObj)
　　
　　set attrResTmp to getAttributeRunsFromAttrString(aStyledStr) of parseLib
　　set attrList to attributes of attrResTmp
　　set menuStyle to menuList of attrResTmp
　　
　　set selectedNum to {}
　　
　　set aView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　–Ppopup Buttonをつくる
　　set a1Button to NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 20, 400, 20)) pullsDown:false
　　a1Button’s removeAllItems()
　　
　　–WYSIWHG popup menuをつくる
　　set a1Menu to NSMenu’s alloc()’s init()
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set aTitle to (tmpFont & " " & tmpSize as string) & " point"
　　　　set aMenuItem to (NSMenuItem’s alloc()’s initWithTitle:aTitle action:"actionHandler:" keyEquivalent:"")
　　　　
　　　　set attributedTitle to makeRTFfromParameters(aTitle, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　
　　　　(aMenuItem’s setEnabled:true)
　　　　(aMenuItem’s setTarget:me)
　　　　(aMenuItem’s setTag:(i as string))
　　　　(aMenuItem’s setAttributedTitle:(attributedTitle))
　　　　(a1Menu’s addItem:aMenuItem)
　　end repeat
　　
　　–Ppopup Buttonにmenuをつける
　　a1Button’s setMenu:a1Menu
　　
　　–Make Tab View
　　set aTabV to NSTabView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 30))
　　aTabV’s setTabViewType:(TabPosition)
　　
　　
　　–TabViewに中身を入れる
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set tmpKey to (tmpFont as string) & "/" & (tmpSize as string)
　　　　set tmpArry to filterRecListByLabel1(attrList, "styleKey2 == ’" & tmpKey & "’") of me
　　　　set tmpStr to (tmpArry’s valueForKeyPath:"stringVal") as list
　　　　
　　　　set aTVItem to (NSTabViewItem’s alloc()’s initWithIdentifier:(i as string))
　　　　(aTVItem’s setLabel:(i as string))
　　　　
　　　　
　　　　set aTextView to (NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth – 10, aHeight – 10)))
　　　　(aTextView’s setRichText:true)
　　　　set tmpAttr to makeRTFfromParameters(tmpStr as string, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　(aTextView’s textStorage()’s appendAttributedString:tmpAttr)
　　　　
　　　　(aTVItem’s setView:aTextView)
　　　　
　　　　(aTabV’s addTabViewItem:aTVItem)
　　end repeat
　　
　　
　　aView’s setSubviews:{a1Button, aTabV}
　　aView’s setNeedsDisplay:true
　　
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aView)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　end tell
　　
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set selectedNum to contents of item ((a1Button’s indexOfSelectedItem()) + 1) of menuStyle
end dispTabViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–Popup Action Handler
on actionHandler:sender
　　set aTag to tag of sender as integer
　　aTabV’s selectTabViewItemAtIndex:(aTag – 1)
end actionHandler:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, aFontName as string, aFontSize as real, aColor)
　　–フォント
　　set aVal1 to NSFont’s fontWithName:(aFontName) |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　–色
　　set aVal2 to aColor
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　–カーニング
　　set aVal3 to 0.0
　　set akey3 to (NSKernAttributeName)
　　
　　–アンダーライン
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　–リガチャ
　　–set aVal5 to 2 –全てのリガチャを有効にする
　　–set akey5 to ( NSLigatureAttributeName)
　　
　　–枠線（アウトライン）
　　–set aVal6 to outlineNum
　　–set akey6 to ( NSStrokeWidthAttributeName)
　　
　　
　　set keyList to {aKey1, aKey2, akey3, akey4}
　　set valList to {aVal1, aVal2, aVal3, aVal4}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　set bList to filteredArray
　　return bList
end filterRecListByLabel1

★Click Here to Open This Script　

指定のフォントとサイズに該当するテキストを抽出する v2

Posted on 11月 30, 2019 by Takaaki Naganoya

macOS標準搭載のテキストエディタ「テキストエディット」の最前面のドキュメントから書式情報を取得し、フォント名とフォントサイズのペアをスタイルを反映させたポップアップメニューで選択。選択したスタイルが該当する箇所を抽出したのちにテキスト化してTextViewで結果を表示します。

–> Download Code-signed AppleScript applet executable with libraries

▲Sample RTF（なんでもOK）

▲添付のAppleScriptアプレットは、初回実行時に制御許可のダイアログが表示されます。OKすれば、２回目以降はダイアログ表示されません

▲書式情報をRTF書類から読み込んで、スタイルを反映させたポップアップメニューで表示。サンプル文をRTF書類から取得しているものの、改行部分だけがヒットしたりとなかなかうまくありません

▲一覧から選択

▲RTF書類から指定書式に相当するテキストを抽出して出力

AppleScript名：指定のフォントとサイズに該当するテキストを抽出する v2.scptd

— Created 2019-11-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use wgMenuLib : script "wysiwygMenuLib" –WYSIWYGポップアップメニューダイアログ　ライブラリ
use dtLib : script "dTextView" –TextView表示ライブラリ

script spd
　　property fontList : {}
　　property fontSizes : {}
　　property textList : {}
　　property outList : {}
　　property combiList : {}
end script

set (outList of spd) to {}
set (fontList of spd) to {}
set (fontSizes of spd) to {}
set (textList of spd) to {}
set (combiList of spd) to {}

–TextEdit書類から書式情報を根こそぎ取得
tell application "TextEdit"
　　tell text of front document
　　　　set (fontList of spd) to font of every attribute run –フォント名
　　　　set (fontSizes of spd) to size of every attribute run –文字サイズ
　　　　set (textList of spd) to character of every attribute run –文字
　　end tell
end tell

–ポップアップメニュー選択用のデータを作成
set aLen to length of (fontList of spd)
set menuList to {}
set sampleList to {}
repeat with i from 1 to aLen
　　set tmpFont to contents of item i of (fontList of spd)
　　set tmpSize to contents of item i of (fontSizes of spd)
　　set tmpSample to (contents of item i of (textList of spd)) as string
　　set tmpList to {tmpFont, tmpSize}
　　if {tmpList} is not in (combiList of spd) then
　　　　set the end of (combiList of spd) to tmpList
　　　　set the end of menuList to (tmpFont & " — " & tmpSize as string) & " point ex.:" & tmpSample
　　end if
end repeat

–WYSIWYGポップアップメニューで項目選択
set paramObj to {myMessage:"Select Attribute", mySubMessage:"Select target attribute", segmentMes:{menuList}, segmentTitles:{"Select combination of font name and size"}, segmentAttributes:(combiList of spd)}
set fRes to makeMenuAndcheck(paramObj) of wgMenuLib
if fRes = 0 then return

copy item (first item of fRes) of (combiList of spd) to {aFont, aSize}

–取得した条件にもとづいて、根こそぎ取得した書式と照合を行いつつループ
repeat with i from 1 to length of (fontList of spd)
　　set tmpFont to contents of item i of (fontList of spd)
　　set tmpSize to contents of item i of (fontSizes of spd)
　　
　　–文字サイズをざっくり判定することで「大、中、小」といったおおまかな切り分けも可能
　　if {tmpFont, tmpSize} = {aFont, aSize} then
　　　　set tmpCon to (contents of item i of (textList of spd)) as string
　　　　if tmpCon does not contain "•" then –ごみ取り
　　　　　　set the end of (outList of spd) to tmpCon
　　　　end if
　　end if
end repeat

–結果をTextViewで表示
set aStr to retListedText(outList of spd, return) of me
set eRes to (display text view aStr main message "Result" sub message "" with properties {font name:aFont, size:aSize, width:800, height:400})

on retListedText(aList, aSeparator)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aSeparator
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retListedText

★Click Here to Open This Script　

テキストエディットで指定のフォントとサイズに該当するテキストを抽出する

Posted on 11月 22, 2019 by Takaaki Naganoya

macOS標準搭載のテキストエディタ、「テキストエディット」（TextEdit）をコントロールして、最前面のウィンドウの書類から、指定のフォント名とサイズに該当するテキストを抽出するAppleScriptです。

テキストエディットはApple純正のアプリケーションの割にはAppleScriptサポート機能がよくできていて、選択範囲（selection）を取得できないことをのぞけば、けっこう使えます。

テキストエディットのAppleScript系の機能で最も重要なものは、書類からの書式取得機能（attribute run）です。

▲最前面の書類がリッチテキストフォーマットになっている必要があります

▲Github上のGPUImageのフィルタ紹介文からコピペしてきた文章

▲この書類のこのレベルの見出しだけを抽出したい場合にはHelvetica Neue Bold 20pointを指定

▲この書類のこのレベルの見出しだけを抽出したい場合にはHelvetica Neue Bold 16pointを指定

Webブラウザなどからコピペしてきたスタイル付きテキストから、特定のフォントや文字サイズの箇所を抽出したい場合に使います。

実行すると、リッチテキストで使用されているフォント名とサイズの一覧を生成し、ダイアログでフォント名の選択、

そして、文字サイズの選択を実行。

すると、該当箇所のみ抽出して返します。さらに改行で区切ったテキストに変換するとかいった処理を行なってもよいでしょう。

RTFのファイルを処理するのであれば、テキストエディットを使わなくてもCocoaの機能を用いて同様の処理を行えますが、割と書き捨てレベルの瑣末なScriptなのでテキストエディット経由で書式情報を取得するように組んでみました。

AppleScript名：指定のフォントとサイズに該当するテキストを抽出する

— Created 2019-11-22 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

script spd
　　property fontList : {}
　　property fontSizes : {}
　　property textList : {}
　　property outList : {}
end script

set (outList of spd) to {}
set (fontList of spd) to {}
set (fontSizes of spd) to {}
set (textList of spd) to {}

–取得したフォント名一覧から重複部分を除去してどれを対象にするかユーザーに問い合わせ
set fRes to uniquify1DList((fontList of spd), true) of me
set targFont to choose from list fRes
set aFont to contents of first item of targFont

–取得したフォントサイズ一覧から重複部分を除去してどれを対象にするかユーザーに問い合わせ
set sRes to uniquify1DList((fontSizes of spd), true) of me
set targSize to choose from list sRes
set aSize to contents of first item of targSize

return (outList of spd)

–1D/2D Listをユニーク化
on uniquify1DList(theList as list, aBool as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:theList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　if aBool = true then
　　　　return bArray as list
　　else
　　　　return bArray
　　end if
end uniquify1DList

★Click Here to Open This Script　

Skimでオープン中のPDFで選択中のテキストを返す

Posted on 9月 16, 2019 by Takaaki Naganoya

フリーでScriptableなmacOS用PDFビューワー「Skim」上でオープン中のPDFで、選択中のテキストの内容を取得するAppleScriptです。

フリーかつオープンソースで提供されているアプリケーションのうち、奇跡的に豊富なAppleScript対応機能を備えるPDFビューワー、それがSkimです。Skimに比べればPreview.appなど取るに足らない存在。「PDFビューワー四天王」のうち、その最上位に君臨するアプリケーションこそがSkimです（四天王とかいいつつ、Skim、Preview、Acrobatの３人しかいないのはお約束）。

▲SkimでPDFをオープンし、「AppleScriptってなんだろう？」の文字列を選択

ただ、そんなグレートな存在のSkimでも、「選択中のテキストを取得する」という処理を書いたことはありませんでした。

Skimの「selection」によって取得されるのがテキストではなくRTFなので、AppleScriptの基本的な機能ではこのRTFはひどく扱いが難しいデータ「でした」。

しかし、Cocoaの機能を利用することで、テキストへの変換は可能です。

それでも、Cocoaが期待するRTFのデータとAppleScriptの世界のRTFのデータ同士の変換が難儀でした。食後の腹ごなしに行うには手に余るといったレベル。

そこで、お気軽データ変換の最後の砦であるクリップボードを経由してRTFをAppleScriptの世界からCocoaの世界に受け渡してみたところ、大成功。あとは、PDFから取得したテキストデータによくあることですが、日本語のテキストだとUnicodeのNormalize方法の問題によりひらがな/カタカナと濁点や半濁点が分離した状態で返ってきました。

これについても、Cocoaの機能を利用してNormalizeを行い、常識的なテキストに変換できました。

AppleScript名：Skimでオープン中のPDFの選択中のテキストを返す

tell application "Skim"
　　tell front document
　　　　set aSel to selection
　　　　repeat with i in aSel
　　　　　　set aCon to contents of i
　　　　　　set rList to RTF of aCon
　　　　　　
　　　　　　set sCon to ""
　　　　　　repeat with ii in rList
　　　　　　　　set the clipboard to ii
　　　　　　　　set aText to getClipboardAsText() of me
　　　　　　　　set aCon to aCon & aText
　　　　　　end repeat
　　　　　　
　　　　　　set aStr to textfy(aCon) of me
　　　　　　return aStr
　　　　end repeat
　　end tell
end tell

–Normalize Unicode Text in NFKC
on textfy(aText as string)
　　set aStr to current application’s NSString’s stringWithString:aText
　　set aNFKC to aStr’s precomposedStringWithCompatibilityMapping()
　　return aNFKC as string
end textfy

–Clipboard内の情報をテキストとして取得する
on getClipboardAsText()
　　— get the pasteboard items
　　set theClip to current application’s NSPasteboard’s generalPasteboard()
　　set pbItems to theClip’s pasteboardItems()
　　
　　set theStrings to {}
　　
　　repeat with anItem in pbItems
　　　　if (anItem’s types()’s containsObject:(current application’s NSPasteboardTypeString)) then
　　　　　　set end of theStrings to (anItem’s stringForType:(current application’s NSPasteboardTypeString)) as text
　　　　end if
　　end repeat
　　
　　return theStrings as text
end getClipboardAsText

★Click Here to Open This Script　

とか言ってたら、夕飯の買い物に出かけようとした頃にShane Stanleyから「もっとシンプルに書けるよー」というサンプルが届いて脱力しました。もっと簡潔に書けたようです（同一サンプルで日本語データに対してチェックずみ）。

ただ、PDFから文字取り出ししたあとは、Unicodeの再Normalizeは割とやらないといけないケースが多いので、選択部分（selection）からRTFじゃなくてcharacterでデータを取り出せばよかったというあたりが反省点でしょうか。

set theText to ""
tell application "Skim"
　　tell front document
　　　　set aSel to selection
　　　　repeat with anItem in aSel
　　　　　　set theText to theText & (characters of anItem) as text
　　　　end repeat
　　end tell
end tell
return theText

★Click Here to Open This Script　

Keynoteのテキストアイテム内の文字の実際の幅でリサイズ

Posted on 4月 5, 2019 by Takaaki Naganoya

Keynote書類上のテキストアイテムを、内容の文字の実際の幅でリサイズするAppleScriptです。

▲テキストアイテム中のテキストをコピー（Command-C）

▲リサイズ前のテキストアイテム。文字に対してフレームサイズが大きい

▲本Scriptによりリサイズした後のテキストアイテム。文字の内容に対してフレームサイズがフィットしている

▲本Scriptにより順次複数のテキストアイテムを文字幅にリサイズしたところ。selectionがまともに動作していれば、複数のテキストアイテムを選択した状態でScriptを走らせて一度にリサイズできる（はず）だが、selectionが動作していないので複数のオブジェクトに対して同じ回数の操作が必要

Keynoteにはversion 9.0で「selection」の予約語が追加されましたが、これは一般に期待されるような「表示中のスライド上で選択中のオブジェクトへの参照が取得できる」というものではありません。

つまり、選択中のオブジェクトへの参照をKeynoteに対して問い合わせることは、（現時点では）不可能です。

そこで、テキストアイテム内の内容（object text）をコピー（Command-C）してクリップボードに格納し、その内容をキーにして現在表示中のスライド内のテキストアイテムを抽出してみたところ、うまくいきました（なんでこんなことさせられてるんだろ？）。早くselectionがKeynote上でもまともに使えるようになってほしいものです（Pages上ではけっこういい感じに使えるのに）。

テキストアイテムの特定ができるようになったので、入っているobject textのサイズに合わせてテキストアイテムをリサイズする処理を書いてみました。

クリップボードの内容をNSAttributedStringとして取得し、その画面上の描画サイズを取得するサブルーチンは毎日さんざん使っているので（掲載リストのproperty宣言部をソートするのに使っています）信頼性があります。

とりあえず、擬似的に現在選択中のオブジェクトを特定する実験コードにちょっとだけ機能をつけたものですが、操作１に対して結果１というのは普通「自動化」とか言わないので、実用性は皆無です（めんどくさい操作ステップを省けるぐらいしか）。

AppleScript名：Keynoteのテキストアイテム内の文字の実際の幅でリサイズ

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/05
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use BPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSPasteboard : a reference to current application’s NSPasteboard
property NSAttributedString : a reference to current application’s NSAttributedString
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

load framework

–クリップボードの内容をテキストとして取得し、現在のKeynote書類中のtext itemのうちコピーしたテキストに該当するものを抽出
set targString to (the clipboard) as string

tell application "Keynote"
　　tell document 1
　　　　tell current slide
　　　　　　set tList to every text item whose object text is targString
　　　　　　if tList = {} then return
　　　　　　set targObject to first item of tList
　　　　end tell
　　end tell
end tell

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()

–Split Attributed Strings into lines
set attrList to splitAttributedStringByLines(anAttr) of me

–Sort Attributed String list by its width in descending (large–> small)
set aResList to shellSortListDecending(attrList, 1) of me
set {targObjWidth, targAttrStrObj} to first item of aResList

–Resize Text item objet’s frame by its drawing width on screen
tell application "Keynote"
　　tell document 1
　　　　tell current slide
　　　　　　tell targObject
　　　　　　　　set width to ((targObjWidth as number) + 10) –resize it !
　　　　　　end tell
　　　　end tell
　　end tell
end tell

–入れ子のリストを昇順ソート
on shellSortListAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end shellSortListAscending

–入れ子のリストを降順ソート
on shellSortListDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end shellSortListDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　–Sort
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　
　　return resList
end sort2DList

— クリップボードの内容をNSAttributedStringとして取り出して返す
on getClipboardASStyledText()
　　try
　　　　set theNSPasteboard to NSPasteboard’s generalPasteboard()
　　　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({NSAttributedString}) options:(missing value)
　　　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　　　return theNSAttributedString
　　on error
　　　　return missing value
　　end try
end getClipboardASStyledText

on splitAttributedStringByLines(theStyledText)
　　set outList to {}
　　set outAttr to NSMutableAttributedString’s alloc()’s initWithString:""
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　set aText to (thePureString’s substringWithRange:theRange) as string –String
　　　　
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor") –Color
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont") –Font
　　　　if aFont is equal to missing value then error "Not font name and size are specified" –Font Name error
　　　　set aDFontName to aFont’s displayName() –Font Name
　　　　set aDFontSize to aFont’s pointSize() –Font Size
　　　　
　　　　set tmpAttrStr to generateAttributedString(aText, aDFontName, aDFontSize, aColor) of me
　　　　outAttr’s appendAttributedString:tmpAttrStr
　　　　
　　　　if (aText contains return) or (aText contains string id 10) then –CR or LF
　　　　　　set tmpSize to outAttr’s |size|()
　　　　　　set tmpWidth to retWidthFromSize(tmpSize) of me
　　　　　　
　　　　　　set the end of outList to {tmpWidth, outAttr}
　　　　　　set outAttr to NSMutableAttributedString’s alloc()’s initWithString:""
　　　　end if
　　　　
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　end repeat
　　
　　set tmpSize to outAttr’s |size|()
　　set tmpWidth to retWidthFromSize(tmpSize) of me
　　set the end of outList to {tmpWidth, outAttr}
　　
　　return outList
end splitAttributedStringByLines

on retWidthFromSize(tmpSize)
　　if class of tmpSize = record then
　　　　–macOS 10.10, 10.11, 10.12
　　　　set tmpWidth to width of tmpSize
　　else
　　　　–macOS 10.13, 10.14
　　　　set tmpWidth to first item of tmpSize
　　end if
　　return tmpWidth
end retWidthFromSize

on generateAttributedString(aStr, aFontPSName, aFontSize, aColor)
　　set tmpAttr to NSMutableAttributedString’s alloc()’s initWithString:aStr
　　set aRange to current application’s NSMakeRange(0, tmpAttr’s |length|())
　　set aVal1 to NSFont’s fontWithName:aFontPSName |size|:aFontSize
　　tmpAttr’s beginEditing()
　　tmpAttr’s addAttribute:(NSFontAttributeName) value:aVal1 range:aRange
　　tmpAttr’s addAttribute:(NSForegroundColorAttributeName) value:aColor range:aRange
　　tmpAttr’s endEditing()
　　return tmpAttr
end generateAttributedString

★Click Here to Open This Script　

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

Posted on 3月 29, 2019 by Takaaki Naganoya

英語版の花文字テキストを作成してテキストエディタ（CotEditor）に出力するAppleScriptです。

描画用の英単語と、塗りつぶし用の英単語を別々に指定できます。invertFをtrueに設定すると、白黒反転出力を行います。

おおもとの元ネタは、大型計算機を大勢のユーザーで共有していた時代（ぱそこん登場前）、計算結果を高速プリンタの帳票に出力するようになっていたころにさかのぼります。どのユーザーの計算結果かを大量のプリンタの出力結果の中から仕分けるため、印刷出力の１ページ目をユーザー名などの情報を印字した「バナー」として使用。

そのさい、ドットインパクトプリンターだったので、決められた固定ドット数の文字しか印字できないため、英数字を組み合わせて擬似的に大きな文字でバナーを印刷していたことに端を発します。

その時代の「残り香」ともいえるバナーがパソコンの電子メールやBBSの時代にお遊びの「花文字」として引き継がれ、原始的なアスキーアートの一種として楽しまれてきました。

いまでも、shell commandの「banner」コマンドにその末裔を見ることができます。

先週のmacOS nativeのデモ時に「祝」という花文字を「呪」の文字で出力するという、定番の持ちネタを披露したところ、たいへんウケておりました。

ただ、これを海外のScripter向けにそのままデモしても受けません。

この、花文字テキストを出力するプログラムの英語版としては、love.scptといういにしえのデータをそのまま使いまわしたものがありますが、描画パターンを数値データで保持しているため、異なるパターンを表示させることはできません。

そこで、日本語版の花文字テキスト出力プログラムに若干手をくわえ、英単語の出力が行えるようにしてみました。

テキストの出力はCotEditorに対して行なっていますが、新規書類を指定文字で作成する程度なので、AppleScriptに対応しているテキストエディタならどれでも作り変えられます。また、表示を等幅フォントにしておく必要があります（あとから指定してもOK）。

AppleScript名：指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

— Created 2017-12-12 by Takaaki Naganoya
— Modified 2019-03-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSColorSpace : a reference to current application’s NSColorSpace
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSFontManager : a reference to current application’s NSFontManager
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property fillCharList : {}
property fillCharCounter : 1

set aString to "Love"
set bString to "hate"
set hanaSize to 24
set thisFont to selectAFont(first character of aString) of me
if thisFont = false then return –Cancel

–花文字文字列を作成
set fRes to getEnglishHanamojiStr(hanaSize, thisFont, aString, bString, 0.7, true, true) of me
makeNewDocument given parameter:fRes

–花文字文字列を計算して返す
on getEnglishHanamojiStr(aFontSize as real, aFontName as string, aString as string, fillString as string, aThread as real, incFontName as boolean, invertF as boolean)
　　
　　set my fillCharList to characters of fillString
　　set my fillCharCounter to 1
　　
　　–指定文字コードが指定フォント中に存在するかチェック
　　repeat with i in (characters of aString)
　　　　set fRes to retGlyphsInFont(aFontName, id of i) of me
　　　　if fRes = false then return false
　　end repeat
　　
　　set aThreadShould to 768 * aThread
　　if (chkMultiByteChar(first character of aString) of me) = false then
　　　　set spaceChar to string id 12288 –全角スペース（UTF-16）
　　else
　　　　set spaceChar to string id 32 –半角スペース
　　end if
　　
　　set fillColor to NSColor’s whiteColor –塗り色
　　set bString to aString & " " –処理内容の帳尻合わせ（そのままだと右端が欠けるのでスペースを入れた）
　　set anAssrStr to makeRTFfromParameters(bString, aFontName, aFontSize, -2, (aFontSize * 1.2)) of me
　　set aSize to anAssrStr’s |size|()
　　
　　if class of aSize = record then
　　　　set attrStrWidth to width of aSize
　　　　set attrStrHeight to height of aSize
　　else if class of aSize = list then –macOS 10.13.xのバグ回避
　　　　copy aSize to {attrStrWidth, attrStrHeight}
　　end if
　　
　　set {xPos, yPos} to {0, 0}
　　
　　set tmpImg1 to makeImageWithFilledColor(attrStrWidth, attrStrHeight, fillColor) of me
　　set tmpImg2 to drawAttributedStringsOnImage(tmpImg1, anAssrStr, xPos, yPos) of me
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:(tmpImg2’s TIFFRepresentation())
　　
　　–画像から順次指定座標の色データを拾って花文字listに反映
　　set strList to {}
　　repeat with y from 1 to attrStrHeight – 1
　　　　
　　　　set strListX to {}
　　　　repeat with x from 0 to attrStrWidth – 1
　　　　　　set tmpCol to getColorFromRawImage(aRawimg, x, y) of me
　　　　　　
　　　　　　if invertF = false then
　　　　　　　　
　　　　　　　　–通常描画（invert = false）時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　else
　　　　　　　　–白黒反転（invert = true)時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　end if
　　　　end repeat
　　　　set the end of strList to strListX
　　end repeat
　　
　　–2D List→Text
　　set aRes to list2dToStringByUsingDelimiters(strList, "", return) of me
　　
　　if incFontName = true then
　　　　set fName to getDisplayedNameOfFont(aFontName) of me
　　　　set aRes to "Font=" & fName & return & return & aRes
　　end if
　　
　　return aRes
end getEnglishHanamojiStr

on getChar()
　　set retChar to item (my fillCharCounter) of (my fillCharList)
　　if (my fillCharCounter) = length of (my fillCharList) then
　　　　set (my fillCharCounter) to 1
　　else
　　　　set (my fillCharCounter) to (my fillCharCounter) + 1
　　end if
　　return retChar
end getChar

–指定Raw画像中の指定座標のピクセルの色をRGBで取り出す
on getColorFromRawImage(aRawimg, x as real, y as real)
　　set aRatio to getImageRatio() of me –Retina Display対応
　　set origColor to (aRawimg’s colorAtX:(x * aRatio) y:(y * aRatio))
　　
　　set srgbColSpace to NSColorSpace’s deviceRGBColorSpace
　　if srgbColSpace = missing value then return false
　　
　　set aColor to (origColor’s colorUsingColorSpace:srgbColSpace)
　　
　　set aRed to (aColor’s redComponent()) * 255
　　set aGreen to (aColor’s greenComponent()) * 255
　　set aBlue to (aColor’s blueComponent()) * 255
　　
　　return {aRed as integer, aGreen as integer, aBlue as integer}
end getColorFromRawImage

–画像のうえに指定のスタイル付きテキストを描画して画像を返す
on drawAttributedStringsOnImage(anImage, anAssrStr, xPos as real, yPos as real)
　　anImage’s lockFocus()
　　anAssrStr’s drawAtPoint:(current application’s NSMakePoint(xPos, yPos))
　　anImage’s unlockFocus()
　　return anImage
end drawAttributedStringsOnImage

–指定サイズの画像を作成し、背景を指定色で塗る
on makeImageWithFilledColor(aWidth as real, aHeight as real, fillColor)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　set aRatio to getImageRatio() of me –Retina Display対応
　　
　　anImage’s lockFocus()
　　set theRect to {{x:0, y:0}, {width:aWidth * aRatio, height:aHeight * aRatio}}
　　set theNSBezierPath to NSBezierPath’s bezierPath
　　theNSBezierPath’s appendBezierPathWithRect:theRect
　　fillColor’s |set|()
　　theNSBezierPath’s fill()
　　anImage’s unlockFocus()
　　
　　return anImage
end makeImageWithFilledColor

–2D Listをアイテム間および行間のデリミタを個別に指定してテキスト変換
on list2dToStringByUsingDelimiters(aList as list, itemDelimiter, lineDelimiter)
　　set outList to {}
　　repeat with i in aList
　　　　set aStr to listToStringUsingTextItemDelimiter(i, itemDelimiter) of me
　　　　set the end of outList to aStr
　　end repeat
　　
　　set bStr to listToStringUsingTextItemDelimiter(outList, lineDelimiter) of me
　　return bStr
end list2dToStringByUsingDelimiters

on listToStringUsingTextItemDelimiter(sourceList as list, textItemDelimiter)
　　set CocoaArray to NSArray’s arrayWithArray:sourceList
　　set CocoaString to CocoaArray’s componentsJoinedByString:textItemDelimiter
　　return (CocoaString as string)
end listToStringUsingTextItemDelimiter

–ユーザー環境にインストールされているすべてのフォントのPostScript名とグリフ数を返す
on getEveryFontPSNameANdGlyphsNum(aStr)
　　set aFontList to NSFontManager’s sharedFontManager()’s availableFonts()
　　set thePred to NSPredicate’s predicateWithFormat:"NOT SELF BEGINSWITH ’.’"
　　set aFontList to (aFontList’s filteredArrayUsingPredicate:thePred) as list
　　
　　set aList to {}
　　repeat with i in aFontList
　　　　set aName to contents of i
　　　　set aNum to countNumberOfGlyphsInFont(aName) of me
　　　　set dName to getDisplayedNameOfFont(aName) of me
　　　　
　　　　set fRes to retGlyphsInFont(aName, id of aStr) of me
　　　　if fRes = true then
　　　　　　set the end of aList to {fontName:aName, fontNum:aNum, dispName:dName}
　　　　end if
　　end repeat
　　
　　return aList
end getEveryFontPSNameANdGlyphsNum

–指定Postscript名称のフォントに定義されている文字数を数えて返す
on countNumberOfGlyphsInFont(fontName as string)
　　set aFont to NSFont’s fontWithName:fontName |size|:9.0
　　if aFont = missing value then return false
　　set aProp to aFont’s numberOfGlyphs()
　　return aProp as number
end countNumberOfGlyphsInFont

–フォントのPostScript NameからDisplayed Nameを取得
on getDisplayedNameOfFont(aName as string)
　　set aFont to NSFont’s fontWithName:aName |size|:9.0
　　set aDispName to (aFont’s displayName()) as string
　　return aDispName
end getDisplayedNameOfFont

–全角文字が存在するか
on chkMultiByteChar(checkString as string)
　　set aStr to NSString’s stringWithString:checkString
　　set aRes to aStr’s canBeConvertedToEncoding:(current application’s NSASCIIStringEncoding)
　　return (aRes as boolean)
end chkMultiByteChar

–指定名称のフォントに指定の文字コードが含まれているかチェック
on retGlyphsInFont(fontName as string, strCode as integer)
　　set aFont to NSFont’s fontWithName:fontName |size|:24.0
　　if aFont = missing value then return false
　　set aSet to aFont’s coveredCharacterSet()
　　set aRes to (aSet’s characterIsMember:strCode) as boolean
　　return aRes as list of string or string –as anything
end retGlyphsInFont

on selectAFont(aString)
　　set fRes to getEveryFontPSNameANdGlyphsNum(aString) of me
　　set theArray to NSArray’s arrayWithArray:fRes
　　set thePred to NSPredicate’s predicateWithFormat:"fontNum > 10000"
　　set bArray to ((theArray’s filteredArrayUsingPredicate:thePred)’s valueForKeyPath:"dispName") as list
　　set thisFont to choose from list bArray
　　return thisFont
end selectAFont

–Retina Display対応ルーチン
on getImageRatio()
　　set retinaF to detectRetinaDisplay() of me
　　if retinaF = true then
　　　　return 2.0 as real
　　else
　　　　return 1.0 as real
　　end if
end getImageRatio

on detectRetinaDisplay()
　　set dispList to current application’s NSScreen’s screens()
　　set retinaF to false
　　
　　repeat with i in dispList
　　　　set j to contents of i
　　　　set aDepth to j’s backingScaleFactor()
　　　　if aDepth > 1.0 then
　　　　　　set retinaF to true
　　　　end if
　　end repeat
　　
　　return retinaF
end detectRetinaDisplay

on makeNewDocument given parameter:aStr
　　tell application id "com.coteditor.CotEditor"
　　　　activate
　　　　set newDoc to make new document
　　　　tell newDoc
　　　　　　set contents to aStr
　　　　end tell
　　end tell
end makeNewDocument

★Click Here to Open This Script　

クリップボード内のRTFをStyled Stringとして解釈して行ごとに分割して画面描画サイズ幅で昇順ソートして再結合

Posted on 2月 27, 2019 by Takaaki Naganoya

クリップボードにコピーしておいた書式つきテキストを、行ごとに画面上の描画サイズで昇順ソートし、再結合してクリップボードに転送するAppleScriptです。

ほぼ毎日使っているAppleScriptの改良版です。

Cocoaの機能を呼び出すと、AppleScript冒頭にproperty宣言文を書くことになりますが（書かなくてもいいんですが）、この宣言文を「プロポーショナルフォントを考慮しつつ実際の画面上の描画サイズを考慮」して短いものから長いものにソートして掲載しています。

ただし、従来のバージョンでは実際のフォントではなく一律に指定フォントで描画したさいの描画幅でソートしていたため、ごくまれに掲載時のリストが短い順になっていませんでした（世界中で誰も気にしてねえよ！　＾ー＾；）。

これを、実際の指定フォントやサイズを考慮した行単位のスタイル付きテキストに分解し、描画幅でソートしたあとにスタイル付きテキストを再合成するようにしました。

従来のOld Style AppleScriptではスタイル付きテキストの操作は一切できませんでしたが、Cocoaの機能を活用することでこのように自由度の高い処理ができるようになった、という好例です。

なお、本ルーチンによって厳密に描画幅でソートしても、Web掲載時にはWebブラウザのレンダリングのルール（＆ユーザー側で指定しているWebブラウザのフォント）が適用されるため、macOS上のアプリケーション上での見た目と若干違いが出るという残念な結果も出ています。

macOS標準装備のスクリプトメニューに入れて呼び出しています。

AppleScript名：クリップボード内のRTFをStyled Stringとして解釈して行ごとに分割して画面描画サイズ幅で昇順ソートして再結合

— Created 2017-04-24 by Shane Stanley
— Modified 2019-02-27 by Takaaki Naganoya
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()
if anAttr = missing value then return

–Split Attributed Strings into lines
set attrList to splitAttributedStringByLines(anAttr) of me

–Sort by Width in ascending
set sortedList to shellSortListAscending(attrList, 1) of me

–Append Attributed Strings
set mutableReturn to NSMutableAttributedString’s alloc()’s initWithString:(return)
set outStr to NSMutableAttributedString’s alloc()’s initWithString:""

repeat with i in sortedList
　　copy i to {tmpWidth, tmpAttr}
　　(outStr’s appendAttributedString:tmpAttr)
　　
　　set tmpStr to tmpAttr’s |string|() as string
　　if (tmpStr does not end with string id 10) and (tmpStr does not end with string id 13) then
　　　　(outStr’s appendAttributedString:mutableReturn)
　　end if
end repeat

— Set Styled String to Clipboard
set theArray to {outStr}
restoreClipboard(theArray) of me

–Clipboardにデータを設定する
on restoreClipboard(theArray as list)
　　set thePasteboard to NSPasteboard’s generalPasteboard()
　　thePasteboard’s clearContents()
　　thePasteboard’s writeObjects:theArray
end restoreClipboard

–入れ子のリストを昇順ソート
on shellSortListAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end shellSortListAscending

–入れ子のリストを降順ソート
on shellSortListDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end shellSortListDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　load framework
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　–Sort
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　return resList
end sort2DList

★Click Here to Open This Script　

クリップボード中の書式つきテキストのフォントサイズを取得する

Posted on 2月 8, 2019 by Takaaki Naganoya

クリップボードに入っているデータを書式付きテキストとして評価して取得し、そのうち最大のフォントサイズを取得するAppleScriptです。

クリップボードに入っているデータをプレーンテキストとして取得して処理することはよくやっていたのですが、書式付きテキストとして処理することはあまりやっていなかったので、試してみたものです。

AppleScript名：クリップボード中の書式つきテキストのフォントサイズを取得する.scptd

–Created 2015-08-03 by Shane Stanley
–Modified 2019-02-06 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit" — for NSPasteboard

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()
if anAttr = missing value then return 0

set maxSize to getAttributeStringFontSize(anAttr) of me
–> 13.0

— クリップボードの内容をNSAttributedStringとして取り出して返す
on getClipboardASStyledText()
　　try
　　　　set theNSPasteboard to current application’s NSPasteboard’s generalPasteboard()
　　　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({current application’s NSAttributedString}) options:(missing value)
　　　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　　　return theNSAttributedString
　　on error
　　　　return missing value
　　end try
end getClipboardASStyledText

on getAttributeStringFontSize(theStyledText)
　　set maxSize to 0
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　set theLength to theStyledText’s |length|()
　　
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to (aFont’s pointSize()) as real
　　　　end if
　　　　
　　　　if maxSize < aDFontSize then
　　　　　　set maxSize to aDFontSize
　　　　end if
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　end repeat
　　
　　return maxSize
end getAttributeStringFontSize

★Click Here to Open This Script　

Stickiesからのデータ取り出し v2

Posted on 9月 6, 2018 by Takaaki Naganoya

スティッキーズ（Stickies.app）のデータをまとめて引っこ抜いてListに入れるAppleScriptです。色情報、１行目の内容をタイトルとみなしてタイトル情報も付加して出力するようにしてみました。

オープンソースのStickiesViewerをFramework化したstickiesLib.frameworkを経由してデータを読み出します。データベースファイルから情報を直接読み取るので、Stickies.appが起動している必要はありません。

–> Download stickiesLib.framework（To ~/Library/Frameworks/）

–> {creationDate:date “2006年1月15日日曜日 11:02:32″, aTitle:”WX-310Kの画像サイズ”, modificationDate:date “2006年1月15日日曜日 11:03:09″, aContents:”WX-310Kの画像サイズ
ケータイ：120×160
壁紙：240×320″, colorName:”Yellow”}

StickiesDatabaseからまとめて一括で全部抽出するので、個別に何かのIDで指定して抽出するといった動作にはなりません。

93個のスティッキーズ書類（93個のウィンドウが表示されている状態、１つのDBを指定）から、全データを取得して本AppleScriptで0.1秒程度です。

AppleScript名：Stickiesからのデータ取り出し v2.scptd

use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use framework "AppKit"
use framework "stickiesLib"
use scripting additions

property NSColor : a reference to current application’s NSColor
property |NSURL| : a reference to current application’s |NSURL|
property SVReader : a reference to current application’s SVReader
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray

set sRes to retStickiesData() of me
–>
(*
{{creationDate:date "2006年1月15日日曜日 11:02:32", aTitle:"WX-310Kの画像サイズ", modificationDate:date "2006年1月15日日曜日 11:03:09", aContents:"WX-310Kの画像サイズ
ケータイ：120×160
壁紙：240×320", colorName:"Yellow"}, ….}
*)

on retStickiesData()
　　set dbPath to POSIX path of (path to library folder from user domain) & "StickiesDatabase"
　　set aExt to (NSFileManager’s defaultManager()’s fileExistsAtPath:dbPath) as boolean
　　
　　if aExt = false then
　　　　set dbPath to POSIX path of (choose file with prompt "Select StickiesDatabase file")
　　end if
　　
　　set aURL to |NSURL|’s fileURLWithPath:dbPath
　　set aStickDB to SVReader’s notesWithContentsOfURL:aURL
　　
　　set aList to aStickDB as list
　　
　　–スティッキーズの色データ
　　set cList to {{"Yellow", {254, 244, 156}}, {"Blue", {173, 244, 255}}, {"Green", {178, 255, 161}}, {"Pink", {255, 199, 199}}, {"Purple", {182, 202, 255}}, {"Gray", {238, 238, 238}}}
　　
　　
　　set outArray to NSMutableArray’s new()
　　
　　repeat with i in aList
　　　　set anAttrStr to i’s attributedString()
　　　　set aStr to (anAttrStr’s |string|()) as string
　　　　
　　　　set curTitle to first paragraph of aStr
　　　　
　　　　set aColor to i’s |color|()
　　　　set cDate to i’s dateCreated() as date
　　　　set mDate to i’s dateModified() as date
　　　　
　　　　set c1List to retColListFromNSColor(aColor, 255) of me
　　　　
　　　　–Find Color Name
　　　　set hitF to false
　　　　repeat with ii in cList
　　　　　　set {colName, colList} to ii
　　　　　　if c1List = colList then
　　　　　　　　set hitF to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　if hitF = false then error "Color name did not hit"
　　　　
　　　　set curName to colName
　　　　(outArray’s addObject:{creationDate:cDate, modificationDate:mDate, aContents:aStr, colorName:curName, aTitle:curTitle})
　　　　
　　end repeat
　　
　　return outArray as list
end retStickiesData

on retColorFromRGBnum(r, g, b)
　　return (NSColor’s colorWithCalibratedRed:r / 255.0 green:g / 255.0 blue:b / 255.0 alpha:1.0)
end retColorFromRGBnum

–NSColorからrgbの8bitの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

★Click Here to Open This Script　

Stickiesからのデータ取り出し

Posted on 9月 5, 2018 by Takaaki Naganoya

スティッキーズ（Stickies.app）のデータをまとめて引っこ抜いてListに入れるAppleScriptです。

オープンソースのStickiesViewerをFramework化したstickiesLib.frameworkを経由してデータを読み出します。データベースファイルから情報を直接読み取るので、Stickeys.appが起動している必要はありません。

–> Download stickiesLib.framework（To ~/Library/Frameworks/）

昔はいろいろ苦労したような気がするのですが、あっさりデータを取り出せて驚きます。

色情報も取り出していますが、色名を取り出すにはややScriptがおおげさになるので、とりあえず作成日、修正日、テキストを取り出してみました。

AppleScript名：Stickiesからのデータ取り出し v1.scptd

use AppleScript version "2.4" — Yosemite (10.10) or later
use scripting additions
use framework "Foundation"
use framework "stickiesLib" –https://github.com/kainjow/StickiesViewer

set aFile to POSIX path of (choose file default location (path to library folder from user domain) with prompt "Select StickiesDatabase file")

set aURL to current application’s |NSURL|’s fileURLWithPath:aFile
set aList to (current application’s SVReader’s notesWithContentsOfURL:aURL) as list

set outList to {}

repeat with i in aList
　　set anAttrStr to i’s attributedString()
　　set aStr to (anAttrStr’s |string|()) as string
　　
　　set aColor to i’s |color|()
　　set cDate to i’s dateCreated() as date
　　set mDate to i’s dateModified() as date
　　
　　set the end of outList to {creationDate:cDate, modificationDate:mDate, aContents:aStr}
end repeat

return outList

★Click Here to Open This Script　

WordPressの指定IDの記事にリンクされているapplescriptからCocoa Classのproperty宣言を抽出 v3

Posted on 8月 5, 2018 by Takaaki Naganoya

本BlogのようなWordPressで運用されており、AppleScriptのURLリンクを記事に埋め込んでいるWordPressに対して、XML-RPC経由で指定IDの記事本文を取得し、埋め込まれているURLリンクからAppleScriptのソースコードを取得して、メモリー上でコンパイルして書式つきテキストに変換し、AppleScript構文書式をもとにpropertyラベルを抽出、そのうちCocoa Classのみをリストで取得するAppleScriptです。

本Blogに投稿した記事から宣言しているCocoa Classを抽出し、自動でタグ付けするために準備したものです。１記事に対して複数のAppleScriptが掲載されている場合にも対応しています。

HTMLReader.frameworkを用いてBlog本文からのリンク抽出、リンクURL抽出を行っています。

–> HTMLReader.framework（To ~/Library/Frameworks/）

本Sample Scriptで指定したIDの記事のproperty部分はこのようになっており、

本Scriptの実行によって抽出されたCocoa Class（単なる変数的なproperty項目や、Enumは対象外のため排除）は、

–> {“NSString”, “NSArray”, “OSAScript”, “NSPredicate”, “OSALanguage”, “NSDictionary”, “OSALanguageInstance”, “NSBundle”, “NSUnarchiver”}

のようになります。自分の環境でMacBook Proを有線ネットワーク接続した状態で、3.3〜3.4秒程度かかっています。大量の記事を処理する場合には本AppleScriptの並列処理を行うと処理時間の大幅な短縮が期待できます（MacのCPUがサーマルスロットリングで速度低下しなければ）。

また、負荷が集中している特定コアの動作周波数を上げ、他のコアの動作周波数を落とすTurbo Boostが有効な状態で並列処理を実行すると、並列処理を行う意義そのものが低下してしまうため、Turbo-Boost-Switcherのようなツールの併用が必要と思われます。

AppleScript名：WordPressの指定IDの記事にリンクされているapplescriptからCocoa Classのproperty宣言を抽出 v3

— Created 2018-07-30 by Takaaki Naganoya
— Modified 2018-08-05 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "OSAKit"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSBundle : a reference to current application’s NSBundle
property NSThread : a reference to current application’s NSThread
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSTextView : a reference to current application’s NSTextView
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property OSAScriptView : a reference to current application’s OSAScriptView
property NSMutableArray : a reference to current application’s NSMutableArray
property OSAScriptController : a reference to current application’s OSAScriptController
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property OSALanguageInstance : a reference to current application’s OSALanguageInstance
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

set postID to 3864
set {myUser, myPass} to getAcountData() of me
set aURL to "http://piyocast.com/as/xmlrpc.php"
set cocoaClassList to getCocoaPropListFromPost(aURL, postID, myUser, myPass) of me
–>　　{"NSString", "NSBundle", "NSPredicate", "NSDictionary", "NSMutableArray", "NSMutableDictionary"}

–指定Blogの指定IDの記事にURLリンクされているAppleScriptから、Cocoa Classのpropertyのみ取得する
on getCocoaPropListFromPost(aURL, postID, myUser, myPass)
　　–AppleScriptの構文色分け設定ファイルを読み込んで、重複色のチェックを実施　　
　　set cList to getAppleScriptSourceColors() of me
　　set cRes to chkASLexicalFormatColorConfliction(cList) of me –構文色分けの重複色チェック
　　if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"
　　
　　–WordPressの指定Post IDの記事を取得してリンクされているURLからURL Schemeでフィルタして、リンクされているAppleScriptのソースを取得
　　set aScheme to "applescript://"
　　set sourceList to getASSouceLinkedInWordPressPost(postID, aURL, aScheme, myUser, myPass) of me
　　
　　–AppleScriptのソースをRAM上でコンパイル（構文確認）して、構文色分けしたRTFを取得。RTFの書式情報をparseしてattribute runsと同様のrecordを生成
　　–構文色分けをもとにproperty項目を抽出し、Cocoa Classに該当するもののみを抽出
　　set outList to {}
　　repeat with i in sourceList
　　　　set j to contents of i
　　　　set anAttrStr to compileASandReturnAttributedString(j) of me
　　　　set attrRes to getAttributeRunsFromAttrString(anAttrStr) of me
　　　　set propNames to getPropertyNamesCocoaOnly(cList, attrRes) of me
　　　　
　　　　if propNames is not equal to {} then
　　　　　　set outList to outList & propNames
　　　　end if
　　end repeat
　　
　　–1D Listのユニーク化（重複要素の排除）
　　set aArray to NSArray’s arrayWithArray:outList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　set bList to bArray as list of string or string –as anything
　　
　　return bList
end getCocoaPropListFromPost

–Property名称を取得する
on getPropertyNamesCocoaOnly(cList, aRec)
　　script spdHnd
　　　　property aRec : {}
　　end script
　　
　　set (aRec of spdHnd) to aRec
　　
　　set targAttr to contents of item 7 of cList –ハンドラあるいは変数
　　set tmpCoStr to ((redValue of targAttr) as string) & " " & ((greenValue of targAttr) as string) & " " & ((blueValue of targAttr) as string)
　　
　　set ontoColItem to contents of item 3 of cList –スクリプティング予約語（on/to）
　　set ontoCoStr to ((redValue of ontoColItem) as string) & " " & ((greenValue of ontoColItem) as string) & " " & ((blueValue of ontoColItem) as string)
　　
　　
　　–変数あるいはハンドラ名称をリストアップ(variables & handler)
　　set tmp1Array to NSArray’s arrayWithArray:(aRec of spdHnd)
　　set thePred0 to NSPredicate’s predicateWithFormat_("colorStr == %@", tmpCoStr)
　　set dArray to (tmp1Array’s filteredArrayUsingPredicate:thePred0) as list
　　
　　–改行を含むデータをリストアップ(text data contains return)
　　set thePred1 to NSPredicate’s predicateWithFormat_("stringVal CONTAINS %@", return)
　　set eArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred1)’s valueForKeyPath:"itemIndex") as list
　　
　　set the beginning of eArray to 0 –ハンドラ宣言部がTopに来る場合に備える
　　
　　–"property"（プロパティ宣言）の項目をリストアップ文字と色で抽出
　　set thePred2 to NSPredicate’s predicateWithFormat_("stringVal == %@ && colorStr == %@ ", "property", ontoCoStr)
　　set fArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
　　
　　set handlerList to {}
　　
　　–property ではじまるハンドラの抽出
　　repeat with i in eArray –改行を含むテキストのアイテム番号リスト
　　　　set j to (contents of i) as integer
　　　　repeat with ii in fArray –"on"の項目リスト
　　　　　　set jj to (contents of ii) as integer
　　　　　　
　　　　　　set handlerStr to missing value
　　　　　　
　　　　　　if (j + 1) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of ((aRec of spdHnd) as list))
　　　　　　else if (j + 2) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of ((aRec of spdHnd) as list))
　　　　　　end if
　　　　　　
　　　　　　set tmpStr to repChar(handlerStr, "|", "") of me
　　　　　　
　　　　　　if tmpStr is not in {"error", missing value} and tmpStr is not in handlerList then
　　　　　　　　–抽出したProperty宣言がCocoa Classのものかどうか判定
　　　　　　　　if searchClassInFrameworks(tmpStr) of me is not equal to false then
　　　　　　　　　　set the end of handlerList to tmpStr
　　　　　　　　end if
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　return handlerList
end getPropertyNamesCocoaOnly

–RAM上にスクリプトエディタと同じ部品を組み立て（非表示）、AppleScriptのソーステキストからObjectを生成し、Attributed Stringデータを返す
on compileASandReturnAttributedString(theSource as string)
　　set targX to 1024 –View Width
　　set targY to 2048 –View Height
　　
　　set osaCon to current application’s OSAScriptController’s alloc()’s init()
　　set osaView to current application’s OSAScriptView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, targX, targY))
　　
　　set resView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, targX, targY))
　　resView’s setRichText:true
　　resView’s useAllLigatures:true
　　
　　osaCon’s setScriptView:osaView
　　osaCon’s setLanguage:(OSALanguage’s languageForName:"AppleScript")
　　osaCon’s setResultView:resView
　　
　　osaView’s setString:theSource
　　osaCon’s compileScript:(missing value) –Compile（構文確認）
　　
　　set aRes to (osaView’s attributedString())
　　
　　return aRes
end compileASandReturnAttributedString

–Attributed StringをDictionary化
on getAttributeRunsFromAttrString(theStyledText)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　set itemCount to 1
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–String　　
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　–Color
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize, itemIndex:itemCount}
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　
　　　　set itemCount to itemCount + 1
　　end repeat
　　
　　return (styleList of aSpd)
　　
end getAttributeRunsFromAttrString

–指定クラスがいずれかのCocoa Frameworkに所属しているかを検索
on searchClassInFrameworks(aTarget)
　　set aClass to current application’s NSClassFromString(aTarget)
　　if aClass = missing value then return false
　　set theComponenents to (NSBundle’s bundleForClass:aClass)’s bundleURL’s pathComponents()
　　set thePred to NSPredicate’s predicateWithFormat:"pathExtension == ’framework’"
　　set aRes to (theComponenents’s filteredArrayUsingPredicate:thePred)’s firstObject() as list of string or string
　　return aRes
end searchClassInFrameworks

–指定Post IDのWordPress記事から、指定SchemeのURLを抽出し、AS Sourceをdecodeしてproperty行のみ抽出
on getASSouceLinkedInWordPressPost(postID, aURL, aScheme, myUser, myPass)
　　–call xmlrpc命令に対するURLの間接指定を有効にするために、AppleScriptの構文解釈機能をダミーURLでだます
　　using terms from application "http://piyocast.com/as/xmlrpc.php" –URLと判定されればなんでもいい
　　　　tell application aURL
　　　　　　set wRes to (call xmlrpc {method name:"wp.getPost", parameters:{"1", myUser, myPass, postID as string}})
　　　　end tell
　　end using terms from
　　
　　set aBody to post_content of wRes –Blog本文
　　
　　–記事中でリンクしているURLを取得し、指定のURL Schemeでフィルタする
　　set urlList to filterURLLinksByScheme(aBody, aScheme) of me
　　
　　set propList to {}
　　
　　repeat with i in urlList
　　　　set j to contents of i
　　　　set urlRec to parseQueryDictFromURLString(j) of me
　　　　set tmpScript to (urlRec’s |script|) as string –Get AppleScript Source
　　　　
　　　　set propList to propList & tmpScript
　　end repeat
　　
　　return propList
end getASSouceLinkedInWordPressPost

on parseQueryDictFromURLString(aURLStr as string)
　　if aURLStr = "" then error "No URL String"
　　
　　set aURL to |NSURL|’s URLWithString:aURLStr
　　set aQuery to aURL’s query() –Get Query string part from URL
　　if aQuery’s |length|() = 0 then return false
　　
　　set aDict to NSMutableDictionary’s alloc()’s init()
　　set aParamList to (aQuery’s componentsSeparatedByString:"&") as list
　　
　　repeat with i in aParamList
　　　　set j to contents of i
　　　　if length of j > 0 then
　　　　　　set tmpStr to (NSString’s stringWithString:j)
　　　　　　set eList to (tmpStr’s componentsSeparatedByString:"=")
　　　　　　set anElement to (eList’s firstObject()’s stringByReplacingPercentEscapesUsingEncoding:(NSUTF8StringEncoding))
　　　　　　set aValStr to (eList’s lastObject()’s stringByReplacingPercentEscapesUsingEncoding:(NSUTF8StringEncoding))
　　　　　　(aDict’s setObject:aValStr forKey:anElement)
　　　　end if
　　end repeat
　　
　　return aDict
end parseQueryDictFromURLString

–指定のHTML文字列から、Link URLを抽出し、schemeで再抽出する
on filterURLLinksByScheme(aBody, aScheme)
　　set conType to "text/html"
　　
　　–HTML文字列をいったんNSDataにしているのは、HTMLReader.frameworkの仕様のため
　　set aData to (current application’s NSString’s stringWithString:aBody)’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aHTML to current application’s HTMLDocument’s documentWithData:aData contentTypeHeader:conType
　　
　　set aTextArray to ((aHTML’s nodesMatchingSelector:"a")’s textContent) as list –リンク文字
　　set aLinkList to ((aHTML’s nodesMatchingSelector:"a")’s attributes’s valueForKeyPath:"href") as list –URL文字列
　　
　　set outList to {}
　　repeat with i in aLinkList
　　　　set j to contents of i
　　　　if j begins with aScheme then
　　　　　　set the end of outList to j
　　　　end if
　　end repeat
　　
　　return outList
end filterURLLinksByScheme

–文字置換
on repChar(origText as string, targChar as string, repChar as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceColors()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set colList to {}
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set aColRec to {redValue:rVal, greenValue:gVal, blueValue:bVal, fontName:aFontName, fontSize:aFontSize}
　　　　
　　　　set the end of colList to aColRec
　　end repeat
　　
　　return colList
end getAppleScriptSourceColors

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

–AS書式で配色に重複がないかどうかチェック
on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on returnDuplicatesOnly(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

on getAcountData()
　　return {"xxxxxxxx_xx", "XXXXXXXXXXXXXXXXXXXXXXXX"} –user name, password
end getAcountData

★Click Here to Open This Script　

RTF本文内の色を置換 v2

Posted on 2月 11, 2018 by Takaaki Naganoya

指定のRTF書類の本文中の色を置換するAppleScriptです。

指定のRTF書類内のカラーをざっくりとした色に分類し、同じくざっくりとした色名で置換対象を指定し（blue, green）、指定色（black）に色置換。結果をデスクトップ上に別名で保存します。

AppleScript名：RTF本文内の色を置換 v2

— Created 2018-01-13 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSData : a reference to current application’s NSData
property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
property NSDocumentTypeDocumentAttribute : a reference to current application’s NSDocumentTypeDocumentAttribute

set targFilePath to POSIX path of (choose file of type {"public.rtf"})
set targColorNameList to {"blue", "green"} –replace target color names
set toColor to NSColor’s blackColor() –to color
set aRes to replaceRTFColorsByColorName(targFilePath, targColorNameList, toColor, 65535) of me

–指定RTF書類本文中、名称で指定した色の該当箇所を指定色（NSColor）に置換する（複数色）
on replaceRTFColorsByColorName(targFilePath as string, targColorNameList as list, toColor, aColorMax as integer)
　　script spd
　　　　property hitList : {}
　　end script
　　
　　set (hitList of spd) to {}
　　set aFilePath to NSString’s stringWithString:(targFilePath)
　　set aData to NSData’s dataWithContentsOfFile:aFilePath options:0 |error|:(missing value)
　　set theStyledText to NSMutableAttributedString’s alloc()’s initWithData:aData options:(missing value) documentAttributes:(missing value) |error|:(missing value)
　　
　　set attrList to getAttributeRunsFromAttrString(theStyledText, aColorMax) of me
　　set attrArray to NSMutableArray’s arrayWithArray:attrList
　　
　　theStyledText’s beginEditing() ——
　　repeat with ii in targColorNameList
　　　　set jj to contents of ii
　　　　set thePred to NSPredicate’s predicateWithFormat_("colorName == %@", jj)
　　　　set (hitList of spd) to ((attrArray’s filteredArrayUsingPredicate:thePred)’s valueForKey:"rangeVal") as list
　　　　
　　　　repeat with i in (hitList of spd)
　　　　　　(theStyledText’s addAttribute:(NSForegroundColorAttributeName) value:toColor range:(contents of i))
　　　　end repeat
　　　　
　　end repeat
　　theStyledText’s endEditing() ——
　　
　　–Save RTF to desktop
　　set targFol to current application’s NSHomeDirectory()’s stringByAppendingPathComponent:"Desktop"
　　set aRes to saveStyledTextAsRTF(targFol, theStyledText) of me
　　return aRes as boolean
end replaceRTFColorsByColorName

–AttributedStringを書式でlist of record化
on getAttributeRunsFromAttrString(theStyledText, aColorMax)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–String
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　–Color
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * aColorMax
　　　　　　set aGreen to (aColor’s greenComponent()) * aColorMax
　　　　　　set aBlue to (aColor’s blueComponent()) * aColorMax
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　–Color Name
　　　　set cName to retColorName(aRed, aGreen, aBlue, aColorMax) of me
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize, rangeVal:theRange, colorName:cName}
　　　　
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　
　　end repeat
　　
　　return (styleList of aSpd)
end getAttributeRunsFromAttrString

–RGB値から色名称（だいたいの色）を計算する
on retColorName(rCol as integer, gCol as integer, bCol as integer, aColMax as integer)
　　set aCol to makeNSColorFromRGBAval(rCol, gCol, bCol, aColMax, aColMax) of me
　　set hueVal to aCol’s hueComponent() as real
　　set satVal to aCol’s saturationComponent() as real
　　set brightVal to aCol’s brightnessComponent() as real
　　
　　if satVal ≤ 0.01 then set satVal to 0.0
　　
　　if satVal = 0.0 then
　　　　if brightVal ≤ 0.2 then
　　　　　　set colName to "black"
　　　　else if (brightVal > 0.95) then
　　　　　　set colName to "white"
　　　　else
　　　　　　set colName to "gray"
　　　　end if
　　else
　　　　if hueVal ≤ (15.0 / 360) or hueVal ≥ (330 / 360) then
　　　　　　set colName to "red"
　　　　else if hueVal ≤ (45.0 / 360) then
　　　　　　set colName to "orange"
　　　　else if hueVal < (70.0 / 360) then
　　　　　　set colName to "yellow"
　　　　else if hueVal < (150.0 / 360) then
　　　　　　set colName to "green"
　　　　else if hueVal < (190.0 / 360) then
　　　　　　set colName to "cyan"
　　　　else if (hueVal < 250.0 / 360.0) then
　　　　　　set colName to "blue"
　　　　else if (hueVal < 290.0 / 360.0) then
　　　　　　set colName to "purple"
　　　　else
　　　　　　set colName to "magenta"
　　　　end if
　　end if
　　
　　return colName
end retColorName

on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: RTF

マンデルブロ集合を文字で描画してRTFとして組み立ててテキストエディットでオープン

NSAttributedStringにtab指定つきparagraph styleを指定

Pagesのテキストアイテム内の文字の実際の幅でリサイズ

FileMaker Proのテキストフィールドにスタイル付きテキストを代入

クリップボードに入ったStyled Stringからフォントとサイズと文字内容の情報を取得

インライン画像つきスタイル付きテキストの作成 v1b

choose style lib

choose style fromコマンド

choose contens by style fromコマンド

filter by styleコマンド

extract stylesコマンド

指定のフォントとサイズに該当するテキストを抽出する v3

Skimでオープン中のPDFで選択中のテキストを返す

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

クリップボード中の書式つきテキストのフォントサイズを取得する

Stickiesからのデータ取り出し v2

Stickiesからのデータ取り出し

RTF本文内の色を置換 v2