RectangleBinPackを用いて2D Bin Packを解く v2.3

Posted on 5月 31, 2022 by Takaaki Naganoya

オープンソースの「RectangleBinPack」を用いて2D Bin Packagingを解き、Keynote上の汎用オブジェクト（iWork item）を指定矩形内に詰め込むAppleScriptです。

2D Bin Packは、指定のオブジェクトを面積で評価して、ターゲットの領域に「詰め込む」（オブジェクト回転あり）という処理で、ワードクラウドであるとか、記事レイアウト時の最適化配置といった用途に用いられます。

さまざまなアルゴリズムが提唱され、コンピュータの登場初期からどえらい先人たちが攻めまくった分野であるため、ありがたく、その成果をいただいているという用途でもあります。

よく、ゲームのテクスチャ画像を１枚の画像ファイルに詰め込む際に2D Bin Packの処理を用いている例を見かけます。なんでファイルごとに分けないのかはわかりませんけれども（ファイル容量の節約？？？）。

–> Download Script bundle with RectangleBinPack in its bundle + sample Keynote document

# This AppleScript requires RectangleBinPack executable in its bundle. So, download the whole AppleScript bundle archive from the link above (↑)

オープン中のKeynote書類の表示中のスライド（ページ）上にある矩形オブジェクト（Shape）を指定の矩形エリア内に2D Packingします。エリアの大きさが小さすぎると正常にPackingされなかったり、false（エラー）を返したりします。

変更履歴：

v2.1: BinPackTestをIntel x64とARM binaryのそれぞれのバイナリでビルドしてバンドルに入れた（Makeを書き換えて直接Universalバイナリに仕立てられるといいのに）
v2.2: BridgePlusがなくても動くように書き換えた（ないと動かないのはいろいろ運用上問題がある）
v2.3: shapeに対してBinPackしていたのを、Keynote上の汎用オブジェクトへのアクセス予約語iWork itemでアクセスするように変更した

AppleScript名：rectBinPack v2.3_Universal.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/31
—
–　　Copyright © 2019-2022 Piyomaru Software, All Rights Reserved
—
— 2D Bin Packing by juj https://github.com/juj/RectangleBinPack
— v2.1: BinPackTestをIntel x64とARM binaryのそれぞれのバイナリでビルドしてバンドルに入れた（Universalバイナリに仕立てられるといいのに）
— v2.2: BridgePlusを外した（ないと動かないのはいろいろ運用上問題がある）
— v2.3: shapeに対してBinPackしていたのを、Keynote上の汎用オブジェクトへのアクセス予約語iWork itemでアクセスするように変更した

use AppleScript version "2.4"
use framework "Foundation"
use scripting additions

–Packaging Target Area
set binSizeX to 600
set binSizeY to 600

set packRes to packKeynoteObjectsOnCurrentSlide(binSizeX, binSizeY) of me

on packKeynoteObjectsOnCurrentSlide(binSizeX, binSizeY)
　　set {tList, a0List} to retRectsFromKeynote() of me
　　
　　set aList to sortList2DDecending(a0List, {"myWidth", "myHeight", "myArea"}) of me –Sorting key is Width(main) and Area(sub) and Height(sub)
　　
　　set aRes to twoDBinPacking(binSizeX, binSizeY, aList) of me
　　if aRes = false then return false
　　
　　tell application "Keynote"
　　　　tell front document
　　　　　　tell current slide
　　　　　　　　repeat with i in aRes
　　　　　　　　　　set {posX, posY} to myPos of i
　　　　　　　　　　set itemIndex to myID of i
　　　　　　　　　　set aDeg to myDegree of i
　　　　　　　　　　
　　　　　　　　　　–sample data {itemCounter:5, myWidth:573, myHeight:52, myArea:29796}
　　　　　　　　　　set anObjID to itemCounter of (item itemIndex of aList)
　　　　　　　　　　
　　　　　　　　　　set rotation of iWork item anObjID to aDeg
　　　　　　　　　　set position of iWork item anObjID to {posX, posY}
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　return true
end packKeynoteObjectsOnCurrentSlide

on twoDBinPacking(binSizeX as integer, binSizeY as integer, boxList as list)
　　set aParamList to {binSizeX, binSizeY}
　　
　　repeat with i in boxList
　　　　–copy i to {tmpID, tmpX, tmpY, tmpArea}
　　　　— {itemCounter:iCount, myWidth:aWidth, myHeight:aHeight, myArea:anArea}
　　　　set tmpID to itemCounter of i
　　　　set tmpX to myWidth of i
　　　　set tmpY to myHeight of i
　　　　set tmpArea to myArea of i
　　　　
　　　　set aParamList to aParamList & tmpX
　　　　set aParamList to aParamList & tmpY
　　end repeat
　　
　　set aParam to retDelimitedText(aParamList, " ") of me
　　–> "800 800 340 243 340 73 340 73 155 240 147 125 147 125 147 125 147 125"
　　
　　–Parameters for result parsing
　　set s1Str to "Packed to (x,y)=("
　　set s2Str to ")"
　　set s3Str to ","
　　
　　set cpuRes to CPU type of (system info)
　　if cpuRes begins with "ARM" then
　　　　set exName to "arm"
　　else if cpuRes begins with "Intel" then
　　　　set exName to "x86"
　　end if
　　
　　set binName to "BinPackTest_" & exName
　　set aPath to POSIX path of (path to resource binName)
　　
　　try
　　　　set aRes to do shell script quoted form of aPath & " " & aParam
　　on error
　　　　return false
　　end try
　　
　　if aRes does not end with "Done. All rectangles packed." then return false
　　
　　set aList to paragraphs of aRes
　　
　　set bList to {}
　　set aCount to 1
　　repeat with i in aList
　　　　set j to contents of i
　　　　if j begins with "Packing rectangle of size " and j does not contain "Failed!" then
　　　　　　set xyRes to pickUpFromToStrAndParse(j, s1Str, s2Str, s3Str) of me
　　　　　　
　　　　　　–RectangleBinPackがオブジェクトの回転をサポートしているため、その対処
　　　　　　if xyRes is not equal to false then
　　　　　　　　set s11Str to "(w,h)=("
　　　　　　　　set s12Str to ")"
　　　　　　　　set s13Str to ","
　　　　　　　　
　　　　　　　　set whRes to pickUpFromToStrAndParse(j, s11Str, s12Str, s13Str) of me
　　　　　　　　set tmpBox to item aCount of boxList
　　　　　　　　
　　　　　　　　— {itemCounter:5, myWidth:573, myHeight:52, myArea:29796}
　　　　　　　　–copy tmpBox to {tmpID, tmpX, tmpY, tmpArea}
　　　　　　　　set tmpID to itemCounter of tmpBox
　　　　　　　　set tmpX to myWidth of tmpBox
　　　　　　　　set tmpY to myHeight of tmpBox
　　　　　　　　set tmpArea to myArea of tmpBox
　　　　　　　　
　　　　　　　　if whRes = {tmpX, tmpY} then
　　　　　　　　　　set aDeg to 0
　　　　　　　　else if whRes = {tmpY, tmpX} then
　　　　　　　　　　set aDeg to 90
　　　　　　　　else
　　　　　　　　　　return false
　　　　　　　　end if
　　　　　　　　
　　　　　　　　set the end of bList to {myPos:xyRes, myID:aCount, myDegree:aDeg}
　　　　　　end if
　　　　　　set aCount to aCount + 1
　　　　end if
　　end repeat
　　
　　return bList
end twoDBinPacking

on pickUpFromToStrAndParse(aStr as string, s1Str as string, s2Str as string, s3Str as string)
　　set a1Offset to offset of s1Str in aStr
　　if a1Offset = 0 then return false
　　set bStr to text (a1Offset + (length of s1Str)) thru -1 of aStr
　　
　　set a2Offset to offset of s2Str in bStr
　　if a2Offset = 0 then return false
　　
　　set cStr to text 1 thru (a2Offset – (length of s2Str)) of bStr
　　set {x, y} to parseByDelim(cStr, s3Str) of me
　　
　　return {x as integer, y as integer}
end pickUpFromToStrAndParse

on parseByDelim(aData, aDelim)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set dList to text items of aData
　　set AppleScript’s text item delimiters to curDelim
　　return dList
end parseByDelim

–リストを指定デリミタでテキスト化
on retDelimitedText(aList, aNewDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aNewDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retDelimitedText

on retRectsFromKeynote()
　　tell application "Keynote"
　　　　tell front document
　　　　　　tell current slide
　　　　　　　　set tList to every iWork item
　　　　　　　　set bList to {}
　　　　　　　　set iCount to 1
　　　　　　　　
　　　　　　　　repeat with i in tList
　　　　　　　　　　set aWidth to width of i
　　　　　　　　　　set aHeight to height of i
　　　　　　　　　　set {xPos, yPos} to position of i
　　　　　　　　　　set anArea to aWidth * aHeight
　　　　　　　　　　
　　　　　　　　　　set the end of bList to {itemCounter:iCount, myWidth:aWidth, myHeight:aHeight, myArea:anArea}
　　　　　　　　　　set iCount to iCount + 1
　　　　　　　　end repeat
　　　　　　　　
　　　　　　　　return {tList, bList}
　　　　　　end tell
　　　　end tell
　　end tell
end retRectsFromKeynote

–入れ子のリストを降順ソート
on sortList2DDecending(a, keyLabelList)
　　set fLen to length of keyLabelList
　　set fList to {}
　　
　　repeat fLen times
　　　　set the end of fList to false
　　end repeat
　　
　　return cocoaSortListAscending(a, keyLabelList, fList) of me
end sortList2DDecending

–Cocoaで入れ子のリストをソート true:昇順、false:降順
on cocoaSortListAscending(theList as list, keyLabelList as list, ascendingF as list)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:(theList)
　　
　　set sortDesc to {}
　　set dLen to length of keyLabelList
　　repeat with i from 1 to dLen
　　　　set tmpKeyLabel to contents of item i of keyLabelList
　　　　set tmpSortF to contents of item i of ascendingF
　　　　set theDescriptor to (current application’s NSSortDescriptor’s sortDescriptorWithKey:(tmpKeyLabel) ascending:(tmpSortF))
　　　　set the end of sortDesc to theDescriptor
　　end repeat
　　
　　set sortedList to anArray’s sortedArrayUsingDescriptors:(sortDesc)
　　
　　return sortedList as list
end cocoaSortListAscending

★Click Here to Open This Script　

Keynoteで選択中のGroup内オブジェクトを座標でソートし、テキスト抜き出し

Posted on 5月 15, 2022 by Takaaki Naganoya

Keynote v12.0以降でオープン中の最前面の書類の、表示中のスライド（ページ）上で選択中のグループから、その内部に収められているオブジェクトからテキストを取り出し、リスト（配列）にまとめるAppleScriptです。

▲書類上のオブジェクト（グループ）を選択した状態

▲１冊分のデータがグループにまとめられており、グループ内にオブジェクトを格納

いったんデータを組み上げた「書類」からデータを抜き出すのは、AppleScriptの重要な仕事です。各データ内のフィールドについて座標情報から自動判別するようにしていますが、座標値が想定どおりになっていない場合もあるため、これでもまだ不十分なので、相対的な位置関係（左上、右上、下　などといった）を定義してデータを取り出すようにするとよいでしょう。

……そこまで高度なものを作らなくても、文字列の長さに着目してソートしたら瞬殺でした。

AppleScript名：選択中のGroup内オブジェクトを座標でソートし、テキスト抜き出し.scpt

use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

script spd
　　property allList : {}
　　property aaSel : {}
end script

set (allList of spd) to {}

tell application "Keynote"
　　set aVer to version
　　if aVer < "12.0" then return
　　
　　set acceptClass to {text item, shape}
　　
　　tell front document
　　　　set (aaSel of spd) to selection –need Keynote v12.0 or later
　　　　
　　　　repeat with i in (aaSel of spd)
　　　　　　set j to contents of i
　　　　　　set aClass to class of j
　　　　　　
　　　　　　if aClass = group then
　　　　　　　　tell j
　　　　　　　　　　set gItemList to every iWork item
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　set posList to {}
　　　　　　　　set aCount to 1
　　　　　　　　
　　　　　　　　repeat with ii in gItemList
　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　set bClass to class of jj
　　　　　　　　　　
　　　　　　　　　　if bClass is in acceptClass then
　　　　　　　　　　　　tell jj
　　　　　　　　　　　　　　set {posX, posY} to position
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　try
　　　　　　　　　　　　　　　　set tmpStr to object text as string
　　　　　　　　　　　　　　on error
　　　　　　　　　　　　　　　　set tmpStr to ""
　　　　　　　　　　　　　　end try
　　　　　　　　　　　　end tell
　　　　　　　　　　　　
　　　　　　　　　　　　set the end of posList to {positionX:posX, positionY:posY, objID:aCount, myStr:tmpStr}
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　　　set aCount to aCount + 1
　　　　　　　　end repeat
　　　　　　　　
　　　　　　　　–座標データをもとにソート
　　　　　　　　set sortedList to sortRecListByLabel(posList, {"positionY", "positionX"}, {true, true}) of me
　　　　　　　　
　　　　　　　　–１グループ分のテキストを組み立てる
　　　　　　　　set tmpList to {}
　　　　　　　　repeat with ii in sortedList
　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　set aStr to myStr of jj
　　　　　　　　　　set the end of tmpList to aStr
　　　　　　　　end repeat
　　　　　　　　set the end of (allList of spd) to tmpList
　　　　　　end if
　　　　end repeat
　　end tell
end tell

return (allList of spd)
–> {{"変数名", "❺", "意外と苦労している人が多い、変数やプロパティ名の命名ルール。とくに、予約語と衝突しない名前について"}, {"条件分岐", "❼", "条件分岐はプログラムに必須。自転車でいえば、カーブで曲がれないとか、水たまりを避けられないぐらい困ります。"}, {"用語辞書", "❹", "読めないと書けない、でも、あの人もこの人も読めない用語辞書。自由自在に読めれば、自由自在に書ける！"}, {"ループ処理", "➓", "プログラムをシンプルに書くための一番大事な構文。書き方によって速度が違ったり、高度な処理を簡潔に書ける！"}, {"アプレット", "⓫", "AppleScriptをアプリケーションとして書き出す、簡易アプリケーション「アプレット」の最新動向！"}, {"間接指定", "❶", "対象としたデータだけでなく、幅広いデータに対応できるよう、プログラムに柔軟性を与える間接指定"}, {"ダイアログ表示", "❾", "簡単に行えるメッセージ表示手段。外部ライブラリの利用でさらなる高機能ダイアログを紹介。"}, {"環境整備", "❽", "macOSに標準で入っているツールを呼び出しやすくしたり設定したりする程度。全体像を掴んでレッツ環境整備。"}, {"フィルタ参照", "❻", "AppleScript独特の概念で、「膨大なデータから正規表現で絞り込む」などの他の処理系と異なる、基礎にして奥義"}, {"tellブロック", "❷", "AppleScriptの７割以上を占める、tellブロックの記述や整理方法を楽に書く秘訣のかずかず"}, {"❸", "ファイルパス", "まさに「基礎」中の「基礎」。「できて当たり前」といえるパス操作。知っているだけで差がつく基礎"}}

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as list, ascendF as list)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　set aCount to length of aLabelStr
　　set sortDescArray to current application’s NSMutableArray’s new()
　　repeat with i from 1 to aCount
　　　　set aLabel to (item i of aLabelStr)
　　　　set aKey to (item i of ascendF)
　　　　set sortDesc to (current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabel ascending:aKey)
　　　　(sortDescArray’s addObject:sortDesc)
　　end repeat
　　
　　return (aArray’s sortedArrayUsingDescriptors:sortDescArray) as list
end sortRecListByLabel

★Click Here to Open This Script　

Keynoteで選択中のオブジェクトを取得して座標でソート

Posted on 4月 10, 2022 by Takaaki Naganoya

Keynote 12.0でまともになった「selection」を使って、選択状態にあるKeynote書類上のオブジェクト（text item）をX座標、Y座標でソートするAppleScriptです。

--> {{objID:2, positionY:219, myCon:"①①①①①", positionX:184}, {objID:4, positionY:492, myCon:"❷❷❷❷❷", positionX:184}, {objID:1, positionY:219, myCon:"③③③③③", positionX:1047}, {objID:3, positionY:492, myCon:"❹❹❹❹❹", positionX:1047}}

選択したtext itemを座標で並べ替え、内容を個別に評価してファイル書き出しするAppleScriptを別途用意して書籍作成用のツールとして、使っています。

書籍の作成作業用に作ったので、アホみたいに高機能です。text itemの内容をAppleScriptとして構文確認して、AppleScriptのオブジェクトを生成し、中間言語コードに解釈ずみの.scptファイルとして書き出しています（書籍のサンプルScript生成用）。こういうツールを作ってすぐに実戦投入できるのも、Keynoteのselectionがまともになったおかげです。

–> Watch Demo Movie

AppleScript名：選択中のオブジェクトを座標をもとにソート.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/04/09
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Keynote"
　　tell front document
　　　　set aaSel to selection
　　　　set posList to {}
　　　　set aCount to 1
　　　　
　　　　repeat with i in aaSel
　　　　　　set j to contents of i
　　　　　　set mySource to object text of j
　　　　　　
　　　　　　tell j
　　　　　　　　set {posX, posY} to position
　　　　　　end tell
　　　　　　
　　　　　　set the end of posList to {positionX:posX, positionY:posY, objID:aCount, myCon:mySource}
　　　　　　
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　　　
　　end tell
end tell

set zList to sortRecListByLabel(posList, {"positionX", "positionY"}, {true, true}) of me

★Click Here to Open This Script　

M1 Mac miniのベンチマーク 1万要素の1次元配列ソート

Posted on 6月 21, 2021 by Takaaki Naganoya

M1 Mac miniを使ってみて、「なーんかMacBook Pro Retina 2012とかわんねーなー」と感じていましたが、本当にそんな感じでした。

＃　後日、詳細に検証したところM1 Mac＋macOS 11.xではAppleScriptからのCocoa呼び出しが大幅に遅くなっていることが判明。処理性能重視のメインCPUコアではなく、省エネのサブCPUコアで実行されていることがわかり、これをAppleにレポートしてmacOS 12からはAppleScript＋Cocoa呼び出しの処理速度が大幅に改善されました

Webブラウザの動作とかディスクI/Oなど、キビキビ動いて快適なのですが、AppleScriptを書いて動かしてみると……GUIアプリの操作は速い（Mac mini 2014比で2〜3倍速い）のですが、Cocoa Scriptingしていると速くなった感じがしません。

Xcode上でCocoa AppleScriptアプリケーションを書いて動かしてみると、冒頭のような感想になります。

机の上にマシンが５台ぐらい並んでおり、これらすべてでベンチマークを実施。体感速度を裏付ける結果が出ました。

#　MacBook Air 2011のベンチマーク計測が抜けていました、、、、

上から３番目のマシンは仲間からの借り物の検証用マシンで、前主力環境のMacBook Pro Retina 2012とは別物で、HDDで動作しているマシンです。macOS 10.15の動作確認用マシンで、MacBook Pro Retina 2012よりも少しCPUが速いマシンでもあります。

なので、MacBook Pro Retina 2012をmacOS 10.15にアップデートすると、ほぼこれと同じ結果になるはずです（もったいなくてアップデートしませんが）。

macOS 10.14から10.15に移行したときに「全体的に速度が遅くなった」との証言をShane Stanleyからももらっています。

全体的な傾向として、「macOS 10.15で大幅な速度低下があり、その低下分をM1 Macのハードウェアとしての速さが穴埋めしている」という印象。macOS 10.15はBeta段階で「こんなのはダメ、使い物にならない」と判断し、パスして10.14を使い続けるという判断を行なっていました。

搭載メモリはM1 Mac miniとMac mini 2014が16GB、MacBook Pro 2012とMacBook Pro Retina 2012が8GBです。

AppleScript名：ASで1D Listをソート（１万件）

use AppleScript version "2.7"
use framework "Foundation"
use scripting additions

script spd
　　property aList : {}
　　property aRes : {}
　　property bRes : {}
end script

set (aRes of spd) to {}
set (bRes of spd) to {}

–テスト用データリストの作成（1万アイテム）
set (aList of spd) to {}
repeat with i from 1 to 10000
　　set the end of (aList of spd) to (random number from 10000 to 99999)
end repeat

–昇順ソートの時間計測
set a1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()

set (aRes of spd) to sort1DList_ascOrder_((aList of spd), true)

set b1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()

set c1Dat to b1Dat – a1Dat

–降順ソートの時間計測
set a2Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()

set (bRes of spd) to sort1DList_ascOrder_((aList of spd), false)

set b2Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
set c2Dat to b2Dat – a2Dat

return {c1Dat, c2Dat}

–1D Listをsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DList:theList ascOrder:aBool
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"compare:"
　　set theArray to current application’s NSArray’s arrayWithArray:theList
　　return (theArray’s sortedArrayUsingDescriptors:{aDdesc}) as list
end sort1DList:ascOrder:

★Click Here to Open This Script　

AMChartsで円グラフをダイアログ上に表示 v3

Posted on 6月 27, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを作成し、その上でAMChartsによる円グラフを表示するAppleScriptです。

ダイアログでテーマ選択したのちに、グラフ表示を行います。

—> Download ampiechartSample(AppleScript bundle with Script Library and HTMLs)

AppleScript名：AMChartsで円グラフをダイアログ上に表示 v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/06/25
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use webD : script "webDialogLib"

set themeList to {"dark", "dataviz", "material", "kelly", "frozen", "moonrisekingdom", "spiritedaway"}

set aSel to (choose from list themeList with prompt "Select Theme")
if aSel = false then
　　set aTheme to false
　　set aHTML to "index_notheme.html"
else
　　set aTheme to contents of first item of aSel
　　if aTheme = "dark" then
　　　　set aTheme to false
　　　　set aHTML to "index_dark.html"
　　else
　　　　set aHTML to "index.html"
　　end if
end if

set aList to {{label:"ひよこ王国", value:403}, {label:"ぴよぴよ連邦", value:301}, {label:"ぴよランド", value:101}, {label:"ぴよー", value:65}}
set bList to sortRecListByLabel(aList, {"value"}, {false}) of me –降順ソート

–https://www.amcharts.com/demos/pie-chart/
set mePath to path to me
set resPath to (mePath as string) & "Contents:Resources:" & aHTML
set myStr to (read (resPath as alias) as «class utf8») as string

set jsonStr to array2DToJSONArray(bList) of me as string

if aTheme = false then
　　set aString to current application’s NSString’s stringWithFormat_(myStr, jsonStr) as string
else
　　set aString to current application’s NSString’s stringWithFormat_(myStr, aTheme, aTheme, jsonStr) as string
end if

set paramObj to {myMessage:"Simple Pie Chart", mySubMessage:"This is a AMCharts test", htmlStr:aString, jsDelimiters:{"<script>", "</script>"}, viewSize:{1000, 550}}

webD’s displayWebDialog(paramObj)

on array2DToJSONArray(aList)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　set jsonData to current application’s NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value)
　　set resString to current application’s NSString’s alloc()’s initWithData:jsonData encoding:(current application’s NSUTF8StringEncoding)
　　return resString
end array2DToJSONArray

★Click Here to Open This Script　

アラートダイアログ上にWebViewでGoogle Chartsを表示（Calendar Chart）

Posted on 5月 7, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを配置し、Google Chartsを用いてCalendar Chartを表示するAppleScriptです。

自分の開発環境（MacBook Pro Retina 2012, Core i7 2.6GHz）で100日間のアクセス履歴を処理して７秒強ぐらいで描画が終了します。

調子に乗って300日分のアクセス履歴を処理したところ、表示まで１分ほどかかりました。あまり長い期間の描画を行わせるのは（このプログラムの書き方だと）向いていないと感じます。いまのところテストしただけで実用性は考えていませんが、この程度のグラフなら自前でNSImage上にボックスを描画して表示しても大した手間にはならないでしょう。

▲スクリプトエディタ上で実行したところ

▲Script Debugger上で実行したところ

▲スクリプトメニュー上で実行したところ

Safariのアクセス履歴は例によってsqliteのDatabaseにアクセスして取得していますが、AppleScriptのランタイム環境によっては、アクセス権限がないというメッセージが出てアクセスできないことがあります。ASObjC Explorer 4上では実行できませんでしたし、Switch Control上でも実行できません。

＃　管理者権限つきで実行しても（with administrator privileges）実行できません　→ Switch Controlでも実行できるようになりました

最初に掲載したバージョンでは、グラフ化したときに表示月が１か月ズレるという問題がありました。

Google Chartsのドキュメントを確認したところ、

Note: JavaScript counts months starting at zero: January is 0, February is 1, and December is 11. If your calendar chart seems off by a month, this is why.

JavaScriptでMonthはJanuaryが0らしく、monthを-1する必要があるとdocumentに書かれていました。うわ、なにその仕様？（ーー；；；

AppleScript名：アラートダイアログ上にWebViewでGoogle Chartを表示（Calendar Charts）v1a.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/07
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSAlert : a reference to current application’s NSAlert
property NSString : a reference to current application’s NSString
property NSButton : a reference to current application’s NSButton
property WKWebView : a reference to current application’s WKWebView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property WKUserContentController : a reference to current application’s WKUserContentController
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property returnCode : 0

script spd
　　property aRes : {}
　　property bRes : {}
end script

–Calculate Safari access frequency for (parameter days)
set (aRes of spd) to calcMain(100) of safariHistLib

set (bRes of spd) to ""
repeat with i in (aRes of spd)
　　set {item1, item2, item3} to parseByDelim(theName of (contents of i), "-") of me
　　set newLine to " [ new Date(" & (item1 as string) & ", " & ((item2 – 1) as string) & ", " & (item3 as string) & "), " & (numberOfTimes of i) & "]," & (string id 10)
　　set (bRes of spd) to (bRes of spd) & newLine
end repeat

set (bRes of spd) to text 1 thru -3 of (bRes of spd)

–Pie Chart Template HTML
set myStr to "<!DOCTYPE html>
<html lang=＼"UTF-8＼">
<head>
<div id=＼"calendarchart＼"></div>

// Draw the chart and set the chart values
function drawChart() {
var dataTable = new google.visualization.DataTable();
dataTable.addColumn({ type: ’date’, id: ’Date’ });
dataTable.addColumn({ type: ’number’, id: ’Web Access’ });
dataTable.addRows([
　　%@
]);

var chart = new google.visualization.Calendar(document.getElementById(’calendar_basic’));

var options = {
title: ＼"Web Activity＼",
height: 350,
};

chart.draw(dataTable, options);
}
</script>
</head>
<body>
　　<div id=＼"calendar_basic＼" style=＼"width: 1000px; height: 350px;＼"></div>
</body>
</html>"

set aString to current application’s NSString’s stringWithFormat_(myStr, (bRes of spd)) as string

set paramObj to {myMessage:"Calendar Chart Test", mySubMessage:"This is a simple calendar chart using google charts", htmlStr:aString}
–my browseStrWebContents:paramObj–for debug
my performSelectorOnMainThread:"browseStrWebContents:" withObject:(paramObj) waitUntilDone:true

on browseStrWebContents:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set htmlString to (htmlStr of paramObj)
　　
　　set aWidth to 1000
　　set aHeight to 300
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定HTML内のJavaScriptをFetch
　　set jsSource to pickUpFromToStr(htmlString, "<script type=＼"text/javascript＼">", "</script>") of me
　　
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 100)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s fileURLWithPath:(POSIX path of (path to me))
　　aWebView’s loadHTMLString:htmlString baseURL:(bURL)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　–its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aWebView
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　if (my returnCode as number) = 1001 then error number -128
end browseStrWebContents:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

on fetchJSSourceString(aURL)
　　set jsURL to |NSURL|’s URLWithString:aURL
　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　return jsSourceString
end fetchJSSourceString

on pickUpFromToStr(aStr as string, s1Str as string, s2Str as string)
　　set a1Offset to offset of s1Str in aStr
　　if a1Offset = 0 then return false
　　set bStr to text (a1Offset + (length of s1Str)) thru -1 of aStr
　　set a2Offset to offset of s2Str in bStr
　　if a2Offset = 0 then return false
　　set cStr to text 1 thru (a2Offset – (length of s2Str)) of bStr
　　return cStr as string
end pickUpFromToStr

–リストを任意のデリミタ付きでテキストに
on retArrowText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retArrowText

on array2DToJSONArray(aList)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　set jsonData to current application’s NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value) –0 is
　　set resString to current application’s NSString’s alloc()’s initWithData:jsonData encoding:(current application’s NSUTF8StringEncoding)
　　return resString
end array2DToJSONArray

script safariHistLib
　　property parent : AppleScript
　　use scripting additions
　　use framework "Foundation"
　　
　　property |NSURL| : a reference to current application’s |NSURL|
　　
　　script spd
　　　　property sList : {}
　　　　property nList : {}
　　　　property sRes : {}
　　　　property dRes1 : {}
　　　　property dRes2 : {}
　　end script
　　
　　
　　on calcMain(daysNum)
　　　　set (dRes1 of spd) to dumpSafariHistoryFromDaysBefore(daysNum) of me
　　　　
　　　　set (dRes2 of spd) to {}
　　　　repeat with i in (dRes1 of spd)
　　　　　　copy (first item of i) as string to dStr
　　　　　　set convDstr to first item of (parseByDelim(dStr, {" "}) of me)
　　　　　　set the end of (dRes2 of spd) to convDstr
　　　　end repeat
　　　　
　　　　–日付ごとに登場頻度集計
　　　　set cRes to countItemsByItsAppearance2((dRes2 of spd)) of me
　　　　return cRes as list
　　end calcMain
　　
　　
　　–NSArrayに入れたレコードを、指定の属性ラベルの値でソート
　　on sortRecListByLabel(aArray, aLabelStr as string, ascendF as boolean)
　　　　–ソート
　　　　set sortDesc to current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabelStr ascending:ascendF
　　　　set sortDescArray to current application’s NSArray’s arrayWithObjects:sortDesc
　　　　set sortedArray to aArray’s sortedArrayUsingDescriptors:sortDescArray
　　　　
　　　　–NSArrayからListに型変換して返す
　　　　set bList to (sortedArray) as list
　　　　return bList
　　end sortRecListByLabel
　　
　　
　　on dumpSafariHistoryFromDaysBefore(daysBefore)
　　　　–現在日時のn日前を求める
　　　　using terms from scripting additions
　　　　　　set origDate to (current date) – (daysBefore * days)
　　　　end using terms from
　　　　
　　　　set dStr to convDateObjToStrWithFormat(origDate, "yyyy-MM-dd hh:mm:ss") of me
　　　　
　　　　set aDBpath to "~/Library/Safari/History.db"
　　　　set pathString to current application’s NSString’s stringWithString:aDBpath
　　　　set newPath to pathString’s stringByExpandingTildeInPath()
　　　　
　　　　set aText to "/usr/bin/sqlite3 " & newPath & " ’SELECT datetime(history_visits.visit_time+978307200, ＼"unixepoch＼", ＼"localtime＼"), history_visits.title || ＼" @ ＼" || substr(history_items.URL,1,max(length(history_items.URL)*(instr(history_items.URL,＼" & ＼")=0),instr(history_items.URL,＼" & ＼"))) as Info FROM history_visits INNER JOIN history_items ON history_items.id = history_visits.history_item where history_visits.visit_time>(julianday(＼"" & dStr & "＼")*86400-211845068000) ORDER BY visit_time ASC LIMIT 999999;’"
　　　　
　　　　using terms from scripting additions
　　　　　　set (sRes of spd) to do shell script aText
　　　　end using terms from
　　　　
　　　　set (sList of spd) to (paragraphs of (sRes of spd))
　　　　
　　　　repeat with i in (sList of spd)
　　　　　　set j to contents of i
　　　　　　
　　　　　　–Parse each field
　　　　　　set j2 to parseByDelim(j, {"|", "@ "}) of me
　　　　　　
　　　　　　set the end of (nList of spd) to j2
　　　　end repeat
　　　　
　　　　return (nList of spd)
　　end dumpSafariHistoryFromDaysBefore
　　
　　
　　
　　on parseByDelim(aData, aDelim)
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to aDelim
　　　　set dList to text items of aData
　　　　set AppleScript’s text item delimiters to curDelim
　　　　return dList
　　end parseByDelim
　　
　　
　　–出現回数で集計
　　on countItemsByItsAppearance2(aList)
　　　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　　　set bArray to current application’s NSMutableArray’s array()
　　　　set theEnumerator to aSet’s objectEnumerator()
　　　　
　　　　repeat
　　　　　　set aValue to theEnumerator’s nextObject()
　　　　　　if aValue is missing value then exit repeat
　　　　　　bArray’s addObject:(current application’s NSDictionary’s dictionaryWithObjects:{aValue, (aSet’s countForObject:aValue)} forKeys:{"theName", "numberOfTimes"})
　　　　end repeat
　　　　
　　　　–出現回数（numberOfTimes）で降順ソート
　　　　set theDesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"theName" ascending:true
　　　　bArray’s sortUsingDescriptors:{theDesc}
　　　　
　　　　return bArray
　　end countItemsByItsAppearance2
　　
　　
　　on convDateObjToStrWithFormat(aDateO as date, aFormatStr as string)
　　　　set aDF to current application’s NSDateFormatter’s alloc()’s init()
　　　　
　　　　set aLoc to current application’s NSLocale’s currentLocale()
　　　　set aLocStr to (aLoc’s localeIdentifier()) as string
　　　　
　　　　aDF’s setLocale:(current application’s NSLocale’s alloc()’s initWithLocaleIdentifier:aLocStr)
　　　　aDF’s setDateFormat:aFormatStr
　　　　set dRes to (aDF’s stringFromDate:aDateO) as string
　　　　return dRes
　　end convDateObjToStrWithFormat
　　
end script

★Click Here to Open This Script　

テキストから数値を抽出して度数分布集計 v3

Posted on 6月 29, 2019 by Takaaki Naganoya

CotEditorで編集中の最前面の書類の本文中から指定桁の数値を抽出して登場回数で度数分布の集計を行うAppleScriptです。

初版では、集計対象の数値を桁数で指定するという（使うのに）無茶な仕様になっていたので、この頭の悪い仕様に作った本人もめまいがしていました。

わざわざAppleScriptを使うのは、他のどの環境でも追いつけない高度な処理を行うことに意義があると思っています。

そこで、

　（１）数字部分をあらかじめ抽出して事前に集計（分布および最小値、最大値を計算）
　（２）事前集計結果をグラフ表示
　（３）集計対象の数字の範囲を最小値〜最大値までの間で指定できるように
　（４）パラメータの入力、および事前集計結果の表示を自前で作成したアラートダイアログで表示

といった変更を加えてみました。初版では「数字の桁数」というご無体な指定で数字を抽出していましたが、最初に最大値を計算しておいたことで、最大値の桁数ですべて数値を抽出し、最小値・最大値の間に収まる数値のみを抽出して度数分布を再計算しています（言うほど計算結果が変わってきたりはしないんですけど　＾ー＾；；）。

このぐらい行えば、安心して見られる感じでしょうか。

追記：
4.11といった文字が「4」と「11」に分離して認識されるようだったので数値として認識するCharacter setに「.」（小数点）および「,」（桁数区切り）を追加してみました。想定していた部分はうまくクリアしたものの、「REV.」の部分の「.」も認識して「0.411」のような数値として認識したようです。

このあたりに課題を残しつつも、全体として見ると当初からノイズとして除去する対象として考えていた箇所でもあったため、そんなもんだろうかと。

アラートダイアログに表示するテスト集計結果の文字が小さかったので、少し大きくしてみました。フォントについては「ヒラギノ角ゴシック W1」（PostScript名は「HiraginoSans-W1」）を指定しています。このあたりは好みに応じて変更してみるとよいでしょう。

巨大なテキスト（青空文庫の小説１作文まるごととか）を対象に処理していないので（画面キャプチャ掲載している程度のサイズ）そういう配慮は行っていません。仕事だと考慮しないでもないですが、必要と思われた処理をとりあえず組んでみた程度なので、そういうものだとお考えください。

–> Download Applet With Libraries (mainly for macOS 10.14 or later)

AppleScript名：テキストから数値を抽出して度数分布集計 v3.1

— Created 2019-06-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextField : a reference to current application’s NSTextField
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication

–property theResult : 0
property returnCode : 0
property segRes : missing value

set segRes to missing value

tell application "CotEditor"
　　if (count every document) = 0 then return –No Document
　　
　　tell front document
　　　　set aText to contents of it
　　　　set lineTerm to (line ending)
　　end tell
　　
　　–改行コードの選択（ドキュメントの状態から取得）
　　if lineTerm = LF then
　　　　set aRet to ASCII character 10 –To avoid keyword conflict (string)
　　else if lineTerm = CR then
　　　　set aRet to ASCII character 13
　　else if lineTerm = CRLF then
　　　　set aRet to (ASCII character 13) & (ASCII character 10)
　　else
　　　　set aRet to ASCII character 10
　　end if
end tell

–事前にテキストから自動で数値部分を抽出して分析
set cArray to extractNumberFromText(aText) of me
set aRes to (cArray’s valueForKeyPath:"@max.self")’s intValue()
set bRes to (cArray’s valueForKeyPath:"@min.self")’s intValue()
set cRes to (cArray’s valueForKeyPath:"@count")’s intValue()

–事前に数字の分布シミュレーションを計算
set tmpLen to count every character of (aRes as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set sampleStr to calculateNumFreq(cArray, "■", aRet, bRes, aRes, true) of me

set sampleStr to return & return & "テスト集計結果：" & return & return & sampleStr

–テキストからの数値抽出時のパラメータ取得
set paramObj to {myMessage:"テキスト内の数値の度数分布集計", mySubMessage:"集計対象の数値の範囲と、集計時のグラフ生成時の構成文字を指定してください", mes1:"最小値（min.）", mes1Default:(bRes as string), mes2:"最大値（max.）", mes2Default:(aRes as string), mes3:"出力文字", mes3Default:"絆", aSample:sampleStr}

–set segRes to my inputParametersFromAlertDialog:paramObj–for debugging
my performSelectorOnMainThread:"inputParametersFromAlertDialog:" withObject:(paramObj) waitUntilDone:true
if segRes = missing value then return –Cancel

–度数分布計算
set tmpLen to count every character of ((a2Res of segRes) as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set outStr to calculateNumFreq(cArray, a3Res of segRes, aRet, a1Res of segRes, a2Res of segRes, false) of me

–テキストエディタへの集計結果出力
tell application "CotEditor"
　　tell front document
　　　　set contents of it to (aText & aRet & aRet & "集計結果：" & aRet & aRet & outStr & aRet)
　　end tell
end tell

on inputParametersFromAlertDialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mes1Label to (mes1 of paramObj) as string –Text Input field 1 Label
　　set mes2Label to (mes2 of paramObj) as string –Text Input field 2 Label
　　set mes3Label to (mes3 of paramObj) as string –Text Input field 3 Label
　　set aTextInputString to (mes1Default of paramObj) as string –Text Input field 1 Default value
　　set bTextInputString to (mes2Default of paramObj) as string –Text Input field 2 Default value
　　set cTextInputString to (mes3Default of paramObj) as string –Text Input field 2 Default value
　　set sampleString to (aSample of paramObj) as string
　　
　　— Create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 500, 400))
　　
　　— create two input field and their labels pairs
　　–NSTextFields for Input
　　set aTextInput to makeNSTextField(100, 70, 140, 20, true, (aTextInputString), true, true) of me
　　set bTextInput to makeNSTextField(100, 35, 140, 20, true, (bTextInputString), true, true) of me
　　set cTextInput to makeNSTextField(100, 0, 140, 20, true, (cTextInputString), true, true) of me
　　
　　–Labels
　　set a1TF to makeNSTextField(0, 70, 100, 20, false, (mes1Label), false, false) of me
　　set a2TF to makeNSTextField(0, 35, 100, 20, false, (mes2Label), false, false) of me
　　set a3TF to makeNSTextField(0, 0, 100, 20, false, (mes3Label), false, false) of me
　　
　　–Sample Text View
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.9
　　set tvScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 300))
　　set tvView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 380))
　　tvView’s setRichText:true
　　tvView’s useAllLigatures:true
　　tvView’s setTextColor:(NSColor’s cyanColor()) —
　　tvView’s setFont:(current application’s NSFont’s fontWithName:"HiraginoSans-W1" |size|:16.0)
　　tvView’s setBackgroundColor:aColor
　　tvView’s setEditable:false
　　
　　tvScroll’s setDocumentView:tvView
　　tvView’s enclosingScrollView()’s setHasVerticalScroller:true
　　tvView’s setString:(sampleString)
　　
　　
　　theView’s setSubviews:{a1TF, aTextInput, a2TF, bTextInput, a3TF, cTextInput, tvScroll}
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then
　　　　set my segRes to missing value
　　else
　　　　set s1Val to (aTextInput’s integerValue()) as integer
　　　　set s2Val to (bTextInput’s integerValue()) as integer
　　　　set s3Val to (cTextInput’s stringValue()) as string
　　　　
　　　　–return {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}–old version’s way to return values
　　　　set my segRes to {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}
　　end if
end inputParametersFromAlertDialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–与えられたテキストから数値部分を抽出して1D Arrayで返す
on extractNumberFromText(aText)
　　set aStr to current application’s NSString’s stringWithString:aText
　　–set nonDigitCharacterSet to (current application’s NSCharacterSet’s decimalDigitCharacterSet())’s invertedSet()
　　set nonDigitCharacterSet to (current application’s NSCharacterSet’s characterSetWithCharactersInString:"0123456789.,")’s invertedSet()
　　set bArray to (aStr’s componentsSeparatedByCharactersInSet:nonDigitCharacterSet)
　　
　　–Sweep Blank Items
　　load framework –BridgePlus
　　set cArray to (current application’s SMSForder’s arrayByDeletingBlanksIn:(bArray))’s valueForKey:"intValue"
　　return cArray –return as NSArray
end extractNumberFromText

–正規表現でテキスト中から指定パターンに該当する箇所を抽出してリストで返す
on findPattern:thePattern inString:theString
　　set theOptions to ((current application’s NSRegularExpressionDotMatchesLineSeparators) as integer) + ((current application’s NSRegularExpressionAnchorsMatchLines) as integer)
　　set theRegEx to current application’s NSRegularExpression’s regularExpressionWithPattern:thePattern options:theOptions |error|:(missing value)
　　set theFinds to theRegEx’s matchesInString:theString options:0 range:{location:0, |length|:length of theString}
　　set theFinds to theFinds as list — so we can loop through
　　set theResult to {} — we will add to this
　　set theNSString to current application’s NSString’s stringWithString:theString
　　repeat with i from 1 to count of items of theFinds
　　　　set theRange to (item i of theFinds)’s range()
　　　　set end of theResult to (theNSString’s substringWithRange:theRange) as integer
　　end repeat
　　return theResult
end findPattern:inString:

–1D Listをユニーク化してソート
on uniquifyAndSort1DList(theList as list, aBool as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:theList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"compare:"
　　set cArray to bArray’s sortedArrayUsingDescriptors:{aDdesc}
　　
　　set bList to cArray as list
　　return bList
end uniquifyAndSort1DList

–度数分布集計して文字グラフ出力
on calculateNumFreq(theList, outChar, aLineTerminator, aMin, aMax, zeroPaddingF)
　　set theCountedSet to current application’s NSCountedSet’s alloc()’s initWithArray:theList
　　set newArray to current application’s NSMutableArray’s new()
　　
　　set kList to uniquifyAndSort1DList(theList, false) of me –降順ソート
　　set maxDigit to (count every character of (aMax as string))
　　
　　repeat with i in kList
　　　　if (i ≥ aMin) and (i ≤ aMax) then
　　　　　　(newArray’s addObject:{theKey:i, theCount:(theCountedSet’s countForObject:i)})
　　　　end if
　　end repeat
　　
　　set outStr to ""
　　
　　repeat with i in newArray as list
　　　　set j to (current application’s NSDictionary’s dictionaryWithDictionary:i)
　　　　set tmpStr to (j’s valueForKey:"theKey")
　　　　
　　　　if zeroPaddingF = true then
　　　　　　–Zero Pagging
　　　　　　set keyNumStr to numToZeroPaddingStr(tmpStr, maxDigit, "0") of me
　　　　else
　　　　　　–No Padding
　　　　　　copy (tmpStr as string) to keyNumStr
　　　　end if
　　　　
　　　　set outStr to outStr & keyNumStr & "："
　　　　
　　　　set aNum to (j’s valueForKey:"theCount")
　　　　repeat aNum times
　　　　　　set outStr to outStr & outChar
　　　　end repeat
　　　　
　　　　set outStr to outStr & aLineTerminator
　　end repeat
end calculateNumFreq

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

テキストから指定桁数の数値を抽出して度数分布集計

Posted on 6月 28, 2019 by Takaaki Naganoya

CotEditorで編集中の最前面の書類の本文中から指定桁の数値を抽出して登場回数で度数分布の集計を行うAppleScriptです。

CotEditorのアプリケーション内のスクリプトメニューに入れて実行できることを確認してあります（@macOS 10.14.5）。

たまたま、テキストで集計していた情報のうち、数値部分の度数分布を計算したいと考え、ありもののルーチンを組み合わせて作ったものです。

実行すると、集計対象の数値の桁数を聞いてくるため、適当なものを選択してださい。

CotEditorのScriptingの要注意点で、オブジェクト階層を素直に書いて、当該階層のオブジェクトの属性値を取りたいような場合に、そのまま属性を書いても取得できないケースが見られます。そのため、明示的にオブジェクト階層を指定するために「of it」を書いています。Xcodeが同じような挙動を行うため、注意が必要です。

本Scriptについていえば、正規表現でテキストから情報を抽出したりと、一応最低限のレベルはクリアしているものの、いまひとつ満足できません。

数字が連続して登場している箇所を抽出し、どれを集計対象にするのかといった分析を冒頭で行ってユーザーに問い合わせしたいところです。現段階では、「桁数を聞く」という頭の悪い実装になっていますが、そのうちどうにかしたいと考えるところです。

AppleScript名：テキストから指定桁数の数値を抽出して度数分布集計.scptd

— Created 2019-06-28 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property graphStr : "絆" –グラフに出力する文字

tell application "CotEditor"
　　–最前面の書類からテキスト本文を取得
　　tell front document
　　　　set aText to contents of it –本文
　　　　set lineTerm to (line ending) –改行コード
　　end tell
　　
　　–改行コードの選択（ドキュメントの状態から取得）
　　if lineTerm = LF then
　　　　set aRet to ASCII character 10 –To avoid keyword conflict (string)
　　else if lineTerm = CR then
　　　　set aRet to ASCII character 13
　　else if lineTerm = CRLF then
　　　　set aRet to (ASCII character 13) & (ASCII character 10)
　　else
　　　　set aRet to ASCII character 10
　　end if
end tell

–桁数選択
set digiList to {"2", "3", "4", "5"}
set digitRes to first item of (choose from list digiList with prompt "Choose the digit to extract as numbers")

–正規表現で数字部分のみ抽出
set theList to my findPattern:("[0-9]{" & digitRes & "}") inString:aText

–検出した数字部分の度数分布を計算
set theCountedSet to current application’s NSCountedSet’s alloc()’s initWithArray:theList
set newArray to current application’s NSMutableArray’s new()
set kList to uniquifyAndSort1DList(theList, false) of me –降順ソート

repeat with i in kList
　　(newArray’s addObject:{theKey:i, theCount:(theCountedSet’s countForObject:i)})
end repeat

–出力用のテキストを作成
set outStr to ""
repeat with i in newArray as list
　　set outStr to (outStr & (theKey of i) as string) & "："
　　set aNum to (theCount of i) as integer
　　
　　repeat aNum times
　　　　set outStr to outStr & graphStr
　　end repeat
　　
　　set outStr to outStr & aRet
end repeat

–最前面のテキスト末尾に集計結果を出力
tell application "CotEditor"
　　tell front document
　　　　set contents of it to (aText & aRet & aRet & "集計結果：" & aRet & aRet & outStr & aRet)
　　end tell
end tell

★Click Here to Open This Script　

Keynoteで表示中のスライド上の表を２つ、横方向に連結する

Posted on 5月 21, 2019 by Takaaki Naganoya

Keynoteでオープン中の書類の表示中のスライド（ページ）上にある表を２つ選択して、横方向に連結するAppleScriptです。

Keynoteで資料を作っていて、あまりにこういう処理が多いのでScript化しました。縦方向に連結してもいいのですが（最初は連結方向を選択させかけた）、実際に扱っている表が横長のケースが（個人的に）多いので「横連結だけでいいや」ということに。

▲マージ対象の表

▲現在表示中のスライド（ページ）中に存在している表のタイトルが一覧表示される。座標位置をもとに上→下、左→右とソートした順で表示

▲複数項目を選択する場合にはCommandキーを押しながら選択

▲２つの表を横方向にマージ（連結）。マージされたほうの表は削除

macOS 10.14.5＋Keynote v9.0.2で作成および動作確認を行っています。macOS 10.14上ではBridgePlusを呼び出すためにScript Debugger上で実行するか、アプレット書き出しして実行する必要があります。または、アプレット書き出ししてスクリプトメニューから呼び出してもよいでしょう。

＃　個人的には、めんどくさいのでmacOS 10.14環境ではSIP（System Integrity Protection）をオフにして使っています

macOS 10.13.x、macOS 10.12.xでは普通にスクリプトエディタなどから実行可能です。

AppleScript名：Keynoteで表示中のスライド上の表を２つ、横方向に連結する.scpt

— Created 2019-05-21 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use Bplus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　set tCount to count every table
　　　　　　if tCount < 2 then
　　　　　　　　display dialog "There is no tables to merge" buttons {"OK"} default button 1
　　　　　　　　return
　　　　　　end if
　　　　　　
　　　　　　set tList to every table
　　　　　　set tInfoList to {}
　　　　　　repeat with i in tList
　　　　　　　　set {tPosX, tPosY} to position of i
　　　　　　　　set tName to name of i
　　　　　　　　set the end of tInfoList to {tName, tPosX, tPosY}
　　　　　　end repeat
　　　　end tell
　　end tell
end tell

–表のY座標、X座標で昇順ソート（上→下、左→右の順で並べる）
set sortedList to sort2DList(tInfoList, {3, 2}, {true, true}) of me

–表リストから名前だけ抽出
set tmpTList to retSpecifiedItemFrom2DList({1}, sortedList) of me

–マージ対象のテーブルを名称で選択
set tRes to choose from list tmpTList with title "Select Merge Tables" with prompt "Select merge target two table names " & return & "(Sorted Up-> Down, Left->Right)" with multiple selections allowed
if length of tRes is not equal to 2 then
　　display dialog "Select *two* tables"
　　return
end if

–set mDirection to contents of (choose from list {"Vertival", "Horizontal"} with title "Select Merge Direction" without empty selection allowed)
set mDirection to "Horizontal"

set f1Table to contents of item 1 of tRes –Left (Original)
set f2Table to contents of item 2 of tRes –Right (merged)

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　–マージ先の表のサイズを取得（幅、高さ）
　　　　　　tell table f1Table
　　　　　　　　set f1Width to column count
　　　　　　　　set f1Height to row count
　　　　　　end tell
　　　　　　
　　　　　　–マージされるの表のサイズを取得（幅、高さ、データを2D Listで）
　　　　　　tell table f2Table
　　　　　　　　set f2Width to column count
　　　　　　　　set f2Height to row count
　　　　　　　　set f2DatList to {}
　　　　　　　　repeat with i from 1 to f2Height
　　　　　　　　　　tell row i
　　　　　　　　　　　　set aRowDat to value of every cell
　　　　　　　　　　end tell
　　　　　　　　　　set the end of f2DatList to aRowDat
　　　　　　　　end repeat
　　　　　　end tell
　　　　　　
　　　　　　–マージ先の表のサイズを変更して新規追加したセルにデータを埋める
　　　　　　tell table f1Table
　　　　　　　　set column count to column count + f2Width –表リサイズ
　　　　　　　　
　　　　　　　　set rowCount to 1
　　　　　　　　repeat with i in f2DatList
　　　　　　　　　　set colCount to (f1Width + 1)
　　　　　　　　　　
　　　　　　　　　　tell row rowCount
　　　　　　　　　　　　repeat with ii in i
　　　　　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　if jj is not equal to missing value then –空白セルを処理スキップ
　　　　　　　　　　　　　　　　tell cell colCount
　　　　　　　　　　　　　　　　　　set value to jj
　　　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　　　end if
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　set colCount to colCount + 1
　　　　　　　　　　　　end repeat
　　　　　　　　　　end tell
　　　　　　　　　　
　　　　　　　　　　set rowCount to rowCount + 1
　　　　　　　　end repeat
　　　　　　end tell
　　　　　　
　　　　　　delete table f2Table
　　　　end tell
　　end tell
end tell

return f2DatList

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　load framework
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　return resList
end sort2DList

–指定2Dリストから、各要素の指定アイテム目を取り出して（1D Listで）返す
on retSpecifiedItemFrom2DList(aList as list, bList as list)
　　set newList to {}
　　repeat with i in aList
　　　　repeat with ii in bList
　　　　　　set j to contents of ii
　　　　　　set a to contents of (item i of j)
　　　　　　set the end of newList to a
　　　　end repeat
　　end repeat
　　return newList
end retSpecifiedItemFrom2DList

★Click Here to Open This Script　

RectangleBinPackを用いて2D Bin Packを解く

Posted on 4月 23, 2019 by Takaaki Naganoya

オープンソースの「RectangleBinPack」を用いて2D Bin Packagingを解き、Keynote上のshapeオブジェクトを指定矩形内に詰め込むAppleScriptです。

–> Download Script bundle with RectangleBinPack in its bundle

# This AppleScript requires RectangleBinPack executable in its bundle. So, download the whole AppleScript bundle archive from the link above (↑)

オープン中のKeynote書類の表示中のスライド（ページ）上にある矩形オブジェクト（Shape）を指定の矩形エリア内に2D Packingします。

github上で調査してみたところ、2D Bin Packのプログラムの多くはCないしC++で記述されており（JavaScriptも多いですね）、コンパイルしてAppleScriptのバンドル内に入れて呼び出せます。

ただし、それらの多くがゲーム開発用のものらしく、オブジェクトの回転をサポートしていたり（実用性を考えると回転してほしくない）、面積の大きな順に渡しても無視したり（優先順位をサポートしない）と、実際のGUIアプリケーション上のオブジェクトの整列には向いていないものがほとんどです。

▲Before Packing

▲AFter Packing

唯一、タグクラウドの画像を作りたい場合に本プログラムは向いていると思います。とくに、Keynoteのスライド上にタグクラウドっぽいページを作って、発表内容を示すとかいうのは実用性もありそうです。

▲本Scriptを文字アイテム処理用に書き換えて2D Bin Packした処理結果

▲本ScriptをAdobe Illustrator CC 2018用に書き換えて2D Bin Packした処理結果

AppleScript名：rectBinPack v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/23
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

–Packaging Target Area
set binSizeX to 600
set binSizeY to 500

set {tList, a0List} to retRectsFromKeynote() of me
set aList to sortList2DDecending(a0List, {2, 4, 3}) of me –Sorting key is Width(main) and Area(sub) and Height(sub)
–> {{2, 340, 243, 82620}, {3, 340, 73, 24820}, {8, 340, 73, 24820}, {1, 155, 240, 37200}, {4, 147, 125, 18375}, {5, 147, 125, 18375}, {6, 147, 125, 18375}, {7, 147, 125, 18375}}

set aRes to twoDBinPacking(binSizeX, binSizeY, aList) of me
if aRes = false then return
–> {{myPos:{0, 0}, myID:1}, {myPos:{0, 340}, myID:2}, {myPos:{243, 0}, myID:3}, {myPos:{316, 0}, myID:4}, {myPos:{340, 240}, myID:5}, {myPos:{465, 240}, myID:6}, {myPos:{590, 0}, myID:7}, {myPos:{590, 125}, myID:8}}

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　repeat with i in aRes
　　　　　　　　set {posX, posY} to myPos of i
　　　　　　　　set itemIndex to myID of i
　　　　　　　　set aDeg to myDegree of i
　　　　　　　　
　　　　　　　　set anObjID to item 1 of (item itemIndex of aList)
　　　　　　　　
　　　　　　　　set rotation of shape anObjID to aDeg
　　　　　　　　set position of shape anObjID to {posX, posY}
　　　　　　　　
　　　　　　end repeat
　　　　end tell
　　end tell
end tell

on twoDBinPacking(binSizeX as integer, binSizeY as integer, boxList as list)
　　set aParamList to {binSizeX, binSizeY}
　　repeat with i in boxList
　　　　copy i to {tmpID, tmpX, tmpY, tmpArea}
　　　　set aParamList to aParamList & tmpX
　　　　set aParamList to aParamList & tmpY
　　end repeat
　　
　　set aParam to retDelimitedText(aParamList, " ") of me
　　–> "800 800 340 243 340 73 340 73 155 240 147 125 147 125 147 125 147 125"
　　
　　–Parameters for result parsing
　　set s1Str to "Packed to (x,y)=("
　　set s2Str to ")"
　　set s3Str to ","
　　
　　–https://github.com/juj/RectangleBinPack
　　set aPath to POSIX path of (path to resource "BinPackTest") –cause error if "BinPackTest" is not present in this script bundle
　　try
　　　　set aRes to do shell script quoted form of aPath & " " & aParam
　　on error
　　　　return false
　　end try
　　
　　if aRes does not end with "Done. All rectangles packed." then return false
　　
　　set aList to paragraphs of aRes
　　
　　set bList to {}
　　set aCount to 1
　　repeat with i in aList
　　　　set j to contents of i
　　　　if j begins with "Packing rectangle of size " and j does not contain "Failed!" then
　　　　　　set xyRes to pickUpFromToStrAndParse(j, s1Str, s2Str, s3Str) of me
　　　　　　
　　　　　　–RectangleBinPackがオブジェクトの回転をサポートしているため、その対処
　　　　　　if xyRes is not equal to false then
　　　　　　　　set s11Str to "(w,h)=("
　　　　　　　　set s12Str to ")"
　　　　　　　　set s13Str to ","
　　　　　　　　
　　　　　　　　set whRes to pickUpFromToStrAndParse(j, s11Str, s12Str, s13Str) of me
　　　　　　　　set tmpBox to item aCount of boxList
　　　　　　　　copy tmpBox to {tmpID, tmpX, tmpY, tmpArea}
　　　　　　　　
　　　　　　　　if whRes = {tmpX, tmpY} then
　　　　　　　　　　set aDeg to 0
　　　　　　　　else if whRes = {tmpY, tmpX} then
　　　　　　　　　　set aDeg to 90
　　　　　　　　else
　　　　　　　　　　error
　　　　　　　　end if
　　　　　　　　
　　　　　　　　set the end of bList to {myPos:xyRes, myID:aCount, myDegree:aDeg}
　　　　　　end if
　　　　　　set aCount to aCount + 1
　　　　end if
　　end repeat
　　
　　return bList
end twoDBinPacking

on retRectsFromKeynote()
　　tell application "Keynote"
　　　　tell front document
　　　　　　tell current slide
　　　　　　　　set tList to every shape
　　　　　　　　set bList to {}
　　　　　　　　set iCount to 1
　　　　　　　　
　　　　　　　　repeat with i in tList
　　　　　　　　　　set aWidth to width of i
　　　　　　　　　　set aHeight to height of i
　　　　　　　　　　set {xPos, yPos} to position of i
　　　　　　　　　　set anArea to aWidth * aHeight
　　　　　　　　　　
　　　　　　　　　　set the end of bList to {iCount, aWidth, aHeight, anArea}
　　　　　　　　　　set iCount to iCount + 1
　　　　　　　　end repeat
　　　　　　　　
　　　　　　　　return {tList, bList}
　　　　　　end tell
　　　　end tell
　　end tell
end retRectsFromKeynote

–入れ子のリストを昇順ソート
on sortList2DAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end sortList2DAscending

–入れ子のリストを降順ソート
on sortList2DDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end sortList2DDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　load framework
　　
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　–Sort
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as {missing value, list}
　　
　　return resList
end sort2DList

★Click Here to Open This Script　

レコードのリストを複数Keyでソート

Posted on 4月 19, 2019 by Takaaki Naganoya

リストに入れたレコードを複数キー、キーごとのソート方向（ascending/descending）指定でソートするAppleScriptです。

ソート対象のラベルはサンプルのように階層構造ごと指定できます。キーとして列挙するラベルは、最初のものが主キーで、２番目以降はサブキーです。

AppleScript名：レコードのリストを複数Keyでソート.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/19
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set aRecList to {{aName:"piyoko", aVal:10, bVal:{x:3, y:1}}, {aName:"piyomaru", aVal:20, bVal:{x:5, y:2}}, {aName:"piyoo", aVal:20, bVal:{x:4, y:5}}, {aName:"piyozo", aVal:10, bVal:{x:10, y:9}}}

set bList to sortRecListByLabel(aRecList, {"aVal", "bVal.x"}, {true, false}) of me
–> {{aName:"piyozo", aVal:10, bVal:{x:10, y:9}}, {aName:"piyoko", aVal:10, bVal:{x:3, y:1}}, {aName:"piyomaru", aVal:20, bVal:{x:5, y:2}}, {aName:"piyoo", aVal:20, bVal:{x:4, y:5}}}

★Click Here to Open This Script　

Keynoteのテキストアイテム内の文字の実際の幅でリサイズ

Posted on 4月 5, 2019 by Takaaki Naganoya

Keynote書類上のテキストアイテムを、内容の文字の実際の幅でリサイズするAppleScriptです。

▲テキストアイテム中のテキストをコピー（Command-C）

▲リサイズ前のテキストアイテム。文字に対してフレームサイズが大きい

▲本Scriptによりリサイズした後のテキストアイテム。文字の内容に対してフレームサイズがフィットしている

▲本Scriptにより順次複数のテキストアイテムを文字幅にリサイズしたところ。selectionがまともに動作していれば、複数のテキストアイテムを選択した状態でScriptを走らせて一度にリサイズできる（はず）だが、selectionが動作していないので複数のオブジェクトに対して同じ回数の操作が必要

Keynoteにはversion 9.0で「selection」の予約語が追加されましたが、これは一般に期待されるような「表示中のスライド上で選択中のオブジェクトへの参照が取得できる」というものではありません。

つまり、選択中のオブジェクトへの参照をKeynoteに対して問い合わせることは、（現時点では）不可能です。

そこで、テキストアイテム内の内容（object text）をコピー（Command-C）してクリップボードに格納し、その内容をキーにして現在表示中のスライド内のテキストアイテムを抽出してみたところ、うまくいきました（なんでこんなことさせられてるんだろ？）。早くselectionがKeynote上でもまともに使えるようになってほしいものです（Pages上ではけっこういい感じに使えるのに）。

テキストアイテムの特定ができるようになったので、入っているobject textのサイズに合わせてテキストアイテムをリサイズする処理を書いてみました。

クリップボードの内容をNSAttributedStringとして取得し、その画面上の描画サイズを取得するサブルーチンは毎日さんざん使っているので（掲載リストのproperty宣言部をソートするのに使っています）信頼性があります。

とりあえず、擬似的に現在選択中のオブジェクトを特定する実験コードにちょっとだけ機能をつけたものですが、操作１に対して結果１というのは普通「自動化」とか言わないので、実用性は皆無です（めんどくさい操作ステップを省けるぐらいしか）。

AppleScript名：Keynoteのテキストアイテム内の文字の実際の幅でリサイズ

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/05
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use BPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSPasteboard : a reference to current application’s NSPasteboard
property NSAttributedString : a reference to current application’s NSAttributedString
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

load framework

–クリップボードの内容をテキストとして取得し、現在のKeynote書類中のtext itemのうちコピーしたテキストに該当するものを抽出
set targString to (the clipboard) as string

tell application "Keynote"
　　tell document 1
　　　　tell current slide
　　　　　　set tList to every text item whose object text is targString
　　　　　　if tList = {} then return
　　　　　　set targObject to first item of tList
　　　　end tell
　　end tell
end tell

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()

–Split Attributed Strings into lines
set attrList to splitAttributedStringByLines(anAttr) of me

–Sort Attributed String list by its width in descending (large–> small)
set aResList to shellSortListDecending(attrList, 1) of me
set {targObjWidth, targAttrStrObj} to first item of aResList

–Resize Text item objet’s frame by its drawing width on screen
tell application "Keynote"
　　tell document 1
　　　　tell current slide
　　　　　　tell targObject
　　　　　　　　set width to ((targObjWidth as number) + 10) –resize it !
　　　　　　end tell
　　　　end tell
　　end tell
end tell

–入れ子のリストを昇順ソート
on shellSortListAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end shellSortListAscending

–入れ子のリストを降順ソート
on shellSortListDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end shellSortListDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　–Sort
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　
　　return resList
end sort2DList

— クリップボードの内容をNSAttributedStringとして取り出して返す
on getClipboardASStyledText()
　　try
　　　　set theNSPasteboard to NSPasteboard’s generalPasteboard()
　　　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({NSAttributedString}) options:(missing value)
　　　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　　　return theNSAttributedString
　　on error
　　　　return missing value
　　end try
end getClipboardASStyledText

on splitAttributedStringByLines(theStyledText)
　　set outList to {}
　　set outAttr to NSMutableAttributedString’s alloc()’s initWithString:""
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　set aText to (thePureString’s substringWithRange:theRange) as string –String
　　　　
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor") –Color
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont") –Font
　　　　if aFont is equal to missing value then error "Not font name and size are specified" –Font Name error
　　　　set aDFontName to aFont’s displayName() –Font Name
　　　　set aDFontSize to aFont’s pointSize() –Font Size
　　　　
　　　　set tmpAttrStr to generateAttributedString(aText, aDFontName, aDFontSize, aColor) of me
　　　　outAttr’s appendAttributedString:tmpAttrStr
　　　　
　　　　if (aText contains return) or (aText contains string id 10) then –CR or LF
　　　　　　set tmpSize to outAttr’s |size|()
　　　　　　set tmpWidth to retWidthFromSize(tmpSize) of me
　　　　　　
　　　　　　set the end of outList to {tmpWidth, outAttr}
　　　　　　set outAttr to NSMutableAttributedString’s alloc()’s initWithString:""
　　　　end if
　　　　
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　end repeat
　　
　　set tmpSize to outAttr’s |size|()
　　set tmpWidth to retWidthFromSize(tmpSize) of me
　　set the end of outList to {tmpWidth, outAttr}
　　
　　return outList
end splitAttributedStringByLines

on retWidthFromSize(tmpSize)
　　if class of tmpSize = record then
　　　　–macOS 10.10, 10.11, 10.12
　　　　set tmpWidth to width of tmpSize
　　else
　　　　–macOS 10.13, 10.14
　　　　set tmpWidth to first item of tmpSize
　　end if
　　return tmpWidth
end retWidthFromSize

on generateAttributedString(aStr, aFontPSName, aFontSize, aColor)
　　set tmpAttr to NSMutableAttributedString’s alloc()’s initWithString:aStr
　　set aRange to current application’s NSMakeRange(0, tmpAttr’s |length|())
　　set aVal1 to NSFont’s fontWithName:aFontPSName |size|:aFontSize
　　tmpAttr’s beginEditing()
　　tmpAttr’s addAttribute:(NSFontAttributeName) value:aVal1 range:aRange
　　tmpAttr’s addAttribute:(NSForegroundColorAttributeName) value:aColor range:aRange
　　tmpAttr’s endEditing()
　　return tmpAttr
end generateAttributedString

★Click Here to Open This Script　

クリップボード内のRTFをStyled Stringとして解釈して行ごとに分割して画面描画サイズ幅で昇順ソートして再結合

Posted on 2月 27, 2019 by Takaaki Naganoya

クリップボードにコピーしておいた書式つきテキストを、行ごとに画面上の描画サイズで昇順ソートし、再結合してクリップボードに転送するAppleScriptです。

ほぼ毎日使っているAppleScriptの改良版です。

Cocoaの機能を呼び出すと、AppleScript冒頭にproperty宣言文を書くことになりますが（書かなくてもいいんですが）、この宣言文を「プロポーショナルフォントを考慮しつつ実際の画面上の描画サイズを考慮」して短いものから長いものにソートして掲載しています。

ただし、従来のバージョンでは実際のフォントではなく一律に指定フォントで描画したさいの描画幅でソートしていたため、ごくまれに掲載時のリストが短い順になっていませんでした（世界中で誰も気にしてねえよ！　＾ー＾；）。

これを、実際の指定フォントやサイズを考慮した行単位のスタイル付きテキストに分解し、描画幅でソートしたあとにスタイル付きテキストを再合成するようにしました。

従来のOld Style AppleScriptではスタイル付きテキストの操作は一切できませんでしたが、Cocoaの機能を活用することでこのように自由度の高い処理ができるようになった、という好例です。

なお、本ルーチンによって厳密に描画幅でソートしても、Web掲載時にはWebブラウザのレンダリングのルール（＆ユーザー側で指定しているWebブラウザのフォント）が適用されるため、macOS上のアプリケーション上での見た目と若干違いが出るという残念な結果も出ています。

macOS標準装備のスクリプトメニューに入れて呼び出しています。

AppleScript名：クリップボード内のRTFをStyled Stringとして解釈して行ごとに分割して画面描画サイズ幅で昇順ソートして再結合

— Created 2017-04-24 by Shane Stanley
— Modified 2019-02-27 by Takaaki Naganoya
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()
if anAttr = missing value then return

–Split Attributed Strings into lines
set attrList to splitAttributedStringByLines(anAttr) of me

–Sort by Width in ascending
set sortedList to shellSortListAscending(attrList, 1) of me

–Append Attributed Strings
set mutableReturn to NSMutableAttributedString’s alloc()’s initWithString:(return)
set outStr to NSMutableAttributedString’s alloc()’s initWithString:""

repeat with i in sortedList
　　copy i to {tmpWidth, tmpAttr}
　　(outStr’s appendAttributedString:tmpAttr)
　　
　　set tmpStr to tmpAttr’s |string|() as string
　　if (tmpStr does not end with string id 10) and (tmpStr does not end with string id 13) then
　　　　(outStr’s appendAttributedString:mutableReturn)
　　end if
end repeat

— Set Styled String to Clipboard
set theArray to {outStr}
restoreClipboard(theArray) of me

–Clipboardにデータを設定する
on restoreClipboard(theArray as list)
　　set thePasteboard to NSPasteboard’s generalPasteboard()
　　thePasteboard’s clearContents()
　　thePasteboard’s writeObjects:theArray
end restoreClipboard

–入れ子のリストを昇順ソート
on shellSortListAscending(a, keyItem)
　　return sort2DList(a, keyItem, {true}) of me
end shellSortListAscending

–入れ子のリストを降順ソート
on shellSortListDecending(a, keyItem)
　　return sort2DList(a, keyItem, {false}) of me
end shellSortListDecending

–2D Listをソート
on sort2DList(aList as list, sortIndexes as list, sortOrders as list)
　　load framework
　　–index値をAS流（アイテムが1はじまり）からCocoa流（アイテムが0はじまり）に変換
　　set newIndex to {}
　　repeat with i in sortIndexes
　　　　set j to contents of i
　　　　set j to j – 1
　　　　set the end of newIndex to j
　　end repeat
　　
　　–Sort TypeのListを作成（あえて外部から指定する内容でもない）
　　set sortTypes to {}
　　repeat (length of sortIndexes) times
　　　　set the end of sortTypes to "compare:"
　　end repeat
　　
　　–Sort
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:newIndex ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　return resList
end sort2DList

★Click Here to Open This Script　

住所録から苗字を抽出して１文字以上の苗字をリスト出力

Posted on 12月 20, 2018 by Takaaki Naganoya

固有名詞を抽出するために、住所録から苗字を抽出して１文字以上の長さの苗字をリスト出力するAppleScriptです。

簡易形態素解析を行うさいに、みのまわりの人物の苗字を認識してくれないと知性を感じられないため（例：”長野”,”谷”）、逆に住所録に登録があるぐらい身の回りの人物の苗字を固有名詞として認識してくれるよう、住所録から苗字を抽出させてみました。

抽出した苗字は、missing valueが返ってきたものを除去し、重複を排除し、文字列長でソートして長いものから短いものへと並べ替え。

さらに、文字種別を判定して漢字のみで構成されているものを抽出。さらに、１文字の苗字を排除。

こうして得られたリストの先頭に自分の苗字を入れて、真っ先に自分の名前が認識されるようにしてみました。

住所録へのアクセスは、macOS標準装備の「連絡先.app」にアクセスしてみました。最近はmacOS標準装備のFrameworkにアクセスしてこの手のデータを取得していたりしましたが、その際に利用していたAddressBook.frameworkが廃止になる見込みであるため、新設されたContacts.frameworkを使ったほうが好ましいところです。

ただ、Contacts.frameworkの各種メソッドはObjective-CのBlocks構文の記述を必要とするため、AppleScriptからそのまま呼び出すことができません。

そのため、連絡先.app（Contacts.app）にアクセスすることになった次第です。

固有名詞抽出については、簡易形態素解析を実行するたびに実行するのではなく、１日に１回ぐらいの頻度で実行すればよいと考えています。

AppleScript名：住所録から苗字を抽出して１文字以上の苗字をリスト出力

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/12/20
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use bPlus : script "BridgePlus"

property NSString : a reference to current application’s NSString
property NSScanner : a reference to current application’s NSScanner
property NSNumber : a reference to current application’s NSNumber
property NSDictionary : a reference to current application’s NSDictionary
property NSCountedSet : a reference to current application’s NSCountedSet
property NSCharacterSet : a reference to current application’s NSCharacterSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSNumberFormatter : a reference to current application’s NSNumberFormatter
property NSMutableCharacterSet : a reference to current application’s NSMutableCharacterSet
property NSRegularExpressionSearch : a reference to current application’s NSRegularExpressionSearch
property NSNumberFormatterRoundUp : a reference to current application’s NSNumberFormatterRoundUp
property NSStringTransformFullwidthToHalfwidth : a reference to current application’s NSStringTransformFullwidthToHalfwidth

tell application "Contacts"
　　set lastNames to last name of every person
　　set myName to last name of my card
end tell

load framework

–Remove missing value (Cleaning)
set aList to (current application’s SMSForder’s arrayByDeletingBlanksIn:(lastNames)) as list

–重複部分の削除
set bList to makeUniqueListFrom(aList) of me

–文字列長でソート。長い文字列→短い文字列
set cList to sort1DListByStringLength(bList, false) of me –降順

–文字種別を判定して漢字のみから構成されるものを抽出し、１文字のものを除外
set dList to {}
repeat with i in cList
　　set j to contents of i
　　set tmpPat to retAtrPatternFromStr(j) of me
　　if tmpPat is equal to "漢" then
　　　　–１文字以上の苗字のみ出力
　　　　if length of j > 1 then
　　　　　　set the end of dList to j
　　　　end if
　　end if
end repeat

set the beginning of dList to myName
return dList
–> {"長野谷", "久保田", "三津田", "小笠原", "上田平", "大久保", "長谷川", "長野谷", "伊賀", "伊勢","伊東", "伊藤", "井上", "稲葉" …}

–Objective-Cライクなパラメータ記述
on makeUniqueListOf:theList
　　set theSet to current application’s NSOrderedSet’s orderedSetWithArray:theList
　　return (theSet’s array()) as list
end makeUniqueListOf:

–Pure AS風のパラメータ記述
on makeUniqueListFrom(theList)
　　set aList to my makeUniqueListOf:theList
　　return aList
end makeUniqueListFrom

–1D Listを文字列長でソート v2
on sort1DListByStringLength(aList as list, sortOrder as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:aList
　　set desc1 to current application’s NSSortDescriptor’s sortDescriptorWithKey:"length" ascending:sortOrder
　　set desc2 to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:true selector:"localizedCaseInsensitiveCompare:"
　　set bArray to aArray’s sortedArrayUsingDescriptors:{desc1, desc2}
　　return bArray as list of string or string
end sort1DListByStringLength

–文字種別の判定
on retAtrPatternFromStr(aText)
　　set a1List to {"100000", "010000", "001000", "000100", "000010", "000001"}
　　set b1List to {"9", "A", "$", "漢", "あ", "ア"} –数字、アルファベット、記号、全角漢字、全角ひらがな、全角カタカナ
　　set aDict to NSDictionary’s dictionaryWithObjects:b1List forKeys:a1List
　　
　　set aStr to NSString’s stringWithString:aText
　　set bStr to aStr’s stringByDeletingPathExtension()
　　set cStr to zenToHan(bStr) of me
　　
　　set outList to {}
　　set cList to characters of cStr
　　
　　repeat with i in cList
　　　　set j to contents of i
　　　　set chk1 to ((my chkNumeric:j) as integer) as string
　　　　set chk2 to ((my chkAlphabet:j) as integer) as string
　　　　set chk3 to ((my chkSymbol:j) as integer) as string
　　　　set chk4 to ((my chkKanji:j) as integer) as string
　　　　set chk5 to ((my chkHiragana:j) as integer) as string
　　　　set chk6 to ((my chkKatakana:j) as integer) as string
　　　　
　　　　set allKey to (chk1 & chk2 & chk3 & chk4 & chk5 & chk6) as string
　　　　set aVal to (aDict’s valueForKeyPath:allKey) as string
　　　　
　　　　if aVal is not in outList then
　　　　　　set the end of outList to aVal
　　　　end if
　　end repeat
　　
　　return outList as string
end retAtrPatternFromStr

–全角→半角変換
on zenToHan(aStr)
　　set aString to NSString’s stringWithString:aStr
　　return (aString’s stringByApplyingTransform:(NSStringTransformFullwidthToHalfwidth) |reverse|:false) as string
end zenToHan

–数字か
on chkNumeric:checkString
　　set digitCharSet to NSCharacterSet’s characterSetWithCharactersInString:"0123456789"
　　set ret to my chkCompareString:checkString baseString:digitCharSet
　　return ret as boolean
end chkNumeric:

–記号か
on chkSymbol:checkString
　　set muCharSet to NSCharacterSet’s alloc()’s init()
　　muCharSet’s addCharactersInString:"$＼"!~&=#[]._-+`|{}?%^*/’@-/:;(),"
　　set ret to my chkCompareString:checkString baseString:muCharSet
　　return ret as boolean
end chkSymbol:

–漢字か
on chkKanji:aChar
　　return detectCharKind(aChar, "[一-龠]") of me
end chkKanji:

–ひらがなか
on chkHiragana:aChar
　　return detectCharKind(aChar, "[ぁ-ん]") of me
end chkHiragana:

–カタカナか
on chkKatakana:aChar
　　return detectCharKind(aChar, "[ァ-ヶ]") of me
end chkKatakana:

–半角スペースか
on chkSpace:checkString
　　set muCharSet to NSCharacterSet’s alloc()’s init()
　　muCharSet’s addCharactersInString:" " –半角スペース（20h）
　　set ret to my chkCompareString:checkString baseString:muCharSet
　　return ret as boolean
end chkSpace:

— アルファベットか
on chkAlphabet:checkString
　　set aStr to NSString’s stringWithString:checkString
　　set allCharSet to NSMutableCharacterSet’s alloc()’s init()
　　allCharSet’s addCharactersInRange:(current application’s NSMakeRange(id of "a", 26))
　　allCharSet’s addCharactersInRange:(current application’s NSMakeRange(id of "A", 26))
　　set aBool to my chkCompareString:aStr baseString:allCharSet
　　return aBool as boolean
end chkAlphabet:

on chkCompareString:checkString baseString:baseString
　　set aScanner to NSScanner’s localizedScannerWithString:checkString
　　aScanner’s setCharactersToBeSkipped:(missing value)
　　aScanner’s scanCharactersFromSet:baseString intoString:(missing value)
　　return (aScanner’s isAtEnd()) as boolean
end chkCompareString:baseString:

on detectCharKind(aChar, aPattern)
　　set aChar to NSString’s stringWithString:aChar
　　set searchStr to NSString’s stringWithString:aPattern
　　set matchRes to aChar’s rangeOfString:searchStr options:(NSRegularExpressionSearch)
　　if matchRes’s location() = (current application’s NSNotFound) or (matchRes’s location() as number) > 9.99999999E+8 then
　　　　return false
　　else
　　　　return true
　　end if
end detectCharKind

★Click Here to Open This Script　

squeezeNetで画像のオブジェクト認識を行い、結果をCSV出力してNumbersでオープン

Posted on 11月 12, 2018 by Takaaki Naganoya

Core MLモデル「squeezeNet.mlmodel」を用いて画像のオブジェクト認識を行い、結果をデスクトップにCSV形式でデータ書き出しを行い、NumbersでオープンするAppleScriptです。

–> Download squeezeNetKit.framework (To ~/Library/Frameworks)

macOS 10.13上ではスクリプトエディタ、Script Debugger上で、macOS 10.14上ではScript Debugger上で動作します（AppleScript Appletでも動作）。

さまざまなCore MLモデルを用いて画像認識を行わせてはみたものの、最もスコアの高いもののラベルだけを返させても、結果がまったく内容にそぐわないケースが多く見られます。

▲機械学習の評価値が1.0に近いものは確度が高く、0.0に近いものは判断に迷った末に消極的に出した値。経験則でいえば、最高スコアの項目が0.7以上のスコアでないといまひとつのようです（0.7以上でもダメな時はダメなわけで、、、）

画像認識については、結果があまりに的外れで「なんじゃこら？」というケースが多いので、確認のためにCSVデータ出力させてNumbers上で確認させてみることにしてみました。そのためにありあわせのサブルーチンを組み合わせて作ったものです。

スコアが高い順に結果を並べて確認してみると、最も高いスコアの値であっても0.0に近い評価値であることがあり、「何も考えずに最高スコアのラベルだけ取ってくるのはものすごく危険」なことがよくわかります。

▲squeezeNet.mlmodelをNetronでビジュアライズしたところ（一部抜粋）

AppleScript名：SqueezeNetでオブジェクト判定して結果をCSV書き出ししてNumbersでオープン.scpt

–　　Created by: Takaaki Naganoya
–　　Created on: 2018/11/11
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use framework "AppKit"
use framework "squeezeNetKit"
use scripting additions

property NSUUID : a reference to current application’s NSUUID
property NSArray : a reference to current application’s NSArray
property NSImage : a reference to current application’s NSImage
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor

set aFile to POSIX path of (choose file of type {"public.image"})
set aImage to NSImage’s alloc()’s initWithContentsOfFile:aFile
set resDict to (current application’s imageClassifier’s alloc()’s init()’s ImageClassifierWithImageAndRetDict:aImage)

set kArray to (resDict’s allKeys())
set vArray to (resDict’s allValues())
set aLen to kArray’s |count|()

set anArray to NSMutableArray’s new()

repeat with i from 0 to (aLen – 1)
　　set tmpKey to (kArray’s objectAtIndex:i) as string
　　set tmpVal to (vArray’s objectAtIndex:i) as real
　　(anArray’s addObject:{aKey:tmpKey, aVal:tmpVal})
end repeat

–Sort by value
set bList to sortRecListByLabel(anArray, "aVal", false) of me

–record in list –> 2D list
set cList to convRecInListTo2DList(bList) of me

–デスクトップにCSVファイルを書き出してNumbersでオープン
set aPath to (((path to desktop) as string) & (NSUUID’s UUID()’s UUIDString()) as string) & ".csv"
set fRes to saveAsCSV(cList, aPath) of me
tell application "Numbers"
　　open (aPath as alias)
end tell

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as string, ascendF as boolean)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set sortDesc to NSSortDescriptor’s alloc()’s initWithKey:aLabelStr ascending:ascendF
　　set sortDescArray to NSArray’s arrayWithObjects:sortDesc
　　set sortedArray to aArray’s sortedArrayUsingDescriptors:sortDescArray
　　set bList to (sortedArray) as anything
　　return bList
end sortRecListByLabel

on convRecInListTo2DList(aList)
　　set anArray to NSMutableArray’s arrayWithArray:aList
　　set fItem to anArray’s objectAtIndex:0
　　set keyList to fItem’s allKeys() as list
　　set aCount to anArray’s |count|()
　　
　　set allArray to NSMutableArray’s new()
　　
　　repeat with i from 1 to aCount
　　　　set anItem to (anArray’s objectAtIndex:(i – 1))
　　　　set tmpItem to {}
　　　　
　　　　repeat with ii in keyList
　　　　　　set tmpDat to (anItem’s valueForKeyPath:(contents of ii))
　　　　　　if tmpDat is not equal to missing value then
　　　　　　　　set the end of tmpItem to tmpDat
　　　　　　else
　　　　　　　　set the end of tmpItem to ""
　　　　　　end if
　　　　end repeat
　　　　(allArray’s addObject:tmpItem)
　　end repeat
　　
　　set allList to allArray as list
　　set the beginning of allList to keyList
　　return allList
end convRecInListTo2DList

–CSV Kit

–2D List to CSV file
on saveAsCSV(aList, aPath)
　　–set crlfChar to (ASCII character 13) & (ASCII character 10)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　write_to_file(wholeText, bPath, false) of me
　　
end saveAsCSV

on write_to_file(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end write_to_file

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

並び順をインデックスリストで指定してソート

Posted on 10月 29, 2018 by Takaaki Naganoya

並び順を定義したリスト（インデックスリスト）にもとづいてソートを行うAppleScriptです。

テストデータにあるように、都道府県別のリストを処理する際に、結果を北から南へと並べたいというニーズを満たすために、その場で作ったものでしかありません。都道府県別なので重複データが存在しないことが前提です。

一応、リストを扱うための高速化処理を行なっているので、速度についてはそれほど困ることはないと思われます。

＃　書籍「AppleScript最新リファレンス」からのリンクURLがBlog消失後に修復されていなかったので、再掲載しました。書籍側もリンクURLを修正したものを近日中にアップします

AppleScript名：並び順をインデックスリストで指定してソート

–並び順を指定するインデックスリスト（この順番にソート対象データを並べ替える）
set indexList to {"北海道", "青森県", "岩手県", "秋田県", "宮城県", "山形県", "福島県", "新潟県", "富山県", "石川県", "福井県", "茨城県", "栃木県", "群馬県", "埼玉県", "千葉県", "東京都", "神奈川県", "長野県", "山梨県", "岐阜県", "静岡県", "愛知県", "三重県", "滋賀県", "京都府", "兵庫県", "大阪府", "奈良県", "和歌山県", "島根県", "岡山県", "鳥取県", "広島県", "山口県", "香川県", "徳島県", "愛媛県", "高知県", "福岡県", "大分県", "佐賀県", "長崎県", "宮崎県", "熊本県", "鹿児島県", "沖縄県"}

–ソート対象データ
set aList to {{"東京都", 301}, {"神奈川県", 98}, {"大阪府", 90}, {"千葉県", 60}, {"埼玉県", 55}, {"北海道", 40}, {"愛知県", 40}, {"京都府", 40}, {"兵庫県", 40}, {"福岡県", 30}, {"静岡県", 20}, {"広島県", 20}, {"茨城県", 20}, {"宮城県", 16}, {"長野県", 15}, {"福島県", 12}, {"新潟県", 11}, {"滋賀県", 10}, {"岐阜県", 10}, {"群馬県", 10}, {"石川県", 10}, {"熊本県", 9}, {"岡山県", 9}, {"福井県", 7}, {"青森県", 7}, {"秋田県", 6}, {"愛媛県", 6}, {"和歌山県", 6}, {"奈良県", 5}, {"三重県", 5}, {"沖縄県", 5}, {"岩手県", 5}, {"大分県", 4}, {"鹿児島県", 4}, {"宮崎県", 4}, {"栃木県", 3}, {"香川県", 3}, {"山形県", 3}, {"富山県", 2}, {"山梨県", 2}, {"長崎県", 2}, {"徳島県", 2}, {"島根県", 2}, {"鳥取県", 1}, {"高知県", 1}, {"山口県", 1}}

set bList to sortItemByIndexList(aList, indexList, 1, 2) of me
–> {{"北海道", 40}, {"青森県", 7}, {"岩手県", 5}, {"秋田県", 6}, {"宮城県", 16}, {"山形県", 3}, {"福島県", 12}, {"新潟県", 11}, {"富山県", 2}, {"石川県", 10}, {"福井県", 7}, {"茨城県", 20}, {"栃木県", 3}, {"群馬県", 10}, {"埼玉県", 55}, {"千葉県", 60}, {"東京都", 301}, {"神奈川県", 98}, {"長野県", 15}, {"山梨県", 2}, {"岐阜県", 10}, {"静岡県", 20}, {"愛知県", 40}, {"三重県", 5}, {"滋賀県", 10}, {"京都府", 40}, {"兵庫県", 40}, {"大阪府", 90}, {"奈良県", 5}, {"和歌山県", 6}, {"島根県", 2}, {"岡山県", 9}, {"鳥取県", 1}, {"広島県", 20}, {"山口県", 1}, {"香川県", 3}, {"徳島県", 2}, {"愛媛県", 6}, {"高知県", 1}, {"福岡県", 30}, {"大分県", 4}, {"佐賀県", 0}, {"長崎県", 2}, {"宮崎県", 4}, {"熊本県", 9}, {"鹿児島県", 4}, {"沖縄県", 5}}

–並び順をインデックスリストで指定してソート
–パラメータ： (1) aList＝ソート元リスト（{{"name1", number1}, {"name2", number2}……} ）、
–　　　　　　(2) indexList＝ソート順指定用インデックスリスト、
–　　　　　　(3) itemNo＝並べ替え対象アイテム番号（ソート元リスト内の各リスト要素内のソートキーになるアイテムの番号）
–　　　　　　(4) nohitItem＝インデックス項目がソート元リストに対してヒットしなかった場合の、件数0を入れるアイテム番号
–エラー：　　　　エラー時にはfalseを返す
on sortItemByIndexList(aList, indexList, itemNo, nohitItem)
　　–処理高速化のためにハンドラ内部にScript Objectを宣言してデータアクセス
　　script sortItemByIndexListObj
　　　　property indexListSpd : indexList
　　　　property aListSpd : aList
　　end script
　　
　　–パラメータのエラーチェック
　　set tmpItem to contents of first item of aList
　　set tmpLen to length of tmpItem
　　
　　–itemNoのエラーチェック
　　if (itemNo < 1) or (itemNo > tmpLen) then return false
　　–nohitItemのエラーチェック
　　if (nohitItem < 1) or (nohitItem > tmpLen) then return false
　　–itemNoとnohitItemが衝突していないかチェック
　　if itemNo = nohitItem then return false
　　
　　
　　–処理本体
　　set outList to {}
　　repeat with i in indexListSpd of sortItemByIndexListObj
　　　　set j to contents of i
　　　　
　　　　set hitF to false
　　　　
　　　　repeat with ii in aListSpd of sortItemByIndexListObj
　　　　　　set targItem to contents of item itemNo of ii
　　　　　　if targItem = j then
　　　　　　　　set the end of outList to contents of ii
　　　　　　　　set hitF to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　–合致するデータがなかった場合の対応
　　　　if hitF = false then
　　　　　　set tmpList to {}
　　　　　　repeat nohitItem times
　　　　　　　　set the end of tmpList to ""
　　　　　　end repeat
　　　　　　set item itemNo of tmpList to j
　　　　　　set item nohitItem of tmpList to 0
　　　　　　set the end of outList to tmpList
　　　　end if
　　　　
　　end repeat
　　
　　outList
　　
end sortItemByIndexList

★Click Here to Open This Script　

easyJParse v3

Posted on 9月 27, 2018 by Takaaki Naganoya

簡易的な日本語テキストのParse（辞書なし）を行うAppleScriptです。

英語などの言語では、文章中の各単語の間にスペース（” “）を入れるようになっており、

My name is Takaaki Naganoya.

文章を単語ごとに分割することがきわめて容易です。

words of "My name is Takaaki Naganoya."
--> {"My", "name", "is", "Takaaki", "Naganoya"}

一方、日本語の文章において単語は続けて記述するため、

私の名前は長野谷です。

これを単語ごとに切り分けるのは大変です。そのため、単語の辞書を手掛かりに文章中の単語を切り分けるのが普通です。

辞書を使って単語単位の切り分けを行う日本語形態素解析器

日本語テキストを単語（形態素）ごとに区分けするソフトウェアは日本語形態素解析器と呼ばれます。Chasen、Juman、MeCabなどが有名です。形態素解析のための巨大な辞書を用いて、地名ぐらいの固有名詞なら問題なくParseできることが普通です。各単語がどの品詞なのか、活用形はどうなっているかといった文法的な情報も管理しています。

たとえば、ApitoreのREST API経由でKuromojiを呼び出して形態素解析を行うと、

"警告音「Basso」を最大音量で鳴らす"
-->{{startTime:"1538006762864", tokens:{{partOfSpeechLevel1:"名詞", baseForm:"警告", pronunciation:"ケイコク", position:0, partOfSpeechLevel3:"*", reading:"ケイコク", surface:"警告", known:true, allFeatures:"名詞,サ変接続,*,*,*,*,警告,ケイコク,ケイコク", conjugationType:"*", partOfSpeechLevel2:"サ変接続", conjugationForm:"*", allFeaturesArray:{"名詞", "サ変接続", "*", "*", "*", "*", "警告", "ケイコク", "ケイコク"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"音", pronunciation:"オン", position:2, partOfSpeechLevel3:"一般", reading:"オン", surface:"音", known:true, allFeatures:"名詞,接尾,一般,*,*,*,音,オン,オン", conjugationType:"*", partOfSpeechLevel2:"接尾", conjugationForm:"*", allFeaturesArray:{"名詞", "接尾", "一般", "*", "*", "*", "音", "オン", "オン"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"記号", baseForm:"「", pronunciation:"「", position:3, partOfSpeechLevel3:"*", reading:"「", surface:"「", known:true, allFeatures:"記号,括弧開,*,*,*,*,「,「,「", conjugationType:"*", partOfSpeechLevel2:"括弧開", conjugationForm:"*", allFeaturesArray:{"記号", "括弧開", "*", "*", "*", "*", "「", "「", "「"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"Basso", pronunciation:"バッソ", position:4, partOfSpeechLevel3:"一般", reading:"バッソ", surface:"Basso", known:true, allFeatures:"名詞,固有名詞,一般,*,*,*,Basso,バッソ,バッソ", conjugationType:"*", partOfSpeechLevel2:"固有名詞", conjugationForm:"*", allFeaturesArray:{"名詞", "固有名詞", "一般", "*", "*", "*", "Basso", "バッソ", "バッソ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"記号", baseForm:"」", pronunciation:"」", position:9, partOfSpeechLevel3:"*", reading:"」", surface:"」", known:true, allFeatures:"記号,括弧閉,*,*,*,*,」,」,」", conjugationType:"*", partOfSpeechLevel2:"括弧閉", conjugationForm:"*", allFeaturesArray:{"記号", "括弧閉", "*", "*", "*", "*", "」", "」", "」"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"助詞", baseForm:"を", pronunciation:"ヲ", position:10, partOfSpeechLevel3:"一般", reading:"ヲ", surface:"を", known:true, allFeatures:"助詞,格助詞,一般,*,*,*,を,ヲ,ヲ", conjugationType:"*", partOfSpeechLevel2:"格助詞", conjugationForm:"*", allFeaturesArray:{"助詞", "格助詞", "一般", "*", "*", "*", "を", "ヲ", "ヲ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"最大", pronunciation:"サイダイ", position:11, partOfSpeechLevel3:"*", reading:"サイダイ", surface:"最大", known:true, allFeatures:"名詞,一般,*,*,*,*,最大,サイダイ,サイダイ", conjugationType:"*", partOfSpeechLevel2:"一般", conjugationForm:"*", allFeaturesArray:{"名詞", "一般", "*", "*", "*", "*", "最大", "サイダイ", "サイダイ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"音量", pronunciation:"オンリョー", position:13, partOfSpeechLevel3:"*", reading:"オンリョウ", surface:"音量", known:true, allFeatures:"名詞,一般,*,*,*,*,音量,オンリョウ,オンリョー", conjugationType:"*", partOfSpeechLevel2:"一般", conjugationForm:"*", allFeaturesArray:{"名詞", "一般", "*", "*", "*", "*", "音量", "オンリョウ", "オンリョー"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"助詞", baseForm:"で", pronunciation:"デ", position:15, partOfSpeechLevel3:"一般", reading:"デ", surface:"で", known:true, allFeatures:"助詞,格助詞,一般,*,*,*,で,デ,デ", conjugationType:"*", partOfSpeechLevel2:"格助詞", conjugationForm:"*", allFeaturesArray:{"助詞", "格助詞", "一般", "*", "*", "*", "で", "デ", "デ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"動詞", baseForm:"鳴らす", pronunciation:"ナラス", position:16, partOfSpeechLevel3:"*", reading:"ナラス", surface:"鳴らす", known:true, allFeatures:"動詞,自立,*,*,五段・サ行,基本形,鳴らす,ナラス,ナラス", conjugationType:"五段・サ行", partOfSpeechLevel2:"自立", conjugationForm:"基本形", allFeaturesArray:{"動詞", "自立", "*", "*", "五段・サ行", "基本形", "鳴らす", "ナラス", "ナラス"}, partOfSpeechLevel4:"*"}}, endTime:"1538006762864", |log|:"", processTime:"0"}}

のようになります。これらのデータのうち、surface項目を抽出すると、

--> {"警告", "音", "「", "Basso", "」", "を", "最大", "音量", "で", "鳴らす", "。"}

となります。

辞書を使わずにトリッキーな方法で単語単位の切り分けを行う日本語パーサー

一方で、これらの日本語形態素解析器ほどの大規模なデータや機能が必要ない場合もあります。形態素解析のための辞書を持たず、単にそれっぽく単語ごとに区切ることができればよいという、「割り切った用途」に用いるもので、便宜上「日本語パーサー」と呼びます。単語っぽいものに分割することが目的であり、品詞のデータなどは取得できないのが普通です。

この種類のソフトウェアは、工藤拓さんのTinySegmenterがあり、これをObjective-Cに移植したSuper compact Japanese tokenizer 「Tiny Segmenter」をCocoa Framework化してAppleScriptから呼び出し、テストしています。正規表現を用いて助詞などをピックアップして、それを手掛かりに単語切り分けを行うもので、そのサイズからは想像できないぐらいまっとうに単語に切り分けてくれます。

このTiny Segmenter（Objective-C版）をコマンド解釈用に使ってみたのですが、

--> {"警告音", "「Basso", "」", "を", "最大", "音量", "で", "鳴ら", "す"}

記号などがきちんと分離されなかったため、いまひとつ。自分でコマンド解釈用のParserを作ってみることにしました。

words ofの不完全さを補う簡易日本語パーサーeasyJParse

AppleScriptの「words of」は、前述のように英文であればスペースを区切り子として、文章の単語への分解を行ってくれます。

一方、日本語テキストに対して「words of」で単語分解処理を行うと、ながらく「文字種別の切り替え箇所で区切る」という気の狂ったような使えない処理が行われていました。その無意味さと使えなさをAppleのエンジニアにことあるごとに説明してきたのですが、一向に理解されず、相手にされてきませんでした。

＃　冗談抜きで、Appleのエンジニアとは「戦いの歴史」しかありません。そして、そうして戦って勝ち取っていかないと機能の改善もバグの修正も何もないのであります（本当）

風向きが変わってきたのは、OS X 10.6のころ。このころから日本語テキストのwords ofの実行結果が形態素解析を行なっているような気がする動作を行うようになっており、何かに使えるような気がするものの……

 words of "警告音「Basso」を最大音量で鳴らす。"
 --> {"警告", "音", "Basso", "を", "最大", "音量", "で", "鳴らす"}

なぜか記号類などをすべて無視してしまうので、いまひとつ実用性がありませんでした。

そこで、基本的にはこの「words of」の演算結果を活かしつつ、オリジナルの文章と比較を行なって、欠損した記号類を補うことで簡易日本語parserとして利用できるのでは？　と考えました。

set aTargName to "警告音「Basso」を最大音量で鳴らす。"
set aList to parseJ(aTargName) of me
--> {"警告", "音", "「", "Basso", "」", "を", "最大", "音量", "で", "鳴らす", "。"}

実際に作ってテストしてみたところ、自分が必要なコマンド解析ぐらいの目的には十分に使えることがわかりました。むしろ、単語切り分けについてはKuromojiと同じ結果が得られています。

しかも、辞書を持たないためコンパクトであり、実行速度もたいへんに高速で、このeasyJParseを組み込んだプログラムはREST APIの日本語形態素解析器を呼んだバージョンよりも明らかに高速化され、ネットワーク接続のない環境でも実行可能になりました。いいことづくめです。

easyJParseの制約事項

なお、easyJParseはすでに文章単位で分割されたテキストをコマンド解釈用に分解するため「だけ」に作ったものであり、長文を文章ごとに分割する機能は持っていません。別のプログラムやルーチンで文章ごとに分割してからeasyJParseで処理してください。

easyJParseは、日本語ユーザー環境における日本語テキストに対する「words of」の演算結果を利用しており、言語環境が日本語に設定していない環境で同様に演算できることは保証していません。
→　一応、英語ユーザー環境で実行してみたら期待どおりの動作を行いました

当然のことながら、macOS専用です。一部Cocoaの機能を呼び出しているため、macOS 10.10以降で動きます（10.10では動作確認していませんけれども）。

AppleScript名：easyJParse v3

— Created 2018-09-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use scripting additions

property NSArray : a reference to current application’s NSArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor

set aTargName to "警告音「Basso」を最大音量で鳴らす。"
set aList to parseJ(aTargName) of me
–> {"警告", "音", "「", "Basso", "」", "を", "最大", "音量", "で", "鳴らす", "。"}

–set aTargName to "JPEGファイルを50％にリサイズして、デスクトップの「AAA」フォルダに出力"
–set aList to parseJ(aTargName) of me
–> {"JPEG", "ファイル", "を", "50", "％", "に", "リサイズ", "し", "て", "、", "デスクトップ", "の", "「", "AAA", "」", "フォルダ", "に", "出力"}

on parseJ(aTargStr as string)
　　copy aTargStr to tStr
　　
　　set cList to characters of tStr
　　set wList to words of tStr
　　
　　set cLen to length of cList
　　
　　set w2List to {}
　　set w3List to {}
　　set aCount to 0
　　
　　set lastPos to 0
　　
　　repeat with i in wList
　　　　set j to contents of i
　　　　
　　　　set anOffset to offset of j in tStr
　　　　
　　　　if anOffset is not equal to 1 then
　　　　　　set aChar to character (lastPos + 1) of aTargStr
　　　　　　
　　　　　　set the end of w3List to {wordList:aChar, characterList:{aChar}, startPos:(lastPos + 1), endPos:(lastPos + 1)}
　　　　end if
　　　　
　　　　set aLen to length of j
　　　　
　　　　set w2List to w2List & (characters of j)
　　　　set startPointer to (anOffset + aCount)
　　　　set endPointer to (anOffset + aCount + aLen – 1)
　　　　
　　　　set the end of w3List to {wordList:j, characterList:(characters of j), startPos:startPointer, endPos:endPointer}
　　　　
　　　　set trimStart to (anOffset + aLen)
　　　　
　　　　if trimStart > (length of tStr) then
　　　　　　set trimStart to 1
　　　　end if
　　　　
　　　　set tStr to text trimStart thru -1 of tStr
　　　　
　　　　set aCount to aCount + anOffset + aLen – 1
　　　　copy endPointer to lastPos
　　end repeat
　　
　　–句読点など。文末の処理
　　if endPointer is not equal to cLen then
　　　　set the end of w3List to {wordList:tStr, characterList:(characters of tStr), startPos:(lastPos + aCount), endPos:aLen}
　　end if
　　
　　set bArray to sortRecListByLabel((w3List), "startPos", true) of me
　　set cArray to (bArray’s valueForKeyPath:"wordList") as list
　　
　　return cArray
end parseJ

★Click Here to Open This Script　

Keynoteで一番左上のshapeオブジェクトに他のshapeのサイズを合わせる

Posted on 8月 17, 2018 by Takaaki Naganoya

Keynoteでオープン中の最前面の書類で表示中のスライド（ページ）上の一番左上のshapeオブジェクトの縦横のサイズに他のshapeオブジェクトのサイズを合わせるAppleScriptです。

座標（position）の配列（2D Array）のソートにはBridgePlus Script Libraryを用いています。

▲初期状態

▲本AppleScriptで一番左上のshapeオブジェクトに他のshapeオブジェクトのサイズを合わせた

▲コマンドで適当に上ぞろえや左ぞろえを実行して整列（ここは手作業）

昔、Finder上のアイコンの整列AppleScriptを作ったことがあったので、その処理を使い回せば「いい感じの整列」はできそうです。

AppleScript名：Keynoteで一番左上のshapeオブジェクトに他のshapeのサイズを合わせる

— Created 2018-08-17 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

tell application "Keynote"
　　tell front document
　　　　tell (current slide)
　　　　　　— すべてのshapeオブジェクトの座標{x,y}を返す
　　　　　　set pList to position of every shape
　　　　　　
　　　　　　— shapeオブジェクトの全座標を昇順ソートして最もX座標値が小さいものを返す
　　　　　　set mostLeftPos to first item of sort2DList(pList) of me
　　　　　　
　　　　　　— 一番X,Y座標値が小さい（＝左上にある）オブジェクトを特定
　　　　　　set mostLeftObj to first item of (every shape whose position is equal to mostLeftPos)
　　　　　　set mostLeftProp to properties of mostLeftObj
　　　　　　–> {opacity:100, parent:slide 13 of document id "95E47D6C-C444-41BD-9E7E-61229486F370" of application "Keynote", class:shape, reflection showing:false, background fill type:color fill, position:{45, 229}, object text:"", width:144, rotation:0, reflection value:0, height:25, locked:false}
　　　　　　
　　　　　　set mostLeftHeight to height of mostLeftProp
　　　　　　set mostLeftWidth to width of mostLeftProp
　　　　　　
　　　　　　— 「一番左」以外のshapeオブジェクトへの参照を取得して一気にオブジェクトのwidthをそろえる
　　　　　　set otherShape to a reference to (every shape whose position is not equal to mostLeftPos)
　　　　　　set width of otherShape to mostLeftWidth
　　　　　　set height of otherShape to mostLeftHeight
　　　　　　
　　　　end tell
　　end tell
end tell

on sort2DList(aList)
　　load framework
　　set sortIndexes to {1, 0} –Key Item id: begin from 0
　　set sortOrders to {true, true} –ascending = true
　　set sortTypes to {"compare:", "compare:"}
　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:sortIndexes ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　return resList
end sort2DList

★Click Here to Open This Script　

Finder上で選択中のMarkdown書類をファイル名で昇順ソート（A→Z）して、各書類のタイトル見出しを取得する

Posted on 7月 8, 2018 by Takaaki Naganoya

Finder上で選択中のMarkdown書類を取得し、ファイル名で昇順ソート（A→Z）して、各Markdown書類中のタイトルのうち最もレベルの高い（重要な）ものを抽出し、まとめてテキストにしてクリップボードに転送するAppleScriptです。

大量にあるMarkdown書類の本文中から一番重要なタイトルを抽出する作業を……さすがに手作業で行うわけには行かなかったので、AppleScriptを書いて処理してみました。ただし、新規に書いた処理はほとんどなく、既存のルーチンの寄せ合わせで構成しています。

Finder上でMarkdown書類を選択した状態で本Scriptを実行すると（Markdown書類以外は除外して）、AppleScriptでMarkdown書類を読み込んで（Markdown書類がUTF-8固定なのでUTF-8を指定して読み込み）、正規表現で書類中のタイトルを抽出し、重要なタイトル（＃の個数が少ない）をピックアップ。これをすべての書類について行います。

処理結果をクリップボードに転送します。

最終的には、（手作業で加工して）このようになります。

若干の手作業は発生してしまいますが、このScriptを組まなかったら、とてもその手作業を行う気も起こらなかったわけで、、、

AppleScript名：Finder上で選択中のMarkdown書類をファイル名で昇順ソート（A→Z）して、各書類のタイトル見出しを取得する

— Created 2018-06-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "Quartz"
use mdLib : script "Metadata Lib" version "1.0.0"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property SMSForder : a reference to current application’s SMSForder
property NSIndexSet : a reference to current application’s NSIndexSet
property NSPredicate : a reference to current application’s NSPredicate
property NSMutableSet : a reference to current application’s NSMutableSet
property NSFileManager : a reference to current application’s NSFileManager
property NSCountedSet : a reference to current application’s NSCountedSet
property NSURLPathKey : a reference to current application’s NSURLPathKey
property NSMutableArray : a reference to current application’s NSMutableArray
property NSURLNameKey : a reference to current application’s NSURLNameKey
property NSSortDescriptor : a reference to current application’s NSSortDescriptor
property NSURLIsPackageKey : a reference to current application’s NSURLIsPackageKey
property NSRegularExpression : a reference to current application’s NSRegularExpression
property NSURLIsDirectoryKey : a reference to current application’s NSURLIsDirectoryKey
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSURLContentModificationDateKey : a reference to current application’s NSURLContentModificationDateKey
property NSRegularExpressionAnchorsMatchLines : a reference to current application’s NSRegularExpressionAnchorsMatchLines
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSRegularExpressionDotMatchesLineSeparators : a reference to current application’s NSRegularExpressionDotMatchesLineSeparators

load framework

–set inFiles to (choose file of type {"pdf"} with prompt "Choose your PDF files:" with multiple selections allowed)
tell application "Finder"
　　set inFiles to selection as alias list
end tell

if inFiles = {} then return

–指定のAlias listのうちMarkdown書類のみ抽出
set filRes1 to filterAliasListByUTI(inFiles, "net.daringfireball.markdown") of me

–指定のPOSIX path listから、各Markdown書類中の一番重要な見出しを抽出して返す
set tRes to listTitlesFromMarkdownDocPathList(filRes1) of me

–取得したタイトル一覧リストをテキストに変換
set t2Res to retStrFromArrayWithDelimiter(tRes, return) of me

–クリップボードに結果を転送
set the clipboard to t2Res

on listTitlesFromMarkdownDocPathList(inFiles)
　　set outList to {}
　　set inFilesSorted to my filesInListSortAscending(inFiles)
　　
　　repeat with i in inFilesSorted
　　　　–POSIX pathからaliasにパス変換してテキスト読み込み
　　　　set j to POSIX file (contents of i)
　　　　set jj to j as alias
　　　　set aStr to (read jj as «class utf8»)
　　　　
　　　　set aList to retHeaders(aStr) of me –Markdown書類中の見出しをリストアップ
　　　　–>　　{{1, " 2008/3/9 ５桁の乱数を生成"}}
　　　　
　　　　if aList is not equal to {} then
　　　　　　–2D Listの昇順ソート
　　　　　　set sortIndexes to {0} –Key Item id: begin from 0
　　　　　　set sortOrders to {true} –ascending = true
　　　　　　set sortTypes to {"compare:"}
　　　　　　set resList to (current application’s SMSForder’s subarraysIn:(aList) sortedByIndexes:sortIndexes ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list
　　　　　　
　　　　　　set aCon to contents of second item of first item of resList
　　　　　　set the end of outList to aCon
　　　　end if
　　end repeat
　　return outList
end listTitlesFromMarkdownDocPathList

on filesInListSortAscending(aliasList as list)
　　set cList to {}
　　repeat with i in aliasList
　　　　set j to contents of i
　　　　set aFileName to ((current application’s NSString’s stringWithString:j)’s valueForKeyPath:"lastPathComponent")
　　　　set the end of cList to {fileName:aFileName, pathDat:j}
　　end repeat
　　
　　set aResList to sortRecListByLabel(cList, "fileName", true) of me –昇順ソート
　　set bResList to (aResList’s valueForKeyPath:"pathDat") as list of string or string
　　return bResList
end filesInListSortAscending

–Alias listから指定UTIに含まれるものをPOSIX pathのリストで返す
on filterAliasListByUTI(aList, targUTI)
　　set newList to {}
　　repeat with i in aList
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, targUTI)
　　　　if utiRes is not equal to {} then
　　　　　　set the end of newList to j
　　　　end if
　　end repeat
　　return newList
end filterAliasListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

on returnNumberCharsOnly(aStr)
　　set anNSString to current application’s NSString’s stringWithString:aStr
　　set anNSString to anNSString’s stringByReplacingOccurrencesOfString:"[^0-9]" withString:"" options:(current application’s NSRegularExpressionSearch) range:{0, anNSString’s |length|()}
　　return anNSString as text
end returnNumberCharsOnly

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as string, ascendF as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　set sortDesc to current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabelStr ascending:ascendF
　　set sortDescArray to current application’s NSArray’s arrayWithObjects:sortDesc
　　set sortedArray to aArray’s sortedArrayUsingDescriptors:sortDescArray
　　return sortedArray
end sortRecListByLabel

–見出し抽出用サブルーチン群
on retHeaders(aCon)
　　set tList to {}
　　set regStr to "^#{1,6}[^#]*?$"
　　
　　set headerList to my findPattern:regStr inString:aCon
　　repeat with i in headerList
　　　　set j to contents of i
　　　　set regStr2 to "^#{1,6}[^#]*?"
　　　　set headerLevel to length of first item of (my findPattern:regStr2 inString:j)
　　　　set the end of tList to {headerLevel, text (headerLevel + 1) thru -1 in j}
　　end repeat
　　
　　return tList
end retHeaders

on findPattern:thePattern inString:theString
　　set theOptions to ((NSRegularExpressionDotMatchesLineSeparators) as integer) + ((NSRegularExpressionAnchorsMatchLines) as integer)
　　set theRegEx to NSRegularExpression’s regularExpressionWithPattern:thePattern options:theOptions |error|:(missing value)
　　set theFinds to theRegEx’s matchesInString:theString options:0 range:{location:0, |length|:length of theString}
　　set theFinds to theFinds as list — so we can loop through
　　set theResult to {} — we will add to this
　　set theNSString to NSString’s stringWithString:theString
　　repeat with i from 1 to count of items of theFinds
　　　　set theRange to (item i of theFinds)’s range()
　　　　set end of theResult to (theNSString’s substringWithRange:theRange) as string
　　end repeat
　　return theResult
end findPattern:inString:

–リストを指定デリミタをはさんでテキスト化
on retStrFromArrayWithDelimiter(aList, aDelim)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set aRes to anArray’s componentsJoinedByString:aDelim
　　return aRes as list of string or string
end retStrFromArrayWithDelimiter

★Click Here to Open This Script　

Finder上で選択中のPDFのファイル名の数字部分で小さいものから大きなものへとソート

Posted on 6月 27, 2018 by Takaaki Naganoya

Finder上で選択中のPDFのうち、ファイル名中の数字が小さいものから大きなものへソートを行うAppleScriptです。

Finder上で選択中のPDFをファイル名順でソートするような用途に使用します。選択中のファイルのうちPDFに該当しないものは無視します。

Finderで選択中の各PDFファイルに数字以外の文字がファイル名に混入していても無視します。

ファイル名はいったん数値として評価してソートするため、ファイル名にゼロパディングしてある場合には無視します。

Finder上で選択中のPDFを連結するさいに、ファイル名順で連結するScriptがあったほうが便利なので、そのために作ったものです。

ソートを行う際に、ファイル名の中の数字以外の部分をすべて無視するようにしています。そのため、Finder上の並び順と関係なく、ファイル名の中の数字部分のみをピックアップしてソートします。Finder自体にもFinderのルールでファイル名をソートして返すAppleScriptの機能がありますが、あれに甘えているとまともな処理はできません。

「test1_0004.pdf」というファイル名があった場合には10004という数値を検出するため、こうしたケースに対応する必要があるかもしれませんが、現時点では無用な数字の除去はしていません（それこそ一括処理で行うものではなくユーザーの目で見て判断してもらうような処理なので）。

AppleScript名：Finder上で選択中のPDFの数字のファイル名で小さいものから大きなものへとソート

— Created 2018-06-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use mdLib : script "Metadata Lib" version "1.0.0" –https://www.macosxautomation.com/applescript/apps/
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSPredicate : a reference to current application’s NSPredicate
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

tell application "Finder"
　　set inFiles to selection as alias list
end tell

if inFiles = {} then return

–指定のAlias listのうちPDFのみ抽出
set filRes1 to filterAliasListByUTI(inFiles, "com.adobe.pdf") of me

–ファイル名
set cList to {}
repeat with i in (filRes1 as list)
　　set j to contents of i
　　set aFileName to ((current application’s NSString’s stringWithString:j)’s valueForKeyPath:"lastPathComponent.stringByDeletingPathExtension")
　　
　　set aNumF to returnNumberCharsOnly(aFileName) of me
　　set the end of cList to {numDat:(aNumF as integer), pathDat:j}
end repeat

set aResList to sortRecListByLabel(cList, "numDat", true) of me –昇順ソート
set bResList to (aResList’s valueForKeyPath:"pathDat") as list of string or string
–>　　{"/Users/me/Pictures/243.pdf", "/Users/me/Pictures/244.pdf", "/Users/me/Pictures/245.pdf", "/Users/me/Pictures/246.pdf", "/Users/me/Pictures/247.pdf", "/Users/me/Pictures/248.pdf", "/Users/me/Pictures/249.pdf", "/Users/me/Pictures/250.pdf", "/Users/me/Pictures/251.pdf", "/Users/me/Pictures/252.pdf", "/Users/me/Pictures/253.pdf", "/Users/me/Pictures/254.pdf", "/Users/me/Pictures/255.pdf", "/Users/me/Pictures/256.pdf", "/Users/me/Pictures/257.pdf"}

–文字列中から
on returnNumberCharsOnly(aStr)
　　set anNSString to current application’s NSString’s stringWithString:aStr
　　set anNSString to anNSString’s stringByReplacingOccurrencesOfString:"[^0-9]" withString:"" options:(current application’s NSRegularExpressionSearch) range:{0, anNSString’s |length|()}
　　return anNSString as text
end returnNumberCharsOnly

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as string, ascendF as boolean)
　　–ListからNSArrayへの型変換
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　–ソート
　　set sortDesc to current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabelStr ascending:ascendF
　　set sortDescArray to current application’s NSArray’s arrayWithObjects:sortDesc
　　set sortedArray to aArray’s sortedArrayUsingDescriptors:sortDescArray
　　return sortedArray
end sortRecListByLabel

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: Sort

M1 Mac miniのベンチマーク 1万要素の1次元配列ソート

アラートダイアログ上にWebViewでGoogle Chartsを表示（Calendar Chart）

easyJParse v3

辞書を使って単語単位の切り分けを行う日本語形態素解析器

辞書を使わずにトリッキーな方法で単語単位の切り分けを行う日本語パーサー

words ofの不完全さを補う簡易日本語パーサーeasyJParse

easyJParseの制約事項

Finder上で選択中のPDFのファイル名の数字部分で小さいものから大きなものへとソート