YouTubeムービー再生実験

macOS 26上でdisplay youtube AppleScriptライブラリの機能を利用したAppleScriptを、macOS標準搭載の「スクリプトメニュー」から呼び出すと、

のようにエラー表示されるようになっていました。

macOS 26.0βのときには再生されたりしていたのですが、リリース後のmacOS 26.2では再生されません。

これが、macOSの内部機能やポリシーの変更によるものなのか、あるいはmacOS 26のデフォルト設定の変化によるものかは不明です。YouTube側の仕様変更という疑いもありますが、定かではありません。

以前は文字列で組み立てたHTMLをWkWebViewに読み込ませていましたが、いまmacOS 26上ではそのやり方ではYouTubeのムービーは再生されません。

そこで、根本的な解決を図るため、local web server（httpd）を介してHTMLを表示する方式に変更。docrootをtemporary items folderに設定したhttpdを起動。temporary items folderに書き込んだhtmlをダイアログ上のWkWebViewに表示するようにしました。

このlocal web serverの起動にpython3を呼び出しており、インストールされていない環境（一般的な環境ではインストールされていない）ではDeveloper Toolsのインストールが実行初回時に行われます。一般ユーザーのことを考えるとPython3以外のツールを使って起動すべきなんでしょう。

以前のバージョンと異なるのは、ダイアログ上のWkWebViewに再生用のUI（中央にYouTUbeロゴ）が配置され、それをクリックしないとムービーの再生が始まらないことです。このあたりは、自動再生を開始できるように改変できそうではあるものの、同時にデメリット（音声の再生が行えないとか）が生じるおそれがあるため、現状のままがよさそうです。

それでも、macOS 26上でWkWebViewでYouTubeムービーを再生させられるようになりました。まだ、繰り返し実行して問題が出ないかといったテストを行なっている段階です。

htmlファイルの書き込みが間に合わないと上記のようなエラーが出ていましたが、処理の冒頭で明示的にhttpdをkillすることで、この問題を解消できるようになりました。httpdのkillについては、他のプログラムが起動していた場合には問題になりそうなので、そこも様子見といったところでしょう。

ちなみに、YouTubeムービー再生以外の用途では、とくにこのような大幅な改変は必要ではないと認識しています。たとえば、CDN上のJavaScriptライブラリを呼び出してアニメーション表示つきのグラフ表示をAppleScriptで行なっていますが、こちらでは書き換えは必要ありませんでした。

AppleScript名：youtubeムービー再生実験.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/11/12
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property WKWebView : a reference to current application’s WKWebView
property NSURLRequest : a reference to current application’s NSURLRequest
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration

property returnCode : 0

set mainMessage to "Youtube Test"
set subMessage to "Using local Web Server"
set viewSizeArray to {1200, 640}

set youtubeMovieID to "GP_tVXTYdmY"

–テスト用HTML文字列
–set htmlString to "<!DOCTYPE html><html><body><h1>Hello World</h1></body></html>"

— HTML文字列
set htmlString to "
<!DOCTYPE html>
<html lang=＼"ja＼">
<head>
<meta charset=＼"UTF-8＼">
<title>YouTube Embed</title>
<style>
body { margin:0; padding:0; }
iframe { width:100%; height:100vh; border:none; }
</style>
</head>
<body>
<iframe width=＼"560＼" height=＼"315＼" src=＼"https://www.youtube.com/embed/" & youtubeMovieID & "?start=1＼" title=＼"YouTube video player＼" frameborder=＼"0＼" allow=＼"accelerometer; autoplay; clipboard-write; encrypted-media; gyroscope; picture-in-picture＼" allowfullscreen></iframe>
</body>
</html>
"

try
　　do shell script "pkill -f ’http.server’ || true"
end try

set docroot to POSIX path of (path to temporary items)

–1. Python3でバックグラウンドサーバー起動（Local Web Server）
set pythonCmd to "python3 -m http.server 8000 –directory " & quoted form of docroot & " >/dev/null 2>&1 & echo $!"
set pidStr to do shell script pythonCmd
set serverPID to pidStr as integer

— 2. HTMLを書き出す
set htmlPath to docroot & "index.html"
set nsHTML to current application’s NSString’s stringWithString:htmlString
nsHTML’s writeToFile:htmlPath atomically:true encoding:(current application’s NSUTF8StringEncoding) |error|:(missing value)

— 3. 少し待ってサーバー起動を待機
delay 0.5

try
　　— 4. WKWebViewでHTTP URLを読み込む
　　set httpURL to "http://localhost:8000/index.html"
　　set paramObj to {myMessage:mainMessage, mySubMessage:subMessage, viewSize:viewSizeArray, htmlStr:"", myURL:httpURL}
　　
　　–my browseURLContents:paramObj
　　my performSelectorOnMainThread:"browseURLContents:" withObject:(paramObj) waitUntilDone:true
on error errMsg
　　display dialog errMsg
end try

— 5. サーバープロセス終了
try
　　do shell script "pkill -f ’http.server’ || true"
end try

— WKWebView表示用ハンドラ
on browseURLContents:paramObj
　　set webSize to viewSize of paramObj
　　copy webSize to {aWidth, aHeight}
　　
　　set aURL to myURL of paramObj
　　
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s URLWithString:aURL
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　— Move to frontmost
　　current application’s NSApplication’s sharedApplication()’s setActivationPolicy:(current application’s NSApplicationActivationPolicyRegular)
　　current application’s NSApp’s activateIgnoringOtherApps:true
　　
　　— アラートに埋め込む
　　set theAlert to current application’s NSAlert’s alloc()’s init()
　　tell theAlert
　　　　–addButtonWithTitle_("Cancel")
　　　　its setMessageText:(myMessage of paramObj)
　　　　its setInformativeText:(mySubMessage of paramObj)
　　　　its addButtonWithTitle:"OK"
　　　　its setAccessoryView:aWebView
　　　　set myWindow to its |window|
　　　　tell myWindow
　　　　　　its setLevel:(current application’s NSScreenSaverWindowLevel)
　　　　　　setInitialFirstResponder_(aWebView)
　　　　end tell
　　end tell
　　
　　— モーダル表示
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　set returnCode to (theAlert’s runModal()) as number
　　
　　— WKWebViewの後始末
　　set jsStop to "try { document.getElementById(’ytplayer’).contentWindow.postMessage(’{＼"event＼":＼"command＼",＼"func＼":＼"stopVideo＼",＼"args＼":＼"＼"}’, ’*’); } catch(e) {}"
　　aWebView’s evaluateJavaScript:jsStop completionHandler:(missing value)
　　delay 0.1
　　aWebView’s loadRequest:(NSURLRequest’s requestWithURL:(|NSURL|’s URLWithString:"about:blank"))
　　delay 0.1
　　aWebView’s stopLoading()
　　set aWebView to missing value
　　
　　set aWebView to missing value
end browseURLContents:

★Click Here to Open This Script　

「AppleScriptセキュリティ実践ガイド」を発売

Posted on 11月 6 by Takaaki Naganoya

電子書籍の新刊を発売しました。「AppleScriptセキュリティ実践ガイド」です。PDF 562ページ、サンプルAppleScriptのZipアーカイブを添付。

→　販売ページ

macOS上の各種機能を自由に呼び出せて、GUIベースのアプリの機能や情報を呼び出せる強力なAppleScriptは、ソースコードが読めない実行専用形式で、Scriptやアプレットとして公開可能です。

しかし、「暗号化済み」のように見える「実行専用形式」で保存されていたとしても、実際にはApple Events Codeという命令列の形で格納されており、文字列に関してはターミナル上でhexdumpやstringsコマンドによるダンプ出力が可能です。

さらに、昨今ではApple Events Codeそのものをダンプ（＝内部の命令構造を可視化）するツールが登場。防衛用のツールですが、攻撃側もこれを利用できる状態にあります。

本書では、Apple Events Codeのダンプツールによってどのような情報が「抜かれ」、それらが実際にどのように見えるのかを詳細に検証しています。

実行専用のScript/アプレットで書き出した内容をダンプ（Apple Events Codeのダンプ）するapplescript-disassemblerと、その出力内容を読みやすく整形するaevt-decompileを用いて、さらにそれらを統合して使いやすくした統合ダンプツールをAppleScriptで開発。

対象フォルダ中のAppleScript書類を実行専用形式で書き出し、ダンプツールで解析して結果をテキスト書き出し……という作業フローを一括で行います。これを、さまざまな構造の複雑さを備えたテスト用AppleScriptに対して、さまざまなデータ型のデータを記述してどの程度漏洩するのか、しないのかを確認しています。

また、すべてのAppleScript予約語を含むサンプルScriptを作成し、個別にどのようにApple Events Codeにダンプされるかを掲載しています。

その上で、想定されるリスクと防止策を提示し、AppleScriptを安全に活用するための基礎資料としてご活用ください。

1章　「実行専用」は安全なのか？

AppleScriptの概要と機能のひろがり／実行プログラムのひろがり／システム設定による機能制限／ヘックスダンプや文字ダンプで得られる情報／Apple Events関連の参考資料／コラム　本書掲載のAppleScriptリストの構文色分け設定について

2章　AppleScriptアプレットの構造

スクリプトエディタでアプレットを作成／書き出したアプレットの内部構造を追う／クラシックOS時代のアプレットのscptリソースの内容と比較

3章　Apple Eventダンプによる情報抽出

アップルスクリプトの完全なデコンパイルは無理／あくまでApple Events Codeとして解釈して読みやすくする／applescript-disassembler／aevt_decompile／統合分析ツールas_disassem+decompile／strings／hexdump

4章　実行専用スクリプトから漏れる情報の実態

Apple Events Code上で各データ型がどう見えるか？／プログラムの複雑さを変更して結果を調べる／アルファベット＋数字／日本語の文字列／絵文字の文字列／真偽値／整数値／実数値／dateオブジェクト／数値のリスト（配列）／文字列のリスト（配列）／レコード／アプリケーションのオブジェクト／Xcodeで開発したAppleScrIptObjCアプリ

5章　情報漏洩をふせぐ技術的手法

安直なダンプで見えない形式でユーザー名やパスワードを記述／キーチェーンに情報を保存して内容を取り出すにしてもアクセス用キーワードは必要／データ暗号化の基礎①シフト暗号／データ暗号化の基礎②暗号表による換字式暗号／データ暗号化の基礎③多表式暗号と鍵のしくみ（ヴィジュネル暗号）／データ暗号化の基礎④「鍵」をさらに安全・自動的に扱う仕組みをもつOpenSSLによる現代暗号／プログラム難読化①データ形式変更／プログラム難読化②変数名絵文字置換／プログラム難読化③構造高度化

6章　安全な配布のための設計指針

アップルスクリプトの配布形態とかけられる労力の違い／配布時に最低限でもコード署名が必要。そのために開発者登録も必須／習熟のために経験しておきたいアプレットのオンライン配布

7章　AppleScriptのセキュリティ再考

最近発生したAppleScriptがらみの諸問題はメモリリーク／ユーザー名やパスワード、APIキーをスクリプト内に平文で記録すると危険／かつては可能だったアプリとAppleScript間の通信傍受もいまや不可能に／ネットワーク経由の操作は、途中で傍受される危険性も／AppleScript実行ツールで、埋め込みテキストのスクリプトを設定ファイルに平文保存？

8章　Apple Events Codeダンプ分析資料

全予約語を含む記述例を実行専用状態でApple Events Codeダンプ

9章　ダンプ結果から見る情報露出傾向と対策

コマンド、記述方法、データ型から読み解く露出傾向／script objectによるダンプ対策が有効／「OSAMiner事件」から再考されたAppleScript環境におけるセキュリティ対策／コラム　本書作成のために作成・使用したAppleScript

macOS 26.1が登場。Finderのバグが直らない？

Posted on 11月 4 by Takaaki Naganoya

macOS 26.1がリリースされ、macOS 26.0で発生していたFinderまわりのバグが、一応修正されたような形跡もあるのですが、結論からいえば別のエラーが出るようになりました。

macOS 26.0：
ゴミ箱に何も入っていない状態で、AppleScriptからFinderに「empty trash」を実行すると、タイムアウト時間（180秒）まで待ってタイムアウトエラーに。

macOS 26.1：
ゴミ箱に何も入っていない状態で、AppleScriptからFinderに「empty trash」を実行すると、時間待ちしないでエラーに。

一応、empty trashをtry〜end tryで囲っておけば、ゴミ箱が空の場合に発生するエラーを回避できます。

AppleScript名：empty trash test 2.scpt

tell application "Finder"
　　try
　　　　empty trash
　　end try
end tell

★Click Here to Open This Script　

macOS 15.7.2 スクリプトメニューから実行できなくなった地図系ライブラリ？

Posted on 10月 11 by Takaaki Naganoya

macOS 15.7.2やmacOS 26.x上のスクリプトメニューで地図表示系のライブラリ呼び出し、とくにchoose location libが動作しません。

てっきり「スクリプトメニューで地図系のAPIへのアクセスが禁止されたのか？」と思っていたのですが、

同じく地図系APIにアクセスしているdisplay locationライブラリはスクリプトメニューから呼び出せています。

不思議。

以下に、AppleScriptライブラリの呼び出しが可能なAppleScript実行環境の一覧を示し、呼び出しの検証が行えているものは「Yes」を、検証して動かないことを確認したものに「No」と記入しています。

Program Name	Can Call choose location Libraries?
Script Debugger 8	Yes
Script Editor	Yes
Mail.app (rule–> Run AppleScript)
Shortcuts.app	No	Can not load map image
Shortcuts Events	No	Can not load map image
Script Menu (macOS 10.14 or later)	No	Can not execute
Terminal.app (osascript)	Yes
Service Station
elgato Stream Deck
BBEdit	No	Can not execute
Jedit Ω
Adobe Indesign
Adobe Illustrator
Music (Script Menu)	No	Can not execute
Microsoft Excel
Microsoft Word
Microsoft PowerPoint
Keyboard Maestro
EventScript
FastScript 3	Yes
LaunchPalette
Visual Studio Code extension	Yes
Dropzone 4
ScreenFloat
Xojo 2025	No	Error
Live Code

階層を指定したlistからOutLineViewで表示できるデータ形式に変換 v4（3階層対応）

Posted on 10月 10 by Takaaki Naganoya

入れ子のlist（2D List）で {{インデント階層＋タイトル}…} 指定したデータを、NSOutlineViewで表示できるデータ形式に変換するAppleScriptです。

Keynoteに各スライドのインデント・レベルをAppleScriptに返す機能が存在しないため、各スライドのマスタースライド名から「このスライドマスターは、この階層に使いがち」といったルールをもとに階層関係を推測して処理しています。

主に、Keynote書類の各スライド（ページ）上のタイトルを、そのマスタースライド名をもとにインデントレベルを仮想的に判定し、PDFのTOCを作成する際の「プレビュー」を行うべく、NSOutLineViewで表示するために作成したものです。

これ自体は、2d ListからNSOutLineView表示用のデータを作成するだけのScriptです。

n階層をサポートしています。0がトップ階層。1がタブ1個と等価。2がタブ2個インデントと等価です。

{{0, "表紙"}, {0, "目次"}, {0, "1章"}, {1, "セクション1"}, {2, "項目1"}, {3, "コラム1"}, {2, "項目2"}, {3, "コラム2"}, {1, "セクション2"}, {2, "項目3"}, {0, "2章"}, {1, "セクションA"}, {2, "項目A1"}, {2, "項目A2"}, {1, "セクションB"}, {0, "裏表紙"}}

こんなデータを、

{{|name|:"表紙", isLeaf:true, children:{}}, {|name|:"目次", isLeaf:true, children:{}}, {|name|:"1章", isLeaf:false, children:{{|name|:"セクション1", isLeaf:false, children:{{|name|:"項目1", isLeaf:false, children:{{|name|:"コラム1", isLeaf:true, children:{}}}}, {|name|:"項目2", isLeaf:false, children:{{|name|:"コラム2", isLeaf:true, children:{}}}}}}, {|name|:"セクション2", isLeaf:false, children:{{|name|:"項目3", isLeaf:true, children:{}}}}}}, {|name|:"2章", isLeaf:false, children:{{|name|:"セクションA", isLeaf:false, children:{{|name|:"項目A1", isLeaf:true, children:{}}, {|name|:"項目A2", isLeaf:true, children:{}}}}, {|name|:"セクションB", isLeaf:true, children:{}}}}, {|name|:"裏表紙", isLeaf:true, children:{}}}

のように変換します。

NSOutlineViewをダイアログ表示するAppleScriptライブラリを作りかけて、データ作成部分もライブラリに組み込まないと使い物にならないと気づき、ChatGPTに作らせたものです。

AppleScript名：階層を指定したlistからOutLineViewで表示できるデータ形式に変換 v4（3階層対応）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/10/10
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use scripting additions

— サンプル入力（3階層以上）
set srcList to {{0, "表紙"}, {0, "目次"}, {0, "1章"}, {1, "セクション1"}, {2, "項目1"}, {3, "コラム1"}, {2, "項目2"}, {3, "コラム2"}, {1, "セクション2"}, {2, "項目3"}, {0, "2章"}, {1, "セクションA"}, {2, "項目A1"}, {2, "項目A2"}, {1, "セクションB"}, {0, "裏表紙"}}

set aRec to convlistToStructuredRec(srcList) of me
–> {{|name|:"表紙", isLeaf:true, children:{}}, {|name|:"目次", isLeaf:true, children:{}}, {|name|:"1章", isLeaf:false, children:{{|name|:"セクション1", isLeaf:false, children:{{|name|:"項目1", isLeaf:false, children:{{|name|:"コラム1", isLeaf:true, children:{}}}}, {|name|:"項目2", isLeaf:false, children:{{|name|:"コラム2", isLeaf:true, children:{}}}}}}, {|name|:"セクション2", isLeaf:false, children:{{|name|:"項目3", isLeaf:true, children:{}}}}}}, {|name|:"2章", isLeaf:false, children:{{|name|:"セクションA", isLeaf:false, children:{{|name|:"項目A1", isLeaf:true, children:{}}, {|name|:"項目A2", isLeaf:true, children:{}}}}, {|name|:"セクションB", isLeaf:true, children:{}}}}, {|name|:"裏表紙", isLeaf:true, children:{}}}

on convlistToStructuredRec(allLines)
　　set topList to {} — 最終出力
　　set stack to {} — 階層ごとの親ノードを保持
　　
　　repeat with aLine in allLines
　　　　copy aLine to {tabCount, lineStr}
　　　　set lineNS to (current application’s NSString’s stringWithString:(lineStr as text))
　　　　set contentText to (lineNS’s stringByTrimmingCharactersInSet:(current application’s NSCharacterSet’s whitespaceAndNewlineCharacterSet())) as text
　　　　if contentText is "" then
　　　　　　— 空行スキップ
　　　　else
　　　　　　— 新しいレコード
　　　　　　set newRec to {|name|:contentText, isLeaf:true, children:{}}
　　　　　　
　　　　　　if tabCount = 0 then
　　　　　　　　— トップレベル
　　　　　　　　set end of topList to newRec
　　　　　　　　set stack to {newRec}
　　　　　　else
　　　　　　　　— stack を tabCount に合わせて切り詰め
　　　　　　　　if (count of stack) ≥ tabCount then
　　　　　　　　　　set stack to items 1 thru tabCount of stack
　　　　　　　　end if
　　　　　　　　
　　　　　　　　— 親ノード取得
　　　　　　　　set parentRec to item tabCount of stack
　　　　　　　　
　　　　　　　　— 親の children に追加
　　　　　　　　set parentChildren to parentRec’s children
　　　　　　　　set end of parentChildren to newRec
　　　　　　　　set parentRec’s children to parentChildren
　　　　　　　　
　　　　　　　　— 親の isLeaf を false に
　　　　　　　　set parentRec’s isLeaf to false
　　　　　　　　
　　　　　　　　— stack に追加
　　　　　　　　set end of stack to newRec
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return topList
end convlistToStructuredRec

★Click Here to Open This Script　

タブでインデントしたテキストをOutLineViewで表示できるデータ形式に変換 v4（3階層対応）

Posted on 10月 10 by Takaaki Naganoya

タブでインデントしたテキストを、NSOutlineViewで表示できるデータ形式に変換するAppleScriptの改良版です。

ChatGPTにオーダーを出して、エラー内容と処理結果をそのまま差し返すことで、数回このフローを繰り返して正しい処理内容を取得できました。

これ自体は、テストデータ（テキスト）からNSOutLineView表示用のデータを作成するだけのScriptです。

Tab n個のn階層をサポートしています。

表紙
目次
1章
	セクション1
		項目1
			コラム1
		項目2
			コラム2
	セクション2
		項目3
2章
	セクションA
		項目A1
		項目A2
	セクションB
裏表紙

こんなデータを、

のように変換します。

AppleScript名：タブでインデントしたテキストをOutLineViewで表示できるデータ形式に変換 v4（3階層対応）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/10/10
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use scripting additions

— サンプル入力（3階層以上）
set srcText to "表紙
目次
1章
　　セクション1
　　　　項目1
　　　　　　コラム1
　　　　項目2
　　　　　　コラム2
　　セクション2
　　　　項目3
2章
　　セクションA
　　　　項目A1
　　　　項目A2
　　セクションB
裏表紙"

set aRec to convStrToStructuredRec(srcText) of me
–> {{|name|:"表紙", isLeaf:true, children:{}}, {|name|:"目次", isLeaf:true, children:{}}, {|name|:"1章", isLeaf:false, children:{{|name|:"セクション1", isLeaf:false, children:{{|name|:"項目1", isLeaf:false, children:{{|name|:"コラム1", isLeaf:true, children:{}}}}, {|name|:"項目2", isLeaf:false, children:{{|name|:"コラム2", isLeaf:true, children:{}}}}}}, {|name|:"セクション2", isLeaf:false, children:{{|name|:"項目3", isLeaf:true, children:{}}}}}}, {|name|:"2章", isLeaf:false, children:{{|name|:"セクションA", isLeaf:false, children:{{|name|:"項目A1", isLeaf:true, children:{}}, {|name|:"項目A2", isLeaf:true, children:{}}}}, {|name|:"セクションB", isLeaf:true, children:{}}}}, {|name|:"裏表紙", isLeaf:true, children:{}}}

on convStrToStructuredRec(srcText)
　　set nsText to current application’s NSString’s stringWithString:srcText
　　set allLines to nsText’s componentsSeparatedByCharactersInSet:(current application’s NSCharacterSet’s newlineCharacterSet())
　　
　　set topList to {} — 最終出力
　　set stack to {} — 階層ごとの親ノードを保持
　　
　　repeat with aLine in allLines
　　　　set lineNS to (current application’s NSString’s stringWithString:(aLine as text))
　　　　set trimmedStr to (lineNS’s stringByTrimmingCharactersInSet:(current application’s NSCharacterSet’s whitespaceAndNewlineCharacterSet())) as text
　　　　if trimmedStr is "" then
　　　　　　— 空行スキップ
　　　　else
　　　　　　— 行頭タブ数
　　　　　　set len to lineNS’s |length|()
　　　　　　set tabCount to 0
　　　　　　repeat with i from 0 to (len – 1)
　　　　　　　　set ch to (lineNS’s characterAtIndex:i)
　　　　　　　　if (ch as integer) = 9 then
　　　　　　　　　　set tabCount to tabCount + 1
　　　　　　　　else
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　end repeat
　　　　　　
　　　　　　— タブ除去文字列
　　　　　　if len > tabCount then
　　　　　　　　set contentText to (lineNS’s substringFromIndex:tabCount) as text
　　　　　　else
　　　　　　　　set contentText to ""
　　　　　　end if
　　　　　　
　　　　　　— 新しいレコード
　　　　　　set newRec to {|name|:contentText, isLeaf:true, children:{}}
　　　　　　
　　　　　　if tabCount = 0 then
　　　　　　　　— トップレベル
　　　　　　　　set end of topList to newRec
　　　　　　　　set stack to {newRec}
　　　　　　else
　　　　　　　　— stack を tabCount に合わせて切り詰め
　　　　　　　　if (count of stack) ≥ tabCount then
　　　　　　　　　　set stack to items 1 thru tabCount of stack
　　　　　　　　end if
　　　　　　　　— 親ノード取得
　　　　　　　　set parentRec to item tabCount of stack
　　　　　　　　— 親の children に追加
　　　　　　　　set parentChildren to parentRec’s children
　　　　　　　　set end of parentChildren to newRec
　　　　　　　　set parentRec’s children to parentChildren
　　　　　　　　— 親の isLeaf を false に
　　　　　　　　set parentRec’s isLeaf to false
　　　　　　　　— stack に追加
　　　　　　　　set end of stack to newRec
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return topList
end convStrToStructuredRec

★Click Here to Open This Script　

FaceTimeカメラから取り込み v1

Posted on 10月 8 by Takaaki Naganoya

MacBook Air/Pro/iMac搭載のFaceTime HDカメラから静止画を取り込むAppleScriptです。

QRコードの画像を取り込んで、QRコードを認識させて、URLを含んでいる場合にはWebブラウザでオープンするといったワークフローを作っておこうかと考えて書いてみました。

ただ、まだ調べ始めて日がないため、取り込み中の画像のプレビューは表示されません。FaceTime HDカメラが点灯して2秒ぐらいで何も言わずに画像取り込みされる無愛想なプログラムになっています。

本当はAVCaptureViewを用いてプレビュー表示が行われることがベストです。アラートダイアログ上にプレビューが表示できれば……そのうち、できるようになるのではないかと。

AppleScript名：FaceTimeカメラから取り込み v1.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/10/07
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use framework "AVFoundation"
use scripting additions

property captureSession : missing value
property stillOutput : missing value
property saveURL : missing value

on run
　　set aPath to POSIX path of (choose file name)
　　my captureStillImage(aPath)
end run

on captureStillImage(aPath)
　　set saveURL to current application’s |NSURL|’s fileURLWithPath:aPath
　　
　　— セッション作成
　　set captureSession to current application’s AVCaptureSession’s alloc()’s init()
　　captureSession’s setSessionPreset:(current application’s AVCaptureSessionPresetPhoto)
　　
　　— カメラデバイスを取得
　　set device to (current application’s AVCaptureDevice’s defaultDeviceWithMediaType:(current application’s AVMediaTypeVideo))
　　if device = missing value then
　　　　display dialog "カメラが見つかりません。" buttons {"OK"} default button 1
　　　　return
　　end if
　　
　　— 入力設定
　　set input to (current application’s AVCaptureDeviceInput’s deviceInputWithDevice:device |error|:(missing value))
　　if input = missing value then
　　　　display dialog "カメラ入力を初期化できません。" buttons {"OK"} default button 1
　　　　return
　　end if
　　
　　if (captureSession’s canAddInput:input) as boolean then
　　　　captureSession’s addInput:input
　　else
　　　　display dialog "入力を追加できません。" buttons {"OK"} default button 1
　　　　return
　　end if
　　
　　
　　— 出力設定
　　set stillOutput to current application’s AVCapturePhotoOutput’s alloc()’s init()
　　if (captureSession’s canAddOutput:stillOutput) as boolean then
　　　　captureSession’s addOutput:stillOutput
　　else
　　　　display dialog "出力を追加できません。" buttons {"OK"} default button 1
　　　　return
　　end if
　　
　　
　　— セッション開始
　　captureSession’s startRunning()
　　delay 1 — カメラ起動待機
　　
　　— 写真設定
　　set photoSet to (current application’s AVCapturePhotoSettings’s photoSettings)
　　
　　— 撮影
　　(stillOutput’s capturePhotoWithSettings:photoSet delegate:me)
　　
　　delay 2
　　captureSession’s stopRunning()
end captureStillImage

on captureOutput:(output) didFinishProcessingPhoto:(photo) |error|:err
　　if err ≠ missing value then
　　　　display dialog "撮影エラー: " & (err’s localizedDescription() as text)
　　　　return
　　end if
　　set imageData to photo’s fileDataRepresentation()
　　imageData’s writeToURL:saveURL atomically:true
　　display notification "画像を保存しました。" with title "カメラキャプチャ"
end captureOutput:didFinishProcessingPhoto:|error|:

★Click Here to Open This Script　

指定日が所属する週のうち、最終日の日付を求める v2

Posted on 10月 7 by Takaaki Naganoya

指定日を基準として「今週末」までの日付を求めるAppleScriptです。

日付の範囲指定で「今週」という指定を行った場合、+7日を足して相対的に1週間先の日付を返すという処理方法もありますが、（日本国内の）常識的には週末までの日付を返すことでしょう。

そして、今週末といった場合に、日曜日はじまりのカレンダーであれば土曜日が該当するわけですが、全世界的に考えると「日曜日はじまりではない」カレンダーを採用しているエリア（国）も存在しています。

月曜日はじまりのカレンダーを採用している国には、ヨーロッパ全域（EU諸国？）などがあるようです。

「今週末」というキーワードをmacOSの自然言語処理系の機能を用いて具体的な日付に変換することは可能ですが、OSアップデートのたびにAppleがバグを作りやすい機能なので（こんなところにまでバグを作るAppleのエンジニアが信じられない）、もうちょっと安心して計算できるプログラムがあったほうがいいと考えました。

そこで、すでに作ってあるさまざまな日付計算系のルーチンを組み合わせて計算してみました。

AppleScript名：指定日が所属する週のうち、最終日の日付を求める v2.scpt

— Created 2015-02-02 by Shane Stanley
— Modified 2015-02-02 by Takaaki Naganoya
— Modified 2025-10-01 by Takaaki Naganoya

— v2 最終週で、カレンダーが途中で途切れているケースに対応

use AppleScript
use scripting additions
use framework "Foundation"

set targY to 2025
set targM to 9
set targD to 21

set theLastDay to calcLastDayFromTheTargetDay(targY, targM, targD) of me
–> date "2025年9月27日土曜日 0:00:00"

–指定日が所属する週のうち、最終日の日付を求める
on calcLastDayFromTheTargetDay(targY, targM, targD)
　　–指定日が月内で何週目に該当するかを算出
　　set targWN to getDatesWeekNumberWithinAMonth(targY, targM, targD) of me
　　–> 4
　　
　　–指定日の当該週の日付を1D Listで返す
　　set wRes to getWeekDatesWithinAWNinAMonth(targY, targM, targWN) of me
　　–> {21, 22, 23, 24, 25, 26, 27}
　　
　　–1D List（当該週の日付）内における指定日の登場インデックスを算出
　　set cRes to offsetOf(wRes, targD) of me
　　
　　–1D List（当該週の日付）内の末尾までの日付を返す
　　set restDays to items cRes thru -1 of wRes
　　–> {28, 29, 30, missing value, missing value, missing value, missing value}
　　
　　–指定日が所属する週のうち、最終日の日付を求める
　　set revList to reverse of restDays –逆順で末尾から数字が入っている場所をシーケンシャルサーチ
　　repeat with i in revList
　　　　set j to contents of i
　　　　if j is not equal to missing value then
　　　　　　exit repeat
　　　　end if
　　end repeat
　　
　　set targDate to getDateInternational(targY, targM, j, 23, 59, 59, "JST") of me
　　
　　return targDate
end calcLastDayFromTheTargetDay

–日曜日はじまりのカレンダーにおいて、指定年月内の指定週目の日付を配列で返す
on getWeekDatesWithinAWNinAMonth(targY, targM, targWN)
　　set mRen to getMlenInternational(targY, targM) of me
　　
　　set aList to make2DBlankArray(7, 5) of me –1か月分の2次元配列を求める
　　
　　set aCount to 1
　　repeat with i from 1 to mRen
　　　　set tmpDO to getDateInternational(targY, targM, i, 23, 59, 59, "JST") of me –当初、00:00:00に指定していたが、週末（土曜日）を指定したときに、範囲が00:00;00〜00:00:00になると具合がよくないので00:00:00〜23:59:59になるようこの時間に変更し
　　　　set aWD to weekday of tmpDO as number
　　　　
　　　　set aList to setItemByXY(aWD, aCount, aList, i) of me
　　　　
　　　　if aWD = 7 then
　　　　　　set aCount to aCount + 1
　　　　end if
　　end repeat
　　
　　return item targWN of aList
end getWeekDatesWithinAWNinAMonth

–日曜日はじまりのカレンダーにおいて、指定年月日の日付が月内の何週目にあたるかを算出
on getDatesWeekNumberWithinAMonth(targY, targM, targD)
　　set mRen to getMlenInternational(targY, targM) of me
　　
　　set aList to make2DBlankArray(7, 5) of me
　　
　　set aCount to 1
　　repeat with i from 1 to mRen
　　　　set tmpDO to getDateInternational(targY, targM, i, 23, 59, 59, "JST") of me –当初、00:00:00に指定していたが、週末（土曜日）を指定したときに、範囲が00:00;00〜00:00:00になると具合がよくないので00:00:00〜23:59:59になるようこの時間に変更した
　　　　set aWD to weekday of tmpDO as number
　　　　
　　　　set aList to setItemByXY(aWD, aCount, aList, i) of me
　　　　
　　　　if i = targD then return aCount
　　　　
　　　　if aWD = 7 then
　　　　　　set aCount to aCount + 1
　　　　end if
　　　　
　　end repeat
　　
　　return false
end getDatesWeekNumberWithinAMonth

–現在のカレンダーで指定年月の日数を返す
on getMlenInternational(aYear, aMonth)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar() — do *not* use initWithCalendarIdentifier:
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　–>　　{location:1, length:31}
　　return |length| of theResult
end getMlenInternational

–Make a GMT Date Object with parameters from a given time zone.
on getDateInternational(aYear, aMonth, aDay, anHour, aMinute, aSecond, timeZoneAbbreviation)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar()
　　theNSCalendar’s setTimeZone:(current application’s NSTimeZone’s timeZoneWithAbbreviation:(timeZoneAbbreviation))
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:aDay hour:anHour minute:aMinute |second|:aSecond nanosecond:0
　　return theDate as date
end getDateInternational

–Listに配列的な添字を使ってアクセスするルーチン群
on xFill(aX, aY, aList, aVal, aRepNum)
　　repeat with x from aX to (aX + aRepNum – 1)
　　　　set aList to setItemByXY(x, aY, aList, aVal) of me
　　end repeat
　　return aList
end xFill

on yFill(aX, aY, aList, aVal, aRepNum)
　　repeat with y from aY to (aY + aRepNum – 1)
　　　　set aList to setItemByXY(aX, y, aList, aVal) of me
　　end repeat
　　return aList
end yFill

on getItemByXY(aX, aY, aList, aBlankItem)
　　try
　　　　set aContents to contents of (item aX of item aY of aList)
　　on error
　　　　set aContents to aBlankItem
　　end try
　　return aContents
end getItemByXY

on setItemByXY(aX, aY, aList, aContents)
　　try
　　　　set (item aX of item aY of aList) to aContents
　　end try
　　return aList
end setItemByXY

–空白の2D Array を出力する
on make2DBlankArray(curLen, curMax)
　　set outArray to {}
　　repeat curMax times
　　　　set aList to {}
　　　　repeat curLen times
　　　　　　set the end of aList to missing value –オリジナルの""（ヌル文字）からmissing valueに変更
　　　　end repeat
　　　　set the end of outArray to aList
　　end repeat
　　return outArray
end make2DBlankArray

–1D Listのoffsetを求める
on offsetOf(aList as list, aTarg)
　　set aArray to current application’s NSArray’s arrayWithArray:aList
　　set aIndex to aArray’s indexOfObjectIdenticalTo:aTarg
　　return (aIndex + 1)
end offsetOf

★Click Here to Open This Script　

テキストベースの棒グラフ取得

Posted on 9月 27 by Takaaki Naganoya

テキストで作成した棒グラフの生成AppleScriptです。

比較的どうでもいいデータの傾向を知りたい場合に棒グラフ表示させて全体の傾向を把握することが、よくあります。そんなときに、文字だけで作成した棒グラフを生成します。何回か書いたことがあるような気もするのですが、簡単なものを作っておきます。

本Scriptで生成するグラフのタイプは2種類。

▲モノクロ表示用の、同じ文字を重ねて棒グラフを表示するタイプ

▲カラー（色分け）表示用の、絵文字を用いて色分けして棒グラフを表示するタイプ

項目名の最大文字数を求めて、他の項目で文字数が足りない箇所には不足分のスペースを足して、グラフの位置揃えを行なっていますが、このあたりタブで処理するべきなのか。

実際には、Pages書類上で選択しておいたオブジェクトから画像（image）のみピックアップして、それらの幅を集計してグラフ表示するような用途に使っています。

AppleScript名：テキストベースの棒グラフ取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/09/27
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use radioLib : script "displayTextView"

set bList to {12, 21, 15, 26}
set labelList to {"Aaaa", "Bbb", "Cc", "D"}

set aStr to retCharBarChart(labelList, bList, "|") of me
set aStr to "Name" & tab & tab & "Data" & tab & tab & "Number" & return & return & aStr
display text view aStr main message "Bar chart Sample 1" sub message "Sub Message" with properties {font name:"Courier", size:32, width:800, height:300, color:{0, 255, 128}}
(*
"Name　　　　Data　　　　Number

Aaaa　　　　|||||||||||| 12
Bbb 　　　　||||||||||||||||||||| 21
Cc 　　　　||||||||||||||| 15
D 　　　　|||||||||||||||||||||||||| 26
"
*)

set bStr to retCharBarChart(labelList, bList, false) of me
(*
"Aaaa　　　　🟥🟥🟥🟥🟥🟥🟥🟥🟥🟥🟥🟥 12
Bbb 　　　　🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦🟦 21
Cc 　　　　🟨🟨🟨🟨🟨🟨🟨🟨🟨🟨🟨🟨🟨🟨🟨 15
D 　　　　🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩🟩 26
"
*)
set bStr to "Name" & tab & tab & "Data" & tab & tab & "Number" & return & return & bStr
display text view bStr main message "Bar chart Sample 2" sub message "Sub Message" with properties {font name:"Courier", size:16, width:800, height:150, color:{0, 255, 128}}

–文字ベースで棒グラフを作成するための文字グラフルーチン
on retCharBarChart(labelList, bList, charFlag)
　　–ラベル文字の長さをそろえる（文字種類については不問、単に文字数をそろえるだけ）
　　set tMax to maximumItemLengthFromList(labelList) of me
　　
　　set resText to ""
　　–set aChar to "■"
　　set aCharList to {"🟥", "🟦", "🟨", "🟩", "🟧", "🟪", "🟫", "⬛️", "❤️", "💙", "💛", "💚", "🧡", "💜", "🤎", "🩶", "🖤", "🔴", "🔵", "🟡", "🟢", "🟠", "🟣", "🟤", "⚫️"}
　　set aCharLLen to length of aCharList
　　
　　set iCounter to 1
　　set aCharPointer to 1
　　
　　if charFlag = false then
　　　　–ローテーション方式の色文字グラフ
　　　　repeat with i in bList
　　　　　　set j to contents of i
　　　　　　set aLabel to (contents of item iCounter of labelList) as string
　　　　　　set aLabel to paddingSpacesAfter(aLabel, tMax, " ") of me
　　　　　　
　　　　　　set tmpChar to contents of item aCharPointer of aCharList
　　　　　　set resText to (resText & aLabel & tab & tab & makeCharRep(j, tmpChar) of me & " " & j as string) & return
　　　　　　
　　　　　　set iCounter to iCounter + 1
　　　　　　set aCharPointer to aCharPointer + 1
　　　　　　if aCharPointer > aCharLLen then
　　　　　　　　set aCharPointer to 1
　　　　　　end if
　　　　end repeat
　　else
　　　　–指定文字で作成する文字グラフ
　　　　repeat with i in bList
　　　　　　set j to contents of i
　　　　　　
　　　　　　set aLabel to (contents of item iCounter of labelList) as string
　　　　　　set aLabel to paddingSpacesAfter(aLabel, tMax, " ") of me
　　　　　　
　　　　　　set resText to (resText & aLabel & tab & tab & makeCharRep(j, charFlag) of me & " " & j as string) & return
　　　　　　
　　　　　　set iCounter to iCounter + 1
　　　　　　set aCharPointer to aCharPointer + 1
　　　　　　if aCharPointer > aCharLLen then
　　　　　　　　set aCharPointer to 1
　　　　　　end if
　　　　end repeat
　　end if
　　
　　return resText
end retCharBarChart

–指定文字を指定回数連結したテキストを返す
on makeCharRep(aNum, aChar)
　　set aText to ""
　　repeat aNum times
　　　　set aText to aText & aChar
　　end repeat
　　return aText
end makeCharRep

–指定文字列に、指定の長さまで空白文字列を追加
on paddingSpacesAfter(aDat as string, targLen as integer, padStr as {boolean, string})
　　set dLen to length of aDat
　　if dLen > targLen then error "Logical error: Target length is shorter than data length"
　　copy aDat to aStr
　　
　　set padStr to makeCharRep(targLen – dLen, padStr) of me
　　return aStr & padStr
end paddingSpacesAfter

–1D Listで最長の文字列の文字数を返す
on maximumItemLengthFromList(nList as list)
　　script o
　　　　property nl : nList
　　　　property itemNo : 1
　　end script
　　
　　set max to length of (item 1 of o’s nl)
　　
　　repeat with i from 2 to (count nList)
　　　　set n to length of (item i of o’s nl)
　　　　if n > max then
　　　　　　set max to n
　　　　　　set o’s itemNo to i
　　　　end if
　　end repeat
　　return length of (contents of (item (o’s itemNo) of nList))
end maximumItemLengthFromList

★Click Here to Open This Script　

MacBook Air/MacBook Proのディスプレイ開閉角度を取得

Posted on 9月 23 by Takaaki Naganoya

samhenrigold氏によるLid Angle SensorをCocoa Framework化して呼び出して、MacBook Air/MacBook Proのディスプレイ開閉角度を取得するAppleScriptです。画面角度センサーを持たないMac miniなどで実行した場合には値を返さず処理終了します。

▲左：119度　右：90度　センサーが返してくる値と実際の画面角度の値には若干の「差」がある。0度の開始値が若干画面が開いた状態になっている？

本記事に掲載しているAppleScriptのプログラムリストだけでは実行できないため、下記のリンクからFrameworkバイナリ入りのScript Bundleをダウンロードして実行してください。

Apple Silicon Macでは実行確認していますが、Intel Macで動くかどうかは未検証です。一応、githubのsamhenrigoldの説明によると2019年のMacBook Pro以降で導入されたセンサーとのことで、Intel Macでも当該モデルであれば動作することが期待されます。

ただし、M1 MacBook Air/Proで問題が発生することが報告されているようです（自分は実機で確認していません。センサー値の取得だけなら問題が起きないのか、センサー値の取得で問題が起きているのか）。

同プログラムをCocoa Framework化して呼び出しているため（Universal Binary）、Script Debuggerおよび同環境で書き出したEnhanced Appletなどで実行可能です。

→ Download Script Bundle with Framework

→ Download angleSensorKit Xcode Project

AppleScript名：画面開閉角度センサーの値を取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/09/07
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "angleSensorKit" — Created by Sam on 2025-09-06. https://github.com/samhenrigold/LidAngleSensor
use scripting additions

set anASensor to current application’s LidAngleSensor’s alloc()’s init()

set aRes to anASensor’s isAvailable() as boolean
if aRes = false then return —Maybe not MacBook Air/Pro
set sensorVal to anASensor’s lidAngle()

return sensorVal

★Click Here to Open This Script　

スクリプトメニューでAirDropが使えない？

Posted on 9月 23 by Takaaki Naganoya

macOS 15/26にて、AirDropをAppleScriptから利用するAirSharing Libを、スクリプトメニューに入れたAppleScriptから呼び出せないという現象に直面しています。

スクリプトエディタ上で動かすと動作するのですが、スクリプトメニューから動かすとまったく動作しません。一般ユーザー向けのAppleScript実行環境であるスクリプトメニューで動作しないのはかなり問題です。

AirSharing LibはもともとSal Soghoianが書いたプログラムにWiFi制御系のコードを追加して書いたものですが、現状のmacOS 15上で動作する最低限の記述だとこんな感じ（↓）です。

スクリプトメニュー上で動作するために、何かの「おまじない」が必要なのか、そもそもスクリプトメニューの仕様上それが禁止されるようになったのか？　なかなか不思議なところです。

動作確認できたAppleScript実行環境：
スクリプトエディタ、Script Debugger、Switch Control、Automator、Claris FileMaker Pro 2025、FastScript 3、Xojo 2025

AppleScript名：AirDropTest.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/09/23
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions

property airDropService : missing value

set theFile to POSIX path of (choose file with prompt "AirDropで共有するファイルを選んでください:")

my performSelectorOnMainThread:"shareWithAir:" withObject:(theFile) waitUntilDone:true
–my shareWithAir:theFile–for debug

on shareWithAir:thePOSIXFile
　　set theFile to thePOSIXFile as string
　　set fileURL to current application’s NSURL’s fileURLWithPath:(theFile)
　　
　　— AirDrop用の共有サービスを取得
　　set airDropService to current application’s NSSharingService’s sharingServiceNamed:(current application’s NSSharingServiceNameSendViaAirDrop)
　　
　　if airDropService ≠ missing value then
　　　　airDropService’s performSelectorOnMainThread:"performWithItems:" withObject:{fileURL} waitUntilDone:true
　　else
　　　　display dialog "AirDrop共有サービスが利用できません。" buttons {"OK"} default button 1
　　end if
end shareWithAir:

★Click Here to Open This Script　

指定フォルダ内から指定拡張子のファイルを取得し、エイリアスだったらオリジナルのパスをPOSIX pathで取得

Posted on 9月 20 by Takaaki Naganoya

指定フォルダから、指定拡張子のファイルを取得し、取得したファイルがエイリアス書類だったらオリジナルのパスを返すAppleScriptです。

AppleScriptを指定スケジュールで実行するAppleScriptを作成しており、スケジュールフォルダ以下に「毎月15日 15時」といった名前のフォルダを作っておき、その中に入れたAppleScriptを指定スケジュールで実行するようにしてありました。

ただ、フォルダ内に入れるのが「AppleScript書類そのもの」だと、運用上いろいろまずい（同じScriptの複製が大量にできてしまうとか）ので、エイリアスを入れても反応するように、本Scriptを書いてみた次第です。

割とちゃんと動いているように見えます。

2025/9/29修正：
処理対象にエイリアス書類「ではなく」本物のファイルが指定されていた（＝エイリアス書類ではなかった）場合にエラーになっていました。作成・使用目的は「エイリアス書類の実体の追跡」ではあったものの、実体のファイルに行き当たった場合にエラーになるのは意図しない動作です。

このため、掲載リストを一部修正しました。

AppleScript名：指定フォルダ内から指定拡張子のファイルを取得し、エイリアスだったらオリジナルのパスをPOSIX pathで取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/09/19
–　　Modified on: 2025/09/29
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use scripting additions

set aRoot to choose folder

set scptList to getFilePathListWithResolveAlias(aRoot, "scpt") of me
–> {"/Users/me/Documents/sample2.scpt", "/Users/me/Documents/sample1.scpt"}

on getFilePathListWithResolveAlias(aFol, aExt)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aFol)
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　set f0List to filePaths as list
　　if f0List = {} then return {}
　　
　　set f2List to {}
　　repeat with i in f0List
　　　　set tmpPath1 to POSIX path of i
　　　　set tmpPath2 to (my fullpathOfOriginalFileForAlias:tmpPath1)
　　　　set tmpPath to (current application’s NSString’s stringWithString:(tmpPath2))
　　　　set the end of f2List to tmpPath as string
　　end repeat
　　
　　return f2List
end getFilePathListWithResolveAlias

–エイリアスファイルのパスからオリジナルのファイルパス（POSIX Path）を返す
on fullpathOfOriginalFileForAlias:posixPath
　　tell current application’s |NSURL|
　　　　set anNSURL to its fileURLWithPath:posixPath
　　　　set theData to its bookmarkDataWithContentsOfURL:anNSURL |error|:(missing value)
　　　　set theResult to its resourceValuesForKeys:{current application’s NSURLPathKey} fromBookmarkData:theData
　　end tell
　　
　　if theResult = missing value then return posixPath
　　
　　return (theResult’s objectForKey:(current application’s NSURLPathKey)) as text
end fullpathOfOriginalFileForAlias:

★Click Here to Open This Script　

macOS 15.xで自作AppleScriptライブラリの一部がScript Menuから使えなくなったので修正

Posted on 9月 19 by Takaaki Naganoya

X（旧Twitter）上でPiyomaru SoftwareのAppleScriptライブラリについてフィードバックをいただきました。おおよそ改修が済んでいるため、ドキュメントを書き次第、最新版をBlogからダウンロードできるようにしておきます。

こうしたフィードバックを得るために公開しているので、動作しないとか、予想外の動作を行った場合にはフィードバックしていただきたいところです（すぐに対処できる保証はないのですが）。

確認された現象

Piyomaru Software制作のAppleScriptライブラリの一部で、macOS 15.xのスクリプトメニューに呼び出しScriptを入れた場合に実行できないものがありました。その一方で、スクリプトエディタ/Script Debugger上では実行できます。

・AirSharing Lib
・Choose location Lib
・Display Youtube Lib
・Pickup Color Lib

修正して動作するようになった事例

CheckboxLibについては、SDEF中のdocumentからのムービーおよび画像へのリンクを削除。

Enumをas stringでstringにcast処理していた箇所が、スクリプトメニュー上では動作しなくなっていた（→ stringへのcastをやめることで問題解消）。

choose color Libも同様に、Enumをas stringでstringにcast処理していた場所で、スクリプトメニュー上では動作しなくなっていたので修正。

動作条件そのものが変更になったライブラリ

・Display youtube Lib
macOS 15上ではInfo.plistにNSAppTransportSecurityのエントリを追加してアプレット書き出しが必要です。
ただし、macOS 26上ではスクリプトメニュー上で呼び出しScriptを実行しても、問題なくYouTubeムービーの再生が可能です。

問題を解消できていないライブラリ

目下、スクリプトメニューから呼び出すと動作しないライブラリは以下の通り。

・AirSharing Lib
・Choose location Lib

シンプルな文字置換

Posted on 9月 13 by Takaaki Naganoya

AppleScriptで文字置換を行う場合には、いくつかの方法があります。

①text item delimitersを利用する

AppleScriptの登場以来、利用されてきた方法です。AppleScriptの処理系では最速といってよい方法ですが、複数の箇所を一気に置換するのでやや過剰なのと処理方法が独特なので敬遠する人もいるようです。

また、処理対象の文字列のサイズが数Mバイト以上になると、処理が終了しなかったりします。巨大な文字列の置換には⑤が推奨されます。CotEditorのようなScriptableなテキストエディタの機能を利用するのもアリでしょう。

AppleScript名：文字置換（最短）.scpt

set origText to "abcdefg"
set targStr to "de"
set repStr to "xx"

set a to repChar(origText, targStr, repStr) of me
–> "abcxxfg"

–Written By Philip Aker
–文字置換ルーチン
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

★Click Here to Open This Script　

②shellコマンドを利用する

do shell scriptコマンド経由で置換コマンドを利用する方法です。Mac OS X以降後に利用できるようになったものですが、日本語に対して正確に置換できるのか不安が残るので、個人的にはあまり積極的には利用していません。

③OSAXを利用する

macOS 10.15でサードパーティのOSAX（Scripting Additions）が廃止されたため、現在では利用できません。

④AppleScript Librariesを利用する

Shane StanleyのRegexAndStuffLibなどのライブラリを用いて正規表現を用いた文字置換を利用するものです。

⑤Cocoaの機能を利用する

Cocoaの機能を呼び出して文字置換を行うものです。いくつも利用できる機能があります。正規表現を使うものなど、お好きなものを利用してください。

AppleScript名：ASOCで文字置換5.scptd

— Created 2015-06-30 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set a to "あいうえお＋＋かきくけこ"
set b to cleanUpText(a, "＋", "●")
–> "あいうえお●●かきくけこ"

on cleanUpText(someText, targStr, repStr)
　　set theString to current application’s NSString’s stringWithString:someText
　　set targString to current application’s NSString’s stringWithString:targStr
　　set repString to current application’s NSString’s stringWithString:repStr
　　
　　set theString to theString’s stringByReplacingOccurrencesOfString:targString withString:repString options:(current application’s NSRegularExpressionSearch) range:{location:0, |length|:length of someText}
　　return theString as text
end cleanUpText

★Click Here to Open This Script　

これらに加えて、もっと簡単な方法がないかと探してみたら、

⑥offset ofで文字列検索して置換を行う

offset ofで置換対象の文字列を検索して置換を行います。オリジナル文字列に対して置換対象の文字列の位置が「冒頭ではない」「末尾ではない」という条件がそろっていて、かつ置換対象が0ないし1回しか対象文字列中に存在しないことが事前に分かりきっている場合にのみ使えます。

set urlData to "https://www.amazon.co.jp/gp/css/summary/print.html/ref=oh_aui_ajax_invoice"

set anOffset to offset of "/gp/" in urlData
set newURL to (text 1 thru (anOffset + (length of "/gp/") – 1) of urlData) & "legacy" & (text (anOffset + (length of "/gp/") – 1) thru -1 of urlData)

–> "https://www.amazon.co.jp/gp/legacy/css/summary/print.html/ref=oh_aui_ajax_invoice"

★Click Here to Open This Script　

このぐらいで使えますが、本当にすべてのパターンを利用するには、場合分けしつつ書く必要があります。シンプルなはずなのに、シンプルになっていないという。

AppleScript名：単純文字置換.scpt

set urlData1 to "https://www.amazon.co.jp/gp/css/summary/print.html/ref=oh_aui_ajax_invoice"
set newURL1 to replaceOne(urlData1, "/gp/", "/gp/legacy/") of me
–> "https://www.amazon.co.jp/gp/legacy/css/summary/print.html/ref=oh_aui_ajax_invoice"

set urlData2 to "https://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/"
set newURL2 to replaceOne(urlData2, "/gp/", "/gp/legacy/") of me
–> "https://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/legacy/"

set urlData3 to "https://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/"
set newURL3 to replaceOne(urlData3, "https://", "http://") of me
–> "http://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/"

on replaceOne(origStr as string, targStr as string, repStr as string)
　　set anOffset to offset of targStr in origStr
　　if anOffset = 0 then return origStr
　　set {aLen, bLen} to {length of origStr, length of targStr}
　　
　　if anOffset + bLen > aLen then
　　　　–置換対象文字が末尾にある場合
　　　　set newStr1 to (text 1 thru (anOffset – 1) of origStr)
　　　　set newStr2 to ""
　　else if anOffset = 1 then
　　　　–置換対象文字が先頭にある場合
　　　　set newStr2 to (text (anOffset + ((length of targStr))) thru -1 of origStr)
　　　　set newStr1 to ""
　　else
　　　　–通常パターン
　　　　set newStr1 to (text 1 thru (anOffset – 1) of origStr)
　　　　set newStr2 to (text (anOffset + ((length of targStr))) thru -1 of origStr)
　　end if
　　return newStr1 & repStr & newStr2
end replaceOne

★Click Here to Open This Script　

macOS（Mac OS X/OS X）上のAppleScriptの歴史

Posted on 9月 9 by Takaaki Naganoya

macOS 26.0のリリース日が公開されそうなので、AppleScriptの歴史年表について書いておきます。

各種電子書籍に掲載している内容ですが、一般にも共有できていたほうがメリットが多そうなので公開しておきます。

マイナーバージョンで発生したバグの件については、すべて掲載できていません。ファイル書き込み時の文字エンコーディングが狂うとか、OSのバージョン番号をまともに返してこないとか。

Mac OS X 10.0（AppleScript v1.6）
◯Classic Mac OS向けに書かれたOSAXを認識しなくなった　
◯Unicode Textを扱えるようになった（as Unicode Text）
◯Mac OS Xのファイル/アプリケーションの新しい仕組み「バンドル」を扱えるようになった　
◯コマンドラインからosascript、osacompile、osadecompile、osalangが使えるようになった　
◯read/writeコマンドで2GB以上のデータの読み書きができるようになった

Mac OS X 10.1（AppleScript v1.7）
◯AppleScript自体の改行コードに、CR＋LF（Windows）、CR（Mac）、LF（Unix）の３種類を使えるようになった（ネイティブはCR）
◯プログラムリンクの機能が復活。ただし、AppleTalkによるノード名称の指定はできず、TCP/IPベースに変更される（eppc://）
◯SOAPとXML-RPCの機能がサポートされた
◯拡張子を扱えるようになった
◯アプレット保存時にPowerPC/68kのどちらかのバイナリを選択するようになった

Mac OS X 10.2（AppleScript v1.9）
◯choose URLがWindows系サービスとFTPサーバーに対応
◯Script Menuの機能が単体でダウンロード提供されるようになった
（Folder ActionsがSystem Eventsの管轄にあるなど混乱期）

Mac OS X 10.3（AppleScript v1.9.2）
×AppleScript史上最大最悪のバグ「is in」演算子が使えないバグが発生（→10.3.x台で修正される）
◯AppleScriptおよびアプリケーションがバンドル形式でも保存できるようになった
◯delayに小数点以下の数値が指定できるようになった
（×AppleScriptの処理系のバグがとても多かった暗黒時代）

Mac OS X 10.4（AppleScript v1.10）
◯日本語環境がらみのバグが多数修正されたが、本格的な修正は10.5を待つ必要があった
×バグの指摘から修正まで時間がかかり、このバージョンを経てようやく処理系の安定が図られるようになった
×Finderからファイルパスを取得するとエンコーディングがおかしくなったり、display dialogで日本語がまともに表示できないアプリが存在していたのもこのバージョンまで

Mac OS X 10.5（AppleScript v2.0）
◯文字列をすべてUnicodeで扱うようになった
◯ASCIIキャラクター0〜255だけでなく、Unicodeの広い範囲の文字を取得できるように「text id xxxx」（xxxxは10進数で指定）が新設された
◯日本語の文字を含むファイルパスの取扱いがまともになってきた
◯アプリケーション起動中の状態（running）を取得できるようになった
◯アプリケーションをバンドルIDで指定できるようになった
◯FolderAction SetupがScriptableになった
◯「#」ではじまるコメント行を書けるようになった

OS X 10.6（AppleScript v2.1）
◯「スクリプトエディタ」が「AppleScriptエディタ」と名称変更
◯AppleScriptエディタが「ユーティリティー」フォルダに移動になった
◯AppleScriptエディタ上での構文色分け機能が強化された
◯AppleScript処理系の（ログイン後の）起動が速くなった
→　ただし、逆にログインアイテムに登録したAppleScriptアプレットが正しく実行されないというバグを生んだ。ログインアイテムに登録したAppleScriptアプレットでSystem Eventsを呼び出すと、System Eventsの起動が間に合わず、エラーになったりしていた

OS X 10.7（AppleScript v2.2）
◯AppleScriptエディタにスクリプトテンプレートの機能が追加された
◯AppleScriptエディタ上でAppleScriptObjC（Cocoa AppleScript Applet）を書けるようになった
×64bit版に書き直されたFinder、通称「Cocoa Finder」の動作速度が遅く、とくにファイル処理をFinderに任せると大幅に速度が低下する現象が発生。Scripterの間で「ファイル処理をFinderで行わないという」暗黙の合意が広がった

OS X 10.8（AppleScript v2.2）
◯AppleScriptエディタに「エクスポート」の機能がついた。アプレットはエクスポートして生成するよう変更
◯AppleScriptがOSのSandbox化の機能の影響を受けるようになった

OS X 10.9（AppleScript v2.3）
◯AppleScript 20年来の大改革。ライブラリ機能「AppleScript Libraries」が追加された
◯ユーザーへのNotification Center経由での通知命令「display notification」が追加された
◯AppleScriptObjCのハンドラ記述方式に、Objective-Cに似た記述方式が使えるようになった（Xcode上）
◯AppleScriptエディタでアプレットへのコードサインができるようになった
◯AppleScriptエディタがiCloudに対応し、iCloud上にAppleScriptを保存、iCloudからのAppleScriptの読み込みができるようになった

OS X 10.10（AppleScript v2.4）
◯「AppleScriptエディタ」が名称変更でふたたび「スクリプトエディタ」に
◯スクリプトエディタ上でCocoaの機能を利用するAppleScriptObjCを標準でサポートするようになった
◯プログレスバーの表示機能をサポート
◯「as」による型変換（cast）で複数の型をリストで指定できるようになった
◯AppleScriptObjCのハンドラ記述方式に、Objective-Cに似た記述方式が使えるようになった（スクリプトエディタ上）
◯ハンドラ（サブルーチン）宣言部でパラメータの型指定が行えるようになった
◯無意味句を用いたハンドラ記述した場合に、パラメータ省略時の初期値を宣言できるようになった 
×AppleScriptアプレット中でdelayコマンドを利用したときに、正しく時間待ちされないバグ 
×AppleScriptとCocoaの間で小数点を含む実数を変換すると小数点以下の値が欠落するバグ
×NSStringとtext、NSStringとstring、NSStringとUnicode textの間でデータ変換をしたときに、一部の文字が正しく変換されないというバグ（castバグ）
×Folder Actionにバグ。利用者権限に抵触してまともに動作しない（OS X 10.11で修正）

OS X 10.11（AppleScript v2.5）
◯Folder Actionのバグ修正。FSEventsを用いて随時ドロップされたファイルのイベントを受け付けるように処理方式があらためられた（以前は数秒ごとに対象フォルダをチェックする方式）
◯10.10のAppleScriptObjCのバグ修正（cast、enum）
◯AppleScript Librariesのファイルの置き場所を追加（環境変数で指定可能に）
◯より多くのCocoaのデータ型をAppleScriptの型に変換するようになった
◯delayの時間待ち無効バグ修正

macOS 10.12（AppleScript v2.5）
◯パフォーマンス改善のためのバグ修正を実施
×ドロップレットに不具合。ファイルの拡張属性「com.apple.quarantine」がついていると、ファイルが無視される（Script側で対処。以後Apple修正せず）
×Scripting Bridgeの定義ファイルに不具合。Enum「NSNotFound」のブリッジされている定義値が-1にならない（macOS 10.13.1で修正）

macOS 10.13（AppleScript v2.7）
◯セキュリティ関連の修正を実施
◯NSCharacterSet newlineCharacterSet()のようなメソッドでクラッシュしなくなった ◯NSNotFoundのScriptingBridge経由でブリッジされる定義値を-1に修正（macOS 10.13.1）
◯Remote AppleEventsの機能が復旧し、AppleScriptからLAN上の他のマシンの上で動作しているアプリケーションを直接操作できるようになった（起動している必要がある） 
◯ScriptingBridge定義ファイルにバグ。PDFKit中のPDFPageのcurrentPage()がブリッジされていない。報告するも未修正（ずっと未修正）

macOS 10.14（AppleScript v2.7）
◯システム環境設定の「アクセシビリティ」＞「プライバシー」に、「フルディスクアクセス」「オートーメーション」が新設され、ディスクやリソースへのアクセス、アプリケーションとの通信を管理するようになった。これに伴い、このアプリケーションへのアクセス認証を得ていない場合に発生するエラー（エラーコード-1743）が新設された。
◯サードパーティのOSAXサポートが廃止された
◯スクリプトメニューが、Menu Extraから独立したアプリケーションに変更になった
◯DVDプレイヤーがアプリケーションから補助ツールに格下げになり、AppleScriptからの操作が行えなくなった
◯SIPの機能が強化されセキュリティが強化された。その結果、アプレット内にFrameworkを同梱して配布したり、~/Library/Frameworksに入れたフレームワークをスクリプトエディタが認識しなくなった（事実上、Script Debuggerが必須に）
◯スクリプトエディタのAppleScript用語辞書から「execute」コマンドが削除された
◯住所録（Contacts.app）でプラグインScriptを利用できる機能が削除された（AppleScript用語辞書には残されているが機能しない）

macOS 10.15（AppleScript v2.7）
◯Remote AppleEvents（eppc）経由で他のマシン上のアプリケーションと通信する場合に、同一ユーザー名であることが必要になった。この制限を解除するためには、「defaults write /Library/Preferences/com.apple.AEServer RestrictAccessToUserSession -bool false」の操作をターミナル上で行う必要がある
◯AppleScript専用補助ツール「Image Events」がデフォルト状態ではファイルに一切アクセスできない状態で出荷される（セキュリティ設定によりアクセス可能に。その後のOSバージョンでも修正されない）
 ◯Cocoa呼び出しを行なった際の実行速度が大幅に低下（→macOS 12で修正）

macOS 11.0（AppleScript v2.7）
◯ARM（Apple Silicon）対応。AppleScript Appletなど実行アプリケーションがすべてApple Silicon/Intel 64のUniversal Binary化
◯Automator Action用に盲腸のように残っていたAppleScript Studioランタイムの廃止が明言される
 ◯AppleScriptアプレット中にproperty値が保存されなくなった。property値を保存する場合にはUser Defaultsに書き込む必要がある ◯ファイル共有のプロトコルに「afp://」が利用できなくなった。「smb://」に一本化 
◯AppleScript書類（.scpt）アイコンが単なるプレーンテキストのものに変わっている（バグなのか本気なのかは不明。macOS 11.x台では修正されない見込み） 
◯System Eventsの初回操作時に明示的に「launch」コマンドの実行が必要に（自動起動しない） 
◯macOS 11.5において、NSString’s stringWithFormat:メソッドをAppleScriptから呼び出してもクラッシュしなくなった（macOS 11.0〜11.4の間はクラッシュ発生）
 ◯これまでに書かれたCocoa Scriptingのプログラムで「書き方が間違っているが、許容されてきた」書き方がエラーもしくはクラッシュを引き起こすようになった
×AppleScriptがM1 CPUの高効率コア「Icestorm」で実行されてしまうため、Cocoa Scripting時にIntel CPUにくらべて10分の１〜70分の１程度にパフォーマンス低下（→macOS 12で修正）

macOS 12.0（AppleScript v2.8）
◯ショートカット.appが標準搭載される。ショートカットにAppleScript実行アクションが搭載され、ショートカット中からAppleScript（Cocoa Scripting機能を含む）の呼び出しが可能に
◯ショートカット.appが起動中でなくてもショートカットを実行できるShortcuts Eventsが標準搭載される 
◯Piyomaru Softwareの働きかけにより、macOS 10.15で生じたCocoa Scriptingの速度低下、およびmacOS 11で生じたApple Silicon MacのCocoa Scripting速度低下が是正される。Cocoa呼び出し時のAppleScriptの大幅な処理速度向上
◯macOS 12.3、悪意を持って作られたAppleScriptバイナリ（アプレット）のセキュリティ上の問題（CVE-2022-22626）を解消
◯macOS 12.1〜2の間、日本語環境限定で、NSDataDetectorで自然言語テキストから「電話番号」を抽出する機能が動作していなかった（12.3で修正）
◯macOS 12.3、スクリプトエディタのコンテクストメニュー（スクリプトアシスタント表示用）にバグ。項目が複数回表示される（macOS 13で修正）
 ◯macOS 12.3.1、セキュリティ強化にともなう不具合（Finder上のselectionをオープンすると、ファイルを作成したアプリケーションが起動されないエラーなど）を修正
 ◯macOS 12.4、AppleScriptアプレットで、入力検証を強化して、領域外読み込みの脆弱性に対処（CVE-2022-26697）。アプリケーションが予期せず終了したり、プロセスメモリが漏洩したりする可能性がある脆弱性に対し、配列境界チェック機能を改善して対処（CVE-2022-26698）。

macOS 13.0（AppleScript v2.8）
◯「システム環境設定」が「システム設定」に。AppleScriptで各種Paneを表示させる機能が動作しなくなった → macOS 13.5あたりでmacOS 14同様の機能を実装、機能復旧
◯「Font Book」がAppleScript非対応に
◯「アプリケーションのAppleScript用語辞書をブラウズする方法が、「アプリケーションのアイコンをスクリプトエディタにドラッグ＆ドロップする」ものから「アプリケーションのアイコンをスクリプトエディタの「ライブラリ」ウインドウにドラッグ＆ドロップもしくは「＋」ボタンのクリックで追加するやりかたに変更される（macOS 14で復旧）
×Text To Speech（テキスト読み上げ音声）のIDがすべて変更になる。日本語環境用にSiriのO-renとHattoriが搭載されるが、sayコマンドで使えるようにはなっていない 
×AppleScriptからMail.appにメール作成＋送信を行うと1通作成ごとに生成されたプロセスがメモリ上から消えず、メモリを食い潰してマシンの処理速度自体が遅くなる
×スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットが動作しない問題が発生 ◯テキスト読み上げキャラクタのうち一部のキャラクタで名前がローカライズされてしまい、sayコマンドで指定できないバグが発生（日本語環境限定バグ）

macOS 14.0（AppleScript v2.8）
◯「システム設定」のAppleScriptで各種Paneを表示させる機能が復旧
◯Safari v17で隠し命令「show credit card settings」が追加される。do javascript命令の実行許可のための「Apple EventからのJavaScriptを許可」の場所が設定＞デベロッパに変更される
◯ミュージック.appでplaylistの「loved」属性が「favorited」に変更される
◯連絡先.appの廃止済みプラグイン機能用の「Address Book Rollover Suite」の属性がhiddenに変更される
 ◯スクリプトエディタのコンテクストメニュー・スクリプトに、絵文字つきのファイル/フォルダのコンテンツを入れると、コンテクストメニューに「項目が重複して表示される」不具合が修正される
◯「アプリケーションのAppleScript用語辞書をブラウズする方法「アプリケーションのアイコンをスクリプトエディタにドラッグ＆ドロップ」が復旧する
×スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットが動作しない問題が継続中
×スクリプトメニューから呼び出したAppleScriptの実行速度が、スクリプトエディタ上よりも6倍以上遅くなる現象が発生
×半角スペース文字列の数値への型変換で処理系自体がクラッシュするバグ（14.0 Sonoma Crasher→ 15.0で修正）
×テキスト読み上げキャラクタのうち一部のキャラクタで名前がローカライズされてしまい、sayコマンドで指定できないバグが継続中（日本語環境限定バグ）

macOS 15.0（AppleScript v2.8）
◯Safariのtabにpidプロパティが追加される
◯AppleScriptドロップレットにドロップしたファイル/フォルダが、xattr「com.apple.quarantine」の影響とGatekeeperの兼ね合いですべてが受け渡されない現象がmcOS 10.12から継続して発生していたが、これが改められ、ドロップされたファイル/フォルダの欠損が発生しなくなった。なお、この変更がmacOS 13.xおよび14.xにもさかのぼって適用された
◯半角スペース文字列の数値への型変換で処理系自体がクラッシュするバグ（14.0, Sonoma Crasher）が解消
×スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットが動作しない問題が継続中 
×スクリプトメニューから呼び出したAppleScriptの実行速度が、スクリプトエディタ上よりも6倍以上遅くなる現象が継続中
×テキスト読み上げキャラクタのうち一部のキャラクタで名前がローカライズされてしまい、sayコマンドで指定できないバグが継続中（日本語環境限定バグ）

macOS 26.0（AppleScript v2.8）
◯スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットがApple Silicon Mac上で動作しない問題が解決される（？？？？？？）
◯スクリプトエディタ上でコンパイル（構文確認）を行うと、最終行が見えなくなる問題が解決される 
◯スクリプトエディタがDark Modeに対応
◯スクリプトエディタのアイコンがmacOS 26風に変更される

開始時刻から終了時刻までhh:mm形式の文字列を15分単位でリスト出力

Posted on 8月 13 by Takaaki Naganoya

指定の開始時刻から終了時刻まで、hh:mm形式の文字列を15分間隔でリスト出力するAppleScriptです。

ありもののサブルーチンを組み合わせて即席で作ったCocoa版のルーチンと、ChatGPT（GPT-5）に書かせた非Cocoa版のルーチンの2つがあり（ChatGPTにCocoa使用を指定せず）、速度を比較してみたら……

非Cocoa版のルーチンのほうが６倍ぐらい高速でした。データが小さすぎるとか、処理内容が小さすぎる場合にはCocoaの機能を利用しないほうが高速に処理できる場合があります。

Shane Stanleyの処理時間計測アプリ「ScriptGeek」が、かなりCocoa Scriptingの登場初期から存在しており、不思議に思ってきたものですが……処理内容の規模によってはCocoa Scriptingのほうが遅くなるケースがあるため、実際に書いて動かして計測してみないと、Cocoa Scriptingで高速化が達成できるかわからないところです。

このほか、AppleScriptのランタイム環境が何になるかによって実行速度は変わってきます。Xcode上で開発するCocoa Applicationなども実行特性が違うため、やはり動かして計測してみないと何がベストなのかはわかりません。

ただ、この程度の処理であれば、0.0028秒が0.4秒になったところで、何か実用上の差異が発生するわけでもありません。

追記：
追加で最速パターンを掲載しておきます。汎用性を求めて計算して出力していましたが、ほとんどの用途で毎回同じようなデータを出力することでしょう。なので、固定データを返すだけでいいだろうかと。高速版とくらべても65〜70倍ぐらい高速です（当たり前）。

AppleScript名：15分メッシュの時間文字列を生成.scptd

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aRes to generateWorkUnitList() of me
–> {"5:15", "5:30", "5:45", "6:00", "6:15", "6:30", "6:45", "7:00", "7:15", "7:30", "7:45", "8:00", "8:15", "8:30", "8:45", "9:00", "9:15", "9:30", "9:45", "10:00", "10:15", "10:30", "10:45", "11:00", "11:15", "11:30", "11:45", "12:00", "12:15", "12:30", "12:45", "13:00", "13:15", "13:30", "13:45", "14:00", "14:15", "14:30", "14:45", "15:00", "15:15", "15:30", "15:45", "16:00", "16:15", "16:30", "16:45", "17:00", "17:15", "17:30", "17:45", "18:00", "18:15", "18:30", "18:45", "19:00", "19:15", "19:30", "19:45", "20:00", "20:15", "20:30", "20:45"}

on generateWorkUnitList()
　　set hList to {}
　　
　　repeat with h from 5 to 20 by 1
　　　　repeat with m from 0 to 59 by 15
　　　　　　if {h, m} is not equal to {5, 0} then
　　　　　　　　set mStr to numToZeroPaddingStr(m, 2, "0")
　　　　　　　　set the end of hList to (h as string) & ":" & mStr
　　　　　　end if
　　　　end repeat
　　end repeat
　　
　　return hList
end generateWorkUnitList

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

AppleScript名：15分メッシュの時間文字列を生成（高速）.scpt

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set mList to retWorkingMeshStrList() of me
–> {"5:15", "5:30", "5:45", "6:00", "6:15", "6:30", "6:45", "7:00", "7:15", "7:30", "7:45", "8:00", "8:15", "8:30", "8:45", "9:00", "9:15", "9:30", "9:45", "10:00", "10:15", "10:30", "10:45", "11:00", "11:15", "11:30", "11:45", "12:00", "12:15", "12:30", "12:45", "13:00", "13:15", "13:30", "13:45", "14:00", "14:15", "14:30", "14:45", "15:00", "15:15", "15:30", "15:45", "16:00", "16:15", "16:30", "16:45", "17:00", "17:15", "17:30", "17:45", "18:00", "18:15", "18:30", "18:45", "19:00", "19:15", "19:30", "19:45", "20:00"}

on retWorkingMeshStrList()
　　set startSeconds to (5 * 3600) + (15 * 60) — 5:15 の相対秒
　　set endSeconds to (20 * 3600) — 20:00 の相対秒
　　set intervalSeconds to 15 * 60 — 15分間隔
　　
　　set timeList to {}
　　
　　repeat with t from startSeconds to endSeconds by intervalSeconds
　　　　set h to t div 3600
　　　　set m to (t mod 3600) div 60
　　　　— 2桁表示に整形
　　　　–set hStr to text -2 thru -1 of ("0" & h)
　　　　set hStr to h as string
　　　　set mStr to text -2 thru -1 of ("0" & m)
　　　　set end of timeList to (hStr & ":" & mStr)
　　end repeat
　　
　　return timeList
end retWorkingMeshStrList

★Click Here to Open This Script　

AppleScript名：15分メッシュの時間文字列を生成（最速）.scptd

use AppleScript version "2.4"
use framework "Foundation"
use scripting additions

set hList to generateWorkUnitList() of me

on generateWorkUnitList()
　　return {"5:15", "5:30", "5:45", "6:00", "6:15", "6:30", "6:45", "7:00", "7:15", "7:30", "7:45", "8:00", "8:15", "8:30", "8:45", "9:00", "9:15", "9:30", "9:45", "10:00", "10:15", "10:30", "10:45", "11:00", "11:15", "11:30", "11:45", "12:00", "12:15", "12:30", "12:45", "13:00", "13:15", "13:30", "13:45", "14:00", "14:15", "14:30", "14:45", "15:00", "15:15", "15:30", "15:45", "16:00", "16:15", "16:30", "16:45", "17:00", "17:15", "17:30", "17:45", "18:00", "18:15", "18:30", "18:45", "19:00", "19:15", "19:30", "19:45", "20:00"}
end generateWorkUnitList

★Click Here to Open This Script　

Finderを終了させる

Posted on 7月 29 by Takaaki Naganoya

Finderを終了させたままにしておくAppleScriptです。

この種類のQ&Aだと、

do shell script "killall Finder"

といった回答が書かれがちですが、これだと終了させたままにはできません。

Finderを終了させたままにしておく方法について調べてみたら、見つかったのでまとめておきました。

AppleScript名：Finderを終了させる.scpt

do shell script "defaults write com.apple.Finder QuitMenuItem -boolean true"

tell application "Finder" to quit

★Click Here to Open This Script　

Claris FileMaker Pro 2025（v22）がリリースされた

Posted on 7月 12 by Takaaki Naganoya

Appleの子会社であるClarisから、Claris FileMaker Pro 2025（v22）がリリースされました。

AppleScript名：Claris FileMaker Pro 2025のバージョン番号取得.scpt

tell application "FileMaker Pro"
　　version
　　–> "22.0.1"
end tell

★Click Here to Open This Script　

AppleScript用語辞書は前バージョンから変更されていません。

ASCII ARTで直線を引く v3.1

Posted on 7月 8 by Takaaki Naganoya

ASCII ARTで指定の2点間に線を引くAppleScriptです。（デモ用の）文字で表現するゲームを作る場合に、基礎ルーチンを整備しておく必要性を感じて、書いておきました。

AppleScript名：ASCII ARTで直線を引く v3.1.scpt

property widthCount : 40
property heightCount : 25
property spaceChar : "　"
property drawChar : "■"

— 使用例
set canvas to makeBlankCanvas() of me

set canvas to drawLine(canvas, 0, 0, 39, 24, 1) of me — 太さ1の線

set curDelim to AppleScript’s text item delimiters
set AppleScript’s text item delimiters to return
set resultText to canvas as text
set AppleScript’s text item delimiters to curDelim

return resultText

on makeBlankCanvas()
　　set blankLine to ""
　　repeat widthCount times
　　　　set blankLine to blankLine & spaceChar
　　end repeat
　　set canvas to {}
　　repeat heightCount times
　　　　set end of canvas to blankLine
　　end repeat
　　return canvas
end makeBlankCanvas

on drawLine(canvas, x0, y0, x1, y1, thickness)
　　script spd
　　　　property drawnPositions : {}
　　　　property drawXCoords : {}
　　　　property canvas : {}
　　　　property lineChars : {}
　　end script
　　
　　copy canvas to (canvas of spd)
　　
　　set dx to x1 – x0
　　set dy to y1 – y0
　　set lineLength to (dx * dx + dy * dy) ^ 0.5
　　
　　if lineLength = 0 then
　　　　if x0 ≥ 0 and x0 < widthCount and y0 ≥ 0 and y0 < heightCount then
　　　　　　set theLine to item (y0 + 1) of (canvas of spd)
　　　　　　set newLine to replaceCharAt(theLine, x0 + 1, drawChar)
　　　　　　set item (y0 + 1) of (canvas of spd) to newLine
　　　　end if
　　　　
　　　　return (canvas of spd)
　　end if
　　
　　set nx to –dy / lineLength
　　set ny to dx / lineLength
　　
　　set halfThickness to (thickness – 1) / 2
　　if halfThickness < 0 then set halfThickness to 0
　　
　　set x to x0
　　set y to y0
　　
　　set dxAbs to absNum(dx) of me
　　set dyAbs to absNum(dy) of me
　　set sx to signNum(dx) of me
　　set sy to signNum(dy) of me
　　set err to dxAbs – dyAbs
　　
　　set (drawnPositions of spd) to {}
　　
　　repeat
　　　　set (drawXCoords of spd) to {}
　　　　repeat with t from –halfThickness to halfThickness
　　　　　　set pxF to x + nx * t
　　　　　　set pxInt to pxF as integer
　　　　　　if pxInt ≥ 0 and pxInt < widthCount then
　　　　　　　　if (drawXCoords of spd) does not contain pxInt then
　　　　　　　　　　set end of (drawXCoords of spd) to pxInt
　　　　　　　　end if
　　　　　　end if
　　　　end repeat
　　　　
　　　　set pyInt to y as integer
　　　　if pyInt ≥ 0 and pyInt < heightCount then
　　　　　　set theLine to item (pyInt + 1) of (canvas of spd)
　　　　　　set (lineChars of spd) to characters of theLine
　　　　　　
　　　　　　repeat with pxInt in (drawXCoords of spd)
　　　　　　　　set posKey to (pxInt as string) & "," & (pyInt as string)
　　　　　　　　
　　　　　　　　if (drawnPositions of spd) does not contain posKey then
　　　　　　　　　　set item (pxInt + 1) of (lineChars of spd) to drawChar
　　　　　　　　　　set end of (drawnPositions of spd) to posKey
　　　　　　　　end if
　　　　　　　　
　　　　　　end repeat
　　　　　　
　　　　　　set newLine to (lineChars of spd) as string
　　　　　　set item (pyInt + 1) of (canvas of spd) to newLine
　　　　end if
　　　　
　　　　if x = x1 and y = y1 then exit repeat
　　　　
　　　　set e2 to 2 * err
　　　　if e2 > –dyAbs then
　　　　　　set err to err – dyAbs
　　　　　　set x to x + sx
　　　　end if
　　　　
　　　　if e2 < dxAbs then
　　　　　　set err to err + dxAbs
　　　　　　set y to y + sy
　　　　end if
　　end repeat
　　
　　return (canvas of spd)
end drawLine

on replaceCharAt(str, pos, char)
　　if pos < 1 or pos > (length of str) then return str
　　set prefix to text 1 thru (pos – 1) of str
　　set suffix to text (pos + 1) thru -1 of str
　　return prefix & char & suffix
end replaceCharAt

on absNum(n)
　　if n < 0 then return –n
　　return n
end absNum

on signNum(n)
　　if n > 0 then return 1
　　if n < 0 then return -1
　　return 0
end signNum

★Click Here to Open This Script　

NLTaggerで品詞つきの日本語形態素解析

Posted on 6月 30 by Takaaki Naganoya

ChatGPTに日本語形態素解析のAppleScriptを書かせてみました。そのままでは使い物にならず、ずいぶん書き直しましたが、ゼロから書くよりは時間の節約になっています。

ただし、実際に書いて動かしてみるとNLTaggerでは日本語の品詞情報が取得できないので、ほぼ役に立ちません。MeCab経由で取得したほうが実用的です。

この状態で「なんちゃらIntelligence」とか言われても、「はぁ？」としか、、、基礎ができていないのに応用はできませんよ。

AppleScript名：NLTaggerで品詞つきの日本語形態素解析（ただし、品詞はほとんど役に立たない）.scptd

use AppleScript version "2.8" — macOS 12 or later
use framework "Foundation"
use framework "NaturalLanguage"
use scripting additions

set inputText to current application’s NSString’s stringWithString:"私は昨日東京に行きました。"

— NLTaggerの作成（品詞情報を取得したいのでLexicalClassを指定）
set tagger to current application’s NLTagger’s alloc()’s initWithTagSchemes:{current application’s NLTagSchemeLexicalClass}
tagger’s setString:inputText
tagger’s setLanguage:(current application’s NLLanguageJapanese) range:{location:0, |length|:(inputText’s |length|())}

— 結果を格納するリスト
set tokenList to {}

— 解析処理
set inputLength to (inputText’s |length|()) as integer
set currentIndex to 0

repeat while currentIndex < inputLength
　　set tokenRangeRef to reference
　　set {tagRes, theRange} to tagger’s tagAtIndex:(currentIndex) unit:(current application’s NLTokenUnitWord) |scheme|:(current application’s NLTagSchemeLexicalClass) tokenRange:(tokenRangeRef)
　　–return theRange
　　
　　set theRange to theRange as record
　　set startLoc to theRange’s location
　　set rangeLen to theRange’s |length|()
　　
　　if (rangeLen > 0) then
　　　　set tokenText to inputText’s substringWithRange:(current application’s NSMakeRange(startLoc, rangeLen))
　　　　if tagRes is not missing value then
　　　　　　set posStr to tagRes as string
　　　　else
　　　　　　set posStr to "Unknown"
　　　　end if
　　　　set endIndex to startLoc + rangeLen
　　　　set end of tokenList to {(tokenText as string), posStr}
　　　　set currentIndex to endIndex
　　else
　　　　exit repeat
　　end if
end repeat

return tokenList
–> {{"私", "OtherWord"}, {"は", "OtherWord"}, {"昨日", "OtherWord"}, {"東京", "OtherWord"}, {"に", "OtherWord"}, {"行き", "OtherWord"}, {"まし", "OtherWord"}, {"た", "OtherWord"}, {"。", "SentenceTerminator"}}

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: 26.0savvy

YouTubeムービー再生実験

「AppleScriptセキュリティ実践ガイド」を発売

macOS 26.1が登場。Finderのバグが直らない？

macOS 15.7.2 スクリプトメニューから実行できなくなった地図系ライブラリ？

FaceTimeカメラから取り込み v1

指定日が所属する週のうち、最終日の日付を求める v2

テキストベースの棒グラフ取得

MacBook Air/MacBook Proのディスプレイ開閉角度を取得

スクリプトメニューでAirDropが使えない？

指定フォルダ内から指定拡張子のファイルを取得し、エイリアスだったらオリジナルのパスをPOSIX pathで取得

macOS 15.xで自作AppleScriptライブラリの一部がScript Menuから使えなくなったので修正

確認された現象

修正して動作するようになった事例

動作条件そのものが変更になったライブラリ

問題を解消できていないライブラリ

シンプルな文字置換

①text item delimitersを利用する

②shellコマンドを利用する

③OSAXを利用する

④AppleScript Librariesを利用する

⑤Cocoaの機能を利用する

⑥offset ofで文字列検索して置換を行う

macOS（Mac OS X/OS X）上のAppleScriptの歴史

Finderを終了させる

Claris FileMaker Pro 2025（v22）がリリースされた

ASCII ARTで直線を引く v3.1

NLTaggerで品詞つきの日本語形態素解析