Menu

Skip to content
AppleScriptの穴
  • Home
  • Products
  • Books
  • Docs
  • Events
  • Forum
  • About This Blog
  • License
  • 仕事依頼

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: Numbers

新発売：iWork Scripting Book with AppleScript

Posted on 9月 30 by Takaaki Naganoya

Piyomaru Software Booksの59冊目。Keynote、Pages、Numbersの３つのアプリケーションのScriptingについて、共通する部分に着目して３つとも解説するScripting本、「iWork Scripting Book with AppleScript」を発売しました。本文239ページ、資料編198ページの合計437ページの大ボリウムです。

→ 販売ページ

目次

スクリプトエディタを起動しよう
スクリプトエディタを起動しよう！
スクリプトエディタのヘルプ
色設定を変えてみよう！
スクリプトを入力してみよう
スクリプトを保存しよう
スクリプトを実行しよう（1/3）
スクリプトを実行しよう（2/3）
スクリプトを実行しよう（3/3）
セキュリティとプライバシー
セキュリティとプライバシー＞プライバシー
iWork appsを起動しよう
Keynote/Pages/Numbersを指定
Keynote/Pages/Numbersを起動
Keynote/Pages/Numbersを終了
Mail.appのAppleScript用語辞書の調べ方
メニュー項目や画面強制操作の調べ方
各iWork appsの詳細仕様について
iWork appsの情報を取得しよう
アプリケーションの名前を取得
アプリケーションの情報を一括取得
アプリケーションのプロパティ項目と内容
新規書類の作成
新規書類の作成
テーマ/テンプレート名の取得
テーマ/テンプレートを指定しつつ新規書類作成①
テーマ/テンプレートを指定しつつ新規書類作成②
参考資料：テーマ/テンプレート名
Keynote：SD/HD、他のサイズの書類の指定
新規スライド/ページ/シートの作成
各iWork appsにおける新規ページの作成
Keynote：レイアウト名の取得とスライド追加
Pages：ページ追加
Numbers：シート追加
書類情報の取得
書類からの各種情報取得
書類名（name）はFinder設定と連動
書類のパスワード保護状態を取得
書類保存
書類を保存（保存ずみ書類に上書き保存）
書類を新規保存①
書類を新規保存（A.）
書類を新規保存（B.）
書類を新規保存（C.）
コラム「iWork appsが使用するパス表現」
書類へのパスワード
設定と解除
iWork書類へのパスワード設定
パスワード設定されたiWork書類のオープン
書類へのパスワード設定と解除
通常書類とパスワード保護された書類の比較

■中級

書類上の座標系
書類上の座標系
Pages書類の座標系
現在表示中のページ
書類上の現在表示中のページ番号を取得
選択中のアイテムの取得
selectionで取得できる選択中のオブジェクト
Numbersで取得できる表オブジェクト情報
デフォルトタイトル
アイテムへの文字設定（Keynote）
デフォルトタイトルアイテムのオブジェクト
デフォルトタイトルアイテムのテキストを取得
デフォルトタイトルアイテムにテキストを設定
Pagesの本文作成
書類タイプ別のPages本文の作り方
Pagesの文章の本文（body text）の操作
Pagesの文章の本文（body text）の色指定
Pagesの文章の本文（body text）のフォント指定
Pagesの文章の本文（body text）の単語にアクセス
Pagesの文章のページにアクセス（追加）
Pagesの文章のページにアクセス（削除①）
Pagesの文章のページにアクセス（削除②）
Pagesの文章のセクションにアクセス
Pagesの文章のセクションにアクセス
選択中の表からのデータ取得/設定
選択範囲（selection range）へのアクセス
選択範囲のセルの取得
選択範囲のセルのデータの取得
指定セルのデータの取得①
指定セルのデータの取得②
指定範囲のセルのデータの取得
カラム名の数値からの変換
指定範囲のセルのデータを2次元配列で取得①
指定範囲のセルのデータを2次元配列で取得②
指定範囲のセルのデータを2次元配列で取得③
指定セルにデータを設定①
指定セルにデータを設定②
指定範囲のセルへの配列データの設定
表にクリップボード経由で大量の２次元配列データを設定
テキストボックスの作成
テキストボックスのオブジェクト
テキストボックスの作成
表の作成
表の作成
表の作成＋データ設定
表のソート、
セルの結合と分離
表の昇順（A→Z）ソート
表の降順（Z→A）ソート
表セルの結合
結合セルの解除
画像（image）の挿入
指定画像の挿入
Keynote：イメージスライドの作成
shape, lineの作成
shape/lineの分類
shapeの識別
shapeの作成
放射状にラインを引く（Keynote）
放射状にラインを引く（Pages）
放射状にラインを引く（Numbers）
audio clip, movieの作成
音声トラックのaudio clipの作成
ムービー（movie）の作成
プレースホルダへのデータさしこみ（Pages）
プレースホルダとは？
Pagesのテキストプレースホルダの作成①
Pagesのテキストプレースホルダの作成②
Pagesのテキストプレースホルダを利用
Pagesのメディアプレースホルダの作成
Keynoteのテキストプレースホルダ
グループへのアクセス
Keynote：グループ内のオブジェクトにアクセス
Pages：グループ内のオブジェクトにアクセス
Numbers：グループ内のオブジェクトにアクセス
Keynote：グループ内のオブジェクトの親にアクセス
シート処理（Numbers）
Numbers：シートの新規追加
Numbers：シートの削除、表示切り替え
Numbers：シートの名称変更
Numbers：現在表示中のシートのIDを返す
Numbers：シートの名称による検索
スライドの追加と順次ループ（Keynote）
Keynote：スライドの追加
Keynote：スライドの順次ループアクセス
Keynote：スライドの順次追加
スライド間の表示切り替えエフェクト指定（Keynote）
Keynote：スライド切り替え効果一覧
Keynote：スライド切り替えを設定
発表者ノート（Keynote）を記入
Keynote：発表者ノートとは？
Keynote：発表者ノートの操作
表への計算式の代入
iWork appsで共通して利用できる関数
表のセルに計算式を代入
表のセルの計算結果（値）を取得
表のセルの計算式を取得
グラフ作成（Keynote）
Keynoteで扱えるグラフの一覧
Keynote：2D横/縦棒グラフ
Keynote：3D横/縦棒グラフ
Keynote：2D/3D面グラフ
Keynote：2D/3D円グラフ
Keynote：2D散布図グラフ
Keynote：2D積み重ね縦/横棒グラフ
Keynote：3D積み重ね縦/横棒グラフ
Keynote：2D/3D階層グラフ
Keynote：2D/3D折れ線グラフ
データの書き出し（エクスポート）
各iWork appsが書き出し可能なフォーマット
書き出し用ファイルパスの組み立て
PDF書き出し
Microsoft Office書類として書き出し
Keynote：HTML書き出し
Keynote：QuickTimeムービー書き出し
Keynote：イメージ書き出し
Keynote：Keynote 09形式書き出し
Pages：EPUB形式書き出し
Pages：テキスト書き出し
Pages：Pages 09形式書き出し
Pages：リッチテキストフォーマットで書き出し
Numbers：Numbers 09形式で書き出し
Numbers：CSV形式で書き出し
印刷
iWork appsから印刷出力
AppleScriptによるプリントアウト
Keynote：印刷オプションの指定
Pages：印刷オプションの指定
Numbers：印刷オプションの指定

■上級

書式付きテキストへのアクセス
Keynoteでobject textの書式属性設定
Pagesでobject textの書式属性設定
Numbersでobject textの書式属性設定
Keynoteでobject textの文字色、フォント置換
Pagesでobject textの文字色、フォント置換
Numbersでobject textの文字色、フォント置換
書式付きテキストの幅に応じたtext item自体のリサイズ
Text itemの枠の幅を文字内容でリサイズ①
Text itemの枠の幅を文字内容でリサイズ②
Text itemの枠の幅を文字内容でリサイズ①
Text itemの枠の幅を文字内容でリサイズ②
Text itemの枠の幅を文字内容でリサイズ①
Text itemの枠の幅を文字内容でリサイズ②
text item内のテキストの使用言語の自動推定
Keynote：書類中のtext itemの使用言語を推定①
Keynote：書類中のtext itemの使用言語を推定②
Pages：書類中のtext itemの使用言語を推定①
Pages：書類中のtext itemの使用言語を推定②
Numbers：書類中のtext itemの使用言語を推定①
Numbers：書類中のtext itemの使用言語を推定②
指定行列ヘッダによる表セルへのアクセス
Keynote：指定行列ヘッダによる表セルへのアクセス
Keynote：指定行列ヘッダによる表セルへのアクセス
Pages：指定行列ヘッダによる表セルへのアクセス
Pages：指定行列ヘッダによる表セルへのアクセス
Numbers：指定行列ヘッダによる表セルへのアクセス
Numbers：指定行列ヘッダによる表セルへのアクセス
汎用オブジェクト（iWork item）によるアクセス
汎用クラスiWork itemで取得できるオブジェクト
Keynote：iWork itemでアクセス
Pages：iWork itemでアクセス
Numbers：iWork itemでアクセス
オブジェクトの重なり検出（Keynote）
Keynote：テキストとshapeの重なり検出①
Keynote：テキストとshapeの重なり検出②
書類内部データへのアクセス
iWork app書類の構造
通常書類とパスワード保護された書類の比較
Keynote固有のプレゼン系操作について
Keynote：プレゼン再生コントロール
Keynote書類のプレゼン関連情報
Keynote：プレゼン再生関連の属性値
Keynote：transitionサンプル書類作成＆再生

(Visited 13 times, 5 visits today)
Posted in Books news | Tagged 12.0savvy Keynote Numbers Pages | Leave a comment

1D Listを2Dに評価してアイテム内の相違点を検出

Posted on 6月 28 by Takaaki Naganoya

１次元リスト（配列）を幅を指定しつつ２次元リストとして評価し、１番左側のセルとの変化を横方向にサーチして検出するAppleScriptです。

もともと、macOS標準搭載の「辞書.app」に収録される各辞書データの名称が、各OSバージョンでどのように変化しているかを表計算ソフトNumbers上でチェックしていました。辞書.appの辞書をCocoa Frameworkを通じて呼び出し、さまざまな便利な処理を行っているため、辞書名称が変わると日常的に利用しているAppleScriptに影響が出てしまいます。その変化を検出するために、辞書名の変化を知っておこうというチェック作業が発生しています。

辞書.appの収録辞書名称は、意図したものか意図していないものか不明ですが、OSバージョンごとに微妙に変化することが知られています。そうした名称細部の変化を実際にチェックするのに、専用のScriptを使っていました（過去形）。

ただし、NumbersのデータをAppleScriptから取得すると、2D Listではなく1D Listとして返ってきます。そのさいに、BridgePlusの機能を用いて1D→2D変換を行ったのちに、いろいろ処理を行ってきました。

リストの1D→2D変換処理なんて、使っている場所が多すぎて数えきれないぐらいですが、Script Menu上で動かすScriptでBridgePlusを呼び出せなくなっており（macOS 10.14以降）、今後Script Menuが機能強化されるとは考えにくいところです。

サードパーティのFastScriptsなどでFramework入りScriptの実行をサポートするとか、そういう進化ができてほしいところですが、それもちょっと期待できません。

結果として、BridgePlusを極力使わなくて済むように、機能の置き換えを進めるしかありません。無理な機能もありますが、1D→2D変換ぐらいなら問題ありません（そして、出現頻度がおっそろしく高いものであります）。

そして、実際にNumbers上のデータを横方向（左→右、冒頭から末尾へ）に走査して変更を検出する処理を書いてみました。

処理に柔軟性が欲しかったので、追加でフラグ（reNewF）を用意しました。

これがfalseの場合には、横方向に変更を走査し、変化を検出した場合には評価を打ち切ります。trueの場合には、変化を検出した場合でも変化の検出を続行します。

AppleScript名：1D Listを2D的に評価してアイテム内の相違点を検出.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/06/28
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aList to {1, 1, 1, 2, 3, 3, 3, 3, 3, 4, 3, 5}
set diffRes to getListDifference2D(aList, 3, true) of me
–> {{xAddrs:{2}, yAddr:2}, {xAddrs:{2}, yAddr:4}}–reNewF=falseで評価
–> {{xAddrs:{2}, yAddr:2}, {xAddrs:{2, 3}, yAddr:4}}—reNewF=true で評価

–1D Listを、2D Listとして評価しつつ、{cell1, cell2, cell3}のcell 1とcell2, cell3が違っていないか評価して返す
on getListDifference2D(dList as list, aWidth as integer, reNewF as boolean)
　　script tdSpd
　　　　property dList : {}
　　end script
　　
　　copy dList to (dList of tdSpd)
　　
　　set diffList to {}
　　set diffAdrList to {}
　　
　　set yOffsetCount to 1
　　
　　set aCountMax to ((length of dList) div aWidth)
　　
　　repeat with aC from 1 to (length of dList) by aWidth
　　　　set tmpList to items aC thru (aC + aWidth – 1) of (dList of tdSpd)
　　　　
　　　　set i1 to first item of tmpList
　　　　set i2 to rest of tmpList
　　　　
　　　　set xOffsetCount to 2
　　　　set xDiffList to {}
　　　　
　　　　repeat with ii in i2
　　　　　　set jj to contents of ii
　　　　　　
　　　　　　if i1 is not equal to jj then
　　　　　　　　set the end of diffList to {i1, jj}
　　　　　　　　set the end of xDiffList to xOffsetCount
　　　　　　　　
　　　　　　　　if reNewF = true then
　　　　　　　　　　copy jj to i1
　　　　　　　　else
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　end if
　　　　　　
　　　　　　set xOffsetCount to xOffsetCount + 1
　　　　　　
　　　　end repeat
　　　　
　　　　if xDiffList is not equal to {} then
　　　　　　set the end of diffAdrList to {xAddrs:xDiffList, yAddr:yOffsetCount}
　　　　end if
　　　　
　　　　set yOffsetCount to yOffsetCount + 1
　　end repeat
　　
　　return diffAdrList
end getListDifference2D

★Click Here to Open This Script　
(Visited 19 times, 1 visits today)
Posted in list | Tagged 10.14savvy 10.15savvy 11.0savvy 12.0savvy Numbers | Leave a comment

iWork Appsがv12.1にアップデート

Posted on 6月 22 by Takaaki Naganoya

v12で発生していた、新規書類をAppleScriptから保存できないバグは修正されていません。

(Visited 24 times, 1 visits today)
Posted in Bug | Tagged 10.15savvy 11.0savvy 12.0savvy Keynote Numbers Pages | Leave a comment

iWorkアプリケーションv12に共通のバグ？　新規ファイルの保存ができない

Posted on 5月 23 by Takaaki Naganoya

Apple iWorkアプリケーション（Keynote、Pages、Numbers）の最新バージョンv12.0において、共通のバグがあるのではないか？　と見ています。もちろん、見ているだけでなくAppleにバグレポートもしています。

症状は、新規作成した書類を「保存できない」というものです。

以前にも、PDFをexportできないという致命的なバグが発生していましたが、今回のも同様のメカニズムで発生しているものと見ています。つまり、「Appleが自社OSに設定したセキュリティ機能によって、自社アプリであるKeynote、Pages、Numbersが自家中毒を起こしている」という状態です。

自分の勘違いだとよいのですが….

あとは、Numbersのsaveコマンドをよく見てみると、書類フォーマットに「as Numbers」というenumがあるのですが、これはAppleScriptの処理系では「number」の複数形として認識されてしまうので、この予約語自体に無理があります。ここは、「as Numbers format」といった予約語に変えるべきです。

AppleScript名：Keynoteで新規書類作成して指定名称で新規保存.scpt
set dtPath to (path to documents folder) as string
set uuidStr to (do shell script "uuidgen") & ".key"
set savePath to dtPath & uuidStr

tell application "Keynote"
　　set nDoc to make new document with properties {document theme:theme id "Application/21_BasicWhite/Standard", width:1024, height:768}
　　save nDoc in file savePath as Keynote
end tell

★Click Here to Open This Script　
AppleScript名：Pagesで新規書類を作成して指定名称で新規保存.scpt
set dtPath to (path to documents folder) as string
set uuidStr to (do shell script "uuidgen") & ".pages"
set savePath to dtPath & uuidStr

tell application "Pages"
　　set nDoc to make new document with properties {document template:template id "Application/Blank/ISO"}
　　save nDoc in file savePath as Pages Format
end tell

★Click Here to Open This Script　
AppleScript名：Numbersで新規書類作成して指定名称で新規保存.scpt
set dtPath to (path to documents folder) as string
set uuidStr to (do shell script "uuidgen") & ".numbers"
set savePath to dtPath & uuidStr

tell application "Numbers"
　　set nDoc to make new document
　　save nDoc in file savePath as numbers –change "Numbers" word into "numbers format" because "numbers" is alredy registered as "list of number" or "every number"
end tell

★Click Here to Open This Script　
(Visited 39 times, 1 visits today)
Posted in Bug news | Tagged 10.15savvy 11.0savvy 12.0savvy Keynote Numbers Pages | Leave a comment

iWork Appsがバージョン12.0にアップデートでselection動作正常化

Posted on 4月 9 by Takaaki Naganoya

昨日、iWork Apps（Keynote、Pages、Numbers）がVer.12.0にバージョンアップしていました。

AppleScript系ではgetコマンドが追加（Keynote、Pages）されたぐらいですが、これによって「selection」の動作がまともになりました。

前バージョンのアップデートで「スライド単位の選択」がselectionで取れなくなったことで、「何か変更しようとしている最中なんだろう」とは思っていました。予想どおりです。selection動作の空白期間を置かず、前バージョンの段階で実装されていたらもっとよかったのですが。

AppleScript対応アプリケーション、スクリプタブルなアプリケーションの世界観は、小さい世界観のものから大きい世界観のものまでいろいろです。

小さい世界観１（一番小さい）：
アプリケーション起動、バージョン確認、書類のオープン、書類の印刷、アプリケーションの設定情報の確認

小さい世界観２：
小さい世界観１＋アプリケーション固有のコマンドの実行

小さい世界観３：
小さい世界観２＋書類やデータ作成のための機能、選択中のデータをおおまかに取得する機能
Keynote v11.xはここ

小さい世界観４：
小さい世界観３＋書類上のオブジェクト作成/改変機能、選択中のデータやオブジェクトへの参照を取得する機能
Keynote v12.xはここ？　まだ、Chart作成などで未サポートのグラフ形式などもあり、不完全

大きい世界観：
小さい世界観４＋書類上のオブジェクトの多数を作成/改変する機能
Adobe InDesign、Word、Excel、PowerPoint、Pixelmator Proなど。かつての（v5ぐらいの）Pagesはここにいた

Keynoteでselectionを試してみたところ、何か書類上のオブジェクトを選択してselectionを実行すると、オブジェクトへの参照を（複数、リスト形式で）取れます。オブジェクトを選択した状態でなければ、書類上のどのスライドを表示中かというスライドへの参照が取得できるようです。

Keynoteにおける処理の自由度は大幅に上がりました。選択中のテキストボックスを取得できれば、その中に含まれるテキストなり書式つきテキストを取得して、書き直し、元のテキストボックスに書き戻すことができます。

選択中のイメージを取得できれば、その画像のパスを求めるかあるいはファイル名を求めて、オリジナルの画像ファイル（書類内に格納された画像、外部に存在する画像かはやってみないと）を画像フィルタ処理などを行って書き戻すといった処理が行いやすくなります。以前までのバージョンでは、選択した画像をいったんコピーしてクリップボードに格納し、そのクリップボード内の画像に対して画像処理していました。

Pagesでも、さまざまなオブジェクトへの参照がselectionによって取得できますが、あいかわらず「ページ」という概念があるんだかないんだか不明で、アプリケーションの根幹にかかわる部分なのでいまひとつ気軽に言えないところではあります。

(Visited 29 times, 1 visits today)
Posted in news | Tagged 10.15savvy 11.0savvy 12.0savvy Keynote Numbers Pages | Leave a comment

指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力

Posted on 2月 4 by Takaaki Naganoya

指定アプリケーションが対応している各ローカライズ言語におけるアプリケーション名称を取得して、言語名をcurrent localeに合わせて変換しつつCSV出力してNumbersでオープンするAppleScriptです。

アプリケーションバンドルを調査して、ローカライズ対応している言語の一覧を取得するプログラムは組んでありました。そのローカライズを順次調べて、InfoPlist.stringsファイルを読み込み、CFBundleNameのエントリを調べています。

これで、その言語向けにローカライズされた「名称」を調べられます。あとは、言語コードを名称に変換する処理（これも、ありもの）を組み合わせて、２次元配列（2D list）にまとめあげ、CSV書き出しして（ありもの）、Numbersでオープンしただけのものです。

言語名称については、currentLocaleを利用しているため、日本語環境で実行すれば日本語表現で出力されますし、英語環境で実行すれば英語表現で出力されます。

実際に、書籍に掲載する資料用のデータを作成するときに使ってみました。

言語 Code 「地図」アプリのローカライズ名称
ドイツ語 de Karten
ヘブライ語 he מפות
英語（オーストラリア） en_AU Maps
アラビア語 ar الخرائط
ギリシャ語 el Χάρτες
日本語 ja マップ
英語 en Maps
ウクライナ語 uk Карти
スペイン語（ラテンアメリカ） es_419 Mapas
中国語（中国本土） zh_CN 地图
スペイン語 es Mapas
デンマーク語 da Kort
イタリア語 it Mappe
スロバキア語 sk Mapy
ポルトガル語（ポルトガル） pt_PT Mapas
マレー語 ms Peta
スウェーデン語 sv Kartor
チェコ語 cs Mapy
韓国語 ko 지도
広東語（中国本土） yue_CN 地图
ノルウェー語 no Kart
ハンガリー語 hu Térképek
中国語（香港） zh_HK 地圖
トルコ語 tr Harita
ポーランド語 pl Mapy
中国語（台湾） zh_TW 地圖
英語（イギリス） en_GB Maps
ベトナム語 vi Bản đồ
ロシア語 ru Карты
フランス語（カナダ） fr_CA Plans
フランス語 fr Plans
フィンランド語 fi Kartat
インドネシア語 id Peta
オランダ語 nl Kaarten
タイ語 th แผนที่
ポルトガル語 pt Mapas
ルーマニア語 ro Hărți
クロアチア語 hr Karte
ヒンディー語 hi नक़्शा
カタロニア語 ca Mapes
AppleScript名：指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/02/04
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set targFile to "InfoPlist.strings"
set targKey to "CFBundleName"

set aLocale to (current application’s NSLocale’s currentLocale())

set aLoc to path to applications folder
set anApp to POSIX path of (choose file of type {"com.apple.application-bundle"} default location aLoc)

set aBundle to getBundleFromPath(anApp) of me
set aName to aBundle’s objectForInfoDictionaryKey:(current application’s kCFBundleNameKey)

set aLocList to getSpecifiedAppFilesLocalizationListWithDuplication(aBundle) of me

set hitList to {}

repeat with i in aLocList
　　set j to contents of i
　　
　　if j is not equal to "Base" then
　　　　set allPath to anApp & "/Contents/Resources/" & j & ".lproj/" & targFile
　　　　set aDict to (current application’s NSDictionary’s alloc()’s initWithContentsOfFile:allPath)
　　　　
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　set aLang to getLangNameWithLocale(j, aLocale) of me
　　　　　　　　set the end of hitList to {aLang, j, aVal as string}
　　　　　　end if
　　　　else
　　　　　　log {"Error in ", j}
　　　　end if
　　end if
end repeat

–一時ファイルをCSV形式でデスクトップに書き出し
set aPath to (path to desktop as string) & (do shell script "uuidgen") & ".csv"
saveAsCSV(hitList, aPath) of me

–書き出したCSVファイルをNumbersでオープン
tell application "Numbers"
　　open (aPath as alias)
end tell

–Application path –> Bundle
on getBundleFromPath(aPOSIXpath)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aPOSIXpath
　　set aWorkspace to current application’s NSWorkspace’s sharedWorkspace()
　　set appURL to aWorkspace’s URLForApplicationToOpenURL:aURL
　　set aBundle to current application’s NSBundle’s bundleWithURL:appURL
　　return aBundle
end getBundleFromPath

–指定Bundleのローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(aBundle)
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on getLangNameWithLocale(langCode, aLocale)
　　set aLangName to (aLocale’s displayNameForKey:(current application’s NSLocaleIdentifier) value:langCode) as string
　　return aLangName
end getLangNameWithLocale

–2D List to CSV file
on saveAsCSV(aList, aPath)
　　–set crlfChar to (ASCII character 13) & (ASCII character 10)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　writeToFileAsUTF8(wholeText, bPath, false) of me
　　
end saveAsCSV

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　
(Visited 31 times, 1 visits today)
Posted in Language Locale Record | Tagged 10.15savvy 11.0savvy 12.0savvy NSBundle NSDictionary NSLocale NSURL NSWorkspace Numbers | Leave a comment

Numbersの表でセル連結箇所が存在していたらすべて連結解除

Posted on 1月 31 by Takaaki Naganoya

指定のNumbers書類中の指定の表で、セルの連結が行われた箇所が存在していたらすべて連結解除するAppleScriptです。

Numbersの表でセルの連結が存在していると、フィルタ処理などが行えないために、セル連結箇所がないかを調べる手段がないと困ります。でも、そういう便利なコマンドがNumbersのAppleScript用語辞書には存在していないので作りました。

連結箇所が分かれば、個別に連結解除するだけです。ループですべてunmergeします。

動作確認は、M1 Mac mini＋macOS 12.3beta＋Numbersバージョン11.2で行なっています。


▲処理前 セルが連結されている箇所が複数存在している


▲処理後　すべてのセル結合されている箇所が連結解除された

AppleScript名：指定の表で連結セルがあればすべて分離.scpt
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/01/31
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSCountedSet : a reference to current application’s NSCountedSet

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　tell table 1
　　　　　　　　set nList to name of every cell
　　　　　　　　set aRes1 to returnDuplicatesOnly(nList) of me –重複するセルの名称のみピックアップ
　　　　　　　　
　　　　　　　　–重複セルを個別に分離
　　　　　　　　repeat with i in aRes1
　　　　　　　　　　set j to contents of i
　　　　　　　　　　unmerge cell j
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
end tell

on returnDuplicatesOnly(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　
(Visited 37 times, 1 visits today)
Posted in list Object control | Tagged 10.15savvy 11.0savvy 12.0savvy NSCountedSet Numbers | Leave a comment

Numbersの表でセル連結箇所が存在しているかどうかチェック

Posted on 1月 31 by Takaaki Naganoya

指定のNumbers書類中の指定の表で、セルの連結が行われた箇所が存在しているかどうかチェックするAppleScriptです。

Numbersの表でセルの連結が存在していると、フィルタ処理などが行えないために、セル連結箇所がないかを調べる手段がないと困ります。でも、そういう便利なコマンドはNumbersのAppleScript用語辞書には存在していません。

動作確認は、M1 Mac mini＋macOS 12.3beta＋Numbersバージョン11.2で行なっています。

セルが連結されている箇所は、セルのnameが重複していることが判明。すべてのセルの「name」を取得して、重複しているものをチェックするとセル連結の有無がわかります。

B3セルのproperties

{vertical alignment:top, row:row “row2” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, class:cell, font name:”HiraKakuProN-W3″, formatted value:”2 21″, background color:missing value, formula:missing value, name:”B3″, text wrap:true, text color:{0, 0, 0}, alignment:auto align, column:column “field1” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, format:automatic, font size:10.0, value:”2 21″}

C3セルのproperties

{vertical alignment:top, row:row “row2” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, class:cell, font name:”HiraKakuProN-W3″, formatted value:”2 21″, background color:missing value, formula:missing value, name:”B3″, text wrap:true, text color:{0, 0, 0}, alignment:auto align, column:column “field2” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, format:automatic, font size:10.0, value:”2 21″}

AppleScript名：指定の表でセル連結がないかチェック.scpt
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/01/31
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSCountedSet : a reference to current application’s NSCountedSet

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　tell table 1
　　　　　　　　set nList to name of every cell
　　　　　　　　set aRes1 to returnDuplicatesOnly(nList) of me
　　　　　　　　return aRes1
　　　　　　　　–> {"B3"}
　　　　　　end tell
　　　　end tell
　　end tell
end tell

on returnDuplicatesOnly(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　
(Visited 39 times, 1 visits today)
Posted in list Object control | Tagged 10.15savvy 11.0savvy 12.0savvy NSCountedSet Numbers | 1 Comment

iWorks Apps v11.2が登場

Posted on 9月 30, 2021 by Takaaki Naganoya

Apple純正のiWorks App（Keynote、Pages、Numbers）の新バージョンv11.2がリリースされました。

バージョン番号が「11.1」から「11.2」に変わっただけですが、内部的にも…各アプリケーションともアイコン自体が変更になり、大きな節目のバージョンであることが伺われます。

iOS、iPadOSが新製品とともに９月にアップデートし、iWorkアプリケーションがアップデートした後にmacOSのアップデートが行われるわけで、実にリリース間近であることを感じさせます。Windows 11の発表日がどの程度注目を浴びているかはわかりませんが、10月5日より前に発表することは…ないのではないかと（ノーアイデアです）。

これらのアプリケーションのAppleScript用語辞書については、「get」コマンドが追加されたことを確認していますが、このコマンドがないと実現できないことが不明（普通は省略されるコマンド）なので、何か後で追加するための「布石」と見るのが正しい見方でしょう。

Keynote v11.2の変更点：
・スライド上のライブビデオ
・複数発表者スライドショー
・レーダーグラフ（レーダーチャートのこと）

Pages v11.2の変更点：
・ブックの公開の改善
・素早くテキストを翻訳
・レーダーグラフ（レーダーチャートのこと）

Numbers v11.2の変更点：
・強力なピボットテーブル
・レーダーグラフ（レーダーチャートのこと）
・フィルタの改善

そして、AppleScript用語辞書に「レーダーグラフ」の作成機能は反映されていないため、まだAppleScriptから追加することはできません。通例だと、マイナーアップデート２回後ぐらいに反映されるのではないでしょうか？

Pages v11.2でトンでもない変更が加わっていることが判明しました。なんと、selectionを取得できなくなっています。

これは、Pagesの数少ない長所だったのですが、selectionを取得できないととても困ります、、、、、

一応、フィードバックしておきましたが、直るかどうかは不明です。Pagesの唯一の美点であった、selectionを返せ！！！

Keynote v11.2でも、selectionが使えなくなっていました（スライド単位の選択も無効に）。

(Visited 71 times, 1 visits today)
Posted in news | Tagged 10.15savvy 11.0savvy 12.0savvy Keynote Numbers Pages | Leave a comment

Pagesの最前面の書類で選択中のツメを修正する

Posted on 9月 22, 2021 by Takaaki Naganoya

Pagesで作成中の書類すべての見開き右側ページ右端につけている「ツメ」（辞書や電話帳でページ端につけているマーク的なもの、A〜Zのうちいま「S」の部分を表示していますよ、という場合にはSの箇所のみ色を変えておくなど）の修正を行うAppleScriptです。

PagesはiWork 3兄弟で唯一、選択中のオブジェクトがselectionで取得できるアプリケーションです。selectionでオブジェクトを選択可能かどうかでScriptの書きやすさが段違いです。

「ツメ」の修正が必要な事態になりました。AppleScriptのプログラムでPages書類を順次オープンして、書類中の右側ページ右端についている超縦長の表オブジェクトを「ツメ」であると仮定。このツメ（表）の修正を行う処理部分が、本AppleScriptの該当部分です。

Pages書類上の表の各種操作は、削除についてはdelete row 2とかdelete column 3といった操作が行えるのですが、追加に関してはinsert rowとかadd rowといった明示的なコマンドがあるわけではなく、propertyのcount rowを変更することで表末尾への行追加を行うことになります。

その後は、表のセル内の値を移動させたり、書式を変更するなどの「つじつま合わせ」を行うことになるでしょう。

あとは、指定フォルダ以下に入っているPages書類を抽出して、順次オープンし、書類中の右側ページ右端にある「ツメ」を計算でピックアップ。「ツメ」に対して修正を行い、保存してクローズ、という処理になるでしょうか。一度しか使えない壮大な「使い捨てScript」です。

AppleScript名：選択中のツメの修正・変更.scpt
tell application "Pages"
　　tell front document
　　　　set aSel to selection
　　　　if aSel = {} then return
　　　　
　　　　set aaSel to first item of aSel
　　　　
　　　　tell aaSel
　　　　　　set row count of it to 15 –表の行数変更
　　　　　　
　　　　　　tell row 14
　　　　　　　　set aCon to value of cell 1
　　　　　　　　
　　　　　　　　tell cell 1
　　　　　　　　　　set value to "14"
　　　　　　　　　　set font name to "7barSPBd"
　　　　　　　　　　set font size to 22.0
　　　　　　　　　　set text color to {32767, 32767, 32767}
　　　　　　　　end tell
　　　　　　　　
　　　　　　end tell
　　　　　　
　　　　　　tell row 15
　　　　　　　　set value of cell 1 to aCon
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　
(Visited 50 times, 1 visits today)
Posted in Object control | Tagged 10.15savvy 11.0savvy 12.0savvy Numbers | 1 Comment

Numbersの書類上で選択中の範囲のセルの値をシャッフル

Posted on 8月 24, 2021 by Takaaki Naganoya

Numbersの書類上で選択中の範囲のセルの値をシャッフルするAppleScriptです。Numbers書類の表の上で節度ある範囲（テスト用なので…100個ぐらい？）のセルを選択して実行し、シャッフされたデータをNumbersに描き戻します。

＃　単なるデモScriptなので、数千とか数万個のセルを選択した場合には、CSVに書き出してNumbersでオープンし、そのデータ内容をコピペで元のNumbersに書き戻したほうが処理が速いことでしょう。

実際にmacOS 12 beta5でどの程度、処理速度が向上したかを確認するために書いてみました。

–> Watch macbookpro10,1_10.14_macminim1_12 demo

上記の画像で左がMacBookPro 10,1（Intel Core i7 2.66GHz、macOS 10.14.6）、右がMacmini9,1（Apple M1 3.2GHz、macOS 12 beta5）です。

これまで使用してきたMacBook Pro Retina 2012と現行のM1 Mac miniの速度差は気になります。macOS 11上ではM1 Mac miniのほうが10倍遅かったわけですが、最新のmacOS 12 beta5ではどうなのか。

きっちり両方とも揃えてスタートできているわけではありませんが、それでもM1のほうが２倍強ほど高速になっていることがわかります。このぐらいだと友人知人におすすめしても恨まれないレベルだと思います。

ただ、お勧めするにしてもmacOS 12の正式版が出てからですね。自分のMac App Storeに出しているアプリも、macOS 12がリリースされる前にUniversal Binary版を出すと「M1対応にしても速くなっていない」などと文句を言われそうです。

逆に、macOS 12の正式版がリリースされたら「Intel版のままなのに信じられないほど速くなった」ということになりそうです。

AppleScript名：セルの値のシャッフル.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/08/22
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use framework "GameplayKit"
use scripting additions

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　return –何も選択されてなかった場合は終了
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　set mySelectedRanges to value of every cell of selection range
　　　　　　　　set cellList to cell of selection range
　　　　　　end tell
　　　　end tell
　　end tell
end tell

–1D Array Shuffle
set anArray to current application’s NSArray’s arrayWithArray:mySelectedRanges
set randomArray to anArray’s shuffledArray() as list — requires macOS 10.12

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　tell theTable
　　　　　　　　repeat with i from 1 to (length of cellList)
　　　　　　　　　　tell item i of cellList
　　　　　　　　　　　　set value to item i of randomArray
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　
(Visited 53 times, 1 visits today)
Posted in list | Tagged 10.14savvy 10.15savvy 11.0savvy 12.0savvy Numbers | Leave a comment

iWork Appsがv11.0にアップデート、Keynoteの恥ずかしいバグが直る

Posted on 3月 24, 2021 by Takaaki Naganoya

iWork Apps（Keynote、Numbers、Pages）がバージョン11.0にアップデートされました。

３アプリ共通でAppleScriptから書類のパスワード設定確認、パスワード設定の機能が追加されています。

また、Keynote v10.3.5、v10.3.8とmovie書き出し時のCodec指定オプションに「h.264」とAppleScriptの処理系ではエラーになる記号を含む予約語が入っていたのですが、これがv11.0で「h264」と修正されました。

＃　記号を含む予約語は禁止されています。「C++」とか（Fine Reader OCR Proに入っていますわー）

実際に動作確認してみないとまともに動くかどうかは不明ですが、用語辞書上では修正されています。報告して半年以内で修正されたので、修正も何もされないよりはマシでしょう。正直なところ、こんな程度の低いバグは事前にチェックして解消してほしいところではあります（Mac App Storeに一般開発者が出したらリジェクトされるレベル？）。

ちょいちょいAppleScriptの瑣末な機能を追加していただけるのはありがたいのですが、ページ内の選択中のオブジェクトへのアクセス（selected itemsとか）を用意してほしいところです。現状ではselectionで取れるのはページ（slide）単位だけです。

また、text itemの縦書き（Vertical）属性にもアクセス（Read/Write）できてほしい気がします。Keynote書類上にWord Cloudを作成するときにScriptから素直にオブジェクト回転ができずに困ります（GUI Scriptingで強引にやってるんですけれども）。


▲Keynote v11：h.264→h264と修正


▲Keynote v11：documentに「password protected」属性（Read Only）と、「set password」コマンドが追加

Keynote v11.0上で動作確認ずみ。ただし、いったんパスワードを設定した書類は、GUI側からしかパスワード解除できない点に注意。また、AppleScriptからのKeynote書類オープン時にパスワードを指定してオープンすることもできないので、当該書類のパスワードをKeychainに保存しないと書類オープン時のパスワード入力をパスできない。こちらはちゃんと（h.264と違って）動作確認したらしい。でも、油断はできない。それがAppleクオリティ。


▲Numbers v11：documentに「password protected」属性（Read Only）と、「set password」コマンドが追加


▲Pages v11：documentに「password protected」属性（Read Only）と、「set password」コマンドが追加


▲Pages v11：exportコマンドのexport optionsに「include comments」属性と、「include annotations」属性が追加

(Visited 96 times, 1 visits today)
Posted in Bug Update | Tagged 10.15savvy 11.0savvy Keynote Numbers Pages | Leave a comment

Numbersで選択範囲に背景色を塗られているセル数をカウント

Posted on 12月 14, 2020 by Takaaki Naganoya

Numbersでオープン中の最前面の書類の現在のシート上の選択状態にある表の選択範囲から、背景色（background color）が塗られているセルを数えるAppleScriptです。

用途は、WebGL + three.jsで作られた3Dの回転選択メニューのデータ確認のためです。Numbers上で表示範囲の表を作って、その上で背景色を塗ることで「どの位置にデータを表示するか」を指定します。そのさいに、並べるセル数が表示用のJavaScriptと合っていないと面倒なので、本Scriptで色つきセルをかぞえています。

Numbers上で背景色（background color）が塗られているセルは16ビットで色の値が返ってきますし、塗られていないセルはmissing valueが返ってきます。

AppleScript名：Numbersで選択範囲に背景色を塗られているセル数をカウント
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/12/06
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Numbers"
　　tell front document
　　　　–現在表示中のシートを対象にする
　　　　tell active sheet
　　　　　　–Tableを特定する
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　display notification "Numbers: There is no selection"
　　　　　　　　return {}
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　–選択範囲のデータを1D Listで取得する
　　　　　　　　set aRes to background color of cells of selection range
　　　　　　end tell
　　　　　　
　　　　　　
　　　　　　–Count Background
　　　　　　set aCount to 0
　　　　　　repeat with i in aRes
　　　　　　　　set j to contents of i
　　　　　　　　
　　　　　　　　if j is not equal to missing value then
　　　　　　　　　　set aCount to aCount + 1
　　　　　　　　end if
　　　　　　end repeat
　　　　　　
　　　　　　return aCount
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

同様に、着色セルの座標値（x座標, y座標）を返すものも作って使用しています。

AppleScript名：Numbersで選択中のセルのうち背景色を塗られているもののx,y座標を2D Listで返す
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/12/06
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Numbers"
　　tell front document
　　　　–現在表示中のシートを対象にする
　　　　tell active sheet
　　　　　　–Tableを特定する
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　display notification "Numbers: There is no selection"
　　　　　　　　return {}
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　tell selection range
　　　　　　　　　　set cellRes to background color of cells
　　　　　　　　　　set aWidth to count every column
　　　　　　　　　　set aHeight to count every row
　　　　　　　　end tell
　　　　　　end tell
　　　　　　
　　　　　　–Check selected cell’s background color
　　　　　　set cellL to {}
　　　　　　set adrCount to 1
　　　　　　repeat with y from 1 to aHeight
　　　　　　　　repeat with x from 1 to aWidth
　　　　　　　　　　set aTmp to contents of (item adrCount of cellRes)
　　　　　　　　　　
　　　　　　　　　　if aTmp is not equal to missing value then
　　　　　　　　　　　　set the end of cellL to {x, y}
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　　　set adrCount to adrCount + 1
　　　　　　　　end repeat
　　　　　　end repeat
　　　　　　
　　　　　　return cellL
　　　　　　–> {{1, 1}, {2, 1}, {3, 1}, {6, 1}, {8, 1}, {12, 1}, {15, 1}, {16, 1}, {20, 1}, {21, 1}, {24, 1}, {27, 1}, {28, 1}, {29, 1}, {1, 2}, {4, 2}, {6, 2}, {9, 2}, {11, 2}, {14, 2}, {17, 2}, {19, 2}, {23, 2}, {25, 2}, {27, 2}, {1, 3}, {2, 3}, {3, 3}, {6, 3}, {10, 3}, {14, 3}, {17, 3}, {19, 3}, {20, 3}, {23, 3}, {25, 3}, {27, 3}, {28, 3}, {29, 3}, {1, 4}, {6, 4}, {10, 4}, {14, 4}, {17, 4}, {21, 4}, {23, 4}, {25, 4}, {27, 4}, {1, 5}, {6, 5}, {10, 5}, {15, 5}, {16, 5}, {19, 5}, {20, 5}, {21, 5}, {24, 5}, {27, 5}, {1, 7}, {5, 7}, {8, 7}, {11, 7}, {12, 7}, {15, 7}, {17, 7}, {19, 7}, {20, 7}, {21, 7}, {23, 7}, {27, 7}, {1, 8}, {2, 8}, {4, 8}, {5, 8}, {7, 8}, {9, 8}, {11, 8}, {13, 8}, {15, 8}, {17, 8}, {20, 8}, {23, 8}, {27, 8}, {1, 9}, {3, 9}, {5, 9}, {7, 9}, {8, 9}, {9, 9}, {11, 9}, {12, 9}, {15, 9}, {17, 9}, {20, 9}, {23, 9}, {25, 9}, {27, 9}, {1, 10}, {5, 10}, {7, 10}, {9, 10}, {11, 10}, {13, 10}, {15, 10}, {17, 10}, {20, 10}, {23, 10}, {24, 10}, {26, 10}, {27, 10}, {1, 11}, {5, 11}, {7, 11}, {9, 11}, {11, 11}, {13, 11}, {16, 11}, {20, 11}, {23, 11}, {27, 11}}
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　
(Visited 381 times, 4 visits today)
Posted in Color list | Tagged 10.13savvy 10.14savvy 10.15savvy 11.0savvy Numbers | Leave a comment

Numbers選択セルの内容の&エンコーディング文字をプレーン化

Posted on 12月 7, 2020 by Takaaki Naganoya

Numbersのワークシート上で選択したセル中の文字に＆エンコーディング文字が存在している場合に、その内容をプレーンテキスト化するAppleScriptです。

内容自体はよくあるものなので、説明が必要なものでもありません。Stream DeckにNumbers関連のScriptをいくつか用意して試していますが、なかなか便利です（かといって、Stream Deckの購入を決意するほどではないのですが）。ただ、実際にデータ整理が少ない手間で行えました。

Stream Deck Softwareの「システム」＞「開く」のアクションにscpt形式のAppleScript書類を登録しておけば実行してくれるため、そのような利用方法を想定しています。

Numbers関連のさまざまな雑多な作業をAppleScriptで省力化し、それをStream Deckから呼び出すことで作業の負荷を減らせることを実感しています。それでもStream Deckの物理的な厚みがあるので何度もパチパチ叩いていると疲れやすいような気もします。

AppleScript名：選択セルの内容の&エンコーディング文字をプレーン化.scpt
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/12/06
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

decodeSelection() of me

–Numbersの選択範囲のデータを2D Listで返す
on decodeSelection()
　　tell application "Numbers"
　　　　tell front document
　　　　　　–現在表示中のシートを対象にする
　　　　　　tell active sheet
　　　　　　　　–Tableを特定する
　　　　　　　　try
　　　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　　　on error
　　　　　　　　　　display notification "Numbers: There is no selection"
　　　　　　　　　　return {}
　　　　　　　　end try
　　　　　　　　
　　　　　　　　tell theTable
　　　　　　　　　　–選択範囲のデータを1D Listで取得する
　　　　　　　　　　set aRes to value of cells of selection range
　　　　　　　　　　–選択範囲のセルのアドレスデータを1D Listで取得する
　　　　　　　　　　set cellList to cell of selection range
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　–Percent Decode
　　　　　　　　set newList to {}
　　　　　　　　repeat with i in aRes
　　　　　　　　　　set j to contents of i
　　　　　　　　　　set aRes to decodeCharacterReference(j as string) of me
　　　　　　　　　　set the end of newList to aRes
　　　　　　　　end repeat
　　　　　　　　
　　　　　　　　–Write Back to Numbers
　　　　　　　　repeat with i from 1 to (length of cellList)
　　　　　　　　　　tell item i of cellList
　　　　　　　　　　　　set value to item i of newList
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　　　
　　　　　　end tell
　　　　end tell
　　end tell
end decodeSelection

on parseByDelim(aData, aDelim)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set dList to text items of aData
　　set AppleScript’s text item delimiters to curDelim
　　return dList
end parseByDelim

on decodeCharacterReference(aStr)
　　set anNSString to current application’s NSString’s stringWithString:aStr
　　set theData to anNSString’s dataUsingEncoding:(current application’s NSUTF16StringEncoding)
　　set styledString to current application’s NSAttributedString’s alloc()’s initWithHTML:theData documentAttributes:(missing value)
　　set plainText to (styledString’s |string|()) as string
　　return plainText
end decodeCharacterReference

★Click Here to Open This Script　
(Visited 48 times, 1 visits today)
Posted in Text | Tagged 10.14savvy 10.15savvy 11.0savvy Numbers | Leave a comment

iWork Appsのv10.2アップデートが公開される

Posted on 9月 23, 2020 by Takaaki Naganoya

AppleがKeynote/Pages/Numbersのv10.2アッップデートを公開しました。このv10.2から対象OSがmacOS 10.15以降になり、macOS 10.14では最新のKeynote v10.2を使えなくなったことになります。

Keynote v10.2のAppleScript系の機能の差分チェックを（sdefファイルベースで）行ってみたところ、iWorkアプリケーション中でKeynoteのみ機能追加されたことがわかりました。

Keynoteにムービー書き出し機能のAppleScriptオプション機能が追加される

exportコマンドのexport optionsで「movie codecs」と「movie framerates」の指定ができるように機能追加されています。

movie codecs enum
h.264 : H.264
AppleProRes422 : Apple ProRes 422
AppleProRes4444 : Apple ProRes 4444
AppleProRes422LT : Apple ProRes 422LT
AppleProRes422HQ : Apple ProRes 422HQ
AppleProRes422Proxy : Apple ProRes 422Proxy
HEVC : HEVC

movie framerates enum
FPS12 : 12 FPS
FPS2398 : 23.98 FPS
FPS24 : 24 FPS
FPS25 : 25 FPS
FPS2997 : 29.97 FPS
FPS30 : 30 FPS
FPS50 : 50 FPS
FPS5994 : 59.94 FPS
FPS60 : 60 FPS

風の噂によるとどうもARM Macはムービー書き出しが高速なようなので、そのあたりをアピールするためにもムービー書き出し系の機能の拡充は必要ということなのでしょう。

KeynoteのAppleScript用語辞書に構文確認をパスできないバグ持ち予約語が存在

同時に、「こんなんAppleScriptの処理系でコンパイル（構文確認）通るわけないやん、メーカーが何やってますのん？」という予約語がsdef内に書かれていることが一目でわかりました。

「h.264？」

この「h.264」の予約語はexportコマンドのexport optionsのmovie codecsのEnum内に書かれています。

        ＜enumeration name="movie codecs" code="Knmc"＞
            ＜enumerator name="h.264" code="Kmc1" description="H.264"＞
                ＜cocoa string-value="AVVideoCodecTypeH264" /＞
            ＜/enumerator＞

macOS 10.15.6上で確認したところ、見事に構文確認時にエラーになります。

Apple製のアプリケーションのAppleによるスクリプティング定義内容がまともに動きません。こうした事態は理解に苦しむものがあります。100％動作確認していないとしか思えません。

ここは、記号入りの予約語では言語処理系的に構文確認すらパスできないので、「h.264」ではなく記号を含まない「h264」ないし「H264」という予約語にすべきです。AppleScript系の機能を追加していただくのは前向きでよいと思いますが、メーカーとして一度も動作確認しないで機能をリリースするというのはいかがなものでしょう？

そんなところに凝っていないで、選択中のオブジェクトを取れる属性「selected objects」とか、テキストオブジェクトの縦書き制御属性「vertical」などをつけたほうが実用性があって助かります。機能追加自体はたいした作業ではありませんが、ぜひ動作確認した上でリリースしていただきたいところです。

AppleScript名：keynote movie export test
–Works with Keynote v10.2 or later
set aTagFile to ((path to desktop) as string) & "testOut.m4v"

tell application "Keynote"
　　set exOpt to {compression factor:1.0, movie format:native size, class:export options}
　　–set exOpt to {compression factor:1.0, movie format:native size, movie codec:h.264, class:export options}–this cause error
　　export document 1 to file aTagFile as QuickTime movie with properties exOpt
　　
end tell

★Click Here to Open This Script　

日頃からMac App Storeのレビューアーの血も涙もない（でも、ツッコミどころ満載の）リジェクトに遭っている身からすれば、こんなのリジェクト案件です。

個人的には信頼度の問題からmacOS 10.15は「パス」なので、macOS 11.0 Big SurがRelease時にコケないことを祈るのみです（メールが消えるとかいう話が一番OSの信頼度を下げる）。macOS 10.13, “Vista”という史上最悪・最低の大失敗をやらかして以来、「Release版のOSがBetaよりも低品質」という昨今のmacOS。10.13もBetaの時にはよかったのに、Release版で大崩壊を起こして見るも無残な姿に成り果てました。10.14もBetaの段階でGUI Scriptingの認証系でひどいバグがあって、「とても使えない」と判断。10.14.6まで待ってようやく手を出す気になったほど。

macOS 11.0, Big SurはBeta段階でも珍しく好印象で（GUIまわりの仕様はコロコロ変わるけど）、macOS 10.15みたいにBeta段階で「もう、これはダメ！」という話も聞きません（Relase時に紹介記事を書かなかったOSは10.15がはじめてです。10.15の崩壊度はひどかった）。macOS 11.0, Big Surには、macOS 10.13のような「Release版の大崩壊」を起こしてほしくないものです。

(Visited 46 times, 1 visits today)
Posted in Bug sdef | Tagged 10.15savvy 11.0savvy Keynote Numbers Pages | Leave a comment

Numbers書類からExcel書き出し

Posted on 7月 4, 2020 by Takaaki Naganoya

Numbers書類をExcel形式（.xlsx）で書き出すAppleScriptです。

とりあえず動作確認のために作っただけだったので、動作は最低限のものです。Numbersでオープン中のNumbers書類をExcel形式に書き出します。それだけです。処理対象は１つのシートのみ含んでいる書類に限っています。Numbers書類のオープンや書き出した書類のクローズは別途作成してください。

Numbers書類でシートが複数存在しているものをExcel書類に書き出すと、各シートへのリンクが含まれたインデックスが１枚追加されます。このインデックスは非常に親切でよいのですが、割と邪魔です。あとでScript側から削除することも可能ですが、自分はNumbersから書き出す際に複数シートの書類は書き出さないようにまとめてみました。

もちろん、これはルーチンを整備して実際に使う人の考えによるものなので、別の人はNumbersの複数シートを含む書類をそのままExcel書類に変換されてもいいと考えるかもしれないですし、処理時に複数のシートを個別のNumbers書類に分割するような処理を書いてもいいでしょう。

実際にNumbersを使っていて、あまりExcel書き出しは必要にならなかったので「できる」ことは知っていながらも書かなかった処理ではあります。

AppleScript名：Numbers書類からExcel書き出し
— Created 2017-03-28 by Takaaki Naganoya
— Modified 2020-07-02 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set tmpPath to (path to desktop) as string
set aRes to exportNumbersDocToExcel(tmpPath) of me

–Numbers書類をExcel書き出し
on exportNumbersDocToExcel(targFolderPath as string)
　　tell application "Numbers"
　　　　set dCount to count every document
　　　　if dCount = 0 then
　　　　　　return false
　　　　end if
　　　　
　　　　–複数のシートが存在していると書き出せないことはないが、リンク付きの凝ったExcelシートになる
　　　　tell front document
　　　　　　set sCount to count every sheet
　　　　　　if sCount = 0 or sCount > 1 then
　　　　　　　　return false
　　　　　　end if
　　　　end tell
　　　　
　　　　set aPath to file of document 1
　　end tell
　　
　　set curPath to (current application’s NSString’s stringWithString:(POSIX path of aPath))’s lastPathComponent()’s stringByDeletingPathExtension()’s stringByAppendingString:".xlsx"
　　set outPath to (targFolderPath & curPath)
　　–このあと、安全のために重複パスの回避ルーチンを呼んでおくといいでしょう
　　
　　tell application "Numbers"
　　　　set anOpt to {class:export options, image quality:Best}
　　　　export document 1 to file outPath as Microsoft Excel with properties anOpt
　　　　return true
　　end tell
end exportNumbersDocToExcel

★Click Here to Open This Script　
(Visited 125 times, 1 visits today)
Posted in file | Tagged 10.13savvy 10.14savvy 10.15savvy 11.0savvy Numbers | Leave a comment

Finder上で「すべてのファイル名拡張子を表示」にチェックが入っているかを返す

Posted on 5月 19, 2020 by Takaaki Naganoya

Finderの環境設定で「すべてのファイル名拡張子を表示」にチェックが入っているかを確認するAppleScriptです。

iWorkアプリケーション（Keynote、Pages、Numbers）では、オープン中の書類名を返すときに、Finderの上記の環境設定の内容を反映して拡張子を含めたり、含めなかったりしつつ名称を返すという仕様。

「ファイル名単独で求めることなんてないでしょ？」と思いつつも、オープン中のドキュメントの存在確認を名称で行うため、けっこう左右されることになります。

AppleScript名：Finder上で「すべてのファイル名拡張子を表示」にチェックが入っているかを返す.scpt
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/19
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

set exRes to checkDisplayTheFileExtensionsInFinder() of me
–> true

on checkDisplayTheFileExtensionsInFinder()
　　try
　　　　set aRes to (do shell script "/usr/bin/defaults read NSGlobalDomain AppleShowAllExtensions") as integer
　　　　return aRes as boolean
　　on error
　　　　return false
　　end try
end checkDisplayTheFileExtensionsInFinder

★Click Here to Open This Script　
(Visited 41 times, 1 visits today)
Posted in file shell script | Tagged Finder Keynote Numbers Pages | 2 Comments

iWork Apps Update v10.0

Posted on 4月 1, 2020 by Takaaki Naganoya

Keynote、Pages、Numbersのv10.0が配信されました。Keynoteの前バージョンはv9.2、Pagesはv8.2、Numbersはv6.2.1でしたが、バージョン番号を別々に採番することがめんどくさくなったのか、内部のエンジンが一新されたのか、バージョン番号をそろえてきました。

おそらく、マーケティング的な要請やユーザーサポートの手間を省くために番号をそろえてきたのでしょう。

Pages/NumbersについてはmacOS 10.14以上が対象。KeynoteはmacOS 10.15.4が必要とのことですが、いろいろ致命的なバグの修正を含んでいるため、後日macOS 10.14.6向けのKeynoteアップデートが配信されることを期待したいところです。

# アップデートに出てこないだけで、Mac App Storeから個別にKeynote v10.0のダウンロードが（macOS 10.14.6上でも）できました。なんででしょう？

v10.0 UpdateのAppleScript的な変更の有無

■Keynote v10.0：２か所

■Pages v10.0：１か所

■Numbers v10.0：変更点なし
Numbers v6.2で「特定の行数の表を作るとエラーになる」というバグがありましたが、これはv6.2.1で修正されました。これが修正されています（記憶違いだったので、記事を修正しておきます）。

Pages v10.0の変更点

documentにfacing pagesというプロパティが新設されました。見開き表示時にページの左右（奇数ページ、偶数ページ）を考慮して２ページ表示のペアを変更するという機能のようです。

AppleScript名：Pages v10.0で追加されたfacing pagesの操作を行う
tell application "Pages"
　　tell front document
　　　　set curStat to facing pages
　　　　
　　　　set facing pages to not curStat –反転
　　　　delay 2
　　　　set facing pages to curStat –元に戻す
　　end tell
end tell

★Click Here to Open This Script　

全言語的に普遍的な内容ではあるのですが、日本語ユーザー的には縦書き/横書きの設定属性値を持ってくれたほうがありがたいところです。たぶん、自分は使うことはないと思います。

Keynote v10.0の変更点

Keynoteは前バージョンでかなりおかしなバグが発覚していたので、その修正が行われているかどうか、というのが見所です。

結論からいえば、バグは修正されています。macOSに関して久しぶりに前向きなニュースといえます。彼らにバグを修正する意思と能力が残されていたことについては喜びたいところです。同時に残念なニュースとして、この修正に関連して新たなバグが生まれています（このあたりがいかにもAppleらしい）。

Keynoteバグ１：表（table）作成時に行数によってはエラーになる

５行の表を作るとエラーになり、他の行数でもいろいろエラーになる組み合わせが確認されていました。テスト用のAppleScriptを書いて、行数を2〜100行で変更しつつ作成、列数を2〜30列で変更しつつ作成、行数および列数を順次ループで2〜20まで変更しつつ新規作成するなどのテストを実施。無事、修正を確認できました。

ただし、本テストは表の新規作成についてのみ確認したものであり、既存の表の行数/列数の変更を確認したものではありません。Appleの仕事に関しては、修正点の周囲に新たなバグを生む可能性が高く、修正時と修正後が一番危険な状態です。彼らに「自分の作った機能を動作確認する」という能力を期待してはいけません。信じてもいけません。つねに、疑いの目で見ることが重要です。

AppleScript名：Keynote書類上に表を作成、行数を2から100まで可変
tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　repeat with i from 2 to 100
　　　　　　　　set aTable to make new table with properties {header column count:0, header row count:0, row count:i, column count:3}
　　　　　　　　delay 1
　　　　　　　　delete aTable
　　　　　　end repeat
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　
AppleScript名：Keynote書類上に表を作成、列数を2から30まで可変
tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　repeat with i from 2 to 30
　　　　　　　　set aTable to make new table with properties {header column count:0, header row count:0, row count:5, column count:i}
　　　　　　　　delay 1
　　　　　　　　delete aTable
　　　　　　end repeat
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　
AppleScript名：Keynote書類上に表を作成、行数および列数を2から20まで可変
tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　repeat with x from 2 to 20
　　　　　　　　repeat with y from 2 to 20
　　　　　　　　　　set aTable to make new table with properties {header column count:0, header row count:0, row count:y, column count:x}
　　　　　　　　　　delay 0.01
　　　　　　　　　　delete aTable
　　　　　　　　end repeat
　　　　　　end repeat
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

Keynoteバグ２：書類（document）のムービーexport optionsにバグ

数値ではじまる予約語や記号を含む予約語はAppleScriptの言語処理系では宣言できません。エラーになります。それをAppleの（おそらくKeynoteの）担当者がKeynote v7.1のアップデート時に、従来の「small」「midium」「large」といったEnumによる指定から、「360p」「540p」「720p」「1080p」「2160p」という指定を行えるように変更を加えました。

より大きな解像度の書き出しに対処したことは評価できると思いますが、そもそもAppleScriptの処理系で認識できない「数字で始まる予約語」に変えたのはダメダメです（スクリプトエディタ上で構文確認を行うとエラーになる＝使えない）。つまり、この担当者はsdefの改変を行なっただけで、実際にコードを書いて動作確認を行っていないことがわかります。

Appleにバグレポートを書きつつ、このような処理が必要な場合にはnative sizeで書き出して、そのあとでムービーをリサイズするような処理で回避していました（GUI Scriptingで乗り切ったScripterもいるようですが）。

Keynote v10.0では「format360p」「format540p」「format720p」「format1080p」「format2160p」と変更され、AppleScriptの構文確認時にエラーでハネられることはなくなりました。この点についてはバグ修正が行われたものと判断してよいと思われます。

ただし、従来動作していたEnum「native size」を指定するとエラーになるようになってしまいました。互換性のために残したが動作していない、といったコメントが書かれているわけでもないため、これはバグだと判断します。

■Keynote書類フォーマットとムービー書き出し時の解像度の対応表（Piyomaru Software独自調査による）

movie export formats 標準（4:3） ワイド（16:9）
format360p 480 × 360 640 × 360
format540p 720 × 540 960 × 540
format720p 960 × 720 1280 × 720
format1080p 1440 × 1080 1920 × 1080
format2160p 2880 × 2160 3840 × 2160
AppleScript名：Keynote 360p movie export test
set targetFileHFSPath to (choose file name) as string –かならずファイル拡張子に「.m4v」を指定する必要がある
if targetFileHFSPath does not end with ".m4v" then
　　set targetFileHFSPath to targetFileHFSPath & ".m4v"
end if

with timeout of 3600 seconds
　　tell application "Keynote"
　　　　export front document to file targetFileHFSPath as QuickTime movie with properties {movie format:format360p}
　　end tell
end timeout

★Click Here to Open This Script　
AppleScript名：Keynote 540p movie export test
set targetFileHFSPath to (choose file name) as string –かならずファイル拡張子に「.m4v」を指定する必要がある
if targetFileHFSPath does not end with ".m4v" then
　　set targetFileHFSPath to targetFileHFSPath & ".m4v"
end if

with timeout of 3600 seconds
　　tell application "Keynote"
　　　　export front document to file targetFileHFSPath as QuickTime movie with properties {movie format:format540p}
　　end tell
end timeout

★Click Here to Open This Script　
AppleScript名：Keynote 720p movie export test
set targetFileHFSPath to (choose file name) as string –かならずファイル拡張子に「.m4v」を指定する必要がある
if targetFileHFSPath does not end with ".m4v" then
　　set targetFileHFSPath to targetFileHFSPath & ".m4v"
end if

with timeout of 3600 seconds
　　tell application "Keynote"
　　　　export front document to file targetFileHFSPath as QuickTime movie with properties {movie format:format720p}
　　end tell
end timeout

★Click Here to Open This Script　
AppleScript名：Keynote 1080p movie export test
set targetFileHFSPath to (choose file name) as string –かならずファイル拡張子に「.m4v」を指定する必要がある
if targetFileHFSPath does not end with ".m4v" then
　　set targetFileHFSPath to targetFileHFSPath & ".m4v"
end if

with timeout of 3600 seconds
　　tell application "Keynote"
　　　　export front document to file targetFileHFSPath as QuickTime movie with properties {movie format:format1080p}
　　end tell
end timeout

★Click Here to Open This Script　
AppleScript名：Keynote 2160p movie export test
set targetFileHFSPath to (choose file name) as string –かならずファイル拡張子に「.m4v」を指定する必要がある
if targetFileHFSPath does not end with ".m4v" then
　　set targetFileHFSPath to targetFileHFSPath & ".m4v"
end if

with timeout of 3600 seconds
　　tell application "Keynote"
　　　　export front document to file targetFileHFSPath as QuickTime movie with properties {movie format:format2160p}
　　end tell
end timeout

★Click Here to Open This Script　
AppleScript名：Keynote ‌‌native size movie export test (Bug)
set targetFileHFSPath to (choose file name) as string –かならずファイル拡張子に「.m4v」を指定する必要がある
if targetFileHFSPath does not end with ".m4v" then
　　set targetFileHFSPath to targetFileHFSPath & ".m4v"
end if

with timeout of 3600 seconds
　　tell application "Keynote"
　　　　–export front document to file targetFileHFSPath as QuickTime movie with properties {movie format:‌‌native size}
　　end tell
end timeout

★Click Here to Open This Script　
(Visited 67 times, 1 visits today)
Posted in Bug news | Tagged 10.14savvy 10.15savvy Keynote Numbers Pages | 1 Comment

Numbersで書類Aのすべてのシートの表1を、書類Bの現在のシートの表１にまとめる

Posted on 1月 21, 2020 by Takaaki Naganoya

Numbersでオープン中の複数の書類があったときに、書類Aのすべてのシートの表１を、書類Bの現在のシートの表１にまとめるAppleScriptです。

さすがに、機械的な作業すぎて手で行う気にはなれなかったので、ありもののScriptを利用して作ってみました。

こういう用途のために作っておいたライブラリ「choose multiple list」を利用しています。


▲データ取得元


▲データ集約先


▲ダイアログで「データ取得元」と「データ集約先」を選択

BridgePlus内蔵のFrameworkがmacOS 10.14/10.15に邪魔されて認識されない環境では動かせないかもしれません。このあたり、SIP解除するしかないと思わせるものがあります。

ライブラリで複雑な選択を行えるUI部品を作っておいたおかげで、これだけ込み入った動作を行うAppleScriptを書きましたが、Cocoaの機能はほぼ使っていません（getDataFromNumbersDocは作り置きしておいた、頻出ルーチンなので使いまわしています）。choose multiple listライブラリは、こういう用途のために作っておいたものであり、まさにそのぴったりな用途であったといえるでしょう。

AppleScript名：書類Aのすべてのシートの表1を、書類Bの現在のシートの表１にまとめる.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/20
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use scripting additions
use bPlus : script "BridgePlus"
use mulList : script "choose multiple list"

script spd
　　property allData : {}
end script

set (allData of spd) to {}

set {aName, bName} to getTargetDocNames() of me

–「データ取得元」のNumbers書類のすべてのシートの表１から2D Listでデータ取得
tell application "Numbers"
　　tell document aName
　　　　set sList to name of every sheet
　　　　repeat with i in sList
　　　　　　set tmp2DDat to getDataFromNumbersDoc(aName, i) of me
　　　　　　set (allData of spd) to (allData of spd) & tmp2DDat
　　　　end repeat
　　end tell
end tell

set aHeight to length of (allData of spd)
set aWidth to length of item 1 of (allData of spd)

–「データ集約先」のNumbers書類の現在のシートの表１にまとめた2D Listを展開する（巨大すぎると時間がかかるので、CSV書き出ししてオープンするなどの別の方法を採るべき）
tell application "Numbers"
　　tell document bName
　　　　tell active sheet
　　　　　　set tRes to make new table with properties {row count:aHeight + 1, column count:aWidth}
　　　　end tell
　　end tell
end tell

fillCurrentTable(bName, (allData of spd)) of me

–Numbersの書類の現在のシートを、指定の２次元配列でfillする
on fillCurrentTable(docName, aList)
　　set aLen to length of aList
　　set aWidth to length of first item of aList
　　
　　tell application "Numbers"
　　　　tell document docName
　　　　　　tell active sheet
　　　　　　　　tell table 1
　　　　　　　　　　repeat with i from 1 to aLen
　　　　　　　　　　　　tell row (i + 1)
　　　　　　　　　　　　　　set aRowList to contents of item i of aList
　　　　　　　　　　　　　　repeat with ii from 1 to aWidth
　　　　　　　　　　　　　　　　tell cell ii
　　　　　　　　　　　　　　　　　　set aTmpData to contents of item ii of aRowList
　　　　　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　　　　　set value to aTmpData
　　　　　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　　　end repeat
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
end fillCurrentTable

–Numbersでオープン中の書類の名称一覧からデータ取得元とデータ集約先の書類名をダイアログで選択
on getTargetDocNames()
　　tell application "Numbers"
　　　　set nList to name of every document
　　end tell
　　
　　set selList to {nList, nList}
　　set tList to {"データ取得元", "データ集約先"}
　　
　　set {aRes, bRes} to choose multiple list selList main message "各Numbers書類の役割を選択してください" sub message "「データ取得元」のデータを順次、「データ集約先」の表1に連結します" with title lists tList height 140 width 400 return type item contents without allow same items
　　return {aRes, bRes}
end getTargetDocNames

–Numbersでオープン中の書類の選択中のシートの表1からデータを取得して2D Listに
on getDataFromNumbersDoc(aDocName, sheetName)
　　
　　load framework
　　
　　tell application "Numbers"
　　　　if (count (every document)) = 0 then return false
　　　　
　　　　tell document aDocName
　　　　　　if (count (every sheet)) = 0 then return false
　　　　　　
　　　　　　tell sheet sheetName
　　　　　　　　tell table 1
　　　　　　　　　　set colCount to column count
　　　　　　　　　　set rowCount to row count
　　　　　　　　　　set headerCount to header row count
　　　　　　　　　　set footerCount to footer row count
　　　　　　　　　　
　　　　　　　　　　set dList to value of every cell of cell range
　　　　　　　　end tell
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
　　
　　–Convert 1D List to 2D List
　　set bList to (current application’s SMSForder’s subarraysFrom:dList groupedBy:colCount |error|:(missing value)) as list
　　set sItem to 1 + headerCount
　　set eItem to rowCount – footerCount
　　set cList to items sItem thru eItem of bList
　　
　　return cList
　　
end getDataFromNumbersDoc

★Click Here to Open This Script　
(Visited 238 times, 3 visits today)
Posted in dialog GUI list | Tagged 10.13savvy 10.14savvy 10.15savvy Numbers | Leave a comment

Numbersでオープン中の最前面の書類のすべてのシートの表1の行数合計を計算する

Posted on 1月 15, 2020 by Takaaki Naganoya

Numbersでオープン中の最前面の書類のすべてのシートの表1の行数の合計を計算するAppleScriptです。

Blogアーカイブ本作成のために書いたものです。

この記事数をカウントするために使いました。

AppleScript名：Numbersでオープン中の最前面の書類のすべてのシートの表1の行数合計を計算する
set aCount to 0

tell application "Numbers"
　　tell front document
　　　　set sList to every sheet
　　　　repeat with i in sList
　　　　　　tell i
　　　　　　　　try
　　　　　　　　　　set tmpC to count every row of table 1
　　　　　　　　　　set aCount to aCount + tmpC
　　　　　　　　end try
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

return aCount

★Click Here to Open This Script　
(Visited 115 times, 1 visits today)
Posted in Number | Tagged 10.13savvy 10.14savvy 10.15savvy Numbers | Leave a comment

Post navigation

  • Older posts

電子書籍（PDF）をオンラインストアで販売中！

Google Search

Popular posts

  • AppleScriptによるWebブラウザ自動操縦ガイド
  • Xcode 13.2 〜 13.3は有害（正式版でもまだ有害）
  • 2021年に書いた価値あるAppleScript
  • Intel MacとApple Silicon Macの速度差〜画像処理
  • ドラッグ＆ドロップ機能の未来？
  • macOS 12.x上のAppleScriptのトラブルまとめ
  • CotEditorで選択範囲の行頭にある数字をリナンバーする v1
  • マウスの右クリックメニューをカスタマイズするService Station
  • macOS 12.3 beta 5、ASの障害が解消される（？）
  • 不可視プロセスで表示したNSAlertを最前面に表示
  • 与えられた自然言語テキストから言語を推測して、指定の性別で、TTSキャラクタを自動選択して読み上げ
  • SF Symbolsを名称で指定してPNG画像化
  • macOS 12.3 beta4、まだ直らないASまわりの障害
  • Microsoftが新OutlookにAppleScript機能を追加表明
  • SkimのAppleScriptサポート機能にバグ
  • 新刊発売：AppleScriptによるWebブラウザ自動操縦ガイド
  • SafariでブックマークされたURL一覧を取得
  • PFiddlesoft UI Browserが製品終了に
  • 人類史上初、魔導書の観点から書かれたAppleScript入門書「７つの宝珠」シリーズ開始？！
  • macOS 12.3上でFinder上で選択中のファイルをそのままオープンできない件

Tags

10.11savvy (1102) 10.12savvy (1243) 10.13savvy (1391) 10.14savvy (586) 10.15savvy (433) 11.0savvy (272) 12.0savvy (156) CotEditor (54) Finder (46) iTunes (19) Keynote (92) NSAlert (60) NSArray (51) NSBezierPath (18) NSBitmapImageRep (21) NSBundle (20) NSButton (34) NSColor (51) NSDictionary (27) NSFileManager (23) NSFont (18) NSImage (42) NSJSONSerialization (21) NSMutableArray (61) NSMutableDictionary (21) NSPredicate (36) NSRunningApplication (56) NSScreen (30) NSScrollView (22) NSString (117) NSURL (97) NSURLRequest (23) NSUTF8StringEncoding (30) NSUUID (18) NSView (33) NSWorkspace (20) Numbers (54) Pages (34) Safari (40) Script Editor (19) WKUserContentController (21) WKUserScript (20) WKUserScriptInjectionTimeAtDocumentEnd (18) WKWebView (22) WKWebViewConfiguration (22)

カテゴリー

  • 2D Bin Packing
  • AirDrop
  • AirPlay
  • Animation
  • AppleScript Application on Xcode
  • beta
  • Bluetooth
  • Books
  • boolean
  • bounds
  • Bug
  • Calendar
  • call by reference
  • Clipboard
  • Code Sign
  • Color
  • Custom Class
  • dialog
  • drive
  • exif
  • file
  • File path
  • filter
  • folder
  • Font
  • Font
  • GAME
  • geolocation
  • GUI
  • GUI Scripting
  • History
  • How To
  • iCloud
  • Icon
  • Image
  • Input Method
  • Internet
  • iOS App
  • JavaScript
  • JSON
  • JXA
  • Keychain
  • Keychain
  • Language
  • Library
  • list
  • Locale
  • Machine Learning
  • Map
  • Markdown
  • Menu
  • Metadata
  • MIDI
  • MIME
  • Natural Language Processing
  • Network
  • news
  • Noification
  • Notarization
  • Number
  • Object control
  • OCR
  • OSA
  • PDF
  • Peripheral
  • PRODUCTS
  • QR Code
  • Raw AppleEvent Code
  • Record
  • recursive call
  • regexp
  • Release
  • Remote Control
  • Require Control-Command-R to run
  • REST API
  • Review
  • RTF
  • Sandbox
  • Screen Saver
  • Script Libraries
  • sdef
  • search
  • Security
  • selection
  • shell script
  • Shortcuts Workflow
  • Sort
  • Sound
  • Spellchecker
  • Spotlight
  • SVG
  • System
  • Tag
  • Telephony
  • Text
  • Text to Speech
  • timezone
  • Tools
  • Update
  • URL
  • UTI
  • Web Contents Control
  • WiFi
  • XML
  • XML-RPC
  • イベント（Event）
  • 未分類

アーカイブ

  • 2022年9月
  • 2022年8月
  • 2022年7月
  • 2022年6月
  • 2022年5月
  • 2022年4月
  • 2022年3月
  • 2022年2月
  • 2022年1月
  • 2021年12月
  • 2021年11月
  • 2021年10月
  • 2021年9月
  • 2021年8月
  • 2021年7月
  • 2021年6月
  • 2021年5月
  • 2021年4月
  • 2021年3月
  • 2021年2月
  • 2021年1月
  • 2020年12月
  • 2020年11月
  • 2020年10月
  • 2020年9月
  • 2020年8月
  • 2020年7月
  • 2020年6月
  • 2020年5月
  • 2020年4月
  • 2020年3月
  • 2020年2月
  • 2020年1月
  • 2019年12月
  • 2019年11月
  • 2019年10月
  • 2019年9月
  • 2019年8月
  • 2019年7月
  • 2019年6月
  • 2019年5月
  • 2019年4月
  • 2019年3月
  • 2019年2月
  • 2019年1月
  • 2018年12月
  • 2018年11月
  • 2018年10月
  • 2018年9月
  • 2018年8月
  • 2018年7月
  • 2018年6月
  • 2018年5月
  • 2018年4月
  • 2018年3月
  • 2018年2月

https://piyomarusoft.booth.pm/items/301502

メタ情報

  • 登録
  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org

Forum Posts

  • 人気のトピック
  • 返信がないトピック

メタ情報

  • 登録
  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org
Proudly powered by WordPress
Theme: Flint by Star Verte LLC