AS関連データの取り扱いを容易にする（はずの）privateDataTypeLib

Posted on 8月 22, 2022 by Takaaki Naganoya

AS関連データの取り扱いを簡単にすることを目的に書き出した、privateDatatypeLibです。

プログラムとデータを分離して、データ記述部分を外部ファイル（設定ファイルなど）に追い出したときに、どのようなデータかを表現するための道具として試作してみました。

macOS上のデータ記述子は、

などのさまざまなデータ識別方法が存在していますが、どれも（自分の）用途には合わなかったので、検討・試作をはじめてみました。Predicatesが一番近いものの、不十分なのでいろんなデータ型や用途に拡張。あくまで自分用なので「public」などの宣言はとくに不必要と考え、縮小して処理を行なっています。

とくに、ファイルパスの処理なんて定型処理しかしないのに、わざわざ何かの表現を行う必要があるのはナンセンスですし、日付関連も割と余計な記述が多いように感じています。

また、緯度/経度のデータや座標データなども、もう少しなんとかならないかと思っています。

AppleScript名：privateDataTypeLib.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/08/22
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aData to "１００"
set dType to "@number"
set bData to "" –不要なケース多数。不要な場合にはヌル文字を指定
set mePath to path to me –実際には、呼び出し側で取得して指定。ライブラリ自体のパスを求めているのはテスト実行時のみ
set aRes to getParameterAndCalc(aData, dType, bData, mePath) of me

on getParameterAndCalc(aData, dType, bData, mePath)
　　if dType = "@string" then
　　　　return normalizeByNFC(aData) of me
　　　　
　　else if dType = "@number" then
　　　　set tmpA to zenToHan(aData) of charConvKit of me –全角→半角変換
　　　　set a to detectOutNumStr(tmpA) of me –数字＋関連・意外の文字を除外
　　　　return normalizeByNFC(a) of me
　　　　
　　else if dType = "@filepath.sub.foldername" then
　　　　set aClass to class of aData –aliasだったらPOSIX pathに変換。file…はどうなんだか
　　　　if aClass = alias then set aData to POSIX path of aData
　　　　return aData & bData & "/"
　　　　
　　else if dType = "@file.comment" then
　　　　set aStr to getFinderComment(POSIX path of mePath) of me
　　　　return normalizeByNFC(aStr) of me
　　　　
　　else if dType = "@file.name" then
　　　　set aClass to class of aData
　　　　if aClass = alias then set aData to POSIX path of aData
　　　　set aStr to (current application’s NSString’s stringWithString:aData)’s lastPathComponent()’s stringByDeletingPathExtension()
　　　　return normalizeByNFC(aStr as string) of me
　　　　
　　else if dType = "@date.month" then
　　　　set curDate to current date
　　　　set curMonth to month of curDate as number
　　　　return curMonth as string
　　　　
　　else
　　　　return aData
　　end if
end getParameterAndCalc

on normalizeByNFC(aStr)
　　set aNSStr to current application’s NSString’s stringWithString:aStr
　　set aNFC to aNSStr’s precomposedStringWithCanonicalMapping()
　　return aNFC as string
end normalizeByNFC

–ANK文字列以外のものをそぎ落とす
on detectOutNumStr(testStr)
　　set sList to characters of testStr
　　set aStr to ""
　　
　　repeat with i in sList
　　　　if detectOutNumChar(i) of me then
　　　　　　set aStr to aStr & (i as string)
　　　　end if
　　end repeat
　　
　　return aStr
end detectOutNumStr

on detectOutNumChar(testText)
　　–Numeric + Special char
　　set ankChar to {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9", ".", "-", "+", "E", ","}
　　
　　set _testChar to testText as Unicode text
　　
　　ignoring case
　　　　repeat with i in _testChar
　　　　　　set j to contents of i
　　　　　　if j is not in ankChar then
　　　　　　　　return false
　　　　　　end if
　　　　end repeat
　　end ignoring
　　
　　return true
end detectOutNumChar

–Finderコメントを取得
on getFinderComment(aPOSIX)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aPOSIX
　　set aMetaInfo to current application’s NSMetadataItem’s alloc()’s initWithURL:aURL
　　set metaDict to (aMetaInfo’s valuesForAttributes:{"kMDItemFinderComment"}) as record
　　if metaDict = {} then return ""
　　set aComment to kMDItemFinderComment of (metaDict)
　　return aComment
end getFinderComment

script charConvKit
　　— Created 2017-09-06 by Shane Stanley
　　— Modified 2017-09-06 by Takaaki Naganoya
　　use AppleScript
　　use framework "Foundation"
　　property parent : AppleScript
　　
　　property NSString : a reference to current application’s NSString
　　property NSStringTransformFullwidthToHalfwidth : a reference to current application’s NSStringTransformFullwidthToHalfwidth
　　property NSStringTransformHiraganaToKatakana : a reference to current application’s NSStringTransformHiraganaToKatakana
　　property NSStringTransformLatinToHiragana : a reference to current application’s NSStringTransformLatinToHiragana
　　property NSStringTransformLatinToKatakana : a reference to current application’s NSStringTransformLatinToKatakana
　　property NSStringTransformToUnicodeName : a reference to current application’s NSStringTransformToUnicodeName
　　property NSStringTransformToXMLHex : a reference to current application’s NSStringTransformToXMLHex
　　
　　–半角→全角変換
　　on hanToZen(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformFullwidthToHalfwidth) |reverse|:true) as string
　　end hanToZen
　　
　　–全角→半角変換
　　on zenToHan(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformFullwidthToHalfwidth) |reverse|:false) as string
　　end zenToHan
　　
　　–ひらがな→カタカナ変換
　　on hiraganaToKatakana(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformHiraganaToKatakana) |reverse|:false) as string
　　end hiraganaToKatakana
　　
　　–カタカナ→ひらがな変換
　　on katakanaToHiraganaTo(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformHiraganaToKatakana) |reverse|:true) as string
　　end katakanaToHiraganaTo
　　
　　–ローマ字→ひらがな変換
　　on alphabetToHiragana(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToHiragana) |reverse|:false) as string
　　end alphabetToHiragana
　　
　　–ひらがな→ローマ字変換
　　on hiraganaToalphabet(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToHiragana) |reverse|:true) as string
　　end hiraganaToalphabet
　　
　　–ローマ字→カタカナ変換
　　on alphabetToKatakana(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToKatakana) |reverse|:false) as string
　　end alphabetToKatakana
　　
　　–カタカナ→ローマ字変換
　　on katakanaToAlphabet(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformLatinToKatakana) |reverse|:true) as string
　　end katakanaToAlphabet
　　
　　–文字→Unicode Name変換
　　on characterToUnicodeName(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToUnicodeName) |reverse|:false) as string
　　end characterToUnicodeName
　　
　　–Unicode Name→文字変換
　　on unicodeNameToCharacter(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToUnicodeName) |reverse|:true) as string
　　end unicodeNameToCharacter
　　
　　–文字→XML Hex変換
　　on stringToXMLHex(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToXMLHex) |reverse|:false) as string
　　end stringToXMLHex
　　
　　–XML Hex→文字変換
　　on xmlHexTostring(aStr)
　　　　set aString to NSString’s stringWithString:aStr
　　　　return (aString’s stringByApplyingTransform:(NSStringTransformToXMLHex) |reverse|:true) as string
　　end xmlHexTostring
end script

★Click Here to Open This Script　

(Visited 63 times, 1 visits today)

applescript:// URL Linkの状況確認

Posted on 7月 15, 2022 by Takaaki Naganoya

本Blogに掲載しているプログラムリストは、すべてapplescript:// URLリンクを埋め込んであり、リスト末尾にあるリンクをクリックするだけで、スクリプトエディタに内容を転送できるようにしています。

ところが、macOS 12.5RCにおいてSafariで表示した本Blog内のコンテンツで、applescript:// URLリンクをクリックしたところ、

・プログラムリストが短いと内容はスクリプトエディタに転送される
・プログラムリストが一定基準よりも長くなると、スクリプトエディタに内容は転送されなくなる

といった現象が確認されています。知り合いにいろいろ確認してみたところ、

・macOS 12.5以前のOSであっても、上記のような現象を確認していた

という話です（「じゃあ教えてよ！」と心の中でツッコミを入れていましたが）。

macOS 10.15のときに、PDFView上のURL Link（applescript://）が一律で無視されたときには、不服申し立てを行い、最終的には、

・macOS標準添付のPreview.app上のPDFはapplescript:// URL Linkは無視される
・サードパーティのアプリケーション上のPDFViewのapplescript:// URL Linkの妨害はやめる

ということになったようです。いつ状況が変わるかわからないので、未来永劫この状況が維持されるかどうかは不明です。自分だけがAppleに文句を言っていたわけではないと思いますが、基本的にAppleとの歴史は戦いの積み重ねです。Appleのやらかしを指摘して、事実関係のみ述べ、修正されるまで執念深く追求するという戦いの繰り返しです。

→ 本件は私のやらかしかもしれません、、、、

現状の確認

本BlogへのAppleScriptのプログラム掲載に使用しているAppleScript→HTML変換プログラム「AS Publisher v18」の内容を再確認してみましたが、Cocoaの機能を用いて文字列をURLエンコードしているだけです（そんなに複雑な処理をしていません）。部品単品でエンコード/デコードを行って検証してみたものの、呼び出している部品に問題は見つかりませんでした。

→ この部品でURLエンコードする方法を間違っていたもよう。ただし、過去のmacOSでは「間違ったURLエンコードが飛んでくることがあるので、対処しとくか」という処理になっていたところが、「厳密に正しいものしか処理しないようにしよう」という方針に変わったことが原因？

次に、Safariで何らかの妨害をしている可能性について検証してみました。

Safariではなく、CotEditor上でURLエンコードしたAppleScriptのプログラムのHTMLコンテンツをオープンし、CotEditorの最前面の書類からURL部分をURL Event的にオープン。これもSafari同様の問題が発生していることを確認しました。

コンテンツ中のURL部分をData Detectorを用いて抽出→Openさせた場合、URL内容が一定以上の長さを超えると途中で切られてしまうという動作を確認。macOS全体で「長いURL」への応答を殺しているという現状を確認。こういう話は一切WWDCでやらずに、コソコソ変更するんですよねー。

→ 事実関係を確認すると、本件についてはとくに悪意はない模様

本Blog側の対応

本問題の確認直後、すぐにAppleにバグレポートを行いました。この後は、PDFViewのときと同様に、Appleと２・３年あまりも不毛なやりとりを続けることになるのでしょう。事実上の牛歩戦術ともいえます。

そのやりとりをしている２・３年の間、ぼーっとしているわけにも行かないので対応策を考えておかなければなりません。

確実で安全な対策は、Script Debuggerでapplescript:// URLリンクを受信するように、Script Debugger側で設定することです。これなら、途中でApple側の妨害や嫌がらせに遭うことなく、プログラムリストの内容を転送できます。

ただし、「AppleScriptを今日はじめました」という人がScript Debuggerをダウンロードしているはずがないので、そこには対策しておく必要があります。

少ない労力で対処するのであれば、掲載リストのZipアーカイブをダウンロードできるようにしておくぐらいでしょう。

プラス、本Blogの過去記事アーカイブの英訳版を企画中ですが、日本語版も出してもいいような気もします。

(Visited 51 times, 1 visits today)

Safariで表示中のYouTubeムービーのサムネイル画像を取得

Posted on 5月 9, 2022 by Takaaki Naganoya

Safariで表示中のYouTubeムービーのサムネール画像を取得、保存、表示するAppleScriptです。

YouTubeのムービーのサムネール画像の取得方法を確認し、動作確認用にダイアログ表示＋画像保存の機能を追加したものです。Script Debugger上で動かしている分には、NSImageの内容を結果表示ビューワで自動表示されますが、ない人向けに付けた機能です。

画像自体は、「ピクチャ」フォルダにUUIDつきでPNG形式で保存します。

–> Download Script bundle with Library

掲載リストには、画像表示ライブラリが含まれていないため、そのままでは実行できません。上記のScript Bundleをダウンロードして実行する必要があります。

AppleScript名：Safariで表示中のYouTubeムービーのサムネイル画像を取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/09
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use imgLib : script "imageDisplayLib"

property NSUUID : a reference to current application’s NSUUID
property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSURLComponents : a reference to current application’s NSURLComponents
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

tell application "Safari"
　　tell front document
　　　　try
　　　　　　set aURL to URL
　　　　on error
　　　　　　set aURL to "https://www.youtube.com/watch?v=_fmDtIV9vvI"
　　　　end try
　　end tell
end tell

if aURL does not start with "https://www.youtube.com/watch?" then return

set urlDict to parseURLParamsAsDict(aURL) of me
set aParam to urlDict’s valueForKey:"v"
if aParam = missing value then return

set imgURL to "https://i1.ytimg.com/vi/" & (aParam as string) & "/mqdefault.jpg"
set newURL to |NSURL|’s URLWithString:imgURL
set aImg to NSImage’s alloc()’s initWithContentsOfURL:newURL

set imgPath to (POSIX path of (path to pictures folder) & ((aParam as string) & "_") & (NSUUID’s UUID()’s UUIDString()) as string) & ".png"

–Save
saveNSImageAtPathAsPNG(aImg, imgPath) of me

–Display
dispImage(aImg, "YouTube thumbnail") of imgLib

on parseURLParamsAsDict(aURL)
　　set components to NSURLComponents’s alloc()’s initWithString:aURL
　　set qList to (components’s query())’s componentsSeparatedByString:"&"
　　
　　set paramRec to NSMutableDictionary’s dictionary()
　　
　　repeat with i in qList
　　　　set keyAndValues to (i’s componentsSeparatedByString:"=")
　　　　(paramRec’s setObject:(keyAndValues’s objectAtIndex:1) forKey:(keyAndValues’s objectAtIndex:0))
　　end repeat
　　
　　return paramRec
end parseURLParamsAsDict

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

(Visited 99 times, 1 visits today)

macOS 12.3上でFinder上で選択中のファイルをそのままオープンできない件

Posted on 3月 28, 2022 by Takaaki Naganoya

macOS 12.xはAppleScriptの処理系に対して、主にセキュリティ面でいろいろ修正が加わっています。

この修正は、セキュリテイを「高める」という名目のもとに行われているのですが、セキュリティ面での課題さえ片付けられれば、その他に悪影響を及ぼしていたとしても「知ったことではない」というのがAppleの態度です。そして、その問題に対してユーザー側から文句が出てこなければ、そのままです。

–> View Demo Movie

とくに、深謀遠慮な考えとか、素晴らしい見通しとかはなく、「上から言われたからやっている」というやっつけ仕事感を感じます。

AppleはSteve Jobsが作り上げた秘密警察みたいな組織になっていて、チーム間の権限の切り分けが病的なまでに行われており、チームが違うと会社が違うぐらいの隔たりが発生しています。それは、Steve Jobsという「垣根を無視して横断して歩く異物」がいたから成立する組織であって、官僚化、硬直化が絶賛進行中といったところです。

話を戻しますが….たしかに、そうした機能的なアップを伴わない修正で何も問題（副作用）が起こらなければ「セキュリティが高まったのでよかったね」という美談になるわけですが、たいていの場合にはそうなりません。意図していなかった箇所に副作用が生じます。

あるいは、セキュリティのポリシー同士が実は矛盾を生んでいる、という状況になっていて、Aという問題とBという問題を解決した結果、あらたにCというもっと巨大な問題が発生する、とかいった状況は容易にあり得るわけです。それでも、各担当者は誠意をもってその仕事に取り組んでいるわけで、こうした「人間的に尊敬できて素晴らしい能力を持ったスタッフ」による「熱心かつ誠意あふれる真摯な仕事」が合成された結果、「見たことも聞いたこともない間抜けな理由から生じる猛毒にまみれた悪意」が合成されてしまうことが、現在のTim CookのAppleの下ではあり得るのです。

「Finder上で選択中のファイルをそのままオープンする」

というのは、ここ数年というよりもAppleScriptを覚えたてのころにちょろっと書いて実行したぐらいであり、実際のところ「それがどうした？」というレベルの処理です。

AppleScript名：Finder上で選択中のファイルをオープン.scpt

–macOS 12.3でエラーになる処理
tell application "Finder"
　　open selection
end tell

★Click Here to Open This Script　

Finder上で選択したファイルに対する処理は、きょうび何かのアプリケーションに渡さなくてもAppleScriptだけで処理できてしまうことが多いということもありますし（画像とか）、選択されたファイルをそのままオープンするという「1＝1」みたいな処理はやりません。

選択したフォルダの中をすべてSpotlight経由で走査して、指定の形式のファイルだけをリストアップして、順次処理するようなものになっています。

ただ、10年たっても20年たっても「1＝1」みたいな処理しかしていない人がけっこういて驚かされると同時に、意外なところで（Adobeのアプリケーションでアプリケーション間の連携に）使っていたりして、修正されないと困るケースは多いようです。

Shane StanleyがLateNight Softwareのフォーラムに投稿した、こうした処理への迂回Scriptがありました。さすがです。

Finder経由で書類のオープンと、その書類を作成したアプリケーションの起動を促すという、macOS 12.3で問題が起こっている処理を、Cocoaの機能を用いることで迂回してしまおうというものです。

ただ、そのままではFinder上で指定したファイルを１つオープンするという実証コードのレベルのものだったので、複数のファイルが選択されたものをオープンするように書き足してみました。

AppleScript名：macOS 12.3でFinder上の選択中のファイルをオープン.scpt

—
–　　Created by: Shane Stanley
–　　Created on: 2022/03/24

–　　Modified by: Takaaki Naganoya
–　　Modified on: 2022/03/27
—
— macOS 12.3でFinder上のselectionをただopenすると、作成したアプリケーションは起動するが、書類はオープンされないバグ
–　に対処したもの。複数ファイルの選択状態を処理する場合がほとんどなので、若干追記
–　ただ、漫然と選択したファイルをオープンするという処理はやっていないので（なにがしかの処理を自前でやるので）

use framework "AppKit"
use framework "Foundation"
use scripting additions

tell application "Finder"
　　set aSel to selection as alias list
　　if aSel = {} then return
end tell

openFiles(aSel) of me

on openFiles(pathList as list)
　　repeat with i in pathList
　　　　set j to contents of i
　　　　openFile(POSIX path of j) of me
　　end repeat
end openFiles

on openFile(thePath as string) — POSIX path
　　set ws to current application’s NSWorkspace’s sharedWorkspace()
　　set theURL to current application’s |NSURL|’s fileURLWithPath:thePath
　　ws’s openURL:theURL
end openFile

★Click Here to Open This Script　

(Visited 112 times, 2 visits today)

アラートダイアログでMarkdownをプレビュー v3a

Posted on 8月 15, 2020 by Takaaki Naganoya

edama2さんからの投稿です。Markdown書類をプレビューするAppleScriptです。

–> Download Script bundle

本Scriptには、画期的な技術が用いられています。普通、AppleScriptObjCでは、WkWebViewによるネットワークアクセスを行うと、ネットワークアクセスを行う子プロセスと、WkWebViewで表示を行う子プロセスが生じて、処理が終了しても残ってしまいます。

スクリプトエディタ上で実行した場合には、スクリプトエディタを終了すればこうした子プロセスはメモリ上からパージされますが、終了するまで子プロセスは残されたままです。

「まー、AppleScriptObjCだから仕方ないよねー」

などと去年の年末に秋葉原でカレーを食べながらバカ話をしていた記憶がありますが、edama2さんがついにこれを回避する記法を編み出してしまったわけです。

回避方法については、やり方を説明されると「なるほど」という単純明快なものです（それを思いつくのがすごい）。osascript経由でAppleScriptを再実行することで、ランタイム環境を明示的にosascriptに指定してプログラムを実行。osascriptの終了とともにメモリ上から子プロセスがパージされるということのようです。

ランタイム環境を動的に生成し、実行後にランタイム環境がメモリ上から消去されるようになっていれば、子プロセス（ゴミ）が残っていてもまとめて消える………AppleScriptのランタイム環境はosascriptのほかCocoa系もあるので、そちらでも試してみるとよいでしょう。

ほかにも、WkWebViewによる表示を行う専用の支援アプリケーションを作っておき、AppleScript用語辞書経由で表示を行わせるという解決策も考えられます（ためしていないですが）。

AppleScript名：アラートダイアログでMarkdownをプレビュー v3a

use AppleScript
use framework “AppKit”
use framework “Foundation”
use framework “WebKit”
use scripting additions

on run args
　　if (args’s class) is script then
　　　　set myPath to (path to me)’s POSIX path
set resultText to do shell script “osascript “ & myPath’s quoted form
　　else
　　　　my main()
　　end if
end run

on main()
　　set mes to “Markdownファイルを選択してください。”
set chooseItems to choose file of type {“net.daringfireball.markdown”} with prompt mes

　　#
set aScreen to current application’s NSScreen’s mainScreen()
set screenFrame to aScreen’s frame()
set aHeight to current application’s NSHeight(screenFrame)
set aWidth to current application’s NSWidth(screenFrame)
set aHeight to aHeight * 0.845
set aWidth to aWidth * 0.94 / 2

　　set paramObj to {myMessage:“Markdown preview”}
set paramObj to paramObj & {mySubMessage:“file : “ & chooseItems’s POSIX path}
set paramObj to paramObj & {mdFile:chooseItems}
set paramObj to paramObj & {viewWidth:aWidth}
set paramObj to paramObj & {viewHeight:aHeight}

　　my performSelectorOnMainThread:“displayMarkdownPreview:” withObject:(paramObj) waitUntilDone:true
end main

# Markdownをダイアログで表示
on displayMarkdownPreview:paramObj
　　set mesText to myMessage of paramObj as text
set infoText to mySubMessage of paramObj as text
set mdFile to (mdFile of paramObj) as alias
set viewWidth to (viewWidth of paramObj) as integer
set viewHeight to (viewHeight of paramObj) as integer

　　## HTMLを読み込む
set mePath to path to me
set resPath to (mePath & “Contents:Resources:index.html”) as text
set htmlStr to (read (resPath as alias) as «class utf8») as text

　　## MDを読み込む
set mdStr to (read mdFile as «class utf8») as text

　　## MD内に改行があるとうまく読み込まれないので改行を置き換え
set mdStr to current application’s NSString’s stringWithString:mdStr
set mdStr to mdStr’s stringByReplacingOccurrencesOfString:(linefeed) withString:“＼＼n”
set mdStr to mdStr’s stringByReplacingOccurrencesOfString:“’” withString:“＼＼’”

　　## html内の文字を置き換え
set aString to current application’s NSString’s stringWithFormat_(htmlStr, mdStr) as text
log result

　　## baseURL
set aPath to mdFile’s POSIX path
set baseURL to current application’s NSURL’s fileURLWithPath:aPath
set baseURL to baseURL’s URLByDeletingLastPathComponent()

　　##
set aConf to current application’s WKWebViewConfiguration’s new()
tell current application’s WKUserContentController’s new()
　　　　aConf’s setUserContentController:it
　　end tell

　　## WebViewを作成＆読み込み
set frameSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
tell current application’s WKWebView’s alloc()
　　　　tell initWithFrame_configuration_(frameSize, aConf)
　　　　　　setNavigationDelegate_(me)
setUIDelegate_(me)
loadHTMLString_baseURL_(aString, baseURL)
set theView to it
　　　　end tell
　　end tell

　　## アイコンの指定
set aImage to current application’s NSWorkspace’s sharedWorkspace()’s iconForFileType:“net.daringfireball.markdown”

　　current application’s NSRunningApplication’s currentApplication()’s activateWithOptions:0

　　## set up alert
tell current application’s NSAlert’s new()
　　　　addButtonWithTitle_(“Close”)
setAccessoryView_(theView)
setIcon_(aImage)
setInformativeText_(infoText)
setMessageText_(mesText)
tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
### show alert in modal loop
if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell

　　## 後始末
theView’s stopLoading()
set js to “window.open(’about:blank’,’_self’).close();”
theView’s evaluateJavaScript:js completionHandler:(missing value)
set theView to missing value
end displayMarkdownPreview:

★Click Here to Open This Script　

(Visited 61 times, 1 visits today)

SafariでURLローディング完了検出

Posted on 8月 10, 2020 by Takaaki Naganoya

Safariで指定URLのページローディングを検出するAppleScriptです。

Safari 13で従来どおり、do javascriptコマンド経由で、

if (do JavaScript "document.readyState" in document 1) is "complete" then

などと処理させてみたら、URLが変更される前に”complete”が返ってきました。どうも、この処理が非同期実行されるのか、表示が反映される前に内部的にはページ遷移が完了しているようです。

現行のSafariにおいては、上記の処理ではページローディング完了検出が行えないことが判明。割と利用する機会が多く、重要な処理であるため、書き換えてみました。

いろいろ実験してみると、documentに新規URLを設定しても、すぐにはURLが変更されないようです。その割にAppleScriptの実行は完了したものとして次の行へと進んでしまいます。普通、こんな挙動を行うアプリケーションはないのですが（OCRで見たことがあったかも？）、ただ、逆にここで処理待ちすると問題が発生するケースもありそうです。

非同期モードと同期モードの両方が存在していて、明示的に選択できるとよいのですが、現状ではそうなっていません。

仕方がないので、旧URLから新URLへの切り替えをループで見張るという処理を書いてみたら、いい感じにローディング検出できました。

AppleScript名：SafariでURLローディング検出.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/08/09
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aURL to "http://piyocast.com/as/"
openURLWithSafari(aURL)
set aText to getBodyTextFromSafariFrontWindow() of me

on openURLWithSafari(aURL as string)
　　if aURL = "" then error "URL is blank"
　　try
　　　　tell application "Safari"
　　　　　　set d to count every window
　　　　　　if d = 0 then
　　　　　　　　make new window
　　　　　　　　tell front document
　　　　　　　　　　set URL to aURL
　　　　　　　　end tell
　　　　　　else
　　　　　　　　tell front document
　　　　　　　　　　set oldURL to URL
　　　　　　　　　　set URL to aURL
　　　　　　　　end tell
　　　　　　end if
　　　　　　
　　　　　　detectPageLoaded(10, oldURL, aURL) of me
　　　　　　
　　　　end tell
　　on error
　　　　return false
　　end try
end openURLWithSafari

on detectPageLoaded(timeout_value, oldURL, newURL)
　　try
　　　　repeat with i from 1 to (timeout_value * 5)
　　　　　　tell application "Safari"
　　　　　　　　tell front document
　　　　　　　　　　set curURL to URL
　　　　　　　　end tell
　　　　　　end tell
　　　　　　
　　　　　　if curURL = newURL then return
　　　　　　delay 0.2
　　　　end repeat
　　on error
　　　　return false
　　end try
　　
　　return false
end detectPageLoaded

on getBodyTextFromSafariFrontWindow()
　　–フレームを使っていないことが前提条件
　　tell application "Safari"
　　　　return text of front document
　　end tell
end getBodyTextFromSafariFrontWindow

★Click Here to Open This Script　

(Visited 217 times, 2 visits today)

辞書.appで指定の単語を検索する v3

Posted on 7月 9, 2020 by Takaaki Naganoya

辞書.appで指定の単語を検索するAppleScriptです。

辞書.app（Dictionary.app）にはAppleScript用語辞書が存在していませんが、URL event経由で検索・表示できるほか、サードパーティのFramework経由でも串刺し検索できるようになっています。

URL eventはApple側から最もセキュリティ面で懸念されている箇所であり、以前はURL event経由でアプリケーション起動もできたのですが、いまはURL event経由のアプリケーション起動は（ごく一部の例外を除き）禁止されている様子です。

ただし、OSバージョンが上がるたびに微妙に辞書名称が変更されており、定数で指定されることに対して微妙にAppleのエンジニアが嫌がらせをしている様子が伺えます。

AppleScript名：辞書.appで指定の単語を検索する v3

— Created 2017-09-19 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aText to text returned of (display dialog "Input keyword to search" default answer "")
set encText to encodeURL(aText) of me
activate application "Dictionary"

set aURL to "dict://" & encText
open location aURL

on encodeURL(origStr as string)
　　set aStr to current application’s NSString’s stringWithString:origStr
　　set encodedStr to aStr’s stringByAddingPercentEscapesUsingEncoding:(current application’s NSUTF8StringEncoding)
　　return encodedStr as string
end encodeURL

★Click Here to Open This Script　

Shaneからツッコミが入って「stringByAddingPercentEscapesUsingEncoding: はdeprecatedだよー」とのこと。こんな細かいところでAPIが入れ替わっているとはおそろしいところです。

AppleScript名：辞書.appで指定の単語を検索する v4

— Created 2017-09-19 by Takaaki Naganoya
— Modified 2020-07-09 by Shane Stanley
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aText to text returned of (display dialog "Input keyword to search" default answer "")
set encText to encodeURL(aText) of me
activate application "Dictionary"

set aURL to "dict://" & encText
open location aURL

on encodeURL(origStr as string)
　　set aStr to current application’s NSString’s stringWithString:origStr
　　set encodedStr to aStr’s stringByAddingPercentEncodingWithAllowedCharacters:(current application’s NSCharacterSet’s URLHostAllowedCharacterSet())
　　–It’s just that stringByAddingPercentEscapesUsingEncoding: is deprecated.
　　return encodedStr as string
end encodeURL

★Click Here to Open This Script　

(Visited 41 times, 1 visits today)

アラートダイアログ上にWebViewでChart.jsを表示（Pie Chart） v2

Posted on 6月 15, 2020 by Takaaki Naganoya

Chart.jsを用いてアラートダイアログ上に円グラフを表示するAppleScriptです。

サンプルの円グラフの色使いがいまひとつだったので、Keynoteのグラフの色設定を読み取って利用しています。

ネットワーク接続チェックなど、必要な処理はひととおり行なっている、実戦レベルに近いものです。

さまざまなJavaScript系のグラフ表示のプログラムを試してみましたが、Chart.jsはとてもいい感じです。

AppleScript名：アラートダイアログ上にWebViewでChart.jsを表示（Pie Chart） v2.scptd

set aList to {"field1", "field2", "field3", "field4", "field5"}
set cList to {38, 31, 21, 10, 1}
set dMes1 to "Pie chart Test"
set dMes2 to "This is a simple Donut chart using charts.js"

displayPieChart(aList, cList, dMes1, dMes2) of pieChartLib

script pieChartLib
　　—
　　–　　Created by: Takaaki Naganoya
　　–　　Created on: 2020/06/12
　　—
　　–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
　　—
　　use AppleScript version "2.4" — Yosemite (10.10) or later
　　use framework "Foundation"
　　use framework "AppKit"
　　use framework "WebKit"
　　use scripting additions
　　
　　property |NSURL| : a reference to current application’s |NSURL|
　　property NSAlert : a reference to current application’s NSAlert
　　property NSString : a reference to current application’s NSString
　　property NSButton : a reference to current application’s NSButton
　　property WKWebView : a reference to current application’s WKWebView
　　property WKUserScript : a reference to current application’s WKUserScript
　　property NSURLRequest : a reference to current application’s NSURLRequest
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSJSONSerialization : a reference to current application’s NSJSONSerialization
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
　　property WKUserContentController : a reference to current application’s WKUserContentController
　　property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
　　property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd
　　
　　property returnCode : 0
　　property parent : AppleScript
　　
　　
　　on displayPieChart(aList, cList, dMes1, dMes2)
　　　　–Error Check
　　　　if length of aList is not equal to length of cList then error "Wrong Parameter items"
　　　　if length of aList > 18 then error "Too much items"
　　　　
　　　　set aRes to hasInternetConnection("https://cdnjs.cloudflare.com") of me
　　　　if aRes = false then error "Internet connection lost"
　　　　
　　　　–Data convert to JSON strings
　　　　set aJsonStr to array2DToJSONArray(aList) of me
　　　　set cJsonStr to array2DToJSONArray(cList) of me
　　　　
　　　　–Pie Chart Template HTML
　　　　set myStr to "<!DOCTYPE html>
<html lang=＼"ja＼">
<head>
<meta charset=＼"utf-8＼">
　<title>Graph</title>
</head>
<body>
<canvas id=＼"myPieChart＼"></canvas>
<script src=＼"https://cdnjs.cloudflare.com/ajax/libs/Chart.js/2.7.2/Chart.bundle.js＼"></script>

<script>
var ctx = document.getElementById(＼"myPieChart＼");
var myPieChart = new Chart(ctx, {
type: ’pie’,
data: {
labels: %@,
datasets: [{
backgroundColor: %@,
data: %@
}]
},
options: {
title: {
display: false,
text: ＼"＼"
}
}
});
</script>
</body>
</html>"
　　　　–Color Table From Apple Keynote
　　　　set bList to {"#118EFE", "#53D529", "#F5AD10", "#FC0007", "#8B2659", "#2A2A2A", "#118EFE", "#53D529", "#F5AD10", "#FC0007", "#8B2659", "#2A2A2A", "#118EFE", "#53D529", "#F5AD10", "#FC0007", "#8B2659", "#2A2A2A"}
　　　　set bJsonStr to array2DToJSONArray(bList) of me
　　　　
　　　　set aString to NSString’s stringWithFormat_(myStr, aJsonStr, bJsonStr, cJsonStr) as string
　　　　
　　　　set paramObj to {myMessage:dMes1, mySubMessage:dMes2, htmlStr:aString}
　　　　–my browseStrWebContents:paramObj–for debug
　　　　my performSelectorOnMainThread:"browseStrWebContents:" withObject:(paramObj) waitUntilDone:true
　　end displayPieChart
　　
　　on browseStrWebContents:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set htmlString to (htmlStr of paramObj)
　　　　
　　　　set aWidth to 920
　　　　set aHeight to 500
　　　　
　　　　–WebViewをつくる
　　　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　　　
　　　　–指定HTML内のJavaScriptをFetch
　　　　set jsSource to pickUpFromToStr(htmlString, "<script>", "</script>") of me
　　　　
　　　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　　　set userContentController to WKUserContentController’s alloc()’s init()
　　　　userContentController’s addUserScript:(userScript)
　　　　aConf’s setUserContentController:userContentController
　　　　
　　　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) configuration:aConf
　　　　aWebView’s setNavigationDelegate:me
　　　　aWebView’s setUIDelegate:me
　　　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　　　using terms from scripting additions
　　　　　　set bURL to |NSURL|’s fileURLWithPath:(POSIX path of (path to me))
　　　　end using terms from
　　　　aWebView’s loadHTMLString:htmlString baseURL:(bURL)
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　–its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:aWebView
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　
　　　　–Stop Web View Action
　　　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　　　set bReq to NSURLRequest’s requestWithURL:bURL
　　　　aWebView’s loadRequest:bReq
　　　　
　　　　if (my returnCode as number) = 1001 then error number -128
　　end browseStrWebContents:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　on viewDidLoad:aNotification
　　　　return true
　　end viewDidLoad:
　　
　　
　　on fetchJSSourceString(aURL)
　　　　set jsURL to |NSURL|’s URLWithString:aURL
　　　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　　　return jsSourceString
　　end fetchJSSourceString
　　
　　
　　on pickUpFromToStr(aStr as string, s1Str as string, s2Str as string)
　　　　set a1Offset to offset of s1Str in aStr
　　　　if a1Offset = 0 then return false
　　　　set bStr to text (a1Offset + (length of s1Str)) thru -1 of aStr
　　　　set a2Offset to offset of s2Str in bStr
　　　　if a2Offset = 0 then return false
　　　　set cStr to text 1 thru (a2Offset – (length of s2Str)) of bStr
　　　　return cStr as string
　　end pickUpFromToStr
　　
　　
　　on array2DToJSONArray(aList)
　　　　set anArray to NSMutableArray’s arrayWithArray:aList
　　　　set jsonData to NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value) –0 is
　　　　set resString to NSString’s alloc()’s initWithData:jsonData encoding:(NSUTF8StringEncoding)
　　　　return resString
　　end array2DToJSONArray
　　
　　
　　on parseByDelim(aData, aDelim)
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to aDelim
　　　　set dList to text items of aData
　　　　set AppleScript’s text item delimiters to curDelim
　　　　return dList
　　end parseByDelim
　　
　　on hasInternetConnection(aURL)
　　　　set aURL to current application’s |NSURL|’s alloc()’s initWithString:aURL
　　　　set aReq to current application’s NSURLRequest’s alloc()’s initWithURL:aURL cachePolicy:(current application’s NSURLRequestReloadIgnoringLocalCacheData) timeoutInterval:5.0
　　　　set urlRes to (current application’s NSURLConnection’s sendSynchronousRequest:aReq returningResponse:(missing value) |error|:(missing value))
　　　　if urlRes = missing value then
　　　　　　return false
　　　　else
　　　　　　return true
　　　　end if
　　end hasInternetConnection
end script

★Click Here to Open This Script　

(Visited 159 times, 1 visits today)

Automator Actionを実行 v3

Posted on 6月 7, 2020 by Takaaki Naganoya

指定のAutomator Actionをパラメータ指定つきで実行するAppleScriptです。

Automatorは、登場当初から「なにこれ、仕様がダメダメじゃん」という感想しかありませんでした。

各Actionをキーワード検索できる仕様になっているものの、検索キーワードが固定で、ゆらぎを許容しない狂気の仕様。

その割に、ものによっては「写真」だったり「画像」だったりと、検索キーワードがゆらぎまくっています。とくに日本語などという同義語がたくさん存在する系の言語では、その苦痛は尋常なものではありません。

＃　フィードバックしたものの、Apple側が聞く耳持たない感じだったのでVersion 1.0で見捨てました

おまけに、まとまった処理を書こうとすると、途中の処理をつなぐActionがごっそり存在せず、あとはひたすら普通にAppleScriptを書くことに。気がつくと、スクリプトエディタで書いたほうがはるかに速い……とまあ、自分とAutomatorの相性は最悪です。

とはいえ、この先何があるかわかりません。Automatorにしかない機能を呼び出さないと実現できない（奇特な）処理に遭遇するかもしれません。Automator Actionを呼び出す方法についても、一応経験を積んでおくべきでしょう。

AMWorkflow経由でAutomator Actionを呼び出したとき、指定できるパラメータはAction自体のURLと、inputパラメータ。

inputパラメータについては、指定したものがそのままAutomator Action側に伝えられるようです。

Automator Action側のinputにこのinputパラメータの内容が伝えられるようです。一方のparametersパラメータについては、

{|temporary items path|:"/var/folders/h4/...../1/com.apple.Automator.RunScript", ignoresInput:false, source:"on run {input, parameters}
	set aClass to convToStr(input)
	display dialog aClass as string
....

のような内容になっていました。

若干間違っていたのと、AMWorkflowを呼び出すのにメインスレッド実行を強制する必要はなかったので修正版を掲載しておきます。

AppleScript名：Automator Actionを実行 v3.1

–Original By Shane Stanley 2020/1/28
–https://www.macscripter.net/viewtopic.php?id=47364
–Modified by Takaaki Naganoya 2020/6/4
–Error reported by hiro 2020/6/10
use AppleScript version "2.5" — macOS 10.11 or later
use framework "Foundation"
use framework "Automator"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property AMWorkflow : a reference to current application’s AMWorkflow

set thePath to POSIX path of (choose file of type {"com.apple.automator-workflow"})
set {theResult, theError} to runWorkflow(thePath, "AAA") of me
–> {<NSAppleEventDescriptor: ’utxt’("OK")>, missing value}

on runWorkflow(thePath, theInput)
　　set theURL to |NSURL|’s fileURLWithPath:thePath
　　set {theResult, theError} to AMWorkflow’s runWorkflowAtURL:(theURL) withInput:theInput |error|:(reference)
　　return {theResult, theError}
end runWorkflow

★Click Here to Open This Script　

(Visited 268 times, 4 visits today)

アラートダイアログ上にWebViewでGoogle Chartを表示（Bar Chart）

Posted on 5月 30, 2020 by Takaaki Naganoya

アラートダイアログ上にWkWebViewを配置し、Google Chartsを用いてbarChartを表示するAppleScriptです。

Googleのオンラインドキュメント品質が一定になっておらず、一番簡単なはずの棒グラフを書かせるのに手間取ってしまいました。

Cocoa Scriptingを始めた当初は、このJavaScriptを含んだHTMLコンテンツをダイアログ上に表示してインタラクティブな表示を行わせるなど、夢のまた夢という感じでしたが、いまでは見慣れた光景になってしまいました。

箱庭ダイアログ系AppleScriptも、YouTubeの動画表示ができるようになった頃から、進化にはずみがついた気がします。

ひととおりGoogle Chartsを表示できるようになったので、チャート表示のScript Libraryにまとめ、sdef（AppleScript用語辞書）をかぶせてカプセル化するといい感じでしょうか。Google Charts Scripting Libとかいって、display google chartコマンドを実行するのでしょうか。そこまで作り込むと、無料公開は勘弁して欲しいところですけれども。

AppleScript名：アラートダイアログ上にWebViewでGoogle Chartを表示（Bar Chart）v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/02
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSAlert : a reference to current application’s NSAlert
property NSString : a reference to current application’s NSString
property NSButton : a reference to current application’s NSButton
property WKWebView : a reference to current application’s WKWebView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property WKUserContentController : a reference to current application’s WKUserContentController
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property returnCode : 0

set aList to {{"City", "2010 Population", "2000 Population"}, ¬
　　{"New York City, NY", 8175000, 8008000}, ¬
　　{"Los Angeles, CA", 3792000, 3694000}, ¬
　　{"Chicago, IL", 2695000, 2896000}, ¬
　　{"Houston, TX", 2099000, 1953000}, ¬
　　{"Philadelphia, PA", 1526000, 1517000}}

set aJsonArrayStr to array2DToJSONArray(aList) of me

–Pie Chart Template HTML
set myStr to "<!DOCTYPE html>
<html lang=＼"UTF-8＼">
<head>
<script type=＼"text/javascript＼" src=＼"https://www.gstatic.com/charts/loader.js＼"></script>

// Draw the chart and set the chart values
function drawChart() {
var data =google.visualization.arrayToDataTable(%@);

// Optional; add a title and set the width and height of the chart
var options = {
　　title: ’Population’,
　　chartArea: {width: ’400’},
　　isStacked: true,
　　hAxis: {
　　 title: ’Total Population’,
　　 minValue: 0,
　　},
　　vAxis: {
　　 title: ’City’
　　}
};

// Display the chart inside the <div> element with id=＼"barchart＼"
var chart = new google.visualization.BarChart(document.getElementById(＼"barchart_values＼"));
chart.draw(data, options);
}
</script>
<body>
<div id=＼"barchart_values＼" style=＼"width: 800px; height: 200;＼"></div>
</body>
</html>"

set aString to current application’s NSString’s stringWithFormat_(myStr, aJsonArrayStr) as string

set paramObj to {myMessage:"Bar Chart Test", mySubMessage:"This is a simple bar chart using google charts", htmlStr:aString}
–my browseStrWebContents:paramObj–for debug
my performSelectorOnMainThread:"browseStrWebContents:" withObject:(paramObj) waitUntilDone:true

on browseStrWebContents:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set htmlString to (htmlStr of paramObj)
　　
　　set aWidth to 820
　　set aHeight to 220
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定HTML内のJavaScriptをFetch
　　set jsSource to pickUpFromToStr(htmlString, "<script type=＼"text/javascript＼">", "</script>") of me
　　
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　using terms from scripting additions
　　　　set bURL to |NSURL|’s fileURLWithPath:(POSIX path of (path to me))
　　end using terms from
　　aWebView’s loadHTMLString:htmlString baseURL:(bURL)
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　–its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aWebView
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　if (my returnCode as number) = 1001 then error number -128
end browseStrWebContents:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

on fetchJSSourceString(aURL)
　　set jsURL to |NSURL|’s URLWithString:aURL
　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　return jsSourceString
end fetchJSSourceString

on pickUpFromToStr(aStr as string, s1Str as string, s2Str as string)
　　set a1Offset to offset of s1Str in aStr
　　if a1Offset = 0 then return false
　　set bStr to text (a1Offset + (length of s1Str)) thru -1 of aStr
　　set a2Offset to offset of s2Str in bStr
　　if a2Offset = 0 then return false
　　set cStr to text 1 thru (a2Offset – (length of s2Str)) of bStr
　　return cStr as string
end pickUpFromToStr

–リストを任意のデリミタ付きでテキストに
on retArrowText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retArrowText

on array2DToJSONArray(aList)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　set jsonData to current application’s NSJSONSerialization’s dataWithJSONObject:anArray options:(0 as integer) |error|:(missing value) –0 is
　　set resString to current application’s NSString’s alloc()’s initWithData:jsonData encoding:(current application’s NSUTF8StringEncoding)
　　return resString
end array2DToJSONArray

on parseByDelim(aData, aDelim)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set dList to text items of aData
　　set AppleScript’s text item delimiters to curDelim
　　return dList
end parseByDelim

★Click Here to Open This Script　

(Visited 73 times, 1 visits today)

NSURLSessionでREST API呼び出しv4.4.2a

Posted on 4月 3, 2020 by Takaaki Naganoya

REST API呼び出しに欠かせない部品をアップデートしました。URLキャッシュが効くようになったような気がします。

–> GET method REST API v4.4.1
–> GET method REST API v4.4
–> GET method REST API v4.3
–> GET method REST API v4.1
–> GET method REST API v4

前バージョンではmacOS 10.15上でクラッシュしないかわりにURLキャッシュが効かないという特徴がありました。ただ、edama2さんと協議した結果、macOS 10.15上でクラッシュする原因と考えられていた内容にあまり根拠がないことがわかってきました（人ごとではなく自分のことなのですが）。

可能な範囲でトライアル＆エラーで調査を行なったところ、本バージョンのような処理に落ち着きました。AppleScriptからのCocoa利用については明確にドキュメントがAppleから出ているわけではないので、すでに存在するObjective-Cのプログラムの処理を参考にしつつ、Objective-CからAppleScriptへの置き換えが可能かを検討しています。

URLキャッシュについては、（当然のことながら）処理１回目には効きません。なぜか２回目も効きません。３回目とか４回目あたりから効いていることが実感できる感じです（回数ではなく、前回処理時からの経過時間を見ているのかも？　GUIアプリケーションに入れて使うと２回目から効いたりします）。URLキャッシュが効いていない場合には1.5秒ぐらい、URLキャッシュが効き出すと0.02秒ぐらいで結果が返ってきています。

macOS 10.13/14/15で検証を行い、繰り返し処理を行ってもクラッシュしないことを確認しています。ただ、動作保証するというレベルではないので（本Blog掲載のScriptすべてそうですが）、問題があったら知らせてください。

ためしに、Xcode上で作成したGUIベースのAppleScriptアプリケーションに本処理を導入したところ、REST APIへの問い合わせがキャッシュされて著しい高速化を実現できました。

AppleScript名：GET method REST API v4.4.2a_wikipedia.scptd

— Created 2019-05-02 by Takaaki Naganoya
— Modified 2020-04-03 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLCache : a reference to current application’s NSURLCache
property NSURLSession : a reference to current application’s NSURLSession
property NSMutableData : a reference to current application’s NSMutableData
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSOperationQueue : a reference to current application’s NSOperationQueue
property NSURLComponents : a reference to current application’s NSURLComponents
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration
property NSURLRequestReturnCacheDataElseLoad : a reference to current application’s NSURLRequestReturnCacheDataElseLoad

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false
property aSession : missing value
property aCache : missing value

on run
　　set retData to missing value
　　set drecF to false
　　set aSession to missing value
　　
　　set aQueryKeyTitle to "AppleScript"
　　set aRes to getWikiText(aQueryKeyTitle) of me
　　return aRes
end run

on getWikiText(aQueryKeyTitle)
　　set reqURLStr to "https://en.wikipedia.org/w/api.php"
　　set aRec to {action:"parse", page:aQueryKeyTitle, |prop|:"wikitext", format:"json"}
　　set aURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set aRes to callRestGETAPIAndParseResults(aURL, 5) of me
　　if aRes = missing value then return false
　　
　　set bRes to (aRes’s valueForKeyPath:"parse.wikitext.*") as string
　　return bRes
end getWikiText

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set (my retData) to NSMutableData’s alloc()’s init()
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　–if my aCache = missing value then
　　set cachePath to (POSIX path of (path to library folder from user domain)) & "/Caches/AppleScriptURLCache"
　　set my aCache to NSURLCache’s alloc()’s initWithMemoryCapacity:512000 diskCapacity:1024 * 1024 * 5 diskPath:cachePath
　　–end if
　　NSURLCache’s setSharedURLCache:(my aCache)
　　
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　aConfig’s setRequestCachePolicy:(NSURLRequestReturnCacheDataElseLoad)
　　
　　aConfig’s setURLCache:(my aCache)
　　
　　–どちらでも速度差がない
　　set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(NSOperationQueue’s mainQueue())
　　–set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　aTask’s resume() –Start URL Session
　　
　　repeat (1000 * timeoutSec) times
　　　　if (my drecF) is not equal to false then
　　　　　　exit repeat
　　　　end if
　　　　delay "0.001" as real
　　end repeat
　　
　　–delegateの無効化
　　my aSession’s finishTasksAndInvalidate()
　　set my aSession to missing value
　　
　　return my parseSessionResults()
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　(my retData)’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

on URLSession:tmpSession task:tmpTask didCompleteWithError:tmpError
　　if tmpError = missing value then
　　　　set (my drecF) to true
　　else
　　　　error "Donwload Failed"
　　end if
end URLSession:task:didCompleteWithError:

on parseSessionResults()
　　set resStr to NSString’s alloc()’s initWithData:(my retData) encoding:(NSUTF8StringEncoding)
　　set jsonString to NSString’s stringWithString:(resStr)
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　return aJsonDict
end parseSessionResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

(Visited 72 times, 1 visits today)

NSURLSessionでREST API呼び出しv4.4.1

Posted on 4月 2, 2020 by Takaaki Naganoya

REST API呼び出しに欠かせない部品をアップデートしました。macOS 10.15でクラッシュしないように書き換えています。

–> GET method REST API v4.4
–> GET method REST API v4.3
–> GET method REST API v4.1
–> GET method REST API v4

前バージョンではmacOS 10.15上でクラッシュするかわりにmacOS 10.14上で高速という特徴がありました。ただ、macOS 10.15上でクラッシュしないように調整を行っていくと、処理速度については別段速くもなく（キャッシュがヒットしていない雰囲気）、よりいっそうキャッシュについて調べる必要が出てきています。

一応、キャッシュの作り方については調べてみたものの、

キャッシュが効いている雰囲気がまったくありません。

キャッシュの内容を確認してみると、からっぽですね（＾ー＾；　もう少し（時間のあるときに）キャッシュの連携などを調べておくといいのかもしれません。最低限、macOS 10.15でクラッシュしなくなったので、NSURLConnectionを呼び出してリジェクトを喰らわないように準備しておくという感じでしょうか。

AppleScript名：GET method REST API v4.4.1_wikipedia.scptd

— Created 2019-05-02 by Takaaki Naganoya
— Modified 2020-04-02 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSMutableData : a reference to current application’s NSMutableData
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false
property aSession : missing value
property aCache : missing value

on getWikiText(aQueryKeyTitle)
　　set reqURLStr to "https://en.wikipedia.org/w/api.php"
　　set aRec to {action:"parse", page:aQueryKeyTitle, |prop|:"wikitext", format:"json"}
　　set aURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set aRes to callRestGETAPIAndParseResults(aURL, 5) of me
　　if aRes = missing value then return "Error"
　　
　　set bRes to (aRes’s valueForKeyPath:"parse.wikitext.*") as string
　　return bRes
end getWikiText

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set (my retData) to NSMutableData’s alloc()’s init()
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　–if my aCache = missing value then
　　set cachePath to (POSIX path of (path to library folder from user domain)) & "/Caches/AppleScriptURLCache"
　　set my aCache to current application’s NSURLCache’s alloc()’s initWithMemoryCapacity:512000 diskCapacity:1024 * 1024 * 5 diskPath:cachePath
　　–end if
　　current application’s NSURLCache’s setSharedURLCache:(my aCache)
　　
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set v2 to system attribute "sys2" –> 14
　　if v2 < 15 then
　　　　–macOS 10.14まで
　　　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　else
　　　　–macOS 10.15以降。10.15でdefaultSessionConfigurationを使うとクラッシュしやすい？？？
　　　　set identifier to "BackgroundSessionConfiguration"
　　　　set aConfig to NSURLSessionConfiguration’s backgroundSessionConfiguration:(identifier)
　　end if
　　
　　aConfig’s setRequestCachePolicy:(current application’s NSURLRequestReturnCacheDataElseLoad)
　　
　　aConfig’s setURLCache:(my aCache)
　　–aConfig’s setTimeoutIntervalForRequest:0.5
　　–aConfig’s setTimeoutIntervalForResource:timeoutSec
　　–aConfig’s setWaitsForConnectivity:false
　　
　　–どちらでも速度差がない
　　set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(current application’s NSOperationQueue’s mainQueue())
　　–set my aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　aTask’s resume() –Start URL Session
　　
　　repeat (1000 * timeoutSec) times
　　　　if (my drecF) is not equal to false then
　　　　　　exit repeat
　　　　end if
　　　　delay "0.001" as real
　　end repeat
　　
　　–aSession’s invalidateAndCancel() –delegateの無効化
　　my aSession’s finishTasksAndInvalidate()
　　set my aSession to missing value
　　
　　return my parseSessionResults()
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　(my retData)’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

on URLSession:tmpSession dataTask:tmpTask willCacheResponse:cacheRes completionHandler:aHandler
　　set (my drecF) to true
end URLSession:dataTask:willCacheResponse:completionHandler:

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

(Visited 87 times, 1 visits today)

NSURLSessionでREST API呼び出しv4.4

Posted on 3月 29, 2020 by Takaaki Naganoya

REST API呼び出しに欠かせない部品をアップデートしました。

–> GET method REST API v4.3
–> GET method REST API v4.1
–> GET method REST API v4

従来、NSURLConnectionを使って同期処理を行っていましたが、これがDepreceted扱いになりました。すぐになくなることはありませんが、いつかなくなる可能性があります。

このため、NSURLConnectionから動作原理の異なるNSURLSessionを使うよう移行する必要があります（curlコマンドを利用するというルートもあります）。

とはいえ、blocks構文の使えないAppleScriptでこのNSURLSessionを使えるようにするのは大変です。非同期通信を行うNSURLSessionを非同期処理のしにくいAppleScriptで、同期処理っぽく書かなくてはなりません。

NSURLSessionによる通信では、サーバーとの間で何回かのやりとりがあって、データを小分けに複数回受信する必要がありました。NSMutableDataというオブジェクトの存在を知ったのでいい感じに処理できるようになってきました。

NSURLSessionのメリットとして喧伝されている非同期処理は、AppleScriptから呼び出しているかぎりはそれほどメリットになりません。もう少し使い込めば活用できるかもしれませんが、まだそういう段階にはありません。

NSURLSessionの導入によって得られるメリットで最大のものは、キャッシュ機構です。NSURLConnectionでもキャッシュ機構は利用できましたが、NSURLSessionではよりAPIに深く統合されているものと理解しました。

キャッシュの効き方については、設定で何段階かに設定できるとAppleのオンラインドキュメントに書かれています。本Scriptでは、キャッシュ優先でキャッシュが存在している場合にはキャッシュ内のデータを返し、キャッシュが存在していない場合にはWebサーバーに問い合わせを行うように設定しています。

キャッシュが効いている状況なら、NSURLConnectionで1.8秒ぐらいの処理がNSURLSessionで0.1秒程度と大幅に速く処理できます。キャッシュが効いていない状況（初回実行時）だと、NSURLSessionのほうがやや処理に時間がかかるぐらいです。

処理結果について、NSURLConnection版とNSURLSession版で結果の比較を行ってみましたが、とくに差異は見られませんでした。

本サンプルScriptでは、Wikipedia（英語版）へのキーワードの問い合わせを行います。NSURLConnection版では複数回実行しても同じぐらいの速度で実行されますが、NSURLSession版では２度目から早く終わります（Script Debugger上で動かすと秒以下の精度の時間がわかります）。

macOS 10.14上で作ってmacOS 10.14.6/10.13.6上で動作確認しています（スクリプトエディタ、Script Debuggerで動作確認）。ただし、macOS 10.15上だとクラッシュします。Xcodeのプロジェクトに入れてみましたが、同様にmacOS 10.15上ではクラッシュします。

ただし、自分のmacOS 10.14.6環境はSIP解除しているのと、macOS 10.15環境のクラッシュログにSIP関連のメッセージが残っているので、OSバージョンではなくSIPのためかもしれません（macOS 10.14.6でもSIPを有効にするとクラッシュするかもしれない　＆　macOS 10.15.xでもSIPを無効にするとクラッシュしないかもしれない）。

AppleScript名：GET method REST API v4.4_wikipedia

— Created 2019-05-02 by Takaaki Naganoya
— Modified 2020-03-29 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property retData : missing value
property retCode : 0
property retHeaders : 0
property drecF : false

set aQueryKeyTitle to "Steve Jobs" –キーワードの正規化が必要（"戦場の絆"→"機動戦士ガンダム戦場の絆" ）
set reqURLStr to "https://en.wikipedia.org/w/api.php"
set aRec to {action:"parse", page:aQueryKeyTitle, |prop|:"wikitext", format:"json"}
set aURL to retURLwithParams(reqURLStr, aRec) of me

set aRes to callRestGETAPIAndParseResults(aURL, 10) of me
set bRes to (aRes’s valueForKeyPath:"parse.wikitext.*") as string
return bRes

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set (my retData) to NSMutableData’s alloc()’s init()
　　set (my retCode) to 0
　　set (my retHeaders) to {}
　　set (my drecF) to false
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　aConfig’s setRequestCachePolicy:(current application’s NSURLRequestReturnCacheDataElseLoad)
　　set aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　aTask’s resume() –Start URL Session
　　
　　repeat (10 * timeoutSec) times
　　　　if (my drecF) = true then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　return my parseSessionResults()
end callRestGETAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　(my retData)’s appendData:tmpData
end URLSession:dataTask:didReceiveData:

on URLSession:tmpSession dataTask:tmpTask didCompleteWithError:tmpError
　　set (my drecF) to true
end URLSession:dataTask:didCompleteWithError:

on URLSession:tmpSession dataTask:tmpTask willCacheResponse:cacheRes completionHandler:aHandler
　　set (my drecF) to true
end URLSession:dataTask:willCacheResponse:completionHandler:

on urlencodeStr(aStr)
　　set aString to current application’s NSString’s stringWithString:aStr
　　set aString to (aString’s stringByAddingPercentEncodingWithAllowedCharacters:(current application’s NSCharacterSet’s URLQueryAllowedCharacterSet())) as text
　　return aString
end urlencodeStr

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　set bList to filteredArray as {list, missing value}
　　return bList
end filterRecListByLabel1

★Click Here to Open This Script　

AppleScript名：GET method REST API_wikipedia

— Created 2016-03-03 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aRes to callRestGETAPIAndParseResults(aURL, 10) of me
set aRESTres to json of aRes
set bRes to (aRESTres’s valueForKeyPath:"parse.wikitext.*") as string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL, timeoutSec)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setTimeoutInterval:timeoutSec
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　aRequest’s setValue:"AppleScript/Cocoa" forHTTPHeaderField:"User-Agent"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code
　　set dRes to contents of second item of resList
　　set resCode to (dRes’s statusCode()) as integer
　　
　　–Get Response Header
　　set resHeaders to (dRes’s allHeaderFields()) as record
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
　　
end callRestGETAPIAndParseResults

★Click Here to Open This Script　

(Visited 84 times, 1 visits today)

WebKit Utilities v2

Posted on 3月 16, 2020 by Takaaki Naganoya

AppleScriptで指定URLのページを表示する「WebKit Utilities」がmacOS 10.13以降の環境で動かなくなっていたので、書き換えて動くようにしておきました。

–> Download WebKit Utilities_archive v2

これ自体が役に立ったということはなく、単にAppleScript Librariesの書き方のサンプルと理解しています。Webサイトの表示を行うよりも１枚ものの画像やPDFにレンダリングする処理のほうがバッチ処理の中では相性がいいと思います。

また、このScriptはWkWebViewではなく古いWebViewを使っているので、じきに動かなくなります。

AppleScript名：WebKit Utilitiesで指定URLをウィンドウ表示

— Created 2017-03-24 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use webLib : script "WebKit Utilities"

set targetURL to "http://www.piyocast.com/"
display URL targetURL window size {1024, 1024}

★Click Here to Open This Script　

AppleScript名：WebKit Utilities

— An example AppleScript/Objective-C library that uses the WebKit framework.

use AppleScript
use framework "AppKit"
use framework "WebKit"

property NSURL : a reference to current application’s NSURL
property WebView : a reference to current application’s WebView
property NSScreen : a reference to current application’s NSScreen
property NSThread : a reference to current application’s NSThread
property NSWindow : a reference to current application’s NSWindow
property NSURLRequest : a reference to current application’s NSURLRequest
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

on _DisplayWebWindowWithURL:theURLString windowSize:theWindowSize
　　— Create and display a horizontally centered window with a WebView
　　
　　set {thisWindowWidth, thisWindowHeight} to theWindowSize
　　set screenBounds to the NSScreen’s mainScreen’s visibleFrame as any
　　
　　if class of screenBounds = record then
　　　　set screenWidth to screenBounds’s |size|’s width
　　　　set screenHeight to screenBounds’s |size|’s height
　　　　set windowLeft to ((screenWidth – thisWindowWidth) / 2) + (screenBounds’s origin’s x)
　　　　set windowBottom to screenHeight – thisWindowHeight + (screenBounds’s origin’s y) – 40
　　else
　　　　copy screenBounds to {{originX, originY}, {screenWidth, screenHeight}}
　　　　set windowLeft to ((screenWidth – thisWindowWidth) / 2) + originX
　　　　set windowBottom to screenHeight – thisWindowHeight + originY – 40
　　end if
　　
　　set theStyleMask to (get current application’s NSTitledWindowMask) + (get current application’s NSClosableWindowMask) + (get current application’s NSMiniaturizableWindowMask) + (get current application’s NSResizableWindowMask)
　　set webWindow to NSWindow’s alloc()’s initWithContentRect:(current application’s NSMakeRect(windowLeft, windowBottom, thisWindowWidth, thisWindowHeight)) ¬
　　　　styleMask:theStyleMask backing:(current application’s NSBackingStoreBuffered) defer:false
　　— set webWindow’s title to "WebView Created with AppleScript – " & theURLString
　　
　　set theWebView to WebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, thisWindowWidth, thisWindowHeight)) ¬
　　　　frameName:"WebKit Frame" groupName:"WebKit Group"
　　set webWindow’s contentView to theWebView
　　
　　tell webWindow to makeKeyAndOrderFront:(missing value)
　　
　　— Start loading the URL
　　
　　set theURL to NSURL’s URLWithString:theURLString
　　set theURLRequest to NSURLRequest’s requestWithURL:theURL
　　tell theWebView’s mainFrame to loadRequest:theURLRequest
　　
　　webWindow
end _DisplayWebWindowWithURL:windowSize:

— The following two handlers exist to deal with running on a background thread.
— If we’re on a background thread, we have to run the UI code on the main thread.

on _DisplayWebWindowMainThread:parameterDictionary
　　try
　　　　set theURLString to parameterDictionary’s objectForKey:"url string"
　　　　set theWindowSize to parameterDictionary’s objectForKey:"window size"
　　　　
　　　　set webWindow to my _DisplayWebWindowWithURL:theURLString windowSize:theWindowSize
　　　　
　　　　tell parameterDictionary to setObject:webWindow forKey:"result"
　　on error errMsg number errNum
　　　　using terms from scripting additions
　　　　　　display alert "Error!" message errMsg & " (" & errNum & ")"
　　　　end using terms from
　　　　tell parameterDictionary to setObject:{errMsg, errNum} forKey:"error"
　　end try
end _DisplayWebWindowMainThread:

on display URL theURLString window size theWindowSize
　　— All UI methods must be invoked on the main thread.
　　if (NSThread’s isMainThread) then
　　　　my _DisplayWebWindowWithURL:theURLString windowSize:theWindowSize
　　else
　　　　— Parameters, results and error information are communicated between threads via a dictionary.
　　　　set parameterDictionary to NSMutableDictionary’s dictionary()
　　　　tell parameterDictionary to setObject:theURLString forKey:"url string"
　　　　tell parameterDictionary to setObject:theWindowSize forKey:"window size"
　　　　
　　　　its performSelectorOnMainThread:"_DisplayWebWindowMainThread:" withObject:parameterDictionary waitUntilDone:true
　　　　
　　　　— Propagate errors from the other thread
　　　　
　　　　set errInfo to parameterDictionary’s objectForKey:"error"
　　　　if errInfo is not missing value then error errInfo’s first item number errInfo’s second item
　　　　
　　　　parameterDictionary’s objectForKey:"result"
　　end if
end display URL

★Click Here to Open This Script　

(Visited 113 times, 1 visits today)

指定文字列ではじまるURLをオープン中のTabをクローズ

Posted on 3月 1, 2020 by Takaaki Naganoya

Safariでオープン中のウィンドウ/Tabのうち、指定URLではじまるもの（この場合にはGoogle翻訳）をオープン中のものだけをクローズする掃除用のAppleScriptです。

TabのIDを取得して、1から処理するとナンバリングがおかしくなるので、後ろから処理しているあたりが「ワザ」とでもいうべきものでしょうか。

AppleScript名：指定文字列ではじまるURLをオープン中のTabをクローズ

set targURL to "https://translate.google.co.jp" –Google翻訳
closeSafariTabsBeginsWithAURL(targURL) of me

on closeSafariTabsBeginsWithAURL(targURL)
　　tell application "Safari"
　　　　set wCount to (every window whose visible is true)
　　　　
　　　　repeat with w in wCount
　　　　　　set aWin to contents of w
　　　　　　
　　　　　　tell aWin
　　　　　　　　set tabCount to count every tab
　　　　　　　　repeat with t from tabCount to 1 by -1
　　　　　　　　　　tell tab t
　　　　　　　　　　　　set aURL to URL of it
　　　　　　　　　　　　if aURL begins with targURL then
　　　　　　　　　　　　　　close
　　　　　　　　　　　　end if
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　end tell
　　　　　　
　　　　end repeat
　　end tell
end closeSafariTabsBeginsWithAURL

★Click Here to Open This Script　

(Visited 63 times, 1 visits today)

macOS 10.15.2でPDFViewでオープン中のPDFで発生したURLリンクバグが新たなバグを呼ぶ

Posted on 12月 11, 2019 by Takaaki Naganoya

macOS 10.15には、PDFViewでオープン中のPDFで、URLリンクをクリックして発生したURLイベントが正常にデコードされないというバグがあります。本日リリースされたmacOS 10.15.2アップデートでもまともに修正されていないため、その内容についての解説です。

＃　BugReporter経由でバグ報告ずみです。が、、、

macOS 10.15のPDFViewのバグ

macOS 10.15.0で観測されたこのバグは、URL自体がURLエンコードされたまま、デコードされずにアプリケーションに伝わるというものでした。httpなどのメジャーなURLスキームを持つURL以外のマイナーなもの、具体的にいえば「applescript://」URLスキームで失敗することを確認しています。

「applescript://」URLスキームは本Blog掲載のプログラムリストすべてに添付しているURLリンクで、プログラムリスト末尾のリンクをクリックすると内容がスクリプトエディタに転送される仕組みです。

つまり、WkWebViewなりWebViewなりの、WebView系のGUI部品から「applescript://」URLイベントが発生した場合には、macOS 10.15上でも正常に処理できています。

これが、PDFView上では正常に（従来のmacOSと同様には）動作していないというのがmacOS 10.15上のバグです。

macOS 10.15.2でバグが変質

では、macOS 10.15.2 Updateでこれが修正されたかといえば、

　・まったくデコードされないでデータが転送される、という不具合はなくなった
　・しかし、デコードの仕方に問題が残っている。３通りの反応が返ってくる、「頭の悪い修正」が行われた

　　CASE 1：正常にデコードされて伝わる（内容はすべて伝わる）
　　CASE 2：デコードされた内容が途中で途切れる
　　CASE 3：何も伝わらない

CASE 1の反応が返ってくるものは毎回CASE 1の反応が返ります。同様に、CASE 2の反応が返ってくるものは毎回CASE 2。CASE 3も同様です。なにやら、URLデコードした文字列の内容に応じて「データが欠損する」という新たな不具合が発生するようです。

自助努力によるPDFViewのバグ回避は？

OSの基礎的な部分ではなく、PDFViewというバグ連発の部品で発生している状況です。Appleの社内は縦割り組織で、社員が他のチームにアクセスする権限はありません。そのため、コアOSチームとPDFViewのチーム（チーム名は具体的には知りません）が連携する可能性には期待できません。WebViewでは発生していないことから、PDFViewが単独で何かの実装を行なったときにバグを発生させたものと見ています。

macOS 10.15のPDFViewにおけるURLリンクのクリックで発生するバグを回避するために、自前で簡易PDFビューワーを作成しましたが、PDFView上でオープンしたPDF内のURLリンクをクリックした時点でデータが欠損（CASE 2、3）しているため、リンククリックから発生するイベントを横取りして何らかの処理を行なっても補えません。

Appleが従来どおりの実装を行わず、正常に動作しない不具合やバグばかり新たに作り出す理由はわかりませんが、Appleには不用意にバグを追加することはできても、「そのバグが何であるかを認識し、修正する能力がない」と考えたほうがよいでしょう。

CASE 2の「途中で途切れる」パターンについては、現在表示中のページ（currentPage＝単独ページはScripting Bridgeのバグにより取得できないので、見開きページがどれかという判定に）上のすべてのURLリンクを取得し、デコードした内容をすべて取り出して前方一致検索で該当すると思われる内容をスクリプトエディタに転送することは不可能ではありません。

不可能ではないものの、途中で途切れたデータを単なる前方一致検索するだけでは同一のものが複数検出される可能性もあり、ユーザーに対して「あなたがクリックした内容は以下のうちのどれですか？」と間抜けな問い合わせを行う必要が発生してしまいます。

CASE 3についてはお手上げです。何かがクリックされたことしかわかりません。「PDF上のURLリンクのクリックを受信する」という動作には一切期待しないほうがよさそうです。

PDFView上のリンククリック挙動修正に期待できない

PDF上のURLリンクをクリックするとmacOS 10.15のバグに遭遇してしまうので、「applescript://」URLをクリックしても別の機能にフォワードしたほうがよいでしょう。

PDFViewで表示中のPDFの見開きページがどこかはわかるので、そのページ範囲にある「applescript://」URLリンクをすべて取り出し、その内容もデコードして、すべてスクリプトエディタに転送するのがよいでしょう。

最初のバグ状態よりも状況が悪化しているような気もしますが、どんなもんなんでしょう？

(Visited 43 times, 1 visits today)

URLエンコードずみ文字列チェック

Posted on 11月 29, 2019 by Takaaki Naganoya

与えられた文字列がURLエンコードずみ文字列かどうかをチェックするAppleScriptです。

なんでそんなものが必要になったかといえば、macOS 10.15のPDFView上で発生した（”applescript://” schemeの）URL EventがデコードされずにOSデフォルト指定のスクリプトエディタに転送される、URLデコード不良バグが発生。これに対処した簡易PDFビューワーも用意しましたが、macOS 10.15.2 Beta3でこのバグが修正されているように見えます。

＃　一度発生したバグは、今後もAppleが再発しないよう継続して監視する必要があります

すると、今度は簡易PDFビューワー側でURLイベントをデコードしてからScript Editorに転送している処理が「余計」になってしまいます。再デコードした文字列は途中で途切れてしまうので、処理対象の文字列がURLエンコードされたものかどうかをチェックする必要が出てきました。

このままOSにURLデコード不良バグが残存するよりは、こうしたプログラムでチェックしてから処理するほうがよいでしょう。

AppleScript名：URLエンコードずみ文字列チェック.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/29
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString

set aStr to "applescript://com.apple.scripteditor?action=new&script=display%20dialog%20%22TEST%22"
set aRes to chkEncodedURLorNot(aStr) of me
–> true –URL Encoded

set bStr to "display dialog ＼"TEST＼""
set bRes to chkEncodedURLorNot(bStr) of me
–> false –Not URL encoded

on chkEncodedURLorNot(aStr)
　　set nsStr to NSString’s stringWithString:aStr
　　set decodedStr to nsStr’s stringByRemovingPercentEncoding()
　　
　　if (nsStr’s isEqualToString:decodedStr) then
　　　　return false –encoded URL
　　else
　　　　return true –Not encoded URL
　　end if
end chkEncodedURLorNot

★Click Here to Open This Script　

(Visited 39 times, 1 visits today)

指定アプリケーション内の現在のLocaleの指定stringsファイル内の指定キーの値を取得する

Posted on 11月 16, 2019 by Takaaki Naganoya

Bundle IDで指定したアプリケーションのバンドル中（/Contents/Resources/）の現在のLocalizationに存在する指定のstringsファイル内で、指定キーの値を取得するAppleScriptです。

アプリケーションバンドル内の各ローカライズフォルダの名称は一意に決定されているものでもなく、ある程度の「ゆらぎ」が生じています。

/Contents/Resources/Japanese.lproj/
/Contents/Resources/ja.lproj/

NSLocaleからcurrentLocale()を取得すると、「ja-JP」のような識別子が得られます。これと上記のパターンのフォルダとの付け合わせのためのメソッドがどこかに存在しているはずなのですが、現状では見つけられていません（ないと各アプリケーションが正しくメニュー表示できていないので）。

まだいまひとつ、しっくりきていません。

AppleScript名：指定アプリケーション内の現在のLocaleの指定stringsファイル内の指定キーの値を取得する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/11/15
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSBundle : a reference to current application’s NSBundle
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSLocaleCountryCode : a reference to current application’s NSLocaleCountryCode
property NSLocaleLanguageCode : a reference to current application’s NSLocaleLanguageCode
property NSLocaleCollatorIdentifier : a reference to current application’s NSLocaleCollatorIdentifier

set targID to "com.apple.iWork.Keynote"
set targFile to "Keynote" –"Keynote.strings" file
set targKey to "Arrange"
set vStr to getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey) of me
–> "配置"

on getAValInASpecifiedStringFileOfAllLocaleInABundle(targID, targFile, targKey)
　　set aPath to retPathFromBundleID(targID) of me
　　
　　set aURL to (|NSURL|’s fileURLWithPath:aPath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　
　　set aLocale to (current application’s NSLocale’s preferredLanguages()’s firstObject()) as string
　　
　　set curLocale to current application’s NSLocale’s currentLocale()
　　set aDS11 to (curLocale’s objectForKey:(NSLocaleLanguageCode)) as string
　　set aDS12 to (curLocale’s objectForKey:(NSLocaleCountryCode)) as string
　　set aDS5 to (curLocale’s objectForKey:(NSLocaleCollatorIdentifier)) as string
　　–set bID to (current application’s NSBundle’s mainBundle()’s preferredLocalizations()’s firstObject()) as string
　　
　　set langIDList to {aDS11, aLocale, aDS12, aDS5} –> {"ja", "ja-JP", "JP", "ja-JP"}
　　
　　repeat with i in langIDList
　　　　set j to contents of i
　　　　set aRes to (aBundle’s pathForResource:targFile ofType:"strings" inDirectory:"" forLocalization:(j))
　　　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:aRes)
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　return aVal as string
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return false
end getAValInASpecifiedStringFileOfAllLocaleInABundle

on getLocalizationsFromBundleID(aBundleID)
　　set aRes to retPathFromBundleID(aBundleID) of me
　　if aRes = false then error "Wrong Bundle ID."
　　return getSpecifiedAppFilesLocalizationListWithDuplication(aRes) of me
end getLocalizationsFromBundleID

–指定アプリケーションファイルの、指定Localeにおけるローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(appPOSIXpath)
　　set aURL to (|NSURL|’s fileURLWithPath:appPOSIXpath)
　　set aBundle to NSBundle’s bundleWithURL:aURL
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on retPathFromBundleID(aBundleID)
　　set aURL to NSWorkspace’s sharedWorkspace()’s URLForApplicationWithBundleIdentifier:aBundleID
　　if aURL = missing value then return false –Error
　　return aURL’s |path|() as string
end retPathFromBundleID

★Click Here to Open This Script　

(Visited 57 times, 1 visits today)

macOS 10.15のPDFViewのバグに対処した簡易PDFリーダー

Posted on 11月 7, 2019 by Takaaki Naganoya

従来のmacOSではPDFリーダー「Skim」上で「applescript://」スキームのURLリンクをクリックした場合に正常にスクリプトエディタ/Script Debuggerに新規スクリプト作成のURLイベントが伝達されていました。

macOS 10.15.xには、PDFView上でPDF閲覧中にクリックしたURLが「applescript://」プロトコルの場合に、正確にデコードされるべき内容がデコードされずにスクリプトエディタに転送されるというバグが確認されています。

このmacOS 10.15のPDFViewのバグに対処するための簡易PDFリーダーのアプリケーション「PiyoREADER」を作成してみました。フリーで配布いたします。コード署名はしてありますが、ダウンロードして初回起動時にハネられるので、システム環境設定の「セキュリティとプライバシー」＞「一般」で「そのまま起動」を選ぶ必要があります。

–> Download PiyoReader(2.1MB)

この簡易PDFリーダーにはもう１つ重要な機能があります。PDF中の「http://」スキームのURLリンククリック時に、本BlogのURLである場合には内部テーブルにもとづきURLをフォワードするという機能です。つまり、2018年1月末のXserver.jpによるBlog消去以前のURLを、現行のBlog上のURLに変換してオープンするというものです。

なお、PDF内に仕込まれた「applescript://」スキームのURLリンクはスクリプトエディタに、「http://」スキームのURLリンクはSafariに伝えるように固定しています。

PiyoReaderはmacOS 10.10以降で動作し、macOS 10.15以外のまともに「applescript://」スキームのURLを扱えるOSでは、「AppleScriptの穴」BlogのURL変換の機能が活用できる簡易PDFリーダーということになります。

Piyomaru Softwareが執筆・刊行している各種電子書籍には「applescript://」URLリンクが埋め込んであり、ご好評をいただいておりますが、この書籍の価値をmacOS 10.15上でも維持するためにこの簡易PDFリーダーを作成する必要に迫られました。こんなバグをAppleが作らなければ必要のなかった作業です。

レポートずみではありますが、Appleがこのバグを認識して早期に修正することを希望してやみません。

(Visited 101 times, 1 visits today)

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す

Posted on 9月 21, 2019 by Takaaki Naganoya

バンドルIDで指定したアプリケーションのResourcesフォルダ中の、指定ロケールのstringsファイルをすべて読み込んでkeyを取り出すAppleScriptです。

アプリケーション内の指定のローカライズしたメッセージ（テキスト）の内容を取り出すことはできますが、そのためにはキーを知っておく必要があります。そのキーを取り出してローカライズされた文字列を取り出すため、キーを調査してみました。

これをそのまま何かのツールなりScriptに使うというものではなく、いわゆる「下調べ」のためのScriptの部品です。

ほぼ、ありもののルーチンを再利用しただけのプログラムでできていますが、ありものはありもので、数千本のAppleScriptのストックからそれを探し出してくるのも一苦労です。

アプリケーションバンドル内のResourcesフォルダ以下の（各lprojフォルダ以下の）stringsファイルの中身はまんま（シリアライズした）NSDictionaryなので、そのままDictionaryに読み込んでallkey()などのメソッドを実行できます。昔のstringsファイルはテキストファイルだったような気がしますが、テキストファイルだとparseしないといけないんで、ビルド時にparseしておいてDictionaryの状態でファイルに書いておくのは正しいと思います。

Xcode 8あたりから、アプリケーションのローカライズのルールが変更になったようで、基本となる言語環境がBase.lprojになり、英語はen.lprojといった１ローカライズ言語という位置付けに変更になりました。

NSLocalizedStringFromTableInBundleを使ってアクセスしようかとも思ったのですが、こちらはまだ目的を達成できていません。

▲Xcode 11上で実験的に作成したAppleScriptアプリケーションのバンドル構造（左）。ローカライズしていない状態だとEnglishではなくBase.lprojが作成される。右はKeynote.app/Contents/Resources/ja.lprojフォルダの内容。stringsファイルが大量に存在している

AppleScript名：指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/21
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSWorkspace : a reference to current application’s NSWorkspace
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants

set targID to "com.apple.iWork.Keynote"

set bRes to getLocalizationsFromBundleID(targID) of me
–>　　{"de", "he", "en_AU", "ar", "el", "ja", "en", "uk", "es_419", "zh_CN", "es", "da", "it", "sk", "pt_PT", "ms", "sv", "cs", "ko", "Base", "no", "hu", "zh_HK", "tr", "pl", "zh_TW", "en_GB", "vi", "ru", "fr_CA", "fr", "fi", "id", "nl", "th", "pt", "ro", "hr", "hi", "ca"}

set curLang to first item of (choose from list bRes)
set aPath to retPathFromBundleID(targID) of me

set aPath to aPath & "/Contents/Resources/" & curLang & ".lproj"
set sList to getFilepathListByUTI(aPath, "com.apple.xcode.strings-text", "POSIX") of me

set aMDict to NSMutableDictionary’s new()

repeat with i in sList
　　set j to contents of i
　　set aDict to (NSDictionary’s alloc()’s initWithContentsOfFile:j)
　　(aMDict’s addEntriesFromDictionary:aDict)
end repeat

return aMDict’s allKeys() as list
–> {"Interactive Bubble Chart", "Rehearse Slideshow", "PMT_ARGUMENT_1", "ACCRINTM_ARGUMENT_4_MODE_0", "Truck_378",….}

on getFilepathListByUTI(aFolPOSIX, aUTI as string, aFileType as string)
　　script spdFile
　　　　property urlList : {}
　　end script
　　
　　if aFileType is not in {"file", "POSIX"} then return {}
　　
　　set aFM to NSFileManager’s defaultManager()
　　set aFolExt to (aFM’s fileExistsAtPath:aFolPOSIX isDirectory:true) as boolean
　　if aFolExt = false then return {} –フォルダ自体が存在しなければヌルリストを返す
　　
　　set aURL to |NSURL|’s fileURLWithPath:aFolPOSIX
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer)
　　set urlArray to (aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value))
　　if urlArray = missing value then return {}
　　
　　set (urlList of spdFile) to urlArray as list
　　set newList to {}
　　
　　repeat with i in (urlList of spdFile)
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, aUTI)
　　　　
　　　　if utiRes is not equal to {} then
　　　　　　if aFileType = "POSIX" then
　　　　　　　　set the end of newList to j
　　　　　　else if aFileType = "file" then
　　　　　　　　set the end of newList to POSIX file j
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return newList
end getFilepathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　

(Visited 57 times, 1 visits today)

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: URL

AS関連データの取り扱いを容易にする（はずの）privateDataTypeLib

applescript:// URL Linkの状況確認

現状の確認

本Blog側の対応

Safariで表示中のYouTubeムービーのサムネイル画像を取得

macOS 12.3上でFinder上で選択中のファイルをそのままオープンできない件

アラートダイアログでMarkdownをプレビュー v3a

SafariでURLローディング完了検出

辞書.appで指定の単語を検索する v3

アラートダイアログ上にWebViewでChart.jsを表示（Pie Chart） v2

Automator Actionを実行 v3

アラートダイアログ上にWebViewでGoogle Chartを表示（Bar Chart）

NSURLSessionでREST API呼び出しv4.4.2a

NSURLSessionでREST API呼び出しv4.4.1

NSURLSessionでREST API呼び出しv4.4

WebKit Utilities v2

指定文字列ではじまるURLをオープン中のTabをクローズ

macOS 10.15.2でPDFViewでオープン中のPDFで発生したURLリンクバグが新たなバグを呼ぶ

macOS 10.15のPDFViewのバグ

macOS 10.15.2でバグが変質

自助努力によるPDFViewのバグ回避は？

PDFView上のリンククリック挙動修正に期待できない

URLエンコードずみ文字列チェック

macOS 10.15のPDFViewのバグに対処した簡易PDFリーダー

指定アプリケーションの指定言語のstringsファイルの内容をすべて取り出す