アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

Posted on 8月 9, 2020 by Takaaki Naganoya

edama2さんからの投稿です。起動中のアプリケーション一覧をダイアログ表示するAppleScriptシリーズで、アプリケーションのアイコン画像やパス情報を表示し、単数/複数のアプリケーション選択ができます。

▲単一選択（左）のダイアログと、複数選択（右）のダイアログ

タイトルは「アラートダイアログ上のTable Viewで起動中のアプリケーションを選択」
起動中のアプリケーションをiOSライクなレイアウトで表示します
Table Viewにカスタムセルビューを作って表現し、アプリの起動と終了を検知してリアルタイムで更新します
行数は12行に固定し、項目の複数選択がオプションで選べます

AppleScriptObjCフレームワークを呼び出すことにより、Xcod上で記述するAppleScriptアプリケーションのように、各種クラスのサブクラスを定義して利用しているScriptです。さまざまなScripterの技術が積み上がっている感じがして壮観ですが、ほとんどはedama2さんが長い時間をかけて積み上げてきたものの集大成といったものです。

本Scriptは途中で試行錯誤がいろいろあって、返り値がファイルパスだったりアプリケーションオブジェクトになったりと紆余曲折あって、現在の「アプリケーションオブジェクト」になりました。

ただ、実行中のアプリケーション自身を選択すると「current application」になってしまう点に注意が必要です。

AppleScript名：アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

on run
　　my testRun()
end run

on testRun()
　　
　　set mes to "選択モードを指定してください"
　　set bOK to "複数選択"
　　set bOther to "単一選択"
　　set bCancel to "キャンセル"
　　set bList to {bCancel, bOther, bOK}
　　
　　set userAction to display dialog mes buttons bList default button bOK cancel button bCancel with icon note
　　
　　if userAction’s button returned is bOther then
　　　　set isMultiple to false
　　else if userAction’s button returned is bOK then
　　　　set isMultiple to true
　　end if
　　
　　set aMainMes to "Select Runnning Application"
　　set aSubMes to "Sub Message"
　　set execButtonTitle to "OK😁"
　　set dateObj to my chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:(isMultiple) okTitle:execButtonTitle
　　
end testRun

on chooseRunningApplication:(aMainMes as text) subMes:(aSubMes as text) withMultipleSelections:(isMultiple as boolean) okTitle:(execButtonTitle as text)
　　
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　# subClasses.scptを呼び出す
　　set DialogCore to current application’s AppDelegate’s new()
　　set fRes to DialogCore’s chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:isMultiple okTitle:execButtonTitle
　　
　　if fRes is missing value then error number -128
　　return fRes as list
end chooseRunningApplication:subMes:withMultipleSelections:okTitle:

★Click Here to Open This Script　

AppleScript名：subClasses.scpt

#MARK: AppDelegate
script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on applicationShouldTerminateAfterLastWindowClosed:sender
　　　　return true
　　end applicationShouldTerminateAfterLastWindowClosed:
　　
　　on applicationWillFinishLaunching:aNotification
　　　　log my testRun()
　　end applicationWillFinishLaunching:
　　
　　——————
　　#MARK: テスト
　　on testRun()
　　　　–log "testRun"
　　　　
　　　　set mes to "選択モードを指定してください"
　　　　set bOK to "複数選択"
　　　　set bOther to "単一選択"
　　　　set bCancel to "キャンセル"
　　　　set bList to {bCancel, bOther, bOK}
　　　　
　　　　set userAction to display dialog mes buttons bList default button bOK cancel button bCancel with icon note
　　　　
　　　　if userAction’s button returned is bOther then
　　　　　　set isMultiple to false
　　　　else if userAction’s button returned is bOK then
　　　　　　set isMultiple to true
　　　　end if
　　　　
　　　　set aMainMes to "Select Runnning Application"
　　　　set aSubMes to "Sub Message"
　　　　set execButtonTitle to "OK😁"
　　　　set dateObj to my chooseRunningApplication:aMainMes subMes:aSubMes withMultipleSelections:(isMultiple) okTitle:execButtonTitle
　　　　
　　　　return dateObj
　　end testRun
　　
　　#MARK: アラートダイアログでtableviewを表示
　　property _retrieve_data : missing value
　　on chooseRunningApplication:(aMainMes as text) subMes:(aSubMes as text) withMultipleSelections:(isMultiple as boolean) okTitle:(execButtonTitle as text)
　　　　# reset
　　　　set my _retrieve_data to missing value
　　　　
　　　　#
　　　　if aMainMes = "" then error "Dialog main message is missing"
　　　　
　　　　#
　　　　set dataSourceList to {}
　　　　
　　　　# OKボタンの文字
　　　　if execButtonTitle = "" then set execButtonTitle to "Execute"
　　　　
　　　　set thisFileType to "com.apple.application-bundle"
　　　　
　　　　#
　　　　set paramObj to {myMessage:aMainMes}
　　　　set paramObj to paramObj & {mySubMessage:aSubMes}
　　　　set paramObj to paramObj & {myDataSource:dataSourceList}
　　　　set paramObj to paramObj & {myType:thisFileType}
　　　　set paramObj to paramObj & {mySelectType:isMultiple}
　　　　set paramObj to paramObj & {myOKTitile:execButtonTitle}
　　　　
　　　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　　　
　　　　if (my _retrieve_data) is missing value then error number -128
　　　　set retrieveData to my _retrieve_data
　　　　set my _retrieve_data to missing value
　　　　
　　　　return retrieveData
　　end chooseRunningApplication:subMes:withMultipleSelections:okTitle:
　　
　　#MARK: Raize Alert
　　on raizeAlert:paramObj
　　　　set mesText to paramObj’s myMessage as text
　　　　set infoText to paramObj’s mySubMessage as text
　　　　set dataSourceList to paramObj’s myDataSource as list
　　　　set myUTI to paramObj’s myType as text
　　　　set isMultiple to paramObj’s mySelectType as boolean
　　　　set okButton to paramObj’s myOKTitile as text
　　　　
　　　　### set up view
　　　　#### data sourceにデータを追加
　　　　set theController to current application’s YKZArrayController’s alloc()’s initWithContent:dataSourceList
　　　　theController’s setMultipleSelections:isMultiple
　　　　theController’s setupView()
　　　　
　　　　### アイコンの指定
　　　　–set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:myUTI
　　　　
　　　　set setSize to 128
　　　　set fontObj to current application’s NSFont’s systemFontOfSize:setSize
　　　　set aValue to {fontObj}
　　　　set aKey to {current application’s NSFontAttributeName}
　　　　set attributes to current application’s NSDictionary’s dictionaryWithObjects:aValue forKeys:aKey
　　　　
　　　　set strEmoji to current application’s NSString’s stringWithString:"😎"
　　　　
　　　　set newSizeObj to current application’s NSMakeSize(setSize, setSize)
　　　　tell current application’s NSImage’s alloc
　　　　　　tell initWithSize_(newSizeObj)
　　　　　　　　lockFocus()
　　　　　　　　strEmoji’s drawInRect:(current application’s NSMakeRect(0, 0, setSize, setSize)) withAttributes:attributes
　　　　　　　　unlockFocus()
　　　　　　　　set aImage to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　
　　　　### set up alert
　　　　tell current application’s NSAlert’s new()
　　　　　　addButtonWithTitle_(okButton)
　　　　　　addButtonWithTitle_("Cancel")
　　　　　　setAccessoryView_(theController’s _the_view)
　　　　　　setIcon_(aImage)
　　　　　　setInformativeText_(infoText)
　　　　　　setMessageText_(mesText)
　　　　　　tell |window|()
　　　　　　　　setInitialFirstResponder_(theController’s _the_view)
　　　　　　end tell
　　　　　　#### show alert in modal loop
　　　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　　　end tell
　　　　
　　　　### retrieve data
　　　　set (my _retrieve_data) to theController’s retrieveSelectItems()
　　　　return my _retrieve_data
　　end raizeAlert:
end script

#MARK: – NSValueTransformer
script YKZURLToIcon
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSImage –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set iconImage to current application’s NSWorkspace’s sharedWorkspace’s iconForFile:appPath
　　　　return iconImage
　　end transformedValue:
end script

script YKZURLToDisplayedName
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set displayedName to current application’s NSFileManager’s defaultManager’s displayNameAtPath:appPath
　　　　return displayedName
　　end transformedValue:
end script

script YKZURLToPath
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　return appPath
　　end transformedValue:
end script

script YKZURLToVersion
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　tell (current application’s NSBundle’s bundleWithURL:fileURL)
　　　　　　tell its infoDictionary()
　　　　　　　　set aVar to objectForKey_("CFBundleShortVersionString")
　　　　　　end tell
　　　　end tell
　　　　return aVar
　　end transformedValue:
end script

#MARK: – Array Controller
script YKZArrayController
　　property parent : class "NSArrayController"
　　
　　#MARK: IBOutlets
　　property _the_view : missing value
　　property _table_view : missing value
　　
　　#MARK: Property
　　property multipleSelections : false
　　property rowCount : 12
　　
　　#MARK: 初期化
　　on initWithContent:aContent
　　　　continue initWithContent:aContent
　　　　
　　　　#通知の登録
　　　　tell current application’s NSWorkspace’s sharedWorkspace()’s notificationCenter()
　　　　　　addObserver_selector_name_object_(me, "changed:", "NSWorkspaceDidLaunchApplicationNotification", missing value)
　　　　　　addObserver_selector_name_object_(me, "changed:", "NSWorkspaceDidTerminateApplicationNotification", missing value)
　　　　end tell
　　　　
　　　　return me
　　end initWithContent:
　　
　　
　　#MARK: 戻り値
　　on retrieveSelectItems()
　　　　set retrieveData to {}
　　　　
　　　　set aIndexSet to my _table_view’s selectedRowIndexes()
　　　　set chooseItems to ((my _table_view’s dataSource())’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　　　repeat with anItem in chooseItems
　　　　　　set aPath to anItem’s fileURL
　　　　　　set retrieveData’s end to application (aPath as text)
　　　　end repeat
　　　　
　　　　return retrieveData as list
　　end retrieveSelectItems
　　
　　#MARK: viewの作成
　　on setupView()
　　　　#Transformerの登録
　　　　set tNames to {}
　　　　set tNames’s end to "YKZURLToIcon"
　　　　set tNames’s end to "YKZURLToDisplayedName"
　　　　set tNames’s end to "YKZURLToPath"
　　　　set tNames’s end to "YKZURLToVersion"
　　　　repeat with aTransformer in tNames
　　　　　　set theTransformer to current application’s class aTransformer’s new()
　　　　　　(current application’s NSValueTransformer’s setValueTransformer:theTransformer forName:aTransformer)
　　　　end repeat
　　　　log multipleSelections
　　　　## NSTableView
　　　　tell current application’s NSTableView’s alloc()
　　　　　　tell initWithFrame_(current application’s CGRectZero)
　　　　　　　　–registerForDraggedTypes_({current application’s NSFilenamesPboardType, (my _data_type)})
　　　　　　　　setAllowsEmptySelection_(false)
　　　　　　　　setAllowsMultipleSelection_(multipleSelections)
　　　　　　　　setDataSource_(me)
　　　　　　　　setDelegate_(me)
　　　　　　　　setDoubleAction_("doubleAction:")
　　　　　　　　–setDraggingSourceOperationMask_forLocal_(current application’s NSDragOperationCopy, false)
　　　　　　　　setGridStyleMask_(current application’s NSTableViewSolidVerticalGridLineMask)
　　　　　　　　setSelectionHighlightStyle_(current application’s NSTableViewSelectionHighlightStyleRegular)
　　　　　　　　setTarget_(me)
　　　　　　　　setUsesAlternatingRowBackgroundColors_(true)
　　　　　　　　setHeaderView_(missing value)
　　　　　　　　setRowHeight_(50)
　　　　　　　　
　　　　　　　　set thisRowHeight to rowHeight() as integer
　　　　　　　　set my _table_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　## NSTableColumn
　　　　### Columnの並び順を指定する
　　　　set keyrec to {column1:"Name"}
　　　　set keyDict to (current application’s NSDictionary’s dictionaryWithDictionary:keyrec)
　　　　
　　　　set viewWidth to 400 –表示幅を変更
　　　　set columnsCount to keyDict’s |count|()
　　　　
　　　　repeat with colNum from 1 to columnsCount
　　　　　　
　　　　　　set keyName to "column" & colNum as text
　　　　　　set aTitle to (keyDict’s objectForKey:keyName)
　　　　　　
　　　　　　tell (current application’s NSTableColumn’s alloc()’s initWithIdentifier:(colNum as text))
　　　　　　　　tell headerCell()
　　　　　　　　　　setStringValue_(aTitle)
　　　　　　　　　　set thisHeaderHeight to cellSize()’s height
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　### バインディングのオプション
　　　　　　　　— ソートを無効にする
　　　　　　　　set anObj to (current application’s NSNumber’s numberWithBool:false)
　　　　　　　　set aKey to current application’s NSCreatesSortDescriptorBindingOption
　　　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　　　
　　　　　　　　### 表示内容をNSArrayControllerにバインディング
　　　　　　　　bind_toObject_withKeyPath_options_(current application’s NSValueBinding, (my _table_view’s dataSource()), "arrangedObjects", bOptions)
　　　　　　　　
　　　　　　　　set aTableColumn to it
　　　　　　end tell
　　　　　　
　　　　　　### Columnの横幅を調整
　　　　　　tell (my _table_view)
　　　　　　　　addTableColumn_(aTableColumn)
　　　　　　end tell
　　　　　　
　　　　　　tell aTableColumn
　　　　　　　　setWidth_(viewWidth)
　　　　　　end tell
　　　　end repeat
　　　　
　　　　## NSScrollView
　　　　### Viewの高さを計算
　　　　set viewHeight to thisRowHeight * rowCount + thisHeaderHeight
　　　　
　　　　#ダイアログ内のビューサイズを指定
　　　　set aScreen to current application’s NSScreen’s mainScreen()
　　　　set screenFrame to aScreen’s frame()
　　　　set aHeight to current application’s NSHeight(screenFrame)
　　　　set aWidth to current application’s NSWidth(screenFrame)
　　　　set maxHeight to aHeight * 0.845
　　　　set maxWidth to aWidth * 0.94
　　　　–log viewHeight
　　　　–log maxHeight
　　　　–set viewHeight to viewHeight + aSpace + sfHeight
　　　　if viewHeight > maxHeight then set viewHeight to maxHeight
　　　　if viewWidth > maxWidth then set viewWidth to maxWidth
　　　　if viewWidth < 360 then set viewWidth to 360
　　　　
　　　　set vSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　　　
　　　　### Viewを作成
　　　　tell current application’s NSScrollView’s alloc()
　　　　　　tell initWithFrame_(vSize)
　　　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　　　setDocumentView_(my _table_view)
　　　　　　　　setHasHorizontalScroller_(true)
　　　　　　　　setHasVerticalScroller_(true)
　　　　　　　　set my _the_view to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　my changed:me
　　　　
　　　　# 1行目を選択
　　　　my setSelectionIndex:0
　　　　
　　　　return my _the_view
　　end setupView
　　
　　#MARK: アプリケーションが切り替わった時
　　— tableViewを作成してから実行する
　　on changed:sender
　　　　log "changed"
　　　　
　　　　tell (my _table_view)’s dataSource()
　　　　　　removeObjects_(arrangedObjects())
　　　　end tell
　　　　
　　　　#起動中のアプリケーション
　　　　set aList to current application’s NSWorkspace’s sharedWorkspace()’s runningApplications()
　　　　set sort to (current application’s NSSortDescriptor’s alloc()’s initWithKey:"localizedName" ascending:true selector:"caseInsensitiveCompare:")
　　　　set sortedList to aList’s sortedArrayUsingDescriptors:(sort as list)
　　　　
　　　　repeat with anItem in (sortedList as list)
　　　　　　#普通のアプリだけ
　　　　　　set aFlag to anItem’s activationPolicy() is current application’s NSApplicationActivationPolicyRegular
　　　　　　if aFlag then
　　　　　　　　set theURL to anItem’s bundleURL()
　　　　　　　　((my _table_view)’s dataSource()’s addObject:{fileURL:theURL})
　　　　　　end if
　　　　　　
　　　　end repeat
　　　　
　　end changed:
　　
　　
　　#MARK: Data Source Overrides
　　on numberOfRowsInTableView:aTableView
　　　　return (aTableView’s dataSource())’s content()’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aTableView viewForTableColumn:aColumn row:aRow
　　　　
　　　　set aCellView to aTableView’s makeViewWithIdentifier:"YKZTableCellView" owner:me
　　　　
　　　　if aCellView is missing value then
　　　　　　
　　　　　　set frameRect to current application’s NSMakeRect(0, 0, aColumn’s width, aTableView’s rowHeight())
　　　　　　set aCellView to current application’s YKZTableCellView’s alloc’s initWithFrame:frameRect
　　　　　　
　　　　　　set anObj to "YKZURLToIcon"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s imageView())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToDisplayedName"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s textField())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToPath"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s pathTextField)’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToVersion"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s varTextField)’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　return aCellView
　　　　end if
　　　　
　　　　return missing value
　　end tableView:viewForTableColumn:row:
　　
　　
　　# テーブル内のセルが編集できるか
　　on tableView:aTableView shouldEditTableColumn:aColumn row:aRow
　　　　return false
　　end tableView:shouldEditTableColumn:row:
　　
　　#
　　on validateProposedFirstResponder:aResponder forEvent:aEvent
　　　　log "validateProposedFirstResponder"
　　　　return true
　　　　
　　　　set aBoolean to aResponder’s isKindOfClass:(current application’s NSTableCellView’s |class|())
　　　　if aBoolean as boolean then
　　　　　　return true
　　　　end if
　　　　
　　　　return true
　　end validateProposedFirstResponder:forEvent:
　　
　　# テーブル内をダブルクリックしたらOKボタンを押す
　　on doubleAction:sender
　　　　log "doubleAction"
　　　　## ヘッダをクリックした時は何もしない
　　　　if (sender’s clickedRow()) is -1 then return
　　　　
　　　　set theEvent to current application’s NSEvent’s ¬
　　　　　　keyEventWithType:(current application’s NSEventTypeKeyDown) ¬
　　　　　　　　location:(current application’s NSZeroPoint) ¬
　　　　　　　　modifierFlags:0 ¬
　　　　　　　　timestamp:0.0 ¬
　　　　　　　　windowNumber:(sender’s |window|()’s windowNumber()) ¬
　　　　　　　　context:(current application’s NSGraphicsContext’s currentContext()) ¬
　　　　　　　　|characters|:return ¬
　　　　　　　　charactersIgnoringModifiers:(missing value) ¬
　　　　　　　　isARepeat:false ¬
　　　　　　　　keyCode:0
　　　　current application’s NSApp’s postEvent:theEvent atStart:(not false)
　　end doubleAction:
　　
end script

#MARK: – NSTableCellView
script YKZTableCellView
　　property parent : class "NSTableCellView"
　　
　　property acceptsFirstResponder : true
　　
　　property pathTextField : missing value
　　property varTextField : missing value
　　
　　on initWithFrame:rect
　　　　continue initWithFrame:rect
　　　　
　　　　setAutoresizingMask_(current application’s NSViewWidthSizable)
　　　　
　　　　–set myWidth to current application’s NSWidth(rect)
　　　　–set myHeight to current application’s NSHeight(rect)
　　　　
　　　　# アイコン
　　　　tell current application’s NSImageView’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(12, 1, 48, 48))
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　my setImageView:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# 表示名
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(66, 26, 280, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setFont_(current application’s NSFont’s boldSystemFontOfSize:13)
　　　　　　　　my setTextField:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# パス
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(66, 6, 316, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setFont_(current application’s NSFont’s systemFontOfSize:11)
　　　　　　　　set my pathTextField to it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# バージョン
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(300, 24, 80, 17))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　setFont_(current application’s NSFont’s systemFontOfSize:11)
　　　　　　　　setLineBreakMode_(current application’s NSLineBreakByTruncatingMiddle)
　　　　　　　　setAlignment_(current application’s NSRightTextAlignment)
　　　　　　　　set my varTextField to it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return me
　　end initWithFrame:
end script

★Click Here to Open This Script　

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

Posted on 7月 17, 2020 by Takaaki Naganoya

アラートダイアログ上にボタンタイプのチェックボックスを並べて、選択したボタンのタイトルを選択するAppleScriptです。

書類の印刷対象を、こまかくページ指定するために作成した部品です。

ヘルプボタンにより、全ボタンの選択/非選択状態を作り出せます。

▲Beta2でAlert Dialogのタイトルまわりが変更されたようですが、、、、うーーん。あと、選択状態をボタンの見かけから知ることができないですわー

AppleScript名：アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

— Created 2020-07-17 by Takaaki Naganoya
— 2020 Piyomaru Software

set aRes to selectByCheckbox("Select each printout page", "Selected pages are the target", 64, "Helvetica") of chooseSeqNum

script chooseSeqNum
　　
　　use AppleScript version "2.5"
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　
　　property NSFont : a reference to current application’s NSFont
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSButton : a reference to current application’s NSButton
　　property NSOnState : a reference to current application’s NSOnState
　　property NSOffState : a reference to current application’s NSOffState
　　property NSTextField : a reference to current application’s NSTextField
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
　　property NSMutableDictionary : a reference to current application’s NSMutableDictionary
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSFontAttributeName : a reference to current application’s NSFontAttributeName
　　property NSKernAttributeName : a reference to current application’s NSKernAttributeName
　　property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
　　property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
　　property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
　　property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
　　property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
　　property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
　　
　　property theResult : 0
　　property returnCode : 0
　　property cList : {} –Checkbox button object array
　　property bArray : {}
　　
　　
　　on selectByCheckbox(aMainMessage, aSubMessage, aMaxPage, myFont)
　　　　set paramObj to {myMessage:aMainMessage, mySubMessage:aSubMessage, maxPage:aMaxPage, fontName:myFont}
　　　　–my chooseItemByCheckBox:paramObj –for Debugging
　　　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　　　–> {1, 3, 5, 7, 9, 11}
　　　　return cList
　　end selectByCheckbox
　　
　　on chooseItemByCheckBox:(paramObj)
　　　　set aMainMes to (myMessage of paramObj) as string
　　　　set aSubMes to (mySubMessage of paramObj) as string
　　　　set aMaxPage to (maxPage of paramObj) as integer
　　　　set aFontName to (fontName of paramObj) as string
　　　　
　　　　set cList to {}
　　　　
　　　　set colNum to 10
　　　　set rowNum to (aMaxPage div 10) + 1
　　　　set aLen to (colNum * rowNum)
　　　　
　　　　set aButtonCellWidth to 56
　　　　set aButtonCellHeight to 40
　　　　
　　　　set viewWidth to aButtonCellWidth * colNum
　　　　set viewHeight to aButtonCellHeight * (rowNum + 1)
　　　　
　　　　–define the matrix size where you’ll put the radio buttons
　　　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　　　
　　　　set aCount to 1
　　　　set aFontSize to 24
　　　　set bArray to current application’s NSMutableArray’s new()
　　　　
　　　　–Make Header (Month, Year)
　　　　set aCalList to makeSeqNumList(1, aMaxPage) of me
　　　　set aCount to 1
　　　　
　　　　
　　　　–Make Calendar (Calendar Body)
　　　　repeat with y from 1 to rowNum
　　　　　　repeat with x from 1 to colNum
　　　　　　　　–try
　　　　　　　　set j to (contents of item aCount of aCalList)
　　　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　　　
　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize))
　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), aFontName, aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeOnOff))
　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　
　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　
　　　　　　　　set aCount to aCount + 1
　　　　　　　　if aCount > aMaxPage then exit repeat
　　　　　　　　–end try
　　　　　　end repeat
　　　　　　if aCount > aMaxPage then exit repeat
　　　　end repeat
　　　　
　　　　–Select the first radio button item
　　　　–(tmpArray’s objectAtIndex:0)’s setState:(current application’s NSOnState)
　　　　set my theResult to {}
　　　　
　　　　(aView’s setSubviews:bArray)
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aView
　　　　　　
　　　　　　–for Help Button
　　　　　　its setShowsHelp:(true)
　　　　　　its setDelegate:(me)
　　　　　　
　　　　end tell
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode as number) = 1001 then error number -128
　　　　
　　　　set bNumList to (bArray’s valueForKeyPath:"state") as list
　　　　–set cList to {}
　　　　repeat with i from 1 to aMaxPage
　　　　　　set aFlag to (contents of item i of bNumList) as boolean
　　　　　　if aFlag = true then
　　　　　　　　set the end of cList to contents of i
　　　　　　end if
　　　　end repeat
　　　　
　　　　copy cList to bArray
　　end chooseItemByCheckBox:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to aParam’s runModal()
　　end doModal:
　　
　　
　　
　　on clicked:aParam
　　　　set aTag to (tag of aParam) as integer
　　　　–clicked
　　　　if aTag is not in (my theResult) then
　　　　　　set the end of (my theResult) to aTag
　　　　else
　　　　　　set theResult to my deleteItem:aTag fromList:theResult
　　　　end if
　　end clicked:
　　
　　
　　
　　on deleteItem:anItem fromList:theList
　　　　set theArray to NSMutableArray’s arrayWithArray:theList
　　　　theArray’s removeObject:anItem
　　　　return theArray as list
　　end deleteItem:fromList:
　　
　　
　　
　　–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
　　on sort1DNumList:theList ascOrder:aBool
　　　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　　　return (sortedList) as list
　　end sort1DNumList:ascOrder:
　　
　　
　　–Help Button Clicked Event Handler
　　on alertShowHelp:aNotification
　　　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　　　set bRes to (button returned of aRes) as string
　　　　
　　　　if bRes = "All Off" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　　　end repeat
　　　　　　
　　　　else if bRes = "All On" then
　　　　　　set bLen to bArray’s |count|()
　　　　　　set theResult to {}
　　　　　　repeat with i from 0 to bLen
　　　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　　　set the end of theResult to i + 1
　　　　　　end repeat
　　　　end if
　　　　
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　
　　–書式つきテキストを組み立てる
　　on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　　　set aKey1 to (NSFontAttributeName)
　　　　
　　　　set aVal2 to NSColor’s blackColor()
　　　　set aKey2 to (NSForegroundColorAttributeName)
　　　　
　　　　set aVal3 to aKerning
　　　　set akey3 to (NSKernAttributeName)
　　　　
　　　　set aVal4 to 0
　　　　set akey4 to (NSUnderlineStyleAttributeName)
　　　　
　　　　set aVal5 to 2 –all ligature ON
　　　　set akey5 to (NSLigatureAttributeName)
　　　　
　　　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　　　set akey7 to (NSParagraphStyleAttributeName)
　　　　
　　　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　　　
　　　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　　　return attrStr
　　end makeRTFfromParameters
　　
　　
　　on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aNSString’s setEditable:(editableF)
　　　　aNSString’s setStringValue:(setVal)
　　　　aNSString’s setDrawsBackground:(backgroundF)
　　　　aNSString’s setBordered:(borderedF)
　　　　return aNSString
　　end makeNSTextField
　　
　　
　　
　　on makeSeqNumList(fromNum as integer, toNum as integer)
　　　　script spd
　　　　　　property aList : {}
　　　　end script
　　　　
　　　　set aList of spd to {}
　　　　
　　　　repeat with i from fromNum to toNum
　　　　　　set the end of (aList of spd) to i
　　　　end repeat
　　　　
　　　　return (aList of spd)
　　end makeSeqNumList
　　
　　
end script

★Click Here to Open This Script　

システムフォントをWeightつきで指定

Posted on 5月 15, 2020 by Takaaki Naganoya

システムフォントをWeightつきで指定するAppleScriptです。

NSFontまわりの、フォント名を具体的に文字列で指定「しない」フォントの指定方法を、（必要があったので）いろいろ調べてみました。

ここに紹介したサンプルでは、System FontをWeightおよびSize指定して取得していますが、本当にやりたいのは言語（英語、日本語など）とセリフつき（Timesなど）サンセリフ（Helveticaなど）、Handwritingフォントかなどの属性情報を指定すると、なんとなくフォントを特定してくれる処理で、とてもOS内にありそうな気もするのですが、まだ見つけられておりません。

AppleScript名：システムフォントをWeightつきで指定.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/14
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aFont1 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightRegular)
—> (NSFont) ".AppleSystemUIFont 48.00 pt. P [] (0x60000154c060) fobj=0x7f8bb176bfc0, spc=10.20"
set aFont1Name to aFont1’s fontName() as string
–> ".AppleSystemUIFont"

set aFont2 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightUltraLight)
–> (NSFont) ".AppleSystemUIFontUltraLight 48.00 pt. P [] (0x6000012d42a0) fobj=0x7f8bb8925090, spc=10.10"
set aFont2Name to aFont2’s fontName() as string
–> ".AppleSystemUIFontUltraLight"

set aFont3 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightThin)
–> (NSFont) ".AppleSystemUIFontThin 48.00 pt. P [] (0x6000013fd350) fobj=0x7f8bb3ba1140, spc=10.12"
set aFont3Name to aFont3’s fontName() as string
–> ".AppleSystemUIFontThin"

set aFont4 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightLight)
–> (NSFont) ".AppleSystemUIFontLight 48.00 pt. P [] (0x6000013fd410) fobj=0x7f8bb3bbf890, spc=10.17"
set aFont4Name to aFont4’s fontName() as string
–> ".AppleSystemUIFontLight"

set aFont5 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightMedium)
–> (NSFont) ".AppleSystemUIFontMedium 48.00 pt. P [] (0x60000151c8a0) fobj=0x7f8bb79289e0, spc=10.08"
set aFont5Name to aFont5’s fontName() as string
–> ".AppleSystemUIFontMedium"

set aFont6 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightSemibold)
–> (NSFont) ".AppleSystemUIFontDemi 48.00 pt. P [] (0x6000013fd710) fobj=0x7f8bb69ef060, spc=9.96"
set aFont6Name to aFont6’s fontName() as string
–> ".AppleSystemUIFontDemi"

set aFont7 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightBold)
–> (NSFont) ".AppleSystemUIFontBold 48.00 pt. P [] (0x600000bfa430) fobj=0x7f8bb3b55630, spc=9.84"
set aFont7Name to aFont7’s fontName() as string
–> ".AppleSystemUIFontBold"

set aFont8 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightHeavy)
–> (NSFont) ".AppleSystemUIFontHeavy 48.00 pt. P [] (0x600000898a50) fobj=0x7f8bb3b79730, spc=9.66"
set aFont8Name to aFont8’s fontName() as string
–> ".AppleSystemUIFontHeavy"

set aFont9 to current application’s NSFont’s systemFontOfSize:48 weight:(current application’s NSFontWeightBlack)
–> (NSFont) ".AppleSystemUIFontBlack 48.00 pt. P [] (0x6000015a57a0) fobj=0x7f8bb14cb330, spc=9.49"
set aFont9Name to aFont9’s fontName() as string
–> ".AppleSystemUIFontBlack"

★Click Here to Open This Script　

AppleScript名：システムフォントをWeightつきで指定（monospacedDigitSystemFont）.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/14
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aFont1 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightRegular)
—> (NSFont) ".SFNSText 16.00 pt. P [] (0x600001557d80) fobj=0x7f8bb7e011b0, spc=4.20"
set aFont1Name to aFont1’s fontName() as string
–> ".SFNSText"

set aFont2 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightUltraLight)
–> (NSFont) ".SFNSText-Light 16.00 pt. P [] (0x6000015e08d0) fobj=0x7f8bb8914700, spc=4.02"
set aFont2Name to aFont2’s fontName() as string
–> ".SFNSText-Light"

set aFont3 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightThin)
–> (NSFont) ".SFNSText-Light 16.00 pt. P [] (0x600000b789f0) fobj=0x7f8bb697f020, spc=4.02"
set aFont3Name to aFont3’s fontName() as string
–> ".SFNSText-Light"

set aFont4 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightLight)
–> (NSFont) ".SFNSText-Light 16.00 pt. P [] (0x6000015a3c90) fobj=0x7f8bb88c2130, spc=4.02"
set aFont4Name to aFont4’s fontName() as string
–> ".SFNSText-Light"

set aFont5 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightMedium)
–> (NSFont) ".SFNSText-Medium 16.00 pt. P [] (0x6000014667f0) fobj=0x7f8bb891bdd0, spc=4.06"
set aFont5Name to aFont5’s fontName() as string
–> ".SFNSText-Medium"

set aFont6 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightSemibold)
–> (NSFont) ".SFNSText-Semibold 16.00 pt. P [] (0x6000014b7120) fobj=0x7f8bb8866210, spc=3.95"
set aFont6Name to aFont6’s fontName() as string
–> ".SFNSText-Semibold"

set aFont7 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightBold)
–> (NSFont) ".SFNSText-Bold 16.00 pt. P [] (0x600001412dc0) fobj=0x7f8bb8920310, spc=3.81"
set aFont7Name to aFont7’s fontName() as string
–> ".SFNSText-Bold"

set aFont8 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightHeavy)
–> (NSFont) ".SFNSText-Heavy 16.00 pt. P [] (0x600001443720) fobj=0x7f8bb6cea5f0, spc=3.61"
set aFont8Name to aFont8’s fontName() as string
–> ".SFNSText-Heavy"

set aFont9 to current application’s NSFont’s monospacedDigitSystemFontOfSize:16 weight:(current application’s NSFontWeightBlack)
–> (NSFont) ".SFNSText-Heavy 16.00 pt. P [] (0x60000145b5d0) fobj=0x7f8bb6996ff0, spc=3.61"
set aFont9Name to aFont9’s fontName() as string
–> ".SFNSText-Heavy"

★Click Here to Open This Script　

プログラムで作ったアラートダイアログ上のTextViewをフォーカスする

Posted on 4月 14, 2020 by Takaaki Naganoya

AppleScriptでダイナミックに（動的に）生成したアラートダイアログ上にテキストビューを生成し、そのテキストビュー上にテキスト入力用のキャレットを移動させる（フォーカスする）AppleScriptです。

Xcode上でAppleScriptでGUIアプリケーションを作っていて、文字サイズの大きなテキスト入力フィールドを動的に生成。さらに、テキスト入力フィールドにテキスト入力用のキャレットを移動させようとして、割と手こずっていました。

テキスト入力を受け付けるGUI部品に対して、入力フォーカスを与え、テキスト入力のキャレットが置かれた状態を再現するには、GUIの画面上からはマウスカーソルでクリック操作するとできます。同じ状態をプログラム側から作る場合にはFirstResponderにセットするという処理になります。

この、FirstResponderに指定することは理解でき、Xcode（Interface Builder）上で配置した部品に対して実行する処理は昔からやっています。NSTextFieldに強制的に入力フォーカスを置いた上でバーコードリーダーからのテキスト入力を受け付けるといった処理です。

一方、プログラムから動的に生成したGUI部品に対して、Cocoaが用意しているAPIのどれを用いて、どのように指定すべきなのかで困りました。

親WindowのFirstResponderにしてみたり、アラートウィンドウのFirstResponderにしてみたり、いろいろ試した末に、

parentWin's setInitialFirstResponder:aView

で、Alert DialogのWindowをparentWinに、alert dialog上のテキストビューをaViewに代入した状態で実行して、入力キャレットをテキストビュー上に移動できました。本Xcode Projectは上記の１行の記述の検証を行うためのテストプロジェクトです。

–> Download Xcode Project

AppleScript名：AppDelegate.applescript

—
— AppDelegate.applescript
— dialogCarret
—
— Created by Takaaki Naganoya on 2020/04/14.
— Copyright © 2020 Takaaki Naganoya. All rights reserved.
—

script AppDelegate
　　property parent : class "NSObject"
　　
　　property |NSURL| : a reference to current application’s |NSURL|
　　property NSFont : a reference to current application’s NSFont
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSTextView : a reference to current application’s NSTextView
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　property returnCode : 0
　　property resStr : ""
　　
　　
　　on applicationWillFinishLaunching:aNotification
　　　　—
　　end applicationWillFinishLaunching:
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on clicked:sender
　　　　set tmpStr to "TEST"
　　　　set paramObj to {myMessage:"Input Text", mySubMessage:"", mes1:(tmpStr), mesWidth:400, mesHeight:200}
　　　　my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
　　　　set aResText to (my resStr) as string
　　　　
　　　　display dialog aResText
　　end clicked:
　　
　　on dispTextViewWithAlertdialog:paramObj
　　　　–Receive Parameters
　　　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　　　set mesStr to (mes1 of paramObj) as string –Text Input field 1 Label
　　　　set aWidth to (mesWidth of paramObj) as integer –TextView width
　　　　set aHeight to (mesHeight of paramObj) as integer –TextView height
　　　　
　　　　set vNum to system attribute "sys2"
　　　　if vNum > 13 then
　　　　　　set apRes to retLightOrDark() of me
　　　　　　if apRes = true then
　　　　　　　　set textColor to (current application’s NSColor’s cyanColor())
　　　　　　else
　　　　　　　　set textColor to (current application’s NSColor’s blackColor())
　　　　　　end if
　　　　else
　　　　　　set textColor to (current application’s NSColor’s blackColor())
　　　　end if
　　　　
　　　　
　　　　— Create a TextView with Scroll View
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　aView’s setDelegate:me
　　　　aView’s setRichText:true
　　　　aView’s useAllLigatures:true
　　　　aView’s setTextColor:textColor
　　　　aView’s setFont:(current application’s NSFont’s systemFontOfSize:90.0)
　　　　set aColor to current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.1
　　　　
　　　　aView’s setBackgroundColor:aColor
　　　　aView’s setString:mesStr
　　　　aScroll’s setDocumentView:aView
　　　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　
　　　　— set up alert
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　–its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aScroll
　　　　　　set parentWin to its |window|()
　　　　end tell
　　　　
　　　　parentWin’s setAlphaValue:0.8
　　　　–parentWin’s setOpaque:(false)
　　　　parentWin’s setLevel:(current application’s NSScreenSaverWindowLevel)
　　　　
　　　　parentWin’s setInitialFirstResponder:aView —Place Input Carret to Alert Dialog
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　
　　　　if (my returnCode as number) = 1001 then
　　　　　　—
　　　　else
　　　　　　set my resStr to aView’s |string|()
　　　　end if
　　end dispTextViewWithAlertdialog:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to aParam’s runModal()
　　end doModal:
　　
　　
　　on retLightOrDark()
　　　　return true
　　end retLightOrDark
　　
end script

★Click Here to Open This Script　

システムフォントの名称を取得

Posted on 4月 13, 2020 by Takaaki Naganoya

システムフォントの名称を取得するAppleScriptです。

GUIベースのアプリケーションを作っているときに、「もう、無難なフォントなんでもいいからとりあえず指定できるものがあれば指定しておこうよ」という局面はあります。ないフォントを指定するとクラッシュすることもあるので、とりあえずコレ指定しておけば大丈夫だから！

という「安全パイ」のフォントとしてSystem Fontを取得＆指定したいという時に書いたScriptでもあります。プログラム内容がつまらない割には、切実なニーズを満たすためのものです。

AppleScript名：システムフォントの名称を取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/04/06
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set aFont to current application’s NSFont’s systemFontOfSize:24.0
set aInfo to aFont’s fontDescriptor()
set aSize to (aInfo’s pointSize()) as real
set aPSName to (aInfo’s postscriptName()) as string
–> ".SFNSDisplay"

set bFont to current application’s NSFont’s boldSystemFontOfSize:24.0
set bInfo to bFont’s fontDescriptor()
set bSize to (bInfo’s pointSize()) as real
set bPSName to (bInfo’s postscriptName()) as string
–> ".SFNSDisplay-Bold"

★Click Here to Open This Script　

NSFontPanelでフォントを選択

Posted on 4月 7, 2020 by Takaaki Naganoya

自前でメニューを作ってフォントおよびサイズの選択を行おうとするとめんどくさい（時間がかかるし管理も大変）ので、NSFontPanelを用いてフォントを選択する試作品を作ってみました。

ただし、まだ完全ではなく「１つ前の状態が取得できる」という状態なので、修正が必要です。作成はmacOS 10.14.6＋Xcode 11.3.1上で行っています。

–> Download Xcode Project

AppleScript名：AppDelegate.applescript

—
— AppDelegate.applescript
— fontPanel
—
— Created by Takaaki Naganoya on 2020/03/12.
— Copyright © 2020 Takaaki Naganoya. All rights reserved.
—

script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　property theField : missing value
　　
　　property aFontNameField : missing value
　　property aFontSizeField : missing value
　　
　　property aFontManager : missing value
　　
　　property font : missing value
　　property aFP : missing value
　　
　　on applicationWillFinishLaunching:aNotification
　　　　set aFontManager to current application’s NSFontManager’s sharedFontManager()
　　　　aFontManager’s setAction:"appSpecificChangeFont:"
　　　　set aFP to current application’s NSFontPanel’s sharedFontPanel()
　　　　set aFont to current application’s NSFont’s fontWithName:"Helvetica" |size|:16
　　　　aFontManager’s setSelectedFont:aFont isMultiple:false
　　　　
　　　　theField’s setStringValue:"ぴよまるソフトウエア, Piyomaru Software"
　　end applicationWillFinishLaunching:
　　
　　on applicationShouldTerminate:sender
　　　　— Insert code here to do any housekeeping before your application quits
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on clicked:aSender
　　　　theWindow’s makeFirstResponder:theField
　　　　aFP’s makeKeyAndOrderFront:me
　　end clicked:
　　
　　on appSpecificChangeFont:sender
　　　　set aSelFont to sender’s selectedFont()
　　　　set aDesc to aSelFont’s fontDescriptor()
　　　　set aPSID to (aDesc’s postscriptName()) as string
　　　　set aSize to (aDesc’s pointSize()) as real
　　　　theField’s setFont:aSelFont
　　　　aFontNameField’s setStringValue:aPSID
　　　　aFontSizeField’s setStringValue:(aSize as string)
　　end appSpecificChangeFont:
end script

★Click Here to Open This Script　

RoundWindow v2

Posted on 1月 12, 2020 by Takaaki Naganoya

Edama2さんと「無理だよねー」「そうそう、絶対無理〜」などとメールで言っていたら、Shane Stanleyから届いた「できるよ」という衝撃のメール。

スクリプトエディタ上で記述する通常のAppleScriptで、CocoaのCustom Class宣言と呼び出しができるとのこと。

自分で動作確認してみるまで、半信半疑でしたが、、、、できますねこれは、、、

–> Download Editable and Executable Script Bundle

冗談半分で思いついたことを試してみたらできてしまったり、冗談半分でできるわけないよねと念のために書いておいたことが世界の誰かの目に止まったりと、「冗談半分」ってけっこう重要なことだと思えてきました。

以下、Shane Stanleyの説明による、その書き換え手順です。

（１）Subclassファイル（複数可）をXcode上のプロジェクトで書くようなスタイルで書く

こういう（↑）スタイルですね。かならずscript宣言しつつ、parent属性を宣言しておくところがXcode上のAppleScriptアプリケーションのスタイルです。あとで動作確認して、アプリケーションの起動や終了に関するイベントハンドラを書いておいたのは無駄（実行されない）ではないかとも思われました。

（２）実行するメインのScriptのResourcesフォルダ内にSubclassファイルを入れる

普通、AppleScriptのファイルが入る/Contents/Resources/Scripts/でも、ライブラリを入れておく/Contents/Resources/Script Libraries/でもなく、/Contents/Resources/の直下に入れます。ファイル名はオリジナルのEdama2さんのものをそのまま採用していますが、割となんでもいいようです。Custom Classファイルは分割してもいいし、このサンプルのようにまとめてもいいんでしょう。

＃　追加実験してみたところ、Resourcesフォルダ以下の/Scriptsや/Script Libraries/フォルダと重複しない名称の別フォルダ（例：/Classes/）に入れておいても大丈夫でした

（３）use framework “AppleScriptObjC”の宣言文を追加

見たことのない光景ですが、書くことについてはとくに障害はありません。AppKit.Frameworkもuse宣言しておいたほうがよかったかもしれません。

（４）メインスクリプトの実行時に以下の処理を実行

set theBundle to current application’s NSBundle’s bundleWithPath:pathToFolderWithScripts
theBundle’s loadAppleScriptObjectiveCScripts()

★Click Here to Open This Script　

試行錯誤して、上記の「pathToFolderWithScripts」にバンドル内の/Contents/Resources/を入れて実行すればよいことが理解できました。

以上の変更を加えて、ためしにスクリプトエディタ＆Script Debugger上で実行してみたところ、改変前と変わりなく実行できてしまいました（冒頭のスクリーンショット）。

いや、これはめちゃくちゃすごいですよ！！　何がすごいって、CocoaのCustom Classをスクリプトライブラリ中に入れて呼び出せるということで、けっこう無茶な箱庭インタフェースが作れてしまう予感が、、、、。

そして、AppleScriptObjC（AppleScriptObjC.frameworkより）でスクリプトエディタの「.scpt」形式のファイルを読み込んで実行できてしまったということは、Xcode上のAppleScriptアプリケーション内のScriptもテキスト形式だけでなく、スクリプトエディタで編集できる.scpt形式のファイルを突っ込んで編集できる可能性が見えてきました。

ただ、テキスト形式になっていないと、Interface Builderとの連携のあたりで問題になりそうな気もします。

AppleScript名：customClassTest.scptd

—
–　　Created by: Edama2 2020/01/10
–　　Adviced by: Shane Stanley 2020/01/11
–　　Modified by: Takaaki Naganoya 2020/01/12
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

property _clock_text_view : missing value –> 時計用の文字列
property _clock_timer : missing value –> 時計用のNSTimer

–Script Bundle内のResourcesフォルダを求める
set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
theBundle’s loadAppleScriptObjectiveCScripts()

my performSelectorOnMainThread:"raizeWindow:" withObject:(missing value) waitUntilDone:true

# ウィンドウを作成
on raizeWindow:aParam
　　
　　# 時計用の文字を作成
　　tell current application’s NSTextView’s alloc()
　　　　tell initWithFrame_(current application’s NSMakeRect(35, 120, 300, 40))
　　　　　　setRichText_(true)
　　　　　　useAllLigatures_(true)
　　　　　　setTextColor_(current application’s NSColor’s whiteColor())
　　　　　　setFont_(current application’s NSFont’s fontWithName:"Arial-Black" |size|:48)
　　　　　　setBackgroundColor_(current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.0)
　　　　　　setAlphaValue_(1.0)
　　　　　　setEditable_(false)
　　　　　　–setString_("00:00:00")
　　　　　　
　　　　　　set my _clock_text_view to it
　　　　end tell
　　end tell
　　
　　# 時計を更新するNSTimerを作成
　　set my _clock_timer to current application’s NSTimer’s scheduledTimerWithTimeInterval:1 target:me selector:"idleHandler:" userInfo:(missing value) repeats:true
　　
　　# 丸いViewを作成
　　set aFrame to current application’s NSMakeRect(0, 0, 300, 300)
　　tell current application’s RoundView’s alloc()
　　　　tell initWithFrame_(aFrame)
　　　　　　setNeedsDisplay_(true)
　　　　　　setSubviews_({my _clock_text_view})
　　　　　　set customView to it
　　　　end tell
　　end tell
　　
　　#スクリーンのサイズを調べる
　　set aScreen to current application’s NSScreen’s mainScreen()
　　
　　# Window
　　set aBacking to current application’s NSWindowStyleMaskBorderless
　　–set aBacking to current application’s NSBorderlessWindowMask
　　set aDefer to current application’s NSBackingStoreBuffered
　　
　　tell current application’s CustomWindow’s alloc()
　　　　tell initWithContentRect_styleMask_backing_defer_screen_(aFrame, aBacking, aDefer, false, aScreen)
　　　　　　–setTitle_(uniqueName) –>タイトル
　　　　　　setBackgroundColor_(current application’s NSColor’s clearColor()) — Grammar Police –>背景色
　　　　　　setContentView_(customView) –>内容ビューのセット
　　　　　　setDelegate_(me) –>デリゲート
　　　　　　setDisplaysWhenScreenProfileChanges_(true) –>スクリーンプロファイルが変更されたときウインドウの内容をアップデートするか
　　　　　　setHasShadow_(true) –>ウインドウに影があるか
　　　　　　setIgnoresMouseEvents_(false) –>マウスイベントを無視するか
　　　　　　–setLevel_((current application’s NSScreenSaverWindowLevel) + 1) –>ウインドウの前後関係の位置
　　　　　　setOpaque_(false) –>ウインドウを不透明にするか
　　　　　　setReleasedWhenClosed_(true) –>閉じたときにメモリを解放するか
　　　　　　
　　　　　　#
　　　　　　|center|()
　　　　　　makeKeyAndOrderFront_(me) –>キーウインドウにして前面に持ってくる
　　　　　　–setFrame_display_(aFrame, true) –>表示
　　　　end tell
　　end tell
end raizeWindow:

#タイマー割り込み
on idleHandler:aSender
　　set mesStr to time string of (current date)
　　(my _clock_text_view)’s setString:mesStr
end idleHandler:

★Click Here to Open This Script　

AppleScript名：CocoaAppletAppDelegate.scpt

script CocoaAppletAppDelegate
　　property parent : class "NSObject"
　　
　　on applicationWillFinishLaunching:aNotification
　　　　—
　　end applicationWillFinishLaunching:
　　
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
end script

script CustomWindow
　　property parent : class "NSWindow"
　　property canBecomeKeyWindow : true
　　
　　property _initial_location : missing value
　　
　　on mouseDown:theEvent
　　　　set my _initial_location to theEvent’s locationInWindow()
　　end mouseDown:
　　
　　on mouseDragged:theEvent
　　　　–set res to display dialog "mouseDragged" buttons {"OK"} default button "OK"
　　　　try
　　　　　　set screenVisibleFrame to current application’s NSScreen’s mainScreen()’s visibleFrame()
　　　　　　set screenVisibleFrame to my myHandler(screenVisibleFrame)
　　　　　　set windowFrame to my frame()
　　　　　　set windowFrame to my myHandler(windowFrame)
　　　　　　set newOrigin to windowFrame’s origin
　　　　　　
　　　　　　set currentLocation to theEvent’s locationInWindow()
　　　　　　set newOrigin’s x to (newOrigin’s x) + ((currentLocation’s x) – (_initial_location’s x))
　　　　　　set newOrigin’s y to (newOrigin’s y) + ((currentLocation’s y) – (_initial_location’s y))
　　　　　　
　　　　　　set tmpY to ((newOrigin’s y) + (windowFrame’s |size|’s height))
　　　　　　set screenY to (screenVisibleFrame’s origin’s y) + (screenVisibleFrame’s |size|’s height)
　　　　　　if tmpY > screenY then
　　　　　　　　set newOrigin’s y to (screenVisibleFrame’s origin’s y) + ((screenVisibleFrame’s |size|’s height) – (windowFrame’s |size|’s height))
　　　　　　end if
　　　　　　
　　　　　　my setFrameOrigin:newOrigin
　　　　on error error_message number error_number
　　　　　　set error_text to "Error: " & error_number & ". " & error_message
　　　　　　display dialog error_text buttons {"OK"} default button 1
　　　　　　return error_text
　　　　end try
　　　　
　　end mouseDragged:
　　
　　on myHandler(aFrame)
　　　　if class of aFrame is list then
　　　　　　set {{theX, theY}, {theWidth, theHeight}} to aFrame
　　　　　　set aFrame to {origin:{x:theX, y:theY}, |size|:{width:theWidth, height:theHeight}}
　　　　　　–set aFrame to current application’s NSMakeRect(theX, theY, theWidth, theHeight)
　　　　end if
　　　　return aFrame
　　end myHandler
end script

script RoundView
　　property parent : class "NSView"
　　
　　on drawRect:rect
　　　　set aFrame to my frame()
　　　　set myColor to current application’s NSColor’s redColor()
　　　　
　　　　tell current application’s NSBezierPath
　　　　　　tell bezierPathWithOvalInRect_(aFrame)
　　　　　　　　myColor’s |set|()
　　　　　　　　fill()
　　　　　　end tell
　　　　end tell
　　end drawRect:
end script

★Click Here to Open This Script　

指定のフォントとサイズに該当するテキストを抽出する v3

Posted on 12月 1, 2019 by Takaaki Naganoya

指定のRTFファイルから書式情報を取得し、フォント名とフォントサイズのペアをスタイルを反映させたポップアップメニューで選択。RTFの内容を解析したのち、ダイアログが表示されます（ここの所要時間は読ませるRTFのサイズ次第）。ポップアップメニューで書式を選ぶと、すぐさま抽出した箇所をすべてまとめて表示します。

–> Watch Demo Movie

–> Download Script Bundle with Sample data

ダイアログ表示前に書式ごとの抽出を完了し、個別のTabViewに抽出後の文字データを展開しておくので、ポップアップメニューから選択すると、展開ずみのデータを入れてあるTabViewに表示を切り替えるだけ。切り替え時に計算は行わないため、すぐに抽出ずみの文字データが表示されるという寸法です。

今回は短いサンプルデータを処理してみましたが、サンプル抽出時にあらかじめ範囲指定するなどして、データ処理規模を限定することで処理時間を稼ぐこともできることでしょう。

テキストエディットでオープン中のRTF書類のパスを取得して、それを処理対象にしてもいいでしょう。

ただし、やっつけで作ったのでスクリプトエディタ上でCommand-Control-Rで実行しないと動きません（メインスレッド実行をプログラムで強制しても、途中でクラッシュしてしまいます）。それほど時間もかけずに作ったやっつけプログラムなので、あまり原因追求も行えずそのままです。

AppleScript名：アラートダイアログ＋Tab View v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/16
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use rtfLib : script "readStyledTextLib"
use parseLib : script "parseAttrLib"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSMenu : a reference to current application’s NSMenu
property NSArray : a reference to current application’s NSArray
property NSTabView : a reference to current application’s NSTabView
property NSPredicate : a reference to current application’s NSPredicate
property NSTextView : a reference to current application’s NSTextView
property NSMenuItem : a reference to current application’s NSMenuItem
property NSTabViewItem : a reference to current application’s NSTabViewItem
property NSPopUpButton : a reference to current application’s NSPopUpButton
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSStrokeWidthAttributeName : a reference to current application’s NSStrokeWidthAttributeName
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property TabPosition : 4 —0=Top, 1=Left, 2=Bottom, 3=Right, 4=None

property returnCode : 0

property aTabV : missing value
property selectedNum : {}

set aFile to choose file of type {"public.rtf"}

set aStyledStr to readRTFfile(aFile) of rtfLib
set paramObj to {myMessage:"Select Style", mySubMessage:"Select style you want to filter", viewWidth:800, viewHeight:400, myStyledStr:aStyledStr}

my dispTabViewWithAlertdialog:paramObj –for debug
–my performSelectorOnMainThread:"dispTabViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
return selectedNum

on dispTabViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set aWidth to (viewWidth of paramObj) as integer –TextView width
　　set aHeight to (viewHeight of paramObj) as integer –TextView height
　　set aStyledStr to (myStyledStr of paramObj)
　　
　　set attrResTmp to getAttributeRunsFromAttrString(aStyledStr) of parseLib
　　set attrList to attributes of attrResTmp
　　set menuStyle to menuList of attrResTmp
　　
　　set selectedNum to {}
　　
　　set aView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　–Ppopup Buttonをつくる
　　set a1Button to NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 20, 400, 20)) pullsDown:false
　　a1Button’s removeAllItems()
　　
　　–WYSIWHG popup menuをつくる
　　set a1Menu to NSMenu’s alloc()’s init()
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set aTitle to (tmpFont & " " & tmpSize as string) & " point"
　　　　set aMenuItem to (NSMenuItem’s alloc()’s initWithTitle:aTitle action:"actionHandler:" keyEquivalent:"")
　　　　
　　　　set attributedTitle to makeRTFfromParameters(aTitle, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　
　　　　(aMenuItem’s setEnabled:true)
　　　　(aMenuItem’s setTarget:me)
　　　　(aMenuItem’s setTag:(i as string))
　　　　(aMenuItem’s setAttributedTitle:(attributedTitle))
　　　　(a1Menu’s addItem:aMenuItem)
　　end repeat
　　
　　–Ppopup Buttonにmenuをつける
　　a1Button’s setMenu:a1Menu
　　
　　–Make Tab View
　　set aTabV to NSTabView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 30))
　　aTabV’s setTabViewType:(TabPosition)
　　
　　
　　–TabViewに中身を入れる
　　repeat with i from 1 to (length of menuStyle)
　　　　set {tmpFont, tmpSize} to contents of item i of menuStyle
　　　　set tmpKey to (tmpFont as string) & "/" & (tmpSize as string)
　　　　set tmpArry to filterRecListByLabel1(attrList, "styleKey2 == ’" & tmpKey & "’") of me
　　　　set tmpStr to (tmpArry’s valueForKeyPath:"stringVal") as list
　　　　
　　　　set aTVItem to (NSTabViewItem’s alloc()’s initWithIdentifier:(i as string))
　　　　(aTVItem’s setLabel:(i as string))
　　　　
　　　　
　　　　set aTextView to (NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth – 10, aHeight – 10)))
　　　　(aTextView’s setRichText:true)
　　　　set tmpAttr to makeRTFfromParameters(tmpStr as string, tmpFont, tmpSize, NSColor’s blackColor()) of me
　　　　(aTextView’s textStorage()’s appendAttributedString:tmpAttr)
　　　　
　　　　(aTVItem’s setView:aTextView)
　　　　
　　　　(aTabV’s addTabViewItem:aTVItem)
　　end repeat
　　
　　
　　aView’s setSubviews:{a1Button, aTabV}
　　aView’s setNeedsDisplay:true
　　
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aView)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　end tell
　　
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set selectedNum to contents of item ((a1Button’s indexOfSelectedItem()) + 1) of menuStyle
end dispTabViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–Popup Action Handler
on actionHandler:sender
　　set aTag to tag of sender as integer
　　aTabV’s selectTabViewItemAtIndex:(aTag – 1)
end actionHandler:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, aFontName as string, aFontSize as real, aColor)
　　–フォント
　　set aVal1 to NSFont’s fontWithName:(aFontName) |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　–色
　　set aVal2 to aColor
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　–カーニング
　　set aVal3 to 0.0
　　set akey3 to (NSKernAttributeName)
　　
　　–アンダーライン
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　–リガチャ
　　–set aVal5 to 2 –全てのリガチャを有効にする
　　–set akey5 to ( NSLigatureAttributeName)
　　
　　–枠線（アウトライン）
　　–set aVal6 to outlineNum
　　–set akey6 to ( NSStrokeWidthAttributeName)
　　
　　
　　set keyList to {aKey1, aKey2, akey3, akey4}
　　set valList to {aVal1, aVal2, aVal3, aVal4}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　set bList to filteredArray
　　return bList
end filterRecListByLabel1

★Click Here to Open This Script　

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

Posted on 11月 13, 2019 by Takaaki Naganoya

アラートダイアログ上に指定月のカレンダー１か月分を表示してユーザーの日付選択（複数可）をもとめるAppleScriptです。

NSDatePickerを用いて日付選択のダイアログを作っていたら、日付がとても小さくて現代のMacの画面解像度にとても合っておらず、もっと大きめのカレンダーで選択したいと考えて作ったものです。

（１）カレンダーの表示サイズを大型化

現代のMacの画面にNSDatePickerをそのまま表示すると、とても小さくて見ていられないので、表示サイズを自由に変えられるカレンダー選択部品を作ってみました。どれか１つの日付を選択するものではなく、複数の日付を選択して、リストで結果を返してきます。

▲画面上で見やすいようにカレンダー部品を大型化

（２）選択無効日指定

あらかじめ、日付選択の対象外とする日付を指定できるようにしました。

（３）過去日付の選択無効

過去の日付を表示・選択できないようにする指定です。

▲過去日付を無効に指定すると、現在日時よりも過去の日付は選択できない

（４）曜日を現在のLocale情報から変更

曜日に用いる文字列を現在のLocale情報から取得するようにしてみました。本来であれば、日曜日はじまり「ではない」カレンダーを用いている場所もあるので（香港とかフランスとか？）、どの曜日から表示開始するかを自由選択にしたいところですが、そこまでは作り込んでいません。

▲Localeに合わせた曜日が表示される（ただし、年/月は固定フォーマット）

実用性を考えれば、Calendar.appのように日付選択とスケジュール確認が行えるものが望ましいのですが、そこまで作り込む手間をかけるほどのものでもないですし、表示対象月の移動を行おうとしてclickイベントを拾いつつカレンダー再描画に失敗した「残骸」です。見た目はいいのに完成度がいまひとつというあたりが残念です。

AppleScript名：アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

— Created 2019-10-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSButton : a reference to current application’s NSButton
property NSOnState : a reference to current application’s NSOnState
property NSOffState : a reference to current application’s NSOffState
property NSTextField : a reference to current application’s NSTextField
property NSMutableArray : a reference to current application’s NSMutableArray
property NSButtonTypeOnOff : a reference to current application’s NSButtonTypeOnOff
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property theResult : 0
property returnCode : 0
property bArray : {} –Checkbox button object array

property tYear : 0
property tMonth : 0
property theAlert : missing value
property theView : missing value

on run
　　set tYear to 2019
　　set tMonth to 11
　　set ignoreP to true
　　set ndList to {2, 3, 4, 9, 10, 13, 16, 17, 23, 24, 25, 30} –選択表示させない日付
　　set paramObj to {myMessage:"", mySubMessage:"適切な日付を以下からえらんでください", targetYear:tYear, targetMonth:tMonth, nodisp:ndList, ignorePast:ignoreP}
　　
　　–Detect Past Date Error
　　set curDate to current date
　　set dLimit to getMlen(tYear, tMonth) of me
　　set tmpDate to getDateInternational(tYear, tMonth, dLimit) of me
　　if (tmpDate < curDate) and (ignoreP = true) then error (("Target month is past (" & tYear as string) & "/" & tMonth as string) & "/1 is past. Today is " & date string of curDate & ")"
　　
　　–my chooseItemByCheckBox:paramObj –for Debugging
　　my performSelectorOnMainThread:"chooseItemByCheckBox:" withObject:(paramObj) waitUntilDone:true
　　return my sort1DNumList:(my theResult) ascOrder:true
　　–> {1, 3, 5, 7, 9, 11}
end run

on chooseItemByCheckBox:(paramObj)
　　set aMainMes to (myMessage of paramObj) as string
　　set aSubMes to (mySubMessage of paramObj) as string
　　set aMatList to (matrixTitleList of paramObj) as list
　　set tYear to (targetYear of paramObj) as integer
　　set tMonth to (targetMonth of paramObj) as integer
　　set noDispList to (nodisp of paramObj) as list
　　set ignoreP to (ignorePast of paramObj) as boolean
　　
　　if aMainMes = "" then
　　　　set aMainMes to "日付を選択してください"
　　end if
　　
　　set theView to makeCalendarView(tYear, tMonth, noDispList, ignoreP) of me
　　
　　–Select the first radio button item
　　set my theResult to {}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　　　
　　　　–for Help Button
　　　　–its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　set aWin to its |window|()
　　end tell
　　
　　aWin’s setLevel:(current application’s NSFloatingWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end chooseItemByCheckBox:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clicked:aParam
　　set aTag to (tag of aParam) as integer
　　
　　–clicked
　　if aTag is not in (my theResult) then
　　　　set the end of (my theResult) to aTag
　　else
　　　　set theResult to my deleteItem:aTag fromList:theResult
　　end if
end clicked:

on deleteItem:anItem fromList:theList
　　set theArray to NSMutableArray’s arrayWithArray:theList
　　theArray’s removeObject:anItem
　　return theArray as list
end deleteItem:fromList:

–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DNumList:theList ascOrder:aBool
　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, true)
　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　return (sortedList) as list
end sort1DNumList:ascOrder:

–Help Button Clicked Event Handler
on alertShowHelp:aNotification
　　set aRes to display dialog "Do you change all checkbox state?" buttons {"All Off", "All On", "Cancel"} default button 3 with icon 1
　　set bRes to (button returned of aRes) as string
　　
　　if bRes = "All Off" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOffState))
　　　　end repeat
　　　　
　　else if bRes = "All On" then
　　　　set bLen to bArray’s |count|()
　　　　set theResult to {}
　　　　repeat with i from 0 to bLen
　　　　　　((bArray’s objectAtIndex:i)’s setState:(current application’s NSOnState))
　　　　　　set the end of theResult to i + 1
　　　　end repeat
　　end if
　　
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　set aVal2 to NSColor’s blackColor()
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　set aVal3 to aKerning
　　set akey3 to (NSKernAttributeName)
　　
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　set aVal5 to 2 –all ligature ON
　　set akey5 to (NSLigatureAttributeName)
　　
　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　set akey7 to (NSParagraphStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–指定月のカレンダーを1D List(7 days x 6 weeks) で返す
on retListCalendar(tYear, tMonth)
　　set mLen to getMlen(tYear, tMonth) of me
　　set aList to {}
　　
　　set fDat to getDateInternational(tYear, tMonth, 1) of me
　　tell current application
　　　　set aOffset to (weekday of fDat) as number
　　end tell
　　
　　–header gap
　　repeat (aOffset – 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　–calendar body
　　repeat with i from 1 to mLen
　　　　set the end of aList to (i as string)
　　end repeat
　　
　　–footer gap
　　repeat (42 – aOffset – mLen + 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　return aList
end retListCalendar

–現在のカレンダーで指定年月の日数を返す（国際化対応版）
on getMlen(aYear as integer, aMonth as integer)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar()
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　return |length| of theResult
end getMlen

–ローカライズされた曜日名称を返す
on getLocalizedDaynames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols() as list
　　return dayNames
end getLocalizedDaynames

–ローカライズされた月名称を返す
on getLocalizedMonthnames(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set monthNames to df’s standaloneMonthSymbols() as list
　　return monthNames
end getLocalizedMonthnames

–ローカライズされた曜日の名称を返す
on getLocalizedWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s weekdaySymbols()
　　return dayNames as list
end getLocalizedWeekdaySymbol

–ローカライズされた曜日の名称（短縮版）を返す
on getLocalizedShortWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s shortWeekdaySymbols()
　　return dayNames as list
end getLocalizedShortWeekdaySymbol

–ローカライズされた曜日の名称（短縮記号）を返す
on getLocalizedVeryShortWeekdaySymbol(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s veryShortWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryShortWeekdaySymbol

–ローカライズされた曜日の名称を返す
on getLocalizedVeryStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s standaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryStandaloneWeekdaySymbols

–ローカライズされた曜日の名称を返す
on getLocalizedShortStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s shortStandaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedShortStandaloneWeekdaySymbols

–ローカライズされた曜日の名称を返す
on getLocalizedVeryShortStandaloneWeekdaySymbols(aLoc)
　　set df to current application’s NSDateFormatter’s alloc()’s init()
　　df’s setLocale:(current application’s NSLocale’s localeWithLocaleIdentifier:aLoc)
　　set dayNames to df’s veryShortStandaloneWeekdaySymbols()
　　return dayNames as list
end getLocalizedVeryShortStandaloneWeekdaySymbols

–カレンダー表示ビューを作成
on makeCalendarView(tYear as integer, tMonth as integer, noDispList as list, ignoreP as boolean)
　　set colNum to 7
　　set rowNum to 8
　　set aLen to (colNum * rowNum)
　　
　　set aButtonCellWidth to 70 –56
　　set aButtonCellHeight to 40
　　
　　set viewWidth to aButtonCellWidth * colNum
　　set viewHeight to aButtonCellHeight * rowNum
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(0.0, 0.0, viewWidth, viewHeight)
　　set aView to NSView’s alloc()’s initWithFrame:(matrixRect)
　　
　　set aCount to 1
　　set aFontSize to 30
　　set bArray to current application’s NSMutableArray’s new()
　　
　　–Make Header (Month, Year)
　　set x to 1
　　set tmpB to (NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum) * (aButtonCellHeight), aButtonCellWidth * 4, aButtonCellHeight)))
　　(tmpB’s setEditable:false)
　　(tmpB’s setBordered:false)
　　(tmpB’s setDrawsBackground:false)
　　(tmpB’s setAlignment:(current application’s NSLeftTextAlignment))
　　(tmpB’s setStringValue:((tYear as string) & " / " & tMonth as string))
　　(tmpB’s setFont:(NSFont’s fontWithName:"Times-Roman" |size|:40))
　　(bArray’s addObject:tmpB)
　　
　　set aCount to aCount + 1
　　
　　
　　–Make Header (Weekday)
　　set curLocale to current application’s NSLocale’s currentLocale()
　　set aDS10 to (curLocale’s objectForKey:(current application’s NSLocaleIdentifier)) as string
　　set wdList to getLocalizedShortStandaloneWeekdaySymbols(aDS10) of me
　　set y to 2
　　
　　repeat with x from 1 to 7
　　　　set j to contents of item x of wdList
　　　　set tmpB to (NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum – 1) * (aButtonCellHeight), aButtonCellWidth, aButtonCellHeight / 2)))
　　　　(tmpB’s setEditable:false)
　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　(tmpB’s setStringValue:(j))
　　　　(bArray’s addObject:tmpB)
　　end repeat
　　
　　set aCalList to retListCalendar(tYear, tMonth) of me
　　set aCount to 1
　　
　　
　　–Make Calendar (Calendar Body)
　　set curDat to current date
　　
　　repeat with y from 3 to rowNum
　　　　repeat with x from 1 to colNum
　　　　　　set j to contents of item aCount of aCalList
　　　　　　set tmpB to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(((x – 1) * aButtonCellWidth), ((aLen – aCount) div colNum – 2) * aButtonCellHeight, aButtonCellWidth, aButtonCellHeight)))
　　　　　　
　　　　　　set tmpDate to getDateInternational(tYear, tMonth, j as integer) of me
　　　　　　set tmpF to (tmpDate < curDat) as boolean
　　　　　　
　　　　　　if ignoreP = false then
　　　　　　　　set dispF to true
　　　　　　else if ignoreP = true and tmpF = false then
　　　　　　　　set dispF to true
　　　　　　else
　　　　　　　　set dispF to false
　　　　　　end if
　　　　　　
　　　　　　if (j as integer) is not in noDispList then
　　　　　　　　if (dispF = true) then
　　　　　　　　　　(tmpB’s setTitle:(j as string))
　　　　　　　　　　(tmpB’s setFont:(NSFont’s fontWithName:"ArialMT" |size|:aFontSize))
　　　　　　　　　　–set attrTitle to makeRTFfromParameters((aCount as string), "ArialMT", aFontSize, 0, (aFontSize * 1.2)) of me
　　　　　　　　　　–(tmpB’s setAttributedTitle:(attrTitle))
　　　　　　　　　　(tmpB’s setShowsBorderOnlyWhileMouseInside:true)
　　　　　　　　　　(tmpB’s setAlignment:(current application’s NSCenterTextAlignment))
　　　　　　　　　　(tmpB’s setEnabled:(j ≠ ""))
　　　　　　　　　　(tmpB’s setTarget:me)
　　　　　　　　　　(tmpB’s setAction:("clicked:"))
　　　　　　　　　　(tmpB’s setButtonType:(NSButtonTypeOnOff))
　　　　　　　　　　(tmpB’s setHidden:(j = ""))
　　　　　　　　　　if j is not equal to "" then
　　　　　　　　　　　　(tmpB’s setTag:(j))
　　　　　　　　　　　　(bArray’s addObject:tmpB)
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　end if
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　end repeat
　　
　　(aView’s setSubviews:bArray)
　　return aView
end makeCalendarView

★Click Here to Open This Script　

透明ウィンドウで時計表示

Posted on 10月 2, 2019 by Takaaki Naganoya

透明のNSTextView＋NSWindowで時計を表示するAppleScriptです。ありものを組み合わせて作ってみました。

テキストビュー＋ボタンをつくる ScriptにTimerを組み合わせたぐらいです。macOS標準装備のスクリプトエディタ上でそのまま動きますし、Script Debugger上でも動作確認ずみです。

この手のプログラムは初心者が割と作りたくなるものの、作ってもそれほど役に立たない上に、「まあ、こんなもんか」という程度にしかなりません。初心者向けといえば初心者向けですが、記述量がそれほど少なくないのが困りものです（Xcode上でAppleScriptでCocoa-Appを書いたほうがずっと短く書けることでしょう）。

それもこれも、実際に動かしてみないとわからないことでしょう。Safariで表示中の表だけCSVに書き出すScriptなどと比べると、ものすごく面白くありません。

AppleScript名：テキストビュー＋ボタンを作成（フォント指定）_+Timer

— Created 2019-10-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSTimer : a reference to current application’s NSTimer
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property NSWindow : a reference to current application’s NSWindow
property NSSplitView : a reference to current application’s NSSplitView
property NSTextView : a reference to current application’s NSTextView
property NSWindowController : a reference to current application’s NSWindowController
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSFloatingWindowLevel : a reference to current application’s NSFloatingWindowLevel
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered

property windisp : false
property aView : missing value

set aFontName to "Arial-Black"
set aWidth to 350
set aHeight to 120
set aTitle to "Clock Test" –Window Title
set aButtonMSG to "OK" –Button Title

set aRes to checkExistenceOfFont(aFontName) of me
if aRes = false then
　　display dialog "There is no <" & aFontName & "> font. Select another one." –No font
　　return
end if
set dispStr to ""

set paramObj to {myWidth:aWidth, myHeight:aHeight, myTitle:aTitle, myBMes:aButtonMSG, myTimeOut:180, myFontID:aFontName, myFontSize:48}
–my dispTextView:aRecObj
my performSelectorOnMainThread:"dispTextView:" withObject:paramObj waitUntilDone:true

on dispTextView:aRecObj
　　set aWidth to myWidth of aRecObj as integer
　　set aHeight to myHeight of aRecObj as integer
　　set aTitle to myTitle of aRecObj as string
　　set aButtonMSG to myBMes of aRecObj as string
　　set timeOutSecs to myTimeOut of aRecObj as integer
　　set fontID to myFontID of aRecObj as string
　　set fontSize to myFontSize of aRecObj as integer
　　
　　set dispStr to ""
　　
　　–Make Timer
　　set aTimer to NSTimer’s scheduledTimerWithTimeInterval:1 target:me selector:"idleHandler:" userInfo:(missing value) repeats:true
　　
　　— Text View Background color
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.0
　　set (my windisp) to true
　　
　　–Text　View＋Scroll Viewをつくる
　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aView’s setRichText:true
　　aView’s useAllLigatures:true
　　aView’s setTextColor:(NSColor’s magentaColor())
　　aView’s setFont:(NSFont’s fontWithName:fontID |size|:fontSize)
　　aView’s setBackgroundColor:aColor
　　aView’s setAlphaValue:1.0
　　aView’s setEditable:false
　　–aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–Buttonをつくる
　　set bButton to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, 40)))
　　bButton’s setTitle:aButtonMSG
　　bButton’s setTarget:me
　　bButton’s setAction:("clicked:")
　　
　　–SplitViewをつくる
　　set aSplitV to NSSplitView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aHeight, aWidth))
　　aSplitV’s setVertical:false
　　
　　aSplitV’s addSubview:aView
　　aSplitV’s addSubview:bButton
　　aSplitV’s setNeedsDisplay:true
　　
　　–WindowとWindow Controllerをつくる
　　set aWin to makeWinWithView(aSplitV, aWidth, aHeight, aTitle, 1.0)
　　aWin’s makeKeyAndOrderFront:(missing value)
　　set wController to NSWindowController’s alloc()
　　wController’s initWithWindow:aWin
　　aWin’s makeFirstResponder:aView
　　aView’s setString:dispStr
　　wController’s showWindow:me
　　
　　set aCount to timeOutSecs * 10 –timeout seconds * 10
　　repeat aCount times
　　　　if (my windisp) = false then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　　　set aCount to aCount – 1
　　end repeat
　　
　　aTimer’s invalidate() –Stop Timer
　　my closeWin:aWin
　　
end dispTextView:

–Button Clicked Event Handler
on clicked:aSender
　　set (my windisp) to false
end clicked:

–make Window for Input
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle, alphaV)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　set aBacking to NSTitledWindowMask –NSBorderlessWindowMask
　　set aDefer to NSBackingStoreBuffered
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　aWin’s setBackgroundColor:(NSColor’s clearColor())
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSFloatingWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setAlphaValue:alphaV –append
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　–aWin’s makeKeyAndOrderFront:(me)
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aWindow
　　aWindow’s |close|()
end closeWin:

–指定PostScript名称のフォントがコンピューター上に存在するかどうかチェック
on checkExistenceOfFont(fontName as string)
　　if fontName = "" then return false
　　set aFont to NSFont’s fontWithName:fontName |size|:9.0
　　if aFont = missing value then
　　　　return false
　　else
　　　　return true
　　end if
end checkExistenceOfFont

–タイマー割り込み
on idleHandler:aSender
　　set mesStr to time string of (current date)
　　aView’s setString:mesStr
end idleHandler:

★Click Here to Open This Script　

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明_Float_SuppressionButtonつき

Posted on 7月 10, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

Xcode上でNSAlert.hを調べ、アラートダイアログに指定できる各種オプションを指定してみました。NSWindowLevelの変更は効いていないみたいですけれども。

AppleScript名：アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明_Float_SuppressionButtonつき

— Created 2019-07-09 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSUserDefaults : a reference to current application’s NSUserDefaults
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel

property returnCode : 0
property supState : false

set asStr to do shell script "cal 2019"
set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:450, mesHeight:200, fontName:"Courier", fontSize:11.0, suppressionMes:"Some Option"}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

return (my supState)

on dispTextViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mesStr to (mes1 of paramObj) as string –Text Input field 1 Label
　　set aWidth to (mesWidth of paramObj) as integer –TextView width
　　set aHeight to (mesHeight of paramObj) as integer –TextView height
　　set aFontName to (fontName of paramObj) as string –TextView font name
　　set aFontSize to (fontSize of paramObj) as real –TextView font size
　　set aSupMes to (suppressionMes of paramObj) as string –Suppression Button Titile
　　
　　–Detect Dark Mode
　　set dMode to retLIghtOrDark() of me
　　if dMode = true then
　　　　set tvCol to 1
　　　　set tvAlpha to 0.8
　　　　set bCol to 0.1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s cyanColor())
　　else
　　　　set tvCol to 0
　　　　set tvAlpha to 0.1
　　　　set bCol to 1
　　　　set bAlpha to 0.5
　　　　set contentCol to (NSColor’s grayColor())
　　end if
　　
　　— Create a TextView with Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:(tvAlpha)
　　
　　aView’s setRichText:true
　　aView’s useAllLigatures:true
　　aView’s setTextColor:(contentCol)
　　aView’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize)
　　
　　aView’s setDrawsBackground:false
　　
　　
　　aView’s setBackgroundColor:aColor
　　aView’s setOpaque:(false)
　　aView’s setString:mesStr
　　aScroll’s setDocumentView:aView
　　–aScroll’s setBorderType:(current application’s NSBezelBorder)
　　–aScroll’s setBorderType:(current application’s NSGrooveBorder)
　　–aScroll’s setBorderType:(current application’s NSLineBorder)
　　aScroll’s setBorderType:(current application’s NSNoBorder)
　　
　　–Ruler
　　–aScroll’s setHasHorizontalRuler:(true)
　　–aScroll’s setRulersVisible:(true)
　　
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　set anImage to current application’s NSImage’s imageNamed:(current application’s NSImageNameComputer)
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setIcon:(anImage)
　　　　
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aScroll)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　
　　　　its setAlertStyle:0 —-0…2
　　　　
　　　　its setShowsSuppressionButton:(true) –「今後このメッセージを表示しない」チェックボックスを表示
　　　　
　　　　set suppressionB to its suppressionButton
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setOpaque:(false)
　　myWindow’s setBackgroundColor:(NSColor’s colorWithCalibratedWhite:(bCol) alpha:(bAlpha))
　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　
　　suppressionB’s setTitle:(aSupMes)
　　suppressionB’s setState:(true) —default state
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set my supState to (suppressionB’s state) as boolean
end dispTextViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る。System Eventsを使っていないのは、macOS 10.14以降対策（承認を取得しなくてもいいように）
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

Posted on 7月 8, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

＃　前バージョンの「自分のソースコード」表示というのは意味不明だったので、プロセス一覧を取得してみました

ヘルプボタン（？）を付け、アラートダイアログのウィンドウ背景を半透明に設定。そのままでは配色の都合上Dark Mode/Light Modeの切り替え時に読みづらい文字なども出てきたため、モード判定を行って表示色などを変更しています。

アプレット書き出ししたときに、スクロールビューがマウスのスクロールホイールの操作に追従したスクロールを行ってくれないので、そのあたり何か追加でNSScrollViewに設定を行う必要があるのだろうかと。

▲スクリプトエディタ上で実行@macOS 10.14.5。左がLight Mode、右がDark Mode（以下同様）

▲ヘルプボタンをクリックしたところ。本当にアンカーを指定して指定のヘルプコンテンツを表示させることもできる模様。そのための基礎的な試験

▲AppleScriptアプレット書き出しして実行したところ

▲Script Debugger上で実行@macOS 10.14.5。Dark Modeに対応できていない（次バージョンで対応することでしょう）

▲Script DebuggerからAppleScript Applet (Enhanced）で書き出して実行したところ。マウスのスクロールホイールの操作を受け付けて文字がスクロールする

AppleScript名：アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

— Created 2019-07-08 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication

property returnCode : 0

–Get Self Source Code (a kind of joke)
set asStr to do shell script "ps -ax"
set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:400, mesHeight:200, fontName:"HiraginoSans-W3", fontSize:11.0}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

アラートダイアログ上にTextViewを表示

Posted on 7月 8, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

とくにこれといって何か表示するものを思いつかなかったので、自分自身のソースコードを取得して表示しています。スクリプトエディタやScript Debugger上で実行した場合には自分自身のソースコードをテキストビュー上で表示します。

読み取り専用のスクリプトやアプレットで実行している場合にはソースコードを取得できません。何か適宜自分で表示させたいテキストを与えてみてください。

AppleScript名：アラートダイアログ上にTexViewを表示

— Created 2019-07-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "OSAKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication
property OSAScript : a reference to current application’s OSAScript

property returnCode : 0

–Get Self Source Code (a kind of joke)
set mePath to path to me
set asStr to getASsourceFor(mePath) of me

set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:400, mesHeight:200, fontName:"HiraginoSans-W3", fontSize:11.0}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
— Original Created 2014-02-23 Shane Stanley
on getASsourceFor(anAlias as {alias, string})
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　error "Compile Error" — handle error
　　else
　　　　set sourceText to theScript’s source()
　　end if
　　
　　return sourceText as string
end getASsourceFor

★Click Here to Open This Script　

Keynoteのテキストアイテム内の文字の実際の幅でリサイズ

Posted on 4月 5, 2019 by Takaaki Naganoya

Keynote書類上のテキストアイテムを、内容の文字の実際の幅でリサイズするAppleScriptです。

▲テキストアイテム中のテキストをコピー（Command-C）

▲リサイズ前のテキストアイテム。文字に対してフレームサイズが大きい

▲本Scriptによりリサイズした後のテキストアイテム。文字の内容に対してフレームサイズがフィットしている

▲本Scriptにより順次複数のテキストアイテムを文字幅にリサイズしたところ。selectionがまともに動作していれば、複数のテキストアイテムを選択した状態でScriptを走らせて一度にリサイズできる（はず）だが、selectionが動作していないので複数のオブジェクトに対して同じ回数の操作が必要

Keynoteにはversion 9.0で「selection」の予約語が追加されましたが、これは一般に期待されるような「表示中のスライド上で選択中のオブジェクトへの参照が取得できる」というものではありません。

つまり、選択中のオブジェクトへの参照をKeynoteに対して問い合わせることは、（現時点では）不可能です。

そこで、テキストアイテム内の内容（object text）をコピー（Command-C）してクリップボードに格納し、その内容をキーにして現在表示中のスライド内のテキストアイテムを抽出してみたところ、うまくいきました（なんでこんなことさせられてるんだろ？）。早くselectionがKeynote上でもまともに使えるようになってほしいものです（Pages上ではけっこういい感じに使えるのに）。

テキストアイテムの特定ができるようになったので、入っているobject textのサイズに合わせてテキストアイテムをリサイズする処理を書いてみました。

クリップボードの内容をNSAttributedStringとして取得し、その画面上の描画サイズを取得するサブルーチンは毎日さんざん使っているので（掲載リストのproperty宣言部をソートするのに使っています）信頼性があります。

とりあえず、擬似的に現在選択中のオブジェクトを特定する実験コードにちょっとだけ機能をつけたものですが、操作１に対して結果１というのは普通「自動化」とか言わないので、実用性は皆無です（めんどくさい操作ステップを省けるぐらいしか）。

AppleScript名：Keynoteのテキストアイテム内の文字の実際の幅でリサイズ

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/05
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use BPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSPasteboard : a reference to current application’s NSPasteboard
property NSAttributedString : a reference to current application’s NSAttributedString
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

load framework

–クリップボードの内容をテキストとして取得し、現在のKeynote書類中のtext itemのうちコピーしたテキストに該当するものを抽出
set targString to (the clipboard) as string

tell application "Keynote"
　　tell document 1
　　　　tell current slide
　　　　　　set tList to every text item whose object text is targString
　　　　　　if tList = {} then return
　　　　　　set targObject to first item of tList
　　　　end tell
　　end tell
end tell

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()

–Split Attributed Strings into lines
set attrList to splitAttributedStringByLines(anAttr) of me

–Sort Attributed String list by its width in descending (large–> small)
set aResList to shellSortListDecending(attrList, 1) of me
set {targObjWidth, targAttrStrObj} to first item of aResList

–Resize Text item objet’s frame by its drawing width on screen
tell application "Keynote"
　　tell document 1
　　　　tell current slide
　　　　　　tell targObject
　　　　　　　　set width to ((targObjWidth as number) + 10) –resize it !
　　　　　　end tell
　　　　end tell
　　end tell
end tell

–入れ子のリストを昇順ソート
on shellSortListAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end shellSortListAscending

–入れ子のリストを降順ソート
on shellSortListDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end shellSortListDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　–Sort
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　
　　return resList
end sort2DList

— クリップボードの内容をNSAttributedStringとして取り出して返す
on getClipboardASStyledText()
　　try
　　　　set theNSPasteboard to NSPasteboard’s generalPasteboard()
　　　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({NSAttributedString}) options:(missing value)
　　　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　　　return theNSAttributedString
　　on error
　　　　return missing value
　　end try
end getClipboardASStyledText

on splitAttributedStringByLines(theStyledText)
　　set outList to {}
　　set outAttr to NSMutableAttributedString’s alloc()’s initWithString:""
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　set aText to (thePureString’s substringWithRange:theRange) as string –String
　　　　
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor") –Color
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont") –Font
　　　　if aFont is equal to missing value then error "Not font name and size are specified" –Font Name error
　　　　set aDFontName to aFont’s displayName() –Font Name
　　　　set aDFontSize to aFont’s pointSize() –Font Size
　　　　
　　　　set tmpAttrStr to generateAttributedString(aText, aDFontName, aDFontSize, aColor) of me
　　　　outAttr’s appendAttributedString:tmpAttrStr
　　　　
　　　　if (aText contains return) or (aText contains string id 10) then –CR or LF
　　　　　　set tmpSize to outAttr’s |size|()
　　　　　　set tmpWidth to retWidthFromSize(tmpSize) of me
　　　　　　
　　　　　　set the end of outList to {tmpWidth, outAttr}
　　　　　　set outAttr to NSMutableAttributedString’s alloc()’s initWithString:""
　　　　end if
　　　　
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　end repeat
　　
　　set tmpSize to outAttr’s |size|()
　　set tmpWidth to retWidthFromSize(tmpSize) of me
　　set the end of outList to {tmpWidth, outAttr}
　　
　　return outList
end splitAttributedStringByLines

on retWidthFromSize(tmpSize)
　　if class of tmpSize = record then
　　　　–macOS 10.10, 10.11, 10.12
　　　　set tmpWidth to width of tmpSize
　　else
　　　　–macOS 10.13, 10.14
　　　　set tmpWidth to first item of tmpSize
　　end if
　　return tmpWidth
end retWidthFromSize

on generateAttributedString(aStr, aFontPSName, aFontSize, aColor)
　　set tmpAttr to NSMutableAttributedString’s alloc()’s initWithString:aStr
　　set aRange to current application’s NSMakeRange(0, tmpAttr’s |length|())
　　set aVal1 to NSFont’s fontWithName:aFontPSName |size|:aFontSize
　　tmpAttr’s beginEditing()
　　tmpAttr’s addAttribute:(NSFontAttributeName) value:aVal1 range:aRange
　　tmpAttr’s addAttribute:(NSForegroundColorAttributeName) value:aColor range:aRange
　　tmpAttr’s endEditing()
　　return tmpAttr
end generateAttributedString

★Click Here to Open This Script　

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

Posted on 3月 29, 2019 by Takaaki Naganoya

英語版の花文字テキストを作成してテキストエディタ（CotEditor）に出力するAppleScriptです。

描画用の英単語と、塗りつぶし用の英単語を別々に指定できます。invertFをtrueに設定すると、白黒反転出力を行います。

おおもとの元ネタは、大型計算機を大勢のユーザーで共有していた時代（ぱそこん登場前）、計算結果を高速プリンタの帳票に出力するようになっていたころにさかのぼります。どのユーザーの計算結果かを大量のプリンタの出力結果の中から仕分けるため、印刷出力の１ページ目をユーザー名などの情報を印字した「バナー」として使用。

そのさい、ドットインパクトプリンターだったので、決められた固定ドット数の文字しか印字できないため、英数字を組み合わせて擬似的に大きな文字でバナーを印刷していたことに端を発します。

その時代の「残り香」ともいえるバナーがパソコンの電子メールやBBSの時代にお遊びの「花文字」として引き継がれ、原始的なアスキーアートの一種として楽しまれてきました。

いまでも、shell commandの「banner」コマンドにその末裔を見ることができます。

先週のmacOS nativeのデモ時に「祝」という花文字を「呪」の文字で出力するという、定番の持ちネタを披露したところ、たいへんウケておりました。

ただ、これを海外のScripter向けにそのままデモしても受けません。

この、花文字テキストを出力するプログラムの英語版としては、love.scptといういにしえのデータをそのまま使いまわしたものがありますが、描画パターンを数値データで保持しているため、異なるパターンを表示させることはできません。

そこで、日本語版の花文字テキスト出力プログラムに若干手をくわえ、英単語の出力が行えるようにしてみました。

テキストの出力はCotEditorに対して行なっていますが、新規書類を指定文字で作成する程度なので、AppleScriptに対応しているテキストエディタならどれでも作り変えられます。また、表示を等幅フォントにしておく必要があります（あとから指定してもOK）。

AppleScript名：指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

— Created 2017-12-12 by Takaaki Naganoya
— Modified 2019-03-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSColorSpace : a reference to current application’s NSColorSpace
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSFontManager : a reference to current application’s NSFontManager
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property fillCharList : {}
property fillCharCounter : 1

set aString to "Love"
set bString to "hate"
set hanaSize to 24
set thisFont to selectAFont(first character of aString) of me
if thisFont = false then return –Cancel

–花文字文字列を作成
set fRes to getEnglishHanamojiStr(hanaSize, thisFont, aString, bString, 0.7, true, true) of me
makeNewDocument given parameter:fRes

–花文字文字列を計算して返す
on getEnglishHanamojiStr(aFontSize as real, aFontName as string, aString as string, fillString as string, aThread as real, incFontName as boolean, invertF as boolean)
　　
　　set my fillCharList to characters of fillString
　　set my fillCharCounter to 1
　　
　　–指定文字コードが指定フォント中に存在するかチェック
　　repeat with i in (characters of aString)
　　　　set fRes to retGlyphsInFont(aFontName, id of i) of me
　　　　if fRes = false then return false
　　end repeat
　　
　　set aThreadShould to 768 * aThread
　　if (chkMultiByteChar(first character of aString) of me) = false then
　　　　set spaceChar to string id 12288 –全角スペース（UTF-16）
　　else
　　　　set spaceChar to string id 32 –半角スペース
　　end if
　　
　　set fillColor to NSColor’s whiteColor –塗り色
　　set bString to aString & " " –処理内容の帳尻合わせ（そのままだと右端が欠けるのでスペースを入れた）
　　set anAssrStr to makeRTFfromParameters(bString, aFontName, aFontSize, -2, (aFontSize * 1.2)) of me
　　set aSize to anAssrStr’s |size|()
　　
　　if class of aSize = record then
　　　　set attrStrWidth to width of aSize
　　　　set attrStrHeight to height of aSize
　　else if class of aSize = list then –macOS 10.13.xのバグ回避
　　　　copy aSize to {attrStrWidth, attrStrHeight}
　　end if
　　
　　set {xPos, yPos} to {0, 0}
　　
　　set tmpImg1 to makeImageWithFilledColor(attrStrWidth, attrStrHeight, fillColor) of me
　　set tmpImg2 to drawAttributedStringsOnImage(tmpImg1, anAssrStr, xPos, yPos) of me
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:(tmpImg2’s TIFFRepresentation())
　　
　　–画像から順次指定座標の色データを拾って花文字listに反映
　　set strList to {}
　　repeat with y from 1 to attrStrHeight – 1
　　　　
　　　　set strListX to {}
　　　　repeat with x from 0 to attrStrWidth – 1
　　　　　　set tmpCol to getColorFromRawImage(aRawimg, x, y) of me
　　　　　　
　　　　　　if invertF = false then
　　　　　　　　
　　　　　　　　–通常描画（invert = false）時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　else
　　　　　　　　–白黒反転（invert = true)時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　end if
　　　　end repeat
　　　　set the end of strList to strListX
　　end repeat
　　
　　–2D List→Text
　　set aRes to list2dToStringByUsingDelimiters(strList, "", return) of me
　　
　　if incFontName = true then
　　　　set fName to getDisplayedNameOfFont(aFontName) of me
　　　　set aRes to "Font=" & fName & return & return & aRes
　　end if
　　
　　return aRes
end getEnglishHanamojiStr

on getChar()
　　set retChar to item (my fillCharCounter) of (my fillCharList)
　　if (my fillCharCounter) = length of (my fillCharList) then
　　　　set (my fillCharCounter) to 1
　　else
　　　　set (my fillCharCounter) to (my fillCharCounter) + 1
　　end if
　　return retChar
end getChar

–指定Raw画像中の指定座標のピクセルの色をRGBで取り出す
on getColorFromRawImage(aRawimg, x as real, y as real)
　　set aRatio to getImageRatio() of me –Retina Display対応
　　set origColor to (aRawimg’s colorAtX:(x * aRatio) y:(y * aRatio))
　　
　　set srgbColSpace to NSColorSpace’s deviceRGBColorSpace
　　if srgbColSpace = missing value then return false
　　
　　set aColor to (origColor’s colorUsingColorSpace:srgbColSpace)
　　
　　set aRed to (aColor’s redComponent()) * 255
　　set aGreen to (aColor’s greenComponent()) * 255
　　set aBlue to (aColor’s blueComponent()) * 255
　　
　　return {aRed as integer, aGreen as integer, aBlue as integer}
end getColorFromRawImage

–画像のうえに指定のスタイル付きテキストを描画して画像を返す
on drawAttributedStringsOnImage(anImage, anAssrStr, xPos as real, yPos as real)
　　anImage’s lockFocus()
　　anAssrStr’s drawAtPoint:(current application’s NSMakePoint(xPos, yPos))
　　anImage’s unlockFocus()
　　return anImage
end drawAttributedStringsOnImage

–指定サイズの画像を作成し、背景を指定色で塗る
on makeImageWithFilledColor(aWidth as real, aHeight as real, fillColor)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　set aRatio to getImageRatio() of me –Retina Display対応
　　
　　anImage’s lockFocus()
　　set theRect to {{x:0, y:0}, {width:aWidth * aRatio, height:aHeight * aRatio}}
　　set theNSBezierPath to NSBezierPath’s bezierPath
　　theNSBezierPath’s appendBezierPathWithRect:theRect
　　fillColor’s |set|()
　　theNSBezierPath’s fill()
　　anImage’s unlockFocus()
　　
　　return anImage
end makeImageWithFilledColor

–2D Listをアイテム間および行間のデリミタを個別に指定してテキスト変換
on list2dToStringByUsingDelimiters(aList as list, itemDelimiter, lineDelimiter)
　　set outList to {}
　　repeat with i in aList
　　　　set aStr to listToStringUsingTextItemDelimiter(i, itemDelimiter) of me
　　　　set the end of outList to aStr
　　end repeat
　　
　　set bStr to listToStringUsingTextItemDelimiter(outList, lineDelimiter) of me
　　return bStr
end list2dToStringByUsingDelimiters

on listToStringUsingTextItemDelimiter(sourceList as list, textItemDelimiter)
　　set CocoaArray to NSArray’s arrayWithArray:sourceList
　　set CocoaString to CocoaArray’s componentsJoinedByString:textItemDelimiter
　　return (CocoaString as string)
end listToStringUsingTextItemDelimiter

–ユーザー環境にインストールされているすべてのフォントのPostScript名とグリフ数を返す
on getEveryFontPSNameANdGlyphsNum(aStr)
　　set aFontList to NSFontManager’s sharedFontManager()’s availableFonts()
　　set thePred to NSPredicate’s predicateWithFormat:"NOT SELF BEGINSWITH ’.’"
　　set aFontList to (aFontList’s filteredArrayUsingPredicate:thePred) as list
　　
　　set aList to {}
　　repeat with i in aFontList
　　　　set aName to contents of i
　　　　set aNum to countNumberOfGlyphsInFont(aName) of me
　　　　set dName to getDisplayedNameOfFont(aName) of me
　　　　
　　　　set fRes to retGlyphsInFont(aName, id of aStr) of me
　　　　if fRes = true then
　　　　　　set the end of aList to {fontName:aName, fontNum:aNum, dispName:dName}
　　　　end if
　　end repeat
　　
　　return aList
end getEveryFontPSNameANdGlyphsNum

–指定Postscript名称のフォントに定義されている文字数を数えて返す
on countNumberOfGlyphsInFont(fontName as string)
　　set aFont to NSFont’s fontWithName:fontName |size|:9.0
　　if aFont = missing value then return false
　　set aProp to aFont’s numberOfGlyphs()
　　return aProp as number
end countNumberOfGlyphsInFont

–フォントのPostScript NameからDisplayed Nameを取得
on getDisplayedNameOfFont(aName as string)
　　set aFont to NSFont’s fontWithName:aName |size|:9.0
　　set aDispName to (aFont’s displayName()) as string
　　return aDispName
end getDisplayedNameOfFont

–全角文字が存在するか
on chkMultiByteChar(checkString as string)
　　set aStr to NSString’s stringWithString:checkString
　　set aRes to aStr’s canBeConvertedToEncoding:(current application’s NSASCIIStringEncoding)
　　return (aRes as boolean)
end chkMultiByteChar

–指定名称のフォントに指定の文字コードが含まれているかチェック
on retGlyphsInFont(fontName as string, strCode as integer)
　　set aFont to NSFont’s fontWithName:fontName |size|:24.0
　　if aFont = missing value then return false
　　set aSet to aFont’s coveredCharacterSet()
　　set aRes to (aSet’s characterIsMember:strCode) as boolean
　　return aRes as list of string or string –as anything
end retGlyphsInFont

on selectAFont(aString)
　　set fRes to getEveryFontPSNameANdGlyphsNum(aString) of me
　　set theArray to NSArray’s arrayWithArray:fRes
　　set thePred to NSPredicate’s predicateWithFormat:"fontNum > 10000"
　　set bArray to ((theArray’s filteredArrayUsingPredicate:thePred)’s valueForKeyPath:"dispName") as list
　　set thisFont to choose from list bArray
　　return thisFont
end selectAFont

–Retina Display対応ルーチン
on getImageRatio()
　　set retinaF to detectRetinaDisplay() of me
　　if retinaF = true then
　　　　return 2.0 as real
　　else
　　　　return 1.0 as real
　　end if
end getImageRatio

on detectRetinaDisplay()
　　set dispList to current application’s NSScreen’s screens()
　　set retinaF to false
　　
　　repeat with i in dispList
　　　　set j to contents of i
　　　　set aDepth to j’s backingScaleFactor()
　　　　if aDepth > 1.0 then
　　　　　　set retinaF to true
　　　　end if
　　end repeat
　　
　　return retinaF
end detectRetinaDisplay

on makeNewDocument given parameter:aStr
　　tell application id "com.coteditor.CotEditor"
　　　　activate
　　　　set newDoc to make new document
　　　　tell newDoc
　　　　　　set contents to aStr
　　　　end tell
　　end tell
end makeNewDocument

★Click Here to Open This Script　

アラートダイアログ上に縦棒グラフを表示

Posted on 3月 4, 2019 by Takaaki Naganoya

アラートダイアログ上に縦棒グラフを表示するAppleScriptです。

グラフを作成するのであれば、NumbersやKeynoteなどを使ったほうがいいですが、簡単にデータの傾向だけダイアログ上で見せたいような場合のために作成した部品です。

NSImageViewの表示実験がしたかっただけなので、別に他の言語処理系で作成したグラフ画像を読み込んでNSImageに読み込んでからNSIMageViewで表示するぐらいの使い方でもぜんぜんOKでしょう。

WebViewを表示してインタラクティブなグラフ（マウスカーソルに反応してアニメーション表示を行うとか）を表示するといった使い方もよさそうです（アプリケーション化しないとダメかも）。

macOS 10.14上のDark Modeについては、実行環境によって対応度が異なります。

▲macOS 10.14上のDark Modeで実行したところ。左側からスクリプトエディタ、AppleScriptアプレット、スクリプトメニュー

▲macOS 10.14上のDark Modeで実行したところ。左側からScript Debugger、Script DebuggerからSD拡張アプレットで書き出したもの

グラフの描画については、色指定をblackColor()とかgrayColor()などと指定せずに、Dark Mode時に制御されるUI色で指定しておく必要があることでしょう。

AppleScript名：アラートダイアログ上に縦棒グラフを表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/04
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSFont : a reference to current application’s NSFont
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSScreen : a reference to current application’s NSScreen
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSImageView : a reference to current application’s NSImageView
property NSMutableArray : a reference to current application’s NSMutableArray
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
property NSImageScaleProportionallyUpOrDown : a reference to current application’s NSImageScaleProportionallyUpOrDown

property returnCode : 0

set plotData to {20, 30, 100, 80, 150, 90}
set paramObj to {myMessage:"This is a graph", mySubMessage:"Browse bar graph", aPlotData:plotData}
my performSelectorOnMainThread:"displayBarGraph:" withObject:(paramObj) waitUntilDone:true

on displayBarGraph:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aPlotData of paramObj) as list
　　
　　— make NSIMageView with graph image
　　set anImage to makeGraphImage(aTList, 300, 200) of me
　　set anImageView to NSImageView’s alloc()’s initWithFrame:{origin:{x:0.0, y:0.0}, |size|:{width:300.0, height:200.0}}
　　anImageView’s setImageScaling:(NSImageScaleProportionallyUpOrDown)
　　anImageView’s setEditable:false
　　anImageView’s setImage:anImage
　　anImageView’s display()
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:anImageView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end displayBarGraph:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeGraphImage(plotData, aWidth, aHeight)
　　set innerGapL to 30
　　set innerGapU to 10
　　set innerGapR to 20
　　set innerGapD to 20
　　set barGap to 10
　　
　　–パラメータから下地になる画像を作成する
　　set aSize to current application’s NSMakeSize(aWidth, aHeight)
　　set anImage to NSImage’s alloc()’s initWithSize:aSize
　　
　　–各種パラメータの計算
　　–copy plotArea to {plotWidth, plotHeight}
　　set itemNum to count every item of plotData
　　set barThickness to (aWidth – (itemNum * barGap * 2)) div itemNum
　　
　　–プロットデータの最大値
　　set anArray to NSArray’s arrayWithArray:plotData
　　set aYmax to (anArray’s valueForKeyPath:"@max.self")’s intValue()
　　set aMaxYVal to aHeight – innerGapU – innerGapD
　　set aYPlotArea to aHeight – innerGapU – innerGapD – 20
　　set aYUnit to aYPlotArea / aYmax
　　
　　–数値データをもとに描画データを組み立てる
　　set drawList to {}
　　
　　set startX to innerGapL
　　copy startX to origX
　　
　　repeat with i in plotData
　　　　set the end of drawList to current application’s NSMakeRect(startX, innerGapD, barThickness, innerGapD + (i * aYUnit))
　　　　set startX

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSFont

アラートダイアログ上のTable Viewで起動中のアプリケーションを選択 v3c

アラートダイアログ上に印刷対象ページ一覧を表示して対象ページを指定

システムフォントをWeightつきで指定

プログラムで作ったアラートダイアログ上のTextViewをフォーカスする

システムフォントの名称を取得

NSFontPanelでフォントを選択

RoundWindow v2

（１）Subclassファイル（複数可）をXcode上のプロジェクトで書くようなスタイルで書く

（２）実行するメインのScriptのResourcesフォルダ内にSubclassファイルを入れる

（３）use framework “AppleScriptObjC”の宣言文を追加

（４）メインスクリプトの実行時に以下の処理を実行

指定のフォントとサイズに該当するテキストを抽出する v3

アラートダイアログ上にカレンダー１か月分を表示して選択有効日指定あり v3a

（１）カレンダーの表示サイズを大型化

（２）選択無効日指定

（３）過去日付の選択無効

（４）曜日を現在のLocale情報から変更

透明ウィンドウで時計表示

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明_Float_SuppressionButtonつき

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

アラートダイアログ上にTextViewを表示

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2