アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

Posted on 12月 23, 2019 by Takaaki Naganoya

アラートダイアログ上にTableViewを表示し、複数キーの組み合わせによって項目抽出。選択項目のデータを返すAppleScriptです。

あくまで試作品なので、あちらこちらに「お可愛らしい」実装が転がっています。NSBoxがまだまともに使いこなせていないあたりとか（Xcode上で部品として配置するのは楽勝ですが、プログラムから動的に生成して使用するのは別なので）。

抽出キー数は可変で外部から指定できるとよいのですが、本Scriptでは固定です。また、各抽出条件も外部から供給するのが本来あるべき姿ですが、ハードコーディングしています。

あと、TableViewの下側に謎の余白があるのは、めんどくさくなってそのまま放置しています。これで外部から各種パラメータを指定できるようにして、sdefつけて１命令で呼び出せるようにしておけば、レコード数の多い選択項目から条件抽出しつつ項目選択できてよいでしょう。

プログラム内容自体は、高度でもなければ高尚でもありません。実にダラダラとGUI部品のパラメータを設定しているだけです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

— Created 2019-12-22 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSBox : a reference to current application’s NSBox
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSPopUpButton : a reference to current application’s NSPopUpButton
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSCompoundPredicate : a reference to current application’s NSCompoundPredicate
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
　　
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　property aSel : 0
　　property bSel : 0
　　property cSel : 0
　　property predList : {}
　　property a1Button : missing value
　　property a2Button : missing value
　　property a3Button : missing value
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 400
　　　　set my aSel to 0
　　　　set my bSel to 0
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　
　　　　
　　　　–BOX Aをつくる
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 60, aWidth, 60)))
　　　　(aBox’s setTitle:("Filter Condition"))
　　　　
　　　　–このあたり、項目数に合わせてUIを可変で生成するように（本Scriptは試作品なので、決め打ちでUI生成）
　　　　set a1Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 200, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:{"▼Select Item", "MacBook", "iMac", "mini", "Air", "Pro"})
　　　　a1Button’s setTarget:(me)
　　　　a1Button’s setAction:("mySelector:")
　　　　a1Button’s setEnabled:(true)
　　　　
　　　　set a2Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(220, 0, 200, 30)) pullsDown:false)
　　　　a2Button’s removeAllItems()
　　　　(a2Button’s addItemsWithTitles:{"▼Select Item", "150000", "200000", "300000", "400000", "600000"})
　　　　a2Button’s setTarget:(me)
　　　　a2Button’s setAction:("mySelector:")
　　　　a2Button’s setEnabled:(true)
　　　　
　　　　set a3Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(440, 0, 200, 30)) pullsDown:false)
　　　　a3Button’s removeAllItems()
　　　　(a3Button’s addItemsWithTitles:{"▼Select Item", "デュアルコア", "クアッドコア", "6コア", "8コア"})
　　　　a3Button’s setTarget:(me)
　　　　a3Button’s setAction:("mySelector:")
　　　　a3Button’s setEnabled:(true)
　　　　
　　　　
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s addSubview:a2Button)
　　　　(aBox’s addSubview:a3Button)
　　　　
　　　　
　　　　–BOX Bをつくる
　　　　set bBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 80)))
　　　　(bBox’s setTitle:("Data"))
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 150, labelSortList) of me
　　　　
　　　　(bBox’s addSubview:aScroll)
　　　　
　　　　parentView’s setSubviews:{aBox, bBox}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on mySelector:aObject
　　　　set aIndex to (aObject’s indexOfSelectedItem()) as number
　　　　filterByMultipleCondition() of me
　　end mySelector:
　　
　　
　　
　　on filterByMultipleCondition()
　　　　set prediCatesArray to {}
　　　　
　　　　set aInd to (my a1Button’s indexOfSelectedItem()) as number
　　　　set bInd to (my a2Button’s indexOfSelectedItem()) as number
　　　　set cInd to (my a3Button’s indexOfSelectedItem()) as number
　　　　
　　　　if {aInd, bInd, cInd} = {0, 0, 0} then
　　　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　　　tView’s reloadData()
　　　　　　return
　　　　end if
　　　　
　　　　–このあたり、複数条件をハードコーディングしているのは超絶頭悪い。項目数の増減に対応できるべき
　　　　if aInd > 0 then
　　　　　　set aTitle to (my a1Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field1 contains ’" & aTitle & "’"
　　　　end if
　　　　
　　　　if bInd > 0 then
　　　　　　set bTitle to (my a2Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field2.integerValue < " & bTitle
　　　　end if
　　　　
　　　　if cInd > 0 then
　　　　　　set cTitle to (my a3Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field3 contains ’" & cTitle & "’"
　　　　end if
　　　　
　　　　–データ抽出
　　　　set tmpList to filterDictArrayByLabel3((my aDataList), prediCatesArray) of me
　　　　
　　　　–データ再表示
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(tmpList)
　　　　tView’s reloadData()
　　end filterByMultipleCondition
　　
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出（複数PredicatesをANDで合成）
　　on filterDictArrayByLabel3(origArray as list, aPredicateList as list)
　　　　set aArray to NSMutableArray’s arrayWithArray:origArray
　　　　set predArray to NSMutableArray’s new()
　　　　
　　　　repeat with i in aPredicateList
　　　　　　(predArray’s addObject:(NSPredicate’s predicateWithFormat:(contents of i)))
　　　　end repeat
　　　　
　　　　set pred to current application’s NSCompoundPredicate’s andPredicateWithSubpredicates:predArray
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:pred
　　　　
　　　　return filteredArray
　　end filterDictArrayByLabel3
end script

★Click Here to Open This Script　

ジャンル名名寄せ v2

Posted on 11月 27, 2019 by Takaaki Naganoya

iTunes/Musicのライブラリに入っている楽曲データのジャンル分けのゆらぎ吸収を行う、ジャンル名のいわゆる「名寄せ」を行うAppleScriptです。

▲１つのアルバム中でもジャンル名に表記ゆれがあるのは勘弁してほしい

iTunes/Musicライブラリ中の全楽曲の最終再生日時を24時間の各時で集計を行い、ジャンルごとに再生時間に偏りがないかどうかを分析するため、さらにジャンルごろに集計してみました。

「名寄せ」（なよせ）は昔から情報処理に見られる泥臭い地道な処理で、データ上の表記ゆれを吸収するための処理です。地名などの固有名詞で多く見られます（念のためにWikipediaで調べたら、異なる業界では割とブラックな言葉として用いられている模様）。

このジャンル名が英語で入っていたり日本語で入っていたりと、ゆらぎが発生しているので、同様のジャンル名であれば同じものとして合算して集計してみました。

また、英語で表記されたジャンル名ではなく日本語で表記されたものを採用（＝すべてアルファベットで書かれたものを不採用）しています。まだ、それほどいじめ抜いていない（自分の環境でしかテストしていない）ので、ジャンル名の名寄せリストはもう少し鍛えておく必要があるものと思っています。

AppleScript名：ジャンル名名寄せ v2

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/24
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use scripting additions

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSScanner : a reference to current application’s NSScanner
property NSPredicate : a reference to current application’s NSPredicate
property NSMutableCharacterSet : a reference to current application’s NSMutableCharacterSet

–ジャンル名寄せリスト（2要素から構成される2D List）
set genreNayoseList to {{"World", "ワールド"}, {"Anime", "アニメ"}, {"Electronic", "エレクトロニック"}, {"R&B/ソウル", "R&B／ソウル"}, {"Kayokyoku", "歌謡曲"}, {"Electronic", "エレクトロニック"}, {"Vocal", "ヴォーカル"}, {"Classical", "クラシック"}, {"Dance", "ダンス"}, {"Soundtrack", "サウンドトラック"}}

–名寄せ対象リスト（genreNameを名寄せ）
set aList to {{genreName:"シンガーソングライター", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 2, 1, 0, 0, 0, 1, 5, 0, 0, 0, 0}}, {genreName:"ロック", playingList:{2, 2, 0, 0, 0, 1, 0, 0, 4, 3, 9, 5, 11, 11, 22, 19, 48, 17, 28, 15, 2, 11, 13, 1}}, {genreName:"Soundtrack", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0}}, {genreName:"World", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0}}, {genreName:"演歌", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 4, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"ホリデーミュージック", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"ディズニー", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 15, 0, 0, 0, 0, 0}}, {genreName:"J-Pop", playingList:{4, 0, 1, 1, 2, 1, 5, 3, 2, 3, 27, 19, 14, 26, 17, 20, 28, 32, 40, 25, 10, 10, 6, 6}}, {genreName:"ヒップホップ/ ラップ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"Electronic", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"アニメ", playingList:{7, 1, 0, 0, 7, 2, 0, 0, 0, 9, 23, 45, 17, 10, 17, 50, 48, 65, 53, 27, 12, 16, 23, 45}}, {genreName:"ポップ", playingList:{3, 0, 0, 0, 0, 0, 0, 3, 1, 6, 2, 9, 7, 0, 11, 7, 8, 10, 7, 5, 3, 1, 0, 1}}, {genreName:"Kayokyoku", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}}, {genreName:"ヒップホップ／ラップ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"Dance", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}}, {genreName:"ダンス", playingList:{0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 2, 0, 0}}, {genreName:"R&B/ソウル", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"Anime", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 7, 0, 0, 0, 0, 1, 2, 1, 0, 0, 0, 0, 0}}, {genreName:"チルドレン・ミュージック", playingList:{0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"Classical", playingList:{1, 1, 0, 0, 2, 1, 8, 1, 0, 0, 11, 5, 2, 0, 4, 9, 13, 2, 2, 0, 0, 0, 0, 0}}, {genreName:"ニューエイジ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 12, 0, 0, 0, 0}}, {genreName:"Pop", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0}}, {genreName:"ヴォーカル", playingList:{0, 0, 0, 0, 0, 1, 0, 0, 0, 6, 7, 0, 0, 1, 6, 0, 0, 3, 1, 0, 3, 0, 0, 0}}, {genreName:"サウンドトラック", playingList:{23, 31, 0, 0, 0, 2, 1, 0, 7, 7, 27, 29, 26, 25, 28, 48, 66, 76, 56, 16, 8, 31, 6, 10}}, {genreName:"歌謡曲", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 4, 2, 4, 5, 5, 4, 6, 6, 7, 1, 0, 0, 0}}, {genreName:"ホリデー", playingList:{0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 2, 0, 0, 0, 0, 0}}, {genreName:"Folk", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0}}, {genreName:"ジャズ", playingList:{0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 16, 7, 3, 9, 0, 5, 10, 20, 10, 2, 1, 0, 0}}, {genreName:"エレクトロニック", playingList:{0, 1, 3, 0, 0, 0, 0, 1, 4, 13, 8, 13, 2, 18, 6, 13, 10, 16, 25, 7, 8, 0, 2, 10}}, {genreName:"ワールド", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 4, 0, 0, 1, 0, 5, 5, 7, 6, 0, 0, 0, 0, 0}}, {genreName:"インストゥルメンタル", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}}, {genreName:"Vocal", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"クラシック", playingList:{0, 0, 1, 1, 0, 3, 2, 0, 4, 3, 13, 11, 24, 1, 21, 14, 24, 38, 21, 7, 5, 8, 4, 5}}, {genreName:"オルタナティブ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 2, 1, 0, 0, 6, 9, 0}}, {genreName:"R&B／ソウル", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}}

set bList to genreNayoseAndUnify(aList, genreNayoseList) of me
–> {{genreName:"シンガーソングライター", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 2, 1, 0, 0, 0, 1, 5, 0, 0, 0, 0}}, {genreName:"ロック", playingList:{2, 2, 0, 0, 0, 1, 0, 0, 4, 3, 9, 5, 11, 11, 22, 19, 48, 17, 28, 15, 2, 11, 13, 1}}, {genreName:"サウンドトラック", playingList:{23, 31, 0, 0, 0, 2, 1, 0, 7, 7, 28, 29, 26, 25, 28, 48, 66, 77, 56, 16, 8, 31, 6, 10}}, {genreName:"ワールド", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 4, 0, 0, 1, 0, 5, 5, 8, 6, 0, 0, 0, 0, 0}}, {genreName:"演歌", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 4, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"ホリデーミュージック", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"ディズニー", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 15, 0, 0, 0, 0, 0}}, {genreName:"J-Pop", playingList:{4, 0, 1, 1, 2, 1, 5, 3, 2, 3, 27, 19, 14, 26, 17, 20, 28, 32, 40, 25, 10, 10, 6, 6}}, {genreName:"ヒップホップ/ ラップ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"エレクトロニック", playingList:{0, 1, 3, 0, 0, 0, 0, 1, 4, 13, 8, 13, 2, 19, 6, 13, 10, 16, 25, 7, 8, 0, 2, 10}}, {genreName:"アニメ", playingList:{7, 1, 0, 0, 7, 2, 0, 0, 0, 9, 23, 52, 17, 10, 17, 50, 49, 67, 54, 27, 12, 16, 23, 45}}, {genreName:"ポップ", playingList:{3, 0, 0, 0, 0, 0, 0, 3, 1, 6, 2, 9, 7, 0, 11, 7, 8, 10, 7, 5, 3, 1, 0, 1}}, {genreName:"歌謡曲", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 4, 2, 4, 5, 5, 4, 6, 7, 7, 1, 0, 0, 0}}, {genreName:"ヒップホップ／ラップ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"ダンス", playingList:{0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 2, 0, 0, 2, 0, 0}}, {genreName:"R&B/ソウル", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"チルドレン・ミュージック", playingList:{0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}}, {genreName:"クラシック", playingList:{1, 1, 1, 1, 2, 4, 10, 1, 4, 3, 24, 16, 26, 1, 25, 23, 37, 40, 23, 7, 5, 8, 4, 5}}, {genreName:"ニューエイジ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 12, 0, 0, 0, 0}}, {genreName:"Pop", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0}}, {genreName:"ヴォーカル", playingList:{0, 0, 0, 0, 0, 1, 0, 0, 0, 6, 7, 0, 0, 1, 6, 1, 0, 3, 1, 0, 3, 0, 0, 0}}, {genreName:"ホリデー", playingList:{0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 2, 0, 0, 0, 0, 0}}, {genreName:"Folk", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0}}, {genreName:"ジャズ", playingList:{0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 16, 7, 3, 9, 0, 5, 10, 20, 10, 2, 1, 0, 0}}, {genreName:"インストゥルメンタル", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}}, {genreName:"オルタナティブ", playingList:{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 2, 1, 0, 0, 6, 9, 0}}}

on genreNayoseAndUnify(aList as list, genreNayoseList as list)
　　set gList to FlattenList(genreNayoseList) of me
　　
　　set didProc to {}
　　
　　set a2List to {}
　　
　　repeat with i in aList
　　　　set aGenre to genreName of i
　　　　
　　　　if (aGenre is in gList) and (aGenre is not in didProc) then
　　　　　　
　　　　　　repeat with ii in genreNayoseList
　　　　　　　　set jj to contents of ii
　　　　　　　　
　　　　　　　　if aGenre is in jj then
　　　　　　　　　　copy jj to {g1, g2}
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　if chkAlphabet(g1) of me = true then
　　　　　　　　　　　　set targG to g2
　　　　　　　　　　　　set targG2 to g1
　　　　　　　　　　else
　　　　　　　　　　　　set targG to g1
　　　　　　　　　　　　set targG2 to g2
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　　　set s1Res to searchByGenreName(aList, targG) of me
　　　　　　　　　　set s2Res to searchByGenreName(aList, targG2) of me
　　　　　　　　　　
　　　　　　　　　　set s3Res to addMutipleLists({s1Res, s2Res}) of me
　　　　　　　　　　
　　　　　　　　　　set outRec to {genreName:targG, playingList:s3Res}
　　　　　　　　　　set the end of didProc to g1
　　　　　　　　　　set the end of didProc to g2
　　　　　　　　　　
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　　　
　　　　　　end repeat
　　　　　　
　　　　　　set the end of a2List to outRec
　　　　else
　　　　　　if (aGenre is not in didProc) then
　　　　　　　　set the end of a2List to contents of i
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return a2List
end genreNayoseAndUnify

on searchByGenreName(aList as list, aGenreName as string)
　　set predicatesStr to "genreName == ’" & aGenreName & "’"
　　set anArray to (NSArray’s arrayWithArray:aList)
　　set aPred to (NSPredicate’s predicateWithFormat:predicatesStr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred)
　　
　　set bbRes to first item of bRes
　　return (playingList of bbRes) as list
end searchByGenreName

on addMutipleLists(s1List)
　　script spdAdd
　　　　property s1List : {}
　　　　property s3List : {}
　　end script
　　
　　copy s1List to (s1List of spdAdd) –init
　　
　　set s1Len to length of first item of (s1List of spdAdd)
　　set (s3List of spdAdd) to makeZero1DList(s1Len, 0) of me
　　
　　repeat with i in (s1List of spdAdd)
　　　　set tmpLen to length of i
　　　　if tmpLen is not equal to s1Len then return false
　　　　
　　　　repeat with ii from 1 to s1Len
　　　　　　set tmp1 to contents of item ii of (s3List of spdAdd)
　　　　　　set tmp2 to contents of item ii of i
　　　　　　
　　　　　　set item ii of (s3List of spdAdd) to (tmp1 + tmp2)
　　　　end repeat
　　end repeat
　　
　　return (s3List of spdAdd)
end addMutipleLists

–指定要素を指定回数追加したリストを作成する
on makeZero1DList(itemMax, itemElem)
　　set allData to {}
　　repeat itemMax times
　　　　set the end of allData to itemElem
　　end repeat
　　return allData
end makeZero1DList

–By Paul Berkowitz
–2009年1月27日 2:24:08:JST
–Re: Flattening Nested Lists
on FlattenList(aList)
　　set oldDelims to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to {"????"}
　　set aString to aList as text
　　set aList to text items of aString
　　set AppleScript’s text item delimiters to oldDelims
　　return aList
end FlattenList

— アルファベットのみか調べて返す
on chkAlphabet(checkString)
　　set aStr to NSString’s stringWithString:checkString
　　set allCharSet to NSMutableCharacterSet’s alloc()’s init()
　　allCharSet’s addCharactersInRange:(current application’s NSMakeRange(ASCII number of "a", 26))
　　allCharSet’s addCharactersInRange:(current application’s NSMakeRange(ASCII number of "A", 26))
　　set aBool to my chkCompareString:aStr baseString:allCharSet
　　return aBool as boolean
end chkAlphabet

on chkCompareString:checkString baseString:baseString
　　set aScanner to NSScanner’s localizedScannerWithString:checkString
　　aScanner’s setCharactersToBeSkipped:(missing value)
　　aScanner’s scanCharactersFromSet:baseString intoString:(missing value)
　　return (aScanner’s isAtEnd()) as boolean
end chkCompareString:baseString:

★Click Here to Open This Script　

Safariで現在見えている表を抽出してCSV書き出しv3

Posted on 10月 8, 2019 by Takaaki Naganoya

Safariの最前面のウィンドウで表示中のページのうち、現在ウィンドウ内に表示中の表要素をCSV書き出ししてNumbersでオープンするAppleScriptの改良版です。HTMLのtable中にrowspan（複数セルを行方向に連結）とcolspan（複数セルを列方向に連結）の属性値が指定されていた場合に対応します。

–> Download table2CSV_visibleonly_v2 (Code-Signed AppleScript applet with Framework and Library in its bundle)

各DOM ElementsのWebコンテンツ中の表示座標を取得して、絞り込みを行なっています。ただし、各DOM座標はWebブラウザのスクロールにしたがって数値が変わる（相対座標）ため、少々手こずりました。また、本Scriptでは上下スクロールのみ考慮してDOM要素の抽出を行なっており、横に長いページの横方向スクロールは考慮しておりません。

このバージョンではrowspan / colspanへの対処を追加しました。

行単位で（１次元配列ベースで）表を作っていてはとても対処できなかったので、HTMLの表と同じセル数のヌル文字が入った２次元配列を作成し、そこにX座標/Y座標を指定してセルを埋めるように処理内容を変更しました。また、rowspan/colspanの属性を見つけた場合には、結合されていた複数セルを個別の（同じ値を入れた）セルに分解しています。

本バージョンでは、１つのセル（td）でrowspanとcolspanを同時に指定しないことが処理の前提条件となっています。また、一番上の行がヘッダーの場合を想定しており、一番左の列がヘッダーになっているケースには対処しておりません。

AppleScript名：Safariで現在見えている表を抽出してCSV書き出しv3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/22
–　　Modified on: 2019/10/07
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader
use aLib : script "arrayLib"

property NSUUID : a reference to current application’s NSUUID
property NSString : a reference to current application’s NSString
property HTMLDocument : a reference to current application’s HTMLDocument
property NSMutableArray : a reference to current application’s NSMutableArray
property NSJSONSerialization : a reference to current application’s NSJSONSerialization

set aTag to "table"

set indRes to getVisibleElementIndexList(aTag) of me
if indRes = false or indRes = {} then
　　display notification "No Visible Table in Web browser"
　　return
end if

tell application "Safari"
　　tell front document
　　　　set aSource to source
　　end tell
end tell

repeat with i in indRes
　　set inList to filterATableAndPaseCells(aSource, i, aTag) of me
　　
　　if inList = false or inList = {} then return
　　set aUUID to current application’s NSUUID’s UUID()’s UUIDString() as text
　　set aNewFile to ((path to desktop) as string) & aUUID & ".csv"
　　saveAsCSV(inList, aNewFile) of me
　　
　　tell application "Numbers"
　　　　activate
　　　　open (aNewFile as alias)
　　end tell
end repeat

on filterATableAndPaseCells(aSource as string, targInd as integer, aTag as string)
　　set aHTML to current application’s HTMLDocument’s documentWithString:(aSource as string)
　　
　　–Table要素をリストアップ
　　set eList to (aHTML’s nodesMatchingSelector:aTag) as list
　　set aObj to contents of item (targInd + 1) of eList
　　
　　–Count columns of Table Header (Count only)
　　set aTableHeader to (aObj’s nodesMatchingSelector:"tr")’s firstObject()
　　set hList to aTableHeader’s nodesMatchingSelector:"th"
　　set hStrList to {}
　　repeat with i1 in hList
　　　　set hCellStr to i1’s textContent() as string
　　　　set the end of hStrList to (hCellStr)
　　end repeat
　　set hLen to length of hStrList –count columns
　　
　　
　　–Acquire whole table body contents
　　set aTableBody to (aObj’s nodesMatchingSelector:"tbody")’s firstObject()
　　set bList to (aTableBody’s nodesMatchingSelector:"tr") as list
　　
　　set rCount to (length of bList) –count rows
　　
　　–行単位ループ
　　set yCount to 1
　　set attrList to make2DBlankArray(hLen, rCount) of aLib
　　
　　repeat with i2 in bList
　　　　set bb2List to {}
　　　　set i3 to (i2’s nodesMatchingSelector:"th") as list
　　　　if i3 = {} then
　　　　　　set i3 to (i2’s nodesMatchingSelector:"td") as list
　　　　end if
　　　　
　　　　–カラム単位ループ
　　　　set xCount to 1
　　　　repeat with i4 in i3
　　　　　　set anAttr to i4’s attributes()
　　　　　　set colAtr to (anAttr’s valueForKey:"colspan")
　　　　　　set rowAttr to (anAttr’s valueForKey:"rowspan")
　　　　　　set cellStr to i4’s textContent() as string
　　　　　　
　　　　　　if colAtr is not equal to missing value then
　　　　　　　　–colspan処理
　　　　　　　　set colNum to colAtr as integer
　　　　　　　　set attrList to xFill(xCount, yCount, attrList, cellStr, colNum) of aLib
　　　　　　　　
　　　　　　else if rowAttr is not equal to missing value then
　　　　　　　　–rowspan処理
　　　　　　　　set rowNum to rowAttr as integer
　　　　　　　　set attrList to yFill(xCount, yCount, attrList, cellStr, rowNum) of aLib
　　　　　　　　
　　　　　　else if cellStr is not equal to "" then
　　　　　　　　–通常処理
　　　　　　　　repeat with ii from xCount to hLen
　　　　　　　　　　set aRes to getItemByXY(ii, yCount, attrList, "") of aLib
　　　　　　　　　　if aRes = "" then
　　　　　　　　　　　　set attrList to setItemByXY(ii, yCount, attrList, cellStr) of aLib
　　　　　　　　　　　　exit repeat
　　　　　　　　　　else
　　　　　　　　　　　　set xCount to xCount + 1
　　　　　　　　　　end if
　　　　　　　　end repeat
　　　　　　　　
　　　　　　end if
　　　　　　
　　　　　　set xCount to xCount + 1
　　　　end repeat
　　　　
　　　　set yCount to yCount + 1
　　end repeat
　　
　　return attrList
end filterATableAndPaseCells

–Safariのウィンドウ上で表示中のDOM Elementsを座標計算して返す
on getVisibleElementIndexList(aTag as string)
　　tell application "Safari"
　　　　set dCount to count every document
　　　　if dCount = 0 then return false
　　　　
　　　　set jRes to do JavaScript "var winWidth = window.innerWidth,
winHeight = window.innerHeight,
winLeft = window.scrollX,
winTop = window.scrollY,
winBottom = winTop + winHeight,
winRight = winLeft + winWidth,
　　　　elementsArray = document.body.getElementsByTagName(’" & aTag & "’),
　　　　elemLen = elementsArray.length,
inView = [];
　　　　　　
　　　　var step;
　　　　for (step = 0 ; step < elemLen ; step++) {
　　　　　　var tmpElem = document.body.getElementsByTagName(’" & aTag & "’)[step];
　　　　　　var bVar = tmpElem.getBoundingClientRect();
　　　　　　if (bVar.top > 0 && bVar.top < winHeight) {
　　　　　　　　inView.push(step);
　　　　　　}
　　　　}
　　　　JSON.stringify(inView);" in front document
　　　　
　　　　set jList to parseJSONAsList(jRes) of me
　　　　return jList
　　　　
　　end tell
end getVisibleElementIndexList

on parseJSONAsList(jsRes as string)
　　set jsonString to NSString’s stringWithString:jsRes
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　return aJsonDict as list
end parseJSONAsList

–Save 2D List to CSV file
on saveAsCSV(aList as list, aPath)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　writeToFileAsUTF8(wholeText, bPath, false) of me
　　
end saveAsCSV

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

PDFのサイズをpointで取得 v2

Posted on 9月 28, 2019 by Takaaki Naganoya

指定PDFのサイズ（幅、高さ）をPointで取得するAppleScriptです。

以前に掲載したバージョンでは、macOS 10.13以降でboundsの値の返り方が変わったことに対応できていないので（それ以前に作ったので無理もないというか、勝手にAppleが仕様を変えたのが悪い）、対処してみました。

AppleScript名：PDFのサイズをpointで取得 v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/28
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "Quartz"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property PDFDocument : a reference to current application’s PDFDocument

set aHFSPath to (choose file of type {"com.adobe.pdf"} with prompt "Select PDF")
set sizeRes to retPDFSizeInfo(aHFSPath) of me
–>　　{width:595.28, height:841.89}

–PDFのサイズを取得する（単位：Point）
on retPDFSizeInfo(aHFSPath)
　　set aPOSIX to POSIX path of aHFSPath
　　set aURL to (|NSURL|’s fileURLWithPath:aPOSIX)
　　
　　set aPDFdoc to PDFDocument’s alloc()’s initWithURL:aURL
　　set pCount to aPDFdoc’s pageCount()
　　set aPage to aPDFdoc’s pageAtIndex:0
　　
　　set aBounds to aPage’s boundsForBox:(current application’s kPDFDisplayBoxMediaBox)
　　
　　set aClass to class of aBounds
　　if aClass = record then
　　　　set aSize to |size| of aBounds
　　else if aClass = list then
　　　　set aWidth to item 1 of item 2 of aBounds
　　　　set aHeight to item 2 of item 2 of aBounds
　　　　set aSize to {width:aWidth, height:aHeight}
　　else
　　　　error "Wrong PDF….Can not get bounds from PDF"
　　end if
　　
　　return aSize
end retPDFSizeInfo

★Click Here to Open This Script　

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

Posted on 9月 21, 2019 by Takaaki Naganoya

バンドルIDで指定したアプリケーションのResourcesフォルダ中の、指定ロケールのstringsファイルをすべて読み込んでkeyを取り出すAppleScriptです。

アプリケーション内の指定のローカライズしたメッセージ（テキスト）の内容を取り出すことはできますが、そのためにはキーを知っておく必要があります。そのキーを取り出してローカライズされた文字列を取り出すため、キーを調査してみました。

これをそのまま何かのツールなりScriptに使うというものではなく、いわゆる「下調べ」のためのScriptの部品です。

ほぼ、ありもののルーチンを再利用しただけのプログラムでできていますが、ありものはありもので、数千本のAppleScriptのストックからそれを探し出してくるのも一苦労です。

アプリケーションバンドル内のResourcesフォルダ以下の（各lprojフォルダ以下の）stringsファイルの中身はまんま（シリアライズした）NSDictionaryなので、そのままDictionaryに読み込んでallkey()などのメソッドを実行できます。昔のstringsファイルはテキストファイルだったような気がしますが、テキストファイルだとparseしないといけないんで、ビルド時にparseしておいてDictionaryの状態でファイルに書いておくのは正しいと思います。

Xcode 8あたりから、アプリケーションのローカライズのルールが変更になったようで、基本となる言語環境がBase.lprojになり、英語はen.lprojといった１ローカライズ言語という位置付けに変更になりました。

NSLocalizedStringFromTableInBundleを使ってアクセスしようかとも思ったのですが、こちらはまだ目的を達成できていません。

▲Xcode 11上で実験的に作成したAppleScriptアプリケーションのバンドル構造（左）。ローカライズしていない状態だとEnglishではなくBase.lprojが作成される。右はKeynote.app/Contents/Resources/ja.lprojフォルダの内容。stringsファイルが大量に存在している

AppleScript名：指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants

set targID to "com.apple.iWork.Keynote"

set bRes to getLocalizationsFromBundleID(targID) of me
–>　　{"de", "he", "en_AU", "ar", "el", "ja", "en", "uk", "es_419", "zh_CN", "es", "da", "it", "sk", "pt_PT", "ms", "sv", "cs", "ko", "Base", "no", "hu", "zh_HK", "tr", "pl", "zh_TW", "en_GB", "vi", "ru", "fr_CA", "fr", "fi", "id", "nl", "th", "pt", "ro", "hr", "hi", "ca"}

set curLang to first item of (choose from list bRes)
set aPath to retPathFromBundleID(targID) of me

set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

set aMDict to NSMutableDictionary’s new()

repeat with i in sList
　　set j to contents of i
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:j)
　　(aMDict’s addEntriesFromDictionary:aDict)
end repeat

return aMDict’s allKeys() as list
–> {"Interactive Bubble Chart", "Rehearse Slideshow", "PMT_ARGUMENT_1", "ACCRINTM_ARGUMENT_4_MODE_0", "Truck_378",….}

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　

2つのレコードのキーの重複を計算

Posted on 9月 7, 2019 by Takaaki Naganoya

2つのレコードのキーの重複を検出するAppleScriptです。

こういう処理がお手軽にできるようになったので、macOS 10.10以降のAppleScriptでないとプログラムが組めなくなっている今日このごろ。死ぬほど努力してOld Style AppleScript（Cocoaの機能を使わない）だけで組めないこともないですが、それだけで半日は費やして数百行のプログラムになってしまいそうです。

というわけで、Cocoaの機能を利用した「ありもの」のルーチンを組み合わせるだけでほぼ完成。２つのレコードのキーの重複計算を行います。

どういう用途で使うかといえば、パラメータつきのURLに対して追加パラメータを付加したい場合です。URLからレコード形式でパラメータを分離し、追加パラメータ（レコード形式）を足し算する「前」に、２つのレコード間で重複キーがないかチェックする、という用途です。

では、２つのレコードの加算はどーするのか？　という話になりますが、それは単に&演算子で加算するだけです。

set aRec to {abc:"1", bcd:"2"}
set bRec to {ccc:"0", ddd:"9"}
set cRec to aRec & bRec
–> {abc:"1", bcd:"2", ccc:"0", ddd:"9"}

★Click Here to Open This Script　

AppleScript名：2つのレコードのキーの重複を計算.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/06
—
–　　Copyright © 2019 jp.piyomarusoft, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSSet : a reference to current application’s NSSet
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

set aRec to {autoplay:"1", hd:"9"}
set bRec to {v:"GP_tVXTYdmY", t:"120", hd:"3"}

set dupKeys to detectDuplicateKeysInTwoRecords(aRec, bRec) of me
–> {"hd"}

on detectDuplicateKeysInTwoRecords(aRec, bRec)
　　set aDict to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set bDict to NSMutableDictionary’s dictionaryWithDictionary:bRec
　　
　　set aKeyList to (aDict’s allKeys()) as list
　　set bKeyList to (bDict’s allKeys()) as list
　　
　　set allKeyList to aKeyList & bKeyList
　　
　　set aRes to returnDuplicatesOnly(allKeyList) of me
　　return aRes
end detectDuplicateKeysInTwoRecords

–1D Listから重複項目のみ返す
on returnDuplicatesOnly(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　

recordの値をラベルを指定して変更

Posted on 7月 23, 2019 by Takaaki Naganoya

record型変数に対して、ラベルを指定して変更するAppleScriptです。各種データ型に対応しています。

AppleScriptの属性値ラベル付きデータであるrecord型変数は、さまざまな操作のための方法が（まっとうな手段では）存在せず、使いこなすためにはまっとうでない方法がよく使われてきました（動的にrecordを生成するAppleScriptのテキストを作成してrun scriptで実行するとか。提唱者本人が書いているので間違いない）。

特定のラベルを指定してデータを取り出したり、設定したりはできますが、ラベルを動的に生成して設定するようなことはできませんし、指定のラベルが存在するかどうかを確認する機能もありません（エラートラップを仕掛けて値の取り出しを確認するぐらい？）。

macOS 10.10で全面的にCocoaの機能が利用できるようになってからは、recordを操作するにはCocoaのオブジェクト（NSDictionary, NSMutableDictionary）に変換し、Cocoaの機能を使って加工することが一般的になってきました。

CocoaのNSDictionary/NSMutableDictionaryにはAppleScriptのGUIアプリケーションのオブジェクトは格納できませんが、アプリケーションのオブジェクトを扱わない用途には問題ありません。

本Scriptは、そんな中で（巨大なAppleScriptのプログラムを書く中で）些細なサブルーチンを整備する必要があったために書いたものです。こういう細かい部品を積み重ねていくと、いろいろと巨大な概念を積み上げていくのに便利なもので。

数値に足し算しかできないの？　という指摘はあるかもしれませんが、そこはマイナスの数を指定することで引き算は実現できます。

もちろん、この処理はPure AppleScriptだけで書くこともできます。

set aRec to {columnAdr:2, rowAdr:2, tableName:"table1", sheetName:"Sheet1", docName:"numbTest", cellValue:"AAA"}
set tmpVal to aRec’s rowAdr
set tmpVal to tmpVal – 1
set aRec’s rowAdr to tmpVal

return aRec
–> {columnAdr:2, rowAdr:1, tableName:"table1", sheetName:"Sheet1", docName:"numbTest", cellValue:"AAA"}

★Click Here to Open This Script　

本ルーチン（↓）では、記述性を高め、取り出したり入れたりといった記述を省略することが目的です。

＃　本ルーチンを実戦投入してみたら、意外と使えなかったというオチが（＾ー＾；；；

AppleScript名：recordの値をラベルを指定して変更.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/23
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aRec to {columnAdr:2, rowAdr:2, tableName:"table1", sheetName:"Sheet1", docName:"numbTest", cellValue:{"AAA"}}

–Number
set bRes to changeRecByKeyAndOperator(aRec, "rowAdr", 2) of me
–> {rowAdr:4, docName:"numbTest", cellValue:"AAA", tableName:"table1", sheetName:"Sheet1", columnAdr:2}

–String
set cRes to changeRecByKeyAndOperator(aRec, "docName", ".numbers") of me
–> {rowAdr:2, docName:"numbTest.numbers", cellValue:"AAA", tableName:"table1", sheetName:"Sheet1", columnAdr:2}

–List
set dRes to changeRecByKeyAndOperator(aRec, "cellValue", {".numbers"}) of me
–> {rowAdr:2, docName:"numbTest", cellValue:{"AAA", ".numbers"}, tableName:"table1", sheetName:"Sheet1", columnAdr:2}

–Date (Date value is localized in each locale (This is Japanese locale format). Change Date format in your locale format. It depends on System Preferences > International)
set bRec to {columnAdr:2, rowAdr:2, theTime:date "2019年1月1日火曜日 0:00:00", sheetName:"Sheet1", docName:"numbTest", cellValue:{"AAA"}}
set eRes to changeRecByKeyAndOperator(bRec, "theTime", 10) of me
–> {theTime:date "2019年1月1日火曜日 0:00:10", rowAdr:2, docName:"numbTest", cellValue:{"AAA"}, sheetName:"Sheet1", columnAdr:2}

on changeRecByKeyAndOperator(aRec as record, aKey as string, aVal as {date, list, number, string})
　　set aDict to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set tmpVal to aDict’s valueForKey:aKey
　　
　　–指定キーの存在チェック。存在しない場合には元の値をそのまま返す
　　set tmpKeyList to (aDict’s allKeys()) as list
　　if aKey is not in tmpKeyList then return aRec
　　
　　set tmpVal to tmpVal as {date, list, number, string}
　　set tmpClass to class of tmpVal
　　
　　if tmpClass = integer then
　　　　aDict’s setValue:(tmpVal + aVal) forKey:aKey
　　else if tmpClass = string then
　　　　aDict’s setValue:(tmpVal & aVal) forKey:aKey
　　else if tmpClass = list then
　　　　aDict’s setValue:(tmpVal & aVal) forKey:aKey
　　else if tmpClass = date then
　　　　aDict’s setValue:(tmpVal + aVal) forKey:aKey
　　end if
　　
　　return aDict as record
end changeRecByKeyAndOperator

★Click Here to Open This Script　

指定のAppleScriptテキストを構文確認して変数・プロパティ、サブルーチン名部分のみを取得して置換

Posted on 7月 17, 2019 by Takaaki Naganoya

指定のAppleScriptのテキストを構文確認して、構文的に「変数・プロパティ、サブルーチン名」部分に該当する部分のテキストを取得して、目的のテキストに差し替えるAppleScriptです。

Script Debugger上の生産性を向上させるために書いたものです。Script Debuggerはいわゆる「デバッグ」段階では役に立ちますが、快適にScriptを書くための機能はほとんどありません。

いわゆる、ブレークポイントの設定、プログラムのステップ実行、ステップ実行時の変数値のリアルタイムモニタリング、という「デバッガ」の機能は持っていますが、巨大なScriptを書いたときの特定のサブルーチンを前回実行時に指定したパラメータで再実行して結果を比較といった機能は備えていません（切実にほしー。自分で作りたいぐらい）。

とくに、記述中のAppleScriptの選択部分の構文要素を検出して特定の構文要素（コメントとか変数名とか）についてのみ処理を行うような機能が用意されていない点が残念です（スクリプトエディタ用は数百本書いて使っているので）。

とりわけ、プロパティ文の記述などは毎回同じようなものをコピペで足すだけなので、書き足すのがかったるいと思っていました。

そこで、編集中のAppleScriptの範囲から構文要素を考慮して変数名だけ書き換えてくれるといった機能を足してみました。

テキストで与えたAppleScript（実際にはScript Debuggerの選択範囲から取得）を

	property textList : {}

実際にメモリ上でコンパイル（構文確認）して、書式付きテキストを取得し、そこから構文色分け設定に基づいて該当する構文要素をピックアップ。該当する構文要素の箇所を置換します。

--> textList

＃　置換部分だけ文字置換にしていますが、そこはそれ

	property boundsList : {}

–> Download repLexicalValStr as AppleScript bundle doc with library

例によって、AppleScriptの構文色分け設定の値を読み取って処理しているので、構文要素間で色の値（RGB値）で重複があると（or 値が近すぎると）エラーになります。また、先日報告された「RGB以外の色空間の色」で設定してある場合でもRGB色空間に色データを変換して処理しています（まさかCMYKとかグレースケールで色設定しているユーザーがいるとは思わなかったわー）。

スクリプトエディタ、Script Debugger上での動作を確認していますが、Applet書き出ししたときにまだ謎なメッセージを出すようです。何か、明示的にメインスレッドで実行する必要のあるものがあったでしょうか。

▲Applet書き出しして、実行した際に、ちょっと謎なメッセージが出る時がある（macOS 10.14.5）。vectorってなんだよ？

▲Applet実行時にエラーが出たあとに、再度実行したときにこんな謎なメッセージが出る（macOS 10.14.5）

AppleScript名：指定のAppleScriptテキストを構文確認して変数・プロパティ、サブルーチン名部分のみを取得して置換.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/04
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "AppKit"
use framework "OSAKit"
use attrLib : script "asAttrRecLib"

property NSArray : a reference to current application’s NSArray
property OSANull : a reference to current application’s OSANull
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property OSALanguageInstance : a reference to current application’s OSALanguageInstance

script spd
　　property fArray : {}
　　property outList : {}
　　property resStr : {}
end script

on run
　　set theSource to "　　property textList : {}"
　　set repValstr to "boundsList"
　　
　　set pureValStr to retTargStrFromCompiledScriptAttribute(theSource, 7) of me –Variables and Sub-routine names
　　–> "textList"
　　
　　set newLine to repChar(theSource, pureValStr, repValstr) of me
　　–> "　　property boundsList : {}"
　　
　　display dialog newLine
end run

–AppleScriptのソーステキストをコンパイルして、
on retTargStrFromCompiledScriptAttribute(theSource as string, colSettingOrder as integer)
　　if colSettingOrder < 1 or colSettingOrder > 18 then error ("Lexical element index range error (safe range: 1….18. You set " & colSettingOrder as string) & ")"
　　
　　–AppleScriptの構文色分け情報を取得
　　set ccRes to getAppleScriptSourceColors() of me
　　set cRes to chkASLexicalFormatColorConfliction(ccRes) of me –構文色分けの重複色チェック
　　if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"
　　
　　–検索用の色情報を作成
　　set commentCol to contents of item colSettingOrder of ccRes –Variable and Sub-routine name
　　set searchVal to (redValue of commentCol as string) & " " & (greenValue of commentCol as string) & " " & (blueValue of commentCol as string) –for filtering
　　
　　–与えられたテキストをAppleScriptとして評価し構文色分け情報をもとにStyle Runs的なDictionary化して返す
　　set aRitch to compileASSourcetextAndReturnStyledText(theSource) of me
　　
　　
　　–書式付きテキストからstyle runs的な書式リストを作成
　　set anAttrList to getAttributeRunsFromAttrString(aRitch) of attrLib
　　–>
　　(*
(NSArray) {
　　{
　　　　fontSize:12.0,
　　　　stringVal:"set",
　　　　colorVal:{
　　　　　　14,
　　　　　　62,
　　　　　　251
　　　　},
　　　　fontName:"Osaka",
　　　　itemIndex:1,
　　　　colorStr:"14 62 251"
　　},…..
*)
　　
　　set tmp1Array to NSArray’s arrayWithArray:anAttrList
　　
　　–コメント以外の要素をピックアップ文字と色で抽出
　　–set thePred2 to NSPredicate’s predicateWithFormat_("colorStr != %@ && stringVal != %@", searchVal, (return & return & return & return))
　　set thePred2 to NSPredicate’s predicateWithFormat_("colorStr == %@", searchVal)
　　set (fArray of spd) to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
　　–> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84}
　　
　　–アイテム番号のリストをもとに、ピックアップ対象のアイテムだけを再連結
　　set (outList of spd) to {}
　　repeat with i in (fArray of spd)
　　　　set aStr to ((item i of anAttrList)’s stringVal) as string
　　　　set the end of (outList of spd) to aStr
　　end repeat
　　
　　set (resStr of spd) to retDelimedText((outList of spd), return) of me
　　
　　return (resStr of spd)
end retTargStrFromCompiledScriptAttribute

on retDelimedText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retDelimedText

——-

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceColors()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set colList to {}
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set aColRec to {redValue:rVal, greenValue:gVal, blueValue:bVal, fontName:aFontName, fontSize:aFontSize}
　　　　
　　　　set the end of colList to aColRec
　　end repeat
　　
　　return colList
end getAppleScriptSourceColors

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceNSColorsDict()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set aDict to NSMutableDictionary’s alloc()’s init()
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set colIndStr to (rVal as string) & " " & (gVal as string) & " " & (bVal as string)
　　　　set tmpColDat to {numList:{rVal, gVal, bVal}, strInd:colIndStr}
　　　　–(aDict’s addObject:tmpColDat forKey:theColor)
　　　　(aDict’s addObject:{rVal, gVal, bVal} forKey:theColor)
　　end repeat
　　
　　return aDict
end getAppleScriptSourceNSColorsDict

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aSpace to (aCol’s colorSpaceName()) as string
　　–set aSpace to (aCol’s type()) as integer
　　
　　if aSpace is in {"NSDeviceRGBColorSpace", "NSCalibratedRGBColorSpace"} then
　　　　copy aCol to cCol
　　else
　　　　–RGB以外の色空間の色は、RGBに変換
　　　　–CMYKとグレースケールは同一メソッドでRGBに変換できることを確認済み
　　　　set cCol to aCol’s colorUsingColorSpaceName:"NSCalibratedRGBColorSpace"
　　　　if cCol = missing value then error "Color Space Conversion Error (" & aSpace & " to NSCalibratedRGBColorSpace)"
　　end if
　　
　　set aRed to round ((cCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((cCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((cCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue} as list
end retColListFromNSColor

–AS書式で配色に重複がないかどうかチェック
on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on returnDuplicatesOnly(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

–テキスト形式のAppleScriptをコンパイルして書式付きテキスト（NSAttributedString）を返す
on compileASSourcetextAndReturnStyledText(theSource)
　　— create a new AppleScript instance
　　set anOSALanguageInstance to OSALanguage’s languageForName:"AppleScript"
　　
　　set theScript to OSAScript’s alloc()’s initWithSource:theSource fromURL:(missing value) languageInstance:anOSALanguageInstance usingStorageOptions:(OSANull)
　　set {theResult, theError} to theScript’s compileAndReturnError:(reference)
　　
　　if theResult as boolean is false then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　return styledSourceText
end compileASSourcetextAndReturnStyledText

–文字置換
on repChar(origText as string, targChar as string, repChar as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示 v4

Posted on 7月 11, 2019 by Takaaki Naganoya

アラートダイアログ上にTable Viewを表示するAppleScriptです。

データを表UIで表示する部品としては、Shane Stanleyの「Myriad Tables Lib」が定番ですが、高機能なぶんライブラリ中にFrameworkが含まれていたりして、場合によっては困ることもあります。また、見た目をカスタマイズしたい場合にも、あまりいじくれなくて困ることもあります（とくにデータの文字サイズを変更できなくて困ること多し）。

そのため、AppleScriptだけで書いた表UI表示用の部品も、たまに必要になることがあります。

▲スクリプトエディタで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

▲Script Debuggerで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

▲AppleScriptアプレットで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

AppleScript名：アラートダイアログ上にTable Viewを表示 v4

— Created 2019-02-21 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

on run
　　set (my theResult) to 0 –initialize
　　
　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:{{field1:"MacBook Air", field2:"119,800円", field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:"139,800円", field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:"258,800円", field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:"122,800円", field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:"120,800円", field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:"142,800円", field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:"198,800円", field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:"558,800円", field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}}, aSortOrder:{"field1", "field2", "field3"}}
　　
　　–my chooseItemByTableView:paramObj–for debug
　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　return (my theResult)
end run

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　set labelSortList to (aSortOrder of paramObj) as list
　　
　　set aWidth to 600
　　set aHeight to 200
　　
　　set aScroll to makeTableView(aTList, aWidth, aHeight, labelSortList) of me
　　
　　–Detect Dark Mode
　　set dMode to retLIghtOrDark() of me
　　if dMode = true then
　　　　set tvCol to 1
　　　　set tvAlpha to 0.8
　　　　set bCol to 0.1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s cyanColor())
　　else
　　　　set tvCol to 0
　　　　set tvAlpha to 0.1
　　　　set bCol to 1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s blackColor())
　　end if
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setOpaque:(false)
　　myWindow’s setBackgroundColor:(NSColor’s colorWithCalibratedWhite:(bCol) alpha:(bAlpha))
　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode) = 1001 then error number -128
　　
　　set (my theResult) to (aScroll’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle)
　　return aRes
end tableView:objectValueForTableColumn:row:

on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　set aOffset to 40
　　set theDataSource to current application’s NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:aDicList
　　
　　set aScroll to current application’s NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to current application’s NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　set aLen to length of labelSortList
　　
　　repeat with i in labelSortList
　　　　set j to contents of i
　　　　set aColumn to (current application’s NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　(aView’s addTableColumn:aColumn)
　　end repeat
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　
　　–１行目を選択
　　set aIndexSet to current application’s NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る。System Eventsを使っていないのは、macOS 10.14以降対策（承認を取得しなくてもいいように）
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

指定のAppleScriptのソースコードからコメント部分のみを取得

Posted on 7月 8, 2019 by Takaaki Naganoya

指定のAppleScript書類のソースコードを取得し、構文色分け情報をもとにコメント部分の文字列のみを取得するAppleScriptです。

こうした処理はとくに昨日今日で実現したものではなく、実は同じような処理をOS X 10.4の時代からスクリプトエディタをAppleScriptから操作して行ってきました（スクリプトエディタ版のコメント抽出プログラムは、電子書籍の購入者特典でつけた「Piyomaru Script Assistant」に入っています）。Cocoaの機能を利用して処理すると、スクリプトエディタを操作せずにAppleScript書類から情報を取得できます。もちろん、GUIアプリケーションを操作しないぶん、並列処理にも有利です。

本Scriptを実行すると、指定のAppleScript書類をバックグラウンドでオープンして、書式情報を取得し、コメントに該当する箇所の文字のみを取得して返します。

–> Download commentPicker (executable app within library)

ほんの少し修正することで、ソースコードからコメント部分のみを削除したテキストを取得することも可能です。

AppleScript名：指定のAppleScriptのソースコードからコメント部分のみを取得.scptd

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

script spd
　　property fArray : {}
　　property outList : {}
　　property resStr : {}
end script

–AppleScriptの構文色分け情報を取得
set ccRes to getAppleScriptSourceColors() of me
set cRes to chkASLexicalFormatColorConfliction(ccRes) of me –構文色分けの重複色チェック
if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"

–検索用の色情報を作成
set commentCol to contents of item 5 of ccRes –Comment
set searchVal to (redValue of commentCol as string) & " " & (greenValue of commentCol as string) & " " & (blueValue of commentCol as string) –for filtering

–処理対象のAppleScript書類を選択
set asPath to choose file of type {"com.apple.applescript.script-bundle", "com.apple.applescript.script"}

–書式付きテキストからstyle runs的な書式リストを作成
set anAttrList to getAttrRecFromASPath(asPath) of attrLib
–>
(*
(NSArray) {
　　{
　　　　fontSize:12.0,
　　　　stringVal:"set",
　　　　colorVal:{
　　　　　　14,
　　　　　　62,
　　　　　　251
　　　　},
　　　　fontName:"Osaka",
　　　　itemIndex:1,
　　　　colorStr:"14 62 251"
　　},…..
*)

set tmp1Array to NSArray’s arrayWithArray:anAttrList

–コメント以外の要素をピックアップ文字と色で抽出
–set thePred2 to NSPredicate’s predicateWithFormat_("colorStr != %@ && stringVal != %@", searchVal, (return & return & return & return))
set thePred2 to NSPredicate’s predicateWithFormat_("colorStr == %@", searchVal)
set (fArray of spd) to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
–> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84}

–アイテム番号のリストをもとに、ピックアップ対象のアイテムだけを再連結
set (outList of spd) to {}
repeat with i in (fArray of spd)
　　set aStr to ((item i of anAttrList)’s stringVal) as string
　　set the end of (outList of spd) to aStr
end repeat

set (resStr of spd) to retDelimedText((outList of spd), return) of me

return (resStr of spd)

——-

★Click Here to Open This Script　

Cocoa ObjectをキーにしたDictionaryから合致するObjectを取得

Posted on 7月 7, 2019 by Takaaki Naganoya

Cocoa ObjectをキーにしたDictionaryから、Cocoa Objectでキー検索を行い、キーが合致する要素に定義されているオブジェクトを取得するAppleScriptです。

AppleScriptのrecord型変数は、本当に基本的な機能しか用意されておらず、

{keyLabel1:value1, keyLabel2:value2, keyLabel3:value3 }

のような、キーとなるラベルには「空白文字や使用禁止文字を含まない」文字しか使えませんし、キーに何らかのオブジェクトを指定することはできません。

そんな中、macOS 10.10でCocoa Scriptingが標準搭載されたため、CocoaのNSDictionaryを調べて「へー、キーにオブジェクトが使えるのか！」などと喜んでいました（macOS 10.10が出た頃）。

{Cocoa Object 1:value1, Cocoa Object 2:value2, Cocoa Object 3:value3 }

{Cocoa Object 1:some object 1, Cocoa Object 2:some object 2, Cocoa Object 3:some object 3 }

ちょうどそういう（CocoaオブジェクトをキーにしたDictionaryの検索）プログラムを組もうとして、Dictionaryから「valueForKey:」でvalueを取り出そうとして（エラーに遭遇して）試行錯誤していました。

(NSDictionary) {
	NSCalibratedRGBColorSpace 0 1 0 1:"Green",
	NSCalibratedRGBColorSpace 0 0 1 1:"Blue",
	NSCalibratedRGBColorSpace 1 0 0 1:"Red"
}

実際にはこれは「objectForKey:」で取り出さないとエラーになってしまうんですね。その確認のために書いた基礎確認用のAppleScriptです。やっぱり、基礎の再確認はとても大事です。

AppleScript名：Cocoa ObjectをキーにしたDictionaryから合致するObjectを取得

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/06
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCol to current application’s NSColor’s redColor()
set bCol to current application’s NSColor’s greenColor()
set cCol to current application’s NSColor’s blueColor()

set aDict to current application’s NSMutableDictionary’s new()
aDict’s addObject:"Red" forKey:aCol
aDict’s addObject:"Green" forKey:bCol
aDict’s addObject:"Blue" forKey:cCol

set dCol to current application’s NSColor’s blueColor()

set aRes to (aDict’s objectForKey:dCol) as string
–> "Blue"

★Click Here to Open This Script　

構文色分け情報を取得（Color Spaceを考慮）

Posted on 7月 4, 2019 by Takaaki Naganoya

macOS標準搭載のスクリプトエディタで定義している、AppleScriptの構文要素ごとの色分け情報。これを設定ファイルから取り出してレコード型データ（を入れた配列）に変換するAppleScriptの、カラースペースを考慮したデータの取り出しを行う改修版です。

AppleScriptの構文色分け情報は、ユーザーごとに異なります。一応、OSデフォルトの趣味の悪い配色なんかもありますが、

　（１）美的センスがなく見た目に気持ち悪い（ほら変更したいでしょ？　自分の好きなように変えてね、というメッセージだと受け止めました）

　（２）重複した色が設定されている構文要素がたくさんある（構文要素ごとの見分けがしにくいので、デフォルトのままだと無意味。ほら変更したくなったでしょ、というメッセージだと受け止めました）

ということから、AppleScript入門初日に設定色を変更。何度か細かい変更を行いつつも、今日までだいたい同じ感じの設定を使い続けています。

他のScripterがどのような配色にしているかはあまり知りません。Scripterごとに違うんだろうな、ぐらいの感じです。

ところが、蓋を開けてみたらこの構文色分け設定に「RGB以外の色」が設定できることが判明。けっこう長い間、この処理系使い続けてきましたけれど、昨日はじめて知りました。

具体的に言えば、RGB以外の「CMYK色」と「グレースケール色」の２つを設定可能なことが判明。CMYK色は、何度かアクセスしているうちに勝手にRGB色に置き換わってしまうようですが、グレースケールで指定した色はそのまま色種別がグレースケールのまま保持される（RGBに変換されたりしない）ようです。そのため、NSColorからredValue()などのメソッドで数値を取り出そうとするとエラーになる事例が発生したのでした。

そこで、RGBの各チャンネルの値を取り出す前にNSColorの色空間（グレースケール色空間というのはないので、種別ぐらい？）をチェックし、RGB以外であれば変換処理を行うようにしてみました。

ただし、この色空間（色モデル）の確認にNSColorのcolorSpaceNameというメソッドを使っている点に注意が必要です。これはmacOS 10.13で非推奨（deprecated）になっています。ヘッダーファイル上の説明を読むかぎりだと、Color Space（色空間）といいながら実際には色空間に該当する（HSBとかL*a*b*とか）ものを指定しているわけではないので、色タイプと言い換えることにした、という説明が行われていました。

このため、macOS 10.15betaでは未確認ではあるものの、このNSColorからRGB値を取り出すという処理自体を書き換える必要が出てくるため、本ルーチンだけ別のライブラリに分離しておくとか、メンテナンス時にわかるように書いておくとよいでしょう（NSColorのtypeを取得してみたものの、いまひとつサンプルなどもなく不明。macOS 10.14上で全部一律で0が返ってくるし）。

AppleにOS内部の機能修正リクエストを出す場合、「実際に機能不全を起こしているんだから直してほしい」と依頼してもなかなか直らない一方で、「学術的に正しくない」という指摘をされるととっとと変更するんだなーという発見をしたような気がします。

AppleScript名：構文色分け情報を取得（Color Spaceを考慮）.scptd

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver

set cList to getAppleScriptSourceColors() of me

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aSpace to (aCol’s colorSpaceName()) as string
　　
　　if aSpace is in {"NSDeviceRGBColorSpace", "NSCalibratedRGBColorSpace"} then
　　　　–do nothing
　　else
　　　　–RGB以外の色空間の色は、RGBに変換
　　　　–CMYKとグレースケールは同一メソッドでRGBに変換できることを確認済み
　　　　set cCol to aCol’s colorUsingColorSpaceName:"NSCalibratedRGBColorSpace"
　　　　if cCol = missing value then error "Color Space Conversion Error (" & aSpace & " to NSCalibratedRGBColorSpace)"
　　　　copy cCol to aCol
　　end if
　　
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

★Click Here to Open This Script　

Handle diff v2

Posted on 7月 3, 2019 by Takaaki Naganoya

Script Debugger上でオープン中の２つのAppleScript書類のうち、名称が同じハンドラ（サブルーチン）の内容同士を比較して、お互いに合っているかどうかをチェックするAppleScriptです。

アプリケーション書き出しして、Script Debuggerのスクリプトメニューに入れて実行します（AppleScript書類のままだと、Myriad Tables Lib内のフレームワークが呼べないため）。

▲本Scriptはスクリプトエディタの環境設定で行うAppleScriptの構文色分け設定色が「RGBカラー」でないとエラーになります。CMYKとかグレースケールカラーで指定して、そのままRGBに変換されずに保持される（CMYK色はアクセスしているうちにRGBに変換されるが、グレースケールは保持される）ため、色空間の判定を行ってRGB色に変換してから処理する必要があります（自分用メモ）

スクリプトエディタ上で設定する構文色分け設定をもとに、AppleScriptの構文要素を考慮したハンドラ一覧を作成し、２つのAppleScript書類の間に共通して存在するハンドラ名のハンドラ（サブルーチン）のAppleScriptソースを取得。インデント（tab）を削除したのちに比較を実行。

共通名称のハンドラすべてをチェックして、結果を表インタフェースで表示します。初版（v1）では実行するたびに１つのハンドラをチェックしていたのですが、あまりにかったるいので即座にループですべて調べてまとめて結果を表示するようにしました（v2）。

–> download executable archive (mainly for macOS 10.14 or later)

ただし、１つのAppleScript書類内にScript Object（JavaScriptでいうところのClosureみたいなもの）で論理分割された同名のハンドラが複数回登場するパターンは想定していません。複数検出するとエラーになります。

とくにScript Debuggerを対象にせずスクリプトエディタを対象にしてもよいのですが、些細な変更で実現できるため、興味のある方はやってみてください。あと、本Scriptは必要に迫られまくって作ったものなので、動作でおかしい箇所があったらぜひぜひご指摘を。

個人的には、ハンドラ名称を構文要素を考慮しつつ取得している一方で、ハンドラの内容は単なる文字列検索で取り出しているというあたりにアンバランスさを感じます。ただ、趣味のScriptではないので若干の手抜きを（＾ー＾；；

macOS 10.14.5上のスクリプトエディタで、構文色分け情報を何回設定しても「黒」になるという現象に遭遇したのですが、他のユーザー環境上での再現性については未知数であるため、まだレポートできない状況です。

→　その後、本ツールは強化されて、構文色分け設定にRGB以外の色が設定してあってもRGBに変換して処理する機能や、構文色分け設定を参照したコメント除去機能や、各種書式情報の取得を３倍高速化するカラーキャッシュなどの機能を実装したプログラムに（必要に迫られて）成長しました。

AppleScript名：Handle diff v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/02
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — Sierra (10.12) or later (maybe 10.11 is OK but not confirmed)
use framework "Foundation"
use scripting additions
use framework "OSAKit"
use script "Myriad Tables Lib" version "1.0.9" –https://www.macosxautomation.com/applescript/apps/Script_Libs.html

–構文色分け設定に重複色がないかチェック
set cList to getAppleScriptSourceColors() of me
set cRes to chkASLexicalFormatColorConfliction(cList) of me –構文色分けの重複色チェック
if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"

–Script Debugger上でオープン中の２つのAppleScript書類のパスを取得
set dList to retTwoPathList() of me
if dList = false then return

copy dList to {d1Path, d2Path}

–各AppleScript書類のハンドラ名称一覧を取得する
set hList1 to retHandlerNamesFromAppleScriptSource(d1Path as alias) of me
set hList2 to retHandlerNamesFromAppleScriptSource(d2Path as alias) of me

–２つのAppleScript書類のハンドラの共通項目（名称のみ）を抽出する
set resList to returnDuplicatesOnly(hList1 & hList2) of me
if resList = {} then
　　–共通のハンドラ（サブルーチン）が指定の２つのScriptに存在していなかった
　　display dialog "There is no common handler between the scripts." buttons {"OK"} default button 1
　　return
end if

–各AppleScript書類のソースを取得して、指定のハンドラのテキストを取得する
set s1Source to getASsourceFor(d1Path as alias) of me
set s2Source to getASsourceFor(d2Path as alias) of me

if (s1Source = false) or (s2Source = false) then
　　display dialog "Error occured in getteing AS source" buttons {"OK"} default button 1
　　return
end if

set outList to {}
repeat with i in resList
　　set resHandler to contents of i
　　set s1Source to extractHandlerSourceOnly(s1Source, resHandler) of me
　　set s2Source to extractHandlerSourceOnly(s2Source, resHandler) of me
　　set compareF to (s1Source is equal to s2Source) as boolean
　　set the end of outList to {resHandler, compareF}
end repeat

–結果表示
tell me to activate
display table with data outList with prompt "Handler contents compare results" column headings {"Handler name", "Match?"} with title "Handler Diff Results"

–指定のハンドラの内容を抽出する（コメントぐらいは結果から削除してもいいような気もする）
–Script Objectの使用は考慮していない。１つのAppleScript書類からScript Objectで論理分割された同名のハンドラが複数検出されるケースは想定していない
on extractHandlerSourceOnly(wholeScript as string, handlerName as string)
　　–インデント文字（Tab）をすべて削除
　　set targScript to repChar(wholeScript, tab, "") of me
　　
　　–"on"ではじまるハンドラと仮定して抽出
　　set handlerStr to extractStrFromTo(targScript, "on " & handlerName, "end " & handlerName) of me
　　if handlerStr = false then
　　　　–"to"ではじまるハンドラと仮定して抽出
　　　　set handlerStr to extractStrFromTo(targScript, "to " & handlerName, "end " & handlerName) of me
　　　　if handlerStr = false then return false
　　else
　　　　return handlerStr
　　end if
end extractHandlerSourceOnly

on retHandlerNamesFromAppleScriptSource(aFile)
　　set aRec to getAttrRecFromASPath(aFile) of me
　　set cList to getAppleScriptSourceColors() of me
　　
　　set targAttr to contents of item 7 of cList –ハンドラあるいは変数
　　set tmpCoStr to ((redValue of targAttr) as string) & " " & ((greenValue of targAttr) as string) & " " & ((blueValue of targAttr) as string)
　　
　　set ontoColItem to contents of item 3 of cList –スクリプティング予約語（on/to）
　　set ontoCoStr to ((redValue of ontoColItem) as string) & " " & ((greenValue of ontoColItem) as string) & " " & ((blueValue of ontoColItem) as string)
　　
　　
　　–変数あるいはハンドラ名称をリストアップ(variables & handler)
　　set tmp1Array to NSArray’s arrayWithArray:aRec
　　set thePred0 to NSPredicate’s predicateWithFormat_("colorStr == %@", tmpCoStr)
　　set dArray to (tmp1Array’s filteredArrayUsingPredicate:thePred0) as list
　　
　　–改行を含むデータをリストアップ(text data contains return)
　　set thePred1 to NSPredicate’s predicateWithFormat_("stringVal CONTAINS %@", return)
　　set eArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred1)’s valueForKeyPath:"itemIndex") as list
　　
　　set the beginning of eArray to 0 –ハンドラ宣言部がTopに来る場合に備える
　　
　　–"on"（ハンドラ宣言）の項目をリストアップ文字と色で抽出
　　set thePred2 to NSPredicate’s predicateWithFormat_("stringVal == %@ && colorStr == %@ ", "on", ontoCoStr)
　　set fArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
　　
　　–"to"（ハンドラ宣言ないしは代入対象指定）　の項目をリストアップ文字と色で抽出
　　set thePred3 to NSPredicate’s predicateWithFormat_("stringVal == %@ && colorStr == %@ ", "to", ontoCoStr)
　　set gArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred3)’s valueForKeyPath:"itemIndex") as list
　　
　　
　　set handlerList to {}
　　
　　–on ではじまるハンドラの抽出
　　repeat with i in eArray –改行を含むテキストのアイテム番号リスト
　　　　set j to (contents of i) as integer
　　　　repeat with ii in fArray –"on"の項目リスト
　　　　　　set jj to (contents of ii) as integer
　　　　　　
　　　　　　set handlerStr to missing value
　　　　　　
　　　　　　if (j + 1) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　else if (j + 2) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　end if
　　　　　　
　　　　　　if handlerStr is not in {"error", missing value} and handlerStr is not in handlerList then
　　　　　　　　set the end of handlerList to handlerStr
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　
　　–to ではじまるハンドラの抽出
　　repeat with i in eArray –改行を含むテキストのアイテム番号リスト
　　　　set j to (contents of i) as integer
　　　　repeat with ii in gArray –"to"の項目リスト
　　　　　　set jj to (contents of ii) as integer
　　　　　　
　　　　　　set handlerStr to missing value
　　　　　　
　　　　　　if (j + 1) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　else if (j + 2) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　end if
　　　　　　
　　　　　　if handlerStr is not in {"error", missing value} and handlerStr is not in handlerList then
　　　　　　　　set the end of handlerList to handlerStr
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　return handlerList
end retHandlerNamesFromAppleScriptSource

–ソースを取得してコンパイル（構文確認）する方式から、URL（fileURL）を指定してコンパイル（構文確認）する方式に変更した
on getAttrRecFromASPath(aFile)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　–set sourceText to theScript’s source() –No Use
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　set attrRes to getAttributeRunsFromAttrString(styledSourceText) of me
　　return attrRes
end getAttrRecFromASPath

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
— Original Created 2014-02-23 Shane Stanley
on getASsourceFor(anAlias as {alias, string})
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　set sourceText to theScript’s source()
　　end if
　　
　　return sourceText as string
end getASsourceFor

–Attributed StringをDictionary化
on getAttributeRunsFromAttrString(theStyledText)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　set itemCount to 1
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(specifier) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–String　　
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　–Color
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize, itemIndex:itemCount}
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　
　　　　set itemCount to itemCount + 1
　　end repeat
　　
　　return (styleList of aSpd)
　　
end getAttributeRunsFromAttrString

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceColors()
　　
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set colList to {}
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set aColRec to {redValue:rVal, greenValue:gVal, blueValue:bVal, fontName:aFontName, fontSize:aFontSize}
　　　　
　　　　set the end of colList to aColRec
　　end repeat
　　
　　return colList
end getAppleScriptSourceColors

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

–AS書式で配色に重複がないかどうかチェック
on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　log aRes
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on retTwoPathList()
　　tell application "Script Debugger"
　　　　set dList to name of every document
　　　　set dResList to choose from list dList with prompt "Select two documents" with multiple selections allowed
　　　　if dResList = false then return false
　　　　if length of dResList is not equal to 2 then
　　　　　　display dialog "Please Select two documents to compare handler contents" buttons {"OK"} default button 1 with icon 1 with title "Selection Error"
　　　　　　return false
　　　　end if
　　　　
　　　　set dPathList to {}
　　　　repeat with i in dResList
　　　　　　set j to contents of i
　　　　　　tell document j
　　　　　　　　set tmpPath to (file spec) as string –HFS path string
　　　　　　end tell
　　　　　　
　　　　　　set the end of dPathList to tmpPath
　　　　end repeat
　　end tell
　　
　　return dPathList
end retTwoPathList

–Written By Philip Aker
–文字置換ルーチン
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

–指定文字と終了文字に囲まれた内容を抽出
on extractStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to current application’s NSScanner’s scannerWithString:aParamStr
　　set anArray to current application’s NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(specifier)
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(specifier)
　　　　if theValue is missing value then set theValue to "" –>追加
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　if anArray’s |count|() is not equal to 1 then return false
　　
　　return first item of (anArray as list)
end extractStrFromTo

★Click Here to Open This Script　

AppleScript書類を構文要素ごとに分解（Script Libraries対応版）

Posted on 7月 3, 2019 by Takaaki Naganoya

指定のAppleScript書類を読み込んで、スクリプトエディタ上で実行するのと同じ構文色分けのデータに変換するAppleScriptです。

説明するのがややこしい、AppleScript書類の内容を分析するためのAppleScriptです。

AppleScriptのプログラム内容を分析するプログラムは昔からよく作ってきました。とくに、プログラムが巨大になってきたり複雑になってきたり、納品直前に巨大な仕様変更があったりすると（涙）、自分で書いたプログラムを自分で分析する必要が出てくるからです。

AppleScriptの構文解析は面倒です。「return return」（前者はサブルーチンから値を返すコマンド　後者は改行コード）といった記述が可能なので、これを正しく解釈する必要があります。

GithubやXcode上のソースコードエディタなど、キーワードだけで色分けするバカプログラムでは「return return」を正しく解釈できていません。

AppleScriptの処理系そのものが持っている「構文色分け」の機能を用いて、構文解析するのではなく、処理系の機能を用いて構文ごとに色分けされた、その色分け結果の情報を用いて構文ごとの要素を区分けするという方法をMac OS X 10.3の時代から使っていました。

当初はスクリプトエディタをコントロールして実行していましたが、macOS 10.10以降でCocoaの機能が利用できるようになったため、Cocoaのメソッドを用いて処理するようになってきました。

ところが最近、これまで使っていたサブルーチン部品では分析できないケースが出てきました。AppleScript Librariesを組み込んだバンドルスクリプトを処理させるとエラーになります。

自分が使っていたサブルーチンでは、指定のAppleScript書類のソースコードを求め、メモリ上でコンパイルしてインスタンスを生成し、そこから書式情報を取得していました。

しかし、AppleScript Librariesを含むAppleScriptバンドル書類に対してこれを用いると、エラーが出て処理できないことがわかりました。つまり、ライブラリが含まれていない状態のソースを取得してコンパイル（構文確認）すると、ライブラリが存在しないというエラーに直面するわけです。

仕方なく、Xcode上でヘッダーファイル「OSAScript.h」を調べ、URL指定してコンパイル（構文確認）できるメソッドがあることを確認。これを使ってみたところ、AppleScript Librariesを含むAppleScriptバンドル書類も構文要素ごとに分解できました。Shane Stanleyから「Appleのオンラインドキュメントを見ただけでは調査したことにならない。ヘッダーファイルを確認する必要がある」とは何回もコメントをもらっていますが、なかなか奥深いです。

最初（v1.0）、

- (id)initWithContentsOfURL:(NSURL *)url language:(OSALanguage *)language error:(NSDictionary * __nullable * __nullable)errorInfo DEPRECATED_IN_MAC_OS_X_VERSION_10_6_AND_LATER;

を使っていたのですが、「DEPRECATED_IN_MAC_OS_X_VERSION_10_6_AND_LATER」の表記に気づいて、

- (instancetype)initWithSource:(NSString *)source fromURL:(nullable NSURL *)url languageInstance:(nullable OSALanguageInstance *)instance usingStorageOptions:(OSAStorageOptions)storageOptions AVAILABLE_MAC_OS_X_VERSION_10_6_AND_LATER;

に変更しました。OSA言語インスタンスを作ったまま使っていなかったりしますが、その時の変更の名残です。

AppleScript名：AppleScript書類を構文要素ごとに分解（Script Libraries対応版）v1.1.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/03
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "OSAKit"
use framework "AppKit"

property OSANull : a reference to current application’s OSANull
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property OSALanguageInstance : a reference to current application’s OSALanguageInstance
property OSADontSetScriptLocation : a reference to current application’s OSADontSetScriptLocation

set aFile to choose file of type {"com.apple.applescript.script-bundle", "com.apple.applescript.script"}
set aRec to getAttrRecFromASPath(aFile) of me

–ソースを取得してコンパイル（構文確認）する方式から、URL（fileURL）を指定してコンパイル（構文確認）する方式に変更した
on getAttrRecFromASPath(aFile)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　set anOSALanguageInstance to OSALanguage’s languageForName:"AppleScript"
　　set {theScript, theError} to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(reference)
　　
　　if theError is not equal to missing value then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　–set sourceText to theScript’s source() –No Use
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　set attrRes to getAttributeRunsFromAttrString(styledSourceText) of me
　　return attrRes
end getAttrRecFromASPath

–Attributed StringをDictionary化
on getAttributeRunsFromAttrString(theStyledText)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　set itemCount to 1
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–String　　
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　–Color
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize, itemIndex:itemCount}
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　
　　　　set itemCount to itemCount + 1
　　end repeat
　　
　　return (styleList of aSpd)
　　
end getAttributeRunsFromAttrString

★Click Here to Open This Script　

テキストから指定桁数の数値を抽出して度数分布集計

Posted on 6月 28, 2019 by Takaaki Naganoya

CotEditorで編集中の最前面の書類の本文中から指定桁の数値を抽出して登場回数で度数分布の集計を行うAppleScriptです。

CotEditorのアプリケーション内のスクリプトメニューに入れて実行できることを確認してあります（@macOS 10.14.5）。

たまたま、テキストで集計していた情報のうち、数値部分の度数分布を計算したいと考え、ありもののルーチンを組み合わせて作ったものです。

実行すると、集計対象の数値の桁数を聞いてくるため、適当なものを選択してださい。

CotEditorのScriptingの要注意点で、オブジェクト階層を素直に書いて、当該階層のオブジェクトの属性値を取りたいような場合に、そのまま属性を書いても取得できないケースが見られます。そのため、明示的にオブジェクト階層を指定するために「of it」を書いています。Xcodeが同じような挙動を行うため、注意が必要です。

本Scriptについていえば、正規表現でテキストから情報を抽出したりと、一応最低限のレベルはクリアしているものの、いまひとつ満足できません。

数字が連続して登場している箇所を抽出し、どれを集計対象にするのかといった分析を冒頭で行ってユーザーに問い合わせしたいところです。現段階では、「桁数を聞く」という頭の悪い実装になっていますが、そのうちどうにかしたいと考えるところです。

AppleScript名：テキストから指定桁数の数値を抽出して度数分布集計.scptd

— Created 2019-06-28 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property graphStr : "絆" –グラフに出力する文字

tell application "CotEditor"
　　–最前面の書類からテキスト本文を取得
　　tell front document
　　　　set aText to contents of it –本文
　　　　set lineTerm to (line ending) –改行コード
　　end tell
　　
　　–改行コードの選択（ドキュメントの状態から取得）
　　if lineTerm = LF then
　　　　set aRet to ASCII character 10 –To avoid keyword conflict (string)
　　else if lineTerm = CR then
　　　　set aRet to ASCII character 13
　　else if lineTerm = CRLF then
　　　　set aRet to (ASCII character 13) & (ASCII character 10)
　　else
　　　　set aRet to ASCII character 10
　　end if
end tell

–桁数選択
set digiList to {"2", "3", "4", "5"}
set digitRes to first item of (choose from list digiList with prompt "Choose the digit to extract as numbers")

–正規表現で数字部分のみ抽出
set theList to my findPattern:("[0-9]{" & digitRes & "}") inString:aText

–検出した数字部分の度数分布を計算
set theCountedSet to current application’s NSCountedSet’s alloc()’s initWithArray:theList
set newArray to current application’s NSMutableArray’s new()
set kList to uniquifyAndSort1DList(theList, false) of me –降順ソート

repeat with i in kList
　　(newArray’s addObject:{theKey:i, theCount:(theCountedSet’s countForObject:i)})
end repeat

–出力用のテキストを作成
set outStr to ""
repeat with i in newArray as list
　　set outStr to (outStr & (theKey of i) as string) & "："
　　set aNum to (theCount of i) as integer
　　
　　repeat aNum times
　　　　set outStr to outStr & graphStr
　　end repeat
　　
　　set outStr to outStr & aRet
end repeat

–最前面のテキスト末尾に集計結果を出力
tell application "CotEditor"
　　tell front document
　　　　set contents of it to (aText & aRet & aRet & "集計結果：" & aRet & aRet & outStr & aRet)
　　end tell
end tell

–正規表現でテキスト中から指定パターンに該当する箇所を抽出してリストで返す
on findPattern:thePattern inString:theString
　　set theOptions to ((current application’s NSRegularExpressionDotMatchesLineSeparators) as integer) + ((current application’s NSRegularExpressionAnchorsMatchLines) as integer)
　　set theRegEx to current application’s NSRegularExpression’s regularExpressionWithPattern:thePattern options:theOptions |error|:(missing value)
　　set theFinds to theRegEx’s matchesInString:theString options:0 range:{location:0, |length|:length of theString}
　　set theFinds to theFinds as list — so we can loop through
　　set theResult to {} — we will add to this
　　set theNSString to current application’s NSString’s stringWithString:theString
　　repeat with i from 1 to count of items of theFinds
　　　　set theRange to (item i of theFinds)’s range()
　　　　set end of theResult to (theNSString’s substringWithRange:theRange) as integer
　　end repeat
　　return theResult
end findPattern:inString:

–1D Listをユニーク化してソート
on uniquifyAndSort1DList(theList as list, aBool as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:theList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"compare:"
　　set cArray to bArray’s sortedArrayUsingDescriptors:{aDdesc}
　　
　　set bList to cArray as list
　　return bList
end uniquifyAndSort1DList

★Click Here to Open This Script　

Numbersで選択中の表のセルの範囲を背景色で頻度集計

Posted on 6月 6, 2019 by Takaaki Naganoya

Numbersでオープン中の書類の現在のシート上にある表の選択範囲のセルに対して、背景色（Background color）で登場頻度の集計を行って、どの色が何回登場しているかを色プレビューしつつ表示するAppleScriptです。

集計をRGB値で数値的に行うことは容易ですが、結局のところ色なんてRGB値で見せられてもわからず、実際に目で見える色で表示しないと判断できません。そのため、アラートダイアログを作成してその上にColorWellで表示しています。

▲Numbersの表でセルを選択

▲Numbersの表のセルに指定されている背景色の登場頻度で集計し、色プレビューと登場回数を表示（スクリプトエディタ@macOS 10.14.5上の表示、Dark Mode）

▲Numbersの表のセルに指定されている背景色の登場頻度で集計し、色プレビューと登場回数を表示（Script Debugger@macOS 10.14.5上の表示、Dark Mode）

上記サンプル表は本Blog上での説明用のために簡略化した表ですが、実際には数十行の入り組んだNumbersの表を相手にしており、かつ、手作業で色付きセルだけを数えるなんて考えたくもないレベルで頻繁に確認しなくてはならなかったために、本Scriptを作ってみました。

Numbersにかぎらず、iWorkアプリケーション（Keynote、Pages、Numbers）で共通の仕様ですが、背景色を塗らないセルから背景色を取得するとmissing valueが返ります。

本ScriptはScript Menuに入れて実行するとアラートダイアログが最前面に出てこないなど、Script書類（.scpt、.scptd）のままで実行すると問題が発生。Script Menuに入れる場合にはアプレット（.app）書き出しする必要があります。

▲スクリプトメニューにアプレット書き出しした実行ファイルを入れて呼び出し（macOS 10.14.5）。スクリプトメニューは最前面にあるGUIアプリケーションに応じて、それぞれのアプリケーション用のメニューを表示できるようになっている

AppleScript名：選択中の表のセルの範囲を背景色で頻度集計.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/06/06
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSTextField : a reference to current application’s NSTextField
property NSColorWell : a reference to current application’s NSColorWell
property NSScrollView : a reference to current application’s NSScrollView
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication

property theResult : 0
property returnCode : 0
property theDataSource : {}

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　return "No Selection" –何も選択されてなかった場合
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　set bgColList to background color of every cell of selection range
　　　　　　　　–> {{18572, 45937, 65452}, {18572, 45937, 65452}, {3001, 24801, 44056}, {18572, 45937, 65452}, {18572, 45937, 65452}, {64899, 33134, 31509}, {64899, 33134, 31509}, {18572, 45937, 65452}, {18572, 45937, 65452}, {3001, 24801, 44056}, {18572, 45937, 65452}, {18572, 45937, 65452}, {26149, 65534, 58650}, {26149, 65534, 58650}, {26149, 65534, 58650}, {26149, 65534, 58650}, {18572, 45937, 65452}, {18572, 45937, 65452}}
　　　　　　end tell
　　　　end tell
　　end tell
end tell

set bgColList to countItemsByItsAppearance(bgColList) of me
–> {{theName:{65535, 65533, 65534}, numberOfTimes:73}, {theName:{65535, 65535, 21706}, numberOfTimes:73}, {theName:missing value, numberOfTimes:27}}

set paramObj to {mainDat:bgColList, myTitle:"色別集計", mySubTitle:"Numbers上で選択したセルの背景色の頻度集計"}
–my browseColors:paramObj–for debug

my performSelectorOnMainThread:"browseColors:" withObject:(paramObj) waitUntilDone:true

on browseColors:paramObj
　　set aParamList to (mainDat of (paramObj as record)) as list
　　set winTitle to (myTitle of (paramObj as record)) as string
　　set subTitle to (mySubTitle of (paramObj as record)) as string
　　
　　set aLen to length of aParamList
　　
　　set aHeight to 100
　　set aWidth to 300
　　
　　–NSViewをつくる
　　set aNSV to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight * 1.5))
　　aNSV’s setNeedsDisplay:true
　　
　　— NSScroll Viewをつくる
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aScroll’s setDocumentView:aNSV
　　
　　aNSV’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aNSV’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–NSColorWell+ NSTextFieldをつくる
　　set aStep to 1
　　repeat with i in aParamList
　　　　set aColorWell to (NSColorWell’s alloc()’s initWithFrame:(current application’s NSMakeRect(10, ((aLen – aStep + 1) * 30), 60, 20)))
　　　　
　　　　set myName to (theName of i)
　　　　set myTimes to (numberOfTimes of i)
　　　　
　　　　if myName is not equal to missing value then
　　　　　　copy (myName as list) to {rNum, gNum, bNum}
　　　　　　set myTimes to numberOfTimes of i
　　　　　　
　　　　　　set myColor to makeNSColorFromRGBAval(rNum, gNum, bNum, 65535, 65535) of me
　　　　　　(aColorWell’s setColor:myColor)
　　　　　　(aColorWell’s setBordered:false)
　　　　　　(aNSV’s addSubview:aColorWell)
　　　　　　
　　　　　　set aTF to makeNSTextField(80, ((aLen – aStep + 1) * 30), 100, 20, false, myTimes as string, true, true) of me
　　　　　　(aNSV’s addSubview:aTF)
　　　　　　
　　　　　　set aStep to aStep + 1
　　　　end if
　　end repeat
　　
　　–NSScrollViewを強制的にトップにスクロール
　　set aPT to current application’s NSMakePoint(0.0, aHeight)
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:winTitle
　　　　its setInformativeText:subTitle
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end browseColors:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

–1D Listを要素別に出現回数で集計
on countItemsByItsAppearance(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bArray to current application’s NSMutableArray’s array()
　　set theEnumerator to aSet’s objectEnumerator()
　　
　　repeat
　　　　set aValue to theEnumerator’s nextObject()
　　　　if aValue is missing value then exit repeat
　　　　bArray’s addObject:(current application’s NSDictionary’s dictionaryWithObjects:{aValue, (aSet’s countForObject:aValue)} forKeys:{"theName", "numberOfTimes"})
　　end repeat
　　
　　–出現回数（numberOfTimes）で降順ソート
　　set theDesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"numberOfTimes" ascending:false
　　bArray’s sortUsingDescriptors:{theDesc}
　　
　　return bArray as list
end countItemsByItsAppearance

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

★Click Here to Open This Script　

リストの差分を取得して、登場順序が変わっていても1D List同士の登場要素が同じかをチェック

Posted on 5月 27, 2019 by Takaaki Naganoya

２つの1D List（１次元配列）同士の全要素をチェックし、登場順序に変更があったとしても要素自体に差がないかどうかをチェックするAppleScriptです。

……ソートしてから比較すれば、もっと短くて済むような気もしないでもないですが、もし違った場合には何が足りなくて（minusitems）、何が余計なのか（additems）をレポートしてくれるので実用的だと思います。

AppleScript名：リストの差分を取得して、登場順序が変わっていても1D List同士の登場要素が同じかをチェック

— Created 2019-05-27 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aList to {3, 2, 1, 7, 6, 4}
set bList to {1, 2, 3, 4, 6, 7}
set a1Res to checkAllItemsAreSame(aList, bList) of me
–> true （配列要素の登場順序が変わっていても要素はすべて同じ）

set aList to {3, 2, 1, 7, 6}
set bList to {1, 2, 3, 4, 6, 7}
set a2Res to checkAllItemsAreSame(aList, bList) of me
–> addItems:{4}, minusItems:{}}–配列要素に過不足があった

–1D List同士の全要素が（登場順序が変更になっていても）同じかどうかをチェック
on checkAllItemsAreSame(aList, bList)
　　set dRes to getDiffBetweenLists(aList, bList) of me
　　set ddRes to (dRes is equal to {addItems:{}, minusItems:{}}) as boolean
　　if ddRes = true then
　　　　return true
　　else
　　　　return dRes
　　end if
end checkAllItemsAreSame

–1D List同士のdiffを検出
on getDiffBetweenLists(aArray as list, bArray as list)
　　set allSet to current application’s NSMutableSet’s setWithArray:aArray
　　allSet’s addObjectsFromArray:bArray
　　
　　–重複する要素のみ抜き出す
　　set duplicateSet to current application’s NSMutableSet’s setWithArray:aArray
　　duplicateSet’s intersectSet:(current application’s NSSet’s setWithArray:bArray)
　　
　　–重複部分を削除する
　　allSet’s minusSet:duplicateSet
　　set resArray to (allSet’s allObjects()) as list
　　
　　set aSet to current application’s NSMutableSet’s setWithArray:aArray
　　set bSet to current application’s NSMutableSet’s setWithArray:resArray
　　aSet’s intersectSet:bSet –積集合
　　set addRes to aSet’s allObjects() as list
　　
　　set cSet to current application’s NSMutableSet’s setWithArray:bArray
　　cSet’s intersectSet:bSet –積集合
　　set minusRes to cSet’s allObjects() as list
　　
　　return {addItems:minusRes, minusItems:addRes}
end getDiffBetweenLists

★Click Here to Open This Script　

URLにリソースが存在するかチェック v5（NSURLSession）

Posted on 5月 24, 2019 by Takaaki Naganoya

指定URLの存在確認を行うAppleScriptです。

以前はNSURLConnectionを使って確認するものを使っていましたが、NSURLSessionへと移行しようかというところ。

もちろん、shellのcurlコマンドを使えば数行で済んでしまいますが、そこをあえてCocoaの機能を利用して、というよりはちょっと前に書いたREST API呼び出しのサブルーチンが絶好調で動いているので、これをそのまま流用してみました。

ライブラリ化して自分のScriptのバンドル内に入れておくとか、~/Library/Script Librariesフォルダに入れておくとか、そういう使い方になると思います。自分でもわざわざこれだけの機能のために、これだけの量のコードをゼロから書くことは……めったにありません。

AppleScript名：URLにリソースが存在するかチェック（curl版）_v2

set aURL to "http://www.apple.com/jp/"
set aRes to chekURLExistence(aURL) of me

on chekURLExistence(aURL)
　　try
　　　　set aRes to do shell script ("/usr/bin/curl -LI " & aURL)
　　on error
　　　　return false
　　end try
　　return ((aRes contains "HTTP/1.1 200") or (aRes contains "HTTP/2 200")) as boolean
end chekURLExistence

★Click Here to Open This Script　

AppleScript名：URLにリソースが存在するかチェック v5（NSURLSession）

— Created 2019-05-24 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false

set aURL to "http://piyocast.com/as/"
set uRes to chekURLExistence(aURL) of me
–> true

on chekURLExistence(aURL as string)
　　set webRes to callRestGETAPIAndParseResults(aURL, 5) of me
　　return ((retCode of webRes) as integer = 200)
end chekURLExistence

— 指定URLにファイル（画像など）が存在するかチェック
–> {存在確認結果（boolean）, レスポンスヘッダー(NSDictionary), データ(NSData)}
on callRestGETAPIAndParseResults(reqURLStr as string, timeOutSec as real)
　　set (my retData) to false
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　set aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　set hitF to false
　　aTask’s resume() –Start URL Session
　　
　　repeat (1000 * timeOutSec) times
　　　　if (my drecF) = true then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　　　delay ("0.001" as real)
　　end repeat
　　
　　if hitF = false then error "REST API Timeout Error"
　　
　　return {retData:retData, retCode:retCode, retHeaders:retHeaders}
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　parseSessionResults(tmpSession, tmpTask, tmpData) of me
　　set (my drecF) to true
end URLSession:dataTask:didReceiveData:

–ないとエラーになるので足した。とくに何もしていない
on URLSession:tmpSession dataTask:tmpTask willCacheResponse:cacheRes completionHandler:aHandler
　　—
end URLSession:dataTask:willCacheResponse:completionHandler:

on parseSessionResults(aSession, aTask, tmpData)
　　set aRes to aTask’s response()
　　set (my retCode) to aRes’s statusCode()
　　set (my retHeaders) to aRes’s allHeaderFields()
　　
　　set resStr to NSString’s alloc()’s initWithData:tmpData encoding:(NSUTF8StringEncoding)
　　set jsonString to NSString’s stringWithString:(resStr)
　　
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　set (my retData) to aJsonDict as anything
end parseSessionResults

★Click Here to Open This Script　

Script Debugger上で選択中の文字の構文要素名を取得

Posted on 5月 23, 2019 by Takaaki Naganoya

Script Debugger上でオープン中のAppleScript書類で、選択中の文字列の構文要素名を取得するAppleScriptです。

Classic Mac OS時代はScript Debuggerのほうが圧倒的にScript Editorよりも性能が上だったんですが、正直なところ、OS X 10.3ぐらいでScript Editorがスクリプタブル（AppleScriptから制御可能）になって、コンテクストメニューからAppleScriptの呼び出しができるようになって、、、、AppleがOSにデフォルトで入れているScriptが微妙だったので自分で全部書き直して（スクリプトメニュー・アシスタント）、Script Editorのほうが生産性が上がってしまった今日このごろ。

▲筆者がこれでもかと強化しまくった「Piyomaru Script Assistant」、電子書籍購入者向けのオマケとして配布中！

AppleScriptから直接Cocoaの機能が使えなかった頃には、その差は埋めがたいものがあったのですが、Cocoaの機能を使えばScript Debuggerにもこれらのスクリプトメニュー・アシスタントで提供している強力な機能を移植可能になるかもしれません。本Scriptはそのための単なる下調べです（実用性は求めていません）。

まず、本Scriptを実行できる大前提として、Script Editorの環境設定で、

のように、構文要素をきちんとすべて「別々の色」に指定してあることが必要です。Script Editor上ではこの色情報をもとに選択範囲の構文要素情報を取得しています（15年以上昔から）。

RGB値で1でも違えば別の色なので、何が何でも別の色に設定してください。

そのうえで、Script Debugger上でAppleScript書類をオープンし、なにがしかの文字列を選択。その状態で本AppleScriptを（Script Editorででも）実行すると構文要素名を返します。

Script Debuggerには、Script EditorのようなAppleScriptの内容からstyle runsを取得できるわけではないので、選択中のテキストの色情報を取得できません。

そこで、（１）Script Debuggerからは選択位置の情報だけを取得して、（２）AppleScriptでAppleScript書類から自力でstyle runs的な情報を強引に取得。（３）plistからScript Editorの構文要素色分けの情報を取得。

（１）（２）（３）の情報を付け合わせて、Script Debugger上で選択中の構文要素の名称を取得します。こういう強引な力技が日常的に登場しているのが2019年のAppleScript界隈であろうかと。

AppleScript名：Script Debugger上で選択中の文字の構文要素名を取得

— Created 2018-10-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "OSAKit"

property |NSURL| : a reference to current application’s |NSURL|
property OSANull : a reference to current application’s OSANull
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property NSCountedSet : a reference to current application’s NSCountedSet
property OSALanguageInstance : a reference to current application’s OSALanguageInstance

script spd
　　property aRecList : {}
end script

–This item is localized. See Script Editor’s Preference’s "Format"
property lexicalElementNames : {"新規テキスト（未コンパイル）", "演算子など（+&,）", "スクリプティング予約語", "アプリケーション予約語", "コメント", "値（数値、データ）", "変数およびサブルーチン名", "文字列", "コマンド名", "パラメータ名", "クラス", "プロパティ", "列挙値", "追加コマンド名", "追加パラメータ名", "追加クラス", "追加プロパティ", "追加列挙値"}

tell application "Script Debugger"
　　tell front document
　　　　try
　　　　　　save
　　　　on error
　　　　　　return
　　　　end try
　　　　
　　　　set {aLoc, aLen} to selection ASObjC range
　　　　set mySpec to file spec
　　end tell
end tell

set aRange to current application’s NSMakeRange(aLoc, aLen)

–AppleScriptのソースをAttributed Stringとして読み込んで、Dictionaryに変換
set (aRecList of spd) to getAttrRecFromASPath(mySpec) of me

set hitF to false
repeat with i in (aRecList of spd)
　　set j to contents of i
　　set bRange to itemRange of j
　　set aRes to current application’s NSIntersectionRange(aRange, bRange)
　　if aRes is not equal to {location:0, |length|:0} then
　　　　set hitF to true
　　　　–return j
　　　　–> {stringVal:"＼"あいうえお＼"", colorStr:"0 0 0", colorVal:{0, 0, 0}, fontName:"Osaka", fontSize:13.0, itemIndex:39, itemRange:{location:247, |length|:7}}
　　　　exit repeat
　　end if
end repeat

if hitF = false then return

–plistからAppleScriptの構文色分け情報を取得する
set cList to getAppleScriptSourceColorsStrVals() of me
–構文色分けの重複色チェック
set cRes to chkASLexicalFormatColorConfliction(cList) of me
if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"

set tmpArray to current application’s NSArray’s arrayWithArray:cList
set resInd to tmpArray’s indexOfObject:(colorStr of j)

set elemName to item (resInd + 1) of lexicalElementNames

on getAttrRecFromASPath(aFile)
　　set theSource to

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: Record

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

recordの値をラベルを指定して変更

指定のAppleScriptテキストを構文確認して変数・プロパティ、サブルーチン名部分のみを取得して置換

Cocoa ObjectをキーにしたDictionaryから合致するObjectを取得

Handle diff v2

AppleScript書類を構文要素ごとに分解（Script Libraries対応版）

URLにリソースが存在するかチェック v5（NSURLSession）

Script Debugger上で選択中の文字の構文要素名を取得