iWorkアプリケーションv12に共通のバグ？　新規ファイルの保存ができない

Posted on 5月 23, 2022 by Takaaki Naganoya

Apple iWorkアプリケーション（Keynote、Pages、Numbers）の最新バージョンv12.0において、共通のバグがあるのではないか？　と見ています。もちろん、見ているだけでなくAppleにバグレポートもしています。

症状は、新規作成した書類を「保存できない」というものです。

以前にも、PDFをexportできないという致命的なバグが発生していましたが、今回のも同様のメカニズムで発生しているものと見ています。つまり、「Appleが自社OSに設定したセキュリティ機能によって、自社アプリであるKeynote、Pages、Numbersが自家中毒を起こしている」という状態です。

自分の勘違いだとよいのですが….

あとは、Numbersのsaveコマンドをよく見てみると、書類フォーマットに「as Numbers」というenumがあるのですが、これはAppleScriptの処理系では「number」の複数形として認識されてしまうので、この予約語自体に無理があります。ここは、「as Numbers format」といった予約語に変えるべきです。

AppleScript名：Keynoteで新規書類作成して指定名称で新規保存.scpt

set dtPath to (path to documents folder) as string
set uuidStr to (do shell script "uuidgen") & ".key"
set savePath to dtPath & uuidStr

tell application "Keynote"
　　set nDoc to make new document with properties {document theme:theme id "Application/21_BasicWhite/Standard", width:1024, height:768}
　　save nDoc in file savePath as Keynote
end tell

★Click Here to Open This Script　

AppleScript名：Pagesで新規書類を作成して指定名称で新規保存.scpt

set dtPath to (path to documents folder) as string
set uuidStr to (do shell script "uuidgen") & ".pages"
set savePath to dtPath & uuidStr

tell application "Pages"
　　set nDoc to make new document with properties {document template:template id "Application/Blank/ISO"}
　　save nDoc in file savePath as Pages Format
end tell

★Click Here to Open This Script　

AppleScript名：Numbersで新規書類作成して指定名称で新規保存.scpt

set dtPath to (path to documents folder) as string
set uuidStr to (do shell script "uuidgen") & ".numbers"
set savePath to dtPath & uuidStr

tell application "Numbers"
　　set nDoc to make new document
　　save nDoc in file savePath as numbers –change "Numbers" word into "numbers format" because "numbers" is alredy registered as "list of number" or "every number"
end tell

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（11）AppleScriptアプレットとドロップレット

Posted on 5月 20, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第11巻、「AppleScriptアプレットとドロップレット」です。PDF 41ページ、サンプルAppleScriptのZipアーカイブを添付。

→ 販売ページ

本シリーズも、着手した頃には「そんなに細切れのテーマで書けるのか？」「そんな作り方で作れるはずがない」といった意見が集まっていたものですが（チーム内の打ち合わせ時には割と批判的です）、実際に作り出したらトンでもなく「書くべきこと」があって、書けば書くほど新たなテーマが見つかるという恐るべき状態。

今回の「アプレット」「ドロップレット」については、あまり振り返ったことがなかったのですが、いざ書いてみると尋常でないほどの情報が溜まっていました。

スクリプトエディタとScript Debuggerという２つの開発環境のちがい、アプレット、ドロップレット、Cocoa-AppleScriptアプレット、Script Debuggerの拡張ドロップレットなどなど。常駐タイプのアプレットに、タイマー割り込み処理のアプレット。アプレットのアイコンのカスタマイズに、アプレット内にAppleScriptライブラリを同梱する方法、Cocoa Frameworkを入れて呼び出す方法など、盛りだくさんな内容をお送りしています。

■アプレット

AppleScriptをアプリケーション形式で書き出し
AppleScriptアプレットの種類
AppleScriptアプレットの作成方法
AppleScriptアプレットのオプション指定
常駐型AppleScriptアプレットの作成方法
常駐型AppleScriptアプレットの記述
アプレットの「初期画面」を指定
「初期画面」に画像をペーストした場合の動作
アプレット/ドロップレットのユーザーインタフェース
資料：スクリプト/アプレットのバンドル構造
資料：アプレットのカスタマイズ①
資料：アプレットのカスタマイズ②
資料：アプレットのカスタマイズ③

■Cocoa-AppleScriptアプレット

Cocoa-AppleScriptアプレットの作成方法
参考資料：Delegateスクリプトの内容確認方法
参考資料：Delegateスクリプトのヘッダー内容
参考資料：Delegateスクリプトのハンドラ

■Script Debuggerのアプレット/拡張アプレット

AppleScriptアプレット（SD）の作成方法
AppleScript拡張アプレット（SD）の作成方法
AppleScript拡張アプレット（SD）の作成方法

■ドロップレット

AppleScriptドロップレットの作成方法
AppleScriptドロップレットの作成方法
ドロップレットによるファイルの受信
macOS 10.12以降の問題への対策ドロップレット
macOS 12.4上でドロップレット処理を実験

新発売：AppleScript基礎テクニック集（10）ループ処理

Posted on 5月 13, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第10巻、「ループ処理」です。PDF 33ページ、サンプルAppleScriptのZipアーカイブを添付。

→ 販売ページ

ループ処理について、さまざまなrepeat文のバリエーションをまんべんなくすべて知って理解するよりも「間違いなく必要な場所で使える」ことが重要です。

repeat文にもいくつか書き方はあるものの、おおよそ２パターンぐらいでだいたい足ります。

それでも、複数の配列を同時にループしなくてはならないとか、ステップ値を想定の値に合わせるための調整とか、ノウハウらしきものはいろいろあります。

また、参照値をそのまま使うとエラーになる例もあるため、「contents of」でオブジェクトを取り出す必要があるといったささいなノウハウが必要なものでもあります。

■ループによる繰り返し処理

AppleScriptの制御構文
繰り返しループ
repeat文①
repeat文②
repeat文③
repeat文④
repeat文⑤
repeat文⑥
exit repeat
多重ループ＋exit repeat

■アプリケーションから取得したオブジェクトでループ

アプリケーションのオブジェクトを処理
Photos上の選択中の写真から情報を取得
Keynoteで選択中のオブジェクトを位置でソート
Numbersで表のセルが連結されていたら分離
targetが重複しているFinder Windowをクローズする
ミュージック.appで選択中のtrackの情報取得
大量のオブジェクト受信に備える

■高度な処理を簡潔に記述

複数の配列の同時ループ
ページ分け
再帰処理

Safariで表示中のYouTubeムービーのサムネイル画像を取得

Posted on 5月 9, 2022 by Takaaki Naganoya

Safariで表示中のYouTubeムービーのサムネール画像を取得、保存、表示するAppleScriptです。

YouTubeのムービーのサムネール画像の取得方法を確認し、動作確認用にダイアログ表示＋画像保存の機能を追加したものです。Script Debugger上で動かしている分には、NSImageの内容を結果表示ビューワで自動表示されますが、ない人向けに付けた機能です。

画像自体は、「ピクチャ」フォルダにUUIDつきでPNG形式で保存します。

–> Download Script bundle with Library

掲載リストには、画像表示ライブラリが含まれていないため、そのままでは実行できません。上記のScript Bundleをダウンロードして実行する必要があります。

AppleScript名：Safariで表示中のYouTubeムービーのサムネイル画像を取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/09
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use imgLib : script "imageDisplayLib"

property NSUUID : a reference to current application’s NSUUID
property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSURLComponents : a reference to current application’s NSURLComponents
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

tell application "Safari"
　　tell front document
　　　　try
　　　　　　set aURL to URL
　　　　on error
　　　　　　set aURL to "https://www.youtube.com/watch?v=_fmDtIV9vvI"
　　　　end try
　　end tell
end tell

if aURL does not start with "https://www.youtube.com/watch?" then return

set urlDict to parseURLParamsAsDict(aURL) of me
set aParam to urlDict’s valueForKey:"v"
if aParam = missing value then return

set imgURL to "https://i1.ytimg.com/vi/" & (aParam as string) & "/mqdefault.jpg"
set newURL to |NSURL|’s URLWithString:imgURL
set aImg to NSImage’s alloc()’s initWithContentsOfURL:newURL

set imgPath to (POSIX path of (path to pictures folder) & ((aParam as string) & "_") & (NSUUID’s UUID()’s UUIDString()) as string) & ".png"

–Save
saveNSImageAtPathAsPNG(aImg, imgPath) of me

–Display
dispImage(aImg, "YouTube thumbnail") of imgLib

on parseURLParamsAsDict(aURL)
　　set components to NSURLComponents’s alloc()’s initWithString:aURL
　　set qList to (components’s query())’s componentsSeparatedByString:"&"
　　
　　set paramRec to NSMutableDictionary’s dictionary()
　　
　　repeat with i in qList
　　　　set keyAndValues to (i’s componentsSeparatedByString:"=")
　　　　(paramRec’s setObject:(keyAndValues’s objectAtIndex:1) forKey:(keyAndValues’s objectAtIndex:0))
　　end repeat
　　
　　return paramRec
end parseURLParamsAsDict

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（９）ダイアログ表示

Posted on 5月 6, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第９巻、「ダイアログ表示」です。PDF 43ページ、サンプルScript、AppleScriptライブラリのZipアーカイブを添付。

→ 販売ページ

ダイアログ表示については、たいへん基礎的な内容でありながらも数多くの機能が盛り込まれています。サードパーティ側でさまざまなダイアログを作れるようになってきて、「みんなが思っているよりも、けっこう便利」な環境ができています。

利用するかしないかは、皆様の判断によると思いますが、実際に利用した方は割と便利で手放せなくなるようです。

ダイアログ表示

標準搭載のさまざまなダイアログ表示機能
メッセージ表示系ダイアログ
メッセージ表示系ダイアログ
ファイル選択ダイアログ
フォルダ選択ダイアログ
ファイル名選択ダイアログ
多項目選択系ダイアログ
色選択ダイアログ
LAN内のリモート資源の選択
ローカルのアプリケーションの選択
リモート・アプリケーションの選択

AppleScriptライブラリを利用したダイアログ表示

AppleScriptライブラリの用語辞書の確認方法
筆者のライブラリにはサンプルScript掲載
iPhoneやiPad、MacとAirDrop通信
チェックボックス選択ダイアログを表示
日付選択ダイアログを表示
場所選択ダイアログを表示
複数ポップアップ選択ダイアログを表示
指定のRTF書類から抽出した書式を選択するダイアログ
指定の場所を異なる拡大倍率で地図表示
表形式のデータをダイアログ表示
ラベルつきテキストフィールドを表示/データ修正
指定色の一覧選択ポップアップメニューを表示
Scriptでカスタマイズ可能な複雑なダイアログ

Keynoteのタイトル内の強制改行コードを置換….できない？

Posted on 5月 3, 2022 by Takaaki Naganoya

Keynote v12のスライド（ページ）内のタイトル（default title item）内のテキスト（object text）の強制改行を置換（削除）できないという件についての試行錯誤です。

もともと、v12以前のバージョンのKeynoteでは、LF+LFを削除することで、タイトル内のテキストの改行削除は行えていました。

ただ、同様の処理では強制改行を削除し切れないようで….

--> {"AppleSript＋NSImageでよく使う
 基礎的な処理一覧", "画像ファイル 変換処理", "画像回転処理", "画像ファイルからの 
情報取得処理", "画像リサイズ処理", "画像フィルタ処理"}

いまひとつすっきりしません。

Keynoteのタイトル文字列をコピーして、CotEditor（文字コードをAppleScriptと同じUTF16BEに変更）の書類上にペーストすると0Ahと表示するのですが、どうもKeynote上では異なるようで困ります。

AppleScript名：Keynote v12上の選択中のスライドのタイトルをテキスト化（改行削除）（未遂）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/03
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set repTargList to {string id 10 & string id 10, string id 10, string id 11, string id 13} –LF,CR,VTab一括置換

tell application "Keynote"
　　tell front document
　　　　set aSel to selection
　　　　set aList to {}
　　　　
　　　　repeat with i in aSel
　　　　　　set tmpClass to class of i
　　　　　　if tmpClass = slide then
　　　　　　　　set tmpStr0 to object text of default title item of i
　　　　　　　　set hexList to retHexDumpedStr(tmpStr0) of me
　　　　　　　　set tmpStr1 to (paragraphs of tmpStr0) –パラグラフごとにlistにしてみた
　　　　　　　　log tmpStr1
　　　　　　　　set tmpStr2 to replaceTextMultiple(tmpStr1 as string, repTargList, "") of me as string
　　　　　　　　set the end of aList to tmpStr2
　　　　　　end if
　　　　end repeat
　　end tell
end tell

return aList

–文字列の前後の改行と空白文字を除去
on cleanUpText(someText)
　　set theString to current application’s NSString’s stringWithString:someText
　　set theString to theString’s stringByReplacingOccurrencesOfString:" +" withString:" " options:(current application’s NSRegularExpressionSearch) range:{location:0, |length|:length of someText}
　　set theWhiteSet to current application’s NSCharacterSet’s whitespaceAndNewlineCharacterSet()
　　set theString to theString’s stringByTrimmingCharactersInSet:theWhiteSet
　　return theString as text
end cleanUpText

–指定文字列からCRLFを除去
on cleanUpCRLF(aStr)
　　set aString to current application’s NSString’s stringWithString:aStr
　　set bString to aString’s stringByReplacingOccurrencesOfString:(string id 10) withString:"" –remove LF
　　set cString to bString’s stringByReplacingOccurrencesOfString:(string id 13) withString:"" –remove CR
　　set dString to cString as string
　　return dString
end cleanUpCRLF

–文字置換ルーチン
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

–任意のデータから特定の文字列を複数パターン一括置換
on replaceTextMultiple(origData as string, origTexts as list, repText as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to origTexts
　　set origData to text items of origData
　　set AppleScript’s text item delimiters to {repText}
　　set origData to origData as text
　　set AppleScript’s text item delimiters to curDelim
　　return origData
end replaceTextMultiple

on hexDumpString(aStr as string)
　　set theNSString to current application’s NSString’s stringWithString:aStr
　　set theNSData to theNSString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set theString to (theNSData’s |debugDescription|()’s uppercaseString())
　　
　　–Remove "<" ">" characters in head and tail
　　set tLength to (theString’s |length|()) – 2
　　set aRange to current application’s NSMakeRange(1, tLength)
　　set theString2 to theString’s substringWithRange:aRange
　　
　　–Replace Space Characters
　　set aString to current application’s NSString’s stringWithString:theString2
　　set bString to aString’s stringByReplacingOccurrencesOfString:" " withString:""
　　
　　set aResList to splitString(bString, 2)
　　–> {"E3", "81", "82", "E3", "81", "84", "E3", "81", "86", "E3", "81", "88", "E3", "81", "8A"}
　　
　　return aResList
end hexDumpString

–Split NSString in specified aNum characters
on splitString(aText, aNum)
　　set aStr to current application’s NSString’s stringWithString:aText
　　if aStr’s |length|() ≤ aNum then return aText
　　
　　set anArray to current application’s NSMutableArray’s new()
　　set mStr to current application’s NSMutableString’s stringWithString:aStr
　　
　　set aRange to current application’s NSMakeRange(0, aNum)
　　
　　repeat while (mStr’s |length|()) > 0
　　　　if (mStr’s |length|()) < aNum then
　　　　　　anArray’s addObject:(current application’s NSString’s stringWithString:mStr)
　　　　　　mStr’s deleteCharactersInRange:(current application’s NSMakeRange(0, mStr’s |length|()))
　　　　else
　　　　　　anArray’s addObject:(mStr’s substringWithRange:aRange)
　　　　　　mStr’s deleteCharactersInRange:aRange
　　　　end if
　　end repeat
　　
　　return (current application’s NSArray’s arrayWithArray:anArray) as list
end splitString

–与えられたデータ内容をhexdumpして返す
on retHexDumpedStr(aStr)
　　set aRes to do shell script "echo " & quoted form of aStr & " | hexdump -v "
　　return aRes
end retHexDumpedStr

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（５）〜変数、プロパティ名

Posted on 4月 20, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第５巻、「変数、プロパティ名」です。PDF 31ページ、掲載Scriptアーカイブつき。

→ 販売ページ

変数名の決め方……自分がそこで困ったり悩んだり苦しんだりしたことはないのですが、いろいろ聞いてみると意外なほど困っている様子。え、そこなの？？？？

長い変数名、短い変数名、プロパティとグローバル変数はどこが違うの？　といった聞きたいけど聞く相手がいないといった「素朴な疑問」をなるべくあぶり出して、明確になるようまとめてみました。PDF 31ページ、掲載ScriptのZipアーカイブを添付。

変数/プロパティとは？

変数ってなに？
変数に入れられるものは？
ローカル変数とグローバル変数
変数の型ってあるの？
変数の型の確認方法は？
propertyと変数の違い（1/2）
propertyと変数の違い（2/2）
暗黙のrunハンドラ
暗黙のrunハンドラ内の変数
propertyの有効範囲＝スコープ
propertyの有効範囲を超える
暗黙のrunハンドラ内の変数と各ローカル変数との衝突？

変数/プロパティの名前の決め方

変数名の命名ルール
「予約語」と衝突しない命名を
「予約語」と衝突しない命名を
アプリケーションの予約語
AppleScriptの単語が何として認識されているか
かんたんな変数名/プロパティ名の付け方
変数/プロパティの運用の要点

Keynoteで選択中のtext itemとshapeをもとにtext itemを敷き詰める

Posted on 4月 15, 2022 by Takaaki Naganoya

Keynote v12で正常化した「selection」を用いて、選択中のshapeオブジェクトの範囲に、選択中のtext itemを指定数敷き詰めるAppleScriptです。

–> Watch Demo Movie

Keynote書類上に、敷き詰める領域を示すshapeオブジェクトを１つ、敷き詰める内容を示すtext itemオブジェクトを１つ配置し、これら２つを選択して本Scriptを実行。

選択状態で実行。

指定の最小文字サイズから最大文字サイズ（Keynote書類上で選択したtext item中の文字サイズ）までの間で乱数選択しつつ、指定個数を指定エリア中に作成します。

AppleScript名：選択中のtext itemとshapeをもとにtext itemを敷き詰める.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/04/15
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property textItem : missing value
property shapeItem : missing value

property objMax : 200 –生成するオブジェクト（text item）の個数
property fontSizeMin : 12 –生成するオブジェクト内のobject textのフォントサイズ（これ以下のサイズは生成しない）

tell application "Keynote"
　　set aVer to (version as real)
　　if aVer < 12 then return
　　
　　tell front document
　　　　–書類上で選択中のオブジェクトを種別に抽出する
　　　　set aaSel to selection
　　　　if length of aaSel is not equal to 2 then error "You have to select one text item and one shape."
　　　　
　　　　repeat with i in aaSel
　　　　　　set j to contents of i
　　　　　　set tmpClass to class of j
　　　　　　
　　　　　　if tmpClass = text item and textItem = missing value then
　　　　　　　　set textItem to j
　　　　　　else if tmpClass = shape and shapeItem = missing value then
　　　　　　　　set shapeItem to j
　　　　　　end if
　　　　end repeat
　　　　
　　　　if {textItem, shapeItem} contains missing value then error "Selected objects are not suitable"
　　　　
　　　　
　　　　–選択されたshapeオブジェクトから情報を取得
　　　　set aPos to (position of shapeItem)
　　　　set minX to item 1 of aPos
　　　　set maxX to minX + (width of shapeItem)
　　　　set minY to item 2 of aPos
　　　　set maxY to minY + (height of shapeItem)
　　　　
　　　　–選択されたtext itemオブジェクトから情報を取得
　　　　set maxFSize to size of object text of textItem
　　　　set oText to object text of textItem
　　　　set tWidth to width of textItem
　　　　set tHeight to height of textItem
　　　　
　　　　
　　　　–shapeオブジェクトで指定された領域に、text itemを生成
　　　　repeat objMax times
　　　　　　–座標を乱数で指定
　　　　　　set randomX to random number from minX to (maxX – tWidth)
　　　　　　set randomY to random number from minY to (maxY – tHeight)
　　　　　　–文字サイズを乱数で指定
　　　　　　set randomCSize to random number from fontSizeMin to maxFSize
　　　　　　
　　　　　　tell current slide
　　　　　　　　set tmpT to make new text item with properties {object text:oText, position:{randomX, randomY}, width:tWidth, height:tHeight} at the end
　　　　　　　　ignoring application responses
　　　　　　　　　　set size of every character of object text of tmpT to randomCSize
　　　　　　　　end ignoring
　　　　　　end tell
　　　　　　
　　　　end repeat
　　end tell
end tell

★Click Here to Open This Script　

Pixelmator Pro v2.4.1で新機能追加＋AppleScriptコマンド追加

Posted on 4月 14, 2022 by Takaaki Naganoya

いまひとつ、「こういう表現を行いたいんだけど、どう操作していいのかわからない」感のあるPixelmator Pro。毎回、メニューを漁っては「これ、どう作るんだろうーなー」という手探り感があります。

Photoshopで育って、どっぷりPhotoshopで画像処理を理解した人がPixelmator Proを理解するのに、敷居の高さを感じます。これ、絶対に「こういう完成物を作りたい」という人向けに「こういう手順で操作すればいい」というマニュアル的なものが必要です。

さて、Pixelmator Proの新バージョンv2.4.1が登場。機械学習を利用した人物写真の自動切り抜き機能が目玉のようです。

Student with laptop photo created by freepic.diller – www.freepik.com

おお！まつげの箇所だけちょっと切れてしまったけど、これはいい感じ！

Lookstudio – jp.freepik.com によって作成された people 写真

上半身はほぼ完璧！　こーれーはすごい。

いろんなスナップ写真を切り抜かせてみましたが、人物の全身が写っているとヒット率が高いようです。つまり、おかしな箇所を切り抜かれる危険性が低くなるということです。白いTシャツが抜ける危険性が高いようで、、、

Pixelmator 2.4.1　AppleScript用語辞書変更内容

export formatに「Motion」（Motion project.）が追加された
コマンド「select subject」追加。
コマンド「smart refine selection」追加。
コマンド「remove background」追加。
エレメント「color adjustments layer」「effects layer」追加。

クラス「image layer」がコマンド「remove background」と「decontaminate colors」に応答するようになった。
クラス「group laye」に要素「color adjustments layer」「effects layer」を追加
クラス「color adjustments layer」「effects layer」を追加

コマンド「draw elliptical selection」の同義語（draw oval selection）を廃止
コマンド「resize image」の同義語（adjust size、image size）を廃止
コマンド「resize canvas」の同義語（adjust canvas、canvas size）を廃止

冒頭の人物自動切り抜きを行うAppleScriptを書いてみると、こんな感じです。Pixelmator ProのAppleScript用語辞書にもサンプルScriptが掲載されています。

AppleScript名：人物自動切り抜き.scpt

tell application "Pixelmator Pro"
　　tell front document
　　　　remove background –v2.4.1 or later
　　end tell
end tell

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（４）〜AppleScript用語辞書の読み方

Posted on 4月 13, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第４巻、「AppleScript用語辞書の読み方」です。PDF 39ページ、掲載Scriptアーカイブつき。

→ 販売ページ

AppleScript用語辞書の読み方については、業務の一環として記述していても理解していない人も多いので、理解できると大きな力になる内容です。普段使っていないアプリケーションでも、AppleScriptが書きやすくなるはずです。

用語辞書の構成要素

AppleScript用語辞書ってなに？
AppleScript用語辞書を読む前に
AppleScript用語辞書を読むために必要なもの
AppleScript用語辞書の確認方法
参考資料：えせスクリプタブルなアプリケーション一覧
AppleScript用語辞書の表示内容
AppleScript用語辞書掲載のサンプルScript
AppleScript用語辞書の生ファイルを表示
参考資料：用語辞書の生ファイルを得る意義
AppleScript用語辞書の構成要素
えせスクリプタブルな用語辞書の具体例

用語辞書の読み方

GUIアプリケーション操作のAppleScript記述例
アプリケーションのオブジェクト構造を調べる
document
へたくそなサンプルScriptをわかりやすく清書
より高機能なツールによる用語辞書の確認

画面上の機能とAppleScript的な属性値の付け合わせ

オブジェクトのプロパティを取得して調査
オブジェクトの選択状態による結果の変化
オブジェクトのプロパティを取得して調査
複数クラスの属性を継承している場合に
オブジェクトのプロパティを変更するテスト

新発売：AppleScript基礎テクニック集（３）〜ファイル・パス処理

Posted on 4月 10, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第３巻、「ファイル・パス処理」です。PDF 38ページ、掲載Scriptアーカイブつき。

→ 販売ページ

本書は、まさに「基礎」中の「基礎」ともいえる「パス操作」の基礎的なサンプルを提示して段階的に紹介。最近はCocoaの機能ばかり使っているので、逆にFinderやSystem Events相手に苦労しました。

ファイル・パス処理

ファイル・パス関連オブジェクトの全体像
ファイルパス各形式の特徴や用途
ファイル・パス形式
ホームディレクトリのパスを取得
参考資料：path to で指定できるパラメータ
参考資料：path to temporary items
各種パス形式の変換
パスの組み立て
指定ファイルの親フォルダ（上位フォルダ）を求める
指定パスのファイル名だけを求める
指定パスの拡張子を求める
指定パスの拡張子だけを置換
指定フォルダの存在確認
指定フォルダに指定名称のファイルが存在するか確認
指定ファイルのリネーム（名称変更）
指定フォルダのリネーム（名称変更）
指定ファイルがパッケージかどうかを求める
指定パスからUTIを求める
指定パスがフォルダかどうかを求める
POSIX pathのチルダ（「~」）を展開
フルパスからチルダ（「~」）つきPOSIX pathを計算
特定パスのローカライズ名称を求める
特定パスが所属するドライブ名を求める

iWork Appsがバージョン12.0にアップデートでselection動作正常化

Posted on 4月 9, 2022 by Takaaki Naganoya

昨日、iWork Apps（Keynote、Pages、Numbers）がVer.12.0にバージョンアップしていました。

AppleScript系ではgetコマンドが追加（Keynote、Pages）されたぐらいですが、これによって「selection」の動作がまともになりました。

前バージョンのアップデートで「スライド単位の選択」がselectionで取れなくなったことで、「何か変更しようとしている最中なんだろう」とは思っていました。予想どおりです。selection動作の空白期間を置かず、前バージョンの段階で実装されていたらもっとよかったのですが。

AppleScript対応アプリケーション、スクリプタブルなアプリケーションの世界観は、小さい世界観のものから大きい世界観のものまでいろいろです。

小さい世界観１（一番小さい）：
アプリケーション起動、バージョン確認、書類のオープン、書類の印刷、アプリケーションの設定情報の確認

小さい世界観２：
小さい世界観１＋アプリケーション固有のコマンドの実行

小さい世界観３：
小さい世界観２＋書類やデータ作成のための機能、選択中のデータをおおまかに取得する機能
Keynote v11.xはここ

小さい世界観４：
小さい世界観３＋書類上のオブジェクト作成/改変機能、選択中のデータやオブジェクトへの参照を取得する機能
Keynote v12.xはここ？　まだ、Chart作成などで未サポートのグラフ形式などもあり、不完全

大きい世界観：
小さい世界観４＋書類上のオブジェクトの多数を作成/改変する機能
Adobe InDesign、Word、Excel、PowerPoint、Pixelmator Proなど。かつての（v5ぐらいの）Pagesはここにいた

Keynoteでselectionを試してみたところ、何か書類上のオブジェクトを選択してselectionを実行すると、オブジェクトへの参照を（複数、リスト形式で）取れます。オブジェクトを選択した状態でなければ、書類上のどのスライドを表示中かというスライドへの参照が取得できるようです。

Keynoteにおける処理の自由度は大幅に上がりました。選択中のテキストボックスを取得できれば、その中に含まれるテキストなり書式つきテキストを取得して、書き直し、元のテキストボックスに書き戻すことができます。

選択中のイメージを取得できれば、その画像のパスを求めるかあるいはファイル名を求めて、オリジナルの画像ファイル（書類内に格納された画像、外部に存在する画像かはやってみないと）を画像フィルタ処理などを行って書き戻すといった処理が行いやすくなります。以前までのバージョンでは、選択した画像をいったんコピーしてクリップボードに格納し、そのクリップボード内の画像に対して画像処理していました。

Pagesでも、さまざまなオブジェクトへの参照がselectionによって取得できますが、あいかわらず「ページ」という概念があるんだかないんだか不明で、アプリケーションの根幹にかかわる部分なのでいまひとつ気軽に言えないところではあります。

CotEditor v4.1.2でAppleScript系の機能を追加

Posted on 2月 22, 2022 by Takaaki Naganoya

オープンソース開発されているフリーのテキストエディタ「CotEditor」v4.1.2において、AppleScript系の機能が追加されています。

・DocumentオブジェクトのhasBOM属性

has BOM (boolean, r/o) : Is the file encoding of the document has BOM (byte order mark)?

・convertコマンドのBOMオプション

convert v : Convert the document text to new encoding.
convert document : The document to convert encoding.
[lossy boolean] : Allows lossy conversion?
[BOM boolean] : Has the new encoding a BOM (byte order mark)?
to text : The new encoding, either in localized encoding name or an IANA charset name.
→ boolean : Did the convertion succeed?

・新設のjumpコマンド

jump v : Move the caret to the specified location. At least, either one of a parameter is required.
jump document : The document to move.
to line integer : The number of the line to go. If a negative value is provided, the line is counted from the end of the document.
[column integer] : The location in the line to jump. If a negative value is provided, the column is counted from the end of the line.

こんなサンプル書類があったとして、

AppleScriptのdocumentオブジェクトの文字データを取得してダンプしてみても、

--No BOM
{"E3", "81", "B4", "E3", "82", "88", "E3", "81", "BE", "E3", "82", "8B", "E3", "82", "BD", "E3", "83", "95", "E3", "83", "88", "E3", "82", "A6", "E3", "82", "A7", "E3", "82", "A2", "0A", "61", "62", "63", "64", "E9", "AB", "98", "E5", "B3", "B6", "E5", "B1", "8B", "65", "66", "67", "68", "69", "0A", "0A"}

--with BOM
{"E3", "81", "B4", "E3", "82", "88", "E3", "81", "BE", "E3", "82", "8B", "E3", "82", "BD", "E3", "83", "95", "E3", "83", "88", "E3", "82", "A6", "E3", "82", "A7", "E3", "82", "A2", "0A", "61", "62", "63", "64", "E9", "AB", "98", "E5", "B3", "B6", "E5", "B1", "8B", "65", "66", "67", "68", "69", "0A", "0A"}

この状態ではhasBOM属性値で差があっても、内部データでは差が出ません。これをファイルに書き込んで、ファイル内容についてチェックを行うと、

--No BOM
0000000 81e3 e3b4 8882 81e3 e3be 8b82 82e3 e3bd
0000010 9583 83e3 e388 a682 82e3 e3a7 a282 610a
0000020 6362 e964 98ab b3e5 e5b6 8bb1 6665 6867
0000030 0a69 000a                              
0000033

--With BOM
0000000 bbef e3bf b481 82e3 e388 be81 82e3 e38b
0000010 bd82 83e3 e395 8883 82e3 e3a6 a782 82e3
0000020 0aa2 6261 6463 abe9 e598 b6b3 b1e5 658b
0000030 6766 6968 0a0a                         
0000036

のように、差を検出できます。

Pages書類内の表の指定ラベルの行を削除

Posted on 2月 14, 2022 by Takaaki Naganoya

Pagesの書類上にある表に対して、指定のラベルを持つ行を削除するAppleScriptです。macOS 12.3beta2＋Pages 11.2で動作確認しています。

現在作成中のWebブラウザのScripting本で、各種AppleScript実行環境の一覧表を掲載しているのですが、

それぞれの差別化ポイントとして掲載していたデータのうちの１つが、執筆後に一律で解決できることになり（NSAlertダイアログの最前面表示）、そのデータ行については削除することになりました。

そこで、複数のPages書類に記載した表を一括で削除することになり、AppleScriptを組んで削除することにしました。

必要はありませんでしたが、ヘッダー列が１列だけでなく、複数の列になった場合と、ヘッダーの複数セルが１つにまとめられていた場合への対処も行っておきました。ただし、気休め程度であって、本気で対処したものではありません。

AppleScript名：Pages書類内の表の指定ラベルの行を削除.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/02/14
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use framework "Foundation"
use scripting additions

set targRowLabel to "NSAlert ダイアログの最前面表示"

tell application "Pages"
　　tell front document
　　　　set tList to every table whose column count = 2
　　end tell
end tell

delRowInEveryTable(tList, targRowLabel) of me

on delRowInEveryTable(tList as list, targRowLabel as string)
　　tell application "Pages"
　　　　repeat with i in tList
　　　　　　set j to contents of i
　　　　　　
　　　　　　tell j
　　　　　　　　set hCCount to header column count
　　　　　　　　set hRCount to header column count
　　　　　　　　
　　　　　　　　–ヘッダーカラムが複数存在している場合に対処？
　　　　　　　　repeat with hc from 1 to hCCount
　　　　　　　　　　tell column hc
　　　　　　　　　　　　set aList to value of every cell
　　　　　　　　　　end tell
　　　　　　　　　　
　　　　　　　　　　if targRowLabel is in aList then
　　　　　　　　　　　　set aRes to search1DList(aList, targRowLabel) of me
　　　　　　　　　　　　
　　　　　　　　　　　　–ヘッダー列に削除対象ラベルが存在しつつ、削除対象ラベルがヘッダー行の範囲ではない場所に出現した場合に削除
　　　　　　　　　　　　if (aRes is not equal to false) and (aRes ≥ hRCount) then
　　　　　　　　　　　　　　try –ねんのため
　　　　　　　　　　　　　　　　delete row aRes
　　　　　　　　　　　　　　end try
　　　　　　　　　　　　end if
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　end repeat
　　　　　　end tell
　　　　end repeat
　　　　
　　end tell
end delRowInEveryTable

on search1DList(aList, aTarg)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　set anIndex to anArray’s indexOfObject:aTarg
　　if (anIndex = current application’s NSNotFound) or (anIndex > 9.99999999E+8) then
　　　　return false
　　end if
　　return (anIndex as integer) + 1 –convert index base (0 based to 1 based)
end search1DList

★Click Here to Open This Script　

リストに入れたテキストで、冒頭に入ったマルつき数字をリナンバーする

Posted on 2月 12, 2022 by Takaaki Naganoya

日本語環境限定かもしれませんが、マルつき数字（①②③④⑤⑥⑦⑧⑨….）をさまざまな場所でよく使います。

データにマルつき数字を入れると、順番がわかりやすくてよいのですが、データそのものを入れ替えたときに番号をふり直すという手間がかかってしまいます。これがけっこうな手間になっています（地味に大変）。

そこで、

 {"③AAAAAA", "②BBBBB", "①CCCCC", "⑬DDDDDD", "⑫EEEE", "④FFFF", "⑤GGGG", "⑥HHHH", "⑲IIIII", "⑧JJJJ"}

というデータを本Scriptによって、

{"①AAAAAA", "②BBBBB", "③CCCCC", "④DDDDDD", "⑤EEEE", "⑥FFFF", "⑦GGGG", "⑧HHHH", "⑨IIIII", "⑩JJJJ"}

と、リナンバー処理します。

本処理は、絵文字の削除Scriptの副産物として生まれたもので、マル文字を削除したのちに番号をふり直して付加したところ、たいへん有用性を感じられました。

Keynote、Numbers、Pages…と、同じことができるようにScriptを整備し、CotEditor用にあったほうが便利だろうと考えて、CotEditor用にかきかえた際に、

–> Watch Demo Movie

「ほかのアプリケーションでも使えたほうが便利なので、再利用しやすいように部品化しておこう」

と、Script文でラッピングしてみたものがこれです。

AppleScript名：リストに入れたテキストで、冒頭に入ったマルつき数字をリナンバーする.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/02/12
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aOffset to 0

set aSelList to {"③AAAAAA", "②BBBBB", "①CCCCC", "⑬DDDDDD", "⑫EEEE", "④FFFF", "⑤GGGG", "⑥HHHH", "⑲IIIII", "⑧JJJJ"}

—データ中に丸つき数字が存在した場合には、最小のものを取得
set aOffset to (getMinimumNumFromNumberWithSign(aSelList) of maruNumKit)

–ユーザーに対して「本当に初期値がこれでいいのか？」をダイアログなどで確認したほうがいい

–Keynoteの表のセルから取得したデータから丸つき数字を除去する
set cList to removeNumberWithSignFromList(aSelList) of maruNumKit

–list中の各アイテムの冒頭に順次丸つき数字を追加する
set dList to {}
set aCount to 0

repeat with i in cList
　　set j to convNumToNumWithSign(aCount + aOffset) of maruNumKit
　　set jj to contents of i
　　
　　set the end of dList to (j & jj)
　　
　　set aCount to aCount + 1
end repeat

return dList
–> {"①AAAAAA", "②BBBBB", "③CCCCC", "④DDDDDD", "⑤EEEE", "⑥FFFF", "⑦GGGG", "⑧HHHH", "⑨IIIII", "⑩JJJJ"}

–1D Arrayを改行コードをデリミタに指定しつつテキスト化
–set outStr to retDelimedText(dList, return) of maruNumKit

–丸つき数字を扱うキット
script maruNumKit
　　
　　use AppleScript
　　use framework "Foundation"
　　use scripting additions
　　property parent : AppleScript
　　
　　–1～50の範囲の数値を丸つき数字に変換して返す
　　on convNumToNumWithSign(aNum as number)
　　　　if (aNum ≤ 0) or (aNum > 50) then return ""
　　　　set aStr to "①②③④⑤⑥⑦⑧⑨⑩⑪⑫⑬⑭⑮⑯⑰⑱⑲⑳㉑㉒㉓㉔㉕㉖㉗㉘㉙㉚㉛㉜㉝㉞㉟㊱㊲㊳㊴㊵㊶㊷㊸㊹㊺㊻㊼㊽㊾㊿"
　　　　set bChar to character aNum of aStr
　　　　return bChar
　　end convNumToNumWithSign
　　
　　
　　–1D List上で指定データを検索してヒットしたアイテム番号を返す
　　on search1DList(aList, aTarg)
　　　　set anArray to current application’s NSMutableArray’s arrayWithArray:aList
　　　　set anIndex to anArray’s indexOfObject:aTarg
　　　　if (anIndex = current application’s NSNotFound) or (anIndex > 9.99999999E+8) then
　　　　　　return false
　　　　end if
　　　　return (anIndex as integer) + 1 –convert index base (0 based to 1 based)
　　end search1DList
　　
　　
　　–1D listのクリーニング
　　on cleanUp1DList(aList as list, cleanUpItems as list)
　　　　set bList to {}
　　　　repeat with i in aList
　　　　　　set j to contents of i
　　　　　　if j is not in cleanUpItems then
　　　　　　　　set the end of bList to j
　　　　　　else
　　　　　　　　set the end of bList to ""
　　　　　　end if
　　　　end repeat
　　　　return bList
　　end cleanUp1DList
　　
　　
　　–text in listから丸つき数字を除去する
　　on removeNumberWithSignFromList(aList as list)
　　　　set bList to {}
　　　　repeat with i in aList
　　　　　　set j to contents of i
　　　　　　set j2 to removeNumberWithSign(j) of me
　　　　　　set the end of bList to j2
　　　　end repeat
　　　　return bList
　　end removeNumberWithSignFromList
　　
　　
　　–文字列から丸つき数字を除去する
　　on removeNumberWithSign(aStr as text)
　　　　set aNSString to current application’s NSString’s stringWithString:aStr
　　　　return (aNSString’s stringByReplacingOccurrencesOfString:"[＼＼U000024EA-＼＼U000024EA＼＼U00002460-＼＼U00002473＼＼U00003251-＼＼U000032BF＼＼U000024FF-＼＼U000024FF＼＼U00002776-＼＼U0000277F＼＼U000024EB-＼＼U000024F4＼＼U00002780-＼＼U00002789＼＼U0000278A-＼＼U00002793＼＼U000024F5-＼＼U000024FE]" withString:"" options:(current application’s NSRegularExpressionSearch) range:{0, aNSString’s |length|()}) as text
　　end removeNumberWithSign
　　
　　
　　–1D Listに入っているテキストから丸つき数字を抽出して数値化し、最小のものを求める
　　on getMinimumNumFromNumberWithSign(aList)
　　　　set nList to {}
　　　　
　　　　repeat with i in aList
　　　　　　set j to contents of i
　　　　　　–与えられたテキストのうち、丸つき数字（白）の
　　　　　　set j2 to holdNumberWithSignOnly(j) of me
　　　　　　set n2List to characters of j2 –複数の丸つき数字が入っている場合に対処
　　　　　　
　　　　　　repeat with ii in n2List
　　　　　　　　set jj to contents of ii
　　　　　　　　set tmpNum to decodeNumFromNumWithSign(jj) of me
　　　　　　　　set the end of nList to tmpNum
　　　　　　end repeat
　　　　　　
　　　　end repeat
　　　　
　　　　set anArray to current application’s NSArray’s arrayWithArray:nList
　　　　set cRes to (anArray’s valueForKeyPath:"@min.self") as integer
　　　　return cRes
　　end getMinimumNumFromNumberWithSign
　　
　　
　　–指定文字列から丸つき数字のみ抽出する
　　on holdNumberWithSignOnly(aStr as text)
　　　　set aNSString to current application’s NSString’s stringWithString:aStr
　　　　return (aNSString’s stringByReplacingOccurrencesOfString:"[^＼＼U000024EA-＼＼U000024EA＼＼U00002460-＼＼U00002473＼＼U00003251-＼＼U000032BF＼＼U000024FF-＼＼U000024FF＼＼U00002776-＼＼U0000277F＼＼U000024EB-＼＼U000024F4＼＼U00002780-＼＼U00002789＼＼U0000278A-＼＼U00002793＼＼U000024F5-＼＼U000024FE]" withString:"" options:(current application’s NSRegularExpressionSearch) range:{0, aNSString’s |length|()}) as text
　　end holdNumberWithSignOnly
　　
　　
　　–丸つき数字を数値にデコードする v2
　　on decodeNumFromNumWithSign(aStr as string)
　　　　set numStr1 to "①②③④⑤⑥⑦⑧⑨⑩⑪⑫⑬⑭⑮⑯⑰⑱⑲⑳㉑㉒㉓㉔㉕㉖㉗㉘㉙㉚㉛㉜㉝㉞㉟㊱㊲㊳㊴㊵㊶㊷㊸㊹㊺㊻㊼㊽㊾㊿"
　　　　set numStr2 to "❶❷❸❹❺❻❼❽❾❿⓫⓬⓭⓮⓯⓰⓱⓲⓳⓴"
　　　　set numStr3 to "➀➁➂➃➄➅➆➇➈➉"
　　　　set numStr4 to "➊➋➌➍➎➏➐➑➒➓"
　　　　set numStr5 to "⓵⓶⓷⓸⓹⓺⓻⓼⓽⓾"
　　　　
　　　　set nList to {numStr1, numStr2, numStr3, numStr4, numStr5}
　　　　
　　　　repeat with i in nList
　　　　　　set numTemp to contents of i
　　　　　　if numTemp contains aStr then
　　　　　　　　using terms from scripting additions
　　　　　　　　　　set bNum to offset of aStr in numTemp
　　　　　　　　end using terms from
　　　　　　　　return bNum
　　　　　　end if
　　　　end repeat
　　　　return false
　　end decodeNumFromNumWithSign
　　
　　–1D Listを指定デリミタをはさみつつテキストに
　　on retDelimedText(aList as list, aDelim as string)
　　　　set aText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to aDelim
　　　　set aText to aList as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　return aText
　　end retDelimedText
end script

★Click Here to Open This Script　

与えられた自然言語テキストから言語を推測して、指定の性別で、TTSキャラクタを自動選択して読み上げ

Posted on 2月 5, 2022 by Takaaki Naganoya

自然言語テキストを与えると、記述言語を推測して、その言語コード（jaとか）、性別、Premium（高音質）音声かどうか（true/false）をもとにText to Speechの読み上げ音声キャラクタをしぼりこんで、sayコマンドで音声読み上げするAppleScriptです。

# ScriptのリストについているURL Linkを書き換えました

自然言語から推測される言語コードと、TTS音声キャラクタに振られている言語コードの間に仕様的な食い違いがあるので、中国語の自動判定を行うためには、（若干の）処理を追加する必要があります。

自然言語テキストから取得できるのは「簡体字」「繁体字」のコードである一方で、TTS読み上げキャラクタが持っているのは、China、HongKong、Taiwanと国コードなので、対照表でもつけるか、いっそ全部「zh」でくくってランダム選択するか、、、はたまた、実行マシンの緯度・経度情報から判定するか、テーブルを編集可能なようにしておいて、テーブルのルールを決め打ちで反映するとか、、、、

▲システム環境設定＞アクセシビリティ＞読み上げコンテンツ＞システムの声　のポップアップメニューで、一番下に「カスタマイズ」の項目があり、Text To Speech読み上げキャラクタの追加が行える

▲追加したTTSキャラクタの音声データは自動でダウンロードが行われる。TTS用にSiri音声は指定できないが、「ショートカット」の音声読み上げでは指定できる。このあたり、外部のTTS音声データ提供会社との契約によるものなのか、あるいは管理プログラムが異なるのか？

AppleScript名：与えられた自然言語テキストから言語を推測して、指定の性別で、TTSキャラクタを自動選択して読み上げ v1（簡体字、繁体字　未サポート）.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/02/05
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSSpeechSynthesizer : a reference to current application’s NSSpeechSynthesizer

set str1 to "こんにちは"

–指定文字列が何語かを推測して、言語コード（Short）を取得
set a1Res to guessLanguageCodeOf(str1) of me

–指定の言語コード（Short）をキーにしてTTS属性情報を取得
set vList to retAvailableTTSbyShortLangCodeAndSexAndPremium(a1Res, "Female", true) of me
if vList = {} then return

–取得したTTS情報リストから、てきとーに項目を取得
set fV to contents of first item of vList

set vName to VoiceName of fV
say str1 using vName

—
on retAvailableTTSbyShortLangCodeAndSexAndPremium(aLangShortCode as string, aSex as string, premiumFlag as boolean)
　　set outList to {}
　　
　　if aSex is not in {"Male", "Female"} then error "Sex code is wrong"
　　
　　set aList to NSSpeechSynthesizer’s availableVoices()
　　set bList to aList as list
　　
　　repeat with i in bList
　　　　set j to contents of i
　　　　set aInfo to (NSSpeechSynthesizer’s attributesForVoice:j)
　　　　set aInfoRec to aInfo as record
　　　　
　　　　–読み上げ対象文字データは多すぎるので削除しておく
　　　　set VoiceIndividuallySpokenCharacters of aInfoRec to {}
　　　　set VoiceSupportedCharacters of aInfoRec to {}
　　　　
　　　　set aName to VoiceName of aInfoRec
　　　　set aLangCode to VoiceLocaleIdentifier of aInfoRec
　　　　
　　　　set aGender to VoiceGender of aInfoRec
　　　　set aVID to VoiceIdentifier of aInfoRec
　　　　
　　　　if (aLangCode starts with aLangShortCode) and (aGender = "VoiceGender" & aSex) then
　　　　　　if premiumFlag = true then
　　　　　　　　if aVID ends with "premium" then
　　　　　　　　　　set the end of outList to aInfoRec
　　　　　　　　end if
　　　　　　else
　　　　　　　　set the end of outList to aInfoRec
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return outList
end retAvailableTTSbyShortLangCodeAndSexAndPremium

–文字列から言語を推測して言語名を返す
on guessLanguageOf(theString)
　　set theTagger to current application’s NSLinguisticTagger’s alloc()’s initWithTagSchemes:{current application’s NSLinguisticTagSchemeLanguage} options:0
　　theTagger’s setString:theString
　　set languageID to theTagger’s tagAtIndex:0 |scheme|:(current application’s NSLinguisticTagSchemeLanguage) tokenRange:(missing value) sentenceRange:(missing value)
　　return ((current application’s NSLocale’s localeWithLocaleIdentifier:"en")’s localizedStringForLanguageCode:languageID) as text
end guessLanguageOf

–文字列から言語を推測して言語コードを返す
on guessLanguageCodeOf(theString)
　　set theTagger to current application’s NSLinguisticTagger’s alloc()’s initWithTagSchemes:{current application’s NSLinguisticTagSchemeLanguage} options:0
　　theTagger’s setString:theString
　　set languageID to theTagger’s tagAtIndex:0 |scheme|:(current application’s NSLinguisticTagSchemeLanguage) tokenRange:(missing value) sentenceRange:(missing value)
　　return languageID as text
end guessLanguageCodeOf

★Click Here to Open This Script　

指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力

Posted on 2月 4, 2022 by Takaaki Naganoya

指定アプリケーションが対応している各ローカライズ言語におけるアプリケーション名称を取得して、言語名をcurrent localeに合わせて変換しつつCSV出力してNumbersでオープンするAppleScriptです。

アプリケーションバンドルを調査して、ローカライズ対応している言語の一覧を取得するプログラムは組んでありました。そのローカライズを順次調べて、InfoPlist.stringsファイルを読み込み、CFBundleNameのエントリを調べています。

これで、その言語向けにローカライズされた「名称」を調べられます。あとは、言語コードを名称に変換する処理（これも、ありもの）を組み合わせて、２次元配列（2D list）にまとめあげ、CSV書き出しして（ありもの）、Numbersでオープンしただけのものです。

言語名称については、currentLocaleを利用しているため、日本語環境で実行すれば日本語表現で出力されますし、英語環境で実行すれば英語表現で出力されます。

実際に、書籍に掲載する資料用のデータを作成するときに使ってみました。

言語	Code	「地図」アプリのローカライズ名称
ドイツ語	de	Karten
ヘブライ語	he	מפות
英語（オーストラリア）	en_AU	Maps
アラビア語	ar	الخرائط
ギリシャ語	el	Χάρτες
日本語	ja	マップ
英語	en	Maps
ウクライナ語	uk	Карти
スペイン語（ラテンアメリカ）	es_419	Mapas
中国語（中国本土）	zh_CN	地图
スペイン語	es	Mapas
デンマーク語	da	Kort
イタリア語	it	Mappe
スロバキア語	sk	Mapy
ポルトガル語（ポルトガル）	pt_PT	Mapas
マレー語	ms	Peta
スウェーデン語	sv	Kartor
チェコ語	cs	Mapy
韓国語	ko	지도
広東語（中国本土）	yue_CN	地图
ノルウェー語	no	Kart
ハンガリー語	hu	Térképek
中国語（香港）	zh_HK	地圖
トルコ語	tr	Harita
ポーランド語	pl	Mapy
中国語（台湾）	zh_TW	地圖
英語（イギリス）	en_GB	Maps
ベトナム語	vi	Bản đồ
ロシア語	ru	Карты
フランス語（カナダ）	fr_CA	Plans
フランス語	fr	Plans
フィンランド語	fi	Kartat
インドネシア語	id	Peta
オランダ語	nl	Kaarten
タイ語	th	แผนที่
ポルトガル語	pt	Mapas
ルーマニア語	ro	Hărți
クロアチア語	hr	Karte
ヒンディー語	hi	नक़्शा
カタロニア語	ca	Mapes

AppleScript名：指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力.scptd

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

set targFile to "InfoPlist.strings"
set targKey to "CFBundleName"

set aLocale to (current application’s NSLocale’s currentLocale())

set aLoc to path to applications folder
set anApp to POSIX path of (choose file of type {"com.apple.application-bundle"} default location aLoc)

set aBundle to getBundleFromPath(anApp) of me
set aName to aBundle’s objectForInfoDictionaryKey:(current application’s kCFBundleNameKey)

set aLocList to getSpecifiedAppFilesLocalizationListWithDuplication(aBundle) of me

set hitList to {}

repeat with i in aLocList
　　set j to contents of i
　　
　　if j is not equal to "Base" then
　　　　set allPath to anApp & "/Contents/Resources/" & j & ".lproj/" & targFile
　　　　set aDict to (current application’s NSDictionary’s alloc()’s initWithContentsOfFile:allPath)
　　　　
　　　　if aDict is not equal to missing value then
　　　　　　set aVal to (aDict’s valueForKeyPath:(targKey))
　　　　　　if aVal is not equal to missing value then
　　　　　　　　set aLang to getLangNameWithLocale(j, aLocale) of me
　　　　　　　　set the end of hitList to {aLang, j, aVal as string}
　　　　　　end if
　　　　else
　　　　　　log {"Error in ", j}
　　　　end if
　　end if
end repeat

–一時ファイルをCSV形式でデスクトップに書き出し
set aPath to (path to desktop as string) & (do shell script "uuidgen") & ".csv"
saveAsCSV(hitList, aPath) of me

–書き出したCSVファイルをNumbersでオープン
tell application "Numbers"
　　open (aPath as alias)
end tell

–Application path –> Bundle
on getBundleFromPath(aPOSIXpath)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aPOSIXpath
　　set aWorkspace to current application’s NSWorkspace’s sharedWorkspace()
　　set appURL to aWorkspace’s URLForApplicationToOpenURL:aURL
　　set aBundle to current application’s NSBundle’s bundleWithURL:appURL
　　return aBundle
end getBundleFromPath

–指定Bundleのローカライズ言語リストを求める。重複を許容
on getSpecifiedAppFilesLocalizationListWithDuplication(aBundle)
　　set locList to aBundle’s localizations()
　　return locList as list
end getSpecifiedAppFilesLocalizationListWithDuplication

on getLangNameWithLocale(langCode, aLocale)
　　set aLangName to (aLocale’s displayNameForKey:(current application’s NSLocaleIdentifier) value:langCode) as string
　　return aLangName
end getLangNameWithLocale

–2D List to CSV file
on saveAsCSV(aList, aPath)
　　–set crlfChar to (ASCII character 13) & (ASCII character 10)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　writeToFileAsUTF8(wholeText, bPath, false) of me
　　
end saveAsCSV

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

Numbersの表でセル連結箇所が存在していたらすべて連結解除

Posted on 1月 31, 2022 by Takaaki Naganoya

指定のNumbers書類中の指定の表で、セルの連結が行われた箇所が存在していたらすべて連結解除するAppleScriptです。

Numbersの表でセルの連結が存在していると、フィルタ処理などが行えないために、セル連結箇所がないかを調べる手段がないと困ります。でも、そういう便利なコマンドがNumbersのAppleScript用語辞書には存在していないので作りました。

連結箇所が分かれば、個別に連結解除するだけです。ループですべてunmergeします。

動作確認は、M1 Mac mini＋macOS 12.3beta＋Numbersバージョン11.2で行なっています。

▲処理前セルが連結されている箇所が複数存在している

▲処理後　すべてのセル結合されている箇所が連結解除された

AppleScript名：指定の表で連結セルがあればすべて分離.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/01/31
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSCountedSet : a reference to current application’s NSCountedSet

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　tell table 1
　　　　　　　　set nList to name of every cell
　　　　　　　　set aRes1 to returnDuplicatesOnly(nList) of me –重複するセルの名称のみピックアップ
　　　　　　　　
　　　　　　　　–重複セルを個別に分離
　　　　　　　　repeat with i in aRes1
　　　　　　　　　　set j to contents of i
　　　　　　　　　　unmerge cell j
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
end tell

on returnDuplicatesOnly(aList as list)
　　set aSet to NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　

Numbersの表でセル連結箇所が存在しているかどうかチェック

Posted on 1月 31, 2022 by Takaaki Naganoya

指定のNumbers書類中の指定の表で、セルの連結が行われた箇所が存在しているかどうかチェックするAppleScriptです。

Numbersの表でセルの連結が存在していると、フィルタ処理などが行えないために、セル連結箇所がないかを調べる手段がないと困ります。でも、そういう便利なコマンドはNumbersのAppleScript用語辞書には存在していません。

動作確認は、M1 Mac mini＋macOS 12.3beta＋Numbersバージョン11.2で行なっています。

セルが連結されている箇所は、セルのnameが重複していることが判明。すべてのセルの「name」を取得して、重複しているものをチェックするとセル連結の有無がわかります。

B3セルのproperties

{vertical alignment:top, row:row “row2” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, class:cell, font name:”HiraKakuProN-W3″, formatted value:”2 21″, background color:missing value, formula:missing value, name:”B3″, text wrap:true, text color:{0, 0, 0}, alignment:auto align, column:column “field1” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, format:automatic, font size:10.0, value:”2 21″}

C3セルのproperties

{vertical alignment:top, row:row “row2” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, class:cell, font name:”HiraKakuProN-W3″, formatted value:”2 21″, background color:missing value, formula:missing value, name:”B3″, text wrap:true, text color:{0, 0, 0}, alignment:auto align, column:column “field2” of table 1 of sheet 1 of document id “6ED4F3E1-57BD-4A1E-8E0E-9C781DE3840E” of application “Numbers”, format:automatic, font size:10.0, value:”2 21″}

AppleScript名：指定の表でセル連結がないかチェック.scpt

property NSCountedSet : a reference to current application’s NSCountedSet

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　tell table 1
　　　　　　　　set nList to name of every cell
　　　　　　　　set aRes1 to returnDuplicatesOnly(nList) of me
　　　　　　　　return aRes1
　　　　　　　　–> {"B3"}
　　　　　　end tell
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

16bitカラー値から明度を取得 v1.1

Posted on 1月 20, 2022 by Takaaki Naganoya

choose colorコマンドやiWorkアプリケーションが返してくる16ビットのカラー値（{R,G,B}）から明度情報を取得するAppleScriptです。0から1までの値を返し、0に近づくほど暗く、1に近づくほど明るい色であることを表現しています。

色情報同士を比較して、明るい箇所に指定している色データと暗い箇所に指定している色データを、RGB値から自動認識するような処理に使っています。

また、ファイル名から「章」（Chapter）の番号を検出して、実際のツメ（Index）の選択部分を暗い色で塗り直す処理も行なっています。

–> Watch Demo Movie

Pages書類の上に作成したツメ（辞書などの端に印刷されているAからZのインデックス）に対して、ツメのオブジェクトを（座標や形状から）自動認識したあとに、色の塗り分け情報を本ルーチンを用いて自動認識。濃い色を現在の選択箇所の色、明るい（淡い）色を通常の箇所の色情報として扱い、あらかじめツメに指定していた色情報を用いて実際の章構成を反映させてツメのオブジェクト（表）を再構成する処理に必須のものです。

明度情報の取得には、グレースケールに変換してグレー度（whiteComponent）を明度とみなして計算しています。直感的にこちらのほうが、まっとうな処理（HSB色空間の色に変換してからBrightnessを取得）よりもしっくり来る計算結果だったので採用しています。

おまけで、２つの色情報のうちどちらが暗いか、結果をインデックス値で返す処理ルーチンをつけています。これも、選択色と非選択色の自動識別のために必要なものです。

AppleScript名：16bitカラー値から明度を取得 v1.1.scptd

set a1Col to {26148, 65535, 58650}
set a1Col to choose color default color a1Col
set w1Col to calcBrightnessFrom16bitColorList(a1Col) of colorBrightnessKit
–> 0.900838315487

set a2Col to {2966, 23133, 21203}
set a2Col to choose color default color a2Col
set w2Col to calcBrightnessFrom16bitColorList(a2Col) of colorBrightnessKit
–> 0.37399661541–0に近いのでこちらのほうが暗い

set cIndRes to calcColorPairsDarkerCol(a1Col, a2Col) of colorBrightnessKit
–> {2, 1}–暗い順にインデックス値を返す

–色情報から明度を計算するKit。0に近い値が暗い。CMYKやグレースケール値は対象外。RGBのみ
script colorBrightnessKit
　　
　　use AppleScript
　　use framework "Foundation"
　　use framework "AppKit"
　　use scripting additions
　　property parent : AppleScript
　　
　　property NSColor : a reference to current application’s NSColor
　　property NSString : a reference to current application’s NSString
　　property NSAttributedString : a reference to current application’s NSAttributedString
　　property NSUTF16StringEncoding : a reference to current application’s NSUTF16StringEncoding
　　property NSDeviceWhiteColorSpace : a reference to current application’s NSDeviceWhiteColorSpace
　　
　　
　　–２つの16ビットカラー値でそれぞれ明度を計算し、暗いものから順にインデックス値を返す
　　on calcColorPairsDarkerCol(aCol as list, bCol as list)
　　　　set b1 to calcBrightnessFrom16bitColorList(aCol) of me
　　　　set b2 to calcBrightnessFrom16bitColorList(bCol) of me
　　　　if b1 ≥ b2 then
　　　　　　return {2, 1} –bColのほうが暗い
　　　　else
　　　　　　return {1, 2} –aColのほうが暗い
　　　　end if
　　end calcColorPairsDarkerCol
　　
　　
　　–16ビットカラー値から明度を計算
　　on calcBrightnessFrom16bitColorList(colList as list)
　　　　copy colList to {rVal, gVal, bVal}
　　　　–NSColorを作成
　　　　set aCol to makeNSColorFromRGBAval(rVal, gVal, bVal, 65535, 65535) of me
　　　　— グレースケール化
　　　　set gCol to aCol’s colorUsingColorSpaceName:(NSDeviceWhiteColorSpace)
　　　　set wComp to gCol’s whiteComponent() –whiteComponentを取得することで擬似的に明度情報を取得　　
　　　　return wComp
　　end calcBrightnessFrom16bitColorList
　　
　　
　　–HTMLカラー値あから明度を計算
　　on calcBrightnessFromHTMLColorCodeStr(aStr as string)
　　　　set {rVal, gVal, bVal} to rgbHex2nunList(aStr) of me
　　　　–NSColorを作成
　　　　set aCol to makeNSColorFromRGBAval(rVal, gVal, bVal, 255, 255) of me
　　　　— グレースケール化
　　　　set gCol to aCol’s colorUsingColorSpaceName:(NSDeviceWhiteColorSpace)
　　　　set wComp to gCol’s whiteComponent() –whiteComponentを取得することで擬似的に明度情報を取得　　
　　　　return wComp
　　end calcBrightnessFromHTMLColorCodeStr
　　
　　
　　on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　　　set aRedCocoa to (redValue / aMaxVal) as real
　　　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　　　return aColor
　　end makeNSColorFromRGBAval
　　
　　
　　
　　on decodeCharacterReference(aStr)
　　　　set anNSString to NSString’s stringWithString:aStr
　　　　set theData to anNSString’s dataUsingEncoding:(NSUTF16StringEncoding)
　　　　set styledString to NSAttributedString’s alloc()’s initWithHTML:theData documentAttributes:(missing value)
　　　　set plainText to (styledString’s |string|()) as string
　　　　return plainText
　　end decodeCharacterReference
　　
　　
　　
　　–HTMLコードのRGB 16進数コードを数値リストに変換
　　on rgbHex2nunList(aHexStr)
　　　　–エラーチェック
　　　　if aHexStr does not start with "#" then return false
　　　　if length of aHexStr is not equal to 7 then return false
　　　　set bHex to text 2 thru -1 of aHexStr
　　　　
　　　　set {rStr, gStr, bStr} to {text 1 thru 2 of bHex, text 3 thru 4 of bHex, text 5 thru 6 of bHex}
　　　　
　　　　set bList to {}
　　　　repeat with i in {rStr, gStr, bStr}
　　　　　　set j to contents of i
　　　　　　set the end of bList to aHexStrToNum(j) of me
　　　　end repeat
　　　　
　　　　return bList
　　end rgbHex2nunList
　　
　　
　　–16進数文字列を10進数数値に変換する
　　on aHexStrToNum(hexStr)
　　　　set hStr to "0123456789ABCDEF"
　　　　
　　　　set aNum to 0
　　　　set aLen to length of hexStr
　　　　
　　　　repeat with i from aLen to 1 by -1
　　　　　　
　　　　　　set aCon to contents of character i of hexStr
　　　　　　using terms from scripting additions
　　　　　　　　set aVal to (offset of aCon in hStr) – 1
　　　　　　end using terms from
　　　　　　set aNum to aNum + aVal * (16 ^ (aLen – i))
　　　　　　
　　　　end repeat
　　　　
　　　　return aNum as integer
　　end aHexStrToNum
end script

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: 10.15savvy

iWorkアプリケーションv12に共通のバグ？　新規ファイルの保存ができない

新発売：AppleScript基礎テクニック集（11）AppleScriptアプレットとドロップレット

目次

■アプレット

■Cocoa-AppleScriptアプレット

■Script Debuggerのアプレット/拡張アプレット

■ドロップレット

新発売：AppleScript基礎テクニック集（10）ループ処理

目次

■ループによる繰り返し処理

■アプリケーションから取得したオブジェクトでループ

■高度な処理を簡潔に記述

Safariで表示中のYouTubeムービーのサムネイル画像を取得

新発売：AppleScript基礎テクニック集（９）ダイアログ表示

目次

ダイアログ表示

AppleScriptライブラリを利用したダイアログ表示

Keynoteのタイトル内の強制改行コードを置換….できない？

新発売：AppleScript基礎テクニック集（５）〜変数、プロパティ名

変数/プロパティとは？

変数/プロパティの名前の決め方

Pixelmator Pro v2.4.1で新機能追加＋AppleScriptコマンド追加

Pixelmator 2.4.1　AppleScript用語辞書変更内容

新発売：AppleScript基礎テクニック集（４）〜AppleScript用語辞書の読み方

用語辞書の構成要素

用語辞書の読み方

画面上の機能とAppleScript的な属性値の付け合わせ

新発売：AppleScript基礎テクニック集（３）〜ファイル・パス処理

ファイル・パス処理

iWork Appsがバージョン12.0にアップデートでselection動作正常化

CotEditor v4.1.2でAppleScript系の機能を追加

与えられた自然言語テキストから言語を推測して、指定の性別で、TTSキャラクタを自動選択して読み上げ

指定アプリケーションの各言語のローカライズ名称を取得して、言語名をローカライズしてNumbersに出力

目次

■アプレット

■Cocoa-AppleScriptアプレット

■Script Debuggerのアプレット/拡張アプレット

■ドロップレット

目次

■ループによる繰り返し処理

■アプリケーションから取得したオブジェクトでループ

■高度な処理を簡潔に記述

目次

ダイアログ表示

AppleScriptライブラリを利用したダイアログ表示

変数/プロパティとは？

変数/プロパティの名前の決め方

Pixelmator 2.4.1 AppleScript用語辞書変更内容

用語辞書の構成要素

用語辞書の読み方

画面上の機能とAppleScript的な属性値の付け合わせ

ファイル・パス処理

Pixelmator 2.4.1　AppleScript用語辞書変更内容