use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

script spd
　　property aList : {}
　　property bList : {}
end script

–Mesurement data gen.
set (aList of spd) to {}
repeat with i from 1 to 100000
　　set the end of (aList of spd) to (random number from 1 to 10000)
end repeat

–Benchmark Code
set hList to {"returnDuplicatesOnly1:", "returnDuplicatesOnly2:", "returnDuplicatesOnly3:"}
set resList to {}

repeat with i in hList
　　set nameOfTargetHandler to contents of i
　　
　　–Check Handler existence
　　set existsHandler to (me’s respondsToSelector:nameOfTargetHandler) as boolean
　　if existsHandler = true then
　　　　–Call handler
　　　　set a1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
　　　　
　　　　set aRes to (my performSelector:nameOfTargetHandler withObject:(aList of spd))
　　　　
　　　　set b1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
　　　　set c1Dat to b1Dat – a1Dat
　　else
　　　　error "Handler does not exists"
　　end if
　　
　　set the end of resList to {nameOfTargetHandler, c1Dat}
end repeat

return resList
–> {{"returnDuplicatesOnly1:", 0.065470099449}, {"returnDuplicatesOnly2:", 2.39611697197}, {"returnDuplicatesOnly3:", 0.038006067276}}

–Cocoa Scripting最速？
on returnDuplicatesOnly1:aList
　　set arrayOne to current application’s NSArray’s arrayWithArray:aList
　　set setOne to current application’s NSCountedSet’s alloc()’s initWithArray:(arrayOne)
　　set arrayTwo to (arrayOne’s valueForKeyPath:"@distinctUnionOfObjects.self")
　　set setTwo to current application’s NSCountedSet’s alloc()’s initWithArray:(arrayTwo)
　　setOne’s minusSet:setTwo
　　return setOne’s allObjects() as list –>{3, 6, 4}
end returnDuplicatesOnly1:

–1より遅い
on returnDuplicatesOnly2:(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly2:

–リスト中から重複項目をリストアップする（Vanilla AS高速化版）
on returnDuplicatesOnly3:(aList)
　　script spd
　　　　property aList : {}
　　　　property dList : {}
　　end script
　　
　　copy aList to (aList of spd)
　　set aCount to length of (aList of spd)
　　
　　set (dList of spd) to {}
　　
　　repeat aCount times
　　　　set anItem to contents of (first item of (aList of spd))
　　　　set (aList of spd) to rest of (aList of spd)
　　　　
　　　　if {anItem} is in (aList of spd) then
　　　　　　if {anItem} is not in (dList of spd) then –ここを追加した （v3）
　　　　　　　　set the end of (dList of spd) to anItem
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return (dList of spd)
end returnDuplicatesOnly3:

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set dList to {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16}

set aRes to my subarraysFrom:(dList) groupedBy:6 gapFilledBy:0
–> {{1, 2, 3, 4, 5, 6}, {7, 8, 9, 10, 11, 12}, {13, 14, 15, 16, 0, 0}}

set bRes to my subarraysFrom:(dList) groupedBy:4 gapFilledBy:0
–> {{1, 2, 3, 4}, {5, 6, 7, 8}, {9, 10, 11, 12}, {13, 14, 15, 16}}

set cRes to my subarraysFrom:(dList) groupedBy:3 gapFilledBy:0
–> {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}, {10, 11, 12}, {13, 14, 15}, {16, 0, 0}}

–1D Listの2D LIst化
on subarraysFrom:aList groupedBy:colCount gapFilledBy:gapItem
　　script spd
　　　　property aList : {}
　　　　property bList : {}
　　　　property cList : {}
　　end script
　　
　　copy aList to (aList of spd) –deep copy (Important !!!)
　　
　　set (bList of spd) to {}
　　set (cList of spd) to {}
　　
　　set aLen to length of (aList of spd)
　　set aMod to aLen mod colCount
　　
　　–あらかじめ指定数（groupedBy）の倍数になっていない場合にはgap itemを末尾に足しておく
　　if aMod is not equal to 0 then
　　　　repeat (colCount – aMod) times
　　　　　　set the end of (aList of spd) to gapItem
　　　　end repeat
　　　　set aLen to length of (aList of spd)
　　end if
　　
　　–通常処理
　　repeat with i from 1 to aLen by colCount
　　　　set (bList of spd) to items i thru (i + colCount – 1) of (aList of spd)
　　　　set the end of (cList of spd) to (bList of spd)
　　end repeat
　　
　　return (cList of spd)
end subarraysFrom:groupedBy:gapFilledBy:

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set dList to {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15}
set aRes to my subarraysFrom:dList groupedBy:3
–> {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}, {10, 11, 12}, {13, 14, 15}}

set aRes to my subarraysFrom:dList groupedBy:5
–> {{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}, {11, 12, 13, 14, 15}}

–1D Listの2D LIst化
on subarraysFrom:aList groupedBy:colCount
　　script spd
　　　　property aList : {}
　　　　property bList : {}
　　　　property cList : {}
　　end script
　　
　　set (aList of spd) to aList
　　set (bList of spd) to {}
　　set (cList of spd) to {}
　　
　　set aLen to length of (aList of spd)
　　
　　set aMod to aLen mod colCount
　　if aMod is not equal to 0 then error "Item number does not match paramaters"
　　
　　repeat with i from 1 to aLen by colCount
　　　　set (bList of spd) to items i thru (i + colCount – 1) of (aList of spd)
　　　　set the end of (cList of spd) to (bList of spd)
　　end repeat
　　
　　return (cList of spd)
end subarraysFrom:groupedBy: