Menu

Skip to content
AppleScriptの穴
  • Home
  • Products
  • Books
  • Docs
  • Events
  • Forum
  • About This Blog
  • License
  • 仕事依頼

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: System Events

新発売：AppleScript実践的テクニック集（1）GUI Scripting

Posted on 10月 10, 2022 by Takaaki Naganoya

Piyomaru Software Booksの60冊目。GUIアプリケーションを強引に動かす「GUI Scripting」について動作原理から気をつけるべき点、実戦レベルのScriptで注意している点やサンプルなどをまとめた「AppleScript実践的テクニック集（1）GUI Scripting」を発売しました。本文283ページとなっています。

→ 販売ページ

「AppleScript実践的テクニック集」とは、従来の「基礎テクニック集」の枠組みでは収まりきらないテーマを扱う新シリーズです。基礎テクニック集は32ページ前後のコンパクトな構成にするために、いろいろ省略した部分もありましたが、この枠組みに入り切らないテーマを別枠でご紹介することにしたものです。

ページ数の上限をとくに設けず、徹底的に情報を入れる設計です。それでいて、「基礎テクニック集」ゆずりの図や表を多用した構成はそのままです。

使い所さえ間違えなければ強力な武器になるGUI Scriptingについて、動作原理からノウハウ、注意すべきポイントや実戦レベルのScriptで気をつけていること、さまざまな「ありがちな処理」のサンプルなどを紹介する１冊です。

■GUI Scripting (UI Element Scripting)とは？

AS用語辞書にすべての機能は掲載されていません①
AS用語辞書にすべての機能は掲載されていません②
AppleScript非対応機能を呼ぶGUI Scripting
GUI Scriptingとは？
GUI ScriptingはSystem Eventsごしに操作
操作対象のアプリケーション①
操作対象のアプリケーション②

■AppleScript非対応機能を操作する

KeynoteでASから利用できない機能を呼ぶ
GUIアプリケーションの挙動確認が欠かせません
メニュー項目操作の実例
実行結果のリストアップ①
実行結果のリストアップ②

■GUI Scriptingの実行を許可する

デフォルト状態だとGUI Scriptingは無効
AppleScript実行アプリケーションを登録
設定するとGUI Scriptingが有効に
スクリプトメニューも登録必須
資料：macOS上のAppleScript実行環境①
資料：macOS上のAppleScript実行環境②

■GUI部品への参照を求める方法

メニュー項目：メニューを頂点としたツリー
ウィンドウ上のオブジェクト：ウィンドウが基準
簡単なGUI部品の求め方

■GUI Scriptingでやりたい特徴的な操作

GUI Scriptingの有効チェック
属性値の取得（properties）
属性値の取得（AX-attributes）
GUI部品のクリック
指定座標のクリック
参考資料：GUI Scriptingの座標系
ポップアップメニューの項目選択
キー入力操作
項目選択
コンテクストメニューの表示
スクロール操作
ファイル保存/書き出し
自分で発生させたモーダルなダイアログのクリック
ドラッグ＆ドロップ操作
日本語IMの文字入力モード取得/設定

■マウスカーソルの強制移動＆強制クリック

マウスカーソルを移動させる必要性
マウスカーソルの強制移動とクリック

■実戦レベルのAppleScriptにおけるGUI Scripting解説

指定フォルダ以下のPagesなどをPDF出力して連結
実際のメインScript部分
generatePDFLibの当該箇所
本プログラムが環境の影響を受けた点
参考資料：デスクトップの表示/非表示切り替え

■Accessibility Inspectorの使い方

Xcodeに入っているGUI部品探索ツール
Accessibility Inspectorの画面構成①
Accessibility Inspectorの画面構成②
プロセス一覧から対象を選択してInspection
指定プロセスのGUI部品の追跡中の画面表示
GUI部品の追跡ポーズ中の画面表示

■OSやアプリケーションのアップデートに備える

OSアップデートごとにGUI構成は変わる
GUI Scripting処理部分だけをサブルーチンに分離
GUI Scripting処理部分をライブラリに分離
OSアップデートの影響を受けにくい構造に

■GUI Scriptingの信頼性は？

GUI Scriptingの信頼性は？
一般的な信頼性の計測方法
経験に基づく傾向と対策
GUI Scriptingで直面した問題とその解決策
指定した処理の終了前に次の処理が行われる
同じ名前のプロセスが存在していると名称衝突①
同じ名前のプロセスが存在していると名称衝突②

■GUI Scriptingサンプル集

指定のアプリケーションの全メニュータイトルを取得
選択中のテキストを取得
選択中のテキストを書き換え
Safariの最前面のウィンドウへの参照を得る
GUI部品への参照から所属するアプリケーション名を取得
Dockに登録されているアイコンの情報を取得
Keynoteで選択中のテキストを縦書きに
CotEditorで最前面のウィンドウを縦書きに

■GUI Scripting資料集

click【クリック】コマンド
key code【キーコード】コマンド
keystroke【キーストローク】コマンド
perform【パフォーム】コマンド
select【セレクト】コマンド
application【アプリケーション】クラス
action【アクション】クラス
application process【アプリケーションプロセス】クラス
attribute【アトリビュート】クラス
browser【ブラウザ】クラス
busy indicator【ビジーインディケータ】クラス
button【ボタン】クラス
checkbox【チェックボックス】クラス
color well【カラーウェル】クラス
column【カラム】クラス
combo box【コンボボックス】クラス
desk accessory process【デスクアクセサリプロセス】クラス
drawer【ドロワー】クラス
group【グループ】クラス
grow area【グローエリア】クラス
image【イメージ】クラス
incrementor【インクリメンタ】クラス
list【リスト】クラス
menu【メニュー】クラス
menu bar【メニューバー】クラス
menu bar item【メニューバーアイテム】クラス
menu button 【メニューボタン】クラス
menu item 【メニューアイテム】クラス
outline 【アウトライン】クラス
pop over 【ポップオーバー】クラス
pop up button 【ポップアップボタン】クラス
process 【プロセス】クラス
progress indicator 【プログレスインジケータ】クラス
radio button 【ラジオボタン】クラス
radio group【ラジオグループ】クラス
relevance indicator【レレベンスインジケータ】クラス
row【ロー】クラス
scroll area【スクロールエリア】クラス
scroll bar 【スクロールバー】クラス
sheet 【シート】クラス
slider【スライダ】クラス
splitter【スプリッタ】クラス
splitter group【スプリッタグループ】クラス
static text【スタティックテキスト】クラス
tab group【タブグループ】クラス
table【テーブル】クラス
text area【テキストエリア】クラス
text field【テキストフィールド】クラス
toolbar【ツールバー】クラス
UI element【ユーアイエレメント】クラス
value indicator【バリューインディケータ】クラス
window【ウインドウ】クラス

■AppleScript資料集

macOSバージョンとAppleScriptの動向
macOSとAppleScriptの要素技術史
各macOSごとのAppleScript解説
macOS内AppleScript補助ツールの歴史
System EventsのAppleScript用語辞書変更点
AppleScript 各ランタイム環境情報
AppleScript予約語一覧
AppleScriptのエラーコード
あとがき
奥付

Posted in Books GUI Scripting news PRODUCTS | Tagged 12.0savvy CotEditor Keynote System Events TextEdit | Leave a comment

同じバージョン番号のまま大幅に機能が変更されたSystem Events

Posted on 12月 15, 2020 by Takaaki Naganoya

macOS 10.15はBetaの頃から出来が悪くて、とても「これは常用できない」としてメインマシンにはインストールせず、専用のマシンに入れて様子を見ていました。10.15については「こんなもんリリースすんな」という印象。10.13については、担当者の首が飛ばない理由が分からない出来でした。

そんなmacOS 10.15で、ご無体な変更がSystem Eventsに見られました。

10.13、10.14、10.15、11.0とSystem Eventsのバージョン番号は同じ「1.3.6」ですが、AppleScript用語辞書の内容が大幅に変更されています。

これまでにもAppleのエンジニアの失敗やバグにいろいろ酷い目に遭わされてきましたが、「内容に大幅に変更があってもバージョン番号を変えない」という新たな失敗が記録されることになりました。これは、斬新な手口ですね！　

今後も、バージョン番号を変更せずに機能の変更を行なってくることが予想されます。できれば、ちゃんとバージョン番号を変更することも覚えてほしいですよね。

■macOS 10.13→10.14

（１）Disk-Folder-File Suiteから、指定のOSA言語のScriptを実行する「do script」コマンドが削除されました。同機能は標準命令の中にも重複して存在しており、とくに影響はありません。

■macOS 10.14→10.15

（１）desktop picture settingsに「dynamic style」という属性値が新設されました。指定できる値は「auto」「dynamic」「light」「dark」「unknown」。

（２）Audio File Suiteが削除された
どこまで行っても実装が微妙だったAudio File Suiteが削除されました。32bitコードだったのでしょうか。

（３）Movie File Suiteが削除された
同じく、微妙な出来だったMovie File Suitesが削除されました。理由はAudio File Suiteと同じなのでしょう。

（３）QuickTime File Suiteが削除された
同上。

（４）key up/key downコマンドが強化された
文字コードでしか指定できなかったkey up/key downコマンドが強化され、integerでキーコードを指定する従来どおりの指定方法のほか、textでキーボードの文字を指定できるようになりました。

■macOS 10.15→11.1

（１）dock preferences objectに属性値が新設された
autohide menu bar：システムメニューバーの自動非表示機能のオン/オフ
double click behavior：ウィンドウのタイトルバーをダブルクリックしたときの挙動の切り替え
minimize into application：ウィンドウのタイトルバーをダブルクリックしたときにDock上のアプリケーションアイコンに向けて最小化？
show indicators：Dock上のアプリケーションアイコンに起動中のインジケータ表示を行う/行わない設定
show recents：最近使ったアプリケーションのグループを表示する設定

こうした調査は、AppleScript用語辞書ファイル（sdef）そのものや、それをHTMLに書き出したデータを比較することで検討しているわけですが、一回それを電子書籍のオマケにすることを検討したものの、他のScripterに「そういうものに興味はないか？」と聞いてみたところ、まったく関心を持っていないようでした。

ある意味、最重要書類というか「秘伝のタレ」に近い情報ではあったものの、コピペだけでコードを書いているレベルのScripterは、そういう「一次情報」（死活問題になる）に関心がないんだなーということが分かっただけでした。

■表　System Eventsの用語辞書の変遷（「最新事情がわかるAppleScript 10大最新技術」より引用してアップデート）

macOS Version 10.x 2 3 4 5 6 7 8 9 10 11 12 13 14 15 11.0
Standard Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
System Events Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Accounts Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Appearance Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
CD and DVD Preferences Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Desktop Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Dock Preferences Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Login Items Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Network Preferences Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Screen Saver Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Audio File Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Security Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Disk-Folder-File Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Folder Actions Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Movie File Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Power Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Processes Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Property List Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
QuickTime File Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
XML Suite ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Type Definitions ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■ ■
Scripting Definition Suite ■ ■ ■ ■ ■ ■ ■
Text Suite ■ ■ ■ ■ ■ ■ ■
Expose Preferences Suite ■ ■ ■ ■
Posted in news | Tagged 10.14savvy 10.15savvy 11.0savvy System Events | 1 Comment

Switch Controlを起動

Posted on 5月 13, 2020 by Takaaki Naganoya

Switch Controlを起動するAppleScriptです。macOS標準搭載のScript Menuに入れて呼び出して使っています。Switch Controlは、障害者向けの支援機能を提供するmacOSの標準機能で、標準のマウス/トラックパッド、キーボードなどの利用が困難なユーザーに向けて少ないボタンや音声で操作する機能を提供するものです。

一般のユーザーにとってもSwitch Controlは有効活用できる機能であるため、個人的にいろいろ試しています。

もともと、Switch Controlを起動するためのコマンドは用意されていません。AppleScriptのコマンドで起動できるとか、コマンドラインから起動できるとかいった手軽な起動手段は存在していません。

……というわけで、仕方なくGUI Scriptingで画面上のチェックボックスをクリックするという不毛な処理を書いたわけですが、ただダラダラとGUI部品の階層をなぞるだけの知性のカケラもないコードを書くだけでは意味がありません。

この、クリックする対象のチェックボックスを実行言語環境が変わっても自動で検出できるようにチャレンジしてみました。

結果：失敗　追いかける対象が大きすぎたようです。システム環境設定の画面上のチェックボックスについているタイトル文字を特定するだけの話なのですが、システム環境設定（System Preferences.app）の各機能はプラグインで提供されており、システム環境設定のバンドル内のstringsファイルを追いかけても希望の文字列は得られません。

＃　このため、チェックボックスのタイトルを言語環境ごとに書き換える必要があります

では、実際に各プラグインのバンドル構造内でstringsファイルを取得することを試みたのですが、これにも失敗。それらしい文字列は得られるものの、文章すべてが１エントリに登録されているわけではないようで、stringsファイルでキーを指定すれば各ロケールごとの対象文字列が得られる……という理想的な処理はできませんでした。

今回のアプローチは技術的には失敗してしまいましたが、他の誰かが突破する日も来るかもしれません。自分のマシンのSSD内には、割とそうした「失敗作」のScriptも存在しており、そうした失敗作が別の機会の土台になることも多々あります。

仕事で作り込む必要のあるScriptであれば、スクリプトバンドル内に各言語ごとの文字列テーブルを自分で作って、localized stringでその値を引けるようにする感じでしょうか。OS側で対象箇所の文言を変更した場合には自分のテーブル側もアップデートする必要が出てきてしまいます。

本Scriptの冒頭でSwitch Controlが起動しているかどうかのチェックを行い、起動中であれば起動処理を行わないようにしています。この判定処理自体は、単体ではほぼ意味がありませんが、こうして組み合わせることで「不要な処理を行わない」ための部品として有効に活用できているといえます。

AppleScript名：Switch Controlを起動
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/13
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set aRes to launchSwitchControl() of me

on launchSwitchControl()
　　if current application’s NSWorkspace’s sharedWorkspace()’s isSwitchControlEnabled() = true then return true
　　set aLoc to (current application’s NSLocale’s currentLocale()’s languageCode()) as string
　　
　　–Current Language detection
　　if aLoc = "en" then
　　　　set aStr to "Enable Switch Control" –English
　　else if aLoc = "ja" then
　　　　set aStr to "スイッチコントロールを有効にする" –Japanese
　　else
　　　　error "Make current language entry"
　　end if
　　
　　tell application "System Preferences"
　　　　activate
　　　　tell pane id "com.apple.preference.universalaccess"
　　　　　　reveal anchor "Switch"
　　　　end tell
　　end tell
　　
　　set hitF to false
　　
　　tell application "System Events"
　　　　tell process "System Preferences"
　　　　　　repeat 200 times
　　　　　　　　delay 0.1
　　　　　　　　if (exists checkbox aStr of tab group 1 of group 1 of window 1) then
　　　　　　　　　　click checkbox aStr of tab group 1 of group 1 of window 1
　　　　　　　　　　set hitF to true
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　end repeat
　　　　end tell
　　end tell
　　
　　tell application "System Preferences" to quit
　　return hitF
end launchSwitchControl

★Click Here to Open This Script　
Posted in GUI Scripting | Tagged 10.14savvy 10.15savvy Switch Control System Events | Leave a comment

面積で評価して、Keynoteのメインウィンドウのうち最大のもののItem Numberを返す

Posted on 5月 10, 2020 by Takaaki Naganoya

ウィンドウ上に複数存在するscroll areaのうち処理対象となるべきものを面積を計算することで特定するGUI Scripting系のAppleScriptです。

どーしてもGUI Scriptingでしか操作できない機能があって、それを自動化する価値があって、大幅に発生する可能性の高い労力を削減できる見込みが立ったので、一気に自動化Scriptを作成。本Scriptはその中で作成した１つの部品です。

自分が書いた処理内容は、Keynoteで作った書類の目次ページに用意した、各スライドのタイトルに実際のスライドへのリンクを付加するもの。

本来、Keynote自体のAppleScript用語辞書に標準装備されていてほしい機能です。残念ながら標準装備されていないために、自分で組む必要があったわけです。

それを作っている途中で、このメインの（Keynoteオブジェクトを配置する中央のエリア）scroll areaのIDが起動するたびに変わるという現象に直面。初期状態（インスペクタの表示状態）をそろえてもIDが変わる。たいていこうしたGUI Scriptingがらみの「怪奇現象」に直面した場合には、スクルプトエディタやアプリケーションの再起動を行えば回避できることが多いのですが、何回かためしても回避できなかったので、scroll areaの特定をID以外で行うことに。

IDが毎回（起動ごとに）変更になるので、「最大の面積を持つもの」を計算して求めるようにしてみました。

AppleScript名：面積で評価して、Keynoteのメインウィンドウのうち最大のもののItem Numberを返す
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/05/09
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set areaNum to getKenoteScrollAreaMax() of me

–面積で評価して、Keynoteのメインウィンドウのうち最大のもののItem Numberを返す
on getKenoteScrollAreaMax()
　　tell application "System Events"
　　　　tell process "Keynote"
　　　　　　tell window 1
　　　　　　　　set sCount to count every scroll area
　　　　　　　　set tmpMax to 0
　　　　　　　　set tmpMaxItem to 0
　　　　　　　　repeat with i from 1 to sCount
　　　　　　　　　　tell scroll area i
　　　　　　　　　　　　set tmpA to size
　　　　　　　　　　　　copy tmpA to {tmpW, tmpH}
　　　　　　　　　　　　set tmpArea to tmpW * tmpH
　　　　　　　　　　　　if tmpArea > tmpMax then
　　　　　　　　　　　　　　set tmpMax to tmpArea
　　　　　　　　　　　　　　set tmpMaxItem to i
　　　　　　　　　　　　end if
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　return tmpMaxItem
end getKenoteScrollAreaMax

★Click Here to Open This Script　
Posted in GUI Scripting | Tagged 10.13savvy 10.14savvy 10.15savvy Keynote System Events | Leave a comment

マウス充電用AppleScript

Posted on 3月 6, 2020 by Takaaki Naganoya

本Scriptはいつも書き捨てにするAppleScriptですが、使用頻度はそれなりに高いものです。

AppleのMagic Mouse 2を充電するには、裏返してLightningケーブルを挿す必要があります。

STEP1：コンピュータをスリープさせる
STEP2：マウスを裏返す
STEP3：ケーブルを挿して充電する

という手順になるわけですが、、、マウスを裏返した時点でボタンが押されたりして、充電できないケースが多々あります。

そこで、本Scriptをスクリプトエディタ上で実行して、10秒以内にマウスに充電ケーブルを挿すと、あとからコンピュータがスリープ。問題なくマウスを充電できます。

AppleScript名：マウス充電用Script
delay 10

tell application "System Events" to sleep

★Click Here to Open This Script　
Posted in How To System | Tagged 10.13savvy 10.14savvy 10.15savvy System Events | Leave a comment

Bundle IDで指定したアプリケーションを「隠す」

Posted on 2月 16, 2020 by Takaaki Naganoya

Bundle IDで指定したアプリケーションを隠すAppleScriptです。

アプリケーションの指定

macOS上のアプリケーションは一意に判別できるID「Bundle ID」を持っています。このBundle IDは各アプリケーションのバンドル内のInfo.plistに書かれています。

アプリケーションの名称については、ローカライズ名称を指定できるので、英語環境、フランス語環境、日本語環境で異なるアプリケーション名がFinder上で見えるようにできるので、名称ではなくBundle IDで区別するのが一般的です。

言語環境ごとに名称が変わる代表的なアプリケーションには、「リマインダー」（本当の名称はReminders）、「メモ」（本当の名称はNotes）、「写真」（本当の名称はPhotos）などがあります。

アプリケーションプロセスの隠し方

各アプリケーションのアプリケーションメニューに「隠す」というメニュー項目があり、これを実行することで隠すことができます。AppleScriptからこれに該当する操作は、System Eventsに対して指定のアプリケーションプロセスの可視属性をfalseに設定するというものです。

野蛮かつ強引にメニューを操作するという方法（GUI Scripting）も使えますが、速度や信頼性の面でおすすめしません。

AppleScript名：指定アプリケーションプロセスを隠す（System Events）
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/02/16
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—

set pRes to hideAProcessByBUndleID("com.apple.Safari") of me

–指定プロセスを隠す
on hideAProcessByBUndleID(aBundleID)
　　tell application "System Events"
　　　　set targProcList to every process whose bundle identifier is aBundleID
　　　　if targProcList = {} then return false
　　　　
　　　　set targProc to first item of targProcList
　　　　tell targProc
　　　　　　set visible to false
　　　　end tell
　　end tell
　　return true
end hideAProcessByBUndleID

★Click Here to Open This Script　

macOS 10.10以降では通常のAppleScriptでCocoaの機能が使えるようになったため、こうしたOS側の機能を用いてもよいでしょう。


▲セキュリティダイアログの表示例

むしろ、macOS 10.14以降では各種アプリケーションへの初回命令時にはセキュリティ・ダイアログが表示されて止まるため、Cocoaの機能を利用できたほうがメリットが大きいといえるぐらいです。

AppleScript名：指定アプリケーションプロセスを隠す（Cocoa）
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2020/02/16
—
–　　Copyright © 2020 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set pRes to hideAProcessByBUndleID("com.apple.Safari") of me

–指定プロセスを隠す
on hideAProcessByBUndleID(aBundleID)
　　set appArray to current application’s NSRunningApplication’s runningApplicationsWithBundleIdentifier:aBundleID
　　if appArray’s |count|() > 0 then
　　　　set appItem to appArray’s objectAtIndex:0
　　　　set aRes to (appItem’s hide()) as boolean
　　　　return aRes
　　else
　　　　return false
　　end if
end hideAProcessByBUndleID

★Click Here to Open This Script　
Posted in System | Tagged 10.14savvy 10.15savvy NSArray NSRunningApplication System Events | Leave a comment

GUI ScriptingでGUI要素のIDもOSアップデート後には見直す必要あり

Posted on 1月 13, 2020 by Takaaki Naganoya

GUI Scripting、それは画面上のGUI部品に直接メッセージを送って強引にアプリケーションを動かす必要悪。AppleScript非対応機能を強引に動かすことが目的の機能です。

MarkdownエディタのMacDownも、PDF書き出しについてはAppleScript用語辞書にコマンドが掲載されていないので、Markdown書類のPDF書き出しはGUI Scriptingで行なっています。

メイン環境をmacOS 10.12.6から10.14.6に移行して、はじめて動かした重量級のAppleScriptがあります。指定フォルダ以下のPages、Markdown、Wordなどの書類をすべてデスクトップ上にPDFで書き出して、ファイル名順にならべかえて１つのPDFにまとめるAppleScriptです。

つまり、電子書籍の書き出し＆連結作業を１本でこなすScriptなわけで、自分にとっては命綱的に重要なAppleScriptです。

で、こいつがmacOS 10.14.6上でまともに動かないことが判明して、顔色が変わりました。

システム環境設定のセキュリティ系の妨害を受けているのかと思って確認してみると、必要な設定はすべて行なってある状態。MacDownからのPDF書き出しだけが効いていません。


–注意！！　ここでGUI Scriptingを使用。バージョンが変わったときにメニュー階層などの変更があったら書き換え
on macDownForceExport()
　　activate application "MacDown"
　　tell application "System Events"
　　　　tell process "MacDown"
　　　　　　— File > Export > PDF
　　　　　　–click menu item 2 of menu 1 of menu item 14 of menu 1 of menu bar item 3 of menu bar 1
　　　　　　click menuItemRef1
　　　　　　
　　　　　　–Go to Desktop Folder
　　　　　　keystroke "d" using {command down}
　　　　　　
　　　　　　–Save Button on Sheet
　　　　　　click button 1 of sheet 1 of window 1
　　　　end tell
　　end tell
end macDownForceExport

★Click Here to Open This Script　

ためしに、SIPを解除して実行してみたものの、それでも問題は解決しません。

動きを観察していると、書き出し時に「保存」ではなく「キャンセル」ボタンをクリックしている模様。そこで、ボタンをIndexではなくTitleで指し示してみたら、問題なく書き出しできました。


–注意！！　ここでGUI Scriptingを使用。バージョンが変わったときにメニュー階層などの変更があったら書き換え
on macDownForceExport()
　　activate application "MacDown"
　　tell application "System Events"
　　　　tell process "MacDown"
　　　　　　— File > Export > PDF
　　　　　　–click menu item 2 of menu 1 of menu item 14 of menu 1 of menu bar item 3 of menu bar 1
　　　　　　click menuItemRef1
　　　　　　
　　　　　　–Go to Desktop Folder
　　　　　　keystroke "d" using {command down}
　　　　　　
　　　　　　–Save Button on Sheet
　　　　　　click button "保存" of sheet 1 of window 1 –保存ボタンのIndexが変わっていた
　　　　end tell
　　end tell
end macDownForceExport

★Click Here to Open This Script　

＃　久しぶりに怪奇現象っぽい挙動で震えました。だいたい、怪奇現象とか心霊現象っぽい挙動というのは、技術や経験が足りない場合に「そう見える」だけであって、知っていたり経験していれば「当然」という現象に見えます

いま、ちょうどGUI Scriptingは端境期で、手で書かなくてもアプリケーションの状態を検知してオブジェクト階層を動的に走査して動かすようなScriptが一部で使われている一方で、古いタイプのIDやTitleを直接指定するような書き方が残っていたりします。

OSがアップデートされても、IDで書いておけば同じGUI部品を指定できるだろう、という思い込みがありましたが、Titleで指定していたほうがIDの数え方が変わっても影響がない、という現象だったのでしょうか。

久しぶりにハマりそうになりました。あと、MacDownのソースに手を入れて、PDF書き出し命令ぐらいは自前で実装したい気がします。

Posted in GUI Scripting | Tagged 10.14savvy MacDown System Events | Leave a comment

GUI Scripting的なUI Elementへの参照から所属するアプリケーション名を取得する

Posted on 9月 17, 2018 by Takaaki Naganoya

GUI Scripting的なUI Elementへの参照をもとに、そのUI Elementが所属するアプリケーション名を取得するAppleScriptです。

こんな、Safariの「ファイル」メニューの中にあるメニュー項目、

menu item “PDFとして書き出す…” of menu “ファイル” of menu bar item “ファイル” of menu bar 1 of application process “Safari”

があったとして、このオブジェクトが所属しているアプリケーション名を取得したいというケースがありました。上記の例では「Safari」がそれに該当します。

GUI Scripting的なお約束として、オブジェクト階層が上から下に向かって取得する場合には「entire contents」でまとめて取得できるのですが、下から上に向かってparentで取得できるわけでもなく、アプリケーションプロセス名をさかのぼって取得するといった処理ができていませんでした。

AppleScriptの「仕様」的には不可能です。

でも、不可能であることさえわかれば（正攻法では不可能なので）、いつものトリッキーかつ邪道な手口でなんとかなりそうです。

そうです、エラートラップ中で無理やりエラーを起こして、そのエラーメッセージの情報から取得してしまおうという、いつものやつです。

というわけで、GUI Elementの情報から所属アプリケーション名を取得できました。

最近は、さらなる「卑劣な手段」を用意しているので、そちらで華麗かつ卑劣に処理してもよかったのですが、とりあえず手短にまとめたかったのでいつものやつで処理しました。

AppleScript名：GUI Scripting的なUI Elementへの参照から所属するアプリケーション名を取得する.scptd
—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/09/17
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "System Events"
　　set aRef to menu item "PDFとして書き出す…" of menu "ファイル" of menu bar item "ファイル" of menu bar 1 of application process "Safari"
end tell

set appName to retRootAppProcessNameFromGUIElementRef(aRef) of me
–> "Safari"

–GUI Scripting的なUI Elementへの参照から、rootのアプリケーションプロセス名を取得する
on retRootAppProcessNameFromGUIElementRef(aRef)
　　try
　　　　set aStr to aRef as string –force cause error
　　on error erM
　　　　set offsetA to offset of " of application ＼"System Events＼"" in erM
　　　　set offsetB to offset of "«class pcap» " in erM
　　　　set appName to text (offsetB + (length of "«class pcap» ") + 1) thru (offsetA – 2) of erM
　　　　return appName as string
　　end try
end retRootAppProcessNameFromGUIElementRef

★Click Here to Open This Script　
Posted in GUI GUI Scripting System | Tagged 10.11savvy 10.12savvy 10.13savvy System Events | Leave a comment

各デスクトップのデスクトップピクチャをPreviewでオープン

Posted on 6月 1, 2018 by Takaaki Naganoya

各デスクトップに設定してあるデスクトップピクチャのパスをもとめ、Preview.appでオープンするAppleScriptです。

こんな感じに複数のディスプレイにデスクトップピクチャが設定してある状態で実行すると、

すべてのディスプレイのデスクトップピクチャの画像をPreview.appでオープンします。

Keynoteで資料を作っているときに、デスクトップのキャプチャを行なったような場合に、デスクトップピクチャを含めて合成できたほうが便利なケースがあって、そのようなときに書いた「作り捨て」レベルのScriptです。

AppleScript名：各デスクトップのデスクトップピクチャをPreviewでオープン
tell application "System Events"
　　set aList to picture of every desktop
end tell

repeat with i in aList
　　try
　　　　set targFile to (POSIX file i) as alias
　　　　tell application "Preview"
　　　　　　open targFile
　　　　end tell
　　end try
end repeat

★Click Here to Open This Script　
Posted in System | Tagged 10.11savvy 10.12savvy 10.13savvy Preview System Events | Leave a comment

指定ファイルの拡張子を取得する

Posted on 2月 19, 2018 by Takaaki Naganoya

指定ファイルの拡張子を取得するAppleScriptです。

純粋にパス文字列から拡張子を取得する方法（テキストを逆順に変換してピリオドに遭遇するところまでを拡張子とみなす）などもありますが、それは当時の環境（AppleScript Studio）でエラーの出にくい処理方法を選択したものでした。

FinderやSystem Eventsの機能を用いて拡張子を取得するのが一番手軽ではあるのですが、macOS 10.14以降の環境ではこの程度でもアプリケーションの機能を呼び出すと認証ダイアログが（初回のみですが）表示されます。Cocoaの機能呼び出しが手軽にできるので、些細な処理でもよく呼び出して使っています（個人的に）。

Mac App Storeに出すアプリケーションの内部で、ファイルの拡張子を求めるためだけにFinderやSystem Eventsのコントロールを行おうとするのはリジェクトの原因になります。そういう場合には純粋に文字列処理するか、Cocoaの機能を用いることになるでしょう。

AppleScript名：指定ファイルの拡張子を取得する
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set a to choose file
set aPath to POSIX path of a
set pathString to current application’s NSString’s stringWithString:aPath
set newPath to (pathString’s pathExtension()) as string
–>　　"jpg"

★Click Here to Open This Script　
AppleScript名：ファイルから拡張子を取得（Finder）
set aFile to choose file

tell application "Finder"
　　set aExt to name extension of aFile
end tell

★Click Here to Open This Script　
AppleScript名：ファイルから拡張子を取得（System Events）
set aFile to choose file

tell application "System Events"
　　set aExt to name extension of aFile
end tell

★Click Here to Open This Script　
Posted in File path | Tagged 10.11savvy 10.12savvy 10.13savvy Finder System Events | Leave a comment

フルパスからファイル名を取得する

Posted on 2月 19, 2018 by Takaaki Naganoya

フルパスからファイル名を取得するAppleScriptです。

AppleScriptでは、ファイルパス形式をいくつか併用しています。HFS形式、URL形式、POSIX形式などです。


▲2019/7/20変更。POSIX pathからaliasに直接変換できるような誤解を招く表現があったので、いったんPOSIX file（=file）を経由しないとaliasに変換できないことを表現


▲2022/6/3変更。NSURL（file://）から直接「as alias」で変換できることが判明。この変換を追記

ここではPOSIX形式のパスからファイル名を、Cocoaの機能を用いて求めるScriptを掲載しています。

AppleScript名：フルパスからファイル名を取得する
— Created 2017-02-04 10:38:44 +0900 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aPath to "/Users/me/Documents/ぴよまるソフトウェア/–Book1「AppleScript最新リファレンス」/9999_images/E81F91B7-4931-463F-A027-21A18A853290.jpg"

set aStr to (current application’s NSString’s stringWithString:aPath)’s lastPathComponent() as string
–>　　"E81F91B7-4931-463F-A027-21A18A853290.jpg"

★Click Here to Open This Script　

古典的なAppleScriptのやり方だと、aliasからアプリケーションの機能を用いてファイル名を取得することになります。

AppleScript名：aliasからファイル名を取得（Finder）
set aFile to choose file

tell application "Finder"
　　set aName to name of aFile
end tell

★Click Here to Open This Script　
AppleScript名：aliasからファイル名を取得（System Events）
set aFile to choose file

tell application "System Events"
　　set aName to name of aFile
end tell

★Click Here to Open This Script　
Posted in File path | Tagged 10.11savvy 10.12savvy 10.13savvy Finder System Events | Leave a comment

VPN経由のネットワーク接続を切断する

Posted on 2月 11, 2018 by Takaaki Naganoya
AppleScript名：VPN経由のネットワーク接続を切断する
— Created 2017-09-30 by Takaaki Naganoya
— 2017 Piyomaru Software

tell application "System Events"
　　tell current location of network preferences
　　　　set sList to every service whose kind is 13 and active is true –種別がVPNのNetwork Serviceで状態がactive（接続中）のものを取得
　　　　if sList = {} then return false
　　　　
　　　　if length of sList is not equal to 1 then
　　　　　　–複数VPNが存在している場合にはユーザー選択
　　　　　　set ssRes to choose from list sList
　　　　　　if ssRes = false then return false
　　　　　　set sRes to first item of ssRes
　　　　else
　　　　　　set sRes to first item of sList
　　　　end if
　　　　
　　　　disconnect sRes
　　end tell
end tell

★Click Here to Open This Script　
Posted in Internet | Tagged 10.11savvy 10.12savvy 10.13savvy System Events | Leave a comment

VPN経由でネットワーク接続

Posted on 2月 11, 2018 by Takaaki Naganoya

VPN経由でネットワーク接続を行うAppleScriptです。

システム環境設定の「ネットワーク」で「VPN」を追加、定義し、正常にVPN接続できていることを確認してください。本AppleScriptはあらかじめ定義してあるVPN接続先への自動接続を行うものです。

複数のVPN接続を定義してある場合にはユーザーに選択を求めます。

VPN接続関連のAppleScriptの機能に、勝手に新規接続先を定義してVPN接続できるようなものはありません。あくまで、すでにユーザーが定義したVPN接続先に対して接続/切断を行うだけの機能です。

AppleScript名：VPN経由でネットワーク接続
— Created 2017-09-30 by Takaaki Naganoya
— 2017 Piyomaru Software

tell application "System Events"
　　tell current location of network preferences
　　　　set sList to every service whose kind is 13 –種別がVPNのNetwork Service
　　　　if sList = {} then return false
　　　　
　　　　if length of sList is not equal to 1 then
　　　　　　–複数VPNが存在している場合にはユーザー選択
　　　　　　set ssRes to choose from list sList
　　　　　　if ssRes = false then return false
　　　　　　set sRes to first item of ssRes
　　　　else
　　　　　　set sRes to first item of sList
　　　　end if
　　　　
　　　　connect sRes
　　end tell
end tell

★Click Here to Open This Script　
Posted in Internet | Tagged 10.11savvy 10.12savvy 10.13savvy System Events | Leave a comment

指定名称のアプリケーションプロセスが存在すればその正しい名前を返す

Posted on 2月 8, 2018 by Takaaki Naganoya
AppleScript名：指定名称のアプリケーションプロセスが存在すればその正しい名前を返す
— Created 2015-07-29 16:43:11 +0900 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aName to "メール"
set aRes to returnExactNameOfAnApp(aName) of me

on returnExactNameOfAnApp(aName)
　　tell application "System Events"
　　　　set ap1List to every process whose name is equal to aName
　　　　if ap1List = {} then
　　　　　　set ap1List to every process whose displayed name is equal to aName
　　　　　　if ap1List = {} then return false
　　　　end if
　　　　set anApp to contents of first item of ap1List
　　　　return name of anApp
　　end tell
end returnExactNameOfAnApp

★Click Here to Open This Script　
Posted in System | Tagged 10.11savvy 10.12savvy 10.13savvy System Events | Leave a comment

Safariのダウンロードフォルダを求めるv4

Posted on 2月 6, 2018 by Takaaki Naganoya

本ScriptはSafariのダウンロードフォルダのパスを求めるためのものですが、macOSおよびSafariのアップデートによって動かなくなりました。

現時点では設定値からダウンロードフォルダを知ることはできないようです。セキュリティ上「できては困る」という判断が行われたものでしょうか。

なので、Spotlightの機能を用いて、「Download」フォルダを検索し、見つかったものの一覧からユーザーに選んでもらうとか、デフォルト状態のDownloadフォルダを指定してみて存在しなかったらユーザーに選択してもらうといった方法になると思われます。

AppleScript名：Safariのダウンロードフォルダを求めるv4
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

getSafariDownloadFolder() of me
–> alias "Cherry:Users:me:Downloads:"

–By Phillip Aker, Mark J Reed
on getSafariDownloadFolder()
　　set preferencesPath to POSIX path of (path to preferences)
　　set bundleId to bundle identifier of (info for (path to application "Safari"))
　　set safariPrefsFile to preferencesPath & bundleId & ".plist"
　　tell application "System Events" to set folderName to get value of property list item "DownloadsPath" of property list file safariPrefsFile
　　
　　set pathString to current application’s NSString’s stringWithString:folderName
　　set dlPath to pathString’s stringByExpandingTildeInPath() as string
　　return (POSIX file dlPath) as alias
end getSafariDownloadFolder

★Click Here to Open This Script　
Posted in 未分類 | Tagged 10.11savvy 10.12savvy 10.13savvy System Events | 1 Comment

ダークモード/ライトモードの切り替え

Posted on 2月 6, 2018 by Takaaki Naganoya

Dark Modeのトグル切り替えを行うAppleScriptです。

System Eventsに問い合わせて、appearance preferencesのDark Modeがtrueならダークモード、Dark Modeがfalseならライトモード（通常モード）です。

＃　Mac App Store用アプリケーションの中で使うとリジェクトの原因になります

AppleScript名：ダークモードの検出 v2
tell application "System Events"
　　tell appearance preferences
　　　　set dark mode to not dark mode
　　end tell
end tell

★Click Here to Open This Script　
Posted in 未分類 | Tagged 10.11savvy 10.12savvy 10.13savvy 10.14savvy System Events | Leave a comment

電子書籍（PDF）をオンラインストアで販売中！

Google Search

Popular posts

  • macOS 13, Ventura（継続更新）
  • アラートダイアログ上にWebViewで3Dコンテンツを表示（WebGL＋three.js）v3
  • Xcode 14.2でAppleScript App Templateを復活させる
  • UI Browserがgithub上でソース公開され、オープンソースに
  • macOS 13 TTS Voice環境に変更
  • 2022年に書いた価値あるAppleScript
  • ChatGPTで文章のベクトル化（Embedding）
  • 新発売：AppleScriptからSiriを呼び出そう！
  • iWork 12.2がリリースされた
  • 従来と異なるmacOS 13の性格？
  • 新発売：CotEditor Scripting Book with AppleScript
  • macOS 13対応アップデート：AppleScript実践的テクニック集（1）GUI Scripting
  • AS関連データの取り扱いを容易にする（はずの）privateDataTypeLib
  • macOS 13でNSNotFoundバグふたたび
  • macOS 12.5.1、11.6.8でFinderのselectionでスクリーンショット画像をopenできない問題
  • ChatGPTでchatに対する応答文を取得
  • 新発売：iWork Scripting Book with AppleScript
  • Finderの隠し命令openVirtualLocationが発見される
  • macOS 13.1アップデートでスクリプトエディタの挙動がようやくまともに
  • あのコン過去ログビューワー（暫定版）

Tags

10.11savvy (1101) 10.12savvy (1242) 10.13savvy (1390) 10.14savvy (586) 10.15savvy (434) 11.0savvy (277) 12.0savvy (185) 13.0savvy (55) CotEditor (60) Finder (47) iTunes (19) Keynote (98) NSAlert (60) NSArray (51) NSBezierPath (18) NSBitmapImageRep (20) NSBundle (20) NSButton (34) NSColor (51) NSDictionary (27) NSFileManager (23) NSFont (18) NSImage (41) NSJSONSerialization (21) NSMutableArray (62) NSMutableDictionary (21) NSPredicate (36) NSRunningApplication (56) NSScreen (30) NSScrollView (22) NSString (117) NSURL (97) NSURLRequest (23) NSUTF8StringEncoding (30) NSView (33) NSWorkspace (20) Numbers (56) Pages (37) Safari (41) Script Editor (20) WKUserContentController (21) WKUserScript (20) WKUserScriptInjectionTimeAtDocumentEnd (18) WKWebView (23) WKWebViewConfiguration (22)

カテゴリー

  • 2D Bin Packing
  • 3D
  • AirDrop
  • AirPlay
  • Animation
  • AppleScript Application on Xcode
  • beta
  • Bluetooth
  • Books
  • boolean
  • bounds
  • Bug
  • Calendar
  • call by reference
  • Clipboard
  • Code Sign
  • Color
  • Custom Class
  • dialog
  • drive
  • exif
  • file
  • File path
  • filter
  • folder
  • Font
  • Font
  • GAME
  • geolocation
  • GUI
  • GUI Scripting
  • Hex
  • History
  • How To
  • iCloud
  • Icon
  • Image
  • Input Method
  • Internet
  • iOS App
  • JavaScript
  • JSON
  • JXA
  • Keychain
  • Keychain
  • Language
  • Library
  • list
  • Locale
  • Machine Learning
  • Map
  • Markdown
  • Menu
  • Metadata
  • MIDI
  • MIME
  • Natural Language Processing
  • Network
  • news
  • Noification
  • Notarization
  • Number
  • Object control
  • OCR
  • OSA
  • PDF
  • Peripheral
  • PRODUCTS
  • QR Code
  • Raw AppleEvent Code
  • Record
  • rectangle
  • recursive call
  • regexp
  • Release
  • Remote Control
  • Require Control-Command-R to run
  • REST API
  • Review
  • RTF
  • Sandbox
  • Screen Saver
  • Script Libraries
  • sdef
  • search
  • Security
  • selection
  • shell script
  • Shortcuts Workflow
  • Sort
  • Sound
  • Spellchecker
  • Spotlight
  • SVG
  • System
  • Tag
  • Telephony
  • Text
  • Text to Speech
  • timezone
  • Tools
  • Update
  • URL
  • UTI
  • Web Contents Control
  • WiFi
  • XML
  • XML-RPC
  • イベント（Event）
  • 未分類

アーカイブ

  • 2023年9月
  • 2023年8月
  • 2023年7月
  • 2023年6月
  • 2023年5月
  • 2023年4月
  • 2023年3月
  • 2023年2月
  • 2023年1月
  • 2022年12月
  • 2022年11月
  • 2022年10月
  • 2022年9月
  • 2022年8月
  • 2022年7月
  • 2022年6月
  • 2022年5月
  • 2022年4月
  • 2022年3月
  • 2022年2月
  • 2022年1月
  • 2021年12月
  • 2021年11月
  • 2021年10月
  • 2021年9月
  • 2021年8月
  • 2021年7月
  • 2021年6月
  • 2021年5月
  • 2021年4月
  • 2021年3月
  • 2021年2月
  • 2021年1月
  • 2020年12月
  • 2020年11月
  • 2020年10月
  • 2020年9月
  • 2020年8月
  • 2020年7月
  • 2020年6月
  • 2020年5月
  • 2020年4月
  • 2020年3月
  • 2020年2月
  • 2020年1月
  • 2019年12月
  • 2019年11月
  • 2019年10月
  • 2019年9月
  • 2019年8月
  • 2019年7月
  • 2019年6月
  • 2019年5月
  • 2019年4月
  • 2019年3月
  • 2019年2月
  • 2019年1月
  • 2018年12月
  • 2018年11月
  • 2018年10月
  • 2018年9月
  • 2018年8月
  • 2018年7月
  • 2018年6月
  • 2018年5月
  • 2018年4月
  • 2018年3月
  • 2018年2月

https://piyomarusoft.booth.pm/items/301502

メタ情報

  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org

Forum Posts

  • 人気のトピック
  • 返信がないトピック

メタ情報

  • ログイン
  • 投稿フィード
  • コメントフィード
  • WordPress.org
Proudly powered by WordPress
Theme: Flint by Star Verte LLC