画像をExcelのワークシート上に配置

Posted on 4月 4 by Takaaki Naganoya

Microsoft 365のExcel v16.71、Windows版とmacOS版のソースコードが共通化されたというふれ込みではあるものの、実はけっこうフォーム部分が違うし、VBのマクロエディタで日本語が記入できないとか、互換性のない関数（Mac上で動作しないENCODEURL、Switch,IFS、FILTERXML、WEBSERVICEなどの関数）の存在など、いろいろ勘弁してほしい出来です。

しばらくはNumbersだけで用が済んでいたのですが、ここのところWindows版のExcelの講座なども行っていたので、併せてmacOS版のExcelについても追加調査。細かい点のチェックを行っていました。

そんなExcelでアドインのオンラインストアからQRコード作成用アドインを探してみたところ、フリーなものは存在していないようです。

Cocoaの機能を利用すれば、割とすぐにできてしまう程度のQRコード。わざわざアドインの力を利用する必要などなかったのです。AppleScriptでQRコードを生成して、Excelのワークシートに差し込めばよいだけです。

ところが、ひさしぶりにExcelのScriptを引っ張り出してきて、昔書いた「Excelに指定の画像を配置する」Scriptを実行してみたところ、エラーで動きません。

ワークシート上にshapeを作成できるのに、そのshapeに指定パスの画像を割り当てる処理でエラーになります。

そんな時、「出来の悪いプログラマは、POSIX pathで誤魔化して実装する」という経験則が思い出されました。

目を閉じると、AppleのKeynoteで一時期行われていた、画像配置コマンドにPOSIX pathを要求していたアレな実装であるとか（あれはひどかった）、いまだにアレであり続けているAdobe Acrobat DistillerのdistillコマンドがPOSIX pathを要求する件であるとか（file pathって書いてあるのに、aliasじゃなくてPOSIX pathを要求するという地雷仕様）、枚挙にいとまがありません。

そんなわけで、普通に書いても通らなかったのでパスをPOSIX pathで与えてみたところ、見事（？）配置されました。

AppleScript名：画像をワークシート上に配置.scpt

set anImagePath to choose file
set anImagePOSIX to POSIX path of anImagePath

tell application "Microsoft Excel"
　　set cwb to workbook 1
　　tell cwb
　　　　tell worksheet 1
　　　　　　set aPicShape to make new shape at the beginning
　　　　　　set width of aPicShape to 312
　　　　　　set height of aPicShape to 312
　　　　　　user picture of aPicShape picture file anImagePOSIX
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

(Visited 33 times, 1 visits today)

ファイル選択でiCloud Driveをデフォルトフォルダに指定

Posted on 9月 24, 2022 by Takaaki Naganoya

ファイル選択時にiCloud Driveをデフォルトのフォルダに指定するAppleScriptです。

macOS 10.9あたりでスクリプトエディタがiCloud DriveにAppleScriptを保存したり、iCloud Drive上のAppleScriptをオープンしたりできるようになりました。iCloud Drive上にAppleScriptライブラリを置いて参照することもできたはずですが、ちょっと情報が出てきません。

AppleScript名：ファイル選択でiCloud Driveをデフォルトフォルダに指定.scpt

set filePath to (path to library folder from user domain as text) & "Mobile Documents:"
set fRes to choose file default location (filePath as alias)

★Click Here to Open This Script　

(Visited 34 times, 1 visits today)

AS関連データの取り扱いを容易にする（はずの）privateDataTypeLib

Posted on 8月 22, 2022 by Takaaki Naganoya

AS関連データの取り扱いを簡単にすることを目的に書き出した、privateDatatypeLibです。

プログラムとデータを分離して、データ記述部分を外部ファイル（設定ファイルなど）に追い出したときに、どのようなデータかを表現するための道具として試作してみました。

macOS上のデータ記述子は、

などのさまざまなデータ識別方法が存在していますが、どれも（自分の）用途には合わなかったので、検討・試作をはじめてみました。Predicatesが一番近いものの、不十分なのでいろんなデータ型や用途に拡張。あくまで自分用なので「public」などの宣言はとくに不必要と考え、縮小して処理を行なっています。

とくに、ファイルパスの処理なんて定型処理しかしないのに、わざわざ何かの表現を行う必要があるのはナンセンスですし、日付関連も割と余計な記述が多いように感じています。

また、緯度/経度のデータや座標データなども、もう少しなんとかならないかと思っています。

AppleScript名：privateDataTypeLib.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/08/22
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aData to "１００"
set dType to "@number"
set bData to "" –不要なケース多数。不要な場合にはヌル文字を指定
set mePath to path to me –実際には、呼び出し側で取得して指定。ライブラリ自体のパスを求めているのはテスト実行時のみ
set aRes to getParameterAndCalc(aData, dType, bData, mePath) of me

on getParameterAndCalc(aData, dType, bData, mePath)
　　if dType = "@string" then
　　　　return normalizeByNFC(aData) of me
　　　　
　　else if dType = "@number" then
　　　　set tmpA to zenToHan(aData) of charConvKit of me –全角→半角変換
　　　　set a to detectOutNumStr(tmpA) of me –数字＋関連・意外の文字を除外
　　　　return normalizeByNFC(a) of me
　　　　
　　else if dType = "@filepath.sub.foldername" then
　　　　set aClass to class of aData –aliasだったらPOSIX pathに変換。file…はどうなんだか
　　　　if aClass = alias then set aData to POSIX path of aData
　　　　return aData & bData & "/"
　　　　
　　else if dType = "@file.comment" then
　　　　set aStr to getFinderComment(POSIX path of mePath) of me
　　　　return normalizeByNFC(aStr) of me
　　　　
　　else if dType = "@file.name" then
　　　　set aClass to class of aData
　　　　if aClass = alias then set aData to POSIX path of aData
　　　　set aStr to (current application’s NSString’s stringWithString:aData)’s lastPathComponent()’s stringByDeletingPathExtension()
　　　　return normalizeByNFC(aStr as string) of me
　　　　
　　else if dType = "@date.month" then
　　　　set curDate to current date
　　　　set curMonth to month of curDate as number
　　　　return curMonth as string
　　　　
　　else
　　　　return aData
　　end if
end getParameterAndCalc

on normalizeByNFC(aStr)
　　set aNSStr to current application’s NSString’s stringWithString:aStr
　　set aNFC to aNSStr’s precomposedStringWithCanonicalMapping()
　　return aNFC as string
end normalizeByNFC

–ANK文字列以外のものをそぎ落とす
on detectOutNumStr(testStr)
　　set sList to characters of testStr
　　set aStr to ""
　　
　　repeat with i in sList
　　　　if detectOutNumChar(i) of me then
　　　　　　set aStr to aStr & (i as string)
　　　　end if
　　end repeat
　　
　　return aStr
end detectOutNumStr

on detectOutNumChar(testText)
　　–Numeric + Special char
　　set ankChar to {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9", ".", "-", "+", "E", ","}
　　
　　set _testChar to testText as Unicode text
　　
　　ignoring case
　　　　repeat with i in _testChar
　　　　　　set j to contents of i
　　　　　　if j is not in ankChar then
　　　　　　　　return false
　　　　　　end if
　　　　end repeat
　　end ignoring
　　
　　return true
end detectOutNumChar

–Finderコメントを取得
on getFinderComment(aPOSIX)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aPOSIX
　　set aMetaInfo to current application’s NSMetadataItem’s alloc()’s initWithURL:aURL
　　set metaDict to (aMetaInfo’s valuesForAttributes:{"kMDItemFinderComment"}) as record
　　if metaDict = {} then return ""
　　set aComment to kMDItemFinderComment of (metaDict)
　　return aComment
end getFinderComment

script charConvKit
　　— Created 2017-09-06 by Shane Stanley
　　— Modified 2017-09-06 by Takaaki Naganoya
　　use AppleScript
　　use framework "Foundation"
　　property parent : AppleScript
　　
　　property NSString : a reference to current application’s NSString
　　property NSStringTransformFullwidthToHalfwidth : a reference to current application’s NSStringTransformFullwidthToHalfwidth
　　property NSStringTransformHiraganaToKatakana : a reference to current application’s NSStringTransformHiraganaToKatakana
　　property NSStringTransformLatinToHiragana : a reference to current application’s NSStringTransformLatinToHiragana
　　property NSStringTransformLatinToKatakana : a reference to current application’s NSStringTransformLatinToKatakana
　　property NSStringTransformToUnicodeName : a reference to current application’s NSStringTransformToUnicodeName
　　property NSStringTransformToXMLHex : a reference to current application’s NSStringTransformToXMLHex
　　
　　–半角→全角変換
　　on hanToZen(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformFullwidthToHalfwidth) |reverse|:true) as string
　　end hanToZen
　　
　　–全角→半角変換
　　on zenToHan(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformFullwidthToHalfwidth) |reverse|:false) as string
　　end zenToHan
　　
　　–ひらがな→カタカナ変換
　　on hiraganaToKatakana(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformHiraganaToKatakana) |reverse|:false) as string
　　end hiraganaToKatakana
　　
　　–カタカナ→ひらがな変換
　　on katakanaToHiraganaTo(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformHiraganaToKatakana) |reverse|:true) as string
　　end katakanaToHiraganaTo
　　
　　–ローマ字→ひらがな変換
　　on alphabetToHiragana(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToHiragana) |reverse|:false) as string
　　end alphabetToHiragana
　　
　　–ひらがな→ローマ字変換
　　on hiraganaToalphabet(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToHiragana) |reverse|:true) as string
　　end hiraganaToalphabet
　　
　　–ローマ字→カタカナ変換
　　on alphabetToKatakana(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToKatakana) |reverse|:false) as string
　　end alphabetToKatakana
　　
　　–カタカナ→ローマ字変換
　　on katakanaToAlphabet(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToKatakana) |reverse|:true) as string
　　end katakanaToAlphabet
　　
　　–文字→Unicode Name変換
　　on characterToUnicodeName(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToUnicodeName) |reverse|:false) as string
　　end characterToUnicodeName
　　
　　–Unicode Name→文字変換
　　on unicodeNameToCharacter(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToUnicodeName) |reverse|:true) as string
　　end unicodeNameToCharacter
　　
　　–文字→XML Hex変換
　　on stringToXMLHex(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToXMLHex) |reverse|:false) as string
　　end stringToXMLHex
　　
　　–XML Hex→文字変換
　　on xmlHexTostring(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToXMLHex) |reverse|:true) as string
　　end xmlHexTostring
end script

★Click Here to Open This Script　

(Visited 73 times, 1 visits today)

xincludeを有効にしてXML（sdef）読み込み v2

Posted on 7月 26, 2022 by Takaaki Naganoya

指定のBundle IDのアプリケーションのInfo.plistの値からSDEF（AppleScript命令定義ファイル）のファイル情報を読み取って、実際にSDEFの実ファイルを読み取り、得られた文字列をXMLとして解釈する際にXincludeを展開して、再度文字列に戻すAppleScriptです。

もともと、SDEFを読み取って分析することは、アプリケーションのバージョン間の変更差分を検出する用途で試していました。これは、変化のみを検出することを目的としたもので、内容について仔細に認識することを目的としたものではありませんでした。

そこから１歩進んで、AppleScript側から実行環境情報を取得する試みをいろいろ続けてきました。

実行環境自体が何なのか、という判別はここ数年で一番大きな成果だったと感じます。地球にいながら「銀河系の中の、太陽系の中の第３惑星にいる」ということが観測できるようになったわけです。

さらに、それぞれのランタイム環境の識別が可能になったことにより、各実行環境の「差」を判定しやすくなった、という副産物もありました。

話を戻しましょう。

SDEFを読んで、当該アプリケーションが何を行えるかをAppleScript側からも認識できるはずで、そのための調査も開始していました。

System Eventsの「Scripting Definition Suite」はその名前と用語から、AppleScriptからSDEFの解析を行うための部品であることが推測され、いろいろ調べてきたものの…..Apple側がSystem Eventsそれ自体のチェックを行うために設けた「メンテナンス＆デバッグのための機能（ただしSystem Events専用）」だという結論にいたっています。つまり、System Events以外にはまるっきり使えません。

これで、AppleScriptのプログラム側からアプリケーション側の仕様を自動判別＆解析するためには、SDEFそのものを解析するしかないという話になりました。

ただ、SDEFの直接解析については１つの「ちょっと困った仕様」がありました。外部ファイルをincludeできる（Xinclude）ようになっており、そのファイルを元のSDEF上に展開するのは、まじめにXML上の情報を分析する必要があります。ファイル・システム上のどこの場所からどのファイルを読み込むのか、という話と……XMLのオブジェクトモデル上のどこに展開するのかという話の両方を処理する必要があります。まじめに組むと、それなりの時間がかかってしまいそうです。

少ない例から推測してScriptを書くことは不可能ではありませんが、「隠れ仕様」が存在していた場合には対処できません。OS側にその機能があれば、そのままそっくり利用できたほうがよいだろうと思われました。

このXincludeの展開を（他力本願で）行うには、どこのレイヤーのどの機能を用いるべきなのか？

matttのOno.frameworkなどもビルドして試してみたものの、Xincludeの展開はソースコードを全文検索しても見つけられず、もうちょっと物理層に近いレイヤーのlibxml2の機能にアクセスする必要があるようでした。

ほかにも、Unix Shell Commandに、「xsltproc」コマンドが存在しており、Xinclude展開を行ってくれるようでした（XSLTを書けば）。スクリプトエディタに任意のアプリケーションをオープンさせればAppleScript用語辞書を表示してくれるわけで、この表示中のSDEFについてはXincludeがすべて解決された状態になっているため、AppleScriptからスクリプトエディタを操作するという手段もないわけではないのですが、もっとスマートに（こっそり）処理したかったので、これは（機能することがわかっていながらも）使えません。

結局、NSXMLDocumentのNSXMLNodeOptionsでNSXMLDocumentXIncludeを指定すると、XMLテキストをオブジェクトに解釈する際に外部ファイルを展開してくれることが判明。

Mail.appのSDEFでいえば、Standard Suiteにinclude指定があり、

元ファイルを読み込んだだけでは完全体のSDEFを取得できません。これを、本AppleScriptを用いて読み込んで解釈すると、

のように、指定パスに存在している「CocoaStandard.sdef」を展開します。ほかにも、Microsoft系のアプリケーションでXincludeを使用しており、本AppleScriptのような処理を経た上でSDEFの分析を行う必要があることでしょう。

これが、今日明日の段階で何か「すごいこと」ができるような存在になることは決してありませんが、この部品が存在していることで異次元の処理ができるようになるような手応えはあります。

AppleScript名：xincludeを有効にしてXML（sdef）読み込み v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/07/26
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set targAppBundleID to "com.apple.mail" –SDEFを取り出すターゲットのアプリケーションのBundle ID

set thePath to POSIX path of (path to application id targAppBundleID)

set aSDEFname to retAppSdefNameFromBundleIPath(thePath, "OSAScriptingDefinition") of me
if aSDEFname = false then return

if aSDEFname does not end with ".sdef" then set aSDEFname to aSDEFname & ".sdef"
set sdefFullPath to thePath & "Contents/Resources/" & aSDEFname
set sdefAlias to (POSIX file sdefFullPath) as alias –sdefのフルパスを求める

–SDEF読み込み（Xincludeの展開が必要な状態）
tell current application
　　set theXML to read sdefAlias as «class utf8»
end tell

–NSXMLDocumentの生成、Xincludeを有効に
set {theXMLDoc, theError} to current application’s NSXMLDocument’s alloc()’s initWithXMLString:theXML options:(current application’s NSXMLDocumentXInclude) |error|:(reference)

–XMLを文字データ化
set aDocStr to (theXMLDoc’s XMLData)
set aDocStr2 to (current application’s NSString’s alloc()’s initWithData:(aDocStr) encoding:(current application’s NSUTF8StringEncoding)) as string

–指定パスからアプリケーションのScriptabilityをbooleanで返す
on retAppSdefNameFromBundleIPath(appPath as string, aKey as string)
　　set aDict to (current application’s NSBundle’s bundleWithPath:appPath)’s infoDictionary()
　　set aRes to aDict’s valueForKey:(aKey)
　　if aRes = missing value then return false
　　set asRes to aRes as string
　　
　　return asRes as string
end retAppSdefNameFromBundleIPath

★Click Here to Open This Script　

(Visited 52 times, 1 visits today)

相対パスを計算で求める

Posted on 6月 14, 2022 by Takaaki Naganoya

指定のPOSIX pathを元に相対パスを計算するAppleScriptです。

Unix shellであれば、相対パスについては「../../../」などと表現できるわけですが、シェルを介さずに計算する方法が見つからなかったので、必要に迫られて作っておきました。

AppleScript名：上位パスを相対的に求める.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/06/14
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aFile to "/Users/me/Documents/1/2/3"

set aNum to 1
set bFile to getUpperDir(aFile, aNum) of me

–> "/Users/me/Documents/1/2"

set aNum to 2
set cFile to getUpperDir(aFile, aNum) of me
–>"/Users/me/Documents/1"

set aNum to 3
set dFile to getUpperDir(aFile, aNum) of me
–> "/Users/me/Documents"

–与えられたパスから指定階層「上」のパスを求める
on getUpperDir(aPOSIXpath as string, aNum as integer)
　　if aNum < 1 then return aPOSIXpath
　　set pathString to current application’s NSString’s stringWithString:aPOSIXpath
　　repeat aNum times
　　　　set pathString to pathString’s stringByDeletingLastPathComponent()
　　end repeat
　　return pathString as string
end getUpperDir

★Click Here to Open This Script　

AppleScript名：下位パスを配列で追加して求める.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/06/14
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aPOSIXpath to "/Users/me/Documents/" –AppleScriptのPOSIX path表現（フォルダを表現するさい、末尾に「/」）
set catDirList to {"1", "2", "3"}
set bPath to getChildPathByAppendingDirsByArray(aPOSIXpath, catDirList) of me
–> /Users/me/Documents/1/2/3

set aPOSIXpath to "/Users/me/Documents" –CocoaのPOSIX path表現（フォルダを表現する場合でも、末尾に「/」入らず）
set catDirList to {"3", "2", "1"}
set cPath to getChildPathByAppendingDirsByArray(aPOSIXpath, catDirList) of me
–> "/Users/me/Documents/3/2/1"

on getChildPathByAppendingDirsByArray(aPOSIXpath, catDirList)
　　set pathString to current application’s NSString’s stringWithString:aPOSIXpath
　　set aList to (pathString’s pathComponents()) as list
　　set aList to aList & catDirList
　　
　　set bPath to current application’s NSString’s pathWithComponents:aList
　　return bPath as string
end getChildPathByAppendingDirsByArray

★Click Here to Open This Script　

(Visited 56 times, 1 visits today)

Keynoteの現在の書類と同じ階層に没スライド入れを作成

Posted on 5月 29, 2022 by Takaaki Naganoya

Keynoteの最前面の書類（現在の書類）と同じ階層に没スライドを入れるゴミ箱用のスライドを、編集中の現在のスライドと同じサイズ（Normal/HD）で同じテーマで作成するAppleScriptです。

ふだん、Keynoteで作業をしているときに、不要になったスライド（ページ）を完全削除せず、別書類に移動させて復活させられるようにしているのですが、その作業が煩雑だったのでScriptで自動化したものです。

同階層にゴミ箱用のスライド書類が存在していたら、それをオープンします。存在していなければ、新規作成して指定ファイル名で保存….というところで、v12のバグに遭遇してしまったわけです。

AppleScript名：Keynoteの現在の書類と同じ階層に没スライド入れを作成.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/29
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property newFileName : "没.key" —"trash.key"

tell application "Keynote"
　　tell front document
　　　　set dName to getCurThemeName() of me
　　　　set curFile to (file of it) as alias
　　　　set myHeight to height of it
　　　　set myWidth to width of it
　　end tell
end tell

–書類の親フォルダを取得（POSIX path）
set parentFol to getParentFol(curFile) of me
set newKeynoteFile to parentFol & "/" & newFileName

–ファイルの存在確認
set exRes to chkFileExistence(newKeynoteFile) of me
if exRes = true then
　　–すでに存在している場合はそれをオープン
　　set newKeynoteFileAlias to (POSIX file newKeynoteFile) as alias
　　tell application "Keynote"
　　　　open newKeynoteFileAlias
　　end tell
　　return
else
　　–まだ存在していない場合、最前面の書類と同じテーマ、縦横比（SD、HD）の新規書類を作成する
　　set parentFolAlias to (POSIX file parentFol) as alias as string –POSIX path to HFS path string
　　set saveFilePathStr to (parentFolAlias as string) & newFileName
　　
　　tell application "Keynote"
　　　　set newDoc to make new document with properties {document theme:theme dName, width:myWidth, height:myHeight}
　　　　–save newDoc in file saveFilePathStr as Keynote–Keynote v12のバグに遭遇したため機能オフに
　　end tell
end if

–ファイルの存在確認
on chkFileExistence(aFilePathStr)
　　set fileManager to current application’s NSFileManager’s defaultManager()
　　set aRes to fileManager’s fileExistsAtPath:aFilePathStr
　　return aRes as boolean
end chkFileExistence

on getParentFol(anAlias)
　　set aPath to POSIX path of anAlias
　　set pathString to current application’s NSString’s stringWithString:aPath
　　set newPath to pathString’s stringByDeletingLastPathComponent()
　　return newPath as string
end getParentFol

on getCurThemeName()
　　tell application "Keynote"
　　　　set dCount to count every document
　　　　if dCount = 0 then error "No Document"
　　　　
　　　　tell front document
　　　　　　set aTheme to document theme
　　　　　　set atThemeName to name of aTheme
　　　　end tell
　　end tell
end getCurThemeName

★Click Here to Open This Script　

(Visited 35 times, 1 visits today)

書籍フォルダの階層をさかのぼって、ツメに掲載する最大チャプターを推測 v2

Posted on 3月 4, 2022 by Takaaki Naganoya

電子書籍を作るのにPagesやKeynoteを使っており、「AppleScriptによるWebブラウザ自動操縦ガイド」（以下、Webブラウザガイド）も全ページPagesで作っています。

PagesやKeynoteでは書籍作成用としては機能が素朴すぎて、足りない点はAppleScriptでツールを作って、作業の手間を減らしています。それらの補助Scriptは、各種パラメータをその本に合わせて固定して使用しています。

Webブラウザガイドは全14章で構成されているため、ページの左右につけている「ツメ」（Index）は1から14までの数字が入っています。

今後もツメチェックAppleScript（座標、塗りつぶし色と非選択色の自動判別、ファイル名からの該当章の自動ピックアップ）を他の書籍用にも運用していくつもりですが、この「全14章」という仕様は固定なので、章構成が異なる他の本のプロジェクトでは、自動で章の数をかぞえてくれるとよさそうだと考えました。

だいたい電子書籍のファイルについては、フォルダ分けして２階層ぐらいで管理しているので、その階層数については決め打ちでDoc rootフォルダを計算（parent of parent of….）するようにしました。そして、全フォルダのフォルダ名称を取得。

ダイアログで最終章を選択させると、そこから章番号を自動抽出して（「XX章」と書かれていることが前提）、その番号を返します。

こういう用途を考えると、階層構造をそのまま選択できるNSOutlineViewを選択用の部品に使えると便利で……これまでにもedama2さんと意見交換しつつNSOutlineViewをNSAlertダイアログ上に表示するといった試作も何回か検討してきたのですが、スクリプトエディタ/Script Debugger上で記述するAppleScriptObjCではこの部品を扱うのがとても難しいんですね。

ならば、Xcode上で記述するAppleScriptObjCにAppleScript用語辞書を持たせて、階層ファイル構造を選択させる専用の補助アプリケーションを作ってもいいのかも？　ただ、Xcode 13.x系が壊れて使えないままの環境であるため、いまXcodeでビルドするわけにもいかないのでした。

choose fileコマンドやchoose folderコマンドに「icon view」「list view」「column view」といった初期表示状態を指定できる機能があれば、それで済むような気もしますが、どうせAppleに要望出してもこういうのは通らないので、自分で作ったほうが確実で早いですわー。

にしても、この通常ウィンドウと見分けがつかないファイル選択ダイアログ、macOS 11で最初に見たときには「正気か？！」と、腰を抜かしました。あいかわらず、この決定を下した責任者は●●だと思いますが、せめてもう少し視覚的に見分けがつくようにできなかったもんでしょうか。

AppleScript名：書籍フォルダの階層をさかのぼって、ツメに掲載する最大チャプターを推測 v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/02/26
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Pages"
　　tell front document
　　　　set filePath to (file of it) as alias
　　end tell
end tell

tell application "Finder"
　　set parentFol to (parent of parent of filePath)
　　tell parentFol
　　　　set fNames to name of every folder
　　end tell
end tell

set folName to contents of (choose from list fNames with prompt "書籍のツメに載せる最終章のフォルダを選択")
set cNum to retChapter(folName as string) of me
–> 14

–ファイル名から「章」情報を抽出
on retChapter(aStr)
　　set wList to words of aStr
　　set aCount to 1
　　repeat with ii in wList
　　　　set jj to contents of ii
　　　　if jj = "章" then
　　　　　　return contents of item (aCount – 1) of wList
　　　　end if
　　　　set aCount to aCount + 1
　　end repeat
　　return 0 –Illeagal file name
end retChapter

★Click Here to Open This Script　

(Visited 48 times, 1 visits today)

Pixelmator Proで指定の画像を複数の3D LUTを用いてカラー調整して画像書き出し

Posted on 5月 2, 2021 by Takaaki Naganoya

Pixelmator Pro v2.0.8で追加された3D LUT（Look Up Table）によるカラー調整機能。これを用いて、複数の3D LUTファイルによるカラー調整を行い、それぞれ3D LUTファイルのファイル名を反映させて書き出すAppleScriptです。

3D LUTファイルは、探してみるとあちこちで配布されており、割とありふれた存在のようです。実際にフリー配布されている3D LUTファイルをダウンロードしてきて、１つのフォルダに入れておき、指定画像に対してカラー調整を行わせてみました。

–> [全てフリー！] シネマティックなルックになる10のLUTsを紹介します！！

フォルダに入っている3D LUTファイルをすべてループで処理するので、3D LUTファイル100個でも1,000個でも処理できますし、ちょっと書き換えれば複数の画像に対してそれぞれすべての3D LUTファイルによる色調整を実行するようにもできます。

AppleScript名：指定の画像を複数の3D LUTでカラー調整して画像書き出し.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/02
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSPredicate : a reference to current application’s NSPredicate
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

–処理対象の画像を選択
set anImage to choose file of type {"public.image"} default location (path to pictures folder) with prompt "Select Proc Image"
set imgParent to getParentPathFromAlias(anImage) of me

–3D LUTファイルを入れてあるフォルダを選択
set lutFolder to choose folder with prompt "Select 3D LUT folder"

–Filter 3D LUT (.cube) files only
tell application "Finder"
　　set fList to (every file of folder lutFolder) as alias list
end tell

set lutList to getFilesWithUTI("com.blackmagicdesign.cube", fList) of me

–指定の画像ファイルをオープン
tell application "Pixelmator Pro"
　　close every document saving no
　　open anImage
end tell

–Main Loop
repeat with i in lutList
　　set aLut to contents of i
　　
　　–ファイルパスの加工処理
　　set newImgName to ((current application’s NSString’s stringWithString:(POSIX path of aLut))’s lastPathComponent()’s stringByDeletingPathExtension()’s stringByAppendingString:".jpg") as string
　　set newImgFullPath to (imgParent as string) & "/" & newImgName
　　set newImgFile to POSIX file newImgFullPath
　　
　　tell application "Pixelmator Pro"
　　　　activate
　　　　tell front document
　　　　　　tell color adjustments of first layer –ここだけ、ネスティングを分割するとエラーになる
　　　　　　　　set its custom lut to aLut
　　　　　　end tell
　　　　　　
　　　　　　export to newImgFullPath as JPEG with properties {compression factor:0.5, bits per channel:8}
　　　　　　undo
　　　　end tell
　　end tell
end repeat

–後片付け
tell application "Pixelmator Pro"
　　tell front document
　　　　close without saving
　　end tell
end tell

on getParentPathFromAlias(aliasPath)
　　set aPath to POSIX path of aliasPath
　　set pathString to current application’s NSString’s stringWithString:aPath
　　set newPath to pathString’s stringByDeletingLastPathComponent()
　　return newPath
end getParentPathFromAlias

on getFilesWithUTI(acceptUTI, aliasList)
　　set aList to {}
　　
　　repeat with i in aliasList
　　　　set anAlias to i as alias
　　　　set aUTI to getUTIfromPath(anAlias) of me
　　　　if aUTI is not equal to missing value then
　　　　　　set uRes to filterUTIList({aUTI}, acceptUTI) of me
　　　　　　
　　　　　　if uRes is not equal to {} then
　　　　　　　　set the end of aList to contents of i
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return aList
end getFilesWithUTI

–AliasからUTIを求める
on getUTIfromPath(anAlias)
　　set aPOSIXpath to POSIX path of anAlias
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aPOSIXpath
　　if aURL = missing value then return missing value
　　set aRes to aURL’s resourceValuesForKeys:{current application’s NSURLTypeIdentifierKey} |error|:(missing value)
　　if aRes = missing value then return missing value
　　return (aRes’s NSURLTypeIdentifierKey) as string
end getUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　

(Visited 126 times, 1 visits today)

画面スナップショット超解像バッチ処理 v1

Posted on 3月 25, 2021 by Takaaki Naganoya

Pixelmator Proの機能「ML Super Resolution」をAppleScriptから呼び出して、指定フォルダ内の画像をすべて超解像処理を行って、機械学習モデルをもとに解像度２倍化を行った画像を別フォルダに書き出すAppleScriptです。

超解像処理を行う対象は、別に画面のスナップショット画像でなくてもよいのですが、効果がわかりやすい用途です。

Keynoteに画面スナップショット画像を貼り付けていたときに、拡大倍率が上がると解像度が足りずに荒くなってしまいました。Retina環境で画面のスナップショットを取ると、けっこう綺麗に拡大できるのですが、等倍表示しかできない（＆画面表示解像度を落とすことで2x Retina解像度で画面キャプチャ可能）環境なので、ちょっと困りました。

▲macOS 11.0、見た目の悪さで使う気が失せるはじめてのmacOS。12.0ではもう少しなんとかしてほしい。とくに、このダイアログ。ダイアログと見分けのつかないウィンドウ。ファイル保存ダイアログとかも

そこで、Pixelmator Proで画像のML Super Resolution機能（超解像機能）を用いてソフトウェアの力で画面スナップショット画像を高解像度化してみました。これが予想を超えていい感じだったので、指定フォルダ以下の画像をすべて処理するようにAppleScriptで処理してみました。

–> Download pixelmatorMLSuperResol（Script Bundle with libraries）

ML Super Resolution処理は自分の使っているIntel Mac（MacBook Pro 10,1）には荷の重い処理でささいな画像でも数秒かかりますが、おそらくApple Silicon搭載Macだと瞬殺でしょう。Core MLの処理が段違いに速いので。

▲オリジナル画像（左）、超解像処理を行なった画像（右）

▲オリジナル画像と超解像処理を行なった画像のファイルサイズの違い

本リストは実際にAppleScriptで開発を行う際に記述するコード量そのものを示したものです。本リストには２つのライブラリを利用していますが、ふだんはプログラムリストの再現性（実行できること）を優先して、ライブラリ部分もScript本体に一緒に展開しています。使い回ししている分も同じリストに展開しているので、「たくさん書かないといけない」と思われているようです。

実際には、共通部分はほとんど書いていないので、本処理もこんな（↓）ぐらいの記述量です。リアルな記述量を感じられるような掲載の仕方を考えなくてはいけないのかもしれません。本リストはその試みの第一歩です。

まー、超解像処理を行って72dpiの画面スナップショット画像を144dpiに上げているだけなんで、Retina Display環境で処理すれば不要なんですが、ソフトウェアだけで実現できるのはロマンを感じますし、無駄に2x Retina環境のスクリーンショットを処理して288dpiの高解像度画像に上げてみるとか。

ただ、WWDCのビデオなどを見ていると、画面のスナップショットそのものをベクターグラフィックで取るような仕組みも考えていそうな気配がします。当てずっぽうですが、そういう何かを考えていそうな….

AppleScript名：画面スナップショット超解像バッチ処理 v1

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/03/25
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use cPathLib : script "choosePathLib"
use imgPicker : script "imgPickerLib"

–掃除
tell application "Pixelmator Pro" to close every document without saving

–必要なパス情報をユーザーに問い合わせる
set {inFol, outFol} to choose multiple path with titles {"Img Folder", "Output Folder"}
set outFolStr to outFol as string

–画像フォルダから画像のパス一覧を取得
set f1List to getFilepathListByUTI(POSIX path of inFol, "public.image", "alias") of imgPicker

–取得した画像を超解像処理して
repeat with i in f1List
　　tell application "Pixelmator Pro"
　　　　open i
　　　　tell front document
　　　　　　with timeout of 3000 seconds
　　　　　　　　super resolution
　　　　　　end timeout
　　　　end tell
　　end tell
　　
　　–新規保存ファイルパスの作成
　　set pathStr to POSIX path of i
　　set filenameStr to (current application’s NSString’s stringWithString:(pathStr))’s lastPathComponent() as string
　　set savePath to outFolStr & filenameStr
　　
　　tell application "Pixelmator Pro"
　　　　save front document in file savePath as PNG
　　　　
　　　　tell front document
　　　　　　close without saving
　　　　end tell
　　end tell
end repeat

★Click Here to Open This Script　

(Visited 227 times, 1 visits today)

部首で漢字検索

Posted on 2月 21, 2021 by Takaaki Naganoya

漢字の部首を指定して、漢字を検索するAppleScriptです。厳密にいえば「部首」の文字ではなく、それっぽい文字で探せます。用途や利用者を想定できれば（子供が勉強用に使わないのであれば）十分に有用だと思います（理由は後述）。

Unicodeのデータから検索できるのではないかと考え、Unicodeの規格を調べていたのですが、漢字のSVGデータから構成文字情報を抽出したとされる「kanjivg-radical」を偶然みつけ、これを利用することで、割と手軽に実現できました。

–> kanjiSearch.zip(Download Script Bundle included JSON in its bundle)

開発環境のMac（Intel Core i7 2.66GHz）で、キャッシュがヒットしていれば（JSONから変換したデータがpropertyに読み込まれていれば）0.02秒程度で検索できています。この手の処理はデータのローディング（読み込み）が命なので、SSD使用必須です。

同データはJSON形式なので、AppleScriptバンドル中にJSONのまま突っ込んで、Cocoaの機能を用いてNSDictionaryに読み込んで検索しています。

ほかにも、Mac OS Xへの移行時に散々紹介されたMac OS Xのビックリドッキリ機能「関連文字に変換」をAppleScriptで実現した「関連文字を検索」も作ってみました。

このあたりをまとめてAppleScriptライブラリにしておけば便利そうですが、まだ使い勝手をテストしている段階です。義務教育で習う漢字の構成要素（へん、つくり etc）の呼び名とkanjivg-radicalで利用できる構成パーツの間に不整合（kanjivg-radicalの方が柔軟）があるので、そのあたりを埋めないと使いにくそう（下手に子供が使うと間違った国語知識を持ってしまう）な危険があるので、そのあたりを補う必要性を感じます。

たとえば、「禾」（のぎへん）を持つ漢字を「木」で検索できてしまうところです。大人は「実用的で使いやすい！」と喜ぶところですが、義務教育課程では両者は厳密に区別されています。自分は使いやすいので喜んで使っていますが、用途によっては使わないほうがよいかもしれません。

追記：

へんやつくりを元に検索できるデータとして、同梱の「radical2kanji_left_right.json」や「radical2kanji_top_bottom.json」が存在していることに気づいたので、そちらをAppleScriptのバンドル中に入れて、同様に検索してみました。

ただ、こちらのデータは随分と粗が多く、「⻖」（こざとへん）で自分の名前に使われている「隆」を「radical2kanji_left_right.json」から検索したところヒットしません。

{"阨", "陵", "隈", "険", "陣", "院", "陲", "陦", "陽", "陳", "陬", "隧", "險", "除", "隍", "陜", "陀", "陏", "隗", "階", "障", "隕", "降", "陂", "隴", "隔", "際", "隅", "附", "限", "陸", "陟", "陌", "阮", "阡", "阯", "阻", "阿", "阪", "防"}

国語辞書や文字コード表との照合といいますか、きちんとした検証作業は行われておらず、機械的に処理しただけのデータという印象を受けます。

一方で、「element2kanji.json」を用いて「⻖」（こざとへん）で検索したところ、

{"嶐", "阨", "蔭", "橢", "薩", "隣", "婀", "陵", "隈", "窿", "険", "隠", "陷", "陣", "痾", "院", "陶", "隙", "陲", "陦", "陽", "陪", "陳", "隘", "陥", "陬", "墜", "隧", "陰", "險", "除", "隍", "陜", "陀", "陛", "陏", "隗", "階", "障", "隕", "降", "陂", "隨", "隴", "隔", "随", "際", "隋", "陞", "隰", "墮", "隱", "陝", "隅", "隊", "附", "限", "陋", "陸", "陟", "隲", "陌", "隆", "阮", "阡", "阯", "阻", "阿", "阪", "堕", "防"}

と、結果が返ってきており……どうも複数のJSONデータを用いて、へんやつくりを考慮したJSONデータで検索して、ヒットしなかったら「element2kanji.json」を用いて物量でダメ押しするように設計されているようです。つまり、「radical2kanji_left_right.json」や「radical2kanji_top_bottom.json」が粗いのを複数のデータで補うように使うものである、と。

無限の量とバリエーションを持つデータに対するアプローチとしては間違っていないと思いますが、文字コードという有限のデータに対しての処理としては少し疑問が残る実装です。本当に使い物になるデータにするには、実際に人間の手による検証と校正が必要な内容でしょう。そのことは明記されるべきです。

「element2kanji.json」は現状のままで有用だと思いますが、「radical2kanji_left_right.json」や「radical2kanji_top_bottom.json」については、実際に国語辞典と照合してデータを補わないと実用レベルにはならないと感じました。盲目的に信用しないで、手元で実際に評価・検証することが重要です。

データ自体、CJK（中国語、日本語、韓国語）の統合漢字をサポートする範囲で作成されているようで、日本語で日常的に利用する常用漢字よりも幅広い文字がデータ化されています。常用漢字の範囲内に含まれているかをチェックするデータを併用するのが妥当でしょう。

AppleScript名：部首で漢字検索.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/21
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7"
use framework "Foundation"
use scripting additions

script jsonStr
　　property aJsonDict : missing value
end script

property NSString : a reference to current application’s NSString
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

–部首を指定して漢字検索
set aRes to searchKanjiFromElement("木") of me –きへん
–> {"稾", "欅", "謀", "酥", "悚", "椁", "検"….}

–set bRes to searchKanjiFromElement("氵") of me–さんずい
–> {"溯", "湮", "漁", "漕", "濶", "懣", "添", "淨",…..}

–set cRes to searchKanjiFromElement("之") of me
–> {"芝", "泛", "貶", "乏"}

–set dRes to searchKanjiFromElement("⻖") of me
–> {"嶐", "阨", "蔭", "橢", "薩", "隣", "婀"…}

–検索に使える部首のキー文字の一覧を返す
–set qList to listupQueryKeysForKanji() of me
–> {"工", "棘", "左", "位", "婁", "攴", "巨", "攵"…}

on searchKanjiFromElement(aQueryStr)
　　if (aJsonDict of jsonStr) = missing value then my init()
　　set aRes to (aJsonDict of jsonStr)’s valueForKey:aQueryStr
　　if aRes = missing value then return missing value
　　return aRes as list
end searchKanjiFromElement

on listupQueryKeysForKanji()
　　if (aJsonDict of jsonStr) = missing value then my init()
　　set aRes to (aJsonDict of jsonStr)’s allKeys()
　　return aRes as list
end listupQueryKeysForKanji

on init()
　　–https://github.com/yagays/kanjivg-radical
　　set aPath to (POSIX path of (path to me)) & "Contents/Resources/element2kanji.json"
　　set jsonString to NSString’s alloc()’s initWithContentsOfFile:(aPath) encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set (aJsonDict of jsonStr) to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
end init

★Click Here to Open This Script　

(Visited 141 times, 1 visits today)

アプリケーションが扱えるデータ拡張子を取得

Posted on 10月 28, 2020 by Takaaki Naganoya

指定のアプリケーションが扱えるデータ拡張子を取得するAppleScriptです。

アプリケーションバンドル内のInfo.plistの、CFBundleDocumentTypesエントリの中のCFBundleTypeExtensionsを拾ってリストで返します。用途は、このアプリケーションに表示させるためのものです。

ただ、この標準的といいますか一般的な処理でこのデータを拾ってこれないアプリケーション（凝った処理をしているもよう）がかなりの数存在し、それらについては個別に対応処理を書かないとダメっぽいです。

だいたい、AppleのiWork Appsが全滅。BBEditも独自の記述をしているらしく、Pixelmator Proも少し凝った書き方をしているもよう（Pixelmator Proが「凝っていない」部分なんてないみたいですが）。個別にInfo.plistからエントリをたどって拡張子リストを作るしかなさそうです。

OS内、具体的に言えばNSApplicationとかNSBundleにそういうInfo.plistをあさってこなくても対応ドキュメントデータ型を渡してくれるようなサービスがありそうな気がとてもするのですが、なかなか見つかりそうにありません。

あまりに対応が大変だった場合には、機能を盛り込むことを断念するかもしれません。メタデータから拾ってこれたりすると楽でよいのですが……。

▲結局、できた模様

AppleScript名：アプリケーションが扱えるデータ拡張子を取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/10/28
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aPath to POSIX path of (choose file of type {"com.apple.application-bundle"})
set aURL to (current application’s |NSURL|’s fileURLWithPath:aPath)
set exResList to getDocumentTypesExtensionsFromPath(aURL) of me

return exResList
–> {".INDD", ".INX", ".IDMS", ".INCD", ".INCX", ".ICML", ".INCA", ".ICMA", ".P65", ".T65", ".PMD", ".PMT", ".QXD", ".QXT", ".INDT", ".INDB", ".INDL", ".INLX", ".FLST", ".PRST", ".PDFS", ".joboptions", ".DCST", ".LNST", ".UDC", ".InDesignPlugin", ".PSET", ".SMRD", ".SMWT", ".IDML", ".IDPP", ".INDK", ".INLK", ".CSF", ".ASE", ".ACB", ".ACBL", ".IDPK", ".INJB", ".INRS", ".INCP", ".INDP", ".ICAP", ".IDAP", ".INMS", ".epub"}

on getDocumentTypesExtensionsFromPath(aURL)
　　set aRes to getDocumentTypesFromAppURL(aURL) of me
　　
　　set exRes to {}
　　repeat with i in (aRes as list)
　　　　set j to (current application’s NSDictionary’s dictionaryWithDictionary:(contents of i))
　　　　set tmpExt to (j’s valueForKey:"CFBundleTypeExtensions")
　　　　
　　　　if tmpExt is not equal to missing value then
　　　　　　set tmpExt to tmpExt as list
　　　　　　repeat with ii in tmpExt
　　　　　　　　set jj to "." & (contents of ii)
　　　　　　　　if (jj is not in exRes) and (jj is not equal to ".*") and (jj is not equal to ".???") then
　　　　　　　　　　set the end of exRes to jj
　　　　　　　　end if
　　　　　　end repeat
　　　　end if
　　end repeat
　　
　　return exRes
end getDocumentTypesExtensionsFromPath

on getDocumentTypesFromAppURL(aURL)
　　set aBundle to current application’s NSBundle’s bundleWithURL:aURL
　　if aBundle = missing value then return {}
　　set aInfo to aBundle’s infoDictionary()
　　if aInfo = missing value then return {}
　　set aRes to aInfo’s objectForKey:"CFBundleDocumentTypes" –Document Types
　　if aRes = missing value then return {}
　　return aRes
end getDocumentTypesFromAppURL

★Click Here to Open This Script　

(Visited 55 times, 1 visits today)

アラートダイアログ上にCollection Viewを表示

Posted on 8月 24, 2020 by Takaaki Naganoya

emada2さんからの投稿です。Collection Viewの利用については、Kamenokoの開発時に導入検討したことがありますが、Objective-CのサンプルコードをAppleScriptに翻訳しきれなくて中途半端に放置していました。

まとまった形でCollection Viewのサンプルコードが出てきたのは、おそらくこれが初めてだと思います。ありがとうございます。

Collection Viewを箱庭ダイアログに乗せることができました。
でも残念なのは、itemPrototypeは10.14でDeprecatedになっているので将来的に長く使えないでしょう
その他のやり方を探してappleのサンプルコードをみたら、swift 3で書かれていているので10.14でビルドできませんでした。
なのでまだまだCollection Viewを使いこなすのは難しそうです😢

–> Download Script Bundle

@property (nullable, strong) NSCollectionViewItem *itemPrototype API_DEPRECATED("Use -registerNib:forItemWithIdentifier: or -registerClass:forItemWithIdentifier: instead.", macos(10.5,10.14));

AppleScript名：アラートダイアログ上にCollection Viewを表示

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "AppKit"
use framework "AppleScriptObjC"
use framework "CoreFoundation"
use framework "Foundation"
use scripting additions

on run
　　my testRun()
end run

on testRun()
　　set aMainMes to "アプリケーションの選択"
　　set aSubMes to "適切なものを以下からえらんでください"
　　
　　#ダイアログ内のビューサイズを指定
　　set aHeight to 384
　　set aWidth to 512 + 12 –> スクロールバーの分
　　
　　#アプリケーションフォルダ内のアプリケーションを取得
　　set aFolder to path to applications folder
　　set aPath to aFolder’s POSIX path
　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　
　　set filePaths to filePaths as list
　　set thisFileType to "com.apple.application-bundle"
　　
　　set dataSourceList to {}
　　repeat with anItem in filePaths
　　　　
　　　　set aPath to anItem’s contents’s POSIX path
　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　
　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　
　　　　if (aUTI as text) is thisFileType then
　　　　　　set iconImage to (current application’s NSWorkspace’s sharedWorkspace’s iconForFile:aPath)
　　　　　　set dict to {fileURL:aURL, icon:iconImage}
　　　　　　set dataSourceList’s end to dict
　　　　end if
　　end repeat
　　
　　set execButtonTitle to "OK😄"
　　
　　set dateObj to my chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
end testRun

on chooseItemByCollectionView:(aMainMes as text) subMes:(aSubMes as text) myWidth:(aWidth as integer) myHeight:(aHeight as integer) myDataSource:(dataSourceList as list) okTitle:(execButtonTitle as text)
　　
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　# subClasses.scptを呼び出す
　　set DialogCore to current application’s AppDelegate’s new()
　　set fRes to DialogCore’s chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
　　
　　if fRes is missing value then error number -128
　　return fRes as list
end chooseItemByCollectionView:subMes:myWidth:myHeight:myDataSource:okTitle:

★Click Here to Open This Script　

AppleScript名：subClasses

script AppDelegate
　　property parent : class "NSObject"
　　
　　— IBOutlets
　　property theWindow : missing value
　　
　　on applicationShouldTerminate:sender
　　　　return current application’s NSTerminateNow
　　end applicationShouldTerminate:
　　
　　on applicationShouldTerminateAfterLastWindowClosed:sender
　　　　return true
　　end applicationShouldTerminateAfterLastWindowClosed:
　　
　　——————
　　
　　on applicationWillFinishLaunching:aNotification
　　　　log my testRun()
　　end applicationWillFinishLaunching:
　　
　　on testRun()
　　　　set aMainMes to "アプリケーションの選択"
　　　　set aSubMes to "適切なものを以下からえらんでください"
　　　　
　　　　#ダイアログ内のビューサイズを指定
　　　　set aHeight to 384
　　　　set aWidth to 512 + 12 –> スクロールバーの分
　　　　
　　　　#アプリケーションフォルダ内のアプリケーションを取得
　　　　set aFolder to path to applications folder
　　　　set aPath to aFolder’s POSIX path
　　　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　　　
　　　　# 指定フォルダの直下のファイルを取得
　　　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　　　|error|:(missing value)
　　　　
　　　　set filePaths to filePaths as list
　　　　set thisFileType to "com.apple.application-bundle"
　　　　
　　　　set dataSourceList to {}
　　　　repeat with anItem in filePaths
　　　　　　
　　　　　　set aPath to anItem’s contents’s POSIX path
　　　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　　　
　　　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　　　|error|:(reference))
　　　　　　
　　　　　　if (aUTI as text) is thisFileType then
　　　　　　　　set iconImage to (current application’s NSWorkspace’s sharedWorkspace’s iconForFile:aPath)
　　　　　　　　set dict to {fileURL:aURL, icon:iconImage}
　　　　　　　　set dataSourceList’s end to dict
　　　　　　end if
　　　　end repeat
　　　　
　　　　set execButtonTitle to "OK😄"
　　　　
　　　　set dateObj to my chooseItemByCollectionView:aMainMes subMes:aSubMes myWidth:aWidth myHeight:aHeight myDataSource:dataSourceList okTitle:execButtonTitle
　　end testRun
　　
　　# アラートダイアログでCollectionViewを表示
　　property _retrieve_data : missing value
　　on chooseItemByCollectionView:(aMainMes as text) subMes:(aSubMes as text) myWidth:(aWidth as integer) myHeight:(aHeight as integer) myDataSource:(dataSourceList as list) okTitle:(execButtonTitle as text)
　　　　
　　　　set paramObj to {myMessage:aMainMes}
　　　　set paramObj to paramObj & {mySubMessage:aSubMes}
　　　　set paramObj to paramObj & {myDataSource:dataSourceList}
　　　　set paramObj to paramObj & {myWidth:aWidth}
　　　　set paramObj to paramObj & {myHeight:aHeight}
　　　　set paramObj to paramObj & {myOKTitile:execButtonTitle}
　　　　
　　　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　　　
　　　　if (my _retrieve_data) is missing value then error number -128
　　　　return (my _retrieve_data)
　　end chooseItemByCollectionView:subMes:myWidth:myHeight:myDataSource:okTitle:
　　
　　## retrieve date
　　on raizeAlert:paramObj
　　　　
　　　　set mesText to paramObj’s myMessage as text
　　　　set infoText to paramObj’s mySubMessage as text
　　　　set dataSourceList to paramObj’s myDataSource as list
　　　　set viewWidth to paramObj’s myWidth as integer
　　　　set viewHeight to paramObj’s myHeight as integer
　　　　set okButton to paramObj’s myOKTitile as text
　　　　
　　　　# set up view
　　　　set {thisView, collectionView} to my makeContentView(dataSourceList, viewWidth, viewHeight)
　　　　
　　　　### set up alert
　　　　tell current application’s NSAlert’s new()
　　　　　　addButtonWithTitle_(okButton)
　　　　　　addButtonWithTitle_("Cancel")
　　　　　　setAccessoryView_(thisView)
　　　　　　–setIcon_(aImage)
　　　　　　setInformativeText_(infoText)
　　　　　　setMessageText_(mesText)
　　　　　　tell |window|()
　　　　　　　　setInitialFirstResponder_(thisView)
　　　　　　end tell
　　　　　　#### show alert in modal loop
　　　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　　　end tell
　　　　
　　　　### retrieve data
　　　　set aIndexSet to collectionView’s selectionIndexes()
　　　　set theArray to current application’s NSArrayController’s alloc()’s initWithContent:(collectionView’s content())
　　　　set chooseItems to ((theArray)’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　　　
　　　　# reset
　　　　set _retrieve_data to {}
　　　　
　　　　repeat with anItem in chooseItems
　　　　　　set (my _retrieve_data)’s end to anItem’s contents
　　　　end repeat
　　　　
　　　　return my _retrieve_data
　　end raizeAlert:
　　
　　# set up view
　　on makeContentView(dataSourceList, viewWidth, viewHeight)
　　　　
　　　　set thisRect to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　　　
　　　　tell current application’s NSCollectionView’s alloc
　　　　　　tell initWithFrame_(thisRect)
　　　　　　　　setItemPrototype_(current application’s YKZCollectionViewItem’s new())
　　　　　　　　
　　　　　　　　setAllowsEmptySelection_(true)
　　　　　　　　setAllowsMultipleSelection_(true)
　　　　　　　　setContent_(dataSourceList)
　　　　　　　　setSelectable_(true)
　　　　　　　　
　　　　　　　　set collectionView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　# Viewを作成
　　　　tell current application’s NSScrollView’s alloc()
　　　　　　tell initWithFrame_(thisRect)
　　　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　　　setDocumentView_(collectionView)
　　　　　　　　setHasHorizontalScroller_(true)
　　　　　　　　setHasVerticalScroller_(true)
　　　　　　　　set baseView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return {baseView, collectionView}
　　end makeContentView
end script

#MARK: –
script YKZView
　　property parent : class "NSView"
　　
　　property imageView : missing value
　　
　　property selected : false
　　property viewItemHeight : 128
　　property viewItemWidth : 128
　　
　　on initWithFrame:rect
　　　　
　　　　set myRect to current application’s NSMakeRect(0, 0, viewItemWidth, viewItemHeight)
　　　　continue initWithFrame:myRect
　　　　
　　　　set aHeight to viewItemHeight – 10
　　　　set aWidth to viewItemWidth – 10
　　　　set newRect to current application’s NSMakeRect(5, 5, aWidth, aHeight)
　　　　
　　　　tell current application’s NSImageView’s alloc()
　　　　　　tell initWithFrame_(newRect)
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　set my imageView to it
　　　　　　end tell
　　　　end tell
　　　　
　　　　my addSubview:(my imageView)
　　　　return me
　　end initWithFrame:
　　
　　on drawRect:rect
　　　　if my selected then
　　　　　　current application’s NSColor’s redColor()’s |set|()
　　　　else
　　　　　　current application’s NSColor’s controlBackgroundColor()’s |set|()
　　　　end if
　　　　current application’s NSRectFill(rect)
　　　　continue drawRect:rect
　　end drawRect:
end script

#MARK: –
script YKZCollectionViewItem
　　property parent : class "NSCollectionViewItem"
　　
　　on loadView()
　　　　my setView:(current application’s YKZView’s alloc()’s initWithFrame:(current application’s NSZeroRect))
　　end loadView
　　
　　on setRepresentedObject:representedObject
　　　　–continue setRepresentedObject:representedObject
　　　　if representedObject is missing value then return
　　　　(my view())’s imageView’s setImage:(representedObject’s icon)
　　end setRepresentedObject:
　　
　　on setSelected:isSelected
　　　　set (my view())’s selected to isSelected
　　　　(my view())’s setNeedsDisplay:true
　　　　continue setSelected:isSelected
　　end setSelected:
end script

★Click Here to Open This Script　

(Visited 92 times, 1 visits today)

指定アプリケーションのバイナリアーキテクチャ判定 v3

Posted on 8月 18, 2020 by Takaaki Naganoya

指定のアプリケーションファイルが32bitバイナリかどうかを判定するAppleScriptの改訂版です。

本Scriptシリーズは対象のアプリケーションが起動している状態で対象CPUアーキテクチャを判定するものではなく、起動していない状態で判定するものです。

PPC 32 / PPC 64 / Intel 32 / Intel 64 / ARM 64の各アーキテクチャの判定を行います。FAT Binaryの場合には複数のアーキテクチャが返ってきます。

▲本Scriptの応用例

AppleScript名：指定アプリケーションのバイナリアーキテクチャ判定 v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/08/18
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set anApp to choose file of type {"com.apple.application-bundle"} default location (path to applications folder)
–set anApp to choose file default location (path to applications folder)
set app32 to chk32Binary(anApp) of me
–> {"PPC 32", "Intel x32"}

on chk32Binary(anAlias)
　　set aPOSIX to POSIX path of anAlias
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(aPOSIX)
　　set aBundle to current application’s NSBundle’s bundleWithURL:aURL
　　
　　set F1 to (aBundle = missing value) as boolean
　　if F1 is not equal to false then return calcIllegular(aPOSIX) of me
　　
　　set aDict to aBundle’s executableArchitectures()
　　set F2 to (aDict = missing value) as boolean
　　if F2 is equal to true then return calcIllegular(aPOSIX) of me
　　
　　set aList to (aDict’s valueForKeyPath:"stringValue") as list
　　
　　set arList to {}
　　repeat with i in aList
　　　　set j to contents of i
　　　　
　　　　if j = "7" then –NSBundleExecutableArchitectureI386
　　　　　　set the end of arList to "Intel 32"
　　　　else if j = "18" then –NSBundleExecutableArchitecturePPC
　　　　　　set the end of arList to "PPC 32"
　　　　else if j = "16777223" then –NSBundleExecutableArchitectureX86_64
　　　　　　set the end of arList to "Intel 64"
　　　　else if j = "16777234" then –NSBundleExecutableArchitecturePPC64
　　　　　　set the end of arList to "PPC 64"
　　　　else if j = "16777228" then –NSBundleExecutableArchitectureARM64
　　　　　　set the end of arList to "ARM 64"
　　　　end if
　　end repeat
　　
　　return arList
end chk32Binary

on calcIllegular(aPOSIX)
　　–Old Style Bundle for PPC
　　set sRes to do shell script "file " & quoted form of aPOSIX
　　if sRes contains "Mach-O executable ppc" then return {"PPC 32"} –NSBundleExecutableArchitecturePPC
　　return missing value
end calcIllegular

★Click Here to Open This Script　

(Visited 65 times, 1 visits today)

指定アプリケーションのバイナリアーキテクチャ判定

Posted on 8月 18, 2020 by Takaaki Naganoya

指定のアプリケーションファイルが32bitバイナリかどうかを判定するAppleScriptです。

実行ファイルのパスを求めて、fileコマンドで情報を取得します。本Scriptでは32bitバイナリであるかどうかの判定のみ行なっていますが、CPUアーキテクチャに着目してPPC/Intel 32/Intel 64/ARMの判定を行えるように作り込めます。

また、アプリケーションでありながらもバンドル形式になっていない実行ファイル（古い時代のファイルだったり、サードパーティの開発環境だったり）も存在しているため、NSBundleを求めたときにmissing valueが返ってくることもあります。

１ファイルだけ処理できてもあまり意味がないので、指定フォルダ以下のすべてのアプリケーションファイルをリストアップして、ループで処理するようなことをやることになるでしょう。

--PPC 32bit
/Applications/okaeri_up/v2.0b/Okaeri.app/Contents/MacOS/Okaeri: Mach-O executable ppc

--PPC/Intel 32bit FAT Binary
/Applications/Adobe Illustrator CS3/Adobe Illustrator.app//Contents/MacOS/Adobe Illustrator: Mach-O universal binary with 2 architectures: [i386:Mach-O executable i386] [ppc]
/Applications/Adobe Illustrator CS3/Adobe Illustrator.app//Contents/MacOS/Adobe Illustrator (for architecture i386):	Mach-O executable i386
/Applications/Adobe Illustrator CS3/Adobe Illustrator.app//Contents/MacOS/Adobe Illustrator (for architecture ppc):	Mach-O executable ppc

--Intel 32
/Applications/Adobe Illustrator CS5/Adobe Illustrator.app//Contents/MacOS/Adobe Illustrator: Mach-O executable i386

--Intel 32/64bit FAT Binary
/Applications/System Preferences.app//Contents/MacOS/System Preferences: Mach-O universal binary with 2 architectures: [x86_64:Mach-O 64-bit executable x86_64] [i386:Mach-O executable i386]
/Applications/System Preferences.app//Contents/MacOS/System Preferences (for architecture x86_64):	Mach-O 64-bit executable x86_64
/Applications/System Preferences.app//Contents/MacOS/System Preferences (for architecture i386):	Mach-O executable i386

--Intel 64
/Applications/Adobe Illustrator 2020/Adobe Illustrator.app//Contents/MacOS/Adobe Illustrator: Mach-O 64-bit executable x86_64

--Intel/PPC 64bit FAT Binary
/Applications/Geekbench 2.1/Geekbench (64-bit).app/Contents/MacOS/Geekbench: Mach-O universal binary with 2 architectures: [x86_64:Mach-O 64-bit executable x86_64] [ppc64]
/Applications/Geekbench 2.1/Geekbench (64-bit).app/Contents/MacOS/Geekbench (for architecture x86_64):	Mach-O 64-bit executable x86_64
/Applications/Geekbench 2.1/Geekbench (64-bit).app/Contents/MacOS/Geekbench (for architecture ppc64):	Mach-O executable ppc64

--Intel 64/ARM 64 FAT Binary
/System/Applications/Utilities/Script Editor.app/Contents/MacOS/Script Editor: Mach-O universal binary with 2 architectures: [x86_64:Mach-O 64-bit executable x86_64] [arm64e:Mach-O 64-bit executable arm64e]
/System/Applications/Utilities/Script Editor.app/Contents/MacOS/Script Editor (for architecture x86_64):	Mach-O 64-bit executable x86_64
/System/Applications/Utilities/Script Editor.app/Contents/MacOS/Script Editor (for architecture arm64e):	Mach-O 64-bit executable arm64e

AppleScript名：指定アプリケーションのバイナリアーキテクチャ判定.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/08/18
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version “2.4” — Yosemite (10.10) or later
use framework “Foundation”
use scripting additions

set anApp to choose file of type {“com.apple.application-bundle”} default location (path to applications folder)

set app32 to chk32Binary(anApp) of me
–> true –32bit
–> false –64bit

on chk32Binary(anApp)
　　set aExec to getAppPropertyFromInfoPlist(anApp, “CFBundleExecutable”) of me
set posixPath to (POSIX path of anApp) & “/Contents/MacOS/” & aExec

　　set aRes to do shell script “file “ & quoted form of posixPath
log aRes
if aRes contains “Mach-O executable i386” then
　　　　return true –32bit
　　else
　　　　return false –64bit
　　end if
end chk32Binary

on getAppPropertyFromInfoPlist(anAlias, aKey as string)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
set aBundle to current application’s NSBundle’s bundleWithURL:aURL
set aDict to aBundle’s infoDictionary()
set vRes to (aDict’s valueForKey:aKey) as string
return vRes as string
end getAppPropertyFromInfoPlist

★Click Here to Open This Script　

(Visited 164 times, 1 visits today)

ファイル保存ダイアログ（SavePanel）表示

Posted on 4月 22, 2020 by Takaaki Naganoya

Mac App StoreアプリケーションをAppleScriptで作ったときに、ファイル保存ダイアログを実装するのにchoose file nameコマンドでは拡張子の処理に問題があります（ユーザーが拡張子まで入力しなかった場合への対処を行うと逆効果に）。

choose file nameコマンド
ユーザーが選択、入力したパス：Macintosh HD:Users:me:Desktop:aaaaa

Script側で拡張子を補足：Macintosh HD:Users:me:Desktop:aaaaa.kame
--> エラー（Sandbox制限による）

その回避策としてありものを引っ張り出してきて手直ししたNSSavePanelベースのファイル保存ダイアログ表示サブルーチンです。

▲choose file nameコマンドで表示したファイル名入力ダイアログ。ダイアログ上でタグの選択はできるがchoose file nameにはタグ受信のための機能がない。また、拡張子が入力されていなかったらそのまま

▲本Scriptで表示したNSSavePanelによる保存ファイル名入力ダイアログ。タグの選択、指定した拡張子の指定などが行える。ユーザーが拡張子を入力していなくても自動で補える

choose file nameによるダイアログも、NSSavePanelによるダイアログも、見た目は同じで見分けはつきません。

普通にAppleScriptを書いて自分で実行している分にはchoose file nameコマンドでも問題はありません。

AppleScript名：ファイル保存ダイアログ（SavePanel）表示

— Original by Shane Stanley
— Modified 2020-04-22 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property savePath : ""
property saveTag : {}

set savePath to ""
set saveTag to {}

set aParam to {extList:{"kame"}, saveMsg:"新規ファイルの名前と場所を指定", saveName:"Some name", initialDir:(POSIX path of (path to documents folder))}
my performSelectorOnMainThread:"showModalSave:" withObject:(aParam) waitUntilDone:true
return {savePath:savePath as string, saveTags:saveTag as list}
–> {savePath:"/Users/me/Desktop/Some name.kame", saveTags:{"ブルー", "ヤンキー"}}

on showModalSave:sender
　　set tmpExt to extList of sender as list
　　set tmpMsg to saveMsg of sender as string
　　set defName to saveName of sender as string
　　set tmpInit to initialDir of sender as string
　　
　　using terms from scripting additions
　　　　set startURL to current application’s NSURL’s fileURLWithPath:(tmpInit)
　　end using terms from
　　
　　set thePanel to current application’s NSSavePanel’s savePanel()
　　tell thePanel
　　　　its setMessage:(tmpMsg)
　　　　its setAllowedFileTypes:(tmpExt)
　　　　its setNameFieldStringValue:(defName)
　　　　its setShowsHiddenFiles:false
　　　　its setTreatsFilePackagesAsDirectories:false
　　　　–its setDirectoryURL:startURL–指定しないほうが前回呼び出し時と同じフォルダが表示されて便利
　　　　set returnCode to its runModal() as integer
　　end tell
　　
　　if returnCode = (current application’s NSFileHandlingPanelOKButton) as integer then
　　　　set my savePath to thePanel’s |URL|()’s |path|()
　　　　
　　　　if (thePanel’s respondsToSelector:"tagNames") as boolean then
　　　　　　set my saveTag to thePanel’s tagNames()
　　　　end if
　　　　
　　else
　　　　— cancel button
　　　　error -1
　　end if
end showModalSave:

★Click Here to Open This Script　

(Visited 358 times, 1 visits today)

指定Bundle IDのstringsファイル中における指定タイトルの指定言語のローカライズ版を求める

Posted on 2月 24, 2020 by Takaaki Naganoya

/Applicationsフォルダ以下のすべてのアプリケーションのバンドル中のstringsファイル中を走査して、指定の言語における指定キーワード（”Quit”など）の指定言語におけるローカライズした文字列を取得するAppleScriptです。

自分でアプリケーションのローカライズを行う際に、既存のmacOS用のアプリケーションのバンドル内にあるstringsファイルを参考にするためのツールです。

もともとは、Shane StanleyがLate Night Softwareのフォーラムに投稿したプログラムですが、自分もいろいろ試していたように、アプリケーション側のローカライズのされ方（言語別のフォルダ名の名称指定）に「ゆらぎ」があるため、そのあたりは総当たりでテストしているようです。

オリジナルではデータが存在しない場合にはエラーにしていましたが、このようにすべてのアプリケーションに対してループで処理を行うような場合にはエラーで止まっては困るので、そのあたりを書き換えています。

/Applicationsフォルダ以下のSpotlight検索によるアプリケーションの取得についてはMetadata Libを用いています。自分の開発環境で１キーワード（x バンドル内のすべてのstringsファイル x すべてのアプリケーション）の問い合わせに3.6〜5秒程度かかっています。HDDの環境ではこれより大幅に長くかかるはずなので、ちょっと考えたくありません。

また、Stringsファイルで供給されるローカライズ情報については探すことができますが、OS側が強制的に供給するWindowメニューなどの内容については本Scriptで調査することはできません。ねんのため。

AppleScript名：指定Bundle IDのstringsファイル中における指定タイトルの指定言語のローカライズ版を求める.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/02/24
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions
use mdLib : script "Metadata Lib" version "2.0.0" –https://macosxautomation.com/applescript/apps/Script_Libs.html

property NSWorkspace : a reference to current application’s NSWorkspace

set targStr to "Performance"
set origLang to "en" –From
set targLang to "hu" –To

set tList to {}

set origPath to POSIX path of (path to applications folder)
set aResList to mdLib’s searchFolders:{origPath} searchString:("kMDItemContentType == %@") searchArgs:{"com.apple.application-bundle"}
repeat with i in aResList
　　set aTitleRes to getAppGUITitleWithCurrentLocale(i, targStr, origLang, targLang) of me
　　if aTitleRes is not equal to missing value and aTitleRes is not in tList then
　　　　set the end of tList to aTitleRes
　　end if
end repeat

return tList
–> {"Előadás", "Teljesítmény"}

–指定Bundle IDのstringsファイル中における指定タイトルの現在実行中のロケールのローカライズ版を求める
on getAppGUITitleWithCurrentLocale(aPath, aTargetTitle, origLang, targLang)
　　return my localizedStringFor:aTargetTitle inBundle:aPath destLang:targLang sourceLang:origLang
end getAppGUITitleWithCurrentLocale

–Bundle IDからアプリケーションのPathを返す
on retAppAbusolutePathFromBundleID(aBundleID)
　　set appPath to NSWorkspace’s sharedWorkspace()’s absolutePathForAppBundleWithIdentifier:aBundleID
　　if appPath = missing value then return false
　　return appPath as string
end retAppAbusolutePathFromBundleID

–Original By Shane Stanley@Late Night Software
–Modified By Takaaki Naganoya
–https://forum.latenightsw.com/t/localizing-gui-scripts/2246
on localizedStringFor:baseString inBundle:aPOSIX destLang:destLangCode sourceLang:sourceLangCode
　　set anURL to current application’s |NSURL|’s fileURLWithPath:aPOSIX
　　set theBundle to current application’s NSBundle’s bundleWithURL:anURL
　　if theBundle = missing value then return missing value
　　
　　set sourceLangString to current application’s NSString’s stringWithString:sourceLangCode
　　set destLangString to current application’s NSString’s stringWithString:destLangCode
　　
　　— get source strings values
　　set theURLs to theBundle’s URLsForResourcesWithExtension:"strings" subdirectory:"" localization:sourceLangString
　　if theURLs = missing value then return missing value
　　if theURLs’s |count|() < 2 and (sourceLangString’s containsString:"_") as boolean then
　　　　— try stripping off country-specific part
　　　　set sourceLangString to sourceLangString’s substringToIndex:2
　　　　set theURLs to theBundle’s URLsForResourcesWithExtension:"strings" subdirectory:"" localization:sourceLangString
　　end if
　　
　　if theURLs’s |count|() < 2 then
　　　　— try long name for localization
　　　　set sourceLangString to (current application’s NSLocale’s localeWithLocaleIdentifier:"en")’s localizedStringForLocaleIdentifier:sourceLangString
　　　　set theURLs to theBundle’s URLsForResourcesWithExtension:"strings" subdirectory:"" localization:sourceLangString
　　end if
　　
　　if theURLs’s |count|() < 2 then return missing value –error "No " & sourceLangCode & " localization found"
　　
　　repeat with sourceURL in theURLs
　　　　— skip unlocalized file
　　　　if not (sourceURL’s URLByDeletingLastPathComponent()’s lastPathComponent()’s isEqualToString:"Resources") as boolean then
　　　　　　set theData to (current application’s NSData’s alloc()’s initWithContentsOfURL:sourceURL)
　　　　　　
　　　　　　if theData is missing value then return — error "No " & sourceLangCode & " localization found"
　　　　　　set sourceDict to (current application’s NSPropertyListSerialization’s propertyListWithData:theData options:0 format:0 |error|:(missing value))
　　　　　　if sourceDict = missing value then return missing value
　　　　　　
　　　　　　set theKey to (sourceDict’s allKeysForObject:baseString)’s firstObject()
　　　　　　
　　　　　　if theKey is not missing value then
　　　　　　　　set stringsFileName to sourceURL’s lastPathComponent()’s stringByDeletingPathExtension()
　　　　　　　　set localURL to (theBundle’s URLForResource:stringsFileName withExtension:"strings" subdirectory:"" localization:destLangString)
　　　　　　　　
　　　　　　　　if localURL is missing value and (destLangString’s containsString:"_") as boolean then
　　　　　　　　　　— try stripping off country-specific part
　　　　　　　　　　set destLangString to (destLangString’s substringToIndex:2)
　　　　　　　　　　set localURL to (theBundle’s URLForResource:stringsFileName withExtension:"strings" subdirectory:"" localization:destLangString)
　　　　　　　　end if
　　　　　　　　
　　　　　　　　if localURL is missing value then
　　　　　　　　　　— try long name for localization
　　　　　　　　　　set destLangString to ((current application’s NSLocale’s localeWithLocaleIdentifier:"en")’s localizedStringForLocaleIdentifier:destLangString)
　　　　　　　　　　set localURL to (theBundle’s URLForResource:stringsFileName withExtension:"strings" subdirectory:"" localization:destLangString)
　　　　　　　　end if
　　　　　　　　
　　　　　　　　if localURL is missing value then return missing value — "No " & destLangCode & " localization found"
　　　　　　　　
　　　　　　　　set theData to (current application’s NSData’s alloc()’s initWithContentsOfURL:localURL)
　　　　　　　　if theData is missing value then missing value — "No " & destLangCode & " localization found"
　　　　　　　　set destDict to (current application’s NSPropertyListSerialization’s propertyListWithData:theData options:0 format:0 |error|:(missing value))
　　　　　　　　set destValue to (destDict’s objectForKey:theKey)
　　　　　　　　
　　　　　　　　–if destValue is not missing value then return {destValue as text, stringsFileName as text}
　　　　　　　　if destValue is not missing value then return destValue as text
　　　　　　　　return missing value
　　　　　　end if
　　　　end if
　　end repeat
　　return missing value
end localizedStringFor:inBundle:destLang:sourceLang:

★Click Here to Open This Script　

(Visited 51 times, 1 visits today)

画像に円を塗る

Posted on 2月 11, 2020 by Takaaki Naganoya

作成した画像（NSImage）に円を塗るAppleScriptです。

最近、６角形の図形ばかり塗りつぶしていましたが、「円に変えるとどうなんだろう？」と考えて、本ルーチンを試作してみました。

ためしに、６角形ではなく円で塗りつぶしてみたものの、そんなにイケていない感じがします。

AppleScript名：画像に円を塗る.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/02/11
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property aRadius : 40

set aFile to POSIX path of (choose file name)
if aFile does not end with ".png" then
　　set aFile to aFile & ".png"
end if

set aColor to current application’s NSColor’s redColor()

set aImage to current application’s NSImage’s alloc()’s initWithSize:{300, 300}

repeat with y from 0 to 300 by aRadius + 4
　　repeat with x from 0 to 300 by aRadius + 4
　　　　my drawCircleOnNSIMage(aImage, aRadius, x, y, aColor)
　　end repeat
end repeat

set sRes to my saveNSImageAtPathAsPNG(aImage, aFile)

#　　MARK: Call By Reference
on drawCircleOnNSIMage(aImage, aRadius, aXpos, aYpos, aColor)
　　set aBezier to generateCircle(aRadius, aXpos, aYpos) of me
　　(aImage)’s lockFocus()
　　aColor’s |set|()
　　aBezier’s fill() –ぬりつぶし
　　(aImage)’s unlockFocus()
end drawCircleOnNSIMage

#　　MARK: circleのBezier曲線を作成して返す
on generateCircle(theRadius, x, y)
　　set aRect to current application’s NSMakeRect(x, y, theRadius, theRadius)
　　set aCirCle to current application’s NSBezierPath’s bezierPath()
　　aCirCle’s appendBezierPathWithOvalInRect:aRect
　　return aCirCle
end generateCircle

# NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to current application’s NSBitmapImageRep’s imageRepWithData:imageRep
　　set pathString to current application’s NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　set myNewImageData to (aRawimg’s representationUsingType:(current application’s NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

(Visited 63 times, 1 visits today)

画像の指定エリアを透明色塗りつぶし（矩形切り抜き）

Posted on 2月 3, 2020 by Takaaki Naganoya

指定画像の指定エリア（矩形）を透明色で塗りつぶすAppleScriptです。透明色で塗りつぶす＝矩形で切り抜いたようなかっこうになります。

画像（NSImage）を指定色で塗りつぶすという処理はよく見かけるものですが、clearColor()（透明色）で塗りつぶすという処理を行うとどうなるかといえば…………何も起こりません。

透明色でNSImageを塗りつぶすという処理は、たいへんに「ありそう」な処理ですが、なかなか見つからない。

さんざん探し回ったのですが、自分には見つけられませんでした。ちょうどEdama2さんに相談してみたところ、こういう処理を探し出してもらえました（ありがとうございますー）。ただ、見つけてきた処理そのままでは思い通りの結果にならなかったので、修正が必要であったとのこと。

透明塗りつぶし（切り抜き）の指定座標はCocoaの座標系をそのまま利用しているので、左下が原点です。

NSBezierPathで切り抜き（透明色で塗りつぶし）できるといいのになーという感じではあります。

AppleScript名：画像の指定エリアを透明色塗りつぶし（矩形切り抜き）

— Created 2017-11-19 by Takaaki Naganoya
— Modified 2018-02-14 by Takaaki Naganoya
— Modified 2020-02-03 by Edama2 & Takaaki Naganoya
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSScreen : a reference to current application’s NSScreen
property NSBezierPath : a reference to current application’s NSBezierPath
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSCompositeClear : a reference to current application’s NSCompositeClear
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep

–切り抜きエリア（複数）
set drawList to {{origin:{x:0, y:0}, |size|:{width:200, height:100}}, {origin:{x:100, y:100}, |size|:{width:50, height:50}}}

set imgPath to POSIX path of (choose file of type {"public.image"})
set anImage to NSImage’s alloc()’s initWithContentsOfFile:imgPath

set fillColor to (NSColor’s colorWithCalibratedRed:1.0 green:0.0 blue:0.0 alpha:0.9)

–透明色塗りつぶし処理呼び出し
set resImage to drawImageWithClearColorFill(anImage, drawList) of me

set aUUIDstr to (NSUUID’s UUID()’s UUIDString()) as string
set aPath to ((NSString’s stringWithString:imgPath)’s stringByDeletingLastPathComponent()’s stringByAppendingPathComponent:aUUIDstr)’s stringByAppendingPathExtension:"png"

set fRes to saveImageRepAtPathAsPNG(resImage, aPath) of me

on drawImageWithClearColorFill(anImage, drawList)
　　set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
　　–>　　2.0 (Retina) / 1.0 (Non Retina)
　　
　　set aClearCol to NSColor’s clearColor()
　　set op to current application’s NSCompositeClear
　　
　　anImage’s lockFocus() –描画開始
　　
　　repeat with i in drawList
　　　　set origX to (x of origin of i) / retinaF
　　　　set origY to (y of origin of i) / retinaF
　　　　set sizeX to (width of |size| of i) / retinaF
　　　　set sizeY to (height of |size| of i) / retinaF
　　　　
　　　　–Draw Clear Color
　　　　–http://www.drissman.com/blog/archives/2009/10/09/nsrectfill_and_nscolor_clearcolor.html
　　　　set theRect to {{x:origX, y:origY}, {width:sizeX, height:sizeY}}
　　　　aClearCol’s |set|()
　　　　current application’s NSRectFillUsingOperation(theRect, op)
　　end repeat
　　
　　anImage’s unlockFocus() –描画ここまで
　　
　　return anImage –returns NSImage
end drawImageWithClearColorFill

–画像を指定パスにPNG形式で保存
on saveImageRepAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　return (myNewImageData’s writeToFile:newPath atomically:true) as boolean
end saveImageRepAtPathAsPNG

★Click Here to Open This Script　

(Visited 123 times, 3 visits today)

BlogアーカイブのMarkdown書類をリネーム。親、親+1階層フォルダをMM, YYYYとみなして反映

Posted on 1月 19, 2020 by Takaaki Naganoya

Finderで選択中のファイルすべてに対して、親フォルダ名、親＋1階層のフォルダ名を反映させたファイル名をつけるAppleScriptです。

Blogアーカイブ本を作るのに、こうした道具を作って使っています。一度書いておけば、２度目からは大幅に時間を短縮できます。最初のファイルから拡張子を取得してそれを後続のファイルすべてに適用するため、同一種類のファイルである必要があります。自分用のツールならではの手抜きといったところでしょうか。

AppleScript名：BlogアーカイブのMarkdown書類をリネーム。親、親+1階層フォルダをMM, YYYYとみなして反映 .scptd

— Created 2020-01-18 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

–選択ファイルを取得
tell application "Finder"
　　set aSel to selection as alias list –Select documents to Rename
end tell

set aCount to 10 –start
set aStep to 10
set aDigit to 3

–パス情報を取得
set aFirst to first item of aSel
set aPOSIX to POSIX path of aFirst
set aPathStr to (current application’s NSString’s stringWithString:aPOSIX)
set aDateComList to aPathStr’s pathComponents() –ディレクトリごとにパス情報を分割してリスト化
set aExt to aPathStr’s pathExtension() –拡張子

set aYear to (item -3 of aDateComList) as string –親の親フォルダ名
set aMonth to (item -2 of aDateComList) as string –親フォルダ名

–リネーム（数百項目を超える場合にはFinderでは遅すぎるのでNSFileManagerで処理）
tell application "Finder"
　　repeat with i in aSel
　　　　set aTEXT to numToZeroPaddingStr(aCount, aDigit, "0") of me –3 digit
　　　　set aName to aYear & aMonth & aTEXT & "." & aExt
　　　　set name of i to aName
　　　　set aCount to aCount + aStep
　　end repeat
end tell

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

(Visited 113 times, 1 visits today)

path to temporary items

Posted on 1月 6, 2020 by Takaaki Naganoya

AppleScript users ML上で2016/10/16〜18に行われていた議論の内容を自分でも再確認しました（Thanks Yvan!）。一時フォルダの場所を求める「path to temporary items」の値が、macOS 10.12から変更になっています。

▲AppleScript Users ML上の議論のフロー（Mail Flow Visualizerによりバッチ出力。つまり、Mail.app上で出力フローを選択してAppleScriptでフロー図出力しています）

AppleScript標準装備の「path to」コマンドは、Classic MacOS環境からMac OS X環境に移行した後に重要度が上がったコマンドです。OS側が用意している特別な意味を持つフォルダの場所を返してくれます。

とくに、（いまさらですが）Mac OS X環境はマルチユーザー環境なので、とくにPicturesとかDocumentsとかDesktopとかの特別なフォルダのパスを求める機能は基礎的ではあるものの、とても重要です。このあたりをめんどくさがってなんでもかんでも固定パスで書きたがる人を見かけたことがありますが、その人が書いたプログラムは他のユーザー環境で動かなくて苦労していました（本人ではなく周囲の人々が）。

AdobeのCS/CCアプリケーションのサンプルAppleScriptでも固定パスで書かれたものを多数見かけましたが、あれはなんだったんでしょう。

ドメイン

もともと、path toコマンドにより求められる各種パスには、

system domain：/System 
network domain：/Network
user domain：~

などのほか、

local domain：/Library
Classic domain： Classic Mac OSのシステムフォルダ（Classic環境をサポートするOS＆ハードウェアの組み合わせ上でのみ有効）

などの「ドメイン」が指定できることになっていました。system domainはOSのSystemが利用、User domainはユーザーのホームフォルダ以下。network domainはmacOSのNetBootが廃止/他の機能への移行対象となっている（すでに、iMac ProではNetBoot非サポート）ほか、そのような環境下にないと有意な結果が得られません。

作業用一時フォルダtemporary items

ドメインの区分けが存在するものの、これらの区分のうちClassic domainははるかかなた昔に消滅、network domainも使ったことのあるユーザーは稀（まれ）でしょう。

そんな中、作業用の一時フォルダの場所を求める「path to temporary items」の仕様がmacOS 10.12で変更になっていました。

テンポラリフォルダの特性ゆえに、細かいディレクトリ名はユーザー環境ごと、実行時ごとに微妙に異なりますが（赤字部分が変化する部分）、上の図では（↑）どのあたりに作られるのかという点に着目して色分けしてみました。

macOS 10.12以降では、user domainでもsystem domainでも同じような場所が指定されることになることがわかります。

ちなみに、Cocoaの機能を用いて求められる一時フォルダはまた別の場所が示されています。

use framework "Foundation"

current application’s NSTemporaryDirectory() as text
–> "/var/folders/h4/jfhlwst88xl9z0001s7k9vk00000gr/T/"

★Click Here to Open This Script　

(Visited 237 times, 2 visits today)

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: File path

画像をExcelのワークシート上に配置

ファイル選択でiCloud Driveをデフォルトフォルダに指定

AS関連データの取り扱いを容易にする（はずの）privateDataTypeLib

xincludeを有効にしてXML（sdef）読み込み v2

Keynoteの現在の書類と同じ階層に没スライド入れを作成

書籍フォルダの階層をさかのぼって、ツメに掲載する最大チャプターを推測 v2

Pixelmator Proで指定の画像を複数の3D LUTを用いてカラー調整して画像書き出し

画面スナップショット超解像バッチ処理 v1

部首で漢字検索

追記：

アプリケーションが扱えるデータ拡張子を取得

アラートダイアログ上にCollection Viewを表示

指定アプリケーションのバイナリアーキテクチャ判定 v3

指定アプリケーションのバイナリアーキテクチャ判定

ファイル保存ダイアログ（SavePanel）表示

指定Bundle IDのstringsファイル中における指定タイトルの指定言語のローカライズ版を求める

画像に円を塗る

画像の指定エリアを透明色塗りつぶし（矩形切り抜き）

path to temporary items

ドメイン

作業用一時フォルダtemporary items