アラートダイアログでMarkdownをプレビュー v2

Posted on 8月 8, 2020 by Takaaki Naganoya

edama2さんから投稿していただいた、Markdown書類をダイアログ上でプレビューするScriptの第二弾です。

WKWebViewではなくNSAttributedStringを使ってMarkdownを表示しています。
NSAttributedStringでhtmlが表示できるとわかってWKWebViewの代わりになるかな？と思ったんですが、javascriptは使えないので自前で実行し、NSAttributedStringに＜hr＞に相当するものがないのとWKWebViewとは描画結果が違うので、プレビューとして使うのはイマイチです。作っておいてなんですが…😢

本Scriptの見どころは２点。「Scriptバンドル内にJavaScriptのライブラリを突っ込んで呼び出しているところ」と、「Markdownを（HTML経由で）NSAttributedStringに変換してプレビューしている」ところです。

ひかえめな説明文とは裏腹に、ずいぶんと攻めているというか、野心的な実装です。

JavaScriptのライブラリをローカルに置く案についてはいろいろedama2さんと意見交換をしていたんですが、割とさらっと書いているところにショックを受けます。これだけでも、相当に試行錯誤が必要な内容なんですが、このレベルに追いつくためには相当の苦労が、、、

AppleScript名：アラートダイアログでMarkdownをプレビュー v2

use AppleScript
use framework "Foundation"
use scripting additions

on run
　　my main()
end run

on main()
　　set mes to "Markdownファイルを選択してください。"
　　set chooseItems to choose file of type {"net.daringfireball.markdown"} with prompt mes
　　
　　#
　　set aScreen to current application’s NSScreen’s mainScreen()
　　set screenFrame to aScreen’s frame()
　　set aHeight to current application’s NSHeight(screenFrame)
　　set aWidth to current application’s NSWidth(screenFrame)
　　set aHeight to aHeight * 0.845
　　set aWidth to aWidth * 0.94 / 2
　　
　　set paramObj to {}
　　set paramObj to paramObj & {myMessage:"Markdown preview"}
　　set paramObj to paramObj & {mySubMessage:"file : " & chooseItems’s POSIX path}
　　set paramObj to paramObj & {mdFile:chooseItems}
　　set paramObj to paramObj & {viewWidth:aWidth}
　　set paramObj to paramObj & {viewHeight:aHeight}
　　
　　my performSelectorOnMainThread:"displayMarkdownPreview:" withObject:(paramObj) waitUntilDone:true
end main

# Markdownをダイアログで表示
on displayMarkdownPreview:paramObj
　　set mesText to myMessage of paramObj as text
　　set infoText to mySubMessage of paramObj as text
　　set mdFile to (mdFile of paramObj) as alias
　　set viewWidth to (viewWidth of paramObj) as integer
　　set viewHeight to (viewHeight of paramObj) as integer
　　
　　## MDを読み込む
　　set mdStr to (read mdFile as «class utf8») as text
　　
　　## javascriptを読み込む
　　set mePath to path to me
　　set resPath to (mePath & "Contents:Resources:marked.min.js") as text
　　set jsStr to (read (resPath as alias) as «class utf8») as text
　　
　　## javascriptでMarkdownをhtmlに変換
　　tell current application’s JSContext’s new()
　　　　evaluateScript_(jsStr)
　　　　tell objectForKeyedSubscript_("marked")
　　　　　　tell callWithArguments_({mdStr})
　　　　　　　　set resultStr to toString()
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　## HTMLを読み込む
　　set mePath to path to me
　　set resPath to (mePath & "Contents:Resources:index.html") as text
　　set htmlStr to (read (resPath as alias) as «class utf8») as text
　　
　　## html内の文字を置き換え
　　set aString to current application’s NSString’s stringWithFormat_(htmlStr, resultStr) as text
　　log result
　　
　　
　　## NSAttributedString
　　set aString to current application’s NSString’s stringWithString:aString
　　set stringData to aString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　
　　set aValue to {current application’s NSHTMLTextDocumentType, current application’s NSUTF8StringEncoding}
　　set aKey to {current application’s NSDocumentTypeDocumentAttribute, current application’s NSCharacterEncodingDocumentAttribute}
　　set aOption to current application’s NSDictionary’s dictionaryWithObjects:aValue forKeys:aKey
　　
　　tell current application’s NSAttributedString’s alloc()
　　　　tell initWithHTML_options_documentAttributes_(stringData, aOption, missing value)
　　　　　　set attributedString to it
　　　　end tell
　　end tell
　　log result
　　
　　# Create a TextView with Scroll View
　　set frameSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　tell current application’s NSTextView’s alloc()
　　　　tell initWithFrame_(frameSize)
　　　　　　setEditable_(false)
　　　　　　tell textStorage()
　　　　　　　　appendAttributedString_(attributedString)
　　　　　　end tell
　　　　　　set aView to it
　　　　end tell
　　end tell
　　tell current application’s NSScrollView’s alloc()
　　　　tell initWithFrame_(frameSize)
　　　　　　setDocumentView_(aView)
　　　　　　set theView to it
　　　　end tell
　　end tell
　　
　　
　　## アイコンの指定
　　set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:"net.daringfireball.markdown"
　　
　　## set up alert
　　tell current application’s NSAlert’s new()
　　　　addButtonWithTitle_("Close")
　　　　setAccessoryView_(theView)
　　　　setIcon_(aImage)
　　　　setInformativeText_(infoText)
　　　　setMessageText_(mesText)
　　　　tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
　　　　### show alert in modal loop
　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell
end displayMarkdownPreview:

★Click Here to Open This Script　

そして、本Scriptをよくよく見回してみると、NSAttributedStringになっているのでPDFに変換するのがとても簡単でした。WkWebView上に表示したWebコンテンツをPDF化しようと試みているものの、うまくできていません。Blocks構文を必要とする機能であるため（なんでこんなものまでBlocks（非同期実行）必要なんだろ？）、AppleScriptからの呼び出しができないためです。Xcode上で他の言語をまじえて組めば不可能ではない気もしますが……

CSSがWeb表示用のものなので、PDF出力時には割とゆったり目で密度の低いレイアウトになってしまうものの、このCSS指定を別のものにできればけっこうMarkdown→PDFの変換を行う部品として使えるレベルになってくるのではないでしょうか。それはそれで、Scriptバンドル内に入れたCSSを指定するとか、Web上のどこかに印刷用のCSSをホスティングしておくなどの方法が必要になることでしょう。

(Visited 91 times, 1 visits today)

プログラムで作ったアラートダイアログ上のTextViewをフォーカスする

Posted on 4月 14, 2020 by Takaaki Naganoya

AppleScriptでダイナミックに（動的に）生成したアラートダイアログ上にテキストビューを生成し、そのテキストビュー上にテキスト入力用のキャレットを移動させる（フォーカスする）AppleScriptです。

Xcode上でAppleScriptでGUIアプリケーションを作っていて、文字サイズの大きなテキスト入力フィールドを動的に生成。さらに、テキスト入力フィールドにテキスト入力用のキャレットを移動させようとして、割と手こずっていました。

テキスト入力を受け付けるGUI部品に対して、入力フォーカスを与え、テキスト入力のキャレットが置かれた状態を再現するには、GUIの画面上からはマウスカーソルでクリック操作するとできます。同じ状態をプログラム側から作る場合にはFirstResponderにセットするという処理になります。

この、FirstResponderに指定することは理解でき、Xcode（Interface Builder）上で配置した部品に対して実行する処理は昔からやっています。NSTextFieldに強制的に入力フォーカスを置いた上でバーコードリーダーからのテキスト入力を受け付けるといった処理です。

一方、プログラムから動的に生成したGUI部品に対して、Cocoaが用意しているAPIのどれを用いて、どのように指定すべきなのかで困りました。

親WindowのFirstResponderにしてみたり、アラートウィンドウのFirstResponderにしてみたり、いろいろ試した末に、

parentWin's setInitialFirstResponder:aView

で、Alert DialogのWindowをparentWinに、alert dialog上のテキストビューをaViewに代入した状態で実行して、入力キャレットをテキストビュー上に移動できました。本Xcode Projectは上記の１行の記述の検証を行うためのテストプロジェクトです。

–> Download Xcode Project

AppleScript名：AppDelegate.applescript

—
— AppDelegate.applescript
— dialogCarret
—
— Created by Takaaki Naganoya on 2020/04/14.
— Copyright © 2020 Takaaki Naganoya. All rights reserved.
—

script AppDelegate
　　property parent : class "NSObject"
　　
　　property |NSURL| : a reference to current application’s |NSURL|
　　property NSFont : a reference to current application’s NSFont
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSTextView : a reference to current application’s NSTextView
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　property returnCode : 0
　　property resStr : ""
　　
　　
　　on applicationWillFinishLaunching:aNotification
　　　　—
　　end applicationWillFinishLaunching:
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on clicked:sender
　　　　set tmpStr to "TEST"
　　　　set paramObj to {myMessage:"Input Text", mySubMessage:"", mes1:(tmpStr), mesWidth:400, mesHeight:200}
　　　　my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true
　　　　set aResText to (my resStr) as string
　　　　
　　　　display dialog aResText
　　end clicked:
　　
　　on dispTextViewWithAlertdialog:paramObj
　　　　–Receive Parameters
　　　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　　　set mesStr to (mes1 of paramObj) as string –Text Input field 1 Label
　　　　set aWidth to (mesWidth of paramObj) as integer –TextView width
　　　　set aHeight to (mesHeight of paramObj) as integer –TextView height
　　　　
　　　　set vNum to system attribute "sys2"
　　　　if vNum > 13 then
　　　　　　set apRes to retLightOrDark() of me
　　　　　　if apRes = true then
　　　　　　　　set textColor to (current application’s NSColor’s cyanColor())
　　　　　　else
　　　　　　　　set textColor to (current application’s NSColor’s blackColor())
　　　　　　end if
　　　　else
　　　　　　set textColor to (current application’s NSColor’s blackColor())
　　　　end if
　　　　
　　　　
　　　　— Create a TextView with Scroll View
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　aView’s setDelegate:me
　　　　aView’s setRichText:true
　　　　aView’s useAllLigatures:true
　　　　aView’s setTextColor:textColor
　　　　aView’s setFont:(current application’s NSFont’s systemFontOfSize:90.0)
　　　　set aColor to current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.1
　　　　
　　　　aView’s setBackgroundColor:aColor
　　　　aView’s setString:mesStr
　　　　aScroll’s setDocumentView:aView
　　　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　
　　　　— set up alert
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　–its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aScroll
　　　　　　set parentWin to its |window|()
　　　　end tell
　　　　
　　　　parentWin’s setAlphaValue:0.8
　　　　–parentWin’s setOpaque:(false)
　　　　parentWin’s setLevel:(current application’s NSScreenSaverWindowLevel)
　　　　
　　　　parentWin’s setInitialFirstResponder:aView —Place Input Carret to Alert Dialog
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　
　　　　if (my returnCode as number) = 1001 then
　　　　　　—
　　　　else
　　　　　　set my resStr to aView’s |string|()
　　　　end if
　　end dispTextViewWithAlertdialog:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to aParam’s runModal()
　　end doModal:
　　
　　
　　on retLightOrDark()
　　　　return true
　　end retLightOrDark
　　
end script

★Click Here to Open This Script　

(Visited 161 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

Posted on 1月 15, 2020 by Takaaki Naganoya

Edama2さんからの投稿Scriptです。アラートダイアログ中に各種GUI部品を詰め込む「箱庭インタフェース」シリーズ。テーブルビューを表示して、Finderからのアプリケーションのドラッグ＆ドロップを受け付けるAppleScriptです。

–> Download Editable & Executable Script Bundle Document

カスタムクラスの作り方がわかったので、懲りずにTable Viewネタです。
Thanks  Shane Stanley!

アプリケーションフォルダ直下のアプリを、NSValueTransformerを使ってコラムにローカライズ名とアイコンを表示するのと、finderからのドラッグ＆ドロップでアイテムの追加です。
追加時に重複チェックをしているので試す時はユーティリティフォルダか別の場所にあるアプリで試してください。

本Scriptは自分も作りたいと思いつつも調査が進んでいなかったものですが、TableViewでFinderからのドラッグ＆ドロップを受け付けます。

これを鍛えて再利用しやすい部品に育てることで、ドロップレットの代替品にできると思っています。macOS 10.12以降、Finder上のファイルをAppleScriptドロップレットにドラッグ＆ドロップで処理させても、OS側がダウンロードファイルにつけた拡張属性（Xattr）「com.apple.quarantine」がついているとドロップレット側で処理できなかったりします（回避方法はありますけれども）。

このドロップレットという仕組みを使わずに、同様にドラッグ＆ドロップによる処理を手軽にできる代替インタフェースとしてこのようなものを考えていた次第です。自分で作らなくてもEdama2さんが作ってくださったので助かりました、、、、

AppleScript名：アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

on run
　　my main()
end run
on main()
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　#
　　set aFolder to path to applications folder
　　set aPath to aFolder’s POSIX path
　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　
　　set filePaths to filePaths as list
　　set thisFileType to "com.apple.application-bundle"
　　
　　set fileURLs to {}
　　repeat with anItem in filePaths
　　　　
　　　　set aPath to anItem’s contents’s POSIX path
　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　
　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　
　　　　if (aUTI as text) is thisFileType then
　　　　　　set fileURLs’s end to aURL
　　　　end if
　　end repeat
　　
　　set optionRec to {fileURLs:fileURLs, fileType:thisFileType}
　　
　　set aMainMes to "アプリケーションの選択"
　　set aSubMes to "適切なものを以下からえらんでください"
　　set dateObj to my chooseItemByTableView(aMainMes, aSubMes, optionRec)
end main

# アラートダイアログでtableviewを表示
on chooseItemByTableView(aMainMes, aSubMes, optionRec)
　　### set up view
　　set {theView, makeObj} to my makeContentView(optionRec)
　　
　　set paramObj to {myMessage:aMainMes, mySubMessage:aSubMes, setView:theView, myOption:makeObj}
　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　
　　if (my _retrieve_data) is missing value then error number -128
　　return (my _retrieve_data)
end chooseItemByTableView

## retrieve date
on raizeAlert:paramObj
　　set mesText to paramObj’s myMessage
　　set infoText to paramObj’s mySubMessage
　　set theView to paramObj’s setView
　　set aTableObj to paramObj’s myOption
　　
　　global _retrieve_data
　　set _retrieve_data to missing value
　　
　　### set up alert
　　tell current application’s NSAlert’s new()
　　　　setMessageText_(mesText)
　　　　setInformativeText_(infoText)
　　　　addButtonWithTitle_("OK")
　　　　addButtonWithTitle_("Cancel")
　　　　setAccessoryView_(theView)
　　　　tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
　　　　#### show alert in modal loop
　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell
　　
　　### retrieve date
　　set aIndexSet to aTableObj’s selectedRowIndexes()
　　
　　set chooseItems to ((aTableObj’s dataSource())’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　set _retrieve_data to {}
　　repeat with anItem in chooseItems
　　　　set _retrieve_data’s end to anItem’s fileURL
　　end repeat
end raizeAlert:

## ContentView を作成
on makeContentView(paramObj)
　　## 準備
　　set fileURLs to (paramObj’s fileURLs) as list
　　set thisFileType to (paramObj’s fileType) as text
　　
　　set keyrec to {column1:"Name"}
　　set keyDict to (current application’s NSDictionary’s dictionaryWithDictionary:keyrec)
　　
　　set theDataSource to current application’s YKZArrayController’s new()
　　
　　## NSTableView
　　tell current application’s NSTableView’s alloc()
　　　　tell initWithFrame_(current application’s CGRectZero)
　　　　　　setAllowsEmptySelection_(false)
　　　　　　setAllowsMultipleSelection_(true)
　　　　　　setDataSource_(theDataSource)
　　　　　　setDelegate_(theDataSource)
　　　　　　setDoubleAction_("doubleAction:")
　　　　　　setGridStyleMask_(current application’s NSTableViewSolidVerticalGridLineMask)
　　　　　　setSelectionHighlightStyle_(current application’s NSTableViewSelectionHighlightStyleRegular)
　　　　　　setTarget_(theDataSource)
　　　　　　setUsesAlternatingRowBackgroundColors_(true)
　　　　　　
　　　　　　set thisRowHeight to rowHeight() as integer
　　　　　　set theDataSource’s _table_view to it
　　　　end tell
　　end tell
　　
　　# data sourceに追加
　　tell (theDataSource)
　　　　awakeFromNib()
　　　　set its _file_type to thisFileType
　　　　
　　　　repeat with aURL in fileURLs
　　　　　　addObject_({fileURL:aURL})
　　　　end repeat
　　　　
　　　　setSelectionIndex_(0)
　　end tell
　　
　　## NSTableColumn
　　### Columnの並び順を指定する
　　set viewWidth to 320
　　set columnsCount to keyDict’s |count|()
　　repeat with colNum from 1 to columnsCount
　　　　
　　　　set keyName to "column" & colNum as text
　　　　set aTitle to (keyDict’s objectForKey:keyName)
　　　　
　　　　tell (current application’s NSTableColumn’s alloc()’s initWithIdentifier:(colNum as text))
　　　　　　tell headerCell()
　　　　　　　　setStringValue_(aTitle)
　　　　　　　　set thisHeaderHeight to cellSize()’s height
　　　　　　end tell
　　　　　　
　　　　　　### Columnの横幅を指定
　　　　　　setWidth_(viewWidth)
　　　　　　
　　　　　　### バインディングのオプション
　　　　　　— ソートを無効にする
　　　　　　set anObj to (current application’s NSNumber’s numberWithBool:false)
　　　　　　set aKey to current application’s NSCreatesSortDescriptorBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　
　　　　　　### 表示内容をNSArrayControllerにバインディング
　　　　　　bind_toObject_withKeyPath_options_(current application’s NSValueBinding, theDataSource, "arrangedObjects", bOptions)
　　　　　　
　　　　　　(theDataSource’s _table_view’s addTableColumn:it)
　　　　end tell
　　　　
　　end repeat
　　
　　## NSScrollView
　　### Viewの高さを計算
　　set rowCount to 12 –> 行数を固定
　　set viewHeight to (thisRowHeight + 2) * rowCount + thisHeaderHeight –> 2を足さないと高さが合わない
　　set vSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　
　　### Viewを作成
　　tell current application’s NSScrollView’s alloc()
　　　　tell initWithFrame_(vSize)
　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　setDocumentView_(theDataSource’s _table_view)
　　　　　　–setHasHorizontalScroller_(true)
　　　　　　setHasVerticalScroller_(true)
　　　　　　set aScroll to it
　　　　end tell
　　end tell
　　
　　return {aScroll, theDataSource’s _table_view}
end makeContentView

★Click Here to Open This Script　

AppleScript名：subClasses

#MARK: – NSValueTransformer
script YKZURLToIcon
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSImage –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set iconImage to current application’s NSWorkspace’s sharedWorkspace’s iconForFile:appPath
　　　　return iconImage
　　end transformedValue:
end script

script YKZURLToDisplayedName
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set displayedName to current application’s NSFileManager’s defaultManager’s displayNameAtPath:appPath
　　　　return displayedName
　　end transformedValue:
end script

#MARK: – Array Controller
script YKZArrayController
　　property parent : class "NSArrayController"
　　
　　#MARK: IBOutlets
　　property _table_view : missing value
　　#MARK:
　　property _data_type : do shell script "uuidgen"
　　property _file_type : ""
　　
　　on awakeFromNib()
　　　　–log "YKZArrayController – awakeFromNib"
　　　　tell _table_view
　　　　　　registerForDraggedTypes_({current application’s NSFilenamesPboardType, _data_type})
　　　　　　setDraggingSourceOperationMask_forLocal_(current application’s NSDragOperationCopy, false)
　　　　end tell
　　　　
　　　　#Transformerの登録
　　　　set tNames to {}
　　　　set tNames’s end to "YKZURLToIcon"
　　　　set tNames’s end to "YKZURLToDisplayedName"
　　　　repeat with aTransformer in tNames
　　　　　　set theTransformer to current application’s class aTransformer’s new()
　　　　　　(current application’s NSValueTransformer’s setValueTransformer:theTransformer forName:aTransformer)
　　　　end repeat
　　end awakeFromNib
　　
　　#MARK: Data Source Overrides
　　on numberOfRowsInTableView:aTableView
　　　　return my content()’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aTableView viewForTableColumn:aColumn row:aRow
　　　　–log "viewForTableColumn"
　　　　
　　　　set aCellView to aTableView’s makeViewWithIdentifier:"YKZTableCellView" owner:me
　　　　–set isNull to aCellView’s isEqual:(current application’s NSNull’s |null|())
　　　　–log isNull as text
　　　　
　　　　if aCellView is missing value then
　　　　　　
　　　　　　set frameRect to current application’s NSMakeRect(0, 0, aColumn’s width, aTableView’s rowHeight())
　　　　　　set aCellView to current application’s YKZTableCellView’s alloc’s initWithFrame:frameRect
　　　　　　
　　　　　　set anObj to "YKZURLToIcon"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s imageView())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToDisplayedName"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s textField())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　end if
　　　　
　　　　return aCellView
　　end tableView:viewForTableColumn:row:
　　
　　# テーブル内のセルが編集できるか
　　on tableView:aTableView shouldEditTableColumn:aColumn row:aRow
　　　　return false
　　end tableView:shouldEditTableColumn:row:
　　
　　# テーブル内をダブルクリックしたらOKボタンを押す
　　on doubleAction:sender
　　　　log "doubleAction"
　　　　## ヘッダをクリックした時は何もしない
　　　　if (sender’s clickedRow()) is -1 then return
　　　　
　　　　set theEvent to current application’s NSEvent’s ¬
　　　　　　keyEventWithType:(current application’s NSEventTypeKeyDown) ¬
　　　　　　　　location:(current application’s NSZeroPoint) ¬
　　　　　　　　modifierFlags:0 ¬
　　　　　　　　timestamp:0.0 ¬
　　　　　　　　windowNumber:(sender’s |window|()’s windowNumber()) ¬
　　　　　　　　context:(current application’s NSGraphicsContext’s currentContext()) ¬
　　　　　　　　|characters|:return ¬
　　　　　　　　charactersIgnoringModifiers:(missing value) ¬
　　　　　　　　isARepeat:false ¬
　　　　　　　　keyCode:0
　　　　current application’s NSApp’s postEvent:theEvent atStart:(not false)
　　end doubleAction:
　　
　　#MARK: Drag Operation Method
　　#ドラッグを開始（ペーストボードに書き込む）
　　on tableView:aTableView writeRowsWithIndexes:rowIndexes toPasteboard:pboard
　　　　–log "writeRowsWithIndexes"
　　　　set aData to current application’s NSKeyedArchiver’s archivedDataWithRootObject:rowIndexes
　　　　pboard’s declareTypes:{_data_type} owner:(missing value)
　　　　pboard’s setData:aData forType:_data_type
　　　　return true
　　end tableView:writeRowsWithIndexes:toPasteboard:
　　#ドラッグ途中
　　on tableView:aTableView validateDrop:info proposedRow:row proposedDropOperation:operation
　　　　–log "validateDrop"
　　　　#列の間にドラッグ
　　　　if (operation is current application’s NSTableViewDropAbove) then
　　　　　　return current application’s NSDragOperationMove
　　　　end if
　　　　#項目の上にドラッグ
　　　　set aTypes to info’s draggingPasteboard’s types()
　　　　if (aTypes’s containsObject:_data_type) as boolean then
　　　　　　return current application’s NSDragOperationNone
　　　　end if
　　　　return current application’s NSDragOperationNone
　　end tableView:validateDrop:proposedRow:proposedDropOperation:
　　#ドラッグ終了
　　on tableView:aTableView acceptDrop:info row:row dropOperation:operation
　　　　–log "acceptDrop"
　　　　#
　　　　set pboard to info’s draggingPasteboard()
　　　　set aTypes to pboard’s types()
　　　　
　　　　if (aTypes’s containsObject:_data_type) as boolean then
　　　　　　
　　　　　　set rowData to pboard’s dataForType:_data_type
　　　　　　set rowIndexes to current application’s NSKeyedUnarchiver’s unarchiveObjectWithData:rowData
　　　　　　
　　　　　　if (rowIndexes’s firstIndex()) < row then
　　　　　　　　set row to row – (rowIndexes’s |count|())
　　　　　　end if
　　　　　　
　　　　　　set aRange to current application’s NSMakeRange(row, rowIndexes’s |count|())
　　　　　　set aIndexSet to current application’s NSIndexSet’s indexSetWithIndexesInRange:aRange
　　　　　　
　　　　　　set anObj to ((my content())’s objectsAtIndexes:rowIndexes)
　　　　　　my removeObjects:anObj
　　　　　　my insertObjects:anObj atArrangedObjectIndexes:aIndexSet
　　　　　　my rearrangeObjects()
　　　　　　
　　　　else
　　　　　　set pathList to pboard’s propertyListForType:(current application’s NSFilenamesPboardType)
　　　　　　–log result as list
　　　　　　repeat with aPath in pathList
　　　　　　　　set isAdd to addItem_({filePath:aPath, atIndex:row})
　　　　　　　　if isAdd then beep
　　　　　　end repeat
　　　　　　
　　　　end if
　　　　return true
　　end tableView:acceptDrop:row:dropOperation:
　　
　　#追加する
　　on addItem:sender –> {filePath:aPath, atIndex:aIndex}
　　　　–log "addItem:"
　　　　set isAdd to false
　　　　
　　　　#missing valueの時は最後に追加
　　　　set {filePath:aPath, atIndex:aIndex} to sender
　　　　if aIndex is missing value then
　　　　　　set aIndex to my content()’s |count|() as number
　　　　end if
　　　　
　　　　#URLに変換
　　　　set appURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　#アプリケーション以外は追加しない
　　　　set {aResult, aUTI, aError} to (appURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　log aUTI
　　　　if (aUTI as text) is not (my _file_type as text) then return isAdd
　　　　
　　　　#すでにあるか確認
　　　　set bList to my content() as list
　　　　repeat with aRecord in bList
　　　　　　if ((appURL’s isEqual:(aRecord’s fileURL)) as boolean) then
　　　　　　　　set isAdd to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　#なければ追加
　　　　if not isAdd then
　　　　　　set anObj to {fileURL:appURL}
　　　　　　(my insertObject:anObj atArrangedObjectIndex:aIndex)
　　　　end if
　　　　return isAdd
　　end addItem:
end script

#MARK: – NSTableCellView
script YKZTableCellView
　　property parent : class "NSTableCellView"
　　
　　on initWithFrame:rect
　　　　–log "initWithFrame"
　　　　continue initWithFrame:rect
　　　　
　　　　setAutoresizingMask_(current application’s NSViewWidthSizable)
　　　　
　　　　tell current application’s NSImageView’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(0, 0, 16, 16))
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　
　　　　　　　　my setImageView:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(20, 2, 200, 14))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　
　　　　　　　　my setTextField:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return me
　　end initWithFrame:
end script

★Click Here to Open This Script　

(Visited 146 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

Posted on 12月 24, 2019 by Takaaki Naganoya

検索フィールドつきのTable View表示ダイアログを表示するAppleScriptです。項目選択を行う簡易ユーザーインタフェース（ダイアログ）で、選択肢の数が多い場合に備えて項目のキーワード抽出機能を付加したものです。

サーチフィールドの実装は無理かと思っていたのですが、単体でアラートダイアログ上に表示してみたら、予想外にキーボード入力イベントと検索語のクリアのイベントを簡単に拾えたので、Table Viewと組み合わせて試してみました。

AppleScript名：アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

— Created 2019-12-23 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSSearchField : a reference to current application’s NSSearchField
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 300
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　set aTextInput to makeNSSearchField(0, aHeight – 20, 300, 20) of me
　　　　
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 80, labelSortList) of me
　　　　
　　　　parentView’s setSubviews:{aTextInput, aScroll}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　–TextField
　　　　set aTextInput to makeNSSearchField(0, 0, 300, 20) of me
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on makeNSSearchField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer)
　　　　set aSearchF to NSSearchField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aSearchF’s setDelegate:(me)
　　　　return aSearchF
　　end makeNSSearchField
　　
　　
　　–検索クエリ入力時
　　on searchFieldDidStartSearching:(aField)
　　　　set aStr to (aField’s stringValue()) as string
　　　　set predicStr to "field1 contains[cd] ’" & aStr & "’ OR field3 contains[cd] ’" & aStr & "’"
　　　　set filteredArray to filterRecListByLabel1((my aDataList), predicStr) of me
　　　　set (my theDataSource) to filteredArray
　　　　tView’s reloadData()
　　end searchFieldDidStartSearching:
　　
　　
　　–Search Fieldの「x」ボタンを押したイベント
　　on searchFieldDidEndSearching:(aField)
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　tView’s reloadData()
　　end searchFieldDidEndSearching:
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出
　　on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　　　set aArray to NSMutableArray’s arrayWithArray:aRecList
　　　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　　　return filteredArray
　　end filterRecListByLabel1
　　
end script

★Click Here to Open This Script　

(Visited 99 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

Posted on 12月 23, 2019 by Takaaki Naganoya

アラートダイアログ上にTableViewを表示し、複数キーの組み合わせによって項目抽出。選択項目のデータを返すAppleScriptです。

あくまで試作品なので、あちらこちらに「お可愛らしい」実装が転がっています。NSBoxがまだまともに使いこなせていないあたりとか（Xcode上で部品として配置するのは楽勝ですが、プログラムから動的に生成して使用するのは別なので）。

抽出キー数は可変で外部から指定できるとよいのですが、本Scriptでは固定です。また、各抽出条件も外部から供給するのが本来あるべき姿ですが、ハードコーディングしています。

あと、TableViewの下側に謎の余白があるのは、めんどくさくなってそのまま放置しています。これで外部から各種パラメータを指定できるようにして、sdefつけて１命令で呼び出せるようにしておけば、レコード数の多い選択項目から条件抽出しつつ項目選択できてよいでしょう。

プログラム内容自体は、高度でもなければ高尚でもありません。実にダラダラとGUI部品のパラメータを設定しているだけです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

— Created 2019-12-22 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSBox : a reference to current application’s NSBox
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSPopUpButton : a reference to current application’s NSPopUpButton
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSCompoundPredicate : a reference to current application’s NSCompoundPredicate
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
　　
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　property aSel : 0
　　property bSel : 0
　　property cSel : 0
　　property predList : {}
　　property a1Button : missing value
　　property a2Button : missing value
　　property a3Button : missing value
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 400
　　　　set my aSel to 0
　　　　set my bSel to 0
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　
　　　　
　　　　–BOX Aをつくる
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 60, aWidth, 60)))
　　　　(aBox’s setTitle:("Filter Condition"))
　　　　
　　　　–このあたり、項目数に合わせてUIを可変で生成するように（本Scriptは試作品なので、決め打ちでUI生成）
　　　　set a1Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 200, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:{"▼Select Item", "MacBook", "iMac", "mini", "Air", "Pro"})
　　　　a1Button’s setTarget:(me)
　　　　a1Button’s setAction:("mySelector:")
　　　　a1Button’s setEnabled:(true)
　　　　
　　　　set a2Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(220, 0, 200, 30)) pullsDown:false)
　　　　a2Button’s removeAllItems()
　　　　(a2Button’s addItemsWithTitles:{"▼Select Item", "150000", "200000", "300000", "400000", "600000"})
　　　　a2Button’s setTarget:(me)
　　　　a2Button’s setAction:("mySelector:")
　　　　a2Button’s setEnabled:(true)
　　　　
　　　　set a3Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(440, 0, 200, 30)) pullsDown:false)
　　　　a3Button’s removeAllItems()
　　　　(a3Button’s addItemsWithTitles:{"▼Select Item", "デュアルコア", "クアッドコア", "6コア", "8コア"})
　　　　a3Button’s setTarget:(me)
　　　　a3Button’s setAction:("mySelector:")
　　　　a3Button’s setEnabled:(true)
　　　　
　　　　
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s addSubview:a2Button)
　　　　(aBox’s addSubview:a3Button)
　　　　
　　　　
　　　　–BOX Bをつくる
　　　　set bBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 80)))
　　　　(bBox’s setTitle:("Data"))
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 150, labelSortList) of me
　　　　
　　　　(bBox’s addSubview:aScroll)
　　　　
　　　　parentView’s setSubviews:{aBox, bBox}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on mySelector:aObject
　　　　set aIndex to (aObject’s indexOfSelectedItem()) as number
　　　　filterByMultipleCondition() of me
　　end mySelector:
　　
　　
　　
　　on filterByMultipleCondition()
　　　　set prediCatesArray to {}
　　　　
　　　　set aInd to (my a1Button’s indexOfSelectedItem()) as number
　　　　set bInd to (my a2Button’s indexOfSelectedItem()) as number
　　　　set cInd to (my a3Button’s indexOfSelectedItem()) as number
　　　　
　　　　if {aInd, bInd, cInd} = {0, 0, 0} then
　　　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　　　tView’s reloadData()
　　　　　　return
　　　　end if
　　　　
　　　　–このあたり、複数条件をハードコーディングしているのは超絶頭悪い。項目数の増減に対応できるべき
　　　　if aInd > 0 then
　　　　　　set aTitle to (my a1Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field1 contains ’" & aTitle & "’"
　　　　end if
　　　　
　　　　if bInd > 0 then
　　　　　　set bTitle to (my a2Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field2.integerValue < " & bTitle
　　　　end if
　　　　
　　　　if cInd > 0 then
　　　　　　set cTitle to (my a3Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field3 contains ’" & cTitle & "’"
　　　　end if
　　　　
　　　　–データ抽出
　　　　set tmpList to filterDictArrayByLabel3((my aDataList), prediCatesArray) of me
　　　　
　　　　–データ再表示
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(tmpList)
　　　　tView’s reloadData()
　　end filterByMultipleCondition
　　
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出（複数PredicatesをANDで合成）
　　on filterDictArrayByLabel3(origArray as list, aPredicateList as list)
　　　　set aArray to NSMutableArray’s arrayWithArray:origArray
　　　　set predArray to NSMutableArray’s new()
　　　　
　　　　repeat with i in aPredicateList
　　　　　　(predArray’s addObject:(NSPredicate’s predicateWithFormat:(contents of i)))
　　　　end repeat
　　　　
　　　　set pred to current application’s NSCompoundPredicate’s andPredicateWithSubpredicates:predArray
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:pred
　　　　
　　　　return filteredArray
　　end filterDictArrayByLabel3
end script

★Click Here to Open This Script　

(Visited 104 times, 1 visits today)

アラートダイアログ上にNSBoxを介してPopup Menuを表示

Posted on 11月 14, 2019 by Takaaki Naganoya

アラートダイアログ上に複数のポップアップメニュー（項目数可変）を表示し、指定リスト（配列）からの選択を行うAppleScriptです。

以前、Segmented Controlで作ったものがありましたが、Segmented Controlだと絶望的に実用性がないので、ポップアップボタンに差し替えてみたものです。

AppleScript名：アラートダイアログ上にNSBoxを介してPopup Menuを表示

— Created 2019-11-14 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property returnCode : 0
property returnSels : {}

set paramObj to {myMessage:"項目選択", mySubMessage:"以下の各項目を選択してください。", segmentMes:{{"Red1", "Blue1", "Yellow1", "Brown1", "White1", "Cyan1", "Grey1"}, {"Red2", "Blue2", "Yellow2", "Brown2", "White2", "Cyan2", "Grey2"}, {"Red3", "Blue3", "Yellow3", "Brown3", "White3", "Cyan3", "Grey3"}, {"Red4", "Blue4", "Yellow4", "Brown4", "White4", "Cyan4", "Grey4"}, {"Red5", "Blue5", "Yellow5", "Brown5", "White5", "Cyan5", "Grey5"}}, segmentTitles:{"1st Segments", "2nd Segments", "3rd Segments", "4th Segments", "5th Segments"}}

–my chooseMultipleSegments:paramObj
my performSelectorOnMainThread:"chooseMultipleSegments:" withObject:paramObj waitUntilDone:true

return my returnSels
–> {1, 2, 3, 4, 5}

on chooseMultipleSegments:paramObj
　　set aMainMes to (myMessage of paramObj) as string
　　set aSubMes to (mySubMessage of paramObj) as string
　　set segMes2DList to (segmentMes of paramObj) as list
　　set segTitleList to (segmentTitles of paramObj) as list
　　
　　set aTmpY to (length of segMes2DList) * 60
　　
　　–BoX + Segmented Control をつくる
　　set segsList to {}
　　set boxLIst to {}
　　set segsCount to 0
　　set tmpMaxX to 400
　　
　　set aCount to 1
　　
　　repeat with i in segMes2DList
　　　　set a1Button to (current application’s NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX – 30, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:(i))
　　　　
　　　　set aDBounds to a1Button’s |bounds|()
　　　　set tmpWidth to getWidth(aDBounds) of me
　　　　
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aTmpY – segsCount – 60, tmpMaxX – 10, 60)))
　　　　(aBox’s setTitle:(item aCount of segTitleList))
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s setBorderType:0) –NSNoBorder, this method is depreceted in macOS 10.14. Which is alternative?
　　　　
　　　　if tmpWidth > tmpMaxX then set tmpMaxX to tmpWidth
　　　　
　　　　set the end of segsList to a1Button –選択検出用
　　　　set the end of boxLIst to aBox –表示用
　　　　
　　　　set segsCount to segsCount + 60
　　　　set aCount to aCount + 1
　　end repeat
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX + 10, aTmpY + 20))
　　theView’s setSubviews:boxLIst
　　
　　— create a Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX + 10, 300))
　　aScroll’s setDocumentView:theView
　　aScroll’s documentView()’s scrollPoint:(current application’s NSMakePoint(0, aTmpY + 10)) –Force scroll to top
　　
　　theView’s enclosingScrollView()’s setHasHorizontalScroller:false
　　theView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set my returnSels to {}
　　repeat with i in segsList
　　　　set tmpSegSel to (i’s indexOfSelectedItem()) as number
　　　　set the end of (my returnSels) to tmpSegSel + 1
　　end repeat
end chooseMultipleSegments:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
end clickedSeg:

on getWidth(aDBounds)
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　return item 1 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　return width of |size| of aDBounds
　　end if
end getWidth

★Click Here to Open This Script　

(Visited 177 times, 1 visits today)

アラートダイアログ上にTable Viewを表示 v4

Posted on 7月 11, 2019 by Takaaki Naganoya

アラートダイアログ上にTable Viewを表示するAppleScriptです。

データを表UIで表示する部品としては、Shane Stanleyの「Myriad Tables Lib」が定番ですが、高機能なぶんライブラリ中にFrameworkが含まれていたりして、場合によっては困ることもあります。また、見た目をカスタマイズしたい場合にも、あまりいじくれなくて困ることもあります（とくにデータの文字サイズを変更できなくて困ること多し）。

そのため、AppleScriptだけで書いた表UI表示用の部品も、たまに必要になることがあります。

▲スクリプトエディタで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

▲Script Debuggerで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

▲AppleScriptアプレットで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

AppleScript名：アラートダイアログ上にTable Viewを表示 v4

— Created 2019-02-21 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

on run
　　set (my theResult) to 0 –initialize
　　
　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:{{field1:"MacBook Air", field2:"119,800円", field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:"139,800円", field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:"258,800円", field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:"122,800円", field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:"120,800円", field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:"142,800円", field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:"198,800円", field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:"558,800円", field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}}, aSortOrder:{"field1", "field2", "field3"}}
　　
　　–my chooseItemByTableView:paramObj–for debug
　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　return (my theResult)
end run

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　set labelSortList to (aSortOrder of paramObj) as list
　　
　　set aWidth to 600
　　set aHeight to 200
　　
　　set aScroll to makeTableView(aTList, aWidth, aHeight, labelSortList) of me
　　
　　–Detect Dark Mode
　　set dMode to retLIghtOrDark() of me
　　if dMode = true then
　　　　set tvCol to 1
　　　　set tvAlpha to 0.8
　　　　set bCol to 0.1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s cyanColor())
　　else
　　　　set tvCol to 0
　　　　set tvAlpha to 0.1
　　　　set bCol to 1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s blackColor())
　　end if
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setOpaque:(false)
　　myWindow’s setBackgroundColor:(NSColor’s colorWithCalibratedWhite:(bCol) alpha:(bAlpha))
　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode) = 1001 then error number -128
　　
　　set (my theResult) to (aScroll’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle)
　　return aRes
end tableView:objectValueForTableColumn:row:

on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　set aOffset to 40
　　set theDataSource to current application’s NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:aDicList
　　
　　set aScroll to current application’s NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to current application’s NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　set aLen to length of labelSortList
　　
　　repeat with i in labelSortList
　　　　set j to contents of i
　　　　set aColumn to (current application’s NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　(aView’s addTableColumn:aColumn)
　　end repeat
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　
　　–１行目を選択
　　set aIndexSet to current application’s NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る。System Eventsを使っていないのは、macOS 10.14以降対策（承認を取得しなくてもいいように）
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

(Visited 85 times, 1 visits today)

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明_Float_SuppressionButtonつき

Posted on 7月 10, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

Xcode上でNSAlert.hを調べ、アラートダイアログに指定できる各種オプションを指定してみました。NSWindowLevelの変更は効いていないみたいですけれども。

AppleScript名：アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明_Float_SuppressionButtonつき

— Created 2019-07-09 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSUserDefaults : a reference to current application’s NSUserDefaults
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel

property returnCode : 0
property supState : false

set asStr to do shell script "cal 2019"
set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:450, mesHeight:200, fontName:"Courier", fontSize:11.0, suppressionMes:"Some Option"}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

return (my supState)

on dispTextViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mesStr to (mes1 of paramObj) as string –Text Input field 1 Label
　　set aWidth to (mesWidth of paramObj) as integer –TextView width
　　set aHeight to (mesHeight of paramObj) as integer –TextView height
　　set aFontName to (fontName of paramObj) as string –TextView font name
　　set aFontSize to (fontSize of paramObj) as real –TextView font size
　　set aSupMes to (suppressionMes of paramObj) as string –Suppression Button Titile
　　
　　–Detect Dark Mode
　　set dMode to retLIghtOrDark() of me
　　if dMode = true then
　　　　set tvCol to 1
　　　　set tvAlpha to 0.8
　　　　set bCol to 0.1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s cyanColor())
　　else
　　　　set tvCol to 0
　　　　set tvAlpha to 0.1
　　　　set bCol to 1
　　　　set bAlpha to 0.5
　　　　set contentCol to (NSColor’s grayColor())
　　end if
　　
　　— Create a TextView with Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:(tvAlpha)
　　
　　aView’s setRichText:true
　　aView’s useAllLigatures:true
　　aView’s setTextColor:(contentCol)
　　aView’s setFont:(NSFont’s fontWithName:aFontName |size|:aFontSize)
　　
　　aView’s setDrawsBackground:false
　　
　　
　　aView’s setBackgroundColor:aColor
　　aView’s setOpaque:(false)
　　aView’s setString:mesStr
　　aScroll’s setDocumentView:aView
　　–aScroll’s setBorderType:(current application’s NSBezelBorder)
　　–aScroll’s setBorderType:(current application’s NSGrooveBorder)
　　–aScroll’s setBorderType:(current application’s NSLineBorder)
　　aScroll’s setBorderType:(current application’s NSNoBorder)
　　
　　–Ruler
　　–aScroll’s setHasHorizontalRuler:(true)
　　–aScroll’s setRulersVisible:(true)
　　
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　set anImage to current application’s NSImage’s imageNamed:(current application’s NSImageNameComputer)
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setIcon:(anImage)
　　　　
　　　　–for Messages
　　　　its setMessageText:(aMainMes)
　　　　its setInformativeText:(aSubMes)
　　　　
　　　　–for Buttons
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　
　　　　–Add Accessory View
　　　　its setAccessoryView:(aScroll)
　　　　
　　　　–for Help Button
　　　　its setShowsHelp:(true)
　　　　its setDelegate:(me)
　　　　
　　　　its setAlertStyle:0 —-0…2
　　　　
　　　　its setShowsSuppressionButton:(true) –「今後このメッセージを表示しない」チェックボックスを表示
　　　　
　　　　set suppressionB to its suppressionButton
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setOpaque:(false)
　　myWindow’s setBackgroundColor:(NSColor’s colorWithCalibratedWhite:(bCol) alpha:(bAlpha))
　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　
　　suppressionB’s setTitle:(aSupMes)
　　suppressionB’s setState:(true) —default state
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set my supState to (suppressionB’s state) as boolean
end dispTextViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

★Click Here to Open This Script　

(Visited 79 times, 1 visits today)

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

Posted on 7月 8, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

＃　前バージョンの「自分のソースコード」表示というのは意味不明だったので、プロセス一覧を取得してみました

ヘルプボタン（？）を付け、アラートダイアログのウィンドウ背景を半透明に設定。そのままでは配色の都合上Dark Mode/Light Modeの切り替え時に読みづらい文字なども出てきたため、モード判定を行って表示色などを変更しています。

アプレット書き出ししたときに、スクロールビューがマウスのスクロールホイールの操作に追従したスクロールを行ってくれないので、そのあたり何か追加でNSScrollViewに設定を行う必要があるのだろうかと。

▲スクリプトエディタ上で実行@macOS 10.14.5。左がLight Mode、右がDark Mode（以下同様）

▲ヘルプボタンをクリックしたところ。本当にアンカーを指定して指定のヘルプコンテンツを表示させることもできる模様。そのための基礎的な試験

▲AppleScriptアプレット書き出しして実行したところ

▲Script Debugger上で実行@macOS 10.14.5。Dark Modeに対応できていない（次バージョンで対応することでしょう）

▲Script DebuggerからAppleScript Applet (Enhanced）で書き出して実行したところ。マウスのスクロールホイールの操作を受け付けて文字がスクロールする

AppleScript名：アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

— Created 2019-07-08 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication

property returnCode : 0

–Get Self Source Code (a kind of joke)
set asStr to do shell script "ps -ax"
set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:400, mesHeight:200, fontName:"HiraginoSans-W3", fontSize:11.0}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

(Visited 96 times, 1 visits today)

アラートダイアログ上にTextViewを表示

Posted on 7月 8, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

とくにこれといって何か表示するものを思いつかなかったので、自分自身のソースコードを取得して表示しています。スクリプトエディタやScript Debugger上で実行した場合には自分自身のソースコードをテキストビュー上で表示します。

読み取り専用のスクリプトやアプレットで実行している場合にはソースコードを取得できません。何か適宜自分で表示させたいテキストを与えてみてください。

AppleScript名：アラートダイアログ上にTexViewを表示

— Created 2019-07-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "OSAKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication
property OSAScript : a reference to current application’s OSAScript

property returnCode : 0

–Get Self Source Code (a kind of joke)
set mePath to path to me
set asStr to getASsourceFor(mePath) of me

set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:400, mesHeight:200, fontName:"HiraginoSans-W3", fontSize:11.0}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
— Original Created 2014-02-23 Shane Stanley
on getASsourceFor(anAlias as {alias, string})
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　error "Compile Error" — handle error
　　else
　　　　set sourceText to theScript’s source()
　　end if
　　
　　return sourceText as string
end getASsourceFor

★Click Here to Open This Script　

(Visited 181 times, 1 visits today)

テキストから数値を抽出して度数分布集計 v3

Posted on 6月 29, 2019 by Takaaki Naganoya

CotEditorで編集中の最前面の書類の本文中から指定桁の数値を抽出して登場回数で度数分布の集計を行うAppleScriptです。

初版では、集計対象の数値を桁数で指定するという（使うのに）無茶な仕様になっていたので、この頭の悪い仕様に作った本人もめまいがしていました。

わざわざAppleScriptを使うのは、他のどの環境でも追いつけない高度な処理を行うことに意義があると思っています。

そこで、

　（１）数字部分をあらかじめ抽出して事前に集計（分布および最小値、最大値を計算）
　（２）事前集計結果をグラフ表示
　（３）集計対象の数字の範囲を最小値〜最大値までの間で指定できるように
　（４）パラメータの入力、および事前集計結果の表示を自前で作成したアラートダイアログで表示

といった変更を加えてみました。初版では「数字の桁数」というご無体な指定で数字を抽出していましたが、最初に最大値を計算しておいたことで、最大値の桁数ですべて数値を抽出し、最小値・最大値の間に収まる数値のみを抽出して度数分布を再計算しています（言うほど計算結果が変わってきたりはしないんですけど　＾ー＾；；）。

このぐらい行えば、安心して見られる感じでしょうか。

追記：
4.11といった文字が「4」と「11」に分離して認識されるようだったので数値として認識するCharacter setに「.」（小数点）および「,」（桁数区切り）を追加してみました。想定していた部分はうまくクリアしたものの、「REV.」の部分の「.」も認識して「0.411」のような数値として認識したようです。

このあたりに課題を残しつつも、全体として見ると当初からノイズとして除去する対象として考えていた箇所でもあったため、そんなもんだろうかと。

アラートダイアログに表示するテスト集計結果の文字が小さかったので、少し大きくしてみました。フォントについては「ヒラギノ角ゴシック W1」（PostScript名は「HiraginoSans-W1」）を指定しています。このあたりは好みに応じて変更してみるとよいでしょう。

巨大なテキスト（青空文庫の小説１作文まるごととか）を対象に処理していないので（画面キャプチャ掲載している程度のサイズ）そういう配慮は行っていません。仕事だと考慮しないでもないですが、必要と思われた処理をとりあえず組んでみた程度なので、そういうものだとお考えください。

–> Download Applet With Libraries (mainly for macOS 10.14 or later)

AppleScript名：テキストから数値を抽出して度数分布集計 v3.1

— Created 2019-06-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

–property theResult : 0
property returnCode : 0
property segRes : missing value

set segRes to missing value

tell application "CotEditor"
　　if (count every document) = 0 then return –No Document
　　
　　tell front document
　　　　set aText to contents of it
　　　　set lineTerm to (line ending)
　　end tell
　　
　　–改行コードの選択（ドキュメントの状態から取得）
　　if lineTerm = LF then
　　　　set aRet to ASCII character 10 –To avoid keyword conflict (string)
　　else if lineTerm = CR then
　　　　set aRet to ASCII character 13
　　else if lineTerm = CRLF then
　　　　set aRet to (ASCII character 13) & (ASCII character 10)
　　else
　　　　set aRet to ASCII character 10
　　end if
end tell

–事前にテキストから自動で数値部分を抽出して分析
set cArray to extractNumberFromText(aText) of me
set aRes to (cArray’s valueForKeyPath:"@max.self")’s intValue()
set bRes to (cArray’s valueForKeyPath:"@min.self")’s intValue()
set cRes to (cArray’s valueForKeyPath:"@count")’s intValue()

–事前に数字の分布シミュレーションを計算
set tmpLen to count every character of (aRes as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set sampleStr to calculateNumFreq(cArray, "■", aRet, bRes, aRes, true) of me

set sampleStr to return & return & "テスト集計結果：" & return & return & sampleStr

–テキストからの数値抽出時のパラメータ取得
set paramObj to {myMessage:"テキスト内の数値の度数分布集計", mySubMessage:"集計対象の数値の範囲と、集計時のグラフ生成時の構成文字を指定してください", mes1:"最小値（min.）", mes1Default:(bRes as string), mes2:"最大値（max.）", mes2Default:(aRes as string), mes3:"出力文字", mes3Default:"絆", aSample:sampleStr}

–set segRes to my inputParametersFromAlertDialog:paramObj–for debugging
my performSelectorOnMainThread:"inputParametersFromAlertDialog:" withObject:(paramObj) waitUntilDone:true
if segRes = missing value then return –Cancel

–度数分布計算
set tmpLen to count every character of ((a2Res of segRes) as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set outStr to calculateNumFreq(cArray, a3Res of segRes, aRet, a1Res of segRes, a2Res of segRes, false) of me

–テキストエディタへの集計結果出力
tell application "CotEditor"
　　tell front document
　　　　set contents of it to (aText & aRet & aRet & "集計結果：" & aRet & aRet & outStr & aRet)
　　end tell
end tell

on inputParametersFromAlertDialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mes1Label to (mes1 of paramObj) as string –Text Input field 1 Label
　　set mes2Label to (mes2 of paramObj) as string –Text Input field 2 Label
　　set mes3Label to (mes3 of paramObj) as string –Text Input field 3 Label
　　set aTextInputString to (mes1Default of paramObj) as string –Text Input field 1 Default value
　　set bTextInputString to (mes2Default of paramObj) as string –Text Input field 2 Default value
　　set cTextInputString to (mes3Default of paramObj) as string –Text Input field 2 Default value
　　set sampleString to (aSample of paramObj) as string
　　
　　— Create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 500, 400))
　　
　　— create two input field and their labels pairs
　　–NSTextFields for Input
　　set aTextInput to makeNSTextField(100, 70, 140, 20, true, (aTextInputString), true, true) of me
　　set bTextInput to makeNSTextField(100, 35, 140, 20, true, (bTextInputString), true, true) of me
　　set cTextInput to makeNSTextField(100, 0, 140, 20, true, (cTextInputString), true, true) of me
　　
　　–Labels
　　set a1TF to makeNSTextField(0, 70, 100, 20, false, (mes1Label), false, false) of me
　　set a2TF to makeNSTextField(0, 35, 100, 20, false, (mes2Label), false, false) of me
　　set a3TF to makeNSTextField(0, 0, 100, 20, false, (mes3Label), false, false) of me
　　
　　–Sample Text View
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.9
　　set tvScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 300))
　　set tvView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 380))
　　tvView’s setRichText:true
　　tvView’s useAllLigatures:true
　　tvView’s setTextColor:(NSColor’s cyanColor()) —
　　tvView’s setFont:(current application’s NSFont’s fontWithName:"HiraginoSans-W1" |size|:16.0)
　　tvView’s setBackgroundColor:aColor
　　tvView’s setEditable:false
　　
　　tvScroll’s setDocumentView:tvView
　　tvView’s enclosingScrollView()’s setHasVerticalScroller:true
　　tvView’s setString:(sampleString)
　　
　　
　　theView’s setSubviews:{a1TF, aTextInput, a2TF, bTextInput, a3TF, cTextInput, tvScroll}
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then
　　　　set my segRes to missing value
　　else
　　　　set s1Val to (aTextInput’s integerValue()) as integer
　　　　set s2Val to (bTextInput’s integerValue()) as integer
　　　　set s3Val to (cTextInput’s stringValue()) as string
　　　　
　　　　–return {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}–old version’s way to return values
　　　　set my segRes to {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}
　　end if
end inputParametersFromAlertDialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–与えられたテキストから数値部分を抽出して1D Arrayで返す
on extractNumberFromText(aText)
　　set aStr to current application’s NSString’s stringWithString:aText
　　–set nonDigitCharacterSet to (current application’s NSCharacterSet’s decimalDigitCharacterSet())’s invertedSet()
　　set nonDigitCharacterSet to (current application’s NSCharacterSet’s characterSetWithCharactersInString:"0123456789.,")’s invertedSet()
　　set bArray to (aStr’s componentsSeparatedByCharactersInSet:nonDigitCharacterSet)
　　
　　–Sweep Blank Items
　　load framework –BridgePlus
　　set cArray to (current application’s SMSForder’s arrayByDeletingBlanksIn:(bArray))’s valueForKey:"intValue"
　　return cArray –return as NSArray
end extractNumberFromText

–正規表現でテキスト中から指定パターンに該当する箇所を抽出してリストで返す
on findPattern:thePattern inString:theString
　　set theOptions to ((current application’s NSRegularExpressionDotMatchesLineSeparators) as integer) + ((current application’s NSRegularExpressionAnchorsMatchLines) as integer)
　　set theRegEx to current application’s NSRegularExpression’s regularExpressionWithPattern:thePattern options:theOptions |error|:(missing value)
　　set theFinds to theRegEx’s matchesInString:theString options:0 range:{location:0, |length|:length of theString}
　　set theFinds to theFinds as list — so we can loop through
　　set theResult to {} — we will add to this
　　set theNSString to current application’s NSString’s stringWithString:theString
　　repeat with i from 1 to count of items of theFinds
　　　　set theRange to (item i of theFinds)’s range()
　　　　set end of theResult to (theNSString’s substringWithRange:theRange) as integer
　　end repeat
　　return theResult
end findPattern:inString:

–1D Listをユニーク化してソート
on uniquifyAndSort1DList(theList as list, aBool as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:theList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"compare:"
　　set cArray to bArray’s sortedArrayUsingDescriptors:{aDdesc}
　　
　　set bList to cArray as list
　　return bList
end uniquifyAndSort1DList

–度数分布集計して文字グラフ出力
on calculateNumFreq(theList, outChar, aLineTerminator, aMin, aMax, zeroPaddingF)
　　set theCountedSet to current application’s NSCountedSet’s alloc()’s initWithArray:theList
　　set newArray to current application’s NSMutableArray’s new()
　　
　　set kList to uniquifyAndSort1DList(theList, false) of me –降順ソート
　　set maxDigit to (count every character of (aMax as string))
　　
　　repeat with i in kList
　　　　if (i ≥ aMin) and (i ≤ aMax) then
　　　　　　(newArray’s addObject:{theKey:i, theCount:(theCountedSet’s countForObject:i)})
　　　　end if
　　end repeat
　　
　　set outStr to ""
　　
　　repeat with i in newArray as list
　　　　set j to (current application’s NSDictionary’s dictionaryWithDictionary:i)
　　　　set tmpStr to (j’s valueForKey:"theKey")
　　　　
　　　　if zeroPaddingF = true then
　　　　　　–Zero Pagging
　　　　　　set keyNumStr to numToZeroPaddingStr(tmpStr, maxDigit, "0") of me
　　　　else
　　　　　　–No Padding
　　　　　　copy (tmpStr as string) to keyNumStr
　　　　end if
　　　　
　　　　set outStr to outStr & keyNumStr & "："
　　　　
　　　　set aNum to (j’s valueForKey:"theCount")
　　　　repeat aNum times
　　　　　　set outStr to outStr & outChar
　　　　end repeat
　　　　
　　　　set outStr to outStr & aLineTerminator
　　end repeat
end calculateNumFreq

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

(Visited 130 times, 1 visits today)

Numbersで選択中の表のセルの範囲を背景色で頻度集計

Posted on 6月 6, 2019 by Takaaki Naganoya

Numbersでオープン中の書類の現在のシート上にある表の選択範囲のセルに対して、背景色（Background color）で登場頻度の集計を行って、どの色が何回登場しているかを色プレビューしつつ表示するAppleScriptです。

集計をRGB値で数値的に行うことは容易ですが、結局のところ色なんてRGB値で見せられてもわからず、実際に目で見える色で表示しないと判断できません。そのため、アラートダイアログを作成してその上にColorWellで表示しています。

▲Numbersの表でセルを選択

▲Numbersの表のセルに指定されている背景色の登場頻度で集計し、色プレビューと登場回数を表示（スクリプトエディタ@macOS 10.14.5上の表示、Dark Mode）

▲Numbersの表のセルに指定されている背景色の登場頻度で集計し、色プレビューと登場回数を表示（Script Debugger@macOS 10.14.5上の表示、Dark Mode）

上記サンプル表は本Blog上での説明用のために簡略化した表ですが、実際には数十行の入り組んだNumbersの表を相手にしており、かつ、手作業で色付きセルだけを数えるなんて考えたくもないレベルで頻繁に確認しなくてはならなかったために、本Scriptを作ってみました。

Numbersにかぎらず、iWorkアプリケーション（Keynote、Pages、Numbers）で共通の仕様ですが、背景色を塗らないセルから背景色を取得するとmissing valueが返ります。

本ScriptはScript Menuに入れて実行するとアラートダイアログが最前面に出てこないなど、Script書類（.scpt、.scptd）のままで実行すると問題が発生。Script Menuに入れる場合にはアプレット（.app）書き出しする必要があります。

▲スクリプトメニューにアプレット書き出しした実行ファイルを入れて呼び出し（macOS 10.14.5）。スクリプトメニューは最前面にあるGUIアプリケーションに応じて、それぞれのアプリケーション用のメニューを表示できるようになっている

AppleScript名：選択中の表のセルの範囲を背景色で頻度集計.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/06/06
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property theResult : 0
property returnCode : 0
property theDataSource : {}

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　return "No Selection" –何も選択されてなかった場合
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　set bgColList to background color of every cell of selection range
　　　　　　　　–> {{18572, 45937, 65452}, {18572, 45937, 65452}, {3001, 24801, 44056}, {18572, 45937, 65452}, {18572, 45937, 65452}, {64899, 33134, 31509}, {64899, 33134, 31509}, {18572, 45937, 65452}, {18572, 45937, 65452}, {3001, 24801, 44056}, {18572, 45937, 65452}, {18572, 45937, 65452}, {26149, 65534, 58650}, {26149, 65534, 58650}, {26149, 65534, 58650}, {26149, 65534, 58650}, {18572, 45937, 65452}, {18572, 45937, 65452}}
　　　　　　end tell
　　　　end tell
　　end tell
end tell

set bgColList to countItemsByItsAppearance(bgColList) of me
–> {{theName:{65535, 65533, 65534}, numberOfTimes:73}, {theName:{65535, 65535, 21706}, numberOfTimes:73}, {theName:missing value, numberOfTimes:27}}

set paramObj to {mainDat:bgColList, myTitle:"色別集計", mySubTitle:"Numbers上で選択したセルの背景色の頻度集計"}
–my browseColors:paramObj–for debug

my performSelectorOnMainThread:"browseColors:" withObject:(paramObj) waitUntilDone:true

on browseColors:paramObj
　　set aParamList to (mainDat of (paramObj as record)) as list
　　set winTitle to (myTitle of (paramObj as record)) as string
　　set subTitle to (mySubTitle of (paramObj as record)) as string
　　
　　set aLen to length of aParamList
　　
　　set aHeight to 100
　　set aWidth to 300
　　
　　–NSViewをつくる
　　set aNSV to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight * 1.5))
　　aNSV’s setNeedsDisplay:true
　　
　　— NSScroll Viewをつくる
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aScroll’s setDocumentView:aNSV
　　
　　aNSV’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aNSV’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–NSColorWell+ NSTextFieldをつくる
　　set aStep to 1
　　repeat with i in aParamList
　　　　set aColorWell to (NSColorWell’s alloc()’s initWithFrame:(current application’s NSMakeRect(10, ((aLen – aStep + 1) * 30), 60, 20)))
　　　　
　　　　set myName to (theName of i)
　　　　set myTimes to (numberOfTimes of i)
　　　　
　　　　if myName is not equal to missing value then
　　　　　　copy (myName as list) to {rNum, gNum, bNum}
　　　　　　set myTimes to numberOfTimes of i
　　　　　　
　　　　　　set myColor to makeNSColorFromRGBAval(rNum, gNum, bNum, 65535, 65535) of me
　　　　　　(aColorWell’s setColor:myColor)
　　　　　　(aColorWell’s setBordered:false)
　　　　　　(aNSV’s addSubview:aColorWell)
　　　　　　
　　　　　　set aTF to makeNSTextField(80, ((aLen – aStep + 1) * 30), 100, 20, false, myTimes as string, true, true) of me
　　　　　　(aNSV’s addSubview:aTF)
　　　　　　
　　　　　　set aStep to aStep + 1
　　　　end if
　　end repeat
　　
　　–NSScrollViewを強制的にトップにスクロール
　　set aPT to current application’s NSMakePoint(0.0, aHeight)
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:winTitle
　　　　its setInformativeText:subTitle
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end browseColors:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

–1D Listを要素別に出現回数で集計
on countItemsByItsAppearance(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bArray to current application’s NSMutableArray’s array()
　　set theEnumerator to aSet’s objectEnumerator()
　　
　　repeat
　　　　set aValue to theEnumerator’s nextObject()
　　　　if aValue is missing value then exit repeat
　　　　bArray’s addObject:(current application’s NSDictionary’s dictionaryWithObjects:{aValue, (aSet’s countForObject:aValue)} forKeys:{"theName", "numberOfTimes"})
　　end repeat
　　
　　–出現回数（numberOfTimes）で降順ソート
　　set theDesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"numberOfTimes" ascending:false
　　bArray’s sortUsingDescriptors:{theDesc}
　　
　　return bArray as list
end countItemsByItsAppearance

★Click Here to Open This Script　

(Visited 878 times, 2 visits today)

アラートダイアログ上にsegmented controlを表示 v4

Posted on 3月 27, 2019 by Takaaki Naganoya

アラートダイアログ上にsegmented controlを複数表示して、複数選択項目を取得するAppleScriptです。

複数選択項目にpopup buttonではなくsegmented controlを使う必要性というのは、あんまりないですが………すべての選択項目が見える状態で少量の選択項目から１つを選ぶような用途には使えるのではないでしょうか。

segmented controlをそれぞれBoxに入れ、Viewにまとめ、Scroll viewに突っ込んでいますが、あまり効果があるんだかないんだか不明です。

AppleScript名：アラートダイアログ上にsegmented controlを表示 v4

— Created 2019-03-26 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
–Scroll Viewをつかってみた

property NSBox : a reference to current application’s NSBox
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSScrollView : a reference to current application’s NSScrollView
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property returnCode : 0
property returnSels : {}

set paramObj to {myMessage:"複数項目選択", mySubMessage:"どれか選択してください。", segmentMes:{{"Red1", "Blue1", "Yellow1", "Brown1", "White1", "Cyan1", "Grey1"}, {"Red2", "Blue2", "Yellow2", "Brown2", "White2", "Cyan2", "Grey2"}, {"Red3", "Blue3", "Yellow3", "Brown3", "White3", "Cyan3", "Grey3"}, {"Red4", "Blue4", "Yellow4", "Brown4", "White4", "Cyan4", "Grey4"}, {"Red5", "Blue5", "Yellow5", "Brown5", "White5", "Cyan5", "Grey5"}}, segmentTitles:{"1st Segments", "2nd Segments", "3rd Segments", "4th Segments", "5th Segments"}}

my chooseMultipleSegments:paramObj

return my returnSels
–> {1, 2, 3, 4, 5}

on chooseMultipleSegments:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set segMes2DList to segmentMes of paramObj
　　set segTitleList to segmentTitles of paramObj
　　
　　set aTmpY to (length of segMes2DList) * 60
　　
　　–BoX + Segmented Control をつくる
　　set segsList to {}
　　set boxLIst to {}
　　set segsCount to 0
　　set tmpMaxX to 500
　　
　　set aCount to 1
　　
　　repeat with i in segMes2DList
　　　　set aSeg to makeSegmentedControlWithStartY(i, aTmpY – segsCount – 40, 500, 40) of me
　　　　
　　　　set aDBounds to aSeg’s |bounds|()
　　　　set tmpWidth to getWidth(aDBounds) of me
　　　　
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aTmpY – segsCount – 60, 500, 60)))
　　　　(aBox’s setTitle:(item aCount of segTitleList))
　　　　(aBox’s addSubview:aSeg)
　　　　
　　　　if tmpWidth > tmpMaxX then set tmpMaxX to tmpWidth
　　　　
　　　　set the end of segsList to aSeg –選択検出用
　　　　set the end of boxLIst to aBox –表示用
　　　　
　　　　set segsCount to segsCount + 60
　　　　set aCount to aCount + 1
　　end repeat
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX, aTmpY))
　　theView’s setSubviews:boxLIst
　　
　　— create a Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX, aTmpY))
　　aScroll’s setDocumentView:theView
　　theView’s enclosingScrollView()’s setHasHorizontalScroller:false
　　theView’s enclosingScrollView()’s setHasVerticalScroller:false
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set my returnSels to {}
　　repeat with i in segsList
　　　　set tmpSegSel to (i’s selectedSegment()) as number
　　　　set the end of (my returnSels) to tmpSegSel + 1
　　end repeat
end chooseMultipleSegments:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeSegmentedControlWithStartY(titleList, aStartY, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(20, aHeight – 35, aWidth, aHeight – 40))
　　
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControlWithStartY

on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
end clickedSeg:

★Click Here to Open This Script　

(Visited 136 times, 2 visits today)

アラートダイアログ上にBrowser＋Map Viewを表示 v2

Posted on 3月 17, 2019 by Takaaki Naganoya

ダイアログ上に表示したNSBrowserで都道府県→都道府県別データを選択し、選択したデータの位置情報をMap Viewに表示するAppleScriptの改良版です。

初版掲載時のおかしな挙動を減らし、地図種別の切り替えができるようになっています。本掲載リストだけだと動作が完結しないため、ライブラリを含んだスクリプトバンドルをダウンロードして実行してください。下記リストは「参考までに」掲載しているものです。

–> Download whole Script bundle with Library

前バージョンでは、NSBrowser上でデータが存在していない箇所に空白のセルが表示され、クリックするとクラッシュするという状態でした。本バージョンでもたまに出てくるので完全ではないのですが、

　・予想どおりデータの行数をカウントするハンドラで絞り込みを行うPredicates文の文字列に問題があった
　・データに半角のシングルクォートが入っていて、これによってデータの絞り込みに問題が出た

という問題を解消しました。前者はこまめにstringにcastし、後者は全角文字に置き換えました。

それでもまだ問題が出るケースがあるので、まだしばらく実際に使いつつ様子見といったところでしょうか。

AppleScript名：アラートダイアログ上にBrowser＋Map Viewを表示 v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/10
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"
use scripting additions
use skLib : script "senjoNoKizunaLib"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSBrowser : a reference to current application’s NSBrowser
property MKMapView : a reference to current application’s MKMapView
property NSScrollView : a reference to current application’s NSScrollView
property NSMutableArray : a reference to current application’s NSMutableArray
property MKMapTypeHybrid : a reference to current application’s MKMapTypeHybrid
property MKMapTypeSatellite : a reference to current application’s MKMapTypeSatellite
property MKMapTypeStandard : a reference to current application’s MKMapTypeStandard
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property zLevel : 17
property aMaxViewWidth : 1000
property aMaxViewHeight : 500
property theResult : 0
property returnCode : 0
property theDataSource : {}
property aSelection : {}
property aMapView : missing value
property aBrowser : missing value
property skDataList : {}

property prefList : {"北海道", "青森県", "岩手県", "宮城県", "秋田県", "山形県", "福島県", "茨城県", "栃木県", "群馬県", "埼玉県", "千葉県", "東京都", "神奈川県", "新潟県", "富山県", "石川県", "福井県", "山梨県", "長野県", "岐阜県", "静岡県", "愛知県", "三重県", "滋賀県", "京都府", "大阪府", "兵庫県", "奈良県", "和歌山県", "鳥取県", "島根県", "岡山県", "広島県", "山口県", "徳島県", "香川県", "愛媛県", "高知県", "福岡県", "佐賀県", "長崎県", "熊本県", "大分県", "宮崎県", "鹿児島県", "沖縄県"}

if my skDataList = {} then
　　set my skDataList to current application’s NSMutableArray’s arrayWithArray:(getSenjoNokizunaGameCenterDataList() of skLib)
end if

set tmpLen to length of (my skDataList as list)

set aSelection to {}

set paramObj to {myMessage:"Choose a Game Center", mySubMessage:("Choose an appropriate Game Center from list (" & tmpLen as string) & ") to play Senjo-no-Kizuna"}

my performSelectorOnMainThread:"chooseItemByBrowser:" withObject:(paramObj) waitUntilDone:true
if (my returnCode as number) = 1001 then error number -128

return my aSelection
–> {loc_id:"QIEXj9er5QSA_Y42-OjPNg", gcName:"THE 3RD PLANET ジャングルパーク鹿児島", latitude:31.5703088, longitude:130.5653137, address:"鹿児島県鹿児島市与次郎 1-11-1　フレスポジャングルパーク2F"}

on chooseItemByBrowser:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, aMaxViewHeight))
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(410, 30, aMaxViewWidth – 410, aMaxViewHeight – 30))
　　tell aMapView
　　　　its setMapType:(MKMapTypeStandard)
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　its setDelegate:me
　　end tell
　　
　　— make browser view with scroll view
　　set aScrollWithTable to makeBrowserView(prefList, 400, aMaxViewHeight) of me
　　
　　–Segmented Controlをつくる
　　set segTitleList to {"Map", "Satellite", "Satellite + Map"}
　　set aSeg to makeSegmentedControl(segTitleList, 410, 0, 150, 20) of me
　　
　　–Compose Views in NSView
　　theView’s setSubviews:{aScrollWithTable, aMapView, aSeg}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
end chooseItemByBrowser:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeBrowserView(aList as list, aWidth as number, aHeight as number)
　　set (my theDataSource) to NSMutableArray’s arrayWithArray:aList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aBrowser to NSBrowser’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　aBrowser’s setDelegate:(me)
　　aBrowser’s setTarget:(me)
　　aBrowser’s setAction:"browserCellSelected:"
　　aBrowser’s setMinColumnWidth:120
　　aBrowser’s setSeparatesColumns:true
　　aBrowser’s setMaxVisibleColumns:2
　　aBrowser’s setAutohidesScroller:true
　　aBrowser’s setTakesTitleFromPreviousColumn:true
　　–aBrowser’s setBackgroundColor:(NSColor’s grayColor())
　　
　　aScroll’s setDocumentView:aBrowser
　　aBrowser’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aBrowser’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　return aScroll
end makeBrowserView

–NSBrowser Event Handlers
on browser:aView numberOfRowsInColumn:aColumn
　　if aColumn = 0 then
　　　　return my theDataSource’s |count|()
　　else if aColumn = 1 then
　　　　set aPath to (text 2 thru -1 of ((aView’s |path|()) as string)) as string –ここが問題だったもよう
　　　　set tmpArray to (my filterRecListByLabel1(skDataList, "address BEGINSWITH ’" & aPath & "’")) as list
　　　　return (length of tmpArray)
　　else
　　　　return 0
　　end if
end browser:numberOfRowsInColumn:

on browser:aView willDisplayCell:(aCell) atRow:(rowIndex as integer) column:(colIndex as integer)
　　if colIndex = 0 then
　　　　–Prefectures
　　　　aCell’s setTitle:((item (rowIndex + 1) of prefList) as string)
　　　　aCell’s setLeaf:false
　　　　
　　else if colIndex = 1 then
　　　　–Each Game Centers in the Prefecture
　　　　set aPath to text 2 thru -1 of ((aView’s |path|()) as string)
　　　　set tmpArray to my filterRecListByLabel1(skDataList, "address BEGINSWITH ’" & aPath & "’")
　　　　set tmpItem to (tmpArray’s objectAtIndex:rowIndex)
　　　　
　　　　set aGameCenterName to (tmpItem’s gcName) as string
　　　　aCell’s setTitle:(aGameCenterName)
　　　　aCell’s setLeaf:true
　　　　
　　else if colIndex ≥ 2 then
　　　　error "Wrong NSBrowser status"
　　end if
end browser:willDisplayCell:atRow:column:

on browserCellSelected:aSender
　　set aPath to my aBrowser’s |path|()
　　set aList to (aPath’s pathComponents()) as list
　　set aLen to length of aList
　　
　　if aLen = 3 then
　　　　–set aPref to contents of item 2 of aList
　　　　set aGc to contents of last item of aList
　　　　
　　　　set tmpArray to my filterRecListByLabel1(skDataList, "gcName == ’" & aGc & "’")
　　　　–set tmpArray to my filterRecListByLabel1(skDataList, "gcName == " & aGc)
　　　　set tmpItem to contents of first item of (tmpArray as list)
　　　　
　　　　copy tmpItem to my aSelection
　　　　
　　　　set aLatitude to (latitude of tmpItem) as real
　　　　set aLongitude to (longitude of tmpItem) as real
　　　　
　　　　tell aMapView
　　　　　　set aLocation to current application’s CLLocationCoordinate2DMake(aLatitude, aLongitude)
　　　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　end tell
　　　　
　　end if
end browserCellSelected:

–NSArrayに入れたNSDictionaryを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList, aPredicate as string)
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aRecList’s filteredArrayUsingPredicate:aPredicate
　　return filteredArray
end filterRecListByLabel1

–Segmented Controlをつくる
on makeSegmentedControl(titleList, startX, startY, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(startX, startY, aWidth, aHeight))
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControl

–Segmented Controlのクリック時のイベントハンドラ
on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
　　set tList to {MKMapTypeStandard, MKMapTypeSatellite, MKMapTypeHybrid}
　　set tmpType to contents of item (aSel + 1) of tList
　　
　　aMapView’s setMapType:(tmpType)
　　
　　set selSeg to aSel
end clickedSeg:

★Click Here to Open This Script　

(Visited 63 times, 1 visits today)

アラートダイアログ上にBrowser＋Map Viewを表示

Posted on 3月 12, 2019 by Takaaki Naganoya

ダイアログ上に表示したNSBrowserで都道府県→都道府県別データを選択し、選択したデータの位置情報をMap Viewに表示するAppleScriptです。

＃　2021年11月末にアーケードゲーム「戦場の絆」のサービスが終了したため、Webサイト側からデータ取得する部分の処理は動作しません（Webサイトごとアクセスできなくなったため）

▲macOS 10.12.6上で動作

「OK」ボタンをクリックすると選択したゲームセンターの諸元情報を返してきます。リスト一覧から名称を選択し、途中でその位置情報を地図で見られるという程度のインタフェースです。

NSBrowserを利用したUIの習作で、Web上の「戦場の絆」公式ページから導入店舗の情報を取得し（このあたりライブラリにまとめて部品化）、データを都道府県別にしぼりこんでNSBrowser上で選択できるようにしてみました。

▲macOS 10.13.6上で動作

▲macOS 10.14.4上で動作（Light Mode）

▲macOS 10.14.4上で動作（Dark Mode）

ぱっと見は「何かすごいもの」に見えるのですが、キーワード検索が実装されていないため、データしぼりこみに柔軟性がないと感じるものです。

NSBrowserをAppleScriptから利用した場合に、Xcodeを利用しないとこのレベルの単純なデータ階層固定でデータしぼりこみを行う程度のものしか作りにくいところでしょうか。不可能とは言わないものの、「普通にXcode上で作れば？」という話になると思います。

さらに、該当するカラムの行数を返すハンドラでデータをしぼりこんでレコード数を返しているものの、いまひとつここがうまく動いていない印象を受けます。NSBrowser上で「存在しないデータのような何か」をクリックできるケースがあり、それをクリックすると実行環境（スクリプトエディタとか、Script Debuggerとか）ごとクラッシュします。

→　原因がわかりました。問題箇所も想像どおり。目下、修正版で謎のゴースト行も出てこなくなったので、あとで修正版を掲載しておきます。問題が２つあって、１つがPredicates文をas stringですべてcastしていなかった件、もうひとつは、、、副次的に発生した問題で、愛知県のデータに「M’s」という半角クォート文字を含むものがあって、これでPredicates文が中断されてしまった問題。半角シングルクォートを全角に置き換えるとかいろいろ手を加える必要がありました。

本Script全体をダウンロードして、スクリプトエディタ上で実行すると、最初に「戦場の絆」公式ホームページの日本国内の店舗情報をスキャンして店舗情報を抽出するため、サーバーの混雑具合やネットワーク回線速度にも左右されますが、自分の環境では5〜15秒程度でデータの取得が終了し、ダイアログが表示されます。

–> Download whole Script bundle with Library

AppleScript名：アラートダイアログ上にBrowser＋Map Viewを表示.scptd

if my skDataList = {} then
　　set my skDataList to current application’s NSMutableArray’s arrayWithArray:(getSenjoNokizunaGameCenterDataList() of skLib)
end if

set aSelection to {}

set paramObj to {myMessage:"Choose a Game Center", mySubMessage:"Choose an appropriate Game Center from list to play Senjo-no-Kizuna"}

my performSelectorOnMainThread:"chooseItemByBrowser:" withObject:(paramObj) waitUntilDone:true
return my aSelection
–> {loc_id:"QIEXj9er5QSA_Y42-OjPNg", gcName:"THE 3RD PLANET ジャングルパーク鹿児島", latitude:31.5703088, longitude:130.5653137, address:"鹿児島県鹿児島市与次郎 1-11-1　フレスポジャングルパーク2F"}

on chooseItemByBrowser:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, aMaxViewHeight))
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(410, 0, aMaxViewWidth – 410, aMaxViewHeight))
　　tell aMapView
　　　　its setMapType:(MKMapTypeStandard)
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　its setDelegate:me
　　end tell
　　
　　— make browser view with scroll view
　　set aScrollWithTable to makeBrowserView(prefList, 400, aMaxViewHeight) of me
　　
　　–Compose Views in NSView
　　theView’s setSubviews:{aScrollWithTable, aMapView}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end chooseItemByBrowser:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–NSBrowser Event Handlers
–ここ、いまひとつきちんと動いていないかも？？？
on browser:aView numberOfRowsInColumn:aColumn
　　if aColumn = 0 then
　　　　return my theDataSource’s |count|()
　　else if aColumn = 1 then
　　　　set aPath to text 2 thru -1 of ((aView’s |path|()) as string)
　　　　set tmpArray to (my filterRecListByLabel1(skDataList, "address BEGINSWITH ’" & aPath & "’")) as list
　　　　return (length of tmpArray)
　　end if
end browser:numberOfRowsInColumn:

on browserCellSelected:aSender
　　set aPath to my aBrowser’s |path|()
　　set aList to (aPath’s pathComponents()) as list
　　set aLen to length of aList
　　
　　if aLen = 3 then
　　　　–set aPref to contents of item 2 of aList
　　　　set aGc to contents of last item of aList
　　　　
　　　　set tmpArray to my filterRecListByLabel1(skDataList, "gcName == ’" & aGc & "’")
　　　　set tmpItem to contents of first item of (tmpArray as list)
　　　　
　　　　copy tmpItem to my aSelection
　　　　
　　　　set aLatitude to (latitude of tmpItem) as real
　　　　set aLongitude to (longitude of tmpItem) as real
　　　　
　　　　tell aMapView
　　　　　　set aLocation to current application’s CLLocationCoordinate2DMake(aLatitude, aLongitude)
　　　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　end tell
　　　　
　　end if
end browserCellSelected:

★Click Here to Open This Script　

(Visited 70 times, 1 visits today)

アラートダイアログ上にBrowserを表示

Posted on 3月 2, 2019 by Takaaki Naganoya

アラートダイアログ上にNSBrowserを表示するAppleScriptの試作品です。

＃　本Scriptは実験用であって実用性はありません（＾ー＾；；

Finderに使われていることで認知度は高いものの、使いどころが難しいうえにサンプル・コードも多くないので登場頻度が少ないNSBrowserです。（Mac OS Xの前身である）NEXTSTEPのFile Managerがこんな感じのUIでした。

（個人的に）敷居の高かったNSBrowserも、いろいろ試してみたらいい感じになってきました。現状では単に２次元配列っぽいものにアクセスしているだけですが、ツリー型の構造データを与えるようにするとか、配列から徐々にデータ抽出する（大分類→中分類→小分類）ようにすれば、だいたい期待どおりの動作になるはずです。

NSBrowserも、使いたいときに調べると情報が見つからずに困りますが、用のないときなら調べておくといろいろ大丈夫そうです。

macOS 10.14上のスクリプトエディタ/Script Debugger上で動くようにハンドラをメインスレッド上で明示的に動作させるように変更しましたが、10.14上でだけ独特な挙動があるため要注意です。ただ、テストプログラムなのでそんなものだろうかと。

AppleScript名：アラートダイアログ上にBrowserを表示 v1.1.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/02
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSBrowser : a reference to current application’s NSBrowser
property NSScrollView : a reference to current application’s NSScrollView
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

set paramObj to {myMessage:"Choose a data", mySubMessage:"Choose an appropriate data from tree structured data list", aTableList:{{"1", "1.1", "1.1.1"}, {"2", "2.1", "2.1.1"}, {"3", "3.1", "3.1.1"}, {"4", "4.1", "4.1.1"}}}
–set aRes to my chooseItemByBrowser:paramObj
my performSelectorOnMainThread:"chooseItemByBrowser:" withObject:(paramObj) waitUntilDone:true

on chooseItemByBrowser:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　— make browser view with scroll view
　　set aScrollWithTable to makeBrowserView(aTList, 500, 200) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end chooseItemByBrowser:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeBrowserView(aList as list, aWidth as number, aHeight as number)
　　set (my theDataSource) to NSMutableArray’s arrayWithArray:aList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSBrowser’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　aView’s setDelegate:(me)
　　aView’s setMinColumnWidth:120
　　aView’s setSeparatesColumns:true
　　–aView’s setMaxVisibleColumns:2
　　aView’s setAutohidesScroller:true
　　–aView’s setBackgroundColor:(NSColor’s grayColor())
　　aView’s setReusesColumns:true
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　return aScroll
end makeBrowserView

–NSBrowser Event Handlers
on browser:aView numberOfRowsInColumn:aColumn
　　set aCount to my theDataSource’s |count|()
　　return aCount
end browser:numberOfRowsInColumn:

on browser:aView willDisplayCell:(aCell) atRow:rowIndex column:colIndex
　　set selRow to (my theDataSource)’s objectAtIndex:(rowIndex)
　　set selCol to selRow’s objectAtIndex:(colIndex)
　　aCell’s setTitle:(selCol as string)
　　
　　set colMax to ((my theDataSource)’s objectAtIndex:0)’s |count|()
　　log {"colMax, colIndex", colMax, colIndex}
　　set exMax to (colIndex < colMax – 1) as boolean
　　aCell’s setLeaf:(not exMax)
end browser:willDisplayCell:atRow:column:

★Click Here to Open This Script　

(Visited 93 times, 1 visits today)

アラートダイアログの背景色を指定してTable Viewを表示

Posted on 2月 25, 2019 by Takaaki Naganoya

指定色のアラートダイアログを作成し、その上にScroll View＋Table Viewを表示して選択肢の選択を行うAppleScriptです。

アラートダイアログの背景色変更のテストを行なったものです。また、メソッド名をテキストで（Table Viewから）取得し、そのメソッド名で色を作成するテスト（NSSelectorFromString）も行いました。

Table Viewで選択した色は、次回実行時に反映されます（スクリプトエディタ/Script Debugger上で）。

本当はTable View上で行を選択したときに、アラートダイアログの背景色を変更させたかったのですが、試してみたもののうまく動かなかったので、その機能は削りました。最初から指定色のダイアログウィンドウを表示するだけなら問題はないので、現状のようなコードに落ち着きました。

AppleScript名：アラートダイアログの背景色を指定してTable Viewを表示

— Created 2019-02-25 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSFullSizeContentViewWindowMask : a reference to current application’s NSFullSizeContentViewWindowMask

property theResult : 0
property returnCode : 0
property theDataSource : {}
property theColList : {}
property theWindow : missing value
property selectedColor : missing value

set paramObj to {myMessage:"Choose a color", mySubMessage:"Choose an appropriate color from color name list", aTableList:{"redColor", "blueColor", "yellowColor", "greenColor", "grayColor", "blackColor"}}
set aRes to my chooseItemByTableView:paramObj

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(aTList, 300, 120) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— customize alert’s window style and color
　　if selectedColor = missing value then
　　　　set tmpColor to NSColor’s grayColor()
　　else
　　　　set tmpSel to current application’s NSSelectorFromString(selectedColor)
　　　　set tmpColor to NSColor’s performSelector:tmpSel
　　end if
　　
　　set theWindow to theAlert’s |window|()
　　theWindow’s setTitleVisibility:false
　　–theWindow’s setStyleMask:( NSFullSizeContentViewWindowMask)
　　theWindow’s setTitlebarAppearsTransparent:true
　　theWindow’s setBackgroundColor:tmpColor
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　return (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 40
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSScrollView

アラートダイアログでMarkdownをプレビュー v2

プログラムで作ったアラートダイアログ上のTextViewをフォーカスする

アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

アラートダイアログ上にNSBoxを介してPopup Menuを表示

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明_Float_SuppressionButtonつき

アラートダイアログ上にTexViewを表示_ヘルプ付き_半透明

アラートダイアログ上にTextViewを表示