アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

Posted on 1月 15, 2020 by Takaaki Naganoya

Edama2さんからの投稿Scriptです。アラートダイアログ中に各種GUI部品を詰め込む「箱庭インタフェース」シリーズ。テーブルビューを表示して、Finderからのアプリケーションのドラッグ＆ドロップを受け付けるAppleScriptです。

–> Download Editable & Executable Script Bundle Document

カスタムクラスの作り方がわかったので、懲りずにTable Viewネタです。
Thanks  Shane Stanley!

アプリケーションフォルダ直下のアプリを、NSValueTransformerを使ってコラムにローカライズ名とアイコンを表示するのと、finderからのドラッグ＆ドロップでアイテムの追加です。
追加時に重複チェックをしているので試す時はユーティリティフォルダか別の場所にあるアプリで試してください。

本Scriptは自分も作りたいと思いつつも調査が進んでいなかったものですが、TableViewでFinderからのドラッグ＆ドロップを受け付けます。

これを鍛えて再利用しやすい部品に育てることで、ドロップレットの代替品にできると思っています。macOS 10.12以降、Finder上のファイルをAppleScriptドロップレットにドラッグ＆ドロップで処理させても、OS側がダウンロードファイルにつけた拡張属性（Xattr）「com.apple.quarantine」がついているとドロップレット側で処理できなかったりします（回避方法はありますけれども）。

このドロップレットという仕組みを使わずに、同様にドラッグ＆ドロップによる処理を手軽にできる代替インタフェースとしてこのようなものを考えていた次第です。自分で作らなくてもEdama2さんが作ってくださったので助かりました、、、、

AppleScript名：アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppleScriptObjC"
use scripting additions

on run
　　my main()
end run
on main()
　　# Script Bundle内のResourcesフォルダを求める
　　set resourcePath to POSIX path of (path to me) & "Contents/Resources/"
　　set theBundle to current application’s NSBundle’s bundleWithPath:resourcePath
　　theBundle’s loadAppleScriptObjectiveCScripts()
　　
　　#
　　set aFolder to path to applications folder
　　set aPath to aFolder’s POSIX path
　　set aURL to current application’s NSURL’s fileURLWithPath:aPath
　　
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　
　　set filePaths to filePaths as list
　　set thisFileType to "com.apple.application-bundle"
　　
　　set fileURLs to {}
　　repeat with anItem in filePaths
　　　　
　　　　set aPath to anItem’s contents’s POSIX path
　　　　set aURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　
　　　　set {aResult, aUTI, aError} to (aURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　
　　　　if (aUTI as text) is thisFileType then
　　　　　　set fileURLs’s end to aURL
　　　　end if
　　end repeat
　　
　　set optionRec to {fileURLs:fileURLs, fileType:thisFileType}
　　
　　set aMainMes to "アプリケーションの選択"
　　set aSubMes to "適切なものを以下からえらんでください"
　　set dateObj to my chooseItemByTableView(aMainMes, aSubMes, optionRec)
end main

# アラートダイアログでtableviewを表示
on chooseItemByTableView(aMainMes, aSubMes, optionRec)
　　### set up view
　　set {theView, makeObj} to my makeContentView(optionRec)
　　
　　set paramObj to {myMessage:aMainMes, mySubMessage:aSubMes, setView:theView, myOption:makeObj}
　　my performSelectorOnMainThread:"raizeAlert:" withObject:paramObj waitUntilDone:true
　　
　　if (my _retrieve_data) is missing value then error number -128
　　return (my _retrieve_data)
end chooseItemByTableView

## retrieve date
on raizeAlert:paramObj
　　set mesText to paramObj’s myMessage
　　set infoText to paramObj’s mySubMessage
　　set theView to paramObj’s setView
　　set aTableObj to paramObj’s myOption
　　
　　global _retrieve_data
　　set _retrieve_data to missing value
　　
　　### set up alert
　　tell current application’s NSAlert’s new()
　　　　setMessageText_(mesText)
　　　　setInformativeText_(infoText)
　　　　addButtonWithTitle_("OK")
　　　　addButtonWithTitle_("Cancel")
　　　　setAccessoryView_(theView)
　　　　tell |window|()
　　　　　　setInitialFirstResponder_(theView)
　　　　end tell
　　　　#### show alert in modal loop
　　　　if runModal() is (current application’s NSAlertSecondButtonReturn) then return
　　end tell
　　
　　### retrieve date
　　set aIndexSet to aTableObj’s selectedRowIndexes()
　　
　　set chooseItems to ((aTableObj’s dataSource())’s arrangedObjects()’s objectsAtIndexes:aIndexSet) as list
　　set _retrieve_data to {}
　　repeat with anItem in chooseItems
　　　　set _retrieve_data’s end to anItem’s fileURL
　　end repeat
end raizeAlert:

## ContentView を作成
on makeContentView(paramObj)
　　## 準備
　　set fileURLs to (paramObj’s fileURLs) as list
　　set thisFileType to (paramObj’s fileType) as text
　　
　　set keyrec to {column1:"Name"}
　　set keyDict to (current application’s NSDictionary’s dictionaryWithDictionary:keyrec)
　　
　　set theDataSource to current application’s YKZArrayController’s new()
　　
　　## NSTableView
　　tell current application’s NSTableView’s alloc()
　　　　tell initWithFrame_(current application’s CGRectZero)
　　　　　　setAllowsEmptySelection_(false)
　　　　　　setAllowsMultipleSelection_(true)
　　　　　　setDataSource_(theDataSource)
　　　　　　setDelegate_(theDataSource)
　　　　　　setDoubleAction_("doubleAction:")
　　　　　　setGridStyleMask_(current application’s NSTableViewSolidVerticalGridLineMask)
　　　　　　setSelectionHighlightStyle_(current application’s NSTableViewSelectionHighlightStyleRegular)
　　　　　　setTarget_(theDataSource)
　　　　　　setUsesAlternatingRowBackgroundColors_(true)
　　　　　　
　　　　　　set thisRowHeight to rowHeight() as integer
　　　　　　set theDataSource’s _table_view to it
　　　　end tell
　　end tell
　　
　　# data sourceに追加
　　tell (theDataSource)
　　　　awakeFromNib()
　　　　set its _file_type to thisFileType
　　　　
　　　　repeat with aURL in fileURLs
　　　　　　addObject_({fileURL:aURL})
　　　　end repeat
　　　　
　　　　setSelectionIndex_(0)
　　end tell
　　
　　## NSTableColumn
　　### Columnの並び順を指定する
　　set viewWidth to 320
　　set columnsCount to keyDict’s |count|()
　　repeat with colNum from 1 to columnsCount
　　　　
　　　　set keyName to "column" & colNum as text
　　　　set aTitle to (keyDict’s objectForKey:keyName)
　　　　
　　　　tell (current application’s NSTableColumn’s alloc()’s initWithIdentifier:(colNum as text))
　　　　　　tell headerCell()
　　　　　　　　setStringValue_(aTitle)
　　　　　　　　set thisHeaderHeight to cellSize()’s height
　　　　　　end tell
　　　　　　
　　　　　　### Columnの横幅を指定
　　　　　　setWidth_(viewWidth)
　　　　　　
　　　　　　### バインディングのオプション
　　　　　　— ソートを無効にする
　　　　　　set anObj to (current application’s NSNumber’s numberWithBool:false)
　　　　　　set aKey to current application’s NSCreatesSortDescriptorBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　
　　　　　　### 表示内容をNSArrayControllerにバインディング
　　　　　　bind_toObject_withKeyPath_options_(current application’s NSValueBinding, theDataSource, "arrangedObjects", bOptions)
　　　　　　
　　　　　　(theDataSource’s _table_view’s addTableColumn:it)
　　　　end tell
　　　　
　　end repeat
　　
　　## NSScrollView
　　### Viewの高さを計算
　　set rowCount to 12 –> 行数を固定
　　set viewHeight to (thisRowHeight + 2) * rowCount + thisHeaderHeight –> 2を足さないと高さが合わない
　　set vSize to current application’s NSMakeRect(0, 0, viewWidth, viewHeight)
　　
　　### Viewを作成
　　tell current application’s NSScrollView’s alloc()
　　　　tell initWithFrame_(vSize)
　　　　　　setBorderType_(current application’s NSBezelBorder)
　　　　　　setDocumentView_(theDataSource’s _table_view)
　　　　　　–setHasHorizontalScroller_(true)
　　　　　　setHasVerticalScroller_(true)
　　　　　　set aScroll to it
　　　　end tell
　　end tell
　　
　　return {aScroll, theDataSource’s _table_view}
end makeContentView

★Click Here to Open This Script　

AppleScript名：subClasses

#MARK: – NSValueTransformer
script YKZURLToIcon
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSImage –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set iconImage to current application’s NSWorkspace’s sharedWorkspace’s iconForFile:appPath
　　　　return iconImage
　　end transformedValue:
end script

script YKZURLToDisplayedName
　　property parent : class "NSValueTransformer"
　　property allowsReverseTransformation : false –>逆変換
　　property transformedValueClass : a reference to current application’s NSString –>クラス
　　
　　#変換処理
　　on transformedValue:fileURL
　　　　if fileURL is missing value then return
　　　　
　　　　set appPath to fileURL’s |path|()
　　　　set displayedName to current application’s NSFileManager’s defaultManager’s displayNameAtPath:appPath
　　　　return displayedName
　　end transformedValue:
end script

#MARK: – Array Controller
script YKZArrayController
　　property parent : class "NSArrayController"
　　
　　#MARK: IBOutlets
　　property _table_view : missing value
　　#MARK:
　　property _data_type : do shell script "uuidgen"
　　property _file_type : ""
　　
　　on awakeFromNib()
　　　　–log "YKZArrayController – awakeFromNib"
　　　　tell _table_view
　　　　　　registerForDraggedTypes_({current application’s NSFilenamesPboardType, _data_type})
　　　　　　setDraggingSourceOperationMask_forLocal_(current application’s NSDragOperationCopy, false)
　　　　end tell
　　　　
　　　　#Transformerの登録
　　　　set tNames to {}
　　　　set tNames’s end to "YKZURLToIcon"
　　　　set tNames’s end to "YKZURLToDisplayedName"
　　　　repeat with aTransformer in tNames
　　　　　　set theTransformer to current application’s class aTransformer’s new()
　　　　　　(current application’s NSValueTransformer’s setValueTransformer:theTransformer forName:aTransformer)
　　　　end repeat
　　end awakeFromNib
　　
　　#MARK: Data Source Overrides
　　on numberOfRowsInTableView:aTableView
　　　　return my content()’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aTableView viewForTableColumn:aColumn row:aRow
　　　　–log "viewForTableColumn"
　　　　
　　　　set aCellView to aTableView’s makeViewWithIdentifier:"YKZTableCellView" owner:me
　　　　–set isNull to aCellView’s isEqual:(current application’s NSNull’s |null|())
　　　　–log isNull as text
　　　　
　　　　if aCellView is missing value then
　　　　　　
　　　　　　set frameRect to current application’s NSMakeRect(0, 0, aColumn’s width, aTableView’s rowHeight())
　　　　　　set aCellView to current application’s YKZTableCellView’s alloc’s initWithFrame:frameRect
　　　　　　
　　　　　　set anObj to "YKZURLToIcon"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s imageView())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　　　set anObj to "YKZURLToDisplayedName"
　　　　　　set aKey to current application’s NSValueTransformerNameBindingOption
　　　　　　set bOptions to (current application’s NSDictionary’s dictionaryWithObject:anObj forKey:aKey)
　　　　　　(aCellView’s textField())’s bind:(current application’s NSValueBinding) toObject:aCellView withKeyPath:"objectValue.fileURL" options:bOptions
　　　　　　
　　　　end if
　　　　
　　　　return aCellView
　　end tableView:viewForTableColumn:row:
　　
　　# テーブル内のセルが編集できるか
　　on tableView:aTableView shouldEditTableColumn:aColumn row:aRow
　　　　return false
　　end tableView:shouldEditTableColumn:row:
　　
　　# テーブル内をダブルクリックしたらOKボタンを押す
　　on doubleAction:sender
　　　　log "doubleAction"
　　　　## ヘッダをクリックした時は何もしない
　　　　if (sender’s clickedRow()) is -1 then return
　　　　
　　　　set theEvent to current application’s NSEvent’s ¬
　　　　　　keyEventWithType:(current application’s NSEventTypeKeyDown) ¬
　　　　　　　　location:(current application’s NSZeroPoint) ¬
　　　　　　　　modifierFlags:0 ¬
　　　　　　　　timestamp:0.0 ¬
　　　　　　　　windowNumber:(sender’s |window|()’s windowNumber()) ¬
　　　　　　　　context:(current application’s NSGraphicsContext’s currentContext()) ¬
　　　　　　　　|characters|:return ¬
　　　　　　　　charactersIgnoringModifiers:(missing value) ¬
　　　　　　　　isARepeat:false ¬
　　　　　　　　keyCode:0
　　　　current application’s NSApp’s postEvent:theEvent atStart:(not false)
　　end doubleAction:
　　
　　#MARK: Drag Operation Method
　　#ドラッグを開始（ペーストボードに書き込む）
　　on tableView:aTableView writeRowsWithIndexes:rowIndexes toPasteboard:pboard
　　　　–log "writeRowsWithIndexes"
　　　　set aData to current application’s NSKeyedArchiver’s archivedDataWithRootObject:rowIndexes
　　　　pboard’s declareTypes:{_data_type} owner:(missing value)
　　　　pboard’s setData:aData forType:_data_type
　　　　return true
　　end tableView:writeRowsWithIndexes:toPasteboard:
　　#ドラッグ途中
　　on tableView:aTableView validateDrop:info proposedRow:row proposedDropOperation:operation
　　　　–log "validateDrop"
　　　　#列の間にドラッグ
　　　　if (operation is current application’s NSTableViewDropAbove) then
　　　　　　return current application’s NSDragOperationMove
　　　　end if
　　　　#項目の上にドラッグ
　　　　set aTypes to info’s draggingPasteboard’s types()
　　　　if (aTypes’s containsObject:_data_type) as boolean then
　　　　　　return current application’s NSDragOperationNone
　　　　end if
　　　　return current application’s NSDragOperationNone
　　end tableView:validateDrop:proposedRow:proposedDropOperation:
　　#ドラッグ終了
　　on tableView:aTableView acceptDrop:info row:row dropOperation:operation
　　　　–log "acceptDrop"
　　　　#
　　　　set pboard to info’s draggingPasteboard()
　　　　set aTypes to pboard’s types()
　　　　
　　　　if (aTypes’s containsObject:_data_type) as boolean then
　　　　　　
　　　　　　set rowData to pboard’s dataForType:_data_type
　　　　　　set rowIndexes to current application’s NSKeyedUnarchiver’s unarchiveObjectWithData:rowData
　　　　　　
　　　　　　if (rowIndexes’s firstIndex()) < row then
　　　　　　　　set row to row – (rowIndexes’s |count|())
　　　　　　end if
　　　　　　
　　　　　　set aRange to current application’s NSMakeRange(row, rowIndexes’s |count|())
　　　　　　set aIndexSet to current application’s NSIndexSet’s indexSetWithIndexesInRange:aRange
　　　　　　
　　　　　　set anObj to ((my content())’s objectsAtIndexes:rowIndexes)
　　　　　　my removeObjects:anObj
　　　　　　my insertObjects:anObj atArrangedObjectIndexes:aIndexSet
　　　　　　my rearrangeObjects()
　　　　　　
　　　　else
　　　　　　set pathList to pboard’s propertyListForType:(current application’s NSFilenamesPboardType)
　　　　　　–log result as list
　　　　　　repeat with aPath in pathList
　　　　　　　　set isAdd to addItem_({filePath:aPath, atIndex:row})
　　　　　　　　if isAdd then beep
　　　　　　end repeat
　　　　　　
　　　　end if
　　　　return true
　　end tableView:acceptDrop:row:dropOperation:
　　
　　#追加する
　　on addItem:sender –> {filePath:aPath, atIndex:aIndex}
　　　　–log "addItem:"
　　　　set isAdd to false
　　　　
　　　　#missing valueの時は最後に追加
　　　　set {filePath:aPath, atIndex:aIndex} to sender
　　　　if aIndex is missing value then
　　　　　　set aIndex to my content()’s |count|() as number
　　　　end if
　　　　
　　　　#URLに変換
　　　　set appURL to (current application’s NSURL’s fileURLWithPath:aPath)
　　　　#アプリケーション以外は追加しない
　　　　set {aResult, aUTI, aError} to (appURL’s getResourceValue:(reference) ¬
　　　　　　forKey:(current application’s NSURLTypeIdentifierKey) ¬
　　　　　　|error|:(reference))
　　　　log aUTI
　　　　if (aUTI as text) is not (my _file_type as text) then return isAdd
　　　　
　　　　#すでにあるか確認
　　　　set bList to my content() as list
　　　　repeat with aRecord in bList
　　　　　　if ((appURL’s isEqual:(aRecord’s fileURL)) as boolean) then
　　　　　　　　set isAdd to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　#なければ追加
　　　　if not isAdd then
　　　　　　set anObj to {fileURL:appURL}
　　　　　　(my insertObject:anObj atArrangedObjectIndex:aIndex)
　　　　end if
　　　　return isAdd
　　end addItem:
end script

#MARK: – NSTableCellView
script YKZTableCellView
　　property parent : class "NSTableCellView"
　　
　　on initWithFrame:rect
　　　　–log "initWithFrame"
　　　　continue initWithFrame:rect
　　　　
　　　　setAutoresizingMask_(current application’s NSViewWidthSizable)
　　　　
　　　　tell current application’s NSImageView’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(0, 0, 16, 16))
　　　　　　　　setImageScaling_(current application’s NSImageScaleProportionallyUpOrDown)
　　　　　　　　setImageAlignment_(current application’s NSImageAlignCenter)
　　　　　　　　
　　　　　　　　my setImageView:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　tell current application’s NSTextField’s alloc
　　　　　　tell initWithFrame_(current application’s NSMakeRect(20, 2, 200, 14))
　　　　　　　　setBordered_(false)
　　　　　　　　setDrawsBackground_(false)
　　　　　　　　setEditable_(false)
　　　　　　　　
　　　　　　　　my setTextField:it
　　　　　　　　my addSubview:it
　　　　　　end tell
　　　　end tell
　　　　
　　　　return me
　　end initWithFrame:
end script

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

Posted on 12月 24, 2019 by Takaaki Naganoya

検索フィールドつきのTable View表示ダイアログを表示するAppleScriptです。項目選択を行う簡易ユーザーインタフェース（ダイアログ）で、選択肢の数が多い場合に備えて項目のキーワード抽出機能を付加したものです。

サーチフィールドの実装は無理かと思っていたのですが、単体でアラートダイアログ上に表示してみたら、予想外にキーボード入力イベントと検索語のクリアのイベントを簡単に拾えたので、Table Viewと組み合わせて試してみました。

AppleScript名：アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

— Created 2019-12-23 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSSearchField : a reference to current application’s NSSearchField
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 300
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　set aTextInput to makeNSSearchField(0, aHeight – 20, 300, 20) of me
　　　　
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 80, labelSortList) of me
　　　　
　　　　parentView’s setSubviews:{aTextInput, aScroll}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　–TextField
　　　　set aTextInput to makeNSSearchField(0, 0, 300, 20) of me
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on makeNSSearchField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer)
　　　　set aSearchF to NSSearchField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　　　aSearchF’s setDelegate:(me)
　　　　return aSearchF
　　end makeNSSearchField
　　
　　
　　–検索クエリ入力時
　　on searchFieldDidStartSearching:(aField)
　　　　set aStr to (aField’s stringValue()) as string
　　　　set predicStr to "field1 contains[cd] ’" & aStr & "’ OR field3 contains[cd] ’" & aStr & "’"
　　　　set filteredArray to filterRecListByLabel1((my aDataList), predicStr) of me
　　　　set (my theDataSource) to filteredArray
　　　　tView’s reloadData()
　　end searchFieldDidStartSearching:
　　
　　
　　–Search Fieldの「x」ボタンを押したイベント
　　on searchFieldDidEndSearching:(aField)
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　tView’s reloadData()
　　end searchFieldDidEndSearching:
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出
　　on filterRecListByLabel1(aRecList as list, aPredicate as string)
　　　　set aArray to NSMutableArray’s arrayWithArray:aRecList
　　　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　　　return filteredArray
　　end filterRecListByLabel1
　　
end script

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

Posted on 12月 23, 2019 by Takaaki Naganoya

アラートダイアログ上にTableViewを表示し、複数キーの組み合わせによって項目抽出。選択項目のデータを返すAppleScriptです。

あくまで試作品なので、あちらこちらに「お可愛らしい」実装が転がっています。NSBoxがまだまともに使いこなせていないあたりとか（Xcode上で部品として配置するのは楽勝ですが、プログラムから動的に生成して使用するのは別なので）。

抽出キー数は可変で外部から指定できるとよいのですが、本Scriptでは固定です。また、各抽出条件も外部から供給するのが本来あるべき姿ですが、ハードコーディングしています。

あと、TableViewの下側に謎の余白があるのは、めんどくさくなってそのまま放置しています。これで外部から各種パラメータを指定できるようにして、sdefつけて１命令で呼び出せるようにしておけば、レコード数の多い選択項目から条件抽出しつつ項目選択できてよいでしょう。

プログラム内容自体は、高度でもなければ高尚でもありません。実にダラダラとGUI部品のパラメータを設定しているだけです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v5_複数キー抽出つき

— Created 2019-12-22 by Takaaki Naganoya
— 2019 Piyomaru Software
set aRes to displayCondTable() of filterTableDialogView
–> {field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）", field2:198800, field1:"iMac 5K 27"}

script filterTableDialogView
　　use scripting additions
　　use framework "Foundation"
　　use framework "AppKit"
　　property parent : AppleScript
　　
　　property NSBox : a reference to current application’s NSBox
　　property NSView : a reference to current application’s NSView
　　property NSAlert : a reference to current application’s NSAlert
　　property NSColor : a reference to current application’s NSColor
　　property NSIndexSet : a reference to current application’s NSIndexSet
　　property NSPredicate : a reference to current application’s NSPredicate
　　property NSScrollView : a reference to current application’s NSScrollView
　　property NSTableView : a reference to current application’s NSTableView
　　property NSTableColumn : a reference to current application’s NSTableColumn
　　property NSPopUpButton : a reference to current application’s NSPopUpButton
　　property NSMutableArray : a reference to current application’s NSMutableArray
　　property NSRunningApplication : a reference to current application’s NSRunningApplication
　　property NSCompoundPredicate : a reference to current application’s NSCompoundPredicate
　　property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
　　property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
　　
　　
　　property theResult : 0
　　property returnCode : 0
　　property theDataSource : {}
　　property tView : missing value
　　property aDataList : {}
　　property aSel : 0
　　property bSel : 0
　　property cSel : 0
　　property predList : {}
　　property a1Button : missing value
　　property a2Button : missing value
　　property a3Button : missing value
　　
　　on displayCondTable()
　　　　set (my theResult) to 0 –initialize
　　　　
　　　　set aDataList to {{field1:"MacBook Air", field2:119800, field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:139800, field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:258800, field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:122800, field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:120800, field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:142800, field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:198800, field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:558800, field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}, {field1:"Mac Pro 2019", field2:599800, field3:"3.5GHz 8コアIntel Xeon Wプロセッサ（Turbo Boost使用時最大4.0GHz）"}}
　　　　
　　　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:aDataList, aSortOrder:{"field1", "field2", "field3"}}
　　　　
　　　　–my chooseItemByTableView:paramObj –for debug
　　　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　　　
　　　　return (my theResult)
　　end displayCondTable
　　
　　on chooseItemByTableView:paramObj
　　　　set aMainMes to myMessage of paramObj
　　　　set aSubMes to mySubMessage of paramObj
　　　　set aTList to (aTableList of paramObj) as list
　　　　set labelSortList to (aSortOrder of paramObj) as list
　　　　
　　　　set aWidth to 800
　　　　set aHeight to 400
　　　　set my aSel to 0
　　　　set my bSel to 0
　　　　
　　　　–Viewをつくる
　　　　set parentView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　　　
　　　　
　　　　–BOX Aをつくる
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aHeight – 60, aWidth, 60)))
　　　　(aBox’s setTitle:("Filter Condition"))
　　　　
　　　　–このあたり、項目数に合わせてUIを可変で生成するように（本Scriptは試作品なので、決め打ちでUI生成）
　　　　set a1Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 200, 30)) pullsDown:false)
　　　　a1Button’s removeAllItems()
　　　　(a1Button’s addItemsWithTitles:{"▼Select Item", "MacBook", "iMac", "mini", "Air", "Pro"})
　　　　a1Button’s setTarget:(me)
　　　　a1Button’s setAction:("mySelector:")
　　　　a1Button’s setEnabled:(true)
　　　　
　　　　set a2Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(220, 0, 200, 30)) pullsDown:false)
　　　　a2Button’s removeAllItems()
　　　　(a2Button’s addItemsWithTitles:{"▼Select Item", "150000", "200000", "300000", "400000", "600000"})
　　　　a2Button’s setTarget:(me)
　　　　a2Button’s setAction:("mySelector:")
　　　　a2Button’s setEnabled:(true)
　　　　
　　　　set a3Button to (NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(440, 0, 200, 30)) pullsDown:false)
　　　　a3Button’s removeAllItems()
　　　　(a3Button’s addItemsWithTitles:{"▼Select Item", "デュアルコア", "クアッドコア", "6コア", "8コア"})
　　　　a3Button’s setTarget:(me)
　　　　a3Button’s setAction:("mySelector:")
　　　　a3Button’s setEnabled:(true)
　　　　
　　　　
　　　　(aBox’s addSubview:a1Button)
　　　　(aBox’s addSubview:a2Button)
　　　　(aBox’s addSubview:a3Button)
　　　　
　　　　
　　　　–BOX Bをつくる
　　　　set bBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 80)))
　　　　(bBox’s setTitle:("Data"))
　　　　
　　　　set aScroll to makeTableView(aTList, aWidth, aHeight – 150, labelSortList) of me
　　　　
　　　　(bBox’s addSubview:aScroll)
　　　　
　　　　parentView’s setSubviews:{aBox, bBox}
　　　　
　　　　— set up alert　　
　　　　set theAlert to NSAlert’s alloc()’s init()
　　　　tell theAlert
　　　　　　its setMessageText:aMainMes
　　　　　　its setInformativeText:aSubMes
　　　　　　its addButtonWithTitle:"OK"
　　　　　　its addButtonWithTitle:"Cancel"
　　　　　　its setAccessoryView:(parentView)
　　　　　　
　　　　　　set myWindow to its |window|
　　　　end tell
　　　　
　　　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　　　
　　　　— show alert in modal loop
　　　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　　　if (my returnCode) = 1001 then error number -128
　　　　
　　　　set tmpResult to (aScroll’s documentView’s selectedRow()) + 1
　　　　set (my theResult) to contents of item tmpResult of ((my theDataSource) as list)
　　end chooseItemByTableView:
　　
　　
　　on doModal:aParam
　　　　set (my returnCode) to (aParam’s runModal()) as number
　　end doModal:
　　
　　
　　
　　
　　–TableView Event Handlers
　　on numberOfRowsInTableView:aView
　　　　return (my theDataSource)’s |count|()
　　end numberOfRowsInTableView:
　　
　　on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　　　set aRes to (aRec’s valueForKey:aTitle)
　　　　return aRes
　　end tableView:objectValueForTableColumn:row:
　　
　　
　　
　　on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　　　set aOffset to 40
　　　　set theDataSource to NSMutableArray’s alloc()’s init()
　　　　theDataSource’s addObjectsFromArray:aDicList
　　　　
　　　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　set tView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　　　
　　　　set aLen to length of labelSortList
　　　　
　　　　repeat with i in labelSortList
　　　　　　set j to contents of i
　　　　　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　　　(tView’s addTableColumn:aColumn)
　　　　end repeat
　　　　
　　　　tView’s setDelegate:me
　　　　tView’s setDataSource:me
　　　　tView’s reloadData()
　　　　
　　　　aScroll’s setDocumentView:tView
　　　　tView’s enclosingScrollView()’s setHasVerticalScroller:true
　　　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　　　
　　　　–１行目を選択
　　　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　　　tView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　　　
　　　　–強制的にトップにスクロール
　　　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　　　if class of aDBounds = list then
　　　　　　–macOS 10.13 or later
　　　　　　set maxHeight to item 2 of item 1 of aDBounds
　　　　else
　　　　　　–macOS 10.10….10.12
　　　　　　set maxHeight to height of |size| of aDBounds
　　　　end if
　　　　
　　　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　　　aScroll’s documentView()’s scrollPoint:aPT
　　　　
　　　　return aScroll
　　end makeTableView
　　
　　
　　on alertShowHelp:aNotification
　　　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
　　end alertShowHelp:
　　
　　
　　on mySelector:aObject
　　　　set aIndex to (aObject’s indexOfSelectedItem()) as number
　　　　filterByMultipleCondition() of me
　　end mySelector:
　　
　　
　　
　　on filterByMultipleCondition()
　　　　set prediCatesArray to {}
　　　　
　　　　set aInd to (my a1Button’s indexOfSelectedItem()) as number
　　　　set bInd to (my a2Button’s indexOfSelectedItem()) as number
　　　　set cInd to (my a3Button’s indexOfSelectedItem()) as number
　　　　
　　　　if {aInd, bInd, cInd} = {0, 0, 0} then
　　　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(my aDataList)
　　　　　　tView’s reloadData()
　　　　　　return
　　　　end if
　　　　
　　　　–このあたり、複数条件をハードコーディングしているのは超絶頭悪い。項目数の増減に対応できるべき
　　　　if aInd > 0 then
　　　　　　set aTitle to (my a1Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field1 contains ’" & aTitle & "’"
　　　　end if
　　　　
　　　　if bInd > 0 then
　　　　　　set bTitle to (my a2Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field2.integerValue < " & bTitle
　　　　end if
　　　　
　　　　if cInd > 0 then
　　　　　　set cTitle to (my a3Button’s title()) as string
　　　　　　set the end of prediCatesArray to "field3 contains ’" & cTitle & "’"
　　　　end if
　　　　
　　　　–データ抽出
　　　　set tmpList to filterDictArrayByLabel3((my aDataList), prediCatesArray) of me
　　　　
　　　　–データ再表示
　　　　set (my theDataSource) to NSMutableArray’s arrayWithArray:(tmpList)
　　　　tView’s reloadData()
　　end filterByMultipleCondition
　　
　　
　　
　　–リストに入れたレコードを、指定の属性ラベルの値で抽出（複数PredicatesをANDで合成）
　　on filterDictArrayByLabel3(origArray as list, aPredicateList as list)
　　　　set aArray to NSMutableArray’s arrayWithArray:origArray
　　　　set predArray to NSMutableArray’s new()
　　　　
　　　　repeat with i in aPredicateList
　　　　　　(predArray’s addObject:(NSPredicate’s predicateWithFormat:(contents of i)))
　　　　end repeat
　　　　
　　　　set pred to current application’s NSCompoundPredicate’s andPredicateWithSubpredicates:predArray
　　　　set filteredArray to aArray’s filteredArrayUsingPredicate:pred
　　　　
　　　　return filteredArray
　　end filterDictArrayByLabel3
end script

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示 v4

Posted on 7月 11, 2019 by Takaaki Naganoya

アラートダイアログ上にTable Viewを表示するAppleScriptです。

データを表UIで表示する部品としては、Shane Stanleyの「Myriad Tables Lib」が定番ですが、高機能なぶんライブラリ中にFrameworkが含まれていたりして、場合によっては困ることもあります。また、見た目をカスタマイズしたい場合にも、あまりいじくれなくて困ることもあります（とくにデータの文字サイズを変更できなくて困ること多し）。

そのため、AppleScriptだけで書いた表UI表示用の部品も、たまに必要になることがあります。

▲スクリプトエディタで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

▲Script Debuggerで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

▲AppleScriptアプレットで実行@macOS 10.14.5（左：Light Mode、右：Dark Mode）

AppleScript名：アラートダイアログ上にTable Viewを表示 v4

— Created 2019-02-21 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSModalPanelWindowLevel : a reference to current application’s NSModalPanelWindowLevel
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

on run
　　set (my theResult) to 0 –initialize
　　
　　set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:{{field1:"MacBook Air", field2:"119,800円", field3:"1.6GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）、4MB L3キャッシュ"}, {field1:"MacBook Pro 13", field2:"139,800円", field3:"1.4GHzクアッドコアIntel Core i5（Turbo Boost使用時最大3.9GHz）、128MB eDRAM"}, {field1:"MacBook Pro 15", field2:"258,800円", field3:"2.6GHz 6コアIntel Core i7（Turbo Boost使用時最大4.5GHz）、12MB共有L3キャッシュ"}, {field1:"Mac mini", field2:"122,800円", field3:"3.0GHz 6コアIntel Core i5 Turbo Boost使用時最大4.1GHz 9MB共有L3キャッシュ"}, {field1:"iMac 21.5", field2:"120,800円", field3:"2.3GHzデュアルコアIntel Core i5（Turbo Boost使用時最大3.6GHz）"}, {field1:"iMac 4K 21.5", field2:"142,800円", field3:"3.6GHzクアッドコアIntel Core i3"}, {field1:"iMac 5K 27", field2:"198,800円", field3:"3.0GHz 6コア Intel Core i5（Turbo Boost使用時最大4.1GHz）"}, {field1:"iMac Pro", field2:"558,800円", field3:"3.2GHz Intel Xeon W Turbo Boost使用時最大4.2GHz 19MBキャッシュ"}}, aSortOrder:{"field1", "field2", "field3"}}
　　
　　–my chooseItemByTableView:paramObj–for debug
　　my performSelectorOnMainThread:"chooseItemByTableView:" withObject:paramObj waitUntilDone:true
　　return (my theResult)
end run

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　set labelSortList to (aSortOrder of paramObj) as list
　　
　　set aWidth to 600
　　set aHeight to 200
　　
　　set aScroll to makeTableView(aTList, aWidth, aHeight, labelSortList) of me
　　
　　–Detect Dark Mode
　　set dMode to retLIghtOrDark() of me
　　if dMode = true then
　　　　set tvCol to 1
　　　　set tvAlpha to 0.8
　　　　set bCol to 0.1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s cyanColor())
　　else
　　　　set tvCol to 0
　　　　set tvAlpha to 0.1
　　　　set bCol to 1
　　　　set bAlpha to 0.8
　　　　set contentCol to (NSColor’s blackColor())
　　end if
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　　　
　　　　set myWindow to its |window|
　　end tell
　　
　　myWindow’s setOpaque:(false)
　　myWindow’s setBackgroundColor:(NSColor’s colorWithCalibratedWhite:(bCol) alpha:(bAlpha))
　　myWindow’s setLevel:(NSModalPanelWindowLevel)
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode) = 1001 then error number -128
　　
　　set (my theResult) to (aScroll’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to (aParam’s runModal()) as number
end doModal:

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle)
　　return aRes
end tableView:objectValueForTableColumn:row:

on makeTableView(aDicList, aWidth, aHeight, labelSortList)
　　set aOffset to 40
　　set theDataSource to current application’s NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:aDicList
　　
　　set aScroll to current application’s NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to current application’s NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　set aLen to length of labelSortList
　　
　　repeat with i in labelSortList
　　　　set j to contents of i
　　　　set aColumn to (current application’s NSTableColumn’s alloc()’s initWithIdentifier:j)
　　　　(aColumn’s setWidth:(aWidth div aLen))
　　　　(aColumn’s headerCell()’s setStringValue:j)
　　　　(aView’s addTableColumn:aColumn)
　　end repeat
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　aScroll’s setVerticalLineScroll:(30.0 as real)
　　
　　–１行目を選択
　　set aIndexSet to current application’s NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -1 * (maxHeight as real))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

on alertShowHelp:aNotification
　　display dialog "Help Me!" buttons {"OK"} default button 1 with icon 1
　　return false –trueを返すと親ウィンドウ（アラートダイアログ）がクローズする
end alertShowHelp:

–ダークモードの判定。ダークモード時：true、ライトモード時：falseが返る。System Eventsを使っていないのは、macOS 10.14以降対策（承認を取得しなくてもいいように）
on retLIghtOrDark()
　　set curMode to (current application’s NSUserDefaults’s standardUserDefaults()’s stringForKey:"AppleInterfaceStyle") as string
　　return (curMode = "Dark") as boolean
end retLIghtOrDark

★Click Here to Open This Script　

アラートダイアログの背景色を指定してTable Viewを表示

Posted on 2月 25, 2019 by Takaaki Naganoya

指定色のアラートダイアログを作成し、その上にScroll View＋Table Viewを表示して選択肢の選択を行うAppleScriptです。

アラートダイアログの背景色変更のテストを行なったものです。また、メソッド名をテキストで（Table Viewから）取得し、そのメソッド名で色を作成するテスト（NSSelectorFromString）も行いました。

Table Viewで選択した色は、次回実行時に反映されます（スクリプトエディタ/Script Debugger上で）。

本当はTable View上で行を選択したときに、アラートダイアログの背景色を変更させたかったのですが、試してみたもののうまく動かなかったので、その機能は削りました。最初から指定色のダイアログウィンドウを表示するだけなら問題はないので、現状のようなコードに落ち着きました。

AppleScript名：アラートダイアログの背景色を指定してTable Viewを表示

— Created 2019-02-25 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSFullSizeContentViewWindowMask : a reference to current application’s NSFullSizeContentViewWindowMask

property theResult : 0
property returnCode : 0
property theDataSource : {}
property theColList : {}
property theWindow : missing value
property selectedColor : missing value

set paramObj to {myMessage:"Choose a color", mySubMessage:"Choose an appropriate color from color name list", aTableList:{"redColor", "blueColor", "yellowColor", "greenColor", "grayColor", "blackColor"}}
set aRes to my chooseItemByTableView:paramObj

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(aTList, 300, 120) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— customize alert’s window style and color
　　if selectedColor = missing value then
　　　　set tmpColor to NSColor’s grayColor()
　　else
　　　　set tmpSel to current application’s NSSelectorFromString(selectedColor)
　　　　set tmpColor to NSColor’s performSelector:tmpSel
　　end if
　　
　　set theWindow to theAlert’s |window|()
　　theWindow’s setTitleVisibility:false
　　–theWindow’s setStyleMask:( NSFullSizeContentViewWindowMask)
　　theWindow’s setTitlebarAppearsTransparent:true
　　theWindow’s setBackgroundColor:tmpColor
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　return (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 40
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set selRow to (aRow as number)
　　set aRec to (my theDataSource)’s objectAtIndex:selRow
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle) as string
　　set my selectedColor to aRes
　　
　　return aRes
end tableView:objectValueForTableColumn:row:

on tableView:aView shouldEditTableColumn:aTableColumn row:rowIndex
　　return false –Not Editable
end tableView:shouldEditTableColumn:row:

★Click Here to Open This Script　

アラートダイアログ上にTable View＋Map View＋Segmented Controlを表示

Posted on 2月 23, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にScroll View＋Table ViewおよびMap Viewを表示して選択肢の選択を行うAppleScriptです。Segmented Controlで地図の種別切り替えを行い、項目選択用のTable Viewを編集不可にしました。

Map Viewを使用するために、インターネット接続が必要です。地図表示パフォーマンスはインターネット接続速度次第です。

▲Map Type = Standard (Map)

▲Map Type = Satellite

▲Map Type = Hybrid (Satellite + Map)

本Scriptに与える緯度・経度情報についてはあらかじめ住所ジオコーダーによって「住所情報→緯度・経度情報」の変換を行なったものを書いておく必要がありますが、Yahoo!の住所ジオコーダーサービスなどを呼び出せば、住所情報をパラメーターとすることも可能です。

サンプルデータの緯度・経度情報は、例によって「戦場の絆」の入っている近所のゲーセンの情報を適当にみつくろって入れてみたものです。

本ダイアログは、それほど件数の多くない（20件ぐらい？）選択肢からの選択を意図して作ったものですが、数百件とか数千件のデータから選ぶような場合には、Outline Viewを利用して小エリアごとに分割するとか、Search Fieldを連動させてキーワードによる絞り込みを有効にするなど、それなりの対処が必要です。

AppleScript名：アラートダイアログ上にTable View＋Map View＋Segmented Controlを表示

— Created 2019-02-23 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"

property NSAlert : a reference to current application’s NSAlert
property NSIndexSet : a reference to current application’s NSIndexSet
property MKMapView : a reference to current application’s MKMapView
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property MKPointAnnotation : a reference to current application’s MKPointAnnotation
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property MKMapTypeHybrid : a reference to current application’s MKMapTypeHybrid
property MKMapTypeSatellite : a reference to current application’s MKMapTypeSatellite
property MKMapTypeStandard : a reference to current application’s MKMapTypeStandard

property zLevel : 21 –Map Zoom Level (0:World View, 21:House/Building Zoom View)
property aMaxViewWidth : 800
property theResult : 0
property returnCode : 0
property theDataSource : {}
property curRow : 0
property aMapView : missing value
property nameL : {}
property placeL : {}

set aPlaceList to {{placeName:"Hey", aLat:"35.69906613", aLong:"139.77084064"}, {placeName:"namco中野", aLat:"35.70859274", aLong:"139.66584339"}, {placeName:"ゲームシティ板橋", aLat:"35.74572771", aLong:"139.67553260"}, {placeName:"ラウンドワンスタジアム板橋", aLat:"35.77661583", aLong:"139.67864491"}, {placeName:"キャロム練馬", aLat:"35.76386421", aLong:"139.66591600"}, {placeName:"アミュージアムOSC", aLat:"35.75308308", aLong:"139.59476696"}}

set paramObj to {myMessage:"場所の選択", mySubMessage:"適切な場所を以下のリストからえらんでください", placeList:aPlaceList}
my performSelectorOnMainThread:"chooseItemByTableViewWithMapAndSegment:" withObject:(paramObj) waitUntilDone:true
if (my theResult) = 0 then error number -128
return (my theResult)

on chooseItemByTableViewWithMapAndSegment:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (placeList of paramObj) as list
　　
　　set nameL to {}
　　set placeL to {}
　　repeat with i in aTList
　　　　set the end of nameL to (placeName of i)
　　　　set the end of placeL to {contents of (aLat of i), contents of (aLong of i)}
　　end repeat
　　
　　— create a view
　　set theView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, 400))
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(nameL, 200, 400) of me
　　
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(210, 30, aMaxViewWidth – 210, 370))
　　tell aMapView
　　　　its setMapType:MKMapTypeStandard
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　
　　　　set aLocation to current application’s CLLocationCoordinate2DMake((first item of first item of placeL) as real, (second item of first item of placeL) as real)
　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　its setDelegate:me
　　end tell
　　
　　–MapにPinを追加
　　repeat with i from 1 to (length of nameL)
　　　　set tmpAdr to contents of item i of nameL
　　　　copy item i of placeL to {tmpLat, tmpLong}
　　　　
　　　　set aLocation to current application’s CLLocationCoordinate2DMake(tmpLat as real, tmpLong as real)
　　　　set anAnnotation to MKPointAnnotation’s alloc()’s init()
　　　　(anAnnotation’s setCoordinate:aLocation)
　　　　(anAnnotation’s setTitle:tmpAdr)
　　　　(aMapView’s addAnnotation:anAnnotation)
　　end repeat
　　
　　–Segmented Controlをつくる
　　set segTitleList to {"Map", "Satellite", "Satellite + Map"}
　　set aSeg to makeSegmentedControl(segTitleList, 210, 0, 150, 20) of me
　　
　　theView’s setSubviews:{aScrollWithTable, aMapView, aSeg}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　–To enable the first annotation visible
　　copy item 1 of placeL to {tmpLat, tmpLong}
　　set aLocation to current application’s CLLocationCoordinate2DMake(tmpLat as real, tmpLong as real)
　　aMapView’s setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　set (my theResult) to (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableViewWithMapAndSegment:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 0
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 30, aWidth, aHeight – 30))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 30, aWidth, aHeight – 30))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10,　10.11, 10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set (tmpRow) to aView’s selectedRow() as number
　　
　　–Table View上で現在選択行「以外の」行が選択されたら、Mapを選択項目で更新
　　if (my curRow) is not equal to tmpRow then
　　　　set tmpLat to (first item of item (tmpRow + 1) of placeL) as real
　　　　set tmpLong to (second item of item (tmpRow + 1) of placeL) as real
　　　　
　　　　tell aMapView
　　　　　　set aLocation to current application’s CLLocationCoordinate2DMake(tmpLat, tmpLong)
　　　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　end tell
　　　　
　　　　set (my curRow) to tmpRow
　　end if
　　
　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle)
　　return aRes
end tableView:objectValueForTableColumn:row:

on tableView:aView shouldEditTableColumn:aTableColumn row:rowIndex
　　return false –Not Editable
end tableView:shouldEditTableColumn:row:

–Segmented Controlをつくる
on makeSegmentedControl(titleList, startX, startY, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(startX, startY, aWidth, aHeight))
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControl

–Segmented Controlのクリック時のイベントハンドラ
on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
　　set tList to {MKMapTypeStandard, MKMapTypeSatellite, MKMapTypeHybrid}
　　set tmpType to contents of item (aSel + 1) of tList
　　
　　aMapView’s setMapType:(tmpType)
　　
　　set selSeg to aSel
end clickedSeg:

★Click Here to Open This Script　

アラートダイアログ上にTable View＋Map Viewを表示

Posted on 2月 22, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にScroll View＋Table ViewおよびMap Viewを表示して選択肢の選択を行うAppleScriptです。

Map Viewを使用するために、インターネット接続が必要です。地図表示パフォーマンスはインターネット接続速度次第です。

{{placeName:"Hey", aLat:"35.69906613", aLong:"139.77084064"}....}

のように位置データを、

名称, 緯度, 経度

とまとめたリストで選択肢を指定します。実行すると選択肢のアイテム番号（１からはじまる）を返してきます。

▲左から、macOS 10.12.6、10.13.6、10.14.4betaで同じAppleScriptを動かしたところ。同じ場所、同じZoom LevelでもOSバージョンごとに微妙に表示内容が違う

現状の実装では、表UI（Table View）内のデータがダブルクリックで編集できてしまうので、編集できないようにするあたりが改良対象でしょうか。あと、地図・衛星写真の切り替えもつけておくとよいでしょう。

サンプルデータの緯度・経度情報は、例によって「戦場の絆」の入っている近所のゲーセンの情報を適当にみつくろって入れてみたものです。

AppleScript名：アラートダイアログ上にTable View＋Map Viewを表示 v2

— Created 2019-02-22 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"

property NSAlert : a reference to current application’s NSAlert
property NSIndexSet : a reference to current application’s NSIndexSet
property MKMapView : a reference to current application’s MKMapView
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property zLevel : 18
property aMaxViewWidth : 800
property theResult : 0
property returnCode : 0
property theDataSource : {}
property curRow : 0
property aMapView : missing value
property nameL : {}
property placeL : {}

set paramObj to {myMessage:"場所の選択", mySubMessage:"適切な場所を以下のリストからえらんでください", placeList:aPlaceList}
my performSelectorOnMainThread:"chooseItemByTableViewWithMap:" withObject:(paramObj) waitUntilDone:true
return (my theResult)

on chooseItemByTableViewWithMap:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (placeList of paramObj) as list
　　
　　set nameL to {}
　　set placeL to {}
　　repeat with i in aTList
　　　　set the end of nameL to (placeName of i)
　　　　set the end of placeL to {contents of (aLat of i), contents of (aLong of i)}
　　end repeat
　　
　　— create a view
　　set theView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, 400))
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(nameL, 200, 400) of me
　　
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(210, 0, aMaxViewWidth – 210, 400))
　　tell aMapView
　　　　its setMapType:(current application’s MKMapTypeStandard)
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　
　　　　set aLocation to current application’s CLLocationCoordinate2DMake((first item of first item of placeL) as real, (second item of first item of placeL) as real)
　　　　
　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　its setDelegate:me
　　end tell
　　
　　theView’s setSubviews:{aScrollWithTable, aMapView}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set (my theResult) to (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableViewWithMap:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 0
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　–強制的にトップにスクロール
　　–set maxHeight to aScroll’s documentView()’s |bounds|()’s |size|()’s height
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示

Posted on 2月 22, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にScroll View＋Table Viewを表示して選択肢の選択を行うAppleScriptです。

1D List（１次元配列）を与え、選択を行うUIです。実行すると選択肢のアイテム番号（１からはじまる）を返してきます。

とくにこれが作りたかったのではなく、位置情報（Geo Location）の選択をTable Viewで行い、該当する場所をMap Viewに表示させると擬似的に複数の固定位置情報から任意のものを選択させるダイアログが作れるだろうかと思って作成した試作品です。

東京への引っ越しの荷物が到着して、ようやく検証用のサブマシンが届いたものの、ネットワークを新規敷設しなくてはならないのでぼちぼちです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v3

— Created 2019-02-21 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:{"なし", "りんご", "ひよこ", "ぎょうざ", "すなぎも", "ぼんじり", "もも"}}
set aRes to my chooseItemByTableView:paramObj

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　–define the matrix size where you’ll put the radio buttons
　　set aScrollWithTable to makeTableView(aTList, 300, 150) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　return (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 40
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　–set maxHeight to aScroll’s documentView()’s |bounds|()’s |size|()’s height
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSTableView

アラートダイアログ上にTable Viewを表示 v9_アイコンを表示、Finderからのドラッグ＆ドロップ

アラートダイアログ上にTable Viewを表示 v6_サーチフィールドつき

アラートダイアログ上にTable View＋Map View＋Segmented Controlを表示