アラートダイアログ上にTextViewを表示

Posted on 7月 8, 2019 by Takaaki Naganoya

アラートダイアログ上にTextViewを表示して、指定のテキストを閲覧するAppleScriptです。

とくにこれといって何か表示するものを思いつかなかったので、自分自身のソースコードを取得して表示しています。スクリプトエディタやScript Debugger上で実行した場合には自分自身のソースコードをテキストビュー上で表示します。

読み取り専用のスクリプトやアプレットで実行している場合にはソースコードを取得できません。何か適宜自分で表示させたいテキストを与えてみてください。

AppleScript名：アラートダイアログ上にTexViewを表示

— Created 2019-07-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "OSAKit"

property |NSURL| : a reference to current application’s |NSURL|
property NSFont : a reference to current application’s NSFont
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSTextView : a reference to current application’s NSTextView
property NSScrollView : a reference to current application’s NSScrollView
property NSRunningApplication : a reference to current application’s NSRunningApplication
property OSAScript : a reference to current application’s OSAScript

property returnCode : 0

–Get Self Source Code (a kind of joke)
set mePath to path to me
set asStr to getASsourceFor(mePath) of me

set paramObj to {myMessage:"Main Message", mySubMessage:"Sub information", mes1:(asStr), mesWidth:400, mesHeight:200, fontName:"HiraginoSans-W3", fontSize:11.0}

–my dispTextViewWithAlertdialog:paramObj–for debug
my performSelectorOnMainThread:"dispTextViewWithAlertdialog:" withObject:paramObj waitUntilDone:true

on dispTextViewWithAlertdialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mesStr to (mes1 of paramObj) as string –Text Input field 1 Label
　　set aWidth to (mesWidth of paramObj) as integer –TextView width
　　set aHeight to (mesHeight of paramObj) as integer –TextView height
　　set aFontName to (fontName of paramObj) as string –TextView font name
　　set aFontSize to (fontSize of paramObj) as real –TextView font size
　　
　　— Create a TextView with Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aView’s setRichText:true
　　aView’s useAllLigatures:true
　　aView’s setTextColor:(current application’s NSColor’s cyanColor()) –cyanColor
　　aView’s setFont:(current application’s NSFont’s fontWithName:aFontName |size|:aFontSize)
　　set aColor to current application’s NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.5
　　aView’s setBackgroundColor:aColor
　　aView’s setString:mesStr
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end dispTextViewWithAlertdialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–指定AppleScriptファイルのソースコードを取得する（実行専用Scriptからは取得できない）
— Original Created 2014-02-23 Shane Stanley
on getASsourceFor(anAlias as {alias, string})
　　set aURL to |NSURL|’s fileURLWithPath:(POSIX path of anAlias)
　　set theScript to OSAScript’s alloc()’s initWithContentsOfURL:aURL |error|:(missing value)
　　
　　if theScript is equal to missing value then
　　　　error "Compile Error" — handle error
　　else
　　　　set sourceText to theScript’s source()
　　end if
　　
　　return sourceText as string
end getASsourceFor

★Click Here to Open This Script　

テキストから数値を抽出して度数分布集計 v3

Posted on 6月 29, 2019 by Takaaki Naganoya

CotEditorで編集中の最前面の書類の本文中から指定桁の数値を抽出して登場回数で度数分布の集計を行うAppleScriptです。

初版では、集計対象の数値を桁数で指定するという（使うのに）無茶な仕様になっていたので、この頭の悪い仕様に作った本人もめまいがしていました。

わざわざAppleScriptを使うのは、他のどの環境でも追いつけない高度な処理を行うことに意義があると思っています。

そこで、

　（１）数字部分をあらかじめ抽出して事前に集計（分布および最小値、最大値を計算）
　（２）事前集計結果をグラフ表示
　（３）集計対象の数字の範囲を最小値〜最大値までの間で指定できるように
　（４）パラメータの入力、および事前集計結果の表示を自前で作成したアラートダイアログで表示

といった変更を加えてみました。初版では「数字の桁数」というご無体な指定で数字を抽出していましたが、最初に最大値を計算しておいたことで、最大値の桁数ですべて数値を抽出し、最小値・最大値の間に収まる数値のみを抽出して度数分布を再計算しています（言うほど計算結果が変わってきたりはしないんですけど　＾ー＾；；）。

このぐらい行えば、安心して見られる感じでしょうか。

追記：
4.11といった文字が「4」と「11」に分離して認識されるようだったので数値として認識するCharacter setに「.」（小数点）および「,」（桁数区切り）を追加してみました。想定していた部分はうまくクリアしたものの、「REV.」の部分の「.」も認識して「0.411」のような数値として認識したようです。

このあたりに課題を残しつつも、全体として見ると当初からノイズとして除去する対象として考えていた箇所でもあったため、そんなもんだろうかと。

アラートダイアログに表示するテスト集計結果の文字が小さかったので、少し大きくしてみました。フォントについては「ヒラギノ角ゴシック W1」（PostScript名は「HiraginoSans-W1」）を指定しています。このあたりは好みに応じて変更してみるとよいでしょう。

巨大なテキスト（青空文庫の小説１作文まるごととか）を対象に処理していないので（画面キャプチャ掲載している程度のサイズ）そういう配慮は行っていません。仕事だと考慮しないでもないですが、必要と思われた処理をとりあえず組んでみた程度なので、そういうものだとお考えください。

–> Download Applet With Libraries (mainly for macOS 10.14 or later)

AppleScript名：テキストから数値を抽出して度数分布集計 v3.1

— Created 2019-06-29 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html

–property theResult : 0
property returnCode : 0
property segRes : missing value

set segRes to missing value

tell application "CotEditor"
　　if (count every document) = 0 then return –No Document
　　
　　tell front document
　　　　set aText to contents of it
　　　　set lineTerm to (line ending)
　　end tell
　　
　　–改行コードの選択（ドキュメントの状態から取得）
　　if lineTerm = LF then
　　　　set aRet to ASCII character 10 –To avoid keyword conflict (string)
　　else if lineTerm = CR then
　　　　set aRet to ASCII character 13
　　else if lineTerm = CRLF then
　　　　set aRet to (ASCII character 13) & (ASCII character 10)
　　else
　　　　set aRet to ASCII character 10
　　end if
end tell

–事前にテキストから自動で数値部分を抽出して分析
set cArray to extractNumberFromText(aText) of me
set aRes to (cArray’s valueForKeyPath:"@max.self")’s intValue()
set bRes to (cArray’s valueForKeyPath:"@min.self")’s intValue()
set cRes to (cArray’s valueForKeyPath:"@count")’s intValue()

–事前に数字の分布シミュレーションを計算
set tmpLen to count every character of (aRes as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set sampleStr to calculateNumFreq(cArray, "■", aRet, bRes, aRes, true) of me

set sampleStr to return & return & "テスト集計結果：" & return & return & sampleStr

–テキストからの数値抽出時のパラメータ取得
set paramObj to {myMessage:"テキスト内の数値の度数分布集計", mySubMessage:"集計対象の数値の範囲と、集計時のグラフ生成時の構成文字を指定してください", mes1:"最小値（min.）", mes1Default:(bRes as string), mes2:"最大値（max.）", mes2Default:(aRes as string), mes3:"出力文字", mes3Default:"絆", aSample:sampleStr}

–set segRes to my inputParametersFromAlertDialog:paramObj–for debugging
my performSelectorOnMainThread:"inputParametersFromAlertDialog:" withObject:(paramObj) waitUntilDone:true
if segRes = missing value then return –Cancel

–度数分布計算
set tmpLen to count every character of ((a2Res of segRes) as string)
set theList to my findPattern:("[0-9]{" & tmpLen & "}") inString:aText
set outStr to calculateNumFreq(cArray, a3Res of segRes, aRet, a1Res of segRes, a2Res of segRes, false) of me

–テキストエディタへの集計結果出力
tell application "CotEditor"
　　tell front document
　　　　set contents of it to (aText & aRet & aRet & "集計結果：" & aRet & aRet & outStr & aRet)
　　end tell
end tell

on inputParametersFromAlertDialog:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mes1Label to (mes1 of paramObj) as string –Text Input field 1 Label
　　set mes2Label to (mes2 of paramObj) as string –Text Input field 2 Label
　　set mes3Label to (mes3 of paramObj) as string –Text Input field 3 Label
　　set aTextInputString to (mes1Default of paramObj) as string –Text Input field 1 Default value
　　set bTextInputString to (mes2Default of paramObj) as string –Text Input field 2 Default value
　　set cTextInputString to (mes3Default of paramObj) as string –Text Input field 2 Default value
　　set sampleString to (aSample of paramObj) as string
　　
　　— Create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 500, 400))
　　
　　— create two input field and their labels pairs
　　–NSTextFields for Input
　　set aTextInput to makeNSTextField(100, 70, 140, 20, true, (aTextInputString), true, true) of me
　　set bTextInput to makeNSTextField(100, 35, 140, 20, true, (bTextInputString), true, true) of me
　　set cTextInput to makeNSTextField(100, 0, 140, 20, true, (cTextInputString), true, true) of me
　　
　　–Labels
　　set a1TF to makeNSTextField(0, 70, 100, 20, false, (mes1Label), false, false) of me
　　set a2TF to makeNSTextField(0, 35, 100, 20, false, (mes2Label), false, false) of me
　　set a3TF to makeNSTextField(0, 0, 100, 20, false, (mes3Label), false, false) of me
　　
　　–Sample Text View
　　set aColor to NSColor’s colorWithDeviceRed:0.0 green:0.0 blue:0.0 alpha:0.9
　　set tvScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 300))
　　set tvView to NSTextView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 120, 500, 380))
　　tvView’s setRichText:true
　　tvView’s useAllLigatures:true
　　tvView’s setTextColor:(NSColor’s cyanColor()) —
　　tvView’s setFont:(current application’s NSFont’s fontWithName:"HiraginoSans-W1" |size|:16.0)
　　tvView’s setBackgroundColor:aColor
　　tvView’s setEditable:false
　　
　　tvScroll’s setDocumentView:tvView
　　tvView’s enclosingScrollView()’s setHasVerticalScroller:true
　　tvView’s setString:(sampleString)
　　
　　
　　theView’s setSubviews:{a1TF, aTextInput, a2TF, bTextInput, a3TF, cTextInput, tvScroll}
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then
　　　　set my segRes to missing value
　　else
　　　　set s1Val to (aTextInput’s integerValue()) as integer
　　　　set s2Val to (bTextInput’s integerValue()) as integer
　　　　set s3Val to (cTextInput’s stringValue()) as string
　　　　
　　　　–return {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}–old version’s way to return values
　　　　set my segRes to {a1Res:s1Val, a2Res:s2Val, a3Res:s3Val}
　　end if
end inputParametersFromAlertDialog:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeNSTextField(xPos as integer, yPos as integer, myWidth as integer, myHeight as integer, editableF as boolean, setVal as string, backgroundF as boolean, borderedF as boolean)
　　set aNSString to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, yPos, myWidth, myHeight))
　　aNSString’s setEditable:(editableF)
　　aNSString’s setStringValue:(setVal)
　　aNSString’s setDrawsBackground:(backgroundF)
　　aNSString’s setBordered:(borderedF)
　　return aNSString
end makeNSTextField

–与えられたテキストから数値部分を抽出して1D Arrayで返す
on extractNumberFromText(aText)
　　set aStr to current application’s NSString’s stringWithString:aText
　　–set nonDigitCharacterSet to (current application’s NSCharacterSet’s decimalDigitCharacterSet())’s invertedSet()
　　set nonDigitCharacterSet to (current application’s NSCharacterSet’s characterSetWithCharactersInString:"0123456789.,")’s invertedSet()
　　set bArray to (aStr’s componentsSeparatedByCharactersInSet:nonDigitCharacterSet)
　　
　　–Sweep Blank Items
　　load framework –BridgePlus
　　set cArray to (current application’s SMSForder’s arrayByDeletingBlanksIn:(bArray))’s valueForKey:"intValue"
　　return cArray –return as NSArray
end extractNumberFromText

–正規表現でテキスト中から指定パターンに該当する箇所を抽出してリストで返す
on findPattern:thePattern inString:theString
　　set theOptions to ((current application’s NSRegularExpressionDotMatchesLineSeparators) as integer) + ((current application’s NSRegularExpressionAnchorsMatchLines) as integer)
　　set theRegEx to current application’s NSRegularExpression’s regularExpressionWithPattern:thePattern options:theOptions |error|:(missing value)
　　set theFinds to theRegEx’s matchesInString:theString options:0 range:{location:0, |length|:length of theString}
　　set theFinds to theFinds as list — so we can loop through
　　set theResult to {} — we will add to this
　　set theNSString to current application’s NSString’s stringWithString:theString
　　repeat with i from 1 to count of items of theFinds
　　　　set theRange to (item i of theFinds)’s range()
　　　　set end of theResult to (theNSString’s substringWithRange:theRange) as integer
　　end repeat
　　return theResult
end findPattern:inString:

–1D Listをユニーク化してソート
on uniquifyAndSort1DList(theList as list, aBool as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:theList
　　set bArray to aArray’s valueForKeyPath:"@distinctUnionOfObjects.self"
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"compare:"
　　set cArray to bArray’s sortedArrayUsingDescriptors:{aDdesc}
　　
　　set bList to cArray as list
　　return bList
end uniquifyAndSort1DList

–度数分布集計して文字グラフ出力
on calculateNumFreq(theList, outChar, aLineTerminator, aMin, aMax, zeroPaddingF)
　　set theCountedSet to current application’s NSCountedSet’s alloc()’s initWithArray:theList
　　set newArray to current application’s NSMutableArray’s new()
　　
　　set kList to uniquifyAndSort1DList(theList, false) of me –降順ソート
　　set maxDigit to (count every character of (aMax as string))
　　
　　repeat with i in kList
　　　　if (i ≥ aMin) and (i ≤ aMax) then
　　　　　　(newArray’s addObject:{theKey:i, theCount:(theCountedSet’s countForObject:i)})
　　　　end if
　　end repeat
　　
　　set outStr to ""
　　
　　repeat with i in newArray as list
　　　　set j to (current application’s NSDictionary’s dictionaryWithDictionary:i)
　　　　set tmpStr to (j’s valueForKey:"theKey")
　　　　
　　　　if zeroPaddingF = true then
　　　　　　–Zero Pagging
　　　　　　set keyNumStr to numToZeroPaddingStr(tmpStr, maxDigit, "0") of me
　　　　else
　　　　　　–No Padding
　　　　　　copy (tmpStr as string) to keyNumStr
　　　　end if
　　　　
　　　　set outStr to outStr & keyNumStr & "："
　　　　
　　　　set aNum to (j’s valueForKey:"theCount")
　　　　repeat aNum times
　　　　　　set outStr to outStr & outChar
　　　　end repeat
　　　　
　　　　set outStr to outStr & aLineTerminator
　　end repeat
end calculateNumFreq

–整数の値に指定桁数ゼロパディングして文字列で返す
on numToZeroPaddingStr(aNum as integer, aDigit as integer, paddingChar as text)
　　set aNumForm to current application’s NSNumberFormatter’s alloc()’s init()
　　aNumForm’s setPaddingPosition:(current application’s NSNumberFormatterPadBeforePrefix)
　　aNumForm’s setPaddingCharacter:paddingChar
　　aNumForm’s setMinimumIntegerDigits:aDigit
　　
　　set bNum to current application’s NSNumber’s numberWithInt:aNum
　　set aStr to aNumForm’s stringFromNumber:bNum
　　
　　return aStr as text
end numToZeroPaddingStr

★Click Here to Open This Script　

Keynote書類のテキスト色を置換

Posted on 6月 9, 2019 by Takaaki Naganoya

最前面のKeynote書類の文字色を置換するAppleScriptです。

＃　初出時にはmacOS 10.13であったため、スクリプトエディタ上からも野良Framework呼び出しができましたが、macOS 10.14以降ではSIPを解除するかScript Debugger上で実行する必要があります

Keynoteは文字色の置換をする機能が実装されていないので、個別に手で色を変更するか、あるいはスタイルを編集して一括で修正するやり方になります。

そこで、AppleScriptで色置換を行う処理を書いてみました。表の背景色を置換する処理を書いたときの部品を大幅に使いまわしています。

文字色の取得や判定は、テキストアイテムの１文字目の情報で判断しています。途中で色を変更しているような場合にはうまく検出できません（処理スピードを重視したことと、自分の利用方法の範囲ではそういう文字ごとに異なる色を指定するところまではサポートしなくてよいと考えたためです。仕事ならもうちょっと真面目に作り込むかもしれませんが、、、、）。

ポップアップメニュー中の色名の動的な推定に、オープンソースの「DBColorNames」をフレームワーク化した
「dbColNamesKit.framework」を利用しています。

–> dbColNamesKit.framework (To ~/Library/Frameworks)

▲左上の時刻部分の色を置換したい

▲本Scriptを実行した直後。最前面のKeynote書類のすべてのテキストを走査して文字色を取得する

▲取得した文字色リスト。この中から置換対象を選択する。色データから色名を動的に生成し、色IDとともに名称で個別に指定したり識別したりできる

▲変更後の色をカラーピッカーで選択

▲Keynote書類上の文字色を変更してみた

AppleScript名：Keynote書類の現在のテキスト色を置換.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/06/08
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — Yosemite (10.11) or later
use framework "Foundation"
use framework "AppKit"
use framework "dbColNamesKit" –https://github.com/daniel-beard/DBColorNames/
use scripting additions

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSMenu : a reference to current application’s NSMenu
property NSImage : a reference to current application’s NSImage
property NSIndexSet : a reference to current application’s NSIndexSet
property NSTextField : a reference to current application’s NSTextField
property NSColorWell : a reference to current application’s NSColorWell
property NSMenuItem : a reference to current application’s NSMenuItem
property NSBezierPath : a reference to current application’s NSBezierPath
property NSPopUpButton : a reference to current application’s NSPopUpButton
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication

property returnCode : 0
property pop1ind : 0

–スライド枚数をカウント
tell application "Keynote"
　　tell front document
　　　　set sCount to count every slide
　　end tell
end tell

–すべてのテキストアイテム、タイトルから色情報を取得する
set cList to {}
repeat with sNum from 1 to sCount
　　set cList to cList & getEveryTextColorOfSlide(sNum) of me
end repeat

–文字色のユニーク化
set dList to makeUniqueListOf(cList) of me

set paramObj to {mainDat:dList, myTitle:"テキスト色置換", mySubTitle:"Keynoteのテキストアイテム、デフォルトアイテム（タイトル）の文字色置換", myColorRangeMax:65535}
my getPopupValues:paramObj

if pop1ind = false then return –timed out
set fromCol to (contents of item pop1ind of dList)

–カラーピッカーで置換色選択
set tCol to choose color default color fromCol

–Keynote書類中のテキストの文字色を置換
repeat with sNum from 1 to sCount
　　set cList to cList & repEveryTextColorOfSlide(sNum, fromCol, tCol) of me
end repeat

–カラーポップアップメニューをウィンドウ表示
on getPopupValues:paramObj
　　set ap1List to (mainDat of (paramObj as record)) as list
　　set winTitle to (myTitle of (paramObj as record)) as string
　　set subTitle to (mySubTitle of (paramObj as record)) as string
　　set aColMax to (myColorRangeMax of (paramObj as record)) as list
　　
　　–Viewをつくる
　　set aView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 360, 80))
　　
　　–Labelをつくる
　　set a1TF to NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 40, 80, 20))
　　a1TF’s setEditable:false
　　a1TF’s setStringValue:"From Color:"
　　a1TF’s setDrawsBackground:false
　　a1TF’s setBordered:false
　　
　　–Ppopup Buttonをつくる
　　set a1Button to NSPopUpButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(80, 40, 200, 20)) pullsDown:false
　　a1Button’s removeAllItems()
　　
　　set a1Menu to NSMenu’s alloc()’s init()
　　set aCDB to current application’s DBColorNames’s alloc()’s init()
　　
　　–Popup Menuをつくる
　　set iCount to 1
　　repeat with i in ap1List
　　　　copy i to {r1, g1, b1}
　　　　
　　　　set nsCol to makeNSColorFromRGBAval(r1, g1, b1, aColMax, aColMax) of me
　　　　set anImage to makeRoundedNSImageWithFilledWithColor(64, 64, nsCol, 4) of me
　　　　
　　　　–色名をRGB値から動的に生成（あらかじめdbNamesが持っているカラーパレットの近似色の色名を返す）
　　　　set aTitle to "#" & (iCount as string) & " " & (aCDB’s nameForColor:nsCol) as string
　　　　
　　　　–Menu Itemを作成する
　　　　set aMenuItem to (NSMenuItem’s alloc()’s initWithTitle:aTitle action:"actionHandler:" keyEquivalent:"")
　　　　(aMenuItem’s setImage:anImage)
　　　　(aMenuItem’s setEnabled:true)
　　　　(aMenuItem’s setTarget:me)
　　　　(a1Menu’s addItem:aMenuItem)
　　　　
　　　　set iCount to iCount + 1
　　end repeat
　　
　　–Popup ButtonにPopup Menuを設定する
　　a1Button’s setMenu:a1Menu
　　
　　–ViewにPopup Buttonとテキストラベルを入れる
　　aView’s addSubview:a1TF
　　aView’s addSubview:a1Button
　　aView’s setNeedsDisplay:true
　　
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:winTitle
　　　　its setInformativeText:subTitle
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set s1Val to ((a1Button’s indexOfSelectedItem() as number) + 1)
　　copy s1Val to my pop1ind
end getPopupValues:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–Popup Action Handler
on actionHandler:sender
　　set aTag to tag of sender as integer
　　set aTitle to title of sender as string
end actionHandler:

–aMaxValを最大値とする数値でNSColorを作成して返す
on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

–指定サイズのNSImageを作成し、指定色で塗ってNSImageで返す
on makeNSImageWithFilledWithColor(aWidth as integer, aHeight as integer, fillColor)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　anImage’s lockFocus()
　　—
　　set theRect to {{x:0, y:0}, {height:aHeight, width:aWidth}}
　　set theNSBezierPath to NSBezierPath’s bezierPath
　　theNSBezierPath’s appendBezierPathWithRect:theRect
　　—
　　fillColor’s |set|() –色設定
　　theNSBezierPath’s fill() –ぬりつぶし
　　—
　　anImage’s unlockFocus()
　　—
　　return anImage
end makeNSImageWithFilledWithColor

–指定サイズのNSImageを作成し、指定色で塗ってNSImageで返す、anRadiusの半径の角丸で
on makeRoundedNSImageWithFilledWithColor(aWidth as integer, aHeight as integer, fillColor, anRadius as real)
　　set anImage to NSImage’s alloc()’s initWithSize:(current application’s NSMakeSize(aWidth, aHeight))
　　anImage’s lockFocus()
　　—
　　set theRect to {{x:0, y:0}, {height:aHeight, width:aWidth}}
　　set theNSBezierPath to NSBezierPath’s bezierPathWithRoundedRect:theRect xRadius:anRadius yRadius:anRadius
　　—
　　fillColor’s |set|() –色設定
　　theNSBezierPath’s fill() –ぬりつぶし
　　—
　　anImage’s unlockFocus()
　　
　　return anImage
end makeRoundedNSImageWithFilledWithColor

–最前面のKeynote書類のすべてのスライドから、テキストアイテムとタイトルアイテムの文字色を取得
on getEveryTextColorOfSlide(sNum)
　　set cList to {}
　　
　　tell application "Keynote"
　　　　tell front document
　　　　　　set sMax to count every slide
　　　　　　if sMax < sNum then return false
　　　　　　
　　　　　　tell slide sNum
　　　　　　　　–すべての文字アイテムの先頭の文字の色情報を取得
　　　　　　　　try
　　　　　　　　　　set tCount to count every text item
　　　　　　　　　　repeat with i from 1 to tCount
　　　　　　　　　　　　set s1List to color of character 1 of object text of text item i
　　　　　　　　　　　　set the end of cList to s1List
　　　　　　　　　　end repeat
　　　　　　　　on error
　　　　　　　　　　–set s1List to {}
　　　　　　　　end try
　　　　　　　　
　　　　　　　　–タイトルの先頭の文字の色情報を取得
　　　　　　　　try
　　　　　　　　　　set s2List to color of character 1 of object text of default title item
　　　　　　　　　　set the end of cList to s2List
　　　　　　　　on error
　　　　　　　　　　set s2List to {}
　　　　　　　　end try
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
　　
　　return cList
end getEveryTextColorOfSlide

–最前面のKeynote書類の指定番号のスライドで、テキストアイテムとタイトルアイテムの文字色を置換
on repEveryTextColorOfSlide(sNum, fromCol, toCol)
　　tell application "Keynote"
　　　　tell front document
　　　　　　set sMax to count every slide
　　　　　　if sMax < sNum then return false
　　　　　　
　　　　　　tell slide sNum
　　　　　　　　–すべての文字アイテムの先頭の文字の色情報を置換
　　　　　　　　try
　　　　　　　　　　set tCount to count every text item
　　　　　　　　　　repeat with i from 1 to tCount
　　　　　　　　　　　　set s1List to color of character 1 of object text of text item i
　　　　　　　　　　　　if s1List = fromCol then
　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　set color of every character of object text of text item i to toCol
　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　end if
　　　　　　　　　　end repeat
　　　　　　　　on error
　　　　　　　　　　—
　　　　　　　　end try
　　　　　　　　
　　　　　　　　–タイトルの先頭の文字の色情報を置換
　　　　　　　　try
　　　　　　　　　　set s2List to color of character 1 of object text of default title item
　　　　　　　　　　if s2List = fromCol then
　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　set color of every character of object text of default title item to toCol
　　　　　　　　　　　　end ignoring
　　　　　　　　　　end if
　　　　　　　　on error
　　　　　　　　　　set s2List to {}
　　　　　　　　end try
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
end repEveryTextColorOfSlide

–Listのユニーク化
on makeUniqueListOf(theList)
　　set theSet to current application’s NSOrderedSet’s orderedSetWithArray:theList
　　return (theSet’s array()) as list
end makeUniqueListOf

★Click Here to Open This Script　

Numbersで選択中の表のセルの範囲を背景色で頻度集計

Posted on 6月 6, 2019 by Takaaki Naganoya

Numbersでオープン中の書類の現在のシート上にある表の選択範囲のセルに対して、背景色（Background color）で登場頻度の集計を行って、どの色が何回登場しているかを色プレビューしつつ表示するAppleScriptです。

集計をRGB値で数値的に行うことは容易ですが、結局のところ色なんてRGB値で見せられてもわからず、実際に目で見える色で表示しないと判断できません。そのため、アラートダイアログを作成してその上にColorWellで表示しています。

▲Numbersの表でセルを選択

▲Numbersの表のセルに指定されている背景色の登場頻度で集計し、色プレビューと登場回数を表示（スクリプトエディタ@macOS 10.14.5上の表示、Dark Mode）

▲Numbersの表のセルに指定されている背景色の登場頻度で集計し、色プレビューと登場回数を表示（Script Debugger@macOS 10.14.5上の表示、Dark Mode）

上記サンプル表は本Blog上での説明用のために簡略化した表ですが、実際には数十行の入り組んだNumbersの表を相手にしており、かつ、手作業で色付きセルだけを数えるなんて考えたくもないレベルで頻繁に確認しなくてはならなかったために、本Scriptを作ってみました。

Numbersにかぎらず、iWorkアプリケーション（Keynote、Pages、Numbers）で共通の仕様ですが、背景色を塗らないセルから背景色を取得するとmissing valueが返ります。

本ScriptはScript Menuに入れて実行するとアラートダイアログが最前面に出てこないなど、Script書類（.scpt、.scptd）のままで実行すると問題が発生。Script Menuに入れる場合にはアプレット（.app）書き出しする必要があります。

▲スクリプトメニューにアプレット書き出しした実行ファイルを入れて呼び出し（macOS 10.14.5）。スクリプトメニューは最前面にあるGUIアプリケーションに応じて、それぞれのアプリケーション用のメニューを表示できるようになっている

AppleScript名：選択中の表のセルの範囲を背景色で頻度集計.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/06/06
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property theResult : 0
property returnCode : 0
property theDataSource : {}

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　return "No Selection" –何も選択されてなかった場合
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　set bgColList to background color of every cell of selection range
　　　　　　　　–> {{18572, 45937, 65452}, {18572, 45937, 65452}, {3001, 24801, 44056}, {18572, 45937, 65452}, {18572, 45937, 65452}, {64899, 33134, 31509}, {64899, 33134, 31509}, {18572, 45937, 65452}, {18572, 45937, 65452}, {3001, 24801, 44056}, {18572, 45937, 65452}, {18572, 45937, 65452}, {26149, 65534, 58650}, {26149, 65534, 58650}, {26149, 65534, 58650}, {26149, 65534, 58650}, {18572, 45937, 65452}, {18572, 45937, 65452}}
　　　　　　end tell
　　　　end tell
　　end tell
end tell

set bgColList to countItemsByItsAppearance(bgColList) of me
–> {{theName:{65535, 65533, 65534}, numberOfTimes:73}, {theName:{65535, 65535, 21706}, numberOfTimes:73}, {theName:missing value, numberOfTimes:27}}

set paramObj to {mainDat:bgColList, myTitle:"色別集計", mySubTitle:"Numbers上で選択したセルの背景色の頻度集計"}
–my browseColors:paramObj–for debug

my performSelectorOnMainThread:"browseColors:" withObject:(paramObj) waitUntilDone:true

on browseColors:paramObj
　　set aParamList to (mainDat of (paramObj as record)) as list
　　set winTitle to (myTitle of (paramObj as record)) as string
　　set subTitle to (mySubTitle of (paramObj as record)) as string
　　
　　set aLen to length of aParamList
　　
　　set aHeight to 100
　　set aWidth to 300
　　
　　–NSViewをつくる
　　set aNSV to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight * 1.5))
　　aNSV’s setNeedsDisplay:true
　　
　　— NSScroll Viewをつくる
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aScroll’s setDocumentView:aNSV
　　
　　aNSV’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aNSV’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–NSColorWell+ NSTextFieldをつくる
　　set aStep to 1
　　repeat with i in aParamList
　　　　set aColorWell to (NSColorWell’s alloc()’s initWithFrame:(current application’s NSMakeRect(10, ((aLen – aStep + 1) * 30), 60, 20)))
　　　　
　　　　set myName to (theName of i)
　　　　set myTimes to (numberOfTimes of i)
　　　　
　　　　if myName is not equal to missing value then
　　　　　　copy (myName as list) to {rNum, gNum, bNum}
　　　　　　set myTimes to numberOfTimes of i
　　　　　　
　　　　　　set myColor to makeNSColorFromRGBAval(rNum, gNum, bNum, 65535, 65535) of me
　　　　　　(aColorWell’s setColor:myColor)
　　　　　　(aColorWell’s setBordered:false)
　　　　　　(aNSV’s addSubview:aColorWell)
　　　　　　
　　　　　　set aTF to makeNSTextField(80, ((aLen – aStep + 1) * 30), 100, 20, false, myTimes as string, true, true) of me
　　　　　　(aNSV’s addSubview:aTF)
　　　　　　
　　　　　　set aStep to aStep + 1
　　　　end if
　　end repeat
　　
　　–NSScrollViewを強制的にトップにスクロール
　　set aPT to current application’s NSMakePoint(0.0, aHeight)
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:winTitle
　　　　its setInformativeText:subTitle
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
end browseColors:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeNSColorFromRGBAval(redValue as integer, greenValue as integer, blueValue as integer, alphaValue as integer, aMaxVal as integer)
　　set aRedCocoa to (redValue / aMaxVal) as real
　　set aGreenCocoa to (greenValue / aMaxVal) as real
　　set aBlueCocoa to (blueValue / aMaxVal) as real
　　set aAlphaCocoa to (alphaValue / aMaxVal) as real
　　set aColor to NSColor’s colorWithCalibratedRed:aRedCocoa green:aGreenCocoa blue:aBlueCocoa alpha:aAlphaCocoa
　　return aColor
end makeNSColorFromRGBAval

–1D Listを要素別に出現回数で集計
on countItemsByItsAppearance(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bArray to current application’s NSMutableArray’s array()
　　set theEnumerator to aSet’s objectEnumerator()
　　
　　repeat
　　　　set aValue to theEnumerator’s nextObject()
　　　　if aValue is missing value then exit repeat
　　　　bArray’s addObject:(current application’s NSDictionary’s dictionaryWithObjects:{aValue, (aSet’s countForObject:aValue)} forKeys:{"theName", "numberOfTimes"})
　　end repeat
　　
　　–出現回数（numberOfTimes）で降順ソート
　　set theDesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"numberOfTimes" ascending:false
　　bArray’s sortUsingDescriptors:{theDesc}
　　
　　return bArray as list
end countItemsByItsAppearance

★Click Here to Open This Script　

アラートダイアログ上にTextField x 2を表示 v2

Posted on 5月 2, 2019 by Takaaki Naganoya

アラートダイアログに簡易UIを実装して便利なダイアログ部品を整備する計画の一環として作成した、アラートダイアログにNSTextFieldを２つ＋ラベル用のfield２つを作成して、ユーザーからの数値入力を取得するAppleScriptです。

スクリプトエディタ、ScriptDebuggerの両方で実行できますが、Script Menuから実行するとダイアログが最前面に表示されません。Script Menuから実行する場合にはAppleScript書類の状態で呼び出すのではなく、AppleScriptアプレットに書き出して呼び出すのがよいでしょう。

macOS 10.14上では本Scriptの実行は明確にメインスレッド上で行うことを要求されます。Control-Comand-Rで実行してください。

AppleScript名：アラートダイアログ上にTextField x 2を表示 v2

— Created 2019-05-02 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSTextField : a reference to current application’s NSTextField
property NSRunningApplication : a reference to current application’s NSRunningApplication

property theResult : 0
property returnCode : 0

set paramObj to {myMessage:"Keynoteオブジェクトの２次元詰め込み", mySubMessage:"詰め込み先の矩形サイズを数値で入力してください", mes1:"幅", mes1Default:"900", mes2:"高さ", mes2Default:"500"}

set segRes to my simulateAndRetRect:paramObj
–> {a1Res:900, a2Res:500}

on simulateAndRetRect:paramObj
　　–Receive Parameters
　　set aMainMes to (myMessage of paramObj) as string –Main Message
　　set aSubMes to (mySubMessage of paramObj) as string –Sub Message
　　set mes1Label to (mes1 of paramObj) as string –Text Input field 1 Label
　　set mes2Label to (mes2 of paramObj) as string –Text Input field 2 Label
　　set aTextInputString to (mes1Default of paramObj) as string –Text Input field 1 Default value
　　set bTextInputString to (mes2Default of paramObj) as string –Text Input field 2 Default value
　　
　　— Create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 300, 60))
　　
　　— create two input field and their labels pairs
　　–NSTextFields for Input
　　set aTextInput to makeNSTextField(100, 35, 140, 20, true, (aTextInputString), true, true) of me
　　set bTextInput to makeNSTextField(100, 0, 140, 20, true, (bTextInputString), true, true) of me
　　
　　–Labels
　　set a1TF to makeNSTextField(0, 35, 100, 20, false, (mes1Label), false, false) of me
　　set a2TF to makeNSTextField(0, 0, 100, 20, false, (mes2Label), false, false) of me
　　
　　theView’s setSubviews:{a1TF, aTextInput, a2TF, bTextInput}
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set s1Val to (aTextInput’s integerValue()) as integer
　　set s2Val to (bTextInput’s integerValue()) as integer
　　
　　return {a1Res:s1Val, a2Res:s2Val}
end simulateAndRetRect:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

★Click Here to Open This Script　

アラートダイアログ上にsegmented controlを表示 v4

Posted on 3月 27, 2019 by Takaaki Naganoya

アラートダイアログ上にsegmented controlを複数表示して、複数選択項目を取得するAppleScriptです。

複数選択項目にpopup buttonではなくsegmented controlを使う必要性というのは、あんまりないですが………すべての選択項目が見える状態で少量の選択項目から１つを選ぶような用途には使えるのではないでしょうか。

segmented controlをそれぞれBoxに入れ、Viewにまとめ、Scroll viewに突っ込んでいますが、あまり効果があるんだかないんだか不明です。

AppleScript名：アラートダイアログ上にsegmented controlを表示 v4

— Created 2019-03-26 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
–Scroll Viewをつかってみた

property NSBox : a reference to current application’s NSBox
property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSScrollView : a reference to current application’s NSScrollView
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property returnCode : 0
property returnSels : {}

set paramObj to {myMessage:"複数項目選択", mySubMessage:"どれか選択してください。", segmentMes:{{"Red1", "Blue1", "Yellow1", "Brown1", "White1", "Cyan1", "Grey1"}, {"Red2", "Blue2", "Yellow2", "Brown2", "White2", "Cyan2", "Grey2"}, {"Red3", "Blue3", "Yellow3", "Brown3", "White3", "Cyan3", "Grey3"}, {"Red4", "Blue4", "Yellow4", "Brown4", "White4", "Cyan4", "Grey4"}, {"Red5", "Blue5", "Yellow5", "Brown5", "White5", "Cyan5", "Grey5"}}, segmentTitles:{"1st Segments", "2nd Segments", "3rd Segments", "4th Segments", "5th Segments"}}

my chooseMultipleSegments:paramObj

return my returnSels
–> {1, 2, 3, 4, 5}

on chooseMultipleSegments:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set segMes2DList to segmentMes of paramObj
　　set segTitleList to segmentTitles of paramObj
　　
　　set aTmpY to (length of segMes2DList) * 60
　　
　　–BoX + Segmented Control をつくる
　　set segsList to {}
　　set boxLIst to {}
　　set segsCount to 0
　　set tmpMaxX to 500
　　
　　set aCount to 1
　　
　　repeat with i in segMes2DList
　　　　set aSeg to makeSegmentedControlWithStartY(i, aTmpY – segsCount – 40, 500, 40) of me
　　　　
　　　　set aDBounds to aSeg’s |bounds|()
　　　　set tmpWidth to getWidth(aDBounds) of me
　　　　
　　　　set aBox to (NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aTmpY – segsCount – 60, 500, 60)))
　　　　(aBox’s setTitle:(item aCount of segTitleList))
　　　　(aBox’s addSubview:aSeg)
　　　　
　　　　if tmpWidth > tmpMaxX then set tmpMaxX to tmpWidth
　　　　
　　　　set the end of segsList to aSeg –選択検出用
　　　　set the end of boxLIst to aBox –表示用
　　　　
　　　　set segsCount to segsCount + 60
　　　　set aCount to aCount + 1
　　end repeat
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX, aTmpY))
　　theView’s setSubviews:boxLIst
　　
　　— create a Scroll View
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, tmpMaxX, aTmpY))
　　aScroll’s setDocumentView:theView
　　theView’s enclosingScrollView()’s setHasHorizontalScroller:false
　　theView’s enclosingScrollView()’s setHasVerticalScroller:false
　　
　　— set up alert
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScroll
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set my returnSels to {}
　　repeat with i in segsList
　　　　set tmpSegSel to (i’s selectedSegment()) as number
　　　　set the end of (my returnSels) to tmpSegSel + 1
　　end repeat
end chooseMultipleSegments:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeSegmentedControlWithStartY(titleList, aStartY, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(20, aHeight – 35, aWidth, aHeight – 40))
　　
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControlWithStartY

on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
end clickedSeg:

on getWidth(aDBounds)
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　return item 1 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　return width of |size| of aDBounds
　　end if
end getWidth

★Click Here to Open This Script　

アラートダイアログ上にBrowser＋Map Viewを表示 v2

Posted on 3月 17, 2019 by Takaaki Naganoya

ダイアログ上に表示したNSBrowserで都道府県→都道府県別データを選択し、選択したデータの位置情報をMap Viewに表示するAppleScriptの改良版です。

初版掲載時のおかしな挙動を減らし、地図種別の切り替えができるようになっています。本掲載リストだけだと動作が完結しないため、ライブラリを含んだスクリプトバンドルをダウンロードして実行してください。下記リストは「参考までに」掲載しているものです。

–> Download whole Script bundle with Library

前バージョンでは、NSBrowser上でデータが存在していない箇所に空白のセルが表示され、クリックするとクラッシュするという状態でした。本バージョンでもたまに出てくるので完全ではないのですが、

　・予想どおりデータの行数をカウントするハンドラで絞り込みを行うPredicates文の文字列に問題があった
　・データに半角のシングルクォートが入っていて、これによってデータの絞り込みに問題が出た

という問題を解消しました。前者はこまめにstringにcastし、後者は全角文字に置き換えました。

それでもまだ問題が出るケースがあるので、まだしばらく実際に使いつつ様子見といったところでしょうか。

AppleScript名：アラートダイアログ上にBrowser＋Map Viewを表示 v2.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/10
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"
use scripting additions
use skLib : script "senjoNoKizunaLib"

property NSView : a reference to current application’s NSView
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSBrowser : a reference to current application’s NSBrowser
property MKMapView : a reference to current application’s MKMapView
property NSScrollView : a reference to current application’s NSScrollView
property NSMutableArray : a reference to current application’s NSMutableArray
property MKMapTypeHybrid : a reference to current application’s MKMapTypeHybrid
property MKMapTypeSatellite : a reference to current application’s MKMapTypeSatellite
property MKMapTypeStandard : a reference to current application’s MKMapTypeStandard
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property zLevel : 17
property aMaxViewWidth : 1000
property aMaxViewHeight : 500
property theResult : 0
property returnCode : 0
property theDataSource : {}
property aSelection : {}
property aMapView : missing value
property aBrowser : missing value
property skDataList : {}

property prefList : {"北海道", "青森県", "岩手県", "宮城県", "秋田県", "山形県", "福島県", "茨城県", "栃木県", "群馬県", "埼玉県", "千葉県", "東京都", "神奈川県", "新潟県", "富山県", "石川県", "福井県", "山梨県", "長野県", "岐阜県", "静岡県", "愛知県", "三重県", "滋賀県", "京都府", "大阪府", "兵庫県", "奈良県", "和歌山県", "鳥取県", "島根県", "岡山県", "広島県", "山口県", "徳島県", "香川県", "愛媛県", "高知県", "福岡県", "佐賀県", "長崎県", "熊本県", "大分県", "宮崎県", "鹿児島県", "沖縄県"}

if my skDataList = {} then
　　set my skDataList to current application’s NSMutableArray’s arrayWithArray:(getSenjoNokizunaGameCenterDataList() of skLib)
end if

set tmpLen to length of (my skDataList as list)

set aSelection to {}

set paramObj to {myMessage:"Choose a Game Center", mySubMessage:("Choose an appropriate Game Center from list (" & tmpLen as string) & ") to play Senjo-no-Kizuna"}

my performSelectorOnMainThread:"chooseItemByBrowser:" withObject:(paramObj) waitUntilDone:true
if (my returnCode as number) = 1001 then error number -128

return my aSelection
–> {loc_id:"QIEXj9er5QSA_Y42-OjPNg", gcName:"THE 3RD PLANET ジャングルパーク鹿児島", latitude:31.5703088, longitude:130.5653137, address:"鹿児島県鹿児島市与次郎 1-11-1　フレスポジャングルパーク2F"}

on chooseItemByBrowser:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, aMaxViewHeight))
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(410, 30, aMaxViewWidth – 410, aMaxViewHeight – 30))
　　tell aMapView
　　　　its setMapType:(MKMapTypeStandard)
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　its setDelegate:me
　　end tell
　　
　　— make browser view with scroll view
　　set aScrollWithTable to makeBrowserView(prefList, 400, aMaxViewHeight) of me
　　
　　–Segmented Controlをつくる
　　set segTitleList to {"Map", "Satellite", "Satellite + Map"}
　　set aSeg to makeSegmentedControl(segTitleList, 410, 0, 150, 20) of me
　　
　　–Compose Views in NSView
　　theView’s setSubviews:{aScrollWithTable, aMapView, aSeg}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
end chooseItemByBrowser:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeBrowserView(aList as list, aWidth as number, aHeight as number)
　　set (my theDataSource) to NSMutableArray’s arrayWithArray:aList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aBrowser to NSBrowser’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　aBrowser’s setDelegate:(me)
　　aBrowser’s setTarget:(me)
　　aBrowser’s setAction:"browserCellSelected:"
　　aBrowser’s setMinColumnWidth:120
　　aBrowser’s setSeparatesColumns:true
　　aBrowser’s setMaxVisibleColumns:2
　　aBrowser’s setAutohidesScroller:true
　　aBrowser’s setTakesTitleFromPreviousColumn:true
　　–aBrowser’s setBackgroundColor:(NSColor’s grayColor())
　　
　　aScroll’s setDocumentView:aBrowser
　　aBrowser’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aBrowser’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　return aScroll
end makeBrowserView

–NSBrowser Event Handlers
on browser:aView numberOfRowsInColumn:aColumn
　　if aColumn = 0 then
　　　　return my theDataSource’s |count|()
　　else if aColumn = 1 then
　　　　set aPath to (text 2 thru -1 of ((aView’s |path|()) as string)) as string –ここが問題だったもよう
　　　　set tmpArray to (my filterRecListByLabel1(skDataList, "address BEGINSWITH ’" & aPath & "’")) as list
　　　　return (length of tmpArray)
　　else
　　　　return 0
　　end if
end browser:numberOfRowsInColumn:

on browser:aView willDisplayCell:(aCell) atRow:(rowIndex as integer) column:(colIndex as integer)
　　if colIndex = 0 then
　　　　–Prefectures
　　　　aCell’s setTitle:((item (rowIndex + 1) of prefList) as string)
　　　　aCell’s setLeaf:false
　　　　
　　else if colIndex = 1 then
　　　　–Each Game Centers in the Prefecture
　　　　set aPath to text 2 thru -1 of ((aView’s |path|()) as string)
　　　　set tmpArray to my filterRecListByLabel1(skDataList, "address BEGINSWITH ’" & aPath & "’")
　　　　set tmpItem to (tmpArray’s objectAtIndex:rowIndex)
　　　　
　　　　set aGameCenterName to (tmpItem’s gcName) as string
　　　　aCell’s setTitle:(aGameCenterName)
　　　　aCell’s setLeaf:true
　　　　
　　else if colIndex ≥ 2 then
　　　　error "Wrong NSBrowser status"
　　end if
end browser:willDisplayCell:atRow:column:

on browserCellSelected:aSender
　　set aPath to my aBrowser’s |path|()
　　set aList to (aPath’s pathComponents()) as list
　　set aLen to length of aList
　　
　　if aLen = 3 then
　　　　–set aPref to contents of item 2 of aList
　　　　set aGc to contents of last item of aList
　　　　
　　　　set tmpArray to my filterRecListByLabel1(skDataList, "gcName == ’" & aGc & "’")
　　　　–set tmpArray to my filterRecListByLabel1(skDataList, "gcName == " & aGc)
　　　　set tmpItem to contents of first item of (tmpArray as list)
　　　　
　　　　copy tmpItem to my aSelection
　　　　
　　　　set aLatitude to (latitude of tmpItem) as real
　　　　set aLongitude to (longitude of tmpItem) as real
　　　　
　　　　tell aMapView
　　　　　　set aLocation to current application’s CLLocationCoordinate2DMake(aLatitude, aLongitude)
　　　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　end tell
　　　　
　　end if
end browserCellSelected:

–NSArrayに入れたNSDictionaryを、指定の属性ラベルの値で抽出
on filterRecListByLabel1(aRecList, aPredicate as string)
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat:aPredicate
　　set filteredArray to aRecList’s filteredArrayUsingPredicate:aPredicate
　　return filteredArray
end filterRecListByLabel1

–Segmented Controlをつくる
on makeSegmentedControl(titleList, startX, startY, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(startX, startY, aWidth, aHeight))
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControl

–Segmented Controlのクリック時のイベントハンドラ
on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
　　set tList to {MKMapTypeStandard, MKMapTypeSatellite, MKMapTypeHybrid}
　　set tmpType to contents of item (aSel + 1) of tList
　　
　　aMapView’s setMapType:(tmpType)
　　
　　set selSeg to aSel
end clickedSeg:

★Click Here to Open This Script　

アラートダイアログ上にBrowser＋Map Viewを表示

Posted on 3月 12, 2019 by Takaaki Naganoya

ダイアログ上に表示したNSBrowserで都道府県→都道府県別データを選択し、選択したデータの位置情報をMap Viewに表示するAppleScriptです。

＃　2021年11月末にアーケードゲーム「戦場の絆」のサービスが終了したため、Webサイト側からデータ取得する部分の処理は動作しません（Webサイトごとアクセスできなくなったため）

▲macOS 10.12.6上で動作

「OK」ボタンをクリックすると選択したゲームセンターの諸元情報を返してきます。リスト一覧から名称を選択し、途中でその位置情報を地図で見られるという程度のインタフェースです。

NSBrowserを利用したUIの習作で、Web上の「戦場の絆」公式ページから導入店舗の情報を取得し（このあたりライブラリにまとめて部品化）、データを都道府県別にしぼりこんでNSBrowser上で選択できるようにしてみました。

▲macOS 10.13.6上で動作

▲macOS 10.14.4上で動作（Light Mode）

▲macOS 10.14.4上で動作（Dark Mode）

ぱっと見は「何かすごいもの」に見えるのですが、キーワード検索が実装されていないため、データしぼりこみに柔軟性がないと感じるものです。

NSBrowserをAppleScriptから利用した場合に、Xcodeを利用しないとこのレベルの単純なデータ階層固定でデータしぼりこみを行う程度のものしか作りにくいところでしょうか。不可能とは言わないものの、「普通にXcode上で作れば？」という話になると思います。

さらに、該当するカラムの行数を返すハンドラでデータをしぼりこんでレコード数を返しているものの、いまひとつここがうまく動いていない印象を受けます。NSBrowser上で「存在しないデータのような何か」をクリックできるケースがあり、それをクリックすると実行環境（スクリプトエディタとか、Script Debuggerとか）ごとクラッシュします。

→　原因がわかりました。問題箇所も想像どおり。目下、修正版で謎のゴースト行も出てこなくなったので、あとで修正版を掲載しておきます。問題が２つあって、１つがPredicates文をas stringですべてcastしていなかった件、もうひとつは、、、副次的に発生した問題で、愛知県のデータに「M’s」という半角クォート文字を含むものがあって、これでPredicates文が中断されてしまった問題。半角シングルクォートを全角に置き換えるとかいろいろ手を加える必要がありました。

本Script全体をダウンロードして、スクリプトエディタ上で実行すると、最初に「戦場の絆」公式ホームページの日本国内の店舗情報をスキャンして店舗情報を抽出するため、サーバーの混雑具合やネットワーク回線速度にも左右されますが、自分の環境では5〜15秒程度でデータの取得が終了し、ダイアログが表示されます。

–> Download whole Script bundle with Library

AppleScript名：アラートダイアログ上にBrowser＋Map Viewを表示.scptd

if my skDataList = {} then
　　set my skDataList to current application’s NSMutableArray’s arrayWithArray:(getSenjoNokizunaGameCenterDataList() of skLib)
end if

set aSelection to {}

set paramObj to {myMessage:"Choose a Game Center", mySubMessage:"Choose an appropriate Game Center from list to play Senjo-no-Kizuna"}

my performSelectorOnMainThread:"chooseItemByBrowser:" withObject:(paramObj) waitUntilDone:true
return my aSelection
–> {loc_id:"QIEXj9er5QSA_Y42-OjPNg", gcName:"THE 3RD PLANET ジャングルパーク鹿児島", latitude:31.5703088, longitude:130.5653137, address:"鹿児島県鹿児島市与次郎 1-11-1　フレスポジャングルパーク2F"}

on chooseItemByBrowser:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, aMaxViewHeight))
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(410, 0, aMaxViewWidth – 410, aMaxViewHeight))
　　tell aMapView
　　　　its setMapType:(MKMapTypeStandard)
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　its setDelegate:me
　　end tell
　　
　　— make browser view with scroll view
　　set aScrollWithTable to makeBrowserView(prefList, 400, aMaxViewHeight) of me
　　
　　–Compose Views in NSView
　　theView’s setSubviews:{aScrollWithTable, aMapView}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end chooseItemByBrowser:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–NSBrowser Event Handlers
–ここ、いまひとつきちんと動いていないかも？？？
on browser:aView numberOfRowsInColumn:aColumn
　　if aColumn = 0 then
　　　　return my theDataSource’s |count|()
　　else if aColumn = 1 then
　　　　set aPath to text 2 thru -1 of ((aView’s |path|()) as string)
　　　　set tmpArray to (my filterRecListByLabel1(skDataList, "address BEGINSWITH ’" & aPath & "’")) as list
　　　　return (length of tmpArray)
　　end if
end browser:numberOfRowsInColumn:

on browserCellSelected:aSender
　　set aPath to my aBrowser’s |path|()
　　set aList to (aPath’s pathComponents()) as list
　　set aLen to length of aList
　　
　　if aLen = 3 then
　　　　–set aPref to contents of item 2 of aList
　　　　set aGc to contents of last item of aList
　　　　
　　　　set tmpArray to my filterRecListByLabel1(skDataList, "gcName == ’" & aGc & "’")
　　　　set tmpItem to contents of first item of (tmpArray as list)
　　　　
　　　　copy tmpItem to my aSelection
　　　　
　　　　set aLatitude to (latitude of tmpItem) as real
　　　　set aLongitude to (longitude of tmpItem) as real
　　　　
　　　　tell aMapView
　　　　　　set aLocation to current application’s CLLocationCoordinate2DMake(aLatitude, aLongitude)
　　　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　end tell
　　　　
　　end if
end browserCellSelected:

★Click Here to Open This Script　

アラートダイアログ上に複数のNSBoxを作成してMKMapViewを表示

Posted on 3月 11, 2019 by Takaaki Naganoya

指定されたIPアドレスの位置情報（geo location）を検索して、アラートダイアログ上に拡大レベルの異なる４つの地図を表示するAppleScriptです。

IP Goecodingのサービスはipinfo.ioを利用しています。ただ、この手のサービスは入れ替わりが激しいので、長期的に使い続けられることを期待できないと感じています（有償サービスは別）。

このズームレベルが異なる地図の同時表示Viewは、作成したときには「これは画期的！」「ものすごく使いやすい！」と、狂喜乱舞したものですが、他のユーザーに見せてデモしたら、

「実際には限定されたエリア内の位置データを見ることが多いので、World LevelとかCountry Levelのビューは無駄なことが多い」
「地球を侵略しに来た異星人には向いているが、地球人向けには冗長」

といった意見が多く、オクラ入りしていました。アラートダイアログでさまざまなデータを可視化する部品の整備計画時に倉庫から引っ張り出されてきたものです。

唯一、IPアドレスという「見ただけではどこの国のものだかわからない」（Class AのIPは別。17.のAppleとか）データを可視化するときにはバッチリ合っています。

macOS 10.12〜10.14で確認していますが、唯一、macOS 10.14.4上では初期状態でピンが表示されません。ピン自体は存在しているので、地図表示タイプを変更すると表示されるのですが、一体これはどうしたものか。仕様なのかバグなのかわかりません。

▲なぜか本Blogにロス市警からのアクセスが（汗）

▲macOS 10.12.6 Map

▲macOS 10.12.6 Satellite

▲macOS 10.12.6 Map + Satellite

▲macOS 10.13.6 Map

▲macOS 10.14.4 Map (Light Mode)

▲macOS 10.14.4 Map (Dark Mode)

AppleScript名：アラートダイアログ上に複数のNSBoxを作成してMKMapViewを表示

— Created 2019-03-11 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"
use framework "CoreLocation"

property NSAlert : a reference to current application’s NSAlert
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property MKMapView : a reference to current application’s MKMapView
property MKMapTypeHybrid : a reference to current application’s MKMapTypeHybrid
property MKPointAnnotation : a reference to current application’s MKPointAnnotation
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property MKMapTypeSatellite : a reference to current application’s MKMapTypeSatellite
property MKMapTypeStandard : a reference to current application’s MKMapTypeStandard
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property windisp : false
property selSeg : 0
property aMapViewList : {}

property segTitleList : {"Map", "Satellite", "Satellite + Map"}

property returnCode : 0

set aClip to the clipboard –このへんてきとう
set anIP to text returned of (display dialog "Input IP address to find its location" default answer aClip)

set windisp to false
set geoInfo to getGeoLocationByIPinfo(anIP) of me
if geoInfo = missing value then
　　error "Network Error"
end if

set aInfo to loc of geoInfo

set aPos to offset of "," in aInfo
set aLatitude to text 1 thru (aPos – 1) of aInfo
set aLongitude to text (aPos + 1) thru -1 of aInfo

set aWidth to 1000
set aHeight to 600

set aButtonMSG to "OK"
set aMapViewList to {}

set paramObj to {viewWidth:aWidth, viewHeight:aHeight, viewTitle:anIP, viewSubTitle:"IP-Geocoding Service by ipinfo.io", viewLat:aLatitude, viewLong:aLongitude}

my performSelectorOnMainThread:"dispMapViewinDifferentScales:" withObject:(paramObj) waitUntilDone:true

on dispMapViewinDifferentScales:paramObj
　　set aWidth to (viewWidth of paramObj) as real
　　set aHeight to (viewHeight of paramObj) as real
　　set aLat to (viewLat of paramObj) as real
　　set aLong to (viewLong of paramObj) as real
　　set aTitle to (viewTitle of paramObj) as string
　　set aSubTitle to (viewSubTitle of paramObj) as string
　　
　　set selSeg to 0
　　
　　–NSViewをつくる
　　set aView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　–各レベルのMapViewをBoxでつくる
　　set wList to {{3, "🌏World Level Map"}, {5, "🏰Country Level Map"}, {10, "🏢City Level Map"}, {17, "🏠Town Level Map"}}
　　set xPos to 0
　　repeat with i in wList
　　　　copy i to {aLevelNum, aBoxTitle}
　　　　
　　　　–Boxをつくる
　　　　set aBox to (current application’s NSBox’s alloc()’s initWithFrame:(current application’s NSMakeRect(xPos, 40, aWidth * 0.25, aHeight – 70)))
　　　　(aBox’s setTitle:aBoxTitle)
　　　　
　　　　–MapView＋Pinをつくる
　　　　set aMapView to makeMKMapView(aWidth * 0.25, aHeight – 70, aLevelNum, aLat, aLong, aTitle) of me
　　　　
　　　　(aBox’s addSubview:aMapView)
　　　　(aView’s addSubview:aBox)
　　　　
　　　　set the end of aMapViewList to aMapView
　　　　set xPos to xPos + (aWidth * 0.25)
　　end repeat
　　
　　–Segmented Controlをつくる
　　set aSeg to makeSegmentedControl(segTitleList, aWidth, aHeight) of me
　　aView’s addSubview:aSeg
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aTitle
　　　　its setInformativeText:aSubTitle
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end dispMapViewinDifferentScales:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

–MKMapViewをつくる
on makeMKMapView(aWidth, aHeight, aZoomLevel, aLat, aLong, aTitle)
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　aMapView’s setMapType:(current application’s MKMapTypeStandard)
　　
　　aMapView’s setZoomEnabled:true
　　aMapView’s setScrollEnabled:true
　　aMapView’s setPitchEnabled:false
　　aMapView’s setRotateEnabled:false
　　aMapView’s setShowsCompass:true
　　aMapView’s setShowsZoomControls:true
　　aMapView’s setShowsScale:true
　　aMapView’s setShowsUserLocation:true
　　
　　set aLocation to current application’s CLLocationCoordinate2DMake(aLat, aLong)
　　aMapView’s setCenterCoordinate:aLocation zoomLevel:aZoomLevel animated:false
　　aMapView’s setDelegate:me
　　
　　–MapにPinを追加
　　set anAnnotation to current application’s MKPointAnnotation’s alloc()’s init()
　　anAnnotation’s setCoordinate:aLocation
　　anAnnotation’s setTitle:aTitle
　　aMapView’s addAnnotation:anAnnotation
　　
　　return aMapView
end makeMKMapView

–Make Segmented Control
on makeSegmentedControl(titleList, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(10, 5, 260, 30))
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControl

–Segmented Control’s clicked event handler
on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
　　set selSeg to (aSel + 1)
　　set mapList to {MKMapTypeStandard, MKMapTypeSatellite, MKMapTypeHybrid}
　　set curMap to contents of item selSeg of mapList
　　
　　repeat with i in aMapViewList
　　　　set aView to contents of i
　　　　(aView’s setMapType:(curMap))
　　end repeat
end clickedSeg:

–http://ipinfo.io/developers
on getGeoLocationByIPinfo(myIP)
　　set aURL to "http://ipinfo.io/" & myIP
　　set aRes to callRestGETAPIAndParseResults(aURL, 10) of me
　　return aRes as record
end getGeoLocationByIPinfo

on callRestGETAPIAndParseResults(reqURLStr as string, timeoutSec as integer)
　　set tmpData to (do shell script "curl -X GET ＼"" & reqURLStr & "＼"")
　　set jsonString to NSString’s stringWithString:tmpData
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　if aJsonDict = missing value then return false
　　return (aJsonDict as record)
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

アラートダイアログ上にWebViewを表示

Posted on 3月 5, 2019 by Takaaki Naganoya

アラートダイアログ上にWKWebViewを表示するAppleScriptです。

テストのためにYouTubeのムービーの自動再生URL（戦場の絆のリプレイムービー）をオープンしています。

▲Table ViewとWeb Viewを組み合わせて、所定の場所にYouTubeムービーの頭出しを行う試作品を作ってみたものの、JavaScript経由でWKWebViewをコントロールするのが難しくて頓挫

本来であれば、WkWebViewに対してJavaScript経由でさまざまな操作を行いたいところですが、オープン中のWebコンテンツに対して新たなJavaScriptのインスタンスを生成してセキュリティチェックを行なって、実際に実行を行うのが（自分には）少々難しく感じました。WkWebViewだとあまり凝った制御はできない印象です。Safariをコントロールするほうが自由度が高いところ。

WkWebViewを「自由にこづきまわして操作できる部品」として使うためには、素のままのWkWebViewではない何かを使ったほうがいいのかも？

AppleScript名：アラートダイアログ上にWebViewを表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/02
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use framework "WebKit"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSString : a reference to current application’s NSString
property NSScreen : a reference to current application’s NSScreen
property NSButton : a reference to current application’s NSButton
property WKWebView : a reference to current application’s WKWebView
property NSScrollView : a reference to current application’s NSScrollView
property WKUserScript : a reference to current application’s WKUserScript
property NSURLRequest : a reference to current application’s NSURLRequest
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSBackingStoreBuffered : a reference to current application’s NSBackingStoreBuffered
property WKUserContentController : a reference to current application’s WKUserContentController
property NSMomentaryLightButton : a reference to current application’s NSMomentaryLightButton
property WKWebViewConfiguration : a reference to current application’s WKWebViewConfiguration
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property WKUserScriptInjectionTimeAtDocumentEnd : a reference to current application’s WKUserScriptInjectionTimeAtDocumentEnd

property theResult : 0
property returnCode : 0
property theDataSource : {}

set aURL to "https://www.youtube.com/embed/GP_tVXTYdmY?autoplay=1&hd=1"
set paramObj to {myMessage:"Browse a Replay", mySubMessage:"Browse Senjo-No-Kizuna Replay Movie", targURL:aURL}
my performSelectorOnMainThread:"browseWebContents:" withObject:(paramObj) waitUntilDone:true

on browseWebContents:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set tmpURL to (targURL of paramObj)
　　
　　set aWidth to 600
　　set aHeight to 450
　　
　　–WebViewをつくる
　　set aConf to WKWebViewConfiguration’s alloc()’s init()
　　
　　–指定URLのJavaScriptをFetch
　　set jsSource to my fetchJSSourceString(tmpURL)
　　set userScript to WKUserScript’s alloc()’s initWithSource:jsSource injectionTime:(WKUserScriptInjectionTimeAtDocumentEnd) forMainFrameOnly:true
　　set userContentController to WKUserContentController’s alloc()’s init()
　　userContentController’s addUserScript:(userScript)
　　aConf’s setUserContentController:userContentController
　　
　　set aWebView to WKWebView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight – 100)) configuration:aConf
　　aWebView’s setNavigationDelegate:me
　　aWebView’s setUIDelegate:me
　　aWebView’s setTranslatesAutoresizingMaskIntoConstraints:true
　　
　　set bURL to |NSURL|’s URLWithString:tmpURL
　　set aReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:aReq –Webコンテンツのローディング
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aWebView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　–Stop Web View Action
　　set bURL to |NSURL|’s URLWithString:"about:blank"
　　set bReq to NSURLRequest’s requestWithURL:bURL
　　aWebView’s loadRequest:bReq
　　
　　if (my returnCode as number) = 1001 then error number -128
end browseWebContents:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on viewDidLoad:aNotification
　　return true
end viewDidLoad:

on fetchJSSourceString(aURL)
　　set jsURL to |NSURL|’s URLWithString:aURL
　　set jsSourceString to NSString’s stringWithContentsOfURL:jsURL encoding:(NSUTF8StringEncoding) |error|:(missing value)
　　return jsSourceString
end fetchJSSourceString

★Click Here to Open This Script　

アラートダイアログ上に縦棒グラフを表示

Posted on 3月 4, 2019 by Takaaki Naganoya

アラートダイアログ上に縦棒グラフを表示するAppleScriptです。

グラフを作成するのであれば、NumbersやKeynoteなどを使ったほうがいいですが、簡単にデータの傾向だけダイアログ上で見せたいような場合のために作成した部品です。

NSImageViewの表示実験がしたかっただけなので、別に他の言語処理系で作成したグラフ画像を読み込んでNSImageに読み込んでからNSIMageViewで表示するぐらいの使い方でもぜんぜんOKでしょう。

WebViewを表示してインタラクティブなグラフ（マウスカーソルに反応してアニメーション表示を行うとか）を表示するといった使い方もよさそうです（アプリケーション化しないとダメかも）。

macOS 10.14上のDark Modeについては、実行環境によって対応度が異なります。

▲macOS 10.14上のDark Modeで実行したところ。左側からスクリプトエディタ、AppleScriptアプレット、スクリプトメニュー

▲macOS 10.14上のDark Modeで実行したところ。左側からScript Debugger、Script DebuggerからSD拡張アプレットで書き出したもの

グラフの描画については、色指定をblackColor()とかgrayColor()などと指定せずに、Dark Mode時に制御されるUI色で指定しておく必要があることでしょう。

AppleScript名：アラートダイアログ上に縦棒グラフを表示.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2019/03/04
—
–　　Copyright © 2019 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSFont : a reference to current application’s NSFont
property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSScreen : a reference to current application’s NSScreen
property NSDictionary : a reference to current application’s NSDictionary
property NSBezierPath : a reference to current application’s NSBezierPath
property NSImageView : a reference to current application’s NSImageView
property NSMutableArray : a reference to current application’s NSMutableArray
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName
property NSImageScaleProportionallyUpOrDown : a reference to current application’s NSImageScaleProportionallyUpOrDown

property returnCode : 0

set plotData to {20, 30, 100, 80, 150, 90}
set paramObj to {myMessage:"This is a graph", mySubMessage:"Browse bar graph", aPlotData:plotData}
my performSelectorOnMainThread:"displayBarGraph:" withObject:(paramObj) waitUntilDone:true

on displayBarGraph:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aPlotData of paramObj) as list
　　
　　— make NSIMageView with graph image
　　set anImage to makeGraphImage(aTList, 300, 200) of me
　　set anImageView to NSImageView’s alloc()’s initWithFrame:{origin:{x:0.0, y:0.0}, |size|:{width:300.0, height:200.0}}
　　anImageView’s setImageScaling:(NSImageScaleProportionallyUpOrDown)
　　anImageView’s setEditable:false
　　anImageView’s setImage:anImage
　　anImageView’s display()
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:anImageView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end displayBarGraph:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeGraphImage(plotData, aWidth, aHeight)
　　set innerGapL to 30
　　set innerGapU to 10
　　set innerGapR to 20
　　set innerGapD to 20
　　set barGap to 10
　　
　　–パラメータから下地になる画像を作成する
　　set aSize to current application’s NSMakeSize(aWidth, aHeight)
　　set anImage to NSImage’s alloc()’s initWithSize:aSize
　　
　　–各種パラメータの計算
　　–copy plotArea to {plotWidth, plotHeight}
　　set itemNum to count every item of plotData
　　set barThickness to (aWidth – (itemNum * barGap * 2)) div itemNum
　　
　　–プロットデータの最大値
　　set anArray to NSArray’s arrayWithArray:plotData
　　set aYmax to (anArray’s valueForKeyPath:"@max.self")’s intValue()
　　set aMaxYVal to aHeight – innerGapU – innerGapD
　　set aYPlotArea to aHeight – innerGapU – innerGapD – 20
　　set aYUnit to aYPlotArea / aYmax
　　
　　–数値データをもとに描画データを組み立てる
　　set drawList to {}
　　
　　set startX to innerGapL
　　copy startX to origX
　　
　　repeat with i in plotData
　　　　set the end of drawList to current application’s NSMakeRect(startX, innerGapD, barThickness, innerGapD + (i * aYUnit))
　　　　set startX to startX + barThickness + barGap
　　end repeat
　　
　　–グラフ塗りつぶし処理呼び出し
　　set fillColor to (NSColor’s colorWithCalibratedRed:0.1 green:0.1 blue:0.1 alpha:0.3)
　　set resImage to drawImageWithColorFill(anImage, drawList, fillColor) of me
　　
　　–数値データ（文字）をグラフィックに記入
　　set fillColor2 to NSColor’s blackColor()
　　set resImage to drawImageWithString(resImage, drawList, fillColor2, plotData, "Eurostile Bold", 20.0) of me
　　
　　–補助線を引く
　　set fillColor3 to (NSColor’s colorWithCalibratedRed:0.0 green:0.0 blue:0.0 alpha:0.8)
　　set aVertical to current application’s NSMakeRect(origX, innerGapD, aWidth – innerGapL – innerGapR, 1)
　　set aHorizontal to current application’s NSMakeRect(origX, innerGapD, 1, aHeight – innerGapU – innerGapD)
　　set draw2List to {aVertical, aHorizontal}
　　set resImage to drawImageWithColorFill(resImage, draw2List, fillColor3) of me
　　
　　return resImage
end makeGraphImage

–NSImageに対して文字を描画する
on drawImageWithString(anImage, drawList, fillColor, dataList, aPSFontName, aFontSize)
　　set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
　　–>　　2.0 (Retina) / 1.0 (Non Retina)
　　
　　set aDict to (NSDictionary’s dictionaryWithObjects:{NSFont’s fontWithName:aPSFontName |size|:aFontSize, fillColor} forKeys:{NSFontAttributeName, NSForegroundColorAttributeName})
　　
　　anImage’s lockFocus() –描画開始
　　
　　set aLen to length of drawList
　　repeat with i from 1 to aLen
　　　　set i1 to contents of item i of drawList
　　　　
　　　　set v2 to system attribute "sys2"
　　　　if v2 ≤ 12 then
　　　　　　–To macOS 10.12.x
　　　　　　set origX to (x of origin of i1) / retinaF
　　　　　　set origY to (y of origin of i1) / retinaF
　　　　　　set sizeX to (width of |size| of i1) / retinaF
　　　　　　set sizeY to (height of |size| of i1) / retinaF
　　　　　　set theRect to {{x:origX, y:origY}, {width:sizeX, height:sizeY}}
　　　　else
　　　　　　–macOS 10.13 or later
　　　　　　set origX to (item 1 of item 1 of i1) / retinaF
　　　　　　set origY to (item 2 of item 1 of i1) / retinaF
　　　　　　set sizeX to (item 1 of item 2 of i1) / retinaF
　　　　　　set sizeY to (item 2 of item 2 of i1) / retinaF
　　　　　　set theRect to {{origX, origY}, {sizeX, sizeY}}
　　　　end if
　　　　
　　　　set aString to (current application’s NSString’s stringWithString:((contents of item i of dataList) as string))
　　　　(aString’s drawAtPoint:(current application’s NSMakePoint(origX + (sizeX / 2), sizeY)) withAttributes:aDict)
　　end repeat
　　
　　anImage’s unlockFocus() –描画ここまで
　　
　　return anImage –returns NSImage
end drawImageWithString

–NSImageに対して矩形を塗りつぶす
on drawImageWithColorFill(anImage, drawList, fillColor)
　　set retinaF to (NSScreen’s mainScreen()’s backingScaleFactor()) as real
　　–>　　2.0 (Retina) / 1.0 (Non Retina)
　　
　　anImage’s lockFocus() –描画開始
　　
　　repeat with i in drawList
　　　　set v2 to system attribute "sys2"
　　　　if v2 ≤ 12 then
　　　　　　–To macOS 10.12.x
　　　　　　set origX to (x of origin of i) / retinaF
　　　　　　set origY to (y of origin of i) / retinaF
　　　　　　set sizeX to (width of |size| of i) / retinaF
　　　　　　set sizeY to (height of |size| of i) / retinaF
　　　　　　set theRect to {{x:origX, y:origY}, {width:sizeX, height:sizeY}}
　　　　else
　　　　　　–macOS 10.13 or later
　　　　　　set origX to (item 1 of item 1 of i) / retinaF
　　　　　　set origY to (item 2 of item 1 of i) / retinaF
　　　　　　set sizeX to (item 1 of item 2 of i) / retinaF
　　　　　　set sizeY to (item 2 of item 2 of i) / retinaF
　　　　　　set theRect to {{origX, origY}, {sizeX, sizeY}}
　　　　end if
　　　　
　　　　set theNSBezierPath to NSBezierPath’s bezierPath
　　　　(theNSBezierPath’s appendBezierPathWithRect:theRect)
　　　　
　　　　fillColor’s |set|() –色設定
　　　　theNSBezierPath’s fill() –ぬりつぶし
　　end repeat
　　
　　anImage’s unlockFocus() –描画ここまで
　　
　　return anImage –returns NSImage
end drawImageWithColorFill

★Click Here to Open This Script　

アラートダイアログ上にBrowserを表示

Posted on 3月 2, 2019 by Takaaki Naganoya

アラートダイアログ上にNSBrowserを表示するAppleScriptの試作品です。

＃　本Scriptは実験用であって実用性はありません（＾ー＾；；

Finderに使われていることで認知度は高いものの、使いどころが難しいうえにサンプル・コードも多くないので登場頻度が少ないNSBrowserです。（Mac OS Xの前身である）NEXTSTEPのFile Managerがこんな感じのUIでした。

（個人的に）敷居の高かったNSBrowserも、いろいろ試してみたらいい感じになってきました。現状では単に２次元配列っぽいものにアクセスしているだけですが、ツリー型の構造データを与えるようにするとか、配列から徐々にデータ抽出する（大分類→中分類→小分類）ようにすれば、だいたい期待どおりの動作になるはずです。

NSBrowserも、使いたいときに調べると情報が見つからずに困りますが、用のないときなら調べておくといろいろ大丈夫そうです。

macOS 10.14上のスクリプトエディタ/Script Debugger上で動くようにハンドラをメインスレッド上で明示的に動作させるように変更しましたが、10.14上でだけ独特な挙動があるため要注意です。ただ、テストプログラムなのでそんなものだろうかと。

AppleScript名：アラートダイアログ上にBrowserを表示 v1.1.scptd

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSBrowser : a reference to current application’s NSBrowser
property NSScrollView : a reference to current application’s NSScrollView
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

set paramObj to {myMessage:"Choose a data", mySubMessage:"Choose an appropriate data from tree structured data list", aTableList:{{"1", "1.1", "1.1.1"}, {"2", "2.1", "2.1.1"}, {"3", "3.1", "3.1.1"}, {"4", "4.1", "4.1.1"}}}
–set aRes to my chooseItemByBrowser:paramObj
my performSelectorOnMainThread:"chooseItemByBrowser:" withObject:(paramObj) waitUntilDone:true

on chooseItemByBrowser:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　— make browser view with scroll view
　　set aScrollWithTable to makeBrowserView(aTList, 500, 200) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
end chooseItemByBrowser:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeBrowserView(aList as list, aWidth as number, aHeight as number)
　　set (my theDataSource) to NSMutableArray’s arrayWithArray:aList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　set aView to NSBrowser’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aWidth, aHeight))
　　
　　aView’s setDelegate:(me)
　　aView’s setMinColumnWidth:120
　　aView’s setSeparatesColumns:true
　　–aView’s setMaxVisibleColumns:2
　　aView’s setAutohidesScroller:true
　　–aView’s setBackgroundColor:(NSColor’s grayColor())
　　aView’s setReusesColumns:true
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasHorizontalScroller:true
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　return aScroll
end makeBrowserView

–NSBrowser Event Handlers
on browser:aView numberOfRowsInColumn:aColumn
　　set aCount to my theDataSource’s |count|()
　　return aCount
end browser:numberOfRowsInColumn:

on browser:aView willDisplayCell:(aCell) atRow:rowIndex column:colIndex
　　set selRow to (my theDataSource)’s objectAtIndex:(rowIndex)
　　set selCol to selRow’s objectAtIndex:(colIndex)
　　aCell’s setTitle:(selCol as string)
　　
　　set colMax to ((my theDataSource)’s objectAtIndex:0)’s |count|()
　　log {"colMax, colIndex", colMax, colIndex}
　　set exMax to (colIndex < colMax – 1) as boolean
　　aCell’s setLeaf:(not exMax)
end browser:willDisplayCell:atRow:column:

★Click Here to Open This Script　

アラートダイアログの背景色を指定してTable Viewを表示

Posted on 2月 25, 2019 by Takaaki Naganoya

指定色のアラートダイアログを作成し、その上にScroll View＋Table Viewを表示して選択肢の選択を行うAppleScriptです。

アラートダイアログの背景色変更のテストを行なったものです。また、メソッド名をテキストで（Table Viewから）取得し、そのメソッド名で色を作成するテスト（NSSelectorFromString）も行いました。

Table Viewで選択した色は、次回実行時に反映されます（スクリプトエディタ/Script Debugger上で）。

本当はTable View上で行を選択したときに、アラートダイアログの背景色を変更させたかったのですが、試してみたもののうまく動かなかったので、その機能は削りました。最初から指定色のダイアログウィンドウを表示するだけなら問題はないので、現状のようなコードに落ち着きました。

AppleScript名：アラートダイアログの背景色を指定してTable Viewを表示

— Created 2019-02-25 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSColor : a reference to current application’s NSColor
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSFullSizeContentViewWindowMask : a reference to current application’s NSFullSizeContentViewWindowMask

property theResult : 0
property returnCode : 0
property theDataSource : {}
property theColList : {}
property theWindow : missing value
property selectedColor : missing value

set paramObj to {myMessage:"Choose a color", mySubMessage:"Choose an appropriate color from color name list", aTableList:{"redColor", "blueColor", "yellowColor", "greenColor", "grayColor", "blackColor"}}
set aRes to my chooseItemByTableView:paramObj

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(aTList, 300, 120) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— customize alert’s window style and color
　　if selectedColor = missing value then
　　　　set tmpColor to NSColor’s grayColor()
　　else
　　　　set tmpSel to current application’s NSSelectorFromString(selectedColor)
　　　　set tmpColor to NSColor’s performSelector:tmpSel
　　end if
　　
　　set theWindow to theAlert’s |window|()
　　theWindow’s setTitleVisibility:false
　　–theWindow’s setStyleMask:( NSFullSizeContentViewWindowMask)
　　theWindow’s setTitlebarAppearsTransparent:true
　　theWindow’s setBackgroundColor:tmpColor
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　return (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 40
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set selRow to (aRow as number)
　　set aRec to (my theDataSource)’s objectAtIndex:selRow
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle) as string
　　set my selectedColor to aRes
　　
　　return aRes
end tableView:objectValueForTableColumn:row:

on tableView:aView shouldEditTableColumn:aTableColumn row:rowIndex
　　return false –Not Editable
end tableView:shouldEditTableColumn:row:

★Click Here to Open This Script　

アラートダイアログ上にTable View＋Map View＋Segmented Controlを表示

Posted on 2月 23, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にScroll View＋Table ViewおよびMap Viewを表示して選択肢の選択を行うAppleScriptです。Segmented Controlで地図の種別切り替えを行い、項目選択用のTable Viewを編集不可にしました。

Map Viewを使用するために、インターネット接続が必要です。地図表示パフォーマンスはインターネット接続速度次第です。

▲Map Type = Standard (Map)

▲Map Type = Satellite

▲Map Type = Hybrid (Satellite + Map)

本Scriptに与える緯度・経度情報についてはあらかじめ住所ジオコーダーによって「住所情報→緯度・経度情報」の変換を行なったものを書いておく必要がありますが、Yahoo!の住所ジオコーダーサービスなどを呼び出せば、住所情報をパラメーターとすることも可能です。

サンプルデータの緯度・経度情報は、例によって「戦場の絆」の入っている近所のゲーセンの情報を適当にみつくろって入れてみたものです。

本ダイアログは、それほど件数の多くない（20件ぐらい？）選択肢からの選択を意図して作ったものですが、数百件とか数千件のデータから選ぶような場合には、Outline Viewを利用して小エリアごとに分割するとか、Search Fieldを連動させてキーワードによる絞り込みを有効にするなど、それなりの対処が必要です。

AppleScript名：アラートダイアログ上にTable View＋Map View＋Segmented Controlを表示

— Created 2019-02-23 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"

property NSAlert : a reference to current application’s NSAlert
property NSIndexSet : a reference to current application’s NSIndexSet
property MKMapView : a reference to current application’s MKMapView
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property MKPointAnnotation : a reference to current application’s MKPointAnnotation
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property MKMapTypeHybrid : a reference to current application’s MKMapTypeHybrid
property MKMapTypeSatellite : a reference to current application’s MKMapTypeSatellite
property MKMapTypeStandard : a reference to current application’s MKMapTypeStandard

property zLevel : 21 –Map Zoom Level (0:World View, 21:House/Building Zoom View)
property aMaxViewWidth : 800
property theResult : 0
property returnCode : 0
property theDataSource : {}
property curRow : 0
property aMapView : missing value
property nameL : {}
property placeL : {}

set aPlaceList to {{placeName:"Hey", aLat:"35.69906613", aLong:"139.77084064"}, {placeName:"namco中野", aLat:"35.70859274", aLong:"139.66584339"}, {placeName:"ゲームシティ板橋", aLat:"35.74572771", aLong:"139.67553260"}, {placeName:"ラウンドワンスタジアム板橋", aLat:"35.77661583", aLong:"139.67864491"}, {placeName:"キャロム練馬", aLat:"35.76386421", aLong:"139.66591600"}, {placeName:"アミュージアムOSC", aLat:"35.75308308", aLong:"139.59476696"}}

set paramObj to {myMessage:"場所の選択", mySubMessage:"適切な場所を以下のリストからえらんでください", placeList:aPlaceList}
my performSelectorOnMainThread:"chooseItemByTableViewWithMapAndSegment:" withObject:(paramObj) waitUntilDone:true
if (my theResult) = 0 then error number -128
return (my theResult)

on chooseItemByTableViewWithMapAndSegment:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (placeList of paramObj) as list
　　
　　set nameL to {}
　　set placeL to {}
　　repeat with i in aTList
　　　　set the end of nameL to (placeName of i)
　　　　set the end of placeL to {contents of (aLat of i), contents of (aLong of i)}
　　end repeat
　　
　　— create a view
　　set theView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, 400))
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(nameL, 200, 400) of me
　　
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(210, 30, aMaxViewWidth – 210, 370))
　　tell aMapView
　　　　its setMapType:MKMapTypeStandard
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　
　　　　set aLocation to current application’s CLLocationCoordinate2DMake((first item of first item of placeL) as real, (second item of first item of placeL) as real)
　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　its setDelegate:me
　　end tell
　　
　　–MapにPinを追加
　　repeat with i from 1 to (length of nameL)
　　　　set tmpAdr to contents of item i of nameL
　　　　copy item i of placeL to {tmpLat, tmpLong}
　　　　
　　　　set aLocation to current application’s CLLocationCoordinate2DMake(tmpLat as real, tmpLong as real)
　　　　set anAnnotation to MKPointAnnotation’s alloc()’s init()
　　　　(anAnnotation’s setCoordinate:aLocation)
　　　　(anAnnotation’s setTitle:tmpAdr)
　　　　(aMapView’s addAnnotation:anAnnotation)
　　end repeat
　　
　　–Segmented Controlをつくる
　　set segTitleList to {"Map", "Satellite", "Satellite + Map"}
　　set aSeg to makeSegmentedControl(segTitleList, 210, 0, 150, 20) of me
　　
　　theView’s setSubviews:{aScrollWithTable, aMapView, aSeg}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　–To enable the first annotation visible
　　copy item 1 of placeL to {tmpLat, tmpLong}
　　set aLocation to current application’s CLLocationCoordinate2DMake(tmpLat as real, tmpLong as real)
　　aMapView’s setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　
　　set (my theResult) to (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableViewWithMapAndSegment:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 0
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 30, aWidth, aHeight – 30))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 30, aWidth, aHeight – 30))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10,　10.11, 10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set (tmpRow) to aView’s selectedRow() as number
　　
　　–Table View上で現在選択行「以外の」行が選択されたら、Mapを選択項目で更新
　　if (my curRow) is not equal to tmpRow then
　　　　set tmpLat to (first item of item (tmpRow + 1) of placeL) as real
　　　　set tmpLong to (second item of item (tmpRow + 1) of placeL) as real
　　　　
　　　　tell aMapView
　　　　　　set aLocation to current application’s CLLocationCoordinate2DMake(tmpLat, tmpLong)
　　　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　end tell
　　　　
　　　　set (my curRow) to tmpRow
　　end if
　　
　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle)
　　return aRes
end tableView:objectValueForTableColumn:row:

on tableView:aView shouldEditTableColumn:aTableColumn row:rowIndex
　　return false –Not Editable
end tableView:shouldEditTableColumn:row:

★Click Here to Open This Script　

アラートダイアログ上にTable View＋Map Viewを表示

Posted on 2月 22, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にScroll View＋Table ViewおよびMap Viewを表示して選択肢の選択を行うAppleScriptです。

Map Viewを使用するために、インターネット接続が必要です。地図表示パフォーマンスはインターネット接続速度次第です。

{{placeName:"Hey", aLat:"35.69906613", aLong:"139.77084064"}....}

のように位置データを、

名称, 緯度, 経度

とまとめたリストで選択肢を指定します。実行すると選択肢のアイテム番号（１からはじまる）を返してきます。

▲左から、macOS 10.12.6、10.13.6、10.14.4betaで同じAppleScriptを動かしたところ。同じ場所、同じZoom LevelでもOSバージョンごとに微妙に表示内容が違う

現状の実装では、表UI（Table View）内のデータがダブルクリックで編集できてしまうので、編集できないようにするあたりが改良対象でしょうか。あと、地図・衛星写真の切り替えもつけておくとよいでしょう。

サンプルデータの緯度・経度情報は、例によって「戦場の絆」の入っている近所のゲーセンの情報を適当にみつくろって入れてみたものです。

AppleScript名：アラートダイアログ上にTable View＋Map Viewを表示 v2

— Created 2019-02-22 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "MapKit"

property NSAlert : a reference to current application’s NSAlert
property NSIndexSet : a reference to current application’s NSIndexSet
property MKMapView : a reference to current application’s MKMapView
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property zLevel : 18
property aMaxViewWidth : 800
property theResult : 0
property returnCode : 0
property theDataSource : {}
property curRow : 0
property aMapView : missing value
property nameL : {}
property placeL : {}

set paramObj to {myMessage:"場所の選択", mySubMessage:"適切な場所を以下のリストからえらんでください", placeList:aPlaceList}
my performSelectorOnMainThread:"chooseItemByTableViewWithMap:" withObject:(paramObj) waitUntilDone:true
return (my theResult)

on chooseItemByTableViewWithMap:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (placeList of paramObj) as list
　　
　　set nameL to {}
　　set placeL to {}
　　repeat with i in aTList
　　　　set the end of nameL to (placeName of i)
　　　　set the end of placeL to {contents of (aLat of i), contents of (aLong of i)}
　　end repeat
　　
　　— create a view
　　set theView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, aMaxViewWidth, 400))
　　
　　— make table view with scroll view
　　set aScrollWithTable to makeTableView(nameL, 200, 400) of me
　　
　　set aMapView to MKMapView’s alloc()’s initWithFrame:(current application’s NSMakeRect(210, 0, aMaxViewWidth – 210, 400))
　　tell aMapView
　　　　its setMapType:(current application’s MKMapTypeStandard)
　　　　its setZoomEnabled:true
　　　　its setScrollEnabled:true
　　　　its setPitchEnabled:true
　　　　its setRotateEnabled:true
　　　　its setShowsCompass:true
　　　　its setShowsZoomControls:true
　　　　its setShowsScale:true
　　　　its setShowsUserLocation:true
　　　　
　　　　set aLocation to current application’s CLLocationCoordinate2DMake((first item of first item of placeL) as real, (second item of first item of placeL) as real)
　　　　
　　　　its setCenterCoordinate:aLocation zoomLevel:(zLevel) animated:false
　　　　its setDelegate:me
　　end tell
　　
　　theView’s setSubviews:{aScrollWithTable, aMapView}
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set (my theResult) to (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableViewWithMap:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 0
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　–強制的にトップにスクロール
　　–set maxHeight to aScroll’s documentView()’s |bounds|()’s |size|()’s height
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

★Click Here to Open This Script　

アラートダイアログ上にTable Viewを表示

Posted on 2月 22, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にScroll View＋Table Viewを表示して選択肢の選択を行うAppleScriptです。

1D List（１次元配列）を与え、選択を行うUIです。実行すると選択肢のアイテム番号（１からはじまる）を返してきます。

とくにこれが作りたかったのではなく、位置情報（Geo Location）の選択をTable Viewで行い、該当する場所をMap Viewに表示させると擬似的に複数の固定位置情報から任意のものを選択させるダイアログが作れるだろうかと思って作成した試作品です。

東京への引っ越しの荷物が到着して、ようやく検証用のサブマシンが届いたものの、ネットワークを新規敷設しなくてはならないのでぼちぼちです。

AppleScript名：アラートダイアログ上にTable Viewを表示 v3

— Created 2019-02-21 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSIndexSet : a reference to current application’s NSIndexSet
property NSScrollView : a reference to current application’s NSScrollView
property NSTableView : a reference to current application’s NSTableView
property NSTableColumn : a reference to current application’s NSTableColumn
property NSMutableArray : a reference to current application’s NSMutableArray
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0
property theDataSource : {}

set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", aTableList:{"なし", "りんご", "ひよこ", "ぎょうざ", "すなぎも", "ぼんじり", "もも"}}
set aRes to my chooseItemByTableView:paramObj

on chooseItemByTableView:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aTList to (aTableList of paramObj) as list
　　
　　–define the matrix size where you’ll put the radio buttons
　　set aScrollWithTable to makeTableView(aTList, 300, 150) of me
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aScrollWithTable
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　return (aScrollWithTable’s documentView’s selectedRow()) + 1
end chooseItemByTableView:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeTableView(aList as list, aWidth as number, aHeight as number)
　　set aOffset to 40
　　
　　set sourceList to {}
　　repeat with i in aList
　　　　set the end of sourceList to {dataItem:(contents of i)}
　　end repeat
　　
　　set theDataSource to NSMutableArray’s alloc()’s init()
　　theDataSource’s addObjectsFromArray:sourceList
　　
　　set aScroll to NSScrollView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　set aView to NSTableView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, aOffset, aWidth, aHeight))
　　
　　
　　set aColumn to (NSTableColumn’s alloc()’s initWithIdentifier:"dataItem")
　　(aColumn’s setWidth:aWidth)
　　(aColumn’s headerCell()’s setStringValue:"dataItem")
　　(aView’s addTableColumn:aColumn)
　　
　　aView’s setDelegate:me
　　aView’s setDataSource:me
　　aView’s reloadData()
　　
　　aScroll’s setDocumentView:aView
　　aView’s enclosingScrollView()’s setHasVerticalScroller:true
　　
　　–１行目を選択
　　set aIndexSet to NSIndexSet’s indexSetWithIndex:0
　　aView’s selectRowIndexes:aIndexSet byExtendingSelection:false
　　
　　–強制的にトップにスクロール
　　–set maxHeight to aScroll’s documentView()’s |bounds|()’s |size|()’s height
　　set aDBounds to aScroll’s documentView()’s |bounds|()
　　if class of aDBounds = list then
　　　　–macOS 10.13 or later
　　　　set maxHeight to item 2 of item 1 of aDBounds
　　else
　　　　–macOS 10.10….10.12
　　　　set maxHeight to height of |size| of aDBounds
　　end if
　　
　　set aPT to current application’s NSMakePoint(0.0, -40.0) —— (aScroll’s documentView()’s |bounds|()’s |size|()’s height))
　　aScroll’s documentView()’s scrollPoint:aPT
　　
　　return aScroll
end makeTableView

–TableView Event Handlers
on numberOfRowsInTableView:aView
　　return my theDataSource’s |count|()
end numberOfRowsInTableView:

on tableView:aView objectValueForTableColumn:aColumn row:aRow
　　set aRec to (my theDataSource)’s objectAtIndex:(aRow as number)
　　set aTitle to (aColumn’s headerCell()’s title()) as string
　　set aRes to (aRec’s valueForKey:aTitle)
　　return aRes
end tableView:objectValueForTableColumn:row:

★Click Here to Open This Script　

アラートダイアログ上にsegmented controlを表示

Posted on 2月 19, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にsegmented control（タブみたいな複数項目１択UI部品）を表示して選択肢の選択を行うAppleScriptです。

選択肢のインデックス番号が（１からはじまる）返ってきます。

AppleScript名：アラートダイアログ上にsegmented controlを表示

— Created 2019-02-14 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSView : a reference to current application’s NSView
property NSSegmentedControl : a reference to current application’s NSSegmentedControl
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSSegmentStyleTexturedRounded : a reference to current application’s NSSegmentStyleTexturedRounded

property theSegSel : 0
property returnCode : 0

set paramObj to {myMessage:"項目選択", mySubMessage:"どれか選択してください。", segmentMes:{"Red", "Blue", "Yellow", "Brown", "White", "Cyan", "Grey"}}
set segRes to my chooseSegment:paramObj

on chooseSegment:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set segMesList to segmentMes of paramObj
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 400, 200))
　　
　　–Segmented Controlをつくる
　　set aSeg to makeSegmentedControl(segMesList, 400, 80) of me
　　
　　theView’s setSubviews:{aSeg}
　　
　　set theAlert to NSAlert’s alloc()’s init()
　　
　　— set up alert
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aSeg
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set (my theSegSel) to (aSeg’s selectedSegment()) as number
　　return (my theSegSel) + 1
end chooseSegment:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

on makeSegmentedControl(titleList, aWidth, aHeight)
　　set aLen to length of titleList
　　
　　set aSeg to NSSegmentedControl’s alloc()’s init()
　　aSeg’s setSegmentCount:aLen
　　
　　set aCount to 0
　　repeat with i in titleList
　　　　set j to contents of i
　　　　(aSeg’s setLabel:j forSegment:aCount)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　aSeg’s setTranslatesAutoresizingMaskIntoConstraints:false
　　aSeg’s setSegmentStyle:(NSSegmentStyleTexturedRounded)
　　aSeg’s setFrame:(current application’s NSMakeRect(20, aHeight – 60, aWidth, aHeight – 40))
　　aSeg’s setTrackingMode:0
　　aSeg’s setTarget:me
　　aSeg’s setAction:"clickedSeg:"
　　aSeg’s setSelectedSegment:0
　　
　　return aSeg
end makeSegmentedControl

on clickedSeg:aSender
　　set aSel to aSender’s selectedSegment()
　　set selSeg to aSel
end clickedSeg:

★Click Here to Open This Script　

アラートダイアログ上にRadio Buttonを表示

Posted on 2月 19, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にRadio Buttonを表示して位置座標の選択を行うAppleScriptです。

任意の選択肢をlist（配列）で指定すると、その通りのRadio Buttonを表示します。ユーザーが選択した項目のtitle文字列を返します。項目番号ではありません。

AppleScript名：アラートダイアログ上にRadio Buttonを表示 v2

— Created 2019-02-14 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSMatrix : a reference to current application’s NSMatrix
property NSButtonCell : a reference to current application’s NSButtonCell
property NSRadioButton : a reference to current application’s NSRadioButton
property NSRadioModeMatrix : a reference to current application’s NSRadioModeMatrix
property NSAlertSecondButtonReturn : a reference to current application’s NSAlertSecondButtonReturn

property theResult : 0
property returnCode : 0

set paramObj to {myMessage:"項目の選択", mySubMessage:"適切なものを以下からえらんでください", matrixTitleList:{"なし", "りんご", "ひよこ", "ぎょうざ", "すなぎも", "ぼんじり", "もも"}}
set aRes to my chooseItemByRadioButton:paramObj

on chooseItemByRadioButton:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　set aMatList to (matrixTitleList of paramObj) as list
　　set aLen to length of aMatList
　　
　　–create the radio button prototype
　　set aProto to NSButtonCell’s alloc()’s init()
　　aProto’s setTitle:"Options"
　　aProto’s setButtonType:(NSRadioButton)
　　
　　–define the matrix size where you’ll put the radio buttons
　　set matrixRect to current application’s NSMakeRect(20.0, 20.0, 200.0, (20.0 * aLen))
　　set aMatrix to NSMatrix’s alloc()’s initWithFrame:matrixRect mode:(NSRadioModeMatrix) prototype:aProto numberOfRows:(aLen) numberOfColumns:1
　　
　　set cellList to aMatrix’s cells()
　　set aCount to 0
　　repeat with i in aMatList
　　　　set j to contents of i
　　　　((cellList’s objectAtIndex:aCount)’s setTitle:j)
　　　　set aCount to aCount + 1
　　end repeat
　　
　　— set up alert　　
　　set theAlert to NSAlert’s alloc()’s init()
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:aMatrix
　　end tell
　　
　　— show alert in modal loop
　　current application’s NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　return (aMatrix’s selectedCell()’s title()) as string
end chooseItemByRadioButton:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

★Click Here to Open This Script　

アラートダイアログ上のDate Pickerで日付選択

Posted on 2月 18, 2019 by Takaaki Naganoya

アラートダイアログを作成し、その上にDate Pickerを表示して日付の選択を行うAppleScriptです。

スクリプトエディタ、Script Debugger、Appletなどでは正常に動作しますが、スクリプトメニュー上から呼び出すとアラートダイアログが最前面に表示されず、前に出す操作が必要になります。

もともとはShane Stanleyが作成したカレンダー選択ダイアログでしたが、メインスレッドでの実行を強制しなくてはならなかったのと、汎用的に使える構造になっていなかったので、機能を整理しました。

このDate Pickerダイアログをもとに、さまざまなGUI部品を配置してちょっとしたユーザーの操作を受け付ける汎用ダイアログとして整備してみました。最終的には、SDEF（AppleScript用語辞書）をつけたAppleScript Librariesに仕上げるといい感じでしょうか。

アラートダイアログという、サイズ固定のダイアログウィンドウ上に各種GUI部品を表示するのは、使いにくいんじゃないかと疑問を持っていたのですが、表示後のリサイズはできないものの、中に入れるViewのサイズ次第でダイアログの大きさも可変なので、予想よりも使えそうです。

AppleScript名：アラートダイアログ上のDate Pickerで日付選択

— Created 2019-02-14 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSAlert : a reference to current application’s NSAlert
property NSDate : a reference to current application’s NSDate
property NSView : a reference to current application’s NSView
property NSDatePicker : a reference to current application’s NSDatePicker
property NSRunningApplication : a reference to current application’s NSRunningApplication
property NSClockAndCalendarDatePickerStyle : a reference to current application’s NSClockAndCalendarDatePickerStyle
property NSYearMonthDayDatePickerElementFlag : a reference to current application’s NSYearMonthDayDatePickerElementFlag
property NSHourMinuteSecondDatePickerElementFlag : a reference to current application’s NSHourMinuteSecondDatePickerElementFlag

property theResult : missing value
property returnCode : 0

set paramObj to {myMessage:"月選択", mySubMessage:"作成対象の月を選択してください。日付はどれでもけっこうです。"}
set {targYear, targMonth, targDate} to my chooseDate:((paramObj) of me)
–> {2018, 10, 8}

on chooseDate:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　
　　— create a view
　　set theView to NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 200, 300))
　　set datePicker to NSDatePicker’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 300, 200))
　　datePicker’s setDatePickerStyle:(NSClockAndCalendarDatePickerStyle)
　　datePicker’s setDatePickerElements:((NSYearMonthDayDatePickerElementFlag) + (NSHourMinuteSecondDatePickerElementFlag as integer))
　　
　　datePicker’s setDateValue:(NSDate’s |date|())
　　
　　set theSize to datePicker’s fittingSize()
　　
　　theView’s setFrameSize:theSize
　　datePicker’s setFrameSize:theSize
　　
　　theView’s setSubviews:{datePicker}
　　
　　set theAlert to NSAlert’s alloc()’s init()
　　
　　— set up alert
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　NSRunningApplication’s currentApplication()’s activateWithOptions:0
　　my performSelectorOnMainThread:"doModal:" withObject:(theAlert) waitUntilDone:true
　　if (my returnCode as number) = 1001 then error number -128
　　
　　set (my theResult) to (datePicker’s dateValue()) as date
　　
　　set aYear to year of theResult
　　set aMonth to month of theResult as number
　　set aDate to day of theResult
　　return {aYear, aMonth, aDate}
end chooseDate:

on doModal:aParam
　　set (my returnCode) to aParam’s runModal()
end doModal:

★Click Here to Open This Script　

Keynoteの最前面のドキュメントの現在のスライドに指定月の日曜日はじまりカレンダーを表で作成

Posted on 2月 14, 2019 by Takaaki Naganoya

Keynoteの最前面の書類の現在選択中のスライド（ページ）に、指定月の日曜日はじまりカレンダーを、表オブジェクトで作成するAppleScriptです。

Keynoteで資料を作成していると、資料にカレンダーを入れたいケースが多々あります。Terminal.appを起動してcalコマンドでカレンダーを作ってみたり、Dashboardのカレンダーをコピーして入れることも多いですが、Dashboardはもうあるんだかないんだ分からない状態。かわりのものを用意してみました。

あとは、サイズやスタイル、土日のデータを削除するなど用途に応じて編集して表カレンダーを利用するとよいでしょう。

macOS標準装備のスクリプトメニューに入れて呼び出す場合には、アプリケーション形式で書き出したものを使う必要があります。

世の中のカレンダーは日曜日はじまりだけではないので、月曜日はじまりなど、その国、その現場ごとのルールに合わせて変更することが重要です。曜日名についても、実行中のユーザーの言語環境から取得して入れることも可能なので、そのようにしてもよいでしょう。

同じぐらいのスペックのマシンで本Scriptを動かすと、macOS 10.14, Mojave上では10.12.6上の（Keynote v8.1の）倍ぐらい速くて驚かされます。10.13.6上でも同様なのでOS側の対応というよりは、Keynote側のバージョンアップ（v8.1 –> v8.3）によるものかもしれません。

AppleScript名：指定月の日曜日はじまりカレンダーを表で作成 v2.scptd

— Created 2019-02-14 by Takaaki Naganoya
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property theDate : missing value

property daysList : {"日", "月", "火", "水", "木", "金", "土"} –Japanese
–property daysList : {"Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat"}–English

set paramObj to {myMessage:"月選択", mySubMessage:"作成対象の月を選択してください。日付はどれでもけっこうです。"}
set {targYear, targMonth} to chooseMonth(paramObj) of me

–指定月のカレンダーを1D List(7 days x 6 weeks) で作成
set aCalList to retListCalendar(targYear, targMonth) of me

set fullCalList to daysList & aCalList

set aTitle to (targYear as string) & (targMonth as string)
set dCount to 1

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　set aTable to make new table with properties {header column count:0, header row count:1, row count:7, column count:7, name:aTitle}
　　　　　　tell aTable
　　　　　　　　repeat with i from 1 to 49
　　　　　　　　　　tell cell i
　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　set value to contents of item dCount of fullCalList
　　　　　　　　　　　　end ignoring
　　　　　　　　　　end tell
　　　　　　　　　　set dCount to dCount + 1
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
end tell

–カレンダー作成対象の年、月を選択（ただし、日付をクリックして選択しないと値を取得できないので注意）
on chooseMonth(paramObj)
　　my performSelectorOnMainThread:"chooseDate:" withObject:(paramObj) waitUntilDone:true
　　set aYear to year of theDate
　　set aMonth to month of theDate as number
　　return {aYear, aMonth}
end chooseMonth

on chooseDate:paramObj
　　set aMainMes to myMessage of paramObj
　　set aSubMes to mySubMessage of paramObj
　　
　　— create a view
　　set theView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 100, 200))
　　set datePicker to current application’s NSDatePicker’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 100, 100))
　　datePicker’s setDatePickerStyle:(current application’s NSClockAndCalendarDatePickerStyle)
　　datePicker’s setDatePickerElements:((current application’s NSYearMonthDayDatePickerElementFlag) + (current application’s NSHourMinuteSecondDatePickerElementFlag as integer))
　　
　　datePicker’s setDateValue:(current application’s NSDate’s |date|())
　　
　　set theSize to datePicker’s fittingSize()
　　
　　theView’s setFrameSize:theSize
　　datePicker’s setFrameSize:theSize
　　
　　theView’s setSubviews:{datePicker}
　　
　　set theAlert to current application’s NSAlert’s alloc()’s init()
　　
　　— set up alert
　　tell theAlert
　　　　its setMessageText:aMainMes
　　　　its setInformativeText:aSubMes
　　　　its addButtonWithTitle:"OK"
　　　　its addButtonWithTitle:"Cancel"
　　　　its setAccessoryView:theView
　　end tell
　　
　　— show alert in modal loop
　　set returnCode to theAlert’s runModal()
　　if returnCode = (current application’s NSAlertSecondButtonReturn) then error number -128
　　
　　— retrieve date
　　set (my theDate) to (datePicker’s dateValue()) as date
　　
end chooseDate:

–指定月のカレンダーを1D List(7 days x 6 weeks) で返す
on retListCalendar(tYear, tMonth)
　　set mLen to getMlen(tYear, tMonth) of me
　　set aList to {}
　　
　　set fDat to getDateInternational(tYear, tMonth, 1) of me
　　tell current application
　　　　set aOffset to (weekday of fDat) as number
　　end tell
　　
　　–header gap
　　repeat (aOffset – 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　–calendar body
　　repeat with i from 1 to mLen
　　　　set the end of aList to (i as string)
　　end repeat
　　
　　–footer gap
　　repeat (42 – aOffset – mLen + 1) times
　　　　set the end of aList to ""
　　end repeat
　　
　　return aList
end retListCalendar

–現在のカレンダーで指定年月の日数を返す（国際化対応版）
on getMlen(aYear as integer, aMonth as integer)
　　set theNSCalendar to current application’s NSCalendar’s currentCalendar()
　　set theDate to theNSCalendar’s dateWithEra:1 |year|:aYear |month|:aMonth |day|:1 hour:0 minute:0 |second|:0 nanosecond:0
　　set theResult to theNSCalendar’s rangeOfUnit:(current application’s NSDayCalendarUnit) inUnit:(current application’s NSMonthCalendarUnit) forDate:theDate
　　return |length| of theResult
end getMlen

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSAlert

アラートダイアログ上にTextViewを表示

アラートダイアログ上にTextField x 2を表示 v2

アラートダイアログ上に複数のNSBoxを作成してMKMapViewを表示

アラートダイアログ上にWebViewを表示

アラートダイアログ上にTable View＋Map View＋Segmented Controlを表示

アラートダイアログ上のDate Pickerで日付選択