Menu

Skip to content
AppleScriptの穴
  • Home
  • Products
  • Books
  • Docs
  • Events
  • Forum
  • About This Blog
  • License
  • 仕事依頼

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSWorkspace

指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力

Posted on 2月 4, 2022 by Takaaki Naganoya

指定アプリケーションが対応している各ローカライズ言語におけるアプリケーション名称を取得して、言語名をcurrent localeに合わせて変換しつつCSV出力してNumbersでオープンするAppleScriptです。

アプリケーションバンドルを調査して、ローカライズ対応している言語の一覧を取得するプログラムは組んでありました。そのローカライズを順次調べて、InfoPlist.stringsファイルを読み込み、CFBundleNameのエントリを調べています。

これで、その言語向けにローカライズされた「名称」を調べられます。あとは、言語コードを名称に変換する処理（これも、ありもの）を組み合わせて、２次元配列（2D list）にまとめあげ、CSV書き出しして（ありもの）、Numbersでオープンしただけのものです。

言語名称については、currentLocaleを利用しているため、日本語環境で実行すれば日本語表現で出力されますし、英語環境で実行すれば英語表現で出力されます。

実際に、書籍に掲載する資料用のデータを作成するときに使ってみました。

言語 Code 「地図」アプリのローカライズ名称
ドイツ語 de Karten
ヘブライ語 he מפות
英語（オーストラリア） en_AU Maps
アラビア語 ar الخرائط
ギリシャ語 el Χάρτες
日本語 ja マップ
英語 en Maps
ウクライナ語 uk Карти
スペイン語（ラテンアメリカ） es_419 Mapas
中国語（中国本土） zh_CN 地图
スペイン語 es Mapas
デンマーク語 da Kort
イタリア語 it Mappe
スロバキア語 sk Mapy
ポルトガル語（ポルトガル） pt_PT Mapas
マレー語 ms Peta
スウェーデン語 sv Kartor
チェコ語 cs Mapy
韓国語 ko 지도
広東語（中国本土） yue_CN 地图
ノルウェー語 no Kart
ハンガリー語 hu Térképek
中国語（香港） zh_HK 地圖
トルコ語 tr Harita
ポーランド語 pl Mapy
中国語（台湾） zh_TW 地圖
英語（イギリス） en_GB Maps
ベトナム語 vi Bản đồ
ロシア語 ru Карты
フランス語（カナダ） fr_CA Plans
フランス語 fr Plans
フィンランド語 fi Kartat
インドネシア語 id Peta
オランダ語 nl Kaarten
タイ語 th แผนที่
ポルトガル語 pt Mapas
ルーマニア語 ro Hărți
クロアチア語 hr Karte
ヒンディー語 hi नक़्शा
カタロニア語 ca Mapes
AppleScript名：指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/02/04
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set targFile to "InfoPlist.strings"
set targKey to "CFBundleName"

set aLocale to (current application’s NSLocale’s currentLocale())

set aLoc to path to applications folder
set anApp to POSIX path of (choose file of type {"com.apple.application-bundle"} default location aLoc)

set aBundle to getBundleFromPath(anApp) of me
set aName to aBundle’s objectForInfoDictionaryKey:(current application’s kCFBundleNameKey)

set aLocList to getSpecifiedAppFilesLocalizationListWithDuplication(aBundle) of me

set hitList to {}

repeat with i in aLocList
　　set j to contents of i
　　
　　if j is not equal to "Base" then
　　　　set allPath to anApp & "/Contents/Resources/" & j & ".lproj/" & targFile
　　　　set aDict to (current application’s NSDictionary’s alloc()’s initWithContentsOfFile:allPath)
　　　　
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　set aLang to getLangNameWithLocale(j, aLocale) of me
　　　　　　　　set the end of hitList to {aLang, j, aVal as string}
　　　　　　end if
　　　　else
　　　　　　log {"Error in ", j}
　　　　end if
　　end if
end repeat

–一時ファイルをCSV形式でデスクトップに書き出し
set aPath to (path to desktop as string) & (do shell script "uuidgen") & ".csv"
saveAsCSV(hitList, aPath) of me

–書き出したCSVファイルをNumbersでオープン
tell application "Numbers"
　　open (aPath as alias)
end tell

–Application path –> Bundle
on getBundleFromPath(aPOSIXpath)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aPOSIXpath
　　set aWorkspace to current application’s NSWorkspace’s sharedWorkspace()
　　set appURL to aWorkspace’s URLForApplicationToOpenURL:aURL
　　set aBundle to current application’s NSBundle’s bundleWithURL:appURL
　　return aBundle
end getBundleFromPath

–指定Bundleのローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(aBundle)
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on getLangNameWithLocale(langCode, aLocale)
　　set aLangName to (aLocale’s displayNameForKey:(current application’s NSLocaleIdentifier) value:langCode) as string
　　return aLangName
end getLangNameWithLocale

–2D List to CSV file
on saveAsCSV(aList, aPath)
　　–set crlfChar to (ASCII character 13) & (ASCII character 10)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　writeToFileAsUTF8(wholeText, bPath, false) of me
　　
end saveAsCSV

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

(Visited 50 times, 1 visits today)
Posted in Language Locale Record | Tagged 10.15savvy 11.0savvy 12.0savvy NSBundle NSDictionary NSLocale NSURL NSWorkspace Numbers | Leave a comment

アラートダイアログ上にCollection Viewを表示

Posted on 8月 24, 2020 by Takaaki Naganoya

emada2さんからの投稿です。Collection Viewの利用については、Kamenokoの開発時に導入検討したことがありますが、Objective-CのサンプルコードをAppleScriptに翻訳しきれなくて中途半端に放置していました。

まとまった形でCollection Viewのサンプルコードが出てきたのは、おそらくこれが初めてだと思います。ありがとうございます。

Collection Viewを箱庭ダイアログに乗せることができました。
でも残念なのは、itemPrototypeは10.14でDeprecatedになっているので将来的に長く使えないでしょう
その他のやり方を探してappleのサンプルコードをみたら、swift 3で書かれていているので10.14でビルドできませんでした。
なのでまだまだCollection Viewを使いこなすのは難しそうです😢

–> Download Script Bundle

@property (nullable, strong) NSCollectionViewItem *itemPrototype API_DEPRECATED("Use -registerNib:forItemWithIdentifier: or -registerClass:forItemWithIdentifier: instead.", macos(10.5,10.14));
AppleScript名：アラートダイアログ上にCollection Viewを表示
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "AppKit"
use framework "AppleScriptObjC"
use framework "CoreFoundation"
use framework "Foundation"
use scripting additions

on run
　　my testRun()
end run

on testRun()
　　set aMainMes to "アプリケーションの選択"
　　set aSubMes to "適切なものを以下からえらんでください"
　　
　　#ダイアログ内のビューサイズを指定
　　set aHeight to 384
　　set aWidth to 512 + 12 –> スクロールバーの分
　　
　　#アプリケーションフォルダ内のアプリケーションを取得
　　set aFolder to path to applications folder
　　set aPath to aFolder’s POSIX path
　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　
　　set filePaths to filePaths as list
　　set thisFileType to "com.apple.application-bundle"
　　
　　set dataSourceList to {}
　　repeat with anItem in filePaths
　　　　
　　　　set aPath to anItem’s contents’s POSIX path
　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　
　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　
　　　　if (aUTI as text) is thisFileType then
　　　　　　set iconImage to (current application’s NSWorkspace’s sharedWorkspace’s iconForFile:aPath)
　　　　　　set dict to {fileURL:aURL, icon:iconImage}
　　　　　　set dataSourceList’s end to dict
　　　　end if
　　end repeat
　　
　　set execButtonTitle to "OK😄"
　　
　　set dateObj to my chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
end testRun

on chooseItemByCollectionView:(aMainMes as text) subMes:(aSubMes as text) myWidth:(aWidth as integer) myHeight:(aHeight as integer) myDataSource:(dataSourceList as list) okTitle:(execButtonTitle as text)
　　
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　# subClasses.scptを呼び出す
　　set DialogCore to current application’s AppDelegate’s new()
　　set fRes to DialogCore’s chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
　　
　　if fRes is missing value then error number -128
　　return fRes as list
end chooseItemByCollectionView:subMes:myWidth:myHeight:myDataSource:okTitle:

★Click Here to Open This Script　
AppleScript名：subClasses
script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on applicationShouldTerminateAfterLastWindowClosed:sender
　　　　return true
　　end applicationShouldTerminateAfterLastWindowClosed:
　　
　　——————
　　
　　on applicationWillFinishLaunching:aNotification
　　　　log my testRun()
　　end applicationWillFinishLaunching:
　　
　　on testRun()
　　　　set aMainMes to "アプリケーションの選択"
　　　　set aSubMes to "適切なものを以下からえらんでください"
　　　　
　　　　#ダイアログ内のビューサイズを指定
　　　　set aHeight to 384
　　　　set aWidth to 512 + 12 –> スクロールバーの分
　　　　
　　　　#アプリケーションフォルダ内のアプリケーションを取得
　　　　set aFolder to path to applications folder
　　　　set aPath to aFolder’s POSIX path
　　　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　　　
　　　　# 指定フォルダの直下のファイルを取得
　　　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　　　|error|:(missing value)
　　　　
　　　　set filePaths to filePaths as list
　　　　set thisFileType to "com.apple.application-bundle"
　　　　
　　　　set dataSourceList to {}
　　　　repeat with anItem in filePaths
　　　　　　
　　　　　　set aPath to anItem’s contents’s POSIX path
　　　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　　　
　　　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　　　|error|:(reference))
　　　　　　
　　　　　　if (aUTI as text) is thisFileType then
　　　　　　　　set iconImage to (current application’s NSWorkspace’s sharedWorkspace’s iconForFile:aPath)
　　　　　　　　set dict to {fileURL:aURL, icon:iconImage}
　　　　　　　　set dataSourceList’s end to dict
　　　　　　end if
　　　　end repeat
　　　　
　　　　set execButtonTitle to "OK😄"
　　　　
　　　　set dateObj to my chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
　　end testRun
　　
　　# アラートダイアログでCollectionViewを表示
　　property _retrieve_data : missing value
　　on chooseItemByCollectionView:(aMainMes as text) subMes:(aSubMes as text) myWidth:(aWidth as integer) myHeight:(aHeight as integer) myDataSource:(dataSourceList as list) okTitle:(execButtonTitle as text)
　　　　
　　　　set paramObj to {myMessage:aMainMes}
　　　　set paramObj to paramObj & {mySubMessage:aSubMes}
　　　　set paramObj to paramObj & {myDataSource:dataSourceList}
　　　　set paramObj to paramObj & {myWidth:aWidth}
　　　　set paramObj to paramObj & {myHeight:aHeight}
　　　　set paramObj to paramObj & {myOKTitile:execButtonTitle}
　　　　
　　　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　　　
　　　　if (my _retrieve_data) is missing value then error number -128
　　　　return (my _retrieve_data)
　　end chooseItemByCollectionView:subMes:myWidth:myHeight:myDataSource:okTitle:
　　
　　## retrieve date
　　on raizeAlert:paramObj
　　　　
　　　　set mesText to paramObj’s myMessage as text
　　　　set infoText to paramObj’s mySubMessage as text
　　　　set dataSourceList to paramObj’s myDataSource as list
　　　　set viewWidth to paramObj’s myWidth as integer
　　　　set viewHeight to paramObj’s myHeight as integer
　　　　set okButton to paramObj’s myOKTitile as text
　　　　
　　　　# set up view
　　　　set {thisView, collectionView} to my makeContentView(dataSourceList, viewWidth, viewHeight)
　　　　
　　　　### set up alert
　　　　tell current application’s NSAlert’s new()
　　　　　　addButtonWithTitle_(okButton)
　　　　　　addButtonWithTitle_("Cancel")
　　　　　　setAccessoryView_(thisView)
　　　　　　–setIcon_(aImage)
　　　　　　setInformativeText_(infoText)
　　　　　　setMessageText_(mesText)
　　　　　　tell |window|()
　　　　　　　　setInitialFirstResponder_(thisView)
　　　　　　end tell
　　　　　　#### show alert in modal loop
　　　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　　　end tell
　　　　
　　　　### retrieve data
　　　　set aIndexSet to collectionView’s selectionIndexes()
　　　　set theArray to current application’s NSArrayController’s alloc()’s initWithContent:(collectionView’s content())
　　　　set chooseItems to ((theArray)’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　　　
　　　　# reset
　　　　set _retrieve_data to {}
　　　　
　　　　repeat with anItem in chooseItems
　　　　　　set (my _retrieve_data)’s end to anItem’s contents
　　　　end repeat
　　　　
　　　　return my _retrieve_data
　　end raizeAlert:
　　
　　# set up view
　　on makeContentView(dataSourceList, viewWidth, viewHeight)
　　　　
　　　　set thisRect to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　　　
　　　　tell current application’s NSCollectionView’s alloc
　　　　　　tell initWithFrame_(thisRect)
　　　　　　　　setItemPrototype_(current application’s YKZCollectionViewItem’s new())
　　　　　　　　
　　　　　　　　setAllowsEmptySelection_(true)
　　　　　　　　setAllowsMultipleSelection_(true)
　　　　　　　　setContent_(dataSourceList)
　　　　　　　　setSelectable_(true)
　　　　　　　　
　　　　　　　　set collectionView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# Viewを作成
　　　　tell current application’s NSScrollView’s alloc()
　　　　　　tell initWithFrame_(thisRect)
　　　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　　　setDocumentView_(collectionView)
　　　　　　　　setHasHorizontalScroller_(true)
　　　　　　　　setHasVerticalScroller_(true)
　　　　　　　　set baseView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return {baseView, collectionView}
　　end makeContentView
end script

#MARK: –
script YKZView
　　property parent : class "NSView"
　　
　　property imageView : missing value
　　
　　property selected : false
　　property viewItemHeight : 128
　　property viewItemWidth : 128
　　
　　on initWithFrame:rect
　　　　
　　　　set myRect to current application’s NSMakeRect(0, 0, viewItemWidth, viewItemHeight)
　　　　continue initWithFrame:myRect
　　　　
　　　　set aHeight to viewItemHeight – 10
　　　　set aWidth to viewItemWidth – 10
　　　　set newRect to current application’s NSMakeRect(5, 5, aWidth, aHeight)
　　　　
　　　　tell current application’s NSImageView’s alloc()
　　　　　　tell initWithFrame_(newRect)
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　set my imageView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　my addSubview:(my imageView)
　　　　return me
　　end initWithFrame:
　　
　　on drawRect:rect
　　　　if my selected then
　　　　　　current application’s NSColor’s redColor()’s |set|()
　　　　else
　　　　　　current application’s NSColor’s controlBackgroundColor()’s |set|()
　　　　end if
　　　　current application’s NSRectFill(rect)
　　　　continue drawRect:rect
　　end drawRect:
end script

#MARK: –
script YKZCollectionViewItem
　　property parent : class "NSCollectionViewItem"
　　
　　on loadView()
　　　　my setView:(current application’s YKZView’s alloc()’s initWithFrame:(current application’s NSZeroRect))
　　end loadView
　　
　　on setRepresentedObject:representedObject
　　　　–continue setRepresentedObject:representedObject
　　　　if representedObject is missing value then return
　　　　(my view())’s imageView’s setImage:(representedObject’s icon)
　　end setRepresentedObject:
　　
　　on setSelected:isSelected
　　　　set (my view())’s selected to isSelected
　　　　(my view())’s setNeedsDisplay:true
　　　　continue setSelected:isSelected
　　end setSelected:
end script

★Click Here to Open This Script　
(Visited 91 times, 1 visits today)
Posted in dialog file File path | Tagged 10.13savvy 10.14savvy 10.15savvy 11.0savvy NSAlert NSArrayController NSBundle NSCollectionView NSCollectionViewItem NSColor NSFileManager NSImageView NSURL NSWorkspace | Leave a comment

アラートダイアログでMarkdownをプレビュー v3a

Posted on 8月 15, 2020 by Takaaki Naganoya

edama2さんからの投稿です。Markdown書類をプレビューするAppleScriptです。

–> Download Script bundle

本Scriptには、画期的な技術が用いられています。普通、AppleScriptObjCでは、WkWebViewによるネットワークアクセスを行うと、ネットワークアクセスを行う子プロセスと、WkWebViewで表示を行う子プロセスが生じて、処理が終了しても残ってしまいます。

スクリプトエディタ上で実行した場合には、スクリプトエディタを終了すればこうした子プロセスはメモリ上からパージされますが、終了するまで子プロセスは残されたままです。

「まー、AppleScriptObjCだから仕方ないよねー」

などと去年の年末に秋葉原でカレーを食べながらバカ話をしていた記憶がありますが、edama2さんがついにこれを回避する記法を編み出してしまったわけです。

回避方法については、やり方を説明されると「なるほど」という単純明快なものです（それを思いつくのがすごい）。osascript経由でAppleScriptを再実行することで、ランタイム環境を明示的にosascriptに指定してプログラムを実行。osascriptの終了とともにメモリ上から子プロセスがパージされるということのようです。

ランタイム環境を動的に生成し、実行後にランタイム環境がメモリ上から消去されるようになっていれば、子プロセス（ゴミ）が残っていてもまとめて消える………AppleScriptのランタイム環境はosascriptのほかCocoa系もあるので、そちらでも試してみるとよいでしょう。

ほかにも、WkWebViewによる表示を行う専用の支援アプリケーションを作っておき、AppleScript用語辞書経由で表示を行わせるという解決策も考えられます（ためしていないですが）。

AppleScript名：アラートダイアログでMarkdownをプレビュー v3a
use AppleScript
use framework “AppKit”
use framework “Foundation”
use framework “WebKit”
use scripting additions

on run args
　　if (args’s class) is script then
　　　　set myPath to (path to me)’s POSIX path
set resultText to do shell script “osascript “ & myPath’s quoted form
　　else
　　　　my main()
　　end if
end run


on main()
　　set mes to “Markdownファイルを選択してください。”
set chooseItems to choose file of type {“net.daringfireball.markdown”} with prompt mes


　　#
set aScreen to current application’s NSScreen’s mainScreen()
set screenFrame to aScreen’s frame()
set aHeight to current application’s NSHeight(screenFrame)
set aWidth to current application’s NSWidth(screenFrame)
set aHeight to aHeight * 0.845
set aWidth to aWidth * 0.94 / 2


　　set paramObj to {myMessage:“Markdown preview”}
set paramObj to paramObj & {mySubMessage:“file : “ & chooseItems’s POSIX path}
set paramObj to paramObj & {mdFile:chooseItems}
set paramObj to paramObj & {viewWidth:aWidth}
set paramObj to paramObj & {viewHeight:aHeight}


　　my performSelectorOnMainThread:“displayMarkdownPreview:” withObject:(paramObj) waitUntilDone:true
end main


# Markdownをダイアログで表示
on displayMarkdownPreview:paramObj
　　set mesText to myMessage of paramObj as text
set infoText to mySubMessage of paramObj as text
set mdFile to (mdFile of paramObj) as alias
set viewWidth to (viewWidth of paramObj) as integer
set viewHeight to (viewHeight of paramObj) as integer


　　## HTMLを読み込む
set mePath to path to me
set resPath to (mePath & “Contents:Resources:index.html”) as text
set htmlStr to (read (resPath as alias) as «class utf8») as text


　　## MDを読み込む
set mdStr to (read mdFile as «class utf8») as text


　　## MD内に改行があるとうまく読み込まれないので改行を置き換え
set mdStr to current application’s NSString’s stringWithString:mdStr
set mdStr to mdStr’s stringByReplacingOccurrencesOfString:(linefeed) withString:“＼＼n”
set mdStr to mdStr’s stringByReplacingOccurrencesOfString:“’” withString:“＼＼’”


　　## html内の文字を置き換え
set aString to current application’s NSString’s stringWithFormat_(htmlStr, mdStr) as text
log result


　　## baseURL
set aPath to mdFile’s POSIX path
set baseURL to current application’s NSURL’s fileURLWithPath:aPath
set baseURL to baseURL’s URLByDeletingLastPathComponent()


　　##
set aConf to current application’s WKWebViewConfiguration’s new()
tell current application’s WKUserContentController’s new()
　　　　aConf’s setUserContentController:it
　　end tell


　　## WebViewを作成＆読み込み
set frameSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
tell current application’s WKWebView’s alloc()
　　　　tell initWithFrame_configuration_(frameSize, aConf)
　　　　　　setNavigationDelegate_(me)
setUIDelegate_(me)
loadHTMLString_baseURL_(aString, baseURL)
set theView to it
　　　　end tell
　　end tell


　　## アイコンの指定
set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:“net.daringfireball.markdown”


　　current application’s NSRunningApplication’s currentApplication()’s activateWithOptions:0


　　## set up alert
tell current application’s NSAlert’s new()
　　　　addButtonWithTitle_(“Close”)
setAccessoryView_(theView)
setIcon_(aImage)
setInformativeText_(infoText)
setMessageText_(mesText)
tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
### show alert in modal loop
if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell


　　## 後始末
theView’s stopLoading()
set js to “window.open(’about:blank’,’_self’).close();”
theView’s evaluateJavaScript:js completionHandler:(missing value)
set theView to missing value
end displayMarkdownPreview:
★Click Here to Open This Script　
(Visited 70 times, 1 visits today)
Posted in dialog Markdown URL | Tagged 10.13savvy 10.14savvy 10.15savvy 11.0savvy NSAlert NSAlertSecondButtonReturn NSRunningApplication NSScreen NSString NSURL NSWorkspace WKUserContentController WKWebView WKWebViewConfiguration | Leave a comment

アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

Posted on 8月 9, 2020 by Takaaki Naganoya

edama2さんからの投稿です。起動中のアプリケーション一覧をダイアログ表示するAppleScriptシリーズで、アプリケーションのアイコン画像やパス情報を表示し、単数/複数のアプリケーション選択ができます。

–> Download Script Bundle archive


▲単一選択（左）のダイアログと、複数選択（右）のダイアログ

タイトルは「アラートダイアログ上のTable Viewで起動中のアプリケーションを選択」
起動中のアプリケーションをiOSライクなレイアウトで表示します
Table Viewにカスタムセルビューを作って表現し、アプリの起動と終了を検知してリアルタイムで更新します
行数は12行に固定し、項目の複数選択がオプションで選べます

AppleScriptObjCフレームワークを呼び出すことにより、Xcod上で記述するAppleScriptアプリケーションのように、各種クラスのサブクラスを定義して利用しているScriptです。さまざまなScripterの技術が積み上がっている感じがして壮観ですが、ほとんどはedama2さんが長い時間をかけて積み上げてきたものの集大成といったものです。

本Scriptは途中で試行錯誤がいろいろあって、返り値がファイルパスだったりアプリケーションオブジェクトになったりと紆余曲折あって、現在の「アプリケーションオブジェクト」になりました。

ただ、実行中のアプリケーション自身を選択すると「current application」になってしまう点に注意が必要です。

AppleScript名：アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

on run
　　my testRun()
end run

on testRun()
　　
　　set mes to "選択モードを指定してください"
　　set bOK to "複数選択"
　　set bOther to "単一選択"
　　set bCancel to "キャンセル"
　　set bList to {bCancel, bOther, bOK}
　　
　　set userAction to display dialog mes buttons bList default button bOK cancel button bCancel with icon note
　　
　　if userAction’s button returned is bOther then
　　　　set isMultiple to false
　　else if userAction’s button returned is bOK then
　　　　set isMultiple to true
　　end if
　　
　　set aMainMes to "Select Runnning Application"
　　set aSubMes to "Sub Message"
　　set execButtonTitle to "OK😁"
　　set dateObj to my chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:(isMultiple) okTitle:execButtonTitle
　　
end testRun

on chooseRunningApplication:(aMainMes as text) subMes:(aSubMes as text) withMultipleSelections:(isMultiple as boolean) okTitle:(execButtonTitle as text)
　　
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　# subClasses.scptを呼び出す
　　set DialogCore to current application’s AppDelegate’s new()
　　set fRes to DialogCore’s chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:isMultiple okTitle:execButtonTitle
　　
　　if fRes is missing value then error number -128
　　return fRes as list
end chooseRunningApplication:subMes:withMultipleSelections:okTitle:

★Click Here to Open This Script　
AppleScript名：subClasses.scpt
#MARK: AppDelegate
script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on applicationShouldTerminateAfterLastWindowClosed:sender
　　　　return true
　　end applicationShouldTerminateAfterLastWindowClosed:
　　
　　on applicationWillFinishLaunching:aNotification
　　　　log my testRun()
　　end applicationWillFinishLaunching:
　　
　　——————
　　#MARK: テスト
　　on testRun()
　　　　–log "testRun"
　　　　
　　　　set mes to "選択モードを指定してください"
　　　　set bOK to "複数選択"
　　　　set bOther to "単一選択"
　　　　set bCancel to "キャンセル"
　　　　set bList to {bCancel, bOther, bOK}
　　　　
　　　　set userAction to display dialog mes buttons bList default button bOK cancel button bCancel with icon note
　　　　
　　　　if userAction’s button returned is bOther then
　　　　　　set isMultiple to false
　　　　else if userAction’s button returned is bOK then
　　　　　　set isMultiple to true
　　　　end if
　　　　
　　　　set aMainMes to "Select Runnning Application"
　　　　set aSubMes to "Sub Message"
　　　　set execButtonTitle to "OK😁"
　　　　set dateObj to my chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:(isMultiple) okTitle:execButtonTitle
　　　　
　　　　return dateObj
　　end testRun
　　
　　#MARK: アラートダイアログでtableviewを表示
　　property _retrieve_data : missing value
　　on chooseRunningApplication:(aMainMes as text) subMes:(aSubMes as text) withMultipleSelections:(isMultiple as boolean) okTitle:(execButtonTitle as text)
　　　　# reset
　　　　set my _retrieve_data to missing value
　　　　
　　　　#
　　　　if aMainMes = "" then error "Dialog main message is missing"
　　　　
　　　　#
　　　　set dataSourceList to {}
　　　　
　　　　# OKボタンの文字
　　　　if execButtonTitle = "" then set execButtonTitle to "Execute"
　　　　
　　　　set thisFileType to "com.apple.application-bundle"
　　　　
　　　　#
　　　　set paramObj to {myMessage:aMainMes}
　　　　set paramObj to paramObj & {mySubMessage:aSubMes}
　　　　set paramObj to paramObj & {myDataSource:dataSourceList}
　　　　set paramObj to paramObj & {myType:thisFileType}
　　　　set paramObj to paramObj & {mySelectType:isMultiple}
　　　　set paramObj to paramObj & {myOKTitile:execButtonTitle}
　　　　
　　　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　　　
　　　　if (my _retrieve_data) is missing value then error number -128
　　　　set retrieveData to my _retrieve_data
　　　　set my _retrieve_data to missing value
　　　　
　　　　return retrieveData
　　end chooseRunningApplication:subMes:withMultipleSelections:okTitle:
　　
　　#MARK: Raize Alert
　　on raizeAlert:paramObj
　　　　set mesText to paramObj’s myMessage as text
　　　　set infoText to paramObj’s mySubMessage as text
　　　　set dataSourceList to paramObj’s myDataSource as list
　　　　set myUTI to paramObj’s myType as text
　　　　set isMultiple to paramObj’s mySelectType as boolean
　　　　set okButton to paramObj’s myOKTitile as text
　　　　
　　　　### set up view
　　　　#### data sourceにデータを追加
　　　　set theController to current application’s YKZArrayController’s alloc()’s initWithContent:dataSourceList
　　　　theController’s setMultipleSelections:isMultiple
　　　　theController’s setupView()
　　　　
　　　　### アイコンの指定
　　　　–set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:myUTI
　　　　
　　　　set setSize to 128
　　　　set fontObj to current application’s NSFont’s systemFontOfSize:setSize
　　　　set aValue to {fontObj}
　　　　set aKey to {current application’s NSFontAttributeName}
　　　　set attributes to current application’s NSDictionary’s dictionaryWithObjects:aValue forKeys:aKey
　　　　
　　　　set strEmoji to current application’s NSString’s stringWithString:"😎"
　　　　
　　　　set newSizeObj to current application’s NSMakeSize(setSize, setSize)
　　　　tell current application’s NSImage’s alloc
　　　　　　tell initWithSize_(newSizeObj)
　　　　　　　　lockFocus()
　　　　　　　　strEmoji’s drawInRect:(current application’s NSMakeRect(0, 0, setSize, setSize)) withAttributes:attributes
　　　　　　　　unlockFocus()
　　　　　　　　set aImage to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　
　　　　### set up alert
　　　　tell current application’s NSAlert’s new()
　　　　　　addButtonWithTitle_(okButton)
　　　　　　addButtonWithTitle_("Cancel")
　　　　　　setAccessoryView_(theController’s _the_view)
　　　　　　setIcon_(aImage)
　　　　　　setInformativeText_(infoText)
　　　　　　setMessageText_(mesText)
　　　　　　tell |window|()
　　　　　　　　setInitialFirstResponder_(theController’s _the_view)
　　　　　　end tell
　　　　　　#### show alert in modal loop
　　　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　　　end tell
　　　　
　　　　### retrieve data
　　　　set (my _retrieve_data) to theController’s retrieveSelectItems()
　　　　return my _retrieve_data
　　end raizeAlert:
end script

#MARK: – NSValueTransformer
script YKZURLToIcon
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSImage –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set iconImage to current application’s NSWorkspace’s sharedWorkspace’s iconForFile:appPath
　　　　return iconImage
　　end transformedValue:
end script

script YKZURLToDisplayedName
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set displayedName to current application’s NSFileManager’s defaultManager’s displayNameAtPath:appPath
　　　　return displayedName
　　end transformedValue:
end script

script YKZURLToPath
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　return appPath
　　end transformedValue:
end script

script YKZURLToVersion
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　tell (current application’s NSBundle’s bundleWithURL:fileURL)
　　　　　　tell its infoDictionary()
　　　　　　　　set aVar to objectForKey_("CFBundleShortVersionString")
　　　　　　end tell
　　　　end tell
　　　　return aVar
　　end transformedValue:
end script

#MARK: – Array Controller
script YKZArrayController
　　property parent : class "NSArrayController"
　　
　　#MARK: IBOutlets
　　property _the_view : missing value
　　property _table_view : missing value
　　
　　#MARK: Property
　　property multipleSelections : false
　　property rowCount : 12
　　
　　#MARK: 初期化
　　on initWithContent:aContent
　　　　continue initWithContent:aContent
　　　　
　　　　#通知の登録
　　　　tell current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()
　　　　　　addObserver_selector_name_object_(me, "changed:", "NSWorkspaceDidLaunchApplicationNotification", missing value)
　　　　　　addObserver_selector_name_object_(me, "changed:", "NSWorkspaceDidTerminateApplicationNotification", missing value)
　　　　end tell
　　　　
　　　　return me
　　end initWithContent:
　　
　　
　　#MARK: 戻り値
　　on retrieveSelectItems()
　　　　set retrieveData to {}
　　　　
　　　　set aIndexSet to my _table_view’s selectedRowIndexes()
　　　　set chooseItems to ((my _table_view’s dataSource())’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　　　repeat with anItem in chooseItems
　　　　　　set aPath to anItem’s fileURL
　　　　　　set retrieveData’s end to application (aPath as text)
　　　　end repeat
　　　　
　　　　return retrieveData as list
　　end retrieveSelectItems
　　
　　#MARK: viewの作成
　　on setupView()
　　　　#Transformerの登録
　　　　set tNames to {}
　　　　set tNames’s end to "YKZURLToIcon"
　　　　set tNames’s end to "YKZURLToDisplayedName"
　　　　set tNames’s end to "YKZURLToPath"
　　　　set tNames’s end to "YKZURLToVersion"
　　　　repeat with aTransformer in tNames
　　　　　　set theTransformer to current application’s class aTransformer’s new()
　　　　　　(current application’s NSValueTransformer’s setValueTransformer:theTransformer forName:aTransformer)
　　　　end repeat
　　　　log multipleSelections
　　　　## NSTableView
　　　　tell current application’s NSTableView’s alloc()
　　　　　　tell initWithFrame_(current application’s CGRectZero)
　　　　　　　　–registerForDraggedTypes_({current application’s NSFilenamesPboardType, (my _data_type)})
　　　　　　　　setAllowsEmptySelection_(false)
　　　　　　　　setAllowsMultipleSelection_(multipleSelections)
　　　　　　　　setDataSource_(me)
　　　　　　　　setDelegate_(me)
　　　　　　　　setDoubleAction_("doubleAction:")
　　　　　　　　–setDraggingSourceOperationMask_forLocal_(current application’s NSDragOperationCopy, false)
　　　　　　　　setGridStyleMask_(current application’s NSTableViewSolidVerticalGridLineMask)
　　　　　　　　setSelectionHighlightStyle_(current application’s NSTableViewSelectionHighlightStyleRegular)
　　　　　　　　setTarget_(me)
　　　　　　　　setUsesAlternatingRowBackgroundColors_(true)
　　　　　　　　setHeaderView_(missing value)
　　　　　　　　setRowHeight_(50)
　　　　　　　　
　　　　　　　　set thisRowHeight to rowHeight() as integer
　　　　　　　　set my _table_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　## NSTableColumn
　　　　### Columnの並び順を指定する
　　　　set keyrec to {column1:"Name"}
　　　　set keyDict to (current application’s NSDictionary’s dictionaryWithDictionary:keyrec)
　　　　
　　　　set viewWidth to 400 –表示幅を変更
　　　　set columnsCount to keyDict’s |count|()
　　　　
　　　　repeat with colNum from 1 to columnsCount
　　　　　　
　　　　　　set keyName to "column" & colNum as text
　　　　　　set aTitle to (keyDict’s objectForKey:keyName)
　　　　　　
　　　　　　tell (current application’s NSTableColumn’s alloc()’s initWithIdentifier:(colNum as text))
　　　　　　　　tell headerCell()
　　　　　　　　　　setStringValue_(aTitle)
　　　　　　　　　　set thisHeaderHeight to cellSize()’s height
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　### バインディングのオプション
　　　　　　　　— ソートを無効にする
　　　　　　　　set anObj to (current application’s NSNumber’s numberWithBool:false)
　　　　　　　　set aKey to current application’s NSCreatesSortDescriptorBindingOption
　　　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　　　
　　　　　　　　### 表示内容をNSArrayControllerにバインディング
　　　　　　　　bind_toObject_withKeyPath_options_(current application’s NSValueBinding, (my _table_view’s dataSource()), "arrangedObjects", bOptions)
　　　　　　　　
　　　　　　　　set aTableColumn to it
　　　　　　end tell
　　　　　　
　　　　　　### Columnの横幅を調整
　　　　　　tell (my _table_view)
　　　　　　　　addTableColumn_(aTableColumn)
　　　　　　end tell
　　　　　　
　　　　　　tell aTableColumn
　　　　　　　　setWidth_(viewWidth)
　　　　　　end tell
　　　　end repeat
　　　　
　　　　## NSScrollView
　　　　### Viewの高さを計算
　　　　set viewHeight to thisRowHeight * rowCount + thisHeaderHeight
　　　　
　　　　#ダイアログ内のビューサイズを指定
　　　　set aScreen to current application’s NSScreen’s mainScreen()
　　　　set screenFrame to aScreen’s frame()
　　　　set aHeight to current application’s NSHeight(screenFrame)
　　　　set aWidth to current application’s NSWidth(screenFrame)
　　　　set maxHeight to aHeight * 0.845
　　　　set maxWidth to aWidth * 0.94
　　　　–log viewHeight
　　　　–log maxHeight
　　　　–set viewHeight to viewHeight + aSpace + sfHeight
　　　　if viewHeight > maxHeight then set viewHeight to maxHeight
　　　　if viewWidth > maxWidth then set viewWidth to maxWidth
　　　　if viewWidth < 360 then set viewWidth to 360
　　　　
　　　　set vSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　　　
　　　　### Viewを作成
　　　　tell current application’s NSScrollView’s alloc()
　　　　　　tell initWithFrame_(vSize)
　　　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　　　setDocumentView_(my _table_view)
　　　　　　　　setHasHorizontalScroller_(true)
　　　　　　　　setHasVerticalScroller_(true)
　　　　　　　　set my _the_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　my changed:me
　　　　
　　　　# 1行目を選択
　　　　my setSelectionIndex:0
　　　　
　　　　return my _the_view
　　end setupView
　　
　　#MARK: アプリケーションが切り替わった時
　　— tableViewを作成してから実行する
　　on changed:sender
　　　　log "changed"
　　　　
　　　　tell (my _table_view)’s dataSource()
　　　　　　removeObjects_(arrangedObjects())
　　　　end tell
　　　　
　　　　#起動中のアプリケーション
　　　　set aList to current application’s NSWorkspace’s sharedWorkspace()’s runningApplications()
　　　　set sort to (current application’s NSSortDescriptor’s alloc()’s initWithKey:"localizedName" ascending:true selector:"caseInsensitiveCompare:")
　　　　set sortedList to aList’s sortedArrayUsingDescriptors:(sort as list)
　　　　
　　　　repeat with anItem in (sortedList as list)
　　　　　　#普通のアプリだけ
　　　　　　set aFlag to anItem’s activationPolicy() is current application’s NSApplicationActivationPolicyRegular
　　　　　　if aFlag then
　　　　　　　　set theURL to anItem’s bundleURL()
　　　　　　　　((my _table_view)’s dataSource()’s addObject:{fileURL:theURL})
　　　　　　end if
　　　　　　
　　　　end repeat
　　　　
　　end changed:
　　
　　
　　#MARK: Data Source Overrides
　　on numberOfRowsInTableView:aTableView
　　　　return (aTableView’s dataSource())’s content()’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aTableView viewForTableColumn:aColumn row:aRow
　　　　
　　　　set aCellView to aTableView’s makeViewWithIdentifier:"YKZTableCellView" owner:me
　　　　
　　　　if aCellView is missing value then
　　　　　　
　　　　　　set frameRect to current application’s NSMakeRect(0, 0, aColumn’s width, aTableView’s rowHeight())
　　　　　　set aCellView to current application’s YKZTableCellView’s alloc’s initWithFrame:frameRect
　　　　　　
　　　　　　set anObj to "YKZURLToIcon"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s imageView())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToDisplayedName"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s textField())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToPath"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s pathTextField)’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToVersion"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s varTextField)’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　return aCellView
　　　　end if
　　　　
　　　　return missing value
　　end tableView:viewForTableColumn:row:
　　
　　
　　# テーブル内のセルが編集できるか
　　on tableView:aTableView shouldEditTableColumn:aColumn row:aRow
　　　　return false
　　end tableView:shouldEditTableColumn:row:
　　
　　#
　　on validateProposedFirstResponder:aResponder forEvent:aEvent
　　　　log "validateProposedFirstResponder"
　　　　return true
　　　　
　　　　set aBoolean to aResponder’s isKindOfClass:(current application’s NSTableCellView’s |class|())
　　　　if aBoolean as boolean then
　　　　　　return true
　　　　end if
　　　　
　　　　return true
　　end validateProposedFirstResponder:forEvent:
　　
　　# テーブル内をダブルクリックしたらOKボタンを押す
　　on doubleAction:sender
　　　　log "doubleAction"
　　　　## ヘッダをクリックした時は何もしない
　　　　if (sender’s clickedRow()) is -1 then return
　　　　
　　　　set theEvent to current application’s NSEvent’s ¬
　　　　　　keyEventWithType:(current application’s NSEventTypeKeyDown) ¬
　　　　　　　　location:(current application’s NSZeroPoint) ¬
　　　　　　　　modifierFlags:0 ¬
　　　　　　　　timestamp:0.0 ¬
　　　　　　　　windowNumber:(sender’s |window|()’s windowNumber()) ¬
　　　　　　　　context:(current application’s NSGraphicsContext’s currentContext()) ¬
　　　　　　　　|characters|:return ¬
　　　　　　　　charactersIgnoringModifiers:(missing value) ¬
　　　　　　　　isARepeat:false ¬
　　　　　　　　keyCode:0
　　　　current application’s NSApp’s postEvent:theEvent atStart:(not false)
　　end doubleAction:
　　
end script

#MARK: – NSTableCellView
script YKZTableCellView
　　property parent : class "NSTableCellView"
　　
　　property acceptsFirstResponder : true
　　
　　property pathTextField : missing value
　　property varTextField : missing value
　　
　　on initWithFrame:rect
　　　　continue initWithFrame:rect
　　　　
　　　　setAutoresizingMask_(current application’s NSViewWidthSizable)
　　　　
　　　　–set myWidth to current application’s NSWidth(rect)
　　　　–set myHeight to current application’s NSHeight(rect)
　　　　
　　　　# アイコン
　　　　tell current application’s NSImageView’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(12, 1, 48, 48))
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　my setImageView:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# 表示名
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(66, 26, 280, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setFont_(current application’s NSFont’s boldSystemFontOfSize:13)
　　　　　　　　my setTextField:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# パス
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(66, 6, 316, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setFont_(current application’s NSFont’s systemFontOfSize:11)
　　　　　　　　set my pathTextField to it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# バージョン
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(300, 24, 80, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setFont_(current application’s NSFont’s systemFontOfSize:11)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setAlignment_(current application’s NSRightTextAlignment)
　　　　　　　　set my varTextField to it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return me
　　end initWithFrame:
end script

★Click Here to Open This Script　
(Visited 56 times, 1 visits today)
Posted in dialog | Tagged 10.13savvy 10.14savvy 10.15savvy 11.0savvy AppDelegate NSAlert NSBundle NSDictionary NSFileManager NSFont NSFontAttributeName NSImage NSString NSValueTransformer NSWorkspace | Leave a comment

アラートダイアログでMarkdownをプレビュー v2

Posted on 8月 8, 2020 by Takaaki Naganoya

edama2さんから投稿していただいた、Markdown書類をダイアログ上でプレビューするScriptの第二弾です。

–> Download Script Bundle

WKWebViewではなくNSAttributedStringを使ってMarkdownを表示しています。
NSAttributedStringでhtmlが表示できるとわかってWKWebViewの代わりになるかな？と思ったんですが、javascriptは使えないので自前で実行し、NSAttributedStringに＜hr＞に相当するものがないのとWKWebViewとは描画結果が違うので、プレビューとして使うのはイマイチです。作っておいてなんですが…😢

本Scriptの見どころは２点。「Scriptバンドル内にJavaScriptのライブラリを突っ込んで呼び出しているところ」と、「Markdownを（HTML経由で）NSAttributedStringに変換してプレビューしている」ところです。

ひかえめな説明文とは裏腹に、ずいぶんと攻めているというか、野心的な実装です。

JavaScriptのライブラリをローカルに置く案についてはいろいろedama2さんと意見交換をしていたんですが、割とさらっと書いているところにショックを受けます。これだけでも、相当に試行錯誤が必要な内容なんですが、このレベルに追いつくためには相当の苦労が、、、

AppleScript名：アラートダイアログでMarkdownをプレビュー v2
use AppleScript
use framework "Foundation"
use scripting additions

on run
　　my main()
end run

on main()
　　set mes to "Markdownファイルを選択してください。"
　　set chooseItems to choose file of type {"net.daringfireball.markdown"} with prompt mes
　　
　　#
　　set aScreen to current application’s NSScreen’s mainScreen()
　　set screenFrame to aScreen’s frame()
　　set aHeight to current application’s NSHeight(screenFrame)
　　set aWidth to current application’s NSWidth(screenFrame)
　　set aHeight to aHeight * 0.845
　　set aWidth to aWidth * 0.94 / 2
　　
　　set paramObj to {}
　　set paramObj to paramObj & {myMessage:"Markdown preview"}
　　set paramObj to paramObj & {mySubMessage:"file : " & chooseItems’s POSIX path}
　　set paramObj to paramObj & {mdFile:chooseItems}
　　set paramObj to paramObj & {viewWidth:aWidth}
　　set paramObj to paramObj & {viewHeight:aHeight}
　　
　　my performSelectorOnMainThread:"displayMarkdownPreview:" withObject:(paramObj) waitUntilDone:true
end main

# Markdownをダイアログで表示
on displayMarkdownPreview:paramObj
　　set mesText to myMessage of paramObj as text
　　set infoText to mySubMessage of paramObj as text
　　set mdFile to (mdFile of paramObj) as alias
　　set viewWidth to (viewWidth of paramObj) as integer
　　set viewHeight to (viewHeight of paramObj) as integer
　　
　　## MDを読み込む
　　set mdStr to (read mdFile as «class utf8») as text
　　
　　## javascriptを読み込む
　　set mePath to path to me
　　set resPath to (mePath & "Contents:Resources:marked.min.js") as text
　　set jsStr to (read (resPath as alias) as «class utf8») as text
　　
　　## javascriptでMarkdownをhtmlに変換
　　tell current application’s JSContext’s new()
　　　　evaluateScript_(jsStr)
　　　　tell objectForKeyedSubscript_("marked")
　　　　　　tell callWithArguments_({mdStr})
　　　　　　　　set resultStr to toString()
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　## HTMLを読み込む
　　set mePath to path to me
　　set resPath to (mePath & "Contents:Resources:index.html") as text
　　set htmlStr to (read (resPath as alias) as «class utf8») as text
　　
　　## html内の文字を置き換え
　　set aString to current application’s NSString’s stringWithFormat_(htmlStr, resultStr) as text
　　log result
　　
　　
　　## NSAttributedString
　　set aString to current application’s NSString’s stringWithString:aString
　　set stringData to aString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　
　　set aValue to {current application’s NSHTMLTextDocumentType, current application’s NSUTF8StringEncoding}
　　set aKey to {current application’s NSDocumentTypeDocumentAttribute, current application’s NSCharacterEncodingDocumentAttribute}
　　set aOption to current application’s NSDictionary’s dictionaryWithObjects:aValue forKeys:aKey
　　
　　tell current application’s NSAttributedString’s alloc()
　　　　tell initWithHTML_options_documentAttributes_(stringData, aOption, missing value)
　　　　　　set attributedString to it
　　　　end tell
　　end tell
　　log result
　　
　　# Create a TextView with Scroll View
　　set frameSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　tell current application’s NSTextView’s alloc()
　　　　tell initWithFrame_(frameSize)
　　　　　　setEditable_(false)
　　　　　　tell textStorage()
　　　　　　　　appendAttributedString_(attributedString)
　　　　　　end tell
　　　　　　set aView to it
　　　　end tell
　　end tell
　　tell current application’s NSScrollView’s alloc()
　　　　tell initWithFrame_(frameSize)
　　　　　　setDocumentView_(aView)
　　　　　　set theView to it
　　　　end tell
　　end tell
　　
　　
　　## アイコンの指定
　　set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:"net.daringfireball.markdown"
　　
　　## set up alert
　　tell current application’s NSAlert’s new()
　　　　addButtonWithTitle_("Close")
　　　　setAccessoryView_(theView)
　　　　setIcon_(aImage)
　　　　setInformativeText_(infoText)
　　　　setMessageText_(mesText)
　　　　tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
　　　　### show alert in modal loop
　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell
end displayMarkdownPreview:

★Click Here to Open This Script　

そして、本Scriptをよくよく見回してみると、NSAttributedStringになっているのでPDFに変換するのがとても簡単でした。WkWebView上に表示したWebコンテンツをPDF化しようと試みているものの、うまくできていません。Blocks構文を必要とする機能であるため（なんでこんなものまでBlocks（非同期実行）必要なんだろ？）、AppleScriptからの呼び出しができないためです。Xcode上で他の言語をまじえて組めば不可能ではない気もしますが……

CSSがWeb表示用のものなので、PDF出力時には割とゆったり目で密度の低いレイアウトになってしまうものの、このCSS指定を別のものにできればけっこうMarkdown→PDFの変換を行う部品として使えるレベルになってくるのではないでしょうか。それはそれで、Scriptバンドル内に入れたCSSを指定するとか、Web上のどこかに印刷用のCSSをホスティングしておくなどの方法が必要になることでしょう。

(Visited 90 times, 1 visits today)
Posted in dialog JavaScript Markdown | Tagged 10.13savvy 10.14savvy 10.15savvy 11.0savvy JSContext NSAlert NSAlertSecondButtonReturn NSAttributedString NSCharacterEncodingDocumentAttribute NSDictionary NSDocumentTypeDocumentAttribute NSScreen NSScrollView NSString NSTextView NSUTF8StringEncoding NSWorkspace | Leave a comment

指定アプリケーションを指定言語環境で再起動 v3

Posted on 5月 6, 2020 by Takaaki Naganoya

指定アプリケーションを、現在のユーザーアカウントで指定可能な言語環境を指定して再起動するAppleScriptの改良版です。

初版では言語環境を選んでからアプリケーションを選んでいましたが、この順番を逆にしました。アプリケーションを選択し、そのバンドル内のローカライズ状況を調べ、一覧から選択して起動します。


▲最初にアプリケーションを選択


▲Keynoteのローカライズ言語一覧から対象言語コードを選択


▲アラビア語環境で起動させたKeynote


▲タイ語環境で起動させたKeynote


▲ロシア語環境で起動させたKeynote


▲中国語（簡体字）環境で起動させたKeynote

個人的には割と実用性が高いScriptです。

AppleScript名：指定アプリケーションの指定言語環境で再起動 v3.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/06
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSBundle : a reference to current application’s NSBundle
property NSWorkspace : a reference to current application’s NSWorkspace

set anApp to path to (choose application)

tell application "Finder"
　　set aBundle to properties of anApp
　　set targID to id of aBundle –Get Bundle ID
end tell

set bRes to getLocalizationsFromBundleID(targID) of me
set cRes to my sort1DList:bRes ascOrder:true

set dRes to (choose from list cRes)
if dRes = missing value or dRes = false then return

set targLanguage to first item of dRes

set appPath to retPathFromBundleID(targID) of me

set sText to "open -n -a " & quoted form of appPath & " –args -AppleLanguages ’(＼"" & targLanguage & "＼")’"
do shell script sText

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

–1D Listをsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DList:theList ascOrder:aBool
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"localizedCaseInsensitiveCompare:"
　　set theArray to current application’s NSArray’s arrayWithArray:theList
　　return (theArray’s sortedArrayUsingDescriptors:{aDdesc}) as list
end sort1DList:ascOrder:

★Click Here to Open This Script　
(Visited 65 times, 1 visits today)
Posted in Locale | Tagged 10.13savvy 10.14savvy 10.15savvy Finder NSBundle NSURL NSWorkspace | Leave a comment

Switch Controlがオンになっているか調べる

Posted on 5月 3, 2020 by Takaaki Naganoya

Switch Controlが起動中かどうかをNSWorkspace経由で調べるAppleScriptです。

いろいろなAppleScriptをSwitch Controlのパネルに盛り込んで利用していますが、けっこう使いでがあっていい感じです。Script MenuにAppleScriptを入れて呼び出すのも実用性が高くてよいのですが、Switch Controlのパネルに入れると常時フローティングパネルで表示される（消したり最小化も可）ため、アプリケーションの機能が不完全であると感じるところをユーザーが自分で勝手に補える感覚がとてもいい感じです。

ただ、１つ問題があるとすれば、Switch Controlをプログラム側から起動する方法が公開されていないようである点。本Scriptのように、起動中であることを判定する方法は提供されているのですが。

Switch Control（＝AssistiveControl）がオンになっていると、InputManager側から見えるので

このあたりに解決の鍵がありそうな気もします。ただ、文字入力に介在できる機能でもあるため、セキュリティ上の懸念から「あえて」そうしたAPIを公開していないのかも。

現状では唯一、GUI Scriptingで野蛮にチェックボックスをクリックするか、あるいいはチェックボックスの値を変更するぐらいでしょう。実際に試してはいないので、これもできるか100％の保証があるものではありませんけれども。

AppleScript名：スイッチコントロールがオンになっているか調べる.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/02
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

current application’s NSWorkspace’s sharedWorkspace()’s isSwitchControlEnabled()
–> true / false

★Click Here to Open This Script　
(Visited 107 times, 4 visits today)
Posted in System | Tagged 10.13savvy 10.14savvy 10.15savvy NSWorkspace Switch Control | Leave a comment

システム環境設定の「ディスプレイ」＞「ディスプレイ」を表示

Posted on 4月 28, 2020 by Takaaki Naganoya

システム環境設定の「ディスプレイ」paneの「ディスプレイ」を表示するAppleScriptです。

やりかたは山のようにあるものの、Cocoa系の機能を使うとこんな感じ。

AppleScript名：システム環境設定の「ディスプレイ」＞「ディスプレイ」を表示_asobjc.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/04/28
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

current application’s NSWorkspace’s sharedWorkspace()’s openFile:"/System/Library/PreferencePanes/Displays.prefPane"

★Click Here to Open This Script　

まんま、同じ内容をshell呼び出しで書くとこんな感じ。

AppleScript名：システム環境設定の「ディスプレイ」＞「ディスプレイ」を表示_shell.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/04/28
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

do shell script "open /System/Library/PreferencePanes/Displays.prefPane"

★Click Here to Open This Script　

System Events経由でファイルオープンするとこんな感じ。POSIX pathをfileとして指定できて驚きました。aliasにcastしないとopenできないかと思っていました。

AppleScript名：システム環境設定の「ディスプレイ」＞「ディスプレイ」を表示_System Events.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/04/28
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "System Events"
　　open file "/System/Library/PreferencePanes/Displays.prefPane"
end tell

★Click Here to Open This Script　

AppleScript的にいろいろルーチンを整備して汎用性を持たせつつ、十分な機能を用意するとこんな感じでしょうか。

AppleScript名：システム環境設定の「ディスプレイ」＞「ディスプレイ」を表示
— Created 2017-10-10 by Takaaki Naganoya
— Created 2020-04-28 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

–Get every pane ID
set aList to getEveryPaneID() of me

–Get every anchor in a pane
set pList to getEveryAnchorName("com.apple.preference.displays") of me
–> {"displaysArrangementTab", "displaysNightShiftTab", "displaysColorTab", "displaysGeometryTab", "displaysDisplayTab"}

set aRes to dispSystemPreferences("com.apple.preference.displays", "displaysDisplayTab") of me
–> true

on dispSystemPreferences(paneID, anchorID)
　　tell application "System Preferences"
　　　　activate
　　　　set pList to id of every pane
　　　　if paneID is not in pList then return false
　　　　
　　　　set current pane to pane paneID
　　　　tell current pane
　　　　　　set nList to name of every anchor
　　　　　　if anchorID is not in nList then return false
　　　　　　reveal anchor anchorID
　　　　end tell
　　end tell
　　
　　return true
end dispSystemPreferences

on getEveryPaneID()
　　tell application "System Preferences"
　　　　return id of every pane
　　end tell
end getEveryPaneID

on getEveryAnchorName(paneID)
　　tell application "System Preferences"
　　　　set pList to id of every pane
　　　　if paneID is not in pList then return false
　　　　set current pane to pane paneID
　　　　tell current pane
　　　　　　return name of every anchor
　　　　end tell
　　end tell
end getEveryAnchorName

★Click Here to Open This Script　
(Visited 94 times, 1 visits today)
Posted in System | Tagged 10.13savvy 10.14savvy 10.15savvy NSWorkspace System Preferences | Leave a comment

指定Bundle IDのstringsファイル中における指定タイトルの指定言語のローカライズ版を求める

Posted on 2月 24, 2020 by Takaaki Naganoya

/Applicationsフォルダ以下のすべてのアプリケーションのバンドル中のstringsファイル中を走査して、指定の言語における指定キーワード（”Quit”など）の指定言語におけるローカライズした文字列を取得するAppleScriptです。

自分でアプリケーションのローカライズを行う際に、既存のmacOS用のアプリケーションのバンドル内にあるstringsファイルを参考にするためのツールです。

もともとは、Shane StanleyがLate Night Softwareのフォーラムに投稿したプログラムですが、自分もいろいろ試していたように、アプリケーション側のローカライズのされ方（言語別のフォルダ名の名称指定）に「ゆらぎ」があるため、そのあたりは総当たりでテストしているようです。

オリジナルではデータが存在しない場合にはエラーにしていましたが、このようにすべてのアプリケーションに対してループで処理を行うような場合にはエラーで止まっては困るので、そのあたりを書き換えています。

/Applicationsフォルダ以下のSpotlight検索によるアプリケーションの取得についてはMetadata Libを用いています。自分の開発環境で１キーワード（x バンドル内のすべてのstringsファイル x すべてのアプリケーション）の問い合わせに3.6〜5秒程度かかっています。HDDの環境ではこれより大幅に長くかかるはずなので、ちょっと考えたくありません。

また、Stringsファイルで供給されるローカライズ情報については探すことができますが、OS側が強制的に供給するWindowメニューなどの内容については本Scriptで調査することはできません。ねんのため。

AppleScript名：指定Bundle IDのstringsファイル中における指定タイトルの指定言語のローカライズ版を求める.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/02/24
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions
use mdLib : script "Metadata Lib" version "2.0.0" –https://macosxautomation.com/applescript/apps/Script_Libs.html

property NSWorkspace : a reference to current application’s NSWorkspace

set targStr to "Performance"
set origLang to "en" –From
set targLang to "hu" –To

set tList to {}

set origPath to POSIX path of (path to applications folder)
set aResList to mdLib’s searchFolders:{origPath} searchString:("kMDItemContentType == %@") searchArgs:{"com.apple.application-bundle"}
repeat with i in aResList
　　set aTitleRes to getAppGUITitleWithCurrentLocale(i, targStr, origLang, targLang) of me
　　if aTitleRes is not equal to missing value and aTitleRes is not in tList then
　　　　set the end of tList to aTitleRes
　　end if
end repeat

return tList
–> {"Előadás", "Teljesítmény"}

–指定Bundle IDのstringsファイル中における指定タイトルの現在実行中のロケールのローカライズ版を求める
on getAppGUITitleWithCurrentLocale(aPath, aTargetTitle, origLang, targLang)
　　return my localizedStringFor:aTargetTitle inBundle:aPath destLang:targLang sourceLang:origLang
end getAppGUITitleWithCurrentLocale

–Bundle IDからアプリケーションのPathを返す
on retAppAbusolutePathFromBundleID(aBundleID)
　　set appPath to NSWorkspace’s sharedWorkspace()’s absolutePathForAppBundleWithIdentifier:aBundleID
　　if appPath = missing value then return false
　　return appPath as string
end retAppAbusolutePathFromBundleID

–Original By Shane Stanley@Late Night Software
–Modified By Takaaki Naganoya
–https://forum.latenightsw.com/t/localizing-gui-scripts/2246
on localizedStringFor:baseString inBundle:aPOSIX destLang:destLangCode sourceLang:sourceLangCode
　　set anURL to current application’s |NSURL|’s fileURLWithPath:aPOSIX
　　set theBundle to current application’s NSBundle’s bundleWithURL:anURL
　　if theBundle = missing value then return missing value
　　
　　set sourceLangString to current application’s NSString’s stringWithString:sourceLangCode
　　set destLangString to current application’s NSString’s stringWithString:destLangCode
　　
　　— get source strings values
　　set theURLs to theBundle’s URLsForResourcesWithExtension:"strings" subdirectory:"" localization:sourceLangString
　　if theURLs = missing value then return missing value
　　if theURLs’s |count|() < 2 and (sourceLangString’s containsString:"_") as boolean then
　　　　— try stripping off country-specific part
　　　　set sourceLangString to sourceLangString’s substringToIndex:2
　　　　set theURLs to theBundle’s URLsForResourcesWithExtension:"strings" subdirectory:"" localization:sourceLangString
　　end if
　　
　　if theURLs’s |count|() < 2 then
　　　　— try long name for localization
　　　　set sourceLangString to (current application’s NSLocale’s localeWithLocaleIdentifier:"en")’s localizedStringForLocaleIdentifier:sourceLangString
　　　　set theURLs to theBundle’s URLsForResourcesWithExtension:"strings" subdirectory:"" localization:sourceLangString
　　end if
　　
　　if theURLs’s |count|() < 2 then return missing value –error "No " & sourceLangCode & " localization found"
　　
　　repeat with sourceURL in theURLs
　　　　— skip unlocalized file
　　　　if not (sourceURL’s URLByDeletingLastPathComponent()’s lastPathComponent()’s isEqualToString:"Resources") as boolean then
　　　　　　set theData to (current application’s NSData’s alloc()’s initWithContentsOfURL:sourceURL)
　　　　　　
　　　　　　if theData is missing value then return — error "No " & sourceLangCode & " localization found"
　　　　　　set sourceDict to (current application’s NSPropertyListSerialization’s propertyListWithData:theData options:0 format:0 |error|:(missing value))
　　　　　　if sourceDict = missing value then return missing value
　　　　　　
　　　　　　set theKey to (sourceDict’s allKeysForObject:baseString)’s firstObject()
　　　　　　
　　　　　　if theKey is not missing value then
　　　　　　　　set stringsFileName to sourceURL’s lastPathComponent()’s stringByDeletingPathExtension()
　　　　　　　　set localURL to (theBundle’s URLForResource:stringsFileName withExtension:"strings" subdirectory:"" localization:destLangString)
　　　　　　　　
　　　　　　　　if localURL is missing value and (destLangString’s containsString:"_") as boolean then
　　　　　　　　　　— try stripping off country-specific part
　　　　　　　　　　set destLangString to (destLangString’s substringToIndex:2)
　　　　　　　　　　set localURL to (theBundle’s URLForResource:stringsFileName withExtension:"strings" subdirectory:"" localization:destLangString)
　　　　　　　　end if
　　　　　　　　
　　　　　　　　if localURL is missing value then
　　　　　　　　　　— try long name for localization
　　　　　　　　　　set destLangString to ((current application’s NSLocale’s localeWithLocaleIdentifier:"en")’s localizedStringForLocaleIdentifier:destLangString)
　　　　　　　　　　set localURL to (theBundle’s URLForResource:stringsFileName withExtension:"strings" subdirectory:"" localization:destLangString)
　　　　　　　　end if
　　　　　　　　
　　　　　　　　if localURL is missing value then return missing value — "No " & destLangCode & " localization found"
　　　　　　　　
　　　　　　　　set theData to (current application’s NSData’s alloc()’s initWithContentsOfURL:localURL)
　　　　　　　　if theData is missing value then missing value — "No " & destLangCode & " localization found"
　　　　　　　　set destDict to (current application’s NSPropertyListSerialization’s propertyListWithData:theData options:0 format:0 |error|:(missing value))
　　　　　　　　set destValue to (destDict’s objectForKey:theKey)
　　　　　　　　
　　　　　　　　–if destValue is not missing value then return {destValue as text, stringsFileName as text}
　　　　　　　　if destValue is not missing value then return destValue as text
　　　　　　　　return missing value
　　　　　　end if
　　　　end if
　　end repeat
　　return missing value
end localizedStringFor:inBundle:destLang:sourceLang:

★Click Here to Open This Script　
(Visited 50 times, 1 visits today)
Posted in file File path Language Locale Text | Tagged 10.14savvy 10.15savvy NSBundle NSData NSLocale NSPropertyListSerialization NSString NSURL NSWorkspace | Leave a comment

指定アプリケーション内の現在のLocaleの指定stringsファイル内の指定キーの値を取得する

Posted on 11月 16, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションのバンドル中（/Contents/Resources/）の現在のLocalizationに存在する指定のstringsファイル内で、指定キーの値を取得するAppleScriptです。

アプリケーションバンドル内の各ローカライズフォルダの名称は一意に決定されているものでもなく、ある程度の「ゆらぎ」が生じています。

/Contents/Resources/Japanese.lproj/
/Contents/Resources/ja.lproj/

NSLocaleからcurrentLocale()を取得すると、「ja-JP」のような識別子が得られます。これと上記のパターンのフォルダとの付け合わせのためのメソッドがどこかに存在しているはずなのですが、現状では見つけられていません（ないと各アプリケーションが正しくメニュー表示できていないので）。

まだいまひとつ、しっくりきていません。

AppleScript名：指定アプリケーション内の現在のLocaleの指定stringsファイル内の指定キーの値を取得する.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/15
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSBundle : a reference to current application’s NSBundle
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSLocaleCountryCode : a reference to current application’s NSLocaleCountryCode
property NSLocaleLanguageCode : a reference to current application’s NSLocaleLanguageCode
property NSLocaleCollatorIdentifier : a reference to current application’s NSLocaleCollatorIdentifier

set targID to "com.apple.iWork.Keynote"
set targFile to "Keynote" –"Keynote.strings" file
set targKey to "Arrange"
set vStr to getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey) of me
–> "配置"

on getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey)
　　set aPath to retPathFromBundleID(targID) of me
　　
　　set aURL to (|NSURL|’s fileURLWithPath:aPath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　
　　set aLocale to (current application’s NSLocale’s preferredLanguages()’s firstObject()) as string
　　
　　set curLocale to current application’s NSLocale’s currentLocale()
　　set aDS11 to (curLocale’s objectForKey:(NSLocaleLanguageCode)) as string
　　set aDS12 to (curLocale’s objectForKey:(NSLocaleCountryCode)) as string
　　set aDS5 to (curLocale’s objectForKey:(NSLocaleCollatorIdentifier)) as string
　　–set bID to (current application’s NSBundle’s mainBundle()’s preferredLocalizations()’s firstObject()) as string
　　
　　set langIDList to {aDS11, aLocale, aDS12, aDS5} –> {"ja", "ja-JP", "JP", "ja-JP"}
　　
　　repeat with i in langIDList
　　　　set j to contents of i
　　　　set aRes to (aBundle’s pathForResource:targFile ofType:"strings" inDirectory:"" forLocalization:(j))
　　　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:aRes)
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　return aVal as string
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return false
end getAValInASpecifiedStringFileOfAllLocaleInABundle

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

★Click Here to Open This Script　
(Visited 65 times, 1 visits today)
Posted in list System Text URL | Tagged 10.12savvy 10.13savvy 10.14savvy 10.15savvy NSBundle NSDictionary NSFileManager NSLocaleCollatorIdentifier NSLocaleCountryCode NSLocaleLanguageCode NSURL NSWorkspace | 2 Comments

指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

Posted on 11月 13, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションからすべてのLocaleを取得し、ダイアログ選択したLocale内のすべてのstringsファイルを読み込んでNSDictionary化して指定のキーワードを含むものを抽出するAppleScriptです。

指定キーワードが含まれていた場合には、

キー, 値, stringsファイルのパス

をリストで返します。調査のための下調べを行うものです。

AppleScript名：指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants

set targID to "com.apple.Finder"
set targWords to "のコピー"

set bRes to getLocalizationsFromBundleID(targID) of me
–>　　{"de", "he", "en_AU", "ar", "el", "ja", "en", "uk", "es_419", "zh_CN", "es", "da", "it", "sk", "pt_PT", "ms", "sv", "cs", "ko", "Base", "no", "hu", "zh_HK", "tr", "pl", "zh_TW", "en_GB", "vi", "ru", "fr_CA", "fr", "fi", "id", "nl", "th", "pt", "ro", "hr", "hi", "ca"}

–Select Localization
set curLang to first item of (choose from list bRes)

–Get All strings file path within a bundle
set aPath to retPathFromBundleID(targID) of me
set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

–Get Every Key & Value pair then filter target keyword
set aMDict to NSMutableDictionary’s new()
set hitList to {}
repeat with ii in sList
　　set jj to contents of ii
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:jj)
　　(aMDict’s addEntriesFromDictionary:aDict)
　　
　　set kList to aMDict’s allKeys() as list
　　set vList to aMDict’s allValues() as list
　　
　　set kCount to 1
　　repeat with i in vList
　　　　set j to contents of i
　　　　if j contains targWords then
　　　　　　set the end of hitList to {contents of item kCount of kList, j, jj}
　　　　end if
　　　　set kCount to kCount + 1
　　end repeat
　　
end repeat

return hitList
–> {{"PW5_V2", "^0項目のコピーの準備中", "/System/Library/CoreServices/Finder.app/Contents/Resources/Japanese.lproj/Localizable.strings"}, …}

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　
(Visited 61 times, 1 visits today)
Posted in file File path UTI | Tagged 10.12savvy 10.13savvy 10.14savvy 10.15savvy Finder NSArray NSBundle NSDictionary NSDirectoryEnumerationSkipsHiddenFiles NSDirectoryEnumerationSkipsPackageDescendants NSFileManager NSMutableDictionary NSPredicate NSURL NSURLTypeIdentifierKey NSWorkspace | Leave a comment

指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する

Posted on 11月 13, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションのバンドル中（/Contents/Resources/）のすべてのLocalizationに存在する指定のstringsファイル内で、指定キーの値を取得するAppleScriptです。

macOSの日本語環境では、Finder上でコピーしたファイルのファイル名の後方に「のコピー」といった文字列が追記されますが、他のLocaleでどのような文字列が使用されているか調査するために作成したものです。

AppleScript名：指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/12
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

set targID to "com.apple.Finder"
set targFile to "Localizable.strings"
set targKey to "N4_V2"
set vList to getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey) of me
–> {{"he", "עותק של ^=1 ^=0"}, {"en_AU", "^=1 copy ^=0"}, {"ar", "نسخة ^=0 من ^=1"}, {"el", "^=1 αντίγραφο ^=0"}, {"uk", "^=1 копія ^=0"}, {"English", "^=1 copy ^=0"}, {"es_419", "Copia de ^=1 ^=0"}, {"zh_CN", "^=1的副本 ^=0"}, {"Dutch", "^=1 kopie ^=0"}, {"da", "^=1-kopi ^=0"}, {"sk", "^=1 – kópia ^=0"}, {"pt_PT", "^=1 – cópia ^=0"}, {"German", "^=1 Kopie ^=0"}, {"ms", "salinan ^=0 ^=1"}, {"sv", "^=1 (kopia ^=0)"}, {"cs", "^=1 (kopie ^=0)"}, {"ko", "^=1 복사본 ^=0"}, {"no", "^=1-kopi ^=0"}, {"hu", "^=1 másolat ^=0"}, {"zh_HK", "^=1 副本 ^=0"}, {"Spanish", "^=1 copia ^=0"}, {"tr", "^=1 kopyası ^=0"}, {"pl", "^=1-kopia ^=0"}, {"zh_TW", "^=1 拷貝 ^=0"}, {"en_GB", "^=1 copy ^=0"}, {"French", "^=1 copie ^=0"}, {"vi", "Bản sao ^=1 ^=0"}, {"ru", "^=1 — копия ^=0"}, {"fr_CA", "^=1 copie ^=0"}, {"fi", "^=1 kopio ^=0"}, {"id", "Salinan ^=1 ^=0"}, {"th", "^=1 สำเนา ^=0"}, {"pt", "^=1 – cópia ^=0"}, {"ro", "^=1 – copie ^=0"}, {"Japanese", "^=1のコピー^=0"}, {"hr", "^=1 kopija ^=0"}, {"hi", "^=1 कॉपी ^=0"}, {"Italian", "^=1 copia ^=0"}, {"ca", "^=1 còpia ^=0"}}

on getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey)
　　–Get App Path
　　set aPath to retPathFromBundleID(targID) of me
　　
　　–Get all Localizations
　　set bRes to getLocalizationsFromBundleID(targID) of me
　　
　　set hitList to {}
　　
　　–Loop with Localizations in an application bundle
　　repeat with iii in bRes
　　　　set jjj to contents of iii
　　　　set allPath to aPath & "/Contents/Resources/" & jjj & ".lproj/" & targFile
　　　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:allPath)
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　set the end of hitList to {jjj, aVal as string}
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return hitList
end getAValInASpecifiedStringFileOfAllLocaleInABundle

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

★Click Here to Open This Script　
(Visited 50 times, 1 visits today)
Posted in System Text | Tagged 10.12savvy 10.13savvy 10.14savvy 10.15savvy Finder NSArray NSBundle NSDictionary NSFileManager NSMutableDictionary NSPredicate NSURL NSURLTypeIdentifierKey NSWorkspace | Leave a comment

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

Posted on 9月 21, 2019 by Takaaki Naganoya

バンドルIDで指定したアプリケーションのResourcesフォルダ中の、指定ロケールのstringsファイルをすべて読み込んでkeyを取り出すAppleScriptです。

アプリケーション内の指定のローカライズしたメッセージ（テキスト）の内容を取り出すことはできますが、そのためにはキーを知っておく必要があります。そのキーを取り出してローカライズされた文字列を取り出すため、キーを調査してみました。

これをそのまま何かのツールなりScriptに使うというものではなく、いわゆる「下調べ」のためのScriptの部品です。

ほぼ、ありもののルーチンを再利用しただけのプログラムでできていますが、ありものはありもので、数千本のAppleScriptのストックからそれを探し出してくるのも一苦労です。

アプリケーションバンドル内のResourcesフォルダ以下の（各lprojフォルダ以下の）stringsファイルの中身はまんま（シリアライズした）NSDictionaryなので、そのままDictionaryに読み込んでallkey()などのメソッドを実行できます。昔のstringsファイルはテキストファイルだったような気がしますが、テキストファイルだとparseしないといけないんで、ビルド時にparseしておいてDictionaryの状態でファイルに書いておくのは正しいと思います。

Xcode 8あたりから、アプリケーションのローカライズのルールが変更になったようで、基本となる言語環境がBase.lprojになり、英語はen.lprojといった１ローカライズ言語という位置付けに変更になりました。

NSLocalizedStringFromTableInBundleを使ってアクセスしようかとも思ったのですが、こちらはまだ目的を達成できていません。


▲Xcode 11上で実験的に作成したAppleScriptアプリケーションのバンドル構造（左）。ローカライズしていない状態だとEnglishではなくBase.lprojが作成される。右はKeynote.app/Contents/Resources/ja.lprojフォルダの内容。stringsファイルが大量に存在している

AppleScript名：指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants

set targID to "com.apple.iWork.Keynote"

set bRes to getLocalizationsFromBundleID(targID) of me
–>　　{"de", "he", "en_AU", "ar", "el", "ja", "en", "uk", "es_419", "zh_CN", "es", "da", "it", "sk", "pt_PT", "ms", "sv", "cs", "ko", "Base", "no", "hu", "zh_HK", "tr", "pl", "zh_TW", "en_GB", "vi", "ru", "fr_CA", "fr", "fi", "id", "nl", "th", "pt", "ro", "hr", "hi", "ca"}

set curLang to first item of (choose from list bRes)
set aPath to retPathFromBundleID(targID) of me

set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

set aMDict to NSMutableDictionary’s new()

repeat with i in sList
　　set j to contents of i
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:j)
　　(aMDict’s addEntriesFromDictionary:aDict)
end repeat

return aMDict’s allKeys() as list
–> {"Interactive Bubble Chart", "Rehearse Slideshow", "PMT_ARGUMENT_1", "ACCRINTM_ARGUMENT_4_MODE_0", "Truck_378",….}

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　
(Visited 68 times, 1 visits today)
Posted in file Record URL UTI | Tagged 10.12savvy 10.13savvy 10.14savvy NSArray NSBundle NSDictionary NSDirectoryEnumerationSkipsHiddenFiles NSDirectoryEnumerationSkipsPackageDescendants NSFileManager NSMutableDictionary NSPredicate NSURL NSURLTypeIdentifierKey NSWorkspace | Leave a comment

CotEditorで編集中のMarkdown書類をPDFプレビュー

Posted on 6月 15, 2019 by Takaaki Naganoya

CotEditorで編集中のMarkdown書類を、MacDownでPDF書き出しして、Skimでオープンして表示するAppleScriptです。

CotEditorにMarkdownのプレビュー機能がついたらいいと思っている人は多いようですが、MarkdownはMarkdownで、方言は多いし標準がないし、１枚もののMarkdown書類だけ編集できればいいのか、本などのプロジェクト単位で編集とか、目次が作成できないとダメとか、リンクした画像の扱いをどうするのかとか、対応しようとすると「ほぼ別のソフトを作るのと同じ」ぐらい手間がかかりそうです（メンテナー様ご本人談）。

そこで、AppleScript経由で他のソフトを連携させてPDFプレビューさせてみました。これなら、誰にも迷惑をかけずに、今日この時点からすぐにMarkdownのプレビューが行えます（当然、HTML書き出ししてSafariでプレビューするバージョンははるかかなた昔に作ってあります）。

ただし、OS側の機能制限の問題で、CotEditor上のスクリプトメニューから実行はできません（GUI Scriptingの実行が許可されない）。OS側のスクリプトメニューに登録して実行する必要があります。

GUI Scriptingを利用してメニュー操作を行なっているため、システム環境設定で許可しておく必要があります。

本来であれば、PDFの書き出し先フォルダ（この場合は書き出しダイアログで、GUI Scirptingを用いてCommand-Dで指定して一律に場所指定が行えるデスクトップフォルダ）に同名のPDFが存在しないかどうかチェックし、存在すれば削除するといった処理が必要ですが、面倒だったのであらかじめMarkdown書類をUUIDにリネームしておくことで、書き出されたPDFも同じくUUIDのファイル名になるため、論理上はファイル名の衝突を回避できるため、削除処理を省略しています。

AppleScript名：🌏レンダリングしてPDFプレビュー
— Created 2019-06-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSUUID : a reference to current application’s NSUUID
property NSWorkspace : a reference to current application’s NSWorkspace

–オープン中のMarkdown書類を取得する
tell application "CotEditor"
　　tell front document
　　　　set cStyle to coloring style
　　　　if cStyle is not equal to "Markdown" then
　　　　　　display dialog "編集中のファイルはMarkdown書類ではないようです。" buttons {"OK"} default button 1
　　　　　　return
　　　　end if
　　　　
　　　　set aPath to path
　　end tell
end tell

–一時フォルダにMarkdown書類をコピー
set sPath to (path to temporary items)
tell application "Finder"
　　set sRes to (duplicate ((POSIX file aPath) as alias) to folder sPath with replacing)
end tell

–コピーしたMarkdown書類をリネーム
set s1Res to sRes as alias
set aUUID to NSUUID’s UUID()’s UUIDString() as text –UUIDを作成する
tell application "Finder"
　　set name of s1Res to (aUUID & ".md")
end tell

–Markdown書類をデスクトップにPDF書き出し
set pdfRes to exportFromMacDown(POSIX path of s1Res) of me

–PDF Viewerでオープン
tell application "Skim" –Preview.appでもOK
　　activate
　　open pdfRes
end tell

–一時フォルダに書き出したMarkdown書類を削除
tell application "Finder"
　　delete s1Res
end tell

–指定のMacDownファイル（alias）をデスクトップ上にPDFで書き出し
on exportFromMacDown(anAlias)
　　set s1Text to paragraphs of (do shell script "ls ~/Desktop/*.pdf") –pdf書き出し前のファイル一覧
　　
　　tell application "MacDown"
　　　　open {anAlias}
　　end tell
　　
　　macDownForceSave() of me
　　
　　tell application "MacDown"
　　　　close every document without saving
　　end tell
　　
　　do shell script "sync" –ねんのため
　　
　　set s2Text to paragraphs of (do shell script "ls ~/Desktop/*.pdf") –pdf書き出し後のファイル一覧
　　
　　set dRes to getDiffBetweenLists(s1Text, s2Text) of me –デスクトップ上のPDFファイル名一覧の差分を取得
　　set d2Res to (addItems of dRes)
　　
　　if length of d2Res ≥ 1 then
　　　　return contents of first item of d2Res
　　else
　　　　error "Error in exporting PDF to desktop folder…."
　　end if
end exportFromMacDown

on getDiffBetweenLists(aArray as list, bArray as list)
　　set allSet to current application’s NSMutableSet’s setWithArray:aArray
　　allSet’s addObjectsFromArray:bArray
　　
　　–重複する要素のみ抜き出す
　　set duplicateSet to current application’s NSMutableSet’s setWithArray:aArray
　　duplicateSet’s intersectSet:(current application’s NSSet’s setWithArray:bArray)
　　
　　–重複部分を削除する
　　allSet’s minusSet:duplicateSet
　　set resArray to (allSet’s allObjects()) as list
　　
　　set aSet to current application’s NSMutableSet’s setWithArray:aArray
　　set bSet to current application’s NSMutableSet’s setWithArray:resArray
　　aSet’s intersectSet:bSet –積集合
　　set addRes to aSet’s allObjects() as list
　　
　　set cSet to current application’s NSMutableSet’s setWithArray:bArray
　　cSet’s intersectSet:bSet –積集合
　　set minusRes to cSet’s allObjects() as list
　　
　　return {addItems:minusRes, minusItems:addRes}
end getDiffBetweenLists

–注意！！　ここでGUI Scriptingを使用。バージョンが変わったときにメニュー階層などの変更があったら書き換え
on macDownForceSave()
　　activate application "MacDown"
　　tell application "System Events"
　　　　tell process "MacDown"
　　　　　　— File > Export > PDF
　　　　　　click menu item 2 of menu 1 of menu item 14 of menu 1 of menu bar item 3 of menu bar 1
　　　　　　
　　　　　　–Go to Desktop Folder
　　　　　　keystroke "d" using {command down}
　　　　　　
　　　　　　–Save Button on Sheet
　　　　　　click button 1 of sheet 1 of window 1
　　　　end tell
　　end tell
end macDownForceSave

–Bundle IDからアプリケーションのPathを返す
on retAppAbusolutePathFromBundleID(aBundleID)
　　set appPath to NSWorkspace’s sharedWorkspace()’s absolutePathForAppBundleWithIdentifier:aBundleID
　　if appPath = missing value then return false
　　return appPath as string
end retAppAbusolutePathFromBundleID

★Click Here to Open This Script　
(Visited 872 times, 4 visits today)
Posted in file File path GUI Scripting Markdown PDF shell script | Tagged 10.11savvy 10.12savvy 10.13savvy CotEditor Finder MacDown NSUUID NSWorkspace Skim | Leave a comment

スリープおよびスリープ解除Notificationを受信

Posted on 1月 27, 2019 by Takaaki Naganoya

Macがスリープ/スリープから復帰したノーティフィケーションを受信するAppleScriptです。

Cocoaの機能が利用できない時代にスリープ解除を検出するアプリケーション「Okaeri」をAppleScriptで作って動かしていましたが、あれはon idleハンドラで１秒ごとにタイマー割り込みを発生させ、前回割り込み発生時間を記録、前回割り込みと現在時刻の差分を計算し、１ないし数秒以上間隔が空いていたらスリープ解除が発生したとみなして、syslogにスリープ解除が記録されていないかをチェックするようにしていました。

なので、Cocoaの機能呼び出しやNotificationの受信を行えなくても、ある程度は同様の処理が行えるわけですが、使えれば使えたで便利ではあります。

AppleScript名：スリープおよびスリープ解除Notificationを受信.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/01/25
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCenter to current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()

aCenter’s addObserver:me selector:"notifSleep:" |name|:"NSWorkspaceWillSleepNotification" object:(missing value)

aCenter’s addObserver:me selector:"notifWaked:" |name|:"NSWorkspaceDidWakeNotification" object:(missing value)

on notifSleep:aNotif
　　display notification "System will sleep"
　　say "System will sleep"
end notifSleep:

on notifWaked:aNotif
　　display notification "System did wake"
　　say "System did wake"
end notifWaked:

★Click Here to Open This Script　
(Visited 529 times, 1 visits today)
Posted in Noification System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSWorkspace | 2 Comments

ディスプレイのスリープ/復帰Notificationを受信

Posted on 1月 26, 2019 by Takaaki Naganoya

Macに接続・搭載しているディスプレイのスリープ/スリープ復帰が行われたノーティフィケーションを受信するAppleScriptです。

AppleScript名：ディスプレイがスリープした.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/01/25
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCenter to current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()

aCenter’s addObserver:me selector:"notifDispSleeped:" |name|:"NSWorkspaceScreensDidSleepNotification" object:(missing value)

on notifDispSleeped:aNotif
　　say "Display sleeped"
end notifDispSleeped:

★Click Here to Open This Script　
AppleScript名：ディスプレイがスリープから復帰した.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/01/25
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCenter to current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()

aCenter’s addObserver:me selector:"notifDispWaked:" |name|:"NSWorkspaceScreensDidWakeNotification" object:(missing value)


on notifDispWaked:aNotif
　　say "Display waked"
end notifDispWaked:

★Click Here to Open This Script　
(Visited 143 times, 1 visits today)
Posted in Noification System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSWorkspace | Leave a comment

ボリウムの名称変更Notificationを受信

Posted on 1月 26, 2019 by Takaaki Naganoya

Macに接続・搭載しているドライブのボリウム名変更が行われたノーティフィケーションを受信するAppleScriptです。

ドライブ名を変更してみると、なぜか通知が２回飛んでくるところが謎です。
→　システム再起動後に追試してみましたが、通知が飛んでくるのは１回だけでした。Scriptを複数回実行してしまったのが原因だと思われます。

AppleScript名：ボリウムの名称変更_notification.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/01/25
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

–ドライブ名の変更時にnotify（なぜか２回通知される？）
set aCenter to current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()

aCenter’s addObserver:me selector:"driveNameChanged:" |name|:"NSWorkspaceDidRenameVolumeNotification" object:(missing value)

on driveNameChanged:aNotif
　　say "Drive name changed"
end driveNameChanged:

★Click Here to Open This Script　
(Visited 44 times, 1 visits today)
Posted in Noification System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSWorkspace | Leave a comment

Spaces変更Notificationを受信

Posted on 1月 26, 2019 by Takaaki Naganoya

Spacesのスペース変更が行われた（異なるスペースに変更しなくてもOK）ノーティフィケーションを受信するAppleScriptです。

ちなみに、AppleScriptによる処理を行う分にはSpacesは百害あって一利もないので、複数Spaceを登録「しないで」使うことが推奨されます。

AppleScript名：Spaces変更_notification.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/01/25
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCenter to current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()

aCenter’s addObserver:me selector:"spacesChanged:" |name|:"NSWorkspaceActiveSpaceDidChangeNotification" object:(missing value)

on spacesChanged:aNotif
　　say "Active Spaces changed"
end spacesChanged:

★Click Here to Open This Script　
(Visited 81 times, 1 visits today)
Posted in Noification System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSWorkspace | 1 Comment

コンピュータのシャットダウン/再起動イベントを受信

Posted on 1月 25, 2019 by Takaaki Naganoya

実行中のMacのシャットダウン/再起動イベントを受信するAppleScrptです。

Classic Mac OS時代のシステム終了項目のような処理をAppleScriptで行いたい場合に、本Scriptのような処理を常駐型アプレット形式で書き出しておいて、起動させたままにしておけば、システム終了/再起動のイベントを受信してハンドラを実行します。

スクリプトエディタ上で実行しても、イベントを受信します、一応、ねんのため。

→　Download this script archive

AppleScript名：シャットダウン_notification.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/01/25
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aCenter to current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()
aCenter’s addObserver:me selector:"computerWillShutDownNotification:" |name|:"NSWorkspaceWillPowerOffNotification" object:(missing value)

on computerWillShutDownNotification:aNotif
　　say "Computer Will shutdown or restart now"
end computerWillShutDownNotification:

★Click Here to Open This Script　
(Visited 329 times, 1 visits today)
Posted in Noification System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSWorkspace | Leave a comment

マウント中のドライブをアンマウント

Posted on 10月 7, 2018 by Takaaki Naganoya

マウント中のドライブのうち、起動ドライブを除いたものをアンマウントします。

NSWorkspace経由でアンマウントするものと、OLD Style AppleScriptでFinder経由でアンマウントするものを掲載しておきます。

ただし、Time Machineのバックアップドライブなど、NSWorkspace経由ではアンマウントできないものもあり、「どちらがいい」とも言い切れない様子です。

–> Download Blank Disk Image for test

AppleScript名：NSWorkSpace経由でアンマウント.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/10/07
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aPath to retDrivePosixPath() of me
if aPath = false then return

set aWS to current application’s NSWorkspace’s sharedWorkspace()
set aRes to aWS’s unmountAndEjectDeviceAtPath:aPath

on retDrivePosixPath()
　　tell application "Finder"
　　　　set dList to properties of every disk whose startup is false and size > 0
　　　　
　　　　if length of dList > 1 then
　　　　　　–複数の対象ドライブがある場合にはユーザーに選択させる
　　　　　　set dnList to name of every disk whose startup is false and size > 0
　　　　　　–set dnList to name of every disk whose startup is false
　　　　　　set dRes to choose from list dnList
　　　　　　set driveProp to (properties of disk dRes)
　　　　　　set driveURL to URL of driveProp
　　　　else if dList = {} then
　　　　　　return false
　　　　else
　　　　　　set driveURL to URL of first item of dList
　　　　end if
　　　　
　　end tell
　　
　　set dPath to ((current application’s |NSURL|’s URLWithString:driveURL)’s |path|()) as string
　　return dPath
end retDrivePosixPath

★Click Here to Open This Script　
AppleScript名：OLD style AppleScriptでアンマウント可能なドライブをアンマウント
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/10/07
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
set dName to retEjectableDriveName() of me
if dName = false then return

tell application "Finder" to eject disk dName

on retEjectableDriveName()
　　tell application "Finder"
　　　　set dList to properties of every disk whose startup is false and size > 0
　　　　
　　　　if length of dList > 1 then
　　　　　　–複数の対象ドライブがある場合にはユーザーに選択させる
　　　　　　set dnList to name of every disk whose startup is false and size > 0
　　　　　　set dRes to choose from list dnList
　　　　else if dList = {} then
　　　　　　return false
　　　　else
　　　　　　set dRes to name of first item of dList
　　　　end if
　　　　
　　　　return dRes
　　end tell
end retEjectableDriveName

★Click Here to Open This Script　
(Visited 513 times, 3 visits today)
Posted in drive | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy Finder NSWorkspace | Leave a comment

電子書籍（PDF）をオンラインストアで販売中！

Google Search

Popular posts

  • macOS 13, Ventura（継続更新）
  • アラートダイアログ上にWebViewで3Dコンテンツを表示（WebGL＋three.js）v3
  • UI Browserがgithub上でソース公開され、オープンソースに
  • Safariで表示中のYouTubeムービーのサムネイル画像を取得
  • 人類史上初、魔導書の観点から書かれたAppleScript入門書「７つの宝珠」シリーズ開始？！
  • macOS 13 TTS Voice環境に変更
  • macOS 12.5(21G72)がリリースされた！
  • 2022年に書いた価値あるAppleScript
  • 新発売：AppleScriptからSiriを呼び出そう！
  • iWork 12.2がリリースされた
  • Pages v12に謎のバグ。書類上に11枚しか画像を配置できない→解決
  • Xcode 14.2でAppleScript App Templateを復活させる
  • Dockに登録されている項目の情報を取得する
  • 新発売：AppleScript基礎テクニック集（11）AppleScriptアプレットとドロップレット
  • macOS 13 beta 3
  • 従来と異なるmacOS 13の性格？
  • 新発売：CotEditor Scripting Book with AppleScript
  • macOS 12.5RC（21G69）、一定以上の長さのapplescript:// URL…
  • macOS 12.5.1、11.6.8でFinderのselectionでスクリーンショット画像をopenできない問題
  • OpenAIで文章のベクトル化（Embedding）

Tags

10.11savvy (1101) 10.12savvy (1242) 10.13savvy (1390) 10.14savvy (586) 10.15savvy (434) 11.0savvy (276) 12.0savvy (178) 13.0savvy (38) CotEditor (60) Finder (47) iTunes (19) Keynote (98) NSAlert (60) NSArray (51) NSBezierPath (18) NSBitmapImageRep (20) NSBundle (20) NSButton (34) NSColor (51) NSDictionary (27) NSFileManager (23) NSFont (18) NSImage (41) NSJSONSerialization (21) NSMutableArray (62) NSMutableDictionary (21) NSPredicate (36) NSRunningApplication (56) NSScreen (30) NSScrollView (22) NSString (117) NSURL (97) NSURLRequest (23) NSUTF8StringEncoding (30) NSView (33) NSWorkspace (20) Numbers (56) Pages (37) Safari (41) Script Editor (20) WKUserContentController (21) WKUserScript (20) WKUserScriptInjectionTimeAtDocumentEnd (18) WKWebView (23) WKWebViewConfiguration (22)

カテゴリー

  • 2D Bin Packing
  • 3D
  • AirDrop
  • AirPlay
  • Animation
  • AppleScript Application on Xcode
  • beta
  • Bluetooth
  • Books
  • boolean
  • bounds
  • Bug
  • Calendar
  • call by reference
  • Clipboard
  • Code Sign
  • Color
  • Custom Class
  • dialog
  • drive
  • exif
  • file
  • File path
  • filter
  • folder
  • Font
  • Font
  • GAME
  • geolocation
  • GUI
  • GUI Scripting
  • Hex
  • History
  • How To
  • iCloud
  • Icon
  • Image
  • Input Method
  • Internet
  • iOS App
  • JavaScript
  • JSON
  • JXA
  • Keychain
  • Keychain
  • Language
  • Library
  • list
  • Locale
  • Machine Learning
  • Map
  • Markdown
  • Menu
  • Metadata
  • MIDI
  • MIME
  • Natural Language Processing
  • Network
  • news
  • Noification
  • Notarization
  • Number
  • Object control
  • OCR
  • OSA
  • PDF
  • Peripheral
  • PRODUCTS
  • QR Code
  • Raw AppleEvent Code
  • Record
  • recursive call
  • regexp
  • Release
  • Remote Control
  • Require Control-Command-R to run
  • REST API
  • Review
  • RTF
  • Sandbox
  • Screen Saver
  • Script Libraries
  • sdef
  • search
  • Security
  • selection
  • shell script
  • Shortcuts Workflow
  • Sort
  • Sound
  • Spellchecker
  • Spotlight
  • SVG
  • System
  • Tag
  • Telephony
  • Text
  • Text to Speech
  • timezone
  • Tools
  • Update
  • URL
  • UTI
  • Web Contents Control
  • WiFi
  • XML
  • XML-RPC
  • イベント（Event）
  • 未分類

アーカイブ

  • 2023年5月
  • 2023年4月
  • 2023年3月
  • 2023年2月
  • 2023年1月
  • 2022年12月
  • 2022年11月
  • 2022年10月
  • 2022年9月
  • 2022年8月
  • 2022年7月
  • 2022年6月
  • 2022年5月
  • 2022年4月
  • 2022年3月
  • 2022年2月
  • 2022年1月
  • 2021年12月
  • 2021年11月
  • 2021年10月
  • 2021年9月
  • 2021年8月
  • 2021年7月
  • 2021年6月
  • 2021年5月
  • 2021年4月
  • 2021年3月
  • 2021年2月
  • 2021年1月
  • 2020年12月
  • 2020年11月
  • 2020年10月
  • 2020年9月
  • 2020年8月
  • 2020年7月
  • 2020年6月
  • 2020年5月
  • 2020年4月
  • 2020年3月
  • 2020年2月
  • 2020年1月
  • 2019年12月
  • 2019年11月
  • 2019年10月
  • 2019年9月
  • 2019年8月
  • 2019年7月
  • 2019年6月
  • 2019年5月
  • 2019年4月
  • 2019年3月
  • 2019年2月
  • 2019年1月
  • 2018年12月
  • 2018年11月
  • 2018年10月
  • 2018年9月
  • 2018年8月
  • 2018年7月
  • 2018年6月
  • 2018年5月
  • 2018年4月
  • 2018年3月
  • 2018年2月

https://piyomarusoft.booth.pm/items/301502

メタ情報

  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org

Forum Posts

  • 人気のトピック
  • 返信がないトピック

メタ情報

  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org
Proudly powered by WordPress
Theme: Flint by Star Verte LLC