Safariで現在見えている表を抽出してCSV書き出しv3

Posted on 10月 8 by Takaaki Naganoya

Safariの最前面のウィンドウで表示中のページのうち、現在ウィンドウ内に表示中の表要素をCSV書き出ししてNumbersでオープンするAppleScriptの改良版です。HTMLのtable中にrowspan（複数セルを行方向に連結）とcolspan（複数セルを列方向に連結）の属性値が指定されていた場合に対応します。

–> Download table2CSV_visibleonly_v2 (Code-Signed AppleScript applet with Framework and Library in its bundle)

各DOM ElementsのWebコンテンツ中の表示座標を取得して、絞り込みを行なっています。ただし、各DOM座標はWebブラウザのスクロールにしたがって数値が変わる（相対座標）ため、少々手こずりました。また、本Scriptでは上下スクロールのみ考慮してDOM要素の抽出を行なっており、横に長いページの横方向スクロールは考慮しておりません。

このバージョンではrowspan / colspanへの対処を追加しました。

行単位で（１次元配列ベースで）表を作っていてはとても対処できなかったので、HTMLの表と同じセル数のヌル文字が入った２次元配列を作成し、そこにX座標/Y座標を指定してセルを埋めるように処理内容を変更しました。また、rowspan/colspanの属性を見つけた場合には、結合されていた複数セルを個別の（同じ値を入れた）セルに分解しています。

本バージョンでは、１つのセル（td）でrowspanとcolspanを同時に指定しないことが処理の前提条件となっています。また、一番上の行がヘッダーの場合を想定しており、一番左の列がヘッダーになっているケースには対処しておりません。

AppleScript名：Safariで現在見えている表を抽出してCSV書き出しv3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/22
–　　Modified on: 2019/10/07
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader
use aLib : script "arrayLib"

property NSUUID : a reference to current application’s NSUUID
property NSString : a reference to current application’s NSString
property HTMLDocument : a reference to current application’s HTMLDocument
property NSMutableArray : a reference to current application’s NSMutableArray
property NSJSONSerialization : a reference to current application’s NSJSONSerialization

set aTag to "table"

set indRes to getVisibleElementIndexList(aTag) of me
if indRes = false or indRes = {} then
　　display notification "No Visible Table in Web browser"
　　return
end if

tell application "Safari"
　　tell front document
　　　　set aSource to source
　　end tell
end tell

repeat with i in indRes
　　set inList to filterATableAndPaseCells(aSource, i, aTag) of me
　　
　　if inList = false or inList = {} then return
　　set aUUID to current application’s NSUUID’s UUID()’s UUIDString() as text
　　set aNewFile to ((path to desktop) as string) & aUUID & ".csv"
　　saveAsCSV(inList, aNewFile) of me
　　
　　tell application "Numbers"
　　　　activate
　　　　open (aNewFile as alias)
　　end tell
end repeat

on filterATableAndPaseCells(aSource as string, targInd as integer, aTag as string)
　　set aHTML to current application’s HTMLDocument’s documentWithString:(aSource as string)
　　
　　–Table要素をリストアップ
　　set eList to (aHTML’s nodesMatchingSelector:aTag) as list
　　set aObj to contents of item (targInd + 1) of eList
　　
　　–Count columns of Table Header (Count only)
　　set aTableHeader to (aObj’s nodesMatchingSelector:"tr")’s firstObject()
　　set hList to aTableHeader’s nodesMatchingSelector:"th"
　　set hStrList to {}
　　repeat with i1 in hList
　　　　set hCellStr to i1’s textContent() as string
　　　　set the end of hStrList to (hCellStr)
　　end repeat
　　set hLen to length of hStrList –count columns
　　
　　
　　–Acquire whole table body contents
　　set aTableBody to (aObj’s nodesMatchingSelector:"tbody")’s firstObject()
　　set bList to (aTableBody’s nodesMatchingSelector:"tr") as list
　　
　　set rCount to (length of bList) –count rows
　　
　　–行単位ループ
　　set yCount to 1
　　set attrList to make2DBlankArray(hLen, rCount) of aLib
　　
　　repeat with i2 in bList
　　　　set bb2List to {}
　　　　set i3 to (i2’s nodesMatchingSelector:"th") as list
　　　　if i3 = {} then
　　　　　　set i3 to (i2’s nodesMatchingSelector:"td") as list
　　　　end if
　　　　
　　　　–カラム単位ループ
　　　　set xCount to 1
　　　　repeat with i4 in i3
　　　　　　set anAttr to i4’s attributes()
　　　　　　set colAtr to (anAttr’s valueForKey:"colspan")
　　　　　　set rowAttr to (anAttr’s valueForKey:"rowspan")
　　　　　　set cellStr to i4’s textContent() as string
　　　　　　
　　　　　　if colAtr is not equal to missing value then
　　　　　　　　–colspan処理
　　　　　　　　set colNum to colAtr as integer
　　　　　　　　set attrList to xFill(xCount, yCount, attrList, cellStr, colNum) of aLib
　　　　　　　　
　　　　　　else if rowAttr is not equal to missing value then
　　　　　　　　–rowspan処理
　　　　　　　　set rowNum to rowAttr as integer
　　　　　　　　set attrList to yFill(xCount, yCount, attrList, cellStr, rowNum) of aLib
　　　　　　　　
　　　　　　else if cellStr is not equal to "" then
　　　　　　　　–通常処理
　　　　　　　　repeat with ii from xCount to hLen
　　　　　　　　　　set aRes to getItemByXY(ii, yCount, attrList, "") of aLib
　　　　　　　　　　if aRes = "" then
　　　　　　　　　　　　set attrList to setItemByXY(ii, yCount, attrList, cellStr) of aLib
　　　　　　　　　　　　exit repeat
　　　　　　　　　　else
　　　　　　　　　　　　set xCount to xCount + 1
　　　　　　　　　　end if
　　　　　　　　end repeat
　　　　　　　　
　　　　　　end if
　　　　　　
　　　　　　set xCount to xCount + 1
　　　　end repeat
　　　　
　　　　set yCount to yCount + 1
　　end repeat
　　
　　return attrList
end filterATableAndPaseCells

–Safariのウィンドウ上で表示中のDOM Elementsを座標計算して返す
on getVisibleElementIndexList(aTag as string)
　　tell application "Safari"
　　　　set dCount to count every document
　　　　if dCount = 0 then return false
　　　　
　　　　set jRes to do JavaScript "var winWidth = window.innerWidth,
winHeight = window.innerHeight,
winLeft = window.scrollX,
winTop = window.scrollY,
winBottom = winTop + winHeight,
winRight = winLeft + winWidth,
　　　　elementsArray = document.body.getElementsByTagName(’" & aTag & "’),
　　　　elemLen = elementsArray.length,
inView = [];
　　　　　　
　　　　var step;
　　　　for (step = 0 ; step < elemLen ; step++) {
　　　　　　var tmpElem = document.body.getElementsByTagName(’" & aTag & "’)[step];
　　　　　　var bVar = tmpElem.getBoundingClientRect();
　　　　　　if (bVar.top > 0 && bVar.top < winHeight) {
　　　　　　　　inView.push(step);
　　　　　　}
　　　　}
　　　　JSON.stringify(inView);" in front document
　　　　
　　　　set jList to parseJSONAsList(jRes) of me
　　　　return jList
　　　　
　　end tell
end getVisibleElementIndexList

on parseJSONAsList(jsRes as string)
　　set jsonString to NSString’s stringWithString:jsRes
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　return aJsonDict as list
end parseJSONAsList

–Save 2D List to CSV file
on saveAsCSV(aList as list, aPath)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　writeToFileAsUTF8(wholeText, bPath, false) of me
　　
end saveAsCSV

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

AS書類をオープンして書き換えて別途保存 v2（Cocoa版）

Posted on 10月 6 by Takaaki Naganoya

指定のAppleScript書類からソーステキストを取得して、書き換えたあとに別途ファイル保存するAppleScriptです。OSAKitの機能を利用しており、スクリプトエディタを使用しません。

最小限の実装しかしていませんが、これ以上どこをどうするという箇所もないのでこんなもんなんでしょう。

.scptファイルについてはこんな感じで処理できそうですが、.scptdファイルの書き換え処理についてはノーアイデアです。バンドル内の指定の.scptファイルを書き換えるといった、rtfとrtfdの関係のような感じになるのだろうかと思わないでもありませんが、いろいろ落とし穴がありそうで困ります。

本Scriptの発展版で、OSAKitの機能を用いてAppleScript書類をAppleScript Appletに書き出したりStay Open Appletに書き出すAppleScriptも作って試していますが、OS内の機能をそのまま使っているだけだと、バンドル形式のScriptのバンドル中に含まれている他のファイル（ライブラリとか、Frameworkとか、起動時に表示できるdescription.rtfdファイルとかをもともとのScriptから移し変えてくれないので、そのあたりいちいち自分で書かないといけないのでしょうか。

スクリプトエディタをAppleScriptからコントロールしてAppleScript書類をAppletに書き出すような処理はよくやっていますが、OSAKitの機能を用いて同様のことは行えます。ただし、フラットなScript書類（バンドルではない）をアプレットに書き出す程度の処理が（現状では）到達点のようです。

もしも、大量のAppleScript書類を高速にアプレット書き出しする必要があれば、それなりに時間をかけて処理を記述するかもしれませんが、そういう用途がなければスクリプトエディタをコントロールしたほうがよさそうです。

AppleScript名：AS書類をオープンして書き換えて別途保存 v2.scptd

— Created 2018-03-28 by Takaaki Naganoya
— Modified 2018-04-22 by Shane Stanley
— Modified 2019-10-06 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "OSAKit"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property OSANull : a reference to current application’s OSANull
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property OSALanguage : a reference to current application’s OSALanguage
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

set asPath to choose file of type {"com.apple.applescript.script"}
–set asPath to choose file of type {"com.apple.applescript.script", "com.apple.applescript.script-bundle"}

set aUTI to retUTIfromPath(asPath) of me –UTI
set aEXT to "." & getFileExtension(asPath) of me –Name Extension

–指定ファイルからソーステキストを取得して、冒頭にコメントを追加する
set theSource to getContentsOfFile(asPath) of me
set theSource to "– Modified" & return & return & theSource

–書き換えたソーステキストをコンパイルしてAppleScriptオブジェクトを生成
set anOSALanguageInstance to OSALanguage’s languageForName:"AppleScript"
set theScript to OSAScript’s alloc()’s initWithSource:theSource fromURL:(missing value) languageInstance:anOSALanguageInstance usingStorageOptions:(OSANull)

–AppleScriptオブジェクトをファイルに新規保存
set targFile to POSIX path of (choose file name)
if targFile does not end with aEXT then
　　set targFile to targFile & aEXT
end if
set aURL to |NSURL|’s fileURLWithPath:targFile
set sRes to (theScript’s writeToURL:(aURL) ofType:(aUTI) |error|:(missing value))

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
— Original Created 2014-02-23 Shane Stanley
on getContentsOfFile(anAlias as {alias, string})
　　set anHFSpath to anAlias as string
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of anHFSpath)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　return theScript’s source() as text
end getContentsOfFile

–ファイル情報（Alias）から拡張子を取得する
on getFileExtension(aFile as alias)
　　set aPath to POSIX path of aFile
　　set pathString to NSString’s stringWithString:aPath
　　set aEXT to (pathString’s pathExtension()) as string
　　return aEXT
end getFileExtension

–ファイル情報（Alias）からUTIを取得する
on retUTIfromPath(anAlias as alias)
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

★Click Here to Open This Script　

Safariで現在見えている表を抽出してCSV書き出し

Posted on 9月 24 by Takaaki Naganoya

Safariの最前面のウィンドウで表示中のページのうち、現在ウィンドウ内に表示中の表要素をCSV書き出ししてNumbersでオープンするAppleScriptです。

このところ下調べを行なっていた「Webブラウザで表示中の要素を処理する」「表示中ではない要素は処理をしない」というScriptです。

これで、「表の一部を選択しておく」とかいった操作は不要になりました。ウィンドウ内に表示されている表をWebコンテンツ内部の表示座標をもとに自動抽出します。表示エリア外に位置しているものは書き出し処理しません。

本Scriptは大量一括処理を志向するプログラムではなく、「見えているもの」をそのまま処理してほしいという考えで作ったものでもあり、Webブラウザ（Safari）で表示中のページのソースを取得してそのまま処理しています。つまり、ユーザーが閲覧中のページのデータそのものを処理しています。

これは、ページのソースを取得するコマンドを持っていないGoogle Chromeにはできない処理です（同じURLの内容を別途curlコマンドなどで取得すればOK。Cookie値などの再現が大変でしょうけれども）。

その他、実際に作って使ってみた感想は、装飾用に使われている表データまで取り込んでしまう点に不満があるぐらいでしょうか。これら「ゴミデータ」（再利用する価値のない装飾用の表データ）を区別するために、行数が足りない場合には書き出さないといった「足切り」を行う必要性を感じます。

–> Download VisibleTableExporter(Code-signed executable applet with Framework in its bundle)

AppleScript名：Safariで現在見えている表を抽出してCSV書き出し.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/22
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader

set aTag to "table"

set indRes to getVisibleElementIndexList(aTag) of me
if indRes = false or indRes = {} then
　　display notification "No Visible Table in Web browser"
　　return
end if

tell application "Safari"
　　tell front document
　　　　set aSource to source
　　end tell
end tell

repeat with i in indRes
　　set inList to filterATableAndPaseCells(aSource, i, aTag) of me
　　if inList = false or inList = {} then return
　　set aUUID to current application’s NSUUID’s UUID()’s UUIDString() as text
　　set aNewFile to ((path to desktop) as string) & aUUID & ".csv"
　　saveAsCSV(inList, aNewFile) of me
　　
　　tell application "Numbers"
　　　　open (aNewFile as alias)
　　end tell
end repeat

tell application "Numbers" to activate

–1D Listを2D化
on makeList1DTo2D(orig1DList as list, aMax)
　　set tbList to {}
　　set tmpList to {}
　　set aCount to 1
　　
　　repeat with i3 in orig1DList
　　　　set j to contents of i3
　　　　set the end of tmpList to j
　　　　
　　　　if aCount ≥ aMax then
　　　　　　set aCount to 1
　　　　　　set the end of tbList to tmpList
　　　　　　set tmpList to {}
　　　　else
　　　　　　set aCount to aCount + 1
　　　　end if
　　end repeat
　　
　　return tbList
end makeList1DTo2D

–Safariのウィンドウ上で表示中のDOM Elementsを座標計算して返す
on getVisibleElementIndexList(aTag as string)
　　tell application "Safari"
　　　　set dCount to count every document
　　　　if dCount = 0 then return false
　　　　
　　　　set jRes to do JavaScript "var winWidth = window.innerWidth,
winHeight = window.innerHeight,
winLeft = window.scrollX
winTop = window.scrollY,
winBottom = winTop + winHeight,
winRight = winLeft + winWidth,
　　　　elementsArray = document.body.getElementsByTagName(’" & aTag & "’),
　　　　elemLen = elementsArray.length,
inView = [];
　　　　　　
　　　　var step;
　　　　for (step = 0 ; step < elemLen ; step++) {
　　　　　　var tmpElem = document.body.getElementsByTagName(’" & aTag & "’)[step];
　　　　　　var bVar = tmpElem.getBoundingClientRect();
　　　　　　if (bVar.top > 0 && bVar.top < winHeight) {
　　　　　　　　inView.push(step);
　　　　　　}
　　　　}
　　　　JSON.stringify(inView);" in front document
　　　　
　　　　set jList to parseJSONAsList(jRes) of me
　　　　return jList
　　　　
　　end tell
end getVisibleElementIndexList

★Click Here to Open This Script　

Safariで指定のDOM Elementの情報を取得する

Posted on 9月 22 by Takaaki Naganoya

Safariで表示中の最前面のDocument内の指定Tag、指定Index（出現順、0はじまり）のDOM Elementの詳細なプロパティ値を取得するAppleScriptです。

複数のTableが存在しているページのそれぞれのプロパティ値を取得してdiffを取るための調査用Scriptです。

AppleScript名：Safariで指定のDOM Elementの情報を取得する

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

tell application "Safari"
　　set jsStr to "var elementsArray = document.body.getElementsByTagName(’table’);
　　　　aVar = window.getComputedStyle(elementsArray[1]);
　　JSON.stringify(aVar);"
　　
　　set aHeight to do JavaScript jsStr in front document
　　set cRes to parseJSONAsRecord(aHeight) of me
end tell

–> {|95|:"font-style", |50|:"caret-color", |96|:"font-synthesis", |51|:"clear", |97|:"font-variant", webkitMaskPosition:"0% 0%", |52|:"clip", |98|:"font-variant-alternates", webkitHyphens:"manual", |right|:"auto", |53|:"clip-path", |99|:"font-variant-caps", |54|:"clip-rule", backgroundAttachment:"scroll", willChange:"auto", |55|:"color", margin:"0px 0px 20px", marginTop:"0px", |10|:"animation-name", |56|:"color-interpolation", webkitColumnBreakBefore:"auto", baselineShift:"baseline", webkitLineSnap:"none", |11|:"animation-play-state", |57|:"color-interpolation-filters", scrollSnapMargin:"0px", transform:"none", |12|:"animation-timing-function", |58|:"color-rendering", |13|:"background-attachment", |59|:"color-scheme", fontVariantPosition:"normal", gridAutoFlow:"row", |14|:"background-blend-mode", position:"static", |15|:"background-clip", |16|:"background-color", |17|:"background-image", webkitMaskComposite:"source-over", |18|:"background-origin", justifyItems:"normal", |19|:"background-position", colorRendering:"auto", |color|:"rgb(51, 51, 51)", listStyleImage:"none", borderBottom:"0px none rgb(128, 128, 128)", backgroundOrigin:"padding-box", counterIncrement:"none", webkitMaskRepeatY:"", writingMode:"horizontal-tb", borderInlineEndStyle:"none", columnGap:"normal", textDecorationLine:"none", scrollSnapMarginBottom:"0px", strokeColor:"rgba(0, 0, 0, 0)", webkitBoxOrdinalGroup:"1", alignItems:"normal", caretColor:"rgb(51, 51, 51)", webkitMarginBottomCollapse:"collapse", paddingLeft:"0px", fontWeight:"normal", padding:"0px", scrollPaddingTop:"0px", flexGrow:"0", boxSizing:"border-box", webkitBackgroundSize:"auto", marginBottom:"20px", gridTemplateRows:"none", background:"rgba(0, 0, 0, 0) none repeat scroll 0% 0% / auto padding-box border-box", fontDisplay:"", speakAs:"normal", |left|:"auto", webkitBoxDecorationBreak:"slice", scrollSnapAlign:"none none", backgroundPosition:"0% 0%", gridRowStart:"auto", borderBlockStartWidth:"0px", borderTopLeftRadius:"0px", webkitUserDrag:"auto", borderRightColor:"rgb(128, 128, 128)", fontVariantAlternates:"normal", breakInside:"auto", webkitTextZoom:"normal", marker:"", webkitClipPath:"none", strokeLinejoin:"miter", webkitMarquee:"", breakAfter:"auto", webkitMaskPositionX:"0%", whiteSpace:"normal", backgroundColor:"rgba(0, 0, 0, 0)", flexDirection:"row", columns:"auto auto", transformOriginX:"", clip:"auto", emptyCells:"show", transformOrigin:"413.75px 309.4021911621094px", borderLeftColor:"rgb(128, 128, 128)", flex:"0 1 auto", webkitTextStroke:"", clipRule:"nonzero", grid:"none / none / none / row / auto / auto", listStyleType:"disc", maxWidth:"none", borderInlineStartStyle:"none", webkitTextOrientation:"mixed", clipPath:"none", justifySelf:"auto", clear:"none", transformOriginY:"", overflowWrap:"break-word", webkitHyphenateLimitAfter:"auto", tabSize:"8", marginBlockStart:"0px", |120|:"image-rendering", unicodeRange:"", gridColumnEnd:"auto", webkitRubyPosition:"before", |220|:"text-rendering", animationDirection:"normal", webkitMaskOrigin:"border-box", |121|:"isolation", fontStyle:"normal", |320|:"-webkit-text-emphasis-position", |221|:"text-shadow", webkitTextFillColor:"rgb(51, 51, 51)", |122|:"justify-content", borderBottomLeftRadius:"0px", |321|:"-webkit-text-emphasis-style", |80|:"fill-rule", |222|:"text-transform", |123|:"justify-items", |81|:"filter", |322|:"-webkit-text-fill-color", transformOriginZ:"", borderRightWidth:"0px", |82|:"flex-basis", |223|:"text-underline-position", |124|:"justify-self", webkitTextSizeAdjust:"auto", |83|:"flex-direction", |323|:"-webkit-text-orientation", |224|:"top", |84|:"flex-flow", |125|:"kerning", |150|:"opacity", |85|:"flex-grow", |324|:"-webkit-text-security", borderBlockStartStyle:"none", |225|:"touch-action", |40|:"border-top-color", |86|:"flex-shrink", |126|:"left", |250|:"-apple-color-filter", |151|:"order", |41|:"border-top-left-radius", |87|:"flex-wrap", |325|:"-webkit-text-size-adjust", |226|:"transform", border:"0px none rgb(128, 128, 128)", |42|:"border-top-right-radius", |88|:"float", |127|:"letter-spacing", |152|:"orphans", |251|:"-webkit-appearance", |43|:"border-top-style", |89|:"flood-color", |227|:"transform-box", |326|:"-webkit-text-stroke-color", |252|:"-webkit-backdrop-filter", |44|:"border-top-width", |128|:"lighting-color", |153|:"outline-color", |327|:"-webkit-text-stroke-width", borderBlockEndColor:"rgb(128, 128, 128)", |45|:"bottom", |228|:"transform-origin", borderInlineEnd:"0px none rgb(128, 128, 128)", |253|:"-webkit-backface-visibility", |129|:"line-break", |46|:"box-shadow", |154|:"outline-offset", |328|:"-webkit-text-zoom", alignContent:"normal", borderLeftStyle:"none", |47|:"box-sizing", |229|:"transform-style", |254|:"-webkit-background-clip", colorScheme:"auto", shapeOutside:"none", |48|:"buffered-rendering", |155|:"outline-style", |180|:"ry", |329|:"-webkit-transform-style", minBlockSize:"0px", |49|:"caption-side", |255|:"-webkit-background-composite", inlineSize:"827.5px", |280|:"-webkit-font-kerning", |156|:"outline-width", textDecorationColor:"rgb(51, 51, 51)", |181|:"scroll-padding", transitionProperty:"all", webkitBoxDirection:"normal", webkitInitialLetter:"normal", |256|:"-webkit-background-origin", gridColumn:"auto / auto", |281|:"-webkit-font-smoothing", |157|:"overflow-wrap", listStyle:"disc outside none", |182|:"scroll-padding-bottom", webkitMaskBoxImage:"none", floodColor:"rgb(0, 0, 0)", webkitTextEmphasisPosition:"over right", |257|:"-webkit-background-size", scrollSnapMarginRight:"0px", |282|:"-webkit-hyphenate-character", |158|:"overflow-x", webkitTextSecurity:"none", |183|:"scroll-padding-left", columnRule:"0px none rgb(51, 51, 51)", |258|:"-webkit-border-fit", gridColumnStart:"auto", |283|:"-webkit-hyphenate-limit-after", |159|:"overflow-y", touchAction:"auto", |184|:"scroll-padding-right", webkitFontSizeDelta:"", webkitLocale:"ja", |259|:"-webkit-border-horizontal-spacing", |284|:"-webkit-hyphenate-limit-before", colorInterpolation:"sRGB", borderTopColor:"rgb(128, 128, 128)", |185|:"scroll-padding-top", |285|:"-webkit-hyphenate-limit-lines", hangingPunctuation:"none", |186|:"scroll-snap-align", mask:"none", borderRight:"0px none rgb(128, 128, 128)", paddingInlineStart:"0px", webkitBackgroundOrigin:"padding-box", |286|:"-webkit-hyphens", |187|:"scroll-snap-margin", pageBreakAfter:"auto", colorProfile:"", textAnchor:"start", |287|:"-webkit-initial-letter", webkitMaskSize:"auto", |188|:"scroll-snap-margin-bottom", overflowX:"visible", |288|:"-webkit-line-align", strokeLinecap:"butt", |189|:"scroll-snap-margin-left", |289|:"-webkit-line-box-contain", borderBottomColor:"rgb(128, 128, 128)", paddingRight:"0px", fontOpticalSizing:"auto", borderImage:"none", floodOpacity:"1", webkitAspectRatio:"auto", webkitColumnProgression:"normal", alignSelf:"auto", display:"table", borderRadius:"0px", maxInlineSize:"none", minHeight:"0px", strokeMiterlimit:"4", webkitBorderVerticalSpacing:"0px", webkitMaskClip:"border-box", webkitBorderHorizontalSpacing:"0px", objectPosition:"50% 50%", kerning:"0", borderStyle:"none", visibility:"visible", textShadow:"none", borderLeftWidth:"0px", shapeImageThreshold:"0", scrollSnapMarginTop:"0px", markerMid:"none", scrollPadding:"0px", markerEnd:"none", webkitFontKerning:"auto", borderBottomWidth:"0px", float:"none", placeSelf:"auto auto", webkitBackgroundComposite:"source-over", borderTop:"0px none rgb(128, 128, 128)", backgroundRepeat:"repeat", webkitMarqueeDirection:"auto", animationIterationCount:"1", backgroundPositionX:"0%", content:"", transformStyle:"flat", borderInlineEndColor:"rgb(128, 128, 128)", borderBlockStart:"0px none rgb(128, 128, 128)", overflow:"visible", webkitMaskPositionY:"0%", perspective:"none", strokeDashoffset:"0px", outlineColor:"rgb(51, 51, 51)", webkitMarqueeSpeed:"", webkitTextEmphasisStyle:"none", isolation:"auto", borderInlineStartColor:"rgb(128, 128, 128)", textDecorationSkip:"auto", outlineOffset:"0px", objectFit:"fill", textUnderlineOffset:"auto", webkitAppearance:"none", webkitMaskBoxImageWidth:"auto", animationTimingFunction:"ease", borderWidth:"0px", borderSpacing:"0px 0px", captionSide:"top", columnWidth:"auto", rowGap:"normal", webkitMaskBoxImageSource:"none", webkitRtlOrdering:"logical", |70|:"counter-reset", paddingInlineEnd:"0px", |71|:"cursor", |72|:"cx", fontSize:"14.000000953674316px", |73|:"cy", vectorEffect:"none", |74|:"direction", justifyContent:"normal", fillRule:"nonzero", |75|:"display", fontSynthesis:"style weight small-caps", |30|:"border-image-repeat", |76|:"dominant-baseline", |31|:"border-image-slice", |77|:"empty-cells", pageBreakBefore:"auto", |32|:"border-image-source", |78|:"fill", cx:"0px", webkitMaskBoxImageRepeat:"stretch", borderImageSource:"none", |33|:"border-image-width", |79|:"fill-opacity", cy:"0px", outlineStyle:"none", webkitBoxFlex:"0", |34|:"border-left-color", width:"827.5px", webkitMarginBeforeCollapse:"collapse", |35|:"border-left-style", borderRightStyle:"none", |36|:"border-left-width", |0|:"align-content", |37|:"border-right-color", |1|:"align-items", paddingBlockStart:"0px", |size|:"", |2|:"align-self", |38|:"border-right-style", |3|:"alignment-baseline", |4|:"alt", |39|:"border-right-width", webkitFontSmoothing:"auto", |5|:"animation-delay", borderTopWidth:"0px", |6|:"animation-direction", |100|:"font-variant-east-asian", |7|:"animation-duration", |8|:"animation-fill-mode", |200|:"stroke", |9|:"animation-iteration-count", webkitTransformStyle:"flat", |101|:"font-variant-ligatures", counterReset:"none", |300|:"-webkit-mask-box-image", maskType:"luminance", webkitBoxShadow:"none", |201|:"stroke-color", borderBlockEndStyle:"none", |102|:"font-variant-numeric", fontStretch:"normal", textDecorationStyle:"solid", |301|:"-webkit-mask-box-image-outset", cursor:"auto", |202|:"stroke-dasharray", webkitMarqueeStyle:"scroll", |103|:"font-variant-position", animationFillMode:"none", glyphOrientationVertical:"auto", |302|:"-webkit-mask-box-image-repeat", |203|:"stroke-dashoffset", textRendering:"auto", |104|:"font-variation-settings", borderImageRepeat:"stretch", |303|:"-webkit-mask-box-image-slice", |204|:"stroke-linecap", height:"618.8043823242188px", |105|:"font-weight", all:"", |130|:"line-height", |304|:"-webkit-mask-box-image-source", pointerEvents:"auto", textTransform:"none", |205|:"stroke-linejoin", dominantBaseline:"auto", |230|:"transition-delay", |106|:"glyph-orientation-horizontal", filter:"none", |131|:"list-style-image", |305|:"-webkit-mask-box-image-width", |330|:"-webkit-user-drag", |206|:"stroke-miterlimit", paintOrder:"normal", |231|:"transition-duration", |107|:"glyph-orientation-vertical", placeItems:"normal normal", |132|:"list-style-position", |306|:"-webkit-mask-clip", borderInlineStart:"0px none rgb(128, 128, 128)", |331|:"-webkit-user-modify", |207|:"stroke-opacity", textOverflow:"clip", |232|:"transition-property", |108|:"grid-auto-columns", webkitBackdropFilter:"none", |133|:"list-style-type", |307|:"-webkit-mask-composite", webkitMaskRepeat:"repeat", |332|:"-webkit-user-select", |208|:"stroke-width", webkitBoxReflect:"none", |233|:"transition-timing-function", |109|:"grid-auto-flow", |134|:"margin-bottom", |308|:"-webkit-mask-image", |333|:"fullscreen-inset-bottom", |209|:"tab-size", |234|:"unicode-bidi", flexWrap:"nowrap", wordSpacing:"0px", |135|:"margin-left", |309|:"-webkit-mask-origin", |160|:"padding-bottom", |334|:"safe-area-inset-bottom", flexFlow:"row nowrap", |235|:"vector-effect", |260|:"-webkit-border-image", |136|:"margin-right", |161|:"padding-left", |335|:"safe-area-inset-left", transition:"all 0s ease 0s", |236|:"vertical-align", columnFill:"balance", |261|:"-webkit-border-vertical-spacing", |137|:"margin-top", |162|:"padding-right", |336|:"fullscreen-inset-left", maxHeight:"none", |237|:"visibility", alt:"＼"＼"", |262|:"-webkit-box-align", |138|:"marker-end", marginInlineEnd:"0px", |163|:"padding-top", |337|:"fullscreen-inset-right", webkitMarginTopCollapse:"collapse", |238|:"white-space", gridRowEnd:"auto", |263|:"-webkit-box-decoration-break", |139|:"marker-mid", |164|:"page-break-after", |338|:"fullscreen-auto-hide-duration", fillOpacity:"1", |239|:"widows", |264|:"-webkit-box-direction", overflowY:"visible", |165|:"page-break-before", |339|:"safe-area-inset-right", |190|:"scroll-snap-margin-right", |265|:"-webkit-box-flex", animationDuration:"0s", |290|:"-webkit-line-clamp", |166|:"page-break-inside", marginRight:"0px", |191|:"scroll-snap-margin-top", |266|:"-webkit-box-flex-group", borderInlineStartWidth:"0px", |291|:"-webkit-line-grid", |167|:"paint-order", webkitNbspMode:"normal", |192|:"scroll-snap-type", |267|:"-webkit-box-lines", mixBlendMode:"normal", |292|:"-webkit-line-snap", |168|:"perspective", paddingBlockEnd:"0px", |193|:"shape-image-threshold", src:"", webkitBoxAlign:"stretch", |268|:"-webkit-box-ordinal-group", paddingTop:"0px", |293|:"-webkit-locale", |169|:"perspective-origin", borderBlockEnd:"0px none rgb(128, 128, 128)", |194|:"shape-margin", r:"0px", textAlign:"start", |269|:"-webkit-box-orient", webkitMaskBoxImageOutset:"0px", |294|:"-webkit-margin-after-collapse", webkitTextEmphasis:"", webkitTextStrokeColor:"rgb(51, 51, 51)", |195|:"shape-outside", breakBefore:"auto", wordWrap:"break-word", |295|:"-webkit-margin-before-collapse", minInlineSize:"0px", |196|:"shape-rendering", borderInlineEndWidth:"0px", webkitLineAlign:"none", webkitMaskBoxImageSlice:"0 fill", widows:"auto", perspectiveOrigin:"413.75px 309.4021911621094px", |296|:"-webkit-marquee-direction", x:"0px", y:"0px", |197|:"speak-as", perspectiveOriginX:"", |297|:"-webkit-marquee-increment", |198|:"stop-color", fontFamily:"-apple-system, BlinkMacSystemFont, ＼"Segoe UI＼", Roboto, Oxygen-Sans, Ubuntu, Cantarell, ＼"Helvetica Neue＼", sans-serif", |298|:"-webkit-marquee-repetition", |199|:"stop-opacity", animationPlayState:"running", webkitHyphenateLimitBefore:"auto", |299|:"-webkit-marquee-style", webkitBoxOrient:"horizontal", order:"0", webkitMaskSourceType:"alpha", fontVariantNumeric:"normal", webkitColumnBreakAfter:"auto", webkitColumnBreakInside:"auto", shapeMargin:"0px", webkitMaskImage:"none", top:"auto", backgroundBlendMode:"normal", listStylePosition:"outside", bottom:"auto", gridTemplateColumns:"none", strokeWidth:"0.8695652484893799px", borderTopRightRadius:"0px", direction:"ltr", webkitBackfaceVisibility:"visible", backgroundPositionY:"0%", rx:"0px", webkitHyphenateLimitLines:"no-limit", ry:"0px", lineBreak:"auto", bufferedRendering:"auto", quotes:"", gridRow:"auto / auto", webkitBorderFit:"border", borderBottomRightRadius:"0px", alignmentBaseline:"auto", textIndent:"0px", paddingBottom:"0px", columnRuleColor:"rgb(51, 51, 51)", fontVariantCaps:"normal", backgroundSize:"auto", |60|:"column-count", columnCount:"auto", |61|:"column-fill", webkitBoxLines:"single", webkitBoxFlexGroup:"1", backgroundRepeatX:"", |62|:"column-gap", glyphOrientationHorizontal:"0deg", lineHeight:"20px", |63|:"column-rule-color", borderBlockEndWidth:"0px", opacity:"1", webkitBackgroundClip:"border-box", webkitBoxPack:"start", |64|:"column-rule-style", |65|:"column-rule-width", borderImageWidth:"1", fontVariantLigatures:"normal", |20|:"background-repeat", |66|:"column-span", |21|:"background-size", |67|:"column-width", gridTemplateAreas:"none", tableLayout:"auto", |22|:"baseline-shift", |68|:"content", webkitBorderImage:"none", |23|:"border-bottom-color", |69|:"counter-increment", animationName:"none", letterSpacing:"normal", |24|:"border-bottom-left-radius", |25|:"border-bottom-right-radius", backgroundClip:"border-box", transitionDelay:"0s", |26|:"border-bottom-style", |27|:"border-bottom-width", webkitCursorVisibility:"auto", |28|:"border-collapse", webkitTextDecorationsInEffect:"none", |29|:"border-image-outset", fill:"rgb(0, 0, 0)", webkitHyphenateCharacter:"auto", animation:"", pageBreakInside:"auto", lightingColor:"rgb(255, 255, 255)", webkitLineClamp:"none", perspectiveOriginY:"", textDecorationThickness:"auto", marginInlineStart:"0px", borderTopStyle:"none", placeContent:"normal normal", backgroundRepeatY:"", textUnderlinePosition:"auto", wordBreak:"normal", columnRuleStyle:"none", webkitUserModify:"read-only", columnSpan:"none", strokeOpacity:"1", webkitMarqueeRepetition:"infinite", webkitMarginCollapse:"", flexBasis:"auto", colorInterpolationFilters:"linearRGB", gap:"normal normal", webkitMask:"", gridArea:"auto / auto / auto / auto", gridTemplate:"none / none / none", resize:"none", borderColor:"rgb(128, 128, 128)", zIndex:"auto", webkitTextCombine:"none", webkitTextStrokeWidth:"0px", borderBottomStyle:"none", fontVariant:"normal", scrollSnapType:"none", textDecoration:"none", webkitTextEmphasisColor:"rgb(51, 51, 51)", orphans:"auto", scrollPaddingRight:"0px", borderImageOutset:"0px", webkitTextDecoration:"none solid rgb(51, 51, 51)", |110|:"grid-auto-rows", marginLeft:"0px", transitionTimingFunction:"ease", |210|:"table-layout", stroke:"none", stopOpacity:"1", |111|:"grid-column-end", |310|:"-webkit-mask-position", stopColor:"rgb(0, 0, 0)", webkitPrintColorAdjust:"economy", |211|:"text-align", unicodeBidi:"normal", |112|:"grid-column-start", |311|:"-webkit-mask-repeat", page:"", |212|:"text-anchor", |113|:"grid-row-end", |312|:"-webkit-mask-size", fontFeatureSettings:"normal", |213|:"text-decoration", |114|:"grid-row-start", webkitMarqueeIncrement:"6px", webkitUserSelect:"text", |313|:"-webkit-mask-source-type", gridAutoRows:"auto", |214|:"text-decoration-color", |115|:"grid-template-areas", |140|:"marker-start", |314|:"-webkit-nbsp-mode", scrollPaddingBottom:"0px", |215|:"text-decoration-line", |240|:"width", |116|:"grid-template-columns", |141|:"mask", |315|:"-webkit-print-color-adjust", borderBlockStartColor:"rgb(128, 128, 128)", |340|:"fullscreen-inset-top", |216|:"text-decoration-skip", fontVariantEastAsian:"normal", |241|:"will-change", |117|:"grid-template-rows", fontVariationSettings:"normal", |142|:"mask-type", |316|:"-webkit-rtl-ordering", marginBlockEnd:"20px", |341|:"safe-area-inset-top", |217|:"text-decoration-style", minWidth:"0px", |242|:"word-break", |118|:"hanging-punctuation", zoom:"1", |143|:"max-height", |317|:"-webkit-text-combine", |218|:"text-indent", gridAutoColumns:"auto", |243|:"word-spacing", |119|:"height", verticalAlign:"baseline", |144|:"max-width", |318|:"-webkit-text-decorations-in-effect", imageRendering:"auto", maxBlockSize:"none", |219|:"text-overflow", outlineWidth:"0px", |244|:"word-wrap", shapeRendering:"auto", webkitLineGrid:"none", |145|:"min-height", |319|:"-webkit-text-emphasis-color", |170|:"place-content", enableBackground:"", |245|:"writing-mode", |270|:"-webkit-box-pack", |146|:"min-width", animationDelay:"0s", |171|:"place-items", boxShadow:"none", scrollSnapMarginLeft:"0px", webkitBorderRadius:"", |246|:"x", |271|:"-webkit-box-reflect", |147|:"mix-blend-mode", |172|:"place-self", |247|:"y", blockSize:"618.8043823242188px", |272|:"-webkit-box-shadow", |148|:"object-fit", columnRuleWidth:"0px", |173|:"pointer-events", backgroundImage:"none", |248|:"z-index", |273|:"-webkit-clip-path", |149|:"object-position", transitionDuration:"0s", |174|:"position", |249|:"zoom", |274|:"-webkit-column-axis", webkitColumnAxis:"auto", |175|:"r", borderImageSlice:"100%", |275|:"-webkit-column-break-after", borderCollapse:"collapse", |176|:"resize", |276|:"-webkit-column-break-before", webkitLineBoxContain:"block inline replaced", |177|:"right", |277|:"-webkit-column-break-inside", |178|:"row-gap", borderLeft:"0px none rgb(128, 128, 128)", |font|:"normal normal normal normal 14.000000953674316px/20px -apple-system, BlinkMacSystemFont, ＼"Segoe UI＼", Roboto, Oxygen-Sans, Ubuntu, Cantarell, ＼"Helvetica Neue＼", sans-serif", webkitMarginAfterCollapse:"collapse", |278|:"-webkit-column-progression", |outline|:"rgb(51, 51, 51) none 0px", scrollPaddingLeft:"0px", |90|:"flood-opacity", |179|:"rx", markerStart:"none", strokeDasharray:"none", |91|:"font-family", |279|:"-webkit-cursor-visibility", flexShrink:"1", webkitMaskRepeatX:"", |92|:"font-optical-sizing", transformBox:"border-box", |93|:"font-size", |94|:"font-stretch"}

on parseJSONAsRecord(jsRes)
　　set jsonString to current application’s NSString’s stringWithString:jsRes
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　return aJsonDict as record
end parseJSONAsRecord

★Click Here to Open This Script　

Safariのdo JavaScriptから結果をJSONで返してASの各種オブジェクトに変換

Posted on 9月 22 by Takaaki Naganoya

Safariのdo JavaScriptコマンドから各種結果を取得してAppleScriptの各種オブジェクトに変換するAppleScriptです。

真剣にSafari上でdo JavaScriptコマンド経由で値の受け渡しをするときに、さまざまな型のデータをJavaScript側からAppleScript側に渡したいことがあります。ただ、まじめにデータの受け渡しはそんなにやっていないので、あらためて方法を調べておきました。

AppleScript名：Safariのdo javascriptから結果をJSONで返してASの各種オブジェクトに変換

tell application "Safari"
　　if (count every document) = 0 then return
　　
　　–String List (1D)
　　set jsRes1 to do JavaScript "var tempVar = [’1’,’2’];
　　JSON.stringify(tempVar);" in front document
　　set aRes to parseJSONAsList(jsRes1) of me
　　–> {"1", "2"}
　　
　　–Number List (1D)　　
　　set jsRes2 to do JavaScript "var tempVar = [1,2];
　　JSON.stringify(tempVar);" in front document
　　set bRes to parseJSONAsList(jsRes2) of me
　　–> {1, 2}
　　
　　–Record　　
　　set jsRes3 to do JavaScript "var tempVar2 = { name:’Steve Jobs’, age:32, tel:’080-1234-5678’ };
　　JSON.stringify(tempVar2);" in front document
　　set cRes to parseJSONAsRecord(jsRes3) of me
　　–> {|name|:"Steve Jobs", age:32, tel:"080-1234-5678"}
　　
　　–Records in List
　　set jsRes4 to do JavaScript "var tempVar2 = [{ name:’Steve Jobs’, age:32, tel:’080-1234-5678’ },{ name:’Tim Coo’, age:55, tel:’090-1234-5678’ }] ;
　　JSON.stringify(tempVar2);" in front document
　　set dRes to parseJSONAsList(jsRes4) of me
　　–> {{|name|:"Steve Jobs", age:32, tel:"080-1234-5678"}, {|name|:"Tim Coo", age:55, tel:"090-1234-5678"}}
　　
　　–Number List (2D)　　
　　set jsRes5 to do JavaScript "var tempVar = [[1,2], [3,4], [5,6]];
　　JSON.stringify(tempVar);" in front document
　　set eRes to parseJSONAsList(jsRes5) of me
　　–> {{1, 2}, {3, 4}, {5, 6}}
end tell

on parseJSONAsList(jsRes)
　　set jsonString to current application’s NSString’s stringWithString:jsRes
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　return aJsonDict as list
end parseJSONAsList

★Click Here to Open This Script　

AppleScript名：Safariのdo javascriptから結果をJSONで返してASの各種オブジェクトに変換 2

tell application "Safari"
　　if (count every document) = 0 then return
　　
　　–String
　　set jsRes1 to do JavaScript "var tempVar = ’1’;
　　tempVar;" in front document
　　–> "1"
　　
　　–Number
　　set jsRes2 to do JavaScript "var tempVar = 1;
　　tempVar;" in front document
　　–> 1.0
　　
end tell

★Click Here to Open This Script　

Skimでオープン中のPDFで選択中のテキストを返す

Posted on 9月 16 by Takaaki Naganoya

フリーでScriptableなmacOS用PDFビューワー「Skim」上でオープン中のPDFで、選択中のテキストの内容を取得するAppleScriptです。

フリーかつオープンソースで提供されているアプリケーションのうち、奇跡的に豊富なAppleScript対応機能を備えるPDFビューワー、それがSkimです。Skimに比べればPreview.appなど取るに足らない存在。「PDFビューワー四天王」のうち、その最上位に君臨するアプリケーションこそがSkimです（四天王とかいいつつ、Skim、Preview、Acrobatの３人しかいないのはお約束）。

▲SkimでPDFをオープンし、「AppleScriptってなんだろう？」の文字列を選択

ただ、そんなグレートな存在のSkimでも、「選択中のテキストを取得する」という処理を書いたことはありませんでした。

Skimの「selection」によって取得されるのがテキストではなくRTFなので、AppleScriptの基本的な機能ではこのRTFはひどく扱いが難しいデータ「でした」。

しかし、Cocoaの機能を利用することで、テキストへの変換は可能です。

それでも、Cocoaが期待するRTFのデータとAppleScriptの世界のRTFのデータ同士の変換が難儀でした。食後の腹ごなしに行うには手に余るといったレベル。

そこで、お気軽データ変換の最後の砦であるクリップボードを経由してRTFをAppleScriptの世界からCocoaの世界に受け渡してみたところ、大成功。あとは、PDFから取得したテキストデータによくあることですが、日本語のテキストだとUnicodeのNormalize方法の問題によりひらがな/カタカナと濁点や半濁点が分離した状態で返ってきました。

これについても、Cocoaの機能を利用してNormalizeを行い、常識的なテキストに変換できました。

AppleScript名：Skimでオープン中のPDFの選択中のテキストを返す

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/16
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

tell application "Skim"
　　tell front document
　　　　set aSel to selection
　　　　repeat with i in aSel
　　　　　　set aCon to contents of i
　　　　　　set rList to RTF of aCon
　　　　　　
　　　　　　set sCon to ""
　　　　　　repeat with ii in rList
　　　　　　　　set the clipboard to ii
　　　　　　　　set aText to getClipboardAsText() of me
　　　　　　　　set aCon to aCon & aText
　　　　　　end repeat
　　　　　　
　　　　　　set aStr to textfy(aCon) of me
　　　　　　return aStr
　　　　end repeat
　　end tell
end tell

–Normalize Unicode Text in NFKC
on textfy(aText as string)
　　set aStr to current application’s NSString’s stringWithString:aText
　　set aNFKC to aStr’s precomposedStringWithCompatibilityMapping()
　　return aNFKC as string
end textfy

–Clipboard内の情報をテキストとして取得する
on getClipboardAsText()
　　— get the pasteboard items
　　set theClip to current application’s NSPasteboard’s generalPasteboard()
　　set pbItems to theClip’s pasteboardItems()
　　
　　set theStrings to {}
　　
　　repeat with anItem in pbItems
　　　　if (anItem’s types()’s containsObject:(current application’s NSPasteboardTypeString)) then
　　　　　　set end of theStrings to (anItem’s stringForType:(current application’s NSPasteboardTypeString)) as text
　　　　end if
　　end repeat
　　
　　return theStrings as text
end getClipboardAsText

★Click Here to Open This Script　

とか言ってたら、夕飯の買い物に出かけようとした頃にShane Stanleyから「もっとシンプルに書けるよー」というサンプルが届いて脱力しました。もっと簡潔に書けたようです（同一サンプルで日本語データに対してチェックずみ）。

ただ、PDFから文字取り出ししたあとは、Unicodeの再Normalizeは割とやらないといけないケースが多いので、選択部分（selection）からRTFじゃなくてcharacterでデータを取り出せばよかったというあたりが反省点でしょうか。

set theText to ""
tell application "Skim"
　　tell front document
　　　　set aSel to selection
　　　　repeat with anItem in aSel
　　　　　　set theText to theText & (characters of anItem) as text
　　　　end repeat
　　end tell
end tell
return theText

★Click Here to Open This Script　

tableExtractor

Posted on 9月 15 by Takaaki Naganoya

Safariで表示中のページのうち、テキストを選択中のキーワードを含む表をCSVファイルに書き出してNumbersでオープンするAppleScriptです。

–> Download tableExtractor Run-Only (Code-Signed Executable including Framework in its bundle)

–> Watch Demo movie

実行前にSafariの「開発」メニューから、「スマート検索フィールドからのJavaScriptの実行を許可」「AppleEventからのJavaScriptの実行を許可」を実行しておく必要があります（実行済みの場合には必要ありません）。

▲Safariで表示中のページのうち、CSV書き出ししたい表のテキストを選択

▲本Scriptで表をCSVに書き出してNumbersでオープン

以前に作成した「Safariで表示中のPageの選択中の文字を含む表データを取得」Scriptがいい線を行っていた（あらかじめ表中のテキストを選択しておく、という前提条件がかったるいかと思っていたのに、そうでもなかった）ので、ありもののサブルーチンを追加して、表部分のHTMLからのタグ削除やCSV書き出しなどを行えるようにしました。

本Scriptは表データをCSV書き出しする必要はどこにもないのですが、Numbers v6.1に「表を新規作成して表のセル数を指定すると多くの場合にエラーになる」というバグがあるので、Numbersを直接操作してデータ出力させることはやっていません。

処理時間もさほどかからないので、表示中のページのすべての表オブジェクトをCSV化したり、表を選択するUIを実装して、「どの表を出力するか？」という選択処理をしてもいいかもしれません。

▲漫然とMacOS日本語で書き出ししたため文字化けしたもの（左）、UTF8を指定して書き出ししたために文字化けしなくなったもの（右）

途中でCSV書き出しした表データに文字化けが発生していたのですが、これはUTF8でファイル書き出ししていなかったためでした。

本Scriptは前バージョンよりもキーワードの検出処理をていねいに行なっています。各TableのHTMLに対してタグの除去を行なったうえでWebブラウザ上で選択中の文字列を含んでいるかどうかをチェックしています。

AppleScript名：tableExtractor.scptd

— Created 2019-09-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader

property NSString : a reference to current application’s NSString
property HTMLDocument : a reference to current application’s HTMLDocument
property NSMutableArray : a reference to current application’s NSMutableArray

tell application "Safari"
　　set dList to every document –Sometimes "count every document"causes error
　　if length of dList = 0 then return
　　
　　–Get URL
　　tell front document
　　　　set aURL to URL
　　end tell
　　
　　–Get Selected Text
　　set aRes to do JavaScript "var selObj = window.getSelection();
　　var selStr = (selObj).getRangeAt(0);
　　unescape(selStr);" in front document
　　
　　if aRes = "" then return
end tell

set aRes to filterATableAndPaseCells(aURL, aRes) of me
if aRes = false then
　　display notification "I could not filter table data…"
　　return
end if

–Save 2D List to temp CSV file on desktop folder
set savePath to ((path to desktop) as string) & (do shell script "uuidgen") & ".csv"
saveAsCSV(aRes, savePath) of me

tell application "Numbers"
　　activate
　　open file savePath
end tell

on filterATableAndPaseCells(aURL, aKeyword)
　　set aData to (do shell script "curl " & aURL)
　　set aHTML to current application’s HTMLDocument’s documentWithString:(aData as string)
　　
　　–Table要素をリストアップ
　　set eList to (aHTML’s nodesMatchingSelector:"table")
　　
　　–Table要素のうちSafari上で選択中の文字列を含むものをサーチ（指定データを含むものを抽出）
　　set hitF to false
　　repeat with i in eList
　　　　set cellList to i’s children()’s array()
　　　　set htmlSource to i’s serializedFragment() as string –HTML source
　　　　set html2 to trimStrFromTo(htmlSource, "<", ">") of me
　　　　set html3 to repChar(html2, return, "") of me
　　　　
　　　　if html3 contains aKeyword then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　end repeat
　　if hitF = false then return false
　　
　　–Count columns of Table Header
　　set aTableHeader to (i’s nodesMatchingSelector:"tr")’s firstObject()
　　set hList to aTableHeader’s nodesMatchingSelector:"th"
　　set hStrList to {}
　　repeat with i1 in hList
　　　　set the end of hStrList to i1’s textContent() as string
　　end repeat
　　set hLen to length of hStrList –count columns
　　
　　–Acquire whole table body contents
　　set aTableBody to (i’s nodesMatchingSelector:"tbody")’s firstObject()
　　set bList to aTableBody’s nodesMatchingSelector:"td"
　　set bbList to {}
　　repeat with i2 in bList
　　　　set the end of bbList to i2’s textContent() as string
　　end repeat
　　
　　set tbList to makeList1DTo2D(bbList, hLen) of me
　　
　　return {hStrList} & tbList
end filterATableAndPaseCells

–1D Listを2D化
on makeList1DTo2D(orig1DList, aMax)
　　set tbList to {}
　　set tmpList to {}
　　set aCount to 1
　　
　　repeat with i3 in orig1DList
　　　　set j to contents of i3
　　　　set the end of tmpList to j
　　　　
　　　　if aCount ≥ aMax then
　　　　　　set aCount to 1
　　　　　　set the end of tbList to tmpList
　　　　　　set tmpList to {}
　　　　else
　　　　　　set aCount to aCount + 1
　　　　end if
　　end repeat
　　
　　return tbList
end makeList1DTo2D

on trimStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to current application’s NSScanner’s scannerWithString:aParamStr
　　set anArray to current application’s NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(reference)
　　　　
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(reference)
　　　　if theValue is missing value then set theValue to ""
　　　　
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　if anArray’s |count|() = 0 then return aParamStr
　　
　　copy aParamStr to curStr
　　repeat with i in (anArray as list)
　　　　set curStr to repChar(curStr, fromStr & i & toStr, "") of me
　　end repeat
　　
　　return curStr
end trimStrFromTo

on repChar(aStr, targStr, repStr)
　　set aString to current application’s NSString’s stringWithString:aStr
　　set bString to aString’s stringByReplacingOccurrencesOfString:targStr withString:repStr
　　set cString to bString as string
　　return cString
end repChar

–2D List to CSV file
on saveAsCSV(aList, aPath)
　　–set crlfChar to (ASCII character 13) & (ASCII character 10)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　writeToFileUTF8(wholeText, bPath, false) of me
　　
end saveAsCSV

on writeToFileUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileUTF8

★Click Here to Open This Script　

htmlの並列ダウンロード処理

Posted on 9月 13 by Takaaki Naganoya

Webコンテンツ（HTML）の並列ダウンロードを行うAppleScriptです。

Webコンテンツからデータを抽出する際に、あらかじめ一括でHTMLを並列ダウンロードしておいて、ダウンロードずみのデータを一括処理すると処理時間を大幅に短縮できます。「戦場の絆」Wikiから機体データの表をすべて取得するのに、順次HTMLを取得して抽出していた場合には３〜４分程度かかっていたものを、並列ダウンロードしたのちにデータ処理するように変更すれば、これが十数秒程度にまで高速化できます。

既存のプログラムを修正してHTMLのダウンロード用に仕立ててみました。並列キュー（未処理タスク数）へのアクセスはAppleScriptからはできなかった（実行すると結果が返ってこなかった）のですが、そこに手をつけずに並列処理の完了状態を検出しています。

ダウンロードが完了したデータはlist（配列）に入るので、リクエスト数と完了リクエスト数をループ内でチェックし、完了アイテム数がリクエスト数と同じになれば終了、条件を満たさない場合でも指定のタイムアウト時間を超えたらエラー終了という処理を行なっています。

問題点は、スクリプトエディタ上では実行できるもののScript Debugger上では実行できないことです（結果が返ってきません）。AppleScriptアプレットに書き出して実行してみたところ、結果が返ってきません。ただし、Script Menuからの実行は行えます（macOS 10.12.6、10.13.6、10.14.6で同様）。XcodeのAppleScript Appのプロジェクト内で実行することはできました。

このように、ランタイム環境に実行状況が左右される点にご注意ください。ただし、そうしたマイナス面を補ってあまりあるほどダウンロードは高速です。90ファイル強のダウンロードを数秒で完了（マシン、ネットワーク速度、ダウンロード先サーバーの負荷状況、キャッシュ状態などに左右される、参考値です）するため、ダウンロード後に各HTMLからのデータ抽出も高速に行えます。

AppleScript名：htmlの並列ダウンロード処理

— Created 2019-09-13 by Takaaki Naganoya
— 2019 Piyomaru Software
—
–　オリジナル：　HTTP からファイルをダウンロードして、ローカルに保存する方法（shintarou_horiのブログ）
— http://shintarou-hori.hatenablog.com/entry/2014/03/15/193604

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSData : a reference to current application’s NSData
property NSString : a reference to current application’s NSString
property NSOperationQueue : a reference to current application’s NSOperationQueue
property NSInvocationOperation : a reference to current application’s NSInvocationOperation
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

property aTimer : missing value

script spd
　　property mList : {}
　　property resList : {}
end script

set (mList of spd) to {}
set (resList of spd) to {}
set baseURL to "https://w.atwiki.jp/senjounokizuna/pages/"

set numList to {25, 1594, 890, 70, 1669, 82, 1717, 997, 1080, 1614, 1712, 159, 1311, 1694, 1752, 1263}

set urlList to {}
repeat with i in numList
　　set the end of urlList to (baseURL & i as string) & ".html"
end repeat

set aLen to length of urlList
set paramObj to {urls:urlList, timeOutSec:60}

–set (resList of spd) to downloadHTMLConcurrently(urlList, 60) of me
my performSelectorOnMainThread:"downloadHTMLConcurrently:" withObject:(paramObj) waitUntilDone:true
return length of (mList of spd)

on downloadHTMLConcurrently:paramObj
　　set urlList to (urls of paramObj) as list
　　set timeOutS to (timeOutSec of paramObj) as real
　　set aLen to length of urlList
　　
　　repeat with i in urlList
　　　　set j to contents of i
　　　　set aURL to (|NSURL|’s URLWithString:j)
　　　　set aQueue to NSOperationQueue’s new()
　　　　set aOperation to (NSInvocationOperation’s alloc()’s initWithTarget:me selector:"execDL:" object:aURL)
　　　　(aQueue’s addOperation:aOperation)
　　end repeat
　　
　　–Check Completion
　　set compF to false
　　set loopTimes to (timeOutS * 10)
　　repeat loopTimes times
　　　　if length of (mList of spd) = aLen then
　　　　　　set compF to true
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　if compF = false then error "Concurrent download timed out"
end downloadHTMLConcurrently:

on execDL:theURL
　　set receiveData to NSData’s alloc()’s initWithContentsOfURL:theURL
　　if receiveData = missing value then
　　　　return
　　end if
　　
　　set aFileName to theURL’s |lastPathComponent|()
　　my performSelectorOnMainThread:"saveData:" withObject:{receiveData, aFileName} waitUntilDone:false
end execDL:

on saveData:theDataArray
　　copy theDataArray to {theData, saveFileName}
　　set aCon to NSString’s alloc()’s initWithData:theData encoding:NSUTF8StringEncoding
　　set the end of (mList of spd) to {fileName:saveFileName as string, contentsData:aCon as string}
end saveData:

★Click Here to Open This Script　

Safariで表示中のPageの選択中の文字を含む表データを取得

Posted on 9月 3 by Takaaki Naganoya

Safari上で一部のテキストを選択した「表」のデータをHTMLReaderフレームワークを利用してparseし、2D Listとして取得するAppleScriptです。

Web上の表データをそのまま利用したいケースが多々あります。こんな小さなデータではなく、数百個にわたる表データをインポートして使いたいというケースです。

そのときに作った部品を転用して、より一般的な用途に使えるようにしたのが本Scriptです。ただし、さまざまな用途に使って鍛えたというものでもなく、AppleのWebドキュメントやWikiの内容の抽出など、割と「規則性の高そうなコンテンツ」で利用してみました。

本来は、複数ページの特定の表を指定してデータを取得する用途に用いているものなので、本Scriptのように「選択中の文字列を含む表」といった、のどかな使い方はしません。動作内容がわかりやすいように作り変えたためにこのような仕様になっています。

どこぞのオンラインストアの諸元をまとめた表をWeb上からくすねてくる、とかいう用途だと、割と表が込み入って（JavaScriptを仕込んでソートし直せるようにしてあるとか）いるケースがあるので、どのページのどの表にでもあまねく利用できるという種類のものではありません。

–> Download HTMLReader.framework(To ~/Library/Frameworks)

HTMLReader.frameworkを利用するためには、macOS 10.14以降だとSIPを解除するかScript Debugger上で動かすか、AppleScriptアプレット内に組み込んで実行することになります。

AppleScript名：Safariで表示中のPageの選択中の文字を含む表データを取得.scptd

— Created 2019-09-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader

set aRes to filterATableAndPaseCells(aURL, aRes) of me
–> {{"Objective-C and AppleScript class", "Attributes (script term, if different)", "Relationships"}, {"NSObjectImplements the item AppleScript class. For any scriptable Objective-C class that inherits from NSObject, the AppleScript class it implements inherits from the item class (and inherits the class property and the properties property).", "class name (class), properties", ""}, {"NSApplicationImplements the application AppleScript class.", "name, active flag (frontMost), version", "documents, windows (both accessible as ordered relationship)"}, {"NSDocumentImplements the document AppleScript class.", "location of the document’s on-disk representation (path); last component of filename (name); edited flag (modified)", ""}, {"NSWindowImplements the window AppleScript class.", "title (name); various binary-state attributes: closeable, floating, miniaturized, modal, resizable, titled, visible, zoomable", "document"}}

on filterATableAndPaseCells(aURL, aKeyword)
　　set aData to (do shell script "curl " & aURL)
　　set aHTML to current application’s HTMLDocument’s documentWithString:(aData as string)
　　
　　–Table要素をリストアップ
　　set eList to (aHTML’s nodesMatchingSelector:"table")
　　
　　–Table要素のうちSafari上で選択中の文字列を含むものをサーチ（指定データを含むものを抽出）
　　set hitF to false
　　repeat with i in eList
　　　　set cellList to i’s children()’s array()
　　　　set htmlSource to i’s serializedFragment() as string –HTML source
　　　　
　　　　if htmlSource contains aKeyword then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　end repeat
　　if hitF = false then return false
　　
　　–Count columns of Table Header
　　set aTableHeader to (i’s nodesMatchingSelector:"tr")’s firstObject()
　　set hList to aTableHeader’s nodesMatchingSelector:"th"
　　set hStrList to {}
　　repeat with i1 in hList
　　　　set the end of hStrList to i1’s textContent() as string
　　end repeat
　　set hLen to length of hStrList –count columns
　　
　　–Acquire whole table body contents
　　set aTableBody to (i’s nodesMatchingSelector:"tbody")’s firstObject()
　　set bList to aTableBody’s nodesMatchingSelector:"td"
　　set bbList to {}
　　repeat with i2 in bList
　　　　set the end of bbList to i2’s textContent() as string
　　end repeat
　　
　　set tbList to makeList1DTo2D(bbList, hLen) of me
　　
　　return {hStrList} & tbList
end filterATableAndPaseCells

★Click Here to Open This Script　

指定URLのMS名を取得する v2a

Posted on 9月 3 by Takaaki Naganoya

Shane Stanleyが「HTMLをXMLと見立ててアクセスすれば外部フレームワークなしに処理できて簡単だよ」と、送ってくれたサンプルScriptです。

２つの意味で焦りました。

（１）指定URLの内容をダウンロードするのに、「initWithContentsOfURL:」で処理
（２）この調子で処理したら、お手軽にREST APIも呼べそうな雰囲気

いろいろ考えさせられる内容でもあります。こういう「それ自体で何か製品を構成できるほどのサイズの処理じゃないけど、何かに絶対に使ってますよね」的な処理をBlogで公開しておくことのメリットを感じつつ、XML処理とか正規表現の処理が個人的に不得意なので、とても参考になります。

自分の用途が残念な（そんなに生産的でもなく趣味的な、という意味で）ものだったので、恐縮するばかりですー（オンラインゲームの機体のデータをWikiからまるごと引っこ抜くというものだったので）。

AppleScript名：get a title.scptd

—
–　　Created by: Shane Stanley
–　　Created on: 2019/09/03
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

— classes, constants, and enums used
property NSXMLDocumentTidyHTML : a reference to 512
property NSXMLDocument : a reference to current application’s NSXMLDocument
property NSString : a reference to current application’s NSString
property |NSURL| : a reference to current application’s |NSURL|
property HTMLDocument : a reference to current application’s HTMLDocument
property NSMutableArray : a reference to current application’s NSMutableArray

set aURL to "https://w.atwiki.jp/senjounokizuna/pages/1650.html"
set aRes to getTitleFromAURL(aURL) of me
–> "ジム・スナイパー　　RGM-79(G)"

on getTitleFromAURL(aURL)
　　set theNSURL to |NSURL|’s URLWithString:aURL
　　set {theXML, theError} to NSXMLDocument’s alloc()’s initWithContentsOfURL:theNSURL options:NSXMLDocumentTidyHTML |error|:(reference)
　　if theXML is missing value then error theError’s localizedDescription() as text
　　repeat with i from 2 to 7 by 1
　　　　set theNodes to (theXML’s nodesForXPath:("//h" & i) |error|:(missing value))
　　　　if theNodes’s |count|() is not 0 then return (theNodes’s firstObject()’s stringValue()) as text
　　end repeat
　　error "Header is missing"
end getTitleFromAURL

★Click Here to Open This Script　

指定URLのMS名を取得する v2

Posted on 9月 3 by Takaaki Naganoya

指定URLの初出の指定タグ要素を抽出するAppleScriptです。

たまたま、戦場の絆Wikiから各種データを自動で抽出するAppleScriptを書いたときについでに作った、各ページのh2タグで囲まれた機種名を取り出す処理部分です。

▲このデータだけ機種名がh3タグでマークされていて、例外を吸収するために汎用性を高めたのが本ルーチン

Webサイトからのデータ取り出しは割と重要な技術です。それを容易に可能にするHTMLReaderのようなFrameworkは、とても重要なパーツといえます。HTMLReaderがなければ、こんな簡単に処理することはできなかったでしょう（この些細な処理を、ではなくやりたい処理全体に対しての評価）。

＃　WebスクレイピングはScripter必須の技術なので、Safari/ChromeでDOMアクセス派や正規表現でソースから抽出派、XMLとして解釈してXPathでアクセスする派などいろいろありそうですが、自分はHTMLReaderを使って楽をしてデータを取り出す派　といえます

特定のURL上のHTMLの特定のタグ要素のデータを抜き出すという処理であり、かならずしもどのサイトでも万能に処理できるというわけでもありません。ただ、Wikiのような管理プログラムでコンテンツを生成しているサイトから各種データを抜き出すのは、生成されるHTMLの規則性が高くて例外が少ないため、割と簡単です。

HTMLReaderをAppleScriptから呼び出し、表データを2D Listとして解釈するなど、データ取り出しが簡単にできるようになったことは意義深いと思われます。

macOS 10.13まではスクリプトエディタ/Script Debugger上でScriptを直接実行できます。macOS 10.14以降ではSIPを解除するか、Script Debugger上で実行するか、本記事に添付したようなアプレット（バンドル内にFramework同梱）を実行する必要があります。

HTMLReaderについては、Frameworkにするよりもアプリケーション化してsdefをつけて、AppleEvent経由で呼び出す専用のバックグラウンドアプリケーションにすることも考えるべきかもしれません。ただ、すべての機能についてsdefをかぶせるためには、「こういうパターンで処理すると便利」という例をみつけてまとめる必要があります。つまり、sdefをかぶせると返り値はAppleScript的なデータに限定されるため、何らかの処理が完結した状態にする必要があります。

–> Download tagElementPicker.zip (Code Signed executable Applet)

–> Download HTMLReader.framework (To ~/Library/Frameworks)

Webコンテンツのダウンロードは、本ルーチンではcurlコマンドで実装していますが、いろいろ試してみたところ現時点で暫定的にこれがベストという判断を行っています。

もともと、macOS 10.7でURL Access Scriptingが廃止になったため、Webアクセスのための代替手段を確保することはScritperの間では優先順位の高い調査項目でした。

curlコマンドはその代替手段の中でも最有力ではあったものの、macOS 10.10以降のAppleScript処理系自体のScripting Bridge対応にともない、NSURLConnectionを用いたアクセスも試してきました。同期処理できて、Blocks構文の記述が必須ではないため、実装のための難易度がCocoa系のサービスでは一番低かったからです。

ただし、NSURLConnection自体がDeprecated扱いになり、後継のNSURLSessionを用いた処理を模索。いろいろ書いているうちに、処理内容がapplescript-stdlibのWebモジュールと酷似した内容になってきた（もともと同ライブラリではNSURLSessionを用いていたため）ので、この機能のためだけにapplescript-stdlibを組み込んで使ってみたりもしました。

しかし、applescript-stdlibのWebモジュールは連続して呼び出すと処理が止まるという代物であり、実際のプログラムに組み込んで使うのは「不可能」でした。１つのURLを処理するには問題はないものの、数百個のURLを処理させると止まることを確認しています。おまけに処理本体にも自分自身のsdefを用いた記述を行っているためメンテナンス性が最悪で、中身をいじくることは（自分には）無理です。

＃　applescript-stdlibのWebモジュールではUserAgent名がサイト側の想定しているものに該当せずアクセスを拒否されたのか、Webモジュール側の内部処理がまずいのかまでは原因追求できていません。連続処理を行うと止まるという症状を確認しているだけです

NSURLSessionによる処理については、applescript-stdlibのWebモジュールを参考にしつつもう少し書き慣れる必要がある一方で、いろいろモジュール単位で差し替えて試行錯誤したところ、curlコマンドは遅くなったり処理が止まったりすることもなく利用できています。

それでも、curlコマンド以外の選択肢を用意しておくことは重要であるため、NSURLSessionも引き続き追いかけておきたいところです。

AppleScript名：指定URLのMS名を取得する v2.scptd

set aURL to "https://w.atwiki.jp/senjounokizuna/pages/1650.html"
set aRes to getTitleFromAURL(aURL) of me
–> "ジム・スナイパー　　RGM-79(G)"

on getTitleFromAURL(aURL)
　　set aData to (do shell script "curl " & aURL)
　　set aHTML to current application’s HTMLDocument’s documentWithString:(aData as string)
　　
　　–Levelの高いHeader Tagから順次低い方にサーチして返す
　　repeat with i from 2 to 7 by 1
　　　　set aHeaderTag to "h" & i as string
　　　　set eList to (aHTML’s nodesMatchingSelector:aHeaderTag)
　　　　
　　　　if (eList as list) is not equal to {} then
　　　　　　return (eList’s firstObject()’s textContent()) as string
　　　　end if
　　end repeat
　　
　　error "Header is missing"
end getTitleFromAURL

★Click Here to Open This Script　

Numbersで選択範囲のセルから数字以外の文字を除去する

Posted on 8月 29 by Takaaki Naganoya

Numbersで選択範囲のセルから数字以外の文字を除去するAppleScriptです。

よく、Webブラウザ上で表示中の表データからNumbersなどの表計算ソフトにデータをコピー＆ペーストして再利用することがあります。この際に、Webブラウザ上で選択中のDOM構造などを取得できると便利なのですが、いろいろ調べてみてもなかなか方法が見つかりません（自分が設計していたら、絶対に実装してるんですけれども）。

そこで、表データをWebブラウザから表計算ソフト上にコピー後にデータ加工することを考えることになります。

ExcelやNumbers上に表データをペーストして、その後で加工することをよく行います。手動で行うとかったるいので、選択範囲のセルを順次加工するScriptを日常的に作ってはストックしてあります（セル内の改行文字を削除するとか、いろいろ）。

本ScriptはmacOS 10.14.6＋Numbers v6.1で検証してあります。

OS標準装備のScript Menuに入れて呼び出して利用しています。

もともと、Numbersのセル書き換え速度はそれほど速くないので、数百セルとか数千セルを一気に書き換えるような用途は考慮していません。そういう用途には、書き換えたデータをCSV書き出しして、CSVのファイルをNumbersでオープンするといった処理になると思います。

AppleScript名：選択範囲のセルから数字以外の文字を除去する

— Created 2019-08-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　return false
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　set cellList to cell of selection range
　　　　　　　　set mySelectedRanges to value of cell of selection range
　　　　　　　　set res2 to returnNumbersCharOnlyList(mySelectedRanges) of me
　　　　　　　　
　　　　　　　　repeat with i from 1 to (length of cellList)
　　　　　　　　　　ignoring application responses –Async Mode
　　　　　　　　　　　　tell item i of cellList
　　　　　　　　　　　　　　set value to item i of res2
　　　　　　　　　　　　end tell
　　　　　　　　　　end ignoring
　　　　　　　　end repeat
　　　　　　　　
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
end tell

on returnNumbersCharOnlyList(aList)
　　set nList to {}
　　repeat with i in aList
　　　　set the end of nList to returnNumberCharsOnly(i) of me
　　end repeat
　　return nList
end returnNumbersCharOnlyList

on returnNumberCharsOnly(aStr)
　　set anNSString to current application’s NSString’s stringWithString:aStr
　　set anNSString to anNSString’s stringByReplacingOccurrencesOfString:"[^0-9]" withString:"" options:(current application’s NSRegularExpressionSearch) range:{0, anNSString’s |length|()}
　　return anNSString as text
end returnNumberCharsOnly

★Click Here to Open This Script　

指定のAppleScriptテキストを構文確認して指定の構文要素が入っていないかチェック

Posted on 7月 31 by Takaaki Naganoya

指定のテキストをAppleScriptとみなして構文確認して、指定の構文要素が入っていないかチェックするAppleScriptです。

文字列をそのままrun scriptすると、一応いろいろ保護機能はあるものの、セキュリティ的にリスクの高い操作になってしまいます。

▲こんなのがrun scriptコマンドで実行されてしまったらと思うとゾッとします。ためしに実行してみたら、実行権限がないので実行できないエラーになりました

そこで、文字列をいったんAppleScriptとして評価（構文確認）し、コマンドなどの危険と思われる構文要素が入っていないかどうかチェックするものです。

これら、「コマンド」および「追加コマンド」といった構文要素が入っていたらtrueを返します。

本Scriptをライブラリ化して組み込むことで、少ない記述量で対象の文字列をそのままrun scriptしてよいかどうか判定できるようにするものです。

–> Download checkDanger(with Library in its bundle)

▲実際にテキストをAppleScriptとして評価して構文要素を検出し、このようにコマンド部分（AppleScriptのdo shell scriptコマンド）が入っていることを検知できる

AppleScript名：指定のAppleScriptテキストを構文確認して指定の構文要素が入っていないかチェック.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/31
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "AppKit"
use framework "OSAKit"
use attrLib : script "asAttrRecLib"

property NSArray : a reference to current application’s NSArray
property OSANull : a reference to current application’s OSANull
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property OSALanguageInstance : a reference to current application’s OSALanguageInstance

script spd
　　property fArray : {}
　　property outList : {}
　　property resStr : {}
end script

on run
　　set theSource to "do shell script ＼"rm -f *.*＼""
　　set aRes to chkTargLexicalElementsFromCompiledScriptAttribute(theSource, {9, 14}) of me –{Command, External Command}
　　–> true : 指定の構文要素が入っていた
　　
　　set theSource to "{{aName:＼"piyoko＼", aVal:100}, {aName:＼"piyomaru＼", aVal:80}, {aName:＼"piyoo＼", aVal:10}, {aName:＼"Gundamo＼", aVal:10}}"
　　set bRes to chkTargLexicalElementsFromCompiledScriptAttribute(theSource, {9, 14}) of me –{Command, External Command}
　　–> false : 指定の構文要素は入っていなかった
end run

–AppleScriptのソーステキストをコンパイルして、指定の構文要素が含まれているかチェックする
on chkTargLexicalElementsFromCompiledScriptAttribute(theSource as string, targLexicalElements as list)
　　
　　–AppleScriptの構文色分け情報を取得
　　set ccRes to getAppleScriptSourceColors() of me
　　set cRes to chkASLexicalFormatColorConfliction(ccRes) of me –構文色分けの重複色チェック
　　if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"
　　
　　–検索用の色情報を作成
　　set colTargList to {}
　　repeat with i in targLexicalElements
　　　　set commentCol to contents of item i of ccRes –Variable and Sub-routine name
　　　　set searchVal to (redValue of commentCol as string) & " " & (greenValue of commentCol as string) & " " & (blueValue of commentCol as string) –for filtering
　　　　set the end of colTargList to searchVal
　　end repeat
　　
　　
　　–与えられたテキストをAppleScriptとして評価し構文色分け情報をもとにStyle Runs的なDictionary化して返す
　　set aRitch to compileASSourcetextAndReturnStyledText(theSource) of me
　　
　　
　　–書式付きテキストからstyle runs的な書式リストを作成
　　set anAttrList to getAttributeRunsFromAttrString(aRitch) of attrLib
　　
　　set bList to filterRecListByLabelAndSublist(anAttrList, "colorStr IN %@", colTargList) of me
　　
　　return not (bList as list = {}) as boolean
　　
end chkTargLexicalElementsFromCompiledScriptAttribute

on retDelimedText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retDelimedText

——-

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceColors()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set colList to {}
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set aColRec to {redValue:rVal, greenValue:gVal, blueValue:bVal, fontName:aFontName, fontSize:aFontSize}
　　　　
　　　　set the end of colList to aColRec
　　end repeat
　　
　　return colList
end getAppleScriptSourceColors

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceNSColorsDict()
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set aDict to NSMutableDictionary’s alloc()’s init()
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set colIndStr to (rVal as string) & " " & (gVal as string) & " " & (bVal as string)
　　　　set tmpColDat to {numList:{rVal, gVal, bVal}, strInd:colIndStr}
　　　　–(aDict’s addObject:tmpColDat forKey:theColor)
　　　　(aDict’s addObject:{rVal, gVal, bVal} forKey:theColor)
　　end repeat
　　
　　return aDict
end getAppleScriptSourceNSColorsDict

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aSpace to (aCol’s colorSpaceName()) as string
　　–set aSpace to (aCol’s type()) as integer
　　
　　if aSpace is in {"NSDeviceRGBColorSpace", "NSCalibratedRGBColorSpace"} then
　　　　copy aCol to cCol
　　else
　　　　–RGB以外の色空間の色は、RGBに変換
　　　　–CMYKとグレースケールは同一メソッドでRGBに変換できることを確認済み
　　　　set cCol to aCol’s colorUsingColorSpaceName:"NSCalibratedRGBColorSpace"
　　　　if cCol = missing value then error "Color Space Conversion Error (" & aSpace & " to NSCalibratedRGBColorSpace)"
　　end if
　　
　　set aRed to round ((cCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((cCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((cCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue} as list
end retColListFromNSColor

–AS書式で配色に重複がないかどうかチェック
on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on returnDuplicatesOnly(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

–テキスト形式のAppleScriptをコンパイルして書式付きテキスト（NSAttributedString）を返す
on compileASSourcetextAndReturnStyledText(theSource)
　　— create a new AppleScript instance
　　set anOSALanguageInstance to OSALanguage’s languageForName:"AppleScript"
　　
　　set theScript to OSAScript’s alloc()’s initWithSource:theSource fromURL:(missing value) languageInstance:anOSALanguageInstance usingStorageOptions:(OSANull)
　　set {theResult, theError} to theScript’s compileAndReturnError:(reference)
　　
　　if theResult as boolean is false then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　return styledSourceText
end compileASSourcetextAndReturnStyledText

–文字置換
on repChar(origText as string, targChar as string, repChar as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

–リストに入れたレコードを、指定の属性ラベルの値で抽出。値が別途指定のリストの中に存在していることが条件
on filterRecListByLabelAndSublist(aRecList as list, aPredicate as string, aSubList as list)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set aSubArray to NSArray’s arrayWithArray:aSubList
　　
　　–抽出
　　set aPredicate to NSPredicate’s predicateWithFormat_(aPredicate, aSubArray)
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　
　　return filteredArray as list
end filterRecListByLabelAndSublist

★Click Here to Open This Script　

NumbersのColumn Adr（26進数）と10進数との相互変換

Posted on 7月 22 by Takaaki Naganoya

Numbersの表のカラムを表現するアドレス文字列（26進数）と数値の間のエンコーダーおよびデコーダーのAppleScriptです。

もともとは、Excel 2004/2008で採用されたカラムアドレス形式に対処するためのScriptでした。

Excel上のセルのアドレス（場所）を指し示す方法は、「R1C1」（行とカラムを数値指定）形式、あるいはAppleScriptの行オブジェクトとセルオブジェクトで指定する形式でした。

そこへ新たに「A1」形式……画面上で表記されている行、カラムと親和性の高い形式が採用されることになりました。当初は相互変換のための関数なども用意されていなかったと記憶しています（間違っていたらご指摘ください）。そのため、Scripterが自力でこのA1形式に対応する必要が出てきました。

そんな中、Excel書類にAppleScriptを埋め込んで実行するAppleScriptを開発。本ルーチンはそのScript開発のために作成したものです。

Excel 2008でVBAの処理系が外されてMac上のVBA的なマクロ処理はAppleSctiptに一本化されるという話になっていたため（当時の話）、これを好機ととらえ、マイクロソフトのご担当にデモして、US本社で紹介していただくということになりました。

ただ、その会議上でVBAの復活プランが発表され、自分の提案したプランは廃案に（まさか当時のREALbasicのコンパイラの開発者を引き抜いてきてVBAの処理系をスクラッチで書かせるとは思いませんでしたわー）。

その後は、Excel 2011でVBAの処理系が復活。本ルーチンも割とHDDの肥やしとして絶賛在庫状態になっておりました。ごくたまーに、このExcel 2011でVBAの処理系が復活したことを知らない方がいて、「VBAで動いているマクロをAppleScriptに移植してほしい」という問い合わせがあるのですが、「Excelの最新版を購入してください。VBAがありますよ」とお返事しています。最新のExcelが動く環境を購入する費用よりも安く仕事としてお受けすることは困難なので。

そこから年月が流れ、AppleがNumbersをリリース。そのカラム表記がExcel 2004/2008と同じ形式になっているために、しまいこんでいたルーチンをふたたび引っ張り出してきた次第です。

一応、条件つきで使えるものの、作りが古い（やっつけ仕事な）点が気になります。きっと、誰かがもっといいルーチンを作って使っているに違いありません。一応、本ルーチンでは1〜1351の範囲での動作を確認しています。

もう少し改良したいところではあります。実用上は、Numbersでそこまで大きなデータは扱わない（はず）ので、問題はあまりないものと思われます。

AppleScript名：NumbersのColumn Adr（26進数）と10進数との相互変換

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSString : a reference to current application’s NSString
property NSArray : a reference to current application’s NSArray
property NSRegularExpressionSearch : a reference to current application’s NSRegularExpressionSearch

repeat with i from 1 to 1351
　　set a to numAdrToColumnEncode(i) of me
　　set b to colAddrToNumDecode(a) of me
　　set aRes to (i = b) as boolean
　　log {i, b, a, aRes}
　　if aRes = false then display dialog i as string
end repeat

–10進数数値をExcel 2004/2008的カラム表現にエンコードするサブルーチン（エンコード範囲：1〜1351）
on numAdrToColumnEncode(origNum)
　　if origNum > 1351 then
　　　　error "エラー：Numbersのカラム表現（A1形式）への変換ルーチンにおいて、想定範囲外（1351以上）のパラメータが指定されました"
　　end if
　　
　　set upperDigitEncTable to {"A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z", "A"}
　　set lowerDigitEncTable to {"A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z", "A"}
　　
　　set oNum to origNum
　　set nTh to 26
　　set stringLength to 4
　　
　　–数字が１桁の場合の対応
　　if origNum < 27 then
　　　　set aRes to (item origNum of upperDigitEncTable) as string
　　　　return aRes
　　end if
　　
　　
　　if origNum > 702 then
　　　　–3桁になる場合
　　　　set upupNum to oNum div 676 –整数除算–上の上の桁
　　　　set oNum to oNum – (upupNum * 676)
　　　　set upNum to oNum div 26 –整数除算–上の桁
　　　　set lowNum to oNum mod 26 – 1 –余剰計算–下の桁
　　　　
　　　　–log {origNum, upupNum, upNum, lowNum}
　　　　
　　　　–超つじつま合わせルーチン【強引】
　　　　if lowNum = -1 then
　　　　　　set upNum to upNum – 1
　　　　　　set lowNum to 25
　　　　end if
　　　　
　　　　set upupChar to (item upupNum of upperDigitEncTable) as string
　　　　set upChar to (item upNum of upperDigitEncTable) as string
　　　　set lowChar to (item (lowNum + 1) of lowerDigitEncTable) as string
　　　　set resText to upupChar & upChar & lowChar
　　　　
　　else
　　　　–2桁の場合
　　　　set upNum to oNum div 26 –整数除算–上の桁
　　　　set lowNum to oNum mod 26 – 1 –余剰計算–下の桁
　　　　
　　　　
　　　　–超つじつま合わせルーチン【強引】
　　　　if lowNum = -1 then
　　　　　　set upNum to upNum – 1
　　　　　　set lowNum to 25
　　　　end if
　　　　
　　　　set upChar to (item upNum of upperDigitEncTable) as string
　　　　set lowChar to (item (lowNum + 1) of lowerDigitEncTable) as string
　　　　set resText to upChar & lowChar
　　　　
　　end if
　　
　　return resText
　　
end numAdrToColumnEncode

–Numbersの横方向アドレス（A〜Zの26進数）文字列を10進数に変換
on colAddrToNumDecode(origStr)
　　return aNthToDecimal(origStr, {"A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z"}) of me
end colAddrToNumDecode

–n進数文字列を10進数に変換する
on aNthToDecimal(origStr, nTh)
　　set resNumber to 0
　　
　　set sList to reverse of (characters of origStr)
　　set aLen to length of nTh
　　set digitCount to 0
　　
　　repeat with i in sList
　　　　set j to contents of i
　　　　set aRes to offsetInList(j, nTh) of me
　　　　
　　　　set resNumber to resNumber + (aLen ^ digitCount) * aRes
　　　　
　　　　set digitCount to digitCount + 1
　　end repeat
　　
　　return resNumber as integer
end aNthToDecimal

on offsetInList(aChar, aList)
　　set anArray to NSArray’s arrayWithArray:aList
　　set aInd to (anArray’s indexOfObject:aChar)
　　if aInd = current application’s NSNotFound or (aInd as number) > 9.99999999E+8 then
　　　　error "Invalid Character Error"
　　else
　　　　return (aInd as integer) + 1 –0 to 1 based index conversion
　　end if
end offsetInList

★Click Here to Open This Script　

指定のAppleScriptテキストを構文確認して変数・プロパティ、サブルーチン名部分のみを取得して置換

Posted on 7月 17 by Takaaki Naganoya

指定のAppleScriptのテキストを構文確認して、構文的に「変数・プロパティ、サブルーチン名」部分に該当する部分のテキストを取得して、目的のテキストに差し替えるAppleScriptです。

Script Debugger上の生産性を向上させるために書いたものです。Script Debuggerはいわゆる「デバッグ」段階では役に立ちますが、快適にScriptを書くための機能はほとんどありません。

いわゆる、ブレークポイントの設定、プログラムのステップ実行、ステップ実行時の変数値のリアルタイムモニタリング、という「デバッガ」の機能は持っていますが、巨大なScriptを書いたときの特定のサブルーチンを前回実行時に指定したパラメータで再実行して結果を比較といった機能は備えていません（切実にほしー。自分で作りたいぐらい）。

とくに、記述中のAppleScriptの選択部分の構文要素を検出して特定の構文要素（コメントとか変数名とか）についてのみ処理を行うような機能が用意されていない点が残念です（スクリプトエディタ用は数百本書いて使っているので）。

とりわけ、プロパティ文の記述などは毎回同じようなものをコピペで足すだけなので、書き足すのがかったるいと思っていました。

そこで、編集中のAppleScriptの範囲から構文要素を考慮して変数名だけ書き換えてくれるといった機能を足してみました。

テキストで与えたAppleScript（実際にはScript Debuggerの選択範囲から取得）を

	property textList : {}

実際にメモリ上でコンパイル（構文確認）して、書式付きテキストを取得し、そこから構文色分け設定に基づいて該当する構文要素をピックアップ。該当する構文要素の箇所を置換します。

--> textList

＃　置換部分だけ文字置換にしていますが、そこはそれ

	property boundsList : {}

–> Download repLexicalValStr as AppleScript bundle doc with library

例によって、AppleScriptの構文色分け設定の値を読み取って処理しているので、構文要素間で色の値（RGB値）で重複があると（or 値が近すぎると）エラーになります。また、先日報告された「RGB以外の色空間の色」で設定してある場合でもRGB色空間に色データを変換して処理しています（まさかCMYKとかグレースケールで色設定しているユーザーがいるとは思わなかったわー）。

スクリプトエディタ、Script Debugger上での動作を確認していますが、Applet書き出ししたときにまだ謎なメッセージを出すようです。何か、明示的にメインスレッドで実行する必要のあるものがあったでしょうか。

▲Applet書き出しして、実行した際に、ちょっと謎なメッセージが出る時がある（macOS 10.14.5）。vectorってなんだよ？

▲Applet実行時にエラーが出たあとに、再度実行したときにこんな謎なメッセージが出る（macOS 10.14.5）

AppleScript名：指定のAppleScriptテキストを構文確認して変数・プロパティ、サブルーチン名部分のみを取得して置換.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/04
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "AppKit"
use framework "OSAKit"
use attrLib : script "asAttrRecLib"

script spd
　　property fArray : {}
　　property outList : {}
　　property resStr : {}
end script

on run
　　set theSource to "　　property textList : {}"
　　set repValstr to "boundsList"
　　
　　set pureValStr to retTargStrFromCompiledScriptAttribute(theSource, 7) of me –Variables and Sub-routine names
　　–> "textList"
　　
　　set newLine to repChar(theSource, pureValStr, repValstr) of me
　　–> "　　property boundsList : {}"
　　
　　display dialog newLine
end run

–AppleScriptのソーステキストをコンパイルして、
on retTargStrFromCompiledScriptAttribute(theSource as string, colSettingOrder as integer)
　　if colSettingOrder < 1 or colSettingOrder > 18 then error ("Lexical element index range error (safe range: 1….18. You set " & colSettingOrder as string) & ")"
　　
　　–AppleScriptの構文色分け情報を取得
　　set ccRes to getAppleScriptSourceColors() of me
　　set cRes to chkASLexicalFormatColorConfliction(ccRes) of me –構文色分けの重複色チェック
　　if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"
　　
　　–検索用の色情報を作成
　　set commentCol to contents of item colSettingOrder of ccRes –Variable and Sub-routine name
　　set searchVal to (redValue of commentCol as string) & " " & (greenValue of commentCol as string) & " " & (blueValue of commentCol as string) –for filtering
　　
　　–与えられたテキストをAppleScriptとして評価し構文色分け情報をもとにStyle Runs的なDictionary化して返す
　　set aRitch to compileASSourcetextAndReturnStyledText(theSource) of me
　　
　　
　　–書式付きテキストからstyle runs的な書式リストを作成
　　set anAttrList to getAttributeRunsFromAttrString(aRitch) of attrLib
　　–>
　　(*
(NSArray) {
　　{
　　　　fontSize:12.0,
　　　　stringVal:"set",
　　　　colorVal:{
　　　　　　14,
　　　　　　62,
　　　　　　251
　　　　},
　　　　fontName:"Osaka",
　　　　itemIndex:1,
　　　　colorStr:"14 62 251"
　　},…..
*)
　　
　　set tmp1Array to NSArray’s arrayWithArray:anAttrList
　　
　　–コメント以外の要素をピックアップ文字と色で抽出
　　–set thePred2 to NSPredicate’s predicateWithFormat_("colorStr != %@ && stringVal != %@", searchVal, (return & return & return & return))
　　set thePred2 to NSPredicate’s predicateWithFormat_("colorStr == %@", searchVal)
　　set (fArray of spd) to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
　　–> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84}
　　
　　–アイテム番号のリストをもとに、ピックアップ対象のアイテムだけを再連結
　　set (outList of spd) to {}
　　repeat with i in (fArray of spd)
　　　　set aStr to ((item i of anAttrList)’s stringVal) as string
　　　　set the end of (outList of spd) to aStr
　　end repeat
　　
　　set (resStr of spd) to retDelimedText((outList of spd), return) of me
　　
　　return (resStr of spd)
end retTargStrFromCompiledScriptAttribute

——-

★Click Here to Open This Script　

指定画像をPNG形式（グレースケール）で保存

Posted on 7月 9 by Takaaki Naganoya

指定の画像ファイルをグレースケールのPNG画像ファイルに変換するAppleScriptです。

Appleが配布しているMNISTの手書き数字画像の認識CoreMLモデルをCocoa Framework化してみたところ、グレースケールの画像を要求されたため、画像をグレースケール化するルーチンを作ってみました。

結局、MNISTの手書き画像認識はうまく行かなかったのですが（全部「0」が返ってくる、、、）、グレースケール変換ルーチンは実用的だったので載せておくことにしました。

AppleScript名：指定画像をPNG形式（グレースケール）で保存

— Created 2019-07-09 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSUUID : a reference to current application’s NSUUID
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSColorSpace : a reference to current application’s NSColorSpace
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSColorRenderingIntentPerceptual : a reference to current application’s NSColorRenderingIntentPerceptual

set aFile to POSIX path of (choose file of type {"public.image"} with prompt "Select Image A")
set aImage to NSImage’s alloc()’s initWithContentsOfFile:aFile

set fRes to retUUIDfilePath(aFile, "png") of me
set sRes to saveNSImageAtPathAsGreyPNG(aImage, fRes) of me

–指定ファイルパスを元にUUIDのファイル名、指定拡張子をつけたファイルパスを作成して返す
on retUUIDfilePath(aPath, aEXT)
　　set aUUIDstr to (NSUUID’s UUID()’s UUIDString()) as string
　　set aPath to ((NSString’s stringWithString:aPath)’s stringByDeletingLastPathComponent()’s stringByAppendingPathComponent:aUUIDstr)’s stringByAppendingPathExtension:aEXT
　　return aPath
end retUUIDfilePath

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsGreyPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　–ビットマップをグレースケール変換
　　set bRawimg to convBitMapToDeviceGrey(aRawimg) of me
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (bRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –true/false
end saveNSImageAtPathAsGreyPNG

–NSBitmapImageRepをグレースケールに変換する
on convBitMapToDeviceGrey(aBitmap)
　　set aSpace to NSColorSpace’s deviceGrayColorSpace()
　　set bRawimg to aBitmap’s bitmapImageRepByConvertingToColorSpace:aSpace renderingIntent:(NSColorRenderingIntentPerceptual)
　　return bRawimg
end convBitMapToDeviceGrey

★Click Here to Open This Script　

AppleScript名：指定画像をグレースケールのNSImageに変換

— Created 2019-07-09 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSUUID : a reference to current application’s NSUUID
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSColorSpace : a reference to current application’s NSColorSpace
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSColorRenderingIntentDefault : a reference to current application’s NSColorRenderingIntentDefault

set aFile to POSIX path of (choose file of type {"public.image"} with prompt "Select Image")
set aImage to NSImage’s alloc()’s initWithContentsOfFile:aFile

set nsImageRes to convNSImageAsGrey(aImage) of me

–NSImageをグレースケールに変換する（NSImageで入出力）
on convNSImageAsGrey(anImage)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　set aSpace to NSColorSpace’s deviceGrayColorSpace()
　　set bRawimg to aRawimg’s bitmapImageRepByConvertingToColorSpace:aSpace renderingIntent:(NSColorRenderingIntentDefault)
　　set outImage to NSImage’s alloc()’s initWithSize:(bRawimg’s |size|())
　　outImage’s addRepresentation:(bRawimg)
　　return outImage
end convNSImageAsGrey

★Click Here to Open This Script　

指定のAppleScriptのソースコードからコメント部分のみを取得

Posted on 7月 8 by Takaaki Naganoya

指定のAppleScript書類のソースコードを取得し、構文色分け情報をもとにコメント部分の文字列のみを取得するAppleScriptです。

こうした処理はとくに昨日今日で実現したものではなく、実は同じような処理をOS X 10.4の時代からスクリプトエディタをAppleScriptから操作して行ってきました（スクリプトエディタ版のコメント抽出プログラムは、電子書籍の購入者特典でつけた「Piyomaru Script Assistant」に入っています）。Cocoaの機能を利用して処理すると、スクリプトエディタを操作せずにAppleScript書類から情報を取得できます。もちろん、GUIアプリケーションを操作しないぶん、並列処理にも有利です。

本Scriptを実行すると、指定のAppleScript書類をバックグラウンドでオープンして、書式情報を取得し、コメントに該当する箇所の文字のみを取得して返します。

–> Download commentPicker (executable app within library)

ほんの少し修正することで、ソースコードからコメント部分のみを削除したテキストを取得することも可能です。

AppleScript名：指定のAppleScriptのソースコードからコメント部分のみを取得.scptd

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

script spd
　　property fArray : {}
　　property outList : {}
　　property resStr : {}
end script

–AppleScriptの構文色分け情報を取得
set ccRes to getAppleScriptSourceColors() of me
set cRes to chkASLexicalFormatColorConfliction(ccRes) of me –構文色分けの重複色チェック
if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"

–検索用の色情報を作成
set commentCol to contents of item 5 of ccRes –Comment
set searchVal to (redValue of commentCol as string) & " " & (greenValue of commentCol as string) & " " & (blueValue of commentCol as string) –for filtering

–処理対象のAppleScript書類を選択
set asPath to choose file of type {"com.apple.applescript.script-bundle", "com.apple.applescript.script"}

–書式付きテキストからstyle runs的な書式リストを作成
set anAttrList to getAttrRecFromASPath(asPath) of attrLib
–>
(*
(NSArray) {
　　{
　　　　fontSize:12.0,
　　　　stringVal:"set",
　　　　colorVal:{
　　　　　　14,
　　　　　　62,
　　　　　　251
　　　　},
　　　　fontName:"Osaka",
　　　　itemIndex:1,
　　　　colorStr:"14 62 251"
　　},…..
*)

set tmp1Array to NSArray’s arrayWithArray:anAttrList

–コメント以外の要素をピックアップ文字と色で抽出
–set thePred2 to NSPredicate’s predicateWithFormat_("colorStr != %@ && stringVal != %@", searchVal, (return & return & return & return))
set thePred2 to NSPredicate’s predicateWithFormat_("colorStr == %@", searchVal)
set (fArray of spd) to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
–> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84}

–アイテム番号のリストをもとに、ピックアップ対象のアイテムだけを再連結
set (outList of spd) to {}
repeat with i in (fArray of spd)
　　set aStr to ((item i of anAttrList)’s stringVal) as string
　　set the end of (outList of spd) to aStr
end repeat

set (resStr of spd) to retDelimedText((outList of spd), return) of me

return (resStr of spd)

——-

★Click Here to Open This Script　

構文色分け情報を取得（Color Spaceを考慮）

Posted on 7月 4 by Takaaki Naganoya

macOS標準搭載のスクリプトエディタで定義している、AppleScriptの構文要素ごとの色分け情報。これを設定ファイルから取り出してレコード型データ（を入れた配列）に変換するAppleScriptの、カラースペースを考慮したデータの取り出しを行う改修版です。

AppleScriptの構文色分け情報は、ユーザーごとに異なります。一応、OSデフォルトの趣味の悪い配色なんかもありますが、

　（１）美的センスがなく見た目に気持ち悪い（ほら変更したいでしょ？　自分の好きなように変えてね、というメッセージだと受け止めました）

　（２）重複した色が設定されている構文要素がたくさんある（構文要素ごとの見分けがしにくいので、デフォルトのままだと無意味。ほら変更したくなったでしょ、というメッセージだと受け止めました）

ということから、AppleScript入門初日に設定色を変更。何度か細かい変更を行いつつも、今日までだいたい同じ感じの設定を使い続けています。

他のScripterがどのような配色にしているかはあまり知りません。Scripterごとに違うんだろうな、ぐらいの感じです。

ところが、蓋を開けてみたらこの構文色分け設定に「RGB以外の色」が設定できることが判明。けっこう長い間、この処理系使い続けてきましたけれど、昨日はじめて知りました。

具体的に言えば、RGB以外の「CMYK色」と「グレースケール色」の２つを設定可能なことが判明。CMYK色は、何度かアクセスしているうちに勝手にRGB色に置き換わってしまうようですが、グレースケールで指定した色はそのまま色種別がグレースケールのまま保持される（RGBに変換されたりしない）ようです。そのため、NSColorからredValue()などのメソッドで数値を取り出そうとするとエラーになる事例が発生したのでした。

そこで、RGBの各チャンネルの値を取り出す前にNSColorの色空間（グレースケール色空間というのはないので、種別ぐらい？）をチェックし、RGB以外であれば変換処理を行うようにしてみました。

ただし、この色空間（色モデル）の確認にNSColorのcolorSpaceNameというメソッドを使っている点に注意が必要です。これはmacOS 10.13で非推奨（deprecated）になっています。ヘッダーファイル上の説明を読むかぎりだと、Color Space（色空間）といいながら実際には色空間に該当する（HSBとかL*a*b*とか）ものを指定しているわけではないので、色タイプと言い換えることにした、という説明が行われていました。

このため、macOS 10.15betaでは未確認ではあるものの、このNSColorからRGB値を取り出すという処理自体を書き換える必要が出てくるため、本ルーチンだけ別のライブラリに分離しておくとか、メンテナンス時にわかるように書いておくとよいでしょう（NSColorのtypeを取得してみたものの、いまひとつサンプルなどもなく不明。macOS 10.14上で全部一律で0が返ってくるし）。

AppleにOS内部の機能修正リクエストを出す場合、「実際に機能不全を起こしているんだから直してほしい」と依頼してもなかなか直らない一方で、「学術的に正しくない」という指摘をされるととっとと変更するんだなーという発見をしたような気がします。

AppleScript名：構文色分け情報を取得（Color Spaceを考慮）.scptd

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver

set cList to getAppleScriptSourceColors() of me

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aSpace to (aCol’s colorSpaceName()) as string
　　
　　if aSpace is in {"NSDeviceRGBColorSpace", "NSCalibratedRGBColorSpace"} then
　　　　–do nothing
　　else
　　　　–RGB以外の色空間の色は、RGBに変換
　　　　–CMYKとグレースケールは同一メソッドでRGBに変換できることを確認済み
　　　　set cCol to aCol’s colorUsingColorSpaceName:"NSCalibratedRGBColorSpace"
　　　　if cCol = missing value then error "Color Space Conversion Error (" & aSpace & " to NSCalibratedRGBColorSpace)"
　　　　copy cCol to aCol
　　end if
　　
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

★Click Here to Open This Script　

Handle diff v2

Posted on 7月 3 by Takaaki Naganoya

Script Debugger上でオープン中の２つのAppleScript書類のうち、名称が同じハンドラ（サブルーチン）の内容同士を比較して、お互いに合っているかどうかをチェックするAppleScriptです。

アプリケーション書き出しして、Script Debuggerのスクリプトメニューに入れて実行します（AppleScript書類のままだと、Myriad Tables Lib内のフレームワークが呼べないため）。

▲本Scriptはスクリプトエディタの環境設定で行うAppleScriptの構文色分け設定色が「RGBカラー」でないとエラーになります。CMYKとかグレースケールカラーで指定して、そのままRGBに変換されずに保持される（CMYK色はアクセスしているうちにRGBに変換されるが、グレースケールは保持される）ため、色空間の判定を行ってRGB色に変換してから処理する必要があります（自分用メモ）

スクリプトエディタ上で設定する構文色分け設定をもとに、AppleScriptの構文要素を考慮したハンドラ一覧を作成し、２つのAppleScript書類の間に共通して存在するハンドラ名のハンドラ（サブルーチン）のAppleScriptソースを取得。インデント（tab）を削除したのちに比較を実行。

共通名称のハンドラすべてをチェックして、結果を表インタフェースで表示します。初版（v1）では実行するたびに１つのハンドラをチェックしていたのですが、あまりにかったるいので即座にループですべて調べてまとめて結果を表示するようにしました（v2）。

–> download executable archive (mainly for macOS 10.14 or later)

ただし、１つのAppleScript書類内にScript Object（JavaScriptでいうところのClosureみたいなもの）で論理分割された同名のハンドラが複数回登場するパターンは想定していません。複数検出するとエラーになります。

とくにScript Debuggerを対象にせずスクリプトエディタを対象にしてもよいのですが、些細な変更で実現できるため、興味のある方はやってみてください。あと、本Scriptは必要に迫られまくって作ったものなので、動作でおかしい箇所があったらぜひぜひご指摘を。

個人的には、ハンドラ名称を構文要素を考慮しつつ取得している一方で、ハンドラの内容は単なる文字列検索で取り出しているというあたりにアンバランスさを感じます。ただ、趣味のScriptではないので若干の手抜きを（＾ー＾；；

macOS 10.14.5上のスクリプトエディタで、構文色分け情報を何回設定しても「黒」になるという現象に遭遇したのですが、他のユーザー環境上での再現性については未知数であるため、まだレポートできない状況です。

→　その後、本ツールは強化されて、構文色分け設定にRGB以外の色が設定してあってもRGBに変換して処理する機能や、構文色分け設定を参照したコメント除去機能や、各種書式情報の取得を３倍高速化するカラーキャッシュなどの機能を実装したプログラムに（必要に迫られて）成長しました。

AppleScript名：Handle diff v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/02
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — Sierra (10.12) or later (maybe 10.11 is OK but not confirmed)
use framework "Foundation"
use scripting additions
use framework "OSAKit"
use script "Myriad Tables Lib" version "1.0.9" –https://www.macosxautomation.com/applescript/apps/Script_Libs.html

–構文色分け設定に重複色がないかチェック
set cList to getAppleScriptSourceColors() of me
set cRes to chkASLexicalFormatColorConfliction(cList) of me –構文色分けの重複色チェック
if cRes = false then error "There is some duplicate(s) color among AppleScript’s lexical color settings"

–Script Debugger上でオープン中の２つのAppleScript書類のパスを取得
set dList to retTwoPathList() of me
if dList = false then return

copy dList to {d1Path, d2Path}

–各AppleScript書類のハンドラ名称一覧を取得する
set hList1 to retHandlerNamesFromAppleScriptSource(d1Path as alias) of me
set hList2 to retHandlerNamesFromAppleScriptSource(d2Path as alias) of me

–２つのAppleScript書類のハンドラの共通項目（名称のみ）を抽出する
set resList to returnDuplicatesOnly(hList1 & hList2) of me
if resList = {} then
　　–共通のハンドラ（サブルーチン）が指定の２つのScriptに存在していなかった
　　display dialog "There is no common handler between the scripts." buttons {"OK"} default button 1
　　return
end if

–各AppleScript書類のソースを取得して、指定のハンドラのテキストを取得する
set s1Source to getASsourceFor(d1Path as alias) of me
set s2Source to getASsourceFor(d2Path as alias) of me

if (s1Source = false) or (s2Source = false) then
　　display dialog "Error occured in getteing AS source" buttons {"OK"} default button 1
　　return
end if

set outList to {}
repeat with i in resList
　　set resHandler to contents of i
　　set s1Source to extractHandlerSourceOnly(s1Source, resHandler) of me
　　set s2Source to extractHandlerSourceOnly(s2Source, resHandler) of me
　　set compareF to (s1Source is equal to s2Source) as boolean
　　set the end of outList to {resHandler, compareF}
end repeat

–結果表示
tell me to activate
display table with data outList with prompt "Handler contents compare results" column headings {"Handler name", "Match?"} with title "Handler Diff Results"

–指定のハンドラの内容を抽出する（コメントぐらいは結果から削除してもいいような気もする）
–Script Objectの使用は考慮していない。１つのAppleScript書類からScript Objectで論理分割された同名のハンドラが複数検出されるケースは想定していない
on extractHandlerSourceOnly(wholeScript as string, handlerName as string)
　　–インデント文字（Tab）をすべて削除
　　set targScript to repChar(wholeScript, tab, "") of me
　　
　　–"on"ではじまるハンドラと仮定して抽出
　　set handlerStr to extractStrFromTo(targScript, "on " & handlerName, "end " & handlerName) of me
　　if handlerStr = false then
　　　　–"to"ではじまるハンドラと仮定して抽出
　　　　set handlerStr to extractStrFromTo(targScript, "to " & handlerName, "end " & handlerName) of me
　　　　if handlerStr = false then return false
　　else
　　　　return handlerStr
　　end if
end extractHandlerSourceOnly

on retHandlerNamesFromAppleScriptSource(aFile)
　　set aRec to getAttrRecFromASPath(aFile) of me
　　set cList to getAppleScriptSourceColors() of me
　　
　　set targAttr to contents of item 7 of cList –ハンドラあるいは変数
　　set tmpCoStr to ((redValue of targAttr) as string) & " " & ((greenValue of targAttr) as string) & " " & ((blueValue of targAttr) as string)
　　
　　set ontoColItem to contents of item 3 of cList –スクリプティング予約語（on/to）
　　set ontoCoStr to ((redValue of ontoColItem) as string) & " " & ((greenValue of ontoColItem) as string) & " " & ((blueValue of ontoColItem) as string)
　　
　　
　　–変数あるいはハンドラ名称をリストアップ(variables & handler)
　　set tmp1Array to NSArray’s arrayWithArray:aRec
　　set thePred0 to NSPredicate’s predicateWithFormat_("colorStr == %@", tmpCoStr)
　　set dArray to (tmp1Array’s filteredArrayUsingPredicate:thePred0) as list
　　
　　–改行を含むデータをリストアップ(text data contains return)
　　set thePred1 to NSPredicate’s predicateWithFormat_("stringVal CONTAINS %@", return)
　　set eArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred1)’s valueForKeyPath:"itemIndex") as list
　　
　　set the beginning of eArray to 0 –ハンドラ宣言部がTopに来る場合に備える
　　
　　–"on"（ハンドラ宣言）の項目をリストアップ文字と色で抽出
　　set thePred2 to NSPredicate’s predicateWithFormat_("stringVal == %@ && colorStr == %@ ", "on", ontoCoStr)
　　set fArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred2)’s valueForKeyPath:"itemIndex") as list
　　
　　–"to"（ハンドラ宣言ないしは代入対象指定）　の項目をリストアップ文字と色で抽出
　　set thePred3 to NSPredicate’s predicateWithFormat_("stringVal == %@ && colorStr == %@ ", "to", ontoCoStr)
　　set gArray to ((tmp1Array’s filteredArrayUsingPredicate:thePred3)’s valueForKeyPath:"itemIndex") as list
　　
　　
　　set handlerList to {}
　　
　　–on ではじまるハンドラの抽出
　　repeat with i in eArray –改行を含むテキストのアイテム番号リスト
　　　　set j to (contents of i) as integer
　　　　repeat with ii in fArray –"on"の項目リスト
　　　　　　set jj to (contents of ii) as integer
　　　　　　
　　　　　　set handlerStr to missing value
　　　　　　
　　　　　　if (j + 1) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　else if (j + 2) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　end if
　　　　　　
　　　　　　if handlerStr is not in {"error", missing value} and handlerStr is not in handlerList then
　　　　　　　　set the end of handlerList to handlerStr
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　
　　–to ではじまるハンドラの抽出
　　repeat with i in eArray –改行を含むテキストのアイテム番号リスト
　　　　set j to (contents of i) as integer
　　　　repeat with ii in gArray –"to"の項目リスト
　　　　　　set jj to (contents of ii) as integer
　　　　　　
　　　　　　set handlerStr to missing value
　　　　　　
　　　　　　if (j + 1) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　else if (j + 2) = jj then
　　　　　　　　set handlerStr to stringVal of (item (jj + 2) of (aRec as list))
　　　　　　end if
　　　　　　
　　　　　　if handlerStr is not in {"error", missing value} and handlerStr is not in handlerList then
　　　　　　　　set the end of handlerList to handlerStr
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　return handlerList
end retHandlerNamesFromAppleScriptSource

–ソースを取得してコンパイル（構文確認）する方式から、URL（fileURL）を指定してコンパイル（構文確認）する方式に変更した
on getAttrRecFromASPath(aFile)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　–set sourceText to theScript’s source() –No Use
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　set attrRes to getAttributeRunsFromAttrString(styledSourceText) of me
　　return attrRes
end getAttrRecFromASPath

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
— Original Created 2014-02-23 Shane Stanley
on getASsourceFor(anAlias as {alias, string})
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　set sourceText to theScript’s source()
　　end if
　　
　　return sourceText as string
end getASsourceFor

–Attributed StringをDictionary化
on getAttributeRunsFromAttrString(theStyledText)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　set itemCount to 1
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(specifier) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–String　　
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　–Color
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize, itemIndex:itemCount}
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　
　　　　set itemCount to itemCount + 1
　　end repeat
　　
　　return (styleList of aSpd)
　　
end getAttributeRunsFromAttrString

–AppleScriptの構文色分けのカラー値をRGBで取得する
on getAppleScriptSourceColors()
　　
　　— get the plist info as a dictionary
　　set thePath to NSString’s stringWithString:"~/Library/Preferences/com.apple.applescript.plist"
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theInfo to NSDictionary’s dictionaryWithContentsOfFile:thePath
　　
　　— extract relevant part and loop through
　　set theArray to (theInfo’s valueForKey:"AppleScriptSourceAttributes") as list
　　
　　set colList to {}
　　
　　repeat with i from 1 to count of theArray
　　　　set anEntry to item i of theArray
　　　　
　　　　set colorData to NSColor of anEntry
　　　　set theColor to (NSUnarchiver’s unarchiveObjectWithData:colorData)
　　　　
　　　　set {rVal, gVal, bVal} to retColListFromNSColor(theColor, 255) of me
　　　　
　　　　set fontData to NSFont of anEntry
　　　　set theFont to (NSUnarchiver’s unarchiveObjectWithData:fontData)
　　　　
　　　　set aFontName to theFont’s displayName() as text
　　　　set aFontSize to theFont’s pointSize()
　　　　
　　　　set aColRec to {redValue:rVal, greenValue:gVal, blueValue:bVal, fontName:aFontName, fontSize:aFontSize}
　　　　
　　　　set the end of colList to aColRec
　　end repeat
　　
　　return colList
end getAppleScriptSourceColors

–NSColorからRGBの値を取り出す
on retColListFromNSColor(aCol, aMAX as integer)
　　set aRed to round ((aCol’s redComponent()) * aMAX) rounding as taught in school
　　set aGreen to round ((aCol’s greenComponent()) * aMAX) rounding as taught in school
　　set aBlue to round ((aCol’s blueComponent()) * aMAX) rounding as taught in school
　　
　　if aRed > aMAX then set aRed to aMAX
　　if aGreen > aMAX then set aGreen to aMAX
　　if aBlue > aMAX then set aBlue to aMAX
　　
　　return {aRed, aGreen, aBlue}
end retColListFromNSColor

–AS書式で配色に重複がないかどうかチェック
on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　log aRes
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on retTwoPathList()
　　tell application "Script Debugger"
　　　　set dList to name of every document
　　　　set dResList to choose from list dList with prompt "Select two documents" with multiple selections allowed
　　　　if dResList = false then return false
　　　　if length of dResList is not equal to 2 then
　　　　　　display dialog "Please Select two documents to compare handler contents" buttons {"OK"} default button 1 with icon 1 with title "Selection Error"
　　　　　　return false
　　　　end if
　　　　
　　　　set dPathList to {}
　　　　repeat with i in dResList
　　　　　　set j to contents of i
　　　　　　tell document j
　　　　　　　　set tmpPath to (file spec) as string –HFS path string
　　　　　　end tell
　　　　　　
　　　　　　set the end of dPathList to tmpPath
　　　　end repeat
　　end tell
　　
　　return dPathList
end retTwoPathList

–Written By Philip Aker
–文字置換ルーチン
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

–指定文字と終了文字に囲まれた内容を抽出
on extractStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to current application’s NSScanner’s scannerWithString:aParamStr
　　set anArray to current application’s NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(specifier)
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(specifier)
　　　　if theValue is missing value then set theValue to "" –>追加
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　if anArray’s |count|() is not equal to 1 then return false
　　
　　return first item of (anArray as list)
end extractStrFromTo

★Click Here to Open This Script　

AppleScript書類を構文要素ごとに分解（Script Libraries対応版）

Posted on 7月 3 by Takaaki Naganoya

指定のAppleScript書類を読み込んで、スクリプトエディタ上で実行するのと同じ構文色分けのデータに変換するAppleScriptです。

説明するのがややこしい、AppleScript書類の内容を分析するためのAppleScriptです。

AppleScriptのプログラム内容を分析するプログラムは昔からよく作ってきました。とくに、プログラムが巨大になってきたり複雑になってきたり、納品直前に巨大な仕様変更があったりすると（涙）、自分で書いたプログラムを自分で分析する必要が出てくるからです。

AppleScriptの構文解析は面倒です。「return return」（前者はサブルーチンから値を返すコマンド　後者は改行コード）といった記述が可能なので、これを正しく解釈する必要があります。

GithubやXcode上のソースコードエディタなど、キーワードだけで色分けするバカプログラムでは「return return」を正しく解釈できていません。

AppleScriptの処理系そのものが持っている「構文色分け」の機能を用いて、構文解析するのではなく、処理系の機能を用いて構文ごとに色分けされた、その色分け結果の情報を用いて構文ごとの要素を区分けするという方法をMac OS X 10.3の時代から使っていました。

当初はスクリプトエディタをコントロールして実行していましたが、macOS 10.10以降でCocoaの機能が利用できるようになったため、Cocoaのメソッドを用いて処理するようになってきました。

ところが最近、これまで使っていたサブルーチン部品では分析できないケースが出てきました。AppleScript Librariesを組み込んだバンドルスクリプトを処理させるとエラーになります。

自分が使っていたサブルーチンでは、指定のAppleScript書類のソースコードを求め、メモリ上でコンパイルしてインスタンスを生成し、そこから書式情報を取得していました。

しかし、AppleScript Librariesを含むAppleScriptバンドル書類に対してこれを用いると、エラーが出て処理できないことがわかりました。つまり、ライブラリが含まれていない状態のソースを取得してコンパイル（構文確認）すると、ライブラリが存在しないというエラーに直面するわけです。

仕方なく、Xcode上でヘッダーファイル「OSAScript.h」を調べ、URL指定してコンパイル（構文確認）できるメソッドがあることを確認。これを使ってみたところ、AppleScript Librariesを含むAppleScriptバンドル書類も構文要素ごとに分解できました。Shane Stanleyから「Appleのオンラインドキュメントを見ただけでは調査したことにならない。ヘッダーファイルを確認する必要がある」とは何回もコメントをもらっていますが、なかなか奥深いです。

最初（v1.0）、

- (id)initWithContentsOfURL:(NSURL *)url language:(OSALanguage *)language error:(NSDictionary * __nullable * __nullable)errorInfo DEPRECATED_IN_MAC_OS_X_VERSION_10_6_AND_LATER;

を使っていたのですが、「DEPRECATED_IN_MAC_OS_X_VERSION_10_6_AND_LATER」の表記に気づいて、

- (instancetype)initWithSource:(NSString *)source fromURL:(nullable NSURL *)url languageInstance:(nullable OSALanguageInstance *)instance usingStorageOptions:(OSAStorageOptions)storageOptions AVAILABLE_MAC_OS_X_VERSION_10_6_AND_LATER;

に変更しました。OSA言語インスタンスを作ったまま使っていなかったりしますが、その時の変更の名残です。

AppleScript名：AppleScript書類を構文要素ごとに分解（Script Libraries対応版）v1.1.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/07/03
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "OSAKit"
use framework "AppKit"

property OSANull : a reference to current application’s OSANull
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSUnarchiver : a reference to current application’s NSUnarchiver
property OSALanguage : a reference to current application’s OSALanguage
property OSALanguageInstance : a reference to current application’s OSALanguageInstance
property OSADontSetScriptLocation : a reference to current application’s OSADontSetScriptLocation

set aFile to choose file of type {"com.apple.applescript.script-bundle", "com.apple.applescript.script"}
set aRec to getAttrRecFromASPath(aFile) of me

–ソースを取得してコンパイル（構文確認）する方式から、URL（fileURL）を指定してコンパイル（構文確認）する方式に変更した
on getAttrRecFromASPath(aFile)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aFile)
　　set anOSALanguageInstance to OSALanguage’s languageForName:"AppleScript"
　　set {theScript, theError} to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(reference)
　　
　　if theError is not equal to missing value then
　　　　— handle error
　　　　error "Compile Error"
　　else
　　　　–set sourceText to theScript’s source() –No Use
　　　　set styledSourceText to theScript’s richTextSource()
　　end if
　　
　　set attrRes to getAttributeRunsFromAttrString(styledSourceText) of me
　　return attrRes
end getAttrRecFromASPath

–Attributed StringをDictionary化
on getAttributeRunsFromAttrString(theStyledText)
　　script aSpd
　　　　property styleList : {}
　　end script
　　
　　set (styleList of aSpd) to {} —for output
　　
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　
　　set theLength to theStyledText’s |length|()
　　set startIndex to 0
　　set itemCount to 1
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–String　　
　　　　set aText to (thePureString’s substringWithRange:theRange) as string
　　　　
　　　　–Color
　　　　set aColor to (theAtts’s valueForKeyPath:"NSColor")
　　　　if aColor is not equal to missing value then
　　　　　　set aSpace to aColor’s colorSpace()
　　　　　　
　　　　　　set aRed to (aColor’s redComponent()) * 255
　　　　　　set aGreen to (aColor’s greenComponent()) * 255
　　　　　　set aBlue to (aColor’s blueComponent()) * 255
　　　　　　
　　　　　　set colList to {aRed as integer, aGreen as integer, aBlue as integer} –for comparison
　　　　　　set colStrForFind to (aRed as integer as string) & " " & (aGreen as integer as string) & " " & (aBlue as integer as string) –for filtering
　　　　else
　　　　　　set colList to {0, 0, 0}
　　　　　　set colStrForFind to "0 0 0"
　　　　end if
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to aFont’s pointSize()
　　　　end if
　　　　
　　　　set the end of (styleList of aSpd) to {stringVal:aText, colorStr:colStrForFind, colorVal:colList, fontName:aDFontName as string, fontSize:aDFontSize, itemIndex:itemCount}
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　　　
　　　　set itemCount to itemCount + 1
　　end repeat
　　
　　return (styleList of aSpd)
　　
end getAttributeRunsFromAttrString

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSString

AS書類をオープンして書き換えて別途保存 v2（Cocoa版）

Safariで指定のDOM Elementの情報を取得する

Safariのdo JavaScriptから結果をJSONで返してASの各種オブジェクトに変換

Skimでオープン中のPDFで選択中のテキストを返す

Safariで表示中のPageの選択中の文字を含む表データを取得

指定URLのMS名を取得する v2a

指定URLのMS名を取得する v2

指定のAppleScriptテキストを構文確認して指定の構文要素が入っていないかチェック

指定のAppleScriptテキストを構文確認して変数・プロパティ、サブルーチン名部分のみを取得して置換

指定画像をPNG形式（グレースケール）で保存

Handle diff v2

AppleScript書類を構文要素ごとに分解（Script Libraries対応版）