指定URLをロード_WKWebView版 v2

Posted on 11月 4, 2018 by Takaaki Naganoya

指定のURLを読み込んでページのタイトルを取得するAppleScriptです。

オリジナルはControl＋Command＋Rの操作が必要でしたが、本バージョンでは必要ありません。ただ、Script Debuggerとの相性はよろしくないようで。

AppleScript名：指定URLをロード_WKWebView版 v2

— Created 2015-09-16 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "WebKit"

property theWebView : missing value

set aURL to "http://www.apple.com/jp/shop/browse/home/specialdeals/mac"

my performSelectorOnMainThread:"getPage:" withObject:(aURL) waitUntilDone:true

set aTitle to (theWebView)’s title()
return aTitle as text
–>　　"Mac整備済製品 – Apple（日本）"

–Download the URL page to WkWebView
on getPage:aURL
　　set thisURL to current application’s |NSURL|’s URLWithString:aURL
　　set theRequest to current application’s NSURLRequest’s requestWithURL:thisURL
　　
　　set aConf to current application’s WKWebViewConfiguration’s alloc()’s init()
　　
　　set (my theWebView) to current application’s WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 800, 600)) configuration:aConf –フレームの大きさは根拠レス
　　(my theWebView)’s setNavigationDelegate:me
　　(my theWebView)’s loadRequest:theRequest
　　
　　set waitLoop to 100 * 60 –60 seconds
　　
　　set hitF to false
　　repeat waitLoop times
　　　　set aLoadF to ((my theWebView)’s estimatedProgress()) as number
　　　　if aLoadF = 1.0 then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　　　current application’s NSThread’s sleepForTimeInterval:(0.01)
　　　　–delay 0.1
　　end repeat
　　
　　return hitF
end getPage:

★Click Here to Open This Script　

QuartzComoserでグラフ表示てすと v6

Posted on 11月 4, 2018 by Takaaki Naganoya

QuartzComposerのグラフに任意のデータを指定してウィンドウ表示するAppleScriptです。

スクリプトバンドル内の「Chart.qtz」を読み出して表示しているため、QuartzComposer入りのスクリプトバンドルを用意しておきましたので、ダウンロードしてお試しください。

–> Download qtc_disp_v6

オリジナルはControl＋Command＋Rで実行する必要がありましたが、本Scriptではその必要がありません。ちなみに、一般的なQuartzComposerのようにマウスでグリグリ回せるとかいうことはありません。パラメータを反映して静止画として表示されるだけです（Xcode上で作成したAppleScriptのGUIアプリケーションであれば、普通に回せます）。

macOS 10.14上で実行してみたところ、スクリプトエディタではCompositionが表示されませんでしたが、Script Debugger上で実行したかぎりでは実行されました。Framework宣言で足りないものがあるのでしょうか？

備考：QuartzComposerはmacOS 10.15でDeprecated扱いになりました

AppleScript名：QuartzComoserでグラフ表示てすと v6

— Created 2015-11-03 by Takaaki Naganoya
— Modified 2018-11-04 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "Quartz"
use framework "AppKit"

property NSColor : a reference to current application’s NSColor
property QCView : a reference to current application’s QCView
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property NSWindow : a reference to current application’s NSWindow
property NSNumber : a reference to current application’s NSNumber
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSMutableArray : a reference to current application’s NSMutableArray
property NSWindowController : a reference to current application’s NSWindowController
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSWindowCloseButton : a reference to current application’s NSWindowCloseButton
property NSNormalWindowLevel : a reference to current application’s NSNormalWindowLevel
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered

set chartData to NSMutableArray’s new()
chartData’s addObject:(my recWithLabels:{"label", "value"} andValues:{"練馬区", 3})
chartData’s addObject:(my recWithLabels:{"label", "value"} andValues:{"青梅市", 1})
chartData’s addObject:(my recWithLabels:{"label", "value"} andValues:{"中野区", 2})

my performSelectorOnMainThread:"dispQuartzComposerWindow:" withObject:(chartData) waitUntilDone:true

on dispQuartzComposerWindow:chartData
　　–上記データの最大値を求める
　　set aMaxRec to chartData’s filteredArrayUsingPredicate:(NSPredicate’s predicateWithFormat_("SELF.value == %@.@max.value", chartData))
　　set aMax to value of aMaxRec
　　set aMaxVal to (first item of aMax) as integer
　　
　　–Scalingの最大値を求める
　　if aMaxVal ≥ 10 then
　　　　set aScaleMax to (10 div aMaxVal)
　　　　set aScaleMin to aScaleMax div 10
　　else
　　　　set aScaleMax to (10 / aMaxVal)
　　　　set aScaleMin to 1
　　end if
　　
　　try
　　　　set aPath to path to resource "Chart.qtz"
　　on error
　　　　return
　　end try
　　
　　set qtPath to NSString’s stringWithString:(POSIX path of aPath)
　　
　　set aView to QCView’s alloc()’s init()
　　set qtRes to (aView’s loadCompositionFromFile:qtPath)
　　
　　aView’s setValue:chartData forInputKey:"Data"
　　aView’s setValue:(NSNumber’s numberWithFloat:(0.5)) forInputKey:"Scale"
　　aView’s setValue:(NSNumber’s numberWithFloat:(0.2)) forInputKey:"Spacing"
　　aView’s setAutostartsRendering:true
　　
　　set maXFrameRate to aView’s maxRenderingFrameRate()
　　
　　(aView’s setValue:(NSNumber’s numberWithFloat:aScaleMax / 10) forInputKey:"Scale")
　　
　　set aWin to (my makeWinWithView(aView, 800, 600, "AppleScript Composition Test"))
　　
　　set wController to NSWindowController’s alloc()
　　wController’s initWithWindow:aWin
　　aWin’s makeFirstResponder:aView
　　wController’s showWindow:me
　　
　　aWin’s makeKeyAndOrderFront:me
　　
　　delay 5
　　
　　my closeWin:aWin
　　aView’s stopRendering() –レンダリング停止
　　
end dispQuartzComposerWindow:

–make Window for Display
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　
　　set aBacking to NSTitledWindowMask
　　
　　set aDefer to NSBackingStoreBuffered
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　aWin’s setBackgroundColor:(NSColor’s whiteColor())
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSNormalWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　aWin’s makeKeyAndOrderFront:(me)
　　–aWin’s movableByWindowBackground:true
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　–Set Close Button　　
　　set closeButton to NSWindow’s standardWindowButton:(NSWindowCloseButton) forStyleMask:(NSTitledWindowMask)
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aWindow
　　repeat with n from 10 to 1 by -1
　　　　(aWindow’s setAlphaValue:n / 10)
　　　　delay 0.01
　　end repeat
　　aWindow’s |close|()
end closeWin:

on recWithLabels:theKeys andValues:theValues
　　return (NSDictionary’s dictionaryWithObjects:theValues forKeys:theKeys) as record
end recWithLabels:andValues:

★Click Here to Open This Script　

テキストをMarkdown形式として解釈してHTMLを出力

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースのフレームワーク「MMMarkdown」を利用してMarkdownのテキストをHTMLに変換して出力するAppleScriptです。

ただし、解釈できるMarkdownタグは限定的で、表などは解釈できません。

–> Download MMMarkdown.framework (To ~/Library/Frameworks/)

AppleScript名：テキストをMarkdown形式と解釈してHTMLを出力

— Created 2016-05-12 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "MMMarkdown" –https://github.com/mdiep/MMMarkdown

set markdown to "# Example
What a library!"
set htmlString to (current application’s MMMarkdown’s HTMLStringWithMarkdown:markdown |error|:(missing value)) as string
–>
(*
"<h1>Example</h1>
<p>What a library!</p>
"
*)

★Click Here to Open This Script　

ftpKitのじっけん ftpサーバーからファイル一覧を取得

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースのFTPManagerをフレームワーク化したftpKitを利用して、指定サーバー上の指定ディレクトリ内のファイル一覧を取得するAppleScriptです。

sftp接続が必要な場合にはTransmitをAppleScriptからコントロールすることになるわけですが、セキュリティ的にあまり問題にならない用途であればFTP経由でファイル転送することもあるでしょう。

AppleScript名：ftpKitでファイル一覧を取得

— Created 2016-03-01by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "ftpKit" –https://github.com/nkreipke/FTPManager

set serverURL to "ftp://www.piyocast.com/xxxxx/public_html/private"
set serverUser to "xxxxx@piyocast.com"
set serverPassword to text returned of (display dialog "Input FTP Password" default answer "" with hidden answer)

set aFtpManager to current application’s FTPManager’s alloc()’s init()
set successF to false

set srv to current application’s FMServer’s serverWithDestination:serverURL username:serverUser |password|:serverPassword
srv’s setPort:21

set aResList to aFtpManager’s contentsOfServer:srv

set fileNameList to {}
set fileCount to aResList’s |count|()

repeat with i from 0 to (fileCount – 1)
　　set anItem to (aResList’s objectAtIndex:i)
　　
　　set aFileName to (anItem’s valueForKeyPath:"kCFFTPResourceName") as string
　　set the end of fileNameList to aFileName
end repeat

fileNameList
–>　　{".", "..", "xls1a.png", "xls3.png"}

★Click Here to Open This Script　

度量衡の変換

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースの「DDUnitConverter」（By Dave DeLong）を用いて、度量衡（measurement unit）の変換を行うAppleScriptです。AppleScriptから呼び出すために、DDUnitConverterをフレームワーク化した「ddUnitConversionKit」を作成しています。

もともと、AppleScriptには内蔵の度量衡変換機能があり、

AppleScript名：インチからセンチへの変換

set a to 1
set a to a as inches
–> inches 1.0

set b to a as centimeters
–> centimeters 2.54

set c to a as meters
–> meters 0.0254

set d to a as kilometers
–> kilometers 2.54E-5

★Click Here to Open This Script　

とか、

AppleScript名：液体の容積の単位変換

–液体の容積の単位変換
set a to 10 as liters
–> liters 10.0

set b to a as gallons
–> gallons 2.641720372842

set c to a as quarts
–> quarts 10.566881491367

★Click Here to Open This Script　

ぐらいは簡単にできます。AppleScriptがサポートしている度量衡は、長さ、重さ、温度、液体の容積です。

ただ、mmの下のμmとか、オングストロームとか、そういう単位には対応していませんし、重量でいえばKgに対応していてもt（トン）の単位はサポートしていなかったりと、日常的な度量衡の単位の世界でも不十分な感じが否めません（数値の有効桁数が10桁と小さいことも影響？）。

Cocoaの世界で度量衡変換機能について調べてみたところ、km→m→cm→mmといった変換はしてくれるものの、他の単位への変換は行ってくれていなかったりして、標準機能だけではいまひとつな印象です。

AppleScript名：NSLengthFormatterのじっけん

— Created 2015-11-18 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
–http://dev.classmethod.jp/references/ios8-new-formatter/

set aLengthFormatter to current application’s NSLengthFormatter’s alloc()’s init()
set aMeters to 5000
set aRes to (aLengthFormatter’s stringFromMeters:aMeters) as text
–>　　"5 km"
set bRes to (aLengthFormatter’s stringFromMeters:500) as text
–>　　"500 m"
set cRes to (aLengthFormatter’s stringFromMeters:0.5) as text
–>　　"50 cm"
set dRes to (aLengthFormatter’s stringFromMeters:0.005) as text
–>　　"5 mm"
set eRes to (aLengthFormatter’s stringFromMeters:("0.000005" as real)) as text
–>　　"0.005 mm"

set res2 to aLengthFormatter’s getObjectValue:(missing value) forString:aRes errorDescription:(missing value)
–>　　false

set res3 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitMillimeter)) as text
–>　　"5,000 mm"
set res4 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitCentimeter)) as text
–>　　"5,000 cm"
set res5 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitMeter)) as text
–>　　"5,000 m"
set res6 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitKilometer)) as text
–>　　"5,000 km"
set res7 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitInch)) as text
–>　　"5,000 in"
set res8 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitFoot)) as text
–>　　"5,000 ft"
set res9 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitYard)) as text
–>　　"5,000 yd"
set res10 to (aLengthFormatter’s stringFromValue:aMeters unit:(current application’s NSLengthFormatterUnitMile)) as text
–>　　"5,000 mi"

★Click Here to Open This Script　

AppleScript名：NSMassFormatterのじっけん

— Created 2015-11-18 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
–http://dev.classmethod.jp/references/ios8-new-formatter/

set aMasFormatter to current application’s NSMassFormatter’s alloc()’s init()
set aKilloGrams to 60.0
set aRes to (aMasFormatter’s stringFromKilograms:aKilloGrams) as text
–>　　"60 kg"
set a2Res to (aMasFormatter’s stringFromKilograms:(0.5)) as text
–>　　"500 g"
set a3Res to (aMasFormatter’s stringFromKilograms:(5000000)) as text
–>　　"5,000,000 kg"
set a4Res to (aMasFormatter’s stringFromKilograms:("0.0005" as real)) as text
–>　　"0.5 g"

set bRes to (aMasFormatter’s stringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitGram)) as text
–>　　"60 g"
set cRes to (aMasFormatter’s stringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitKilogram)) as text
–>　　"60 kg"
set dRes to (aMasFormatter’s stringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitOunce)) as text
–>　　"60 oz"
set eRes to (aMasFormatter’s stringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitPound)) as text
–>　　"60 lb"
set fRes to (aMasFormatter’s stringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitStone)) as text
–>　　"60 st"

set gRes to (aMasFormatter’s unitStringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitGram)) as text
–>　　"g"
set hRes to (aMasFormatter’s unitStringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitKilogram)) as text
–>　　"kg"
set iRes to (aMasFormatter’s unitStringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitOunce)) as text
–>　　"oz"
set jRes to (aMasFormatter’s unitStringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitPound)) as text
–>　　"lb"
set kRes to (aMasFormatter’s unitStringFromValue:aKilloGrams unit:(current application’s NSMassFormatterUnitStone)) as text
–>　　"st"

set res01 to aMasFormatter’s getObjectValue:(missing value) forString:fRes errorDescription:(missing value)
–>　　false

set res02 to (aMasFormatter’s stringFromKilograms:80) as text
–>　　"80 kg"

set res03 to aMasFormatter’s unitStyle()
–>　　2 = NSFormattingUnitStyleMedium

★Click Here to Open This Script　

そこで、冒頭に紹介したようにDDUnitConverterを導入してみたわけですが、これはこれで問題がないわけでもありません。本来、通貨同士の変換をサポートしており、通貨レートの更新機能を持っているのですが、実際に呼び出してみると更新されていない雰囲気が濃厚です（呼び出し方を間違っているのか？）。

なので、「通貨レート以外」の度量衡変換にのみ用いるのが安全な使い方なのかもしれない、というところです。

例によって、OS X 10.10以降用にビルドしたバイナリを用意しておきましたので、興味のある方はアーカイブを展開したあとで、~/Library/Frameworksに入れておためしください。

–> Download ddUnitConversionKit.framework（To ~/Library/Frameworks/）

AppleScript名：DDUnitConverterのじっけん1

— Created 2015-11-19 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version “2.4”
use scripting additions
use framework “Foundation”
use framework “ddUnitConversionKit” –davedelong/DDUnitConverter
–https://github.com/davedelong/DDUnitConverter

–enums in DDVelocityUnitConverter.h
property DDVelocityUnitCentimetersPerHour : 0
property DDVelocityUnitCentimetersPerMinute : 1
property DDVelocityUnitCentimetersPerSecond : 2
property DDVelocityUnitFeetPerHour : 3
property DDVelocityUnitFeetPerMinute : 4
property DDVelocityUnitFeetPerSecond : 5
property DDVelocityUnitInchesPerHour : 6
property DDVelocityUnitInchesPerMinute : 7
property DDVelocityUnitInchesPerSecond : 8
property DDVelocityUnitKilometersPerHour : 9
property DDVelocityUnitKilometersPerMinute : 10
property DDVelocityUnitKilometersPerSecond : 11
property DDVelocityUnitKnots : 12
property DDVelocityUnitLight : 13
property DDVelocityUnitMach : 14
property DDVelocityUnitMetersPerHour : 15
property DDVelocityUnitMetersPerMinute : 16
property DDVelocityUnitMetersPerSecond : 17
property DDVelocityUnitMilesPerHour : 18
property DDVelocityUnitMilesPerMinute : 19
property DDVelocityUnitMilesPerSecond : 20
property DDVelocityUnitFurlongsPerFortnight : 21

–時速100kmを秒速kmに変換
set aVal to ((current application’s DDUnitConverter’s velocityUnitConverter())’s convertNumber:100 fromUnit:(DDVelocityUnitKilometersPerHour) toUnit:(DDVelocityUnitKilometersPerSecond)) as real
–>　　0.027777777778

★Click Here to Open This Script　

AppleScript名：DDCurrencyUnitConverterのじっけん

— Created 2015-11-19 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version “2.4”
use scripting additions
use framework “Foundation”
use framework “ddUnitConversionKit” –davedelong/DDUnitConverter
–https://github.com/davedelong/DDUnitConverter

–enums in DDCurrencyUnitConverter.h
property DDCurrencyUnitEuro : 0
property DDCurrencyUnitJapaneseYen : 1
property DDCurrencyUnitUKPoundSterling : 2
property DDCurrencyUnitUSDollar : 3
property DDCurrencyUnitAlgerianDinar : 4
property DDCurrencyUnitArgentinePeso : 5
property DDCurrencyUnitAustralianDollar : 6
property DDCurrencyUnitBahrainDinar : 7
property DDCurrencyUnitBotswanaPula : 8
property DDCurrencyUnitBrazilianReal : 9
property DDCurrencyUnitBruneiDollar : 10
property DDCurrencyUnitCanadianDollar : 11
property DDCurrencyUnitChileanPeso : 12
property DDCurrencyUnitChineseYuan : 13
property DDCurrencyUnitColombianPeso : 14
property DDCurrencyUnitCzechKoruna : 15
property DDCurrencyUnitDanishKrone : 16
property DDCurrencyUnitHungarianForint : 17
property DDCurrencyUnitIcelandicKrona : 18
property DDCurrencyUnitIndianRupee : 19
property DDCurrencyUnitIndonesianRupiah : 20
property DDCurrencyUnitIranianRial : 21
property DDCurrencyUnitIsraeliNewSheqel : 22
property DDCurrencyUnitKazakhstaniTenge : 23
property DDCurrencyUnitKoreanWon : 24
property DDCurrencyUnitKuwaitiDinar : 25
property DDCurrencyUnitLibyanDinar : 26
property DDCurrencyUnitMalaysianRinggit : 27
property DDCurrencyUnitMauritianRupee : 28
property DDCurrencyUnitMexicanPeso : 29
property DDCurrencyUnitNepaleseRupee : 30
property DDCurrencyUnitNewZealandDollar : 31
property DDCurrencyUnitNorwegianKrone : 32
property DDCurrencyUnitRialOmani : 33
property DDCurrencyUnitPakistaniRupee : 34
property DDCurrencyUnitNuevoSol : 35
property DDCurrencyUnitPhilippinePeso : 36
property DDCurrencyUnitPolishZloty : 37
property DDCurrencyUnitQatarRiyal : 38
property DDCurrencyUnitRussianRuble : 39
property DDCurrencyUnitSaudiArabianRiyal : 40
property DDCurrencyUnitSingaporeDollar : 41
property DDCurrencyUnitSouthAfricanRand : 42
property DDCurrencyUnitSriLankaRupee : 43
property DDCurrencyUnitSwedishKrona : 44
property DDCurrencyUnitSwissFranc : 45
property DDCurrencyUnitThaiBaht : 46
property DDCurrencyUnitTrinidadAndTobagoDollar : 47
property DDCurrencyUnitTunisianDinar : 48
property DDCurrencyUnitUAEDirham : 49
property DDCurrencyUnitPesoUruguayo : 50
property DDCurrencyUnitBolivarFuerte : 51
property DDCurrencyUnitSDR : 52

–最初に通貨レートの更新を行う必要があるが、実行しても変わらないのはなぜ？？？？
set aConv to current application’s DDUnitConverter’s currencyUnitConverter()
aConv’s refreshExchangeRates()
set aVal to (aConv’s convertNumber:100 fromUnit:(DDCurrencyUnitUSDollar) toUnit:(DDCurrencyUnitJapaneseYen))
–>　　(NSNumber) 1.006839721743

★Click Here to Open This Script　

シリアルコードの生成と検証

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースのフレームワーク「SerialKeyGenerator」を用いてシリアルコードを生成、検証するAppleScriptです。

シリアルコードについて

シリアルコードは、日本では「レジストコード」「プロダクトコード」などと呼ばれるもので、ソフトウェアの販売時にこのコードを発行し、ソフトウェアのシリアルコード入力ダイアログに入力してもらうことで、完全版として機能させるというものです。

Mac App StoreではApple IDとひもづけることでシリアルコードを使用しないソフトウェア販売とライセンシングを行なっていますが、Mac App Store外で販売する場合にはシリアルコードのことを考える必要が出てきます。

コードの文字数を増やすと、仮にキーボードから入力する場合の難易度が上がってしまいます。適度な長さの文字列になることが望ましいところです。

シリアルコードが仮に流出した場合に備え、どの購入者のコードが流出したかを特定する必要があります。そのため、シリアルコードにはその名のとおり、購入者の番号を含めてあるのが普通です。

SerialKeyGeneratorの使い方について

SerialKeyGeneratorでは、シークレットキーワード、ユーザー番号をもとにシリアルコードが生成されます。日時を考慮してシリアルコードを計算するため、同じシリアルコードを生成させても日時が変われば結果は異なります。

ただ、おおもとのシークレットキーワードが判明してしまうと、第三者がシリアルコードを勝手に発行してソフトウェアの不正使用ができてしまうため、アプリケーション内に格納するシークレットキーワードは文字ダンプされても判明しないようにしておくのが普通です。

–> Download serialKeyGenKit.framework（To ~/Library/Frameworks/）

AppleScript名：SerialKeyGeneratorサンプル1

— Created 2015-10-24 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "serialKeyGenKit" –https://github.com/danielvy/SerialKeyGenerator

–Generate Serial Code with secret Keyword
set aGen to current application’s SerialKeyGenerator’s alloc()’s initWithSecret:"Piyomaru"
–>　　(SerialKeyGenerator) <SerialKeyGenerator: 0x7f8b5b5fa200>

set aList to {}
repeat with i from 1 to 10
　　set aRes to (aGen’s generateSerialWithSequence:i |data|:i)
　　set the end of aList to (aRes as text)
end repeat

aList
–>　　{"1CHH8-BJY89-TR9Z9-AKSTL-70JZF", "4KXCF-LS6P5-7BKYN-CUMPY-NM072", "41GO2-OGZ3T-83YP9-2LS4J-9W3MI", "CA3WV-C7FU7-PSPJ3-LNGT7-N6AJT", "3OG0B-MCFUM-7YKHT-EE533-LNJEJ", "4SKWQ-9G8XE-ZCE6K-APSAL-R0T8S", "CTEZT-H4AQQ-BM15H-FH2DG-P7K7O", "4BZ1X-2OHKF-5FWND-7SZVA-EBR89", "BDKRI-9JU7T-G6N20-YPU9K-6FXQW", "9EWW5-O3FMV-SDEZA-77JZE-OY8FL"}

–Decode Serial with secret Keyword
set rList to {}
set bGen to current application’s SerialKeyGenerator’s alloc()’s initWithSecret:"Piyomaru"
–> (SerialKeyGenerator) <SerialKeyGenerator: 0x7fb6992b8400>

repeat with i in aList
　　set bRes to (bGen’s decodeSerial:(contents of i))
　　
　　set aDate to bRes’s |date| as date
　　set aSeq to bRes’s sequence as integer
　　set aData to bRes’s |data| as integer
　　
　　set the end of rList to {aData, aSeq, aDate}
end repeat
return rList
–> {{1, 1, date "2018年11月3日土曜日 16:44:57"}, {2, 2, date "2018年11月3日土曜日 16:44:57"}, {3, 3, date "2018年11月3日土曜日 16:44:57"}, {4, 4, date "2018年11月3日土曜日 16:44:57"}, {5, 5, date "2018年11月3日土曜日 16:44:57"}, {6, 6, date "2018年11月3日土曜日 16:44:57"}, {7, 7, date "2018年11月3日土曜日 16:44:57"}, {8, 8, date "2018年11月3日土曜日 16:44:57"}, {9, 9, date "2018年11月3日土曜日 16:44:57"}, {10, 10, date "2018年11月3日土曜日 16:44:57"}}

★Click Here to Open This Script　

Excelデータを組み立てて書き出し(フォント指定、カラー指定)

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースのフレームワーク「JXLS」を用いてExcelデータを組み立てるAppleScriptです。

フォント名と色を指定してみました。実際に案件で使用したことがないので、徹底的に活用した………という経験がないので、いまのところ何か風景画像をExcel書類に変換して「実はExcelで作りました」とかフカすぐらいしか用途がなさそうです。

–> Download JXLS（To ~/Library/Frameworks/）

AppleScript名：ASOCでExcelファイル生成テスト v2

— Created 2015-10-08 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "JXLS" –https://github.com/JanX2/JXLS

set aFile to POSIX path of (choose file name)
set filePath to current application’s NSString’s stringWithString:aFile

set workBook to current application’s JXLSWorkBook’s new()
set workSheet to workBook’s workSheetWithName:"ぴよぴよシート"
workSheet’s setWidth:1000 forColumn:0 defaultFormat:(missing value)

repeat with i from 0 to 64
　　set aCell to (workSheet’s setCellAtRow:i column:0 toString:(current application’s NSString’s stringWithString:("ぴよまる " & (i as text))))
　　(aCell’s setFontName:"HiraKakuStd-W8")
　　(aCell’s setFontHeight:320) –this is point * 20
　　(aCell’s setFontColorIndex:i)
　　(aCell’s setForegroundFillColorIndex:13)
end repeat

workBook’s writeToFile:filePath

★Click Here to Open This Script　

Excelデータを組み立てて書き出し

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースの「JXLS.framework」を用いて指定のExcelデータを組み立てて書き出すAppleScriptです。

アプリケーションにメッセージを送ってアプリケーションに仕事をしてもらうのがAppleScriptの流儀ですが、macOS 10.10以降でCocoaの機能が呼べるようになったため、こうしたオープンソースのフレームワークを呼び出して処理できるようになりました。

AppleScriptが自前で行なっていないことには変わらないのですが、Excelデータを（Excelなしで）組み立てられるわけで、出力データとしてExcel書類が求められる用途において、Excelなしで処理が行えます（開発中はExcelでどのように表示されるか確認する必要があるので、開発中は必要です）。

また、本物のExcelをコントロールする方法ではできなかった「並列処理で大量にデータを作成する」という処理も可能になるわけでけっこうなことです（ただ、そういう要求をされたことは皆無なのですが、、、、）。

–> Download JXLS（To ~/Library/Frameworks/）

AppleScript名：ASOCでExcelファイル生成テスト

— Created 2015-10-08 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "JXLS" –https://github.com/JanX2/JXLS

set aFile to POSIX path of (choose file name)
set filePath to current application’s NSString’s stringWithString:aFile

set workBook to current application’s JXLSWorkBook’s new()

set workSheet to workBook’s workSheetWithName:"ぴよぴよシート"
workSheet’s setWidth:1000 forColumn:0 defaultFormat:(missing value)

repeat with i from 0 to 10
　　set aCell to (workSheet’s setCellAtRow:i column:0 toString:(current application’s NSString’s stringWithFormat_("ぴよまる %@", i + 1)))
　　(aCell’s setHorizontalAlignment:1) —-HALIGN_LEFT
　　(aCell’s setIndentation:(0 + i)) —– INDENT_0
end repeat

workBook’s writeToFile:filePath

★Click Here to Open This Script　

ASOCでXML-RPCのテスト v3

Posted on 11月 3, 2018 by Takaaki Naganoya

オープンソースのXMLRPC.frameworkを用いてXMLRPCを実行するAppleScriptです。

XMLRPCといえば、WordPressか郵便専門ネットかというほど用途が限定されていますが、本Blog（Powered By WordPress）の年初の再構築など、使えないと大変な思いをすることがあるので、定期的に調査しています。

初回掲載時は郵便専門ネットのXMLRPCはバージョン番号を”15.09a”と返してきましたが、再掲載時に実行してみたら”18.10a”を返してきました。

–> Download XMLRPC.framework (To ~/Library/Frameworks/)

AppleScript名：ASOCでXML-RPCのテスト v3

— Created 2015-10-06 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "XMLRPC"
–XMLRPC.framework
–https://cocoapods.org/pods/xmlrpc
–Cocoa XML-RPC Framework © 2011 Divisible by Zero
–v2.3.4

set aRes to (callXMLRPC("http://yubin.senmon.net/service/xmlrpc/", "yubin.getMaxFetchCount", missing value)) as integer
–>　　100

set bRes to (callXMLRPC("http://yubin.senmon.net/service/xmlrpc/", "yubin.getVersion", missing value)) as text
–> "15.09a"

on callXMLRPC(paramURL, aMethod, aParamList)
　　
　　set aURL to current application’s |NSURL|’s URLWithString:paramURL
　　set aReq to current application’s XMLRPCRequest’s alloc()’s initWithURL:aURL
　　aReq’s setMethod:aMethod withParameter:aParamList
　　set aRes to current application’s XMLRPCConnection’s sendSynchronousXMLRPCRequest:aReq |error|:(missing value)
　　
　　set errF to (aRes’s isFault()) as boolean
　　
　　if errF = true then
　　　　set xmlRPCres to faultCode of aRes
　　　　–set xmlRPCbody to faultString of aRes
　　else
　　　　set xmlRPCres to aRes’s object()
　　　　–set xmlRPCbody to aRes’s body()
　　end if
　　
　　return xmlRPCres
　　
end callXMLRPC

★Click Here to Open This Script　

テキストビュー＋ボタンを作成 v2

Posted on 11月 3, 2018 by Takaaki Naganoya

Window＋TextView＋Buttonを作成してボタンのクリックを受け付けるAppleScriptです。

ちょっとしたログ表示などのために作成したものです。

▲通常（ライト）モード＠macOS 10.12.6、ダークモード＠10.14.1

オリジナルはスクリプトエディタ上でCommand＋Control＋Rの「フォアグラウンドで実行」を実行する必要があったのですが、

本バージョンでは強制的にメインスレッド実行を行うことで、この操作は不要になっています。

ただ、ランタイム環境ごとに「ボタンをクリックできない」という現象に遭遇。他のいろいろなランタイムでも試しておく必要を感じます。

ランタイム環境	スクリプトエディタ	アプレット	スクリプトメニュー	osascript	Script Debugger
macOS 10.12	OK	OK	クリックできない	クリックできない	クリックできない
macOS 10.13	OK	OK	クリックできない	クリックできない	クリックできない
macOS 10.14	OK	OK	クリックできない	クリックできない	クリックできない

macOS 10.12.6、10.13.6、10.14.1で動作確認してみましたが、傾向は同じです。Script Debugger上でクリックを受け付けないのはかなり問題が、、、、

AppleScript名：テキストビュー＋ボタンを作成 v2

— Created 2015-12-11 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSColor : a reference to current application’s NSColor
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property NSWindow : a reference to current application’s NSWindow
property NSSplitView : a reference to current application’s NSSplitView
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSMutableString : a reference to current application’s NSMutableString
property NSWindowController : a reference to current application’s NSWindowController
property NSTitledWindowMask : a reference to current application’s NSTitledWindowMask
property NSRoundedBezelStyle : a reference to current application’s NSRoundedBezelStyle
property NSNormalWindowLevel : a reference to current application’s NSNormalWindowLevel
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered
property NSMomentaryLightButton : a reference to current application’s NSMomentaryLightButton

property windisp : false
property wController : false

set aWidth to 600
set aHeight to 500

set aTitle to "テキストビューのじっけん/TextView Test"
set outText to "ぴよまるソフトウェア / Piyomaru Software "
set aButtonMSG to "OK"

–表示用テキストの作成
set dispStr to NSMutableString’s alloc()’s init()
repeat with i from 1 to 100
　　set bStr to (NSMutableString’s stringWithString:(outText & (i as string) & return))
　　set dispStr to (bStr’s stringByAppendingString:dispStr)
end repeat

set paramObj to {aWidth, aHeight, aTitle, dispStr, aButtonMSG, "10"}
my performSelectorOnMainThread:"dispTextView:" withObject:(paramObj) waitUntilDone:true

on dispTextView:paramObj
　　set my windisp to false
　　copy paramObj to {aWidth, aHeight, aTitle, dispStr, aButtonMSG, timeOutSecs}
　　
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.9
　　set (my windisp) to true
　　
　　–Text　View＋Scroll Viewをつくる
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aView’s setRichText:true
　　aView’s useAllLigatures:true
　　aView’s setTextColor:(NSColor’s cyanColor()) —
　　aView’s setBackgroundColor:aColor
　　aView’s setEditable:false
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　
　　–Buttonをつくる
　　set bButton to (NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, 40)))
　　–bButton’s setButtonType:( NSMomentaryLightButton)
　　–bButton’s setBezelStyle:( NSRoundedBezelStyle)
　　bButton’s setTitle:aButtonMSG
　　bButton’s setTarget:me
　　bButton’s setAction:("clicked:")
　　bButton’s setKeyEquivalent:(return)
　　
　　–SplitViewをつくる
　　set aSplitV to NSSplitView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aHeight, aWidth))
　　aSplitV’s setVertical:false
　　
　　aSplitV’s addSubview:aScroll
　　aSplitV’s addSubview:bButton
　　aSplitV’s setNeedsDisplay:true
　　
　　set aWin to makeWinWithView(aSplitV, aWidth, aHeight, aTitle, 0.9)
　　aView’s setString:dispStr
　　
　　–NSWindowControllerを作ってみた
　　set my wController to NSWindowController’s alloc()
　　my (wController’s initWithWindow:aWin)
　　
　　my (wController’s showWindow:me)
　　
　　set aCount to (timeOutSecs as string as number) * 10 –timeout seconds * 10
　　repeat aCount times
　　　　if (my windisp) = false then
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　end repeat
　　
　　my closeWin:bButton
end dispTextView:

–Button Clicked Event Handler
on clicked:aSender
　　set (my windisp) to false
　　my closeWin:aSender
end clicked:

–make Window for Input
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle, alphaV)
　　set aScreen to NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　set aBacking to NSTitledWindowMask –NSBorderlessWindowMask
　　set aDefer to NSBackingStoreBuffered
　　
　　— Window
　　set aWin to NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(NSNormalWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setAlphaValue:alphaV –append
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　
　　— Set Custom View
　　aWin’s setContentView:aView
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aSender
　　set tmpWindow to aSender’s |window|()
　　
　　repeat with n from 10 to 1 by -1
　　　　(tmpWindow’s setAlphaValue:n / 10)
　　　　delay 0.02
　　end repeat
　　
　　my wController’s |close|()
end closeWin:

★Click Here to Open This Script　

AppleScript系機能の実装がおかしなGoogle Chrome

Posted on 11月 2, 2018 by Takaaki Naganoya

Google Chromeは自動処理の部品に使ってはいけない

Google ChromeをAppleScriptでコントロールすることは、個人的にはほとんどありません。日常的に利用するのは、自動処理への対応機能を持ち信頼できるアプリケーションが中心です。

必要な機能がなかったり、自動処理と相性がよくなかったりするためです。使用中にGoogle App Storeのダイアログなどが表示されることがあるので、自動処理中にやられると処理が止まってしまいます。これは、自動処理の仕組みを組み立てる上で絶対にあってはならない仕様です。

そのため、Google ChromeをAppleScriptで動かす場合は、途中でGoogle Chrome側の都合で勝手に処理が止まっても腹が立たない程度の、あまり重要ではない処理であるとか、とても短くて簡単な基礎的なマクロ処理に限定されます。

１日中タイマーにのっとって定時に指定のWebサイトに、複数のユーザーIDやパスワードで繰り返しログインを行い、指定のメニューに移動してデータをダウンロードするような処理（実際にAppleScript＋Safariで動かしています）にGoogle Chromeを使うのは自殺行為です。

比較的短めの、

「写真.appで選択中の写真をOCRで文字認識して『戦場の絆』のリプレイIDを取得し、リプレイムービー検索ページにリプレイIDを突っ込み、YouTube上のリプレイムービーのURLを取得。YouTube上でリプレイを再生する」

といった程度の処理でも、途中でGoogle App Storeのダイアログが表示されたら、処理が途切れてそれっきり。コマンドを１つ実行するたびにGoogle App Storeのダイアログを閉じたり無効化する処理を入れれば不可能ではないかもしれませんが、無人の環境で放置するのは無理です。

かといって、Safariの仕様が自動処理に向いているかと言われれば、そういうわけでもありません。ファイルのダウンロード検出をSafari側で行えないなど、自動処理専用のWebブラウザがあったらいいのに、と思うところです（Folder ActionやFSEventsと組み合わせて、非同期処理でダウンロード検出を行なっています）。ただ、Google Chromeのような致命的な動作を行わない点で選択肢になることでしょう。

Google Chromeには、表示中のページのHTMLソースを取得するという、基本的かつないと困る機能が実装されていないのも困りものです。

Google Chromeは実装がおかしい

Google Chromeは一応JavaScriptを実行するための「execute」コマンドを備えているので、JavaScriptのコマンド経由でWebコンテンツへのアクセスや、フォームへのアクセスはできるようになっています。

ただし、肝心の「指定URLをオープンする」という部分の実装がまともに行われていません。

Google Chromeで指定URLをオープンするAppleScriptでよく見かける記述例は、

tell application "Google Chrome"
　　open location "http://piyocast.com/as/"
end tell

★Click Here to Open This Script　

のようなものですが、そもそもこの「open location」はAppleScriptの標準命令であり、Google Chromeが持っているコマンドではありません。open locationは指定URLのURLスキームに対応しているアプリケーションに処理が委ねられます。tellブロックを外すと、OSでデフォルト指定されているアプリケーションで処理されます。Google Chromeへのtellブロック内で実行しているので、Google ChromeにURLが転送されているだけです。

Google Chromeの機能を使って指定URLをオープンしようとすると、

tell application "Google Chrome"
　　set newWin to make new window
　　tell newWin
　　　　tell tab 1
　　　　　　set URL to "http://piyocast.com/as/"
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

のようになります。

一番ひどいのは、Google Chromeのopen命令。これ、

open v : Open a document.
  open list of file : The file(s) to be opened.

用語辞書のとおりに書いてもエラーになります。

そのため、ローカルのファイルをオープンさせようとしても、openコマンドは使えません。fileを与えてもaliasを与えても、AppleScript用語辞書の記述のとおりにfileのlistを与えてもエラーになります。

結論としては、ローカルのfileをオープンする際には、file pathをURL形式に変換して、そのURLをopen locationでオープンするか、tabのURL属性をfile URLに書き換えて表示させることになります。

set anAlias to choose file

tell application "Finder"
　　set aURL to URL of anAlias
end tell

tell application "Google Chrome"
　　open location aURL
end tell

★Click Here to Open This Script　

set anAlias to choose file

tell application "Finder"
　　set aURL to URL of anAlias
end tell

tell application "Google Chrome"
　　tell window 1
　　　　tell active tab
　　　　　　set URL to aURL
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

Finder経由で目的のファイルをGoogle Chromeというアプリケーションを利用してオープンする、という記述もできますが、ここでもそのままapplication “Google Chrome”と書くとエラーになり、「path to application “Google Chrome”」という回避的な記述が必要になってしまうのでありました。

–By @fixdot on Twitter
set anAlias to choose file

tell application "Finder"
　　open anAlias using (path to application "Google Chrome")
end tell

★Click Here to Open This Script　

ただ、ここで書いているのは「自動処理を行うユーザー環境では」ということであって、Google Chromeは自動処理にさえ使わなければ、それなりによくできたいいソフトウェアだと思います。

ほかにもいろいろ落とし穴が

とくに、Google Chromeにかぎらず、macOS内には自動処理の妨げとなる設定項目がいくつか存在しています。デフォルトのまま使うといろいろ問題が出るので、真っ先に設定を変更しています。

Mac miniにBluetooth外付けキーボードを接続した状態で、ファンクションキーをメディアキーに指定して運用していると、iTunesから不定期にダイアログ表示されるため、ファンクションキーはあくまでファンクションキーとして設定しないとダメです（MacBook Proなど本体にキーボードが搭載されているモデルはこのかぎりではありません）。

また、同様にMac miniでヘッドレス（画面なし）運用をしている際に、キーボードやマウス/トラックパッドを接続していない状態で警告するように初期設定されていますが、

　「起動時にキーボードが検出されない場合はBluetooth設定アシスタントを開く」
　「起動時にマウスまたはトラックパッドが検出されない場合はBluetooth設定アシスタントを開く」

の２つのチェックボックスをオフにしておく必要があります。

com.google.Chrome

Numbersの表の選択範囲をHTML化 v2

Posted on 11月 1, 2018 by Takaaki Naganoya

Numbersの最前面の書類で選択中の表の範囲をHTML化してファイルに書き出すAppleScriptです。

Numbers v5.1＋macOS 10.12.6、Numbers v5.2＋macOS 10.13.6、Numbers v5.2＋macOS 10.14.1で確認しています。

Numbers v5.xでは書類の書き出し（export）形式にPDF、Microsoft Excel、CSV、Numbers 09の４形式を指定できるようになっていますが、HTMLの表（table）に書き出してくれたりはしません。

GUI側（↑）にその機能がありませんし、AppleScript用語辞書（↓）にもそういう機能は見当たりません。

ただ、HTMLの表に書き出すという処理自体はとても初歩的で簡単な内容なので、「なければ作ればいい」ということになるでしょう。

そこで、ありもののルーチンを組み合わせて、選択範囲をHTMLの表（table）として書き出すScriptを書いて、OS標準装備のScript Menuに入れて利用しています。書き出すHTMLの内容は個人の趣味や用途に応じて大きく変わってきますので、そのあたりは自由に書き換えるとよいと思われます。

本Scriptは、電子書籍「AppleScript最新リファレンス」の正誤表（2018/1のBlog消失事件の影響で、書籍内で参照していたURLリンクが切れてしまったことへの対処）を作成するために、すでに存在していたものにほんの少しの修正を加えたものです。

データベースやデータからHTMLを作成するという処理は、自分がAppleScriptを覚えようと思ったきっかけでもあり（当時は、FileMaker Pro Server経由でLAN上でデータを共有して処理）、感慨深いものがあります。

AppleScript名：表の選択範囲をHTML化 v2

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use bPlus : script "BridgePlus"

script spd
　　property uniqList : {}
end script

set (uniqList of spd) to {}

–Numbersからデータを取得する
set aList to get2DListFromNumbersSelection() of me
if aList = false then return

set colCount to (length of first item of first item of aList) + 1

set aHeader to "<!DOCTYPE html><html lang=＼"ja＼" ><head><meta charset=＼"utf-8＼"><title>First</title><style>table , td, table , tr, th{border:1px solid #333333;padding:1px;}</style></head><body><table >"
set aTable to "<tr><td>%@</td><td> </td><td>%@</td><td>%@</td><td>%@</td></tr>"
set aFooter to "</table></body></html>"

set aHTMLres to retTableHTML(aList, aHeader, aTable, aFooter) of me

set tFile to choose file name with prompt "Select Output File Name and Folder"
set fRes to writeToFileAsUTF8(aHTMLres, tFile, false) of me

on retTableHTML(aList, aHeaderHTML, aTableHTML, aFooterHTML)
　　set allHTML to current application’s NSMutableString’s stringWithString:aHeaderHTML
　　
　　set aCounter to 1
　　repeat with i in aList
　　　　set j to contents of i
　　　　
　　　　set aRowHTML to "<tr>"
　　　　repeat with ii in j
　　　　　　set jj to contents of ii
　　　　　　if jj = missing value then
　　　　　　　　set jj to " "
　　　　　　else
　　　　　　　　try
　　　　　　　　　　set aURL to (current application’s |NSURL|’s URLWithString:jj)
　　　　　　　　　　if aURL is not equal to missing value then
　　　　　　　　　　　　set jj to "<a href=＼"" & jj & "＼">" & jj & "</a>"
　　　　　　　　　　end if
　　　　　　　　end try
　　　　　　end if
　　　　　　
　　　　　　set aTmpHTML to "<td>" & jj & "</td>"
　　　　　　set aRowHTML to aRowHTML & aTmpHTML
　　　　end repeat
　　　　set aRowHTML to aRowHTML & "</tr>"
　　　　
　　　　(allHTML’s appendString:aRowHTML)
　　　　set aCounter to aCounter + 1
　　end repeat
　　
　　(allHTML’s appendString:aFooterHTML)
　　
　　return allHTML as list of string or string
end retTableHTML

–テキストを指定デリミタでリスト化
on parseByDelim(aData, aDelim)
　　set aText to current application’s NSString’s stringWithString:aData
　　set aList to aText’s componentsSeparatedByString:aDelim
　　return aList as list
end parseByDelim

on get2DListFromNumbersSelection()
　　–Numbersで選択範囲を縦に区切ったリストを返す
　　tell application "Numbers"
　　　　tell front document
　　　　　　tell active sheet
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　　　
　　　　　　　　tell theTable
　　　　　　　　　　try
　　　　　　　　　　　　set selList to value of every cell of selection range –選択範囲のデータを取得
　　　　　　　　　　on error
　　　　　　　　　　　　return "" –何も選択されてなかった場合
　　　　　　　　　　end try
　　　　　　　　　　
　　　　　　　　　　set selName to name of selection range –選択範囲のrange情報を取得
　　　　　　　　　　set {s1, s2} to parseByDelim(selName, ":") of me
　　　　　　　　　　
　　　　　　　　　　–始点の情報を取得する
　　　　　　　　　　set s1Row to (address of row of range s1) as integer
　　　　　　　　　　set s1Column to (address of column of range s1) as integer
　　　　　　　　　　
　　　　　　　　　　–終点の情報を取得する
　　　　　　　　　　set s2Row to (address of row of range s2) as integer
　　　　　　　　　　set s2Column to (address of column of range s2) as integer
　　　　　　　　　　
　　　　　　　　　　–選択範囲の情報を取得する
　　　　　　　　　　set selHeight to s2Row – s1Row + 1 –高さ(Height of selection range)
　　　　　　　　　　set selWidth to s2Column – s1Column + 1 –幅(Width of selection range)
　　　　　　　　　　
　　　　　　　　end tell
　　　　　　end tell
　　　　end tell
　　end tell
　　
　　set aLen to length of selList
　　set aaLen to selHeight
　　
　　set bList to {}
　　repeat with i from 1 to aaLen
　　　　set aHoriList to {}
　　　　
　　　　repeat with ii from 1 to selWidth
　　　　　　set j1 to ii + (i – 1) * selWidth
　　　　　　set tmpCon to contents of item j1 of selList
　　　　　　
　　　　　　set aClass to class of tmpCon
　　　　　　if aClass = number or aClass = integer or aClass = real then
　　　　　　　　set tmpCon to tmpCon as integer
　　　　　　end if
　　　　　　
　　　　　　set the end of aHoriList to tmpCon
　　　　end repeat
　　　　
　　　　set the end of bList to aHoriList
　　end repeat
　　
　　return bList
　　
end get2DListFromNumbersSelection

on writeToFileAsUTF8(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data as «class utf8» to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end writeToFileAsUTF8

★Click Here to Open This Script　

Accessibility Inspectorがv5.0にバージョンアップして使いにくく？

Posted on 10月 30, 2018 by Takaaki Naganoya

電子ブックからリンクしている情報のBlog側の欠落をチェックしていたら、このAccessibility Inspectorの情報が（Blog上に）抜けていることがわかり、埋めているわけですが………チェックしていたら、バージョンがv4.0からv5.0に上がっていることに気づきました。

▲左側がv4.0、右側がv5.0。v5.0はアプリケーションとして動作し、メニューがある

日常的にアプリケーションのGUI部品の情報を収集するのはPFiddlesoftのUI Browserで、使用率は99.9:0.1でUI Browserのほうが圧倒的に多いわけですが、ごくたまにUI Browserでは手が届かないGUI部品があります。

具体的にいえば、フローティングパレットやポップアップメニュー上の凝ったGUI部品で、これらはUI Browserではオブジェクト階層が途中で途切れているものとして表示されるため、オブジェクト階層を追跡できないことがあります。

そんなわけで、ごくたまに（１年間に１回ぐらい？）Accessibility Inspectorのごやっかいになることがあり、v4.0では問題なく使用できていました。

問題は、いつのまにかアップデートされて入っていたAccessibility Inspector v5.0。

これ、Windowの中のGUI部品は追いかけられるんですが、メニュー部品を追いかけられないように見えるのですが………。目の錯覚なのか、使いこなせていないのか現段階では不明です。

それができないと、Accessibility Inspectorの存在意義が、、、、

＃　メニュー項目はOption＋Spaceで選択中のGUI部品への参照をAccessibility Inspector v5.0のメインウィンドウに表示できることを教えてもらいました

一応、Apple Developper Connectionのアカウントがあれば、Developperサイトにログインして、ダウンロード項目から「Accessibility Tools for Xcode – February 2012」のアーカイブをダウンロードすれば、中にAccessibility Inspector v4.0が入っています。macOS 10.12上にコピーして動かせることを確認しています。

macOS 10.14, MojaveにAccessibility Inspector v4.0をインストールして、期待どおりの動作が行えていることを確認しています。Accessibility Inspector v4.0はCode Signされていないのでシステム環境設定の「セキュリティーとプライバシー」＞「アクセシビリティ」でアクセシビリティへのアクセスを許可しておく必要があります。

なお、Accessibility Inspector v4.0はCode Signされていないので、macOS 10.14, Mojave上で起動するといろいろうるさく言われますが、システム環境設定の「セキュリティーとプライバシー」＞「一般」からAccessibility Inspector v4.0の起動許可を指示すれば大丈夫です。

▲macOS 10.14, Mojave上でAccessibility Inspector v4.0を起動したところ

ファイル作成日、修正日を変更する

Posted on 10月 29, 2018 by Takaaki Naganoya

指定ファイルの作成日、修正日を変更するAppleScriptです。

以前はsetFileコマンド（Xcodeのcommand lineユーティリティーをインストールすると入る）で行うパターンを掲載していたのですが、NSFileManagerの方が楽にできるのと、どの実行環境でも（開発ツールが入っていなくても）実行できていいと思います。

AppleScript名：ファイル作成日、修正日を変更する

— Created 2018-05-30 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set aFile to POSIX path of (choose file)
set targDate to current date
changeFileCreationDate(targDate, aFile) of me
changeFileModDate(targDate, aFile) of me

–指定パスのファイルの作成日時を変更する
on changeFileCreationDate(aDate, aFile)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithObject:aDate forKey:(current application’s NSFileCreationDate)
　　set aFM to current application’s NSFileManager’s defaultManager()’s setAttributes:aDic ofItemAtPath:(POSIX path of aFile) |error|:(missing value)
end changeFileCreationDate

–指定パスのファイルの修正日時を変更する
on changeFileModDate(aDate, aFile)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithObject:aDate forKey:(current application’s NSFileModificationDate)
　　set aFM to current application’s NSFileManager’s defaultManager()’s setAttributes:aDic ofItemAtPath:(POSIX path of aFile) |error|:(missing value)
end changeFileModDate

★Click Here to Open This Script　

光学ドライブのオープン（イジェクト）

Posted on 10月 29, 2018 by Takaaki Naganoya

光学ドライブのオープン（メディアのイジェクト）を行うAppleScriptです。

すっかり、Macのラインナップから光学ドライブ標準搭載モデルがなくなって、外付けの光学ドライブばかりというか、そもそも光学ドライブを持っていないというユーザーが増えてきたので、光学メディアでのデータ配布そのものが無意味になりつつある昨今。

光学ドライブもトレイ式（トレイ開閉が電動）のものがほぼ絶滅状態（Pioneerのみ製造？）。スリムタイプのスロットイン方式か、薄型トレイ（イジェクトしたまま戻らない）方式のみなので、光学メディアのイジェクトについて分かればよいでしょう。

drutilコマンドのほか、macOS 10.13まではDVDプレイヤーがScriptableだったので、DVDプレイヤーに対してejectコマンドを送る方法もありました（10.14でScripting機能が廃止に……アプリケーション自体を作り直したもよう）。

macOS 10.12/13：DVDプレイヤー（32bit）　ファイルサイズ：6.4MB　バージョン：5.8

macOS 10.14：DVDプレイヤー（64bit）　ファイルサイズ：2.1MB　バージョン： 6.0
注：macOS 10.14のDVDプレイヤーは/System/Library/CoreServices/Applications/にある。アプリケーションから補助ツールに格下げになった。

これまでDVDプレイヤーが担ってきた用途については、フリーの「Free Mac Media Player」で置き換えるのがよいと思われます。

AppleScript名：光学ドライブのトレイオープン（内蔵ドライブのみ）

do shell script "/usr/bin/drutil eject internal"

★Click Here to Open This Script　

AppleScript名：光学ドライブのトレイオープン（外付けドライブのみ）

do shell script "/usr/bin/drutil eject external"

★Click Here to Open This Script　

現在地点の緯度経度情報を取得する v2

Posted on 10月 29, 2018 by Takaaki Naganoya

WiFiの情報を元に現在地点の緯度経度情報を取得するAppleScriptです。

実行前にWiFiがオンになっている必要があるので、WiFiの状態を確認して、WiFiがオフだったらオンにする処理が必要になります。

AppleScript名：現在地点の緯度経度情報を取得する v2

— Created 2015-03-04 by Takaaki Naganoya, Shane Stanley
— Modified 2015-12-06 by Takaaki Naganoya
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "CoreLocation"

property locationManager : missing value
property curLatitude : 0
property curLongitude : 0

–Get Current Geo Location
set {aLat, aLong} to getCurrentGeoLocation() of me

on getCurrentGeoLocation()
　　set locationManager to current application’s CLLocationManager’s alloc()’s init()
　　
　　set locE to locationManager’s locationServicesEnabled()
　　if (locE as boolean) = true then
　　　　locationManager’s setDelegate:me
　　　　locationManager’s setDesiredAccuracy:(current application’s kCLLocationAccuracyNearestTenMeters)
　　　　locationManager’s setDistanceFilter:500
　　　　locationManager’s startUpdatingLocation()
　　else
　　　　return false –error in init
　　end if
　　
　　set hitF to false
　　repeat 3000 times
　　　　if {curLatitude, curLongitude} is not equal to {0, 0} then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　　　delay ("0.0001" as real)
　　end repeat
　　
　　if hitF = false then return {false, false}
　　return {curLatitude, curLongitude}
end getCurrentGeoLocation

on locationManager:manager didUpdateLocations:locations
　　set location to (locations’s lastObject())
　　set eventDate to (location’s timestamp())
　　set howRecent to (eventDate’s timeIntervalSinceNow())
　　set howRecent to howRecent as real
　　set howRecent to absNum(howRecent)
　　
　　if howRecent < 15.0 then
　　　　set alt to location’s altitude –>(NSNumber) 46.356517791748
　　　　set aSpeed to location’s speed –>(NSNumber) -1.0
　　　　set aCourse to location’s course –North:0, East:90, South:180, West:270
　　　　–>　　(NSNumber) -1.0
　　　　set theDescription to location’s |description|()
　　　　–> (NSString) "<+35.xxxxx,+139.xxxxxx> +/- 65.00m (speed -1.00 mps / course -1.00) @ 2015/03/04 8時56分41秒日本標準時"
　　　　set anNSScanner to current application’s NSScanner’s scannerWithString:theDescription
　　　　anNSScanner’s setCharactersToBeSkipped:(current application’s NSCharacterSet’s characterSetWithCharactersInString:"<,")
　　　　set {theResult, aLat} to anNSScanner’s scanDouble:(reference)
　　　　set {theResult, aLng} to anNSScanner’s scanDouble:(reference)
　　　　copy {aLat, aLng} to {my curLatitude, my curLongitude}
　　else
　　　　locationManager’s stopUpdatingLocation()
　　end if
　　
end locationManager:didUpdateLocations:

on locationManager:anCLLocationManager didFailWithError:anNSError
　　display dialog (anNSError’s localizedDescription() as text)
end locationManager:didFailWithError:

on absNum(aNum)
　　if aNum > 0 then
　　　　return aNum
　　else
　　　　return (aNum * -1)
　　end if
end absNum

★Click Here to Open This Script　

recordのlistでKeynoteに表を作成する v1.5

Posted on 10月 29, 2018 by Takaaki Naganoya

リスト（配列）に入ったレコード（dictionary）のデータをもとに、現在オープン中のKeynoteの書類にスライドを追加し、その上に表を作成するAppleScriptです。

Keynoteで書類をオープンしていない場合には、書類を新規作成します。

表のデータを順次埋めているのは、Keynoteの表作成機能がそのように実装されているからです。普通は、データ内容を指定して表の作成と内容を一気に指定するように実装するのが普通ですが、Keynoteのこの仕様はあまりいただけません。

そのため、各セルを順次データで埋めているわけですが（アプリケーションとの通信頻度が高くなるので本来は避けたい処理）、「ignoring application responses」〜「end ignoring」による非同期実行モードによりデータでセルを埋める箇所のみ倍速実行しています。

「ignoring application responses」を使うと、AppleScriptがアプリケーションに命令を出して、正常に実行されたかどうかの「実行結果」を待たないため、おおよそ２倍の速度で実行できます。ただし、命令が正常に実行できたかどうかを取得できないので、安全性が確認されているようなケースで返り値が不要な場合にのみ利用できます。

macOS 10.14, Mojaveで実行したところ、macOS 10.12, Sierraの倍ぐらいの速度で実行しました。なんだろうこれは（10.12:Keynote v8.1, 10.14:Keynote v8.2）、、、、ハードウェアの構成などはほぼ同じで、まったく同じScriptを実行したのですが、、、、

AppleScript名：recordのlistでKeynoteに表を作成する v1.5

— Created 2016-06-29 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property aFontSize : 12

–This Date format is localized in Japanese. But this date string works only string. Don’t care about it.
set aList to {{pathStr:"book1_0.1.pdf", creationDate:"2016年6月17日金曜日", pageCount:222, countChars:127978, fileSize:"12027660"}, {pathStr:"book1_0.2.pdf", creationDate:"2016年6月17日金曜日", pageCount:230, countChars:129506, fileSize:"11109818"}, {pathStr:"book1_0.210.pdf", creationDate:"2016年6月18日土曜日", pageCount:254, countChars:147119, fileSize:"22832000"}, {pathStr:"book1_0.211.pdf", creationDate:"2016年6月18日土曜日", pageCount:254, countChars:147123, fileSize:"22831931"}, {pathStr:"book1_0.212.pdf", creationDate:"2016年6月18日土曜日", pageCount:241, countChars:134856, fileSize:"22273252"}, {pathStr:"book1_0.213.pdf", creationDate:"2016年6月18日土曜日", pageCount:241, countChars:134845, fileSize:"22271667"}, {pathStr:"book1_0.214.pdf", creationDate:"2016年6月18日土曜日", pageCount:241, countChars:134850, fileSize:"22270980"}, {pathStr:"book1_0.220.pdf", creationDate:"2016年6月18日土曜日", pageCount:242, countChars:134870, fileSize:"21098301"}, {pathStr:"book1_0.222.pdf", creationDate:"2016年6月18日土曜日", pageCount:243, countChars:135694, fileSize:"21146421"}, {pathStr:"book1_0.300.pdf", creationDate:"2016年6月20日月曜日", pageCount:251, countChars:142787, fileSize:"21427502"}, {pathStr:"book1_0.301.pdf", creationDate:"2016年6月20日月曜日", pageCount:251, countChars:142784, fileSize:"21421107"}, {pathStr:"book1_0.302.pdf", creationDate:"2016年6月20日月曜日", pageCount:256, countChars:142827, fileSize:"22593201"}, {pathStr:"book1_0.303.pdf", creationDate:"2016年6月20日月曜日", pageCount:257, countChars:142845, fileSize:"22616595"}, {pathStr:"book1_0.400.pdf", creationDate:"2016年6月22日水曜日", pageCount:281, countChars:162419, fileSize:"22430779"}, {pathStr:"book1_0.500.pdf", creationDate:"2016年6月23日木曜日", pageCount:309, countChars:178210, fileSize:"27611566"}, {pathStr:"book1_0.600.pdf", creationDate:"2016年6月24日金曜日", pageCount:326, countChars:194751, fileSize:"26820825"}, {pathStr:"book1_0.700.pdf", creationDate:"2016年6月24日金曜日", pageCount:310, countChars:195943, fileSize:"26408415"}, {pathStr:"book1_0.701.pdf", creationDate:"2016年6月24日金曜日", pageCount:310, countChars:195926, fileSize:"26406738"}, {pathStr:"book1_0.702.pdf", creationDate:"2016年6月24日金曜日", pageCount:310, countChars:195924, fileSize:"26406703"}, {pathStr:"book1_0.703.pdf", creationDate:"2016年6月24日金曜日", pageCount:311, countChars:196594, fileSize:"26416223"}, {pathStr:"book1_1.0.pdf", creationDate:"2016年6月25日土曜日", pageCount:311, countChars:196594, fileSize:"26075419"}}

set anItem to contents of first item of aList
set aDict to (current application’s NSMutableArray’s arrayWithObject:anItem)’s firstObject()
set aKeyList to aDict’s allKeys() as list
set aKeyCount to length of aKeyList
set aRowCount to length of aList

tell application "Keynote"
　　set dCount to count every document
　　if dCount = 0 then
　　　　set newDoc to make new document with properties {document theme:theme "ホワイト", width:1024, height:768} –This theme name is *localized* by stupid software maker in Cupertino. This means "White" in Japanese
　　end if
　　
　　
　　tell document 1
　　　　set aNewSlide to make new slide
　　　　set base slide of aNewSlide to master slide "空白" –This theme name is *localized* by stupid software maker in Cupertino. This means "Blank" in Japanese
　　　　
　　　　tell aNewSlide
　　　　　　set aTable to make new table with properties {column count:aKeyCount + 1, row count:aRowCount + 1}
　　　　　　
　　　　　　tell aTable
　　　　　　　　–ヘッダー行を作成（ラベルで埋める）
　　　　　　　　tell row 1
　　　　　　　　　　repeat with i from 2 to aKeyCount + 1
　　　　　　　　　　　　set aKey to item (i – 1) of aKeyList
　　　　　　　　　　　　
　　　　　　　　　　　　–非同期実行ここから
　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　set value of cell i to aKey
　　　　　　　　　　　　　　set font size to aFontSize
　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　–非同期実行ここまで
　　　　　　　　　　　　
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　–各行のデータを埋める
　　　　　　　　repeat with ii from 2 to aRowCount + 1
　　　　　　　　　　set aRecRow to item (ii – 1) of aList
　　　　　　　　　　tell row ii
　　　　　　　　　　　　
　　　　　　　　　　　　repeat with iii from 2 to (aKeyCount + 1)
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　tell cell iii
　　　　　　　　　　　　　　　　set aKey to item (iii – 1) of aKeyList
　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　　　–非同期実行ここから
　　　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　　　set value to retValueForKey(aRecRow, aKey) of me
　　　　　　　　　　　　　　　　　　set font size to aFontSize
　　　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　　　　　–非同期実行ここまで
　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　end repeat
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　　　
　　　　　　end tell
　　　　end tell
　　　　
　　end tell
end tell

on retValueForKey(aRec, aLabel)
　　set tmpDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　return (tmpDic’s valueForKey:aLabel) as string
end retValueForKey

★Click Here to Open This Script　

並び順をインデックスリストで指定してソート

Posted on 10月 29, 2018 by Takaaki Naganoya

並び順を定義したリスト（インデックスリスト）にもとづいてソートを行うAppleScriptです。

テストデータにあるように、都道府県別のリストを処理する際に、結果を北から南へと並べたいというニーズを満たすために、その場で作ったものでしかありません。都道府県別なので重複データが存在しないことが前提です。

一応、リストを扱うための高速化処理を行なっているので、速度についてはそれほど困ることはないと思われます。

＃　書籍「AppleScript最新リファレンス」からのリンクURLがBlog消失後に修復されていなかったので、再掲載しました。書籍側もリンクURLを修正したものを近日中にアップします

AppleScript名：並び順をインデックスリストで指定してソート

–並び順を指定するインデックスリスト（この順番にソート対象データを並べ替える）
set indexList to {"北海道", "青森県", "岩手県", "秋田県", "宮城県", "山形県", "福島県", "新潟県", "富山県", "石川県", "福井県", "茨城県", "栃木県", "群馬県", "埼玉県", "千葉県", "東京都", "神奈川県", "長野県", "山梨県", "岐阜県", "静岡県", "愛知県", "三重県", "滋賀県", "京都府", "兵庫県", "大阪府", "奈良県", "和歌山県", "島根県", "岡山県", "鳥取県", "広島県", "山口県", "香川県", "徳島県", "愛媛県", "高知県", "福岡県", "大分県", "佐賀県", "長崎県", "宮崎県", "熊本県", "鹿児島県", "沖縄県"}

–ソート対象データ
set aList to {{"東京都", 301}, {"神奈川県", 98}, {"大阪府", 90}, {"千葉県", 60}, {"埼玉県", 55}, {"北海道", 40}, {"愛知県", 40}, {"京都府", 40}, {"兵庫県", 40}, {"福岡県", 30}, {"静岡県", 20}, {"広島県", 20}, {"茨城県", 20}, {"宮城県", 16}, {"長野県", 15}, {"福島県", 12}, {"新潟県", 11}, {"滋賀県", 10}, {"岐阜県", 10}, {"群馬県", 10}, {"石川県", 10}, {"熊本県", 9}, {"岡山県", 9}, {"福井県", 7}, {"青森県", 7}, {"秋田県", 6}, {"愛媛県", 6}, {"和歌山県", 6}, {"奈良県", 5}, {"三重県", 5}, {"沖縄県", 5}, {"岩手県", 5}, {"大分県", 4}, {"鹿児島県", 4}, {"宮崎県", 4}, {"栃木県", 3}, {"香川県", 3}, {"山形県", 3}, {"富山県", 2}, {"山梨県", 2}, {"長崎県", 2}, {"徳島県", 2}, {"島根県", 2}, {"鳥取県", 1}, {"高知県", 1}, {"山口県", 1}}

set bList to sortItemByIndexList(aList, indexList, 1, 2) of me
–> {{"北海道", 40}, {"青森県", 7}, {"岩手県", 5}, {"秋田県", 6}, {"宮城県", 16}, {"山形県", 3}, {"福島県", 12}, {"新潟県", 11}, {"富山県", 2}, {"石川県", 10}, {"福井県", 7}, {"茨城県", 20}, {"栃木県", 3}, {"群馬県", 10}, {"埼玉県", 55}, {"千葉県", 60}, {"東京都", 301}, {"神奈川県", 98}, {"長野県", 15}, {"山梨県", 2}, {"岐阜県", 10}, {"静岡県", 20}, {"愛知県", 40}, {"三重県", 5}, {"滋賀県", 10}, {"京都府", 40}, {"兵庫県", 40}, {"大阪府", 90}, {"奈良県", 5}, {"和歌山県", 6}, {"島根県", 2}, {"岡山県", 9}, {"鳥取県", 1}, {"広島県", 20}, {"山口県", 1}, {"香川県", 3}, {"徳島県", 2}, {"愛媛県", 6}, {"高知県", 1}, {"福岡県", 30}, {"大分県", 4}, {"佐賀県", 0}, {"長崎県", 2}, {"宮崎県", 4}, {"熊本県", 9}, {"鹿児島県", 4}, {"沖縄県", 5}}

–並び順をインデックスリストで指定してソート
–パラメータ： (1) aList＝ソート元リスト（{{"name1", number1}, {"name2", number2}……} ）、
–　　　　　　(2) indexList＝ソート順指定用インデックスリスト、
–　　　　　　(3) itemNo＝並べ替え対象アイテム番号（ソート元リスト内の各リスト要素内のソートキーになるアイテムの番号）
–　　　　　　(4) nohitItem＝インデックス項目がソート元リストに対してヒットしなかった場合の、件数0を入れるアイテム番号
–エラー：　　　　エラー時にはfalseを返す
on sortItemByIndexList(aList, indexList, itemNo, nohitItem)
　　–処理高速化のためにハンドラ内部にScript Objectを宣言してデータアクセス
　　script sortItemByIndexListObj
　　　　property indexListSpd : indexList
　　　　property aListSpd : aList
　　end script
　　
　　–パラメータのエラーチェック
　　set tmpItem to contents of first item of aList
　　set tmpLen to length of tmpItem
　　
　　–itemNoのエラーチェック
　　if (itemNo < 1) or (itemNo > tmpLen) then return false
　　–nohitItemのエラーチェック
　　if (nohitItem < 1) or (nohitItem > tmpLen) then return false
　　–itemNoとnohitItemが衝突していないかチェック
　　if itemNo = nohitItem then return false
　　
　　
　　–処理本体
　　set outList to {}
　　repeat with i in indexListSpd of sortItemByIndexListObj
　　　　set j to contents of i
　　　　
　　　　set hitF to false
　　　　
　　　　repeat with ii in aListSpd of sortItemByIndexListObj
　　　　　　set targItem to contents of item itemNo of ii
　　　　　　if targItem = j then
　　　　　　　　set the end of outList to contents of ii
　　　　　　　　set hitF to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　end repeat
　　　　
　　　　–合致するデータがなかった場合の対応
　　　　if hitF = false then
　　　　　　set tmpList to {}
　　　　　　repeat nohitItem times
　　　　　　　　set the end of tmpList to ""
　　　　　　end repeat
　　　　　　set item itemNo of tmpList to j
　　　　　　set item nohitItem of tmpList to 0
　　　　　　set the end of outList to tmpList
　　　　end if
　　　　
　　end repeat
　　
　　outList
　　
end sortItemByIndexList

★Click Here to Open This Script　

offset ofの高速実行

Posted on 10月 29, 2018 by Takaaki Naganoya

文字列中の文字/文字列スキャンを行う「offset of」命令を高速化するAppleScriptです。

AppleScript標準装備の「offset of」の処理を横取りして、自前でAppleScriptのコマンドで実行すると2.5倍以上高速になります。発見者に敬意を表して「Jun Araki Method」と呼んでいます。

オリジナルからの改変を行なったポイントは、macOS 10.10以降のAppleScriptObjC（Cocoaの機能を利用するAppleScript）の中に書いたときへの対処として「using terms from scripting additions」句でくくっている点です。Cocoaを使わないOLD Style AppleScriptではこの「using terms from scripting additions」節は必要ありません。

＃　書籍「AppleScript最新リファレンス」からのリンクURLがBlog消失後に修復されていなかったので、再掲載しました。書籍側のリンクURLは簡易PDFビューワー「PiyoReader」で変更を吸収できます

AppleScript名：offset ofの高速実行

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aDate to current date
repeat 100000 times
　　set aStr to "abcdefghi"
　　using terms from scripting additions
　　　　set aRes to offset of "c" in aStr
　　end using terms from
end repeat
set bDate to current date

–結果表示
display dialog (bDate – aDate) as string
–> 通常で5秒、offset ofをフックして自前のサブルーチンで実行すると２秒

–offset命令の実行を横取りする
on offset of searchStr in str
　　set aRes to getOffset(str, searchStr) of me
　　return aRes
end offset

on getOffset(str, searchStr)
　　set d to divideBy(str, searchStr)
　　if (count d) is less than 2 then return 0
　　return (length of item 1 of d) + 1
end getOffset

on divideBy(str, separator)
　　set delSave to AppleScript’s text item delimiters
　　set the AppleScript’s text item delimiters to separator
　　set strItems to every text item of str
　　set the AppleScript’s text item delimiters to delSave
　　return strItems
end divideBy

★Click Here to Open This Script　

文字列で指定したラベルの値をレコードから取得する v2

Posted on 10月 29, 2018 by Takaaki Naganoya

OLD Style AppleScriptで（強引に）レコード中の任意の値を間接指定で取得するAppleScriptです。

裏技を駆使し、エラーメッセージからデータを取り出して動的にScript生成して結果を取得するという、仕様的にはできるわけがないが、実際にできるという処理です。

＃　書籍「AppleScript最新リファレンス」からのリンクURLがBlog消失後に修復されていなかったので、再掲載しました。書籍側もリンクURLを修正したものを近日中にアップします

AppleScript名：文字列で指定したラベルの値をレコードから取得する v2

set aRec to {myAge:36, myHight:166, myWeight:70}
set aLabel to "myHight"

set a to getSpecifiedAttrOfRec(aRec, aLabel) of me
–> 166

–与えられたレコードから指定の属性値ラベルの値を取り出して返す
on getSpecifiedAttrOfRec(aRec, aLabel)
　　
　　–パラメータのエラーチェック。エラー時にはmissing valueを返す
　　set aClass to class of aRec
　　if aClass is not record then return missing value
　　if aLabel = "" then return missing value
　　if class of aLabel is not string then return missing value
　　
　　–レコードを無理矢理stringにcastして、エラーメッセージを取得する
　　try
　　　　set a to aRec as string
　　on error aMes
　　　　set a to aMes
　　end try
　　
　　–エラーメッセージ文字列から、元のレコードの情報を組み立てる
　　set b to trimStrFromTo(a, "{", "}")
　　set b to "{" & b & "}"
　　
　　–動的にAppleScriptを生成して、無理矢理レコードから目的の属性値を取り出す
　　set s to "return " & aLabel & " of " & b
　　try
　　　　set recData to run script s
　　on error
　　　　return missing value –指定の属性値が存在しなかった場合にはエラー
　　end try
　　
　　return recData
　　
end getSpecifiedAttrOfRec

on trimStrFromTo(aStr, fromStr, toStr)
　　–fromStrは前から探す
　　if fromStr is not equal to "" then
　　　　set sPos to (offset of fromStr in aStr) + 1
　　else
　　　　set sPos to 1
　　end if
　　
　　–toStrは後ろから探す
　　if toStr is not equal to "" then
　　　　set b to (reverse of characters of aStr) as string
　　　　set ePos to (offset of toStr in b)
　　　　set ePos to ((length of aStr) – ePos)
　　else
　　　　set ePos to length of aStr
　　end if
　　set aRes to text sPos thru ePos of aStr
　　return aRes
end trimStrFromTo

–文字置換ルーチン
on repChar(origText, targStr, repStr)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

★Click Here to Open This Script　

Cocoaの機能を利用して（macOS 10.10以降）書くと、こんな感じです。

AppleScript名：レコードからラベルを指定して値を取り出し

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aDict to current application’s NSDictionary’s dictionaryWithDictionary:{abc:"123", bcd:"456"}
set aVal to (aDict’s valueForKey:"abc") as string
–>　　"123"

★Click Here to Open This Script　