macOS 27.0, Golden Gate #2

Posted on 6月 26 by Takaaki Naganoya

macOS 27, Golden Gateのベータ版（Beta 2）を利用していますが、従来のβよりもマシといえど、やはりβ版であることを感じさせます。

標準搭載アプリのバージョンが割といいかげん

各アプリのバージョン表記でおかしいところがあります。「ヒント（Hints）」はバージョン27.0がおそらく正しい番号ですが、1.0が割り当てられています。

メッセージ（Messages）もバージョン26.0が割り振られていますが、（何も意図がなければ）27.0が正しい番号でしょう。バージョン番号を見て判定するような処理には不安があります。

	macOS 15.5	macOS 26.0	macOS 27.0
Finder	16	16	27
System Events	1.3.6	1.3.6	1.3.6
連絡先（Contacts）	14	14	14
Safari	18	19	27
Photos	10	11	12
Reminders	7	7	7
Notes	4.12.6	4	4
Messages	14	14	26
Mail	16	16	16
Music	1.5.5	2	2
Maps	3	3	3
Preview	11	11	11
TextEdit	1	1	1
Calendar	15	16	27
TV	1.5.5	2	2
QuickTime Player	10	10	10
Automator	2	2	2
Terminal	2	2	2
Console	1	1	1
Instruments	16	26	27
ScriptEditor	2.11	2.11	2.11
System Information	11	11	11
VoiceOver Utility	10	10	10
Shortcuts	7	7	10
Screen Sharing	5	6	7
ヒント（Hints）	16	26	1

standard additionの用語を使う際に注意

Cocoa Script（use framework “Foundation”あるいは”Cocoa”を含むAppleScript）において、コンパイル（構文確認）時に、standard additionsの予約語を含む場合にエラーになるケースが増えました。

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

★Click Here to Open This Script　

これだとエラーになります。「using terms from scripting additions」〜「end using terms from」で囲う必要が出てくるケースに遭遇しました。

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　using terms from scripting additions
　　　　　　try
　　　　　　　　set the target_file to the target_file as text
　　　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　　　close access the open_target_file
　　　　　　　　return true
　　　　　　on error error_message
　　　　　　　　try
　　　　　　　　　　close access file target_file
　　　　　　　　end try
　　　　　　　　return error_message
　　　　　　end try
　　　　end using terms from
　　end tell
end writeToFileAsUTF8

★Click Here to Open This Script　

macOS 27, Golden Gate

Posted on 6月 9 by Takaaki Naganoya

US Appleによる開発者向けイベントWWDC 26において、macOS 27, Golden Gateが発表されました。

前バージョン（macOS 26）で導入され、いまひとつ人気を得ていなかった「Liquid Glass」から、前々バージョンの「macOS 15」のデザインに差し戻したような印象を受けます。

macOS 26から過剰な装飾を削ぎ落としたようなデザインに変更。さらに、各種バグについて解消を図るほか、Siri AIの機能強化が行われたと発表されています。

珍しくUser系のBeta Program「Apple Seed」にもBeta 1が回ってきた（例年、Beta 1はDeveloper Betaにしか回ってこない）ので、さっそくMacBook Air M2にmacOS 27 Beta 1をインストールしたところ、まだ全体的にバグはあるものの、Beta 1としてはかなり評価できる印象です（常用はつらそう）。

不評だったmacOS 26を「なかったこと」にしつつ、悪かった点は改め、よい点は伸ばすというのがmacOS 27の位置付けのようです。ティム体制下ではこれまでになかった動きであり、これまでの「中身のない、株価対策のためだけのバージョンアップ」よりも評価できる動きです。

AppleScriptの仕様を調べてみるとバージョン2.8で変更はありません。スクリプトエディタにも変更はないようです。特筆すべき点として、このところ毎度毎度Beta初期段階で動作しないまま出てきていた「スクリプトメニュー」が、このBeta 1から動作していて驚かされました。

その他、Beta初期段階で何度も発生していた「aliasをPOSIX pathにcastするとおかしな表記のパスが返ってくる」という恥ずかしいバグも、このBeta 1では見られていません（それでも油断できない）。

バグ修正については、「Cocoa-AppleScript Applet」がまともに動いているように見えます。簡単な（ダイアログを表示する程度の）アプレットを作成し、アプレットとして保存。アプレットを実行すると、問題なくダイアログ表示されました。ただ、このアプレットを通常終了することができなかったので、その点は問題といえるでしょう。

Xcode上でAppleScriptで作成したDocument Basedなアプリが起動しなかったり（Kamenoko）、まだ初期段階だから発生しているのか、それとも他の問題によるものなのか不明な問題も確認しています。

ワークスペース切り替えv2.1

Posted on 5月 6 by Takaaki Naganoya

macOSのSpaces（仮想デスクトップ機能）で、任意のワークスペースに切り替えを行うAppleScriptです。

–> Download changeSpace_v2.1.scptd（with spaces_tool in its bundle）

Spaces系の機能はAPIが公開されておらず、Private APIを叩きまくることになります。現在定義されているSpacesの名称一覧の取得（list）、現在表示中のSpacesの名称（current）についてはこの方法で情報を取得できています。

肝心のSpaces間の切り替えについては、GUI Scripting経由でキーコード（Control 1、Control 2など）を送出することで行なっています。これらのキーボードショートカットが有効になっていないと切り替え自体が行えません（このあたりの機能がOS内部で十分にサポートされていないため、このような行き当たりばったりの実装になってしまいます）。

そのため、本AppleScriptを実行するプログラム……スクリプトエディタ上で実行するのであればスクリプトエディタに、Script Menuで実行するのであればScript MenuにGUI Scriptingの実行権限（アクセシビリティ）を許可しておく必要があります。また、同様の理由からGUI Scripting呼び出し権限を取得できないAppleScriptの実行プログラムからはSpacesの切り替え操作を行えません。

以下のAppleScriptは内蔵ツールを呼び出すだけのものであり、これだけでは実行できません。上記リンクからバンドルスクリプト自体をダウンロードして、実行してください。

＃　もしかしたら、space_toolは各クライアント上でビルドし直さないとダメかもしれないので、実行時にビルド＋実行する形態に書き換えるかもしれません

AppleScript名：ワークスペース切り替えv2.1.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/05/05
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aPath to path to resource "space-tool"
set pPath to POSIX path of aPath

delay 0.5 –超重要。スクリプトエディタ上で実行するには必須

— ① 一覧取得
set allSpaces to do shell script (quoted form of pPath) & " list"
(*
"Desktop_1
Desktop_2"
*)

— ② 現在選択されているSpaces名称を取得
set currentSpace to do shell script (quoted form of pPath) & " current"
–> "Desktop_1"

— ③ 切り替え（例：Desktop_2へ）
my switchToSpace(2)

on switchToSpace(spaceNumber)
　　— 数字キーのキーコードマップ (1=18, 2=19, 3=20, 4=21, 5=23, 6=22, 7=26, 8=28, 9=25)
　　set keyCodes to {18, 19, 20, 21, 23, 22, 26, 28, 25}
　　set theCode to item spaceNumber of keyCodes
　　
　　tell application "System Events"
　　　　key code theCode using {control down}
　　end tell
end switchToSpace

★Click Here to Open This Script　

Safariの最前面のウィンドウで表示されているAmazon.co.jpの製品ページへの最短リンクを取得

Posted on 3月 30 by Takaaki Naganoya

Safariの最前面のウィンドウで表示中のamazon.co.jpの製品ページへの最短リンクを取得して、クリップボードに入れるAppleScriptです。動作確認はmacOS 26.4＋Safari 26.4で確認しています。添付のアプレットはScript Menuに入れて呼び出しています。

–> Download Enhanced Applet with Framework

Amazon.co.jpの製品URLをWebブラウザのURL欄からコピー＆ペーストで取得しようとしても、不要な情報が大量に付加されているため、Blogなどに投稿するのにけっこう苦労します。

そこで、実際に対象の製品ページへのリンクが可能な最短のURL（短縮URLではなく）を作成してクリップボードに入れます。

HTMLの解析については、いつものHTMLReader Framework（https://github.com/nolanw/HTMLReader）を利用しています。そのため、Script DebuggerからExportしたEnhanced Appletとして動作するように想定しています。

正直なところ、やり方はいくつもありますし、プログラム内容もやっつけで書いているので見るに堪えない部分はあるのですが、実際に動作する日常的なScriptなんてこんなもんだろうかと。

本Scriptは、日本のAmazon（amazon.co.jp）のURLを対象に処理していますが、他国のAmazon用に書き換えるのもとくに難しくはありません。

Google Chromeなど他のWebブラウザ用に改変するのもとくに難しくないので、試してみるといいのではないでしょうか。

AppleScript名：最前面に表示中のAmazonのページから製品リンクURLを抽出する_v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/01
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader
use scripting additions

property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property HTMLDocument : a reference to current application’s HTMLDocument
property NSMutableArray : a reference to current application’s NSMutableArray

–URL Check
set uRes to retURLFromActiveSafariTab() of me
if uRes does not start with "https://www.amazon.co.jp" then return –change each location’s Amazon URL

set aURL to getProductURLFromAmazon() of me
if aURL = "" then return

set bURL to current application’s |NSURL|’s URLWithString:aURL
set aList to bURL’s pathComponents()
aList’s removeObjectAtIndex:1 –2番目のアイテムを削除

set bList to aList as list
set bLen to length of bList
if bLen is not equal to 3 then return

if contents of item 1 of bList is not equal to "/" then return
if contents of item 2 of bList is not equal to "dp" then return

set aScheme to bURL’s |scheme|() as string
set aHost to bURL’s |host|() as string

set resURL to aScheme & "://" & aHost & "/" & (contents of item 2 of bList) & "/" & (contents of item 3 of bList)

set the clipboard to resURL
beep 1

on getProductURLFromAmazon()
　　–Get HTML Source
　　set hRes to retHTMLSourceFromActiveSafariTab() of me
　　
　　
　　set aHTML to current application’s HTMLDocument’s documentWithString:(hRes as string)
　　set linkList to (aHTML’s nodesMatchingSelector:"link")
　　
　　log linkList
　　
　　repeat with i in (linkList as list)
　　　　set j to contents of i
　　　　
　　　　set aProp to (j’s attributes’s valueForKeyPath:("rel")) as string
　　　　
　　　　if aProp = "canonical" then
　　　　　　set resURL to (j’s attributes’s valueForKeyPath:("href"))
　　　　　　return resURL as string
　　　　end if
　　　　
　　end repeat
　　
　　return ""
end getProductURLFromAmazon

on retHTMLSourceFromActiveSafariTab()
　　tell application "Safari"
　　　　if running then
　　　　　　if (every document) = {} then return false
　　　　　　tell front document
　　　　　　　　set htmlRes to source
　　　　　　end tell
　　　　else
　　　　　　return false
　　　　end if
　　end tell
　　
　　set aStr to current application’s NSString’s stringWithString:htmlRes
　　set aNFC to (aStr’s precomposedStringWithCanonicalMapping()) as text –Normalize Text
　　return aNFC
end retHTMLSourceFromActiveSafariTab

on retURLFromActiveSafariTab()
　　tell application "Safari"
　　　　if running then
　　　　　　if (every document) = {} then return missing value
　　　　　　tell front document
　　　　　　　　set htmlRes to URL
　　　　　　end tell
　　　　else
　　　　　　return missing value
　　　　end if
　　end tell
end retURLFromActiveSafariTab

★Click Here to Open This Script　

翻訳テスト

Posted on 3月 25 by Takaaki Naganoya

翻訳対象の文と、翻訳先の言語コード（2文字コード）を指定すると、macOS内のサービスを呼び出して翻訳して返します。

翻訳を司るTranslation.frameworkはAppleScriptObjCから呼び出せないため、Swiftを介して呼び出してみました。

実際に、AppleScriptObjCから呼び出すことも試みてみたのですが、結局できず……逆に、この手の処理はAppleScriptから呼び出せると有用性が高いもののはずなので、呼び出せないことに納得が行かず、いろんな方法を試行。

実行処理を考えると、AppleScriptバンドル書類内にSwiftからビルドした実行バイナリを入れて呼び出す方が速くてよいのですが、実行環境の多さを考慮してテキスト形式のSwiftを組み込むようにしてみました。

AppleScript名：翻訳テスト_v5.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/25
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

set targetLang to "ja"
set textList to {"Stay hungry, stay foolish.", "Innovation distinguishes between a leader and a follower."}
set sRes to translateList(targetLang, textList) of me
–>
(*
"飢え続け、愚かであり続けてください。
イノベーションはリーダーとフォロワーを区別します。"
*)

on translateList(targetLang, textList)
　　— 引数の組み立て
　　set argString to targetLang
　　repeat with aText in textList
　　　　set argString to argString & " " & (quoted form of aText)
　　end repeat
　　
　　— Swiftソースコード
　　— 実行速度と安定性を考慮し、RunLoopを使用して非同期完了を待機します
　　set shellCmd to "swift – " & argString & " <<’EOF’
import Foundation
import Translation
import NaturalLanguage

let args = CommandLine.arguments
guard args.count >= 3 else { exit(1) }

let targetLanguage = args[1]
let textsToTranslate = Array(args.dropFirst(2))

let recognizer = NLLanguageRecognizer()
recognizer.processString(textsToTranslate.joined(separator: ＼" ＼"))
guard let identifiedLanguage = recognizer.dominantLanguage?.rawValue else { exit(1) }

let source = Locale.Language(identifier: identifiedLanguage)
let target = Locale.Language(identifier: targetLanguage)

// 翻訳実行フラグ
var isFinished = false

Task {
let session = TranslationSession(installedSource: source, target: target)
do {
let requests = textsToTranslate.map { TranslationSession.Request(sourceText: $0) }
let response = try await session.translations(from: requests)
for result in response {
print(result.targetText)
}
} catch {
fputs(＼"Error: ＼＼(error.localizedDescription)＼＼n＼", stderr)
}
isFinished = true
}

// 非同期処理が完了するまでRunLoopを回して待機する
while !isFinished {
RunLoop.main.run(until: Date(timeIntervalSinceNow: 0.1))
}
EOF"
　　
　　try
　　　　— do shell script は標準出力が返るまで待機します
　　　　set translatedResults to do shell script shellCmd
　　　　return translatedResults
　　on error errMsg
　　　　error "翻訳エラー" & return & errMsg
　　end try
end translateList

★Click Here to Open This Script　

AppleScript名：翻訳言語コードを取得.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/25
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

set langList to returnLangCodes() of me
–> {"ar", "de", "en", "es", "fr", "hi", "id", "it", "ja", "ko", "nl", "pl", "pt", "ru", "th", "tr", "uk", "vi", "zh"}

on returnLangCodes()
　　set shellCmd to "swift – <<’EOF’
import Foundation
import Translation

Task {
let availability = LanguageAvailability()
let supportedLanguages = await availability.supportedLanguages

// languageCode（ja, enなど）のみを抽出し、重複を除いてソート
let codes = Set(supportedLanguages.compactMap { $0.languageCode?.identifier }).sorted()

for code in codes {
print(code)
}
exit(0)
}

RunLoop.main.run(until: Date(timeIntervalSinceNow: 5))
EOF"
　　
　　try
　　　　— 言語コードを改行区切りで取得
　　　　set supportedCodes to do shell script shellCmd
　　　　
　　　　— リスト形式に変換
　　　　set oldDelims to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to string id 13
　　　　set codeList to text items of supportedCodes
　　　　set AppleScript’s text item delimiters to oldDelims
　　　　
　　　　— 結果を表示
　　　　if (count of codeList) > 0 then
　　　　　　return codeList
　　　　else
　　　　　　error "言語コードが見つかりませんでした。"
　　　　end if
　　　　
　　　　set the clipboard to (codeList as string)
　　on error errMsg
　　　　error "取得エラー" & return & errMsg
　　end try
end returnLangCodes

★Click Here to Open This Script　

Finder上で選択中のHEIC画像から位置情報を削除_v5

Posted on 3月 17 by Takaaki Naganoya

Finder上で選択中のHEIC画像から位置情報（緯度、経度）を削除するAppleScriptです。

JEPGのようにEXIF情報を編集するのとはHEIC画像の構造が異なるため、方法については試行錯誤の最中です。いろいろ試してみたところ、HEICの解析を行なっても仕様を追いきれなかったので、メモリ上にHEIC画像を読み込んで、HEIC画像でファイルに書き出し直しています。

また、画像の回転状態を元画像から取得して、自動回転させ、元画像と回転状態を維持しています。

NSImageにHEIC画像を読み込んでファイル書き込みするという方法でも、問題なく処理できることでしょう。

AppleScript名：Finder上で選択中のHEIC画像から位置情報を削除_v5.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/16
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

on run
　　tell application "Finder"
　　　　set targetFilesList to selection as alias list
　　end tell
　　
　　if targetFilesList is {} then
　　　　display alert "エラー" message "FinderでHEICファイルを選択してください。"
　　　　return
　　end if
　　
　　set successfulReconstructions to 0
　　
　　repeat with currentFile in targetFilesList
　　　　set posixPathString to POSIX path of currentFile
　　　　
　　　　if (posixPathString ends with ".heic") or (posixPathString ends with ".HEIC") then
　　　　　　set isProcessed to my redrawImageMaintainingOrientation(posixPathString)
　　　　　　if isProcessed then
　　　　　　　　set successfulReconstructions to successfulReconstructions + 1
　　　　　　end if
　　　　end if
　　end repeat
　　
　　display notification (successfulReconstructions as string) & " 個のファイルの位置情報を削除しました。" with title "位置情報抹消完了"
end run

on redrawImageMaintainingOrientation(posixPath)
　　— Swiftプログラム
　　— 1. 画像データ(CGImage)と回転情報のみを抽出
　　— 2. 新しい画像として書き出し、回転情報を再設定
　　— 3. GPS情報は一切含めない
　　set swiftSource to "
import Foundation
import ImageIO
import CoreGraphics

let path = ＼"" & posixPath & "＼"
let url = URL(fileURLWithPath: path)

guard let source = CGImageSourceCreateWithURL(url as CFURL, nil),
let type = CGImageSourceGetType(source) else { exit(1) }

let count = CGImageSourceGetCount(source)
// 元のファイルに新規作成（上書き）としてDestinationを準備
guard let destination = CGImageDestinationCreateWithURL(url as CFURL, type, count, nil) else { exit(1) }

for i in 0..<count {
// 1. 画像データのみを抽出
if let cgImage = CGImageSourceCreateImageAtIndex(source, i, nil) {

// 2. 新しいプロパティを作成（空の辞書）
let freshProperties = NSMutableDictionary()

// 3. 元のメタデータから「回転情報」だけを取得して引き継ぐ
if let oldProps = CGImageSourceCopyPropertiesAtIndex(source, i, nil) as? [String: Any] {
// 回転情報 (kCGImagePropertyOrientation)
if let orientation = oldProps[kCGImagePropertyOrientation as String] {
freshProperties[kCGImagePropertyOrientation as String] = orientation
}

// カラープロファイル (ColorModel) も維持しないと色が変わるため引き継ぐ
if let colorModel = oldProps[kCGImagePropertyColorModel as String] {
freshProperties[kCGImagePropertyColorModel as String] = colorModel
}
}

// 4. 回転情報は維持し、GPSを含まないプロパティで画像を書き込む
CGImageDestinationAddImage(destination, cgImage, freshProperties as CFDictionary)
}
}

if CGImageDestinationFinalize(destination) {
exit(0)
} else {
exit(1)
}
"
　　try
　　　　do shell script "swift -e " & quoted form of swiftSource
　　　　return true
　　on error
　　　　return false
　　end try
end redrawImageMaintainingOrientation

★Click Here to Open This Script　

住所ジオコーダー2026年最新版

Posted on 3月 16 by Takaaki Naganoya

AppleScriptから住所ジオコーダー/逆住所ジオコーダーの機能にアクセスして日常的に利用していますが、セキュリティ機能の強化によって旧来の機能にアクセスできなくなりつつあります。

住所ジオコーダー系の機能については、さまざまな方法でアクセスできるようにしてきましたが、どうやらmacOS 27あたりでさらにセキュリティ縛りがきつくなることが想定されます。

さまざまな方法を検討した結果、

・SwiftでCLIツールを作ってAppleScriptバンドル内に入れてdo shell scriptコマンドで呼び出す

これは実際にNFCタグの操作Scriptを作った際に試した方法です。問題はないのですが、これだと実行できないAppleScriptの実行環境もあるので、なるべく1つのAppleScript内で完結したいところです。

・AppleScript内に文字列でSwiftのプログラムを記述し、do shell scriptコマンド経由で「swift」（/usr/bin/swift）を呼び出して実行させる

今回はこれを採用してみました。AppleScript実行プログラム側のセキュリティ設定次第ですが、環境を選ばずに実行できるはずです。なお、Script Debugger上では動作しません。

AppleScript名：住所から緯度、経度を返す（Swift版）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/16
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

set myAddress to "東京都新宿区西新宿２丁目８−１"

set gRes to my geocode(myAddress)
set {aLat, Along} to parseByDelim(gRes, "|") of me
–> {"35.6894863", "139.6917052"}

on geocode(addressString)
　　set swiftSource to "
import CoreLocation
import Foundation

let address = ＼"$TARGET$＼"
let geocoder = CLGeocoder()
var completed = false
var resultString = ＼"Error: Timeout or Access Denied＼"

geocoder.geocodeAddressString(address) { placemarks, error in
if let loc = placemarks?.first?.location {
resultString = ＼"＼＼(loc.coordinate.latitude)|＼＼(loc.coordinate.longitude)＼"
} else {
resultString = ＼"Error: ＼＼(error?.localizedDescription ?? ＼"Unknown＼")＼"
}
completed = true
}

// 5秒間、結果を待機しながらランループを回す
let timeout = Date(timeIntervalSinceNow: 5.0)
while !completed && Date() < timeout {
RunLoop.current.run(mode: .default, before: Date(timeIntervalSinceNow: 0.00001))
}

print(resultString)
"
　　return my runSwift(swiftSource, addressString)
end geocode

on runSwift(source, targetValue)
　　set finalCode to my replaceText("$TARGET$", targetValue, source)
　　try
　　　　— ヒアドキュメントで実行
　　　　return do shell script "swift – <<’EOF’" & return & finalCode & return & "EOF"
　　on error errMsg
　　　　return "実行エラー: " & errMsg
　　end try
end runSwift

on replaceText(s, r, t)
　　set AppleScript’s text item delimiters to s
　　set textItems to every text item of t
　　set AppleScript’s text item delimiters to r
　　set res to textItems as string
　　set AppleScript’s text item delimiters to ""
　　return res
end replaceText

on parseByDelim(aData, aDelim)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set dList to text items of aData
　　set AppleScript’s text item delimiters to curDelim
　　return dList
end parseByDelim

★Click Here to Open This Script　

AppleScript名：緯度経度から住所を返す（Swift版）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/16
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

— サンプル座標（東京都庁付近）
set myCoords to "35.6894863|139.6917052"
set gRes to my reverseGeocode(myCoords)
–> "東京都新宿区東京都庁"

———————————————————
— ハンドラ: 緯度|経度 -> 住所
———————————————————
on reverseGeocode(latLonString)
　　set swiftSource to "
import CoreLocation
import Foundation

let input = ＼"$TARGET$＼"
let parts = input.components(separatedBy: ＼"|＼")

guard parts.count == 2,
let lat = Double(parts[0].trimmingCharacters(in: .whitespaces)),
let lon = Double(parts[1].trimmingCharacters(in: .whitespaces))
else {
print(＼"Error: Invalid input format＼")
exit(1)
}

let location = CLLocation(latitude: lat, longitude: lon)
let geocoder = CLGeocoder()
var completed = false
var resultString = ＼"Error: Timeout or No Data＼"

geocoder.reverseGeocodeLocation(location) { placemarks, error in
if let p = placemarks?.first {
// 都道府県 + 市区町村 + 地番・ビル名などを結合
let addr = ＼"＼＼(p.administrativeArea ?? ＼"＼")＼＼(p.locality ?? ＼"＼")＼＼(p.name ?? ＼"＼")＼"
resultString = addr
} else {
resultString = ＼"Error: ＼＼(error?.localizedDescription ?? ＼"Unknown＼")＼"
}
completed = true
}

// 5秒間、結果が返るまでランループを回す
let timeout = Date(timeIntervalSinceNow: 5.0)
while !completed && Date() < timeout {
RunLoop.current.run(mode: .default, before: Date(timeIntervalSinceNow: 0.00001))
}

print(resultString)
"
　　return my runSwift(swiftSource, latLonString)
end reverseGeocode

———————————————————
— Swift実行サブシステム
———————————————————
on runSwift(source, targetValue)
　　set finalCode to my replaceText("$TARGET$", targetValue, source)
　　try
　　　　— ファイルを作らず標準入力から実行
　　　　return do shell script "swift – <<’EOF’" & return & finalCode & return & "EOF"
　　on error errMsg
　　　　return "Error: " & errMsg
　　end try
end runSwift

on replaceText(s, r, t)
　　set AppleScript’s text item delimiters to s
　　set textItems to every text item of t
　　set AppleScript’s text item delimiters to r
　　set res to textItems as string
　　set AppleScript’s text item delimiters to ""
　　return res
end replaceText

★Click Here to Open This Script　

NFCタグリーダー/ライターの情報＋タグ情報を取得

Posted on 3月 9 by Takaaki Naganoya

MacにUSB経由で接続したNFCタグリーダー/ライターの情報、およびそのリーダーに接触しているNFCタグの情報を取得するAppleScriptです（Apple Silicon Mac用、Intelバイナリはなし）。

▲音楽CD型のNFCタグ（おもちゃ）　Apple Musicの配信先URLを記録しておくと、iPhoneにタッチするとApple Musicがオープンする仕組み

NFC関連の情報を取得するmacOS内のフレームワークは、CryptoTokenKitです。

最初は、これをAppleScriptObjCから直接呼び出すことを試みていたのですが、呼び出してオブジェクトを生成した段階でつまづいたので、ASOC経由で直接機能を呼び出すことには早々に見切りをつけました（↓できてもよさそうなのに）。

AppleScript名：NFCカードリーダーの存在確認_v1.scpt

use AppleScript version "2.8"
use scripting additions
use framework "Foundation"
use framework "CryptoTokenKit"

— リーダーの接続確認（ダメ！）
set cardManager to current application’s TKSmartCardSlotManager’s defaultManager()
if cardManager = missing value then
　　display alert "リーダーが見つかりません。接続を確認してください。"
　　return
end if

set allSlots to cardManager’s slotNames()

if (count of allSlots) > 0 then
　　display notification "リーダーを認識しました: " & (item 1 of allSlots) with title "NFC Ready"
else
　　display alert "リーダーが見つかりません。接続を確認してください。"
end if

★Click Here to Open This Script　

このため、CryptoTokenKitフレームワークの機能を呼び出す部分はSwiftで記述したコマンドライン・ツールを用意し、AppleScriptバンドル内に格納してdo shell scriptコマンド経由で呼び出すことにしてみました。

Xcodeプロジェクト化してSwiftのプログラムを直接呼び出す方式でもよかったのですが、確実に呼び出せることを重視して前述の方式に。

–> Download Script Bundle within nfc_reader_writer cli tool

NFCタグリーダー/ライターを操作

日本市場で実績があって入手しやすいNFCリーダー/ライターはソニーのRC-S300一択という状況なので、ほぼ決め打ちでこの機種を想定してもよいのですが、海外市場がどんな状況になっているのかはわかりません。

本プログラムではMacに接続されているNFCリーダー/ライターの製品名（readerName）、NFCタグがスキャン範囲内にあるか？（tagReady）、NFCタグリーダー/ライターが書き込み可能かどうか（canWrite）、NFCタグの属性データ（atr）を取得できます。

–> {{readerName:”SONY FeliCa Port/PaSoRi 4.0″, tagReady:true, atr:”3B8F8001804F0CA0000003060300030000000068″, canWrite:true}}

NFCタグリーダー/ライターが複数接続されている場合にも対処するようになっていますが、複数台のリーダーで動作確認は行なっていません。

かるくUSのAmazonでNFCリーダー/ライターを検索してみたところ、ほぼ同様の仕組みのデバイスが流通していることを確認しました。

現在までにできていること

一応、NFCタグリーダー/ライターの存在確認（本プログラム）、NFCタグへのデータ書き込み（URLだけで確認）、NFCタグからのデータ読み込み……と、ひととおり、Swift＋AppleScriptの組み合わせで実現できています。

ただ、どう考えても全MacユーザーがNFCタグリーダー/ライターを購入して利用する姿は想像しにくいため（MacにNFCリーダー/ライターが標準搭載される未来はたぶん来ない。キーボードやマウスだと可能性はゼロではないかも）、iPhoneを併用して、これでNFCタグを読み込んだり、データ書き込みする利用スタイルを想定しています。つまり、iPhoneでNFCタグを読み取ると、Macに通知が飛んでMac側でAppleScriptによって処理を行う流れになります（そんなに難しくないので、ほぼ実現できる）。

iPhone上でショートカット.appを用いてNFCタグの読み込みに応じて実行されるアクションを作成し、iCloud Drive経由でテキストデータを書き込み。Mac側でFolder Actionを用いて内容を読み取る……という流れを想定しています（ただし、自分が使っているのがiPhone 7なのでまだ実現していません……このアクションにはiPhone X以降が必要とのこと）。

このため、読み込みについてはiPhoneでスキャン→Macで実行というスタイルを考えています。書き込みについてはMac側で、ということになるでしょう（iPhone側でもできるようですが、運用上ちょっと混乱しそうなので）。

つまり、本プログラムを核としたテストプログラムのほとんどは「無駄」になってしまいそうなところです。技術的な調査がひととおり行えた、という意味では意義はあるのかもしれません。難しくなさそうなのに、セキュリティでがんじがらめなのでちょっと残念さを感じます。

AppleScript名：reader_list_v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/03/09
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

set rRes to getNFCReaderList() of me
— {{readerName:"SONY FeliCa Port/PaSoRi 4.0", tagReady:true, atr:"3B8F8001804F0CA0000003060300030000000068", canWrite:true}}

on getNFCReaderList()
　　set mePath to POSIX path of (path to me)
　　set listTool to quoted form of (mePath & "Contents/Resources/nfc_list")
　　
　　— plist文字列を取得
　　set xmlData to do shell script listTool
　　
　　— Property List Dataとしてパース
　　tell application "System Events"
　　　　set plistItems to make new property list item with data xmlData
　　　　set readerList to value of plistItems
　　end tell
　　
　　set outList to {}
　　
　　— 取得したリストをパース
　　repeat with aReader in readerList
　　　　— plistのキーに基づき値を取得
　　　　set rName to |name| of aReader
　　　　set rStatus to status of aReader
　　　　set rAtr to atr of aReader
　　　　set rCanWrite to can_write of aReader
　　　　
　　　　if rStatus is "present" then
　　　　　　set tmpRec to {readerName:rName, tagReady:true, atr:rAtr, canWrite:rCanWrite}
　　　　else
　　　　　　set tmpRec to {readerName:rName, tagReady:false, atr:rAtr, canWrite:rCanWrite}
　　　　end if
　　　　set the end of outList to tmpRec
　　end repeat
　　
　　— 呼び出し元の想定に合わせて、最初のリーダーのレコードを返します
　　if (count of outList) > 0 then
　　　　return outList
　　else
　　　　return {readerName:"", tagReady:false, atr:"", canWrite:false}
　　end if
end getNFCReaderList

★Click Here to Open This Script　

CotEditor v6.2.3でfolder documentが追加されるが……

Posted on 2月 25 by Takaaki Naganoya

CotEditor v6.2.3がリリースされ、AppleScript用語辞書に「folder document」クラスが追加されました。

AppleScript用語辞書では6箇所の変更点が検出されるのですが、folder document以外はすべて説明文の内容変更です。

folder documentは、CotEditorがフォルダごとオープンして、フォルダ階層自体をオープンして個別のファイルをいちいちオープンしなくても編集できるようにしたもの、のようです。

ただ、このfolder documentの操作を試みても、一切操作できません。

AppleScript名：folder documentをカウントする（できない）.scpt

tell application "CotEditor"
　　set dCount to count every document
　　set fdCount to count every folder document
　　–> error "CotEditorでエラーが起きました: every folder documentを取り出すことはできません。" number -1728 from every folder document
end tell

★Click Here to Open This Script　

カウントできないし、current documentも取得できないし、できないことづくしです。

AppleScript名：folder documentからcurrent documentを取得.scpt

tell application "CotEditor"
　　tell front folder document
　　　　set cDoc to current document
　　end tell
end tell

★Click Here to Open This Script　

たぶん、これについては何もチェックも行われていないものなのでしょう。

フォルダ階層ごと書類にできるというべきなのか、windowの下に複数のdocumentがぶら下がっているというものなのか……試行錯誤の最中のようなので、まだこのfolder documentに手を出すべきではないのでしょう。

フォルダごと扱ってprojectっぽい扱いをしたいとか、markdownエディタ的な挙動を行いたいのか、といった理解はしてみますが、画像のビューワーも実装されている割にはrtfのプレビューもできません。

音量計測テスト v3

Posted on 2月 25 by Takaaki Naganoya

Macの本体搭載マイクから音声入力を行い、音量を計測するAppleScriptです。0.1秒間隔で10秒ほど音量を計測してリストに出力します。

音量計測は割と事前の知識が必要なディープな処理で、システム側で想定されている最大音量を0dbとして、その値からの相対値で結果が出力されます。本Scriptでプラスの値が出ていたら、それは手を叩いたり騒音を出したりと瞬間的に大きな音（実際に録音したものを聞くと、おそらく音割れしている）が入力された場合です。

計測値はマイナスの値で出力されるため、一般的なスマホ上で動く騒音計アプリが出力する正の値（db）とくらべ違和感があります。

このマイナスの値が出てくると実用性を感じません。

ただ、これをプラスの値として出すためには、何らかの値（基準値）を足す必要があり、これは実際に無響室でMacの実機を持ち込んで基準となる音量を出しつつ計測するしかないでしょう。

機種ごと、同一機種でも製造年ごとに使用されているマイクの特性も異なるでしょうし、経年変化でマイクの穴にホコリが詰まって音量の「感度」が変化してしまうことでしょう。

無響室にかたっぱしから稼働中のマシンを叩き込んで計測するわけにもいかないので、同一機種の同一モデルで環境音もしくはスピーカーから出した音をマイク計測することで「聞こえ方」の変化の平均値を求めて経年変化などを実測していくしかないのでしょう。

なんといったらよいのか、ひたすらめんどくさいです。とりあえず、現状ではこのままです。

AppleScript名：音量計測テスト v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/02/25
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use framework "AVFoundation"
use scripting additions

property recorder : missing value

— 定数の直接定義（結局、ASの数値の桁数が足りなくて直接書いている。ここに残していることにメモ以上の意味はない）
property kAudioFormatAppleLossless : "1634492771" as integer — ’alac’
property AVAudioQualityMax : 127

–db値が入る
script vS
　　property vList : {}
end script

on run
　　setupRecorder() of me
　　if recorder is missing value then return
　　
　　
　　— 10秒間、0.1秒おきに音量を取得
　　repeat 100 times
　　　　set tmpV to my getVolumeLevel()
　　　　set the end of (vList of vS) to tmpV
　　　　delay 0.1
　　end repeat
　　
　　recorder’s |stop|()
　　
　　return (vList of vS)
　　–> {-47.89, -22.7, -26.29, -30.39, -34.0, -37.11, -39.87, -42.53, -43.21, -39.55, -34.34, -37.54, -27.52, -31.54, -34.65, -36.6, -38.25, -39.7, -41.37, -42.49, -43.89, -38.54, -33.26, -36.65, -39.36, -38.74, -34.47, -37.4, -39.25, -33.12, -36.15, -39.61, -42.5, -35.92, -35.52, -35.85, -38.02, -39.5, -34.86, -39.01, -41.89, -39.15, -37.5, -40.11, -38.1, -35.4, -33.35, -33.85, -35.76, -33.14, -35.21, -35.7, -35.41, -36.55, -33.9, -35.97, -38.45, -36.65, -38.02, -34.14, -35.98, -32.51, -34.71, -37.47, -37.34, -41.38, -39.31, -36.95, -37.92, -34.59, -37.82, -40.41, -43.67, -43.61, -40.3, -34.22, -35.49, -39.51, -43.57, -46.11, -42.36, -41.3, -45.14, -44.23, -38.4, -41.63, -34.71, -37.4, -40.76, -36.16, -39.49, -36.28, -38.27, -39.19, -39.04, -38.36, -39.51, -41.33, -39.5, -42.18, -48.23, -23.73, -27.04, -30.32, -33.36, -36.33, -36.51, -34.89, -38.28, -38.68, -40.08, -41.9, -34.01, -36.47, -32.51, -33.97, -36.79, -34.06, -35.58, -33.09, -36.67, -40.52, -40.13, -37.82, -41.57, -29.71, -32.41, -35.6, -37.91, -34.2, -37.36, -38.87, -38.14, -37.83, -39.65, -33.56, -34.82, -37.31, -35.34, -37.54, -40.05, -42.1, -40.33, -42.72, -45.63, -47.98, -46.96, -45.58, -39.56, -42.37, -44.01, -46.82, -46.01, -41.52, -33.35, -35.45, -34.2, -38.14, -31.96, -35.11, -38.16, -28.24, -32.52, -36.5, -39.57, -41.86, -41.61, -41.71, -43.3, -46.6, -49.13, -51.6, -50.43, -52.44, -37.73, -38.41, -40.31, -32.89, -33.74, -36.4, -40.21, -44.22, -33.76, -36.73, -39.96, -37.03, -37.05, -40.48, -37.44, -40.84, -44.45, -47.59, -32.53, -35.72, -37.82, -39.66, -37.11, -39.43, -37.51, -39.47}
end run

on setupRecorder()
　　try
　　　　set tempDir to current application’s NSTemporaryDirectory()
　　　　set filePath to (tempDir as text) & "vol_monitor.caf"
　　　　set fileURL to current application’s |NSURL|’s fileURLWithPath:filePath
　　　　
　　　　set labelList to {current application’s AVFormatIDKey, current application’s AVSampleRateKey, current application’s AVNumberOfChannelsKey, current application’s AVEncoderAudioQualityKey}
　　　　
　　　　set valueList to {"1634492771" as integer, "44100.0" as real, 1, 127}
　　　　
　　　　set recordSettings to current application’s NSDictionary’s dictionaryWithObjects:valueList forKeys:labelList
　　　　
　　　　set {theRecorder, theError} to current application’s AVAudioRecorder’s alloc()’s initWithURL:fileURL settings:recordSettings |error|:(reference)
　　　　
　　　　if theRecorder is missing value then
　　　　　　error (theError’s localizedDescription() as text)
　　　　end if
　　　　
　　　　set my recorder to theRecorder
　　　　
　　　　recorder’s setMeteringEnabled:true
　　　　recorder’s |prepareToRecord|()
　　　　
　　　　— マイク入力の開始
　　　　set success to recorder’s |record|()
　　　　
　　　　if not success then
　　　　　　display alert "エラー" message "録音の開始に失敗しました。"
　　　　end if
　　　　
　　on error errMsg
　　　　display alert "Setup Error" message errMsg
　　end try
end setupRecorder

on getVolumeLevel()
　　if recorder is missing value then return -160
　　
　　recorder’s updateMeters()
　　
　　— 平均音量(dB)を実数として取得
　　set dbLevel to recorder’s averagePowerForChannel:0
　　
　　— 小数点以下2桁に丸めて文字列として返す
　　set roundedDb to (round (dbLevel * 100)) / 100
　　
　　return (roundedDb)
end getVolumeLevel

★Click Here to Open This Script　

macOS 26.3リリース〜AppleScript関連のバグ修正状況は？

Posted on 2月 13 by Takaaki Naganoya

本日リリースされたmacOS 26.3におけるAppleScript関連の既知のバグの修正状況をまとめてみました。

■Finderのempty trashで発生するエラー
→ 修正されています。

■System Events/Screen Saver preferencesのバグ
→ 修正されていません（継続発生中）

■Xcode 26.x上でAppleScriptObjCプロジェクトにAppleScript（.scpt）を組み込んで、ASオブジェクト（dateなど）をパラメータにして呼び出した場合のバグ
→ 修正されていません。

Pagesの現在＋6ページ分しかページ上のオブジェクトにアクセスできないバグが修正される

Posted on 2月 6 by Takaaki Naganoya

Pages v15.1ことPages Creator Studio v15.1において、従来のPages v14.x系のAppleScript系のバグが修正されていました。

AppleScriptの処理系のバグではなく、Pages側のバグで、タイトルにも書いていますが、

「現在のページ＋6ページ上しかページ上のオブジェクトにアクセスできない」

というものです。この、「現在のページ」をAppleScript側から変更できればよいのですが、Pagesではそれはできません（強引にメニュー操作しなければ）。よって、ページ移動をメニュー操作で行いながら、操作対象のページに移動するという処理しかできていませんでした。

Pages Creator Studio v15.1＋macOS 26.3β上では、問題なく6ページを超える範囲のページ上のオブジェクトにアクセスできているように見えます。propertiesを取得して、カウントして、内容を書き換えるテストをパスしています。

ただ、こうして検証用のAppleScriptを見直してみると、汎用オブジェクトへのアクセスを行う「iWork item」という用語（必須。ないと困る）が、「Creator Studio」という名前と合っていないような気がしないでもありません。

意味的には「general purpose item」とかいうあたりが正しいんでしょうけど、「creator studio item」とかいうんでしょうか。

–> Sample Pages Doc

AppleScript名：ページ上のアイテムへのアクセス上限チェック（バグ解消チェック）.scpt

tell application "Pages Creator Studio"
　　tell front document
　　　　set pCount to count every page
　　　　
　　　　count every iWork item of every page
　　　　
　　end tell
end tell

★Click Here to Open This Script　

AppleScript名：ページ上のアイテムへのアクセス上限チェック（バグ解消チェック2）.scpt

tell application "Pages Creator Studio"
　　tell front document
　　　　set pCount to count every page
　　　　
　　　　repeat with i from 1 to pCount
　　　　　　tell page i
　　　　　　　　set tList to every table
　　　　　　　　
　　　　　　　　if length of tList > 0 then
　　　　　　　　　　set aTable to first item of tList
　　　　　　　　　　
　　　　　　　　　　–表のセル内容を書き換え
　　　　　　　　　　tell aTable
　　　　　　　　　　　　set aProp to properties –とくに意味なし
　　　　　　　　　　　　
　　　　　　　　　　　　set cCount to count every row
　　　　　　　　　　　　repeat with ii from 1 to cCount
　　　　　　　　　　　　　　tell row ii
　　　　　　　　　　　　　　　　tell cell 1
　　　　　　　　　　　　　　　　　　set value to "9"
　　　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　end repeat
　　　　　　　　　　end tell
　　　　　　　　　　
　　　　　　　　end if
　　　　　　　　
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

★Click Here to Open This Script　

ignoring時の超高速化にともなう処理内容の信頼性低下のその後 part 2

Posted on 2月 4 by Takaaki Naganoya

Numbersの選択中の範囲のセルに対して連続値で数値書き込みするAppleScriptにおいて、非同期実行モードでも勝手に処理を打ち切る、という不具合の改修がNumbers Creator Studio v15.1＋macOS 26.3betaで行われていることを確認しました。

その話の補足です。

自分のテスト環境（MacBook Air M2 16GB）において、10万セル（10000行x10列）選択してselection rangeを取得する処理を行なったところ、

のように、エラー-1741のエラーになりました。これが、

（1）selection/selection rangeというコマンド自体の仕様限界
（2）Numbersがselectionを取得する際の限界

なのかは不明ですが、10万セルだと無理であることを確認しました。

結局、エラーが出ない範囲を探ってみたところ「7万310」セルの選択取得とシーケンシャル値で埋める処理は実行できました。7万320セルだとエラーになります。

アプリの内部処理的に問題がある場合にはエラーを返してくれたほうがよいので、これはこの動作で問題ないと考えます。アプリ側の処理的に上限はあるということでよいでしょう。

ignoring時の超高速化にともなう処理内容の信頼性低下のその後

Posted on 2月 4 by Takaaki Naganoya

重要な内容なのですが、話が入り組んでいるので、順に説明します。

AppleScriptの非同期実行モード

AppleScriptでアプリケーションを操作する場合には、コマンド発行、アプリ側の処理待ち、処理結果を返す、という動作が行われます。いわゆる同期実行で行われます。

一方で、処理内容の結果はいらないからコマンド実行だけ高速に行わせてくれという「非同期実行」モードもAppleScriptの登場初期から用意されており、これがignoring application responses〜end ignoring節です。

shell scriptやCocoa呼び出しでは意味がありませんが、macOS上のGUIアプリを操作する場合には、非同期実行で行えばおおよそ半分以下の処理時間で済みます。

非同期実行モードは、書類上に大量のオブジェクトを作成するような操作を行うときに便利で、事前に何度も確認を行なっておいて、まあ多分大丈夫でしょう、という確信が持てた場合に、処理速度向上のために部分的に導入しています。

処理結果を取得したいとか、確実に終了したことを確認したい場合には使用できませんが、それでも導入できる「部分もある」のです。

Numbers v14.x＋macOS 15.xの組み合わせで起こる　問題現象

この非同期実行が、Numbers v14.xとmacOS 15.xの組み合わせで実行したときに問題現象を起こしています。

電子書籍「AppleScript最新リファレンス v2.8対応」でも詳しく言及しているのですが、この環境で非同期実行を行うと、腰が抜けるほど高速な反面、処理が完結しない（勝手に途中で処理を打ち切ってしまう）という問題動作が見られました。

つまり、処理速度を重視してignoringで非同期実行すると、勝手に途中で処理が打ち切られます。Numbers上で5万個のセルを選択して、非同期実行モードで連続値で埋めるというAppleScriptを実行すると、2〜3万セルぐらいで処理が中断されます（macOS 15.7.4＋Numbers 14.5で28880セルで打ち切り）。

知っていて使う分には「1万セルずつ処理しようか？」という話にはなるのですが、知らずに処理して「セルが埋まっていなかった」だとダメージが大きすぎです。

非同期実行モードの処理速度が異様に速くなっていたので、「どうせ何か副作用があるんだろう」と思って検証してみたら、予想通りこのトンでもない欠陥が見つかったというわけです（Appleのエンジニアにありがち）。詳細にバグレポートし、動向を見守ることにしました。

Numbers Creator Studio v15.1で修正

このNumbersのヤバい動作が新たな「Numbers Creator Studio」（v15.1）でどうなっているのか、macOS 26.3β環境で確認してみたところ、なんと修正されていました。うれしい誤算です。

Screenshot

5万セル選択してテストAppleScriptを実行すると、5万セルがきちんと連続値で埋められていました。

処理時間は以前よりもかかるようになったのですが、それでも「勝手に放り出さなくなった」というのは大いに評価できます。

これが、10万セルだとどうなのかとか、macOS 15.7.4＋Numbers Creator Studio v15.1の組み合わせで問題はないのかとか、少々気になるところではありますが、その点は未検証であるということを明記しておきます。興味がある方はお試しください。

Keynote->Keynote Creator Studio（以下同様）

Posted on 1月 29 by Takaaki Naganoya

Keynote v14.5、Pages v14.5、Numbers v14.5がリリースされました。これらは従来のiWork Appsの最終バージョンと位置付けられています。

これからは、Keynote/Pages/Numbersは「Keynote Creator Studio」「Pages Creator Studio」「Numbers Creator Studio」に改称されました。Finder上で表示されている名前は従来どおり「Keynote」ですが、実際の名前は「Keynote Creator Studio」です。

バージョンは3つとも統一で「15.1」です（2026年1月29日現在）。

BUndle IDも変更されており、

Keynote：com.apple.iWork.Keynote
Keynote Creator Studio：com.apple.Keynote

となっています。Pages Creator Studioもcom.apple.Pages、Numbers Creator Studioもcom.apple.Numbersに変更されています。

このため、Keynote用のAppleScriptをKeynote Creator Studio用に使用する際には、tell applicationの名前を書き換える必要があります。iTunes–>Musicの時のように自動で書き換えられたりはしないはずです。両方がインストールされている状態ではそうなりますが、Keynote Creator Studioだけがインストールされている環境では違っているのかも（ダイアログで「どのアプリケーションか？」と聞かれて自動で書き換えられるかも）。

AppleScript用語辞書的に、従来のiWork Appsから変更された点はありません。

AppleScript名：Keynote Creator Studio.scpt

tell application "Keynote Creator Studio"
　　properties
　　–> {frozen:true, class:application, playing:false, version:"15.1", slide switcher visible:false, name:"Keynote", frontmost:false}
end tell

★Click Here to Open This Script　

AppleScript名：Pages Creator Studio.scpt

tell application "Pages Creator Studio"
　　properties
　　–> {frontmost:false, class:application, name:"Pages", version:"15.1"}
end tell

★Click Here to Open This Script　

AppleScript名：Numbers Creator Studio.scpt

tell application "Numbers Creator Studio"
　　properties
　　–> {frontmost:false, class:application, name:"Numbers", version:"15.1"}
end tell

★Click Here to Open This Script　

既刊の電子書籍については、アイコンや画面キャプチャなどの差し替えを行う感じでしょうか。前述のとおりAppleScript用語辞書の内容は変更されていないため、プログラム内容については修正の必要は（tell applicationの対象名以外は）ありません。

iWork AppsのKeynote/Pages/Numbersを、Creator Studio版のアプリが入った状態で起動すると、古いバージョンを削除してもいいよと表示されます。新しいバージョンを使うことを推奨しているようです。

とくに新バージョンに不安はないのですが（画面のデザインは思いっきり違和感ありまくりですが）、これまでの経験上、まだ従来バージョン（バグはあっても少なくともおかしな挙動はしない）を残しておくべきだと感じます。なにせ、相手があのAppleなので。

→ 書き換えが面倒だったので、iWork Appsのほうを削除してみました。iWork Apps用のAppleScript書類をオープンすると、Apple Creator Studio用に自動でtellブロックが書き換えられました。

Apple Creator Studioに含まれるKeynote/Pages/Numbersは新バージョン？

Posted on 1月 14 by Takaaki Naganoya

Final Cut Pro、Pixelmator Pro、Logic Pro、Motion、Compressor、MainStage、Keynote、Pages、Numbers、フリーボードをサブスク（月額1,780円　年17,800円）で利用できる「Apple Creator Studio」が発表されました。映像・音楽系の作業を中心に行なっているユーザーには、よくできたスイーツです。

Adobe Creative Cloudと比べて、映像系はまあまあ、音楽系は優勢、画像系はちょっと落ちる（CMYKサポートがないので）、ページデザインについては冗談みたいな雰囲気です（Adobe InDesignとPagesを比較するなんて、恐れ多くて話題にもならない）。

既存のKeynote/Pages/Numbersについてもそのまま提供されるとのことですが、アイコンが明確に異なっているので現行の14.4のアップデート版である15.xが提供されるということでしょうか（現時点では何も明確な情報はありません。）。

Apple Creator Studioに含まれるKeynote/Pages/Numbersについては、「プレミアムコンテンツ」（テンプレートや素材？）、Apple Intelligenceを活用するAI機能（いつもの作文ツールとか。実体はほぼない）が追加利用できることが明記されています。

これまでにも、「特定のセル数の表が作れない」といったオリジナリティあふれるバグを山のように作られましたが、これからはもっと画期的なバグを作ってくれるのでしょうか？　ワクワクと震えが止まりません。

macOS 26.3beta2が登場。System Eventsのバグ直らず

Posted on 1月 13 by Takaaki Naganoya

macOS 26.3beta2が登場しました。さっそくインストールしましたが、System Eventsのバグは修正されていません。

26.3（1月末一般公開？）でこのバグが修正されるかどうかは、ちょっとわかりません。

AppleScript名：System Events経由でscreen saver infoを取得.scpt

tell application "System Events"
　　set sPref to (screen saver preferences)
　　set aRunF to running of sPref
　　–> false
　　
　　set sClockF to show clock of sPref
　　–> false (macOS 15.7.4)
　　–> error "System Eventsでエラーが起きました: AppleEventのハンドラで誤りが起きました。" number -10000 (macOS 26.3)
　　
　　set mScreenF to main screen only of sPref
　　–> false (macOS 15.7.4)
　　–> error "System Eventsでエラーが起きました: AppleEventのハンドラで誤りが起きました。" number -10000 (macOS 26.3)
　　
　　set aClass to class of sPref
　　–> screen saver preferences object(macOS 15.7.4)
　　–> screen saver preferences object(macOS 26.3)
　　
　　set dIntvl to delay interval of sPref
　　–> 0 (macOS 15.7.4)
　　–> error "System Eventsでエラーが起きました: AppleEventのハンドラで誤りが起きました。" number -10000 (macOS 26.3)
　　
end tell

★Click Here to Open This Script　

関数計算ライブラリで一部のユーザーから再現しない問題が報告される件

Posted on 1月 9 by Takaaki Naganoya

関数演算ライブラリ「calcLibAS」は、自分がフリー配布しているAppleScript用の関数演算ライブラリです。JavaScriptCore経由で関数を呼び出すという、ひじょうにシンプルな原理で動作しています。

このcalcLibASを呼び出した一部のユーザーから「演算を行うとエラーになる」といった報告が行われており、不思議に思っておりました。

　　「こんなにシンプルなのに、どうやったらエラーになるのか？」

いろいろ調べてみたら、発生源が見えてきたような気がします。

小数点にカンマを利用している言語（国）がある

通常、こうした広域にバラまくライブラリを作ったら、日本語環境と英語環境で動作検証します。macOSの開発時のデフォルトの言語は英語なので、英語環境で動作確認を行うのは普通です。

小数点を含む数値を表記するのに、小数点を「.」（ピリオド）で表記するのが日本語のルールですし、英語（米国）でもそうです。

ところが、いろいろ調べてみたら、小数点を「,」（カンマ）で表記する言語があるとかで……実際にプログラムを組んで、macOSがサポートしているlocaleごとに数値フォーマットを調べ、SVGベースの世界地図にプロットしてみました。

＃　この世界地図を塗り分けしてダイアログ表示する処理はけっこう汎用性がありそうなので、ライブラリとして提供することを検討しています。ライブラリというよりは、display worldmap scriptingみたいな、不可視プロセスの補助アプリになりそうですが

→ 「display world map」の実行に、HTMLReader.frameworkを使わなくても大丈夫なように変更しました。同ライブラリの実行にScript Debugerはもう必要ありません。

国単位でみると、小数点＝ピリオドで表記するところは少数派で（でも、人口ベースで見ると少なくなさそう）、とくにヨーロッパ圏で英国以外がみんな「,」を使用しているのは衝撃でした。

ヨーロッパ系の数値表記をしている国で、小数点以下を含む数値を文字列で渡してきたらどうなる？

他の関数演算ライブラリを見たときに、パラメータをas realではなくas {integer, real}でcastしている様子が目に止まりました。

これは処理としてはおかしいのですが、どうもこの小数点以下を含む数値が、しかも文字列で指定された場合には、こういう予防措置を講じておくと、誤った演算を行わないのかもしれません。

ただ、演算内容自体はおかしくなるはず（小数点以下を含んだ数値を、文字列で渡すと小数点以下が無視される？）です。

仕方がないので、関数演算ライブラリ側でパラメータとして数値でも文字列でも受け取るようにしておいて、数値文字列を受け取った場合には、ヨーロッパ系の数値表現（小数点をカンマで記述する）を、米英風の小数点をピリオドで記述する表現に変換する処理を通すのがいいんでしょう（ChatGPTに書かせたので、自分のプログラムとはテイストが違うものの、こんな●●な処理にテイストも●●もないでしょう）。

世界は、まだ広かった……。

AppleScript名：locNumFormatCalc_v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/01/08 (Modified: 2026/01/09)
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSLocale : a reference to current application’s NSLocale
property NSNumberFormatter : a reference to current application’s NSNumberFormatter
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor

set nRes to getLocaleNumFormat() of me
–> {{|color|:"Red", cc:"001"}, {|color|:"Red", cc:"003"}, {|color|:"Blue", cc:"150"}, {|color|:"Blue", cc:"419"}, {|color|:"Red", cc:"AD"}, {|color|:"Blue", cc:"AE"}, {|color|:"Yellow", cc:"AF"}, {|color|:"Blue", cc:"AG"}, {|color|:"Blue", cc:"AI"}, {|color|:"Red", cc:"AL"}, {|color|:"Red", cc:"AM"}, {|color|:"Red", cc:"AO"}, {|color|:"Red", cc:"AR"}, {|color|:"Blue", cc:"AS"}, {|color|:"Red", cc:"AT"}, {|color|:"Blue", cc:"AU"}…}

on getLocaleNumFormat()
　　— 1. データの収集
　　set allId to NSLocale’s availableLocaleIdentifiers()
　　set countryDataList to {} — 最終的な国別データ（レコードのリスト）
　　
　　repeat with ident in allId
　　　　set aLocale to (NSLocale’s alloc()’s initWithLocaleIdentifier:ident)
　　　　set countryCode to (aLocale’s objectForKey:(current application’s NSLocaleCountryCode)) as string
　　　　
　　　　if countryCode is not "missing value" and countryCode is not "" then
　　　　　　set formatter to NSNumberFormatter’s alloc()’s init()
　　　　　　(formatter’s setLocale:aLocale)
　　　　　　set decimalSeparator to formatter’s decimalSeparator() as string
　　　　　　
　　　　　　— 色の判定
　　　　　　set col to "Yellow"
　　　　　　if decimalSeparator is "." then
　　　　　　　　set col to "Blue"
　　　　　　else if decimalSeparator is "," then
　　　　　　　　set col to "Red"
　　　　　　end if
　　　　　　
　　　　　　— 既存データの上書きロジック
　　　　　　set foundIndex to -1
　　　　　　repeat with i from 1 to count of countryDataList
　　　　　　　　if cc of item i of countryDataList is countryCode then
　　　　　　　　　　set foundIndex to i
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　end repeat
　　　　　　
　　　　　　if foundIndex is not -1 then
　　　　　　　　— 既にデータがある場合、新しい色が「赤」なら上書きする
　　　　　　　　if col is "red" then
　　　　　　　　　　set item foundIndex of countryDataList to {cc:countryCode, |color|:col}
　　　　　　　　　　— それ以外の場合は何もしない（最初に見つかった色を維持）
　　　　　　　　end if
　　　　　　else
　　　　　　　　— 新しい国コードの場合はそのまま追加
　　　　　　　　set end of countryDataList to {cc:countryCode, |color|:col}
　　　　　　end if
　　　　end if
　　end repeat
　　
　　— 2. 国コード順にソート（Cocoaの機能を利用）
　　set nsList to NSMutableArray’s arrayWithArray:countryDataList
　　set sortDesc to NSSortDescriptor’s sortDescriptorWithKey:"cc" ascending:true
　　nsList’s sortUsingDescriptors:{sortDesc}
　　
　　return nsList as list
end getLocaleNumFormat

★Click Here to Open This Script　

AppleScript名：ヨーロッパ数値文字列形式をISO形式に変換する.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/01/09
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

set raw1 to "2,5"
set raw2 to "1.234,56"
set raw3 to "1234.5" — ISO形式でもOK

set n1 to normalizeNumberString(raw1) — "2.5"
set n2 to normalizeNumberString(raw2) — "1234.56"
set n3 to normalizeNumberString(raw3) — "1234.5"

log (n1 as number)
log (n2 as number)
log (n3 as number)

— 数値文字列を強制的に「.」小数点に直して返す
on normalizeNumberString(txt)
　　— まず前後の空白・改行を削る（純AppleScript）
　　set t to trimText(txt)
　　
　　— 「1.234,56」系: "." を千区切りとみなして除去
　　repeat while t contains "."
　　　　set AppleScript’s text item delimiters to "."
　　　　set t to text items of t
　　　　set AppleScript’s text item delimiters to ""
　　　　set t to t as text
　　end repeat
　　
　　— 「,」を小数点として「.」に統一
　　set AppleScript’s text item delimiters to ","
　　set toks to text items of t
　　set AppleScript’s text item delimiters to "."
　　set t to toks as text
　　
　　set AppleScript’s text item delimiters to ""
　　return t
end normalizeNumberString

— 前後空白を除去（AppleScript標準のみ）
on trimText(txt)
　　set AppleScript’s text item delimiters to {space, return, linefeed, tab}
　　set theText to txt as text
　　— remove leading
　　repeat while theText starts with space or theText starts with tab or theText starts with return or theText starts with linefeed
　　　　set theText to text 2 thru -1 of theText
　　end repeat
　　— remove trailing
　　repeat while theText ends with space or theText ends with tab or theText ends with return or theText ends with linefeed
　　　　set theText to text 1 thru -2 of theText
　　end repeat
　　return theText
end trimText

★Click Here to Open This Script　

Skim v1.7.12でshareコマンドを追加

Posted on 1月 8 by Takaaki Naganoya

オープンソースで開発を続けられているPDFビューワー「Skim」。AppleScriptへの対応度も高く、万人におすすめできるMac用アプリです。

そのSkimがバージョンアップして、AppleScriptのコマンド「share」が追加されました。

▲「ファイル」＞「共有」コマンド以下のメニュー項目と等価なshareコマンド

すでに数年前から、AppleScriptからAirDropでファイル共有する処理を実際に書いて動かしていましたが、それをSkim側でも実装してきたようです。

shareコマンドのオプションは「The name of the service to use. 」とだけ書かれており、サービス名のenumが用意されていたりはしないようです。というわけで、ひととおり試してみたわけですが、英語で指定するのではなくローカライズされたサービス名を指定するようになっています。

AppleScript名：AirDropで共有.scpt

tell application "Skim"
　　share front document using "AirDrop"
end tell

★Click Here to Open This Script　

AppleScript名：メールで共有.scpt

tell application "Skim"
　　share front document using "メール"
end tell

★Click Here to Open This Script　

AppleScript名：メッセージで共有.scpt

tell application "Skim"
　　share front document using "メッセージ"
end tell

★Click Here to Open This Script　

AppleScript名：メモで共有.scpt

tell application "Skim"
　　share front document using "メモ"
end tell

★Click Here to Open This Script　

AppleScript名：フリーボードで共有.scpt

tell application "Skim"
　　share front document using "フリーボード"
end tell

★Click Here to Open This Script　

AppleScript名：Simulatorで共有.scpt

tell application "Skim"
　　share front document using "Simulator"
end tell

★Click Here to Open This Script　

Gender APIを使って名前から性別を判定

Posted on 1月 7 by Takaaki Naganoya

Gender API（https://www.genderapi.io/ja#）のREST APIを呼び出して、氏名から性別を判定するAppleScriptを書いてみました。

本APIは、POST methodで呼び出すものですが、NSURLConnection経由で呼び出すPOST呼び出しのScriptしか書いてありませんでした。NSURLConnectionは同期実行が行えるため、AppleScriptからは呼び出しやすいものですが、Deprecated宣言されてしまっているため、いつ本当になくなるかわかりません（いうても、あちこちで必要なのですぐになくならない気もする）。

#　本Scriptは、間違いなく2026年の意義あるScriptにリストアップされるものです

そこで、NSURLSessionを呼び出すPOST method呼び出しのAppleScriptを書いておいた次第です。ChatGPTに書かせました。

set aPostData to {|name|:”ぴよ　まるお”, country:”JP”, askToAI:false, forceToGenderize:false}

のように、氏名を指定して呼び出すと、

{|name|:”ぴよ　まるお”, |to|:false, remaining_credits:178, q:”ぴよ　まるお”, expires:1.767849716E+9, isHumanName:true, total_names:1, used_credits:1, probability:80, duration:”828ms”, country:”JP”, status:true, gender:”male”}

のように結果が返ってきます。

Gender APIは無料コースが用意されており、1日に200回までの呼び出しの範囲で無料利用できます。本当は、「日本語の氏名から性別を判定できる機械学習モデル」（Classifier）があれば、それを呼び出すだけで済むのですが、ちょっと探したぐらいでは見当たりませんでした。

こういうのは、公共機関が整備して配布すべきもののような気もするのですが……

AppleScript名：POST method REST API v4.2（NSURLSession）_blog.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2026/01/07
—
–　　Copyright © 2026 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLCache : a reference to current application’s NSURLCache
property NSURLSession : a reference to current application’s NSURLSession
property NSMutableData : a reference to current application’s NSMutableData
property NSOperationQueue : a reference to current application’s NSOperationQueue
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

property retData : missing value
property retCode : 0
property drecF : false
property aSession : missing value
property aCache : missing value

on run
　　–https://www.genderapi.io/ja#　にアクセスしてAPI Keyを取得してください
　　set apiKey to "Bearer " & "999zzz99z9999z99999z999z"
　　set reqURLStr to "https://api.genderapi.io/api"
　　set aPostData to {|name|:"長野谷　隆昌", country:"JP", askToAI:false, forceToGenderize:false}
　　
　　set jsonDict to callRestPOSTJSON(reqURLStr, aPostData, 5, apiKey) of me
　　return jsonDict as record
　　–> {status:false, errno:93, errmsg:"query limit reached"}–API使用制限に到達した場合の返答
　　–> {status:false, errno:94, errmsg:"invalid or missing key"}–API Keyを指定しなかった場合の返答
　　–> {|name|:"長野谷隆昌", |to|:false, remaining_credits:178, q:"長野谷　隆昌", expires:1.767849716E+9, isHumanName:true, total_names:1, used_credits:1, probability:80, duration:"828ms", country:"JP", status:true, gender:"male"}
end run

— POST JSON REST APIを呼び出す
on callRestPOSTJSON(reqURLStr as string, aRec as record, timeoutSec as integer, apiKey)
　　set retData to NSMutableData’s alloc()’s init()
　　set retCode to 0
　　set drecF to false
　　
　　–URL Cache（GETと同じ）
　　set cachePath to (POSIX path of (path to temporary items folder)) & "/Caches/AppleScriptURLCache"
　　set aCache to NSURLCache’s alloc()’s initWithMemoryCapacity:512000 diskCapacity:1024 * 1024 * 5 diskPath:cachePath
　　NSURLCache’s setSharedURLCache:aCache
　　
　　–URL
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　
　　–POST リクエスト作成
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"POST"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　aRequest’s setValue:apiKey forHTTPHeaderField:"Authorization"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　
　　–JSON化
　　set jsonData to NSJSONSerialization’s dataWithJSONObject:aRec options:0 |error|:(missing value)
　　aRequest’s setHTTPBody:jsonData
　　
　　–Session
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　aConfig’s setURLCache:aCache
　　
　　set aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(NSOperationQueue’s mainQueue())
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　aTask’s resume()
　　
　　–delegate終了待ち
　　repeat (1000 * timeoutSec) times
　　　　if drecF is true then exit repeat
　　　　delay "0.001" as real
　　end repeat
　　
　　–Session終了
　　aSession’s finishTasksAndInvalidate()
　　set aSession to missing value
　　
　　–結果パース
　　return my parseSessionResults()
end callRestPOSTJSON

— delegate: body accumulation
on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　retData’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

— delegate: finished/failed
on URLSession:tmpSession task:tmpTask didCompleteWithError:tmpError
　　if tmpError = missing value then
　　　　set drecF to true
　　else
　　　　error "POST Failed:" & tmpError
　　end if
end URLSession:task:didCompleteWithError:

–JSON parse
on parseSessionResults()
　　set resStr to NSString’s alloc()’s initWithData:retData encoding:NSUTF8StringEncoding
　　set jsonString to NSString’s stringWithString:resStr
　　set jsonData2 to jsonString’s dataUsingEncoding:NSUTF8StringEncoding
　　set jsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData2 options:0 |error|:(missing value)
　　return jsonDict
end parseSessionResults

★Click Here to Open This Script　