Menu

Skip to content
AppleScriptの穴
  • Home
  • Products
  • Docs
  • Events
  • Forum
  • About This Blog
  • License
  • 仕事依頼

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: shell script

osascript系のAppleScriptランタイムを区別する

Posted on 1月 18 by Takaaki Naganoya

AppleScriptのランタイム環境が何であるかを区別できるようになりました。

それらのうち、/usr/bin/osascriptを呼び出しているランタイム環境について、さらに細分化して個別に識別するために、ランタイム環境そのものと親プロセスが何であるかをAppleScriptで調査してみました。

結論からいえば、親プロセスが「bash」ならTerminalからosascriptコマンドで起動されたと判断してよさそう。その他は、実行されたScriptの置かれているパスを求めて、macOS標準装備のScript Menuかアプリケーション内部のScript Menuかを見分けるぐらいでしょうか。

これを判定したプログラム自体は、別に技術的にすごいとか機密の塊とかいうことはなくて、「清書してなくて、きたない。無駄に長い。掲載されているプログラムを見ても何も感じない」ことから掲載していません。実験用のテストプログラムでも、ちょっと近年稀に見るぐらいひどい出来です。内容は、単にランタイムプログラムのプロセスIDを取得して、そのプロセスIDをもとにpsコマンドで親プロセスを求めて、コマンドからいろいろ情報を抜いてくるというだけのものです。

Script Menu

ランタイムのパラメータ：/usr/bin/osascript -P /Users/me/Library/Scripts/Finder/pTEST.scptd
親プロセス：/System/Library/Frameworks/Foundation.framework/Versions/C/XPCServices/com.apple.foundation.UserScriptService.xpc/Contents/MacOS/com.apple.foundation.UserScriptService

与えられているScriptが特定フォルダ（/Users/me/Library/Scripts/）以下にあるものかどうか、という識別は可能。ちょっと、根拠が弱そうです。

CotEditor内のScript Menu

ランタイムのパラメータ：/usr/bin/osascript -sd -T 14534 -P /Users/me/Library/Application Scripts/com.coteditor.CotEditor/010)M-pM^_M^MM^NM-pM^_M^SM^\AppleScriptM-cM^AM-(M-cM^AM^WM-cM^AM-&M-hM-'M-#M-iM^GM^H/0020)M-pM^_M^SM^\M-fM-'M^KM-fM^VM^GM-gM-"M-:M-hM-*M^MM-cM^AM^WM-cM^AM-&M-eM-.M^_M-hM-!M^LM-cM^AM^WM-cM^@M^AM-pM^_M^SM^DM-fM^VM-0M-hM-&M^OM-fM^[M-8M-iM-!M^^M-cM^AM-+M-gM-5M^PM-fM^^M^\M-cM^BM^RM-eM^GM-:M-eM^JM^[.@r.scpt
親プロセス：/System/Library/Frameworks/Foundation.framework/Versions/C/XPCServices/com.apple.foundation.UserScriptService.xpc/Contents/MacOS/com.apple.foundation.UserScriptService

親プロセスはScript Menuと同じですが、こちらも実行しているScriptのパスが/Users/me/Library/Application Scripts/com.coteditor.CotEditor/以下であること。これも、識別のための根拠が弱いです。

Terminal経由でosascriptコマンド実行

ランタイムのパラメータ：osascript /Users/me/Desktop/pTEST.scptd
親プロセス：-bash

これは、親プロセスが-bashであることから、明確に区別できます。Terminal.appではなくbashなんですね。

Terminal経由で/usr/bin/osascript（フルパス指定）でコマンド実行

ランタイムのパラメータ：/usr/bin/osascript /Users/me/Desktop/pTEST.scptd
親プロセス：-bash

フルパスで指定すると何か変わってくるかとも思いましたが、とくに変化はありませんでした。

Program AS Style runtime name Parent Process Name Script Path
Script Editor Script/Scriptd Script Editor
Script Editor Cocoa-AppleScript Applet CocoaApplet
Script Editor Applet applet
Script Debugger Script/Scriptd Script Debugger
Script Debugger Applet (Enhanced) FancyDroplet
ASOBjC Explorer 4 Script/Scriptd ASOBjC Explorer 4
Automator Workflow Automator
Automator Applet Application Stub
Script Menu Script/Scriptd osascript …com.apple.foundation.UserScriptService /Users/me/Library/Scripts/ ほか
CotEditor Script osascript …com.apple.foundation.UserScriptService /Users/me/Library/Application Scripts/com.coteditor.CotEditor/
Terminal.app (osascript) Script/Scriptd osascript bash
Posted in OSA shell script | Tagged 10.14savvy | Leave a comment

CotEditorの表示用フォント名を環境設定から取得する

Posted on 10月 15, 2019 by Takaaki Naganoya

CotEditorの環境設定値（plist）から表示用フォント名を取得するAppleScriptです。

本来であれば、CotEditorのwindowオブジェクト自体に属性値として表示用フォント名がついているのが（GUI側からWindowごとに表示フォントを指定できるので）理想的ですが、そういう機能は実装されていないので、無理やりplistから読み取ってみました。

CotEditorの表示用フォントは、環境設定で指定したものがデフォルトで用いられ、個別のウィンドウごとに任意のフォントを指定できるようになっています。本Scriptで取得できるのは、個別のウィンドウの設定値ではなく、環境設定値のほうです。

defaultsコマンドでplistを読むのはあまりおすすめできない方法ですが、できないよりはマシというところです。

まっさらな（macOSをインストールしたての）環境にCotEditorをインストールして一度も環境設定でフォントを指定していない環境だとエラーになる（項目が存在しない）ので、その場合に備えてエラートラップを仕掛けています。


▲環境設定から表示フォント名を取得して、各行をプロポーショナルフォント使用時の画面描画幅をもとにソートする処理を書いたときに利用

AppleScript名：CotEditorの表示用フォント名を環境設定から取得する
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/10/15
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set fName to getCotEditorFontName() of me
–> "HiraginoSans-W3"

–CotEditorのplistから表示用のフォント設定（PostScript名）を取得する
on getCotEditorFontName()
　　try
　　　　set fnRes to do shell script "defaults read com.coteditor.CotEditor | grep fontName"
　　on error
　　　　return "" –インストール後に表示フォントの環境設定を一度も行っていないときにはエラーになる
　　end try
　　set fName to extractStrFromTo(fnRes, "= ＼"", "＼";") of me
　　return fName
end getCotEditorFontName

–指定文字と終了文字に囲まれた内容を抽出
on extractStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to current application’s NSScanner’s scannerWithString:aParamStr
　　set anArray to current application’s NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(reference)
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(reference)
　　　　if theValue is missing value then set theValue to "" –>追加
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　if anArray’s |count|() is not equal to 1 then return ""
　　
　　return first item of (anArray as list)
end extractStrFromTo

★Click Here to Open This Script　

hiro さんのコメントから、defaultsコマンドのオプション追加でずいぶんと簡潔に書けるようで、書き直しておきました。

AppleScript名：CotEditorの表示用フォント名を環境設定から取得する v2
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set fName to getCotEditorFontName() of me
–> "HiraginoSans-W3"

–CotEditorのplistから表示用のフォント設定（PostScript名）を取得する
on getCotEditorFontName()
　　try
　　　　set fnRes to do shell script "defaults read com.coteditor.CotEditor fontName"
　　on error
　　　　return "" –インストール後に表示フォントの環境設定を一度も行っていないときにはエラーになる
　　end try
　　return fnRes
end getCotEditorFontName

★Click Here to Open This Script　
Posted in shell script | Tagged 10.12savvy 10.13savvy 10.14savvy 10.15savvy CotEditor NSMutableArray NSScanner | 3 Comments

CotEditorで編集中のMarkdown書類をPDFプレビュー

Posted on 6月 15, 2019 by Takaaki Naganoya

CotEditorで編集中のMarkdown書類を、MacDownでPDF書き出しして、Skimでオープンして表示するAppleScriptです。

CotEditorにMarkdownのプレビュー機能がついたらいいと思っている人は多いようですが、MarkdownはMarkdownで、方言は多いし標準がないし、１枚もののMarkdown書類だけ編集できればいいのか、本などのプロジェクト単位で編集とか、目次が作成できないとダメとか、リンクした画像の扱いをどうするのかとか、対応しようとすると「ほぼ別のソフトを作るのと同じ」ぐらい手間がかかりそうです（メンテナー様ご本人談）。

そこで、AppleScript経由で他のソフトを連携させてPDFプレビューさせてみました。これなら、誰にも迷惑をかけずに、今日この時点からすぐにMarkdownのプレビューが行えます（当然、HTML書き出ししてSafariでプレビューするバージョンははるかかなた昔に作ってあります）。

ただし、OS側の機能制限の問題で、CotEditor上のスクリプトメニューから実行はできません（GUI Scriptingの実行が許可されない）。OS側のスクリプトメニューに登録して実行する必要があります。

GUI Scriptingを利用してメニュー操作を行なっているため、システム環境設定で許可しておく必要があります。

本来であれば、PDFの書き出し先フォルダ（この場合は書き出しダイアログで、GUI Scirptingを用いてCommand-Dで指定して一律に場所指定が行えるデスクトップフォルダ）に同名のPDFが存在しないかどうかチェックし、存在すれば削除するといった処理が必要ですが、面倒だったのであらかじめMarkdown書類をUUIDにリネームしておくことで、書き出されたPDFも同じくUUIDのファイル名になるため、論理上はファイル名の衝突を回避できるため、削除処理を省略しています。

AppleScript名：🌏レンダリングしてPDFプレビュー
— Created 2019-06-15 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSUUID : a reference to current application’s NSUUID
property NSWorkspace : a reference to current application’s NSWorkspace

–オープン中のMarkdown書類を取得する
tell application "CotEditor"
　　tell front document
　　　　set cStyle to coloring style
　　　　if cStyle is not equal to "Markdown" then
　　　　　　display dialog "編集中のファイルはMarkdown書類ではないようです。" buttons {"OK"} default button 1
　　　　　　return
　　　　end if
　　　　
　　　　set aPath to path
　　end tell
end tell

–一時フォルダにMarkdown書類をコピー
set sPath to (path to temporary items)
tell application "Finder"
　　set sRes to (duplicate ((POSIX file aPath) as alias) to folder sPath with replacing)
end tell

–コピーしたMarkdown書類をリネーム
set s1Res to sRes as alias
set aUUID to NSUUID’s UUID()’s UUIDString() as text –UUIDを作成する
tell application "Finder"
　　set name of s1Res to (aUUID & ".md")
end tell

–Markdown書類をデスクトップにPDF書き出し
set pdfRes to exportFromMacDown(POSIX path of s1Res) of me

–PDF Viewerでオープン
tell application "Skim" –Preview.appでもOK
　　activate
　　open pdfRes
end tell

–一時フォルダに書き出したMarkdown書類を削除
tell application "Finder"
　　delete s1Res
end tell

–指定のMacDownファイル（alias）をデスクトップ上にPDFで書き出し
on exportFromMacDown(anAlias)
　　set s1Text to paragraphs of (do shell script "ls ~/Desktop/*.pdf") –pdf書き出し前のファイル一覧
　　
　　tell application "MacDown"
　　　　open {anAlias}
　　end tell
　　
　　macDownForceSave() of me
　　
　　tell application "MacDown"
　　　　close every document without saving
　　end tell
　　
　　do shell script "sync" –ねんのため
　　
　　set s2Text to paragraphs of (do shell script "ls ~/Desktop/*.pdf") –pdf書き出し後のファイル一覧
　　
　　set dRes to getDiffBetweenLists(s1Text, s2Text) of me –デスクトップ上のPDFファイル名一覧の差分を取得
　　set d2Res to (addItems of dRes)
　　
　　if length of d2Res ≥ 1 then
　　　　return contents of first item of d2Res
　　else
　　　　error "Error in exporting PDF to desktop folder…."
　　end if
end exportFromMacDown

on getDiffBetweenLists(aArray as list, bArray as list)
　　set allSet to current application’s NSMutableSet’s setWithArray:aArray
　　allSet’s addObjectsFromArray:bArray
　　
　　–重複する要素のみ抜き出す
　　set duplicateSet to current application’s NSMutableSet’s setWithArray:aArray
　　duplicateSet’s intersectSet:(current application’s NSSet’s setWithArray:bArray)
　　
　　–重複部分を削除する
　　allSet’s minusSet:duplicateSet
　　set resArray to (allSet’s allObjects()) as list
　　
　　set aSet to current application’s NSMutableSet’s setWithArray:aArray
　　set bSet to current application’s NSMutableSet’s setWithArray:resArray
　　aSet’s intersectSet:bSet –積集合
　　set addRes to aSet’s allObjects() as list
　　
　　set cSet to current application’s NSMutableSet’s setWithArray:bArray
　　cSet’s intersectSet:bSet –積集合
　　set minusRes to cSet’s allObjects() as list
　　
　　return {addItems:minusRes, minusItems:addRes}
end getDiffBetweenLists

–注意！！　ここでGUI Scriptingを使用。バージョンが変わったときにメニュー階層などの変更があったら書き換え
on macDownForceSave()
　　activate application "MacDown"
　　tell application "System Events"
　　　　tell process "MacDown"
　　　　　　— File > Export > PDF
　　　　　　click menu item 2 of menu 1 of menu item 14 of menu 1 of menu bar item 3 of menu bar 1
　　　　　　
　　　　　　–Go to Desktop Folder
　　　　　　keystroke "d" using {command down}
　　　　　　
　　　　　　–Save Button on Sheet
　　　　　　click button 1 of sheet 1 of window 1
　　　　end tell
　　end tell
end macDownForceSave

–Bundle IDからアプリケーションのPathを返す
on retAppAbusolutePathFromBundleID(aBundleID)
　　set appPath to NSWorkspace’s sharedWorkspace()’s absolutePathForAppBundleWithIdentifier:aBundleID
　　if appPath = missing value then return false
　　return appPath as string
end retAppAbusolutePathFromBundleID

★Click Here to Open This Script　
Posted in file File path GUI Scripting Markdown PDF shell script | Tagged 10.11savvy 10.12savvy 10.13savvy CotEditor Finder MacDown NSUUID NSWorkspace Skim | Leave a comment

CPU Family Nameを取得する

Posted on 12月 3, 2018 by Takaaki Naganoya

実行中のMacのMachine ID（MacBookPro10,1など）からIntel CPUのFamily Name（Ivy Bridgeなど）を取得するAppleScriptです。

Macの各モデルの搭載CPUについては、MacTrackerを参照しました。

MacTrackerのデータをコピー＆ペーストでNumbers上に製品データを作成し（手動）、

ユニーク化（重複データの除去）処理を行なって（ASで処理）、プログラム上に展開しました（手動）。

実用性とか意味については、とくに考えていません。Machine IDとCPU Family Nameのデータについてはplistに記述してプログラム外部に追い出して独自でメンテナンスできるようにしたほうがよいと思われます。

AppleScript名：CPU Family Nameを取得する.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/12/03
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set macID to do shell script "sysctl -n hw.model" –get machine ID
–set macID to "MacBookPro99,1"–Error case

set myName to getIntelCoreProcessorFamilyName(macID) of me
—> "Ivy Bridge"

on getIntelCoreProcessorFamilyName(macID)
　　–Machine ID & CPU Core Model Names (uniquefied)
　　set macList to {{"iMac4,1", "Yonah"}, {"iMac4,2", "Yonah"}, {"iMac5,2", "Merom"}, {"iMac5,1", "Merom"}, {"iMac6,1", "Merom"}, {"iMac7,1", "Merom"}, {"iMac8,1", "Penryn"}, {"iMac9,1", "Penryn"}, {"iMac10,1", "Wolfdale"}, {"iMac11,1", "Wolfdale, Lynnfield"}, {"iMac11,2", "Clarkdale"}, {"iMac11,3", "Clarkdale, Lynnfield"}, {"iMac12,1", "Sandy Bridge"}, {"iMac12,2", "Sandy Bridge"}, {"iMac13,1", "Ivy Bridge"}, {"iMac13,2", "Ivy Bridge"}, {"iMac14,1", "Haswell"}, {"iMac14,3", "Haswell"}, {"iMac14,2", "Haswell"}, {"iMac14,4", "Haswell"}, {"iMac15,1", "Haswell"}, {"iMac16,1", "Broadwell"}, {"iMac16,2", "Broadwell"}, {"iMac17,1", "Skylake"}, {"iMac18,1", "Kaby Lake"}, {"iMac18,2", "Kaby Lake"}, {"iMac18,3", "Kaby Lake"}, {"iMacPro1,1", "Skylake"}, {"Macmini1,1", "Yonah"}, {"Macmini2,1", "Merom"}, {"Macmini3,1", "Penryn"}, {"Macmini4,1", "Penryn"}, {"Macmini5,1", "Sandy Bridge"}, {"Macmini5,2", "Sandy Bridge"}, {"Macmini5,3", "Sandy Bridge"}, {"Macmini6,1", "Ivy Bridge"}, {"Macmini6,2", "Ivy Bridge"}, {"Macmini7,1", "Haswell"}, {"Macmini8,1", "Coffe Lake"}, {"MacPro1,1", "Woodcrest"}, {"MacPro2,1", "Clovertown"}, {"MacPro3,1", "Harpertown"}, {"MacPro4,1", "Bloomfield, Gainestown"}, {"MacPro5,1", "Bloomfield, Gulftown, Westmere"}, {"MacPro5,1", "Bloomfield, Westmere, Gulftown"}, {"MacPro6,1", "Ivy Bridge"}, {"MacBook1,1", "Yonah"}, {"MacBook2,1", "Merom"}, {"MacBook3,1", "Merom"}, {"MacBook4,1", "Penryn"}, {"MacBook5,1", "Penryn"}, {"MacBook5,2", "Penryn"}, {"MacBook6,1", "Penryn"}, {"MacBook7,1", "Penryn"}, {"MacBook8,1", "Broadwell"}, {"MacBook9,1", "Skylake"}, {"MacBook10,1", "Kaby Lake"}, {"MacBookAir1,1", "Merom"}, {"MacBookAir2,1", "Penryn"}, {"MacBookAir3,1", "Penryn"}, {"MacBookAir3,2", "Penryn"}, {"MacBookAir4,1", "Sandy Bridge"}, {"MacBookAir4,2", "Sandy Bridge"}, {"MacBookAir5,1", "Ivy Bridge"}, {"MacBookAir5,2", "Ivy Bridge"}, {"MacBookAir6,1", "Haswell"}, {"MacBookAir6,2", "Haswell"}, {"MacBookAir7,1", "Broadwell"}, {"MacBookAir7,2", "Broadwell"}, {"MacBookAir8,1", "Amber Lake Y"}, {"MacBookPro1,1", "Yonah"}, {"MacBookPro1,2", "Yonah"}, {"MacBookPro2,2", "Merom"}, {"MacBookPro2,1", "Merom"}, {"MacBookPro3,1", "Merom"}, {"MacBookPro4,1", "Penryn"}, {"MacBookPro5,1", "Penryn"}, {"MacBookPro5,2", "Penryn"}, {"MacBookPro5,5", "Penryn"}, {"MacBookPro5,4", "Penryn"}, {"MacBookPro5,3", "Penryn"}, {"MacBookPro7,1", "Penryn"}, {"MacBookPro6,2", "Arrandale"}, {"MacBookPro6,1", "Arrandale"}, {"MacBookPro8,1", "Sandy Bridge"}, {"MacBookPro8,2", "Sandy Bridge"}, {"MacBookPro8,3", "Sandy Bridge"}, {"MacBookPro9,2", "Ivy Bridge"}, {"MacBookPro9,1", "Ivy Bridge"}, {"MacBookPro10,1", "Ivy Bridge"}, {"MacBookPro10,2", "Ivy Bridge"}, {"MacBookPro11,1", "Haswell"}, {"MacBookPro11,2", "Haswell"}, {"MacBookPro11,3", "Haswell"}, {"MacBookPro12,1", "Broadwell"}, {"MacBookPro11,4", "Haswell"}, {"MacBookPro11,5", "Haswell"}, {"MacBookPro13,1", "Skylake"}, {"MacBookPro13,2", "Skylake"}, {"MacBookPro13,3", "Skylake"}, {"MacBookPro14,1", "Kaby Lake"}, {"MacBookPro14,2", "Kaby Lake"}, {"MacBookPro14,3", "Kaby Lake"}, {"MacBookPro15,2", "Coffee Lake"}, {"MacBookPro15,1", "Coffee Lake"}}
　　
　　–2D List内の検索
　　set gList to searchInListByIndexItem(macList, 1, macID) of me
　　if gList = missing value or gList = {} then
　　　　error "Error:" & macID & "is newer Machine than I expected in Dec 2018 or Older PowerPC Mac , may be"
　　end if
　　
　　set g2List to FlattenList(gList) of me –複数の結果が得られた場合に備える
　　return contents of second item of g2List
end getIntelCoreProcessorFamilyName

–2Dリストから、指定インデックスアイテムで、指定データが該当する最初のものを返す
on searchInListByIndexItem(aList as list, itemNum as integer, hitData as string)
　　set setKey to current application’s NSMutableSet’s setWithArray:aList
　　
　　if itemNum < 1 then return {}
　　set aPredicateStr to ("SELF[" & (itemNum – 1) as string) & "] == ’" & hitData & "’"
　　
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat:aPredicateStr
　　set aRes to (setKey’s filteredSetUsingPredicate:aPredicate)
　　set bRes to aRes’s allObjects()
　　
　　set cRes to bRes as list of string or string –as anything
　　return cRes
end searchInListByIndexItem

–By Paul Berkowitz
–2009年1月27日 2:24:08:JST
–Re: Flattening Nested Lists
on FlattenList(aList)
　　set oldDelims to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to {"????"}
　　set aString to aList as text
　　set aList to text items of aString
　　set AppleScript’s text item delimiters to oldDelims
　　return aList
end FlattenList

★Click Here to Open This Script　
Posted in shell script System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSMutableSet NSPredicate | Leave a comment

teratailの指定IDのユーザー情報を取得する_curl

Posted on 11月 27, 2018 by Takaaki Naganoya

プログラミング系質問サイトteratailのREST APIを呼び出して、指定ユーザー名の情報を取得するAppleScriptです。

TeratailのREST APIは、タグ、ユーザー、質問の３ジャンルの情報取得を行えるように整備されており、特定カテゴリ（タグで分類）の新規質問が投稿されたかどうかを定期的に確認するようなAppleScriptを作って運用することもできます（そこまでやっていないですけれども）。

REST API呼び出しにはNSURLConnectionからNSURLSessionに移行していますが、どうもNSURLSessionだと呼び出せない（AppleScriptからの呼び出し処理が完了しない）サービスがあったりするので、結局shellのcurlコマンドを呼び出すのが手短にすむケースが多いようです。

Teratailの場合も、NSURLSessionで呼び出せるAPIもあれば、結果が返ってこないAPIもあり、NSURLConnectionよりも使い勝手がよくないと感じています（個人の感想です）。

このあたり、将来的なmacOSのアップデートでNSURLConnectionが使えなくなる日が来るのかもしれませんが、curlコマンドを使うように集約するべきなのか、NSURLSessionで書き換えるべきなのか悩ましいところです。

AppleScript名：teratailの指定IDのユーザー情報を取得する_curl
— Created 2018-11-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

set aUserRes to searchOneUserByDisplayName("Piyomaru") of me
–> {meta:{limit:20, message:"success", hit_num:1, total_page:1, page:1}, users:{{score:43, photo:"https://teratail.storage.googleapis.com/uploads/avatars/u6/66639/MSIS21by_thumbnail.jpg", display_name:"Piyomaru"}}}

on searchOneUserByDisplayName(aName)
　　set aRec to {q:aName}
　　set reqURLStr to "https://teratail.com/api/v1/users/search"
　　set bURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set tmpData to (do shell script "curl -X GET ＼"" & bURL & "＼"")
　　set jsonString to NSString’s stringWithString:tmpData
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　if aJsonDict = missing value then return false
　　return (aJsonDict as record)
end searchOneUserByDisplayName

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　
Posted in Network Record REST API shell script URL | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy NSJSONSerialization NSMutableDictionary NSString NSURL NSURLComponents NSURLQueryItem | 1 Comment

Terminal.appでコマンドを実行する

Posted on 8月 20, 2018 by Takaaki Naganoya

Terminal.appでコマンドを実行するAppleScriptです。

AppleScriptからshell commandを実行するならdo shell scriptコマンドを経由することが多いので、Terminal.appをコントロールしてshell commandを実行しているのは「よくわかっていない人」だけです。

ただ、そうはいってもごくまれにTerminal.app上でshell commandを実行する必要に迫られて（10年に１度ぐらいの割合で）、仕方なくTerminal.appをコントロールすることになりますが、Windowの有無を確認してその場合に応じて書き方を若干変える必要があるのが面倒。なので、このようにサブルーチンにして使い回すのが一般的なやりかたです。

■本ルーチン使用例
・2つのPDFのテキストの指定ページの差分をVimdiffで表示する v2

この例のほかはssh経由でhostにログインしてコマンド実行したときぐらいで、この２例が「本当にTerminal.appを操作しないと処理できない例」で、ほかは99.9％do shell scriptコマンドで済みました。

AppleScript名：Terminal.appでコマンドを実行する
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aCom to "ps"
doComInTerminalWindow(aCom) of me

on doComInTerminalWindow(aCMD as string)
　　using terms from application "Terminal"
　　　　tell application id "com.apple.Terminal"
　　　　　　activate
　　　　　　set wCount to count (every window whose visible is true)
　　　　　　
　　　　　　if wCount = 0 then
　　　　　　　　–ウィンドウが１枚も表示されていない場合
　　　　　　　　do script aCMD
　　　　　　else
　　　　　　　　–すでにウィンドウが表示されている場合
　　　　　　　　do script aCMD in front window
　　　　　　end if
　　　　end tell
　　end using terms from
end doComInTerminalWindow

★Click Here to Open This Script　
Posted in shell script | Tagged 10.11savvy 10.12savvy 10.13savvy Terminal | Leave a comment

オープン中のIllustrator書類をartboardごとに分割 v2

Posted on 8月 9, 2018 by Takaaki Naganoya

Adobe Illustrator CC 2018（バージョン22.1）で、オープン中の（複数のアートボードを持つ）書類を、アートボード単位で別書類に分けるAppleScriptです。

書類は（とりあえず）デスクトップに書き込まれます。

こういうコマンドが最初からあってもおかしくないところですが、存在していないようなので書いてみました。まずは、オープン中の書類のパスを取得し、各アートボードの名称を取得して書き出し時のファイル名として使用します。

元ファイルをクローズしては、デスクトップに新規名称でコピーし、コピーした書類をオープン、書き出し対象外のアートボードを順次選択してはアートボード上のオブジェクトを削除してアートボード自体も削除、すべて削除したら保存してクローズという動作を行います。

本来であれば高速化のために複数のアートボードを一括で削除することを考えるところですが、アートボードの削除だけであればできるものの、アートボード上のオブジェクトの削除が行えなくなってしまうので、順次削除に落ち着きました。また、本Scriptが本気でスピードを求められるようなハードな用途ではなく、文字や画像の流し込みテンプレートのメンテナンス用という「平和な用途」のために作成したものであるため、高速化処理については考慮していません。

最初からアートボード外に置かれたオブジェクトについては削除していません。あくまで自分用のツールなので作り込む必要性を感じません。気が向いたら削除するのではないでしょうか。

本Scriptの作成中にも、単にAppleScriptで命令を出しただけで派手にクラッシュしまくるAdobe Illustrator。バージョンが上がって見た目が変わっても、あの出来の悪いIllustratorであることに変わりはないのだと思い知らされました。

AppleScript名：オープン中のIllustrator書類をartboardごとに分割 v2.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/08/07
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use scripting additions

set dPath to (path to desktop) as string
set namesList to {}

tell application "Adobe Illustrator"
　　tell front document
　　　　set aCount to count every artboard
　　　　set aPath to (file path) as string
　　end tell
　　
　　repeat with i from 1 to aCount
　　　　set aName to getArtboardName(i – 1) of me –index base correction (1 –> 0)
　　　　set the end of namesList to aName
　　end repeat
　　
　　close every document saving no
end tell

repeat with i from 1 to aCount
　　
　　set aRes to retSerialListWithExclusion(1, aCount, i) of me
　　set aaRes to reverse of aRes –artboardをIndex値で指定するため、先頭から削除するとIndex値が変わる。そのため逆順に処理
　　
　　set tmpName to contents of item i of namesList
　　
　　set fromFile to POSIX path of aPath
　　set fromFilePOSIX to quoted form of POSIX path of fromFile
　　
　　set toFile to (dPath & tmpName & ".ai")
　　set toFilePOSIX to quoted form of POSIX path of toFile
　　
　　set shText to "cp " & fromFilePOSIX & " " & toFilePOSIX
　　do shell script shText
　　
　　tell application "Adobe Illustrator"
　　　　open file toFile
　　　　tell front document
　　　　　　repeat with ii in aaRes
　　　　　　　　set jj to ii as integer
　　　　　　　　selectArtboard(jj – 1) of me –index base correction (1 –> 0)
　　　　　　　　selectobjectsonactiveartboard
　　　　　　　　delete selection
　　　　　　　　delete artboard jj
　　　　　　end repeat
　　　　　　
　　　　　　close with saving
　　　　end tell
　　end tell
　　
end repeat

–https://lists.apple.com/archives/applescript-users/2015/Jul/msg00104.html
on selectArtboard(theArtboardIndex as string)
　　tell application "Adobe Illustrator"
　　　　tell front document
　　　　　　–Index is 0 based
　　　　　　do javascript ("app.activeDocument.artboards.setActiveArtboardIndex(" & theArtboardIndex & ")")
　　　　end tell
　　end tell
end selectArtboard

on getArtboardName(theArtboardIndex as string)
　　tell application "Adobe Illustrator"
　　　　tell front document
　　　　　　–Index is 0 based
　　　　　　do javascript ("app.activeDocument.artboards[" & theArtboardIndex & "].name")
　　　　end tell
　　end tell
end getArtboardName

on retSerialListWithExclusion(aFromNum as integer, aToNum as integer, anEXnum as integer)
　　set outList to {}
　　repeat with i from aFromNum to aToNum
　　　　if i = anEXnum then
　　　　　　—
　　　　else
　　　　　　set the end of outList to i
　　　　end if
　　end repeat
　　
　　return outList
end retSerialListWithExclusion

★Click Here to Open This Script　
Posted in file File path shell script | Tagged 10.12savvy Illustrator | Leave a comment

Google Drive File StreamのドライブでSpotlight Indexを生成

Posted on 8月 4, 2018 by Takaaki Naganoya

Google Drive File Stream上でSpotlight Indexを生成するAppleScriptです。

Google Driveには、Gmailのオマケでついてくる個人のデバイス間で情報のシンクロを行う目的のPersonal版（DropboxのGoogle版的なもの）と、企業内やグループ内でファイル共有を行うG SuiteのGoodle Drive File Streamがあり、後者についてはGoogleによる「Google Drive File Stream」ツールが提供され、GoogleDriveをデスクトップにマウントできます。

実際にGoogle Drive File Streamを使ってみたところ、デフォルト状態だとSpotlight検索が効きませんでした。

そこで、Index生成してみたものの…既存のファイルについてはSpotlight検索できませんでした。Index生成後に、新規追加したファイルについてはSpotlight検索が有効でした。

後日談：ただ、Google Drive File Streamに対してSpotlight Indexを常時生成するようにすると、CPUに対する負荷が大きくなるため、実際の運用ではSpotlightを無効にして運用するようにしました。

AppleScript名：Google Drive File Streamでインデックス生成
do shell script "mdutil -E /Volumes/GoogleDrive/" with administrator privileges

★Click Here to Open This Script　

自分が試したのは、Google Drive File Stream内の「マイドライブ」領域のみで、

「グループドライブ」領域についてはまだテストできていません。

既存のファイルについては、mdimportコマンドでインデックス作成すれば大丈夫だと思っていますが、実際に試してみると予想外の挙動を行うのかもしれません。

AppleScript名：GDFS上でSpotlight検索
— Created 2016-06-17 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSArray : a reference to current application’s NSArray
property NSPredicate : a reference to current application’s NSPredicate
property NSSortDescriptor : a reference to current application’s NSSortDescriptor
property NSMetadataQuery : a reference to current application’s NSMetadataQuery
property NSNotificationCenter : a reference to current application’s NSNotificationCenter
property NSMetadataQueryDidUpdateNotification : a reference to current application’s NSMetadataQueryDidUpdateNotification
property NSMetadataQueryDidFinishGatheringNotification : a reference to current application’s NSMetadataQueryDidFinishGatheringNotification

property searchRes : {}

set origPath to POSIX path of (choose folder)
set aList to spotlightSearch(origPath, "kMDItemContentType == ’public.png’") of me

on spotlightSearch(origPath, aMDfindParam)
　　
　　set my searchRes to {} –initialize
　　initiateSearchForFullPath(aMDfindParam, origPath) –Predicate & Scope Directory
　　
　　–Waiting for the result
　　repeat while my searchRes = {}
　　　　delay 0.01
　　end repeat
　　
　　set anObj to my searchRes’s firstObject() –Pick up the first one for test
　　if anObj = missing value then return {} –No Result
　　
　　set resArray to {}
　　repeat with anItem in my searchRes
　　　　set j to contents of anItem
　　　　set aPath to (j’s valueForAttribute:"kMDItemPath") as string
　　　　set the end of resArray to aPath
　　end repeat
　　
　　return resArray
　　
end spotlightSearch

on initiateSearchForFullPath(aQueryStrings, origPath)
　　
　　set aSearch to NSMetadataQuery’s alloc()’s init()
　　
　　NSNotificationCenter’s defaultCenter()’s addObserver:(me) selector:"queryDidUpdate:" |name|:(NSMetadataQueryDidUpdateNotification) object:aSearch
　　NSNotificationCenter’s defaultCenter()’s addObserver:(me) selector:"initalGatherComplete:" |name|:(NSMetadataQueryDidFinishGatheringNotification) object:aSearch
　　
　　set aPredicate to NSPredicate’s predicateWithFormat:aQueryStrings
　　aSearch’s setPredicate:aPredicate
　　
　　set aScope to NSArray’s arrayWithObjects:{origPath}
　　aSearch’s setSearchScopes:aScope
　　
　　set sortKeys to NSSortDescriptor’s sortDescriptorWithKey:"kMDItemFSName" ascending:true
　　aSearch’s setSortDescriptors:(NSArray’s arrayWithObject:sortKeys)
　　
　　aSearch’s startQuery()
　　
end initiateSearchForFullPath

on queryDidUpdate:sender
　　log sender
　　–> (NSConcreteNotification) NSConcreteNotification 0x7fa618450820 {name = NSMetadataQueryDidFinishGatheringNotification; object = <NSMetadataQuery: 0x7fa6172c6ca0>}
end queryDidUpdate:

on initalGatherComplete:sender
　　set anObject to sender’s object
　　anObject’s stopQuery()
　　NSNotificationCenter’s defaultCenter()’s removeObserver:me |name|:(NSMetadataQueryDidUpdateNotification) object:anObject
　　NSNotificationCenter’s defaultCenter()’s removeObserver:me |name|:(NSMetadataQueryDidFinishGatheringNotification) object:anObject
　　
　　set my searchRes to anObject’s results()
end initalGatherComplete:

★Click Here to Open This Script　
Posted in drive file shell script Spotlight | Tagged 10.12savvy NSArray NSMetadataQuery NSNotificationCenter NSPredicate NSSortDescriptor | Leave a comment

Enable Script Menu

Posted on 3月 12, 2018 by Takaaki Naganoya

メニューバー上にあるScript Menuを表示状態に設定変更するAppleScriptです。

Script Menuの表示・非表示はスクリプトエディタ内の環境設定で制御するようになっていますが、Script Menu自体はMenu Extraでスクリプトエディタとは独立して動作しているので、外部からオンにすることが可能です。

–> Demo Movie


▲Default


▲実行後

AppleScript名：Enable System Wide Script Menu
tell application "Finder"
　　open (POSIX file "/System/Library/CoreServices/Menu Extras/Script Menu.menu") as alias
end tell

★Click Here to Open This Script　
AppleScript名：Enable System Wide Script Menu (Shell)
do shell script "open " & quoted form of "/System/Library/CoreServices/Menu Extras/Script Menu.menu"

★Click Here to Open This Script　

追記：macOS 10.14でOS標準装備のScript MenuがMenu Extraから単体のアプリケーションに変更になったので、Enableの方法も変更になりました。

AppleScript名：Enable System Wide Script Menu_10.14.scpt
tell application "Finder"
　　open (POSIX file "/System/Library/CoreServices/Script Menu.app") as alias
end tell

★Click Here to Open This Script　
Posted in shell script System | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy | 1 Comment

shebangっぽい行から実行プログラムを取得してスクリプト言語の拡張子を取得

Posted on 3月 10, 2018 by Takaaki Naganoya

shebangを含む複数行のテキストからshebang（らしきもの）を検索して、実行プログラム名を取得し、実行するScript言語のファイルの拡張子を判定するAppleScriptです。

RTFで記述したシェルスクリプトやRubyのスクリプトのスケルトンに、色分けしたパラメータ部分のデータを差し替えてRubyやシェルスクリプトの実行ファイルを動的に書き出し、所定のスクリプト言語処理系で実行するAppleScriptを書いたときに用いたものです。

割と処理内容はヘロヘロでたいした固い処理は行なっていませんが、凶悪な処理を行うためのキーパーツです。

AppleScript名：shebangっぽい行から実行プログラムを取得してスクリプト言語の拡張子を取得
set aText to "#!/usr/bin/env python
import re
"

set aLang to splitLangFromShebangStr(aText) of me
if aLang = false then error "This data seems not a shebang"
set aExt to detectScriptFileExtension(aLang) of me
return {aLang, aExt}
–> {"python", "py"}

–shebangっぽい行から実行プログラム名を抽出
on splitLangFromShebangStr(aText)
　　set aTmpList to paragraphs of aText
　　
　　repeat with i in aTmpList
　　　　set j to contents of i
　　　　if j starts with "#!" then
　　　　　　set aWorkList to words of j
　　　　　　set aLang to contents of last item of aWorkList
　　　　　　return aLang
　　　　end if
　　end repeat
　　
　　return false
end splitLangFromShebangStr

on detectScriptFileExtension(aLang)
　　ignoring case
　　　　if aLang = "Ruby" then
　　　　　　return "rb"
　　　　else if aLang = "Python" then
　　　　　　return "py"
　　　　else if aLang = "perl" then
　　　　　　return "pl"
　　　　else if aLang = "sh" then
　　　　　　return "sh"
　　　　else
　　　　　　return ""
　　　　end if
　　end ignoring
end detectScriptFileExtension

★Click Here to Open This Script　
Posted in shell script Text | Tagged 10.11savvy 10.12savvy 10.13savvy | 1 Comment

shell環境変数を取得する

Posted on 2月 24, 2018 by Takaaki Naganoya

do shell scriptコマンドでシェルコマンドが実行される場合の環境変数の確認は、１コマンドで実行できます。Terminal.app上で実行するときと初期条件が異なるので、必要に応じて環境変数の設定が必要です。

do shell script "env"

★Click Here to Open This Script　

これが、Cocoaの機能だとどういう条件で実行されるのか、というのがこのScriptを書いた原因です。動かしてみて、「ああ、do shell scriptコマンドと同じなんだね」ということが理解できました。

AppleScript名：shell環境変数を取得する
— Created 2016-03-16 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

current application’s NSProcessInfo’s processInfo()’s environment()
–>　　(NSDictionary) {​​​​​PATH:"/usr/bin:/bin:/usr/sbin:/sbin", ​​​​​TMPDIR:"/var/folders/h4/jfhlwst88xl9z0001s7k9vk00000gr/T/", ​​​​​LOGNAME:"maro", ​​​​​XPC_FLAGS:"0x0", ​​​​​HOME:"/Users/me", ​​​​​Apple_PubSub_Socket_Render:"/private/tmp/com.apple.launchd.KvufhRIpUw/Render", ​​​​​USER:"me", ​​​​​SSH_AUTH_SOCK:"/private/tmp/com.apple.launchd.3B8HzKhUz5/Listeners", ​​​​​DISPLAY:"/private/tmp/com.apple.launchd.el9lFx0WpV/org.macosforge.xquartz:0", ​​​​​XPC_SERVICE_NAME:"au.com.myriad-com.ASObjC-Explorer-4.1891872", ​​​​​SHELL:"/bin/bash", ​​​​​__CF_USER_TEXT_ENCODING:"0x1F8:0x1:0xE"​​​}

★Click Here to Open This Script　
Posted in shell script System | Tagged 10.11savvy 10.12savvy 10.13savvy | Leave a comment

文字列で与えたシェルコマンドを実行する v2

Posted on 2月 13, 2018 by Takaaki Naganoya

do shell scriptコマンドとほぼ等価な、Cocoaの機能を用いたshell script実行のAppleScriptです。

よく「Terminal.app上のshell scriptをそのままdo shell scriptコマンドで実行して動かない」という声を聞きますが、そもそも環境変数が全然違うのでそのまま動くはずがありません。

AppleScriptのdo shell scriptコマンドは、いまのmacOSのセキュリティ向上の流れで行けば確実に近い将来に「デフォルトで実行禁止」「環境設定でオンにしてはじめて実行可能に」という扱いになることでしょう。

Cocoaのshell command呼び出し機能についても同様の制限が加わるかどうかは不明ですが、Cocoa経由でのshell command呼び出しAppleScriptについて調べておきました。

AppleScript名：文字列で与えたシェルコマンドを実行する v2
— Created 2016-02-13 by Takaaki Naganoya
— 2016 Piyomaru Software
–以下を参照：
–http://stackoverflow.com/questions/412562/execute-a-terminal-command-from-a-cocoa-app
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aRes to (runCommandString("pwd") of me) as string
–>　　"/"

set bRes to (runCommandString("cd & ls -la") of me) as string

–Lock Screen
–runCommandAtPath("/System/Library/CoreServices/Menu Extras/User.menu/Contents/Resources/CGSession", "-suspend") of me

–文字列で与えたシェルコマンドを実行する
on runCommandString(commandStr as string)
　　set aPipe to current application’s NSPipe’s pipe()
　　set aTask to current application’s NSTask’s alloc()’s init()
　　aTask’s setLaunchPath:"/bin/sh"
　　aTask’s setArguments:{"-c", current application’s NSString’s stringWithFormat_("%@", commandStr)} –stringWithFormatはASOCに書き換え時の要注意点
　　aTask’s setStandardOutput:aPipe
　　set aFile to aPipe’s fileHandleForReading()
　　aTask’s |launch|()
　　return current application’s NSString’s alloc()’s initWithData:(aFile’s readDataToEndOfFile()) encoding:(current application’s NSUTF8StringEncoding)
end runCommandString

–指定したパスのシェルコマンドを実行する（結果などは取得しない）
on runCommandAtPath(commandPath as string, anArgument as string)
　　set aTask to current application’s NSTask’s alloc()’s init()
　　aTask’s setLaunchPath:commandPath
　　aTask’s setArguments:(current application’s NSArray’s arrayWithObject:anArgument)
　　aTask’s |launch|()
end runCommandAtPath

★Click Here to Open This Script　
Posted in shell script System | Tagged 10.11savvy 10.12savvy 10.13savvy | Leave a comment

電子書籍（PDF）をオンラインストアで販売中！

Popular Posts

  • 画面上の指定座標にマウスカーソルを強制移動させてクリック
  • AppleScript上でJavaScriptを実行する
  • macOS 10.15beta関連
  • Numbersで選択範囲のセルのデータを取得して重複データを抽出
  • 頭のいいタイマー割り込み実行
  • macOS 10.15, Catalina上でBridgePlus,Myriad Tables LibなどのScript Libraryを利用
  • macOS 10.14 AppleScriptリリースノート
  • 指定文字コードでファイル書き出し（UTF-8）v2
  • 指定文字コードでファイル書き出し（UTF-16BE）v2
  • 郵便専門ネットで郵便番号を5桁の全国地方公共団体コード／JISコード／市町村コードに変換
  • MMMM dd yyyyの文字列をdateに変換
  • 自然言語テキストから複数の日付情報を抽出
  • Safariで表示中のWebページの最終更新日時を取得
  • macOS 10.14で新設されたエラーコード-1743を確認する
  • JPEG画像の破損チェック
  • プリンタを指定してダイアログ非表示状態で印刷実行
  • 文字エンコーディングを自動判別してファイル読み込み v1.2.1
  • Pages書類の１ページ目の表の背景色を置換
  • 電子ブック年度末フェア実施中！
  • ファイルパスの変換（Alias→POSIX path→NSURL→POSIX path→file→Alias）

Tags

10.11savvy (1121) 10.12savvy (1264) 10.13savvy (1274) 10.14savvy (344) 10.15savvy (116) CotEditor (44) Finder (38) ITLibrary (13) iTunes (25) Keynote (47) Mail (11) NSAlert (37) NSAlertSecondButtonReturn (14) NSArray (51) NSBezierPath (14) NSBitmapImageRep (17) NSBundle (12) NSButton (17) NSColor (43) NSCountedSet (16) NSDictionary (27) NSFileManager (20) NSFont (14) NSImage (34) NSIndexSet (11) NSMutableArray (50) NSMutableDictionary (19) NSPredicate (39) NSRunningApplication (34) NSScreen (24) NSScrollView (20) NSSortDescriptor (15) NSString (90) NSTextView (14) NSURL (61) NSUTF8StringEncoding (12) NSUUID (16) NSView (31) NSWindow (13) NSWorkspace (12) Numbers (36) OSAScript (18) Safari (25) Script Editor (20) TextEdit (13)

カテゴリー

  • AirDrop
  • AirPlay
  • AppleScript Application on Xcode
  • Bluetooth
  • boolean
  • Bug
  • Calendar
  • call by reference
  • Clipboard
  • Code Sign
  • Color
  • Custom Class
  • dialog
  • drive
  • exif
  • file
  • File path
  • filter
  • folder
  • Font
  • font
  • geolocation
  • GUI
  • GUI Scripting
  • How To
  • Icon
  • Image
  • Input Method
  • Internet
  • JXA
  • Keychain
  • Language
  • list
  • Locale
  • Machine Learning
  • Markdown
  • Menu
  • Metadata
  • MIDI
  • MIME
  • Natural Language Processing
  • Network
  • news
  • Noification
  • Notarization
  • Number
  • OCR
  • OSA
  • PDF
  • PRODUCTS
  • QR Code
  • Raw AppleEvent Code
  • Record
  • recursive call
  • regexp
  • Release
  • Remote Control
  • Require Control-Command-R to run
  • REST API
  • RTF
  • Sandbox
  • Screen Saver
  • Script Libraries
  • sdef
  • search
  • Security
  • shell script
  • Sort
  • Sound
  • Spellchecker
  • Spotlight
  • SVG
  • System
  • Tag
  • Text
  • Text to Speech
  • timezone
  • Tools
  • URL
  • UTI
  • Web Contents Control
  • WiFi
  • XML
  • XML-RPC
  • イベント（Event）
  • 未分類

アーカイブ

  • 2020年1月
  • 2019年12月
  • 2019年11月
  • 2019年10月
  • 2019年9月
  • 2019年8月
  • 2019年7月
  • 2019年6月
  • 2019年5月
  • 2019年4月
  • 2019年3月
  • 2019年2月
  • 2019年1月
  • 2018年12月
  • 2018年11月
  • 2018年10月
  • 2018年9月
  • 2018年8月
  • 2018年7月
  • 2018年6月
  • 2018年5月
  • 2018年4月
  • 2018年3月
  • 2018年2月

https://piyomarusoft.booth.pm/items/301502

メタ情報

  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org
Proudly powered by WordPress
Theme: Flint by Star Verte LLC