macOS 12.3 Beta（21E5196i）、電話番号ピックアップできないバグが直る？

Posted on 1月 28, 2022 by Takaaki Naganoya

macOS 12.3 Beta（21E5196i）が配信され、M1 Mac mini上で実験してみたところ、macOS 12でバグが出ていた「自然言語テキストからNSDataDetectorで電話番号を抽出しようとすると何も出てこない」件（日本語環境限定）が修正されているように見えます。

Thanks Shane!

AppleScript名：与えられたテキストから電話番号を抽出 v2

— Created 2015-08-21 by Shane Stanley
— Modified 2015-08-21 by Takaaki Naganoya
— Modified 2015-08-22 by Shane Stanley
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set theString to "長野谷隆昌
(Takaaki Naganoya)
maro@piyocast.com
http://piyocast.com/as
2015年8月21日〜23日
080-1111-2222
030-1234-5678
東京都練馬区中村橋1-2-3
"

set theDates to (extractPhoneNumberFromNaturalText(theString))
–>　　{"080-1111-2222"}–macOS 10.12 or other version
–> {"080-1111-2222", "030-1234-5678"}–macOS 13.6 with Intel MacBook Air
–> {"080-1111-2222", "030-1234-5678"}–macOS 14.6 with Intel MacBook Pro
–> {"080-1111-2222", "030-1234-5678"}–macOS 15.7 with Intel MacBook Pro
–> {} –macOS 12 beta 6 with M1 Mac mini
–> {"080-1111-2222", "030-1234-5678"}–macOS 12.3beta1 with M1 Mac mini

on extractPhoneNumberFromNaturalText(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　
　　set {theDetector, theError} to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypePhoneNumber) |error|:(reference)
　　set theMatches to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　set theResults to theMatches’s valueForKey:"phoneNumber"
　　
　　return theResults as list
end extractPhoneNumberFromNaturalText

★Click Here to Open This Script　

自然言語テキストから複数の日付情報を抽出

Posted on 1月 21, 2020 by Takaaki Naganoya

自然言語テキストから日付の情報（複数可）を抽出するAppleScriptです。

URLやメールアドレスの抽出では、複数のデータをNSDataDetectorで抽出するAppleScriptは書いてありましたが、日付情報の抽出を行うものはなかったので、書いておきました。

AppleScript名：自然言語テキストから複数の日付情報（複数）を抽出して日付のリストを返す.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/01/21
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set theDate to getDatesIn("本テキストには次の火曜日という日付情報を含んでいる。明日かもしれない。次の木曜日もそうだ。") of me
–> {date "2020年1月28日火曜日 12:00:00", date "2020年1月22日水曜日 12:00:00", date "2020年1月23日木曜日 12:00:00"}

set theDate to getDatesIn("This text contains next Tuesday. The date may be tomorrow. Next Wednesday happen.") of me
–> {date "2020年1月28日火曜日 12:00:00", date "2020年1月22日水曜日 12:00:00", date "2020年1月29日水曜日 12:00:00"}

on getDatesIn(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　set theDetector to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(missing value)
　　set theMatchs to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　if theMatchs = missing value then error "No date found with String:" & aString
　　set dRes to theMatchs’s valueForKeyPath:"date"
　　return dRes as list
end getDatesIn

★Click Here to Open This Script　

AppleScript名：自然言語テキストから複数の日付情報（複数）を抽出して日付と当該箇所のリストを返す v2.scptd

set theDate to getDatesAndOrigStringsIn("本テキストには次の火曜日という日付情報を含んでいる。明日かもしれない。次の木曜日もそうだ。") of me
–> {{originalStr:"次の火曜日", detectDate:date "2020年1月28日火曜日 12:00:00"}, {originalStr:"明日", detectDate:date "2020年1月22日水曜日 12:00:00"}, {originalStr:"次の木曜日", detectDate:date "2020年1月23日木曜日 12:00:00"}}

set theDate to getDatesAndOrigStringsIn("This text contains next Tuesday. The date may be tomorrow. Next Wednesday happen.") of me
–> {{originalStr:"next Tuesday", detectDate:date "2020年1月28日火曜日 12:00:00"}, {originalStr:"tomorrow", detectDate:date "2020年1月22日水曜日 12:00:00"}, {originalStr:"Next Wednesday", detectDate:date "2020年1月29日水曜日 12:00:00"}}

on getDatesAndOrigStringsIn(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　set theDetector to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(missing value)
　　set theMatchs to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　if theMatchs = missing value then error "No date found with String:" & aString
　　set dRes to (theMatchs’s valueForKeyPath:"date") as list
　　set rRes to (theMatchs’s valueForKeyPath:"range") as list
　　
　　set allRes to {}
　　set aLen to length of dRes
　　repeat with i from 1 to aLen
　　　　set aSubStr to (anNSString’s substringWithRange:(item i of rRes))
　　　　set dDate to contents of item i of dRes
　　　　set the end of allRes to {originalStr:aSubStr as string, detectDate:dDate}
　　end repeat
　　
　　return allRes
end getDatesAndOrigStringsIn

★Click Here to Open This Script　

頭のいいタイマー割り込み実行

Posted on 3月 27, 2019 by Takaaki Naganoya

頭のいいタイマー割り込み（on idle）実行のAppleScriptを追求してみました。

AppleScript開闢（かいびゃく）以来、すでに20年以上の時間が経過しているので、on idleによるタイマー割り込み処理なんて、探せばサンプルが山のように出てくるものです。

AppleScript名：timer interrupt

property targetTime : "9:37:00"
property timerInterval : 30

on run
　　set timerInterval to 30
end run

on idle
　　set curTime to current date
　　set cString to time string of curTime
　　
　　if cString ≥ targetTime then
　　　　display dialog "It’s time to take off!" buttons {"OK"} default button 1 giving up after 30
　　　　quit
　　end if
　　
　　return timerInterval
end idle

★Click Here to Open This Script　

これが基礎的な内容で、このScriptをScript Editor上でアプリケーション（アプレット）形式で、「ハンドラの実行後に終了しない」をオンにして書き出すとタイマー実行アプレットが出来上がります（３分間クッキング）。

ただ、実行時刻のパラメータがプログラム内に直打ちなのが気になります。知能レベルが低い感じがします。

そこで、実行時刻のパラメータの外部供給ということを考え出すわけですが、

　（１）設定ファイルから読み込み
　（２）アプレット自身のコメント（File Comment）から読み込み
　（３）ファイル名自体から読み込み
　（４）コマンドラインから実行し、実行時にパラメータ（argv）を指定

などの方法を考えつきます（20世紀にすでにさんざんやった内容）。ただし、全角数字を半角に変換したり、ファイル名の場合には時刻セパレータの「:」がmacOS上ではファイル名に使えない文字（ディレクトリ・セパレータ）だったり、Finderが管理しているファイル名はUnicodeのNormalize方式が異なる（処理しやすいようにNormalizeし直さないとダメ）など割と頭の痛い問題がいろいろあります。

そこで利用したいのが、CocoaのDataFormatter。自然言語風に書かれた「１０時４１分」（全角数字入り）といった文字列から日時データをピックアップします。

そうして書いたのがこれ（↓）です。

ファイル名に書かれた時刻から実行時刻を拾ってタイマー実行します。けっこう頭がいい感じがします。

実際に、こうした処理の延長線上にTanzakuで行なっているファイル名から取得した文字列に対する形態素解析＆コマンドピックアップの処理があります。

AppleScript名：１０時４２分

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property targTime : missing value
property timerInterval : 1

on run
　　set timerInterval to 1
　　
　　–Get filename from this applet
　　set myPath to path to current application
　　tell application "System Events"
　　　　set myName to name of myPath
　　end tell
　　
　　–Validate filename as a natural language format date by using NSDataDetector
　　set dList to getDatesIn(myName) of me
　　repeat while dList = {}
　　　　set myName to text returned of (display dialog "There is no time elements in my filename. Input the target time　in x時xx分" default answer "午後5時45分")
　　　　set dList to getDatesIn(myName) of me
　　end repeat
　　
　　set targDate to first item of dList
　　set targTime to time string of targDate
　　display notification targTime
end run

on idle
　　set curTime to current date
　　set curTimeStr to time string of curTime
　　
　　if curTimeStr ≥ targTime then
　　　　activate
　　　　display dialog "It’s time to take off!" buttons {"OK"} default button 1 giving up after 30
　　　　quit
　　end if
　　
　　return timerInterval
end idle

on getDatesIn(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　set {theDetector, theError} to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(reference)
　　set theMatches to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　set theResults to theMatches’s valueForKey:"date"
　　return theResults as list
end getDatesIn

★Click Here to Open This Script　

MacJournalで選択中のエントリの文中からdata detectorで日付を取得して作成日付に反映

Posted on 1月 8, 2019 by Takaaki Naganoya

MacJournalで選択中のjournal entryの文中（plain text content）からData Detector（NSDataDetector）で日付を取得し、初出の日付をjournal entryの作成日付に設定するAppleScriptです。

macOSの不具合情報をMacJournalにスクラップして整理していたところ、記事作成日をjournal entryの作成日付に反映させたいと考え、以前に作ってあったScriptを修正し、Data Detectorで日付情報を抽出するようにしてみました。

なお、複数のjournal entryを選択した状態で実行すると、ループですべての選択中のjournal entryを処理します。

macOS標準搭載のScript Menuに入れて使用しています。

AppleScript名：MacJournalで選択中のエントリの文中からdata detectorで日付を取得して作成日付に反映

— Created 2019-01-08 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSDataDetector : a reference to current application’s NSDataDetector

tell application "MacJournal"
　　set aSel to selected entries
　　
　　repeat with i in aSel
　　　　set j to contents of i
　　　　set aName to name of j
　　　　set aDate to date of j
　　　　set aStr to plain text content of j
　　　　set aDateList to getDatesIn(aStr) of me
　　　　
　　　　if aStr is not equal to "" and aDateList is not equal to {} then
　　　　　　set targDate to contents of (first item of aDateList)
　　　　　　try
　　　　　　　　set date of j to targDate
　　　　　　end try
　　　　end if
　　end repeat
end tell

on getDatesIn(aString)
　　set anNSString to NSString’s stringWithString:aString
　　set {theDetector, theError} to NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(reference)
　　set theMatches to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　set theResults to theMatches’s valueForKey:"date"
　　return theResults as list
end getDatesIn

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSDataDetector

macOS 12.3 Beta（21E5196i）、電話番号ピックアップできないバグが直る？

自然言語テキストから複数の日付情報を抽出

頭のいいタイマー割り込み実行

MacJournalで選択中のエントリの文中からdata detectorで日付を取得して作成日付に反映