2つのレコードのキーの重複を計算

Posted on 9月 7, 2019 by Takaaki Naganoya

2つのレコードのキーの重複を検出するAppleScriptです。

こういう処理がお手軽にできるようになったので、macOS 10.10以降のAppleScriptでないとプログラムが組めなくなっている今日このごろ。死ぬほど努力してOld Style AppleScript（Cocoaの機能を使わない）だけで組めないこともないですが、それだけで半日は費やして数百行のプログラムになってしまいそうです。

というわけで、Cocoaの機能を利用した「ありもの」のルーチンを組み合わせるだけでほぼ完成。２つのレコードのキーの重複計算を行います。

どういう用途で使うかといえば、パラメータつきのURLに対して追加パラメータを付加したい場合です。URLからレコード形式でパラメータを分離し、追加パラメータ（レコード形式）を足し算する「前」に、２つのレコード間で重複キーがないかチェックする、という用途です。

では、２つのレコードの加算はどーするのか？　という話になりますが、それは単に&演算子で加算するだけです。

set aRec to {abc:"1", bcd:"2"}
set bRec to {ccc:"0", ddd:"9"}
set cRec to aRec & bRec
–> {abc:"1", bcd:"2", ccc:"0", ddd:"9"}

★Click Here to Open This Script　

AppleScript名：2つのレコードのキーの重複を計算.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/09/06
—
–　　Copyright © 2019 jp.piyomarusoft, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property NSSet : a reference to current application’s NSSet
property NSCountedSet : a reference to current application’s NSCountedSet
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

set aRec to {autoplay:"1", hd:"9"}
set bRec to {v:"GP_tVXTYdmY", t:"120", hd:"3"}

set dupKeys to detectDuplicateKeysInTwoRecords(aRec, bRec) of me
–> {"hd"}

on detectDuplicateKeysInTwoRecords(aRec, bRec)
　　set aDict to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set bDict to NSMutableDictionary’s dictionaryWithDictionary:bRec
　　
　　set aKeyList to (aDict’s allKeys()) as list
　　set bKeyList to (bDict’s allKeys()) as list
　　
　　set allKeyList to aKeyList & bKeyList
　　
　　set aRes to returnDuplicatesOnly(allKeyList) of me
　　return aRes
end detectDuplicateKeysInTwoRecords

–1D Listから重複項目のみ返す
on returnDuplicatesOnly(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　

リストの差分を取得して、登場順序が変わっていても1D List同士の登場要素が同じかをチェック

Posted on 5月 27, 2019 by Takaaki Naganoya

２つの1D List（１次元配列）同士の全要素をチェックし、登場順序に変更があったとしても要素自体に差がないかどうかをチェックするAppleScriptです。

……ソートしてから比較すれば、もっと短くて済むような気もしないでもないですが、もし違った場合には何が足りなくて（minusitems）、何が余計なのか（additems）をレポートしてくれるので実用的だと思います。

AppleScript名：リストの差分を取得して、登場順序が変わっていても1D List同士の登場要素が同じかをチェック

— Created 2019-05-27 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aList to {3, 2, 1, 7, 6, 4}
set bList to {1, 2, 3, 4, 6, 7}
set a1Res to checkAllItemsAreSame(aList, bList) of me
–> true （配列要素の登場順序が変わっていても要素はすべて同じ）

set aList to {3, 2, 1, 7, 6}
set bList to {1, 2, 3, 4, 6, 7}
set a2Res to checkAllItemsAreSame(aList, bList) of me
–> addItems:{4}, minusItems:{}}–配列要素に過不足があった

–1D List同士の全要素が（登場順序が変更になっていても）同じかどうかをチェック
on checkAllItemsAreSame(aList, bList)
　　set dRes to getDiffBetweenLists(aList, bList) of me
　　set ddRes to (dRes is equal to {addItems:{}, minusItems:{}}) as boolean
　　if ddRes = true then
　　　　return true
　　else
　　　　return dRes
　　end if
end checkAllItemsAreSame

–1D List同士のdiffを検出
on getDiffBetweenLists(aArray as list, bArray as list)
　　set allSet to current application’s NSMutableSet’s setWithArray:aArray
　　allSet’s addObjectsFromArray:bArray
　　
　　–重複する要素のみ抜き出す
　　set duplicateSet to current application’s NSMutableSet’s setWithArray:aArray
　　duplicateSet’s intersectSet:(current application’s NSSet’s setWithArray:bArray)
　　
　　–重複部分を削除する
　　allSet’s minusSet:duplicateSet
　　set resArray to (allSet’s allObjects()) as list
　　
　　set aSet to current application’s NSMutableSet’s setWithArray:aArray
　　set bSet to current application’s NSMutableSet’s setWithArray:resArray
　　aSet’s intersectSet:bSet –積集合
　　set addRes to aSet’s allObjects() as list
　　
　　set cSet to current application’s NSMutableSet’s setWithArray:bArray
　　cSet’s intersectSet:bSet –積集合
　　set minusRes to cSet’s allObjects() as list
　　
　　return {addItems:minusRes, minusItems:addRes}
end getDiffBetweenLists

★Click Here to Open This Script　

Numbersで指定の２つの書類のデータのdiffを取る

Posted on 4月 19, 2019 by Takaaki Naganoya

指定の２つのNumbers書類（の中の現在表示中のシートのTable 1）同士のdiffを取るAppleScriptです。

＃　書類内のシート内のどの表を処理するか、という階層化された対象選択を行うのにNSOutlineViewを用いたアラートダイアログを作っておきたい気持ちでいっぱいです

バージョン違いの書類間の差分を検出してレポートします。差分の評価は行単位で行なっており、同じデータでもカラムの順番を変えてあったりすると「別物」として検出します。

ただし、Numbersから２次元配列としてデータを抽出する際にすべてAppleScriptで処理するように書き換えた（macOS 10.14対策）ルーチンを使用しているので、大規模データの処理を行わせると（データ取得処理部分は）遅くなる可能性があります。

diffの計算部分はCocoaの機能に依存した（甘えまくった）処理を行なっているため、データが大きくてもそれほど遅くなりません。

612行の旧データと610行の新データをそれぞれ取得して差分を計算するのに、開発環境でだいたい3.5秒ぐらいです。同じ環境でBridgePlusを用いて1D List–> 2D List変換を行うバージョンを試してみたら、0.83秒ぐらいでした。

AppleScript名：Numbersで指定の２つの書類のデータのdiffを取る.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/04/19
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Numbers"
　　set dList to name of every document
　　set oldDoc to contents of first item of (choose from list dList with prompt "古いデータを選択してください")
　　set newDoc to contents of first item of (choose from list dList with prompt "新しいデータを選択してください")
end tell

set oldData to get2DListFromADoc(oldDoc) of me
set newData to get2DListFromADoc(newDoc) of me

–List同士のDiffを計算する
set dRes to getDiffBetweenLists(oldData, newData) of me
–> {addItems:{{"キャッツアイ恵庭", 42.87588548, 141.5834606, "北海道恵庭市住吉町 2-9-1"}}, minusItems:{{"セガワールド白河", 37.11931521, 140.1944139, "福島県白河市新高山 1-1　メガステージ白河内"}, {"プレイアイシー", 35.3721071, 139.272272, "神奈川県秦野市南矢名 1-15-1"}, {"駅前スタジアムIII", 33.8395736, 132.7521903, "愛媛県松山市大手町 2-4-1"}}}

on get2DListFromADoc(aDocName)
　　tell application "Numbers"
　　　　tell document aDocName
　　　　　　tell active sheet
　　　　　　　　set theTable to table 1
　　　　　　　　
　　　　　　　　tell theTable
　　　　　　　　　　set selection range to cell range
　　　　　　　　　　
　　　　　　　　　　set hcCount to header column count
　　　　　　　　　　set hrCount to header row count
　　　　　　　　　　set frCount to footer row count
　　　　　　　　　　
　　　　　　　　　　set cCount to column count
　　　　　　　　　　set rCount to row count
　　　　　　　　　　
　　　　　　　　　　set outList to {}
　　　　　　　　　　
　　　　　　　　　　repeat with i from (hrCount + 1) to rCount
　　　　　　　　　　　　tell row i
　　　　　　　　　　　　　　set tmpList to value of cells (hcCount + 1) thru cCount
　　　　　　　　　　　　　　set the end of outList to tmpList
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　return outList
　　　　　　　　
　　　　　　end tell
　　　　end tell
　　end tell
end get2DListFromADoc

on getDiffBetweenLists(aArray as list, bArray as list)
　　set allSet to current application’s NSMutableSet’s setWithArray:aArray
　　allSet’s addObjectsFromArray:bArray
　　
　　–重複する要素のみ抜き出す
　　set duplicateSet to current application’s NSMutableSet’s setWithArray:aArray
　　duplicateSet’s intersectSet:(current application’s NSSet’s setWithArray:bArray)
　　
　　–重複部分を削除する
　　allSet’s minusSet:duplicateSet
　　set resArray to (allSet’s allObjects()) as list
　　
　　set aSet to current application’s NSMutableSet’s setWithArray:aArray
　　set bSet to current application’s NSMutableSet’s setWithArray:resArray
　　aSet’s intersectSet:bSet –積集合
　　set addRes to aSet’s allObjects() as list
　　
　　set cSet to current application’s NSMutableSet’s setWithArray:bArray
　　cSet’s intersectSet:bSet –積集合
　　set minusRes to cSet’s allObjects() as list
　　
　　return {addItems:minusRes, minusItems:addRes}
end getDiffBetweenLists

★Click Here to Open This Script　

PDFから指定ページ以降を削除

Posted on 7月 10, 2018 by Takaaki Naganoya

PDFから指定ページ以降を削除するAppleScriptです。

こんな（↑）418ページもあるPDFから、おためし版の、冒頭から40ページだけ抽出したPDFを作成する際に使用したものです。

もともとは418ページありましたが、、、

実行後は40ページに、、、

AppleScript名：PDFから指定ページ以降を削除

— Modified 2018-07-08 by Takaaki Naganoya
–Original By Shane Stanley
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "QuartzCore"
use aBplus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

property NSSet : a reference to current application’s NSSet
property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property SMSForder : a reference to current application’s SMSForder
property NSIndexSet : a reference to current application’s NSIndexSet
property PDFDocument : a reference to current application’s PDFDocument
property NSSortDescriptor : a reference to current application’s NSSortDescriptor

load framework

set sPage to 41 –ここから末尾までのページを削除
set inFile to (choose file of type {"pdf"} with prompt "Choose your PDF files:")
set pRes to removePDFPageAfter(inFile, sPage) of me

–指定パスのPDFの指定ページ以降をすべて削除
on removePDFPageAfter(inFile, sPage)
　　set pCount to pdfPageCount(inFile) of me
　　set eCount to pCount – sPage + 1
　　
　　set aindexSet to NSIndexSet’s indexSetWithIndexesInRange:(current application’s NSMakeRange(sPage, eCount))
　　set targPageList to (SMSForder’s arrayWithIndexSet:aindexSet) as list
　　
　　return removeSpecificPagesFromPDF(inFile, targPageList) of me
end removePDFPageAfter

–指定PDF書類の複数ページの一括削除
on removeSpecificPagesFromPDF(inFileAlias, targPageNumList as list)
　　set inNSURL to |NSURL|’s fileURLWithPath:(POSIX path of inFileAlias)
　　set theDoc to PDFDocument’s alloc()’s initWithURL:inNSURL
　　
　　–削除対象ページリストをユニーク化して降順ソート（後方から削除）
　　set pRes to theDoc’s pageCount()
　　set t3List to relativeToAbsNumList(targPageNumList, pRes) of me
　　
　　repeat with i in t3List
　　　　copy i to targPageNum
　　　　(theDoc’s removePageAtIndex:(targPageNum – 1))
　　end repeat
　　
　　–Overwrite Exsiting PDF
　　set aRes to (theDoc’s writeToURL:inNSURL) as boolean
　　
　　return aRes
end removeSpecificPagesFromPDF

–絶対ページと相対ページが混在した削除対象ページリストを絶対ページに変換して重複削除して降順ソート
on relativeToAbsNumList(aList, aMax)
　　set newList to {}
　　
　　repeat with i in aList
　　　　set j to contents of i
　　　　if i < 0 then
　　　　　　set j to aMax + j
　　　　end if
　　　　
　　　　if (j ≤ aMax) and (j is not equal to 0) then
　　　　　　set the end of newList to j
　　　　end if
　　end repeat
　　
　　set t1List to uniquify1DList(newList, true) of me
　　set t2List to sort1DNumListWithOrder(t1List, false) of me
　　
　　return t2List
end relativeToAbsNumList

–1D/2D Listをユニーク化
on uniquify1DList(theList as list, aBool as boolean)
　　set aArray to NSArray’s arrayWithArray:theList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　return bArray as list
end uniquify1DList

–Sort 1-Dimension List（String Number List）
on sort1DNumListWithOrder(theList as list, aBool as boolean)
　　tell NSSet to set theSet to setWithArray_(theList)
　　tell NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_("floatValue", aBool)
　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　return (sortedList) as list
end sort1DNumListWithOrder

–指定PDFのページ数をかぞえる（10.9対応。普通にPDFpageから取得）
–返り値：PDFファイルのページ数（整数値）
on pdfPageCount(aFile)
　　set aFile to POSIX path of aFile
　　set theURL to |NSURL|’s fileURLWithPath:aFile
　　set aPDFdoc to PDFDocument’s alloc()’s initWithURL:theURL
　　set aRes to aPDFdoc’s pageCount()
　　return aRes as integer
end pdfPageCount

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSSet

PDFから指定ページ以降を削除