mapboxSpeech Sample

mapboxが提供しているMapBoxSpeechフレームワークを呼び出すAppleScriptです。

mapboxは地図系の各種機能をWeb APIで提供しています。その一環としてGithub上でNatural-sounding text-to-speech Frameworkを提供しており、これをAppleScriptから呼び出してみました。

Github上のサンプルコードでは、AppleScript（Xcode上のプロジェクト）から呼び出すサンプルも掲載されているのですが、通常のScript EditorやScript Debugger上から呼び出す方法は掲載されていませんでした（しかも、サンプルそのままだと動く気配がないんですが、、、）。

＃　Xcode上で作成したアプリケーションだと、MapboxSpeech.Frameworkが、組み込んだアプリケーション側のInfo.plist内の指定のエントリに書かれているAccess tokenを読み込んでREST APIにアクセスできるとか。単体でAppleScriptからFrameworkを呼び出すような使い方は想定していなかったようです＞サンプル

そこで、実際にmapboxにサインアップして、API Key（というか、プロジェクト単位でのToken）を取得、実際にGithub上で公開されているフレームワークをmacOS用にビルドし、通常のAppleScriptから呼び出してみました。

以下のアプレットは実行すると実際に日本語サンプル（たぶん）の文章を読み上げてくれます。実際に本Script（アプレットではなく）をAppleScriptとしてご自分の環境で動かすためには、Frameworkをインストールし、Script Debugger上で動かす（macOS 10.14以降）か、SIPを解除した環境（macOS 10.14以降）でスクリプトエディタ上で実行することになります。その際には、mapboxのWebサイト上でサインアップしてご自分のAccess tokenを取得してください。サインアップすると公開Access tokenを取得できますが、そちらではなく個別のプロジェクトをWebサイト上で作成して（Test AppleScriptとか）、そちらのAccess tokenを利用してください。

–> Download MapboxSpeech.framework(To ~/Library/Frameworks/)

–> mapboxSpeech Sample Run-Only(Code-Signed Executable Applet with Framework)

……で、実際にサンプル文章を読み上げてみたところ、英文なのに英文っぽくない日本語みたいな発音で、ちょっと「ナニコレ？」と思ってしまいましたが、冗談半分で日本語テキストをパラメータに指定してみたら、ちゃんと日本語を読み上げるのでビビりました。

この手のWebサービスで日本語対応はしておらず、英語＋ヨーロッパの数カ国語のみサポートというのが普通です。

OS標準のsayコマンドよりも形態素解析が弱いようなので、文節ごとに読点（、）を入れてあげる必要はありますが、それでも日本語のテキストを読み上げてしまうのにはちょっと驚かされました。

AppleScript名：mapboxSpeech Sample.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/27
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "MapboxSpeech" –https://github.com/mapbox/mapbox-speech-swift
use framework "AVFoundation"
use scripting additions

on run
　　set theOptions to current application’s MBSpeechOptions’s alloc()
　　theOptions’s initWithText:"こんにちは、私の名前は、「ながのや」です。"
　　
　　set speechSynthesizer to current application’s MBSpeechSynthesizer’s alloc()’s initWithAccessToken:"xx.xxX.X_XXxxxxxXXXXXxXxXXxxX"
　　set theURL to speechSynthesizer’s URLForSynthesizingSpeechWithOptions:theOptions
　　set theData to the current application’s NSData’s dataWithContentsOfURL:theURL
　　
　　set aAudioPlayer to current application’s AVAudioPlayer’s alloc()’s initWithData:theData |error|:(missing value)
　　aAudioPlayer’s prepareToPlay()
　　aAudioPlayer’s setNumberOfLoops:0
　　aAudioPlayer’s setDelegate:me
　　aAudioPlayer’s play()
end run

–音楽再生の終了のDelegate Methodを取得
on audioPlayerDidFinishPlaying:anAudioplayer successfully:aFlag
　　tell current application to quit
end audioPlayerDidFinishPlaying:successfully:

★Click Here to Open This Script　

TTSで日本語数値読み上げ

Posted on 9月 26 by Takaaki Naganoya

桁数の大きな数値のText To Speech（TTS）読み上げのAppleScriptです。

＃　日本語環境における枝葉的な（マニアックな）数値表現の仕様に関する話であり、他の言語では関係ない話です。漢字文化圏で使われる数値表現のようですが、たとえば中国や韓国で使われている数値桁表現との間で厳密な互換性があるかといった確認は行なっておりません

実行前に日本語TTS読み上げ音声の「Otoya」あるいは「Kyoko」をインストールしておいてください。

まず、AppleScriptが指数表示なしに表現できる数値は10^9程度で、それを超えると指数表示になります。

ただし、指数表示になった数値を数値文字列に変換するノウハウは全世界的に共有されており、そのためのサブルーチン（Stringify）を呼び出すだけで済みます。

AppleScriptのsayコマンドでは「100兆」までの読み上げはそれっぽく実行してくれますが、「1000兆」になると読み上げ内容が数字の羅列になってしまいます。

これについても、大きな数値を日本語数値エンコーディング文字列に変換するサブルーチンを昔から公開しており（本Blog開設当初の11年前に掲載）、それを呼び出すだけで日本語数値表現文字列に変換できるため、読み上げられることでしょう。

Number	Japanese	English
1	一（いち）	one
10	十（じゅう）	ten
100	百（ひゃく）	hundred
1000	千（せん）	thousand
10000	万（まん）	10 thousand
100000	十万（じゅうまん）	100 thousand
1000000	百万（ひゃくまん）	million
10000000	千万（せんまん）	10 million
100000000	億（おく）	100million
1000000000000	兆（ちょう）	villion
1000000000000000	京（けい）	thousand villion
100000000000000000	100京（ひゃっけい）	trillion
10^24	丈（じょ）
10^28	穣（じょう）
10^52	恒河沙（ごうがしゃ）
10^56	阿僧祇（あそうぎ）
10^60	那由他（なゆた）
10^64	不可思議（ふかしぎ）
10^68	無量大数（むりょうたいすう）

とはいえ、「阿僧祇（あそうぎ、10^56）「那由多（なゆた、10^60）」といった数値桁を読み上げさせるとTTSが正しく読み上げてくれません。さすがにこんなにマニアックな数値表現はカバーしなくてよいでしょう。「丈（じょ）」「穣（じょう）」など似た音の桁が存在するあたり、これらは口に出して読み上げるものではなく、文字で読むためだけのものだと強く感じるものです。

AppleScript名：TTSで日本語数値読み上げ

repeat with i from 0 to 15
　　set aNum to (10 ^ i)
　　say Stringify(aNum) of me using "Kyoko" –or "Otoya"
end repeat

on Stringify(x) — for E+ numbers
　　set x to x as string
　　set {tids, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, {"E+"}}
　　if (count (text items of x)) = 1 then
　　　　set AppleScript’s text item delimiters to {tids}
　　　　return x
　　else
　　　　set {n, z} to {text item 1 of x, (text item 2 of x) as integer}
　　　　set AppleScript’s text item delimiters to {tids}
　　　　set i to character 1 of n
　　　　set decSepChar to character 2 of n — "." or ","
　　　　set d to text 3 thru -1 of n
　　　　set l to count d
　　　　if l > z then
　　　　　　return (i & (text 1 thru z of d) & decSepChar & (text (z + 1) thru -1 of d))
　　　　else
　　　　　　repeat (z – l) times
　　　　　　　　set d to d & "0"
　　　　　　end repeat
　　　　　　return (i & d)
　　　　end if
　　end if
end Stringify

★Click Here to Open This Script　

AppleScript名：TTSで日本語数値読み上げ v2

repeat with i from 15 to 70
　　set aNum to (10 ^ i)
　　set jRes to encodeJapaneseNumText(aNum) of japaneseNumberEncodingKit
　　say jRes using "Kyoko" –or "Otoya"
end repeat

–課題：オーバーフローチェックを行っていない
set a to "102320120000108220010"
set jRes to encodeJapaneseNumText(a) of japaneseNumberEncodingKit
–> "1垓232京120兆1億822万10"

script japaneseNumberEncodingKit
　　–数字文字列を日本語数値表現文字列に変換
　　on encodeJapaneseNumText(aNum)
　　　　
　　　　set aText to Stringify(aNum) of me
　　　　set aText to aText as Unicode text
　　　　set dotText to "." as Unicode text
　　　　set upperDigit to ""
　　　　set lowerDigit to ""
　　　　
　　　　–小数点の処理
　　　　if dotText is in aText then
　　　　　　set b to offset of dotText in aText
　　　　　　set upperDigit to characters 1 thru (b – 1) of aText
　　　　　　set upperDigit to upperDigit as Unicode text
　　　　　　set lowerDigit to characters b thru -1 of aText
　　　　　　set lowerDigit to lowerDigit as Unicode text
　　　　else
　　　　　　set upperDigit to aText
　　　　end if
　　　　
　　　　
　　　　set scaleList3 to {"", "万", "億", "兆", "京", "垓", "丈", "壌", "溝", "砂", "正", "載", "極", "恒河沙", "阿僧梢", "那由他", "不可思議", "無量大数"}
　　　　set splitDigit to 4
　　　　set nList to splitByDigit(upperDigit, splitDigit) of me
　　　　set nList to reverse of nList
　　　　
　　　　set resText to ""
　　　　set digCount to 1
　　　　repeat with i in nList
　　　　　　set b to (contents of i) as number
　　　　　　if b is not equal to 0 then
　　　　　　　　set resText to (b as text) & item digCount of scaleList3 & resText
　　　　　　end if
　　　　　　set digCount to digCount + 1
　　　　end repeat
　　　　
　　　　
　　　　
　　　　return resText & lowerDigit
　　　　
　　end encodeJapaneseNumText
　　
　　–指定桁数で区切る
　　on splitByDigit(a, splitDigit)
　　　　set aList to characters of a
　　　　set aList to reverse of aList
　　　　log aList
　　　　set resList to {}
　　　　set tempT to ""
　　　　set tempC to 1
　　　　repeat with i in aList
　　　　　　set tempT to contents of i & tempT
　　　　　　if tempC mod splitDigit = 0 then
　　　　　　　　set resList to {tempT} & resList
　　　　　　　　set tempT to ""
　　　　　　end if
　　　　　　set tempC to tempC + 1
　　　　end repeat
　　　　
　　　　if tempT is not equal to "" then
　　　　　　set resList to {tempT} & resList
　　　　end if
　　　　
　　　　resList
　　　　
　　end splitByDigit
　　
　　
　　
　　on Stringify(x) — for E+ numbers
　　　　set x to x as string
　　　　set {tids, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, {"E+"}}
　　　　if (count (text items of x)) = 1 then
　　　　　　set AppleScript’s text item delimiters to tids
　　　　　　return x
　　　　else
　　　　　　set {n, z} to {text item 1 of x, (text item 2 of x) as integer}
　　　　　　set AppleScript’s text item delimiters to tids
　　　　　　set i to character 1 of n
　　　　　　set decSepChar to character 2 of n — "." or ","
　　　　　　set d to text 3 thru -1 of n
　　　　　　set l to count d
　　　　　　if l > z then
　　　　　　　　return (i & (text 1 thru z of d) & decSepChar & (text (z + 1) thru -1 of d))
　　　　　　else
　　　　　　　　repeat (z – l) times
　　　　　　　　　　set d to d & "0"
　　　　　　　　end repeat
　　　　　　　　return (i & d)
　　　　　　end if
　　　　end if
　　end Stringify
end script

★Click Here to Open This Script　

テキストをTTSで読み上げて所要時間を算出 v2.1（CotEditor版）

Posted on 2月 6, 2018 by Takaaki Naganoya

指定のテキストをTTS（Text To Speech）音声で読み上げ、読み上げ所要時間を計算するAppleScriptです。

実時間をかけて読み上げるのではなく、ファイルに対して音声レンダリングしたデータを書き込む動作をsayコマンドで行うため、読み上げ実時間よりも短い時間で動作を完了します。

読み上げ速度を遅いパターンと速いパターンで個別に音声レンダリングして所要時間のシミュレーションを行ったり、Keynoteのプレゼン資料のすべてのテキスト要素を読み上げ所要時間のシミュレーションを行なって、資料が多すぎるとか少なすぎるといった判断を行なっています。

とくに、プレゼン発表に不慣れな人は発表資料のページを多くしがち＆１ページあたりの文字数を多くしがちなので、sayコマンドによる読み上げシミュレーションで「この発表時間に対して要素が多すぎるのでは？」といった話をします。

AppleScript名：テキストをTTSで読み上げて所要時間を算出 v2.1（CotEditor版）

— Created 2018-01-10 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AVFoundation"
use framework "AppKit"
–http://piyocast.com/as/archives/5113

property |NSURL| : a reference to current application’s |NSURL|
property NSDate : a reference to current application’s NSDate
property NSUUID : a reference to current application’s NSUUID
property NSFileManager : a reference to current application’s NSFileManager
property AVAudioPlayer : a reference to current application’s AVAudioPlayer
property NSDateFormatter : a reference to current application’s NSDateFormatter
property NSSpeechSynthesizer : a reference to current application’s NSSpeechSynthesizer

set str3 to getEditorText() of me
if str3 = false then return

set aVoice to "Kyoko"

–Check existence of TTS Voice name
set vList to retAvailableTTSnames() of me
if aVoice is not in vList then error "Wrong TTS Voice Name"

set d1 to readTextByTTSVoiceAndReturnDuration(str3, aVoice, 180) of me –aSpeedRate is "Words per minute. 180 to 220"
set d2 to readTextByTTSVoiceAndReturnDuration(str3, aVoice, 220) of me

set outStr to (formatHMS(d1) of me & "/180 words per minute") & return & (formatHMS(d2) of me & "/220 words per minute") & return
tell application "CotEditor"
　　activate
　　write to console outStr
end tell

on readTextByTTSVoiceAndReturnDuration(aStr as string, aVoice as string, aSpeedRate as integer)
　　set aUUID to NSUUID’s UUID()’s UUIDString() as string
　　–set aPath to (((path to temporary items from user domain) as string) & aUUID & ".aif")
　　set aPath to (((path to desktop) as string) & aUUID & ".aif")
　　set aPOSIX to POSIX path of aPath
　　
　　tell current application
　　　　say aStr using aVoice saving to (aPOSIX) speaking rate aSpeedRate without waiting until completion
　　end tell
　　
　　repeat 100000 times
　　　　set aExt to NSFileManager’s defaultManager()’s fileExistsAtPath:aPOSIX
　　　　if aExt as boolean = true then exit repeat
　　　　delay "0.001" as real
　　end repeat
　　
　　if aExt = false then error "No Sound file"
　　
　　set aDur to getDuration(aPath as alias) of me
　　try
　　　　do shell script "rm -f " & quoted form of POSIX path of aPath
　　end try
　　
　　return aDur as real
end readTextByTTSVoiceAndReturnDuration

on getDuration(aFile)
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　
　　repeat 1000 times
　　　　set aAudioPlayer to AVAudioPlayer’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　　　set aRes to aAudioPlayer’s prepareToPlay()
　　　　if aRes as boolean = true then exit repeat
　　　　delay 0.5
　　end repeat
　　if aRes = false then error "TTS sound output failed"
　　
　　set channelCount to aAudioPlayer’s numberOfChannels()
　　set aDuration to aAudioPlayer’s duration()
　　return aDuration as real
end getDuration

on retAvailableTTSnames()
　　set outList to {}
　　
　　set aList to NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aInfo to (NSSpeechSynthesizer’s attributesForVoice:j)
　　　　set aInfoRec to aInfo as record
　　　　set aName to VoiceName of aInfoRec
　　　　set the end of outList to aName
　　end repeat
　　
　　return outList
end retAvailableTTSnames

on formatHMS(aTime)
　　set aDate to NSDate’s dateWithTimeIntervalSince1970:aTime
　　set aFormatter to NSDateFormatter’s alloc()’s init()
　　
　　—This formatter text is localized in Japanese.
　　if aTime < hours then
　　　　aFormatter’s setDateFormat:"mm分ss秒"
　　else if aTime < days then
　　　　aFormatter’s setDateFormat:"HH時間mm分ss秒"
　　else
　　　　aFormatter’s setDateFormat:"DD日HH時間mm分ss秒"
　　end if
　　
　　set timeStr to (aFormatter’s stringFromDate:aDate) as string
　　return timeStr
end formatHMS

on getEditorText()
　　tell application "CotEditor"
　　　　if (count every document) = 0 then return false
　　　　tell front document
　　　　　　return contents
　　　　end tell
　　end tell
end getEditorText

★Click Here to Open This Script　

システムにインストールされているTTS VoiceのID一覧を取得する

Posted on 2月 6, 2018 by Takaaki Naganoya

AppleScript名：システムにインストールされているTTS VoiceのID一覧を取得する

— Created 2017-03-28 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set vList to current application’s NSSpeechSynthesizer’s availableVoices() as list
–>　　{"com.apple.speech.synthesis.voice.Alex", "com.apple.speech.synthesis.voice.alice", "com.apple.speech.synthesis.voice.allison.premium", "com.apple.speech.synthesis.voice.alva", "com.apple.speech.synthesis.voice.amelie", "com.apple.speech.synthesis.voice.anna.premium", "com.apple.speech.synthesis.voice.audrey.premium", "com.apple.speech.synthesis.voice.ava.premium", "com.apple.speech.synthesis.voice.carmit", "com.apple.speech.synthesis.voice.damayanti", "com.apple.speech.synthesis.voice.daniel.premium", "com.apple.speech.synthesis.voice.diego", "com.apple.speech.synthesis.voice.ellen",……}

★Click Here to Open This Script　

OSにインストールされているTTS Voiceのうち指定言語をサポートするものを返す

Posted on 2月 6, 2018 by Takaaki Naganoya

AppleScript名：OSにインストールされているTTS Voiceのうち指定言語をサポートするものを返す

— Created 2017-03-28 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set aLoc to (current application’s NSLocale’s currentLocale()’s identifier()) as string
–>　　"ja_JP"

set vList to getTTSVoiceNameWithLanguage(aLoc) of me
–>　　{"Kyoko", "Otoya"}

set vIDs to getTTSVoiceIDWithLanguage(aLoc) of me
–>　　{"com.apple.speech.synthesis.voice.kyoko.premium", "com.apple.speech.synthesis.voice.otoya.premium"}

set anID to getTTSVoiceIDWithName("Kyoko") of me
–>　　{"com.apple.speech.synthesis.voice.kyoko.premium"}

set anAge to getTTSVoiceAgeWithName("Otoya") of me
–>　　35

on getTTSVoiceNameWithLanguage(voiceLang)
　　set outArray to current application’s NSMutableArray’s arrayWithObject:{}
　　
　　–Make Installed Voice List
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceLocaleIdentifier == %@", voiceLang)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceName") as list
　　
　　return aResList
end getTTSVoiceNameWithLanguage

on getTTSVoiceIDWithLanguage(voiceLang)
　　set outArray to current application’s NSMutableArray’s arrayWithObject:{}
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceLocaleIdentifier == %@", voiceLang)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceIdentifier") as list
　　
　　return aResList
end getTTSVoiceIDWithLanguage

on getTTSVoiceIDWithName(voiceName)
　　set outArray to current application’s NSMutableArray’s arrayWithObject:{}
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceName == %@", voiceName)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceIdentifier") as list
　　
　　return aResList
end getTTSVoiceIDWithName

on getTTSVoiceAgeWithName(voiceName)
　　set outArray to current application’s NSMutableArray’s arrayWithObject:{}
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceName == %@", voiceName)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceAge") as list
　　set anItem to first item of aResList
　　if anItem = missing value then return 0
　　return anItem as integer
end getTTSVoiceAgeWithName

★Click Here to Open This Script　

TTS Voiceを言語と性別で抽出

Posted on 2月 6, 2018 by Takaaki Naganoya

AppleScript名：TTS Voiceを言語と性別で抽出

— Created 2017-03-28 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set aLoc to (current application’s NSLocale’s currentLocale()’s identifier()) as string
–>　　"ja_JP"

set vList to getTTSVoiceNameWithLanguageAndGender(aLoc, "Male") of me
–>　　{"Otoya"}

set vList to getTTSVoiceNameWithLanguageAndGender(aLoc, "Female") of me
–>　　{"Kyoko"}

set vList to getTTSVoiceNameWithLanguageAndGender("en_US", "Male") of me
–> {"Alex", "Bruce", "Fred", "Junior", "Ralph", "Tom"}

on getTTSVoiceNameWithLanguageAndGender(voiceLang, aGen)
　　if aGen = "Male" then
　　　　set aGender to "VoiceGenderMale"
　　else if aGen = "Female" then
　　　　set aGender to "VoiceGenderFemale"
　　end if
　　
　　set outArray to current application’s NSMutableArray’s new()
　　
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceLocaleIdentifier == %@ && VoiceGender== %@", voiceLang, aGender)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceName") as list
　　
　　return aResList
end getTTSVoiceNameWithLanguageAndGender

★Click Here to Open This Script　

すべてのTTS VoiceからLocale情報を抽出し、指定LocaleのTTS Voice名を取得

Posted on 2月 6, 2018 by Takaaki Naganoya

AppleScript名：すべてのTTS VoiceからLocale情報を抽出し、指定LocaleのTTS Voice名を取得

— Created 2015-08-25 by Takaaki Naganoya
— Modified 2015-08-26 by Shane Stanley, Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

–すべてのTTS VoiceからIdentifier情報を抽出してユニーク化
set v1Res to getLocaleICodeFromTTSVoices()
set vRes to choose from list v1Res with prompt "Select Locale"
set v2Res to getTTSVoiceNameWithLanguage(first item of vRes) of me

on getLocaleICodeFromTTSVoices()
　　set aResList to getAttributeFromTTSVoices("VoiceLocaleIdentifier") of me
　　return aResList as list
end getLocaleICodeFromTTSVoices

on getAttributeFromTTSVoices(anAttribute)
　　set outArray to current application’s NSMutableArray’s new()
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDict to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDict)
　　end repeat
　　
　　set aResArray to (outArray’s valueForKey:anAttribute)
　　
　　set aSet to current application’s NSMutableSet’s setWithArray:aResArray
　　set aResList to aSet’s allObjects()
　　
　　return aResList as list
end getAttributeFromTTSVoices

on getTTSVoiceNameWithLanguage(voiceLang)
　　set outArray to current application’s NSMutableArray’s new()
　　set aList to current application’s NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aDIc to (current application’s NSSpeechSynthesizer’s attributesForVoice:j)
　　　　(outArray’s addObject:aDIc)
　　end repeat
　　
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_("VoiceLocaleIdentifier == %@", voiceLang)
　　set filteredArray to outArray’s filteredArrayUsingPredicate:aPredicate
　　set aResList to (filteredArray’s valueForKey:"VoiceName") as list
　　
　　return aResList
end getTTSVoiceNameWithLanguage

★Click Here to Open This Script　

すべてのTTS VoiceからLanguage情報を抽出してユニーク化

Posted on 2月 6, 2018 by Takaaki Naganoya

AppleScript名：すべてのTTS VoiceからLanguage情報を抽出してユニーク化

— Created 2015-08-25 by Takaaki Naganoya
— Modified 2015-08-26 by Shane Stanley, Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set v1Res to getLocaleICodeFromTTSVoices()
–>　　{"fr_FR", "zh_TW", "it_IT", "en_ZA", "es_AR", "ko_KR", "ro_RO", "en_IN", "fr_CA", "hi_IN", "da_DK", "en-scotland", "pt_BR", "zh_CN", "sv_SE", "es_ES", "ar_SA", "hu_HU", "en_GB", "ja_JP", "fi_FI", "zh_HK", "tr_TR", "nb_NO", "pl_PL", "id_ID", "cs_CZ", "el_GR", "he_IL", "ru_RU", "de_DE", "en_AU", "nl_BE", "pt_PT", "th_TH", "sk_SK", "en_US", "en_IE", "nl_NL", "es_MX"}

set v2Res to getLanguageCodeFromTTSVoices()
–> {"nl-NL", "id", "fr-FR", "it-IT", "es-419", "ko-KR", "ro-RO", "fr-CA", "hi-IN", "da-DK", "pt-BR", "sv-SE", "es-ES", "hu-HU", "en-GB", "ja-JP", "fi-FI", "tr-TR", "ar", "nb-NO", "pl-PL", "cs-CZ", "el-GR", "he-IL", "ru-RU", "zh-Hans", "de-DE", "en-AU", "zh-Hant", "nl-BE", "pt-PT", "th-TH", "sk-SK", "en-US", "en-IE"}

on getLanguageCodeFromTTSVoices()
　　set aResList to getAttributeFromTTSVoices("VoiceLanguage") of me
　　return aResList as list
end getLanguageCodeFromTTSVoices

on getLocaleICodeFromTTSVoices()
　　set aResList to getAttributeFromTTSVoices("VoiceLocaleIdentifier") of me
　　return aResList as list
end getLocaleICodeFromTTSVoices

★Click Here to Open This Script　

TTS Voice名一覧を取得

Posted on 2月 6, 2018 by Takaaki Naganoya

AppleScript名：TTS Voice名一覧を取得

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSSpeechSynthesizer : a reference to current application’s NSSpeechSynthesizer

set vList to retAvailableTTSnames() of me
–> {"Agnes", "Albert", "Alex", "Alice", "Allison", "Alva", "Amelie", "Anna", "Audrey", "Ava", "Bad News", "Bahh", "Bells", "Boing", "Bruce", "Bubbles", "Carmit", "Cellos", "Damayanti", "Daniel", "Deranged", "Diego", "Ellen", "Emily", "Fiona", "Fred", "Good News", "Hysterical", "Ioana", "Jill", "Joana", "Jorge", "Juan", "Junior", "Kanya", "Karen", "Kate", "Kathy", "Kyoko", "Laura", "Lee", "Lekha", "Luca", "Luciana", "Maged", "Mariska", "Mei-Jia", "Melina", "Milena", "Moira", "Monica", "Nora", "Otoya", "Paulina", "Pipe Organ", "Princess", "Ralph", "Samantha", "Sara", "Satu", "Serena", "Sin-ji", "Tessa", "Thomas", "Ting-Ting", "Tom", "Trinoids", "Veena", "Vicki", "Victoria", "Whisper", "Xander", "Yelda", "Yuna", "Yuri", "Zarvox", "Zosia", "Zuzana"}

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: Text to Speech

mapboxSpeech Sample

TTSで日本語数値読み上げ

テキストをTTSで読み上げて所要時間を算出 v2.1（CotEditor版）

システムにインストールされているTTS VoiceのID一覧を取得する

OSにインストールされているTTS Voiceのうち指定言語をサポートするものを返す

TTS Voiceを言語と性別で抽出

すべてのTTS VoiceからLocale情報を抽出し、指定LocaleのTTS Voice名を取得

すべてのTTS VoiceからLanguage情報を抽出してユニーク化

TTS Voice名一覧を取得