各種GUIアプリ書類のオープン速度を向上するためにUIアニメーションの一時停止を

AppleScriptから各種GUIアプリを操作すると、各種GUIアプリ上の操作に要する時間がそのまま必要になります。端的なところでいえば、書類のオープン時のアニメーションも毎回行われるわけで、割と無意味なアニメーションに、そこそこの時間が消費されています。

そのUIアニメーションを無効化する処理について調査したところ、割と簡単に情報が見つかりました。

ここに掲載しているサンプルAppleScript（要・Metadata Lib）では、Finder上の最前面のウィンドウで選択中のフォルダ以下にあるPages書類をSpotlightの機能を用いてすべてピックアップし、それらを「UIアニメーションあり」「UIアニメーションなし」の条件でオープン/クローズだけ行うものです。

結論をいうと、M2 MacBook Air上で通常のUIアニメーションつきの処理では68秒かかっていたものが、UIアニメーションを無効化するだけで43秒で処理できました（125個のPages書類で実験）。

これはちょうど、M1 MacからM4 Macに買い替えるぐらいの処理速度の向上が、ただUIアニメーションを無効にするだけで実現できたということを意味します。

1書類あたり0.2秒の処理速度向上が見られたわけですが、これが400個の書類を処理するとなれば80秒も変わってくるわけで、割と洒落にならない速度向上が実現できます。もっと早く調べておけばよかったと思うことしきりです。

AppleScript名：UI アニメーションの無効化による速度向上実験.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/09/22
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use mdLib : script "Metadata Lib"

tell application "Finder"
　　set aSel to (selection as alias list)
　　if aSel = {} then
　　　　set origPath to choose folder
　　else
　　　　set origPath to (first item of aSel)
　　end if
end tell

–SpotlightでPages書類を検出
set aResList to perform search in folders {origPath} predicate string "kMDItemContentType == %@ || kMDItemContentType == %@" search arguments {"com.apple.iwork.pages.sffpages", "com.apple.iwork.pages.pages"}
–return aResList

–UI Animationを許可
set a1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
openClosePagesDocs(aResList, true) of me
set b1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
set c1Dat to b1Dat – a1Dat

–UI Animationを禁止
set a2Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
openClosePagesDocs(aResList, false) of me
set b2Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
set c2Dat to b2Dat – a2Dat

return {c1Dat, c2Dat, length of aResList}

on openClosePagesDocs(aResList, animationF)
　　if animationF = true then
　　　　–UI Animationをオンにする
　　　　try
　　　　　　do shell script "defaults delete NSGlobalDomain NSAutomaticWindowAnimationsEnabled"
　　　　end try
　　else –UI Animationをオフにする
　　　　do shell script "defaults write NSGlobalDomain NSAutomaticWindowAnimationsEnabled -bool NO"
　　end if
　　
　　–Pages書類を順次オープンしてタイトル（？）を取得
　　set pagesTitleList to {}
　　repeat with i in aResList
　　　　set aFile to POSIX file i
　　　　
　　　　tell application "Pages"
　　　　　　open (aFile as alias)
　　　　end tell
　　　　
　　　　tell application "Pages"
　　　　　　close front document saving no
　　　　end tell
　　　　
　　end repeat
　　
　　if animationF = false then
　　　　–UI Animationをオンにする
　　　　try
　　　　　　do shell script "defaults delete NSGlobalDomain NSAutomaticWindowAnimationsEnabled"
　　　　end try
　　end if
end openClosePagesDocs

★Click Here to Open This Script　

指定フォルダ内から指定拡張子のファイルを取得し、エイリアスだったらオリジナルのパスをPOSIX pathで取得

Posted on 9月 20 by Takaaki Naganoya

指定フォルダから、指定拡張子のファイルを取得し、取得したファイルがエイリアス書類だったらオリジナルのパスを返すAppleScriptです。

AppleScriptを指定スケジュールで実行するAppleScriptを作成しており、スケジュールフォルダ以下に「毎月15日 15時」といった名前のフォルダを作っておき、その中に入れたAppleScriptを指定スケジュールで実行するようにしてありました。

ただ、フォルダ内に入れるのが「AppleScript書類そのもの」だと、運用上いろいろまずい（同じScriptの複製が大量にできてしまうとか）ので、エイリアスを入れても反応するように、本Scriptを書いてみた次第です。

割とちゃんと動いているように見えます。

AppleScript名：指定フォルダ内から指定拡張子のファイルを取得し、エイリアスだったらオリジナルのパスをPOSIX pathで取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/09/19
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use scripting additions

set aRoot to choose folder

set scptList to getFilePathListWithResolveAlias(aRoot, "scpt") of me
–> {"/Users/me/Documents/sample2.scpt", "/Users/me/Documents/sample1.scpt"}

on getFilePathListWithResolveAlias(aFol, aExt)
　　set aURL to current application’s |NSURL|’s fileURLWithPath:(POSIX path of aFol)
　　# 指定フォルダの直下のファイルを取得
　　set filePaths to current application’s NSFileManager’s defaultManager’s ¬
　　　　contentsOfDirectoryAtURL:aURL ¬
　　　　　　includingPropertiesForKeys:{current application’s NSURLNameKey} ¬
　　　　　　options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) ¬
　　　　　　|error|:(missing value)
　　set f0List to filePaths as list
　　if f0List = {} then return {}
　　
　　set f2List to {}
　　repeat with i in f0List
　　　　set tmpPath1 to POSIX path of i
　　　　set tmpPath2 to (my fullpathOfOriginalFileForAlias:tmpPath1)
　　　　set tmpPath to (current application’s NSString’s stringWithString:(tmpPath2))
　　　　set the end of f2List to tmpPath as string
　　end repeat
　　
　　return f2List
end getFilePathListWithResolveAlias

–エイリアスファイルのパスからオリジナルのファイルパス（POSIX Path）を返す
on fullpathOfOriginalFileForAlias:posixPath
　　tell current application’s |NSURL|
　　　　set anNSURL to its fileURLWithPath:posixPath
　　　　set theData to its bookmarkDataWithContentsOfURL:anNSURL |error|:(missing value)
　　　　set theResult to its resourceValuesForKeys:{current application’s NSURLPathKey} fromBookmarkData:theData
　　end tell
　　
　　return (theResult’s objectForKey:(current application’s NSURLPathKey)) as text
end fullpathOfOriginalFileForAlias:

★Click Here to Open This Script　

macOS 15.xで自作AppleScriptライブラリの一部がScript Menuから使えなくなったので修正

Posted on 9月 19 by Takaaki Naganoya

X（旧Twitter）上でPiyomaru SoftwareのAppleScriptライブラリについてフィードバックをいただきました。おおよそ改修が済んでいるため、ドキュメントを書き次第、最新版をBlogからダウンロードできるようにしておきます。

こうしたフィードバックを得るために公開しているので、動作しないとか、予想外の動作を行った場合にはフィードバックしていただきたいところです（すぐに対処できる保証はないのですが）。

確認された現象

Piyomaru Software制作のAppleScriptライブラリの一部で、macOS 15.xのスクリプトメニューに呼び出しScriptを入れた場合に実行できないものがありました。その一方で、スクリプトエディタ/Script Debugger上では実行できます。

・AirSharing Lib
・Choose location Lib
・Display Youtube Lib
・Pickup Color Lib

修正して動作するようになった事例

CheckboxLibについては、SDEF中のdocumentからのムービーおよび画像へのリンクを削除。

Enumをas stringでstringにcast処理していた箇所が、スクリプトメニュー上では動作しなくなっていた（→ stringへのcastをやめることで問題解消）。

choose color Libも同様に、Enumをas stringでstringにcast処理していた場所で、スクリプトメニュー上では動作しなくなっていたので修正。

動作条件そのものが変更になったライブラリ

・Display youtube Lib
macOS 15上ではInfo.plistにNSAppTransportSecurityのエントリを追加してアプレット書き出しが必要です。
ただし、macOS 26上ではスクリプトメニュー上で呼び出しScriptを実行しても、問題なくYouTubeムービーの再生が可能です。

問題を解消できていないライブラリ

目下、スクリプトメニューから呼び出すと動作しないライブラリは以下の通り。

・AirSharing Lib
・Choose location Lib

シンプルな文字置換

Posted on 9月 13 by Takaaki Naganoya

AppleScriptで文字置換を行う場合には、いくつかの方法があります。

①text item delimitersを利用する

AppleScriptの登場以来、利用されてきた方法です。AppleScriptの処理系では最速といってよい方法ですが、複数の箇所を一気に置換するのでやや過剰なのと処理方法が独特なので敬遠する人もいるようです。

また、処理対象の文字列のサイズが数Mバイト以上になると、処理が終了しなかったりします。巨大な文字列の置換には⑤が推奨されます。CotEditorのようなScriptableなテキストエディタの機能を利用するのもアリでしょう。

AppleScript名：文字置換（最短）.scpt

set origText to "abcdefg"
set targStr to "de"
set repStr to "xx"

set a to repChar(origText, targStr, repStr) of me
–> "abcxxfg"

–Written By Philip Aker
–文字置換ルーチン
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

★Click Here to Open This Script　

②shellコマンドを利用する

do shell scriptコマンド経由で置換コマンドを利用する方法です。Mac OS X以降後に利用できるようになったものですが、日本語に対して正確に置換できるのか不安が残るので、個人的にはあまり積極的には利用していません。

③OSAXを利用する

macOS 10.15でサードパーティのOSAX（Scripting Additions）が廃止されたため、現在では利用できません。

④AppleScript Librariesを利用する

Shane StanleyのRegexAndStuffLibなどのライブラリを用いて正規表現を用いた文字置換を利用するものです。

⑤Cocoaの機能を利用する

Cocoaの機能を呼び出して文字置換を行うものです。いくつも利用できる機能があります。正規表現を使うものなど、お好きなものを利用してください。

AppleScript名：ASOCで文字置換5.scptd

— Created 2015-06-30 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set a to "あいうえお＋＋かきくけこ"
set b to cleanUpText(a, "＋", "●")
–> "あいうえお●●かきくけこ"

on cleanUpText(someText, targStr, repStr)
　　set theString to current application’s NSString’s stringWithString:someText
　　set targString to current application’s NSString’s stringWithString:targStr
　　set repString to current application’s NSString’s stringWithString:repStr
　　
　　set theString to theString’s stringByReplacingOccurrencesOfString:targString withString:repString options:(current application’s NSRegularExpressionSearch) range:{location:0, |length|:length of someText}
　　return theString as text
end cleanUpText

★Click Here to Open This Script　

これらに加えて、もっと簡単な方法がないかと探してみたら、

⑥offset ofで文字列検索して置換を行う

offset ofで置換対象の文字列を検索して置換を行います。オリジナル文字列に対して置換対象の文字列の位置が「冒頭ではない」「末尾ではない」という条件がそろっていて、かつ置換対象が0ないし1回しか対象文字列中に存在しないことが事前に分かりきっている場合にのみ使えます。

set urlData to "https://www.amazon.co.jp/gp/css/summary/print.html/ref=oh_aui_ajax_invoice"

set anOffset to offset of "/gp/" in urlData
set newURL to (text 1 thru (anOffset + (length of "/gp/") – 1) of urlData) & "legacy" & (text (anOffset + (length of "/gp/") – 1) thru -1 of urlData)

–> "https://www.amazon.co.jp/gp/legacy/css/summary/print.html/ref=oh_aui_ajax_invoice"

★Click Here to Open This Script　

このぐらいで使えますが、本当にすべてのパターンを利用するには、場合分けしつつ書く必要があります。シンプルなはずなのに、シンプルになっていないという。

AppleScript名：単純文字置換.scpt

set urlData1 to "https://www.amazon.co.jp/gp/css/summary/print.html/ref=oh_aui_ajax_invoice"
set newURL1 to replaceOne(urlData1, "/gp/", "/gp/legacy/") of me
–> "https://www.amazon.co.jp/gp/legacy/css/summary/print.html/ref=oh_aui_ajax_invoice"

set urlData2 to "https://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/"
set newURL2 to replaceOne(urlData2, "/gp/", "/gp/legacy/") of me
–> "https://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/legacy/"

set urlData3 to "https://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/"
set newURL3 to replaceOne(urlData3, "https://", "http://") of me
–> "http://www.amazon.co.jp/css/summary/print.html/ref=oh_aui_ajax_invoice/gp/"

on replaceOne(origStr as string, targStr as string, repStr as string)
　　set anOffset to offset of targStr in origStr
　　if anOffset = 0 then return origStr
　　set {aLen, bLen} to {length of origStr, length of targStr}
　　
　　if anOffset + bLen > aLen then
　　　　–置換対象文字が末尾にある場合
　　　　set newStr1 to (text 1 thru (anOffset – 1) of origStr)
　　　　set newStr2 to ""
　　else if anOffset = 1 then
　　　　–置換対象文字が先頭にある場合
　　　　set newStr2 to (text (anOffset + ((length of targStr))) thru -1 of origStr)
　　　　set newStr1 to ""
　　else
　　　　–通常パターン
　　　　set newStr1 to (text 1 thru (anOffset – 1) of origStr)
　　　　set newStr2 to (text (anOffset + ((length of targStr))) thru -1 of origStr)
　　end if
　　return newStr1 & repStr & newStr2
end replaceOne

★Click Here to Open This Script　

macOS（Mac OS X/OS X）上のAppleScriptの歴史

Posted on 9月 9 by Takaaki Naganoya

macOS 26.0のリリース日が公開されそうなので、AppleScriptの歴史年表について書いておきます。

各種電子書籍に掲載している内容ですが、一般にも共有できていたほうがメリットが多そうなので公開しておきます。

マイナーバージョンで発生したバグの件については、すべて掲載できていません。ファイル書き込み時の文字エンコーディングが狂うとか、OSのバージョン番号をまともに返してこないとか。

Mac OS X 10.0（AppleScript v1.6）
◯Classic Mac OS向けに書かれたOSAXを認識しなくなった　
◯Unicode Textを扱えるようになった（as Unicode Text）
◯Mac OS Xのファイル/アプリケーションの新しい仕組み「バンドル」を扱えるようになった　
◯コマンドラインからosascript、osacompile、osadecompile、osalangが使えるようになった　
◯read/writeコマンドで2GB以上のデータの読み書きができるようになった

Mac OS X 10.1（AppleScript v1.7）
◯AppleScript自体の改行コードに、CR＋LF（Windows）、CR（Mac）、LF（Unix）の３種類を使えるようになった（ネイティブはCR）
◯プログラムリンクの機能が復活。ただし、AppleTalkによるノード名称の指定はできず、TCP/IPベースに変更される（eppc://）
◯SOAPとXML-RPCの機能がサポートされた
◯拡張子を扱えるようになった
◯アプレット保存時にPowerPC/68kのどちらかのバイナリを選択するようになった

Mac OS X 10.2（AppleScript v1.9）
◯choose URLがWindows系サービスとFTPサーバーに対応
◯Script Menuの機能が単体でダウンロード提供されるようになった
（Folder ActionsがSystem Eventsの管轄にあるなど混乱期）

Mac OS X 10.3（AppleScript v1.9.2）
×AppleScript史上最大最悪のバグ「is in」演算子が使えないバグが発生（→10.3.x台で修正される）
◯AppleScriptおよびアプリケーションがバンドル形式でも保存できるようになった
◯delayに小数点以下の数値が指定できるようになった
（×AppleScriptの処理系のバグがとても多かった暗黒時代）

Mac OS X 10.4（AppleScript v1.10）
◯日本語環境がらみのバグが多数修正されたが、本格的な修正は10.5を待つ必要があった
×バグの指摘から修正まで時間がかかり、このバージョンを経てようやく処理系の安定が図られるようになった
×Finderからファイルパスを取得するとエンコーディングがおかしくなったり、display dialogで日本語がまともに表示できないアプリが存在していたのもこのバージョンまで

Mac OS X 10.5（AppleScript v2.0）
◯文字列をすべてUnicodeで扱うようになった
◯ASCIIキャラクター0〜255だけでなく、Unicodeの広い範囲の文字を取得できるように「text id xxxx」（xxxxは10進数で指定）が新設された
◯日本語の文字を含むファイルパスの取扱いがまともになってきた
◯アプリケーション起動中の状態（running）を取得できるようになった
◯アプリケーションをバンドルIDで指定できるようになった
◯FolderAction SetupがScriptableになった
◯「#」ではじまるコメント行を書けるようになった

OS X 10.6（AppleScript v2.1）
◯「スクリプトエディタ」が「AppleScriptエディタ」と名称変更
◯AppleScriptエディタが「ユーティリティー」フォルダに移動になった
◯AppleScriptエディタ上での構文色分け機能が強化された
◯AppleScript処理系の（ログイン後の）起動が速くなった
→　ただし、逆にログインアイテムに登録したAppleScriptアプレットが正しく実行されないというバグを生んだ。ログインアイテムに登録したAppleScriptアプレットでSystem Eventsを呼び出すと、System Eventsの起動が間に合わず、エラーになったりしていた

OS X 10.7（AppleScript v2.2）
◯AppleScriptエディタにスクリプトテンプレートの機能が追加された
◯AppleScriptエディタ上でAppleScriptObjC（Cocoa AppleScript Applet）を書けるようになった
×64bit版に書き直されたFinder、通称「Cocoa Finder」の動作速度が遅く、とくにファイル処理をFinderに任せると大幅に速度が低下する現象が発生。Scripterの間で「ファイル処理をFinderで行わないという」暗黙の合意が広がった

OS X 10.8（AppleScript v2.2）
◯AppleScriptエディタに「エクスポート」の機能がついた。アプレットはエクスポートして生成するよう変更
◯AppleScriptがOSのSandbox化の機能の影響を受けるようになった

OS X 10.9（AppleScript v2.3）
◯AppleScript 20年来の大改革。ライブラリ機能「AppleScript Libraries」が追加された
◯ユーザーへのNotification Center経由での通知命令「display notification」が追加された
◯AppleScriptObjCのハンドラ記述方式に、Objective-Cに似た記述方式が使えるようになった（Xcode上）
◯AppleScriptエディタでアプレットへのコードサインができるようになった
◯AppleScriptエディタがiCloudに対応し、iCloud上にAppleScriptを保存、iCloudからのAppleScriptの読み込みができるようになった

OS X 10.10（AppleScript v2.4）
◯「AppleScriptエディタ」が名称変更でふたたび「スクリプトエディタ」に
◯スクリプトエディタ上でCocoaの機能を利用するAppleScriptObjCを標準でサポートするようになった
◯プログレスバーの表示機能をサポート
◯「as」による型変換（cast）で複数の型をリストで指定できるようになった
◯AppleScriptObjCのハンドラ記述方式に、Objective-Cに似た記述方式が使えるようになった（スクリプトエディタ上）
◯ハンドラ（サブルーチン）宣言部でパラメータの型指定が行えるようになった
◯無意味句を用いたハンドラ記述した場合に、パラメータ省略時の初期値を宣言できるようになった 
×AppleScriptアプレット中でdelayコマンドを利用したときに、正しく時間待ちされないバグ 
×AppleScriptとCocoaの間で小数点を含む実数を変換すると小数点以下の値が欠落するバグ
×NSStringとtext、NSStringとstring、NSStringとUnicode textの間でデータ変換をしたときに、一部の文字が正しく変換されないというバグ（castバグ）
×Folder Actionにバグ。利用者権限に抵触してまともに動作しない（OS X 10.11で修正）

OS X 10.11（AppleScript v2.5）
◯Folder Actionのバグ修正。FSEventsを用いて随時ドロップされたファイルのイベントを受け付けるように処理方式があらためられた（以前は数秒ごとに対象フォルダをチェックする方式）
◯10.10のAppleScriptObjCのバグ修正（cast、enum）
◯AppleScript Librariesのファイルの置き場所を追加（環境変数で指定可能に）
◯より多くのCocoaのデータ型をAppleScriptの型に変換するようになった
◯delayの時間待ち無効バグ修正

macOS 10.12（AppleScript v2.5）
◯パフォーマンス改善のためのバグ修正を実施
×ドロップレットに不具合。ファイルの拡張属性「com.apple.quarantine」がついていると、ファイルが無視される（Script側で対処。以後Apple修正せず）
×Scripting Bridgeの定義ファイルに不具合。Enum「NSNotFound」のブリッジされている定義値が-1にならない（macOS 10.13.1で修正）

macOS 10.13（AppleScript v2.7）
◯セキュリティ関連の修正を実施
◯NSCharacterSet newlineCharacterSet()のようなメソッドでクラッシュしなくなった ◯NSNotFoundのScriptingBridge経由でブリッジされる定義値を-1に修正（macOS 10.13.1）
◯Remote AppleEventsの機能が復旧し、AppleScriptからLAN上の他のマシンの上で動作しているアプリケーションを直接操作できるようになった（起動している必要がある） 
◯ScriptingBridge定義ファイルにバグ。PDFKit中のPDFPageのcurrentPage()がブリッジされていない。報告するも未修正（ずっと未修正）

macOS 10.14（AppleScript v2.7）
◯システム環境設定の「アクセシビリティ」＞「プライバシー」に、「フルディスクアクセス」「オートーメーション」が新設され、ディスクやリソースへのアクセス、アプリケーションとの通信を管理するようになった。これに伴い、このアプリケーションへのアクセス認証を得ていない場合に発生するエラー（エラーコード-1743）が新設された。
◯サードパーティのOSAXサポートが廃止された
◯スクリプトメニューが、Menu Extraから独立したアプリケーションに変更になった
◯DVDプレイヤーがアプリケーションから補助ツールに格下げになり、AppleScriptからの操作が行えなくなった
◯SIPの機能が強化されセキュリティが強化された。その結果、アプレット内にFrameworkを同梱して配布したり、~/Library/Frameworksに入れたフレームワークをスクリプトエディタが認識しなくなった（事実上、Script Debuggerが必須に）
◯スクリプトエディタのAppleScript用語辞書から「execute」コマンドが削除された
◯住所録（Contacts.app）でプラグインScriptを利用できる機能が削除された（AppleScript用語辞書には残されているが機能しない）

macOS 10.15（AppleScript v2.7）
◯Remote AppleEvents（eppc）経由で他のマシン上のアプリケーションと通信する場合に、同一ユーザー名であることが必要になった。この制限を解除するためには、「defaults write /Library/Preferences/com.apple.AEServer RestrictAccessToUserSession -bool false」の操作をターミナル上で行う必要がある
◯AppleScript専用補助ツール「Image Events」がデフォルト状態ではファイルに一切アクセスできない状態で出荷される（セキュリティ設定によりアクセス可能に。その後のOSバージョンでも修正されない）
 ◯Cocoa呼び出しを行なった際の実行速度が大幅に低下（→macOS 12で修正）

macOS 11.0（AppleScript v2.7）
◯ARM（Apple Silicon）対応。AppleScript Appletなど実行アプリケーションがすべてApple Silicon/Intel 64のUniversal Binary化
◯Automator Action用に盲腸のように残っていたAppleScript Studioランタイムの廃止が明言される
 ◯AppleScriptアプレット中にproperty値が保存されなくなった。property値を保存する場合にはUser Defaultsに書き込む必要がある ◯ファイル共有のプロトコルに「afp://」が利用できなくなった。「smb://」に一本化 
◯AppleScript書類（.scpt）アイコンが単なるプレーンテキストのものに変わっている（バグなのか本気なのかは不明。macOS 11.x台では修正されない見込み） 
◯System Eventsの初回操作時に明示的に「launch」コマンドの実行が必要に（自動起動しない） 
◯macOS 11.5において、NSString’s stringWithFormat:メソッドをAppleScriptから呼び出してもクラッシュしなくなった（macOS 11.0〜11.4の間はクラッシュ発生）
 ◯これまでに書かれたCocoa Scriptingのプログラムで「書き方が間違っているが、許容されてきた」書き方がエラーもしくはクラッシュを引き起こすようになった
×AppleScriptがM1 CPUの高効率コア「Icestorm」で実行されてしまうため、Cocoa Scripting時にIntel CPUにくらべて10分の１〜70分の１程度にパフォーマンス低下（→macOS 12で修正）

macOS 12.0（AppleScript v2.8）
◯ショートカット.appが標準搭載される。ショートカットにAppleScript実行アクションが搭載され、ショートカット中からAppleScript（Cocoa Scripting機能を含む）の呼び出しが可能に
◯ショートカット.appが起動中でなくてもショートカットを実行できるShortcuts Eventsが標準搭載される 
◯Piyomaru Softwareの働きかけにより、macOS 10.15で生じたCocoa Scriptingの速度低下、およびmacOS 11で生じたApple Silicon MacのCocoa Scripting速度低下が是正される。Cocoa呼び出し時のAppleScriptの大幅な処理速度向上
◯macOS 12.3、悪意を持って作られたAppleScriptバイナリ（アプレット）のセキュリティ上の問題（CVE-2022-22626）を解消
◯macOS 12.1〜2の間、日本語環境限定で、NSDataDetectorで自然言語テキストから「電話番号」を抽出する機能が動作していなかった（12.3で修正）
◯macOS 12.3、スクリプトエディタのコンテクストメニュー（スクリプトアシスタント表示用）にバグ。項目が複数回表示される（macOS 13で修正）
 ◯macOS 12.3.1、セキュリティ強化にともなう不具合（Finder上のselectionをオープンすると、ファイルを作成したアプリケーションが起動されないエラーなど）を修正
 ◯macOS 12.4、AppleScriptアプレットで、入力検証を強化して、領域外読み込みの脆弱性に対処（CVE-2022-26697）。アプリケーションが予期せず終了したり、プロセスメモリが漏洩したりする可能性がある脆弱性に対し、配列境界チェック機能を改善して対処（CVE-2022-26698）。

macOS 13.0（AppleScript v2.8）
◯「システム環境設定」が「システム設定」に。AppleScriptで各種Paneを表示させる機能が動作しなくなった → macOS 13.5あたりでmacOS 14同様の機能を実装、機能復旧
◯「Font Book」がAppleScript非対応に
◯「アプリケーションのAppleScript用語辞書をブラウズする方法が、「アプリケーションのアイコンをスクリプトエディタにドラッグ＆ドロップする」ものから「アプリケーションのアイコンをスクリプトエディタの「ライブラリ」ウインドウにドラッグ＆ドロップもしくは「＋」ボタンのクリックで追加するやりかたに変更される（macOS 14で復旧）
×Text To Speech（テキスト読み上げ音声）のIDがすべて変更になる。日本語環境用にSiriのO-renとHattoriが搭載されるが、sayコマンドで使えるようにはなっていない 
×AppleScriptからMail.appにメール作成＋送信を行うと1通作成ごとに生成されたプロセスがメモリ上から消えず、メモリを食い潰してマシンの処理速度自体が遅くなる
×スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットが動作しない問題が発生 ◯テキスト読み上げキャラクタのうち一部のキャラクタで名前がローカライズされてしまい、sayコマンドで指定できないバグが発生（日本語環境限定バグ）

macOS 14.0（AppleScript v2.8）
◯「システム設定」のAppleScriptで各種Paneを表示させる機能が復旧
◯Safari v17で隠し命令「show credit card settings」が追加される。do javascript命令の実行許可のための「Apple EventからのJavaScriptを許可」の場所が設定＞デベロッパに変更される
◯ミュージック.appでplaylistの「loved」属性が「favorited」に変更される
◯連絡先.appの廃止済みプラグイン機能用の「Address Book Rollover Suite」の属性がhiddenに変更される
 ◯スクリプトエディタのコンテクストメニュー・スクリプトに、絵文字つきのファイル/フォルダのコンテンツを入れると、コンテクストメニューに「項目が重複して表示される」不具合が修正される
◯「アプリケーションのAppleScript用語辞書をブラウズする方法「アプリケーションのアイコンをスクリプトエディタにドラッグ＆ドロップ」が復旧する
×スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットが動作しない問題が継続中
×スクリプトメニューから呼び出したAppleScriptの実行速度が、スクリプトエディタ上よりも6倍以上遅くなる現象が発生
×半角スペース文字列の数値への型変換で処理系自体がクラッシュするバグ（14.0 Sonoma Crasher→ 15.0で修正）
×テキスト読み上げキャラクタのうち一部のキャラクタで名前がローカライズされてしまい、sayコマンドで指定できないバグが継続中（日本語環境限定バグ）

macOS 15.0（AppleScript v2.8）
◯Safariのtabにpidプロパティが追加される
◯AppleScriptドロップレットにドロップしたファイル/フォルダが、xattr「com.apple.quarantine」の影響とGatekeeperの兼ね合いですべてが受け渡されない現象がmcOS 10.12から継続して発生していたが、これが改められ、ドロップされたファイル/フォルダの欠損が発生しなくなった。なお、この変更がmacOS 13.xおよび14.xにもさかのぼって適用された
◯半角スペース文字列の数値への型変換で処理系自体がクラッシュするバグ（14.0, Sonoma Crasher）が解消
×スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットが動作しない問題が継続中 
×スクリプトメニューから呼び出したAppleScriptの実行速度が、スクリプトエディタ上よりも6倍以上遅くなる現象が継続中
×テキスト読み上げキャラクタのうち一部のキャラクタで名前がローカライズされてしまい、sayコマンドで指定できないバグが継続中（日本語環境限定バグ）

macOS 26.0（AppleScript v2.8）
◯スクリプトエディタ上で「Cocoa-AppleScript Applet」のテンプレートから作成したアプレットがApple Silicon Mac上で動作しない問題が解決される（？？？？？？）
◯スクリプトエディタ上でコンパイル（構文確認）を行うと、最終行が見栄なくなる門外が解決される 
◯スクリプトエディタがDark Modeに対応
◯スクリプトエディタのアイコンがmacOS 26風に変更される

暗黙のuseコマンド

Posted on 9月 2 by Takaaki Naganoya

かつてAppleScript関連で大きな議論を呼んだ話題に「暗黙のrunハンドラ」というものがありました。

何も書かないAppleScriptのプログラムに暗黙のrunハンドラが存在している（ように動く）という話です。

現在でも同様に、

「明確に仕様として明記されていないものの、おそらくこういう動作になっているだろう」

と推測して書いているものがあります。それが、暗黙のuseコマンドです。

useコマンドはデフォルトで指定されている

何もuseコマンドを書かなくても、仮にuseコマンドを記述しても、パラメータを指定しない場合にはデフォルト値が

use AppleScript
無指定時には、現在実行中のバージョンのAppleScriptで動作するようになっているようです。

use scripting additions
macOS 10.15以降はサードパーティのScripting Additionのサポートが廃止されたため、Apple純正のStandard Additionsのオン/オフ設定コマンドという位置付けになっているようです。

use framework
この記述では、とくに無指定時のデフォルト値というものはないようです。

ただし、Vanilla ScriptとCocoa Scriptで動作が異なっています。また、Script Object内に記述したAppleScriptでも動作が変わります。

AppleScript名：scripting additions 1.scpt

display dialog "TEST"

★Click Here to Open This Script　

AppleScript名：scripting additions in script object.scpt

testScript’s testMes("TEST")

script testScript
　　on testMes(aMes as string)
　　　　display dialog aMes
　　end testMes
end script

★Click Here to Open This Script　

AppleScript名：scripting additions 2.scpt

use AppleScript
use framework "Foundation"

–display dialog "TEST"–構文チェック自体できない

★Click Here to Open This Script　

AppleScript名：scripting additions in script object.scpt

use AppleScript
use framework "Foundation"

testScript’s testMes("TEST")

script testScript
　　use AppleScript
　　use framework "Foundation"
　　use scripting additions –ないと、構文確認をパスできない
　　property parent : AppleScript –なくても動く。Scriptオブジェクトの階層を増やすと必須になったりする
　　
　　on testMes(aMes as string)
　　　　display dialog aMes
　　end testMes
　　
　　on testMes2(aMes as string)
　　　　using terms from scripting additions —どの用語辞書の予約語かを明示的に指定するよう構文確認時に求められるケースがある
　　　　　　display dialog aMes
　　　　end using terms from
　　end testMes2
end script

★Click Here to Open This Script　

開始時刻から終了時刻までhh:mm形式の文字列を15分単位でリスト出力

Posted on 8月 13 by Takaaki Naganoya

指定の開始時刻から終了時刻まで、hh:mm形式の文字列を15分間隔でリスト出力するAppleScriptです。

ありもののサブルーチンを組み合わせて即席で作ったCocoa版のルーチンと、ChatGPT（GPT-5）に書かせた非Cocoa版のルーチンの2つがあり（ChatGPTにCocoa使用を指定せず）、速度を比較してみたら……

非Cocoa版のルーチンのほうが６倍ぐらい高速でした。データが小さすぎるとか、処理内容が小さすぎる場合にはCocoaの機能を利用しないほうが高速に処理できる場合があります。

Shane Stanleyの処理時間計測アプリ「ScriptGeek」が、かなりCocoa Scriptingの登場初期から存在しており、不思議に思ってきたものですが……処理内容の規模によってはCocoa Scriptingのほうが遅くなるケースがあるため、実際に書いて動かして計測してみないと、Cocoa Scriptingで高速化が達成できるかわからないところです。

このほか、AppleScriptのランタイム環境が何になるかによって実行速度は変わってきます。Xcode上で開発するCocoa Applicationなども実行特性が違うため、やはり動かして計測してみないと何がベストなのかはわかりません。

ただ、この程度の処理であれば、0.0028秒が0.4秒になったところで、何か実用上の差異が発生するわけでもありません。

追記：
追加で最速パターンを掲載しておきます。汎用性を求めて計算して出力していましたが、ほとんどの用途で毎回同じようなデータを出力することでしょう。なので、固定データを返すだけでいいだろうかと。高速版とくらべても65〜70倍ぐらい高速です（当たり前）。

AppleScript名：15分メッシュの時間文字列を生成.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/08/13
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set aRes to generateWorkUnitList() of me
–> {"5:15", "5:30", "5:45", "6:00", "6:15", "6:30", "6:45", "7:00", "7:15", "7:30", "7:45", "8:00", "8:15", "8:30", "8:45", "9:00", "9:15", "9:30", "9:45", "10:00", "10:15", "10:30", "10:45", "11:00", "11:15", "11:30", "11:45", "12:00", "12:15", "12:30", "12:45", "13:00", "13:15", "13:30", "13:45", "14:00", "14:15", "14:30", "14:45", "15:00", "15:15", "15:30", "15:45", "16:00", "16:15", "16:30", "16:45", "17:00", "17:15", "17:30", "17:45", "18:00", "18:15", "18:30", "18:45", "19:00", "19:15", "19:30", "19:45", "20:00", "20:15", "20:30", "20:45"}

on generateWorkUnitList()
　　set hList to {}
　　
　　repeat with h from 5 to 20 by 1
　　　　repeat with m from 0 to 59 by 15
　　　　　　if {h, m} is not equal to {5, 0} then
　　　　　　　　set mStr to numToZeroPaddingStr(m, 2, "0")
　　　　　　　　set the end of hList to (h as string) & ":" & mStr
　　　　　　end if
　　　　end repeat
　　end repeat
　　
　　return hList
end generateWorkUnitList

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

AppleScript名：15分メッシュの時間文字列を生成（高速）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/08/13
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set mList to retWorkingMeshStrList() of me
–> {"5:15", "5:30", "5:45", "6:00", "6:15", "6:30", "6:45", "7:00", "7:15", "7:30", "7:45", "8:00", "8:15", "8:30", "8:45", "9:00", "9:15", "9:30", "9:45", "10:00", "10:15", "10:30", "10:45", "11:00", "11:15", "11:30", "11:45", "12:00", "12:15", "12:30", "12:45", "13:00", "13:15", "13:30", "13:45", "14:00", "14:15", "14:30", "14:45", "15:00", "15:15", "15:30", "15:45", "16:00", "16:15", "16:30", "16:45", "17:00", "17:15", "17:30", "17:45", "18:00", "18:15", "18:30", "18:45", "19:00", "19:15", "19:30", "19:45", "20:00"}

on retWorkingMeshStrList()
　　set startSeconds to (5 * 3600) + (15 * 60) — 5:15 の相対秒
　　set endSeconds to (20 * 3600) — 20:00 の相対秒
　　set intervalSeconds to 15 * 60 — 15分間隔
　　
　　set timeList to {}
　　
　　repeat with t from startSeconds to endSeconds by intervalSeconds
　　　　set h to t div 3600
　　　　set m to (t mod 3600) div 60
　　　　— 2桁表示に整形
　　　　–set hStr to text -2 thru -1 of ("0" & h)
　　　　set hStr to h as string
　　　　set mStr to text -2 thru -1 of ("0" & m)
　　　　set end of timeList to (hStr & ":" & mStr)
　　end repeat
　　
　　return timeList
end retWorkingMeshStrList

★Click Here to Open This Script　

AppleScript名：15分メッシュの時間文字列を生成（最速）.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/08/10
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use framework "Foundation"
use scripting additions

set hList to generateWorkUnitList() of me

on generateWorkUnitList()
　　return {"5:15", "5:30", "5:45", "6:00", "6:15", "6:30", "6:45", "7:00", "7:15", "7:30", "7:45", "8:00", "8:15", "8:30", "8:45", "9:00", "9:15", "9:30", "9:45", "10:00", "10:15", "10:30", "10:45", "11:00", "11:15", "11:30", "11:45", "12:00", "12:15", "12:30", "12:45", "13:00", "13:15", "13:30", "13:45", "14:00", "14:15", "14:30", "14:45", "15:00", "15:15", "15:30", "15:45", "16:00", "16:15", "16:30", "16:45", "17:00", "17:15", "17:30", "17:45", "18:00", "18:15", "18:30", "18:45", "19:00", "19:15", "19:30", "19:45", "20:00"}
end generateWorkUnitList

★Click Here to Open This Script　

Adobe InDesignのAppleScript実行エンジンがCarbonからCocoaベースに書き換えられる

Posted on 7月 30 by Takaaki Naganoya

最新のAdobe InDesignにおいて、AppleScriptの実行エンジンが従来のCarbonベースのものから、Cocoaベースのものに置き換えられるという情報が入ってきました。

実行エンジンの切り替えにともない、利用できる各種機能に変更点があるかどうかは未確認です。

従来のAdobe InDesignのAppleScript実行エンジンはCocoa系の機能実行に関しては最強レベルのものが搭載されており、Script Debugger並みのユーザーディレクトリ下のFramework呼び出しをはじめ、最強クラスの実行エンジンが搭載されていました。

通常のAppleScript実行はもちろんのこと、幅広い対応を行なっていたCocoa Scripting機能対応が、どの程度新エンジンに継承されているかがみどころです。評価できるといいのに。

Finderを終了させる

Posted on 7月 29 by Takaaki Naganoya

Finderを終了させたままにしておくAppleScriptです。

この種類のQ&Aだと、

do shell script "killall Finder"

といった回答が書かれがちですが、これだと終了させたままにはできません。

Finderを終了させたままにしておく方法について調べてみたら、見つかったのでまとめておきました。

AppleScript名：Finderを終了させる.scpt

do shell script "defaults write com.apple.Finder QuitMenuItem -boolean true"

tell application "Finder" to quit

★Click Here to Open This Script　

Claris FileMaker Pro 2025（v22）がリリースされた

Posted on 7月 12 by Takaaki Naganoya

Appleの子会社であるClarisから、Claris FileMaker Pro 2025（v22）がリリースされました。

AppleScript名：Claris FileMaker Pro 2025のバージョン番号取得.scpt

tell application "FileMaker Pro"
　　version
　　–> "22.0.1"
end tell

★Click Here to Open This Script　

AppleScript用語辞書は前バージョンから変更されていません。

ASCII ARTで直線を引く v3.1

Posted on 7月 8 by Takaaki Naganoya

ASCII ARTで指定の2点間に線を引くAppleScriptです。（デモ用の）文字で表現するゲームを作る場合に、基礎ルーチンを整備しておく必要性を感じて、書いておきました。

AppleScript名：ASCII ARTで直線を引く v3.1.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/07/07
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

property widthCount : 40
property heightCount : 25
property spaceChar : "　"
property drawChar : "■"

— 使用例
set canvas to makeBlankCanvas() of me

set canvas to drawLine(canvas, 0, 0, 39, 24, 1) of me — 太さ1の線

set curDelim to AppleScript’s text item delimiters
set AppleScript’s text item delimiters to return
set resultText to canvas as text
set AppleScript’s text item delimiters to curDelim

return resultText

on makeBlankCanvas()
　　set blankLine to ""
　　repeat widthCount times
　　　　set blankLine to blankLine & spaceChar
　　end repeat
　　set canvas to {}
　　repeat heightCount times
　　　　set end of canvas to blankLine
　　end repeat
　　return canvas
end makeBlankCanvas

on drawLine(canvas, x0, y0, x1, y1, thickness)
　　script spd
　　　　property drawnPositions : {}
　　　　property drawXCoords : {}
　　　　property canvas : {}
　　　　property lineChars : {}
　　end script
　　
　　copy canvas to (canvas of spd)
　　
　　set dx to x1 – x0
　　set dy to y1 – y0
　　set lineLength to (dx * dx + dy * dy) ^ 0.5
　　
　　if lineLength = 0 then
　　　　if x0 ≥ 0 and x0 < widthCount and y0 ≥ 0 and y0 < heightCount then
　　　　　　set theLine to item (y0 + 1) of (canvas of spd)
　　　　　　set newLine to replaceCharAt(theLine, x0 + 1, drawChar)
　　　　　　set item (y0 + 1) of (canvas of spd) to newLine
　　　　end if
　　　　
　　　　return (canvas of spd)
　　end if
　　
　　set nx to –dy / lineLength
　　set ny to dx / lineLength
　　
　　set halfThickness to (thickness – 1) / 2
　　if halfThickness < 0 then set halfThickness to 0
　　
　　set x to x0
　　set y to y0
　　
　　set dxAbs to absNum(dx) of me
　　set dyAbs to absNum(dy) of me
　　set sx to signNum(dx) of me
　　set sy to signNum(dy) of me
　　set err to dxAbs – dyAbs
　　
　　set (drawnPositions of spd) to {}
　　
　　repeat
　　　　set (drawXCoords of spd) to {}
　　　　repeat with t from –halfThickness to halfThickness
　　　　　　set pxF to x + nx * t
　　　　　　set pxInt to pxF as integer
　　　　　　if pxInt ≥ 0 and pxInt < widthCount then
　　　　　　　　if (drawXCoords of spd) does not contain pxInt then
　　　　　　　　　　set end of (drawXCoords of spd) to pxInt
　　　　　　　　end if
　　　　　　end if
　　　　end repeat
　　　　
　　　　set pyInt to y as integer
　　　　if pyInt ≥ 0 and pyInt < heightCount then
　　　　　　set theLine to item (pyInt + 1) of (canvas of spd)
　　　　　　set (lineChars of spd) to characters of theLine
　　　　　　
　　　　　　repeat with pxInt in (drawXCoords of spd)
　　　　　　　　set posKey to (pxInt as string) & "," & (pyInt as string)
　　　　　　　　
　　　　　　　　if (drawnPositions of spd) does not contain posKey then
　　　　　　　　　　set item (pxInt + 1) of (lineChars of spd) to drawChar
　　　　　　　　　　set end of (drawnPositions of spd) to posKey
　　　　　　　　end if
　　　　　　　　
　　　　　　end repeat
　　　　　　
　　　　　　set newLine to (lineChars of spd) as string
　　　　　　set item (pyInt + 1) of (canvas of spd) to newLine
　　　　end if
　　　　
　　　　if x = x1 and y = y1 then exit repeat
　　　　
　　　　set e2 to 2 * err
　　　　if e2 > –dyAbs then
　　　　　　set err to err – dyAbs
　　　　　　set x to x + sx
　　　　end if
　　　　
　　　　if e2 < dxAbs then
　　　　　　set err to err + dxAbs
　　　　　　set y to y + sy
　　　　end if
　　end repeat
　　
　　return (canvas of spd)
end drawLine

on replaceCharAt(str, pos, char)
　　if pos < 1 or pos > (length of str) then return str
　　set prefix to text 1 thru (pos – 1) of str
　　set suffix to text (pos + 1) thru -1 of str
　　return prefix & char & suffix
end replaceCharAt

on absNum(n)
　　if n < 0 then return –n
　　return n
end absNum

on signNum(n)
　　if n > 0 then return 1
　　if n < 0 then return -1
　　return 0
end signNum

★Click Here to Open This Script　

ASCII ARTで円を塗る

Posted on 7月 5 by Takaaki Naganoya

ASCII ARTで円を塗りつぶすAppleScriptです。（デモ用の）文字で表現するゲームを作る場合に、基礎ルーチンを整備しておく必要性を感じて、書いておきました。

AppleScript名：ASCII ARTで円を塗る.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/07/04
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

— 円の半径 (この数値を変更すると円の大きさが変わります)
set radiusNum to 12

— キャンバスのサイズ
set canvasWidth to 80
set canvasHeight to 40

— 円の中心座標
set centerX to canvasWidth / 2
set centerY to canvasHeight / 2

— 全角文字のアスペクト比補正係数
set aspectRatio to 0.7
set aaRes to aaFillCircle(radiusNum, canvasWidth, canvasHeight, centerX, centerY, aspectRatio) of me

on aaFillCircle(radiusNum, canvasWidth, canvasHeight, centerX, centerY, aspectRatio)
　　script spd
　　　　property outputText : ""
　　end script
　　
　　— 描画結果を格納する変数
　　set (outputText of spd) to ""
　　
　　— 描画処理 (1行ずつ文字を生成)
　　repeat with y from 1 to canvasHeight
　　　　set currentLine to ""
　　　　repeat with x from 1 to canvasWidth
　　　　　　— 円の方程式を使い、中心からの距離を計算
　　　　　　set distSquared to ((x – centerX) * aspectRatio) ^ 2 + (y – centerY) ^ 2
　　　　　　
　　　　　　— 現在の座標が円の内側または円周上にあるか判定
　　　　　　if distSquared ≤ radiusNum ^ 2 then
　　　　　　　　set currentLine to currentLine & "■"
　　　　　　else
　　　　　　　　set currentLine to currentLine & "　"
　　　　　　end if
　　　　end repeat
　　　　— 1行分の文字列と改行を出力に追加
　　　　set (outputText of spd) to (outputText of spd) & currentLine & "
"
　　end repeat
　　
　　return contents of (outputText of spd)
end aaFillCircle

★Click Here to Open This Script　

ASCII ARTで円を線で描く

Posted on 7月 5 by Takaaki Naganoya

ASCII ARTで円を線で描くAppleScriptです。（デモ用の）文字で表現するゲームを作る場合に、基礎ルーチンを整備しておく必要性を感じて、書いておきました。

AppleScript名：ASCII ARTで円を線で描く.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2025/07/04
—
–　　Copyright © 2025 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use scripting additions

set radiusNum to 12

— キャンバスのサイズ
set canvasWidth to 80
set canvasHeight to 40

— 円の中心座標
set centerX to canvasWidth / 2
set centerY to canvasHeight / 2

— 全角文字のアスペクト比補正係数
set aspectRatio to 0.7

— 描画する線の太さ
set lineWidth to 0.5
set ssRes to aaDrawCircleLine(radiusNum, canvasWidth, canvasHeight, centerX, centerY, aspectRatio, lineWidth) of me

on aaDrawCircleLine(radiusNum, canvasWidth, canvasHeight, centerX, centerY, aspectRatio, lineWidth)
　　script spd
　　　　property outputText : ""
　　end script
　　
　　— 描画結果を格納する変数
　　set (outputText of spd) to ""
　　
　　— 描画処理 (1行ずつ文字を生成)
　　repeat with y from 1 to canvasHeight
　　　　set currentLine to ""
　　　　repeat with x from 1 to canvasWidth
　　　　　　— 円の方程式を使い、中心からの距離を計算
　　　　　　set distSquared to ((x – centerX) * aspectRatio) ^ 2 + (y – centerY) ^ 2
　　　　　　
　　　　　　— 現在の座標が円周上にあるか判定
　　　　　　if (distSquared > (radiusNum – lineWidth) ^ 2) and (distSquared < (radiusNum + lineWidth) ^ 2) then
　　　　　　　　set currentLine to currentLine & "■"
　　　　　　else
　　　　　　　　set currentLine to currentLine & "　"
　　　　　　end if
　　　　end repeat
　　　　— 1行分の文字列と改行を出力に追加
　　　　set (outputText of spd) to (outputText of spd) & currentLine & "
"
　　end repeat
　　return contents of (outputText of spd)
end aaDrawCircleLine

★Click Here to Open This Script　

Appleに買収されたPixelmator ProがAppleとしての初アップデート

Posted on 7月 2 by Takaaki Naganoya

前回の「買収されました」メッセージを表示するだけのアップデートとは異なり、Apple体制下でのそれらしいアップデート（v3.7）が行われました。

AppleScript用語辞書にも変更が加わっているのですが、

Pixelmatorの各バージョンに設定されていたコードネームを返してくるコマンドが廃止になったようです。そんな機能があったとは知りませんでした。廃止はまぁ、機能的に何も影響がないので妥当なところだろうかと。

NLTaggerで品詞つきの日本語形態素解析

Posted on 6月 30 by Takaaki Naganoya

ChatGPTに日本語形態素解析のAppleScriptを書かせてみました。そのままでは使い物にならず、ずいぶん書き直しましたが、ゼロから書くよりは時間の節約になっています。

ただし、実際に書いて動かしてみるとNLTaggerでは日本語の品詞情報が取得できないので、ほぼ役に立ちません。MeCab経由で取得したほうが実用的です。

この状態で「なんちゃらIntelligence」とか言われても、「はぁ？」としか、、、基礎ができていないのに応用はできませんよ。

AppleScript名：NLTaggerで品詞つきの日本語形態素解析（ただし、品詞はほとんど役に立たない）.scptd

use AppleScript version "2.8" — macOS 12 or later
use framework "Foundation"
use framework "NaturalLanguage"
use scripting additions

set inputText to current application’s NSString’s stringWithString:"私は昨日東京に行きました。"

— NLTaggerの作成（品詞情報を取得したいのでLexicalClassを指定）
set tagger to current application’s NLTagger’s alloc()’s initWithTagSchemes:{current application’s NLTagSchemeLexicalClass}
tagger’s setString:inputText
tagger’s setLanguage:(current application’s NLLanguageJapanese) range:{location:0, |length|:(inputText’s |length|())}

— 結果を格納するリスト
set tokenList to {}

— 解析処理
set inputLength to (inputText’s |length|()) as integer
set currentIndex to 0

repeat while currentIndex < inputLength
　　set tokenRangeRef to reference
　　set {tagRes, theRange} to tagger’s tagAtIndex:(currentIndex) unit:(current application’s NLTokenUnitWord) |scheme|:(current application’s NLTagSchemeLexicalClass) tokenRange:(tokenRangeRef)
　　–return theRange
　　
　　set theRange to theRange as record
　　set startLoc to theRange’s location
　　set rangeLen to theRange’s |length|()
　　
　　if (rangeLen > 0) then
　　　　set tokenText to inputText’s substringWithRange:(current application’s NSMakeRange(startLoc, rangeLen))
　　　　if tagRes is not missing value then
　　　　　　set posStr to tagRes as string
　　　　else
　　　　　　set posStr to "Unknown"
　　　　end if
　　　　set endIndex to startLoc + rangeLen
　　　　set end of tokenList to {(tokenText as string), posStr}
　　　　set currentIndex to endIndex
　　else
　　　　exit repeat
　　end if
end repeat

return tokenList
–> {{"私", "OtherWord"}, {"は", "OtherWord"}, {"昨日", "OtherWord"}, {"東京", "OtherWord"}, {"に", "OtherWord"}, {"行き", "OtherWord"}, {"まし", "OtherWord"}, {"た", "OtherWord"}, {"。", "SentenceTerminator"}}

★Click Here to Open This Script　

Script Debuggerがフリーダウンロードで提供されることに

Posted on 6月 16 by Takaaki Naganoya

2025年1月1日に製品開発の終了を宣言した、AppleScriptの統合開発環境「Script Debugger」について、Late Night Software, ltd.のWebサイトからダウンロードできるようになりました。

→ Download Script Debugger

過去の各バージョンのScript Debugger（v4、v4.5、v5、v6、v7、v8）をダウンロードでき、Registration Numberが記載されています。

ただし、As Isで提供されるものであり、サポートや新たに発見されたバグについては免責とされています。

CotEditor用ブロック崩しゲーム

Posted on 6月 14 by Takaaki Naganoya

CotEditorでオープン中の最前面の書類の内容を書き換えて、ブロック崩し（Breakout）ゲームを行うAppleScriptです。

最前面の書類ウィンドウ内の表示フォントに等幅フォントを指定し、行間をなるべく少なく（0.6行ぐらい）指定した状態で実行してください。

実行はスクリプトエディタなどの実行環境のほか、CotEditorの内蔵スクリプトメニューを利用することも可能です。

CotEditor依存部分はほんの2箇所なので、JeditΩ、mi、BBEdit、Pagesなど幅広いアプリに容易に対応できます。

操作は、パドルの左移動を[option]キー、右移動を[shift]キーで行います。スコアの管理は行なっていません。ミスるとその場でゲームオーバーです。

動作速度は相当に速いので、速すぎてウェイト（delayコマンド）を入れているぐらいです。テキストエディタ上で実行できるブロック崩しとしては、文句のない出来になっていますが、ブロック崩しとしては不満の残る仕上がりです。

開発とテストはMacBook Air M2で行なっているため、delayコマンドの値は同機のパフォーマンスに合わせて調整していますが、Intel Macでは半分以下ぐらいの速度しか出ないので、delayコマンドの値を減らす必要があることでしょう。

Apple Silicon Macの上位機種でコアを貼り合わせてSoCを構成しているものは、シンプルなSoCの構成のものよりもパフォーマンスが下がる可能性もあります。

ボールを打ち返す角度が一定であるため、ブロック崩しといいつつ永遠に消せないブロックが大量に存在しています。実際には、パドルの移動速度を勘案して反射角度を変えるといった処理が必要になることでしょう。

そのままXcode上にもっていって実行していますが、やはりこの反射角度が固定されていることは相当にストレスフルなので、いい感じに書き換えられるとよさそうです。

AppleScript名：Block崩し v3.1.1.scpt

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit" — for NSEvent

property screenWidth : 30
property screenHeight : 20
property paddleSize : 6

property ballX : 0
property ballY : 0
property paddleX : 0

script spd
　　property blockList : {}
　　property screenLines : {}
　　property lineText : ""
end script

set paddleX to (screenWidth div 2) – (paddleSize div 2)
set ballX to screenWidth div 2
set ballY to screenHeight – 3
set ballDX to 1
set ballDY to -1
set (blockList of spd) to {}

— ブロックは「x,y」の文字列形式で格納し、検索高速化
set blockSet to {}

repeat with y from 1 to 3
　　repeat with x from 0 to screenWidth – 1
　　　　if (x mod 2 = 0) then
　　　　　　set end of blockSet to (x as text) & "," & (y as text)
　　　　end if
　　end repeat
end repeat

set text item delimiters to return

–CotEditorに依存している部分(1)　差し替え可能
— CotEditorのドキュメント取得
tell application "CotEditor"
　　set dCount to count every document
　　if dCount = 0 then make new document
　　activate
　　set doc to front document
　　display dialog "◀︎[Option] [Shift]▶︎" with title "How to control"
end tell

delay 2

— ゲームループ
repeat
　　— キー入力処理
　　if my modKeyScan:"Option" then
　　　　if paddleX > 0 then set paddleX to paddleX – 1
　　else if my modKeyScan:"Shift" then
　　　　if paddleX < screenWidth – paddleSize then set paddleX to paddleX + 1
　　end if
　　
　　— ボール移動
　　set ballX to ballX + ballDX
　　set ballY to ballY + ballDY
　　
　　— 壁に当たったら反射
　　if ballX ≤ 0 or ballX ≥ screenWidth – 1 then set ballDX to ballDX * -1
　　if ballY ≤ 0 then set ballDY to ballDY * -1
　　
　　— キー入力処理
　　if my modKeyScan:"Option" then
　　　　if paddleX > 0 then set paddleX to paddleX – 1
　　else if my modKeyScan:"Shift" then
　　　　if paddleX < screenWidth – paddleSize then set paddleX to paddleX + 1
　　end if
　　
　　— パドル反射
　　if ballY = screenHeight – 2 and ballX ≥ paddleX and ballX < (paddleX + paddleSize) then
　　　　set ballDY to ballDY * -1
　　end if
　　
　　— ブロック衝突
　　set coordKey to (ballX as text) & "," & (ballY as text)
　　if coordKey is in blockSet then
　　　　set blockSet to my removeFromList(coordKey, blockSet)
　　　　set ballDY to ballDY * -1
　　end if
　　
　　— ゲームオーバー
　　if ballY ≥ screenHeight – 1 then
　　　　my renderScreen(doc, blockSet, paddleX, ballX, ballY, "GAME OVER")
　　　　exit repeat
　　end if
　　
　　— 描画
　　my renderScreen(doc, blockSet, paddleX, ballX, ballY, "")
　　delay 0.06
end repeat

— 描画ルーチン（配列構築をまとめて実行）
on renderScreen(theDoc, blockSet, paddleX, ballX, ballY, messageText)
　　set screenBuffer to {}
　　repeat with y from 0 to screenHeight – 1
　　　　set rowText to ""
　　　　repeat with x from 0 to screenWidth – 1
　　　　　　if y = ballY and x = ballX then
　　　　　　　　set rowText to rowText & "●"
　　　　　　else if y = (screenHeight – 1) and x ≥ paddleX and x < (paddleX + paddleSize) then
　　　　　　　　set rowText to rowText & "〓"
　　　　　　else if ((x as text) & "," & (y as text)) is in blockSet then
　　　　　　　　set rowText to rowText & "■"
　　　　　　else
　　　　　　　　set rowText to rowText & "　"
　　　　　　end if
　　　　end repeat
　　　　set end of screenBuffer to rowText
　　end repeat
　　
　　if messageText is not "" then
　　　　set end of screenBuffer to ""
　　　　set end of screenBuffer to messageText
　　end if
　　
　　–CotEditorに依存している部分(2)　差し替え可能
　　ignoring application responses
　　　　tell application "CotEditor"
　　　　　　set contents of theDoc to screenBuffer as rich text
　　　　end tell
　　end ignoring
end renderScreen

— 指定要素をリストから削除
on removeFromList(target, sourceList)
　　set newList to {}
　　repeat with i in sourceList
　　　　set j to contents of i
　　　　if j is not target then set end of newList to j
　　end repeat
　　return newList
end removeFromList

on modKeyScan:(targKeyName as string)
　　set chkList to {"fn", "", "", "Command", "Option", "Control", "Shift", "Caps"}
　　
　　set theKey to current application’s NSEvent’s modifierFlags() as integer
　　set aBin to binaryEncode(theKey) of me
　　set detectStr to text 9 thru 16 of aBin
　　set detectList to characters of detectStr
　　set aList to {}
　　set aCount to 1
　　
　　repeat with i in detectList
　　　　set j to contents of i
　　　　if j = "1" then
　　　　　　set jj to contents of item aCount of chkList
　　　　　　set the end of aList to jj
　　　　end if
　　　　set aCount to aCount + 1
　　end repeat
　　
　　return (targKeyName is in aList) as boolean
end modKeyScan:

–0～2^32範囲の10進数を2進数の文字列に変換して返す
on binaryEncode(aNum)
　　if aNum < 0 or 67108864 < aNum then return false
　　set bitStr to ""
　　
　　repeat with i from 31 to 0 by -1
　　　　try
　　　　　　set aRes to aNum div (2 ^ i)
　　　　　　set aNum to aNum mod (aRes * (2 ^ i))
　　　　on error
　　　　　　set aRes to 0
　　　　end try
　　　　
　　　　set aRes to aRes as integer
　　　　set bitStr to bitStr & (aRes as string)
　　end repeat
　　
　　return bitStr
end binaryEncode

★Click Here to Open This Script　

macOS 26, 15.5でShortcuts.app「AppleScriptを実行」アクションのバグが修正される

Posted on 6月 10 by Takaaki Naganoya

macOS 15.xで続いていた、Shortcuts.appの「AppleScriptを実行」アクションにおいて、デフォルト入力されるべきハンドラなどのScriptが新規追加時に入力されないバグが、修正されたようです。

これは、macOS 26BetaのShortcuts.app上で本バグが修正されていたことから、macOS 15.5上のShortcuts.appの再確認を行ったところ、実際に修正されていることが明らかになりました。

macOS 15.5上のShortcuts.app　ようやく「AppleScriptを実行」アクションのバグが修正されたもよう

macOS 26, Tahoe

Posted on 6月 10 by Takaaki Naganoya

バージョン番号のリナンバーが行われ、macOS 15の次はmacOS 26ということになりました。AppleScriptで「system info」を実行すると、 system version:”26.0″が返ってきます。

スクリプトエディタのバージョンは上がっていませんが、Dark Modeへの対応が行われており、エディタ背景がDark Modeで暗くなるようです。ウィンドウの角丸の半径が大きくなって、全体的にオモチャみたいな印象を受けます。個人的に嫌いではないですが、画面を広く使えない（余白が多い）ので現場によっては困ることも。

AppleScriptのバージョンは2.8で変更なし。まだそんなに真剣に使っていないので、AppleScriptから見て挙動が変わったかといった点はわかりません。

β版のmacOSでありがちな、バージョン取得機能ミスや、aliasからPOSIX pathへの変換ミスなどは見られませんでした。

ただ、WWDC Keynoteで見られたガラス調のUIの見た目については、現時点では見られず、これがまだ実装が間に合っていないためなのか、M1 Mac miniだと環境的に再現しないのかは不明です。

テキスト読み上げ音声系のVoice Characterが増えたりはしていないのですが、「プレミアム」と「拡張」が同時に存在しているなど、ポリシーにゆらぎが見えます。どちらかにするのではないんですね。

バグ：
スクリプトエディタ内からスクリプトメニューをオンに設定しても、ステータスメニュー上にスクリプトメニューが表示されません。すぐにオフになります。この点はバグでしょう（調査が始まったとの話）。
→ 本件はリリース版で修正ずみです（βで修正されていました）

Xcode 26でAppleScript App templateが認識されませんでした。関係者に報告していますが、回答はもらっていません。一応、既存のXcode ProjectをmacOS 26に持って行って、ビルド＋実行できることは確認しています。テンプレートの場所や記法が変わったのかも？

→ Xcodeのテンプレートのフォルダが変更になったようです。従来は、~/Library/Xcode/Templatesでしたが、Xcode 26では~/Library/Developer/Xcode/Templates に変わっていました（ドキュメントとかヘルプに記載なし）。

→ 関係者との協議のすえ、これは自分の勘違いで最初から　~/Library/Developer/Xcode/Templates であったことが判明しました。

リリース版のmacOS 26で試したところ、従来どおりの組み方ではStatus Menu Itemを作成するAppleScriptがうまく動作していません。バグなのか、仕様変更なのかは不明です。

Applicationのactivateを記録する v2

Posted on 6月 8 by Takaaki Naganoya

Applicationのactivate（最前面への移動）のイベントを検知して、記録するAppleScriptです。30秒間待って、その間に最前面に移動されたアプリケーションのローカライズ名称をリストに蓄積して返します。Script終了時には、activateされたアプリの名称をリストで返します。

macOS 15.5上で動作を確認しています。スクリプトエディタ、Script Debugger、Xcode（Cocoa Application）での実行を確認していますが、observerの追加宣言の箇所、

notifCenter’s addObserver:me selector:”appWasActivated:” |name|:(current application’s NSWorkspaceDidActivateApplicationNotification) object:(missing value)

で、objectなど記述にエスケープを記述しないと動かないこともありました（Xcode）。「|object|:」と記述する必要が。

イベント記録用の実験用Scriptなので、ほぼ実用性はありません。実際に使い物にするのであれば、リアルタイムでGUIに反映させるとか、アプリごとのactivate期間を集計するとかいったレベルに昇華させる必要があることでしょう。

AppleScript名：activateを記録する v2.scptd

— Created 2015-05-30 18:11:12 +0900 by Piyomaru
— Modified 2025-06-08 12:56:30 +0900 by Piyomaru
— 2015–2025 Piyomaru Software
use AppleScript version "2.8"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property appList : {}
property prevApp : missing value

–アプリケーションのActivateをNotification Centerに登録
set theWorkspace to current application’s NSWorkspace’s sharedWorkspace()
set notifCenter to theWorkspace’s notificationCenter()
notifCenter’s addObserver:me selector:"appWasActivated:" |name|:(current application’s NSWorkspaceDidActivateApplicationNotification) object:(missing value)

delay 30
my stopObserving:(me)

return appList
–> {"Safari", "Finder", "Keynote", "QuickTime Player", "Keynote", "Finder", "スクリプトエディタ"}

on stopObserving:sender
　　set theWorkspace to current application’s NSWorkspace’s sharedWorkspace()
　　set notifCenter to theWorkspace’s notificationCenter()
　　notifCenter’s removeObserver:me |name|:(current application’s NSWorkspaceDidActivateApplicationNotification) object:(missing value)
end stopObserving:

on appWasActivated:aNotification
　　— query the notification for the active app
　　set theApp to aNotification’s userInfo()’s valueForKey:(current application’s NSWorkspaceApplicationKey)
　　set theAppName to (theApp’s localizedName()) as string
　　if prevApp is not equal to theAppName then
　　　　set prevApp to theAppName
　　　　set the end of appList to theAppName
　　end if
　　
　　using terms from scripting additions
　　　　display notification theAppName & " is activated"
　　end using terms from
end appWasActivated:

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

各種GUIアプリ書類のオープン速度を向上するためにUIアニメーションの一時停止を

指定フォルダ内から指定拡張子のファイルを取得し、エイリアスだったらオリジナルのパスをPOSIX pathで取得

macOS 15.xで自作AppleScriptライブラリの一部がScript Menuから使えなくなったので修正

確認された現象

修正して動作するようになった事例

動作条件そのものが変更になったライブラリ

問題を解消できていないライブラリ

シンプルな文字置換

①text item delimitersを利用する

②shellコマンドを利用する

③OSAXを利用する

④AppleScript Librariesを利用する

⑤Cocoaの機能を利用する

⑥offset ofで文字列検索して置換を行う

macOS（Mac OS X/OS X）上のAppleScriptの歴史

暗黙のuseコマンド

useコマンドはデフォルトで指定されている

Adobe InDesignのAppleScript実行エンジンがCarbonからCocoaベースに書き換えられる

Finderを終了させる

Claris FileMaker Pro 2025（v22）がリリースされた

ASCII ARTで直線を引く v3.1

ASCII ARTで円を塗る

ASCII ARTで円を線で描く

Appleに買収されたPixelmator ProがAppleとしての初アップデート

NLTaggerで品詞つきの日本語形態素解析

Script Debuggerがフリーダウンロードで提供されることに

macOS 26, 15.5でShortcuts.app「AppleScriptを実行」アクションのバグが修正される

macOS 26, Tahoe