アラートダイアログ上にCollection Viewを表示

Posted on 8月 24, 2020 by Takaaki Naganoya

emada2さんからの投稿です。Collection Viewの利用については、Kamenokoの開発時に導入検討したことがありますが、Objective-CのサンプルコードをAppleScriptに翻訳しきれなくて中途半端に放置していました。

まとまった形でCollection Viewのサンプルコードが出てきたのは、おそらくこれが初めてだと思います。ありがとうございます。

Collection Viewを箱庭ダイアログに乗せることができました。
でも残念なのは、itemPrototypeは10.14でDeprecatedになっているので将来的に長く使えないでしょう
その他のやり方を探してappleのサンプルコードをみたら、swift 3で書かれていているので10.14でビルドできませんでした。
なのでまだまだCollection Viewを使いこなすのは難しそうです😢

–> Download Script Bundle

@property (nullable, strong) NSCollectionViewItem *itemPrototype API_DEPRECATED("Use -registerNib:forItemWithIdentifier: or -registerClass:forItemWithIdentifier: instead.", macos(10.5,10.14));

AppleScript名：アラートダイアログ上にCollection Viewを表示

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "AppKit"
use framework "AppleScriptObjC"
use framework "CoreFoundation"
use framework "Foundation"
use scripting additions

on run
　　my testRun()
end run

on testRun()
　　set aMainMes to "アプリケーションの選択"
　　set aSubMes to "適切なものを以下からえらんでください"
　　
　　#ダイアログ内のビューサイズを指定
　　set aHeight to 384
　　set aWidth to 512 + 12 –> スクロールバーの分
　　
　　#アプリケーションフォルダ内のアプリケーションを取得
　　set aFolder to path to applications folder
　　set aPath to aFolder’s POSIX path
　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　
　　set filePaths to filePaths as list
　　set thisFileType to "com.apple.application-bundle"
　　
　　set dataSourceList to {}
　　repeat with anItem in filePaths
　　　　
　　　　set aPath to anItem’s contents’s POSIX path
　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　
　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　
　　　　if (aUTI as text) is thisFileType then
　　　　　　set iconImage to (current application’s NSWorkspace’s sharedWorkspace’s iconForFile:aPath)
　　　　　　set dict to {fileURL:aURL, icon:iconImage}
　　　　　　set dataSourceList’s end to dict
　　　　end if
　　end repeat
　　
　　set execButtonTitle to "OK😄"
　　
　　set dateObj to my chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
end testRun

on chooseItemByCollectionView:(aMainMes as text) subMes:(aSubMes as text) myWidth:(aWidth as integer) myHeight:(aHeight as integer) myDataSource:(dataSourceList as list) okTitle:(execButtonTitle as text)
　　
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　# subClasses.scptを呼び出す
　　set DialogCore to current application’s AppDelegate’s new()
　　set fRes to DialogCore’s chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
　　
　　if fRes is missing value then error number -128
　　return fRes as list
end chooseItemByCollectionView:subMes:myWidth:myHeight:myDataSource:okTitle:

★Click Here to Open This Script　

AppleScript名：subClasses

script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on applicationShouldTerminateAfterLastWindowClosed:sender
　　　　return true
　　end applicationShouldTerminateAfterLastWindowClosed:
　　
　　——————
　　
　　on applicationWillFinishLaunching:aNotification
　　　　log my testRun()
　　end applicationWillFinishLaunching:
　　
　　on testRun()
　　　　set aMainMes to "アプリケーションの選択"
　　　　set aSubMes to "適切なものを以下からえらんでください"
　　　　
　　　　#ダイアログ内のビューサイズを指定
　　　　set aHeight to 384
　　　　set aWidth to 512 + 12 –> スクロールバーの分
　　　　
　　　　#アプリケーションフォルダ内のアプリケーションを取得
　　　　set aFolder to path to applications folder
　　　　set aPath to aFolder’s POSIX path
　　　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　　　
　　　　# 指定フォルダの直下のファイルを取得
　　　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　　　|error|:(missing value)
　　　　
　　　　set filePaths to filePaths as list
　　　　set thisFileType to "com.apple.application-bundle"
　　　　
　　　　set dataSourceList to {}
　　　　repeat with anItem in filePaths
　　　　　　
　　　　　　set aPath to anItem’s contents’s POSIX path
　　　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　　　
　　　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　　　|error|:(reference))
　　　　　　
　　　　　　if (aUTI as text) is thisFileType then
　　　　　　　　set iconImage to (current application’s NSWorkspace’s sharedWorkspace’s iconForFile:aPath)
　　　　　　　　set dict to {fileURL:aURL, icon:iconImage}
　　　　　　　　set dataSourceList’s end to dict
　　　　　　end if
　　　　end repeat
　　　　
　　　　set execButtonTitle to "OK😄"
　　　　
　　　　set dateObj to my chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
　　end testRun
　　
　　# アラートダイアログでCollectionViewを表示
　　property _retrieve_data : missing value
　　on chooseItemByCollectionView:(aMainMes as text) subMes:(aSubMes as text) myWidth:(aWidth as integer) myHeight:(aHeight as integer) myDataSource:(dataSourceList as list) okTitle:(execButtonTitle as text)
　　　　
　　　　set paramObj to {myMessage:aMainMes}
　　　　set paramObj to paramObj & {mySubMessage:aSubMes}
　　　　set paramObj to paramObj & {myDataSource:dataSourceList}
　　　　set paramObj to paramObj & {myWidth:aWidth}
　　　　set paramObj to paramObj & {myHeight:aHeight}
　　　　set paramObj to paramObj & {myOKTitile:execButtonTitle}
　　　　
　　　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　　　
　　　　if (my _retrieve_data) is missing value then error number -128
　　　　return (my _retrieve_data)
　　end chooseItemByCollectionView:subMes:myWidth:myHeight:myDataSource:okTitle:
　　
　　## retrieve date
　　on raizeAlert:paramObj
　　　　
　　　　set mesText to paramObj’s myMessage as text
　　　　set infoText to paramObj’s mySubMessage as text
　　　　set dataSourceList to paramObj’s myDataSource as list
　　　　set viewWidth to paramObj’s myWidth as integer
　　　　set viewHeight to paramObj’s myHeight as integer
　　　　set okButton to paramObj’s myOKTitile as text
　　　　
　　　　# set up view
　　　　set {thisView, collectionView} to my makeContentView(dataSourceList, viewWidth, viewHeight)
　　　　
　　　　### set up alert
　　　　tell current application’s NSAlert’s new()
　　　　　　addButtonWithTitle_(okButton)
　　　　　　addButtonWithTitle_("Cancel")
　　　　　　setAccessoryView_(thisView)
　　　　　　–setIcon_(aImage)
　　　　　　setInformativeText_(infoText)
　　　　　　setMessageText_(mesText)
　　　　　　tell |window|()
　　　　　　　　setInitialFirstResponder_(thisView)
　　　　　　end tell
　　　　　　#### show alert in modal loop
　　　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　　　end tell
　　　　
　　　　### retrieve data
　　　　set aIndexSet to collectionView’s selectionIndexes()
　　　　set theArray to current application’s NSArrayController’s alloc()’s initWithContent:(collectionView’s content())
　　　　set chooseItems to ((theArray)’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　　　
　　　　# reset
　　　　set _retrieve_data to {}
　　　　
　　　　repeat with anItem in chooseItems
　　　　　　set (my _retrieve_data)’s end to anItem’s contents
　　　　end repeat
　　　　
　　　　return my _retrieve_data
　　end raizeAlert:
　　
　　# set up view
　　on makeContentView(dataSourceList, viewWidth, viewHeight)
　　　　
　　　　set thisRect to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　　　
　　　　tell current application’s NSCollectionView’s alloc
　　　　　　tell initWithFrame_(thisRect)
　　　　　　　　setItemPrototype_(current application’s YKZCollectionViewItem’s new())
　　　　　　　　
　　　　　　　　setAllowsEmptySelection_(true)
　　　　　　　　setAllowsMultipleSelection_(true)
　　　　　　　　setContent_(dataSourceList)
　　　　　　　　setSelectable_(true)
　　　　　　　　
　　　　　　　　set collectionView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# Viewを作成
　　　　tell current application’s NSScrollView’s alloc()
　　　　　　tell initWithFrame_(thisRect)
　　　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　　　setDocumentView_(collectionView)
　　　　　　　　setHasHorizontalScroller_(true)
　　　　　　　　setHasVerticalScroller_(true)
　　　　　　　　set baseView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return {baseView, collectionView}
　　end makeContentView
end script

#MARK: –
script YKZView
　　property parent : class "NSView"
　　
　　property imageView : missing value
　　
　　property selected : false
　　property viewItemHeight : 128
　　property viewItemWidth : 128
　　
　　on initWithFrame:rect
　　　　
　　　　set myRect to current application’s NSMakeRect(0, 0, viewItemWidth, viewItemHeight)
　　　　continue initWithFrame:myRect
　　　　
　　　　set aHeight to viewItemHeight – 10
　　　　set aWidth to viewItemWidth – 10
　　　　set newRect to current application’s NSMakeRect(5, 5, aWidth, aHeight)
　　　　
　　　　tell current application’s NSImageView’s alloc()
　　　　　　tell initWithFrame_(newRect)
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　set my imageView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　my addSubview:(my imageView)
　　　　return me
　　end initWithFrame:
　　
　　on drawRect:rect
　　　　if my selected then
　　　　　　current application’s NSColor’s redColor()’s |set|()
　　　　else
　　　　　　current application’s NSColor’s controlBackgroundColor()’s |set|()
　　　　end if
　　　　current application’s NSRectFill(rect)
　　　　continue drawRect:rect
　　end drawRect:
end script

#MARK: –
script YKZCollectionViewItem
　　property parent : class "NSCollectionViewItem"
　　
　　on loadView()
　　　　my setView:(current application’s YKZView’s alloc()’s initWithFrame:(current application’s NSZeroRect))
　　end loadView
　　
　　on setRepresentedObject:representedObject
　　　　–continue setRepresentedObject:representedObject
　　　　if representedObject is missing value then return
　　　　(my view())’s imageView’s setImage:(representedObject’s icon)
　　end setRepresentedObject:
　　
　　on setSelected:isSelected
　　　　set (my view())’s selected to isSelected
　　　　(my view())’s setNeedsDisplay:true
　　　　continue setSelected:isSelected
　　end setSelected:
end script

★Click Here to Open This Script　

アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

Posted on 8月 9, 2020 by Takaaki Naganoya

edama2さんからの投稿です。起動中のアプリケーション一覧をダイアログ表示するAppleScriptシリーズで、アプリケーションのアイコン画像やパス情報を表示し、単数/複数のアプリケーション選択ができます。

–> Download Script Bundle archive

▲単一選択（左）のダイアログと、複数選択（右）のダイアログ

タイトルは「アラートダイアログ上のTable Viewで起動中のアプリケーションを選択」
起動中のアプリケーションをiOSライクなレイアウトで表示します
Table Viewにカスタムセルビューを作って表現し、アプリの起動と終了を検知してリアルタイムで更新します
行数は12行に固定し、項目の複数選択がオプションで選べます

AppleScriptObjCフレームワークを呼び出すことにより、Xcod上で記述するAppleScriptアプリケーションのように、各種クラスのサブクラスを定義して利用しているScriptです。さまざまなScripterの技術が積み上がっている感じがして壮観ですが、ほとんどはedama2さんが長い時間をかけて積み上げてきたものの集大成といったものです。

本Scriptは途中で試行錯誤がいろいろあって、返り値がファイルパスだったりアプリケーションオブジェクトになったりと紆余曲折あって、現在の「アプリケーションオブジェクト」になりました。

ただ、実行中のアプリケーション自身を選択すると「current application」になってしまう点に注意が必要です。

AppleScript名：アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

on run
　　my testRun()
end run

on testRun()
　　
　　set mes to "選択モードを指定してください"
　　set bOK to "複数選択"
　　set bOther to "単一選択"
　　set bCancel to "キャンセル"
　　set bList to {bCancel, bOther, bOK}
　　
　　set userAction to display dialog mes buttons bList default button bOK cancel button bCancel with icon note
　　
　　if userAction’s button returned is bOther then
　　　　set isMultiple to false
　　else if userAction’s button returned is bOK then
　　　　set isMultiple to true
　　end if
　　
　　set aMainMes to "Select Runnning Application"
　　set aSubMes to "Sub Message"
　　set execButtonTitle to "OK😁"
　　set dateObj to my chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:(isMultiple) okTitle:execButtonTitle
　　
end testRun

on chooseRunningApplication:(aMainMes as text) subMes:(aSubMes as text) withMultipleSelections:(isMultiple as boolean) okTitle:(execButtonTitle as text)
　　
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　# subClasses.scptを呼び出す
　　set DialogCore to current application’s AppDelegate’s new()
　　set fRes to DialogCore’s chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:isMultiple okTitle:execButtonTitle
　　
　　if fRes is missing value then error number -128
　　return fRes as list
end chooseRunningApplication:subMes:withMultipleSelections:okTitle:

★Click Here to Open This Script　

AppleScript名：subClasses.scpt

#MARK: AppDelegate
script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on applicationShouldTerminateAfterLastWindowClosed:sender
　　　　return true
　　end applicationShouldTerminateAfterLastWindowClosed:
　　
　　on applicationWillFinishLaunching:aNotification
　　　　log my testRun()
　　end applicationWillFinishLaunching:
　　
　　——————
　　#MARK: テスト
　　on testRun()
　　　　–log "testRun"
　　　　
　　　　set mes to "選択モードを指定してください"
　　　　set bOK to "複数選択"
　　　　set bOther to "単一選択"
　　　　set bCancel to "キャンセル"
　　　　set bList to {bCancel, bOther, bOK}
　　　　
　　　　set userAction to display dialog mes buttons bList default button bOK cancel button bCancel with icon note
　　　　
　　　　if userAction’s button returned is bOther then
　　　　　　set isMultiple to false
　　　　else if userAction’s button returned is bOK then
　　　　　　set isMultiple to true
　　　　end if
　　　　
　　　　set aMainMes to "Select Runnning Application"
　　　　set aSubMes to "Sub Message"
　　　　set execButtonTitle to "OK😁"
　　　　set dateObj to my chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:(isMultiple) okTitle:execButtonTitle
　　　　
　　　　return dateObj
　　end testRun
　　
　　#MARK: アラートダイアログでtableviewを表示
　　property _retrieve_data : missing value
　　on chooseRunningApplication:(aMainMes as text) subMes:(aSubMes as text) withMultipleSelections:(isMultiple as boolean) okTitle:(execButtonTitle as text)
　　　　# reset
　　　　set my _retrieve_data to missing value
　　　　
　　　　#
　　　　if aMainMes = "" then error "Dialog main message is missing"
　　　　
　　　　#
　　　　set dataSourceList to {}
　　　　
　　　　# OKボタンの文字
　　　　if execButtonTitle = "" then set execButtonTitle to "Execute"
　　　　
　　　　set thisFileType to "com.apple.application-bundle"
　　　　
　　　　#
　　　　set paramObj to {myMessage:aMainMes}
　　　　set paramObj to paramObj & {mySubMessage:aSubMes}
　　　　set paramObj to paramObj & {myDataSource:dataSourceList}
　　　　set paramObj to paramObj & {myType:thisFileType}
　　　　set paramObj to paramObj & {mySelectType:isMultiple}
　　　　set paramObj to paramObj & {myOKTitile:execButtonTitle}
　　　　
　　　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　　　
　　　　if (my _retrieve_data) is missing value then error number -128
　　　　set retrieveData to my _retrieve_data
　　　　set my _retrieve_data to missing value
　　　　
　　　　return retrieveData
　　end chooseRunningApplication:subMes:withMultipleSelections:okTitle:
　　
　　#MARK: Raize Alert
　　on raizeAlert:paramObj
　　　　set mesText to paramObj’s myMessage as text
　　　　set infoText to paramObj’s mySubMessage as text
　　　　set dataSourceList to paramObj’s myDataSource as list
　　　　set myUTI to paramObj’s myType as text
　　　　set isMultiple to paramObj’s mySelectType as boolean
　　　　set okButton to paramObj’s myOKTitile as text
　　　　
　　　　### set up view
　　　　#### data sourceにデータを追加
　　　　set theController to current application’s YKZArrayController’s alloc()’s initWithContent:dataSourceList
　　　　theController’s setMultipleSelections:isMultiple
　　　　theController’s setupView()
　　　　
　　　　### アイコンの指定
　　　　–set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:myUTI
　　　　
　　　　set setSize to 128
　　　　set fontObj to current application’s NSFont’s systemFontOfSize:setSize
　　　　set aValue to {fontObj}
　　　　set aKey to {current application’s NSFontAttributeName}
　　　　set attributes to current application’s NSDictionary’s dictionaryWithObjects:aValue forKeys:aKey
　　　　
　　　　set strEmoji to current application’s NSString’s stringWithString:"😎"
　　　　
　　　　set newSizeObj to current application’s NSMakeSize(setSize, setSize)
　　　　tell current application’s NSImage’s alloc
　　　　　　tell initWithSize_(newSizeObj)
　　　　　　　　lockFocus()
　　　　　　　　strEmoji’s drawInRect:(current application’s NSMakeRect(0, 0, setSize, setSize)) withAttributes:attributes
　　　　　　　　unlockFocus()
　　　　　　　　set aImage to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　
　　　　### set up alert
　　　　tell current application’s NSAlert’s new()
　　　　　　addButtonWithTitle_(okButton)
　　　　　　addButtonWithTitle_("Cancel")
　　　　　　setAccessoryView_(theController’s _the_view)
　　　　　　setIcon_(aImage)
　　　　　　setInformativeText_(infoText)
　　　　　　setMessageText_(mesText)
　　　　　　tell |window|()
　　　　　　　　setInitialFirstResponder_(theController’s _the_view)
　　　　　　end tell
　　　　　　#### show alert in modal loop
　　　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　　　end tell
　　　　
　　　　### retrieve data
　　　　set (my _retrieve_data) to theController’s retrieveSelectItems()
　　　　return my _retrieve_data
　　end raizeAlert:
end script

#MARK: – NSValueTransformer
script YKZURLToIcon
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSImage –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set iconImage to current application’s NSWorkspace’s sharedWorkspace’s iconForFile:appPath
　　　　return iconImage
　　end transformedValue:
end script

script YKZURLToDisplayedName
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set displayedName to current application’s NSFileManager’s defaultManager’s displayNameAtPath:appPath
　　　　return displayedName
　　end transformedValue:
end script

script YKZURLToPath
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　return appPath
　　end transformedValue:
end script

script YKZURLToVersion
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　tell (current application’s NSBundle’s bundleWithURL:fileURL)
　　　　　　tell its infoDictionary()
　　　　　　　　set aVar to objectForKey_("CFBundleShortVersionString")
　　　　　　end tell
　　　　end tell
　　　　return aVar
　　end transformedValue:
end script

#MARK: – Array Controller
script YKZArrayController
　　property parent : class "NSArrayController"
　　
　　#MARK: IBOutlets
　　property _the_view : missing value
　　property _table_view : missing value
　　
　　#MARK: Property
　　property multipleSelections : false
　　property rowCount : 12
　　
　　#MARK: 初期化
　　on initWithContent:aContent
　　　　continue initWithContent:aContent
　　　　
　　　　#通知の登録
　　　　tell current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()
　　　　　　addObserver_selector_name_object_(me, "changed:", "NSWorkspaceDidLaunchApplicationNotification", missing value)
　　　　　　addObserver_selector_name_object_(me, "changed:", "NSWorkspaceDidTerminateApplicationNotification", missing value)
　　　　end tell
　　　　
　　　　return me
　　end initWithContent:
　　
　　
　　#MARK: 戻り値
　　on retrieveSelectItems()
　　　　set retrieveData to {}
　　　　
　　　　set aIndexSet to my _table_view’s selectedRowIndexes()
　　　　set chooseItems to ((my _table_view’s dataSource())’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　　　repeat with anItem in chooseItems
　　　　　　set aPath to anItem’s fileURL
　　　　　　set retrieveData’s end to application (aPath as text)
　　　　end repeat
　　　　
　　　　return retrieveData as list
　　end retrieveSelectItems
　　
　　#MARK: viewの作成
　　on setupView()
　　　　#Transformerの登録
　　　　set tNames to {}
　　　　set tNames’s end to "YKZURLToIcon"
　　　　set tNames’s end to "YKZURLToDisplayedName"
　　　　set tNames’s end to "YKZURLToPath"
　　　　set tNames’s end to "YKZURLToVersion"
　　　　repeat with aTransformer in tNames
　　　　　　set theTransformer to current application’s class aTransformer’s new()
　　　　　　(current application’s NSValueTransformer’s setValueTransformer:theTransformer forName:aTransformer)
　　　　end repeat
　　　　log multipleSelections
　　　　## NSTableView
　　　　tell current application’s NSTableView’s alloc()
　　　　　　tell initWithFrame_(current application’s CGRectZero)
　　　　　　　　–registerForDraggedTypes_({current application’s NSFilenamesPboardType, (my _data_type)})
　　　　　　　　setAllowsEmptySelection_(false)
　　　　　　　　setAllowsMultipleSelection_(multipleSelections)
　　　　　　　　setDataSource_(me)
　　　　　　　　setDelegate_(me)
　　　　　　　　setDoubleAction_("doubleAction:")
　　　　　　　　–setDraggingSourceOperationMask_forLocal_(current application’s NSDragOperationCopy, false)
　　　　　　　　setGridStyleMask_(current application’s NSTableViewSolidVerticalGridLineMask)
　　　　　　　　setSelectionHighlightStyle_(current application’s NSTableViewSelectionHighlightStyleRegular)
　　　　　　　　setTarget_(me)
　　　　　　　　setUsesAlternatingRowBackgroundColors_(true)
　　　　　　　　setHeaderView_(missing value)
　　　　　　　　setRowHeight_(50)
　　　　　　　　
　　　　　　　　set thisRowHeight to rowHeight() as integer
　　　　　　　　set my _table_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　## NSTableColumn
　　　　### Columnの並び順を指定する
　　　　set keyrec to {column1:"Name"}
　　　　set keyDict to (current application’s NSDictionary’s dictionaryWithDictionary:keyrec)
　　　　
　　　　set viewWidth to 400 –表示幅を変更
　　　　set columnsCount to keyDict’s |count|()
　　　　
　　　　repeat with colNum from 1 to columnsCount
　　　　　　
　　　　　　set keyName to "column" & colNum as text
　　　　　　set aTitle to (keyDict’s objectForKey:keyName)
　　　　　　
　　　　　　tell (current application’s NSTableColumn’s alloc()’s initWithIdentifier:(colNum as text))
　　　　　　　　tell headerCell()
　　　　　　　　　　setStringValue_(aTitle)
　　　　　　　　　　set thisHeaderHeight to cellSize()’s height
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　### バインディングのオプション
　　　　　　　　— ソートを無効にする
　　　　　　　　set anObj to (current application’s NSNumber’s numberWithBool:false)
　　　　　　　　set aKey to current application’s NSCreatesSortDescriptorBindingOption
　　　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　　　
　　　　　　　　### 表示内容をNSArrayControllerにバインディング
　　　　　　　　bind_toObject_withKeyPath_options_(current application’s NSValueBinding, (my _table_view’s dataSource()), "arrangedObjects", bOptions)
　　　　　　　　
　　　　　　　　set aTableColumn to it
　　　　　　end tell
　　　　　　
　　　　　　### Columnの横幅を調整
　　　　　　tell (my _table_view)
　　　　　　　　addTableColumn_(aTableColumn)
　　　　　　end tell
　　　　　　
　　　　　　tell aTableColumn
　　　　　　　　setWidth_(viewWidth)
　　　　　　end tell
　　　　end repeat
　　　　
　　　　## NSScrollView
　　　　### Viewの高さを計算
　　　　set viewHeight to thisRowHeight * rowCount + thisHeaderHeight
　　　　
　　　　#ダイアログ内のビューサイズを指定
　　　　set aScreen to current application’s NSScreen’s mainScreen()
　　　　set screenFrame to aScreen’s frame()
　　　　set aHeight to current application’s NSHeight(screenFrame)
　　　　set aWidth to current application’s NSWidth(screenFrame)
　　　　set maxHeight to aHeight * 0.845
　　　　set maxWidth to aWidth * 0.94
　　　　–log viewHeight
　　　　–log maxHeight
　　　　–set viewHeight to viewHeight + aSpace + sfHeight
　　　　if viewHeight > maxHeight then set viewHeight to maxHeight
　　　　if viewWidth > maxWidth then set viewWidth to maxWidth
　　　　if viewWidth < 360 then set viewWidth to 360
　　　　
　　　　set vSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　　　
　　　　### Viewを作成
　　　　tell current application’s NSScrollView’s alloc()
　　　　　　tell initWithFrame_(vSize)
　　　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　　　setDocumentView_(my _table_view)
　　　　　　　　setHasHorizontalScroller_(true)
　　　　　　　　setHasVerticalScroller_(true)
　　　　　　　　set my _the_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　my changed:me
　　　　
　　　　# 1行目を選択
　　　　my setSelectionIndex:0
　　　　
　　　　return my _the_view
　　end setupView
　　
　　#MARK: アプリケーションが切り替わった時
　　— tableViewを作成してから実行する
　　on changed:sender
　　　　log "changed"
　　　　
　　　　tell (my _table_view)’s dataSource()
　　　　　　removeObjects_(arrangedObjects())
　　　　end tell
　　　　
　　　　#起動中のアプリケーション
　　　　set aList to current application’s NSWorkspace’s sharedWorkspace()’s runningApplications()
　　　　set sort to (current application’s NSSortDescriptor’s alloc()’s initWithKey:"localizedName" ascending:true selector:"caseInsensitiveCompare:")
　　　　set sortedList to aList’s sortedArrayUsingDescriptors:(sort as list)
　　　　
　　　　repeat with anItem in (sortedList as list)
　　　　　　#普通のアプリだけ
　　　　　　set aFlag to anItem’s activationPolicy() is current application’s NSApplicationActivationPolicyRegular
　　　　　　if aFlag then
　　　　　　　　set theURL to anItem’s bundleURL()
　　　　　　　　((my _table_view)’s dataSource()’s addObject:{fileURL:theURL})
　　　　　　end if
　　　　　　
　　　　end repeat
　　　　
　　end changed:
　　
　　
　　#MARK: Data Source Overrides
　　on numberOfRowsInTableView:aTableView
　　　　return (aTableView’s dataSource())’s content()’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aTableView viewForTableColumn:aColumn row:aRow
　　　　
　　　　set aCellView to aTableView’s makeViewWithIdentifier:"YKZTableCellView" owner:me
　　　　
　　　　if aCellView is missing value then
　　　　　　
　　　　　　set frameRect to current application’s NSMakeRect(0, 0, aColumn’s width, aTableView’s rowHeight())
　　　　　　set aCellView to current application’s YKZTableCellView’s alloc’s initWithFrame:frameRect
　　　　　　
　　　　　　set anObj to "YKZURLToIcon"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s imageView())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToDisplayedName"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s textField())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToPath"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s pathTextField)’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToVersion"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s varTextField)’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　return aCellView
　　　　end if
　　　　
　　　　return missing value
　　end tableView:viewForTableColumn:row:
　　
　　
　　# テーブル内のセルが編集できるか
　　on tableView:aTableView shouldEditTableColumn:aColumn row:aRow
　　　　return false
　　end tableView:shouldEditTableColumn:row:
　　
　　#
　　on validateProposedFirstResponder:aResponder forEvent:aEvent
　　　　log "validateProposedFirstResponder"
　　　　return true
　　　　
　　　　set aBoolean to aResponder’s isKindOfClass:(current application’s NSTableCellView’s |class|())
　　　　if aBoolean as boolean then
　　　　　　return true
　　　　end if
　　　　
　　　　return true
　　end validateProposedFirstResponder:forEvent:
　　
　　# テーブル内をダブルクリックしたらOKボタンを押す
　　on doubleAction:sender
　　　　log "doubleAction"
　　　　## ヘッダをクリックした時は何もしない
　　　　if (sender’s clickedRow()) is -1 then return
　　　　
　　　　set theEvent to current application’s NSEvent’s ¬
　　　　　　keyEventWithType:(current application’s NSEventTypeKeyDown) ¬
　　　　　　　　location:(current application’s NSZeroPoint) ¬
　　　　　　　　modifierFlags:0 ¬
　　　　　　　　timestamp:0.0 ¬
　　　　　　　　windowNumber:(sender’s |window|()’s windowNumber()) ¬
　　　　　　　　context:(current application’s NSGraphicsContext’s currentContext()) ¬
　　　　　　　　|characters|:return ¬
　　　　　　　　charactersIgnoringModifiers:(missing value) ¬
　　　　　　　　isARepeat:false ¬
　　　　　　　　keyCode:0
　　　　current application’s NSApp’s postEvent:theEvent atStart:(not false)
　　end doubleAction:
　　
end script

#MARK: – NSTableCellView
script YKZTableCellView
　　property parent : class "NSTableCellView"
　　
　　property acceptsFirstResponder : true
　　
　　property pathTextField : missing value
　　property varTextField : missing value
　　
　　on initWithFrame:rect
　　　　continue initWithFrame:rect
　　　　
　　　　setAutoresizingMask_(current application’s NSViewWidthSizable)
　　　　
　　　　–set myWidth to current application’s NSWidth(rect)
　　　　–set myHeight to current application’s NSHeight(rect)
　　　　
　　　　# アイコン
　　　　tell current application’s NSImageView’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(12, 1, 48, 48))
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　my setImageView:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# 表示名
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(66, 26, 280, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setFont_(current application’s NSFont’s boldSystemFontOfSize:13)
　　　　　　　　my setTextField:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# パス
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(66, 6, 316, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setFont_(current application’s NSFont’s systemFontOfSize:11)
　　　　　　　　set my pathTextField to it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# バージョン
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(300, 24, 80, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setFont_(current application’s NSFont’s systemFontOfSize:11)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setAlignment_(current application’s NSRightTextAlignment)
　　　　　　　　set my varTextField to it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return me
　　end initWithFrame:
end script

★Click Here to Open This Script　

指定のPDFからTOCを削除する

Posted on 6月 19, 2020 by Takaaki Naganoya

指定のPDFからTOCを削除して別名保存するAppleScriptです。

TOCを削除した新規ファイルは元ファイルと同じ場所に枝番つきで重複回避しつつ作成されます。

33MBで257ページほどあるPDFで、詳細に目次から記事へのリンクを手動で作成し、TOCを手動で作ったところ、Adobe Actobatが、

などというメッセージを出して保存ができなかったので、中途半端に１個だけエントリが残ったTOCを削除するために用意したものです（既存のScriptに機能があったので、削除機能だけ抽出）。

AppleScript名：指定のPDFからTOCを削除する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/08/18
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "Quartz"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property PDFDocument : a reference to current application’s PDFDocument
property NSFileManager : a reference to current application’s NSFileManager

–PDFの指定
set aFile to choose file of type {"pdf"} with prompt (progress additional description)
set filePath to aFile’s POSIX path

set fileURL to |NSURL|’s fileURLWithPath:filePath
set aPDFdoc to PDFDocument’s alloc()’s initWithURL:fileURL
set parentOL to aPDFdoc’s outlineRoot()

if parentOL is equal to missing value then
　　display dialog "There is no TOC with this PDF"
　　return
end if

set outLineCount to parentOL’s numberOfChildren()
set outLineCount to outLineCount as number

–既存のTOCを削除
repeat with num from (outLineCount – 1) to 0 by -1
　　(parentOL’s childAtIndex:num)’s removeFromParent()
end repeat

–保存
set progress description to "PDFを保存"
set progress additional description to "保存先の確認"
tell (NSString’s stringWithString:filePath)
　　set parentPath to stringByDeletingLastPathComponent() –>親フォルダ
　　set longFileName to lastPathComponent() –>拡張子ありの名前
end tell
set newFilePath to my pathExists(parentPath, longFileName)

set progress additional description to "書き出し中: " & newFilePath
set newFileURL to |NSURL|’s fileURLWithPath:newFilePath
aPDFdoc’s writeToURL:newFileURL

–名前が重複していないか確認
on pathExists(currentPath as text, fileName as text)
　　tell (NSString’s stringWithString:fileName)
　　　　set shortFileName to stringByDeletingPathExtension() as text
　　　　set aSuffix to pathExtension() as text
　　end tell
　　if aSuffix ≠ "" then set aSuffix to "." & aSuffix as text
　　
　　set currentPath to NSString’s stringWithString:currentPath
　　set unkonwnPath to (currentPath’s stringByAppendingPathComponent:fileName)
　　
　　set aSpace to space
　　set num to 0
　　
　　repeat while ((NSFileManager’s defaultManager)’s fileExistsAtPath:unkonwnPath)
　　　　set num to num + 1
　　　　set tmpName to shortFileName & aSpace & num & aSuffix as text
　　　　set unkonwnPath to (currentPath’s stringByAppendingPathComponent:tmpName)
　　end repeat
　　
　　return (unkonwnPath as text)
end pathExists

★Click Here to Open This Script　

クリップボード内のテキストをSayコマンドで読み上げて音声ファイル化

Posted on 5月 27, 2020 by Takaaki Naganoya

読み上げ対象のテキストをコピーした状態で実行するAppleScriptです。クリップボード内のテキストをSayコマンドで読み上げて、音声ファイルにレンダリングします。出力後、読み上げ所要時間を出力ファイルから求めてダイアログ表示します。

音声レンダリング処理は実際の音声読み上げ処理よりも短い時間で完了します。

–> Downlad Script With library within its bundle

掲載のリストを実行しても、スライダー入力ライブラリが含まれていないため、そのままでは実行できません。↑のScriptをまるごとダウンロードして展開すると、ライブラリ入りのScriptになります。実行にはダウンロードしたScriptをご利用ください。プログラムリスト掲載は参考のために行なっているものです。

▲ステップ１：念のために、読み上げ対象テキストをダイアログ表示

▲ステップ２：読み上げ時の速度をスライダーで選択

▲ステップ３：読み上げ音声を選択

▲ステップ４：読み上げ所要時間をダイアログ表示

▲ステップ５：音声レンダリングしたファイルをQuickTime Playerでオープン

AppleScript名：クリップボード内のテキストをSayコマンドで読み上げて音声ファイル化.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/27
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "AVFoundation"
use scripting additions
use slLib : script "sliderLib"

property |NSURL| : a reference to current application’s |NSURL|
property NSDate : a reference to current application’s NSDate
property NSUUID : a reference to current application’s NSUUID
property NSFileManager : a reference to current application’s NSFileManager
property AVAudioPlayer : a reference to current application’s AVAudioPlayer
property NSDateFormatter : a reference to current application’s NSDateFormatter
property NSSpeechSynthesizer : a reference to current application’s NSSpeechSynthesizer

set aInfo to clipboard info
set uCount to (clipboard info for Unicode text)
if uCount = {} then
　　display dialog "There is no text information in the clipboard" with title "Terminate information" buttons {"OK"} default button 1 with icon 2
　　return
end if

set totalCount to item 2 of item 1 of uCount

set aStr to the clipboard as text

–読み上げ内容の確認
display dialog aStr with title "Text length:" & (uCount as string) & " chars."

–読み上げ速度をSliderで入力
set rRes to slLib’s chooseBySlider(180, 220, "Select TTS reading pitch (small number:slow)")

–読み上げTTSキャラクタの選択
set aLoc to (current application’s NSLocale’s currentLocale()’s identifier()) as string –>　　"ja_JP"
set vList to getTTSVoiceNameWithLanguage(aLoc) of me
set vRes to choose from list vList with prompt ("Select TTS Voice in your language :" & aLoc) without empty selection allowed
if vRes = false then return

set vCharacter to contents of first item of vRes

–音声ファイルの作成先パスを求める
set aUUID to NSUUID’s UUID()’s UUIDString() as string
set aPath to (((path to movies folder) as string) & aUUID & ".aif")
set aPOSIX to POSIX path of aPath

–音声レンダリング
tell current application
　　say aStr using vCharacter saving to (aPOSIX) speaking rate rRes without waiting until completion
end tell

–レンダリングした音声の読み上げ所要時間を計算
set aDur to getDuration(aPath as alias) of me

–レンダリングした音声ファイルをオープン
tell application "QuickTime Player"
　　open aPath
end tell

–完了報告
display dialog "読み上げ所要時間：" & my formatHMS(aDur)

on getTTSVoiceNameWithLanguage(voiceLang)
　　set outArray to current application’s NSMutableArray’s new()
　　
　　set aList to NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceLocaleIdentifier == %@", voiceLang)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceName") as list
　　
　　return aResList
end getTTSVoiceNameWithLanguage

on getDuration(aFile)
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　
　　repeat 1000 times
　　　　set aAudioPlayer to AVAudioPlayer’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　　　set aRes to aAudioPlayer’s prepareToPlay()
　　　　if aRes as boolean = true then exit repeat
　　　　delay 0.5
　　end repeat
　　
　　set channelCount to aAudioPlayer’s numberOfChannels()
　　set aDuration to aAudioPlayer’s duration()
　　return aDuration as real
end getDuration

on retAvailableTTSnames()
　　set outList to {}
　　
　　set aList to NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aInfo to (NSSpeechSynthesizer’s attributesForVoice:j)
　　　　set aInfoRec to aInfo as record
　　　　set aName to VoiceName of aInfoRec
　　　　set the end of outList to aName
　　end repeat
　　
　　return outList
end retAvailableTTSnames

on formatHMS(aTime)
　　set aDate to NSDate’s dateWithTimeIntervalSince1970:aTime
　　set aFormatter to NSDateFormatter’s alloc()’s init()
　　
　　—This formatter text is localized in Japanese.
　　if aTime < hours then
　　　　aFormatter’s setDateFormat:"mm分ss秒"
　　else if aTime < days then
　　　　aFormatter’s setDateFormat:"HH時間mm分ss秒"
　　else
　　　　aFormatter’s setDateFormat:"DD日HH時間mm分ss秒"
　　end if
　　
　　set timeStr to (aFormatter’s stringFromDate:aDate) as string
　　return timeStr
end formatHMS

★Click Here to Open This Script　

指定アプリケーション内の現在のLocaleの指定stringsファイル内の指定キーの値を取得する

Posted on 11月 16, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションのバンドル中（/Contents/Resources/）の現在のLocalizationに存在する指定のstringsファイル内で、指定キーの値を取得するAppleScriptです。

アプリケーションバンドル内の各ローカライズフォルダの名称は一意に決定されているものでもなく、ある程度の「ゆらぎ」が生じています。

/Contents/Resources/Japanese.lproj/
/Contents/Resources/ja.lproj/

NSLocaleからcurrentLocale()を取得すると、「ja-JP」のような識別子が得られます。これと上記のパターンのフォルダとの付け合わせのためのメソッドがどこかに存在しているはずなのですが、現状では見つけられていません（ないと各アプリケーションが正しくメニュー表示できていないので）。

まだいまひとつ、しっくりきていません。

AppleScript名：指定アプリケーション内の現在のLocaleの指定stringsファイル内の指定キーの値を取得する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/15
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSBundle : a reference to current application’s NSBundle
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSLocaleCountryCode : a reference to current application’s NSLocaleCountryCode
property NSLocaleLanguageCode : a reference to current application’s NSLocaleLanguageCode
property NSLocaleCollatorIdentifier : a reference to current application’s NSLocaleCollatorIdentifier

set targID to "com.apple.iWork.Keynote"
set targFile to "Keynote" –"Keynote.strings" file
set targKey to "Arrange"
set vStr to getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey) of me
–> "配置"

on getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey)
　　set aPath to retPathFromBundleID(targID) of me
　　
　　set aURL to (|NSURL|’s fileURLWithPath:aPath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　
　　set aLocale to (current application’s NSLocale’s preferredLanguages()’s firstObject()) as string
　　
　　set curLocale to current application’s NSLocale’s currentLocale()
　　set aDS11 to (curLocale’s objectForKey:(NSLocaleLanguageCode)) as string
　　set aDS12 to (curLocale’s objectForKey:(NSLocaleCountryCode)) as string
　　set aDS5 to (curLocale’s objectForKey:(NSLocaleCollatorIdentifier)) as string
　　–set bID to (current application’s NSBundle’s mainBundle()’s preferredLocalizations()’s firstObject()) as string
　　
　　set langIDList to {aDS11, aLocale, aDS12, aDS5} –> {"ja", "ja-JP", "JP", "ja-JP"}
　　
　　repeat with i in langIDList
　　　　set j to contents of i
　　　　set aRes to (aBundle’s pathForResource:targFile ofType:"strings" inDirectory:"" forLocalization:(j))
　　　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:aRes)
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　return aVal as string
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return false
end getAValInASpecifiedStringFileOfAllLocaleInABundle

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

★Click Here to Open This Script　

指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

Posted on 11月 13, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションからすべてのLocaleを取得し、ダイアログ選択したLocale内のすべてのstringsファイルを読み込んでNSDictionary化して指定のキーワードを含むものを抽出するAppleScriptです。

指定キーワードが含まれていた場合には、

キー, 値, stringsファイルのパス

をリストで返します。調査のための下調べを行うものです。

AppleScript名：指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants

set targID to "com.apple.Finder"
set targWords to "のコピー"

set bRes to getLocalizationsFromBundleID(targID) of me
–>　　{"de", "he", "en_AU", "ar", "el", "ja", "en", "uk", "es_419", "zh_CN", "es", "da", "it", "sk", "pt_PT", "ms", "sv", "cs", "ko", "Base", "no", "hu", "zh_HK", "tr", "pl", "zh_TW", "en_GB", "vi", "ru", "fr_CA", "fr", "fi", "id", "nl", "th", "pt", "ro", "hr", "hi", "ca"}

–Select Localization
set curLang to first item of (choose from list bRes)

–Get All strings file path within a bundle
set aPath to retPathFromBundleID(targID) of me
set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

–Get Every Key & Value pair then filter target keyword
set aMDict to NSMutableDictionary’s new()
set hitList to {}
repeat with ii in sList
　　set jj to contents of ii
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:jj)
　　(aMDict’s addEntriesFromDictionary:aDict)
　　
　　set kList to aMDict’s allKeys() as list
　　set vList to aMDict’s allValues() as list
　　
　　set kCount to 1
　　repeat with i in vList
　　　　set j to contents of i
　　　　if j contains targWords then
　　　　　　set the end of hitList to {contents of item kCount of kList, j, jj}
　　　　end if
　　　　set kCount to kCount + 1
　　end repeat
　　
end repeat

return hitList
–> {{"PW5_V2", "^0項目のコピーの準備中", "/System/Library/CoreServices/Finder.app/Contents/Resources/Japanese.lproj/Localizable.strings"}, …}

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　

指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する

Posted on 11月 13, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションのバンドル中（/Contents/Resources/）のすべてのLocalizationに存在する指定のstringsファイル内で、指定キーの値を取得するAppleScriptです。

macOSの日本語環境では、Finder上でコピーしたファイルのファイル名の後方に「のコピー」といった文字列が追記されますが、他のLocaleでどのような文字列が使用されているか調査するために作成したものです。

AppleScript名：指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/12
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set targID to "com.apple.Finder"
set targFile to "Localizable.strings"
set targKey to "N4_V2"
set vList to getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey) of me
–> {{"he", "עותק של ^=1 ^=0"}, {"en_AU", "^=1 copy ^=0"}, {"ar", "نسخة ^=0 من ^=1"}, {"el", "^=1 αντίγραφο ^=0"}, {"uk", "^=1 копія ^=0"}, {"English", "^=1 copy ^=0"}, {"es_419", "Copia de ^=1 ^=0"}, {"zh_CN", "^=1的副本 ^=0"}, {"Dutch", "^=1 kopie ^=0"}, {"da", "^=1-kopi ^=0"}, {"sk", "^=1 – kópia ^=0"}, {"pt_PT", "^=1 – cópia ^=0"}, {"German", "^=1 Kopie ^=0"}, {"ms", "salinan ^=0 ^=1"}, {"sv", "^=1 (kopia ^=0)"}, {"cs", "^=1 (kopie ^=0)"}, {"ko", "^=1 복사본 ^=0"}, {"no", "^=1-kopi ^=0"}, {"hu", "^=1 másolat ^=0"}, {"zh_HK", "^=1 副本 ^=0"}, {"Spanish", "^=1 copia ^=0"}, {"tr", "^=1 kopyası ^=0"}, {"pl", "^=1-kopia ^=0"}, {"zh_TW", "^=1 拷貝 ^=0"}, {"en_GB", "^=1 copy ^=0"}, {"French", "^=1 copie ^=0"}, {"vi", "Bản sao ^=1 ^=0"}, {"ru", "^=1 — копия ^=0"}, {"fr_CA", "^=1 copie ^=0"}, {"fi", "^=1 kopio ^=0"}, {"id", "Salinan ^=1 ^=0"}, {"th", "^=1 สำเนา ^=0"}, {"pt", "^=1 – cópia ^=0"}, {"ro", "^=1 – copie ^=0"}, {"Japanese", "^=1のコピー^=0"}, {"hr", "^=1 kopija ^=0"}, {"hi", "^=1 कॉपी ^=0"}, {"Italian", "^=1 copia ^=0"}, {"ca", "^=1 còpia ^=0"}}

on getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey)
　　–Get App Path
　　set aPath to retPathFromBundleID(targID) of me
　　
　　–Get all Localizations
　　set bRes to getLocalizationsFromBundleID(targID) of me
　　
　　set hitList to {}
　　
　　–Loop with Localizations in an application bundle
　　repeat with iii in bRes
　　　　set jjj to contents of iii
　　　　set allPath to aPath & "/Contents/Resources/" & jjj & ".lproj/" & targFile
　　　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:allPath)
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　set the end of hitList to {jjj, aVal as string}
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return hitList
end getAValInASpecifiedStringFileOfAllLocaleInABundle

★Click Here to Open This Script　

指定フォルダ以下のすべてのファイルとフォルダ名から絵文字を除去する v2

Posted on 11月 5, 2019 by Takaaki Naganoya

指定フォルダ以下のすべてのファイル名とフォルダ名から絵文字を除去するAppleScriptです。Shane StanleyのremoveEmojiルーチンを使っています。

macOS 10.14.1で絵文字が大幅に追加されたため、これらの絵文字をファイル名に用いていた場合には10.14.1以下のバージョンのOS環境にそのままファイルを持っていくことができません。

　Zipアーカイブ → 展開時にエラー
　DiskImageにコピーするファイルを格納し、古いOSに持って行ってドライブとしてマウントしてファイルコピー　→ コピーできない（エラー）

という状態になります。絵文字自体に害はないのですが、規格がコロコロ変わる（追加される）ことで、ファイル名に用いるのには問題があるということでしょう。

▲もともとのファイル名、フォルダ名。絵文字を大量に使用している（普段はファイル名に絵文字は使っていません）

▲本Scriptで一括で処理したファイル名、フォルダ名。害のない1️⃣2️⃣3️⃣などの文字だけは残る

実際に作ってみたら、aliasに対するリネームはしょっちゅう行ってきたものの、POSIX pathを用いて指定フォルダ以下すべてをリネームするようなScriptは組んでいなかったので、ちょっと考えさせられました。

▲本Scriptでリネームして、CotEditorのScript PackをmacOS 10.13.6の環境に持っていけました。ただ、絵文字がないと寂しい感じがします

指定フォルダ以下のファイル/フォルダを一括取得するのに、今回はあえてSpotlightを使っていません。ファイルサーバー上のファイル/フォルダを処理する可能性がありそうなのと、外部ライブラリを使わないほうがよいと考え、このような構成になっています。

AppleScript名：指定フォルダ以下のすべてのファイルとフォルダ名から絵文字を除去する v2.scptd

—
—　　Created by: Takaaki Naganoya
—　　Created on: 2019/11/04
—
—　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRegularExpressionSearch : a reference to current application’s NSRegularExpressionSearch
property NSURLBookmarkResolutionWithoutUI : a reference to current application’s NSURLBookmarkResolutionWithoutUI

set aFol to POSIX path of (choose folder)

set anArray to NSMutableArray’s array()
set erArray to NSMutableArray’s array()
set aPath to NSString’s stringWithString:aFol
set dirEnum to NSFileManager’s defaultManager()’s enumeratorAtPath:aPath

repeat
　　set aName to (dirEnum’s nextObject())
　　if aName = missing value then exit repeat
　　set aFullPath to aPath’s stringByAppendingPathComponent:aName
　　
　　anArray’s addObject:aFullPath
end repeat

—逆順に（フォルダの深い場所＆ファイル名から先に処理）
set revArray to (anArray’s reverseObjectEnumerator()’s allObjects()) as list

—リネーム
repeat with i in revArray
　　set j to (NSString’s stringWithString:(contents of i))
　　set curName to j’s lastPathComponent() as string
　　set newName to removeEmoji(curName) of me
　　
　　if curName is not equal to newName then
　　　　set fRes to renameFileItem(j as string, newName) of me
　　　　if fRes = false then
　　　　　　(erArray’s addObject:{j, newName})
　　　　end if
　　end if
end repeat

return erArray as list —リネームできなかったパス（フルパス、リネームするはずだった名称）

—絵文字除去
on removeEmoji(aStr)
　　set aNSString to NSString’s stringWithString:aStr
　　return (aNSString’s stringByReplacingOccurrencesOfString:"[＼＼U0001F600-＼＼U0001F64F＼＼U0001F300-＼＼U0001F5FF＼＼U0001F680-＼＼U0001F6FF＼＼U00002600-＼＼U000026FF＼＼U00002700-＼＼U000027BF＼＼U0000FE00-＼＼U0000fE0F＼＼U0001F900-＼＼U0001F9FF＼＼U0001F1E6-＼＼U0001F1FF＼＼U00002B50-＼＼U00002B50＼＼U0000231A-＼＼U0000231B＼＼U00002328-＼＼U000023FA＼＼U000024C2-＼＼U000024C2＼＼U0001F194-＼＼U0001F194＼＼U0001F170-＼＼U0001F251＼＼U000025AB-＼＼U000025FE＼＼U00003297-＼＼U00003299＼＼U00002B55-＼＼U00002B55＼＼U00002139-＼＼U00002139＼＼U00002B1B-＼＼U00002B1C＼＼U000025AA-＼＼U000025AA＼＼U0001F004-＼＼U0001F004＼＼U0001F0CF-＼＼U0001F0CF]" withString:"" options:(NSRegularExpressionSearch) range:{0, aNSString’s |length|()}) as text
end removeEmoji

—ファイル/フォルダのリネーム
on renameFileItem(aPOSIXPath, newName)
　　set theNSFileManager to NSFileManager’s defaultManager()
　　set POSIXPathNSString to NSString’s stringWithString:(aPOSIXPath)
　　
　　–Make New File Path
　　set anExtension to POSIXPathNSString’s pathExtension()
　　set newPath to (POSIXPathNSString’s stringByDeletingLastPathComponent()’s stringByAppendingPathComponent:newName) –’s stringByAppendingPathExtension:anExtension
　　
　　–Rename
　　if theNSFileManager’s fileExistsAtPath:newPath then
　　　　return true
　　else
　　　　set theResult to theNSFileManager’s moveItemAtPath:POSIXPathNSString toPath:newPath |error|:(missing value)
　　　　if (theResult as integer = 1) then
　　　　　　return (newPath as string)
　　　　else
　　　　　　return false
　　　　end if
　　end if
end renameFileItem

★Click Here to Open This Script　

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

Posted on 9月 21, 2019 by Takaaki Naganoya

バンドルIDで指定したアプリケーションのResourcesフォルダ中の、指定ロケールのstringsファイルをすべて読み込んでkeyを取り出すAppleScriptです。

アプリケーション内の指定のローカライズしたメッセージ（テキスト）の内容を取り出すことはできますが、そのためにはキーを知っておく必要があります。そのキーを取り出してローカライズされた文字列を取り出すため、キーを調査してみました。

これをそのまま何かのツールなりScriptに使うというものではなく、いわゆる「下調べ」のためのScriptの部品です。

ほぼ、ありもののルーチンを再利用しただけのプログラムでできていますが、ありものはありもので、数千本のAppleScriptのストックからそれを探し出してくるのも一苦労です。

アプリケーションバンドル内のResourcesフォルダ以下の（各lprojフォルダ以下の）stringsファイルの中身はまんま（シリアライズした）NSDictionaryなので、そのままDictionaryに読み込んでallkey()などのメソッドを実行できます。昔のstringsファイルはテキストファイルだったような気がしますが、テキストファイルだとparseしないといけないんで、ビルド時にparseしておいてDictionaryの状態でファイルに書いておくのは正しいと思います。

Xcode 8あたりから、アプリケーションのローカライズのルールが変更になったようで、基本となる言語環境がBase.lprojになり、英語はen.lprojといった１ローカライズ言語という位置付けに変更になりました。

NSLocalizedStringFromTableInBundleを使ってアクセスしようかとも思ったのですが、こちらはまだ目的を達成できていません。

▲Xcode 11上で実験的に作成したAppleScriptアプリケーションのバンドル構造（左）。ローカライズしていない状態だとEnglishではなくBase.lprojが作成される。右はKeynote.app/Contents/Resources/ja.lprojフォルダの内容。stringsファイルが大量に存在している

AppleScript名：指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す.scptd

set targID to "com.apple.iWork.Keynote"

set curLang to first item of (choose from list bRes)
set aPath to retPathFromBundleID(targID) of me

set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

set aMDict to NSMutableDictionary’s new()

repeat with i in sList
　　set j to contents of i
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:j)
　　(aMDict’s addEntriesFromDictionary:aDict)
end repeat

return aMDict’s allKeys() as list
–> {"Interactive Bubble Chart", "Rehearse Slideshow", "PMT_ARGUMENT_1", "ACCRINTM_ARGUMENT_4_MODE_0", "Truck_378",….}

★Click Here to Open This Script　

指定フォルダ以下のWordのファイルをすべてPDFに書き出す

Posted on 6月 22, 2019 by Takaaki Naganoya

指定フォルダ以下のWordファイルをSpotlight機能でリストアップし、かたっぱしからPDF書き出しするAppleScriptです。

Wordの制御以外はありもののルーチンを組み合わせただけなので、とくにたいした手間がかかっているわけではありません。

逆に、Wordでファイルをオープンするという動作が割とたいへんだということがわかりました。Wordの書類によっては変換の必要があるようで、オープン時に形式を聞かれました。Word書類を作成したWordのバージョン次第のようですが、注意したいところです。Script中ではオートで変換してくれるように指定しておいたものの、それほど現場でさまざまな書類を処理したわけではありません。

処理する書類の古さや、作成したWordがどのOS上で作られたかによっては、さらに何かを追加指定する必要があるかもしれません（確認は作成時最新のWord v16.24＋macOS 10.12.6にて行いました）。

Spotlightでサーチして、指定フォルダ以下のWord書類をすべてリストアップしたあと、オープンしてPDFに書き出してクローズ、という動作を繰り返します。実にAppleScript「らしい」処理です。

これを、GUI Scripting（メニューやボタンの強制的な操作）だけで行うサンプルもあるようですが、GUI Scriptingは各アプリケーションの持っているAppleScriptのコマンド（AppleScript用語辞書に書かれています）に記載のない命令を「仕方なく」「例外的に」実行するだけのものであって、こういう「命令が最初から用意されているコマンド」を実行させてもメリットが何もありません。

GUI Scriptingを使ったScriptを評して「遅い」とか「確実性がない」と言われることが多いようですが、それはGUI Scriptingを使っているからです。GUI Scriptingを使うと、AppleScript本来の処理速度よりも10〜100倍ぐらい遅くなる（Cocoaの機能を活用している現代のAppleScriptだとそこから50倍ぐらい高速）ものなので、GUI Scriptingが（System Eventsを用いてメニューやボタンのクリックが行われている）多用されているAppleScriptは、本来の性能を活かせない可能性が高い（もっと高速に処理できる余地がある）ことを知っていただきたいところです。

本Scriptはそのような意味をこめて作成・公開したものです。

–> Download WordFileToPDFExporter Run-Only (Applet)

AppleScript名：WordFileToPDFExporter.scptd

— Created 2019-06-20 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use mdLib : script "Metadata Lib" version "2.0.0" –https://www.macosxautomation.com/applescript/apps/Script_Libs.html#Metadata_Lib

property NSString : a reference to current application’s NSString
property NSFileManager : a reference to current application’s NSFileManager
property NSOrderedSame : a reference to current application’s NSOrderedSame

set basePath to (path to desktop) as string –Target Folder to write PDFs
set origPath to POSIX path of (choose folder with prompt "Select Word File Orig Folder") –(path to documents folder)

–Find Word (.doc & .docx ) files by Spotlight
set resList to mdLib’s searchFolders:{origPath} searchString:("kMDItemContentTypeTree == %@ || kMDItemContentTypeTree == %@") searchArgs:{"org.openxmlformats.wordprocessingml.document", "com.microsoft.word.doc"}

if resList = {} then
　　–No Word Files or Spotlight index is broken
　　display dialog "There is no Word File within your folder.." buttons {"OK"} default button 1 with icon 1
　　return
end if

set resNumLen to length of ((length of resList) as string)

–Close Word Documents without saving
closeEveryWordDocs() of me

set sCount to 1 –saving file counter
set erCount to 0

–Loop by Word files
repeat with i in resList
　　set j to contents of i
　　set anAlias to (POSIX file j) as alias
　　set dRes to openWordFile(anAlias) of me
　　
　　if dRes is not equal to false then
　　　　set numStr to retZeroPaddingText(sCount, resNumLen + 1) of me
　　　　set newFile to basePath & numStr & "_" & (repFileNameExtension(dRes, ".pdf") of me)
　　　　saveWordDocAsPDF(newFile) of me
　　else
　　　　set erCount to erCount + 1
　　end if
　　
　　set sCount to sCount + 1 –Increment
end repeat

–Report Finish
if erCount = 0 then
　　activate
　　display dialog (sCount as string) & " Word files are converted to PDF.." buttons {"OK"} default button 1 with icon 1
else
　　if erCount = 1 then
　　　　set pluralStr to ""
　　else
　　　　set pluralStr to "s"
　　end if
　　
　　activate
　　display dialog (sCount as string) & " Word files are converted to PDF.." & return & "But " & (erCount as string) & "file" & pluralStr & " caused error to open" buttons {"OK"} default button 1 with icon 1
end if

–最前面のWord Documentを指定パスにPDFとして書き出す
on saveWordDocAsPDF(saveHFSpathStr)
　　tell application "Microsoft Word"
　　　　save as active document file name saveHFSpathStr file format format PDF
　　　　close front document saving no
　　end tell
end saveWordDocAsPDF

–指定パスのWord書類をオープンする
on openWordFile(aFileAlias)
　　tell application "Microsoft Word"
　　　　try
　　　　　　–このあたり、予想外にいろいろオープン処理を止めるダイアログ表示などがあるようなので試行錯誤が必要
　　　　　　open aFileAlias file converter open format auto
　　　　　　tell front document
　　　　　　　　set dName to name
　　　　　　end tell
　　　　on error
　　　　　　return false
　　　　end try
　　end tell
　　return dName
end openWordFile

–Word書類をすべてクローズ。未保存のものも破棄してクローズ
on closeEveryWordDocs()
　　try
　　　　tell application "Microsoft Word"
　　　　　　close every document without saving
　　　　end tell
　　end try
end closeEveryWordDocs

–ファイル名から拡張子を置換する
on repFileNameExtension(origName, newExt)
　　set aName to current application’s NSString’s stringWithString:origName
　　set theExtension to aName’s pathExtension()
　　if (theExtension as string) is not equal to "" then
　　　　set thePathNoExt to aName’s stringByDeletingPathExtension()
　　　　set newName to (thePathNoExt’s stringByAppendingString:newExt)
　　else
　　　　set newName to (aName’s stringByAppendingString:newExt)
　　end if
　　
　　return newName as string
end repFileNameExtension

–数値にゼロパディングしたテキストを返す
on retZeroPaddingText(aNum, aLen)
　　set tText to ("0000000000" & aNum as text)
　　set tCount to length of tText
　　set resText to text (tCount – aLen + 1) thru tCount of tText
　　return resText
end retZeroPaddingText

★Click Here to Open This Script　

Photosで選択中の写真をKeynoteの現在の書類の現在のスライド以降に配置 v2

Posted on 5月 27, 2019 by Takaaki Naganoya

Photosで選択中の写真をKeynoteで現在オープン中の書類の現在のスライド（ページ）以降に配置していくAppleScriptの改良版です。

作業の過程をiPhoneで写真撮影。撮影した写真を写真.app（Photos.app）経由でKeynote書類にまとめる作業を行なっていました。作業工程を時間こみで表示できないとわかりにくかったので、Keynoteの各スライドに時刻を入れるようにAppleScriptを書いておきました。

初版では写真.app（Photos）上の選択項目を一切ソートなどしなかったため、exifから取得した撮影日付で昇順ソートしています。

▲写真.app（Photos）上でKeynoteに配置したい写真を選択

▲あらかじめKeynote上でマスタースライド「画像（横長）」上のアイテムを編集しておくといいかも

▲AppleScriptによって写真.app上の写真をKeynote書類上に順次割り付け。タイトル部分にexifに記録されていた撮影時刻が入る

▲実行結果。写真.appから割り付けた写真は撮影日時でソートされている

AppleScript名：Photosで選択中の写真をKeynoteの現在の書類の現在のスライド以降に配置 v2

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/05/26
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use BPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html
use mdLib : script "Metadata Lib" version "2.0.0" –https://www.macosxautomation.com/applescript/apps/Script_Libs.html#Metadata_Lib

property NSUUID : a reference to current application’s NSUUID
property NSString : a reference to current application’s NSString
property SMSForder : a reference to current application’s SMSForder
property NSFileManager : a reference to current application’s NSFileManager

tell application "Keynote"
　　if (count every document) = 0 then return
end tell

–Photosで選択中の写真をすべて書き出してalias listを取得する
set aList to exportSelectedPhotoOnPhotos() of me
if aList = {} or aList = false then return

set aLen to length of aList

–書き出した画像の親フォルダを求めておく（あとで削除するため）
tell application "Finder"
　　set parentFol to parent of (item 1 of aList)
end tell

–exifから撮影日時を取得して2D List化
set aaList to {}
repeat with i in aList
　　set j to contents of i
　　set exifDate to readExifDateTimeOriginal(j) of me
　　set the end of aaList to {j, exifDate, (time string of exifDate)}
end repeat

–撮影日時で昇順ソート
set aaaList to sortList2DAscending(aaList, {2}) of me

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　set curNum to slide number –現在表示中のスライドの番号（ページ数）を取得する
　　　　end tell
　　　　
　　　　–Photosから取得した写真のアイテム数でループ
　　　　repeat with i from 1 to aLen
　　　　　　copy (item i of aaaList) to {aPhoto, aDateObj, creTime}
　　　　　　
　　　　　　set newSlide to make new slide at slide (curNum + i) with properties {base slide:master slide "画像（横長）"} –This item is localized!! Maybe a "Photo"
　　　　　　
　　　　　　tell newSlide
　　　　　　　　set object text of default title item to creTime
　　　　　　　　set file name of image 1 to aPhoto –place an image to image placeholder
　　　　　　end tell
　　　　　　
　　　　　　–配置画像を削除
　　　　　　tell application "Finder"
　　　　　　　　delete aPhoto –配置した写真を削除
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

–あとしまつ
tell application "Finder"
　　delete parentFol –画像のダウンロードフォルダを削除
end tell

–Photosで選択中のファイルをtmporaryフォルダに書き出してalias listで返す
on exportSelectedPhotoOnPhotos()
　　set dtPath to (path to temporary items) as text
　　set aUUID to NSUUID’s UUID()’s UUIDString() as text
　　
　　set dirPath to ((POSIX path of dtPath) & aUUID)
　　set fileManager to NSFileManager’s defaultManager()
　　set aRes to (fileManager’s createDirectoryAtPath:dirPath withIntermediateDirectories:true attributes:(missing value) |error|:(reference))
　　set dtPath to dtPath & aUUID
　　
　　tell application "Photos"
　　　　set a to selection
　　　　if a = {} then return {}
　　　　set aRes to (export a to file dtPath)
　　end tell
　　
　　tell application "Finder"
　　　　tell folder dtPath
　　　　　　set fList to (every file) as alias list
　　　　end tell
　　end tell
　　
　　if fList = {} then return false
　　return fList
end exportSelectedPhotoOnPhotos

–指定JPEG画像のExif情報からDateTimeOriginalを取得してAS dateオブジェクトに変換して返す
on readExifDateTimeOriginal(aTargFileAlias)
　　set theMetadata to readMetadataFrom(aTargFileAlias) of me
　　if theMetadata = false then return false
　　
　　set keysList to theMetadata’s allKeys()
　　
　　if "{Exif}" is not in (keysList as list) then return false
　　
　　set exifDate to theMetadata’s valueForKeyPath:"{Exif}.DateTimeOriginal"
　　if exifDate = missing value then return false
　　
　　set a to NSString’s stringWithString:exifDate
　　set {aDateStr, aTimeStr} to (a’s componentsSeparatedByString:" ") as list
　　set bDateStr to repChar(aDateStr, ":", "/") of me
　　set fullDate to date (bDateStr & " " & aTimeStr)
　　
　　return fullDate
end readExifDateTimeOriginal

–指定のファイルからメタデータを取得する
on readMetadataFrom(imageFile)
　　load framework
　　set {theRecord, theError} to SMSForder’s metadataFromImage:imageFile |error|:(reference)
　　if theRecord = missing value then — there was a problem, so extract the error description
　　　　error false
　　else
　　　　return theRecord
　　end if
end readMetadataFrom

–文字置換
on repChar(origText as string, targChar as string, repChar as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

–入れ子のリストを昇順ソート
on sortList2DAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end sortList2DAscending

–入れ子のリストを降順ソート
on sortList2DDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end sortList2DDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　load framework
　　
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　set resList to (SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as {missing value, list}
　　
　　return resList
end sort2DList

★Click Here to Open This Script　

Photosで選択中の写真をKeynoteの現在の書類の現在のスライド以降に配置

Posted on 5月 27, 2019 by Takaaki Naganoya

Photosで選択中の写真をKeynoteで現在オープン中の書類の現在のスライド（ページ）以降に配置していくAppleScriptです。

作業の過程をiPhoneで写真撮影。撮影した写真を写真.app（Photos.app）経由でKeynote書類にまとめる作業を行なっていました。作業工程を時間こみで表示できないとわかりにくかったので、Keynoteの各スライドに時刻を入れるようにAppleScriptを書いておきました（同じ作業が二度あるかは不明ですが、二度目からは明らかに時間の節約。つまり時間の貯金ができることになります）。

写真.app（Photos）上でKeynoteに配置したい写真を選択しておき、本Scriptを実行します。

Keynote書類上に新規スライドを追加し、撮影時刻と写真を配置していきます。

実行直後にPhotosで選択中の写真をファイルに書き出すため、若干待たされます。

＃　複数のマシンでiCloudを介して写真を同期した場合に、写真.appのライブラリの写真の並び順は撮影日時どおりにならないようなので、明示的にソートしておく必要があるようです

ちなみに、写真の自作キーボードキットはこの後フットペダルにつなぎなおして、PPSSPP用の足踏みコントローラー化する予定です（「戦場の絆ポータブル」用）。

AppleScript名：Photosで選択中の写真をKeynoteの現在の書類の現在のスライド以降に配置

property NSUUID : a reference to current application’s NSUUID
property NSString : a reference to current application’s NSString
property NSFileManager : a reference to current application’s NSFileManager

tell application "Keynote"
　　if (count every document) = 0 then return
end tell

–Photosで選択中の写真をすべて書き出してalias listを取得する
set aList to exportSelectedPhotoOnPhotos() of me
if aList = {} or aList = false then return

set aLen to length of aList

–書き出した画像の親フォルダを求めておく（あとで削除するため）
tell application "Finder"
　　set parentFol to parent of (item 1 of aList)
end tell

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　set curNum to slide number –現在表示中のスライドの番号（ページ数）を取得する
　　　　end tell
　　　　
　　　　–Photosから取得した写真のアイテム数でループ
　　　　repeat with i from 1 to aLen
　　　　　　set aPhoto to contents of item i of aList
　　　　　　set newSlide to make new slide at slide (curNum + i) with properties {base slide:master slide "画像（横長）"} –This item is localized!! Maybe a "Photo"
　　　　　　set creTime to getCreationTime(aPhoto) of me
　　　　　　tell newSlide
　　　　　　　　set object text of default title item to creTime
　　　　　　　　set file name of image 1 to aPhoto –place an image to image placeholder
　　　　　　end tell
　　　　　　
　　　　　　–配置画像を削除
　　　　　　tell application "Finder"
　　　　　　　　delete aPhoto –配置した写真を削除
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

–あとしまつ
tell application "Finder"
　　delete parentFol –画像のダウンロードフォルダを削除
end tell

–指定のaliasからExif情報の作成日の時刻情報を返す
on getCreationTime(anAlias)
　　set exifDate to readExifDateTimeOriginal(anAlias) of me
　　return time string of exifDate
end getCreationTime

–指定のファイルからメタデータを取得する
on readMetadataFrom(imageFile)
　　load framework
　　set {theRecord, theError} to current application’s SMSForder’s metadataFromImage:imageFile |error|:(reference)
　　if theRecord = missing value then — there was a problem, so extract the error description
　　　　error false
　　else
　　　　return theRecord
　　end if
end readMetadataFrom

★Click Here to Open This Script　

指定フォルダ内のファイルのうち、指定UTIに該当するものをすべて取得してフルパスを返す

Posted on 4月 13, 2019 by Takaaki Naganoya

指定フォルダ内のファイルのうち、指定のUTIに該当するものをすべて取得してフルパス（file/POSIX）で返すAppleScriptです。

指定フォルダの直下のみを走査し、サブフォルダ内は走査しません。調べてみるとUTIでファイルを絞り込む機能は存在していないようなので（見落としているだけ？）、すべてファイルを取得してからループでUTIを調べつつ該当するかどうかチェックしています。

書けば書くほど「それってSpotlightでよくね？」という気がしますが、確実に取得したい（Spotlightインデックスが破損していたり、サーバー上のファイルではSpotlightが効かない場合もある）場合に使うとよいでしょうか。

AppleScript名：指定フォルダ内のファイルのうち、指定UTIに該当するものをすべて取得してフルパスを返す

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/13
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles

set aUTI to "com.adobe.pdf"
set libPath to ((path to documents folder) as string)
set posixLibPath to POSIX path of libPath

set f1List to getFilepathListByUTI(posixLibPath, aUTI, "file") of me
–> {file "Cherry:Users:me:Documents:0718kenpo.pdf", file "Cherry:Users:me:Documents:2013-09Rekihaku.pdf", file "Cherry:Users:maro:Documents:airserver.pdf"}

set f2List to getFilepathListByUTI(posixLibPath, aUTI, "POSIX") of me
–> {"/Users/me/Documents/0718kenpo.pdf", "/Users/me/Documents/2013-09Rekihaku.pdf", "/Users/me/Documents/airserver.pdf"}

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((current application’s NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((current application’s NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

★Click Here to Open This Script　

指定フォルダ内のファイルのうち、指定拡張子リストに入っているものをすべて取得してフルパスを返す

Posted on 4月 12, 2019 by Takaaki Naganoya

指定フォルダに入っているファイルのうち、指定拡張子リストに該当するものをフルパスで返すAppleScriptです。

macOS 10.6以降の64ビット化されたFinderは動作が遅いため、大量のファイル情報を取得するなどの用途には不向きです。このため、「（ファイル選択を取得する以外の）ファイル処理にはFinderを使わない」のが現在のAppleScriptのセオリーとなっています。

本Scriptでは、~/Library/Script Libraries/フォルダの存在確認と、その中に格納されている「scpt」「scptd」の拡張子を持つAppleScript書類ファイルのリストアップを高速に行います。

AppleScript名：指定フォルダ内のファイルのうち、指定拡張子リストに入っているものをすべて取得してフルパスを返す

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles

set anExpList to {"scpt", "scptd"} — no dot
set libPath to (((path to library folder from user domain) as string) & "Script Libraries:")
set posixLibPath to POSIX path of libPath
set fList to getFilepathListByExt(posixLibPath, anExpList) of me

on getFilepathListByExt(aFol, aExtList as list)
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFol isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFol
　　set theOptions to ((current application’s NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((current application’s NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value)
　　set thePred to NSPredicate’s predicateWithFormat_("pathExtension.lowercaseString IN %@", aExtList)
　　set anArray to (urlArray’s filteredArrayUsingPredicate:thePred)
　　return anArray as {missing value, list}
end getFilepathListByExt

★Click Here to Open This Script　

機械学習で学習したMSの画像を連邦・ジオン軍判定してフォルダ分け v2

Posted on 11月 20, 2018 by Takaaki Naganoya

Create MLでガンダムのMS画像（連邦、ジオン区分け）を学習したCore ML Modelをもとに、画像をどちらの軍所属機体かを判定してフォルダ分けするAppleScriptです。

機械学習（深層学習）データをもとに判定を行って対話型処理ではなくバッチ処理的なフローでデータを「なんとなく」推論して区分けを行うサンプルです。非力なIOT機器が機械学習データをもとに推論処理できるぐらいなので、機械学習データを使ってAppleScriptで推論処理できないはずがありません。推論処理時間もさほどかからず、機械学習データを一括処理的なワークフローの中で利用することが可能です。

例によって「戦場の絆」の公式ページから落としてきたMSの画像を連邦軍とジオン軍、および両軍の鹵獲機体の４フォルダに分けてCreate MLで学習させてみました。

実行するとMS画像が入っているフォルダ（各自ご用意ください）と、連邦軍機体（efsf）およびジオン軍機体（zeon）を仕分けるフォルダを聞かれます。あとはプログラム側がなんとなく推論して仕分けを行います。

前回掲載のモデルもそうですが、きちんと学習後にテストデータで評価を行っています。だいたい８割ぐらいのヒット率ではあるものの、特定の画像については間違えることがあらかじめわかっています。

実行にあたっては、macOS 10.14上でCoreML Modelを組み込んだフレームワーク「msDetector.framework」をインストールして、本ScriptをScript Debugger上で動作させてください。

–> Download msDetector.framework (To ~/Library/Frameworks/)

–> Download msDetector (Code Signed executable AppleScript applet with Framework and libraries in its bundle)

Core MLで判定時に詳細なデータを出力させ、その可能性が0.8を上回るものだけを処理するようにしてみました。ただ、全力で間違った判定を行うケースもあるため、単なる「気休め」です。

テストデータでは、連邦軍側が72機体中間違いが９個（正解87.5%）、ジオン軍側が57機体中間違いが３個（正解95%）。鹵獲機体のデータを排除すると、もう少しいい値が出るかもしれません。ただ、学習させたデータとほぼ同じデータ（数が少ない）で再度判定を行っているだけなので、このぐらいの確度が出ないと逆に困ります。

また、確度が高くないものは排除するように処理したので、確度が低い機体の画像バリエーションを増やして学習画像数を足すと正解の確率が上がるのではないか、などと「なんとなく」考えています。

Create MLでは、もっときちんとした表データやタグ付き自然言語テキストデータ（日本語だと形態素への区分けはあらかじめやっておく必要アリ？）の学習が行えるようなので（自然言語テキストの学習例は英語のものしか見かけないけれども）いろいろやっておきたいところです。

今回は「アニメとかゲームに出てくるMSの画像」の判定という、実用性をまったく考えないで行なってみたものですが、自分の身の回りで有用性の高そうな処理といえば……アイコンやプレゼン用資料の作成画像を学習させておおまかなジャンル分けをしておき（メール系のアイコンとか）、未知のアイコン素材をダウンロードしてきたら機械学習データをもとに自動でフォルダ分けするとかでしょうか。

さすがにアイコン画像だとデフォルメされすぎていて、MicrosoftのAzure Computer Vision APIとかでも画像認識してくれなさそうなので。

AppleScript名：機械学習で学習したMSの画像の連邦軍、ジオン軍判定してフォルダ分け v2.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/11/20
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.7" — Mojave (10.14) or later & Script Debugger
use framework "Foundation"
use framework "AppKit"
use framework "msDetector"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

set aFol to POSIX path of (choose folder with prompt "Choose MS Image folder to go!")
set efsfFol to POSIX path of (choose folder with prompt "EFSF folder")
set zeonFol to POSIX path of (choose folder with prompt "Zeon folder")

–指定フォルダ以下のファイルをすべて取得（再帰ですべて取得）
set aSel to retFullpathsWithinAFolderWithRecursive(aFol) of me

–取得したファイルリストを指定UTIでフィルタリング
set filRes2 to filterPOSIXpathListByUTI(aSel, "public.image") of me

–機械学習モデルを用いて区分けを行い、任意の画像の連邦軍（efsf）、ジオン軍（zeon）へのフォルダ分け（コピー）
set msClassifier to current application’s msClassify’s alloc()’s init()

repeat with i in filRes2
　　set aFile to contents of i
　　set aImage to (current application’s NSImage’s alloc()’s initWithContentsOfFile:aFile)
　　
　　set resDict to (msClassifier’s ImageClassifierWithImageAndRetDict:aImage) –returns NSDictionary
　　
　　–Dictinaryのvalueをソートして、最も値の大きいvalueのkeyを求める
　　set sortedArray to (current application’s NSMutableArray’s arrayWithArray:(resDict’s allValues()))
　　(sortedArray’s sortUsingSelector:"compare:")
　　set aRes to (last item of (sortedArray as list)) –末尾のアイテムが一番値の大きい数値
　　set resKey to first item of ((resDict’s allKeysForObject:aRes) as list) –最大値をもとにKeyを求める
　　
　　–可能性の高いものだけ処理してみる（自信たっぷりに全力で間違えることもけっこうある）
　　if (aRes as real) > 0.8 then
　　　　if resKey begins with "efsf" then
　　　　　　–efsf & efsf_stolen
　　　　　　set aRes to (my copyFileAt:aFile toFolder:efsfFol)
　　　　else
　　　　　　–zeon & zeon_stolen
　　　　　　set aRes to (my copyFileAt:aFile toFolder:zeonFol)
　　　　end if
　　end if
end repeat

–POSIX path listから指定UTIに含まれるものをPOSIX pathのリストで返す
on filterPOSIXpathListByUTI(aList, targUTI)
　　set newList to {}
　　repeat with i in aList
　　　　set j to contents of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, targUTI)
　　　　if utiRes is not equal to {} then
　　　　　　set the end of newList to j
　　　　end if
　　end repeat
　　return newList
end filterPOSIXpathListByUTI

–指定フォルダ以下のすべてのファイルを再帰で取得
on retFullpathsWithinAFolderWithRecursive(aFol)
　　set anArray to NSMutableArray’s array()
　　set aPath to NSString’s stringWithString:aFol
　　set dirEnum to NSFileManager’s defaultManager()’s enumeratorAtPath:aPath
　　
　　repeat
　　　　set aName to (dirEnum’s nextObject())
　　　　if aName = missing value then exit repeat
　　　　set aFullPath to aPath’s stringByAppendingPathComponent:aName
　　　　anArray’s addObject:(aFullPath as string)
　　end repeat
　　
　　return anArray as list
end retFullpathsWithinAFolderWithRecursive

on copyFileAt:POSIXPath toFolder:folderPath
　　set POSIXPath to NSString’s stringWithString:POSIXPath
　　set folderPOSIXPath to NSString’s stringWithString:folderPath
　　set theName to POSIXPath’s lastPathComponent()
　　set newPath to folderPOSIXPath’s stringByAppendingPathComponent:theName
　　set fileManager to NSFileManager’s defaultManager()
　　set theResult to fileManager’s copyItemAtPath:POSIXPath toPath:newPath |error|:(missing value)
　　return (theResult as integer = 1)
end copyFileAt:toFolder:

★Click Here to Open This Script　

ハッシュ値から、メモリースティックに保存されたReplay Dataのステージ名とプレイ日時を求める v3

Posted on 10月 30, 2018 by Takaaki Naganoya

PSPのゲーム「戦場の絆ポータブル」のセーブデータについているステージ別のプレビュー画像のハッシュ値から対戦ステージと対戦日時を抽出してタブ区切りテキストで出力するAppleScriptです。

保存された対戦データの内容を集計するために作成したものです。

PSPでメモリースティックに保存された対戦データには、すべて同じファイル名（ICON0.PNG）で異なる画像が添付されていました。ファイル名で対戦ステージを判定しようにも同じファイル名なので区別できません。

そこで、Spotlightの機能を用いて各セーブデータの「ICON0.PNG」をピックアップし、画像の内容のハッシュ値（SHA-1）を計算して、対戦ステージ内容を判定しました。

直近の対戦データをメモリースティック経由でMacに読み込み、本Scriptで分析してみたところ、

ジャブロー地上	2017年9月18日月曜日 14:42:48
ジャブロー地上	2017年9月18日月曜日 14:50:02
ジャブロー地上	2017年9月18日月曜日 14:55:22
タクラマカン砂漠	2017年9月18日月曜日 15:02:32
サイド7	2017年9月18日月曜日 15:09:36
ジャブロー地下	2017年9月18日月曜日 15:17:06
ジャブロー地上	2017年9月18日月曜日 15:31:08
サイド7	2017年9月18日月曜日 15:38:28
ジャブロー地上	2017年9月18日月曜日 15:51:52
ジャブロー地上	2018年1月2日火曜日 16:13:30
サイド7	2018年1月2日火曜日 16:23:04
ジャブロー地下	2018年1月2日火曜日 16:57:22

のようになりました。正月と秋分の日に親戚で集まったときに甥っ子と対戦した様子がありありと記録されています。

本Scriptはたまたまゲームのセーブデータの集計を行っていますが、同様の形式のデータを集計したい場合には使えそうです。

–> md5Lib.framework（To ~/Library/Frameworks）

AppleScript名：チェックサム値から、メモリースティックに保存されたReplay Dataのステージ名とプレイ日時を求める v3.1

— Created 2015-04-17 by Takaaki Naganoya
— Modified 2018-10-29 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "md5Lib" –https://github.com/JoeKun/FileMD5Hash
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html
use mdLib : script "Metadata Lib" version "2.0.0" –https://www.macosxautomation.com/applescript/apps/

property FileHash : a reference to current application’s FileHash
property SMSForder : a reference to current application’s SMSForder
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray

–各SAVEDATAフォルダ中の「ICON0.PNG」のSHA-1ハッシュ値とステージ名の対応表
set shaArray to NSMutableArray’s arrayWithArray:{{stageName:"ニューヤーク", sha1:"dbb9e8e26e96dbb4dd3198e55b6cde41aba8e0a8"}, {stageName:"鉱山都市", sha1:"72f35456504b1957ec85fb6a1597ac1a2baa2ee9"}, {stageName:"グレートキャニオン", sha1:"9de93e8b853fe153bc73066fb07481c774499960"}, {stageName:"サイド7", sha1:"be22fa949bfd78b0cd97596929f07ce4ec501d7b"}, {stageName:"タクラマカン砂漠", sha1:"5284dc5f0f7a53ee5677908f66da1e00b80f76b6"}, {stageName:"トリントン・タワー", sha1:"9f080853dac45ecaf1672ff2230f2b9a80a00eb4"}, {stageName:"ジャブロー地下", sha1:"a93550099419f52444cf77366773192d0bf5f848"}, {stageName:"ヒマラヤ", sha1:"877f998d608dd267c380e59a17b2a95a139baef5"}, {stageName:"ジャブロー地上", sha1:"8c4ee44e8f2fbcbf061e6d5ea2b202b08f42c59a"}}

load framework

set apPath1 to choose folder with prompt "リプレイデータが入っているフォルダを選択してください"
set aRes to perform search in folders {apPath1} predicate string "kMDItemFSName == %@" search arguments {"ICON0.PNG"}

set outList to {}
set errorList to {}

repeat with i in aRes
　　set j to contents of i
　　set sumRes to (FileHash’s sha1HashOfFileAtPath:(j)) as string
　　
　　–チェックサムからステージ名を検索する
　　set aPredStr to "sha1 == ’" & sumRes & "’"
　　set aPredicate to (NSPredicate’s predicateWithFormat:aPredStr)
　　set filteredArray to (shaArray’s filteredArrayUsingPredicate:aPredicate)
　　
　　if filteredArray as list = {} then
　　　　set the end of errorList to j
　　else
　　　　set tmpStage to (filteredArray’s valueForKey:"stageName") as string
　　　　
　　　　set fAttrib to (NSFileManager’s defaultManager()’s attributesOfItemAtPath:j |error|:(missing value))
　　　　set cDat to (fAttrib’s fileCreationDate()) as date
　　　　
　　　　set tmpList to {tmpStage, cDat}
　　　　
　　　　if tmpList is not in outList then
　　　　　　set the end of outList to tmpList
　　　　end if
　　end if
end repeat

–2D Listのソート
set sortIndexes to {1} –Key Item id: begin from 0
set sortOrders to {true} –ascending = true
set sortTypes to {"compare:"}
set out2List to (SMSForder’s subarraysIn:(outList) sortedByIndexes:sortIndexes ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list

–2D Listをタブ区切りテキストに変換して返す
set aText to retItemDelimedAndParagraphDelimedText(out2List, tab, return) of me

–入れ子のリストを、アイテム間のデリミタとパラグラフ間のデリミタを指定してテキスト化
–というか、入れ子のリストをタブ区切りテキストにするのが目的
on retItemDelimedAndParagraphDelimedText(aList, itemDelim, paragraphDelim)
　　set aText to ""
　　
　　repeat with i in aList
　　　　set aStr to retDelimedText(i, itemDelim) of me
　　　　set aText to aText & aStr & paragraphDelim
　　end repeat
　　
　　return aText
end retItemDelimedAndParagraphDelimedText

on retDelimedText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retDelimedText

★Click Here to Open This Script　

ファイル作成日、修正日を変更する

Posted on 10月 29, 2018 by Takaaki Naganoya

指定ファイルの作成日、修正日を変更するAppleScriptです。

以前はsetFileコマンド（Xcodeのcommand lineユーティリティーをインストールすると入る）で行うパターンを掲載していたのですが、NSFileManagerの方が楽にできるのと、どの実行環境でも（開発ツールが入っていなくても）実行できていいと思います。

AppleScript名：ファイル作成日、修正日を変更する

— Created 2018-05-30 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set aFile to POSIX path of (choose file)
set targDate to current date
changeFileCreationDate(targDate, aFile) of me
changeFileModDate(targDate, aFile) of me

–指定パスのファイルの作成日時を変更する
on changeFileCreationDate(aDate, aFile)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithObject:aDate forKey:(current application’s NSFileCreationDate)
　　set aFM to current application’s NSFileManager’s defaultManager()’s setAttributes:aDic ofItemAtPath:(POSIX path of aFile) |error|:(missing value)
end changeFileCreationDate

–指定パスのファイルの修正日時を変更する
on changeFileModDate(aDate, aFile)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithObject:aDate forKey:(current application’s NSFileModificationDate)
　　set aFM to current application’s NSFileManager’s defaultManager()’s setAttributes:aDic ofItemAtPath:(POSIX path of aFile) |error|:(missing value)
end changeFileModDate

★Click Here to Open This Script　

NSURLからBookmarkを作成するじっけん

Posted on 10月 3, 2018 by Takaaki Naganoya

NSURLからbookmarkDataを作成、あるいはbookmarkDataからNSURLを復元する実験を行うAppleScriptです。

POSIX pathのファイルパスをplistに保存するような場合に、元のファイルの場所が変わったり名前が変わったりすると、追跡できなくなってしまいます。

　「aliasをpropertyに保存していた時代には、自動で追跡してもらえたんだけどなー」

そのため、plistからPOSIX pathを取り出したあとは逐一「本当にそのパスにファイルが存在するか」をチェックしていたのですが、

　「もっといいものがあるよ」

と教えていただいたのが、このbookmarkDataです。

NSURL（filePathのほう）をbookmarkDataにすると、元のファイルの名前が変わったり場所（パス）が変わったりしても追跡してくれます。ファイルのノード番号をベースに追跡しているのでしょうか。とにかく、追跡してもらえるのはいいことです。

本AppleScriptでは、POSIX pathをNSURLを経由してboookmarkDataに変換し、オリジナルのファイルをリネームして、bookmarkDataからNSURL–> POSIX pathを取得。得られたパスがリネーム後のものと同じかどうかをチェックするものです。

テストを行った範囲では、想定どおりに使えているようです。

AppleScript名：POSIX path–>Bookmark & bookmark –> POSIX path.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/10/02
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSFileManager : a reference to current application’s NSFileManager
property NSURLBookmarkResolutionWithoutUI : a reference to current application’s NSURLBookmarkResolutionWithoutUI

set aFile to POSIX path of (choose file)
–> "/Users/me/Desktop/9E37BC8B-3920-4844-A6D1-0DCA183D744D.png"

–POSIX path –> URL –> Bookmark
set aURL to |NSURL|’s fileURLWithPath:aFile
set aBookmarkData to aURL’s bookmarkDataWithOptions:0 includingResourceValuesForKeys:(missing value) relativeToURL:(missing value) |error|:(missing value)

–Rename Original File
set fRes to renameFileItem(aFile, "test_test_test") of me
if fRes = false then error "Error: File already exists."

–Bookmark –> URL –> POSIX path
set bURL to |NSURL|’s URLByResolvingBookmarkData:aBookmarkData options:(NSURLBookmarkResolutionWithoutUI) relativeToURL:(missing value) bookmarkDataIsStale:(missing value) |error|:(missing value)
set bPath to (bURL’s |path|()) as string
–> "/Users/me/Desktop/test_test_test.png"

–File Rename Routine
on renameFileItem(aPOSIX, newName)
　　set theNSFileManager to NSFileManager’s defaultManager()
　　set POSIXPathNSString to NSString’s stringWithString:(aPOSIX)
　　
　　–Make New File Path
　　set anExtension to POSIXPathNSString’s pathExtension()
　　set newPath to (POSIXPathNSString’s stringByDeletingLastPathComponent()’s stringByAppendingPathComponent:newName)’s stringByAppendingPathExtension:anExtension
　　
　　–Rename
　　if theNSFileManager’s fileExistsAtPath:newPath then
　　　　return false
　　else
　　　　set theResult to theNSFileManager’s moveItemAtPath:POSIXPathNSString toPath:newPath |error|:(missing value)
　　　　if (theResult as integer = 1) then
　　　　　　return (newPath as string)
　　　　else
　　　　　　return false
　　　　end if
　　end if
end renameFileItem

★Click Here to Open This Script　

Stickiesからのデータ取り出し v2

Posted on 9月 6, 2018 by Takaaki Naganoya

スティッキーズ（Stickies.app）のデータをまとめて引っこ抜いてListに入れるAppleScriptです。色情報、１行目の内容をタイトルとみなしてタイトル情報も付加して出力するようにしてみました。

オープンソースのStickiesViewerをFramework化したstickiesLib.frameworkを経由してデータを読み出します。データベースファイルから情報を直接読み取るので、Stickies.appが起動している必要はありません。

–> Download stickiesLib.framework（To ~/Library/Frameworks/）

–> {creationDate:date “2006年1月15日日曜日 11:02:32″, aTitle:”WX-310Kの画像サイズ”, modificationDate:date “2006年1月15日日曜日 11:03:09″, aContents:”WX-310Kの画像サイズ
ケータイ：120×160
壁紙：240×320″, colorName:”Yellow”}

StickiesDatabaseからまとめて一括で全部抽出するので、個別に何かのIDで指定して抽出するといった動作にはなりません。

93個のスティッキーズ書類（93個のウィンドウが表示されている状態、１つのDBを指定）から、全データを取得して本AppleScriptで0.1秒程度です。

AppleScript名：Stickiesからのデータ取り出し v2.scptd

use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use framework "AppKit"
use framework "stickiesLib"
use scripting additions

property NSColor : a reference to current application’s NSColor
property |NSURL| : a reference to current application’s |NSURL|
property SVReader : a reference to current application’s SVReader
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray

set sRes to retStickiesData() of me
–>
(*
{{creationDate:date "2006年1月15日日曜日 11:02:32", aTitle:"WX-310Kの画像サイズ", modificationDate:date "2006年1月15日日曜日 11:03:09", aContents:"WX-310Kの画像サイズ
ケータイ：120×160
壁紙：240×320", colorName:"Yellow"}, ….}
*)

on retStickiesData()
　　set dbPath to POSIX path of (path to library folder from user domain) & "StickiesDatabase"
　　set aExt to (NSFileManager’s defaultManager()’s fileExistsAtPath:dbPath) as boolean
　　
　　if aExt = false then
　　　　set dbPath to POSIX path of (choose file with prompt "Select StickiesDatabase file")
　　end if
　　
　　set aURL to |NSURL|’s fileURLWithPath:dbPath
　　set aStickDB to SVReader’s notesWithContentsOfURL:aURL
　　
　　set aList to aStickDB as list
　　
　　–スティッキーズの色データ
　　set cList to {{"Yellow", {254, 244, 156}}, {"Blue", {173, 244, 255}}, {"Green", {178, 255, 161}}, {"Pink", {255, 199, 199}}, {"Purple", {182, 202, 255}}, {"Gray", {238, 238, 238}}}
　　
　　
　　set outArray to NSMutableArray’s new()
　　
　　repeat with i in aList
　　　　set anAttrStr to i’s attributedString()
　　　　set aStr to (anAttrStr’s |string|()) as string
　　　　
　　　　set curTitle to first paragraph of aStr
　　　　
　　　　set aColor to i’s |color|()
　　　　set cDate to i’s dateCreated() as date
　　　　set mDate to i’s dateModified() as date
　　　　
　　　　set c1List to retColListFromNSColor(aColor, 255) of me
　　　　
　　　　–Find Color Name
　　　　set hitF to false
　　　　repeat with ii in cList
　　　　　　set {colName, colList} to ii
　　　　　　if c1List = colList then
　　　　　　　　set hitF to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　if hitF = false then error "Color name did not hit"
　　　　
　　　　set curName to colName
　　　　(outArray’s addObject:{creationDate:cDate, modificationDate:mDate, aContents:aStr, colorName:curName, aTitle:curTitle})
　　　　
　　end repeat
　　
　　return outArray as list
end retStickiesData

on retColorFromRGBnum(r, g, b)
　　return (NSColor’s colorWithCalibratedRed:r / 255.0 green:g / 255.0 blue:b / 255.0 alpha:1.0)
end retColorFromRGBnum

–NSColorからrgbの8bitの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

★Click Here to Open This Script　

心配性のリネームプログラム

Posted on 8月 15, 2018 by Takaaki Naganoya

安全策の上に安全策を講じた、心配性のファイル名称変更AppleScriptです。

基本的にはファイルのリネームプログラムであり、Finder上で選択中のファイルについてリネームを行います。

ただし、ファイルのリネーム時に同じファイル名のファイルがすでに存在していて、普段であれば衝突回避のために子番号を振るなどの対処を行うところが、そういう対応が許されていないようなケースに直面しました。

同じフォルダ内にある３つの画像ファイルを、名称が衝突するような他の名称に変更するようなケースです。

1.jpg --> 2.jpg（すでに2.jpgが存在）
2.jpg --> 3.jpg（すでに3.jpgが存在）
3.jpg --> 1.jpg

少々、頭を抱えてしまいました。

そこで、テンポラリフォルダをファイル１つごとに作成し、テンポラリフォルダにファイルを移動。

1.jpg --> /temp/uuid0001/1.jpg

そのタコツボ的なテンポラリフォルダの中でリネームを実施。

/temp/uuid0001/1.jpg --> /temp/uuid0001/2.jpg

リネームしたファイルを元のフォルダに戻すというリネームルーチンを作成した次第です。もちろん、作成したテンポラリフォルダは削除しておきます。

/temp/uuid0001/2.jpg --> 2.jpg

最近はこのAppleScriptのように、ファイル操作処理はNSFileManagerで実行し、Finderには「選択中のファイルの情報を取得」ぐらいしか行わせていません。そのため、ファイル処理が従来よりもはるかに高速に行えて、ちょっと楽しいぐらいです。

数千ファイルのコピー（込み入ったルールに従いJANコードなどのデータを参照して名前を決定したり、フォルダ名を製品名で作成したりとか）が1・２秒というオーダーで終わってしまうのは、SSD上で処理しているせいもありますが、NSFileManager経由でのファイル処理を行っているおかげです（64bit化したCocoa Finderはとにかく処理が遅いのでAppleScriptからのファイル操作用に使うとダメ）。

AppleScript名：tempフォルダに移動しつつリネームして、終了後に元フォルダに戻す v2.scptd

— Created 2018-08-14 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property tResList : {}
property tFol : ""
property newNameTemplate : "test_"

set tResList to {}
set tFol to POSIX path of (path to temporary items)

tell application "Finder"
　　set aSel to selection as alias list
　　if aSel = {} then
　　　　display notification "No Selection"
　　　　return
　　end if
end tell

–コピー元ファイルの親フォルダを求める（リネーム後に戻す）
set origFol to POSIX path of (contents of first item of aSel)
set origFolStr to ((NSString’s stringWithString:origFol)’s stringByDeletingLastPathComponent()) as string

–一時フォルダに移動してリネーム
set aCount to 1
repeat with i1 in aSel
　　set j1 to POSIX path of (contents of i1)
　　set newName to newNameTemplate & (aCount as string)
　　set j1Res to renameSafely(j1, newName) of me
　　set the end of tResList to (j1Res as string)
　　set aCount to aCount + 1
end repeat

–元のフォルダに戻して一時フォルダ削除
repeat with i2 in tResList
　　set j2 to contents of i2
　　set j2Res to (my moveFileAt:j2 toFolder:origFolStr)
　　set j2Res to deleteParentFol(j2) of me
end repeat

–安全なリネーム（個別のテンポラリフォルダに移動してリネーム）
on renameSafely(aFile, newName)
　　–set tFol to POSIX path of (path to temporary items)
　　set aUUIDstr to ((NSUUID’s UUID()’s UUIDString()) as string)
　　set aTmpFol to tFol & aUUIDstr
　　
　　set dRes to makeDirAbsolutely(aTmpFol) of me
　　set mRes to my moveFileAt:aFile toFolder:aTmpFol
　　
　　set aStr to (NSString’s stringWithString:aFile)
　　set newFullPath to aTmpFol & "/" & aStr’s lastPathComponent()
　　set aExt to aStr’s pathExtension()
　　
　　set fRes to renameFileItem(newFullPath, newName) of me
　　
　　set renamedPath to aTmpFol & "/" & newName & "." & aExt
　　
　　return renamedPath
end renameSafely

–指定パスににフォルダを作成する
on makeDirAbsolutely(dirStr)
　　set fileManager to NSFileManager’s defaultManager()
　　set aRes to fileManager’s createDirectoryAtPath:dirStr withIntermediateDirectories:true attributes:(missing value) |error|:(reference)
　　copy aRes to {aFlag, aError}
　　return aFlag as boolean
end makeDirAbsolutely

on moveFileAt:POSIXPath toFolder:folderPOSIXPath
　　set POSIXPath to NSString’s stringWithString:POSIXPath
　　set theName to POSIXPath’s lastPathComponent()
　　set folderPOSIXPath to NSString’s stringWithString:folderPOSIXPath
　　set theNewPath to folderPOSIXPath’s stringByAppendingPathComponent:theName
　　set fileManager to NSFileManager’s defaultManager()
　　set theResult to fileManager’s moveItemAtPath:POSIXPath toPath:theNewPath |error|:(missing value)
　　return theNewPath
end moveFileAt:toFolder:

on renameFileItem(aPOSIXpath as string, newName as string)
　　set theNSFileManager to NSFileManager’s defaultManager()
　　set POSIXPathNSString to NSString’s stringWithString:(aPOSIXpath)
　　
　　–Make New File Path
　　set anExtension to POSIXPathNSString’s pathExtension()
　　set newPath to (POSIXPathNSString’s stringByDeletingLastPathComponent()’s stringByAppendingPathComponent:newName)’s stringByAppendingPathExtension:anExtension
　　
　　–Rename
　　if theNSFileManager’s fileExistsAtPath:newPath then
　　　　return false
　　else
　　　　set theResult to theNSFileManager’s moveItemAtPath:POSIXPathNSString toPath:newPath |error|:(missing value)
　　　　if (theResult as integer = 1) then
　　　　　　return (newPath as string)
　　　　else
　　　　　　return false
　　　　end if
　　end if
end renameFileItem

on deleteParentFol(aPOSIX)
　　set aStr to NSString’s stringWithString:aPOSIX
　　set parentFol to aStr’s stringByDeletingLastPathComponent()
　　set aRes to deleteItemAt(parentFol) of me
　　return aRes
end deleteParentFol

on deleteItemAt(aPOSIX)
　　set theNSFileManager to NSFileManager’s defaultManager()
　　set theResult to theNSFileManager’s removeItemAtPath:(aPOSIX) |error|:(missing value)
　　return (theResult as integer = 1) as boolean
end deleteItemAt

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSFileManager

アラートダイアログ上にCollection Viewを表示

アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

指定のPDFからTOCを削除する

クリップボード内のテキストをSayコマンドで読み上げて音声ファイル化

指定アプリケーションの指定ロケールのフォルダ内の該当キーワードを含むstringsファイル情報を抽出する

指定アプリケーション内の全Localeの指定stringsファイル内の指定キーの値を取得する

指定フォルダ以下のすべてのファイルとフォルダ名から絵文字を除去する v2

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

指定フォルダ以下のWordのファイルをすべてPDFに書き出す

ファイル作成日、修正日を変更する

NSURLからBookmarkを作成するじっけん

Stickiesからのデータ取り出し v2

心配性のリネームプログラム