macOS 13でNSNotFoundバグふたたび

Posted on 12月 1, 2022 by Takaaki Naganoya

また、Appleがやらかしてくれたようです。あの会社はNSNotFoundの定義値を何回間違えたら気が済むんでしょうか。これで通算４回目ぐらいです。macOS 10.12で発生し10.13.1で修正された定義値のミスをまたやったわけで、失敗がまったく生かされていない。大したものです。

今回のバグは、文字列の検索処理を行っているときに発見しました。指定文字列から対象文字列の登場位置と長さをリストで返す処理を行っていたところ、NSRangeからlocationを取得したときに、これ以上見つからない場所まで来たときにNSNotFoundを返すことを期待されるわけですが、そこに前回（macOS 10.12…10.13）と同様のおかしな値を返してきました。

この（↓）AppleScriptをmacOS 13上で実行すると、エラーになります。

追記：macOS 13.1でもエラーになります。

AppleScript名：テキストのキーワード検索（結果をNSRangeのlistで返す）.scptd

— Created 2017-08-09 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
–http://piyocast.com/as/archives/4771

property NSString : a reference to current application’s NSString
property NSMutableArray : a reference to current application’s NSMutableArray
property NSLiteralSearch : a reference to current application’s NSLiteralSearch

on searchWordRanges(aTargText as string, aSearchStr as string)
　　set aStr to NSString’s stringWithString:aTargText
　　set bStr to NSString’s stringWithString:aSearchStr
　　
　　set hitArray to NSMutableArray’s alloc()’s init()
　　set cNum to (aStr’s |length|()) as integer
　　
　　set aRange to current application’s NSMakeRange(0, cNum)
　　
　　repeat
　　　　set detectedRange to aStr’s rangeOfString:bStr options:(NSLiteralSearch) range:aRange
　　　　set aLoc to detectedRange’s location
　　　　log aLoc
　　　　if (detectedRange’s location) is equal to (current application’s NSNotFound) then exit repeat
　　　　
　　　　hitArray’s addObject:detectedRange
　　　　
　　　　set aNum to (detectedRange’s location) as number
　　　　set bNum to (detectedRange’s |length|) as number
　　　　
　　　　set aRange to current application’s NSMakeRange(aNum + bNum, cNum – (aNum + bNum))
　　end repeat
　　
　　return hitArray
end searchWordRanges

★Click Here to Open This Script　

症状も前回とまったく同じなので、対処も前回と同じです。Appleは定期的にNSNotFoundの定義値を間違えるトンでもない会社なので（計測された事実）、NSNotFoundまわりはAppleがバグをやらかすことを前提に書いておくべきなんでしょう。

AppleScript名：テキストのキーワード検索（結果をNSRangeのlistで返す）v2.scptd

— Created 2017-08-09 by Takaaki Naganoya
— Modified 2022-12-01 by Takaaki Naganoya
— 2022 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aStr to "ATGC ACGT ATGC AGTC
ATGC ACGT ATGC AGTC
ATGC ACGT ATGC AGTC
ATGC ACGT ATGC AGTC
"
set aRes to searchWordRanges(aStr, "ATGC") of me as list
–>　　{{location:0, length:4}, {location:10, length:4}, {location:20, length:4}, {location:30, length:4}, {location:40, length:4}, {location:50, length:4}, {location:60, length:4}, {location:70, length:4}}
–> {{location:0, |length|:4}, {location:10, |length|:4}, {location:20, |length|:4}, {location:30, |length|:4}, {location:40, |length|:4}, {location:50, |length|:4}, {location:60, |length|:4}, {location:70, |length|:4}}

on searchWordRanges(aTargText as string, aSearchStr as string)
　　set aStr to NSString’s stringWithString:aTargText
　　set bStr to NSString’s stringWithString:aSearchStr
　　
　　set hitArray to NSMutableArray’s alloc()’s init()
　　set cNum to (aStr’s |length|()) as integer
　　
　　set aRange to current application’s NSMakeRange(0, cNum)
　　
　　repeat
　　　　set detectedRange to aStr’s rangeOfString:bStr options:(NSLiteralSearch) range:aRange
　　　　set aLoc to detectedRange’s location
　　　　
　　　　–macOS 13でAppleが新たに作ったバグを回避
　　　　if (aLoc > 9.999999999E+9) or (aLoc = current application’s NSNotFound) then exit repeat
　　　　
　　　　hitArray’s addObject:detectedRange
　　　　
　　　　set aNum to (detectedRange’s location) as number
　　　　set bNum to (detectedRange’s |length|) as number
　　　　
　　　　set aRange to current application’s NSMakeRange(aNum + bNum, cNum – (aNum + bNum))
　　end repeat
　　
　　return hitArray
end searchWordRanges

★Click Here to Open This Script　

(Visited 73 times, 1 visits today)

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

Posted on 7月 17, 2020 by Takaaki Naganoya

アラートダイアログ上にボタンタイプのチェックボックスを並べて、選択したボタンのタイトルを選択するAppleScriptです。

書類の印刷対象を、こまかくページ指定するために作成した部品です。

ヘルプボタンにより、全ボタンの選択/非選択状態を作り出せます。

▲Beta2でAlert Dialogのタイトルまわりが変更されたようですが、、、、うーーん。あと、選択状態をボタンの見かけから知ることができないですわー

AppleScript名：アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

— Created 2020-07-17 by Takaaki Naganoya
— 2020 Piyomaru Software

set aRes to selectByCheckbox("Select each printout page", "Selected pages are the target", 64, "Helvetica") of chooseSeqNum

script chooseSeqNum
　　
　　use AppleScript version "2.5"
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　
　　property NSFont : a reference to current application’s NSFont
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSButton : a reference to current application’s NSButton
　　property NSOnState : a reference to current application’s NSOnState
　　property NSOffState : a reference to current application’s NSOffState
　　property NSTextField : a reference to current application’s NSTextField
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
　　property NSMutableDictionary : a reference to current application’s NSMutableDictionary
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSFontAttributeName : a reference to current application’s NSFontAttributeName
　　property NSKernAttributeName : a reference to current application’s NSKernAttributeName
　　property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
　　property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
　　property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
　　property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
　　property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
　　property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
　　
　　property theResult : 0
　　property returnCode : 0
　　property cList : {} –Checkbox button object array
　　property bArray : {}
　　
　　
　　on selectByCheckbox(aMainMessage, aSubMessage, aMaxPage, myFont)
　　　　set paramObj to {myMessage:aMainMessage, mySubMessage:aSubMessage, maxPage:aMaxPage, fontName:myFont}
　　　　–my chooseItemByCheckBox:paramObj –for Debugging
　　　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　　　–> {1, 3, 5, 7, 9, 11}
　　　　return cList
　　end selectByCheckbox
　　
　　on chooseItemByCheckBox:(paramObj)
　　　　set aMainMes to (myMessage of paramObj) as string
　　　　set aSubMes to (mySubMessage of paramObj) as string
　　　　set aMaxPage to (maxPage of paramObj) as integer
　　　　set aFontName to (fontName of paramObj) as string
　　　　
　　　　set cList to {}
　　　　
　　　　set colNum to 10
　　　　set rowNum to (aMaxPage div 10) + 1
　　　　set aLen to (colNum * rowNum)
　　　　
　　　　set aButtonCellWidth to 56
　　　　set aButtonCellHeight to 40
　　　　
　　　　set viewWidth to aButtonCellWidth * colNum
　　　　set viewHeight to aButtonCellHeight * (rowNum + 1)
　　　　
　　　　–define the matrix size where you’ll put the radio buttons
　　　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　　　
　　　　set aCount to 1
　　　　set aFontSize to 24
　　　　set bArray to current application’s NSMutableArray’s new()
　　　　
　　　　–Make Header (Month, Year)
　　　　set aCalList to makeSeqNumList(1, aMaxPage) of me
　　　　set aCount to 1
　　　　
　　　　
　　　　–Make Calendar (Calendar Body)
　　　　repeat with y from 1 to rowNum
　　　　　　repeat with x from 1 to colNum
　　　　　　　　–try
　　　　　　　　set j to (contents of item aCount of aCalList)
　　　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　　　
　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize))
　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), aFontName, aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeOnOff))
　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　
　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　
　　　　　　　　set aCount to aCount + 1
　　　　　　　　if aCount > aMaxPage then exit repeat
　　　　　　　　–end try
　　　　　　end repeat
　　　　　　if aCount > aMaxPage then exit repeat
　　　　end repeat
　　　　
　　　　–Select the first radio button item
　　　　–(tmpArray’s objectAtIndex:0)’s setState:(current application’s NSOnState)
　　　　set my theResult to {}
　　　　
　　　　(aView’s setSubviews:bArray)
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aView
　　　　　　
　　　　　　–for Help Button
　　　　　　its setShowsHelp:(true)
　　　　　　its setDelegate:(me)
　　　　　　
　　　　end tell
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode as number) = 1001 then error number -128
　　　　
　　　　set bNumList to (bArray’s valueForKeyPath:"state") as list
　　　　–set cList to {}
　　　　repeat with i from 1 to aMaxPage
　　　　　　set aFlag to (contents of item i of bNumList) as boolean
　　　　　　if aFlag = true then
　　　　　　　　set the end of cList to contents of i
　　　　　　end if
　　　　end repeat
　　　　
　　　　copy cList to bArray
　　end chooseItemByCheckBox:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to aParam’s runModal()
　　end doModal:
　　
　　
　　
　　on clicked:aParam
　　　　set aTag to (tag of aParam) as integer
　　　　–clicked
　　　　if aTag is not in (my theResult) then
　　　　　　set the end of (my theResult) to aTag
　　　　else
　　　　　　set theResult to my deleteItem:aTag fromList:theResult
　　　　end if
　　end clicked:
　　
　　
　　
　　on deleteItem:anItem fromList:theList
　　　　set theArray to NSMutableArray’s arrayWithArray:theList
　　　　theArray’s removeObject:anItem
　　　　return theArray as list
　　end deleteItem:fromList:
　　
　　
　　
　　–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
　　on sort1DNumList:theList ascOrder:aBool
　　　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　　　return (sortedList) as list
　　end sort1DNumList:ascOrder:
　　
　　
　　–Help Button Clicked Event Handler
　　on alertShowHelp:aNotification
　　　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　　　set bRes to (button returned of aRes) as string
　　　　
　　　　if bRes = "All Off" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　　　end repeat
　　　　　　
　　　　else if bRes = "All On" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　　　set the end of theResult to i + 1
　　　　　　end repeat
　　　　end if
　　　　
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　
　　–書式つきテキストを組み立てる
　　on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　　　set aKey1 to (NSFontAttributeName)
　　　　
　　　　set aVal2 to NSColor’s blackColor()
　　　　set aKey2 to (NSForegroundColorAttributeName)
　　　　
　　　　set aVal3 to aKerning
　　　　set akey3 to (NSKernAttributeName)
　　　　
　　　　set aVal4 to 0
　　　　set akey4 to (NSUnderlineStyleAttributeName)
　　　　
　　　　set aVal5 to 2 –all ligature ON
　　　　set akey5 to (NSLigatureAttributeName)
　　　　
　　　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　　　set akey7 to (NSParagraphStyleAttributeName)
　　　　
　　　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　　　
　　　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　　　return attrStr
　　end makeRTFfromParameters
　　
　　
　　on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aNSString’s setEditable:(editableF)
　　　　aNSString’s setStringValue:(setVal)
　　　　aNSString’s setDrawsBackground:(backgroundF)
　　　　aNSString’s setBordered:(borderedF)
　　　　return aNSString
　　end makeNSTextField
　　
　　
　　
　　on makeSeqNumList(fromNum as integer, toNum as integer)
　　　　script spd
　　　　　　property aList : {}
　　　　end script
　　　　
　　　　set aList of spd to {}
　　　　
　　　　repeat with i from fromNum to toNum
　　　　　　set the end of (aList of spd) to i
　　　　end repeat
　　　　
　　　　return (aList of spd)
　　end makeSeqNumList
　　
　　
end script

★Click Here to Open This Script　

(Visited 61 times, 1 visits today)

指定TTSボイスキャラクタの読み上げ例文テキストを取得

Posted on 7月 6, 2020 by Takaaki Naganoya

指定のテキスト読み上げ（Text To Speech）ボイスキャラクターの読み上げ例文テキストを取得して実際に読み上げるAppleScriptです。

TTS音声は言語や性別、年齢、高音質かどうかなどの情報を持っているので、これらを指定して絞り込むことが可能です。また、指定TTS音声キャラクターの例文テキストもこのように取得できます。

AppleScript名：指定TTSボイスキャラクタの読み上げ例文テキストを取得.scpt

— Created 2015-08-25 by Takaaki Naganoya
— Modified 2015-08-26 by Shane Stanley, Takaaki Naganoya
— Modified 2020-07-06 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use scripting additions

set vList to getVoiceNames() of me
using terms from scripting additions
　　set aTargTTSVoiceName to contents of (choose from list vList)
end using terms from

using terms from scripting additions
　　set v1Res to getDemoText(aTargTTSVoiceName) of me
　　say v1Res using aTargTTSVoiceName
end using terms from

–Get TTS Voice sample text
on getDemoText(aName as string)
　　set vList to getVoiceNames() of me
　　if aName is not in vList then return ""
　　set anID to getSpecifiedVoiceIDfromVoiceName(aName) of me
　　
　　set aDemoText to ((current application’s NSSpeechSynthesizer’s attributesForVoice:anID)’s VoiceDemoText)
　　return aDemoText as string
end getDemoText

–Get all voice names
on getVoiceNames()
　　–Make Blank Array
　　set outArray to current application’s NSMutableArray’s arrayWithObject:{}
　　set aList to {}
　　
　　–Make Installed Voice List
　　set nameList to current application’s NSSpeechSynthesizer’s availableVoices()
　　repeat with i in nameList
　　　　set j to contents of i
　　　　
　　　　set aDic to ((current application’s NSSpeechSynthesizer’s attributesForVoice:j))
　　　　
　　　　set aDemoText to (aDic’s VoiceDemoText) as string
　　　　set aName to (aDic’s VoiceName) as string
　　　　
　　　　set the end of aList to aName
　　end repeat
　　
　　return aList as list
end getVoiceNames

–Voice Name –> Voice ID
on getSpecifiedVoiceIDfromVoiceName(VoiceName as string)
　　set outArray to current application’s NSMutableArray’s arrayWithObject:{}
　　
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDic to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDic)
　　end repeat
　　
　　–Filter Voice
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceName == %@", VoiceName)
　　
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aReList to (filteredArray’s valueForKey:"VoiceIdentifier") as list
　　
　　if length of aReList = 1 then
　　　　return first item of aReList
　　else
　　　　return ""
　　end if
end getSpecifiedVoiceIDfromVoiceName

★Click Here to Open This Script　

(Visited 158 times, 1 visits today)

よみがなタグを削除

Posted on 7月 1, 2020 by Takaaki Naganoya

与えられたテキスト（おそらくHTML）から、指定のタグで囲まれた要素を削除するAppleScriptです。

Web上の表をCSVとして書き出すAppleScriptを動かしていて、Wikipediaの表を処理したときに「よみがなタグ」がそのまま文字列として展開されることに気づきました。

その場で既存のルーチンを使いまわして、よみがなタグの削除機能を追加。その追加内容です。

▲上は、Wikipedia掲載の表をそのままCSV化したもの。下は、本Scriptを追加してルビタグを削除するように改良したScriptの処理結果

AppleScript名：指定タグを削除.scpt

— Created 2016-12-12 by Shane Stanley
— Modified 2016-12-14 by edama2
— Modified 2017-11-28 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aStr to getData() of me
set aRes to (trimStrFromTo(aStr, "<span style=＼"display:none;speak:none＼">", "</span>") of me)
–>　　
(*
"
<td><b><a href=＼"/wiki/aaaaa" title=＼"こちら葛飾区亀有公園前派出所＼">こちら葛飾区<br />　亀有公園前派出所</a></b></td>
<td><a href=＼"/wiki/%E7%A7%8B%E6%9C%AC%E6%B2%BB＼" title=＼"秋本治＼">秋本治</a></td>
"
*)

on trimStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to current application’s NSScanner’s scannerWithString:aParamStr
　　set anArray to current application’s NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(reference)
　　　　
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(reference)
　　　　if theValue is missing value then set theValue to ""
　　　　
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　if anArray’s |count|() = 0 then return aParamStr
　　
　　copy aParamStr to curStr
　　repeat with i in (anArray as list)
　　　　set curStr to repChar(curStr, fromStr & i & toStr, "") of me
　　end repeat
　　
　　return curStr
end trimStrFromTo

on repChar(aStr, targStr, repStr)
　　set aString to current application’s NSString’s stringWithString:aStr
　　set bString to aString’s stringByReplacingOccurrencesOfString:targStr withString:repStr
　　set cString to bString as string
　　return cString
end repChar

on getData()
　　return "
<td><span style=＼"display:none;speak:none＼">こちらかつしかくかめありこうえんまえはしゆつしよ/</span><b><a href=＼"/wiki/aaaaa＼" title=＼"こちら葛飾区亀有公園前派出所＼">こちら葛飾区<br />　亀有公園前派出所</a></b></td>
<td><span style=＼"display:none;speak:none＼">あきもとおさむ/</span><a href=＼"/wiki/%E7%A7%8B%E6%9C%AC%E6%B2%BB＼" title=＼"秋本治＼">秋本治</a></td>
"
end getData

★Click Here to Open This Script　

(Visited 56 times, 1 visits today)

chartJSでアニメーション円グラフをダイアログ表示 v2.scptd

Posted on 6月 30, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを作成し、その上でChart.jsによる円グラフを表示するAppleScriptです。

▲実行するとテーマ選択ののちにグラフ表示を行います

–> Download chartJSPieChartDemo.scptd(Script Bundle with Lirbrary and HTML)

Chart.jsは、ダイアグラムやフローチャートなどを描画するJavaScriptのライブラリです。割とデータのカスタマイズがしやすい感じです。

AppleScript名：chartJSでアニメーション円グラフをダイアログ表示 v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/26
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use webD : script "webDialogLib"

set aRes to first item of (choose from list {"light1", "light2", "dark1", "dark2"} with prompt "Choose theme")

set aList to {{y:45.43, label:"Chrome"}, {y:32.4, label:"Safari"}, {y:6.67, label:"Firefox"}, {y:5.41, label:"Microsoft Edge"}, {y:5.26, label:"Internet Explorer"}, {y:1.19, label:"Samsung Internet"}}
set myTitle to "Desktop Browser Market Share in Japan May 2020"

–https://canvasjs.com/javascript-charts/pie-chart-legends/
set mePath to path to me
set resPath to (mePath as string) & "Contents:Resources:index.html"
set myStr to (read (resPath as alias) as «class utf8») as string

set aJsonStr to array2DToJSONArray(aList) of me
set aString to current application’s NSString’s stringWithFormat_(myStr, aRes as string, myTitle, aJsonStr) as string

set paramObj to {myMessage:"Animation Pie Chart", mySubMessage:"This is a canvasJS test", htmlStr:aString, jsDelimiters:{"<script>", "</script>"}, viewSize:{900, 620}}

webD’s displayWebDialog(paramObj)

on array2DToJSONArray(aList)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　set jsonData to current application’s NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value)
　　set resString to current application’s NSString’s alloc()’s initWithData:jsonData encoding:(current application’s NSUTF8StringEncoding)
　　return resString
end array2DToJSONArray

★Click Here to Open This Script　

(Visited 347 times, 1 visits today)

AMChartsで円グラフをダイアログ上に表示 v3

Posted on 6月 27, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを作成し、その上でAMChartsによる円グラフを表示するAppleScriptです。

ダイアログでテーマ選択したのちに、グラフ表示を行います。

—> Download ampiechartSample(AppleScript bundle with Script Library and HTMLs)

AppleScript名：AMChartsで円グラフをダイアログ上に表示 v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/25
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use webD : script "webDialogLib"

set themeList to {"dark", "dataviz", "material", "kelly", "frozen", "moonrisekingdom", "spiritedaway"}

set aSel to (choose from list themeList with prompt "Select Theme")
if aSel = false then
　　set aTheme to false
　　set aHTML to "index_notheme.html"
else
　　set aTheme to contents of first item of aSel
　　if aTheme = "dark" then
　　　　set aTheme to false
　　　　set aHTML to "index_dark.html"
　　else
　　　　set aHTML to "index.html"
　　end if
end if

set aList to {{label:"ひよこ王国", value:403}, {label:"ぴよぴよ連邦", value:301}, {label:"ぴよランド", value:101}, {label:"ぴよー", value:65}}
set bList to sortRecListByLabel(aList, {"value"}, {false}) of me –降順ソート

–https://www.amcharts.com/demos/pie-chart/
set mePath to path to me
set resPath to (mePath as string) & "Contents:Resources:" & aHTML
set myStr to (read (resPath as alias) as «class utf8») as string

set jsonStr to array2DToJSONArray(bList) of me as string

if aTheme = false then
　　set aString to current application’s NSString’s stringWithFormat_(myStr, jsonStr) as string
else
　　set aString to current application’s NSString’s stringWithFormat_(myStr, aTheme, aTheme, jsonStr) as string
end if

set paramObj to {myMessage:"Simple Pie Chart", mySubMessage:"This is a AMCharts test", htmlStr:aString, jsDelimiters:{"<script>", "</script>"}, viewSize:{1000, 550}}

webD’s displayWebDialog(paramObj)

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as list, ascendF as list)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　set aCount to length of aLabelStr
　　set sortDescArray to current application’s NSMutableArray’s new()
　　repeat with i from 1 to aCount
　　　　set aLabel to (item i of aLabelStr)
　　　　set aKey to (item i of ascendF)
　　　　set sortDesc to (current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabel ascending:aKey)
　　　　(sortDescArray’s addObject:sortDesc)
　　end repeat
　　
　　return (aArray’s sortedArrayUsingDescriptors:sortDescArray) as list
end sortRecListByLabel

★Click Here to Open This Script　

(Visited 168 times, 1 visits today)

AMChartsでバブルチャート＋世界地図をダイアログ上に表示 v2

Posted on 6月 26, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを作成し、その上でAMChartsによるバブルチャートつき世界地図を表示するAppleScriptです。

–> Download amBubbleMap.zip(Script Bundle with AppleScript Library and HTML)

表示用のデータをAppleScriptのRecord（をListに入れたもの）に変換して、外部から供給するようにして、表示するさいにJSONに変換してHTMLに差し込んで表示しています。

正直、record形式にすると編集が大変なような気がするので、プログラムリスト中から外部に追い出して、plistとかJSONとかいろいろ他の形式で保持しておくといいと思います。もちろん、AppleScriptらしくNumbersの表データ中にデータを展開してもよいのですが、「ならNumbersでグラフ表示させたほうがよいのでは？」というところなので、あえて触れませんでした。

AMChart掲載のグラフはデータを差し込みやすくていいですね。

AppleScript名：AMChartsでバブルチャート＋世界地図をダイアログ上に表示 v2.scptd

set aList to retData() of me
set jStr to array2DToJSONArray(aList) of me as string

–https://www.zingchart.com/
set mePath to path to me
set resPath to (mePath as string) & "Contents:Resources:index.html"
set myStr to read (resPath as alias) as «class utf8»

set aString to current application’s NSString’s stringWithFormat_(myStr, jStr) as string

set paramObj to {myMessage:"Map with Bubbles", mySubMessage:"This is a AMCharts test", htmlStr:aString, jsDelimiters:{"<script>", "</script>"}, viewSize:{1000, 620}}

webD’s displayWebDialog(paramObj)

on retData()
　　return {{|id|:"AF", |name|:"Afghanistan", value:32358260, |color|:"#ff0000"}, {|id|:"AL", |name|:"Albania", value:3215988, |color|:"#00ff00"}, {|id|:"DZ", |name|:"Algeria", value:35980193, |color|:"#0000ff"}, {|id|:"AO", |name|:"Angola", value:19618432, |color|:"#0000ff"}, {|id|:"AR", |name|:"Argentina", value:40764561, |color|:"#ffff00"}, {|id|:"AM", |name|:"Armenia", value:3100236, |color|:"#00ff00"}, {|id|:"AU", |name|:"Australia", value:22605732, |color|:"#8aabb0"}, {|id|:"AT", |name|:"Austria", value:8413429, |color|:"#00ff00"}, {|id|:"AZ", |name|:"Azerbaijan", value:9306023, |color|:"#00ff00"}, {|id|:"BH", |name|:"Bahrain", value:1323535, |color|:"#ff0000"}, {|id|:"BD", |name|:"Bangladesh", value:150493658, |color|:"#ff0000"}, {|id|:"BY", |name|:"Belarus", value:9559441, |color|:"#00ff00"}, {|id|:"BE", |name|:"Belgium", value:10754056, |color|:"#00ff00"}, {|id|:"BJ", |name|:"Benin", value:9099922, |color|:"#0000ff"}, {|id|:"BT", |name|:"Bhutan", value:738267, |color|:"#ff0000"}, {|id|:"BO", |name|:"Bolivia", value:10088108, |color|:"#ffff00"}, {|id|:"BA", |name|:"Bosnia and Herzegovina", value:3752228, |color|:"#00ff00"}, {|id|:"BW", |name|:"Botswana", value:2030738, |color|:"#0000ff"}, {|id|:"BR", |name|:"Brazil", value:196655014, |color|:"#ffff00"}, {|id|:"BN", |name|:"Brunei", value:405938, |color|:"#ff0000"}, {|id|:"BG", |name|:"Bulgaria", value:7446135, |color|:"#00ff00"}, {|id|:"BF", |name|:"Burkina Faso", value:16967845, |color|:"#0000ff"}, {|id|:"BI", |name|:"Burundi", value:8575172, |color|:"#0000ff"}, {|id|:"KH", |name|:"Cambodia", value:14305183, |color|:"#ff0000"}, {|id|:"CM", |name|:"Cameroon", value:20030362, |color|:"#0000ff"}, {|id|:"CA", |name|:"Canada", value:34349561, |color|:"#888822"}, {|id|:"CV", |name|:"Cape Verde", value:500585, |color|:"#0000ff"}, {|id|:"CF", |name|:"Central African Rep.", value:4486837, |color|:"#0000ff"}, {|id|:"TD", |name|:"Chad", value:11525496, |color|:"#0000ff"}, {|id|:"CL", |name|:"Chile", value:17269525, |color|:"#ffff00"}, {|id|:"CN", |name|:"China", value:1.347565324E+9, |color|:"#ff0000"}, {|id|:"CO", |name|:"Colombia", value:46927125, |color|:"#ffff00"}, {|id|:"KM", |name|:"Comoros", value:753943, |color|:"#0000ff"}, {|id|:"CD", |name|:"Congo, Dem. Rep.", value:67757577, |color|:"#0000ff"}, {|id|:"CG", |name|:"Congo, Rep.", value:4139748, |color|:"#0000ff"}, {|id|:"CR", |name|:"Costa Rica", value:4726575, |color|:"#888822"}, {|id|:"CI", |name|:"Cote d’Ivoire", value:20152894, |color|:"#0000ff"}, {|id|:"HR", |name|:"Croatia", value:4395560, |color|:"#00ff00"}, {|id|:"CU", |name|:"Cuba", value:11253665, |color|:"#888822"}, {|id|:"CY", |name|:"Cyprus", value:1116564, |color|:"#00ff00"}, {|id|:"CZ", |name|:"Czech Rep.", value:10534293, |color|:"#00ff00"}, {|id|:"DK", |name|:"Denmark", value:5572594, |color|:"#00ff00"}, {|id|:"DJ", |name|:"Djibouti", value:905564, |color|:"#0000ff"}, {|id|:"DO", |name|:"Dominican Rep.", value:10056181, |color|:"#888822"}, {|id|:"EC", |name|:"Ecuador", value:14666055, |color|:"#ffff00"}, {|id|:"EG", |name|:"Egypt", value:82536770, |color|:"#0000ff"}, {|id|:"SV", |name|:"El Salvador", value:6227491, |color|:"#888822"}, {|id|:"GQ", |name|:"Equatorial Guinea", value:720213, |color|:"#0000ff"}, {|id|:"ER", |name|:"Eritrea", value:5415280, |color|:"#0000ff"}, {|id|:"EE", |name|:"Estonia", value:1340537, |color|:"#00ff00"}, {|id|:"ET", |name|:"Ethiopia", value:84734262, |color|:"#0000ff"}, {|id|:"FJ", |name|:"Fiji", value:868406, |color|:"#8aabb0"}, {|id|:"FI", |name|:"Finland", value:5384770, |color|:"#00ff00"}, {|id|:"FR", |name|:"France", value:63125894, |color|:"#00ff00"}, {|id|:"GA", |name|:"Gabon", value:1534262, |color|:"#0000ff"}, {|id|:"GM", |name|:"Gambia", value:1776103, |color|:"#0000ff"}, {|id|:"GE", |name|:"Georgia", value:4329026, |color|:"#00ff00"}, {|id|:"DE", |name|:"Germany", value:82162512, |color|:"#00ff00"}, {|id|:"GH", |name|:"Ghana", value:24965816, |color|:"#0000ff"}, {|id|:"GR", |name|:"Greece", value:11390031, |color|:"#00ff00"}, {|id|:"GT", |name|:"Guatemala", value:14757316, |color|:"#888822"}, {|id|:"GN", |name|:"Guinea", value:10221808, |color|:"#0000ff"}, {|id|:"GW", |name|:"Guinea-Bissau", value:1547061, |color|:"#0000ff"}, {|id|:"GY", |name|:"Guyana", value:756040, |color|:"#ffff00"}, {|id|:"HT", |name|:"Haiti", value:10123787, |color|:"#888822"}, {|id|:"HN", |name|:"Honduras", value:7754687, |color|:"#888822"}, {|id|:"HK", |name|:"Hong Kong, China", value:7122187, |color|:"#ff0000"}, {|id|:"HU", |name|:"Hungary", value:9966116, |color|:"#00ff00"}, {|id|:"IS", |name|:"Iceland", value:324366, |color|:"#00ff00"}, {|id|:"IN", |name|:"India", value:1.24149196E+9, |color|:"#ff0000"}, {|id|:"ID", |name|:"Indonesia", value:242325638, |color|:"#ff0000"}, {|id|:"IR", |name|:"Iran", value:74798599, |color|:"#ff0000"}, {|id|:"IQ", |name|:"Iraq", value:32664942, |color|:"#ff0000"}, {|id|:"IE", |name|:"Ireland", value:4525802, |color|:"#00ff00"}, {|id|:"IL", |name|:"Israel", value:7562194, |color|:"#ff0000"}, {|id|:"IT", |name|:"Italy", value:60788694, |color|:"#00ff00"}, {|id|:"JM", |name|:"Jamaica", value:2751273, |color|:"#888822"}, {|id|:"JP", |name|:"Japan", value:126497241, |color|:"#ff0000"}, {|id|:"JO", |name|:"Jordan", value:6330169, |color|:"#ff0000"}, {|id|:"KZ", |name|:"Kazakhstan", value:16206750, |color|:"#ff0000"}, {|id|:"KE", |name|:"Kenya", value:41609728, |color|:"#0000ff"}, {|id|:"KP", |name|:"Korea, Dem. Rep.", value:24451285, |color|:"#ff0000"}, {|id|:"KR", |name|:"Korea, Rep.", value:48391343, |color|:"#ff0000"}, {|id|:"KW", |name|:"Kuwait", value:2818042, |color|:"#ff0000"}, {|id|:"KG", |name|:"Kyrgyzstan", value:5392580, |color|:"#ff0000"}, {|id|:"LA", |name|:"Laos", value:6288037, |color|:"#ff0000"}, {|id|:"LV", |name|:"Latvia", value:2243142, |color|:"#00ff00"}, {|id|:"LB", |name|:"Lebanon", value:4259405, |color|:"#ff0000"}, {|id|:"LS", |name|:"Lesotho", value:2193843, |color|:"#0000ff"}, {|id|:"LR", |name|:"Liberia", value:4128572, |color|:"#0000ff"}, {|id|:"LY", |name|:"Libya", value:6422772, |color|:"#0000ff"}, {|id|:"LT", |name|:"Lithuania", value:3307481, |color|:"#00ff00"}, {|id|:"LU", |name|:"Luxembourg", value:515941, |color|:"#00ff00"}, {|id|:"MK", |name|:"Macedonia, FYR", value:2063893, |color|:"#00ff00"}, {|id|:"MG", |name|:"Madagascar", value:21315135, |color|:"#0000ff"}, {|id|:"MW", |name|:"Malawi", value:15380888, |color|:"#0000ff"}, {|id|:"MY", |name|:"Malaysia", value:28859154, |color|:"#ff0000"}, {|id|:"ML", |name|:"Mali", value:15839538, |color|:"#0000ff"}, {|id|:"MR", |name|:"Mauritania", value:3541540, |color|:"#0000ff"}, {|id|:"MU", |name|:"Mauritius", value:1306593, |color|:"#0000ff"}, {|id|:"MX", |name|:"Mexico", value:114793341, |color|:"#888822"}, {|id|:"MD", |name|:"Moldova", value:3544864, |color|:"#00ff00"}, {|id|:"MN", |name|:"Mongolia", value:2800114, |color|:"#ff0000"}, {|id|:"ME", |name|:"Montenegro", value:632261, |color|:"#00ff00"}, {|id|:"MA", |name|:"Morocco", value:32272974, |color|:"#0000ff"}, {|id|:"MZ", |name|:"Mozambique", value:23929708, |color|:"#0000ff"}, {|id|:"MM", |name|:"Myanmar", value:48336763, |color|:"#ff0000"}, {|id|:"NA", |name|:"Namibia", value:2324004, |color|:"#0000ff"}, {|id|:"NP", |name|:"Nepal", value:30485798, |color|:"#ff0000"}, {|id|:"NL", |name|:"Netherlands", value:16664746, |color|:"#00ff00"}, {|id|:"NZ", |name|:"New Zealand", value:4414509, |color|:"#8aabb0"}, {|id|:"NI", |name|:"Nicaragua", value:5869859, |color|:"#888822"}, {|id|:"NE", |name|:"Niger", value:16068994, |color|:"#0000ff"}, {|id|:"NG", |name|:"Nigeria", value:162470737, |color|:"#0000ff"}, {|id|:"NO", |name|:"Norway", value:4924848, |color|:"#00ff00"}, {|id|:"OM", |name|:"Oman", value:2846145, |color|:"#ff0000"}, {|id|:"PK", |name|:"Pakistan", value:176745364, |color|:"#ff0000"}, {|id|:"PA", |name|:"Panama", value:3571185, |color|:"#888822"}, {|id|:"PG", |name|:"Papua New Guinea", value:7013829, |color|:"#8aabb0"}, {|id|:"PY", |name|:"Paraguay", value:6568290, |color|:"#ffff00"}, {|id|:"PE", |name|:"Peru", value:29399817, |color|:"#ffff00"}, {|id|:"PH", |name|:"Philippines", value:94852030, |color|:"#ff0000"}, {|id|:"PL", |name|:"Poland", value:38298949, |color|:"#00ff00"}, {|id|:"PT", |name|:"Portugal", value:10689663, |color|:"#00ff00"}, {|id|:"PR", |name|:"Puerto Rico", value:3745526, |color|:"#888822"}, {|id|:"QA", |name|:"Qatar", value:1870041, |color|:"#ff0000"}, {|id|:"RO", |name|:"Romania", value:21436495, |color|:"#00ff00"}, {|id|:"RU", |name|:"Russia", value:142835555, |color|:"#00ff00"}, {|id|:"RW", |name|:"Rwanda", value:10942950, |color|:"#0000ff"}, {|id|:"SA", |name|:"Saudi Arabia", value:28082541, |color|:"#ff0000"}, {|id|:"SN", |name|:"Senegal", value:12767556, |color|:"#0000ff"}, {|id|:"RS", |name|:"Serbia", value:9853969, |color|:"#00ff00"}, {|id|:"SL", |name|:"Sierra Leone", value:5997486, |color|:"#0000ff"}, {|id|:"SG", |name|:"Singapore", value:5187933, |color|:"#ff0000"}, {|id|:"SK", |name|:"Slovak Republic", value:5471502, |color|:"#00ff00"}, {|id|:"SI", |name|:"Slovenia", value:2035012, |color|:"#00ff00"}, {|id|:"SB", |name|:"Solomon Islands", value:552267, |color|:"#8aabb0"}, {|id|:"SO", |name|:"Somalia", value:9556873, |color|:"#0000ff"}, {|id|:"ZA", |name|:"South Africa", value:50459978, |color|:"#0000ff"}, {|id|:"ES", |name|:"Spain", value:46454895, |color|:"#00ff00"}, {|id|:"LK", |name|:"Sri Lanka", value:21045394, |color|:"#ff0000"}, {|id|:"SD", |name|:"Sudan", value:34735288, |color|:"#0000ff"}, {|id|:"SR", |name|:"Suriname", value:529419, |color|:"#ffff00"}, {|id|:"SZ", |name|:"Swaziland", value:1203330, |color|:"#0000ff"}, {|id|:"SE", |name|:"Sweden", value:9440747, |color|:"#00ff00"}, {|id|:"CH", |name|:"Switzerland", value:7701690, |color|:"#00ff00"}, {|id|:"SY", |name|:"Syria", value:20766037, |color|:"#ff0000"}, {|id|:"TW", |name|:"Taiwan", value:23072000, |color|:"#ff0000"}, {|id|:"TJ", |name|:"Tajikistan", value:6976958, |color|:"#ff0000"}, {|id|:"TZ", |name|:"Tanzania", value:46218486, |color|:"#0000ff"}, {|id|:"TH", |name|:"Thailand", value:69518555, |color|:"#ff0000"}, {|id|:"TG", |name|:"Togo", value:6154813, |color|:"#0000ff"}, {|id|:"TT", |name|:"Trinidad and Tobago", value:1346350, |color|:"#888822"}, {|id|:"TN", |name|:"Tunisia", value:10594057, |color|:"#0000ff"}, {|id|:"TR", |name|:"Turkey", value:73639596, |color|:"#00ff00"}, {|id|:"TM", |name|:"Turkmenistan", value:5105301, |color|:"#ff0000"}, {|id|:"UG", |name|:"Uganda", value:34509205, |color|:"#0000ff"}, {|id|:"UA", |name|:"Ukraine", value:45190180, |color|:"#00ff00"}, {|id|:"AE", |name|:"United Arab Emirates", value:7890924, |color|:"#ff0000"}, {|id|:"GB", |name|:"United Kingdom", value:62417431, |color|:"#00ff00"}, {|id|:"US", |name|:"United States", value:313085380, |color|:"#888822"}, {|id|:"UY", |name|:"Uruguay", value:3380008, |color|:"#ffff00"}, {|id|:"UZ", |name|:"Uzbekistan", value:27760267, |color|:"#ff0000"}, {|id|:"VE", |name|:"Venezuela", value:29436891, |color|:"#ffff00"}, {|id|:"PS", |name|:"West Bank and Gaza", value:4152369, |color|:"#ff0000"}, {|id|:"VN", |name|:"Vietnam", value:88791996, |color|:"#ff0000"}, {|id|:"YE", |name|:"Yemen, Rep.", value:24799880, |color|:"#ff0000"}, {|id|:"ZM", |name|:"Zambia", value:13474959, |color|:"#0000ff"}, {|id|:"ZW", |name|:"Zimbabwe", value:12754378, |color|:"#0000ff"}}
end retData

★Click Here to Open This Script　

(Visited 470 times, 1 visits today)

AMChartsで点滅ポイントつき世界地図をダイアログ上に表示 v2

Posted on 6月 25, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを作成し、その上でAMChartsによる点滅ポイントつき世界地図を表示するAppleScriptです。

このアラートダイアログによる「箱庭UI」シリーズも、なかなか実用性のあるソリューションにつながる例が少なくて、インパクトとかウケ狙いのものが多いですが、これにはけっこうな実用性を感じました。

世界地図上にプロットする必要のあるデータというのはなかなかありませんが、必要がある場合にはこのように部品として使えるところまで飼い慣らしてあるので、有用性は高いと思われます。

–> Download displayAMChart (Script Bundle with Library and HTML）

▲macOS 11.0Betaでも動きます

AppleScript名：AMChartsで点滅ポイントつき世界地図をダイアログ上に表示 v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/23
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use webD : script "webDialogLib"

set zoomScale to 4 –Flash Radius

–Not actual location
set aList to {{title:"Shane Stanley", latitude:-33.5206, longitude:151.1231, |color|:"#0000ff", |url|:"https://latenightsw.com"}, {title:"Takaaki Naganoya (me)", latitude:35.6785, longitude:139.6823, |color|:"#ff0000", |url|:"http://piyocast.com"}, {title:"Jean-Christophe Helary", latitude:34.349399, longitude:134.025012, |color|:"#0000ff", |url|:"http://mac4translators.blogspot.com"}, {title:"Yvan KOENIG", latitude:43.57803, longitude:7.05451, |color|:"#0000ff"}, {title:"Ed Stockly", latitude:34.052235, longitude:-118.243683, |color|:"#0000ff", |url|:"https://www.latimes.com"}, {title:"Mark Alldritt", latitude:45.2512, longitude:-75.42, |color|:"#0000ff", |url|:"https://latenightsw.com"}}

–https://www.amcharts.com/demos/zooming-to-countries-map/
set mePath to path to me
set resPath to (mePath as string) & "Contents:Resources:index.html"
set myStr to read (resPath as alias) as «class utf8»

set jStr to array2DToJSONArray(aList) of me
set aString to current application’s NSString’s stringWithFormat_(myStr, zoomScale as string, jStr) as string

set paramObj to {myMessage:"AppleScripters I know the location", mySubMessage:"This is a AMCharts test", htmlStr:aString, jsDelimiters:{"<script>", "</script>"}, viewSize:{1000, 520}}

webD’s displayWebDialog(paramObj)

★Click Here to Open This Script　

(Visited 205 times, 1 visits today)

アラートダイアログ上にWebViewでChart.jsを表示（Pie Chart） v2

Posted on 6月 15, 2020 by Takaaki Naganoya

Chart.jsを用いてアラートダイアログ上に円グラフを表示するAppleScriptです。

サンプルの円グラフの色使いがいまひとつだったので、Keynoteのグラフの色設定を読み取って利用しています。

ネットワーク接続チェックなど、必要な処理はひととおり行なっている、実戦レベルに近いものです。

さまざまなJavaScript系のグラフ表示のプログラムを試してみましたが、Chart.jsはとてもいい感じです。

AppleScript名：アラートダイアログ上にWebViewでChart.jsを表示（Pie Chart） v2.scptd

set aList to {"field1", "field2", "field3", "field4", "field5"}
set cList to {38, 31, 21, 10, 1}
set dMes1 to "Pie chart Test"
set dMes2 to "This is a simple Donut chart using charts.js"

displayPieChart(aList, cList, dMes1, dMes2) of pieChartLib

script pieChartLib
　　—
　　–　　Created by: Takaaki Naganoya
　　–　　Created on: 2020/06/12
　　—
　　–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
　　—
　　use AppleScript version "2.4" — Yosemite (10.10) or later
　　use framework "Foundation"
　　use framework "AppKit"
　　use framework "WebKit"
　　use scripting additions
　　
　　property |NSURL| : a reference to current application’s |NSURL|
　　property NSAlert : a reference to current application’s NSAlert
　　property NSString : a reference to current application’s NSString
　　property NSButton : a reference to current application’s NSButton
　　property WKWebView : a reference to current application’s WKWebView
　　property WKUserScript : a reference to current application’s WKUserScript
　　property NSURLRequest : a reference to current application’s NSURLRequest
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSJSONSerialization : a reference to current application’s NSJSONSerialization
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
　　property WKUserContentController : a reference to current application’s WKUserContentController
　　property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
　　property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd
　　
　　property returnCode : 0
　　property parent : AppleScript
　　
　　
　　on displayPieChart(aList, cList, dMes1, dMes2)
　　　　–Error Check
　　　　if length of aList is not equal to length of cList then error "Wrong Parameter items"
　　　　if length of aList > 18 then error "Too much items"
　　　　
　　　　set aRes to hasInternetConnection("https://cdnjs.cloudflare.com") of me
　　　　if aRes = false then error "Internet connection lost"
　　　　
　　　　–Data convert to JSON strings
　　　　set aJsonStr to array2DToJSONArray(aList) of me
　　　　set cJsonStr to array2DToJSONArray(cList) of me
　　　　
　　　　–Pie Chart Template HTML
　　　　set myStr to "<!DOCTYPE html>
<html lang=＼"ja＼">
<head>
<meta charset=＼"utf-8＼">
　<title>Graph</title>
</head>
<body>
<canvas id=＼"myPieChart＼"></canvas>
<script src=＼"https://cdnjs.cloudflare.com/ajax/libs/Chart.js/2.7.2/Chart.bundle.js＼"></script>

<script>
var ctx = document.getElementById(＼"myPieChart＼");
var myPieChart = new Chart(ctx, {
type: ’pie’,
data: {
labels: %@,
datasets: [{
backgroundColor: %@,
data: %@
}]
},
options: {
title: {
display: false,
text: ＼"＼"
}
}
});
</script>
</body>
</html>"
　　　　–Color Table From Apple Keynote
　　　　set bList to {"#118EFE", "#53D529", "#F5AD10", "#FC0007", "#8B2659", "#2A2A2A", "#118EFE", "#53D529", "#F5AD10", "#FC0007", "#8B2659", "#2A2A2A", "#118EFE", "#53D529", "#F5AD10", "#FC0007", "#8B2659", "#2A2A2A"}
　　　　set bJsonStr to array2DToJSONArray(bList) of me
　　　　
　　　　set aString to NSString’s stringWithFormat_(myStr, aJsonStr, bJsonStr, cJsonStr) as string
　　　　
　　　　set paramObj to {myMessage:dMes1, mySubMessage:dMes2, htmlStr:aString}
　　　　–my browseStrWebContents:paramObj–for debug
　　　　my performSelectorOnMainThread:"browseStrWebContents:" withObject:(paramObj) waitUntilDone:true
　　end displayPieChart
　　
　　on browseStrWebContents:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set htmlString to (htmlStr of paramObj)
　　　　
　　　　set aWidth to 920
　　　　set aHeight to 500
　　　　
　　　　–WebViewをつくる
　　　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　　　
　　　　–指定HTML内のJavaScriptをFetch
　　　　set jsSource to pickUpFromToStr(htmlString, "<script>", "</script>") of me
　　　　
　　　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　　　set userContentController to WKUserContentController’s alloc()’s init()
　　　　userContentController’s addUserScript:(userScript)
　　　　aConf’s setUserContentController:userContentController
　　　　
　　　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) configuration:aConf
　　　　aWebView’s setNavigationDelegate:me
　　　　aWebView’s setUIDelegate:me
　　　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　　　using terms from scripting additions
　　　　　　set bURL to |NSURL|’s fileURLWithPath:(POSIX path of (path to me))
　　　　end using terms from
　　　　aWebView’s loadHTMLString:htmlString baseURL:(bURL)
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　–its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aWebView
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　
　　　　–Stop Web View Action
　　　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　　　set bReq to NSURLRequest’s requestWithURL:bURL
　　　　aWebView’s loadRequest:bReq
　　　　
　　　　if (my returnCode as number) = 1001 then error number -128
　　end browseStrWebContents:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　on viewDidLoad:aNotification
　　　　return true
　　end viewDidLoad:
　　
　　
　　on fetchJSSourceString(aURL)
　　　　set jsURL to |NSURL|’s URLWithString:aURL
　　　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　　　return jsSourceString
　　end fetchJSSourceString
　　
　　
　　on pickUpFromToStr(aStr as string, s1Str as string, s2Str as string)
　　　　set a1Offset to offset of s1Str in aStr
　　　　if a1Offset = 0 then return false
　　　　set bStr to text (a1Offset + (length of s1Str)) thru -1 of aStr
　　　　set a2Offset to offset of s2Str in bStr
　　　　if a2Offset = 0 then return false
　　　　set cStr to text 1 thru (a2Offset – (length of s2Str)) of bStr
　　　　return cStr as string
　　end pickUpFromToStr
　　
　　
　　on array2DToJSONArray(aList)
　　　　set anArray to NSMutableArray’s arrayWithArray:aList
　　　　set jsonData to NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value) –0 is
　　　　set resString to NSString’s alloc()’s initWithData:jsonData encoding:(NSUTF8StringEncoding)
　　　　return resString
　　end array2DToJSONArray
　　
　　
　　on parseByDelim(aData, aDelim)
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to aDelim
　　　　set dList to text items of aData
　　　　set AppleScript’s text item delimiters to curDelim
　　　　return dList
　　end parseByDelim
　　
　　on hasInternetConnection(aURL)
　　　　set aURL to current application’s |NSURL|’s alloc()’s initWithString:aURL
　　　　set aReq to current application’s NSURLRequest’s alloc()’s initWithURL:aURL cachePolicy:(current application’s NSURLRequestReloadIgnoringLocalCacheData) timeoutInterval:5.0
　　　　set urlRes to (current application’s NSURLConnection’s sendSynchronousRequest:aReq returningResponse:(missing value) |error|:(missing value))
　　　　if urlRes = missing value then
　　　　　　return false
　　　　else
　　　　　　return true
　　　　end if
　　end hasInternetConnection
end script

★Click Here to Open This Script　

(Visited 180 times, 1 visits today)

アラートダイアログ上にd3-cloudを用いてワードクラウドを表示

Posted on 6月 14, 2020 by Takaaki Naganoya

d3-cloudを用いてワードクラウドを表示するAppleScriptです。

本AppleScriptでは、

 {|word|:"NSString", |count|:97}

のように、登場単語、登場回数のように集計ずみのデータをJSONに変換してワードクラウド表示させています。この（AppleScriptの予約語にかぶりまくりな）属性ラベルはd3-cloud側の仕様です。

以前に作った「Tag CloudっぽいRTFの作成」のデータを用いて（属性ラベルを置換して）表示させたものがこちら（↑）。

Tag/Word Cloud関連のJavaScriptについては前から気になって調べてはいたのですが、「ローカルにデータを持つスクリプトが多い」「d3-cloud自体をローカルにインストールさせる例が多い」（実行速度などの問題で？）という状況で、ありもののスクリプトをこのアラートダイアログ上にはりつけたWkWebViewの「箱庭環境」で追加スクリプトのインストールなしで動くように書き換えるのに少々手間取りました。

CDNにホスティングされているd3-cloudを呼び出すことで、ローカルにd3-cloudをインストールせずに実行していますが、将来的にこれが変更・廃止された場合には別のWeb上のどこかにホスティングされているd3-cloudを呼び出すことになります。

ローカルにあるテキストコンテンツ（CotEditorで編集中の文章とか、Pagesで作成中のワープロ文章とか、Keynoteで作成中のプレゼン資料の内容とか）を分析して頻出単語を取り出し、タグクラウドといいますかワードクラウドで表示して全体の見通しをつけるというScriptは作りたいと思っていました。

AppleScript名：アラートダイアログ上にd3-cloudを用いてワードクラウドを表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/13
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSAlert : a reference to current application’s NSAlert
property NSString : a reference to current application’s NSString
property NSButton : a reference to current application’s NSButton
property WKWebView : a reference to current application’s WKWebView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSMutableArray : a reference to current application’s NSMutableArray
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property WKUserContentController : a reference to current application’s WKUserContentController
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property returnCode : 0

set aRecArray to {{|word|:"NSString", |count|:97}, {|word|:"NSURL", |count|:78}, {|word|:"Keynote", |count|:52}, {|word|:"NSMutableArray", |count|:51}, {|word|:"NSAlert", |count|:50}, {|word|:"NSRunningApplication", |count|:49}, {|word|:"NSArray", |count|:48}, {|word|:"CotEditor", |count|:44}, {|word|:"NSColor", |count|:44}, {|word|:"Finder", |count|:41}, {|word|:"NSImage", |count|:39}, {|word|:"Numbers", |count|:38}, {|word|:"NSPredicate", |count|:34}, {|word|:"NSView", |count|:32}, {|word|:"NSButton", |count|:28}, {|word|:"Safari", |count|:28}, {|word|:"NSScreen", |count|:27}, {|word|:"iTunes", |count|:25}, {|word|:"NSUTF8StringEncoding", |count|:24}, {|word|:"NSDictionary", |count|:22}, {|word|:"NSScrollView", |count|:21}, {|word|:"NSBitmapImageRep", |count|:20}, {|word|:"NSFileManager", |count|:20}, {|word|:"NSMutableDictionary", |count|:19}, {|word|:"NSURLRequest", |count|:18}, {|word|:"NSUUID", |count|:18}, {|word|:"NSWindow", |count|:17}, {|word|:"NSBezierPath", |count|:16}, {|word|:"NSFont", |count|:16}, {|word|:"WKWebView", |count|:16}, {|word|:"WKWebViewConfiguration", |count|:16}, {|word|:"NSWorkspace", |count|:15}, {|word|:"Pages", |count|:15}, {|word|:"Script Editor", |count|:15}, {|word|:"System Events", |count|:15}, {|word|:"WKUserContentController", |count|:15}, {|word|:"WKUserScript", |count|:15}, {|word|:"NSAlertSecondButtonReturn", |count|:14}, {|word|:"NSJSONSerialization", |count|:14}, {|word|:"NSSortDescriptor", |count|:14}}
set jsonStr to array2DToJSONArray(aRecArray) of me

–https://qiita.com/january108/items/5388799531c1ace8324e
set myStr to "<!DOCTYPE HTML>
<html lang=＼"en＼">
<head>
<meta charset=＼"UTF-8＼">
<title>D3 Word Clouds</title>
<meta name=＼"author＼" content=＼"d4i＼"/>
</head>
<body>
<script src=＼"http://d3js.org/d3.v3.min.js＼" charset=＼"utf-8＼"></script>
<script src=＼"https://cdnjs.cloudflare.com/ajax/libs/d3-cloud/1.2.5/d3.layout.cloud.min.js＼"></script>

<script>
　　var data = %@;
var width = 600,
height = 400,
fill = d3.scale.category20(),
maxcount = d3.max(data, function(d){ return d.count; } ),
wordcount = data.map(function(d) { return {text: d.word, size: d.count / maxcount * 100}; });

d3.layout.cloud().size([width, height])
.words(wordcount)
.padding(5)
.rotate(function() { return ~~(Math.random() * 2) * 90; })
.font(＼"Impact＼")
.fontSize(function(d) { return d.size; })
.on(＼"end＼", draw)
.start();

function draw(words) {
d3.select(＼"body＼").append(＼"svg＼")
.attr({
＼"width＼": width,
＼"height＼": height
})
.append(＼"g＼")
.attr(＼"transform＼", ＼"translate(＼" + [ width >> 1, height >> 1 ] + ＼")＼")
.selectAll(＼"text＼")
.data(words)
.enter()
.append(＼"text＼")
.style({
＼"font-size＼": function(d) { return d.size + ＼"px＼"; },
＼"font-family＼": ＼"Impact＼",
＼"fill＼": function(d, i) { return fill(i); }
})
.attr({
＼"text-anchor＼": ＼"middle＼",
＼"transform＼": function(d) { return ＼"translate(＼" + [d.x, d.y] + ＼")rotate(＼" + d.rotate + ＼")＼"; }
})
.text(function(d) { return d.text; });
}
</script>
</body>
</html>"

set aString to current application’s NSString’s stringWithFormat_(myStr, jsonStr) as string

set paramObj to {myMessage:"D3 Test", mySubMessage:"This is a d3-cloud word cloud test", htmlStr:aString}
–my browseStrWebContents:paramObj–for debug
my performSelectorOnMainThread:"browseStrWebContents:" withObject:(paramObj) waitUntilDone:true

on browseStrWebContents:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set htmlString to (htmlStr of paramObj)
　　
　　set aWidth to 620
　　set aHeight to 420
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定HTML内のJavaScriptをFetch
　　set jsSource to pickUpFromToStr(htmlString, "<script>", "</script>") of me
　　
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　using terms from scripting additions
　　　　set bURL to |NSURL|’s fileURLWithPath:(POSIX path of (path to me))
　　end using terms from
　　aWebView’s loadHTMLString:htmlString baseURL:(bURL)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　–its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aWebView
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　if (my returnCode as number) = 1001 then error number -128
end browseStrWebContents:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

on fetchJSSourceString(aURL)
　　set jsURL to |NSURL|’s URLWithString:aURL
　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　return jsSourceString
end fetchJSSourceString

on pickUpFromToStr(aStr as string, s1Str as string, s2Str as string)
　　set a1Offset to offset of s1Str in aStr
　　if a1Offset = 0 then return false
　　set bStr to text (a1Offset + (length of s1Str)) thru -1 of aStr
　　set a2Offset to offset of s2Str in bStr
　　if a2Offset = 0 then return false
　　set cStr to text 1 thru (a2Offset – (length of s2Str)) of bStr
　　return cStr as string
end pickUpFromToStr

–リストを任意のデリミタ付きでテキストに
on retArrowText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retArrowText

on array2DToJSONArray(aList)
　　set anArray to NSMutableArray’s arrayWithArray:aList
　　set jsonData to NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value) –0 is
　　set resString to current application’s NSString’s alloc()’s initWithData:jsonData encoding:(current application’s NSUTF8StringEncoding)
　　return resString
end array2DToJSONArray

on parseByDelim(aData, aDelim)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set dList to text items of aData
　　set AppleScript’s text item delimiters to curDelim
　　return dList
end parseByDelim

★Click Here to Open This Script　

(Visited 175 times, 1 visits today)

Pagesで最前面の書類中のテキストアイテムの文字サイズが最大のもののテキストを求める

Posted on 6月 12, 2020 by Takaaki Naganoya

Pagesでオープン中の最前面の書類から、最大文字サイズのテキストアイテム（文字ボックス）のテキストを抽出するAppleScriptです。

Pagesでは、本文にテキストをベタ打ちしつつ、文字スタイルを適用していくワープロ的な作り方と、ボックスでテキストアイテムを配置して文字を入れていくDTP的な（？）作り方の２通りがあります（混在できます）。

ここでは、ボックスでテキストアイテムを配置して作っています。

AppleScript名：最前面の書類中のテキストアイテムの文字サイズが最大のもののテキストを求める.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/12
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSMutableArray : a reference to current application’s NSMutableArray

tell application "Pages"
　　tell front document
　　　　set tmpList to every text item
　　　　if length of tmpList = 0 then return –テキストアイテムがない場合には処理終了
　　　　
　　　　set szList to size of object text of every text item
　　　　set aMaxPoint to calcMax(szList) of me –最大の文字サイズを取得
　　　　
　　　　–文字サイズが最大のテキストアイテムを抽出
　　　　set resList to object text of every text item whose size of object text is aMaxPoint
　　　　–> {"AppleScript"}
　　end tell
end tell

on calcMax(aList as list)
　　set nArray to (NSMutableArray’s arrayWithArray:aList)
　　set maxRes to (nArray’s valueForKeyPath:"@max.self")’s doubleValue()
　　return maxRes
end calcMax

★Click Here to Open This Script　

(Visited 44 times, 1 visits today)

Pagesで書類中の最大文字サイズのパラグラフのテキストを抽出

Posted on 6月 12, 2020 by Takaaki Naganoya

Pagesでオープン中の最前面の書類から、最大文字サイズのパラグラフ（段落）のテキストを抽出するAppleScriptです。

Pages v10.0で縦組みのテキスト中心の書類を作っていて、そのタイトルに該当する部分のテキストを抽出したいと考えておりました。

ここでは、本文テキストベタ打ちで作っています。

本来であれば、各パラグラフに指定されたスタイルの名称を取得して、スタイル名が「タイトル」だったらタイトルと判定するのが他のアプリケーションでの処理ですが、Pagesにはスタイル名を取得する機能はありません。

そこで、書類中の全パラグラフの文字サイズを取得し、その最大値を求め、最大値の文字サイズを持つパラグラフを求めるようにしてみました。

こういう（↑）文字ボックスを配置して作成した書類では、本Scriptのアプローチではタイトルを取得できません。

AppleScript名：書類中の最大文字サイズのパラグラフのテキストを抽出.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/12
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSMutableArray : a reference to current application’s NSMutableArray

tell application "Pages"
　　tell front document
　　　　tell body text
　　　　　　–フォントサイズのみパラグラフ単位に取得
　　　　　　set szList to size of every paragraph
　　　　　　set aMaxPoint to calcMax(szList) of me –最大の文字サイズを取得
　　　　　　
　　　　　　–文字サイズが最大のパラグラフを抽出
　　　　　　set resList to every paragraph whose size is aMaxPoint
　　　　　　–> {"テクノロジーが色彩（カラー）を決定している例は？"}
　　　　end tell
　　end tell
end tell

on calcMax(aList as list)
　　set nArray to (NSMutableArray’s arrayWithArray:aList)
　　set maxRes to (nArray’s valueForKeyPath:"@max.self")’s doubleValue()
　　return maxRes
end calcMax

★Click Here to Open This Script　

(Visited 272 times, 1 visits today)

クリップボード内のテキストをSayコマンドで読み上げて音声ファイル化

Posted on 5月 27, 2020 by Takaaki Naganoya

読み上げ対象のテキストをコピーした状態で実行するAppleScriptです。クリップボード内のテキストをSayコマンドで読み上げて、音声ファイルにレンダリングします。出力後、読み上げ所要時間を出力ファイルから求めてダイアログ表示します。

音声レンダリング処理は実際の音声読み上げ処理よりも短い時間で完了します。

–> Downlad Script With library within its bundle

掲載のリストを実行しても、スライダー入力ライブラリが含まれていないため、そのままでは実行できません。↑のScriptをまるごとダウンロードして展開すると、ライブラリ入りのScriptになります。実行にはダウンロードしたScriptをご利用ください。プログラムリスト掲載は参考のために行なっているものです。

▲ステップ１：念のために、読み上げ対象テキストをダイアログ表示

▲ステップ２：読み上げ時の速度をスライダーで選択

▲ステップ３：読み上げ音声を選択

▲ステップ４：読み上げ所要時間をダイアログ表示

▲ステップ５：音声レンダリングしたファイルをQuickTime Playerでオープン

AppleScript名：クリップボード内のテキストをSayコマンドで読み上げて音声ファイル化.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/27
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "AVFoundation"
use scripting additions
use slLib : script "sliderLib"

property |NSURL| : a reference to current application’s |NSURL|
property NSDate : a reference to current application’s NSDate
property NSUUID : a reference to current application’s NSUUID
property NSFileManager : a reference to current application’s NSFileManager
property AVAudioPlayer : a reference to current application’s AVAudioPlayer
property NSDateFormatter : a reference to current application’s NSDateFormatter
property NSSpeechSynthesizer : a reference to current application’s NSSpeechSynthesizer

set aInfo to clipboard info
set uCount to (clipboard info for Unicode text)
if uCount = {} then
　　display dialog "There is no text information in the clipboard" with title "Terminate information" buttons {"OK"} default button 1 with icon 2
　　return
end if

set totalCount to item 2 of item 1 of uCount

set aStr to the clipboard as text

–読み上げ内容の確認
display dialog aStr with title "Text length:" & (uCount as string) & " chars."

–読み上げ速度をSliderで入力
set rRes to slLib’s chooseBySlider(180, 220, "Select TTS reading pitch (small number:slow)")

–読み上げTTSキャラクタの選択
set aLoc to (current application’s NSLocale’s currentLocale()’s identifier()) as string –>　　"ja_JP"
set vList to getTTSVoiceNameWithLanguage(aLoc) of me
set vRes to choose from list vList with prompt ("Select TTS Voice in your language :" & aLoc) without empty selection allowed
if vRes = false then return

set vCharacter to contents of first item of vRes

–音声ファイルの作成先パスを求める
set aUUID to NSUUID’s UUID()’s UUIDString() as string
set aPath to (((path to movies folder) as string) & aUUID & ".aif")
set aPOSIX to POSIX path of aPath

–音声レンダリング
tell current application
　　say aStr using vCharacter saving to (aPOSIX) speaking rate rRes without waiting until completion
end tell

–レンダリングした音声の読み上げ所要時間を計算
set aDur to getDuration(aPath as alias) of me

–レンダリングした音声ファイルをオープン
tell application "QuickTime Player"
　　open aPath
end tell

–完了報告
display dialog "読み上げ所要時間：" & my formatHMS(aDur)

on getTTSVoiceNameWithLanguage(voiceLang)
　　set outArray to current application’s NSMutableArray’s new()
　　
　　set aList to NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceLocaleIdentifier == %@", voiceLang)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceName") as list
　　
　　return aResList
end getTTSVoiceNameWithLanguage

on getDuration(aFile)
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　
　　repeat 1000 times
　　　　set aAudioPlayer to AVAudioPlayer’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　　　set aRes to aAudioPlayer’s prepareToPlay()
　　　　if aRes as boolean = true then exit repeat
　　　　delay 0.5
　　end repeat
　　
　　set channelCount to aAudioPlayer’s numberOfChannels()
　　set aDuration to aAudioPlayer’s duration()
　　return aDuration as real
end getDuration

on retAvailableTTSnames()
　　set outList to {}
　　
　　set aList to NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aInfo to (NSSpeechSynthesizer’s attributesForVoice:j)
　　　　set aInfoRec to aInfo as record
　　　　set aName to VoiceName of aInfoRec
　　　　set the end of outList to aName
　　end repeat
　　
　　return outList
end retAvailableTTSnames

on formatHMS(aTime)
　　set aDate to NSDate’s dateWithTimeIntervalSince1970:aTime
　　set aFormatter to NSDateFormatter’s alloc()’s init()
　　
　　—This formatter text is localized in Japanese.
　　if aTime < hours then
　　　　aFormatter’s setDateFormat:"mm分ss秒"
　　else if aTime < days then
　　　　aFormatter’s setDateFormat:"HH時間mm分ss秒"
　　else
　　　　aFormatter’s setDateFormat:"DD日HH時間mm分ss秒"
　　end if
　　
　　set timeStr to (aFormatter’s stringFromDate:aDate) as string
　　return timeStr
end formatHMS

★Click Here to Open This Script　

(Visited 171 times, 2 visits today)

指定のドメインのIPアドレスを指定DNSで引いて返す

Posted on 5月 26, 2020 by Takaaki Naganoya

指定のドメインのIPアドレスを、指定のDNSサーバーで引いて結果を返すAppleScriptです。

DNS系のFramework（Objective-Cで書いてあるもの）はいろいろためしてみたものの、不思議とどれも動作が重くて、このようにshell commandを呼び出したほうが手軽で高速でした。

＃　うまく動いていなかったために遅かった、というのが正確なところかも。タイムアウトエラーを起こして処理が完了しないものばかりだったので、、、書き換えがうまく行っていなかった可能性が50％以上あります

nslookupの結果を取り出すためにいろいろやっていますが、ありもののルーチンを引っ張り出して加工してしているだけです。

apple.comのように、CDNサービスを利用してアクセス負荷分散を行なっているようなドメインだと、問い合わせごとにIPアドレスが変わるようです。

一方で、piyocast.comのように固定ホスト（バーチャルホストではありますが）で細々とホスティングしているようなドメインでは、IPアドレスが毎回変わるということはありません。

AppleScript名：指定のドメインのIPアドレスを指定DNSで引いて返す v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/25
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSScanner : a reference to current application’s NSScanner
property NSMutableArray : a reference to current application’s NSMutableArray

set aDomain to "apple.com"
set aDNS to "8.8.4.4"
set dnRes to getIPAddress(aDomain, aDNS) of me
–> {serverName:"apple.com", serverAddr:{"17.172.224.47", "17.178.96.59", "17.142.160.59"}}–CDNの影響でアドレスが頻繁に変わる？

set dnRes to getIPAddress("piyocast.com", aDNS) of me
–> {serverName:"piyocast.com", serverAddr:{"157.112.183.74"}}

on getIPAddress(aDomain, aDNS)
　　set searchStr to "answer:"
　　
　　using terms from scripting additions
　　　　set aRes to do shell script ("nslookup " & aDomain & " " & aDNS)
　　　　set bRes to offset of searchStr in aRes
　　end using terms from
　　
　　if bRes = 0 then return false
　　
　　set cRes to text (bRes + (length of searchStr) + 1) thru -1 of aRes
　　
　　set adRes1 to extractStrFromTo(cRes, "Name:", return) of me
　　set adRes2 to extractStrFromTo(cRes, "Address:", return) of me
　　
　　set outList to {}
　　set erList to {}
　　repeat with i from 1 to (length of adRes2)
　　　　set j1 to contents of (item i of adRes1)
　　　　set j2 to contents of (item i of adRes2)
　　　　if j1 is equal to aDomain then
　　　　　　set the end of outList to j2
　　　　else
　　　　　　set the end of erList to {j1, j2}
　　　　end if
　　end repeat
　　
　　return {serverName:j1, serverAddr:outList}
end getIPAddress

–offset命令の実行を横取りして高速実行(x2.5 faster)
on offset of searchStr in str
　　set aRes to getOffset(str, searchStr) of me
　　return aRes
end offset

on getOffset(str, searchStr)
　　set d to divideBy(str, searchStr)
　　if (count d) is less than 2 then return 0
　　return (length of item 1 of d) + 1
end getOffset

on divideBy(str, separator)
　　set delSave to AppleScript’s text item delimiters
　　set the AppleScript’s text item delimiters to separator
　　set strItems to every text item of str
　　set the AppleScript’s text item delimiters to delSave
　　return strItems
end divideBy

–指定文字と終了文字に囲まれた内容を抽出
on extractStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to NSScanner’s scannerWithString:aParamStr
　　set anArray to NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(reference)
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(reference)
　　　　if theValue is missing value then set theValue to "" –>追加
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　return (anArray as list)
end extractStrFromTo

★Click Here to Open This Script　

(Visited 42 times, 1 visits today)

クリップボード内の文字種別を集計して円グラフ表示

Posted on 5月 16, 2020 by Takaaki Naganoya

クリップボード内に文字列が入っていれば、いいかえれば「文字列をコピーした状態であれば」、クリップボード内容をテキストとして取り出して文字種別ごとに集計して構成比を円グラフで表示するAppleScriptです。

# CAUTION: This script process Japanese characters. So, this script make no sense for other language users

グラフ表示部分は手抜きでGoogle Chartsを呼び出しているだけなので、Macがネットワークに接続されていない場合には表示できません。

macOS標準装備のScript Menuに入れて使っています。複数の円グラフを表示させることも可能なので、典型的な例文（新聞、論文、なろう系、技術系文章、文学作品）のグラフを一覧表示して、どの例文の使用比率に近いかといったことを見てわかるようにできそうです（やらないけど）。

ありものをただ引っ張り出してきて、Script文でつないだだけなので、オリジナルで記述した部分はほとんどありません。

とはいえ、技術的にはいろいろなハードルを乗り越えまくって動かしているものでもあります。

・メインスレッドでしか動かせないWkWebView、NSAlertをScriptから呼び出している（実行環境に左右されずに実行）
・Cocoa Scriptingを行うAppleScriptObjCをscript文でscript object化して（カプセル化して）呼び出し、再利用
・WkWebViewをdialog内に表示して、マウスオーバーでデータ内容が見えるようなインタラクティブなグラフを表示

といった、いろいろ無茶なことをやっているScriptです。ただ、すでに見慣れた光景になりつつありますけれども。

AppleScript名：クリップボード内の文字種別を集計して円グラフ表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/14
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSAlert : a reference to current application’s NSAlert
property NSString : a reference to current application’s NSString
property NSButton : a reference to current application’s NSButton
property WKWebView : a reference to current application’s WKWebView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property WKUserContentController : a reference to current application’s WKUserContentController
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property NSScreenSaverWindowLevel : a reference to current application’s NSScreenSaverWindowLevel
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property returnCode : 0

–Calc Clipboard
set aRes to clipAnaliticsMain() of clipboardInfoKit
if aRes = false then return —クリップボードが空だった（文字列的に）

set totalC to totalC of aRes

set aList to {{"文字種別", "構成比"}} & rating of aRes

set aJsonArrayStr to array2DToJSONArray(aList) of me

–Pie Chart Template HTML
set myStr to "<!DOCTYPE html>
<html lang=＼"UTF-8＼">
<body>
<div id=＼"piechart＼"></div>

// Draw the chart and set the chart values
function drawChart() {
var data = google.visualization.arrayToDataTable(%@);

// Optional; add a title and set the width and height of the chart
var options = {
is3D: true,
　　 ’width’:600, ’height’:400
};

// Display the chart inside the <div> element with id=＼"piechart＼"
var chart = new google.visualization.PieChart(document.getElementById(’piechart’));
chart.draw(data, options);
}
</script>

</body>
</html>"

set aString to current application’s NSString’s stringWithFormat_(myStr, aJsonArrayStr) as string

set paramObj to {myMessage:"文字種別構成比", mySubMessage:"クリップボードの内容を集計。文字数は" & (totalC as string) & "文字", htmlStr:aString}
–my browseStrWebContents:paramObj–for debug
my performSelectorOnMainThread:"browseStrWebContents:" withObject:(paramObj) waitUntilDone:true

on browseStrWebContents:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set htmlString to (htmlStr of paramObj)
　　
　　set aWidth to 600
　　set aHeight to 450
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定HTML内のJavaScriptをFetch
　　set jsSource to pickUpFromToStr(htmlString, "<script type=＼"text/javascript＼">", "</script>") of me
　　
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 100)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s fileURLWithPath:(POSIX path of (path to me))
　　aWebView’s loadHTMLString:htmlString baseURL:(bURL)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　–its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aWebView
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setLevel:(NSScreenSaverWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　if (my returnCode as number) = 1001 then error number -128
end browseStrWebContents:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

on array2DToJSONArray(aList)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　set jsonData to current application’s NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value) –0 is
　　set resString to current application’s NSString’s alloc()’s initWithData:jsonData encoding:(current application’s NSUTF8StringEncoding)
　　return resString
end array2DToJSONArray

script clipboardInfoKit
　　use scripting additions
　　use framework "Foundation"
　　property parent : AppleScript
　　
　　property NSString : a reference to current application’s NSString
　　property NSNumber : a reference to current application’s NSNumber
　　property NSDictionary : a reference to current application’s NSDictionary
　　property NSCountedSet : a reference to current application’s NSCountedSet
　　property NSCharacterSet : a reference to current application’s NSCharacterSet
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSNumberFormatter : a reference to current application’s NSNumberFormatter
　　property NSRegularExpressionSearch : a reference to current application’s NSRegularExpressionSearch
　　property NSNumberFormatterRoundUp : a reference to current application’s NSNumberFormatterRoundUp
　　property NSNumberFormatterRoundDown : a reference to current application’s NSNumberFormatterRoundDown
　　
　　
　　on clipAnaliticsMain()
　　　　set cCount to 0
　　　　set hCount to 0
　　　　set kCount to 0
　　　　set oCount to 0
　　　　set tCount to 0
　　　　
　　　　using terms from scripting additions
　　　　　　set aStr to (the clipboard as «class utf8»)
　　　　　　if aStr = "" then
　　　　　　　　display dialog "No text data in clipboard" buttons {"OK"} default button 1
　　　　　　　　return false
　　　　　　end if
　　　　end using terms from
　　　　
　　　　set aRec to detectCharKindRating(aStr) of me
　　　　
　　　　set cCount to cCount + (kanjiNum of aRec)
　　　　set hCount to hCount + (hiraganaNum of aRec)
　　　　set kCount to kCount + (katakanaNum of aRec)
　　　　set oCount to oCount + (otherNum of aRec)
　　　　set tCount to tCount + (totalCount of aRec)
　　　　
　　　　return {rating:{{"漢字", cCount}, {"ひらがな", hCount}, {"カタカナ", kCount}, {"その他", oCount}}, totalC:tCount}
　　end clipAnaliticsMain
　　
　　
　　
　　on detectCharKindRating(aStr as string)
　　　　set aList to NSMutableArray’s arrayWithArray:(characters of aStr)
　　　　set theCountedSet to NSCountedSet’s alloc()’s initWithArray:aList
　　　　set theEnumerator to theCountedSet’s objectEnumerator()
　　　　
　　　　set cCount to 0
　　　　set hCount to 0
　　　　set kCount to 0
　　　　set oCount to 0
　　　　set totalC to length of aStr
　　　　
　　　　repeat
　　　　　　set aValue to theEnumerator’s nextObject()
　　　　　　if aValue is missing value then exit repeat
　　　　　　
　　　　　　set aStr to aValue as string
　　　　　　set tmpCount to (theCountedSet’s countForObject:aValue)
　　　　　　
　　　　　　set s1Res to chkKanji(aStr) of me
　　　　　　set s2Res to chkKatakana(aStr) of me
　　　　　　set s3Res to chkHiragana(aStr) of me
　　　　　　
　　　　　　if s1Res = true then
　　　　　　　　set cCount to cCount + tmpCount
　　　　　　else if s2Res = true then
　　　　　　　　set kCount to kCount + tmpCount
　　　　　　else if s3Res = true then
　　　　　　　　set hCount to hCount + tmpCount
　　　　　　else
　　　　　　　　set oCount to oCount + tmpCount
　　　　　　end if
　　　　end repeat
　　　　
　　　　set ckRes to roundingUp((cCount / totalC) * 100, 1) of me
　　　　set kkRes to roundingUp((kCount / totalC) * 100, 1) of me
　　　　set hgRes to roundingUp((hCount / totalC) * 100, 1) of me
　　　　set otRes to roundingUp((oCount / totalC) * 100, 1) of me
　　　　
　　　　return {kanjiNum:cCount, kanjiRating:ckRes, hiraganaNum:hCount, hiraganaRating:hgRes, katakanaNum:kCount, katakanaRating:kkRes, otherNum:oCount, otherRating:otRes, totalCount:totalC}
　　end detectCharKindRating
　　
　　
　　on chkKanji(aChar)
　　　　return detectCharKind(aChar, "[一-龠]") of me
　　end chkKanji
　　
　　on chkHiragana(aChar)
　　　　return detectCharKind(aChar, "[ぁ-ん]") of me
　　end chkHiragana
　　
　　on chkKatakana(aChar)
　　　　return detectCharKind(aChar, "[ァ-ヶ]") of me
　　end chkKatakana
　　
　　on detectCharKind(aChar, aPattern)
　　　　set aChar to NSString’s stringWithString:aChar
　　　　set searchStr to NSString’s stringWithString:aPattern
　　　　set matchRes to aChar’s rangeOfString:searchStr options:(NSRegularExpressionSearch)
　　　　if matchRes’s location() = (current application’s NSNotFound) or (matchRes’s location() as number) > 9.99999999E+8 then
　　　　　　return false
　　　　else
　　　　　　return true
　　　　end if
　　end detectCharKind
　　
　　on roundingUp(aNum, aDigit as integer)
　　　　set a to aNum as real
　　　　set aFormatter to NSNumberFormatter’s alloc()’s init()
　　　　aFormatter’s setMaximumFractionDigits:aDigit
　　　　aFormatter’s setRoundingMode:(NSNumberFormatterRoundUp)
　　　　set aStr to aFormatter’s stringFromNumber:(NSNumber’s numberWithFloat:a)
　　　　return (aStr as text) as real
　　end roundingUp
end script

★Click Here to Open This Script　

(Visited 56 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

Posted on 12月 24, 2019 by Takaaki Naganoya

検索フィールドつきのTable View表示ダイアログを表示するAppleScriptです。項目選択を行う簡易ユーザーインタフェース（ダイアログ）で、選択肢の数が多い場合に備えて項目のキーワード抽出機能を付加したものです。

サーチフィールドの実装は無理かと思っていたのですが、単体でアラートダイアログ上に表示してみたら、予想外にキーボード入力イベントと検索語のクリアのイベントを簡単に拾えたので、Table Viewと組み合わせて試してみました。

AppleScript名：アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

— Created 2019-12-23 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSSearchField : a reference to current application’s NSSearchField
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 300
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　set aTextInput to makeNSSearchField(0, aHeight – 20, 300, 20) of me
　　　　
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 80, labelSortList) of me
　　　　
　　　　parentView’s setSubviews:{aTextInput, aScroll}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　–TextField
　　　　set aTextInput to makeNSSearchField(0, 0, 300, 20) of me
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on makeNSSearchField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer)
　　　　set aSearchF to NSSearchField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aSearchF’s setDelegate:(me)
　　　　return aSearchF
　　end makeNSSearchField
　　
　　
　　–検索クエリ入力時
　　on searchFieldDidStartSearching:(aField)
　　　　set aStr to (aField’s stringValue()) as string
　　　　set predicStr to "field1 contains[cd] ’" & aStr & "’ OR field3 contains[cd] ’" & aStr & "’"
　　　　set filteredArray to filterRecListByLabel1((my aDataList), predicStr) of me
　　　　set (my theDataSource) to filteredArray
　　　　tView’s reloadData()
　　end searchFieldDidStartSearching:
　　
　　
　　–Search Fieldの「x」ボタンを押したイベント
　　on searchFieldDidEndSearching:(aField)
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　tView’s reloadData()
　　end searchFieldDidEndSearching:
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出
　　on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　　　set aArray to NSMutableArray’s arrayWithArray:aRecList
　　　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　　　return filteredArray
　　end filterRecListByLabel1
　　
end script

★Click Here to Open This Script　

(Visited 99 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

Posted on 12月 23, 2019 by Takaaki Naganoya

アラートダイアログ上にTableViewを表示し、複数キーの組み合わせによって項目抽出。選択項目のデータを返すAppleScriptです。

あくまで試作品なので、あちらこちらに「お可愛らしい」実装が転がっています。NSBoxがまだまともに使いこなせていないあたりとか（Xcode上で部品として配置するのは楽勝ですが、プログラムから動的に生成して使用するのは別なので）。

抽出キー数は可変で外部から指定できるとよいのですが、本Scriptでは固定です。また、各抽出条件も外部から供給するのが本来あるべき姿ですが、ハードコーディングしています。

あと、TableViewの下側に謎の余白があるのは、めんどくさくなってそのまま放置しています。これで外部から各種パラメータを指定できるようにして、sdefつけて１命令で呼び出せるようにしておけば、レコード数の多い選択項目から条件抽出しつつ項目選択できてよいでしょう。

プログラム内容自体は、高度でもなければ高尚でもありません。実にダラダラとGUI部品のパラメータを設定しているだけです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

— Created 2019-12-22 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSBox : a reference to current application’s NSBox
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSPopUpButton : a reference to current application’s NSPopUpButton
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSCompoundPredicate : a reference to current application’s NSCompoundPredicate
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
　　
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　property aSel : 0
　　property bSel : 0
　　property cSel : 0
　　property predList : {}
　　property a1Button : missing value
　　property a2Button : missing value
　　property a3Button : missing value
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 400
　　　　set my aSel to 0
　　　　set my bSel to 0
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　
　　　　
　　　　–BOX Aをつくる
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 60, aWidth, 60)))
　　　　(aBox’s setTitle:("Filter Condition"))
　　　　
　　　　–このあたり、項目数に合わせてUIを可変で生成するように（本Scriptは試作品なので、決め打ちでUI生成）
　　　　set a1Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 200, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:{"▼Select Item", "MacBook", "iMac", "mini", "Air", "Pro"})
　　　　a1Button’s setTarget:(me)
　　　　a1Button’s setAction:("mySelector:")
　　　　a1Button’s setEnabled:(true)
　　　　
　　　　set a2Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(220, 0, 200, 30)) pullsDown:false)
　　　　a2Button’s removeAllItems()
　　　　(a2Button’s addItemsWithTitles:{"▼Select Item", "150000", "200000", "300000", "400000", "600000"})
　　　　a2Button’s setTarget:(me)
　　　　a2Button’s setAction:("mySelector:")
　　　　a2Button’s setEnabled:(true)
　　　　
　　　　set a3Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(440, 0, 200, 30)) pullsDown:false)
　　　　a3Button’s removeAllItems()
　　　　(a3Button’s addItemsWithTitles:{"▼Select Item", "デュアルコア", "クアッドコア", "6コア", "8コア"})
　　　　a3Button’s setTarget:(me)
　　　　a3Button’s setAction:("mySelector:")
　　　　a3Button’s setEnabled:(true)
　　　　
　　　　
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s addSubview:a2Button)
　　　　(aBox’s addSubview:a3Button)
　　　　
　　　　
　　　　–BOX Bをつくる
　　　　set bBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 80)))
　　　　(bBox’s setTitle:("Data"))
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 150, labelSortList) of me
　　　　
　　　　(bBox’s addSubview:aScroll)
　　　　
　　　　parentView’s setSubviews:{aBox, bBox}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on mySelector:aObject
　　　　set aIndex to (aObject’s indexOfSelectedItem()) as number
　　　　filterByMultipleCondition() of me
　　end mySelector:
　　
　　
　　
　　on filterByMultipleCondition()
　　　　set prediCatesArray to {}
　　　　
　　　　set aInd to (my a1Button’s indexOfSelectedItem()) as number
　　　　set bInd to (my a2Button’s indexOfSelectedItem()) as number
　　　　set cInd to (my a3Button’s indexOfSelectedItem()) as number
　　　　
　　　　if {aInd, bInd, cInd} = {0, 0, 0} then
　　　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　　　tView’s reloadData()
　　　　　　return
　　　　end if
　　　　
　　　　–このあたり、複数条件をハードコーディングしているのは超絶頭悪い。項目数の増減に対応できるべき
　　　　if aInd > 0 then
　　　　　　set aTitle to (my a1Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field1 contains ’" & aTitle & "’"
　　　　end if
　　　　
　　　　if bInd > 0 then
　　　　　　set bTitle to (my a2Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field2.integerValue < " & bTitle
　　　　end if
　　　　
　　　　if cInd > 0 then
　　　　　　set cTitle to (my a3Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field3 contains ’" & cTitle & "’"
　　　　end if
　　　　
　　　　–データ抽出
　　　　set tmpList to filterDictArrayByLabel3((my aDataList), prediCatesArray) of me
　　　　
　　　　–データ再表示
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(tmpList)
　　　　tView’s reloadData()
　　end filterByMultipleCondition
　　
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出（複数PredicatesをANDで合成）
　　on filterDictArrayByLabel3(origArray as list, aPredicateList as list)
　　　　set aArray to NSMutableArray’s arrayWithArray:origArray
　　　　set predArray to NSMutableArray’s new()
　　　　
　　　　repeat with i in aPredicateList
　　　　　　(predArray’s addObject:(NSPredicate’s predicateWithFormat:(contents of i)))
　　　　end repeat
　　　　
　　　　set pred to current application’s NSCompoundPredicate’s andPredicateWithSubpredicates:predArray
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:pred
　　　　
　　　　return filteredArray
　　end filterDictArrayByLabel3
end script

★Click Here to Open This Script　

(Visited 104 times, 1 visits today)

iTunes Libraryの再生回数をジャンルごとに集計、ジャンル名名寄せ付き

Posted on 12月 2, 2019 by Takaaki Naganoya

iTunesLibrary.framework経由でiTunes/Music.appのライブラリのジャンルごとの再生回数を集計するAppleScriptです。

7,000曲程度入っているライブラリで、ジャンル名の名寄せも含め、開発環境（MacBook Pro Retina 2012, Core i7 2.66GHz@macOS 10.14.6）で0.7秒程度で終了します。2,500曲程度入っているMac mini 2014 Core i5 2.6GHz@macOS 10.15.1で0.6秒程度です。

macOS 10.14まで（iTunes.app）と、macOS 10.15以降（Music.app）でも同様にiTunesLibrary.framework経由でライブラリへのアクセスが行えます。

AppleScript名：iTunes Libraryの再生回数をジャンルごとに集計、ジャンル名名寄せ付き

— Created 2019-11-10 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "iTunesLibrary"
–https://developer.apple.com/reference/ituneslibrary/itlibmediaitem?language=objc

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSScanner : a reference to current application’s NSScanner
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor
property NSMutableCharacterSet : a reference to current application’s NSMutableCharacterSet

–ジャンル名寄せリスト（2要素から構成される2D List）
set genreNayoseList to {{"World", "ワールド"}, {"Anime", "アニメ"}, {"Electronic", "エレクトロニック"}, {"R&B/ソウル", "R&B／ソウル"}, {"Kayokyoku", "歌謡曲"}, {"Electronic", "エレクトロニック"}, {"Vocal", "ヴォーカル"}, {"Classical", "クラシック"}, {"Dance", "ダンス"}, {"Soundtrack", "サウンドトラック"}, {"Rock", "ロック"}}

set library to current application’s ITLibrary’s libraryWithAPIVersion:"1.0" |error|:(missing value)
if library is equal to missing value then return

set aRes1 to (library’s applicationVersion()) as string –>　　"12.10.1.37" @ macOS 10.15
set aRes2 to (library’s apiMinorVersion()) –> 1
set aRes3 to (library’s apiMajorVersion()) –> 1

set playLists to library’s allPlaylists()
set gArray to library’s allMediaItems()’s genre
set aRes to countItemsByItsAppearance(gArray) of me

set bRes to genreNayoseAndUnify(aRes, genreNayoseList) of me
–> {{genreName:"サウンドトラック", numberOfTimes:1965}, {numberOfTimes:1209, genreName:"Podcast"}, {genreName:"ロック", numberOfTimes:1128}, {genreName:"クラシック", numberOfTimes:705}, {numberOfTimes:517, genreName:"ポップ"}, {genreName:"アニメ", numberOfTimes:533}, {numberOfTimes:383, genreName:"J-Pop"}, {numberOfTimes:292, genreName:"Pop"}, {numberOfTimes:279, genreName:"社会／文化"}, {numberOfTimes:252, genreName:missing value}, {genreName:"ワールド", numberOfTimes:246}, {numberOfTimes:187, genreName:"ジャズ"}, {genreName:"エレクトロニック", numberOfTimes:168}, {numberOfTimes:125, genreName:"R&B"}, {numberOfTimes:104, genreName:"ニューエイジ"}, {numberOfTimes:81, genreName:"Unclassifiable"}, {genreName:"歌謡曲", numberOfTimes:60}, {numberOfTimes:57, genreName:"Children’s"}, {numberOfTimes:54, genreName:"オルタナティブ"}, {numberOfTimes:38, genreName:"Holiday"}, {numberOfTimes:32, genreName:"Data"}, {numberOfTimes:31, genreName:"イージーリスニング"}, {genreName:"ヴォーカル", numberOfTimes:31}, {numberOfTimes:19, genreName:"iTunes U"}, {numberOfTimes:17, genreName:"フォーク"}, {numberOfTimes:15, genreName:"ブルース"}, {numberOfTimes:15, genreName:"ディズニー"}, {numberOfTimes:15, genreName:"シンガーソングライター"}, {numberOfTimes:14, genreName:"Easy Listening"}, {numberOfTimes:14, genreName:"ラテン"}, {numberOfTimes:14, genreName:"Electronica/Dance"}, {numberOfTimes:14, genreName:"個人ジャーナル"}, {genreName:"ダンス", numberOfTimes:12}, {numberOfTimes:10, genreName:"アクション／アドベンチャー"}, {numberOfTimes:9, genreName:"J-POP"}, {numberOfTimes:9, genreName:"New Age"}, {numberOfTimes:7, genreName:"演歌"}, {numberOfTimes:6, genreName:"少年"}, {numberOfTimes:6, genreName:"青年"}, {numberOfTimes:6, genreName:"キッズ／ファミリー"}, {numberOfTimes:5, genreName:"Video"}, {numberOfTimes:5, genreName:"プログラミング"}, {numberOfTimes:4, genreName:"ホリデー"}, {numberOfTimes:4, genreName:"カントリー"}, {numberOfTimes:4, genreName:"科学／医学"}, {numberOfTimes:3, genreName:"ビジネス"}, {numberOfTimes:3, genreName:"コメディ"}, {numberOfTimes:3, genreName:"Game Music"}, {numberOfTimes:3, genreName:"Latin"}, {genreName:"R&B/ソウル", numberOfTimes:5}, {numberOfTimes:2, genreName:"#NIPPONSEI @ IRC.MIRCX.COM"}, {numberOfTimes:2, genreName:"Technology"}, {numberOfTimes:2, genreName:"ヒップホップ/ ラップ"}, {numberOfTimes:2, genreName:"ヒップホップ／ラップ"}, {numberOfTimes:2, genreName:"日本"}, {numberOfTimes:2, genreName:"ドラマ"}, {numberOfTimes:1, genreName:"社会科学"}, {numberOfTimes:1, genreName:"コンピュータ／テクノロジー"}, {numberOfTimes:1, genreName:"Tech ニュース"}, {numberOfTimes:1, genreName:"科学／自然"}, {numberOfTimes:1, genreName:"その他"}, {numberOfTimes:1, genreName:"児童書フィクション"}, {numberOfTimes:1, genreName:"レゲエ"}, {numberOfTimes:1, genreName:"Lifestyle & Home"}, {numberOfTimes:1, genreName:"ホリデーミュージック"}, {numberOfTimes:1, genreName:"マネジメント／リーダーシップ"}, {numberOfTimes:1, genreName:"インストゥルメンタル"}, {numberOfTimes:1, genreName:"SF／ファンタジー"}, {numberOfTimes:1, genreName:"146"}, {numberOfTimes:1, genreName:"健康／フィットネス"}, {numberOfTimes:1, genreName:"148"}, {numberOfTimes:1, genreName:"NHK FM(東京)"}, {numberOfTimes:1, genreName:"Seattle Pacific University – Latin"}, {numberOfTimes:1, genreName:"チルドレン・ミュージック"}, {numberOfTimes:1, genreName:"名作"}, {numberOfTimes:1, genreName:"Folk"}}

–ジャンルのリストを出現回数で集計
on countItemsByItsAppearance(aList)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bArray to NSMutableArray’s array()
　　set theEnumerator to aSet’s objectEnumerator()
　　
　　repeat
　　　　set aValue to theEnumerator’s nextObject()
　　　　if aValue is missing value then exit repeat
　　　　bArray’s addObject:(NSDictionary’s dictionaryWithObjects:{aValue, (aSet’s countForObject:aValue)} forKeys:{"genreName", "numberOfTimes"})
　　end repeat
　　
　　–出現回数（numberOfTimes）で降順ソート
　　set theDesc to NSSortDescriptor’s sortDescriptorWithKey:"numberOfTimes" ascending:false
　　bArray’s sortUsingDescriptors:{theDesc}
　　
　　return bArray as list
end countItemsByItsAppearance

on genreNayoseAndUnify(aList as list, genreNayoseList as list)
　　set gList to FlattenList(genreNayoseList) of me
　　
　　set didProc to {}
　　
　　set a2List to {}
　　
　　repeat with i in aList
　　　　set aGenre to genreName of i
　　　　
　　　　if (aGenre is in gList) and (aGenre is not in didProc) then
　　　　　　
　　　　　　repeat with ii in genreNayoseList
　　　　　　　　set jj to contents of ii
　　　　　　　　
　　　　　　　　if aGenre is in jj then
　　　　　　　　　　copy jj to {g1, g2}
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　if chkAlphabet(g1) of me = true then
　　　　　　　　　　　　set targG to g2
　　　　　　　　　　　　set targG2 to g1
　　　　　　　　　　else
　　　　　　　　　　　　set targG to g1
　　　　　　　　　　　　set targG2 to g2
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　set s1Res to searchByGenreName(aList, targG) of me
　　　　　　　　　　set s2Res to searchByGenreName(aList, targG2) of me
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　set s3Res to addMutipleLists({s1Res, s2Res}) of me
　　　　　　　　　　
　　　　　　　　　　set tmpClass to class of s3Res
　　　　　　　　　　if tmpClass = list then
　　　　　　　　　　　　set s3Res to contents of first item of s3Res
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　　　set outRec to {genreName:targG, numberOfTimes:s3Res}
　　　　　　　　　　set the end of didProc to g1
　　　　　　　　　　set the end of didProc to g2
　　　　　　　　　　
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　　　
　　　　　　end repeat
　　　　　　
　　　　　　set the end of a2List to outRec
　　　　else
　　　　　　if (aGenre is not in didProc) then
　　　　　　　　set the end of a2List to contents of i
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return a2List
end genreNayoseAndUnify

on searchByGenreName(aList as list, aGenreName as string)
　　set predicatesStr to "genreName == ’" & aGenreName & "’"
　　set anArray to (NSArray’s arrayWithArray:aList)
　　set aPred to (NSPredicate’s predicateWithFormat:predicatesStr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred)
　　if (bRes as list) = {} then return {}
　　
　　set bbRes to first item of bRes
　　return (numberOfTimes of bbRes) as list
end searchByGenreName

on addMutipleLists(s1List)
　　script spdAdd
　　　　property s1List : {}
　　　　property s3List : {}
　　end script
　　
　　copy s1List to (s1List of spdAdd) –init
　　
　　set s1Len to length of first item of (s1List of spdAdd)
　　set (s3List of spdAdd) to makeZero1DList(s1Len, 0) of me
　　
　　repeat with i in (s1List of spdAdd)
　　　　set tmpLen to length of i
　　　　if tmpLen is not equal to s1Len then return false
　　　　
　　　　repeat with ii from 1 to s1Len
　　　　　　set tmp1 to contents of item ii of (s3List of spdAdd)
　　　　　　set tmp2 to contents of item ii of i
　　　　　　
　　　　　　set item ii of (s3List of spdAdd) to (tmp1 + tmp2)
　　　　end repeat
　　end repeat
　　
　　return (s3List of spdAdd)
end addMutipleLists

–指定要素を指定回数追加したリストを作成する
on makeZero1DList(itemMax, itemElem)
　　set allData to {}
　　repeat itemMax times
　　　　set the end of allData to itemElem
　　end repeat
　　return allData
end makeZero1DList

–By Paul Berkowitz
–2009年1月27日 2:24:08:JST
–Re: Flattening Nested Lists
on FlattenList(aList)
　　set oldDelims to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to {"????"}
　　set aString to aList as text
　　set aList to text items of aString
　　set AppleScript’s text item delimiters to oldDelims
　　return aList
end FlattenList

— アルファベットのみか調べて返す
on chkAlphabet(checkString)
　　set aStr to NSString’s stringWithString:checkString
　　set allCharSet to NSMutableCharacterSet’s alloc()’s init()
　　allCharSet’s addCharactersInRange:(current application’s NSMakeRange(ASCII number of "a", 26))
　　allCharSet’s addCharactersInRange:(current application’s NSMakeRange(ASCII number of "A", 26))
　　set aBool to my chkCompareString:aStr baseString:allCharSet
　　return aBool as boolean
end chkAlphabet

on chkCompareString:checkString baseString:baseString
　　set aScanner to NSScanner’s localizedScannerWithString:checkString
　　aScanner’s setCharactersToBeSkipped:(missing value)
　　aScanner’s scanCharactersFromSet:baseString intoString:(missing value)
　　return (aScanner’s isAtEnd()) as boolean
end chkCompareString:baseString:

★Click Here to Open This Script　

(Visited 62 times, 1 visits today)

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

Posted on 11月 13, 2019 by Takaaki Naganoya

アラートダイアログ上に指定月のカレンダー１か月分を表示してユーザーの日付選択（複数可）をもとめるAppleScriptです。

NSDatePickerを用いて日付選択のダイアログを作っていたら、日付がとても小さくて現代のMacの画面解像度にとても合っておらず、もっと大きめのカレンダーで選択したいと考えて作ったものです。

（１）カレンダーの表示サイズを大型化

現代のMacの画面にNSDatePickerをそのまま表示すると、とても小さくて見ていられないので、表示サイズを自由に変えられるカレンダー選択部品を作ってみました。どれか１つの日付を選択するものではなく、複数の日付を選択して、リストで結果を返してきます。

▲画面上で見やすいようにカレンダー部品を大型化

（２）選択無効日指定

あらかじめ、日付選択の対象外とする日付を指定できるようにしました。

（３）過去日付の選択無効

過去の日付を表示・選択できないようにする指定です。

▲過去日付を無効に指定すると、現在日時よりも過去の日付は選択できない

（４）曜日を現在のLocale情報から変更

曜日に用いる文字列を現在のLocale情報から取得するようにしてみました。本来であれば、日曜日はじまり「ではない」カレンダーを用いている場所もあるので（香港とかフランスとか？）、どの曜日から表示開始するかを自由選択にしたいところですが、そこまでは作り込んでいません。

▲Localeに合わせた曜日が表示される（ただし、年/月は固定フォーマット）

実用性を考えれば、Calendar.appのように日付選択とスケジュール確認が行えるものが望ましいのですが、そこまで作り込む手間をかけるほどのものでもないですし、表示対象月の移動を行おうとしてclickイベントを拾いつつカレンダー再描画に失敗した「残骸」です。見た目はいいのに完成度がいまひとつというあたりが残念です。

AppleScript名：アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

— Created 2019-10-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSButton : a reference to current application’s NSButton
property NSOnState : a reference to current application’s NSOnState
property NSOffState : a reference to current application’s NSOffState
property NSTextField : a reference to current application’s NSTextField
property NSMutableArray : a reference to current application’s NSMutableArray
property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property theResult : 0
property returnCode : 0
property bArray : {} –Checkbox button object array

property tYear : 0
property tMonth : 0
property theAlert : missing value
property theView : missing value

on run
　　set tYear to 2019
　　set tMonth to 11
　　set ignoreP to true
　　set ndList to {2, 3, 4, 9, 10, 13, 16, 17, 23, 24, 25, 30} –選択表示させない日付
　　set paramObj to {myMessage:"", mySubMessage:"適切な日付を以下からえらんでください", targetYear:tYear, targetMonth:tMonth, nodisp:ndList, ignorePast:ignoreP}
　　
　　–Detect Past Date Error
　　set curDate to current date
　　set dLimit to getMlen(tYear, tMonth) of me
　　set tmpDate to getDateInternational(tYear, tMonth, dLimit) of me
　　if (tmpDate < curDate) and (ignoreP = true) then error (("Target month is past (" & tYear as string) & "/" & tMonth as string) & "/1 is past. Today is " & date string of curDate & ")"
　　
　　–my chooseItemByCheckBox:paramObj –for Debugging
　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　return my sort1DNumList:(my theResult) ascOrder:true
　　–> {1, 3, 5, 7, 9, 11}
end run

on chooseItemByCheckBox:(paramObj)
　　set aMainMes to (myMessage of paramObj) as string
　　set aSubMes to (mySubMessage of paramObj) as string
　　set aMatList to (matrixTitleList of paramObj) as list
　　set tYear to (targetYear of paramObj) as integer
　　set tMonth to (targetMonth of paramObj) as integer
　　set noDispList to (nodisp of paramObj) as list
　　set ignoreP to (ignorePast of paramObj) as boolean
　　
　　if aMainMes = "" then
　　　　set aMainMes to "日付を選択してください"
　　end if
　　
　　set theView to makeCalendarView(tYear, tMonth, noDispList, ignoreP) of me
　　
　　–Select the first radio button item
　　set my theResult to {}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　　　
　　　　–for Help Button
　　　　–its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　set aWin to its |window|()
　　end tell
　　
　　aWin’s setLevel:(current application’s NSFloatingWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end chooseItemByCheckBox:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to (tag of aParam) as integer
　　
　　–clicked
　　if aTag is not in (my theResult) then
　　　　set the end of (my theResult) to aTag
　　else
　　　　set theResult to my deleteItem:aTag fromList:theResult
　　end if
end clicked:

on deleteItem:anItem fromList:theList
　　set theArray to NSMutableArray’s arrayWithArray:theList
　　theArray’s removeObject:anItem
　　return theArray as list
end deleteItem:fromList:

–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DNumList:theList ascOrder:aBool
　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　return (sortedList) as list
end sort1DNumList:ascOrder:

–Help Button Clicked Event Handler
on alertShowHelp:aNotification
　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　set bRes to (button returned of aRes) as string
　　
　　if bRes = "All Off" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　end repeat
　　　　
　　else if bRes = "All On" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　set the end of theResult to i + 1
　　　　end repeat
　　end if
　　
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　set aVal2 to NSColor’s blackColor()
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　set aVal3 to aKerning
　　set akey3 to (NSKernAttributeName)
　　
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　set aVal5 to 2 –all ligature ON
　　set akey5 to (NSLigatureAttributeName)
　　
　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　set akey7 to (NSParagraphStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–指定月のカレンダーを1D List(7 days x 6 weeks) で返す
on retListCalendar(tYear, tMonth)
　　set mLen to getMlen(tYear, tMonth) of me
　　set aList to {}
　　
　　set fDat to getDateInternational(tYear, tMonth, 1) of me
　　tell current application
　　　　set aOffset to (weekday of fDat) as number
　　end tell
　　
　　–header gap
　　repeat (aOffset – 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　–calendar body
　　repeat with i from 1 to mLen
　　　　set the end of aList to (i as string)
　　end repeat
　　
　　–footer gap
　　repeat (42 – aOffset – mLen + 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　return aList
end retListCalendar

–現在のカレンダーで指定年月の日数を返す（国際化対応版）
on getMlen(aYear as integer, aMonth as integer)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar()
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　return |length| of theResult
end getMlen

–ローカライズされた曜日名称を返す
on getLocalizedDaynames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols() as list
　　return dayNames
end getLocalizedDaynames

–ローカライズされた月名称を返す

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSMutableArray

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

よみがなタグを削除

AMChartsで点滅ポイントつき世界地図をダイアログ上に表示 v2

アラートダイアログ上にWebViewでChart.jsを表示（Pie Chart） v2

アラートダイアログ上にd3-cloudを用いてワードクラウドを表示

クリップボード内のテキストをSayコマンドで読み上げて音声ファイル化

指定のドメインのIPアドレスを指定DNSで引いて返す

クリップボード内の文字種別を集計して円グラフ表示

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

（１）カレンダーの表示サイズを大型化

（２）選択無効日指定

（３）過去日付の選択無効

（４）曜日を現在のLocale情報から変更