ASの実行結果をNumbersの表に出力する

Posted on 4月 5, 2019 by Takaaki Naganoya

文字列で与えたAppleScriptを実行し、その実行結果をテキストで取得したうえにラベルと値に分割してNumbersの「表」に組み立てるAppleScriptです。

仕様書の作成とかテストデータの評価とかそういう仕事を行うさいに、プログラムコード（AppleScriptが出力するrecordとかlistとか）が読めない人向けに確認してもらうために作成したものです。

Numbersに出力すること自体にはさほど意味はありませんが（ExcelでもREST API経由でGoogle Spread Sheetに出力したっていいわけで）、とりあえずプログラムの結果出力になじみのない方々に計算結果を見ていただくためのものです。

AppleScriptの実行結果をスクリプトエディタではなくOSAScriptControllerなどから受け取る部品などが揃ってきたので、こういう加工も割とすぐにできていい感じです。

ちなみに、Numbersの表のセルに対して直接AppleScriptからデータを突っ込んでいますが、これはあらかじめ出力するデータ数が少ないことが見込まれているためです。多い場合（100件前後がひとつの基準に）には、CSVファイルに書き出してNumbersにオープンさせることになるでしょう。

例によって、Numbersの表セルに対してデータを突っ込むさいには非同期モードで実行して速度を稼いでいます。

AppleScript名：ASの実行結果をNumbersの表に出力する

— Created 2019/04/05 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "OSAKit"
use framework "AppKit"
use bLus : script "BridgePlus"

property NSString : a reference to current application’s NSString
property NSThread : a reference to current application’s NSThread
property OSAScript : a reference to current application’s OSAScript
property NSTextView : a reference to current application’s NSTextView
property OSAScriptView : a reference to current application’s OSAScriptView
property OSAScriptController : a reference to current application’s OSAScriptController

property SMSForder : a reference to current application’s SMSForder

property theResult : "" –result

set origStr to "
tell application ＼"Numbers＼"
　　tell front document
　　　　properties
　　end tell
end tell
"

my performSelectorOnMainThread:"execASandReturnString:" withObject:origStr waitUntilDone:true
set aStr to (my theResult)

set aList to my getListFromText:aStr

makeNewNumbersDocumentAndTable(length of aList, 2) of me
fillCurrentTable(aList) of me

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel(aRecList as list, aPredicate as string)
　　–ListからNSArrayへの型変換
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　–抽出
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　
　　–NSArrayからListに型変換して返す
　　set bList to filteredArray as list
　　return bList
end filterRecListByLabel

–リストに入れたレコードを、指定の属性ラベルの値で抽出。値が別途指定のリストの中に存在していることが条件
on filterRecList:(aRecList as list) byLabel:(aPredicate as string) andSublist:(aSubList as list)
　　–ListからNSArrayへの型変換
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　set aSubArray to current application’s NSArray’s arrayWithArray:aSubList
　　
　　–抽出
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_(aPredicate, aSubArray)
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　
　　–NSArrayからListに型変換して返す
　　set bList to filteredArray as list
　　return bList
end filterRecList:byLabel:andSublist:

–listの共通項を返す
on getSameItemsInLists:(aList as list) withList:(bList as list)
　　
　　–ASオブジェクトをCocoaオブジェクトに変換
　　set aArray to current application’s NSArray’s arrayWithArray:aList
　　set bArray to current application’s NSArray’s arrayWithArray:bList
　　
　　— まとめる
　　set allSet to current application’s NSMutableSet’s setWithArray:aArray
　　allSet’s addObjectsFromArray:bArray
　　
　　–重複する要素のみ抜き出す
　　set duplicateSet to current application’s NSMutableSet’s setWithArray:aArray
　　duplicateSet’s intersectSet:(current application’s NSSet’s setWithArray:bArray)
　　
　　–重複部分だけを返す
　　set resArray to duplicateSet’s allObjects()
　　
　　set resList to resArray as list
　　
　　return resList
end getSameItemsInLists:withList:

–スクリプトエディタのresult欄に返ってきたテキストをリストに変える
on getListFromText:aText
　　
　　script getListFromTextO
　　　　property aaText : ""
　　　　property gList : {}
　　　　property outList : {}
　　　　property aG : ""
　　　　property valList : {}
　　end script
　　
　　copy aText to (aaText of getListFromTextO)
　　
　　set (gList of getListFromTextO) to {}
　　set (outList of getListFromTextO) to {}
　　set (aG of getListFromTextO) to ""
　　set (valList of getListFromTextO) to {}
　　
　　if (aaText of getListFromTextO) does not start with "{" and (aaText of getListFromTextO) does not end with "}" then
　　　　return {}
　　end if
　　
　　set aLen to length of (aaText of getListFromTextO)
　　set (aG of getListFromTextO) to text 2 thru -2 of (aaText of getListFromTextO)
　　set (gList of getListFromTextO) to characters of (aG of getListFromTextO)
　　
　　
　　set sPos to 2 –１文字目は＼"{＼"なので2文字目からスキャンを開始する
　　set ePos to 2
　　
　　set imdF to false –Immediate Data Flag（文字列中を示すダブルクォート内の場合にはtrueになる）
　　set listF to 0 –stacking段数が入る
　　
　　set attrF to true –属性ラベルスキャン時にtrue、データ末尾スキャン時にfalse
　　
　　
　　repeat with i in (gList of getListFromTextO)
　　　　
　　　　set j to contents of i
　　　　
　　　　if attrF = true and imdF = false and listF = 0 then
　　　　　　
　　　　　　–属性値部分の末尾検出
　　　　　　if j = ":" then
　　　　　　　　if text sPos thru sPos of (aaText of getListFromTextO) = " " then
　　　　　　　　　　set sPos to sPos + 1
　　　　　　　　end if
　　　　　　　　set anOut to text sPos thru ePos of (aaText of getListFromTextO)
　　　　　　　　set sPos to ePos + 1
　　　　　　　　set the end of (valList of getListFromTextO) to anOut
　　　　　　　　set attrF to false –データのスキャンを開始する
　　　　　　　　set imdF to false
　　　　　　　　set listF to 0
　　　　　　end if
　　　　　　
　　　　else if imdF = false and listF = 0 and j = "," then
　　　　　　
　　　　　　–データ部分の末尾検出
　　　　　　set anOut to text sPos thru (ePos – 1) of (aaText of getListFromTextO)
　　　　　　set sPos to ePos + 1
　　　　　　set the end of (valList of getListFromTextO) to anOut
　　　　　　set the end of (outList of getListFromTextO) to (valList of getListFromTextO)
　　　　　　set (valList of getListFromTextO) to {}
　　　　　　
　　　　　　set attrF to true –次が属性値ラベルであることを宣言
　　　　　　set imdF to false
　　　　　　set listF to 0
　　　　　　
　　　　else if j = "{" then
　　　　　　if imdF = false then
　　　　　　　　set listF to listF + 1 –１段スタックにpush
　　　　　　end if
　　　　else if j = "}" then
　　　　　　if imdF = false then
　　　　　　　　set listF to listF – 1 –１段スタックからpop
　　　　　　end if
　　　　else if j = "＼"" then
　　　　　　if imdF = true then
　　　　　　　　set imdF to false
　　　　　　else
　　　　　　　　set imdF to true
　　　　　　end if
　　　　end if
　　　　
　　　　set ePos to ePos + 1
　　　　
　　end repeat
　　
　　–ラストのデータ部分を出力
　　try
　　　　set the end of (valList of getListFromTextO) to text sPos thru (ePos – 1) of (aaText of getListFromTextO)
　　　　set the end of (outList of getListFromTextO) to (valList of getListFromTextO)
　　on error
　　　　return false
　　end try
　　
　　return contents of (outList of getListFromTextO)
end getListFromText:

on execASandReturnString:(srcStr as string)
　　
　　set targX to 500 –View Width
　　set targY to 200 –View Height
　　
　　
　　if srcStr = missing value or srcStr = "" then
　　　　–Error
　　　　display dialog "Error in reading script source…." buttons {"OK"} default button 1 with icon 1
　　　　return
　　end if
　　
　　–Make AppleScript Controller & Script Editor View
　　set osaCon to OSAScriptController’s alloc()’s init()
　　set osaView to OSAScriptView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, targX, targY))
　　
　　–Make Result View
　　set resView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, targX, targY))
　　resView’s setRichText:true
　　resView’s useAllLigatures:true
　　
　　–Connect OSAScriptController to Editor View & Result View
　　osaCon’s setScriptView:osaView
　　osaCon’s setResultView:resView
　　
　　–Set AppleScript Source to Editor View & Execute it
　　osaView’s setString:srcStr
　　osaCon’s runScript:(missing value)
　　
　　–Get AppleScript’s Result as string
　　set aRes to resView’s |string|() as list of string or string –as anything
　　
　　set my theResult to aRes –Return the result as string
　　
end execASandReturnString:

on fillCurrentTable(aList)
　　set aLen to length of aList
　　set aWidth to length of first item of aList
　　
　　tell application "Numbers"
　　　　tell front document
　　　　　　tell active sheet
　　　　　　　　tell table 1
　　　　　　　　　　repeat with i from 1 to aLen
　　　　　　　　　　　　tell row (i + 1)
　　　　　　　　　　　　　　set aRowList to contents of item i of aList
　　　　　　　　　　　　　　repeat with ii from 1 to aWidth
　　　　　　　　　　　　　　　　tell cell ii
　　　　　　　　　　　　　　　　　　set aTmpData to contents of item ii of aRowList
　　　　　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　　　　　set value to aTmpData
　　　　　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　　　end repeat
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
end fillCurrentTable

on makeNewNumbersDocumentAndTable(aHeight, aWidth)
　　tell application "Numbers"
　　　　make new document
　　　　
　　　　tell front document
　　　　　　tell active sheet
　　　　　　　　delete every table
　　　　　　end tell
　　　　end tell
　　　　
　　　　tell front document
　　　　　　tell active sheet
　　　　　　　　set tRes to make new table with properties {row count:aHeight, column count:aWidth}
　　　　　　　　return tRes
　　　　　　end tell
　　　　end tell
　　end tell
end makeNewNumbersDocumentAndTable

★Click Here to Open This Script　

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

Posted on 3月 29, 2019 by Takaaki Naganoya

英語版の花文字テキストを作成してテキストエディタ（CotEditor）に出力するAppleScriptです。

描画用の英単語と、塗りつぶし用の英単語を別々に指定できます。invertFをtrueに設定すると、白黒反転出力を行います。

おおもとの元ネタは、大型計算機を大勢のユーザーで共有していた時代（ぱそこん登場前）、計算結果を高速プリンタの帳票に出力するようになっていたころにさかのぼります。どのユーザーの計算結果かを大量のプリンタの出力結果の中から仕分けるため、印刷出力の１ページ目をユーザー名などの情報を印字した「バナー」として使用。

そのさい、ドットインパクトプリンターだったので、決められた固定ドット数の文字しか印字できないため、英数字を組み合わせて擬似的に大きな文字でバナーを印刷していたことに端を発します。

その時代の「残り香」ともいえるバナーがパソコンの電子メールやBBSの時代にお遊びの「花文字」として引き継がれ、原始的なアスキーアートの一種として楽しまれてきました。

いまでも、shell commandの「banner」コマンドにその末裔を見ることができます。

先週のmacOS nativeのデモ時に「祝」という花文字を「呪」の文字で出力するという、定番の持ちネタを披露したところ、たいへんウケておりました。

ただ、これを海外のScripter向けにそのままデモしても受けません。

この、花文字テキストを出力するプログラムの英語版としては、love.scptといういにしえのデータをそのまま使いまわしたものがありますが、描画パターンを数値データで保持しているため、異なるパターンを表示させることはできません。

そこで、日本語版の花文字テキスト出力プログラムに若干手をくわえ、英単語の出力が行えるようにしてみました。

テキストの出力はCotEditorに対して行なっていますが、新規書類を指定文字で作成する程度なので、AppleScriptに対応しているテキストエディタならどれでも作り変えられます。また、表示を等幅フォントにしておく必要があります（あとから指定してもOK）。

AppleScript名：指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

— Created 2017-12-12 by Takaaki Naganoya
— Modified 2019-03-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSFont : a reference to current application’s NSFont
property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSColorSpace : a reference to current application’s NSColorSpace
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSFontManager : a reference to current application’s NSFontManager
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSKernAttributeName : a reference to current application’s NSKernAttributeName
property NSMutableParagraphStyle : a reference to current application’s NSMutableParagraphStyle
property NSLigatureAttributeName : a reference to current application’s NSLigatureAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSUnderlineStyleAttributeName : a reference to current application’s NSUnderlineStyleAttributeName
property NSParagraphStyleAttributeName : a reference to current application’s NSParagraphStyleAttributeName
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

property fillCharList : {}
property fillCharCounter : 1

set aString to "Love"
set bString to "hate"
set hanaSize to 24
set thisFont to selectAFont(first character of aString) of me
if thisFont = false then return –Cancel

–花文字文字列を作成
set fRes to getEnglishHanamojiStr(hanaSize, thisFont, aString, bString, 0.7, true, true) of me
makeNewDocument given parameter:fRes

–花文字文字列を計算して返す
on getEnglishHanamojiStr(aFontSize as real, aFontName as string, aString as string, fillString as string, aThread as real, incFontName as boolean, invertF as boolean)
　　
　　set my fillCharList to characters of fillString
　　set my fillCharCounter to 1
　　
　　–指定文字コードが指定フォント中に存在するかチェック
　　repeat with i in (characters of aString)
　　　　set fRes to retGlyphsInFont(aFontName, id of i) of me
　　　　if fRes = false then return false
　　end repeat
　　
　　set aThreadShould to 768 * aThread
　　if (chkMultiByteChar(first character of aString) of me) = false then
　　　　set spaceChar to string id 12288 –全角スペース（UTF-16）
　　else
　　　　set spaceChar to string id 32 –半角スペース
　　end if
　　
　　set fillColor to NSColor’s whiteColor –塗り色
　　set bString to aString & " " –処理内容の帳尻合わせ（そのままだと右端が欠けるのでスペースを入れた）
　　set anAssrStr to makeRTFfromParameters(bString, aFontName, aFontSize, -2, (aFontSize * 1.2)) of me
　　set aSize to anAssrStr’s |size|()
　　
　　if class of aSize = record then
　　　　set attrStrWidth to width of aSize
　　　　set attrStrHeight to height of aSize
　　else if class of aSize = list then –macOS 10.13.xのバグ回避
　　　　copy aSize to {attrStrWidth, attrStrHeight}
　　end if
　　
　　set {xPos, yPos} to {0, 0}
　　
　　set tmpImg1 to makeImageWithFilledColor(attrStrWidth, attrStrHeight, fillColor) of me
　　set tmpImg2 to drawAttributedStringsOnImage(tmpImg1, anAssrStr, xPos, yPos) of me
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:(tmpImg2’s TIFFRepresentation())
　　
　　–画像から順次指定座標の色データを拾って花文字listに反映
　　set strList to {}
　　repeat with y from 1 to attrStrHeight – 1
　　　　
　　　　set strListX to {}
　　　　repeat with x from 0 to attrStrWidth – 1
　　　　　　set tmpCol to getColorFromRawImage(aRawimg, x, y) of me
　　　　　　
　　　　　　if invertF = false then
　　　　　　　　
　　　　　　　　–通常描画（invert = false）時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　else
　　　　　　　　–白黒反転（invert = true)時
　　　　　　　　if tmpCol is not equal to false then
　　　　　　　　　　if tmpCol is not equal to {255, 255, 255} then
　　　　　　　　　　　　copy tmpCol to {tmpR, tmpG, tmpB}
　　　　　　　　　　　　if (tmpR + tmpG + tmpB) < aThreadShould then
　　　　　　　　　　　　　　set the end of strListX to spaceChar
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　　　end if
　　　　　　　　　　else
　　　　　　　　　　　　set the end of strListX to getChar() of me
　　　　　　　　　　end if
　　　　　　　　end if
　　　　　　　　
　　　　　　end if
　　　　end repeat
　　　　set the end of strList to strListX
　　end repeat
　　
　　–2D List→Text
　　set aRes to list2dToStringByUsingDelimiters(strList, "", return) of me
　　
　　if incFontName = true then
　　　　set fName to getDisplayedNameOfFont(aFontName) of me
　　　　set aRes to "Font=" & fName & return & return & aRes
　　end if
　　
　　return aRes
end getEnglishHanamojiStr

on getChar()
　　set retChar to item (my fillCharCounter) of (my fillCharList)
　　if (my fillCharCounter) = length of (my fillCharList) then
　　　　set (my fillCharCounter) to 1
　　else
　　　　set (my fillCharCounter) to (my fillCharCounter) + 1
　　end if
　　return retChar
end getChar

–指定Raw画像中の指定座標のピクセルの色をRGBで取り出す
on getColorFromRawImage(aRawimg, x as real, y as real)
　　set aRatio to getImageRatio() of me –Retina Display対応
　　set origColor to (aRawimg’s colorAtX:(x * aRatio) y:(y * aRatio))
　　
　　set srgbColSpace to NSColorSpace’s deviceRGBColorSpace
　　if srgbColSpace = missing value then return false
　　
　　set aColor to (origColor’s colorUsingColorSpace:srgbColSpace)
　　
　　set aRed to (aColor’s redComponent()) * 255
　　set aGreen to (aColor’s greenComponent()) * 255
　　set aBlue to (aColor’s blueComponent()) * 255
　　
　　return {aRed as integer, aGreen as integer, aBlue as integer}
end getColorFromRawImage

–画像のうえに指定のスタイル付きテキストを描画して画像を返す
on drawAttributedStringsOnImage(anImage, anAssrStr, xPos as real, yPos as real)
　　anImage’s lockFocus()
　　anAssrStr’s drawAtPoint:(current application’s NSMakePoint(xPos, yPos))
　　anImage’s unlockFocus()
　　return anImage
end drawAttributedStringsOnImage

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, fontName as string, aFontSize as real, aKerning as real, aLineSpacing as real)
　　set aVal1 to NSFont’s fontWithName:fontName |size|:aFontSize
　　set aKey1 to (NSFontAttributeName)
　　
　　set aVal2 to NSColor’s blackColor()
　　set aKey2 to (NSForegroundColorAttributeName)
　　
　　set aVal3 to aKerning
　　set akey3 to (NSKernAttributeName)
　　
　　set aVal4 to 0
　　set akey4 to (NSUnderlineStyleAttributeName)
　　
　　set aVal5 to 2 –all ligature ON
　　set akey5 to (NSLigatureAttributeName)
　　
　　set aParagraphStyle to NSMutableParagraphStyle’s alloc()’s init()
　　aParagraphStyle’s setMinimumLineHeight:(aLineSpacing)
　　aParagraphStyle’s setMaximumLineHeight:(aLineSpacing)
　　set akey7 to (NSParagraphStyleAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3, akey4, akey5, akey7}
　　set valList to {aVal1, aVal2, aVal3, aVal4, aVal5, aParagraphStyle}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–指定サイズの画像を作成し、背景を指定色で塗る
on makeImageWithFilledColor(aWidth as real, aHeight as real, fillColor)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　set aRatio to getImageRatio() of me –Retina Display対応
　　
　　anImage’s lockFocus()
　　set theRect to {{x:0, y:0}, {width:aWidth * aRatio, height:aHeight * aRatio}}
　　set theNSBezierPath to NSBezierPath’s bezierPath
　　theNSBezierPath’s appendBezierPathWithRect:theRect
　　fillColor’s |set|()
　　theNSBezierPath’s fill()
　　anImage’s unlockFocus()
　　
　　return anImage
end makeImageWithFilledColor

–2D Listをアイテム間および行間のデリミタを個別に指定してテキスト変換
on list2dToStringByUsingDelimiters(aList as list, itemDelimiter, lineDelimiter)
　　set outList to {}
　　repeat with i in aList
　　　　set aStr to listToStringUsingTextItemDelimiter(i, itemDelimiter) of me
　　　　set the end of outList to aStr
　　end repeat
　　
　　set bStr to listToStringUsingTextItemDelimiter(outList, lineDelimiter) of me
　　return bStr
end list2dToStringByUsingDelimiters

on listToStringUsingTextItemDelimiter(sourceList as list, textItemDelimiter)
　　set CocoaArray to NSArray’s arrayWithArray:sourceList
　　set CocoaString to CocoaArray’s componentsJoinedByString:textItemDelimiter
　　return (CocoaString as string)
end listToStringUsingTextItemDelimiter

–ユーザー環境にインストールされているすべてのフォントのPostScript名とグリフ数を返す
on getEveryFontPSNameANdGlyphsNum(aStr)
　　set aFontList to NSFontManager’s sharedFontManager()’s availableFonts()
　　set thePred to NSPredicate’s predicateWithFormat:"NOT SELF BEGINSWITH ’.’"
　　set aFontList to (aFontList’s filteredArrayUsingPredicate:thePred) as list
　　
　　set aList to {}
　　repeat with i in aFontList
　　　　set aName to contents of i
　　　　set aNum to countNumberOfGlyphsInFont(aName) of me
　　　　set dName to getDisplayedNameOfFont(aName) of me
　　　　
　　　　set fRes to retGlyphsInFont(aName, id of aStr) of me
　　　　if fRes = true then
　　　　　　set the end of aList to {fontName:aName, fontNum:aNum, dispName:dName}
　　　　end if
　　end repeat
　　
　　return aList
end getEveryFontPSNameANdGlyphsNum

–指定Postscript名称のフォントに定義されている文字数を数えて返す
on countNumberOfGlyphsInFont(fontName as string)
　　set aFont to NSFont’s fontWithName:fontName |size|:9.0
　　if aFont = missing value then return false
　　set aProp to aFont’s numberOfGlyphs()
　　return aProp as number
end countNumberOfGlyphsInFont

–フォントのPostScript NameからDisplayed Nameを取得
on getDisplayedNameOfFont(aName as string)
　　set aFont to NSFont’s fontWithName:aName |size|:9.0
　　set aDispName to (aFont’s displayName()) as string
　　return aDispName
end getDisplayedNameOfFont

–全角文字が存在するか
on chkMultiByteChar(checkString as string)
　　set aStr to NSString’s stringWithString:checkString
　　set aRes to aStr’s canBeConvertedToEncoding:(current application’s NSASCIIStringEncoding)
　　return (aRes as boolean)
end chkMultiByteChar

–指定名称のフォントに指定の文字コードが含まれているかチェック
on retGlyphsInFont(fontName as string, strCode as integer)
　　set aFont to NSFont’s fontWithName:fontName |size|:24.0
　　if aFont = missing value then return false
　　set aSet to aFont’s coveredCharacterSet()
　　set aRes to (aSet’s characterIsMember:strCode) as boolean
　　return aRes as list of string or string –as anything
end retGlyphsInFont

on selectAFont(aString)
　　set fRes to getEveryFontPSNameANdGlyphsNum(aString) of me
　　set theArray to NSArray’s arrayWithArray:fRes
　　set thePred to NSPredicate’s predicateWithFormat:"fontNum > 10000"
　　set bArray to ((theArray’s filteredArrayUsingPredicate:thePred)’s valueForKeyPath:"dispName") as list
　　set thisFont to choose from list bArray
　　return thisFont
end selectAFont

–Retina Display対応ルーチン
on getImageRatio()
　　set retinaF to detectRetinaDisplay() of me
　　if retinaF = true then
　　　　return 2.0 as real
　　else
　　　　return 1.0 as real
　　end if
end getImageRatio

on detectRetinaDisplay()
　　set dispList to current application’s NSScreen’s screens()
　　set retinaF to false
　　
　　repeat with i in dispList
　　　　set j to contents of i
　　　　set aDepth to j’s backingScaleFactor()
　　　　if aDepth > 1.0 then
　　　　　　set retinaF to true
　　　　end if
　　end repeat
　　
　　return retinaF
end detectRetinaDisplay

on makeNewDocument given parameter:aStr
　　tell application id "com.coteditor.CotEditor"
　　　　activate
　　　　set newDoc to make new document
　　　　tell newDoc
　　　　　　set contents to aStr
　　　　end tell
　　end tell
end makeNewDocument

★Click Here to Open This Script　

頭のいいタイマー割り込み実行

Posted on 3月 27, 2019 by Takaaki Naganoya

頭のいいタイマー割り込み（on idle）実行のAppleScriptを追求してみました。

AppleScript開闢（かいびゃく）以来、すでに20年以上の時間が経過しているので、on idleによるタイマー割り込み処理なんて、探せばサンプルが山のように出てくるものです。

AppleScript名：timer interrupt

property targetTime : "9:37:00"
property timerInterval : 30

on run
　　set timerInterval to 30
end run

on idle
　　set curTime to current date
　　set cString to time string of curTime
　　
　　if cString ≥ targetTime then
　　　　display dialog "It’s time to take off!" buttons {"OK"} default button 1 giving up after 30
　　　　quit
　　end if
　　
　　return timerInterval
end idle

★Click Here to Open This Script　

これが基礎的な内容で、このScriptをScript Editor上でアプリケーション（アプレット）形式で、「ハンドラの実行後に終了しない」をオンにして書き出すとタイマー実行アプレットが出来上がります（３分間クッキング）。

ただ、実行時刻のパラメータがプログラム内に直打ちなのが気になります。知能レベルが低い感じがします。

そこで、実行時刻のパラメータの外部供給ということを考え出すわけですが、

　（１）設定ファイルから読み込み
　（２）アプレット自身のコメント（File Comment）から読み込み
　（３）ファイル名自体から読み込み
　（４）コマンドラインから実行し、実行時にパラメータ（argv）を指定

などの方法を考えつきます（20世紀にすでにさんざんやった内容）。ただし、全角数字を半角に変換したり、ファイル名の場合には時刻セパレータの「:」がmacOS上ではファイル名に使えない文字（ディレクトリ・セパレータ）だったり、Finderが管理しているファイル名はUnicodeのNormalize方式が異なる（処理しやすいようにNormalizeし直さないとダメ）など割と頭の痛い問題がいろいろあります。

そこで利用したいのが、CocoaのDataFormatter。自然言語風に書かれた「１０時４１分」（全角数字入り）といった文字列から日時データをピックアップします。

そうして書いたのがこれ（↓）です。

ファイル名に書かれた時刻から実行時刻を拾ってタイマー実行します。けっこう頭がいい感じがします。

実際に、こうした処理の延長線上にTanzakuで行なっているファイル名から取得した文字列に対する形態素解析＆コマンドピックアップの処理があります。

AppleScript名：１０時４２分

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property targTime : missing value
property timerInterval : 1

on run
　　set timerInterval to 1
　　
　　–Get filename from this applet
　　set myPath to path to current application
　　tell application "System Events"
　　　　set myName to name of myPath
　　end tell
　　
　　–Validate filename as a natural language format date by using NSDataDetector
　　set dList to getDatesIn(myName) of me
　　repeat while dList = {}
　　　　set myName to text returned of (display dialog "There is no time elements in my filename. Input the target time　in x時xx分" default answer "午後5時45分")
　　　　set dList to getDatesIn(myName) of me
　　end repeat
　　
　　set targDate to first item of dList
　　set targTime to time string of targDate
　　display notification targTime
end run

on idle
　　set curTime to current date
　　set curTimeStr to time string of curTime
　　
　　if curTimeStr ≥ targTime then
　　　　activate
　　　　display dialog "It’s time to take off!" buttons {"OK"} default button 1 giving up after 30
　　　　quit
　　end if
　　
　　return timerInterval
end idle

on getDatesIn(aString)
　　set anNSString to current application’s NSString’s stringWithString:aString
　　set {theDetector, theError} to current application’s NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(reference)
　　set theMatches to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　set theResults to theMatches’s valueForKey:"date"
　　return theResults as list
end getDatesIn

★Click Here to Open This Script　

HTMLをplain textに変換（文字コード自動認識ライブラリ展開）

Posted on 3月 14, 2019 by Takaaki Naganoya

HTMLをプレーンテキストに変換するAppleScriptです。

本来は、文字コードの自動推測を行う部分はライブラリ化していますが、掲載用にライブラリをScript中に展開してみました。

コードの自動推測部分の処理は、昔のCotEditorのソースを読んで前半部分の「古くからある文字エンコーディングの勝ち抜け」処理を書き、後半部分のマイナー文字エンコーディングの多数決＆文字化け検出方式がオリジナル処理部分です。

本コード自動推測は、意味のある日本語のテキストを処理するように設計してあるので、寿司屋の湯呑みのように魚の名前の漢字が１文字で羅列されているようなテキストの文字コード自動判別でミスを起こす可能性があります（実際に魚の名前のテキストを作って読み込んでみましたが、とくに問題はありませんでした）。

ただ、最近はUTF-8だけでなんとかなりそうなので、そこまでエグいテキストに遭遇することもないでしょう。

AppleScript名：HTMLをplain textに変換（文字コード自動認識ライブラリ展開）

— Created 2017-09-08 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
–use jLib : script "japaneseTextEncodingDetector"

property NSString : a reference to current application’s NSString
property NSMutableArray : a reference to current application’s NSMutableArray
property NSAttributedString : a reference to current application’s NSAttributedString
property NSUnicodeStringEncoding : a reference to current application’s NSUnicodeStringEncoding

set aFile to choose file
set aRes to readJapanesTextFileWithGuessingEncoding(POSIX path of aFile) of me
if aRes = false then return ""

set aPlainText to HTMLDecode(aRes) of me

on HTMLDecode(HTMLString)
　　set theString to current application’s NSString’s stringWithString:HTMLString
　　set theData to theString’s dataUsingEncoding:(NSUnicodeStringEncoding)
　　set attStr to NSAttributedString’s alloc()’s initWithHTML:theData documentAttributes:(missing value)
　　return (attStr’s |string|()) as string
end HTMLDecode

–Read Japanese text with detecting its text encoding
on readJapanesTextFileWithGuessingEncoding(aPOSIXpath as string)
　　
　　–ISO2022JP check
　　set aNSData to current application’s NSData’s dataWithContentsOfFile:aPOSIXpath
　　set aDataLength to aNSData’s |length|()
　　if aDataLength > 1024 then set aDataLength to 1024
　　
　　–0x1B check
　　set anNSString to current application’s NSString’s stringWithString:(character id 27) — 0x1B
　　set theData to anNSString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set theRange to aNSData’s rangeOfData:theData options:0 range:(current application’s NSMakeRange(0, aDataLength))
　　
　　–found 0x1B in aNSData
　　if |length| of theRange = 1 and location of theRange < aDataLength then
　　　　set aStr to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSISO2022JPStringEncoding)) –21
　　　　if aStr is not equal to missing value then return (aStr as text) — ISO2022JP
　　end if
　　
　　–EUC
　　set resValue to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSJapaneseEUCStringEncoding))
　　if resValue is not equal to missing value then return (resValue as text)
　　
　　–UTF-8
　　set resValue to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSUTF8StringEncoding))
　　if resValue is not equal to missing value then return (resValue as text)
　　
　　–SHift JIS
　　set resValue to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSShiftJISStringEncoding))
　　if resValue is not equal to missing value then return (resValue as text)
　　
　　–多数決を取る
　　–UTF-16BE/LE/無印Unicodeは多数決を取る
　　set resValue1 to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSUTF16BigEndianStringEncoding)) as text
　　set sample1 to getTextSample(resValue1) of me
　　set lang1 to specifyLanguageOfText(sample1) of me
　　set para1 to length of (paragraphs of sample1)
　　set words1 to length of (words of sample1)
　　
　　–UTF-16LE　　
　　set resValue2 to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSUTF16LittleEndianStringEncoding)) as text
　　set sample2 to getTextSample(resValue2) of me
　　set lang2 to specifyLanguageOfText(sample2) of me
　　set para2 to length of (paragraphs of sample2)
　　set words2 to length of (words of sample2)
　　
　　–無印Unicode
　　set resValue3 to (current application’s NSString’s alloc()’s initWithData:aNSData encoding:(current application’s NSUnicodeStringEncoding)) as text
　　set sample3 to getTextSample(resValue3) of me
　　set lang3 to specifyLanguageOfText(sample3) of me
　　set para3 to length of (paragraphs of sample3)
　　set words3 to length of (words of sample3)
　　
　　–文字および文法的に見て「日本語」ならそれを返す
　　if lang1 = "ja" then return resValue1
　　if lang2 = "ja" then return resValue2
　　if lang3 = "ja" then return resValue2
　　
　　
　　–文字化けしたときには、日本語の「Word」として認識されづらく、Paragraphも少ない（１とか）なので条件で除外する
　　if para1 is not equal to 1 then
　　　　if (words1 ≤ words2) or (words1 ≤ words3) then
　　　　　　return resValue1
　　　　end if
　　end if
　　
　　if para2 is not equal to 1 then
　　　　if (words2 ≤ words1) or (words2 ≤ words3) then
　　　　　　return resValue2
　　　　end if
　　end if
　　
　　if para3 is not equal to 1 then
　　　　if (words3 ≤ words1) or (words3 ≤ words2) then
　　　　　　return resValue3
　　　　end if
　　end if
　　
　　return false –文字コード判定に失敗した
end readJapanesTextFileWithGuessingEncoding

on specifyLanguageOfText(aStr)
　　set aNSstring to current application’s NSString’s stringWithString:aStr
　　set tagSchemes to current application’s NSArray’s arrayWithObjects:(current application’s NSLinguisticTagSchemeLanguage)
　　set tagger to current application’s NSLinguisticTagger’s alloc()’s initWithTagSchemes:tagSchemes options:0
　　tagger’s setString:aNSstring
　　set aLanguage to tagger’s tagAtIndex:0 |scheme|:(current application’s NSLinguisticTagSchemeLanguage) tokenRange:(missing value) sentenceRange:(missing value)
　　return aLanguage as text
end specifyLanguageOfText

on getTextSample(aText)
　　set aLen to length of aText
　　if aLen < 1024 then
　　　　set bLen to aLen
　　else
　　　　set bLen to 1024
　　end if
　　return (text 1 thru bLen of aText)
end getTextSample

★Click Here to Open This Script　

アラートダイアログ上に複数のNSBoxを作成してMKMapViewを表示

Posted on 3月 11, 2019 by Takaaki Naganoya

指定されたIPアドレスの位置情報（geo location）を検索して、アラートダイアログ上に拡大レベルの異なる４つの地図を表示するAppleScriptです。

IP Goecodingのサービスはipinfo.ioを利用しています。ただ、この手のサービスは入れ替わりが激しいので、長期的に使い続けられることを期待できないと感じています（有償サービスは別）。

このズームレベルが異なる地図の同時表示Viewは、作成したときには「これは画期的！」「ものすごく使いやすい！」と、狂喜乱舞したものですが、他のユーザーに見せてデモしたら、

「実際には限定されたエリア内の位置データを見ることが多いので、World LevelとかCountry Levelのビューは無駄なことが多い」
「地球を侵略しに来た異星人には向いているが、地球人向けには冗長」

といった意見が多く、オクラ入りしていました。アラートダイアログでさまざまなデータを可視化する部品の整備計画時に倉庫から引っ張り出されてきたものです。

唯一、IPアドレスという「見ただけではどこの国のものだかわからない」（Class AのIPは別。17.のAppleとか）データを可視化するときにはバッチリ合っています。

macOS 10.12〜10.14で確認していますが、唯一、macOS 10.14.4上では初期状態でピンが表示されません。ピン自体は存在しているので、地図表示タイプを変更すると表示されるのですが、一体これはどうしたものか。仕様なのかバグなのかわかりません。

▲なぜか本Blogにロス市警からのアクセスが（汗）

▲macOS 10.12.6 Map

▲macOS 10.12.6 Satellite

▲macOS 10.12.6 Map + Satellite

▲macOS 10.13.6 Map

▲macOS 10.14.4 Map (Light Mode)

▲macOS 10.14.4 Map (Dark Mode)

AppleScript名：アラートダイアログ上に複数のNSBoxを作成してMKMapViewを表示

— Created 2019-03-11 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"
use framework "CoreLocation"

property NSAlert : a reference to current application’s NSAlert
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property MKMapView : a reference to current application’s MKMapView
property MKMapTypeHybrid : a reference to current application’s MKMapTypeHybrid
property MKPointAnnotation : a reference to current application’s MKPointAnnotation
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property MKMapTypeSatellite : a reference to current application’s MKMapTypeSatellite
property MKMapTypeStandard : a reference to current application’s MKMapTypeStandard
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property windisp : false
property selSeg : 0
property aMapViewList : {}

property segTitleList : {"Map", "Satellite", "Satellite + Map"}

property returnCode : 0

set aClip to the clipboard –このへんてきとう
set anIP to text returned of (display dialog "Input IP address to find its location" default answer aClip)

set windisp to false
set geoInfo to getGeoLocationByIPinfo(anIP) of me
if geoInfo = missing value then
　　error "Network Error"
end if

set aInfo to loc of geoInfo

set aPos to offset of "," in aInfo
set aLatitude to text 1 thru (aPos – 1) of aInfo
set aLongitude to text (aPos + 1) thru -1 of aInfo

set aWidth to 1000
set aHeight to 600

set aButtonMSG to "OK"
set aMapViewList to {}

set paramObj to {viewWidth:aWidth, viewHeight:aHeight, viewTitle:anIP, viewSubTitle:"IP-Geocoding Service by ipinfo.io", viewLat:aLatitude, viewLong:aLongitude}

my performSelectorOnMainThread:"dispMapViewinDifferentScales:" withObject:(paramObj) waitUntilDone:true

on dispMapViewinDifferentScales:paramObj
　　set aWidth to (viewWidth of paramObj) as real
　　set aHeight to (viewHeight of paramObj) as real
　　set aLat to (viewLat of paramObj) as real
　　set aLong to (viewLong of paramObj) as real
　　set aTitle to (viewTitle of paramObj) as string
　　set aSubTitle to (viewSubTitle of paramObj) as string
　　
　　set selSeg to 0
　　
　　–NSViewをつくる
　　set aView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　–各レベルのMapViewをBoxでつくる
　　set wList to {{3, "🌏World Level Map"}, {5, "🏰Country Level Map"}, {10, "🏢City Level Map"}, {17, "🏠Town Level Map"}}
　　set xPos to 0
　　repeat with i in wList
　　　　copy i to {aLevelNum, aBoxTitle}
　　　　
　　　　–Boxをつくる
　　　　set aBox to (current application’s NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, 40, aWidth * 0.25, aHeight – 70)))
　　　　(aBox’s setTitle:aBoxTitle)
　　　　
　　　　–MapView＋Pinをつくる
　　　　set aMapView to makeMKMapView(aWidth * 0.25, aHeight – 70, aLevelNum, aLat, aLong, aTitle) of me
　　　　
　　　　(aBox’s addSubview:aMapView)
　　　　(aView’s addSubview:aBox)
　　　　
　　　　set the end of aMapViewList to aMapView
　　　　set xPos to xPos + (aWidth * 0.25)
　　end repeat
　　
　　–Segmented Controlをつくる
　　set aSeg to makeSegmentedControl(segTitleList, aWidth, aHeight) of me
　　aView’s addSubview:aSeg
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aTitle
　　　　its setInformativeText:aSubTitle
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end dispMapViewinDifferentScales:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–MKMapViewをつくる
on makeMKMapView(aWidth, aHeight, aZoomLevel, aLat, aLong, aTitle)
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aMapView’s setMapType:(current application’s MKMapTypeStandard)
　　
　　aMapView’s setZoomEnabled:true
　　aMapView’s setScrollEnabled:true
　　aMapView’s setPitchEnabled:false
　　aMapView’s setRotateEnabled:false
　　aMapView’s setShowsCompass:true
　　aMapView’s setShowsZoomControls:true
　　aMapView’s setShowsScale:true
　　aMapView’s setShowsUserLocation:true
　　
　　set aLocation to current application’s CLLocationCoordinate2DMake(aLat, aLong)
　　aMapView’s setCenterCoordinate:aLocation zoomLevel:aZoomLevel animated:false
　　aMapView’s setDelegate:me
　　
　　–MapにPinを追加
　　set anAnnotation to current application’s MKPointAnnotation’s alloc()’s init()
　　anAnnotation’s setCoordinate:aLocation
　　anAnnotation’s setTitle:aTitle
　　aMapView’s addAnnotation:anAnnotation
　　
　　return aMapView
end makeMKMapView

–Make Segmented Control
on makeSegmentedControl(titleList, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(10, 5, 260, 30))
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControl

–Segmented Control’s clicked event handler
on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
　　set selSeg to (aSel + 1)
　　set mapList to {MKMapTypeStandard, MKMapTypeSatellite, MKMapTypeHybrid}
　　set curMap to contents of item selSeg of mapList
　　
　　repeat with i in aMapViewList
　　　　set aView to contents of i
　　　　(aView’s setMapType:(curMap))
　　end repeat
end clickedSeg:

–http://ipinfo.io/developers
on getGeoLocationByIPinfo(myIP)
　　set aURL to "http://ipinfo.io/" & myIP
　　set aRes to callRestGETAPIAndParseResults(aURL, 10) of me
　　return aRes as record
end getGeoLocationByIPinfo

on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set tmpData to (do shell script "curl -X GET ＼"" & reqURLStr & "＼"")
　　set jsonString to NSString’s stringWithString:tmpData
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　if aJsonDict = missing value then return false
　　return (aJsonDict as record)
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

アラートダイアログ上にWebViewを表示

Posted on 3月 5, 2019 by Takaaki Naganoya

アラートダイアログ上にWKWebViewを表示するAppleScriptです。

テストのためにYouTubeのムービーの自動再生URL（戦場の絆のリプレイムービー）をオープンしています。

▲Table ViewとWeb Viewを組み合わせて、所定の場所にYouTubeムービーの頭出しを行う試作品を作ってみたものの、JavaScript経由でWKWebViewをコントロールするのが難しくて頓挫

本来であれば、WkWebViewに対してJavaScript経由でさまざまな操作を行いたいところですが、オープン中のWebコンテンツに対して新たなJavaScriptのインスタンスを生成してセキュリティチェックを行なって、実際に実行を行うのが（自分には）少々難しく感じました。WkWebViewだとあまり凝った制御はできない印象です。Safariをコントロールするほうが自由度が高いところ。

WkWebViewを「自由にこづきまわして操作できる部品」として使うためには、素のままのWkWebViewではない何かを使ったほうがいいのかも？

AppleScript名：アラートダイアログ上にWebViewを表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/02
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property WKWebView : a reference to current application’s WKWebView
property NSScrollView : a reference to current application’s NSScrollView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered
property WKUserContentController : a reference to current application’s WKUserContentController
property NSMomentaryLightButton : a reference to current application’s NSMomentaryLightButton
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property theResult : 0
property returnCode : 0
property theDataSource : {}

set aURL to "https://www.youtube.com/embed/GP_tVXTYdmY?autoplay=1&hd=1"
set paramObj to {myMessage:"Browse a Replay", mySubMessage:"Browse Senjo-No-Kizuna Replay Movie", targURL:aURL}
my performSelectorOnMainThread:"browseWebContents:" withObject:(paramObj) waitUntilDone:true

on browseWebContents:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set tmpURL to (targURL of paramObj)
　　
　　set aWidth to 600
　　set aHeight to 450
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定URLのJavaScriptをFetch
　　set jsSource to my fetchJSSourceString(tmpURL)
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 100)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s URLWithString:tmpURL
　　set aReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:aReq –Webコンテンツのローディング
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aWebView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　if (my returnCode as number) = 1001 then error number -128
end browseWebContents:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

on fetchJSSourceString(aURL)
　　set jsURL to |NSURL|’s URLWithString:aURL
　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　return jsSourceString
end fetchJSSourceString

★Click Here to Open This Script　

アラートダイアログ上に縦棒グラフを表示

Posted on 3月 4, 2019 by Takaaki Naganoya

アラートダイアログ上に縦棒グラフを表示するAppleScriptです。

グラフを作成するのであれば、NumbersやKeynoteなどを使ったほうがいいですが、簡単にデータの傾向だけダイアログ上で見せたいような場合のために作成した部品です。

NSImageViewの表示実験がしたかっただけなので、別に他の言語処理系で作成したグラフ画像を読み込んでNSImageに読み込んでからNSIMageViewで表示するぐらいの使い方でもぜんぜんOKでしょう。

WebViewを表示してインタラクティブなグラフ（マウスカーソルに反応してアニメーション表示を行うとか）を表示するといった使い方もよさそうです（アプリケーション化しないとダメかも）。

macOS 10.14上のDark Modeについては、実行環境によって対応度が異なります。

▲macOS 10.14上のDark Modeで実行したところ。左側からスクリプトエディタ、AppleScriptアプレット、スクリプトメニュー

▲macOS 10.14上のDark Modeで実行したところ。左側からScript Debugger、Script DebuggerからSD拡張アプレットで書き出したもの

グラフの描画については、色指定をblackColor()とかgrayColor()などと指定せずに、Dark Mode時に制御されるUI色で指定しておく必要があることでしょう。

AppleScript名：アラートダイアログ上に縦棒グラフを表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/04
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSFont : a reference to current application’s NSFont
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSScreen : a reference to current application’s NSScreen
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSImageView : a reference to current application’s NSImageView
property NSMutableArray : a reference to current application’s NSMutableArray
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
property NSImageScaleProportionallyUpOrDown : a reference to current application’s NSImageScaleProportionallyUpOrDown

property returnCode : 0

set plotData to {20, 30, 100, 80, 150, 90}
set paramObj to {myMessage:"This is a graph", mySubMessage:"Browse bar graph", aPlotData:plotData}
my performSelectorOnMainThread:"displayBarGraph:" withObject:(paramObj) waitUntilDone:true

on displayBarGraph:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aPlotData of paramObj) as list
　　
　　— make NSIMageView with graph image
　　set anImage to makeGraphImage(aTList, 300, 200) of me
　　set anImageView to NSImageView’s alloc()’s initWithFrame:{origin:{x:0.0, y:0.0}, |size|:{width:300.0, height:200.0}}
　　anImageView’s setImageScaling:(NSImageScaleProportionallyUpOrDown)
　　anImageView’s setEditable:false
　　anImageView’s setImage:anImage
　　anImageView’s display()
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:anImageView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end displayBarGraph:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeGraphImage(plotData, aWidth, aHeight)
　　set innerGapL to 30
　　set innerGapU to 10
　　set innerGapR to 20
　　set innerGapD to 20
　　set barGap to 10
　　
　　–パラメータから下地になる画像を作成する
　　set aSize to current application’s NSMakeSize(aWidth, aHeight)
　　set anImage to NSImage’s alloc()’s initWithSize:aSize
　　
　　–各種パラメータの計算
　　–copy plotArea to {plotWidth, plotHeight}
　　set itemNum to count every item of plotData
　　set barThickness to (aWidth – (itemNum * barGap * 2)) div itemNum
　　
　　–プロットデータの最大値
　　set anArray to NSArray’s arrayWithArray:plotData
　　set aYmax to (anArray’s valueForKeyPath:"@max.self")’s intValue()
　　set aMaxYVal to aHeight – innerGapU – innerGapD
　　set aYPlotArea to aHeight – innerGapU – innerGapD – 20
　　set aYUnit to aYPlotArea / aYmax
　　
　　–数値データをもとに描画データを組み立てる
　　set drawList to {}
　　
　　set startX to innerGapL
　　copy startX to origX
　　
　　repeat with i in plotData
　　　　set the end of drawList to current application’s NSMakeRect(startX, innerGapD, barThickness, innerGapD + (i * aYUnit))
　　　　set startX to startX + barThickness + barGap
　　end repeat
　　
　　–グラフ塗りつぶし処理呼び出し
　　set fillColor to (NSColor’s colorWithCalibratedRed:0.1 green:0.1 blue:0.1 alpha:0.3)
　　set resImage to drawImageWithColorFill(anImage, drawList, fillColor) of me
　　
　　–数値データ（文字）をグラフィックに記入
　　set fillColor2 to NSColor’s blackColor()
　　set resImage to drawImageWithString(resImage, drawList, fillColor2, plotData, "Eurostile Bold", 20.0) of me
　　
　　–補助線を引く
　　set fillColor3 to (NSColor’s colorWithCalibratedRed:0.0 green:0.0 blue:0.0 alpha:0.8)
　　set aVertical to current application’s NSMakeRect(origX, innerGapD, aWidth – innerGapL – innerGapR, 1)
　　set aHorizontal to current application’s NSMakeRect(origX, innerGapD, 1, aHeight – innerGapU – innerGapD)
　　set draw2List to {aVertical, aHorizontal}
　　set resImage to drawImageWithColorFill(resImage, draw2List, fillColor3) of me
　　
　　return resImage
end makeGraphImage

–NSImageに対して文字を描画する
on drawImageWithString(anImage, drawList, fillColor, dataList, aPSFontName, aFontSize)
　　set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
　　–>　　2.0 (Retina) / 1.0 (Non Retina)
　　
　　set aDict to (NSDictionary’s dictionaryWithObjects:{NSFont’s fontWithName:aPSFontName |size|:aFontSize, fillColor} forKeys:{NSFontAttributeName, NSForegroundColorAttributeName})
　　
　　anImage’s lockFocus() –描画開始
　　
　　set aLen to length of drawList
　　repeat with i from 1 to aLen
　　　　set i1 to contents of item i of drawList
　　　　
　　　　set v2 to system attribute "sys2"
　　　　if v2 ≤ 12 then
　　　　　　–To macOS 10.12.x
　　　　　　set origX to (x of origin of i1) / retinaF
　　　　　　set origY to (y of origin of i1) / retinaF
　　　　　　set sizeX to (width of |size| of i1) / retinaF
　　　　　　set sizeY to (height of |size| of i1) / retinaF
　　　　　　set theRect to {{x:origX, y:origY}, {width:sizeX, height:sizeY}}
　　　　else
　　　　　　–macOS 10.13 or later
　　　　　　set origX to (item 1 of item 1 of i1) / retinaF
　　　　　　set origY to (item 2 of item 1 of i1) / retinaF
　　　　　　set sizeX to (item 1 of item 2 of i1) / retinaF
　　　　　　set sizeY to (item 2 of item 2 of i1) / retinaF
　　　　　　set theRect to {{origX, origY}, {sizeX, sizeY}}
　　　　end if
　　　　
　　　　set aString to (current application’s NSString’s stringWithString:((contents of item i of dataList) as string))
　　　　(aString’s drawAtPoint:(current application’s NSMakePoint(origX + (sizeX / 2), sizeY)) withAttributes:aDict)
　　end repeat
　　
　　anImage’s unlockFocus() –描画ここまで
　　
　　return anImage –returns NSImage
end drawImageWithString

–NSImageに対して矩形を塗りつぶす
on drawImageWithColorFill(anImage, drawList, fillColor)
　　set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
　　–>　　2.0 (Retina) / 1.0 (Non Retina)
　　
　　anImage’s lockFocus() –描画開始
　　
　　repeat with i in drawList
　　　　set v2 to system attribute "sys2"
　　　　if v2 ≤ 12 then
　　　　　　–To macOS 10.12.x
　　　　　　set origX to (x of origin of i) / retinaF
　　　　　　set origY to (y of origin of i) / retinaF
　　　　　　set sizeX to (width of |size| of i) / retinaF
　　　　　　set sizeY to (height of |size| of i) / retinaF
　　　　　　set theRect to {{x:origX, y:origY}, {width:sizeX, height:sizeY}}
　　　　else
　　　　　　–macOS 10.13 or later
　　　　　　set origX to (item 1 of item 1 of i) / retinaF
　　　　　　set origY to (item 2 of item 1 of i) / retinaF
　　　　　　set sizeX to (item 1 of item 2 of i) / retinaF
　　　　　　set sizeY to (item 2 of item 2 of i) / retinaF
　　　　　　set theRect to {{origX, origY}, {sizeX, sizeY}}
　　　　end if
　　　　
　　　　set theNSBezierPath to NSBezierPath’s bezierPath
　　　　(theNSBezierPath’s appendBezierPathWithRect:theRect)
　　　　
　　　　fillColor’s |set|() –色設定
　　　　theNSBezierPath’s fill() –ぬりつぶし
　　end repeat
　　
　　anImage’s unlockFocus() –描画ここまで
　　
　　return anImage –returns NSImage
end drawImageWithColorFill

★Click Here to Open This Script　

「戦場の絆」の日本国内の設置店舗数をカウント

Posted on 3月 3, 2019 by Takaaki Naganoya

アーケードゲーム「戦場の絆」が設置されている日本国内のゲームセンターの件数をカウントするAppleScriptです。

指定ページを取得し、本文内容をプレーンテキスト化して正規表現でデータ抽出して加算を行うという処理内容です。

部品がありきたりなので、新規作成部分はほとんどありません（メイン部分だけ）。

AppleScript名：戦場の絆の日本国内の設置店舗数をカウント.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/03
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSAttributedString : a reference to current application’s NSAttributedString
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSUnicodeStringEncoding : a reference to current application’s NSUnicodeStringEncoding

set aTotal to 0

–「戦場の絆」公式ページに掲載されている店舗一覧の都道府県別コード
set areaList to {"JP-01", "JP-02", "JP-03", "JP-04", "JP-05", "JP-06", "JP-07", "JP-08", "JP-09", "JP-10", "JP-11", "JP-12", "JP-13", "JP-14", "JP-15", "JP-16", "JP-17", "JP-18", "JP-19", "JP-20", "JP-21", "JP-22", "JP-23", "JP-24", "JP-25", "JP-26", "JP-27", "JP-28", "JP-29", "JP-30", "JP-31", "JP-32", "JP-33", "JP-34", "JP-35", "JP-36", "JP-37", "JP-38", "JP-39", "JP-40", "JP-41", "JP-42", "JP-43", "JP-44", "JP-45", "JP-46", "JP-47"}

–「戦場の絆」公式ページに掲載されている店舗一覧のBase URL
set baseURL to "https://gundam-kizuna.jp/locations/list"

–都道府県コードでループ
repeat with i in areaList
　　–店舗一覧の都道府県別ページをダウンロード
　　set j to contents of i
　　set aRec to {area:j}
　　set aRes to retURLwithParams(baseURL, aRec) of me
　　set shellText to "curl -s " & aRes
　　set htmlRes to (do shell script shellText)
　　set aPlainText to (HTMLDecode(htmlRes) of me)
　　
　　–店舗件数が入っている箇所を抽出して加算
　　set aList to paragraphs of aPlainText
　　set anArray to (NSArray’s arrayWithArray:aList)
　　set aPred to (NSPredicate’s predicateWithFormat:"SELF MATCHES ’[0-9]{1,3}件の店舗が見つかりました。’")
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　
　　if bRes is not equal to {} then
　　　　set a to repChar(contents of first item of bRes, "件の店舗が見つかりました。", "") of me
　　　　try
　　　　　　set aNum to a as integer
　　　　　　set aTotal to aTotal + aNum
　　　　on error
　　　　　　log {"Error in ", j}
　　　　end try
　　end if
end repeat

return aTotal
–> 622 (2019/3/3)

(*
set countryList to {"HKG", "TWN"}–香港と台湾の店舗のコード
set baseURL2 to "https://gundam-kizuna.jp/locations/list"
*)

–パラメータつきURLを作成
on retURLwithParams(aBaseURL as string, aRec as record)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　set bLen to length of aValList
　　if aLen is not equal to bLen then return false
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to (contents of item i of aKeyList) as string
　　　　set aVal to (contents of item i of aValList) as string
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

–テキストをHTMLとして解釈しプレーンテキスト化
on HTMLDecode(HTMLString)
　　set theString to NSString’s stringWithString:HTMLString
　　set theData to theString’s dataUsingEncoding:(current application’s NSUnicodeStringEncoding)
　　set attStr to NSAttributedString’s alloc()’s initWithHTML:theData documentAttributes:(missing value)
　　set aStr to attStr’s |string|()
　　return aStr as string
end HTMLDecode

–文字置換
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

★Click Here to Open This Script　

指定ファイルサイズのJPEGに変換（圧縮率可変）_1K=1024で計算

Posted on 2月 11, 2019 by Takaaki Naganoya

Finder上で選択中の画像ファイルを指定ファイルサイズを下回るよう圧縮率を調整してJPEGに変換するAppleScriptです。

指定画像を指定のファイルサイズ（1K=1024で計算）以内になるよう、非圧縮の状態から段階的に圧縮率を高くして仕上がりファイルサイズを下回るかどうか演算を行います。ファイルに書き込まずに仕上がりサイズの計算を行うところが新機軸です。

macOS標準搭載のスクリプトメニューから呼び出して使うことを想定しています。実行すると、ダイアログ表示して指定ファイルサイズをKB単位で数値入力する必要があります。

巨大な画像ファイルを処理してしまった場合への対処として、最初に最高圧縮率で圧縮してみて、指定ファイルサイズ以内になるかどうかを計算します。

最初は圧縮率100％から25％まで1％きざみで仕上がり画像ファイルサイズを計算してみたのですが、数十Mバイトの巨大な画像を処理させたら、途中でマウスカーソルが反応しないほどOSが無反応になったので（暴走状態？）、それを避けるために、このような処理を行なってみました。

JPEGにファイル変換した画像はデスクトップに

UUID_JPEG画質.jpg

の形式で出力されます。JPEG画質は1.0から0.01までの数値です。

AppleScript名：指定ファイルサイズのJPEGに変換（圧縮率可変）_1K=1024で計算

— Created 2014-02-21 Shane Stanley
— Modified 2019-02-11 Takaaki Naganoya
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property compressList : {100, 99, 98, 97, 96, 95, 90, 85, 80, 75, 70, 65, 60, 55, 50, 40, 30, 20, 25} –大→小　へと並んでいる必要がある
property kbBase : 1024

tell application "Finder"
　　set inFiles to selection as alias list
end tell

–指定のAlias listのうち画像ファイルのみ抽出
set filRes1 to filterAliasListByUTI(inFiles, "public.image") of me
if filRes1 = {} then return

–ターゲットサイズを指定
set aMessage to "Input Target size in KB ( " & (kbBase as string) & " based )"
set aRes to text returned of (display dialog aMessage default answer "300" buttons {"OK"} default button 1)
if aRes = false or aRes = "" then return
set targLimit to (aRes as number) * kbBase

–選択中のファイルのうちの１つから親フォルダを求め、出力先ファイルパスを組み立てる
set outPathTarg to (contents of first item of filRes1)
set pathString to NSString’s stringWithString:outPathTarg
set newPath to (pathString’s stringByDeletingLastPathComponent()) as string

–Main Loop
repeat with i in filRes1
　　set aNSImage to (NSImage’s alloc()’s initWithContentsOfFile:(i))
　　
　　–巨大すぎる画像のリサイズ時への保険で、最小サイズで投機的に圧縮して結果を確認する
　　set minSize to calcSavedJPEGSizeFromNSIMage(aNSImage, (last item of compressList) / 100) of me
　　
　　if minSize < targLimit then
　　　　–Simulate Suitable JPEG Compression Ratio to target file size
　　　　repeat with ii in compressList
　　　　　　set jj to ii / 100
　　　　　　set fileSize to calcSavedJPEGSizeFromNSIMage(aNSImage, jj) of me
　　　　　　
　　　　　　if fileSize < targLimit then
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　else
　　　　set jj to 0.01 –エラー時にはやけくそで1%まで圧縮指定
　　end if
　　
　　set outPOSIXpath to (newPath & "/" & (NSUUID’s UUID()’s UUIDString()) as string) & "_" & (jj as string)
　　set savePath to outPOSIXpath & ".jpg"
　　
　　saveNSImageAtPathAsJPG(aNSImage, savePath, jj) of me
end repeat

–Alias listから指定UTIに含まれるものをPOSIX pathのリストで返す
on filterAliasListByUTI(aList, targUTI)
　　set newList to {}
　　repeat with i in aList
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, targUTI)
　　　　if utiRes is not equal to {} then
　　　　　　set the end of newList to j
　　　　end if
　　end repeat
　　return newList
end filterAliasListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

–NSImageを指定パスにJPEG形式で保存、qulityNumは0.0〜1.0。1.0は無圧縮
on saveNSImageAtPathAsJPG(anImage, outPath, qulityNum as real)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　set myNewImageData to (aRawimg’s representationUsingType:(NSJPEGFileType) |properties|:{NSImageCompressionFactor:qulityNum})
　　
　　set aLength to (myNewImageData’s |length|()) as number
　　
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –true/false
end saveNSImageAtPathAsJPG

–NSImageをJPEG形式で保存したときのファイルサイズを計算
on calcSavedJPEGSizeFromNSIMage(anImage, qulityNum as real)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　set myNewImageData to (aRawimg’s representationUsingType:(NSJPEGFileType) |properties|:{NSImageCompressionFactor:qulityNum})
　　set aLength to (myNewImageData’s |length|()) as number
　　return aLength
end calcSavedJPEGSizeFromNSIMage

★Click Here to Open This Script　

クリップボード中の書式つきテキストのフォントサイズを取得する

Posted on 2月 8, 2019 by Takaaki Naganoya

クリップボードに入っているデータを書式付きテキストとして評価して取得し、そのうち最大のフォントサイズを取得するAppleScriptです。

クリップボードに入っているデータをプレーンテキストとして取得して処理することはよくやっていたのですが、書式付きテキストとして処理することはあまりやっていなかったので、試してみたものです。

AppleScript名：クリップボード中の書式つきテキストのフォントサイズを取得する.scptd

–Created 2015-08-03 by Shane Stanley
–Modified 2019-02-06 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit" — for NSPasteboard

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

–クリップボードの内容をNSAttributedStringに
set anAttr to my getClipboardASStyledText()
if anAttr = missing value then return 0

set maxSize to getAttributeStringFontSize(anAttr) of me
–> 13.0

— クリップボードの内容をNSAttributedStringとして取り出して返す
on getClipboardASStyledText()
　　try
　　　　set theNSPasteboard to current application’s NSPasteboard’s generalPasteboard()
　　　　set theAttributedStringNSArray to theNSPasteboard’s readObjectsForClasses:({current application’s NSAttributedString}) options:(missing value)
　　　　set theNSAttributedString to theAttributedStringNSArray’s objectAtIndex:0
　　　　return theNSAttributedString
　　on error
　　　　return missing value
　　end try
end getClipboardASStyledText

on getAttributeStringFontSize(theStyledText)
　　set maxSize to 0
　　set thePureString to theStyledText’s |string|() –pure string from theStyledText
　　set theLength to theStyledText’s |length|()
　　
　　set startIndex to 0
　　
　　repeat until (startIndex = theLength)
　　　　set {theAtts, theRange} to theStyledText’s attributesAtIndex:startIndex longestEffectiveRange:(reference) inRange:{startIndex, theLength – startIndex}
　　　　
　　　　–Font
　　　　set aFont to (theAtts’s valueForKeyPath:"NSFont")
　　　　if aFont is not equal to missing value then
　　　　　　set aDFontName to aFont’s displayName()
　　　　　　set aDFontSize to (aFont’s pointSize()) as real
　　　　end if
　　　　
　　　　if maxSize < aDFontSize then
　　　　　　set maxSize to aDFontSize
　　　　end if
　　　　set startIndex to current application’s NSMaxRange(theRange)
　　end repeat
　　
　　return maxSize
end getAttributeStringFontSize

★Click Here to Open This Script　

Finder上で選択中のAppleScriptの行数をカウントする

Posted on 2月 8, 2019 by Takaaki Naganoya

Finder上で選択中のAppleScript書類の行数や種別を取得して表UIで表示するAppleScriptです。

Myriad Tables Libを用いて結果を表UIで表示しています。

当初はAppleScript書類からソースを取得するのに/usr/bin/osadecompileコマンドを使っていたのですが、OSAKit経由で処理したほうが高速な印象があります。

–> Download Executable archive for macOS 10.14 (include Myriad Tables Lib)

macOS 10.14上で動作させるためには、Script Debugger上で本Scriptをオープンするか、本Scriptをバンドル形式で保存し、バンドル内（/Contents/Resources/Script Libraries フォルダ）にMyriad Tables Libを入れ、AppleScriptアプレットとして書き出す必要があります。

また、初回実行時には「セキュリティ」の承認ダイアログが表示されるため、これをOKする必要があります。AppleScriptアプレットはFinder上でアイコンをダブルクリックすると「Finder上で選択中のアイテム」を拾えないため（その瞬間、Finder上での選択アイテムはアプレット自身になってしまうため）、DockやmacOS標準装備のスクリプトメニューに登録して起動する必要があります。

AppleScript名：Finder上で選択中のAppleScriptの行数をカウントする v2.scpt

— Created 2019-02-04 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "OSAKit"
use script "Myriad Tables Lib" version "1.0.8" –https://www.macosxautomation.com/applescript/apps/Script_Libs.html#MyriadTablesLib

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property OSAScript : a reference to current application’s OSAScript
property NSPredicate : a reference to current application’s NSPredicate
property NSURLIsPackageKey : a reference to current application’s NSURLIsPackageKey
property NSURLIsDirectoryKey : a reference to current application’s NSURLIsDirectoryKey
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

–Finder上で選択中のファイルのうちAppleScript書類のみ抽出
tell application "Finder"
　　set inFiles to selection as alias list
　　if inFiles = {} then return
end tell
set filRes1 to filterAliasListByUTIList(inFiles, {"com.apple.applescript.script", "com.apple.applescript.script-bundle"}) of me
if filRes1 = {} then return

–AppleScript書類の種別判定および行数カウント
set outList to {}
repeat with i in filRes1
　　set aName to (NSString’s stringWithString:i)’s lastPathComponent() as string
　　set sInfo to detectScriptIsPureASorASOC(i) of me
　　set sText to scriptSource of getASsourceFor(i) of me
　　set sNum to count every paragraph of sText
　　set sUTI to retUTIfromPath(i) of me
　　if sUTI = "com.apple.applescript.script" then
　　　　set sKind to "Script"
　　else if sUTI = "com.apple.applescript.script-bundle" then
　　　　set sKind to "Script Bundle"
　　else
　　　　set sKind to "Other"
　　end if
　　
　　set the end of outList to {aName, sInfo, sKind, sNum}
end repeat

–結果を表UIで表示する
tell script "Myriad Tables Lib"
　　set aDispBounds to my makeInitialBounds:1200 withHeight:500
　　set theTable to make new table with data outList column headings {"script name", "ASOC", "Script Kind", "lines"} with title "AppleScript Line Count" with prompt "Your Selected Scripts" with row numbering and empty selection allowed –and can add and delete
　　modify table theTable initial position aDispBounds column widths pattern {1, 2, 3, 4} with hidden cancel button
　　modify columns in table theTable user date format {user format full, user format full} entry alignment align left
　　(display table theTable)
end tell

–Alias listから指定UTI Listに含まれるものをPOSIX pathのリストで返す
on filterAliasListByUTIList(aList as list, targUTIList as list)
　　set outList to {}
　　repeat with i in targUTIList
　　　　set j to contents of i
　　　　set aRes to filterAliasListByUTI(aList, j) of me
　　　　if aRes is not equal to {} then
　　　　　　set outList to outList & aRes
　　　　end if
　　end repeat
　　return outList
end filterAliasListByUTIList

–Alias listから指定UTIに含まれるものをPOSIX pathのリストで返す
on filterAliasListByUTI(aList as list, targUTI)
　　set newList to {}
　　repeat with i in aList
　　　　set j to POSIX path of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, targUTI)
　　　　if utiRes is not equal to {} then
　　　　　　set the end of newList to j
　　　　end if
　　end repeat
　　return newList
end filterAliasListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(specifier) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

on makeInitialBounds:(aTWidth as integer) withHeight:(aTHeight as integer)
　　set aDispBounds to current application’s NSScreen’s mainScreen()’s frame()
　　if class of item 1 of aDispBounds = record then
　　　　–macOS 10.10/10.11/10.12
　　　　set aWidth to (width of |size| of aDispBounds)
　　　　set aHeight to (height of |size| of aDispBounds)
　　else
　　　　–macOS 10.13 or later?
　　　　set aWidth to (item 1 of item 2 of aDispBounds)
　　　　set aHeight to (item 2 of item 2 of aDispBounds)
　　end if
　　
　　set xPos to (aWidth div 2) – (aTWidth div 2)
　　set yPos to (aHeight div 2) – (aTHeight div 2)
　　
　　return {xPos, yPos, aTWidth, aTHeight}
end makeInitialBounds:withHeight:

–指定AppleScriptファイルがPure ASかASOCかを判定して返す
on detectScriptIsPureASorASOC(aFile)
　　set sRes to getASsourceFor(aFile) of me
　　set sName to scriptKind of sRes –Name
　　set sText to scriptSource of sRes –Source
　　if sText = "" or sText = missing value then return missing value
　　
　　if sName = "AppleScript" then
　　　　if sText contains "use framework ＼"Foundation＼"" then
　　　　　　return true –ASOC
　　　　else
　　　　　　return false –Pure AppleScript
　　　　end if
　　else
　　　　–JXAなど他のOSA言語の場合
　　　　return sName
　　end if
end detectScriptIsPureASorASOC

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
on getASsourceFor(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:(aPOSIXPath)
　　set theScript to current application’s OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　set scriptName to theScript’s |language|()’s |name|() as string
　　set theSource to theScript’s source() as text
　　return {scriptKind:scriptName, scriptSource:theSource}
end getASsourceFor

★Click Here to Open This Script　

指定色で塗りつぶし角丸画像を作成

Posted on 2月 5, 2019 by Takaaki Naganoya

指定の矩形に対して、指定色で、指定半径の角丸で、指定ファイルパスに角丸ぬりつぶしPNG画像を作成するAppleScriptです。

色選択のポップアップメニュー中に入れるNSImage作成用に作ったものですが、ねんのために（動作確認のために）ファイル出力させてみました。

AppleScript名：指定色で塗りつぶし角丸画像を作成.scptd

—
–　　Created by: Piyomaru Software
–　　Created on: 2019/01/29
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "AppKit"

set tCol to choose color
copy tCol to {rVal, gVal, bVal}

set aRadius to 12
set aNSColor to makeNSColorFromRGBAval(rVal, gVal, bVal, 65535, 65535) of me
set aNSImage to makeRoundedNSImageWithFilledWithColor(100, 100, aNSColor, aRadius) of me

set aPath to NSString’s stringWithString:(POSIX path of (choose file name))
set bPath to aPath’s stringByAppendingPathExtension:"png"
set aRes to saveNSImageAtPathAsPNG(aNSImage, bPath) of me

–指定サイズのNSImageを作成し、指定色で塗ってNSImageで返す、anRadiusの半径の角丸で
on makeRoundedNSImageWithFilledWithColor(aWidth, aHeight, fillColor, anRadius as real)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　anImage’s lockFocus()
　　—
　　set theRect to {{x:0, y:0}, {height:aHeight, width:aWidth}}
　　set theNSBezierPath to NSBezierPath’s bezierPathWithRoundedRect:theRect xRadius:anRadius yRadius:anRadius
　　—
　　fillColor’s |set|() –色設定
　　theNSBezierPath’s fill() –ぬりつぶし
　　—
　　anImage’s unlockFocus()
　　
　　return anImage
end makeRoundedNSImageWithFilledWithColor

–aMaxValを最大値とする数値でNSColorを作成して返す
on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

Finder上で選択中の画像のうち、最小のものに合わせて各画像の右上を基準にサイズ統一

Posted on 1月 26, 2019 by Takaaki Naganoya

Finderで選択中の画像のうち、最小のものに合わせて各画像の右上を原点にサイズを統一するAppleScriptです。

Finderで選択中のファイルから画像のみ抽出し、そのうちサイズが最小のものに合わせて他の画像をトリミングし、変更したものをデスクトップフォルダに出力します。

以前に画像の左上を基準に自動トリミングするバージョンのScriptを作成しましたが、あれはメニュー操作の説明用スクリーンショットの大きさを統一するためのもの。右上基準の本バージョンは、Driveのリネームやステータスバーの操作内容を説明するためのスクリーンショットの大きさ統一のために用意したものです。

▲大きさを揃える画像をFinder上で選択

▲処理後の画像。大きさが最小の画像に合わせてそろっている。切り抜き基準は右上

スクリーンショット画像を複数撮った場合に、厳密に同じサイズに固定することは（各種スクリーンショット作成ユーティリティを使わないと）行いづらいところです。

そこで、最小の画像を計算で求めて、それに合わせて自動トリミングするようにしてみました。Cocoaの機能を用いて画像処理しているため、Photoshopは必要ありません。

最小の画像を求めるのに、幅＋高さの値でソートして最小のものを求めています（widthとheightによる2 key sortではなく1 Keyで済ませたかったので）。

AppleScript名：Finder上で選択中の画像のうち、最小のものに合わせて各画像の右上を基準にサイズ統一

— Created 2018-01-26 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "QuartzCore"

property |NSURL| : a reference to current application’s |NSURL|
property NSUUID : a reference to current application’s NSUUID
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSScreen : a reference to current application’s NSScreen
property NSZeroRect : a reference to current application’s NSZeroRect
property NSPredicate : a reference to current application’s NSPredicate
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSMutableArray : a reference to current application’s NSMutableArray
property NSCompositeCopy : a reference to current application’s NSCompositeCopy
property NSGraphicsContext : a reference to current application’s NSGraphicsContext
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey
property NSCalibratedRGBColorSpace : a reference to current application’s NSCalibratedRGBColorSpace

tell application "Finder"
　　set selList to selection as alias list
end tell

–指定のAlias listのうち画像のみ抽出
set filRes1 to filterAliasListByUTI(selList, "public.image") of me
if filRes1 = {} then
　　tell current application
　　　　–Error Message (No Selection)
　　　　display dialog "Finder上で選択されているファイルはありません。" buttons {"OK"} default button 1 with icon 1 with title "画像リサイズ処理できません"
　　end tell
　　return
end if

–各種情報を入れたArrayを作成
set anArray to NSMutableArray’s new()
repeat with i in selList
　　set imgPath to (POSIX path of i)
　　
　　set aImage to makeNSImageFromFile(i) of me
　　set sizeInfo to |size|() of aImage
　　set sizeInfo to sizeInfo & {aImg:aImage, total:(width of sizeInfo) + (height of sizeInfo), myPath:imgPath}
　　(anArray’s addObject:sizeInfo)
end repeat

–最小のサイズの画像の算出
set aRes to anArray’s valueForKeyPath:("@min.total")
set bRes to first item of (filterRecListByLabel(anArray, "total == " & aRes as string) of me) –最小サイズの画像

–最小サイズ画像のwidthとheight
set minWidth to bRes’s width
set minHeight to bRes’s height

–環境情報の取得
set aPath to POSIX path of (path to desktop)
set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
–>　　2.0 (Retina) / 1.0 (Non Retina)

set cRes to filterRecListByLabel(anArray, "total != " & aRes as string) of me –最小サイズ以外の画像

repeat with i in cRes
　　set j to contents of i
　　set anImage to aImg of j
　　set fRes to myPath of j
　　
　　set tmpSize to |size|() of anImage
　　set tmpWidth to (width of tmpSize)
　　set tmpHeight to (height of tmpSize)
　　
　　set cropedImage to (my cropNSImageBy:{(tmpWidth – minWidth), 0, minWidth, minHeight} fromImage:anImage)
　　
　　–Retina環境対策
　　if retinaF > 1.0 then
　　　　set cropedImage to (my resizedImage:cropedImage toScale:(1.0))
　　end if
　　
　　–ファイル書き込み
　　set fRes to retUUIDfilePathFromDir(aPath, "png") of me
　　set sRes to saveNSImageAtPathAsPNG(cropedImage, fRes) of me
end repeat

–リストに入れたレコードを、指定の属性ラベルの値で抽出
on filterRecListByLabel(aRecList as list, aPredicate as string)
　　–ListからNSArrayへの型変換
　　set aArray to NSArray’s arrayWithArray:aRecList
　　
　　–抽出
　　set aPredicate to NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aArray’s filteredArrayUsingPredicate:aPredicate
　　
　　–NSArrayからListに型変換して返す
　　set bList to filteredArray as list
　　return bList
end filterRecListByLabel

on cropNSImageTo:{x1, y1, x2, y2} fromImage:theImage
　　set newWidth to x2 – x1
　　set newHeight to y2 – y1
　　set theSize to (theImage’s |size|()) as record
　　set oldHeight to height of theSize
　　
　　— transpose y value for Cocoa coordintates
　　set y1 to oldHeight – newHeight – y1
　　set newRect to {{x:x1, y:y1}, {width:newWidth, height:newHeight}}
　　theImage’s lockFocus()
　　set theRep to NSBitmapImageRep’s alloc()’s initWithFocusedViewRect:newRect
　　theImage’s unlockFocus()
　　
　　set outImage to NSImage’s alloc()’s initWithSize:(theRep’s |size|())
　　outImage’s addRepresentation:theRep
　　
　　return outImage
end cropNSImageTo:fromImage:

on makeNSImageFromFile(anAlias)
　　set imgPath to (POSIX path of anAlias)
　　set aURL to (|NSURL|’s fileURLWithPath:(imgPath))
　　return (NSImage’s alloc()’s initWithContentsOfURL:aURL)
end makeNSImageFromFile

–NSImageを指定の大きさでトリミング
on cropNSImageBy:{x1, y1, newWidth, newHeight} fromImage:theImage
　　set theSize to (theImage’s |size|()) as record
　　set oldHeight to height of theSize
　　
　　— transpose y value for Cocoa coordintates
　　set y1 to oldHeight – newHeight – y1
　　set newRect to {{x:x1, y:y1}, {width:newWidth, height:newHeight}}
　　theImage’s lockFocus()
　　set theRep to NSBitmapImageRep’s alloc()’s initWithFocusedViewRect:newRect
　　theImage’s unlockFocus()
　　
　　set outImage to NSImage’s alloc()’s initWithSize:(theRep’s |size|())
　　outImage’s addRepresentation:theRep
　　
　　return outImage
end cropNSImageBy:fromImage:

on retUUIDfilePathFromDir(aPath, aEXT)
　　set aUUIDstr to (NSUUID’s UUID()’s UUIDString()) as string
　　set aPath to ((NSString’s stringWithString:aPath)’s stringByAppendingPathComponent:aUUIDstr)’s stringByAppendingPathExtension:aEXT
　　return aPath
end retUUIDfilePathFromDir

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –true/false
end saveNSImageAtPathAsPNG

on resizedImage:aSourceImg toScale:imgScale
　　if (aSourceImg’s isValid()) as boolean = false then error "Invalid NSImage"
　　
　　set aSize to aSourceImg’s |size|()
　　–>　　{width:32.0, height:32.0}
　　
　　set aWidth to (aSize’s width) * imgScale
　　set aHeight to (aSize’s height) * imgScale
　　
　　set aRep to NSBitmapImageRep’s alloc()’s initWithBitmapDataPlanes:(missing value) pixelsWide:aWidth pixelsHigh:aHeight bitsPerSample:8 samplesPerPixel:4 hasAlpha:true isPlanar:false colorSpaceName:(NSCalibratedRGBColorSpace) bytesPerRow:0 bitsPerPixel:0
　　
　　set newSize to {width:aWidth, height:aHeight}
　　aRep’s setSize:newSize
　　
　　NSGraphicsContext’s saveGraphicsState()
　　NSGraphicsContext’s setCurrentContext:(NSGraphicsContext’s graphicsContextWithBitmapImageRep:aRep)
　　
　　aSourceImg’s drawInRect:(current application’s NSMakeRect(0, 0, aWidth, aHeight)) fromRect:(NSZeroRect) operation:(NSCompositeCopy) fraction:(1.0)
　　
　　NSGraphicsContext’s restoreGraphicsState()
　　
　　set newImg to NSImage’s alloc()’s initWithSize:newSize
　　newImg’s addRepresentation:aRep
　　
　　return newImg
end resizedImage:toScale:

★Click Here to Open This Script　

MacJournalで選択中のエントリの文中からdata detectorで日付を取得して作成日付に反映

Posted on 1月 8, 2019 by Takaaki Naganoya

MacJournalで選択中のjournal entryの文中（plain text content）からData Detector（NSDataDetector）で日付を取得し、初出の日付をjournal entryの作成日付に設定するAppleScriptです。

macOSの不具合情報をMacJournalにスクラップして整理していたところ、記事作成日をjournal entryの作成日付に反映させたいと考え、以前に作ってあったScriptを修正し、Data Detectorで日付情報を抽出するようにしてみました。

なお、複数のjournal entryを選択した状態で実行すると、ループですべての選択中のjournal entryを処理します。

macOS標準搭載のScript Menuに入れて使用しています。

AppleScript名：MacJournalで選択中のエントリの文中からdata detectorで日付を取得して作成日付に反映

— Created 2019-01-08 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSDataDetector : a reference to current application’s NSDataDetector

tell application "MacJournal"
　　set aSel to selected entries
　　
　　repeat with i in aSel
　　　　set j to contents of i
　　　　set aName to name of j
　　　　set aDate to date of j
　　　　set aStr to plain text content of j
　　　　set aDateList to getDatesIn(aStr) of me
　　　　
　　　　if aStr is not equal to "" and aDateList is not equal to {} then
　　　　　　set targDate to contents of (first item of aDateList)
　　　　　　try
　　　　　　　　set date of j to targDate
　　　　　　end try
　　　　end if
　　end repeat
end tell

on getDatesIn(aString)
　　set anNSString to NSString’s stringWithString:aString
　　set {theDetector, theError} to NSDataDetector’s dataDetectorWithTypes:(current application’s NSTextCheckingTypeDate) |error|:(reference)
　　set theMatches to theDetector’s matchesInString:anNSString options:0 range:{0, anNSString’s |length|()}
　　set theResults to theMatches’s valueForKey:"date"
　　return theResults as list
end getDatesIn

★Click Here to Open This Script　

1D Listのうち指定文字種で構成される要素のみ抽出

Posted on 12月 20, 2018 by Takaaki Naganoya

1D List（配列）に入れた文字要素を文字種類で該当するものだけ抽出するAppleScriptです。

文字種類でデータ抽出する、という用途はけっこう多いので、単体で使えるようにしておきました。プログラムを見ていただくとわかるとおり、

　数字：”9″
　英字：”A”
　半角記号：”$”
　ひらがな：”ひ”
　カタカナ：”カ”
　漢字：”漢”

で文字種類を指定します。

以前のバージョンではありもののルーチンを組み合わせただけなので、全体的に無駄があって処理速度についてはあまり感心できないレベルだったので、若干の高速化を図りました（繰り返し処理部分で無駄な演算を省略）。

ただし、「ひらがな＋カタカナは許容する」というふうに、複数の文字種を許可する例が多いので、これではまだ実用レベルには達していないと思います。

AppleScript名：1D Listのうち指定文字種で構成される要素のみ抽出

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/12/20
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSScanner : a reference to current application’s NSScanner
property NSNumber : a reference to current application’s NSNumber
property NSDictionary : a reference to current application’s NSDictionary
property NSCountedSet : a reference to current application’s NSCountedSet
property NSCharacterSet : a reference to current application’s NSCharacterSet
property NSMutableArray : a reference to current application’s NSMutableArray
property NSNumberFormatter : a reference to current application’s NSNumberFormatter
property NSMutableCharacterSet : a reference to current application’s NSMutableCharacterSet
property NSRegularExpressionSearch : a reference to current application’s NSRegularExpressionSearch
property NSNumberFormatterRoundUp : a reference to current application’s NSNumberFormatterRoundUp
property NSStringTransformFullwidthToHalfwidth : a reference to current application’s NSStringTransformFullwidthToHalfwidth

set aList to {"Naganoya", "ながのや", "ナガノヤ", "長野谷"} –Alphabet, Hiragana, Katakana, Kanji

set aRes to filterByCharKind(aList, "A") of me –アルファベットで構成される要素のみ抽出
–> {"Naganoya"}

set bRes to filterByCharKind(aList, "ひ") of me –ひらがなだけで構成される要素のみ抽出
–> {"ながのや"}

set cRes to filterByCharKind(aList, "カ") of me –カタカナだけで構成される要素のみ抽出
–> {"ナガノヤ"}

set dRes to filterByCharKind(aList, "漢") of me –漢字だけで構成される要素のみ抽出
–> {"長野谷"}

–文字種別を判定して指定文字種のみから構成されるものを抽出
on filterByCharKind(aList as list, targCharKind as string)
　　set dList to {}
　　repeat with i in aList
　　　　set j to contents of i
　　　　set tmpPat to retAtrPatternFromStr(j) of me
　　　　if tmpPat is equal to {targCharKind} then
　　　　　　set the end of dList to j
　　　　end if
　　end repeat
　　
　　return dList
end filterByCharKind

–Objective-Cライクなパラメータ記述
on makeUniqueListOf:theList
　　set theSet to current application’s NSOrderedSet’s orderedSetWithArray:theList
　　return (theSet’s array()) as list
end makeUniqueListOf:

–Pure AS風のパラメータ記述
on makeUniqueListFrom(theList)
　　set aList to my makeUniqueListOf:theList
　　return aList
end makeUniqueListFrom

–1D Listを文字列長でソート v2
on sort1DListByStringLength(aList as list, sortOrder as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:aList
　　set desc1 to current application’s NSSortDescriptor’s sortDescriptorWithKey:"length" ascending:sortOrder
　　set desc2 to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:true selector:"localizedCaseInsensitiveCompare:"
　　set bArray to aArray’s sortedArrayUsingDescriptors:{desc1, desc2}
　　return bArray as list of string or string
end sort1DListByStringLength

–文字種別の判定
on retAtrPatternFromStr(aText as string)
　　set b1List to {"9", "A", "$", "漢", "ひ", "カ"} –数字、アルファベット、記号、全角漢字、全角ひらがな、全角カタカナ
　　
　　–set cStr to zenToHan(aText) of me
　　
　　set outList to {}
　　set cList to characters of (aText)
　　
　　repeat with i in cList
　　　　set j to contents of i
　　　　
　　　　set chk1 to ((my chkNumeric:j) as integer) * 1
　　　　set chk2 to ((my chkAlphabet:j) as integer) * 2
　　　　set chk3 to ((my chkSymbol:j) as integer) * 3
　　　　set chk4 to ((my chkKanji:j) as integer) * 4
　　　　set chk5 to ((my chkHiragana:j) as integer) * 5
　　　　set chk6 to ((my chkKatakana:j) as integer) * 6
　　　　
　　　　set itemVal to (chk1 + chk2 + chk3 + chk4 + chk5 + chk6)
　　　　
　　　　–if itemVal > 0 then
　　　　set aVal to (contents of item itemVal of b1List)
　　　　
　　　　if aVal is not in outList then
　　　　　　set the end of outList to aVal
　　　　end if
　　　　–end if
　　end repeat
　　
　　return outList
end retAtrPatternFromStr

–全角→半角変換
on zenToHan(aStr)
　　set aString to NSString’s stringWithString:aStr
　　return (aString’s stringByApplyingTransform:(NSStringTransformFullwidthToHalfwidth) |reverse|:false) as string
end zenToHan

–数字か
on chkNumeric:checkString
　　set digitCharSet to NSCharacterSet’s characterSetWithCharactersInString:"0123456789"
　　set ret to my chkCompareString:checkString baseString:digitCharSet
　　return ret as boolean
end chkNumeric:

–記号か
on chkSymbol:checkString
　　set muCharSet to NSCharacterSet’s alloc()’s init()
　　muCharSet’s addCharactersInString:"$＼"!~&=#[]._-+`|{}?%^*/’@-/:;(),"
　　set ret to my chkCompareString:checkString baseString:muCharSet
　　return ret as boolean
end chkSymbol:

–漢字か
on chkKanji:aChar
　　return detectCharKind(aChar, "[一-龠]") of me
end chkKanji:

–ひらがなか
on chkHiragana:aChar
　　return detectCharKind(aChar, "[ぁ-ん]") of me
end chkHiragana:

–カタカナか
on chkKatakana:aChar
　　return detectCharKind(aChar, "[ァ-ヶ]") of me
end chkKatakana:

–半角スペースか
on chkSpace:checkString
　　set muCharSet to NSCharacterSet’s alloc()’s init()
　　muCharSet’s addCharactersInString:" " –半角スペース（20h）
　　set ret to my chkCompareString:checkString baseString:muCharSet
　　return ret as boolean
end chkSpace:

— アルファベットか
on chkAlphabet:checkString
　　set aStr to NSString’s stringWithString:checkString
　　set allCharSet to NSMutableCharacterSet’s alloc()’s init()
　　allCharSet’s addCharactersInRange:({location:97, |length|:26}) –97 = id of "a"
　　allCharSet’s addCharactersInRange:({location:65, |length|:26}) –65 = id of "A"
　　set aBool to my chkCompareString:aStr baseString:allCharSet
　　return aBool as boolean
end chkAlphabet:

on chkCompareString:checkString baseString:baseString
　　set aScanner to NSScanner’s localizedScannerWithString:checkString
　　aScanner’s setCharactersToBeSkipped:(missing value)
　　aScanner’s scanCharactersFromSet:baseString intoString:(missing value)
　　return (aScanner’s isAtEnd()) as boolean
end chkCompareString:baseString:

on detectCharKind(aChar, aPattern)
　　set aChar to NSString’s stringWithString:aChar
　　set searchStr to NSString’s stringWithString:aPattern
　　set matchRes to aChar’s rangeOfString:searchStr options:(NSRegularExpressionSearch)
　　if matchRes’s location() = (current application’s NSNotFound) or (matchRes’s location() as number) > 9.99999999E+8 then
　　　　return false
　　else
　　　　return true
　　end if
end detectCharKind

★Click Here to Open This Script　

(POST) Google Translate APIで翻訳

Posted on 12月 10, 2018 by Takaaki Naganoya

Google Translate API（REST API）を呼び出して、指定のテキストを別の言語に翻訳するAppleScriptです。

Google Cloud Consoleにお持ちのGoogleアカウントでログインし、プロジェクトを作成して、プロジェクト用のAPIを個別に許可（この場合にはGoogle Translate API）し、API Keyを発行してScript中に記述して呼び出します（retAPIKeyハンドラ中にハードコーディングするのが嫌であれば、Keychainに登録して呼び出すことも可能です）。

処理内容自体は、REST API呼び出しのいつものやつなんでとくに解説はしません。コピペで作れるぐらい退屈で簡単です（本Scriptも呼び出せることを確認するだけして放置していました）。

ただ、本Scriptは同期処理用のNSURLConnectionを使って呼び出しているバージョンで、このNSURLConnectionが将来的に廃止される見込みなので、curlコマンドで呼び出すか、NSURLSessionを使って呼び出すように書き換えるか、といったところです。

単体だとただ翻訳できるだけで、あまり面白味はありません。本ScriptはMicrosoft Azure Computer Vision APIで画像認識を行なったときに、その画像認識テキストが英文で返ってきており、その内容を日本語に自動翻訳するときに使用してみました。翻訳精度は悪くないと思うのですが、画像のシーン認識テキストの英文がいまひとつだったので、「英文で出力してくれた方がまだわかりやすい」というところで、個人的にはあまり活躍していません。

Translate APIを売り物の本の翻訳に使うことが許可されていないなど、利用許諾が割と厳しいので使いどころが多そうに見えつつもそうでもない、といったところでしょうか。

AppleScript名：(POST) Google Translate APIで翻訳

— Created 2016-03-03 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSURLConnection : a reference to current application’s NSURLConnection
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

set aSentense to "a birthday cake with lit candles"
set bSentense to retTranslatedString("en", "ja", aSentense) of me
–> "キャンドルライト付きの誕生日ケーキ"–Japanese

set cSentense to retTranslatedString("en", "de", aSentense) of me
–> "eine Geburtstagstorte mit brennenden Kerzen"–Deutsch

on retTranslatedString(fromLang, toLang, aSentense)
　　set myAPIKey to retAPIKey() of me
　　set aRec to {|key|:myAPIKey, source:fromLang, |format|:"text", target:toLang, q:aSentense}
　　set aURL to "https://www.googleapis.com/language/translate/v2"
　　set bURL to retURLwithParams(aURL, aRec) of me
　　set aRes to callRestPOSTAPIAndParseResults(bURL) of me
　　
　　set aRESCode to responseCode of aRes
　　if aRESCode is not equal to 200 then return ""
　　set aRESHeader to responseHeader of aRes
　　set aRESTres to (translatedText of (first item of translations of |data| of json of aRes)) as string
　　return aRESTres
end retTranslatedString

–POST methodのREST APIを呼ぶ
on callRestPOSTAPIAndParseResults(aURL)
　　set aRequest to NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"POST"
　　aRequest’s setValue:"application/x-www-form-urlencoded" forHTTPHeaderField:"Content-Type"
　　
　　set aRes to NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to NSString’s alloc()’s initWithData:bRes encoding:(NSUTF8StringEncoding)
　　
　　set jsonString to NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestPOSTAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) –as text
　　
　　return aURL
end retURLwithParams

on retAPIKey()
　　return "XXxxXxXXXxXxX-XxXXxXXXxxxxXXXXxXxXXxXXX"
end retAPIKey

★Click Here to Open This Script　

WebView＋ボタンを作成 v3.1（URLから読み込み）

Posted on 12月 3, 2018 by Takaaki Naganoya

WkWebViewを動的に生成して、YouTube上の指定ムービーを再生するAppleScriptの改良版です。とくにYouTube限定ではなく、Webコンテンツのブラウズを単体で行うための実験的なScriptです。

＃　AppleScriptでは、Webブラウザに命令を出せば数行のコマンドで簡単に任意のURLのWebコンテンツを表示させられますが、本ScriptはAppleScriptから他のアプリケーションを介さずに直接Cocoaの機能を呼び出して自前でWebコンテンツを表示させるものです。

NSWindow＋NSSplitView＋WKWebViewを作成して、Webサーバー上の内容を表示します。v3.0からの改良点は、再生中のWebコンテンツのクリアを明示的に行えるようになったことです。

スクリプトエディタ上で実行し、「OK」ボタンをクリックすると、ウィンドウがクローズし、Webコンテンツの再生も停止します（前バージョンではこれができなかった）。Script MenuおよびScript Debugger上では実行できるもののWebコンテンツ操作はできず、OKボタンも反応しません。

AppleScript Appletとして書き出して実行すると、そのままではインターネットへのアクセスが許可されていないため、表示できません。Info.plistのエントリを書き換える必要があるものと思われます。

再生中のWebコンテンツのクリアについては、US Appleが主催しているCocoa-Dev MLにFritz Andersonが2012年4月11日に投稿した、

On 11 Apr 2012, at 7:51 AM, Koen van der Drift wrote:

> Is there a way to empty or clear a webview when I close the popover,
> so that next time it is opened it doesn't show the previous page? I
> don't want to clear the cache, because when the webview is opened for
> an item that was already selected, it can be loaded from the cache.

What works for me on iOS is having the UIWebView load about:blank. Maybe it works the same in Mac OS.

	— F

が参考になりました。Google検索しても見つからなかったのに、MLの過去ログを漁ってみたら割と簡単に発見。あらかじめMLのログをAppleScriptのロボットでテーマごとに自動フォルダ分けして整理してあったのが効きました。

あとは、実行環境がかなり限定される（Script DebuggerやScript Menuから実行すると、Webコンテンツ操作やボタンのクリックができなくなる）点をなんとかしたいところです。AppleScriptアプレットだとそのまま書き出した状態ではネットワーク接続自体ができない（Info.plist書き換えでなんとか？）とか。

Script Menuからの実行時に無反応になる件をなんとかしたいところです。個人的には、Script Menuが主力実行（ランタイム）環境だと思っているので。

AppleScript名：WebView＋ボタンを作成 v3.1（URLから読み込み）

— Created 2018-11-27 by Takaaki Naganoya
— Modified 2018-12-03 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property NSWindow : a reference to current application’s NSWindow
property NSSplitView : a reference to current application’s NSSplitView
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property WKWebView : a reference to current application’s WKWebView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSMutableString : a reference to current application’s NSMutableString
property NSWindowController : a reference to current application’s NSWindowController
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSRoundedBezelStyle : a reference to current application’s NSRoundedBezelStyle
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered
property WKUserContentController : a reference to current application’s WKUserContentController
property NSMomentaryLightButton : a reference to current application’s NSMomentaryLightButton
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property NSScreenSaverWindowLevel : a reference to current application’s NSScreenSaverWindowLevel
property NSWindowStyleMaskResizable : a reference to current application’s NSWindowStyleMaskResizable
property NSWindowStyleMaskMiniaturizable : a reference to current application’s NSWindowStyleMaskMiniaturizable
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property windisp : false
property wController : false

set aWidth to 1100
set aHeight to 700

set aTitle to "WkWebView test2"
set aButtonMSG to "OK"

set aURL to "https://www.youtube.com/embed/GP_tVXTYdmY?autoplay=1&hd=1"

set paramObj to {aWidth, aHeight, aTitle, aURL, aButtonMSG, "600"}
my performSelectorOnMainThread:"dispWebView:" withObject:(paramObj) waitUntilDone:true

on dispWebView:paramObj
　　set my windisp to false
　　copy (paramObj as list) to {aWidth, aHeight, aTitle, tmpURL, aButtonMSG, timeOutSecs}
　　
　　set (my windisp) to true
　　
　　set aWidth to aWidth as integer
　　set aHeight to aHeight as integer
　　set tmpURL to tmpURL as string
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定URLのJavaScriptをFetch
　　set jsSource to my fetchJSSourceString(tmpURL)
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 100)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s URLWithString:tmpURL
　　set aReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:aReq –Webコンテンツのローディング
　　
　　
　　–Buttonをつくる
　　set bButton to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, 40)))
　　bButton’s setTitle:aButtonMSG
　　bButton’s setTarget:me
　　bButton’s setAction:("clicked:")
　　bButton’s setKeyEquivalent:(return)
　　
　　–SplitViewをつくる
　　set aSplitV to NSSplitView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aSplitV’s setVertical:false
　　
　　aSplitV’s addSubview:aWebView
　　aSplitV’s addSubview:bButton
　　aSplitV’s setNeedsDisplay:true
　　
　　set aWin to makeWinWithView(aSplitV, aWidth, aHeight, aTitle, 1.0)
　　
　　–NSWindowControllerを作ってみた
　　set my wController to NSWindowController’s alloc()
　　my (wController’s initWithWindow:aWin)
　　
　　my (wController’s showWindow:me)
　　
　　set aCount to (timeOutSecs as string as number) * 10 –timeout seconds * 10
　　repeat aCount times
　　　　if (my windisp) = false then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　my closeWin:bButton
end dispWebView:

–Button Clicked Event Handler
on clicked:aSender
　　set (my windisp) to false
　　my closeWin:aSender
end clicked:

–make Window for Input
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle, alphaV)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　set aBacking to NSTitledWindowMask –NSBorderlessWindowMask
　　set aDefer to NSWindowStyleMaskMiniaturizable
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSScreenSaverWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setAlphaValue:alphaV –append
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aSender
　　set tmpWindow to aSender’s |window|()
　　
　　repeat with n from 10 to 1 by -1
　　　　(tmpWindow’s setAlphaValue:n / 10)
　　　　delay 0.02
　　end repeat
　　
　　my wController’s |close|()
end closeWin:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

★Click Here to Open This Script　

Numbersで選択中のデータを2D Listで取得し、ユニーク化

Posted on 12月 3, 2018 by Takaaki Naganoya

Numbersの最前面の書類の選択中のシートの選択中のセルの値を2D List（Array）で取り出して、ユニーク化するAppleScriptです。

上記のような状態で本AppleScriptを実行すると、

{{"iMac4,1", "Yonah"}, {"iMac4,2", "Yonah"}, {"iMac5,2", "Merom"}, {"iMac5,1", "Merom"}, {"iMac6,1", "Merom"}, {"iMac7,1", "Merom"}, {"iMac8,1", "Penryn"}, {"iMac9,1", "Penryn"}, {"iMac10,1", "Wolfdale"}, {"iMac11,1", "Wolfdale, Lynnfield"}......}

のような2D Listで結果が得られます。Numbersの選択中のセルからそのまま情報を取得すると1D Listとして結果が返ってきますが、別途selection rangeの情報を取得し、それをもとに2D Listに変換。得られた2D Listに対して重複データの除去をCocoaの機能を用いて行なっています。

特定のフィールド上の選択中のデータを1D Listとして取得し、重複データを検出するようなScriptは日常的に使っていますが、行データをすべて取得して2D Listとして取り出し、重複データ部分を除去するようなものは使っていませんでした。

AppleScript名：Numbersで選択中のデータを2D Listで取得し、ユニーク化

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aList to get2DListFromNumbersSelection() of me
if aList = "" then return "No Selection"

set bList to uniquifyList(aList) of me

on get2DListFromNumbersSelection()
　　–Numbersで選択範囲を縦に区切ったリストを返す
　　tell application "Numbers"
　　　　tell front document
　　　　　　tell active sheet
　　　　　　　　try
　　　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　　　on error
　　　　　　　　　　return "" –何も選択されてなかった場合
　　　　　　　　end try
　　　　　　　　
　　　　　　　　tell theTable
　　　　　　　　　　set selList to value of every cell of selection range –選択範囲のデータを取得
　　　　　　　　　　
　　　　　　　　　　set selName to name of selection range –選択範囲のrange情報を取得
　　　　　　　　　　set {s1, s2} to parseByDelim(selName, ":") of me
　　　　　　　　　　
　　　　　　　　　　–始点の情報を取得する
　　　　　　　　　　set s1Row to (address of row of range s1) as integer
　　　　　　　　　　set s1Column to (address of column of range s1) as integer
　　　　　　　　　　
　　　　　　　　　　–終点の情報を取得する
　　　　　　　　　　set s2Row to (address of row of range s2) as integer
　　　　　　　　　　set s2Column to (address of column of range s2) as integer
　　　　　　　　　　
　　　　　　　　　　–選択範囲の情報を取得する
　　　　　　　　　　set selHeight to s2Row – s1Row + 1 –高さ(Height of selection range)
　　　　　　　　　　set selWidth to s2Column – s1Column + 1 –幅(Width of selection range)
　　　　　　　　　　
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　set aLen to length of selList
　　set aaLen to selHeight
　　
　　set bList to {}
　　repeat with i from 1 to aaLen
　　　　set aHoriList to {}
　　　　
　　　　repeat with ii from 1 to selWidth
　　　　　　set j1 to ii + (i – 1) * selWidth
　　　　　　set tmpCon to contents of item j1 of selList
　　　　　　
　　　　　　set aClass to class of tmpCon
　　　　　　if aClass = number or aClass = integer or aClass = real then
　　　　　　　　set tmpCon to tmpCon as integer
　　　　　　end if
　　　　　　
　　　　　　set the end of aHoriList to tmpCon
　　　　end repeat
　　　　
　　　　set the end of bList to aHoriList
　　end repeat
　　
　　return bList
end get2DListFromNumbersSelection

–テキストを指定デリミタでリスト化
on parseByDelim(aData, aDelim)
　　set aText to current application’s NSString’s stringWithString:aData
　　set aList to aText’s componentsSeparatedByString:aDelim
　　return aList as list
end parseByDelim

–1D/2D Listのユニーク化
on uniquifyList(aList as list)
　　set aArray to current application’s NSArray’s arrayWithArray:aList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　return bArray as list
end uniquifyList

★Click Here to Open This Script　

WebView＋ボタンを作成 v3（URLから読み込み）

Posted on 11月 28, 2018 by Takaaki Naganoya

WkWebViewを動的に生成して、YouTube上の指定ムービーを再生するAppleScriptです。

＃　AppleScriptでは、Webブラウザに命令を出せば数行のコマンドで簡単に任意のURLのWebコンテンツを表示させられますが、本ScriptはAppleScriptから他のアプリケーションを介さずに直接Cocoaの機能を呼び出して自前でWebコンテンツを表示させるものです

NSWindow＋NSSplitView＋WKWebViewを作成して、Webサーバー上の内容を表示します。WkWebViewでWebの内容を表示させるのにかなり苦労しましたが、Objective-Cのサンプル数本を比較してテストし実現しました。

WkWebViewでコンテンツを表示するのにこんなに大変だと思いませんでしたが、これができるようになったおかげで、AppleScriptの処理結果のURLを（Webブラウザを利用せずに）プレビューできます。

グラフ描画のプログラムがJavaScript＋WebViewで作られているケースが多々あるため、凝ったインタラクティブなグラフの表示を行ったり画像やPDFに出力できるようにもなったわけで、たいへんけっこうなことです。

▲Auto StartでYouTube上のムービーの再生を開始する

まだ解決できていないのは、YouTubeのムービー再生が始まるとウィンドウをクローズしてAppleScriptの実行が終了していても再生中の音声が停止しないあたりでしょうか。メモリ上からWebブラウザのオブジェクトを明示的にパージする方法についてはまだ実装できていません。

あと、Script Debugger上で動かすと、WkWebView上のコンテンツの操作（YouTube映像の再生コントロールとか）ができなくなります。ねんのため。

AppleScript名：WebView＋ボタンを作成 v3（URLから読み込み）

— Created 2018-11-27 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property NSWindow : a reference to current application’s NSWindow
property NSSplitView : a reference to current application’s NSSplitView
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property WKWebView : a reference to current application’s WKWebView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSMutableString : a reference to current application’s NSMutableString
property NSWindowController : a reference to current application’s NSWindowController
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSRoundedBezelStyle : a reference to current application’s NSRoundedBezelStyle
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered
property WKUserContentController : a reference to current application’s WKUserContentController
property NSMomentaryLightButton : a reference to current application’s NSMomentaryLightButton
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property NSScreenSaverWindowLevel : a reference to current application’s NSScreenSaverWindowLevel
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property windisp : false
property wController : false

set aWidth to 1100
set aHeight to 600

set aTitle to "WkWebView test"
set aButtonMSG to "OK"
–set aURL to "https://www.youtube.com/watch?v=GP_tVXTYdmY&autoplay=1&hd=1"
set aURL to "https://www.youtube.com/embed/GP_tVXTYdmY?autoplay=1&hd=1"

set paramObj to {aWidth, aHeight, aTitle, aURL, aButtonMSG, "600"}
my performSelectorOnMainThread:"dispWebView:" withObject:(paramObj) waitUntilDone:true

on dispWebView:paramObj
　　set my windisp to false
　　copy (paramObj as list) to {aWidth, aHeight, aTitle, tmpURL, aButtonMSG, timeOutSecs}
　　
　　set (my windisp) to true
　　
　　set aWidth to aWidth as integer
　　set aHeight to aHeight as integer
　　set tmpURL to tmpURL as string
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　set jsSource to my fetchJSSourceString(tmpURL)
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 100)) configuration:aConf –フレームの大きさは根拠レス
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s URLWithString:tmpURL
　　set aReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:aReq
　　
　　
　　–Buttonをつくる
　　set bButton to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, 40)))
　　bButton’s setTitle:aButtonMSG
　　bButton’s setTarget:me
　　bButton’s setAction:("clicked:")
　　bButton’s setKeyEquivalent:(return)
　　
　　–SplitViewをつくる
　　set aSplitV to NSSplitView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aSplitV’s setVertical:false
　　
　　aSplitV’s addSubview:aWebView
　　aSplitV’s addSubview:bButton
　　aSplitV’s setNeedsDisplay:true
　　
　　set aWin to makeWinWithView(aSplitV, aWidth, aHeight, aTitle, 1.0)
　　
　　–NSWindowControllerを作ってみた
　　set my wController to NSWindowController’s alloc()
　　my (wController’s initWithWindow:aWin)
　　
　　my (wController’s showWindow:me)
　　
　　set aCount to (timeOutSecs as string as number) * 10 –timeout seconds * 10
　　repeat aCount times
　　　　if (my windisp) = false then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　–Purge Web Objects (not success)
　　set aWebView to ""
　　set userContentController to ""
　　set aConf to ""
　　set userScript to ""
　　set my wController to ""
　　
　　my closeWin:bButton
end dispWebView:

–Button Clicked Event Handler
on clicked:aSender
　　set (my windisp) to false
　　my closeWin:aSender
end clicked:

–make Window for Input
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle, alphaV)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　set aBacking to NSTitledWindowMask –NSBorderlessWindowMask
　　set aDefer to NSBackingStoreBuffered
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSScreenSaverWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setAlphaValue:alphaV –append
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　return aWin
end makeWinWithView

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

★Click Here to Open This Script　

teratailの指定IDのユーザー情報を取得する_curl

Posted on 11月 27, 2018 by Takaaki Naganoya

プログラミング系質問サイトteratailのREST APIを呼び出して、指定ユーザー名の情報を取得するAppleScriptです。

TeratailのREST APIは、タグ、ユーザー、質問の３ジャンルの情報取得を行えるように整備されており、特定カテゴリ（タグで分類）の新規質問が投稿されたかどうかを定期的に確認するようなAppleScriptを作って運用することもできます（そこまでやっていないですけれども）。

REST API呼び出しにはNSURLConnectionからNSURLSessionに移行していますが、どうもNSURLSessionだと呼び出せない（AppleScriptからの呼び出し処理が完了しない）サービスがあったりするので、結局shellのcurlコマンドを呼び出すのが手短にすむケースが多いようです。

Teratailの場合も、NSURLSessionで呼び出せるAPIもあれば、結果が返ってこないAPIもあり、NSURLConnectionよりも使い勝手がよくないと感じています（個人の感想です）。

このあたり、将来的なmacOSのアップデートでNSURLConnectionが使えなくなる日が来るのかもしれませんが、curlコマンドを使うように集約するべきなのか、NSURLSessionで書き換えるべきなのか悩ましいところです。

AppleScript名：teratailの指定IDのユーザー情報を取得する_curl

— Created 2018-11-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

set aUserRes to searchOneUserByDisplayName("Piyomaru") of me
–> {meta:{limit:20, message:"success", hit_num:1, total_page:1, page:1}, users:{{score:43, photo:"https://teratail.storage.googleapis.com/uploads/avatars/u6/66639/MSIS21by_thumbnail.jpg", display_name:"Piyomaru"}}}

on searchOneUserByDisplayName(aName)
　　set aRec to {q:aName}
　　set reqURLStr to "https://teratail.com/api/v1/users/search"
　　set bURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set tmpData to (do shell script "curl -X GET ＼"" & bURL & "＼"")
　　set jsonString to NSString’s stringWithString:tmpData
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　if aJsonDict = missing value then return false
　　return (aJsonDict as record)
end searchOneUserByDisplayName

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSString

ASの実行結果をNumbersの表に出力する

指定単語の花文字テキストを取得する（Retina対応）英文字用 v2

頭のいいタイマー割り込み実行

HTMLをplain textに変換（文字コード自動認識ライブラリ展開）

アラートダイアログ上に複数のNSBoxを作成してMKMapViewを表示

アラートダイアログ上にWebViewを表示

クリップボード中の書式つきテキストのフォントサイズを取得する

Finder上で選択中のAppleScriptの行数をカウントする

指定色で塗りつぶし角丸画像を作成

Finder上で選択中の画像のうち、最小のものに合わせて各画像の右上を基準にサイズ統一

MacJournalで選択中のエントリの文中からdata detectorで日付を取得して作成日付に反映

(POST) Google Translate APIで翻訳

WebView＋ボタンを作成 v3.1（URLから読み込み）

WebView＋ボタンを作成 v3（URLから読み込み）

teratailの指定IDのユーザー情報を取得する_curl