新発売：Cocoa Scripting Course #6, PDFKit

Posted on 8月 22, 2023 by Takaaki Naganoya

Piymaru Softwareによる電子書籍の83冊目、「Cocoa Scripting Course #6, PDFKit」を発売しました。PDF560ページ＋サンプルScript Zipアーカイブで構成されています。

PDF処理は、Cocoa Scriptingの1つの価値ある到達点です。この処理が行いたいからCocoaの呼び出しについて苦労を重ねてきたと言えます。機械学習やREST API呼び出し、配列からの高速なデータ抽出など、Cocoa Scriptingの「おいしい用途」は星の数ほどありますが、PDF処理は間違いなくその中でもトップランクの攻略目標のうちの1つです。

日常的にPDFを扱っているScripterなら、Cocoa Scriptingによって得られるメリットが膨大なものであることをもれなく間違いなくいかんなく実感できることでしょう。

１章　入門編
２章　実践編
３章　PDFKit編

PDFKitの位置付けと役割
　用途別のフレームワークを知ろう
　PDFKit内の主要クラス
　PDFKit+AppleScriptのつかいどころ
　PDFKit+AppleScriptの注意点
　PDFKit.frameworkの利用宣言文
　（参考資料）PDFの座標系

PDFDocument Basic Samples
PDFPage Basic Samples
PDFOutline Basic Samples
PDFAnnotation Basic Samples

４章　PDF処理基礎編

PDFの処理の流れ
　AppleScript＋PDFKitでよく使う基礎的な処理
　AppleScript＋PDFKitの基礎的な処理手順
　AppleScript＋PDFKitでよく使う基礎的な処理の手順

PDFからの情報取得
　PDFのサイズをPointで取得
　PDFから各種情報をNSDictionaryで取得
　PDFから各種情報を文字列で取得

PDFページカウント
　PDFのページカウント（PDFDocument）
　PDFのページカウント（Metadata Lib経由）

PDF本文テキスト抽出
　PDFの全ページのテキストを抽出
　PDFのテキストをページ単位で抽出

PDFを回転
　PDFを回転させて新規保存

PDFを印刷
　PDFを印刷

RTFをPDFに変換
　RTFをPDFに変換

PDFからのテキスト検索
　PDFテキストからの指定キーワード検索

ページ単位でPDF分割
　ページ単位でPDF分割

複数PDF結合
　choose fileコマンドで選択した複数のPDFを結合

PDF→他形式画像変換
　ページ単位でJPEG画像に変換

画像連結してPDF作成
　フォルダ内のJPEG画像を新規PDFに連結
　指定フォルダ下のすべての画像を新規PDFに連結
　フォルダ内のJPEG画像を既存のPDFに連結

Multi Page TIFFからPDFへの変換
　Multi Page TIFFからPDFへの変換

アラートダイアログでPDFを表示
　アラートダイアログ＋WkWebViewでPDFを表示
　アラートダイアログ＋PDFViewでPDFを表示

５章　PDF処理上級編

PDFのパスワード、暗号化設定
　PDFのアクセス権とパスワード
　パスワード設定をチェック
　設定されているパーミッションを取得
　PDFにパスワードを設定(1/2)
　PDFにパスワードを設定(2/2)
　PDFのパスワードを解除

PDFの空白ページ検出
　PDFから空白ページを削除(1/3)
　PDFから空白ページを削除(2/3)
　PDFから空白ページを削除(3/3)

PDFフォーム入力
　PDFフォームにテキスト入力して別名保存(1/2)
　PDFフォームにテキスト入力して別名保存(2/2)
　PDFフォームにチェックボックス入力(1/2)
　PDFフォームにチェックボックス入力(2/2)

Quartzフィルタ
　Quartzフィルタとは？
　QuartzFilter出力例一覧
　Quartzフィルタの一覧を出力
　白黒のQuartzフィルタをかけて出力
　ブルートーンのQuartzフィルタをかけて出力
　PDFX-3のQuartzフィルタをかけて出力
　グレートーンのQuartzフィルタをかけて出力
　明度低下のQuartzフィルタをかけて出力
　明度上昇のQuartzフィルタをかけて出力
　ファイルサイズ縮小のQuartzフィルタをかけて出力
　セピアトーンのQuartzフィルタをかけて出力

PDFアノテーションを取得、追加、書き換え、削除
　アノテーションについて
　アノテーションを取得
　サークル・アノテーションを追加
　スクウェア・アノテーションを追加
　ライン・アノテーションを追加
　テキスト・アノテーションを追加
　URLリンク・アノテーションを追加(1/2)
　URLリンク・アノテーションを追加(2/2)
　指定語群にハイライトを追加(1/2)
　指定語群にハイライトを追加(2/2)
　指定語群にアンダーラインを追加(1/2)
　指定語群にアンダーラインを追加(2/2)
　指定語群に打ち消し線を追加(1/2)
　指定語群に打ち消し線を追加(2/2)
　PDFからすべてのアノテーションを削除

PDFのリンク抽出、リンク置換
PDFのリンク先は？
リンクの各種情報を取得(1/2)
リンクの各種情報を取得(2/2)
リンク・アノテーションからURLを抽出
URLリンク・アノテーションを追加(1/2)
URLリンク・アノテーションを追加(2/2)
書類内リンク・アノテーションを追加(1/2)
書類内リンク・アノテーションを追加(2/2)
リンクアノテーションのURLを置換

PDFのOCR処理（OCRテキスト埋め込み）
　PDFのOCR処理(1/3)
　PDFのOCR処理(2/3)
　PDFのOCR処理(3/3)

PDFのしおり（TOC）を取得、追加、削除
　TOCの題名と階層が悩ましい(1/2)
　TOCの題名と階層が悩ましい(2/2)
　指定PDFのTOCを取得してレコード化(1/2)
　指定PDFのTOCを取得してレコード化(2/2)
　ノンブルだけのフラットなTOCを付加(1/2)
　ノンブルだけのフラットなTOCを付加(2/2)
　Recordデータから階層TOCを付加(1/3)
　Recordデータから階層TOCを付加(2/3)
　Recordデータから階層TOCを付加(3/3)
　Numbersの表データから階層TOCを付加(1/4)
　Numbersの表データから階層TOCを付加(2/4)
　Numbersの表データから階層TOCを付加(3/4)
　Numbersの表データから階層TOCを付加(4/4)
　指定PDFのTOCを削除

添付サンプルScript紹介

サンプルScript集

資料編

Skim Notesのじっけん

Posted on 8月 18, 2023 by Takaaki Naganoya

目下、「Cocoa Scripting Course #6 PDFKit」の仕上げ作業中ですが、懸案事項がありました。

PDFに対してコメント、注釈的なもの（PDFAnnotation）をつけられるようになっていますが、各アプリケーションで管理方法が微妙に異なっており、互換性がありません。

Adobe Acrobatが付けたアノテーション　→　Skimで表示できない、プレビュー.appで表示できる
Skimが付けたアノテーション　→ Adobe Acrobat、プレビュー.appで表示できない
プレビュー.appが付けたアノテーション　→ Adobe Acrobat、Skimで表示できる

▲Skim上でPDFに対して各種アノテーションを付加した状態

▲Skim上でPDFに各種アノテーションを付加したものをPreview.appで表示。何も表示されない

▲Skim上でPDFに各種アノテーションを付加したものをAdobe Acrobatで表示。こちらも何も表示されない

SkimとAcrobatのアノテーションの互換性がナニでアレでありますが、一応プレビュー.appとSkimがあればなんとかなる感じです。

さて、Skimでアノテーションを付けるとSkim同士でしかアノテーションを表示できない状態になってしまい、かつ、AppleScriptからPDFKitを操作しても読めないので困っていました（SkimのGUIアプリケーション経由で取得できないこともなさそう）。

Skimのアノテーションを読むために、Skim本体とは別にSkimNotes.frameworkとSkimNotesBase.frameworkが提供されています。Skim.appとは別にインストールする必要があります。インストール先は~/Library/Frameworksです。

コード署名されていないので、Script Debugger上でこれらのFrameworkの機能を呼び出そうとすると、署名されていない旨の警告が表示されますが、システム設定.app＞セキュリティとプライバシーで認証できます。これら2つのFramrworkの両方とも認証しておく必要があります。

テストデータとして、Skim.app上でノートアノテーションをPDFに追記して保存。これに対して、AppleScriptからアクセスできるか試してみました。

結論からいえば、AppleScriptからアクセスできるわけですが、互換性を持たせるような何かがあってもいいような気がするところです。Adobe Acrobatでアノテーションを記載したPDFを、Skimで見られるように修正するとか。Skimで記入したアノテーションを他のアプリケーションでも見られるように変換するとか。

AppleScript名：Skim Notesのじっけん.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/08/17
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.8"
use framework "Foundation"
use framework "PDFKit"
use framework "SkimNotes"
use framework "SkimNotesBase"
use scripting additions

set aPOSIX to POSIX path of (choose file of type {"com.adobe.pdf"})
set aURL to (current application’s |NSURL|’s fileURLWithPath:aPOSIX)

set aPDFdoc to current application’s PDFDocument’s alloc()’s initWithURL:aURL readSkimNotes:true
set pCount to aPDFdoc’s pageCount()

repeat with ii from 0 to (pCount – 1)
　　log ii –Page Count
　　
　　set firstPage to (aPDFdoc’s pageAtIndex:ii)
　　–>　　(PDFPage) PDFPage, label 1
　　
　　set anoList to (firstPage’s annotations()) as list
　　if anoList is not equal to {} then
　　　　repeat with i in anoList
　　　　　　set j to contents of i
　　　　　　log j
　　　　　　(*(SKNPDFAnnotationNote) Type: ’/Text’, Bounds: (320, 737) [16, 16]＼n*)
　　　　　　
　　　　　　set aType to (j’s type()) as string
　　　　　　log aType
　　　　　　(*Note*)
　　　　　　
　　　　　　if aType = "Note" then
　　　　　　　　set cVal to j’s |contents|() as string
　　　　　　　　log cVal
　　　　　　　　(*Skim Noteのタイトルだよ Skim Noteの本文だよ＼n＼n*)
　　　　　　　　
　　　　　　　　set cVal to j’s iconType()
　　　　　　　　log cVal
　　　　　　　　(*0*)
　　　　　　　　
　　　　　　　　set dVal to j’s isSkimNote() as boolean
　　　　　　　　log dVal
　　　　　　　　(*true*)
　　　　　　　　
　　　　　　　　if dVal = true then
　　　　　　　　　　set eVal to j’s |string|()
　　　　　　　　　　log eVal
　　　　　　　　　　(*(NSString) "Skim Noteのタイトルだよ"*)
　　　　　　　　　　
　　　　　　　　　　set fVal to j’s SkimNoteProperties()
　　　　　　　　　　(*(NSDictionary) {bounds:"{{308, 732}, {16, 16}}", color:(NSColorSpaceColor) sRGB IEC61966-2.1 colorspace 1 1 0.5 1, userName:"Takaaki Naganoya2", modificationDate:(NSDate) "2023-08-17 14:38:39 +0000", image:<NSImage 0x6000067d32a0 Size={1920, 1200} RepProvider=<NSImageArrayRepProvider: 0x6000015034a0, reps:(＼n "NSBitmapImageRep 0x600003eb85b0 Size={1920, 1200} ColorSpace=(not yet loaded) BPS=8 BPP=(not yet loaded) Pixels=1920×1200 Alpha=YES Planar=NO Format=(not yet loaded) CurrentBacking=nil (faulting) CGImageSource=0x600001089360"＼n)>>, contents:"Skim Noteのタイトルだよ", text:(NSConcreteAttributedString) Skim Note{＼n NSFont = ""Helvetica 12.00 pt. P [] (0x11f597610) fobj=0x139642430, spc=3.33"";＼n NSParagraphStyle = "Alignment 0, LineSpacing 0, ParagraphSpacing 0, ParagraphSpacingBefore 0, HeadIndent 0, TailIndent 0, FirstLineHeadIndent 0, LineHeight 0/0, LineHeightMultiple 0, LineBreakMode 0, Tabs (＼n 28L,＼n 56L,＼n 84L,＼n 112L,＼n 140L,＼n 168L,＼n 196L,＼n 224L,＼n 252L,＼n 280L,＼n 308L,＼n 336L＼n), DefaultTabInterval 0, Blocks (null), Lists (＼n), BaseWritingDirection -1, HyphenationFactor 0, TighteningForTruncation NO, HeaderLevel 0 LineBreakStrategy 0 PresentationIntents (＼n) ListIntentOrdinal 0 CodeBlockIntentLanguageHint ’(null)’";＼n}の本文だよ＼n＼n{＼n NSFont = ""HiraginoSans-W3 12.00 pt. P [] (0x11f597610) fobj=0x11f5277a0, spc=4.00"";＼n NSParagraphStyle = "Alignment 0, LineSpacing 0, ParagraphSpacing 0, ParagraphSpacingBefore 0, HeadIndent 0, TailIndent 0, FirstLineHeadIndent 0, LineHeight 0/0, LineHeightMultiple 0, LineBreakMode 0, Tabs (＼n 28L,＼n 56L,＼n 84L,＼n 112L,＼n 140L,＼n 168L,＼n 196L,＼n 224L,＼n 252L,＼n 280L,＼n 308L,＼n 336L＼n), DefaultTabInterval 0, Blocks (null), Lists (＼n), BaseWritingDirection -1, HyphenationFactor 0, TighteningForTruncation NO, HeaderLevel 0 LineBreakStrategy 0 PresentationIntents (＼n) ListIntentOrdinal 0 CodeBlockIntentLanguageHint ’(null)’";＼n}, type:"Note", pageIndex:0, iconType:0}*)
　　　　　　　　　　
　　　　　　　　　　set anImage to fVal’s image
　　　　　　　　　　log anImage
　　　　　　　　　　(*<NSImage 0x6000067cf700 Size={1920, 1200} RepProvider=<NSImageArrayRepProvider: 0x6000015182c0, reps:(＼n "NSBitmapImageRep 0x600003effb10 Size={1920, 1200} ColorSpace=(not yet loaded) BPS=8 BPP=(not yet loaded) Pixels=1920×1200 Alpha=YES Planar=NO Format=(not yet loaded) CurrentBacking=nil (faulting) CGImageSource=0x60000105fa20"＼n)>>*)
　　　　　　　　　　
　　　　　　　　　　set colRes to fVal’s |color|
　　　　　　　　　　log colRes
　　　　　　　　　　(*(NSColorSpaceColor) sRGB IEC61966-2.1 colorspace 1 1 0.5 1*)
　　　　　　　　　　
　　　　　　　　　　set tRes to fVal’s |text|
　　　　　　　　　　log tRes
　　　　　　　　　　(*(NSConcreteAttributedString) Skim Note{＼n NSFont = ""Helvetica 12.00 pt. P [] (0x1296dd6e0) fobj=0x139642430, spc=3.33"";＼n NSParagraphStyle = "Alignment 0, LineSpacing 0, ParagraphSpacing 0, ParagraphSpacingBefore 0, HeadIndent 0, TailIndent 0, FirstLineHeadIndent 0, LineHeight 0/0, LineHeightMultiple 0, LineBreakMode 0, Tabs (＼n 28L,＼n 56L,＼n 84L,＼n 112L,＼n 140L,＼n 168L,＼n 196L,＼n 224L,＼n 252L,＼n 280L,＼n 308L,＼n 336L＼n), DefaultTabInterval 0, Blocks (null), Lists (＼n), BaseWritingDirection -1, HyphenationFactor 0, TighteningForTruncation NO, HeaderLevel 0 LineBreakStrategy 0 PresentationIntents (＼n) ListIntentOrdinal 0 CodeBlockIntentLanguageHint ’(null)’";＼n}の本文だよ＼n＼n{＼n NSFont = ""HiraginoSans-W3 12.00 pt. P [] (0x1296dd6e0) fobj=0x11f5277a0, spc=4.00"";＼n NSParagraphStyle = "Alignment 0, LineSpacing 0, ParagraphSpacing 0, ParagraphSpacingBefore 0, HeadIndent 0, TailIndent 0, FirstLineHeadIndent 0, LineHeight 0/0, LineHeightMultiple 0, LineBreakMode 0, Tabs (＼n 28L,＼n 56L,＼n 84L,＼n 112L,＼n 140L,＼n 168L,＼n 196L,＼n 224L,＼n 252L,＼n 280L,＼n 308L,＼n 336L＼n), DefaultTabInterval 0, Blocks (null), Lists (＼n), BaseWritingDirection -1, HyphenationFactor 0, TighteningForTruncation NO, HeaderLevel 0 LineBreakStrategy 0 PresentationIntents (＼n) ListIntentOrdinal 0 CodeBlockIntentLanguageHint ’(null)’";＼n}*)
　　　　　　　　　　
　　　　　　　　　　set sBounds to fVal’s |bounds|
　　　　　　　　　　log sBounds
　　　　　　　　　　(*(NSString) "{{308, 732}, {16, 16}}"*)
　　　　　　　　　　
　　　　　　　　　　set uName to fVal’s userName
　　　　　　　　　　log uName
　　　　　　　　　　(*(NSString) "Takaaki Naganoya2"*)
　　　　　　　　　　
　　　　　　　　　　set modRes to fVal’s modificationDate
　　　　　　　　　　log modRes
　　　　　　　　　　(*(NSDate) "2023-08-17 14:38:39 +0000"*)
　　　　　　　　　　
　　　　　　　　end if
　　　　　　end if
　　　　end repeat
　　end if
　　
end repeat

★Click Here to Open This Script　

Excelの書類上に置かれているpictureが置かれているセルのアドレスを推定する v2

Posted on 8月 9, 2023 by Takaaki Naganoya

Excelのワークシート上にドラッグ＆ドロップして配置された画像のセルのアドレスを推定するAppleScriptの強化版です。

このぐらい作り込んでおけば実用性のある部品になることでしょう。Microsoft Excel 16.76を対象に検証を行なっています。テストは1つのExcel書類上に1つだけ画像を配置（Finderからドラッグ＆ドロップで配置）した状態、1つのセルの上に乗っているように見える状態に大きさを調整して実行しました。

まず、大前提でpictureのID（1から始まる通し番号）、pictureの始点座標が存在するExcel上のセルのrow（行）とcolumn（列）。これはあらかじめ各Pictureの始点座標をもとにあらかじめ計算しておいたものを使います。

本Scriptは、この「始点座標から存在するセルを計算」する処理の後処理として、実際に画像が重なっているセルを重なっている部分の面積をもとに最大の面積のものを「配置されているセル」として計算で推定します。

この処理には前提条件があって、複数のセルにまたがりすぎているような（数十のセルにまたがってpictureが配置されている）場合には計算そのものが無意味です。「1セルに1画像ぐらい」の調子で配置されていないと、こうした処理を行なっても無駄になってしまいます。

本Scriptでは、Excelワークシートの対象のpictureのID、pictureの始点座標から求めたセルのrow（行）とcolumn（列）を与えて呼び出します。すると、始点セルを基準に3×3のセルの矩形エリア（NSRect）を求め、pictureの矩形（NSRect）との重なっている面積を計算。もっとも面積が大きいものを対象セルとしてrow, columnを返します。

こうしたScriptを作ってほうがよいと考えた理由は、このExcelシート上に貼り付けた画像に対してさまざまな文字データが隣のセルに入力され、セル上のデータと画像を関連づけてデータ取得するような処理を考えたときに必要と考えたためです。

AppleScript名：pictureが置かれているセルのアドレスを推定する v2.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/08/07
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—
use AppleScript
use scripting additions
use framework "Foundation"

set targRow to 22
set targCol to 2
set targPictureID to 1

set tCell to getPictureLocatedCellRowColByItsPosition(targRow, targCol, targPictureID) of me
–> {rowNum:23, columnNum:2}

–ループで指定セルを左上とした3×3の範囲のセルから、指定のPictureと重なっている面積が最も大きいものを返す
on getPictureLocatedCellRowColByItsPosition(targRow as integer, targCol as integer, targPictureID as integer)
　　
　　–Picture 1のNSRectを求める
　　set pRect to getAPictureRectByID(targPictureID) of me
　　
　　set tmpList to {}
　　
　　–始点座標から3×3の範囲のセルとPictureの重なる面積を計算
　　repeat with x from 0 to 2
　　　　repeat with y from 0 to 2
　　　　　　
　　　　　　set tmpRow to (targRow + y)
　　　　　　set tmpCol to (targCol + x)
　　　　　　
　　　　　　set tmpRect to retExcelCellRect(tmpRow, tmpCol) of me
　　　　　　
　　　　　　–指定Pictureと指定Cellの共通部分の矩形座標を計算
　　　　　　set a1Res to (current application’s NSIntersectionRect(tmpRect, pRect)) as {record, list}
　　　　　　
　　　　　　–指定Pictureと指定Cellの共通部分の面積を計算
　　　　　　set a1Area to calcAnArea(a1Res) of me
　　　　　　if a1Area > 0 then
　　　　　　　　set the end of tmpList to {columnNum:tmpCol, rowNum:tmpRow, interAreaWithPict:a1Area}
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　–面積で降順ソート
　　set zList to (sortRecListByLabel(tmpList, {"interAreaWithPict"}, {false}) of me) as list
　　–> {{columnNum:2, rowNum:23, interAreaWithPict:4973.377807617188}, {columnNum:2, rowNum:24, interAreaWithPict:747.665495456778}, {columnNum:2, rowNum:22, interAreaWithPict:333.296168677043}}
　　
　　set resCell to first item of zList
　　set resCol to columnNum of resCell
　　set resRow to rowNum of resCell
　　
　　return {rowNum:resRow, columnNum:resCol}
end getPictureLocatedCellRowColByItsPosition

–IDで指定したPictureのNSRectを返す
on getAPictureRectByID(anID as integer)
　　tell application "Microsoft Excel"
　　　　tell active workbook
　　　　　　tell active sheet
　　　　　　　　set anImage to picture anID
　　　　　　　　
　　　　　　　　set tmpX to left position of anImage
　　　　　　　　set tmpY to top of anImage
　　　　　　　　set tmpW to width of anImage
　　　　　　　　set tmpH to height of anImage
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　set aZRect to current application’s NSMakeRect(tmpX, tmpY, tmpW, tmpH)
　　return aZRect
end getAPictureRectByID

–NSRectの面積を計算する
on calcAnArea(aRect)
　　if class of aRect = list then
　　　　set xWidth to (item 1 of item 2 of aRect)
　　　　set yHeight to (item 2 of item 2 of aRect)
　　else
　　　　set xWidth to (aRect’s |size|’s width)
　　　　set yHeight to (aRect’s |size|’s height)
　　end if
　　
　　set anArea to xWidth * yHeight
　　return anArea
end calcAnArea

–指定Row, ColumnのCellのNSRectを返す
on retExcelCellRect(y as integer, x as integer)
　　tell application "Microsoft Excel"
　　　　tell active workbook
　　　　　　tell active sheet
　　　　　　　　tell row y
　　　　　　　　　　tell cell x
　　　　　　　　　　　　set xMin0 to left position
　　　　　　　　　　　　set yMin0 to top
　　　　　　　　　　　　set xWidth0 to width
　　　　　　　　　　　　set yHeight0 to height
　　　　　　　　　　end tell
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　set a1Rect to current application’s NSMakeRect(xMin0, yMin0, xWidth0, yHeight0)
　　return a1Rect
end retExcelCellRect

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as list, ascendF as list)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　set aCount to length of aLabelStr
　　set sortDescArray to current application’s NSMutableArray’s new()
　　repeat with i from 1 to aCount
　　　　set aLabel to (item i of aLabelStr)
　　　　set aKey to (item i of ascendF)
　　　　set sortDesc to (current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabel ascending:aKey)
　　　　(sortDescArray’s addObject:sortDesc)
　　end repeat
　　
　　return (aArray’s sortedArrayUsingDescriptors:sortDescArray)
end sortRecListByLabel

★Click Here to Open This Script　

Excelの書類上に置かれているpictureのセルのアドレスを推定する

Posted on 8月 7, 2023 by Takaaki Naganoya

Excelのワークシート上にドラッグ＆ドロップして配置された画像のセルのアドレスを推定するAppleScriptの試作品です。

ただし、pictureオブジェクトは単にExcel書類上に重ね合わせて配置されている「異物」であり、どこかのセルに置かれているわけではありません。オブジェクトからpropertiesを取得しても、セルのアドレスを取得できたりはしません。ワークシート左上を原点とする座標値が取得できるだけです。

ただ、pictureの配置座標を取得して、その座標からセルを求める処理を行ったとしても（やりました）、配置座標と実際に置かれているセルは異なります。

実際に、Excelワークシート上に配置されている画像を個別に書き出す処理（リサイズして高解像度化する処理つき）を書いて動かしてみましたが、書き出したファイル名にセルのアドレスを反映させたら使いやすいのではないかと考え、解決策を試してみました。

上の画面キャプチャでいえば、R22C2のセルにpicture 1が存在している（始点座標が存在している）わけなのですが、実際に目で見た感じではR23C2に存在している（ユーザーがそのように作業を行った）ものと推定されます。この画像をファイル書き出しする際に、R22C2というファイル名をつけてしまっては、後で整理する際に「ナニコレ？」という話になってしまいます。

そこで、複数のセルにまたがってpictureオブジェクトの矩形領域と、それぞれ重なっているセルの矩形領域の共通部分を求め、面積を計算。共通面積が最も大きいものを採用するための試作品を作ってみた次第です。

AppleScript名：pictureが置かれているセルのアドレスを推定する.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/08/07
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—

use AppleScript
use scripting additions
use framework "Foundation"

set aRect to retExcelCellRect(22, 2) of me
set bRect to retExcelCellRect(23, 2) of me

tell application "Microsoft Excel"
　　tell active workbook
　　　　tell active sheet
　　　　　　set anImage to picture 1
　　　　　　
　　　　　　set tmpX to left position of anImage
　　　　　　set tmpY to top of anImage
　　　　　　set tmpW to width of anImage
　　　　　　set tmpH to height of anImage
　　　　end tell
　　end tell
end tell

set aZRect to current application’s NSMakeRect(tmpX, tmpY, tmpW, tmpH)

–共通部分の矩形座標を計算
set a1Res to (current application’s NSIntersectionRect(aRect, aZRect)) as {record, list}
set b1Res to (current application’s NSIntersectionRect(bRect, aZRect)) as {record, list}

–共通部分の面積を計算
set a1Area to calcAnArea(a1Res) of me
set b1Area to calcAnArea(b1Res) of me

–大小判定
if a1Area > b1Area then
　　return "a is larger"
else
　　return "b is larger"
end if

on retExcelCellRect(y, x)
　　tell application "Microsoft Excel"
　　　　tell active workbook
　　　　　　tell active sheet
　　　　　　　　tell row y
　　　　　　　　　　tell cell x
　　　　　　　　　　　　set xMin0 to left position
　　　　　　　　　　　　set yMin0 to top
　　　　　　　　　　　　set xWidth0 to width
　　　　　　　　　　　　set yHeight0 to height
　　　　　　　　　　end tell
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　set a1Rect to current application’s NSMakeRect(xMin0, yMin0, xWidth0, yHeight0)
　　return a1Rect
end retExcelCellRect

★Click Here to Open This Script　

マンデルブロ集合を文字で描画してRTFとして組み立ててテキストエディットでオープン

Posted on 8月 6, 2023 by Takaaki Naganoya

マンデルブロ集合を文字で組み立てて、デスクトップフォルダにRTF形式で保存して、テキストエディットでオープンして表示するAppleScriptです。

Courier Newはどの環境にも入っているフォントだと思っていますが、ない場合には別の等幅フォントのPostScript名に変更してください。また、フォントサイズや描画色を変更してみるといいかもしれません。

ちなみに、実用性はまっっっっったくありません。昔は計算に数分かかったのに、いまだとインタプリタ型の言語で動かしても1秒以下なんだ、へーという納得ができる程度です。

AppleScript名：マンデルブロ集合を描画してRTFとして組み立ててテキストエディットでオープン.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/08/06
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—
use AppleScript
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSFont : a reference to current application’s NSFont
property NSUUID : a reference to current application’s NSUUID
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSDictionary : a reference to current application’s NSDictionary
property NSLiteralSearch : a reference to current application’s NSLiteralSearch
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
property NSDocumentTypeDocumentAttribute : a reference to current application’s NSDocumentTypeDocumentAttribute

set outStr to generateMandel() of me
set anAssrStr to makeRTFfromParameters(outStr, "CourierNewPSMT", 12) of me

–結果のRTFをデスクトップ上に書き出す。ファイル名はUUID.rtf
set thePath to (POSIX path of (path to desktop)) & (do shell script "uuidgen") & ".rtf"
set aRes to my saveStyledTextAsRTF(thePath, anAssrStr)

set targAlias to (POSIX file (thePath as string)) as alias

tell application "TextEdit"
　　activate
　　open targAlias
end tell

–スタイル付きテキストを指定パス（POSIX path）にRTFで書き出し
on saveStyledTextAsRTF(targPath, aStyledString)
　　set targPathNSString to NSString’s stringWithString:targPath
　　set bstyledLength to aStyledString’s |string|()’s |length|()
　　set bDict to NSDictionary’s dictionaryWithObject:"NSRTFTextDocumentType" forKey:(NSDocumentTypeDocumentAttribute)
　　set bRTF to aStyledString’s RTFFromRange:(current application’s NSMakeRange(0, bstyledLength)) documentAttributes:bDict
　　return (bRTF’s writeToFile:targPath atomically:true) as boolean
end saveStyledTextAsRTF

–書式つきテキストを組み立てる
on makeRTFfromParameters(aStr as string, aFontName as string, aFontSize as real)
　　set aVal1 to NSFont’s fontWithName:aFontName |size|:aFontSize
　　set aKey1 to (current application’s NSFontAttributeName)
　　
　　set aVal2 to NSColor’s cyanColor()
　　set aKey2 to (current application’s NSForegroundColorAttributeName)
　　
　　set aVal3 to 0.0
　　set akey3 to (current application’s NSKernAttributeName)
　　
　　set keyList to {aKey1, aKey2, akey3}
　　set valList to {aVal1, aVal2, aVal3}
　　set attrsDictionary to NSMutableDictionary’s dictionaryWithObjects:valList forKeys:keyList
　　
　　set attrStr to NSMutableAttributedString’s alloc()’s initWithString:aStr attributes:attrsDictionary
　　return attrStr
end makeRTFfromParameters

–マンデルブロ集合を文字で描画して返す
on generateMandel()
　　set outStr to ""
　　
　　repeat with y from -12 to 12 by 1
　　　　
　　　　repeat with x from -39 to 39 by 1
　　　　　　
　　　　　　set ca to x * 0.0458
　　　　　　set cb to y * 0.08333
　　　　　　
　　　　　　set a to ca
　　　　　　set b to cb
　　　　　　
　　　　　　repeat with i from 0 to 15 by 1
　　　　　　　　set t to (a * a) – (b * b) + ca
　　　　　　　　set b to (2 * a * b) + cb
　　　　　　　　
　　　　　　　　set a to t
　　　　　　　　
　　　　　　　　if ((a * a) + (b * b)) > 4 then exit repeat
　　　　　　end repeat
　　　　　　
　　　　　　
　　　　　　if ((a * a) + (b * b)) ≤ 4 then
　　　　　　　　set outStr to outStr & " "
　　　　　　else
　　　　　　　　if i > 9 then set i to i + 7
　　　　　　　　set outStr to outStr & string id (48 + i)
　　　　　　end if
　　　　　　
　　　　end repeat
　　　　
　　　　set outStr to outStr & return
　　end repeat
　　
　　return outStr
end generateMandel

★Click Here to Open This Script　

PowerPointを操作するAppleScriptをScript Menuに入れて実行すると動作が完結しない問題

Posted on 8月 4, 2023 by Takaaki Naganoya

日常的に利用するAppleScriptは、macOS標準搭載のScript Menuに入れて使用しています。エンドユーザーに「Script Editor上で実行しろ」とかいうのは無茶ですし、「全部Appletに書き出してアプリケーションとして実行」とかいうのも、セキュリティ的な縛りが増えた環境においては、無茶な話です。だいたい、日常的に利用している数百本のAppleScriptを全部Appletに書き出すというのも（自動処理でできるけど）無茶な話です。

そのため、日常的に利用するAppleScriptは、個人的にScript Menuから実行していますし、Script Menuを「最終防衛線」として定義し、AppleがOSアップデートのたびに作成するバグに対して文句を言っています。Script Menu上で動かなかったら問題視しています。

さて、そこに新たな頭痛の種が舞い込んできました。ここ数日いじくりまわしているPowerPointです。

いつものように、Script Menuに操作系のScriptを入れて実行すれば、それでおしまい！　というわけには行きませんでした。PowerPointの書類からTOCつきのPDFを書き出すAppleScriptを書いて、Script Menuに入れたら実行できなくなりました（途中までは実行できるのに……）。Script Editor/Script Debugger上では問題なく実行できるのに、です。

この場合、Script Menuがランタイム環境（実行環境）になるわけで、各種セキュリティ設定もScript Menuに対して行っています。AppleScript Appletを数百個自動生成できたとしても、数百個のAppletに対してすべてセキュリティ設定を行うのは現実的な話ではありません。Script Menuに対して権限設定をまとめておけたほうが便利です。

そのため、Script Menuには「オートメーション」「フルディスクアクセス」「アクセシビリティ」など考えられる一通りのセキュリティ設定が行われているわけですが、先のPowerPointを操作するAppleScriptが、Script Menu上からは実行が完了しませんでした。

どうもファイルアクセス権限に関する問題（Script Editor上から実行しても、初回はダイアログが出る）のようなのですが、この権限がScript Menuから実行すると取得できないようで…

この問題をAppleに報告すべきなのか、Microsoftに報告すべきなのか、現状だと判断がつかないところです（たらいまわしにされる予感）。

PowerPointなんか使う方が悪い、という話までありそうな、、、、

PowerPoint書類の各スライドのタイトルを取得

Posted on 8月 3, 2023 by Takaaki Naganoya

PowerPoint書類（presentation）の各スライドのタイトルを取得するAppleScriptです。

正確にいえば、タイトルを取得するかもしれないAppleScriptです。本Scriptの実行時にはPowerPointで何らかのPPTX書類をオープンしていることを期待しています。

PowerPointをこづき回してみると、各スライドのタイトルを保持しているプロパティとかいったものが「ない」ことに気づきます。

ではどうやって取り出すかといえば、

（1）slideのplace holderを取得する
（2）place holder内にtext frameが存在しているかを確認
（3）text frameが存在している場合には、内部にアクセスして文字を取り出す

という手順になるようです。

ただし、place holderにアクセスする都合上、

スライドのレイアウトの種類によってはplace holderが存在していないものもあるため、place holderの存在確認から行うべきかもしれません。

また、slide内に複数のplace holderが存在する場合に、どれがtitleに該当するのかを調べる必要があるとか（座標とか、文字サイズとかを頼りに推測）、いろいろと処理が破綻しそうな「例外条件」が多数存在していそうです。

AppleScript名：各slideのタイトル文字列を取得 v2.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/08/03
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—

set tList to getEveryPPTSlideTItles() of me
–> {"Title", "1章", "Slide1", "Slide2", "2章", "Slide3", "Slide4"}

on getEveryPPTSlideTItles()
　　set tList to {}
　　
　　tell application "Microsoft PowerPoint"
　　　　tell active presentation
　　　　　　set sList to every slide
　　　　　　
　　　　　　repeat with i in sList
　　　　　　　　set j to contents of i
　　　　　　　　
　　　　　　　　tell j
　　　　　　　　　　
　　　　　　　　　　set plaList to every place holder
　　　　　　　　　　set aPla to contents of first item of plaList
　　　　　　　　　　set hText to (has text of text frame of aPla) as boolean
　　　　　　　　　　
　　　　　　　　　　if hText = true then
　　　　　　　　　　　　set hTextR to (content of text range of text frame of aPla) as string
　　　　　　　　　　else
　　　　　　　　　　　　set hTextR to ""
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　set the end of tList to hTextR
　　　　　　end repeat
　　　　　　
　　　　　　return tList
　　　　　　
　　　　end tell
　　end tell
end getEveryPPTSlideTItles

★Click Here to Open This Script　

PowerPointが扱うファイルパス形式が支離滅裂な件

Posted on 8月 2, 2023 by Takaaki Naganoya

いろいろ調べてみたら、PowerPointが扱うファイルパス形式に整合性がまったくないことがわかりました。なんなんでしょう、これは。

ファイルのオープン時：alias（HFS path）

これは、とくに問題はありません。最低限のラインはクリアしているといってよいでしょう。

PDF書き出し時：HFS pathのテキスト

fileオブジェクトではなくHFS pathの文字列です。ここでかなり「おかしなプログラムだな」という感想を抱きます。こんなおかしなデータを要求するのはPowerPointぐらいだと思いますよ？

PPTX書類の新規保存時：HFS pathのテキスト

PDF書き出しもPPTX書類の保存も、同じく「save」コマンドで行うので、仕様が同じなのも納得ですが、通常書類のsaveにこれでは相当変わった仕様にしか見えません。

書類のフルパス情報：POSIX path

これは、致命的におかしな挙動であり、呆れるほどおかしな仕様です。担当者が正気なのか疑わしいレベルです。Office 2011のPowerPointでpresentation（書類）のfull name（フルパス情報）を取得してみたところ、HFS path文字列が返ってきたという調査結果が残っていました。

いま、バージョン16.75のPowerPointのpresentation（書類）のfull name（フルパス情報）を取得すると、POSIX pathが返ってきます。

▲Office 2011のPowerPointのパス情報の記述

▲バージョン16.75のPowerPointのパス情報の記述

AppleScript用語辞書上の記載内容にはたいして変化はないのですが、こんな頭のおかしな状態になっているとは思いませんでした。正直、PowerPointで何かまとまった処理を行おうとは思ったことが（それほど）なかったのですが、Keynoteで山のようにいろいろ強烈なScriptを書いているので、PowerPointでもいろいろできるのでは？　と、冗談半分で試してこの通りです。

まさか、ExcelとWordもこの調子なのでは？（＾ー＾；

AppleScript名：オープン中の最前面のPowerPoint書類のフルパスの文字列を取得.scpt

set a to getPPTpath() of me
–> "Cherry:Users:me:Documents:2013-MacUDingCFUD.ppt"–Office 2011
–> "/Users/me/Documents/AppleScript 13/PowerPoint/TESTプレゼンテーション1 .pptx"–Office 2019

–オープン中の最前面のPowerPoint書類のフルパスの文字列を取得
on getPPTpath()
　　tell application "Microsoft PowerPoint"
　　　　set pCount to count every presentation
　　　　if pCount = 0 then return false
　　　　tell active presentation
　　　　　　–Documentのフルパスを取得する
　　　　　　set aPath to full name
　　　　　　return aPath
　　　　end tell
　　end tell
end getPPTpath

★Click Here to Open This Script　

PowerPointの書類からTOCつきのPDFを書き出すAppleScriptを書いた際には、頭のおかしなPowerPoint 16.75が返してくるパス形式をサブルーチン側で吸収して処理するようにしました。ただ、将来的にこの頭のおかしな形式からまともな形式に戻してきたときに問題が発生するので、再変更に備えてもう少し準備しておいたほうがよいのかもしれません。

このPowerPointの担当者は、頭がおかしいです。

AppleScript名：オープン中のPowerPoint書類のパスをalias形式で取得.scpt

set pptPath to getPPTpath() of me
–> alias "Macintosh HD:Users:me:Documents:AppleScript 13:PowerPoint:TESTプレゼンテーション1 （Sectionなし）.pptx"

–オープン中の最前面のPowerPoint書類のフルパスの文字列を取得
on getPPTpath()
　　tell application "Microsoft PowerPoint"
　　　　set pCount to count every presentation
　　　　if pCount = 0 then return false
　　　　
　　　　tell active presentation
　　　　　　–Documentのフルパスを取得する
　　　　　　set aPath to full name
　　　　end tell
　　end tell
　　
　　set aFile to POSIX file aPath
　　set anAlias to aFile as alias
　　return anAlias
end getPPTpath

★Click Here to Open This Script　

PowerPointのスライドから各種情報を取得

Posted on 8月 2, 2023 by Takaaki Naganoya

KeynoteからPDF書き出しを行う際に、デフォルトの機能ではTOCも何もついていないのですが、AppleScriptからあらゆる手段を講じてTOCつきで書き出せるようにしています（新刊「Keynote Scripting Book with AppleScript」に掲載）。

一方、PowerPointではどうかといえば、sectionを作成し章構成を分けて、スライドを章ごとに折りたためるようになっています。PDF書き出し時にこのsectionが反映されるということはまったくなく、sectionを追加しようが書き出されたPDFはそのままです。

このsection内のインデント情報が取得できれば、それを元にTOCを作ってもよいのですが、残念ながらインデント情報は取り出せないようです。

ただ、処理に必要な最低限の情報が取れるので、Keynoteと同レベルのTOCつきPDFをAppleScriptで合成することは可能と思われます。

AppleScript名：各スライドから情報を取得.scpt

★Click Here to Open This Script　

各スライドのタイトルを取得しようとしたら、素直に取得できず……かといって取れなさそうでもないので、いろいろ調べてみたら、どうやら取得できたようです。

AppleScript名：各slideのタイトル文字列を取得.scpt

tell application "Microsoft PowerPoint"
　　tell active presentation
　　　　set sList to every slide
　　　　
　　　　repeat with i in sList
　　　　　　set j to contents of i
　　　　　　tell j
　　　　　　　　set sInd to section index
　　　　　　　　set sNum to section number
　　　　　　　　set myLayout to layout as string
　　　　　　　　log {sInd, sNum, myLayout}
　　　　　　　　
　　　　　　　　set plaList to every place holder
　　　　　　　　set aPla to contents of first item of plaList
　　　　　　　　set hText to (has text of text frame of aPla) as boolean
　　　　　　　　log hText
　　　　　　　　
　　　　　　　　if hText = true then
　　　　　　　　　　set hTextR to (content of text range of text frame of aPla) as string
　　　　　　　　　　log hTextR
　　　　　　　　end if
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

★Click Here to Open This Script　

新発売：Keynote Scripting Book with AppleScript

Posted on 7月 29, 2023 by Takaaki Naganoya

Piymaru Softwareによる電子書籍の82冊目、「Keynote Scripting Book with AppleScript」を発売しました。PDF 434ページ＋サンプルScript Zipアーカイブで構成されています。macOS標準装備のScript Menuに入れてKeynoteをコントロールするメニューScript集も添付しています。

→ 販売ページ

初級、中級、上級のScripting解説内容に加え、大量かつ強力なAppleScriptサンプルを掲載しています。これは、実際に筆者が自分のマシンにインストールして使っているものと同じものです。

実用編

　付録Script Menuスクリプトのインストール
　Script Menuスクリプトのインストール①
　Script Menuスクリプトのインストール②

TOCつきでPDF書き出し
　最前面の書類をTOCつきPDF出力①
　最前面の書類をTOCつきPDF出力②
　最前面の書類をTOCつきPDF出力③
　すべてデスクトップ上にPDF出力

クリップボードに入れたものを処理
　指定色でモノクロ化してクリップボードへ
　赤でモノクロ化してクリップボードへ
　水色でモノクロ化してクリップボードへ
　グリーンでモノクロ化してクリップボードへ
　マゼンタでモノクロ化してクリップボードへ

自動スライドめくり
　冒頭から末尾まで自動スライドめくり

表を処理
　表オブジェクトの重なり合い（２つ以上対応）を検出
　AppleScript Recordから表を作成
　選択中のセルの文字列長さを一覧表で表示
　全スライドの表で行番号入り表の連番修正
　現在のスライド上にある選択中の表のカラム幅を自動調整
　現在のスライド上にあるすべての表のカラム幅を自動調整
　選択中のページのオリジナル表のセル幅に以降の表のセル幅を統一
　選択中のページの表1のセル幅に以降の表のセル幅を統一
　現在のスライド上にあるすべての表のカラム幅を自動調整
　マル付き数字のインクリメント（＋１）
　マル付き数字のデクリメント（ー１）
　マル付き数字のリナンバー

現在のスライドからテキストアイテムを色で選択
　x色系のみ選択

選択中の最前面の書類に対する処理
　連続する同一タイトルに子番号を振る
　スライド末尾にQRコードを追加

選択中の画像へのぼかしフィルタ処理
　選択中の画像にぼかし処理

選択中の各種オブジェクトへの処理
　オブジェクトの重なり合い（２つペア）を検出してグループ化
　テキストを座標値でソートしてまとめてクリップボードへ
　横幅を均等に変更
　数える
　選択中のオブジェクトのうちテキストだけ残す

現在表示中のスライドに対する処理
　テキストを上から順に連結してクリップボードに転送
　指定した文字で囲まれたキーワードの色を置換する
　PDFに書き出してオープン

選択中のテキストアイテムの処理
　AppleScriptとみなして、構文確認してスタイル付きテキストとして書き戻す
　AppleScriptとみなして、構文確認してスタイル付きテキストとして書き戻す（結果つき）
　それぞれ個別のAS書類として保存する
　まとめて1つのAS書類として保存する
　テキストアイテム中のURLにリンクを張って
　HTMLタグを外す
　文字の実際の幅でリサイズ
　文字の実際の幅と高さでリサイズ

選択中のスライドの処理
　すべての表の文字色を黒にする
　タイトルをまとめてクリップボードに入れる
　現在のスライド以降の同じスライドレイアウト（同階層の）スライドのタイトルを取得してクリップボードへ
　現在のスライド以降の同じスライドレイアウト（同階層）のスライドのタイトルを取得して改行でまとめてクリップボードへ（末端レベルではないものが対象）
　選択中のスライドのグループアイテムをグループ解除
　選択中のスライド中の各テキストアイテムのうち指定フォントサイズのものの色を変更
　不透明度が100でないオブジェクトの透明度を解除
　選択スライド枚数を数える
　選択中のスライドのshapeのうち最も右上にあるものの座標を右上角に変更

目次作成
　クリップボードへ転送
　Numbersの表を作成

カレンダー作成
　指定月の日曜日はじまりカレンダーを表で作成

オブジェクトの詰め込み
　指定範囲にスライド上のオブジェクトを詰め込み①
　指定範囲にスライド上のオブジェクトを詰め込み②

２ページ間（現在、次）のオブジェクト整頓
オブジェクトの位置をそろえる

没スライドに対する処理
　現在の書類と同じ階層に没スライド入れを作成

指定画像をbase64エンコード文字列に変換→デコード

Posted on 7月 29, 2023 by Takaaki Naganoya

指定画像をbase64でエンコードしたのちに、デコードして画像に戻すAppleScriptです。

base64文字列からのデコードだけをテストしたかったのですが、テストのために本来は不要な画像のエンコード部分を付け足しています。

macOS 13.5上で動作確認していますが、OSのバージョンやAppleScriptのバージョンに依存はしないことでしょう。

AppleScript名：指定画像をbase64エンコード文字列に変換→デコード.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/07/29
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—
property NSData : a reference to current application’s NSData
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSDataBase64EncodingEndLineWithLineFeed : a reference to current application’s NSDataBase64EncodingEndLineWithLineFeed

use AppleScript version "2.8" — macOS 12 or later
use framework "Foundation"
use scripting additions

set aFile to choose file of type {"public.image"}
set aStr to base64StringFromImageFile(aFile) of me
–> "iVBORw0KGgoAAAANSUhEUgAAAIAAAACACAYAAADDPmHLAAAKuWlDQ1BJQ0MgU……"

set aImage to decodeImageFromBase64String(aStr) of me
–> (NSImage)

–Base64 Decode
on decodeImageFromBase64String(aString)
　　set restoreData to NSData’s alloc()’s initWithBase64EncodedString:aString options:0
　　set restoreImage to NSImage’s alloc()’s initWithData:restoreData
　　return restoreImage
end decodeImageFromBase64String

–Base64 Encode
on base64StringFromImageFile(aFile)
　　set aPOSIX to POSIX path of aFile
　　set anImage to NSImage’s alloc()’s initWithContentsOfFile:aPOSIX
　　set imageRep to NSBitmapImageRep’s alloc()’s initWithData:(anImage’s TIFFRepresentation())
　　set aPNGdat to imageRep’s representationUsingType:(NSPNGFileType) |properties|:(missing value)
　　set base64Str to aPNGdat’s base64EncodedDataWithOptions:(NSDataBase64EncodingEndLineWithLineFeed)
　　set bStr to (NSString’s alloc()’s initWithData:base64Str encoding:(NSUTF8StringEncoding))
　　return bStr as string –or return NSString (delete as string) for speedy processing
end base64StringFromImageFile

★Click Here to Open This Script　

PowerPointで最前面の書類をPDF書き出し

Posted on 7月 29, 2023 by Takaaki Naganoya

よくある、Microsoft PowerPointで、オープン中の最前面の書類を指定のパスにPDFで書き出すAppleScriptです。M1 Mac mini＋macOS 13.5上で動作するMicrosoft PowerPointバージョン16.75で確認しています。

スクリプトエディタ上で動かしてみましたが、デスクトップ上にファイルを書き込もうとしたときに、初回のみPowerPointがデスクトップフォルダにアクセスしてよいか、OSが確認ダイアログを表示してきました。こういう動作はScriptからのコントロール時には困ります。自動処理を行う前にクリアしておきたい（あらかじめダイアログ表示＋認証を済ませておきたい）ところです。

▲PowerPointから書き出したPDF

Microsoft PowerPointのAppleScript用語辞書を確認してみたところ、「export」コマンドが存在しません。情報をいろいろ調べてみたところ「save as PDF」で指定パスにPDFを保存するようです。

さらに、こうした場合にsaveコマンドで指定するファイルパスは、fileオブジェクトで指し示しますが、PowerPointでは少々事情が異なるようでした。fileを指定すると、書き出されません。HFS形式のパスをテキストで指定する必要がありました。どうもこのあたり、ところどころバグめいた実装が散見されます。

Excelへの画像貼り込みScriptのように、POSIX pathでPDF書き出し先を指定してみましたが、こちらはPOSIX pathで指定しても書き出せませんでした。

AppleScript名：最前面の書類をPDF書き出し.scpt

set theOutputPath to ((path to desktop folder) as string) & (do shell script "uuidgen") & ".pdf"

tell application "Microsoft PowerPoint"
　　tell active presentation
　　　　save in theOutputPath as save as PDF
　　　　–保存先のファイルパスを文字列で指定する必要がある
　　　　–fileオブジェクトで指定すると書き出されない（バグのような挙動）
　　end tell
end tell

★Click Here to Open This Script　

出るか？「AppleScript最新リファレンス」のバージョン2.8対応版

Posted on 6月 15, 2023 by Takaaki Naganoya

Piyomaru Softwareの電子書籍も、いまでは80冊ほど出していますが、最初のきっかけは「AppleScript最新リファレンス」という名前の薄い本（500ページぐらい）でした。

▲計画段階の「AppleScript最新リファレンス」。ここから、実際に書けない記事をふるい落とすという「妥協」が…….

その後、何回かアップデート計画が浮上しては、あまりの分量の多さの前に挫折。ゼロから書くよりも、アップデートする作業の方が実は大変です。

「AppleScript最新リファレンス」はいわば何でもありの「大辞典」に相当するものです。「これでは更新し切れないねー」とあきらめて、小さなテーマごとに最新情報を集めて各種電子書籍を書くという「小辞典」「中辞典」方式を展開。

項目数の少ない「小辞典」「中辞典」で情報のリストアップと更新を行い、その結果を「大辞典」に反映させるというやりかたです。

ここに来て、ようやく更新できるんじゃないか？（仮説）という雰囲気になってきたため、更新をすすめています。まえがきとあとがきを書き、その他のコンセプトに関わるページを書いてみて「いけそうかも」という手応えを得ています（挫折する可能性はあるかも）。

「AppleScript最新リファレンス」はMacDownとPages（扉ページや凝ったレイアウトが必要なページだけ）を用いて作成したのですが、記述環境としてのMacDownがあまりにも使えないので、MarkdownのページはPagesで作り直しています。

最新版のmacOSが動くマシンが手元にM1 Mac miniの1台しかないので、これにBeta版のmacOS 14などを入れてしまった日にはスクリーンショットが撮れません。正確に言えば、スクリーンショットを撮っても使えません（禁止事項）。

なので、外付けSSDへのベータ版のmacOSのインストールは必須なのですが、macOS 13の際に「リリース後には、外付けSSDからの複数バージョンのOSのインストールや起動を禁止する」というジャイアン風味たっぷりなAppleの対応。さらに、β版のmacOSよりもRelease版のmacOSの方がバグだらけで（OS X 10.13、10.15にひきつづき3回目）、macOS 14についてもβプログラムの存在意義について疑問視しています。

とにかく、macOS 14についてはβ版をガン無視して「AppleScript最新リファレンス」のアップデートを行うべき、という判断です。

Claris FileMaker Pro 2023と、Microsoft Officeの最新版については、AppleScript記述方法に関する記事は掲載したいところです（Developer Program入ってるし、Office 365の契約しているし）。Adobe Creative Cloudについては契約していないので、このあたりの話は書けません。

AppleScriptコマンドリファレンスについては、各種書籍用にアップデートしながらメンテナンスしているので、これは最新版を掲載できることでしょう。エラーコード表も然りです。

全体的に、Script Sampleを掲載しまくるような本ではなく、それぞれの項目について「最新環境ではどうなっているのか」という情報を提供する書籍になることでしょう。

そして、挫折しなければv2.8対応版を出せることでしょう。

Pixelmator Proで2つの書類のレイヤー表示状態をシンクロ

Posted on 6月 6, 2023 by Takaaki Naganoya

Pixelmator Pro上でオープン中の2つの書類のレイヤー表示状態をシンクロさせるAppleScriptです。

ちょうど、「ゆっくりAppleScript解説」の続刊を作成中で、レイヤー別に部品が分かれている書類（すべてのレイヤー名は同じ）の表情を「同じ状態」にするのが面倒です。

正直なところ、表情名を入力すると該当するレイヤーを表示状態にしてほしいぐらいです。

そこまで行かないにせよ、1つの書類に対して行ったレイヤー表示操作を、もう一度別の書類に対して行わなくてはならないのは大変です（2つの書類を統合して、キャラクター別の差異をレイヤーで吸収するという手もありますが、、、）。

そこで、2つの書類をオープンしておき、最前面の書類のレイヤー表示状態（＝表情の操作）を他方の書類に反映させるAppleScriptを書いてみました。

Pixelmator Proバージョン3.3.6に対してレイヤーの取得を指令してみましたが、なかなか大変です。再帰処理で一番上から末端まで、表示状態になっているレイヤーだけを抽出できるかと考えていたのですが、そうもいきません。

再帰処理がダメなので、もうレイヤー名を決め打ちで指定するようにして（つまり、この用途以外には使えないものと割り切って）、各レイヤーグループ内を走査するように記述しました。

AppleScript名：同一名、同一構造の2つの書類のレイヤー表示状況をシンクロ.scpt

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Pixelmator Pro"
　　set allD to {}
　　
　　set dList to name of every document
　　–> {"ゆっくり素材れいむ.pxd", "ゆっくり素材まりさ.pxd"}
　　
　　tell front document
　　　　set d1Name to name of it
　　　　if d1Name contains "れいむ" then
　　　　　　set d2Name to retAnItemByCond(dList, "れいむ") of me
　　　　else
　　　　　　set d2Name to retAnItemByCond(dList, "まりさ") of me
　　　　end if
　　　　
　　　　tell layer "root"
　　　　　　tell layer "顔"
　　　　　　　　set dList to every layer
　　　　　　　　repeat with i in dList
　　　　　　　　　　set j to contents of i
　　　　　　　　　　tell j
　　　　　　　　　　　　set ddList to (name of every layer whose visible is true)
　　　　　　　　　　　　if ddList is not equal to {} then
　　　　　　　　　　　　　　set aCon to contents of first item of ddList
　　　　　　　　　　　　　　set the end of allD to {"root", "顔", name of j, aCon}
　　　　　　　　　　　　end if
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　tell document d2Name
　　　　repeat with i in allD
　　　　　　copy i to {L1, L2, L3, L4}
　　　　　　tell layer L3 of layer L2 of layer L1
　　　　　　　　set tmpL to name of every layer
　　　　　　　　repeat with ii in tmpL
　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　tell layer jj
　　　　　　　　　　　　if jj = L4 then
　　　　　　　　　　　　　　set visible to true
　　　　　　　　　　　　else
　　　　　　　　　　　　　　set visible to false
　　　　　　　　　　　　end if
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　end tell
　　　　end repeat
　　end tell
end tell

on retAnItemByCond(aList, aParam)
　　repeat with i in aList
　　　　set j to contents of i
　　　　
　　　　if j does not contain aParam then
　　　　　　return j
　　　　end if
　　end repeat
end retAnItemByCond

★Click Here to Open This Script　

macOS 14, Sonoma

Posted on 6月 6, 2023 by Takaaki Naganoya

WWDC23でmacOS 14, Sonomaが発表されたとのことで、WWDCのビデオを見たかぎりではさほどmacOS 13から変わっていないように見えます。

とにかく、Beta段階では安定して動いていたものが、Release時に崩壊してしばらくまともに動かず、1年のうちでまともに安定して使える時期が短いとかいう冗談は勘弁してほしいところです。

日本語入力IMがメモリをバカ喰いして固まるとか、メールをScriptから操作すると表示用プロセスが2つずつ生成されて解放されなくてメモリが埋まってほぼ動かなくなるとか、Finder上の基礎的な操作が効かないとか、macOS 13は悪い冗談のオンパレード。

BetaよりもReleaseのほうが低品質というのでは、Beta Programの位置付けがよくわかりません。

Claris FileMaker 2023がリリースされる

Posted on 5月 23, 2023 by Takaaki Naganoya

日本国内においても、Claris FileMaker 2023および前バージョンのClaris FileMaker v19.xからのアップデータがリリースされました。「2023」と銘打っているからには、翌年には「2024」が出てくることが期待されるわけで……販売戦略的なものがいろいろ変更されることがうかがわれます。

商標その他で記述すべき名称は変わっていますが、macOS上でのプロセス名としては「FileMaker Pro」であることに変更はありません。Clarisの（技術サポート系の）Web上の表記は「FileMaker Pro 20.1」となっているようです。

なお、macOS上でのバンドルIDは「com.filemaker.client.pro12」のままで変更されていません。

アプリケーションのアイコンは変更されています。

まだ確認中ではありますが、AppleScript用語辞書も前バージョンから変更なく、書籍のアップデートもとくに行わなくてもよさそうな雰囲気であります（アイコンと画面スナップショットの都合で差し替えるか別の本にする必要があるかもしれません）。

「Claris FileMaker 2023」が製品シリーズを包括する名称で、macOS上で動作するクライアントソフトウェアについては「Claris FileMaker Pro 2023」であると認識しています。

Claris FileMaker Pro 2023がサポートするOSは、macOS 12と13。Windows 10（22H2、64bitのみ）、Windows 11（22H2、64bitのみ）。

FileMaker GoはiOS 16/iPadOS 16が動作するデバイスが稼働対象です。

指定のアプリケーションの実行アーキテクチャを変更

Posted on 5月 3, 2023 by Takaaki Naganoya

指定のアプリケーションの実行アーキテクチャを変更するAppleScriptです。

–> Download setArchLib.scptd

Apple Silicon Mac上でアプリケーションをRosetta 2によってIntel 64バイナリのARMエミュレーション動作を行うかどうかは、Finder上の「Rosettaを利用して開く」のチェックボックスによって制御されています。

これを、外側（FinderのGUI）から操作するか、内側（何らかのOS内のサービスやメタデータ）から操作するかによって、その「やりかた」は大きく異なります。

自分は、できることなら極力GUI Scriptingを使いたくない派なので、「そういえばASからこのあたりの設定をいじくった記憶がない」と思いつつ、「内側から操作する方法はないものか」と考えていました。

さっそくGithub上でいろいろ調査してみたところ、LaunchServiceのプライベートAPIに「_LSSetArchitecturePreferenceForApplicationURL」というものがあって、これを呼ぶことで処理を実現できそうだということが判明。

処理内容は、アゴが外れそうなほど簡単なので、AppleScript（AppleScriptObjC）でも普通に書けそうな勢いでしたが、アンダースコアで始まるAPIはAppleScriptにBridgeしにくく、もともとのプロジェクトのもの（UNIXのコマンドラインから呼び出す「SetArchPrefForURL」プロジェクト）をビルドしたバイナリをScriptバンドル内に入れて、呼び出すようにしてみました。

Cocoa Frameworkのプロジェクトを作成して、AppleScriptから普通にPOSIX pathとCPUアーキテクチャを渡せば結果をbooleanで返してくるようなスタイルに書き換えようとして、途中で頓挫してしまいました。そんなに気合いを入れる内容でもないので、こんなものでいいんでしょう。

AppleScript名：setArchLib.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2023/05/03
—
–　　Copyright © 2023 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set appPath to choose file of type {"com.apple.application-bundle"}
–set archStr to "x86_64"
set archStr to "arm64"

set archRes to setArchForApp(appPath, archStr as string) of me

on setArchForApp(appPath, archStr as string)
　　if archStr is not in {"x86_64", "arm64"} then error "Invalid architecture"
　　
　　set exePath to POSIX path of (path to resource "SetArchPrefForURL")
　　set sRes to do shell script (quoted form of exePath) & " " & (quoted form of POSIX path of appPath) & " " & archStr
　　return (sRes = "") as boolean
end setArchForApp

★Click Here to Open This Script　

画像をExcelのワークシート上に配置

Posted on 4月 4, 2023 by Takaaki Naganoya

Microsoft 365のExcel v16.71、Windows版とmacOS版のソースコードが共通化されたというふれ込みではあるものの、実はけっこうフォーム部分が違うし、VBのマクロエディタで日本語が記入できないとか、互換性のない関数（Mac上で動作しないENCODEURL、Switch,IFS、FILTERXML、WEBSERVICEなどの関数）の存在など、いろいろ勘弁してほしい出来です。

しばらくはNumbersだけで用が済んでいたのですが、ここのところWindows版のExcelの講座なども行っていたので、併せてmacOS版のExcelについても追加調査。細かい点のチェックを行っていました。

そんなExcelでアドインのオンラインストアからQRコード作成用アドインを探してみたところ、フリーなものは存在していないようです。

Cocoaの機能を利用すれば、割とすぐにできてしまう程度のQRコード。わざわざアドインの力を利用する必要などなかったのです。AppleScriptでQRコードを生成して、Excelのワークシートに差し込めばよいだけです。

ところが、ひさしぶりにExcelのScriptを引っ張り出してきて、昔書いた「Excelに指定の画像を配置する」Scriptを実行してみたところ、エラーで動きません。

ワークシート上にshapeを作成できるのに、そのshapeに指定パスの画像を割り当てる処理でエラーになります。

そんな時、「出来の悪いプログラマは、POSIX pathで誤魔化して実装する」という経験則が思い出されました。

目を閉じると、AppleのKeynoteで一時期行われていた、画像配置コマンドにPOSIX pathを要求していたアレな実装であるとか（あれはひどかった）、いまだにアレであり続けているAdobe Acrobat DistillerのdistillコマンドがPOSIX pathを要求する件であるとか（file pathって書いてあるのに、aliasじゃなくてPOSIX pathを要求するという地雷仕様）、枚挙にいとまがありません。

そんなわけで、普通に書いても通らなかったのでパスをPOSIX pathで与えてみたところ、見事（？）配置されました。

AppleScript名：画像をワークシート上に配置.scpt

set anImagePath to choose file
set anImagePOSIX to POSIX path of anImagePath

tell application "Microsoft Excel"
　　set cwb to workbook 1
　　tell cwb
　　　　tell worksheet 1
　　　　　　set aPicShape to make new shape at the beginning
　　　　　　set width of aPicShape to 312
　　　　　　set height of aPicShape to 312
　　　　　　user picture of aPicShape picture file anImagePOSIX
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

Keynote,Pages,Numbers v13.0がリリースされる

Posted on 4月 2, 2023 by Takaaki Naganoya

Keynote, Pages, Numbersのバージョン13.0がリリースされました。AppleScript用語辞書的な変更点はありません。

Keynote v11からずっと、新規書類を保存するとエラーになる。Full Disk Accessの権限をKeynoteに与えていてもエラーになる、という重大な問題が解消されないままである、という認識でおりました。状況はKeynote v13.0でも変わりません。

これは、Apple側が問題として認識していないのではないか？　という仮説を立て、いろいろ試してみました。

まずは、v12から継続している状況についての説明。Keynoteで新規書類を保存する際に「as Keynote」という、明らかに「指定してくださいね」というオプションがAppleScript用語辞書の中にあるので、指定したくなるところですが

AppleScript名：Keynoteで書類を新規保存（A）.scpt

set newFile to ((path to desktop) as string) & "newDoc1111.key"

tell application "Keynote"
　　set newDoc to make new document
　　save document 1 in file newFile as Keynote
end tell

★Click Here to Open This Script　

これを指定するとエラーになります。これが、Keynote v12.0から続いており、１年以上継続している状況です。以前のバージョンで通っていた記述がエラーを出すようになった、というものです。

ふとここで、「as Keynote」というオプション指定をはずしてみると…….

AppleScript名：Keynoteで書類を新規保存（A）.scpt

set newFile to ((path to desktop) as string) & "newDoc1111.key"

tell application "Keynote"
　　set newDoc to make new document
　　save document 1 in file newFile
end tell

★Click Here to Open This Script　

エラーが出なくなりました！！！（＾ー＾；；；；　ファイル保存もできました。

なんなんでしょう、これは、、、、

Xcode 14.2でAppleScript App Templateを復活させる

Posted on 3月 21, 2023 by Takaaki Naganoya

AppleScript＋Xcodeでアプリケーション開発を行う方法についてわかりやすくまとめた電子書籍「AppleScript＋XcodeでつくるMacアプリ　Xcode 14対応」を刊行しました（PDF 448ページ＋付録、サンプルXcode Project Zipアーカイブ）。

この書籍の中では、テンプレートがXcode 14.2に存在していないので、書籍添付のプロジェクトをコピーして使ってください、という説明を行っています。

と、そんな本をまとめたところ、edama2さんから「なんか、前バージョンのXcodeからテンプレートをコピーして来れるみたいだよ」という話が！

早速、調べてみました。edama2さんから教えていただいた記事のとおりにはいかなかったので、Xcodeのバージョンによっては細部が変わっているようです。

自分は、Apple Developer Connectionに契約しているので、古いバージョンのXcodeもダウンロードできます。古いといっても古すぎるのはどうかと思いますので、ここではXcode 13.2をダウンロードしてきました。アーカイブ展開してさっそく、Xcode 13.2のバンドルパッケージ内にアクセスします。

Xcode 13.2.appをFinder上で選択して、マウスの右ボタンクリックでコンテクストメニューを表示させ、「パッケージの内容を表示」を実行。

/Contents/Developper/Library/Xcode/Templates/Project Templates/macOS/Other

の中に「AppleScript App.xctemplate」が存在していました。

この「AppleScript App.xctemplate」をXcode 14.2（記事執筆時最新）が認識するテンプレートのフォルダにコピーすれば使えるでしょう。

~/Library/Developer/Xcode/Templates

の中にコピーすると、Xcodeが14.2が認識してくれました。

Xcode 14.2を起動し、File＞New Project

「AppleScript App」を選択すると、問題なく新規プロジェクトが作成できます。

テンプレートをZip圧縮して、ダウンロードできるようにしておきます。

Download Templates.zip

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

投稿者: Takaaki Naganoya

新発売：Cocoa Scripting Course #6, PDFKit

Skim Notesのじっけん

Excelの書類上に置かれているpictureが置かれているセルのアドレスを推定する v2

Excelの書類上に置かれているpictureのセルのアドレスを推定する

マンデルブロ集合を文字で描画してRTFとして組み立ててテキストエディットでオープン

PowerPointを操作するAppleScriptをScript Menuに入れて実行すると動作が完結しない問題

PowerPoint書類の各スライドのタイトルを取得

PowerPointが扱うファイルパス形式が支離滅裂な件

ファイルのオープン時：alias（HFS path）

PDF書き出し時：HFS pathのテキスト

PPTX書類の新規保存時：HFS pathのテキスト

書類のフルパス情報：POSIX path

PowerPointのスライドから各種情報を取得

新発売：Keynote Scripting Book with AppleScript

指定画像をbase64エンコード文字列に変換→デコード

PowerPointで最前面の書類をPDF書き出し

出るか？「AppleScript最新リファレンス」のバージョン2.8対応版

Pixelmator Proで2つの書類のレイヤー表示状態をシンクロ

macOS 14, Sonoma

Claris FileMaker 2023がリリースされる

指定のアプリケーションの実行アーキテクチャを変更

画像をExcelのワークシート上に配置

Keynote,Pages,Numbers v13.0がリリースされる

Xcode 14.2でAppleScript App Templateを復活させる