アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

Posted on 7月 17, 2020 by Takaaki Naganoya

アラートダイアログ上にボタンタイプのチェックボックスを並べて、選択したボタンのタイトルを選択するAppleScriptです。

書類の印刷対象を、こまかくページ指定するために作成した部品です。

ヘルプボタンにより、全ボタンの選択/非選択状態を作り出せます。

▲Beta2でAlert Dialogのタイトルまわりが変更されたようですが、、、、うーーん。あと、選択状態をボタンの見かけから知ることができないですわー

AppleScript名：アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

— Created 2020-07-17 by Takaaki Naganoya
— 2020 Piyomaru Software

set aRes to selectByCheckbox("Select each printout page", "Selected pages are the target", 64, "Helvetica") of chooseSeqNum

script chooseSeqNum
　　
　　use AppleScript version "2.5"
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　
　　property NSFont : a reference to current application’s NSFont
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSButton : a reference to current application’s NSButton
　　property NSOnState : a reference to current application’s NSOnState
　　property NSOffState : a reference to current application’s NSOffState
　　property NSTextField : a reference to current application’s NSTextField
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
　　property NSMutableDictionary : a reference to current application’s NSMutableDictionary
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSFontAttributeName : a reference to current application’s NSFontAttributeName
　　property NSKernAttributeName : a reference to current application’s NSKernAttributeName
　　property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
　　property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
　　property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
　　property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
　　property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
　　property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
　　
　　property theResult : 0
　　property returnCode : 0
　　property cList : {} –Checkbox button object array
　　property bArray : {}
　　
　　
　　on selectByCheckbox(aMainMessage, aSubMessage, aMaxPage, myFont)
　　　　set paramObj to {myMessage:aMainMessage, mySubMessage:aSubMessage, maxPage:aMaxPage, fontName:myFont}
　　　　–my chooseItemByCheckBox:paramObj –for Debugging
　　　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　　　–> {1, 3, 5, 7, 9, 11}
　　　　return cList
　　end selectByCheckbox
　　
　　on chooseItemByCheckBox:(paramObj)
　　　　set aMainMes to (myMessage of paramObj) as string
　　　　set aSubMes to (mySubMessage of paramObj) as string
　　　　set aMaxPage to (maxPage of paramObj) as integer
　　　　set aFontName to (fontName of paramObj) as string
　　　　
　　　　set cList to {}
　　　　
　　　　set colNum to 10
　　　　set rowNum to (aMaxPage div 10) + 1
　　　　set aLen to (colNum * rowNum)
　　　　
　　　　set aButtonCellWidth to 56
　　　　set aButtonCellHeight to 40
　　　　
　　　　set viewWidth to aButtonCellWidth * colNum
　　　　set viewHeight to aButtonCellHeight * (rowNum + 1)
　　　　
　　　　–define the matrix size where you’ll put the radio buttons
　　　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　　　
　　　　set aCount to 1
　　　　set aFontSize to 24
　　　　set bArray to current application’s NSMutableArray’s new()
　　　　
　　　　–Make Header (Month, Year)
　　　　set aCalList to makeSeqNumList(1, aMaxPage) of me
　　　　set aCount to 1
　　　　
　　　　
　　　　–Make Calendar (Calendar Body)
　　　　repeat with y from 1 to rowNum
　　　　　　repeat with x from 1 to colNum
　　　　　　　　–try
　　　　　　　　set j to (contents of item aCount of aCalList)
　　　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　　　
　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize))
　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), aFontName, aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeOnOff))
　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　
　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　
　　　　　　　　set aCount to aCount + 1
　　　　　　　　if aCount > aMaxPage then exit repeat
　　　　　　　　–end try
　　　　　　end repeat
　　　　　　if aCount > aMaxPage then exit repeat
　　　　end repeat
　　　　
　　　　–Select the first radio button item
　　　　–(tmpArray’s objectAtIndex:0)’s setState:(current application’s NSOnState)
　　　　set my theResult to {}
　　　　
　　　　(aView’s setSubviews:bArray)
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aView
　　　　　　
　　　　　　–for Help Button
　　　　　　its setShowsHelp:(true)
　　　　　　its setDelegate:(me)
　　　　　　
　　　　end tell
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode as number) = 1001 then error number -128
　　　　
　　　　set bNumList to (bArray’s valueForKeyPath:"state") as list
　　　　–set cList to {}
　　　　repeat with i from 1 to aMaxPage
　　　　　　set aFlag to (contents of item i of bNumList) as boolean
　　　　　　if aFlag = true then
　　　　　　　　set the end of cList to contents of i
　　　　　　end if
　　　　end repeat
　　　　
　　　　copy cList to bArray
　　end chooseItemByCheckBox:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to aParam’s runModal()
　　end doModal:
　　
　　
　　
　　on clicked:aParam
　　　　set aTag to (tag of aParam) as integer
　　　　–clicked
　　　　if aTag is not in (my theResult) then
　　　　　　set the end of (my theResult) to aTag
　　　　else
　　　　　　set theResult to my deleteItem:aTag fromList:theResult
　　　　end if
　　end clicked:
　　
　　
　　
　　on deleteItem:anItem fromList:theList
　　　　set theArray to NSMutableArray’s arrayWithArray:theList
　　　　theArray’s removeObject:anItem
　　　　return theArray as list
　　end deleteItem:fromList:
　　
　　
　　
　　–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
　　on sort1DNumList:theList ascOrder:aBool
　　　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　　　return (sortedList) as list
　　end sort1DNumList:ascOrder:
　　
　　
　　–Help Button Clicked Event Handler
　　on alertShowHelp:aNotification
　　　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　　　set bRes to (button returned of aRes) as string
　　　　
　　　　if bRes = "All Off" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　　　end repeat
　　　　　　
　　　　else if bRes = "All On" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　　　set the end of theResult to i + 1
　　　　　　end repeat
　　　　end if
　　　　
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　
　　–書式つきテキストを組み立てる
　　on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　　　set aKey1 to (NSFontAttributeName)
　　　　
　　　　set aVal2 to NSColor’s blackColor()
　　　　set aKey2 to (NSForegroundColorAttributeName)
　　　　
　　　　set aVal3 to aKerning
　　　　set akey3 to (NSKernAttributeName)
　　　　
　　　　set aVal4 to 0
　　　　set akey4 to (NSUnderlineStyleAttributeName)
　　　　
　　　　set aVal5 to 2 –all ligature ON
　　　　set akey5 to (NSLigatureAttributeName)
　　　　
　　　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　　　set akey7 to (NSParagraphStyleAttributeName)
　　　　
　　　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　　　
　　　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　　　return attrStr
　　end makeRTFfromParameters
　　
　　
　　on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aNSString’s setEditable:(editableF)
　　　　aNSString’s setStringValue:(setVal)
　　　　aNSString’s setDrawsBackground:(backgroundF)
　　　　aNSString’s setBordered:(borderedF)
　　　　return aNSString
　　end makeNSTextField
　　
　　
　　
　　on makeSeqNumList(fromNum as integer, toNum as integer)
　　　　script spd
　　　　　　property aList : {}
　　　　end script
　　　　
　　　　set aList of spd to {}
　　　　
　　　　repeat with i from fromNum to toNum
　　　　　　set the end of (aList of spd) to i
　　　　end repeat
　　　　
　　　　return (aList of spd)
　　end makeSeqNumList
　　
　　
end script

★Click Here to Open This Script　

(Visited 61 times, 1 visits today)

自分のウィンドウのフルスクリーン化 v3

Posted on 5月 22, 2020 by Takaaki Naganoya

Xcode上で作成したAppleScriptアプリケーションのウィンドウをフルスクリーン化するAppleScriptです。

–> download fullScreenTestv3 (Xcode project archive)

前バージョンを実際にアプリケーションに組み込んで実行してみたところ、メニューバーを表示しないうえにツールバー（NSToolbar）も非表示状態でフルスクリーン化したうえに、通常表示状態に戻ってこれませんでした。戻ってくるにはアプリケーションを終了（Command-Q）するしかありませんでした。

ゲームならこれでいいと思うのですが、通常のアプリケーションでフルスクリーンモードから戻ってこられないのは困りますし、メニューやツールバーが使えないのは困ります。

そこで、複数あるうちの別のやりかたを試してみました。本テストアプリケーションのツールバー上の左側のボタンが前バージョンと同じ働きをするもの、右側が新規に試したものです。

ツールバーの右側のボタンをクリックすると、ウィンドウの緑色のボタンをクリックして全画面表示させたのと同じ動きを行います。

▲ビルドして起動したところ

▲ツールバー左側のボタンをクリックして全画面表示させたところ。全画面表示されるが、ツールバーもメニューも表示されない。Command-Qで終了しないと解除されない

▲ツールバー右側のボタンをクリックして全画面表示させたところ。もう一度クリックすると通常表示モードに戻る

▲自分のアプリケーション（Kamenoko）のツールバーに組み込んで実験したところ（制作中のv1.1）

AppleScript名：AppDelegate.applescript

—
— AppDelegate.applescript
— fullScreenTest
—
— Created by Takaaki Naganoya on 2020/05/21.
— Copyright © 2020 Takaaki Naganoya. All rights reserved.
—

script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　property theWindowView : missing value
　　
　　on applicationWillFinishLaunching:aNotification
　　end applicationWillFinishLaunching:
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on clicked:aSender
　　　　set aTag to (tag of aSender) as integer
　　　　
　　　　if aTag = 10 then
　　　　　　set curScreen to theWindow’s screen()
　　　　　　set fMode to (theWindowView’s inFullScreenMode) as boolean
　　　　　　
　　　　　　if fMode = true then
　　　　　　　　–Can not return from Full Screen Mode. Quit this test app to return from full screen mode
　　　　　　　　theWindowView’s exitFullScreenModeWithOptions:(missing value)
　　　　　　else
　　　　　　　　–Enter Full Screen Mode
　　　　　　　　theWindowView’s enterFullScreenMode:(curScreen) withOptions:(missing value)
　　　　　　end if
　　　　　　
　　　　else if aTag = 20 then
　　　　　　set fMode to (theWindowView’s inFullScreenMode) as boolean
　　　　　　
　　　　　　if fMode = true then
　　　　　　　　–Exit Full Screen Mode
　　　　　　　　theWindow’s toggleFullScreen:(missing value)
　　　　　　else
　　　　　　　　–Enter Full Screen Mode with Toolbar
　　　　　　　　theWindow’s toggleFullScreen:theWindow
　　　　　　end if
　　　　end if
　　　　
　　end clicked:
end script

★Click Here to Open This Script　

(Visited 129 times, 1 visits today)

RoundWindow v2

Posted on 1月 12, 2020 by Takaaki Naganoya

Edama2さんと「無理だよねー」「そうそう、絶対無理〜」などとメールで言っていたら、Shane Stanleyから届いた「できるよ」という衝撃のメール。

スクリプトエディタ上で記述する通常のAppleScriptで、CocoaのCustom Class宣言と呼び出しができるとのこと。

自分で動作確認してみるまで、半信半疑でしたが、、、、できますねこれは、、、

–> Download Editable and Executable Script Bundle

冗談半分で思いついたことを試してみたらできてしまったり、冗談半分でできるわけないよねと念のために書いておいたことが世界の誰かの目に止まったりと、「冗談半分」ってけっこう重要なことだと思えてきました。

以下、Shane Stanleyの説明による、その書き換え手順です。

（１）Subclassファイル（複数可）をXcode上のプロジェクトで書くようなスタイルで書く

こういう（↑）スタイルですね。かならずscript宣言しつつ、parent属性を宣言しておくところがXcode上のAppleScriptアプリケーションのスタイルです。あとで動作確認して、アプリケーションの起動や終了に関するイベントハンドラを書いておいたのは無駄（実行されない）ではないかとも思われました。

（２）実行するメインのScriptのResourcesフォルダ内にSubclassファイルを入れる

普通、AppleScriptのファイルが入る/Contents/Resources/Scripts/でも、ライブラリを入れておく/Contents/Resources/Script Libraries/でもなく、/Contents/Resources/の直下に入れます。ファイル名はオリジナルのEdama2さんのものをそのまま採用していますが、割となんでもいいようです。Custom Classファイルは分割してもいいし、このサンプルのようにまとめてもいいんでしょう。

＃　追加実験してみたところ、Resourcesフォルダ以下の/Scriptsや/Script Libraries/フォルダと重複しない名称の別フォルダ（例：/Classes/）に入れておいても大丈夫でした

（３）use framework “AppleScriptObjC”の宣言文を追加

見たことのない光景ですが、書くことについてはとくに障害はありません。AppKit.Frameworkもuse宣言しておいたほうがよかったかもしれません。

（４）メインスクリプトの実行時に以下の処理を実行

set theBundle to current application’s NSBundle’s bundleWithPath:pathToFolderWithScripts
theBundle’s loadAppleScriptObjectiveCScripts()

★Click Here to Open This Script　

試行錯誤して、上記の「pathToFolderWithScripts」にバンドル内の/Contents/Resources/を入れて実行すればよいことが理解できました。

以上の変更を加えて、ためしにスクリプトエディタ＆Script Debugger上で実行してみたところ、改変前と変わりなく実行できてしまいました（冒頭のスクリーンショット）。

いや、これはめちゃくちゃすごいですよ！！　何がすごいって、CocoaのCustom Classをスクリプトライブラリ中に入れて呼び出せるということで、けっこう無茶な箱庭インタフェースが作れてしまう予感が、、、、。

そして、AppleScriptObjC（AppleScriptObjC.frameworkより）でスクリプトエディタの「.scpt」形式のファイルを読み込んで実行できてしまったということは、Xcode上のAppleScriptアプリケーション内のScriptもテキスト形式だけでなく、スクリプトエディタで編集できる.scpt形式のファイルを突っ込んで編集できる可能性が見えてきました。

ただ、テキスト形式になっていないと、Interface Builderとの連携のあたりで問題になりそうな気もします。

AppleScript名：customClassTest.scptd

—
–　　Created by: Edama2 2020/01/10
–　　Adviced by: Shane Stanley 2020/01/11
–　　Modified by: Takaaki Naganoya 2020/01/12
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

property _clock_text_view : missing value –> 時計用の文字列
property _clock_timer : missing value –> 時計用のNSTimer

–Script Bundle内のResourcesフォルダを求める
set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
theBundle’s loadAppleScriptObjectiveCScripts()

my performSelectorOnMainThread:"raizeWindow:" withObject:(missing value) waitUntilDone:true

# ウィンドウを作成
on raizeWindow:aParam
　　
　　# 時計用の文字を作成
　　tell current application’s NSTextView’s alloc()
　　　　tell initWithFrame_(current application’s NSMakeRect(35, 120, 300, 40))
　　　　　　setRichText_(true)
　　　　　　useAllLigatures_(true)
　　　　　　setTextColor_(current application’s NSColor’s whiteColor())
　　　　　　setFont_(current application’s NSFont’s fontWithName:"Arial-Black" |size|:48)
　　　　　　setBackgroundColor_(current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.0)
　　　　　　setAlphaValue_(1.0)
　　　　　　setEditable_(false)
　　　　　　–setString_("00:00:00")
　　　　　　
　　　　　　set my _clock_text_view to it
　　　　end tell
　　end tell
　　
　　# 時計を更新するNSTimerを作成
　　set my _clock_timer to current application’s NSTimer’s scheduledTimerWithTimeInterval:1 target:me selector:"idleHandler:" userInfo:(missing value) repeats:true
　　
　　# 丸いViewを作成
　　set aFrame to current application’s NSMakeRect(0, 0, 300, 300)
　　tell current application’s RoundView’s alloc()
　　　　tell initWithFrame_(aFrame)
　　　　　　setNeedsDisplay_(true)
　　　　　　setSubviews_({my _clock_text_view})
　　　　　　set customView to it
　　　　end tell
　　end tell
　　
　　#スクリーンのサイズを調べる
　　set aScreen to current application’s NSScreen’s mainScreen()
　　
　　# Window
　　set aBacking to current application’s NSWindowStyleMaskBorderless
　　–set aBacking to current application’s NSBorderlessWindowMask
　　set aDefer to current application’s NSBackingStoreBuffered
　　
　　tell current application’s CustomWindow’s alloc()
　　　　tell initWithContentRect_styleMask_backing_defer_screen_(aFrame, aBacking, aDefer, false, aScreen)
　　　　　　–setTitle_(uniqueName) –>タイトル
　　　　　　setBackgroundColor_(current application’s NSColor’s clearColor()) — Grammar Police –>背景色
　　　　　　setContentView_(customView) –>内容ビューのセット
　　　　　　setDelegate_(me) –>デリゲート
　　　　　　setDisplaysWhenScreenProfileChanges_(true) –>スクリーンプロファイルが変更されたときウインドウの内容をアップデートするか
　　　　　　setHasShadow_(true) –>ウインドウに影があるか
　　　　　　setIgnoresMouseEvents_(false) –>マウスイベントを無視するか
　　　　　　–setLevel_((current application’s NSScreenSaverWindowLevel) + 1) –>ウインドウの前後関係の位置
　　　　　　setOpaque_(false) –>ウインドウを不透明にするか
　　　　　　setReleasedWhenClosed_(true) –>閉じたときにメモリを解放するか
　　　　　　
　　　　　　#
　　　　　　|center|()
　　　　　　makeKeyAndOrderFront_(me) –>キーウインドウにして前面に持ってくる
　　　　　　–setFrame_display_(aFrame, true) –>表示
　　　　end tell
　　end tell
end raizeWindow:

#タイマー割り込み
on idleHandler:aSender
　　set mesStr to time string of (current date)
　　(my _clock_text_view)’s setString:mesStr
end idleHandler:

★Click Here to Open This Script　

AppleScript名：CocoaAppletAppDelegate.scpt

script CocoaAppletAppDelegate
　　property parent : class "NSObject"
　　
　　on applicationWillFinishLaunching:aNotification
　　　　—
　　end applicationWillFinishLaunching:
　　
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
end script

script CustomWindow
　　property parent : class "NSWindow"
　　property canBecomeKeyWindow : true
　　
　　property _initial_location : missing value
　　
　　on mouseDown:theEvent
　　　　set my _initial_location to theEvent’s locationInWindow()
　　end mouseDown:
　　
　　on mouseDragged:theEvent
　　　　–set res to display dialog "mouseDragged" buttons {"OK"} default button "OK"
　　　　try
　　　　　　set screenVisibleFrame to current application’s NSScreen’s mainScreen()’s visibleFrame()
　　　　　　set screenVisibleFrame to my myHandler(screenVisibleFrame)
　　　　　　set windowFrame to my frame()
　　　　　　set windowFrame to my myHandler(windowFrame)
　　　　　　set newOrigin to windowFrame’s origin
　　　　　　
　　　　　　set currentLocation to theEvent’s locationInWindow()
　　　　　　set newOrigin’s x to (newOrigin’s x) + ((currentLocation’s x) – (_initial_location’s x))
　　　　　　set newOrigin’s y to (newOrigin’s y) + ((currentLocation’s y) – (_initial_location’s y))
　　　　　　
　　　　　　set tmpY to ((newOrigin’s y) + (windowFrame’s |size|’s height))
　　　　　　set screenY to (screenVisibleFrame’s origin’s y) + (screenVisibleFrame’s |size|’s height)
　　　　　　if tmpY > screenY then
　　　　　　　　set newOrigin’s y to (screenVisibleFrame’s origin’s y) + ((screenVisibleFrame’s |size|’s height) – (windowFrame’s |size|’s height))
　　　　　　end if
　　　　　　
　　　　　　my setFrameOrigin:newOrigin
　　　　on error error_message number error_number
　　　　　　set error_text to "Error: " & error_number & ". " & error_message
　　　　　　display dialog error_text buttons {"OK"} default button 1
　　　　　　return error_text
　　　　end try
　　　　
　　end mouseDragged:
　　
　　on myHandler(aFrame)
　　　　if class of aFrame is list then
　　　　　　set {{theX, theY}, {theWidth, theHeight}} to aFrame
　　　　　　set aFrame to {origin:{x:theX, y:theY}, |size|:{width:theWidth, height:theHeight}}
　　　　　　–set aFrame to current application’s NSMakeRect(theX, theY, theWidth, theHeight)
　　　　end if
　　　　return aFrame
　　end myHandler
end script

script RoundView
　　property parent : class "NSView"
　　
　　on drawRect:rect
　　　　set aFrame to my frame()
　　　　set myColor to current application’s NSColor’s redColor()
　　　　
　　　　tell current application’s NSBezierPath
　　　　　　tell bezierPathWithOvalInRect_(aFrame)
　　　　　　　　myColor’s |set|()
　　　　　　　　fill()
　　　　　　end tell
　　　　end tell
　　end drawRect:
end script

★Click Here to Open This Script　

(Visited 51 times, 1 visits today)

RoundWindow

Posted on 1月 10, 2020 by Takaaki Naganoya

本Scriptは、Edama2さんから投稿していただいたものです。Cocoa AppleScript AppletでCustom Classを宣言して作られた、丸いウィンドウ（透明ウィンドウの上に丸いグラフィックを描画）を表示して、タイマー割り込みで時計を表示するAppleScriptです。

–> Download Editable and Executable Applet

AppleScriptのランタイム環境はいくつかあり、それぞれに「できること」と「できないこと」、「手軽さ」などが異なります。

（１）スクリプトエディタ上で記述、実行する環境
一番セキュリティ上の制約が緩く、できることの多い環境です。

（２）Script Debugger上で記述、実行する環境
Cocoaのイベントやオブジェクトのログ表示などができる環境です。

（３）Applet環境
AppleScriptの実行ファイルです。

（４）Script Menu環境
macOS標準装備の、メニューからAppleScriptを実行できる環境です。

さらに、Cocoa Scriptingの機能に着目してみると、見え方が変わります。

本Scriptを記述している「Cocoa AppleScript Applet」環境（上の図の赤い部分）は、スクリプトエディタ上で記述する通常のAppleScriptと、Xcode上で記述するCocoaアプリケーションの中間的な性格を持つものです。スクリプトエディタ上で直接は動かせず、アプレット形式で動作させることになりますが、スクリプトエディタ上で動かすよりも、よりCocoaの機能が利用できます。

Cocoa AppleScript Appletでは、アプリケーション（Applet）起動や終了の最中で発生するイベントを利用できますし、本ScriptのようにCocoaのCustom Classを宣言できます。これは、普通のスクリプトエディタ上で記述する（本Blogの大部分のScriptのような）Scriptではできない真似です。
→ Shane Stanleyからツッコミが入って、手の込んだ作業を行うとできるとかで（テンプレートそのままでは無理）、後で実際に試してみます

タイトルは「丸いウィンドウと時計の表示」
NSWindowのカスタムクラスを使ったタイトルバーなしのドラッグで移動できる丸いウィンドウとオマケに時計を表示したものです。
初心者受けしそうなやつです。
問題はそこではなく、
XcodeやCocoa applescript appletから実行するASOCだとカスタムクラスが作れるけど、
ノーマルのapplescriptから実行するASOCではカスタムクラスが作れないということです。
表現がややこしいですが...。
ノーマルのapplescriptからカスタムクラスを作ると、ただのスクリプトオブジェクトにしかなりません。
誰かうまい解決方法を知っている人がいたら教えてください。

ちょうど、こういう資料をまとめていたので補足説明に役立ってしまいました。スクリプトエディタ上で記述する通常のAppleScriptでもCustom Cocoa Classが宣言できると便利そうですが、どんなもんでしょうか？　

Custom Classは便利なので使いたくなる一方、AppleScriptのインタプリタ上で実行するため、Objective-Cなどで書くのと同じような感覚で使うと「遅くて使えない」という話になると思いますが、このEdama2さんのサンプルぐらいの使いかたであれば、ちょうどいいんじゃないかというところです。

歴史的にみると、Cocoa-AppleScript Appletは、Xcode上で記述するCocoa-Applicationを簡略化してスクリプトエディタ上でCocoa Scriptingを手軽に使えるように手直しした「途中」の環境といえます。

Cocoa-AppleScript Appletは、GUIが手軽に作れるわけでもなく、スクリプトエディタ上で直接実行やログ表示ができるわけでもなありません。マスターしたところで最終到達点がCocoaアプリケーションほど高くなく、編集や習熟もしづらいことから「中途半端」「使えない」という評価になっていました（自分も使っていませんでした）。

その後、Cocoa-AppleScript Appletの機能要素をさらにダウンサイジングして、スクリプトエディタ上で手軽に記述・実行ができるように進化したのが現在・広くつかわれているCocoa Scripting環境です。

ただ、使いやすくなって広く使われるようになったはいいものの、「Xcodeを使うまでもないが、もうちょっとCocoaの機能が利用できないか？」という意見も出るようになり、Cocoa-AppleScript Appletを再評価してもいいんじゃないかと考えるようになってきてはいます。

ちなみに、本Cocoa-AppleScript AppletでCustom Classを宣言しているのと同じような書き方で、通常のCocoa Scriptingの環境で動かすような変更を加えたScriptもEdama2さんが試していますが、それは「動かない」ということで結論が出ています。

AppleScript名：CocoaAppletAppDelegate.scpt

script CocoaAppletAppDelegate
　　property parent : class "NSObject"
　　
　　property _clock_text_view : missing value –> 時計用の文字列
　　property _clock_timer : missing value –> 時計用のNSTimer
　　
　　on applicationWillFinishLaunching:aNotification
　　　　my raizeWindow()
　　end applicationWillFinishLaunching:
　　
　　on applicationShouldTerminate:sender
　　　　my _clock_timer’s invalidate()
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　# ウィンドウを作成
　　on raizeWindow()
　　　　
　　　　# 時計用の文字を作成
　　　　tell current application’s NSTextView’s alloc()
　　　　　　tell initWithFrame_(current application’s NSMakeRect(35, 120, 300, 40))
　　　　　　　　setRichText_(true)
　　　　　　　　useAllLigatures_(true)
　　　　　　　　setTextColor_(current application’s NSColor’s whiteColor())
　　　　　　　　setFont_(current application’s NSFont’s fontWithName:"Arial-Black" |size|:48)
　　　　　　　　setBackgroundColor_(current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.0)
　　　　　　　　setAlphaValue_(1.0)
　　　　　　　　setEditable_(false)
　　　　　　　　–setString_("00:00:00")
　　　　　　　　
　　　　　　　　set my _clock_text_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# 時計を更新するNSTimerを作成
　　　　set my _clock_timer to current application’s NSTimer’s scheduledTimerWithTimeInterval:1 target:me selector:"idleHandler:" userInfo:(missing value) repeats:true
　　　　
　　　　
　　　　# 丸いViewを作成
　　　　set aFrame to current application’s NSMakeRect(0, 0, 300, 300)
　　　　tell current application’s RoundView’s alloc()
　　　　　　tell initWithFrame_(aFrame)
　　　　　　　　setNeedsDisplay_(true)
　　　　　　　　setSubviews_({my _clock_text_view})
　　　　　　　　set customView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　#スクリーンのサイズを調べる
　　　　set aScreen to current application’s NSScreen’s mainScreen()
　　　　
　　　　# Window
　　　　set aBacking to current application’s NSWindowStyleMaskBorderless
　　　　–set aBacking to current application’s NSBorderlessWindowMask
　　　　set aDefer to current application’s NSBackingStoreBuffered
　　　　tell current application’s CustomWindow’s alloc()
　　　　　　tell initWithContentRect_styleMask_backing_defer_screen_(aFrame, aBacking, aDefer, false, aScreen)
　　　　　　　　–setTitle_(uniqueName) –>タイトル
　　　　　　　　setBackgroundColor_(current application’s NSColor’s clearColor()) –>背景色
　　　　　　　　setContentView_(customView) –>内容ビューのセット
　　　　　　　　setDelegate_(me) –>デリゲート
　　　　　　　　setDisplaysWhenScreenProfileChanges_(true) –>スクリーンプロファイルが変更されたときウインドウの内容をアップデートするか
　　　　　　　　setHasShadow_(true) –>ウインドウに影があるか
　　　　　　　　setIgnoresMouseEvents_(false) –>マウスイベントを無視するか
　　　　　　　　–setLevel_((current application’s NSScreenSaverWindowLevel) + 1) –>ウインドウの前後関係の位置
　　　　　　　　setOpaque_(false) –>ウインドウを不透明にするか
　　　　　　　　setReleasedWhenClosed_(true) –>閉じたときにメモリを解放するか
　　　　　　　　
　　　　　　　　#
　　　　　　　　|center|()
　　　　　　　　makeKeyAndOrderFront_(me) –>キーウインドウにして前面に持ってくる
　　　　　　　　–setFrame_display_(aFrame, true) –>表示
　　　　　　end tell
　　　　end tell
　　end raizeWindow
　　
　　#タイマー割り込み
　　on idleHandler:aSender
　　　　set mesStr to time string of (current date)
　　　　(my _clock_text_view)’s setString:mesStr
　　end idleHandler:
end script

★Click Here to Open This Script　

(Visited 89 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

Posted on 12月 24, 2019 by Takaaki Naganoya

検索フィールドつきのTable View表示ダイアログを表示するAppleScriptです。項目選択を行う簡易ユーザーインタフェース（ダイアログ）で、選択肢の数が多い場合に備えて項目のキーワード抽出機能を付加したものです。

サーチフィールドの実装は無理かと思っていたのですが、単体でアラートダイアログ上に表示してみたら、予想外にキーボード入力イベントと検索語のクリアのイベントを簡単に拾えたので、Table Viewと組み合わせて試してみました。

AppleScript名：アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

— Created 2019-12-23 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSSearchField : a reference to current application’s NSSearchField
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 300
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　set aTextInput to makeNSSearchField(0, aHeight – 20, 300, 20) of me
　　　　
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 80, labelSortList) of me
　　　　
　　　　parentView’s setSubviews:{aTextInput, aScroll}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　–TextField
　　　　set aTextInput to makeNSSearchField(0, 0, 300, 20) of me
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on makeNSSearchField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer)
　　　　set aSearchF to NSSearchField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aSearchF’s setDelegate:(me)
　　　　return aSearchF
　　end makeNSSearchField
　　
　　
　　–検索クエリ入力時
　　on searchFieldDidStartSearching:(aField)
　　　　set aStr to (aField’s stringValue()) as string
　　　　set predicStr to "field1 contains[cd] ’" & aStr & "’ OR field3 contains[cd] ’" & aStr & "’"
　　　　set filteredArray to filterRecListByLabel1((my aDataList), predicStr) of me
　　　　set (my theDataSource) to filteredArray
　　　　tView’s reloadData()
　　end searchFieldDidStartSearching:
　　
　　
　　–Search Fieldの「x」ボタンを押したイベント
　　on searchFieldDidEndSearching:(aField)
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　tView’s reloadData()
　　end searchFieldDidEndSearching:
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出
　　on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　　　set aArray to NSMutableArray’s arrayWithArray:aRecList
　　　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　　　return filteredArray
　　end filterRecListByLabel1
　　
end script

★Click Here to Open This Script　

(Visited 99 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

Posted on 12月 23, 2019 by Takaaki Naganoya

アラートダイアログ上にTableViewを表示し、複数キーの組み合わせによって項目抽出。選択項目のデータを返すAppleScriptです。

あくまで試作品なので、あちらこちらに「お可愛らしい」実装が転がっています。NSBoxがまだまともに使いこなせていないあたりとか（Xcode上で部品として配置するのは楽勝ですが、プログラムから動的に生成して使用するのは別なので）。

抽出キー数は可変で外部から指定できるとよいのですが、本Scriptでは固定です。また、各抽出条件も外部から供給するのが本来あるべき姿ですが、ハードコーディングしています。

あと、TableViewの下側に謎の余白があるのは、めんどくさくなってそのまま放置しています。これで外部から各種パラメータを指定できるようにして、sdefつけて１命令で呼び出せるようにしておけば、レコード数の多い選択項目から条件抽出しつつ項目選択できてよいでしょう。

プログラム内容自体は、高度でもなければ高尚でもありません。実にダラダラとGUI部品のパラメータを設定しているだけです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

— Created 2019-12-22 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSBox : a reference to current application’s NSBox
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSPopUpButton : a reference to current application’s NSPopUpButton
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSCompoundPredicate : a reference to current application’s NSCompoundPredicate
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
　　
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　property aSel : 0
　　property bSel : 0
　　property cSel : 0
　　property predList : {}
　　property a1Button : missing value
　　property a2Button : missing value
　　property a3Button : missing value
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 400
　　　　set my aSel to 0
　　　　set my bSel to 0
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　
　　　　
　　　　–BOX Aをつくる
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 60, aWidth, 60)))
　　　　(aBox’s setTitle:("Filter Condition"))
　　　　
　　　　–このあたり、項目数に合わせてUIを可変で生成するように（本Scriptは試作品なので、決め打ちでUI生成）
　　　　set a1Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 200, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:{"▼Select Item", "MacBook", "iMac", "mini", "Air", "Pro"})
　　　　a1Button’s setTarget:(me)
　　　　a1Button’s setAction:("mySelector:")
　　　　a1Button’s setEnabled:(true)
　　　　
　　　　set a2Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(220, 0, 200, 30)) pullsDown:false)
　　　　a2Button’s removeAllItems()
　　　　(a2Button’s addItemsWithTitles:{"▼Select Item", "150000", "200000", "300000", "400000", "600000"})
　　　　a2Button’s setTarget:(me)
　　　　a2Button’s setAction:("mySelector:")
　　　　a2Button’s setEnabled:(true)
　　　　
　　　　set a3Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(440, 0, 200, 30)) pullsDown:false)
　　　　a3Button’s removeAllItems()
　　　　(a3Button’s addItemsWithTitles:{"▼Select Item", "デュアルコア", "クアッドコア", "6コア", "8コア"})
　　　　a3Button’s setTarget:(me)
　　　　a3Button’s setAction:("mySelector:")
　　　　a3Button’s setEnabled:(true)
　　　　
　　　　
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s addSubview:a2Button)
　　　　(aBox’s addSubview:a3Button)
　　　　
　　　　
　　　　–BOX Bをつくる
　　　　set bBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 80)))
　　　　(bBox’s setTitle:("Data"))
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 150, labelSortList) of me
　　　　
　　　　(bBox’s addSubview:aScroll)
　　　　
　　　　parentView’s setSubviews:{aBox, bBox}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on mySelector:aObject
　　　　set aIndex to (aObject’s indexOfSelectedItem()) as number
　　　　filterByMultipleCondition() of me
　　end mySelector:
　　
　　
　　
　　on filterByMultipleCondition()
　　　　set prediCatesArray to {}
　　　　
　　　　set aInd to (my a1Button’s indexOfSelectedItem()) as number
　　　　set bInd to (my a2Button’s indexOfSelectedItem()) as number
　　　　set cInd to (my a3Button’s indexOfSelectedItem()) as number
　　　　
　　　　if {aInd, bInd, cInd} = {0, 0, 0} then
　　　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　　　tView’s reloadData()
　　　　　　return
　　　　end if
　　　　
　　　　–このあたり、複数条件をハードコーディングしているのは超絶頭悪い。項目数の増減に対応できるべき
　　　　if aInd > 0 then
　　　　　　set aTitle to (my a1Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field1 contains ’" & aTitle & "’"
　　　　end if
　　　　
　　　　if bInd > 0 then
　　　　　　set bTitle to (my a2Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field2.integerValue < " & bTitle
　　　　end if
　　　　
　　　　if cInd > 0 then
　　　　　　set cTitle to (my a3Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field3 contains ’" & cTitle & "’"
　　　　end if
　　　　
　　　　–データ抽出
　　　　set tmpList to filterDictArrayByLabel3((my aDataList), prediCatesArray) of me
　　　　
　　　　–データ再表示
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(tmpList)
　　　　tView’s reloadData()
　　end filterByMultipleCondition
　　
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出（複数PredicatesをANDで合成）
　　on filterDictArrayByLabel3(origArray as list, aPredicateList as list)
　　　　set aArray to NSMutableArray’s arrayWithArray:origArray
　　　　set predArray to NSMutableArray’s new()
　　　　
　　　　repeat with i in aPredicateList
　　　　　　(predArray’s addObject:(NSPredicate’s predicateWithFormat:(contents of i)))
　　　　end repeat
　　　　
　　　　set pred to current application’s NSCompoundPredicate’s andPredicateWithSubpredicates:predArray
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:pred
　　　　
　　　　return filteredArray
　　end filterDictArrayByLabel3
end script

★Click Here to Open This Script　

(Visited 104 times, 1 visits today)

指定のフォントとサイズに該当するテキストを抽出する v3

Posted on 12月 1, 2019 by Takaaki Naganoya

指定のRTFファイルから書式情報を取得し、フォント名とフォントサイズのペアをスタイルを反映させたポップアップメニューで選択。RTFの内容を解析したのち、ダイアログが表示されます（ここの所要時間は読ませるRTFのサイズ次第）。ポップアップメニューで書式を選ぶと、すぐさま抽出した箇所をすべてまとめて表示します。

–> Watch Demo Movie

–> Download Script Bundle with Sample data

ダイアログ表示前に書式ごとの抽出を完了し、個別のTabViewに抽出後の文字データを展開しておくので、ポップアップメニューから選択すると、展開ずみのデータを入れてあるTabViewに表示を切り替えるだけ。切り替え時に計算は行わないため、すぐに抽出ずみの文字データが表示されるという寸法です。

今回は短いサンプルデータを処理してみましたが、サンプル抽出時にあらかじめ範囲指定するなどして、データ処理規模を限定することで処理時間を稼ぐこともできることでしょう。

テキストエディットでオープン中のRTF書類のパスを取得して、それを処理対象にしてもいいでしょう。

ただし、やっつけで作ったのでスクリプトエディタ上でCommand-Control-Rで実行しないと動きません（メインスレッド実行をプログラムで強制しても、途中でクラッシュしてしまいます）。それほど時間もかけずに作ったやっつけプログラムなので、あまり原因追求も行えずそのままです。

AppleScript名：アラートダイアログ＋Tab View v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/16
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use rtfLib : script "readStyledTextLib"
use parseLib : script "parseAttrLib"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSMenu : a reference to current application’s NSMenu
property NSArray : a reference to current application’s NSArray
property NSTabView : a reference to current application’s NSTabView
property NSPredicate : a reference to current application’s NSPredicate
property NSTextView : a reference to current application’s NSTextView
property NSMenuItem : a reference to current application’s NSMenuItem
property NSTabViewItem : a reference to current application’s NSTabViewItem
property NSPopUpButton : a reference to current application’s NSPopUpButton
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSStrokeWidthAttributeName : a reference to current application’s NSStrokeWidthAttributeName
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property TabPosition : 4 —0=Top, 1=Left, 2=Bottom, 3=Right, 4=None

property returnCode : 0

property aTabV : missing value
property selectedNum : {}

set aFile to choose file of type {"public.rtf"}

set aStyledStr to readRTFfile(aFile) of rtfLib
set paramObj to {myMessage:"Select Style", mySubMessage:"Select style you want to filter", viewWidth:800, viewHeight:400, myStyledStr:aStyledStr}

my dispTabViewWithAlertdialog:paramObj –for debug
–my performSelectorOnMainThread:"dispTabViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
return selectedNum

on dispTabViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set aWidth to (viewWidth of paramObj) as integer –TextView width
　　set aHeight to (viewHeight of paramObj) as integer –TextView height
　　set aStyledStr to (myStyledStr of paramObj)
　　
　　set attrResTmp to getAttributeRunsFromAttrString(aStyledStr) of parseLib
　　set attrList to attributes of attrResTmp
　　set menuStyle to menuList of attrResTmp
　　
　　set selectedNum to {}
　　
　　set aView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　–Ppopup Buttonをつくる
　　set a1Button to NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 20, 400, 20)) pullsDown:false
　　a1Button’s removeAllItems()
　　
　　–WYSIWHG popup menuをつくる
　　set a1Menu to NSMenu’s alloc()’s init()
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set aTitle to (tmpFont & " " & tmpSize as string) & " point"
　　　　set aMenuItem to (NSMenuItem’s alloc()’s initWithTitle:aTitle action:"actionHandler:" keyEquivalent:"")
　　　　
　　　　set attributedTitle to makeRTFfromParameters(aTitle, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　
　　　　(aMenuItem’s setEnabled:true)
　　　　(aMenuItem’s setTarget:me)
　　　　(aMenuItem’s setTag:(i as string))
　　　　(aMenuItem’s setAttributedTitle:(attributedTitle))
　　　　(a1Menu’s addItem:aMenuItem)
　　end repeat
　　
　　–Ppopup Buttonにmenuをつける
　　a1Button’s setMenu:a1Menu
　　
　　–Make Tab View
　　set aTabV to NSTabView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 30))
　　aTabV’s setTabViewType:(TabPosition)
　　
　　
　　–TabViewに中身を入れる
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set tmpKey to (tmpFont as string) & "/" & (tmpSize as string)
　　　　set tmpArry to filterRecListByLabel1(attrList, "styleKey2 == ’" & tmpKey & "’") of me
　　　　set tmpStr to (tmpArry’s valueForKeyPath:"stringVal") as list
　　　　
　　　　set aTVItem to (NSTabViewItem’s alloc()’s initWithIdentifier:(i as string))
　　　　(aTVItem’s setLabel:(i as string))
　　　　
　　　　
　　　　set aTextView to (NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth – 10, aHeight – 10)))
　　　　(aTextView’s setRichText:true)
　　　　set tmpAttr to makeRTFfromParameters(tmpStr as string, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　(aTextView’s textStorage()’s appendAttributedString:tmpAttr)
　　　　
　　　　(aTVItem’s setView:aTextView)
　　　　
　　　　(aTabV’s addTabViewItem:aTVItem)
　　end repeat
　　
　　
　　aView’s setSubviews:{a1Button, aTabV}
　　aView’s setNeedsDisplay:true
　　
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aView)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　end tell
　　
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set selectedNum to contents of item ((a1Button’s indexOfSelectedItem()) + 1) of menuStyle
end dispTabViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–Popup Action Handler
on actionHandler:sender
　　set aTag to tag of sender as integer
　　aTabV’s selectTabViewItemAtIndex:(aTag – 1)
end actionHandler:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, aFontName as string, aFontSize as real, aColor)
　　–フォント
　　set aVal1 to NSFont’s fontWithName:(aFontName) |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　–色
　　set aVal2 to aColor
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　–カーニング
　　set aVal3 to 0.0
　　set akey3 to (NSKernAttributeName)
　　
　　–アンダーライン
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　–リガチャ
　　–set aVal5 to 2 –全てのリガチャを有効にする
　　–set akey5 to ( NSLigatureAttributeName)
　　
　　–枠線（アウトライン）
　　–set aVal6 to outlineNum
　　–set akey6 to ( NSStrokeWidthAttributeName)
　　
　　
　　set keyList to {aKey1, aKey2, akey3, akey4}
　　set valList to {aVal1, aVal2, aVal3, aVal4}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　set bList to filteredArray
　　return bList
end filterRecListByLabel1

★Click Here to Open This Script　

(Visited 63 times, 1 visits today)

アラートダイアログ上にNSBoxを介してPopup Menuを表示

Posted on 11月 14, 2019 by Takaaki Naganoya

アラートダイアログ上に複数のポップアップメニュー（項目数可変）を表示し、指定リスト（配列）からの選択を行うAppleScriptです。

以前、Segmented Controlで作ったものがありましたが、Segmented Controlだと絶望的に実用性がないので、ポップアップボタンに差し替えてみたものです。

AppleScript名：アラートダイアログ上にNSBoxを介してPopup Menuを表示

— Created 2019-11-14 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSBox : a reference to current application’s NSBox
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication

property returnCode : 0
property returnSels : {}

set paramObj to {myMessage:"項目選択", mySubMessage:"以下の各項目を選択してください。", segmentMes:{{"Red1", "Blue1", "Yellow1", "Brown1", "White1", "Cyan1", "Grey1"}, {"Red2", "Blue2", "Yellow2", "Brown2", "White2", "Cyan2", "Grey2"}, {"Red3", "Blue3", "Yellow3", "Brown3", "White3", "Cyan3", "Grey3"}, {"Red4", "Blue4", "Yellow4", "Brown4", "White4", "Cyan4", "Grey4"}, {"Red5", "Blue5", "Yellow5", "Brown5", "White5", "Cyan5", "Grey5"}}, segmentTitles:{"1st Segments", "2nd Segments", "3rd Segments", "4th Segments", "5th Segments"}}

–my chooseMultipleSegments:paramObj
my performSelectorOnMainThread:"chooseMultipleSegments:" withObject:paramObj waitUntilDone:true

return my returnSels
–> {1, 2, 3, 4, 5}

on chooseMultipleSegments:paramObj
　　set aMainMes to (myMessage of paramObj) as string
　　set aSubMes to (mySubMessage of paramObj) as string
　　set segMes2DList to (segmentMes of paramObj) as list
　　set segTitleList to (segmentTitles of paramObj) as list
　　
　　set aTmpY to (length of segMes2DList) * 60
　　
　　–BoX + Segmented Control をつくる
　　set segsList to {}
　　set boxLIst to {}
　　set segsCount to 0
　　set tmpMaxX to 400
　　
　　set aCount to 1
　　
　　repeat with i in segMes2DList
　　　　set a1Button to (current application’s NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX – 30, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:(i))
　　　　
　　　　set aDBounds to a1Button’s |bounds|()
　　　　set tmpWidth to getWidth(aDBounds) of me
　　　　
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aTmpY – segsCount – 60, tmpMaxX – 10, 60)))
　　　　(aBox’s setTitle:(item aCount of segTitleList))
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s setBorderType:0) –NSNoBorder, this method is depreceted in macOS 10.14. Which is alternative?
　　　　
　　　　if tmpWidth > tmpMaxX then set tmpMaxX to tmpWidth
　　　　
　　　　set the end of segsList to a1Button –選択検出用
　　　　set the end of boxLIst to aBox –表示用
　　　　
　　　　set segsCount to segsCount + 60
　　　　set aCount to aCount + 1
　　end repeat
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX + 10, aTmpY + 20))
　　theView’s setSubviews:boxLIst
　　
　　— create a Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX + 10, 300))
　　aScroll’s setDocumentView:theView
　　aScroll’s documentView()’s scrollPoint:(current application’s NSMakePoint(0, aTmpY + 10)) –Force scroll to top
　　
　　theView’s enclosingScrollView()’s setHasHorizontalScroller:false
　　theView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set my returnSels to {}
　　repeat with i in segsList
　　　　set tmpSegSel to (i’s indexOfSelectedItem()) as number
　　　　set the end of (my returnSels) to tmpSegSel + 1
　　end repeat
end chooseMultipleSegments:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
end clickedSeg:

on getWidth(aDBounds)
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　return item 1 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　return width of |size| of aDBounds
　　end if
end getWidth

★Click Here to Open This Script　

(Visited 177 times, 1 visits today)

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

Posted on 11月 13, 2019 by Takaaki Naganoya

アラートダイアログ上に指定月のカレンダー１か月分を表示してユーザーの日付選択（複数可）をもとめるAppleScriptです。

NSDatePickerを用いて日付選択のダイアログを作っていたら、日付がとても小さくて現代のMacの画面解像度にとても合っておらず、もっと大きめのカレンダーで選択したいと考えて作ったものです。

（１）カレンダーの表示サイズを大型化

現代のMacの画面にNSDatePickerをそのまま表示すると、とても小さくて見ていられないので、表示サイズを自由に変えられるカレンダー選択部品を作ってみました。どれか１つの日付を選択するものではなく、複数の日付を選択して、リストで結果を返してきます。

▲画面上で見やすいようにカレンダー部品を大型化

（２）選択無効日指定

あらかじめ、日付選択の対象外とする日付を指定できるようにしました。

（３）過去日付の選択無効

過去の日付を表示・選択できないようにする指定です。

▲過去日付を無効に指定すると、現在日時よりも過去の日付は選択できない

（４）曜日を現在のLocale情報から変更

曜日に用いる文字列を現在のLocale情報から取得するようにしてみました。本来であれば、日曜日はじまり「ではない」カレンダーを用いている場所もあるので（香港とかフランスとか？）、どの曜日から表示開始するかを自由選択にしたいところですが、そこまでは作り込んでいません。

▲Localeに合わせた曜日が表示される（ただし、年/月は固定フォーマット）

実用性を考えれば、Calendar.appのように日付選択とスケジュール確認が行えるものが望ましいのですが、そこまで作り込む手間をかけるほどのものでもないですし、表示対象月の移動を行おうとしてclickイベントを拾いつつカレンダー再描画に失敗した「残骸」です。見た目はいいのに完成度がいまひとつというあたりが残念です。

AppleScript名：アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

— Created 2019-10-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSButton : a reference to current application’s NSButton
property NSOnState : a reference to current application’s NSOnState
property NSOffState : a reference to current application’s NSOffState
property NSTextField : a reference to current application’s NSTextField
property NSMutableArray : a reference to current application’s NSMutableArray
property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property theResult : 0
property returnCode : 0
property bArray : {} –Checkbox button object array

property tYear : 0
property tMonth : 0
property theAlert : missing value
property theView : missing value

on run
　　set tYear to 2019
　　set tMonth to 11
　　set ignoreP to true
　　set ndList to {2, 3, 4, 9, 10, 13, 16, 17, 23, 24, 25, 30} –選択表示させない日付
　　set paramObj to {myMessage:"", mySubMessage:"適切な日付を以下からえらんでください", targetYear:tYear, targetMonth:tMonth, nodisp:ndList, ignorePast:ignoreP}
　　
　　–Detect Past Date Error
　　set curDate to current date
　　set dLimit to getMlen(tYear, tMonth) of me
　　set tmpDate to getDateInternational(tYear, tMonth, dLimit) of me
　　if (tmpDate < curDate) and (ignoreP = true) then error (("Target month is past (" & tYear as string) & "/" & tMonth as string) & "/1 is past. Today is " & date string of curDate & ")"
　　
　　–my chooseItemByCheckBox:paramObj –for Debugging
　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　return my sort1DNumList:(my theResult) ascOrder:true
　　–> {1, 3, 5, 7, 9, 11}
end run

on chooseItemByCheckBox:(paramObj)
　　set aMainMes to (myMessage of paramObj) as string
　　set aSubMes to (mySubMessage of paramObj) as string
　　set aMatList to (matrixTitleList of paramObj) as list
　　set tYear to (targetYear of paramObj) as integer
　　set tMonth to (targetMonth of paramObj) as integer
　　set noDispList to (nodisp of paramObj) as list
　　set ignoreP to (ignorePast of paramObj) as boolean
　　
　　if aMainMes = "" then
　　　　set aMainMes to "日付を選択してください"
　　end if
　　
　　set theView to makeCalendarView(tYear, tMonth, noDispList, ignoreP) of me
　　
　　–Select the first radio button item
　　set my theResult to {}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　　　
　　　　–for Help Button
　　　　–its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　set aWin to its |window|()
　　end tell
　　
　　aWin’s setLevel:(current application’s NSFloatingWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end chooseItemByCheckBox:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to (tag of aParam) as integer
　　
　　–clicked
　　if aTag is not in (my theResult) then
　　　　set the end of (my theResult) to aTag
　　else
　　　　set theResult to my deleteItem:aTag fromList:theResult
　　end if
end clicked:

on deleteItem:anItem fromList:theList
　　set theArray to NSMutableArray’s arrayWithArray:theList
　　theArray’s removeObject:anItem
　　return theArray as list
end deleteItem:fromList:

–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DNumList:theList ascOrder:aBool
　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　return (sortedList) as list
end sort1DNumList:ascOrder:

–Help Button Clicked Event Handler
on alertShowHelp:aNotification
　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　set bRes to (button returned of aRes) as string
　　
　　if bRes = "All Off" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　end repeat
　　　　
　　else if bRes = "All On" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　set the end of theResult to i + 1
　　　　end repeat
　　end if
　　
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　set aVal2 to NSColor’s blackColor()
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　set aVal3 to aKerning
　　set akey3 to (NSKernAttributeName)
　　
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　set aVal5 to 2 –all ligature ON
　　set akey5 to (NSLigatureAttributeName)
　　
　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　set akey7 to (NSParagraphStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–指定月のカレンダーを1D List(7 days x 6 weeks) で返す
on retListCalendar(tYear, tMonth)
　　set mLen to getMlen(tYear, tMonth) of me
　　set aList to {}
　　
　　set fDat to getDateInternational(tYear, tMonth, 1) of me
　　tell current application
　　　　set aOffset to (weekday of fDat) as number
　　end tell
　　
　　–header gap
　　repeat (aOffset – 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　–calendar body
　　repeat with i from 1 to mLen
　　　　set the end of aList to (i as string)
　　end repeat
　　
　　–footer gap
　　repeat (42 – aOffset – mLen + 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　return aList
end retListCalendar

–現在のカレンダーで指定年月の日数を返す（国際化対応版）
on getMlen(aYear as integer, aMonth as integer)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar()
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　return |length| of theResult
end getMlen

–ローカライズされた曜日名称を返す
on getLocalizedDaynames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols() as list
　　return dayNames
end getLocalizedDaynames

–ローカライズされた月名称を返す
on getLocalizedMonthnames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set monthNames to df’s standaloneMonthSymbols() as list
　　return monthNames
end getLocalizedMonthnames

–ローカライズされた曜日の名称を返す
on getLocalizedWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s weekdaySymbols()
　　return dayNames as list
end getLocalizedWeekdaySymbol

–ローカライズされた曜日の名称（短縮版）を返す
on getLocalizedShortWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s shortWeekdaySymbols()
　　return dayNames as list
end getLocalizedShortWeekdaySymbol

–ローカライズされた曜日の名称（短縮記号）を返す
on getLocalizedVeryShortWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s veryShortWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryShortWeekdaySymbol

–ローカライズされた曜日の名称を返す
on getLocalizedVeryStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryStandaloneWeekdaySymbols

–ローカライズされた曜日の名称を返す
on getLocalizedShortStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s shortStandaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedShortStandaloneWeekdaySymbols

–ローカライズされた曜日の名称を返す
on getLocalizedVeryShortStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s veryShortStandaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryShortStandaloneWeekdaySymbols

–カレンダー表示ビューを作成
on makeCalendarView(tYear as integer, tMonth as integer, noDispList as list, ignoreP as boolean)
　　set colNum to 7
　　set rowNum to 8
　　set aLen to (colNum * rowNum)
　　
　　set aButtonCellWidth to 70 –56
　　set aButtonCellHeight to 40
　　
　　set viewWidth to aButtonCellWidth * colNum
　　set viewHeight to aButtonCellHeight * rowNum
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　
　　set aCount to 1
　　set aFontSize to 30
　　set bArray to current application’s NSMutableArray’s new()
　　
　　–Make Header (Month, Year)
　　set x to 1
　　set tmpB to (NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * (aButtonCellHeight), aButtonCellWidth * 4, aButtonCellHeight)))
　　(tmpB’s setEditable:false)
　　(tmpB’s setBordered:false)
　　(tmpB’s setDrawsBackground:false)
　　(tmpB’s setAlignment:(current application’s NSLeftTextAlignment))
　　(tmpB’s setStringValue:((tYear as string) & " / " & tMonth as string))
　　(tmpB’s setFont:(NSFont’s fontWithName:"Times-Roman" |size|:40))
　　(bArray’s addObject:tmpB)
　　
　　set aCount to aCount + 1
　　
　　
　　–Make Header (Weekday)
　　set curLocale to current application’s NSLocale’s currentLocale()
　　set aDS10 to (curLocale’s objectForKey:(current application’s NSLocaleIdentifier)) as string
　　set wdList to getLocalizedShortStandaloneWeekdaySymbols(aDS10) of me
　　set y to 2
　　
　　repeat with x from 1 to 7
　　　　set j to contents of item x of wdList
　　　　set tmpB to (NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum – 1) * (aButtonCellHeight), aButtonCellWidth, aButtonCellHeight / 2)))
　　　　(tmpB’s setEditable:false)
　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　(tmpB’s setStringValue:(j))
　　　　(bArray’s addObject:tmpB)
　　end repeat
　　
　　set aCalList to retListCalendar(tYear, tMonth) of me
　　set aCount to 1
　　
　　
　　–Make Calendar (Calendar Body)
　　set curDat to current date
　　
　　repeat with y from 3 to rowNum
　　　　repeat with x from 1 to colNum
　　　　　　set j to contents of item aCount of aCalList
　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum – 2) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　
　　　　　　set tmpDate to getDateInternational(tYear, tMonth, j as integer) of me
　　　　　　set tmpF to (tmpDate < curDat) as boolean
　　　　　　
　　　　　　if ignoreP = false then
　　　　　　　　set dispF to true
　　　　　　else if ignoreP = true and tmpF = false then
　　　　　　　　set dispF to true
　　　　　　else
　　　　　　　　set dispF to false
　　　　　　end if
　　　　　　
　　　　　　if (j as integer) is not in noDispList then
　　　　　　　　if (dispF = true) then
　　　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:"ArialMT" |size|:aFontSize))
　　　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), "ArialMT", aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeOnOff))
　　　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　　　if j is not equal to "" then
　　　　　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　end if
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　end repeat
　　
　　(aView’s setSubviews:bArray)
　　return aView
end makeCalendarView

★Click Here to Open This Script　

(Visited 128 times, 1 visits today)

アラートダイアログ上にTab View＋Popup Buttonを表示して切り替え

Posted on 9月 16, 2019 by Takaaki Naganoya

アラートダイアログ上にTabViewとPopup Buttonを表示して、Popup Menuの選択状況に合わせてTabViewの表示ビューを切り替え、Popup Menuの選択アイテムを1はじまりの番号で返すAppleScriptです。

最終的には各TabViewItem内にCustomViewを生成して、各種データ（TableとかWebとかImageとか）を一覧から選択するようなUI部品として使い回すつもりです。

このバージョンではTabViewのタブが表示状態になっていますが、最終的にはタブレスのTabViewとして表示することになります。

AppleScript名：アラートダイアログ上にTab View＋Popup Buttonを表示して切り替え

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSMenu : a reference to current application’s NSMenu
property NSTabView : a reference to current application’s NSTabView
property NSMenuItem : a reference to current application’s NSMenuItem
property NSTabViewItem : a reference to current application’s NSTabViewItem
property NSPopUpButton : a reference to current application’s NSPopUpButton
property NSRunningApplication : a reference to current application’s NSRunningApplication

property TabPosition : 0 —0=Top, 1=Left, 2=Bottom, 3=Right, 4=None

property returnCode : 0

property aTabV : missing value
property selectedNum : 1

set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", viewWidth:500, viewHeight:300}

–my dispTextViewWithAlertdialog:paramObj –for debug
my performSelectorOnMainThread:"dispTabViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
return selectedNum

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–Popup Action Handler
on actionHandler:sender
　　set aTag to tag of sender as integer
　　aTabV’s selectTabViewItemAtIndex:(aTag – 1)
end actionHandler:

★Click Here to Open This Script　

(Visited 93 times, 1 visits today)

アラートダイアログ上にcheckboxを表示 v2

Posted on 8月 11, 2019 by Takaaki Naganoya

アラートダイアログ上にチェックボックスで選択肢の入力を求めるAppleScriptです。

▲macOS 10.14上のLight Mode（Left）、Dark Mode（Right）

ラジオボタンで項目選択を行うのと同じぐらい、チェックボックスで項目選択を行うのは「よくある処理」です。ただ、それだけのためにXcode上でAppleScriptのプログラムを作るのは大袈裟なのと、できることはなるべく普通のAppleScript（Xcode上ではない）のランタイム環境上でできたほうがよいとの考えから、こうして箱庭UIをちまちま作っているものです。

本AppleScriptは、スクリプトエディタ上、スクリプトメニュー、AppleScriptアプレット、Script Debugger上などのランタイム環境で動作します。他のAppleScriptのバンドル中に入れてAppleScript Librariesとして呼び出して使うことを前提に整備してあります。

チェックした項目の番号がリストで返ってきます。各項目番号は１始まり（1-based index）です。

▲「？」ボタン(Help Button）をクリックすると、すべてのチェックボックスをオン/オフにするかを指定できる（ないと不便そうだったので）

ボタンのタイプはいくつか変更して試していますが、このあたりは最近のOSアップデートでいろいろ変更が加わっており、実際に指定しても有意な結果が得られない（なんで存在するのかよくわからない）ものもあり、実際に指定して試してみることをおすすめします。

本Scriptにはいくつか制約事項があります。選択肢の個数が奇数の場合にうやむやにする処理はつけていません。また、選択肢の文字数が長い場合への対処も一切していません。このあたりは真面目にプログラムを組む際には問題になってくることでしょう。

▲NSButtonTypeOnOff

▲NSButtonTypePushOnPushOff

▲NSButtonTypeRadio

▲NSButtonTypeSwitch

▲NSButtonTypeToggle（クリックすると遅れてステートが変化する。なにこれ？）

実際には、ライブラリ化してこんな風に呼び出して使うことを想定しています。

— Created 2019-08-07 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use checkLib : script "checkboxLib"

set paramObj to {myMessage:"Select target Item", mySubMessage:"適切なものを以下からえらんでください", mySuppression:"", myColNum:2, matrixTitleList:{"にんじん", "ごぼう", "だいこん", "りんご", "キャベツ", "レタス", "じゃがいも", "にんじん", "小松菜", "青梗菜", "しいたけ", "舞茸"}}
set aRes to dispCheckBoxMain(paramObj) of checkLib
–> {1, 2}

★Click Here to Open This Script　

AppleScript名：アラートダイアログ上にcheckboxを表示 v2

— Created 2019-08-07 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSButton : a reference to current application’s NSButton
property NSOnState : a reference to current application’s NSOnState
property NSOffState : a reference to current application’s NSOffState
property NSMutableArray : a reference to current application’s NSMutableArray
property NSButtonTypeSwitch : a reference to current application’s NSButtonTypeSwitch
property NSRunningApplication : a reference to current application’s NSRunningApplication

property theResult : 0
property returnCode : 0
property bArray : {} –Checkbox button object array

on run
　　set paramObj to {myMessage:"Select target Item", mySubMessage:"適切なものを以下からえらんでください", mySuppression:"", myColNum:2, matrixTitleList:{"にんじん", "ごぼう", "だいこん", "りんご", "キャベツ", "レタス", "じゃがいも", "にんじん", "小松菜", "青梗菜", "しいたけ", "舞茸"}}
　　
　　–my chooseItemByCheckBox:paramObj –for Debugging
　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　return my sort1DNumList:theResult ascOrder:true
　　–> {1, 3, 5, 7, 9, 11}
end run

on chooseItemByCheckBox:(paramObj)
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aMatList to (matrixTitleList of paramObj) as list
　　set aLen to length of aMatList
　　set aSupMes to mySuppression of paramObj
　　
　　set colNum to (myColNum of paramObj) as integer
　　set rowNum to (aLen div colNum) + (aLen mod colNum)
　　
　　set aButtonCellWidth to 150
　　set aButtonCellHeight to 24
　　
　　set viewWidth to aButtonCellWidth * colNum
　　set viewHeight to aButtonCellHeight * rowNum
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　
　　set aCount to 1
　　set bArray to current application’s NSMutableArray’s new()
　　repeat with y from 1 to rowNum
　　　　repeat with x from 1 to colNum
　　　　　　if aCount ≤ aLen then
　　　　　　　　set j to contents of item aCount of aMatList
　　　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　　　
　　　　　　　　(tmpB’s setTitle:j)
　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　(tmpB’s setTag:(aCount))
　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeSwitch))
　　　　　　　　
　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　
　　　　　　end if
　　　　　　
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　end repeat
　　
　　–Select the first radio button item
　　–(tmpArray’s objectAtIndex:0)’s setState:(current application’s NSOnState)
　　set theResult to {}
　　
　　(aView’s setSubviews:bArray)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aView
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　
　　　　–for suppression check box ( No use for this case? )
　　　　if (aSupMes as string) is not equal to "" then
　　　　　　its setShowsSuppressionButton:(true) –「今後このメッセージを表示しない」チェックボックスを表示
　　　　　　set suppressionB to its suppressionButton
　　　　　　suppressionB’s setTitle:(aSupMes)
　　　　else
　　　　　　its setShowsSuppressionButton:(false)
　　　　end if
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set theResult to (tmpArray’s valueForKeyPath:"status") as list
end chooseItemByCheckBox:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to (tag of aParam) as integer
　　if aTag is not in (theResult as list) then
　　　　set the end of theResult to aTag
　　else
　　　　set theResult to my deleteItem:aTag fromList:theResult
　　end if
end clicked:

on deleteItem:anItem fromList:theList
　　set theArray to NSMutableArray’s arrayWithArray:theList
　　theArray’s removeObject:anItem
　　return theArray as list
end deleteItem:fromList:

★Click Here to Open This Script　

(Visited 558 times, 1 visits today)

アラートダイアログ上にRadio Buttonを表示 v4a

Posted on 8月 7, 2019 by Takaaki Naganoya

アラートダイアログ上にRadio Buttonを表示して項目選択するAppleScriptです。

普通にラジオボタンで項目選択できるようになりました。

表示列数を指定できるようにしておきましたが、選択項目の余りが発生すると処理に矛盾が発生するため、キリのいい（割り切れる）列数を指定してください（短時間で作った試作品なので、そこまで気合は入れていません）。

AppleScript名：アラートダイアログ上にRadio Buttonを表示 v4a

— Created 2019-08-07 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSButton : a reference to current application’s NSButton
property NSRadioButton : a reference to current application’s NSRadioButton
property NSButtonTypeRadio : a reference to current application’s NSButtonTypeRadio
property NSRunningApplication : a reference to current application’s NSRunningApplication

property theResult : 0
property returnCode : 0

set paramObj to {myMessage:"Select target Item", mySubMessage:"適切なものを以下からえらんでください", myColNum:2, matrixTitleList:{"にんじん", "ごぼう", "だいこん", "りんご", "キャベツ", "レタス", "じゃがいも", "にんじん", "小松菜", "青梗菜", "しいたけ", "舞茸"}}

–my chooseItemByRadioButton:paramObj –for Debugging
my performSelectorOnMainThread:"chooseItemByRadioButton:" withObject:(paramObj) waitUntilDone:true
return (theResult as integer)

on chooseItemByRadioButton:(paramObj)
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aMatList to (matrixTitleList of paramObj) as list
　　set aLen to length of aMatList
　　
　　set colNum to (myColNum of paramObj) as integer
　　set rowNum to (aLen div colNum) + (aLen mod colNum)
　　
　　set aButtonCellWidth to 150
　　set aButtonCellHeight to 24
　　
　　set viewWidth to aButtonCellWidth * colNum
　　set viewHeight to aButtonCellHeight * rowNum
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　
　　set aCount to 1
　　set tmpArray to current application’s NSMutableArray’s new()
　　repeat with y from 1 to rowNum
　　　　repeat with x from 1 to colNum
　　　　　　if aCount ≤ aLen then
　　　　　　　　set j to contents of item aCount of aMatList
　　　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　　　
　　　　　　　　(tmpB’s setTitle:j)
　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　(tmpB’s setTag:(aCount))
　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　(tmpB’s setButtonType:(current application’s NSButtonTypeRadio))
　　　　　　　　
　　　　　　　　(tmpArray’s addObject:tmpB)
　　　　　　　　
　　　　　　end if
　　　　　　
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　end repeat
　　
　　–Select the first radio button item
　　(tmpArray’s objectAtIndex:0)’s setState:(current application’s NSOnState)
　　set theResult to 1
　　
　　(aView’s setSubviews:tmpArray)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end chooseItemByRadioButton:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to tag of aParam
　　set theResult to aTag
end clicked:

★Click Here to Open This Script　

(Visited 189 times, 1 visits today)

アラートダイアログ上にRadio Buttonを表示 v3

Posted on 8月 7, 2019 by Takaaki Naganoya

アラートダイアログ上にラジオボタン的なUIを表示して選択するAppleScriptです。

–> Downdload calImageDialog (with Library within its bundle)

本当はRadio Button的なものを作りたかったのですが、NSMatrixがmacOS 10.8で非推奨というか事実上の廃止になったことを受けて、Radio Button的なものを作ってみたのですが、割と中途半端です（見た目はスゲーいいのに）。

▲macOS 10.14＋Script Editor上の動き

▲macOS 10.14＋Script Debugger上の動き

一応、ボタンの画像に１月分のカレンダー画像を割り当てており、機能と見た目のバランスを取ろうとしたのですが、Radio Buttonっぽい動きにはなっていません（残念！）。

あと、１年分のカレンダー画像を作成するのに不思議なぐらい時間がかかっています。

あんな素朴なcalコマンドにmacOS 10.13から当日のハイライト表示を消すための「-h」オプションが追加されていたとは、気づきませんでした。10.14で作って10.12上で動かなかったのでcalコマンドのオプションを条件分岐で変更するように初版から修正しました。

AppleScript名：アラートダイアログ上にRadio Buttonを表示 v3

— Created 2019-08-07 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use calImage : script "calImageKit"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSMatrix : a reference to current application’s NSMatrix
property NSButton : a reference to current application’s NSButton
property NSButtonCell : a reference to current application’s NSButtonCell
property NSRadioButton : a reference to current application’s NSRadioButton
property NSRadioModeMatrix : a reference to current application’s NSRadioModeMatrix
property NSRoundedBezelStyle : a reference to current application’s NSRoundedBezelStyle
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0

set paramObj to {myMessage:"Select target month", mySubMessage:"適切なものを以下からえらんでください", matrixTitleList:{"1", "2", "3", "4", "5", "6", "7", "8", "9", "10", "11", "12"}}

–my chooseItemByRadioButton:paramObj–for Debugging

my performSelectorOnMainThread:"chooseItemByRadioButton:" withObject:paramObj waitUntilDone:true
return theResult

on chooseItemByRadioButton:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aMatList to (matrixTitleList of paramObj) as list
　　set aLen to length of aMatList
　　
　　
　　set aButtonCellWidth to 104
　　set aButtonCellHeight to 104
　　
　　set colNum to 4
　　set rowNum to 3
　　
　　set targYear to 2019
　　
　　set viewWidth to aButtonCellWidth * colNum
　　set viewHeight to aButtonCellHeight * rowNum
　　
　　–create the radio button prototype
　　set aProto to NSButtonCell’s alloc()’s init()
　　aProto’s setTitle:"Options"
　　aProto’s setButtonType:(NSRadioButton)
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　
　　set aCount to 1
　　set tmpArray to current application’s NSMutableArray’s new()
　　repeat with y from 1 to rowNum
　　　　repeat with x from 1 to colNum
　　　　　　set j to contents of item aCount of aMatList
　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　–(tmpB’s setTitle:j)
　　　　　　
　　　　　　set tmpImage to makeSmallCalendarImage(targYear, aCount) of calImage
　　　　　　(tmpB’s setImage:(tmpImage))
　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　(tmpB’s setTag:(aCount))
　　　　　　(tmpB’s setTarget:me)
　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　(tmpB’s setButtonType:(current application’s NSButtonTypeMomentaryPushIn))
　　　　　　
　　　　　　(tmpArray’s addObject:tmpB)
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　end repeat
　　
　　(aView’s setSubviews:tmpArray)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end chooseItemByRadioButton:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to tag of aParam
　　set theResult to aTag
end clicked:

★Click Here to Open This Script　

(Visited 83 times, 4 visits today)

アラートダイアログ上にpath control x2を表示 v2

Posted on 8月 3, 2019 by Takaaki Naganoya

アラートダイアログ上にPathcontrolを表示して、ファイルパス選択をドラッグ＆ドロップで受け付けるAppleScriptの改良版です。

実行中にアピアランスのDark Mode/Light Modeへの変更が行われたときの対応を追加してみました。

実行途中でアピアランスの変更が行われると、OSが提供している部品をそのまま利用している分にはOSの管理下で色変更が行われますが、あとから色指定している部品はそのままです（↑）。上記の（↑）ように、割と違和感があるというか、実用上困る（そもそもアピアランス変更をそんな時に行う方がどうかしているとは思うのですが）ので、対処してみました。

部品はひととおり作ってあったので、組み合わせただけです。アピアランスの変更Notificationを受信する部品や、アピアランステーマを判定する部品などです。

部品の組み合わせ方にも些細なノウハウがあるので、一応やっておいたことには意義があると思っています。

AppleScript名：アラートダイアログ上にpath control x2を表示 v2

— Created 2019-08-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextField : a reference to current application’s NSTextField
property NSPathControl : a reference to current application’s NSPathControl
property NSUserDefaults : a reference to current application’s NSUserDefaults
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSDistributedNotificationCenter : a reference to current application’s NSDistributedNotificationCenter

property theResult : 0
property returnCode : 0
property resList : {}
property aPathControl : missing value
property bPathControl : missing value

set paramObj to {myMessage:"ファイルの入出力フォルダ選択", mySubMessage:"どれか選択してください。", fromPathMes:"移動元：", toPathMes:"移動先："}
my performSelectorOnMainThread:"chooseTwoPath:" withObject:paramObj waitUntilDone:true

return resList
–> {fromPathRes:"/Users/me/Desktop/keyn1.png", toPathRes:"/Users/me/Desktop/scriptmenu1.png"}

on chooseTwoPath:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set fromLabel to fromPathMes of paramObj
　　set toLabel to toPathMes of paramObj
　　
　　—Dark Mode Notification受信開始
　　NSDistributedNotificationCenter’s defaultCenter()’s addObserver:me selector:"darkModeChanged:" |name|:"AppleInterfaceThemeChangedNotification" object:(missing value)
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 600, 60))
　　
　　— create two path control & text field
　　set aPathControl to NSPathControl’s alloc()’s initWithFrame:(current application’s NSMakeRect(100, 35, 700, 20))
　　set bPathControl to NSPathControl’s alloc()’s initWithFrame:(current application’s NSMakeRect(100, 0, 700, 20))
　　
　　–Set path control’s bg colors
　　set {aCol, bCol} to pathControlSrtringColor() of me
　　aPathControl’s setBackgroundColor:(aCol)
　　bPathControl’s setBackgroundColor:(bCol)
　　
　　
　　set aHome to current application’s |NSURL|’s fileURLWithPath:(current application’s NSHomeDirectory()) –initial dir
　　aPathControl’s setURL:aHome
　　bPathControl’s setURL:aHome
　　
　　set a1TF to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 35, 100, 20))
　　set a2TF to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 100, 20))
　　a1TF’s setEditable:false
　　a2TF’s setEditable:false
　　a1TF’s setStringValue:fromLabel
　　a2TF’s setStringValue:toLabel
　　a1TF’s setDrawsBackground:false
　　a2TF’s setDrawsBackground:false
　　a1TF’s setBordered:false
　　a2TF’s setBordered:false
　　
　　theView’s setSubviews:{a1TF, aPathControl, a2TF, bPathControl}
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set s1Val to (aPathControl’s |URL|’s |path|()) as string
　　set s2Val to (bPathControl’s |URL|’s |path|()) as string
　　
　　set resList to {fromPathRes:s1Val, toPathRes:s2Val}
　　
　　–Notification受信停止
　　NSDistributedNotificationCenter’s defaultCenter()’s removeObserver:me |name|:"AppleInterfaceThemeChangedNotification" object:(missing value)
end chooseTwoPath:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る
on retLIghtOrDark()
　　set curMode to (NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

–aMaxValを最大値とする数値でNSColorを作成して返す
on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

–Notification handler
on darkModeChanged:(aNotification)
　　set {aCol, bCol} to pathControlSrtringColor() of me
　　aPathControl’s setBackgroundColor:(aCol)
　　bPathControl’s setBackgroundColor:(bCol)
end darkModeChanged:

on pathControlSrtringColor()
　　set dMode to retLIghtOrDark() of me –Dark mode:true
　　if dMode = false then
　　　　–Light Mode
　　　　set aCol to (NSColor’s cyanColor())
　　　　set bCol to (NSColor’s yellowColor())
　　else
　　　　–Dark Mode
　　　　set aCol to (makeNSColorFromRGBAval(0, 96, 65, 255, 255) of me)
　　　　set bCol to (makeNSColorFromRGBAval(93, 92, 0, 255, 255) of me)
　　end if
　　
　　return {aCol, bCol}
end pathControlSrtringColor

★Click Here to Open This Script　

(Visited 70 times, 1 visits today)

People Picker

Posted on 7月 11, 2019 by Takaaki Naganoya

ABPersonPickerでアドレスブックに登録のあるPerson（人）をダイアログ選択するAppleScriptです。

ずいぶんと前に作ってあったものの、活用できる機会がまったくなくて埃をかぶっていました。Alertダイアログ上に表示できないかと修正してみたものの、ABPersonPickerがWindowを要求するようで、書き換えてもうまく動かなかったために「誰か改良してくれるかもしれないし、掲載しとくかー」と、引っ張り出してきたものです。

本Scriptは人物（Person）1人を選択するものであるため、正確にいえば、Person Pickerですね。

人物の選択を行うための機能はAppleScriptには提供されていないため、一般的にはアドレスブックに登録されている全員の氏名を一括で取得してchoose from listで選択するといった話になることでしょう。

それよりは幾分マシではあるものの、使い勝手という面ではさっぱりです。アドレスブック（連絡先）でAppleScriptプラグインが（macOS 10.14で）使えなくなりましたが、このような代替案だったり、使い物にならない連作先.appの代わりにAddressBookフレームワークにアクセスしてPerson情報をしぼりこんでScriptを実行するようなプログラムを作ることになるでしょう。

連絡先（旧称アドレスブック）、カレンダー（旧称iCal）は「ただ動けばいい」ぐらいのぞんざいな作りなのが本当に残念です。

▲macOS 10.14.5（Dark Mode）上で実行したところ

▲ ABPersonPicker上でキーワードによる絞り込みもリアルタイムに行える

AppleScript名：People Picker

— Created 2017-12-20 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "AddressBook"

property NSView : a reference to current application’s NSView
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property NSWindow : a reference to current application’s NSWindow
property ABPersonPicker : a reference to current application’s ABPersonPicker
property NSRectEdgeMaxX : a reference to current application’s NSRectEdgeMaxX
property NSWindowController : a reference to current application’s NSWindowController
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSRoundedBezelStyle : a reference to current application’s NSRoundedBezelStyle
property NSNormalWindowLevel : a reference to current application’s NSNormalWindowLevel
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered
property NSMomentaryLightButton : a reference to current application’s NSMomentaryLightButton

property windisp : false
property selectedPerson : missing value

on run
　　set (my selectedPerson) to missing value
　　
　　my performSelectorOnMainThread:"dispPeoplePicker:" withObject:(missing value) waitUntilDone:true
　　if (my selectedPerson) = missing value then return false
　　
　　set firstName to (my selectedPerson’s |First|) as string
　　set lastName to (my selectedPerson’s |Last|) as string
　　
　　return {lastName, firstName}
end run

on dispPeoplePicker:aParam
　　set aWidth to 300
　　set aHeight to 100
　　choosePeople(aWidth, aHeight, "Result", "OK", 180) of me
end dispPeoplePicker:

on choosePeople(aWidth as integer, aHeight as integer, aTitle as text, aButtonMSG as text, timeOutSecs as number)
　　set (my windisp) to true
　　
　　–Buttonをつくる
　　set bButton to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(aWidth / 4, 0, aWidth / 2, 40)))
　　bButton’s setTitle:aButtonMSG
　　bButton’s setButtonType:(NSMomentaryLightButton)
　　bButton’s setBezelStyle:(NSRoundedBezelStyle)
　　bButton’s setKeyEquivalent:(return)
　　bButton’s setTarget:me
　　bButton’s setAction:("clicked:")
　　
　　–NSViewをつくる
　　set aNSV to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aHeight, aWidth))
　　aNSV’s addSubview:bButton
　　aNSV’s setNeedsDisplay:true
　　
　　–NSWindowをつくる　　
　　set aWin to makeWinWithView(aNSV, aWidth, aHeight, aTitle, 1.0)
　　
　　–NSWindowControllerをつくる
　　set wController to NSWindowController’s alloc()
　　wController’s initWithWindow:aWin
　　wController’s showWindow:me
　　
　　–People Pickerをつくる
　　set anAB to ABPersonPicker’s alloc()’s init()
　　anAB’s showRelativeToRect:(current application’s NSMakeRect(0, 0, 200, 200)) ofView:aNSV preferredEdge:(NSRectEdgeMaxX)
　　anAB’s setDelegate:(me)
　　
　　–NSWindowの最前面表示　　
　　aWin’s makeKeyAndOrderFront:me
　　
　　set aCount to timeOutSecs * 10 –timeout seconds * 10
　　repeat aCount times
　　　　if (my windisp) = false then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　my closeWin:aWin
end choosePeople

–Button Clicked Event Handler
on clicked:aSender
　　set (my windisp) to false
end clicked:

–make Window for Input
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle, alphaV)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　set aBacking to NSTitledWindowMask
　　set aDefer to NSBackingStoreBuffered
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSNormalWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setAlphaValue:alphaV –append
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　aWin’s makeKeyAndOrderFront:(me)
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aWindow
　　repeat with n from 10 to 1 by -1
　　　　(aWindow’s setAlphaValue:n / 10)
　　　　delay 0.02
　　end repeat
　　aWindow’s |close|()
end closeWin:

on personPicker:(aPicker) didChoosePerson:(aPerson) |property|:(aProperty) identifier:(anID)
　　log {"personPicker:didChoosePerson:"}
　　log aPicker
　　log aPerson
　　log aProperty
　　log anID
　　copy aPerson to my selectedPerson
end personPicker:didChoosePerson:|property|:identifier:

on personPickerDidClose:(aPicker)
　　log {"personPickerDidClose"}
　　set (my windisp) to false
end personPickerDidClose:

★Click Here to Open This Script　

(Visited 61 times, 1 visits today)

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

Posted on 7月 8, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

＃　前バージョンの「自分のソースコード」表示というのは意味不明だったので、プロセス一覧を取得してみました

ヘルプボタン（？）を付け、アラートダイアログのウィンドウ背景を半透明に設定。そのままでは配色の都合上Dark Mode/Light Modeの切り替え時に読みづらい文字なども出てきたため、モード判定を行って表示色などを変更しています。

アプレット書き出ししたときに、スクロールビューがマウスのスクロールホイールの操作に追従したスクロールを行ってくれないので、そのあたり何か追加でNSScrollViewに設定を行う必要があるのだろうかと。

▲スクリプトエディタ上で実行@macOS 10.14.5。左がLight Mode、右がDark Mode（以下同様）

▲ヘルプボタンをクリックしたところ。本当にアンカーを指定して指定のヘルプコンテンツを表示させることもできる模様。そのための基礎的な試験

▲AppleScriptアプレット書き出しして実行したところ

▲Script Debugger上で実行@macOS 10.14.5。Dark Modeに対応できていない（次バージョンで対応することでしょう）

▲Script DebuggerからAppleScript Applet (Enhanced）で書き出して実行したところ。マウスのスクロールホイールの操作を受け付けて文字がスクロールする

AppleScript名：アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

— Created 2019-07-08 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication

property returnCode : 0

–Get Self Source Code (a kind of joke)
set asStr to do shell script "ps -ax"
set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:400, mesHeight:200, fontName:"HiraginoSans-W3", fontSize:11.0}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

on dispTextViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mesStr to (mes1 of paramObj) as string –Text Input field 1 Label
　　set aWidth to (mesWidth of paramObj) as integer –TextView width
　　set aHeight to (mesHeight of paramObj) as integer –TextView height
　　set aFontName to (fontName of paramObj) as string –TextView font name
　　set aFontSize to (fontSize of paramObj) as real –TextView font size
　　
　　–Detect Dark Mode
　　set dMode to retLIghtOrDark() of me
　　if dMode = true then
　　　　set tvCol to 1
　　　　set tvAlpha to 0.8
　　　　set bCol to 0.1
　　　　set bAlpha to 0.8
　　else
　　　　set tvCol to 1
　　　　set tvAlpha to 1.0
　　　　set bCol to 1
　　　　set bAlpha to 0.7
　　end if
　　
　　— Create a TextView with Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aView’s setRichText:true
　　aView’s useAllLigatures:true
　　aView’s setTextColor:(NSColor’s cyanColor()) –cyanColor
　　aView’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize)
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:(tvAlpha)
　　aView’s setBackgroundColor:aColor
　　aView’s setOpaque:(false)
　　aView’s setString:mesStr
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aScroll)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setOpaque:(false)
　　myWindow’s setBackgroundColor:(NSColor’s colorWithCalibratedWhite:(bCol) alpha:(bAlpha))
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end dispTextViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

(Visited 96 times, 1 visits today)

テキストから数値を抽出して度数分布集計 v3

Posted on 6月 29, 2019 by Takaaki Naganoya

CotEditorで編集中の最前面の書類の本文中から指定桁の数値を抽出して登場回数で度数分布の集計を行うAppleScriptです。

初版では、集計対象の数値を桁数で指定するという（使うのに）無茶な仕様になっていたので、この頭の悪い仕様に作った本人もめまいがしていました。

わざわざAppleScriptを使うのは、他のどの環境でも追いつけない高度な処理を行うことに意義があると思っています。

そこで、

　（１）数字部分をあらかじめ抽出して事前に集計（分布および最小値、最大値を計算）
　（２）事前集計結果をグラフ表示
　（３）集計対象の数字の範囲を最小値〜最大値までの間で指定できるように
　（４）パラメータの入力、および事前集計結果の表示を自前で作成したアラートダイアログで表示

といった変更を加えてみました。初版では「数字の桁数」というご無体な指定で数字を抽出していましたが、最初に最大値を計算しておいたことで、最大値の桁数ですべて数値を抽出し、最小値・最大値の間に収まる数値のみを抽出して度数分布を再計算しています（言うほど計算結果が変わってきたりはしないんですけど　＾ー＾；；）。

このぐらい行えば、安心して見られる感じでしょうか。

追記：
4.11といった文字が「4」と「11」に分離して認識されるようだったので数値として認識するCharacter setに「.」（小数点）および「,」（桁数区切り）を追加してみました。想定していた部分はうまくクリアしたものの、「REV.」の部分の「.」も認識して「0.411」のような数値として認識したようです。

このあたりに課題を残しつつも、全体として見ると当初からノイズとして除去する対象として考えていた箇所でもあったため、そんなもんだろうかと。

アラートダイアログに表示するテスト集計結果の文字が小さかったので、少し大きくしてみました。フォントについては「ヒラギノ角ゴシック W1」（PostScript名は「HiraginoSans-W1」）を指定しています。このあたりは好みに応じて変更してみるとよいでしょう。

巨大なテキスト（青空文庫の小説１作文まるごととか）を対象に処理していないので（画面キャプチャ掲載している程度のサイズ）そういう配慮は行っていません。仕事だと考慮しないでもないですが、必要と思われた処理をとりあえず組んでみた程度なので、そういうものだとお考えください。

–> Download Applet With Libraries (mainly for macOS 10.14 or later)

AppleScript名：テキストから数値を抽出して度数分布集計 v3.1

— Created 2019-06-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextField : a reference to current application’s NSTextField
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication

–property theResult : 0
property returnCode : 0
property segRes : missing value

set segRes to missing value

tell application "CotEditor"
　　if (count every document) = 0 then return –No Document
　　
　　tell front document
　　　　set aText to contents of it
　　　　set lineTerm to (line ending)
　　end tell
　　
　　–改行コードの選択（ドキュメントの状態から取得）
　　if lineTerm = LF then
　　　　set aRet to ASCII character 10 –To avoid keyword conflict (string)
　　else if lineTerm = CR then
　　　　set aRet to ASCII character 13
　　else if lineTerm = CRLF then
　　　　set aRet to (ASCII character 13) & (ASCII character 10)
　　else
　　　　set aRet to ASCII character 10
　　end if
end tell

–事前にテキストから自動で数値部分を抽出して分析
set cArray to extractNumberFromText(aText) of me
set aRes to (cArray’s valueForKeyPath:"@max.self")’s intValue()
set bRes to (cArray’s valueForKeyPath:"@min.self")’s intValue()
set cRes to (cArray’s valueForKeyPath:"@count")’s intValue()

–事前に数字の分布シミュレーションを計算
set tmpLen to count every character of (aRes as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set sampleStr to calculateNumFreq(cArray, "■", aRet, bRes, aRes, true) of me

set sampleStr to return & return & "テスト集計結果：" & return & return & sampleStr

–テキストからの数値抽出時のパラメータ取得
set paramObj to {myMessage:"テキスト内の数値の度数分布集計", mySubMessage:"集計対象の数値の範囲と、集計時のグラフ生成時の構成文字を指定してください", mes1:"最小値（min.）", mes1Default:(bRes as string), mes2:"最大値（max.）", mes2Default:(aRes as string), mes3:"出力文字", mes3Default:"絆", aSample:sampleStr}

–set segRes to my inputParametersFromAlertDialog:paramObj–for debugging
my performSelectorOnMainThread:"inputParametersFromAlertDialog:" withObject:(paramObj) waitUntilDone:true
if segRes = missing value then return –Cancel

–度数分布計算
set tmpLen to count every character of ((a2Res of segRes) as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set outStr to calculateNumFreq(cArray, a3Res of segRes, aRet, a1Res of segRes, a2Res of segRes, false) of me

–テキストエディタへの集計結果出力
tell application "CotEditor"
　　tell front document
　　　　set contents of it to (aText & aRet & aRet & "集計結果：" & aRet & aRet & outStr & aRet)
　　end tell
end tell

on inputParametersFromAlertDialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mes1Label to (mes1 of paramObj) as string –Text Input field 1 Label
　　set mes2Label to (mes2 of paramObj) as string –Text Input field 2 Label
　　set mes3Label to (mes3 of paramObj) as string –Text Input field 3 Label
　　set aTextInputString to (mes1Default of paramObj) as string –Text Input field 1 Default value
　　set bTextInputString to (mes2Default of paramObj) as string –Text Input field 2 Default value
　　set cTextInputString to (mes3Default of paramObj) as string –Text Input field 2 Default value
　　set sampleString to (aSample of paramObj) as string
　　
　　— Create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 500, 400))
　　
　　— create two input field and their labels pairs
　　–NSTextFields for Input
　　set aTextInput to makeNSTextField(100, 70, 140, 20, true, (aTextInputString), true, true) of me
　　set bTextInput to makeNSTextField(100, 35, 140, 20, true, (bTextInputString), true, true) of me
　　set cTextInput to makeNSTextField(100, 0, 140, 20, true, (cTextInputString), true, true) of me
　　
　　–Labels
　　set a1TF to makeNSTextField(0, 70, 100, 20, false, (mes1Label), false, false) of me
　　set a2TF to makeNSTextField(0, 35, 100, 20, false, (mes2Label), false, false) of me
　　set a3TF to makeNSTextField(0, 0, 100, 20, false, (mes3Label), false, false) of me
　　
　　–Sample Text View
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.9
　　set tvScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 300))
　　set tvView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 380))
　　tvView’s setRichText:true
　　tvView’s useAllLigatures:true
　　tvView’s setTextColor:(NSColor’s cyanColor()) —
　　tvView’s setFont:(current application’s NSFont’s fontWithName:"HiraginoSans-W1" |size|:16.0)
　　tvView’s setBackgroundColor:aColor
　　tvView’s setEditable:false
　　
　　tvScroll’s setDocumentView:tvView
　　tvView’s enclosingScrollView()’s setHasVerticalScroller:true
　　tvView’s setString:(sampleString)
　　
　　
　　theView’s setSubviews:{a1TF, aTextInput, a2TF, bTextInput, a3TF, cTextInput, tvScroll}
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then
　　　　set my segRes to missing value
　　else
　　　　set s1Val to (aTextInput’s integerValue()) as integer
　　　　set s2Val to (bTextInput’s integerValue()) as integer
　　　　set s3Val to (cTextInput’s stringValue()) as string
　　　　
　　　　–return {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}–old version’s way to return values
　　　　set my segRes to {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}
　　end if
end inputParametersFromAlertDialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–与えられたテキストから数値部分を抽出して1D Arrayで返す
on extractNumberFromText(aText)
　　set aStr to current application’s NSString’s stringWithString:aText
　　–set nonDigitCharacterSet to (current application’s NSCharacterSet’s decimalDigitCharacterSet())’s invertedSet()
　　set nonDigitCharacterSet to (current application’s NSCharacterSet’s characterSetWithCharactersInString:"0123456789.,")’s invertedSet()
　　set bArray to (aStr’s componentsSeparatedByCharactersInSet:nonDigitCharacterSet)
　　
　　–Sweep Blank Items
　　load framework –BridgePlus
　　set cArray to (current application’s SMSForder’s arrayByDeletingBlanksIn:(bArray))’s valueForKey:"intValue"
　　return cArray –return as NSArray
end extractNumberFromText

–正規表現でテキスト中から指定パターンに該当する箇所を抽出してリストで返す
on findPattern:thePattern inString:theString
　　set theOptions to ((current application’s NSRegularExpressionDotMatchesLineSeparators) as integer) + ((current application’s NSRegularExpressionAnchorsMatchLines) as integer)
　　set theRegEx to current application’s NSRegularExpression’s regularExpressionWithPattern:thePattern options:theOptions |error|:(missing value)
　　set theFinds to theRegEx’s matchesInString:theString options:0 range:{location:0, |length|:length of theString}
　　set theFinds to theFinds as list — so we can loop through
　　set theResult to {} — we will add to this
　　set theNSString to current application’s NSString’s stringWithString:theString
　　repeat with i from 1 to count of items of theFinds
　　　　set theRange to (item i of theFinds)’s range()
　　　　set end of theResult to (theNSString’s substringWithRange:theRange) as integer
　　end repeat
　　return theResult
end findPattern:inString:

–1D Listをユニーク化してソート
on uniquifyAndSort1DList(theList as list, aBool as boolean)
　　set aArray to current application’s NSArray’s

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSView

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

自分のウィンドウのフルスクリーン化 v3

RoundWindow v2

（１）Subclassファイル（複数可）をXcode上のプロジェクトで書くようなスタイルで書く

（２）実行するメインのScriptのResourcesフォルダ内にSubclassファイルを入れる

（３）use framework “AppleScriptObjC”の宣言文を追加

（４）メインスクリプトの実行時に以下の処理を実行

RoundWindow

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

指定のフォントとサイズに該当するテキストを抽出する v3

アラートダイアログ上にNSBoxを介してPopup Menuを表示

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

（１）カレンダーの表示サイズを大型化

（２）選択無効日指定

（３）過去日付の選択無効

（４）曜日を現在のLocale情報から変更

アラートダイアログ上にTab View＋Popup Buttonを表示して切り替え

アラートダイアログ上にRadio Buttonを表示 v3

アラートダイアログ上にpath control x2を表示 v2

People Picker

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明