指定文字のシフトJIS内文字かのチェック

Posted on 2月 28, 2021 by Takaaki Naganoya

指定の文字がシフトJISのコードの範囲に存在しているかどうかをチェックするAppleScriptです。

絵文字とか、日本国内で使われていない（CJK統合漢字のうち日本で使われていない）漢字を除外するために作ってみたものです。もともと、半角文字と全角文字の判定を行うためにNSASCIIStringEncodingに変換できるかどうかを調べるサンプルがあったので、「JIS第１/第２水準文字だけ調べるのに同様の処理で済むのでは？」と考えて試してみたものです。

▲実際のプログラムリスト。プログラムリスト下部のURL Linkをクリックすると、文字列が欠落していないすべての内容がスクリプトエディタ上に転送されます

AppleScript名：指定文字のシフトJIS内文字かのチェック.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/28
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set a1Res to chkSJISChar("微") of me
–> true

set a2Res to chkSJISChar("") of me
–> false

set a3Res to chkSJISChar("熙") of me
–> true

set a4Res to chkSJISChar("") of me
–> false

return {a1Res, a2Res, a3Res, a4Res}
–> {true, false, true, false}

on chkSJISChar(aChar as string)
　　set aStr to current application’s NSString’s stringWithString:aChar
　　set tmpStr1 to (aStr’s canBeConvertedToEncoding:(current application’s NSShiftJISStringEncoding))
　　return tmpStr1 as boolean
end chkSJISChar

★Click Here to Open This Script　

(Visited 33 times, 1 visits today)

私はロボットではありません

Posted on 2月 25, 2021 by Takaaki Naganoya

Web上でクローリングロボットとユーザーが普通にWebブラウズしているのを区別するのに、複数の画像をクリックさせて判定するプログラムが広く利用されています。

AppleScript関連の画像でこれを作るとどうなるのか？　と、考えて手短に作ってみたものです。激ムズです。

意外と難しいので、ほとんどの人類がこれをパスできないはずです。

下段、左：Google Apps Script、中央：Classic Mac OSのAppleScript、右：何か別のもの
上段、左：macOS 11.0上のAppleScript書類（たぶんバグ？）、中央：AppleScript書類、右：VBS

(Visited 98 times, 1 visits today)

指定した文字で囲まれたキーワードの色を置換する

Posted on 2月 24, 2021 by Takaaki Naganoya

Keynoteで現在オープン中の書類の現在表示中のスライド（ページ）中にあるtext itemのうち、開始文字、終了文字ではさまれているテキストを指定色に塗り替えるAppleScriptです。

用途はご覧の通り、現在作成中のCocoa Scripting本の資料の装飾のためであり、「|」と「|」で囲まれている箇所の色を変えたら見やすいのでは？　と、考えて作成・実行したものです。

NSScannerを使えば楽に書けるかも？　などと思っておりましたが、検出位置（文字数）を返す機能がないので、位置だけを返してほしいという用途に向いていないもよう。仕方なく、普通にAppleScriptで１文字ごとチェック＆開始文字/終了文字のチェックをフラグ管理……という、高級言語らしからぬ泥臭いコードを書く羽目に（でも、こういうの書くケースが多いですよね）。

▲実行前

▲実行後

AppleScript名：指定した文字で囲まれたキーワードの色を置換する

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/24
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set targCol to choose color –塗る文字色を選択

set headPickUpChar to "|"
set tailPickUpChar to "|"

–処理対象データの取得
tell application "Keynote"
　　
　　–最前面の書類
　　tell front document
　　　　
　　　　–現在表示中のスライド
　　　　tell current slide
　　　　　　–text itemをすべて取得
　　　　　　set tList to every text item
　　　　　　if tList = {} then return –何もtext itemが存在しなかったら処理終了
　　　　　　
　　　　　　–text itemの中に入っている文字列を取得
　　　　　　set objTList to object text of every text item
　　　　　　
　　　　end tell
　　end tell
end tell

–出現判定しつつ色を塗る
tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　
　　　　　　set posList to {}
　　　　　　set aCount to 1
　　　　　　
　　　　　　–text itemでループ
　　　　　　repeat with i in objTList
　　　　　　　　set j to contents of i
　　　　　　　　
　　　　　　　　–ターゲット文字で囲まれている箇所を検出。複数箇所検出対応
　　　　　　　　set bCon to pickUpPositionPairsFromTo(j, headPickUpChar, tailPickUpChar) of me
　　　　　　　　
　　　　　　　　if bCon is not equal to {} then
　　　　　　　　　　
　　　　　　　　　　set aTarg to item aCount of tList
　　　　　　　　　　
　　　　　　　　　　–出現位置でループ（複数検出対応）
　　　　　　　　　　repeat with ii in bCon
　　　　　　　　　　　　copy ii to {aStart, anEnd}
　　　　　　　　　　　　
　　　　　　　　　　　　–高速処理のために非同期実行
　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　tell aTarg
　　　　　　　　　　　　　　　　set color of characters aStart thru anEnd of object text to targCol
　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　
　　　　　　　　　　end repeat
　　　　　　　　　　
　　　　　　　　end if
　　　　　　　　
　　　　　　　　set aCount to aCount + 1
　　　　　　end repeat
　　　　　　
　　　　end tell
　　end tell
end tell

–開始文字と終了文字に囲われた文字列のすべての位置情報を返す
on pickUpPositionPairsFromTo(aParamStr, fromStr, toStr)
　　script hsAry
　　　　property anArray : {}
　　　　property aList : {}
　　end script
　　
　　set (anArray of hsAry) to {}
　　set (aList of hsAry) to characters of aParamStr
　　
　　set tmpPair to {}
　　set searchMode to 0 — 0:fromStr, 1:toStr
　　set aCount to 1
　　
　　repeat with i in (aList of hsAry)
　　　　set j to contents of i
　　　　
　　　　if searchMode = 0 then
　　　　　　if j = fromStr then
　　　　　　　　set the end of tmpPair to aCount
　　　　　　　　set searchMode to 1
　　　　　　end if
　　　　　　
　　　　else if searchMode = 1 then
　　　　　　if j = toStr then
　　　　　　　　set the end of tmpPair to aCount
　　　　　　　　set searchMode to 0
　　　　　　　　set the end of (anArray of hsAry) to tmpPair
　　　　　　　　set tmpPair to {}
　　　　　　end if
　　　　end if
　　　　
　　　　set aCount to aCount + 1
　　end repeat
　　
　　return (anArray of hsAry)
end pickUpPositionPairsFromTo

★Click Here to Open This Script　

(Visited 74 times, 1 visits today)

AVFAudioでオーディオ再生のじっけん

Posted on 2月 23, 2021 by Takaaki Naganoya

macOS 11.3で追加されたAVFAudio.frameworkを用いてオーディオ再生を行うAppleScriptです。

実行にはmacOS 11.3以降が必要です。オーディオファイル以外（ムービーなど）を渡すと終了します。

AppleScript名：AVFAudio test 1

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/23
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7" — macOS 11.3 or later
use framework "Foundation"
use framework "AppKit"
use framework "AVFAudio"
use scripting additions

set posixPath to POSIX path of (choose file with prompt "Choose an Audio file:")
set theURL to current application’s |NSURL|’s fileURLWithPath:posixPath
set aPlayer to current application’s AVAudioPlayer’s alloc()’s initWithContentsOfURL:theURL |error|:(missing value)
if aPlayer = missing value then return

aPlayer’s play()
delay 30
aPlayer’s |stop|()

★Click Here to Open This Script　

(Visited 200 times, 1 visits today)

構成要素を指定して漢字検索 v3

Posted on 2月 22, 2021 by Takaaki Naganoya

旧称「部首で漢字検索」のバージョンアップ版です。部首ではなく構成部品の文字を指定して漢字を検索するAppleScriptです。

便利な道具ではありますが、あくまでも子供の学習用以外の用途にお使いください。

–> Download kanjiSearchFromPartsV3.zip (AppleScript Bundle with library and JSON files in its bundle)

前バージョンでは常用漢字の範囲を超えるデータが出力されるという問題点があったため、常用漢字の一覧データを作成し、これに合致するものだけを出力するようにしました。

常用漢字との照合処理に時間がかかっており、v2ではAppleScriptのネイティブ機能でループして除外チェックを行なっておりました。これをv3ではCocoaの機能を用いて一括で重複部分の抽出を行うことで、v2の半分の時間で完了できることに。v2で0.6秒程度かかっていたものが、v3では0.3秒を下回る時間で処理できるようになりました（MacBook Pro Core i7 2.66GHz）。

そもそも論でいえば、元のJSONデータから常用漢字＋人名漢字を超える文字の情報を削除すればいいだけの話なので、JSONデータから常用漢字＋人名漢字を超える文字を削除するプログラムを書いて実行するのがよいのでしょう。

AppleScript名：構成要素を指定して漢字検索 v3.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/21
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7"
use framework "Foundation"
use scripting additions
use jkLib : script "jyoyoKanjiLib" –常用漢字一覧を返してくるAppleScriptライブラリ

script jsonStr
　　property aJsonDict : missing value –JSONから読み取ったNSDictionary
　　property jKanji : missing value –常用漢字データ（NSArray）
end script

property NSString : a reference to current application’s NSString
property NSCountedSet : a reference to current application’s NSCountedSet
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

–図形としての構成要素を指定して漢字検索（部首ではない）
–set aRes to searchKanjiFromElementJ("木") of me –きへん？　のぎへんや他のものも返ってくるよ
–> {"椅", "植", "椎", "検", "頼", "漆", "鉢", …}

–set bRes to searchKanjiFromElementJ("氵") of me –さんずい
–> {"滴", "漁", "漂", "漆", "漏", "演", "漠",…}

set dRes to searchKanjiFromElementJ("⻖") of me
–>{"堕", "墜", "阪", "防", "阻", "附", "降"…}

–検索に使える部首のキー文字の一覧を返す
–set qList to listupQueryKeysForKanji() of me
–> {"工", "棘", "左", "位", "婁", "攴", …}

on searchKanjiFromElementJ(aQueryStr)
　　if (aJsonDict of jsonStr) = missing value then my init()
　　if (jKanji of jsonStr) = missing value then my initJ()
　　set aRes to (aJsonDict of jsonStr)’s valueForKey:aQueryStr
　　if aRes = missing value then return missing value
　　
　　set cArray to aRes’s arrayByAddingObjectsFromArray:(jKanji of jsonStr)
　　set cRes to returnDuplicatesOnly(cArray) of me
　　return cRes
end searchKanjiFromElementJ

on searchKanjiFromElement(aQueryStr)
　　if (aJsonDict of jsonStr) = missing value then my init()
　　set aRes to (aJsonDict of jsonStr)’s valueForKey:aQueryStr
　　if aRes = missing value then return missing value
　　return aRes as list
end searchKanjiFromElement

on listupQueryKeysForKanji()
　　if (aJsonDict of jsonStr) = missing value then my init()
　　set aRes to (aJsonDict of jsonStr)’s allKeys()
　　return aRes as list
end listupQueryKeysForKanji

on initJ()
　　set (jKanji of jsonStr) to current application’s NSArray’s arrayWithArray:(retJyouyouKanji() of jkLib)
end initJ

on init()
　　–https://github.com/yagays/kanjivg-radical
　　set aPath to (POSIX path of (path to me)) & "Contents/Resources/element2kanji.json"
　　set jsonString to NSString’s alloc()’s initWithContentsOfFile:(aPath) encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set (aJsonDict of jsonStr) to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
end init

on returnDuplicatesOnly(anArray)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:anArray
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　

(Visited 51 times, 1 visits today)

部首で漢字検索

Posted on 2月 21, 2021 by Takaaki Naganoya

漢字の部首を指定して、漢字を検索するAppleScriptです。厳密にいえば「部首」の文字ではなく、それっぽい文字で探せます。用途や利用者を想定できれば（子供が勉強用に使わないのであれば）十分に有用だと思います（理由は後述）。

Unicodeのデータから検索できるのではないかと考え、Unicodeの規格を調べていたのですが、漢字のSVGデータから構成文字情報を抽出したとされる「kanjivg-radical」を偶然みつけ、これを利用することで、割と手軽に実現できました。

–> kanjiSearch.zip(Download Script Bundle included JSON in its bundle)

開発環境のMac（Intel Core i7 2.66GHz）で、キャッシュがヒットしていれば（JSONから変換したデータがpropertyに読み込まれていれば）0.02秒程度で検索できています。この手の処理はデータのローディング（読み込み）が命なので、SSD使用必須です。

同データはJSON形式なので、AppleScriptバンドル中にJSONのまま突っ込んで、Cocoaの機能を用いてNSDictionaryに読み込んで検索しています。

ほかにも、Mac OS Xへの移行時に散々紹介されたMac OS Xのビックリドッキリ機能「関連文字に変換」をAppleScriptで実現した「関連文字を検索」も作ってみました。

このあたりをまとめてAppleScriptライブラリにしておけば便利そうですが、まだ使い勝手をテストしている段階です。義務教育で習う漢字の構成要素（へん、つくり etc）の呼び名とkanjivg-radicalで利用できる構成パーツの間に不整合（kanjivg-radicalの方が柔軟）があるので、そのあたりを埋めないと使いにくそう（下手に子供が使うと間違った国語知識を持ってしまう）な危険があるので、そのあたりを補う必要性を感じます。

たとえば、「禾」（のぎへん）を持つ漢字を「木」で検索できてしまうところです。大人は「実用的で使いやすい！」と喜ぶところですが、義務教育課程では両者は厳密に区別されています。自分は使いやすいので喜んで使っていますが、用途によっては使わないほうがよいかもしれません。

追記：

へんやつくりを元に検索できるデータとして、同梱の「radical2kanji_left_right.json」や「radical2kanji_top_bottom.json」が存在していることに気づいたので、そちらをAppleScriptのバンドル中に入れて、同様に検索してみました。

ただ、こちらのデータは随分と粗が多く、「⻖」（こざとへん）で自分の名前に使われている「隆」を「radical2kanji_left_right.json」から検索したところヒットしません。

{"阨", "陵", "隈", "険", "陣", "院", "陲", "陦", "陽", "陳", "陬", "隧", "險", "除", "隍", "陜", "陀", "陏", "隗", "階", "障", "隕", "降", "陂", "隴", "隔", "際", "隅", "附", "限", "陸", "陟", "陌", "阮", "阡", "阯", "阻", "阿", "阪", "防"}

国語辞書や文字コード表との照合といいますか、きちんとした検証作業は行われておらず、機械的に処理しただけのデータという印象を受けます。

一方で、「element2kanji.json」を用いて「⻖」（こざとへん）で検索したところ、

{"嶐", "阨", "蔭", "橢", "薩", "隣", "婀", "陵", "隈", "窿", "険", "隠", "陷", "陣", "痾", "院", "陶", "隙", "陲", "陦", "陽", "陪", "陳", "隘", "陥", "陬", "墜", "隧", "陰", "險", "除", "隍", "陜", "陀", "陛", "陏", "隗", "階", "障", "隕", "降", "陂", "隨", "隴", "隔", "随", "際", "隋", "陞", "隰", "墮", "隱", "陝", "隅", "隊", "附", "限", "陋", "陸", "陟", "隲", "陌", "隆", "阮", "阡", "阯", "阻", "阿", "阪", "堕", "防"}

と、結果が返ってきており……どうも複数のJSONデータを用いて、へんやつくりを考慮したJSONデータで検索して、ヒットしなかったら「element2kanji.json」を用いて物量でダメ押しするように設計されているようです。つまり、「radical2kanji_left_right.json」や「radical2kanji_top_bottom.json」が粗いのを複数のデータで補うように使うものである、と。

無限の量とバリエーションを持つデータに対するアプローチとしては間違っていないと思いますが、文字コードという有限のデータに対しての処理としては少し疑問が残る実装です。本当に使い物になるデータにするには、実際に人間の手による検証と校正が必要な内容でしょう。そのことは明記されるべきです。

「element2kanji.json」は現状のままで有用だと思いますが、「radical2kanji_left_right.json」や「radical2kanji_top_bottom.json」については、実際に国語辞典と照合してデータを補わないと実用レベルにはならないと感じました。盲目的に信用しないで、手元で実際に評価・検証することが重要です。

データ自体、CJK（中国語、日本語、韓国語）の統合漢字をサポートする範囲で作成されているようで、日本語で日常的に利用する常用漢字よりも幅広い文字がデータ化されています。常用漢字の範囲内に含まれているかをチェックするデータを併用するのが妥当でしょう。

AppleScript名：部首で漢字検索.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/21
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7"
use framework "Foundation"
use scripting additions

script jsonStr
　　property aJsonDict : missing value
end script

property NSString : a reference to current application’s NSString
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

–部首を指定して漢字検索
set aRes to searchKanjiFromElement("木") of me –きへん
–> {"稾", "欅", "謀", "酥", "悚", "椁", "検"….}

–set bRes to searchKanjiFromElement("氵") of me–さんずい
–> {"溯", "湮", "漁", "漕", "濶", "懣", "添", "淨",…..}

–set cRes to searchKanjiFromElement("之") of me
–> {"芝", "泛", "貶", "乏"}

–set dRes to searchKanjiFromElement("⻖") of me
–> {"嶐", "阨", "蔭", "橢", "薩", "隣", "婀"…}

–検索に使える部首のキー文字の一覧を返す
–set qList to listupQueryKeysForKanji() of me
–> {"工", "棘", "左", "位", "婁", "攴", "巨", "攵"…}

★Click Here to Open This Script　

(Visited 127 times, 1 visits today)

ページ範囲処理 v2

Posted on 2月 14, 2021 by Takaaki Naganoya

処理対象ページをユーザーに文字入力させた場合に、

X1,X2,X3,Y-Z

のようなフォーマットを解釈して、処理対象ページ番号をすべて展開するAppleScriptです。

もともと16年前に作成したScriptを書き換えたものです。オリジナルもとくに現行環境で問題なく動いているのですが、ソートルーチンを高速なものに差し替えています。ただし、処理データの量がたいして多くないことを前提としているため（数万ページ指定しないとCocoaのソートルーチンを利用するメリットがない）、Cocoaのソートルーチンは使っていません。

AppleScript名：ページ範囲処理 v2

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2005/11/04
–　　Modified on: 2021/02/14
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set parsedList to parsePageRangeString("1-10, 35, 37, 39, 100-110") of me
–> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 35, 37, 39, 100, 101, 102, 103, 104, 105, 106, 107, 108, 109, 110}

–ページ範囲指定のテキスト（多分）を展開して実際のページ数の一覧リストに
on parsePageRangeString(pageText as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to ("," as string)
　　set aList to text items of pageText
　　set AppleScript’s text item delimiters to curDelim
　　
　　set eList to {}
　　repeat with i in aList
　　　　set j to contents of i
　　　　if ("-" as string) is in j then
　　　　　　set eList to eList & parseByHyphen(j) of me
　　　　else
　　　　　　set the end of eList to j as number
　　　　end if
　　end repeat
　　
　　set eList to removeDuplicates(eList) of me
　　set eList to shellSortAscending(eList) of me
　　
　　return eList
end parsePageRangeString

–重複部分を削除
on removeDuplicates(aList)
　　set newList to {}
　　repeat with i from 1 to (length of aList)
　　　　set anItem to item 1 of aList
　　　　set aList to rest of aList
　　　　if {anItem} is not in aList then set end of newList to anItem
　　end repeat
　　return newList
end removeDuplicates

–ハイフンを実際の数値に変換
on parseByHyphen(aText)
　　set aText to aText as string
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to ("-" as string)
　　set aList to text items of aText
　　set AppleScript’s text item delimiters to curDelim
　　
　　set sList to {}
　　repeat with i from ((item 1 of aList) as number) to ((item 2 of aList) as number)
　　　　set the end of sList to i
　　end repeat
　　return sList
end parseByHyphen

–入れ子ではないリストの昇順ソート
on shellSortAscending(aSortList)
　　script oBj
　　　　property list : aSortList
　　end script
　　
　　set len to count oBj’s list’s items
　　set gap to 1
　　
　　repeat while (gap ≤ len)
　　　　set gap to ((gap * 3) + 1)
　　end repeat
　　
　　repeat while (gap > 0)
　　　　set gap to (gap div 3)
　　　　if (gap < len) then
　　　　　　repeat with i from gap to (len – 1)
　　　　　　　　set temp to oBj’s list’s item (i + 1)
　　　　　　　　set j to i
　　　　　　　　repeat while ((j ≥ gap) and (oBj’s list’s item (j – gap + 1) > temp))
　　　　　　　　　　set oBj’s list’s item (j + 1) to oBj’s list’s item (j – gap + 1)
　　　　　　　　　　set j to j – gap
　　　　　　　　end repeat
　　　　　　　　set oBj’s list’s item (j + 1) to temp
　　　　　　end repeat
　　　　end if
　　end repeat
　　
　　return oBj’s list
end shellSortAscending

★Click Here to Open This Script　

(Visited 37 times, 1 visits today)

CotEditorの各Windowで選択しておいた内容を座標でソートして結合

Posted on 2月 11, 2021 by Takaaki Naganoya

CotEditorでオープン中の複数のウィンドウから、各ウィンドウ（書類）の選択範囲を取得し、各ウィンドウの画面上の位置情報をもとに、その順番（Y座標、X座標）にテキストを組み合わせて新規書類を作成するAppleScriptです。

▲DEMO

▲Live Coding

当初、ウィンドウの重ね合わせ順（windowのindex）も考慮していたのですが、実際にためしてみたところ、重ね合わせ順を使うのは無駄だったので、機能を外しました。

AppleScript名：CotEditorの各Windowで選択しておいた内容を重ね合わせ順と座標でソートして結合.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/02/10
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set wList to {}

tell application "CotEditor"
　　set wCount to count (every window whose visible is true)
　　if wCount < 2 then return
　　
　　repeat with i from 1 to wCount
　　　　tell window i
　　　　　　set tmpBounds to bounds
　　　　　　
　　　　　　set tmpProp to properties
　　　　end tell
　　　　
　　　　set tmpDoc to document of tmpProp
　　　　tell tmpDoc
　　　　　　set aCon to contents of selection
　　　　end tell
　　　　
　　　　set tmpX to item 1 of tmpBounds
　　　　set tmpY to item 2 of tmpBounds
　　　　set tmpRec to {winIndex:i, winX:tmpX, winY:tmpY, selText:aCon}
　　　　
　　　　set the end of wList to tmpRec
　　　　
　　end repeat
　　
end tell

–座標値をもとにソートして選択テキストを返す
set sWList to sortRecListByLabel(wList, {"winY", "winX"}, {true, true}) of me
set anArray to current application’s NSArray’s arrayWithArray:sWList
set vList to (anArray’s valueForKey:"selText") as list
set jointStr to retArrowText(vList, return) of me

–CotEditor上で指定テキストでドキュメントを新規作成
makeNewCotEditorDoc(jointStr) of me

–リストを指定デリミタを追加しつつテキスト化
on retArrowText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retArrowText

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as list, ascendF as list)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　set aCount to length of aLabelStr
　　set sortDescArray to current application’s NSMutableArray’s new()
　　repeat with i from 1 to aCount
　　　　set aLabel to (item i of aLabelStr)
　　　　set aKey to (item i of ascendF)
　　　　set sortDesc to (current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabel ascending:aKey)
　　　　(sortDescArray’s addObject:sortDesc)
　　end repeat
　　
　　return (aArray’s sortedArrayUsingDescriptors:sortDescArray) as list
end sortRecListByLabel

–指定テキストでCotEditorの新規書類を作成
on makeNewCotEditorDoc(aCon)
　　tell application "CotEditor"
　　　　activate
　　　　set newDoc to make new document
　　　　tell newDoc
　　　　　　set contents to aCon
　　　　end tell
　　end tell
end makeNewCotEditorDoc

★Click Here to Open This Script　

(Visited 48 times, 1 visits today)

We released English edition of “FileMaker Pro Scripting Book with AppleScript”

Posted on 2月 9, 2021 by Takaaki Naganoya

Just we released English edition of ebook “FileMaker Pro Scripting Book with AppleScript”.

–> Download Sampler PDF

Title：FileMaker Pro Scripting Book with AppleScript English Edition
Author：Takaaki Naganoya@Piyomaru Software
Technical Supervisor：Masayuki Nii
Price: JPY 3,000 (About USD 30)@our ebook store, JPY 3,500+VAT 10%@PayPal
Delivery: Soon@our ebook store, 1 business day @ paypal (Check and return your URL on cloud storage via email)
Page：158
File format：PDF
Supplement : AppleScript files / RTF exported files / Piyomaru Script Assistant v2 (Japanese Version)

–> Online Store
–> Product Support page

Somebody asked me “Is there English version?” on twitter. I started translation project at that word.

At that point, I thought the translation project wouldn’t be too much hassle.But…it was wrong for me. It took more effort to translate it than write original Japanese version.

Japanese is a strange language. The subject can be omitted.Writing Japanese sentences makes a lot of effort to create a “good atmosphere” rather than facts.

It was very hard work. I added about 20 pages to explain the current status and history of AppleScript itself.

I hope this book will reach a large number of users.

(Visited 49 times, 1 visits today)

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

月: 2021年2月

指定文字のシフトJIS内文字かのチェック

私はロボットではありません

指定した文字で囲まれたキーワードの色を置換する

AVFAudioでオーディオ再生のじっけん

構成要素を指定して漢字検索 v3

部首で漢字検索

追記：

We released English edition of “FileMaker Pro Scripting Book with AppleScript”