Stream Deck Softwareがバージョン5.1.2にバージョンアップ

Posted on 10月 16, 2021 by Takaaki Naganoya

ElgatoのStream Deck用ソフトウェアがバージョン5から5.1.2にバージョンアップしました。

従来は１台のStream Deckに対してプロファイルを複数登録して、「プロファイルを切り替え」アクションで1→2→3→4→1と、順送りで切り替えして、物理ボタンが15個であってもボタン数を超える機能を呼び出せるようにしてありました。

この仕組みはあらためて説明されると理解できるのですが、一目見て理解できるというものでもありません。自分も書籍を書くために仔細に調査を行うまで分かりませんでした。このあたりの「説明不足感」を解消するために「ページ切り替え」「ページインジケータ」も用意したのでしょうか。

物理ボタン数を超える機能を呼び出すための「プロファイルを切り替え」アクションであったり、「フォルダ」アクションであったり、「ページ切り替え」アクションであったり。同じ働きを行う機能を、見せ方を変えて複数実装してあるというのは、それだけ「問題点」だと（販売・営業的に、）みなされているためでしょうか。

より多くのアクションをボタン上にホスティングするために、プロファイル切り替えアクションに、ページ切り替えアクション、ページ表示アクション、フォルダ移動アクションなど操作系のアクション配置ボタンが増え、実質的にSD上に配置できるアクションが減ってしまう（６ボタンの最小のSDの場合には切り替え用で半分埋まる？）わけで、購入時によりボタン数の多いSDモデルへの誘導を行いたいのか、実ボタン以上のアクションをホスティングできることを訴求したいのか……それは自分にはわかりませんが、力を入れている場所であることは確かです。

最終的にはフェイスプレート部分に透明窓を追加して、プロファイル切り替えやページ切り替え、フォルダ切り替えなどの追加表示をSDの画面上で行うといったあたりに「落とし所」がありそうです。

Pages末尾から指定ページまでページ削除

Posted on 10月 12, 2021 by Takaaki Naganoya

「ページ単位でページを削除する」という機能を持たないPagesに対して、限定的ながらもページ単位の削除を行うAppleScriptです。Pages v11.2＋macOS 12beta9で動作確認していますが、macOS 11.xやmacOS 10.15でも動作すると思います。

Pagesでまとまった内容の書類（例：書籍）を作る場合には、１書類にすべての内容を詰め込むのは自殺行為で、なるべく記事単位に分割するのがセオリーです。さすがに１ページあたり１書類といった作り方はしませんが、まとまった意味のある内容で１つの書類（扉ページと記事ページは別書類）ぐらいの分け方はします。

それというのも、Pagesがページ単位での入れ替えとかページ単位での削除、ページ単位での挿入といった操作系の機能が弱いからです。ページ単位での削除、入れ替えといった操作ができません。おまえはPagesなんて名乗らず「Overflow」とか名乗っとけ！　という気持ちでいっぱいです。Page関連操作の弱いPages.app。

Pagesのヘルプで確認しても、ページ単位での削除については、「ページ上のオブジェクトを削除したあと、地に敷いている文字を削除して回れ」という、脳みそに何か湧いているような説明しか見当たりません。

ウィンドウ左に表示されているページのサムネイルを選択して、コンテクストメニューから「削除」を選ぶと書類の内容がまるごと削除されるという「わけのわからない」挙動をします。セクションを小分けしてある場合には、当該ページを含むセクションを削除してくれるようですが、１セクション＝１ページという作り方をしていない場合には複数ページが削除されてしまいます。

–> Watch Page Removal Demo on Pages Movie

そこで、仕方なく本Scriptを作成してみたわけです。本Scriptの前バージョンとして「最終ページ上のオブジェクトの全削除」Scriptを作成して、実際にこれでページ削除が行える/行えないパターンについて検証を重ねてきました。実用性もある程度あったので、実際に作業で使ってもいました。

条件１：ページ削除は末尾側から行う。先頭側からは行えない
条件２：書類作成時に、ページの「地」に文字を置かず、テキストボックスを配置して文字を流し込んでいる

–> Watch Page Removal AppleScript Demo Movie

本Scriptでは、ページの地に直接「テキスト」や「表」を流し込んでいるような作り方の書類だと、書類上の内容をまるごと削除してしまいます。そういう場合には、Pages上の「表」などの元データが存在しているはずなので、そちらを再利用して別のPagesレイアウトに流し込み直すような対応になることでしょう。

なお、Pagesは（KeynoteやNumbersも）書類に変更を加えるとリアルタイムにファイルに変更が反映されるため、本Scriptのような道具でページ単位の削除をおこなった場合、「ファイル保存していないから、ファイルの再オープンを行えば復帰」ということはできません。あらかじめ、元の書類のコピーを作っておいた上で実行するようにしてください。

AppleScript名：末尾から指定ページまでページ削除.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/10/12
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8"
use framework "Foundation"
use scripting additions

set dMax to 3 –このページまで残す。ここから後はすべて削除する

tell application "Pages"
　　set dCount to count every document
　　if dCount < 1 then
　　　　display notification "Pagesでオープンしている書類はありません"
　　　　return
　　end if
end tell

set pMax to getPageNum() of me
if pMax < (dMax + 1) then
　　display notification "Pagesでオープンしている書類は、指定よりも少ないページ数であるため、削除の必要がありません"
　　return
end if

–セクションごとのページ数のリストを取得
set aList to retSectionPageList() of me
set bList to sectionPageListToSectionHeaderList(aList) of me

repeat with i from pMax to (dMax + 1) by -1
　　tell application "Pages"
　　　　tell front document
　　　　　　–オブジェクト削除前のページ数
　　　　　　set pMax1 to getPageNum() of me
　　　　　　
　　　　　　tell last page
　　　　　　　　delete every iWork item
　　　　　　end tell
　　　　　　
　　　　　　–セクション先頭の場合
　　　　　　set curPStat to contents of item i of bList
　　　　　　if curPStat = true then
　　　　　　　　tell last section
　　　　　　　　　　set body text to ""
　　　　　　　　end tell
　　　　　　end if
　　　　　　
　　　　　　–オブジェクト削除後のページ数
　　　　　　set pMax2 to getPageNum() of me
　　　　　　
　　　　　　–オブジェクト削除処理を行ってもページ数に変動がない場合には、last section上のbody textも消してみる
　　　　　　if pMax2 = pMax1 then
　　　　　　　　tell last section
　　　　　　　　　　set body text to ""
　　　　　　　　end tell
　　　　　　end if
　　　　end tell
　　end tell
end repeat

–セクションごとのページ数のリストを、ページ単位のセクション開始位置リストに変換する
on sectionPageListToSectionHeaderList(aList)
　　set bList to {}
　　
　　repeat with tmpP in aList
　　　　
　　　　if tmpP = 1 then
　　　　　　set the end of bList to true
　　　　else
　　　　　　set the end of bList to true
　　　　　　repeat (tmpP – 1) times
　　　　　　　　set the end of bList to false
　　　　　　end repeat
　　　　end if
　　end repeat
　　
　　return bList
end sectionPageListToSectionHeaderList

–最前面の書類の各セクションごとのページ数を1Dリスト（１次元配列）で返す
on retSectionPageList()
　　tell application "Pages"
　　　　tell front document
　　　　　　set sList to every section
　　　　　　set pList to {}
　　　　　　repeat with i in sList
　　　　　　　　set the end of pList to count every page of i
　　　　　　end repeat
　　　　end tell
　　end tell
　　return pList
end retSectionPageList

–最前面の書類のページ数を取得
on getPageNum()
　　tell application "Pages"
　　　　tell front document
　　　　　　return count every page
　　　　end tell
　　end tell
end getPageNum

★Click Here to Open This Script　

Pages書類の最終ページ上のすべてのオブジェクトを削除

Posted on 10月 11, 2021 by Takaaki Naganoya

最前面のPages書類のうちの最終ページ上のオブジェクトとテキストを削除するAppleScriptです。

Pagesで凝ったレイアウトの書類を作る場合、やりかたはいくつかありますが……ページはすべてセクション（改ページ処理みたいなもの）を入れて１ページ＝１セクションみたいにページを作って、その上にテキストフレームを配置、ページ間のテキストフレームの連続はGUI上で指定しておき、テキストが先頭から末尾まで、指定ボックス上を流れていくように指定しています。

別途、脚注のテキストは別のテキストボックスを配置しておき、こちらも前ページの脚注と連結する必要があればつないでおきます。

そのうえで、このように作成したPages書類を前後で分割しようとした場合に、

（１）書類をコピー
（２）前半の書類は、後半部分を削除
（３）後半部分の書類は、前半部分を削除

となるわけです。

が、Pagesに「指定ページを削除」する機能はないので、このようなScriptを組んでいろいろ対処を行っています。

本Scriptは、（２）の処理を行うためのものです。最終ページ上のオブジェクトおよびテキストを削除することで、ページ自体を削除できます。

あとは、１ページ＝１セクションで書類が構成されているかどうかをチェックすれば、ページ削除とほぼ同義で扱えるところです。

AppleScript名：末尾のページのオブジェクトを全削除.scpt

tell application "Pages"
　　tell front document
　　　　tell last page
　　　　　　delete every iWork item
　　　　end tell
　　　　
　　　　tell last section
　　　　　　set body text to ""
　　　　end tell
　　　　
　　　　
　　end tell
end tell

★Click Here to Open This Script　

iWorks Apps v11.2が登場

Posted on 9月 30, 2021 by Takaaki Naganoya

Apple純正のiWorks App（Keynote、Pages、Numbers）の新バージョンv11.2がリリースされました。

バージョン番号が「11.1」から「11.2」に変わっただけですが、内部的にも…各アプリケーションともアイコン自体が変更になり、大きな節目のバージョンであることが伺われます。

iOS、iPadOSが新製品とともに９月にアップデートし、iWorkアプリケーションがアップデートした後にmacOSのアップデートが行われるわけで、実にリリース間近であることを感じさせます。Windows 11の発表日がどの程度注目を浴びているかはわかりませんが、10月5日より前に発表することは…ないのではないかと（ノーアイデアです）。

これらのアプリケーションのAppleScript用語辞書については、「get」コマンドが追加されたことを確認していますが、このコマンドがないと実現できないことが不明（普通は省略されるコマンド）なので、何か後で追加するための「布石」と見るのが正しい見方でしょう。

Keynote v11.2の変更点：
・スライド上のライブビデオ
・複数発表者スライドショー
・レーダーグラフ（レーダーチャートのこと）

Pages v11.2の変更点：
・ブックの公開の改善
・素早くテキストを翻訳
・レーダーグラフ（レーダーチャートのこと）

Numbers v11.2の変更点：
・強力なピボットテーブル
・レーダーグラフ（レーダーチャートのこと）
・フィルタの改善

そして、AppleScript用語辞書に「レーダーグラフ」の作成機能は反映されていないため、まだAppleScriptから追加することはできません。通例だと、マイナーアップデート２回後ぐらいに反映されるのではないでしょうか？

Pages v11.2でトンでもない変更が加わっていることが判明しました。なんと、selectionを取得できなくなっています。

これは、Pagesの数少ない長所だったのですが、selectionを取得できないととても困ります、、、、、

一応、フィードバックしておきましたが、直るかどうかは不明です。Pagesの唯一の美点であった、selectionを返せ！！！

Keynote v11.2でも、selectionが使えなくなっていました（スライド単位の選択も無効に）。

Pagesでページ数とfacing pagesフラグの値から右側ページを判定

Posted on 9月 26, 2021 by Takaaki Naganoya

Pagesでページ数とfacing pagesの値から該当のページが右側に存在するかどうかを判定するAppleScriptです。

ページが右側にあるかどうか、というこの判定処理はツメ処理のために用意したものです。見開きの右側に置くのが基本といいますか、別に左側にもあってもいいんですが、右側ページ右端に置いた縦長の表オブジェクトをツメと見立てて処理することに（個人的に）したためです。

▲同一のPages書類を「見開きページ」の設定をオフにした状態（左）、オンにした状態（右）でページの並びが変わる

AppleScript名：Pages書類のfacing Pagesを取得.scpt

set fRes to getFacingPages() of me

on getFacingPages()
　　tell application "Pages"
　　　　tell front document
　　　　　　return facing pages
　　　　end tell
　　end tell
end getFacingPages

★Click Here to Open This Script　

こんな記述でfacing pagesの値を取得でき、この値とページ数（ノンブル）をもとに奇数ページ、偶数ページの判定を行い、ページの左右を判定できます。

本Scriptを実行すると、以下のようにログ表示を行います。{facing pages, ノンブル, 右側ページかどうかの判定結果}を表示しています。

(*false, 1, false*)
(*false, 2, true*)
(*false, 3, false*)
(*false, 4, true*)
(*false, 5, false*)
(*false, 6, true*)
(*true, 1, true*)
(*true, 2, false*)
(*true, 3, true*)
(*true, 4, false*)
(*true, 5, true*)
(*true, 6, false*)

以前にどこかで「奇数/偶数の判定処理なんて、素朴な処理をサブルーチンとして独立して用意しておくのか？」と聞かれたことがありましたが、このように、サブルーチンとして用意しておいたので簡単に使い回して利用できているわけです。

AppleScript名：Pagesのページ番号の該当ページが右側にあるかどうか計算.scpt

set flagList to {false, true}
repeat with i in flagList
　　set aFlag to contents of i
　　repeat with aPage from 1 to 6
　　　　set rRes to checkPagesRightPage(aPage, aFlag) of me
　　　　log {i, aPage, rRes}
　　end repeat
end repeat

–Pagesのページ番号の該当ページが右側にあるかどうか計算
on checkPagesRightPage(aNum, aFlag)
　　set oddF to chkOddNum(aNum) of me –奇数チェック
　　if {aFlag, oddF} = {true, true} then
　　　　return true –右側ページ
　　else if {aFlag, oddF} = {false, false} then
　　　　return true –右側ページ
　　else
　　　　return false
　　end if
end checkPagesRightPage

–奇数かどうかチェック
on chkOddNum(aNum)
　　set a to aNum mod 2
　　if a = 1 then
　　　　return true
　　else
　　　　return false
　　end if
end chkOddNum

–偶数かどうかチェック
on chkEvenNum(aNum)
　　set a to aNum mod 2
　　if a = 0 then
　　　　return true
　　else
　　　　return false
　　end if
end chkEvenNum

★Click Here to Open This Script　

Pagesで選択中の表オブジェクトのデータ行を逆順に

Posted on 9月 26, 2021 by Takaaki Naganoya

Pagesで編集中の最前面の書類上で選択中の表オブジェクトに対して、行単位で逆順に入れ替えるAppleScriptです。Pages v11.1＋macOS 12beta7で開発して使用しています。

Pagesの表操作機能には大したものはありませんが、さすがに昇順／降順のソートぐらいはできます。ただ、そうしたソートではなく、単純に順番を入れ替えたいといったときに処理する機能がありません。

この表データにはソート用のキーが存在していません。「軍隊の階級順にソート」とかいうお花畑な機能があれば使うんでしょうけれど、頭がいいヒトなら一時的にソート用の列を作ってシーケンシャル値を入れておき、逆順ソートして一時ソートキー列を削除することでしょう。

ただ、この「ソート用の一時データ列」すら作るのがめんどくさかったので、ありあわせの機能を使って使い捨てレベルのScriptを書いてみました。AppleScriptで書いておけば、同じ作業を行うさいに、２度目からは手間をかけずに行えますので。

PagesはiWork３兄弟（Keynote、Pages、Numbers）の中で、唯一、「selection」で各種選択中のオブジェクトを取得できます。Keynoteもこの仕様になってほしいのですが、違っています（Keynoteでは選択中のスライドが返ってくるだけ）。

正直なところ、いったんPages上の表のデータをコピペでNumbersに持って行って、Numbers側で並べ替えて手動でふたたびPagesの表に書き戻せばScriptを持ち出す必要もないんですが、繰り返し行う作業っぽいのでmacOS標準搭載のScript Menuに組み込んでおくことを前提に書いてみました。

ほぼ組み捨てレベルの使い捨てScriptなので、さまざまな条件でのテストは行っていません。何か問題があったらコメント欄でお知らせください。

Keynote/Pages/Numbers共通で、表のデータを取得すると１次元配列（1D List）で返ってきます。それはもう、既知の事実なので……１次元配列から２次元配列に変換するルーチンを用意して使っています。普通はBridgePlusの機能を呼び出して使うところですが、FileMaker ProのAppleScriptランタイム中でこれを呼び出せない（外部ライブラリの機能を一切呼び出せない）ことに苦しめられ、ちょっとBridgePlusを外しています。

AppleScript名：選択中の表オブジェクトのデータ行を逆順に.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/09/26
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Pages"
　　tell front document
　　　　set aSel to selection
　　　　if aSel = {} then return
　　　　
　　　　set aTarg to first item of aSel
　　　　set aClass to class of aTarg
　　　　if aClass is not equal to table then return
　　　　
　　　　–選択中の表オブジェクトを処理対象に
　　　　tell aTarg
　　　　　　set rCount to count every row
　　　　　　set cCount to count every column
　　　　　　
　　　　　　set hCount to header row count
　　　　　　set fCount to footer row count
　　　　　　
　　　　　　set allData to value of every cell of cell range –表中の全セルのデータを取得（1Dで返ってくる）
　　　　　　set aRes to my subarraysFrom:(allData) groupedBy:(cCount) –1D Listの2D化
　　　　　　
　　　　　　set bRes to items (1 + hCount) thru (-1 – fCount) of aRes
　　　　　　set rList to reverse of bRes –逆順に
　　　　　　
　　　　　　–表にデータを書き戻す
　　　　　　repeat with rC from (1 + hCount) to (rCount – fCount)
　　　　　　　　tell row rC
　　　　　　　　　　repeat with cC from 1 to cCount
　　　　　　　　　　　　tell cell cC
　　　　　　　　　　　　　　set tmpVal to item cC of item (rC – hCount) of rList –けっこういい加減
　　　　　　　　　　　　　　if tmpVal = missing value then set tmpVal to ""
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　set value of it to tmpVal
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　end repeat
　　　　　　
　　　　end tell
　　end tell
end tell

–1D Listの2D化（BridgePlus不使用バージョン）
on subarraysFrom:(aList as list) groupedBy:(gNum as integer)
　　script spdObj
　　　　property list : aList
　　　　property bList : {}
　　end script
　　
　　
　　–Group Num check
　　if gNum = 0 then return false
　　if length of aList < gNum then return false
　　
　　if (length of aList) mod gNum is not equal to 0 then return
　　
　　set (bList of spdObj) to {}
　　
　　set tmpList to {}
　　set aCount to 1
　　
　　repeat with i in aList
　　　　set j to contents of i
　　　　set the end of tmpList to j
　　　　set aCount to aCount + 1
　　　　
　　　　if aCount > gNum then
　　　　　　set the end of (bList of spdObj) to tmpList
　　　　　　set tmpList to {}
　　　　　　set aCount to 1
　　　　end if
　　end repeat
　　
　　return (bList of spdObj)
end subarraysFrom:groupedBy:

★Click Here to Open This Script　

Pagesの最前面の書類で選択中のツメを修正する

Posted on 9月 22, 2021 by Takaaki Naganoya

Pagesで作成中の書類すべての見開き右側ページ右端につけている「ツメ」（辞書や電話帳でページ端につけているマーク的なもの、A〜Zのうちいま「S」の部分を表示していますよ、という場合にはSの箇所のみ色を変えておくなど）の修正を行うAppleScriptです。

PagesはiWork 3兄弟で唯一、選択中のオブジェクトがselectionで取得できるアプリケーションです。selectionでオブジェクトを選択可能かどうかでScriptの書きやすさが段違いです。

「ツメ」の修正が必要な事態になりました。AppleScriptのプログラムでPages書類を順次オープンして、書類中の右側ページ右端についている超縦長の表オブジェクトを「ツメ」であると仮定。このツメ（表）の修正を行う処理部分が、本AppleScriptの該当部分です。

Pages書類上の表の各種操作は、削除についてはdelete row 2とかdelete column 3といった操作が行えるのですが、追加に関してはinsert rowとかadd rowといった明示的なコマンドがあるわけではなく、propertyのcount rowを変更することで表末尾への行追加を行うことになります。

その後は、表のセル内の値を移動させたり、書式を変更するなどの「つじつま合わせ」を行うことになるでしょう。

あとは、指定フォルダ以下に入っているPages書類を抽出して、順次オープンし、書類中の右側ページ右端にある「ツメ」を計算でピックアップ。「ツメ」に対して修正を行い、保存してクローズ、という処理になるでしょうか。一度しか使えない壮大な「使い捨てScript」です。

AppleScript名：選択中のツメの修正・変更.scpt

tell application "Pages"
　　tell front document
　　　　set aSel to selection
　　　　if aSel = {} then return
　　　　
　　　　set aaSel to first item of aSel
　　　　
　　　　tell aaSel
　　　　　　set row count of it to 15 –表の行数変更
　　　　　　
　　　　　　tell row 14
　　　　　　　　set aCon to value of cell 1
　　　　　　　　
　　　　　　　　tell cell 1
　　　　　　　　　　set value to "14"
　　　　　　　　　　set font name to "7barSPBd"
　　　　　　　　　　set font size to 22.0
　　　　　　　　　　set text color to {32767, 32767, 32767}
　　　　　　　　end tell
　　　　　　　　
　　　　　　end tell
　　　　　　
　　　　　　tell row 15
　　　　　　　　set value of cell 1 to aCon
　　　　　　end tell
　　　　　　
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

Pagesの座標系

Posted on 9月 19, 2021 by Takaaki Naganoya

ここしばらくPagesで書類を作る日々が続いていました。間もなく終わりそうな気配です。

Pagesは不思議なワープロというか簡易DTPアプリケーションで、Keynoteから派生したという独特の出自からして、さっさと何かページレイアウトを作って仕上げる……という味付けのアプリケーションであります。

さっさと作るのは、比較的苦もなくできます。１ページもののレイアウトぐらいならそうでしょう。

複数ページのレイアウトになってくると、やや大変です。ルーラーを表示して、ページのレイアウト範囲に補助線を引いて参考にするという作業が……できないことはないのですが、毎ページルーラーを引き直す必要があります。

書類のマスターページという概念がなく、いきなりテンプレートを作らされます。

それでも、１書類で巨大な内容を作らない。書類を極力小分けにする、といった方法でなんとか使いこなしてきました。

昔のバージョンのPages（iOSとソース共通化する前、旧Pagesと呼ぶ）は、もっとDTPソフトっぽい機能を有しており「普通のユーザーが使えるInDesign」とも言われ、けっこうよかったのですが……。

そんな現在のPagesではありますが、いろいろと対策が進んで作れるドキュメントの幅や分量も増えてきました。いま、200ページぐらいのコンテンツをPagesだけで作っていますが、もちろん書類は小分けにしまくっています。

その、Pagesの書類も分量が増えてくると……ヤツを入れたくなってきます。入れないとわからなくなってきます。ツメです。英語で表現すると、辞書のIndexといえばいいんでしょうか。辞書のページの端についている、アルファベットごとに検索しやすくするために印刷されている記です。

DTP系の人間にはおなじみの「手で作るのはごめん被りたいアイテム第１位」のアレです。手で作るなんて正気の沙汰ではありません。

でも、Pagesにその機能がないので、手作りしました。手作りしたのちに、やっぱプログラムで制御しないとしんでしまうと思い、いろいろ調べだしました。

そして知るのです。Pagesの座標系が全ページつながった独自のものであることを。

つまり、ツメの（縦方向、Y軸）の各ページ単位の座標系がないので、各ページのY座標の原点からの相対座標を計算するためには、ページの物理的なサイズ（座標的なX、Y軸の上限値）を知る必要があります。

ページの物理的なサイズを取る手段があるだろ……ない。

テンプレートには物理的なサイズの定義とかが……ない。

現在編集中の書類のページのサイズがわからないのは、けっこう困りますが……オブジェクトのサイズは計測できるので、あらかじめ各テンプレートの上にページいっぱいのサイズでオブジェクトを作っておいて、そのオブジェクトのサイズ（width、height）を調査。

テンプレート名称なりIDから、ページサイズ表を検索して、座標的なサイズを取得するしかないでしょう。

ヤバイ本のiOS版を発売

Posted on 9月 5, 2021 by Takaaki Naganoya

「空前絶後　あなたの知らないヤバイAppleScriptの世界」のiOS版、FileMaker Goを使って読む電子ブックの販売を開始しました。1,000円です。

→ 販売ページ

なんでこれを作ろうと思ったか？

PDF版をiOS上で読んでいただくことも可能ですが、画面の縦横比とかなんとか。とにかくPDF版の読書体験がよくありません。

そして、AppleのiBooks Storeに本を出すのに、ISBNだ何だといろいろうるさく、これに付き合っていられません。

そのため、いろいろ検討したうえでFileMaker Goに白羽の矢を立て、このアプリケーションを読書用のプラットフォームとして活用するために実験を繰り返していました。

小さな画面で文字を読むのは、ガラケーの時代から大変なことですが、スマホで読んでも大変なことに変わりはありません。

レイアウトに一緒に画像を入れるのも大変なので、基本的に文字コンテンツだけです。一応、なんとかすれば画像表示用レイアウトも混在させて、画像を見ていただくことは可能です。

これまで、PDF版（フル・レイアウト）のオマケとか、サブセットとして出すとか（AppleScriptポケットリファレンス）、そういう試みはしてきましたが、.fmp12単体で売ってみるというのははじめてのことです。iPhoneだけで暮らしたことが皆無なので、まだちょっと見落としていることがあるかもしれませんが、失敗も含めて貴重な経験になることでしょう。

FileMaker Goのデータベースアプリケーションとしての出来については、いまひとつ評価が定まっていないというか、バージョンごとに少しずつ問題があるという見立てになっています。期待をしすぎてはダメというところなんでしょう。

ですが、単にレイアウト切り替えをするとか、フィールドに入れた文字を読むというだけであれば問題が出るとも思えません。

いえ、正直なところiPad mini＋FileMaker Go 18（前バージョン）で読んでいたときに、突如としてフィールドが真っ白になってレコード表示がうまく動かなくなったということはありました。

それでも、iPhone＋FileMaker Go 19であれば、とくに問題らしい問題に遭遇したことはありません。RAMが少ないと環境だと問題があるのかもしれません。

とりあえず、「何かあったとき」のために……筆者に文句を送信できるよう、電子ブックに感想送信フォームをつけておきました。

個人的には、.fmp12形式のままBOOTH上で販売したいのですが、その点について提案したもののお返事をいただいていません。

Numbersの書類上で選択中の範囲のセルの値をシャッフル

Posted on 8月 24, 2021 by Takaaki Naganoya

Numbersの書類上で選択中の範囲のセルの値をシャッフルするAppleScriptです。Numbers書類の表の上で節度ある範囲（テスト用なので…100個ぐらい？）のセルを選択して実行し、シャッフされたデータをNumbersに描き戻します。

＃　単なるデモScriptなので、数千とか数万個のセルを選択した場合には、CSVに書き出してNumbersでオープンし、そのデータ内容をコピペで元のNumbersに書き戻したほうが処理が速いことでしょう。

実際にmacOS 12 beta5でどの程度、処理速度が向上したかを確認するために書いてみました。

–> Watch macbookpro10,1_10.14_macminim1_12 demo

上記の画像で左がMacBookPro 10,1（Intel Core i7 2.66GHz、macOS 10.14.6）、右がMacmini9,1（Apple M1 3.2GHz、macOS 12 beta5）です。

これまで使用してきたMacBook Pro Retina 2012と現行のM1 Mac miniの速度差は気になります。macOS 11上ではM1 Mac miniのほうが10倍遅かったわけですが、最新のmacOS 12 beta5ではどうなのか。

きっちり両方とも揃えてスタートできているわけではありませんが、それでもM1のほうが２倍強ほど高速になっていることがわかります。このぐらいだと友人知人におすすめしても恨まれないレベルだと思います。

ただ、お勧めするにしてもmacOS 12の正式版が出てからですね。自分のMac App Storeに出しているアプリも、macOS 12がリリースされる前にUniversal Binary版を出すと「M1対応にしても速くなっていない」などと文句を言われそうです。

逆に、macOS 12の正式版がリリースされたら「Intel版のままなのに信じられないほど速くなった」ということになりそうです。

AppleScript名：セルの値のシャッフル.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/08/22
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use framework "GameplayKit"
use scripting additions

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　try
　　　　　　　　set theTable to first table whose class of selection range is range
　　　　　　on error
　　　　　　　　return –何も選択されてなかった場合は終了
　　　　　　end try
　　　　　　
　　　　　　tell theTable
　　　　　　　　set mySelectedRanges to value of every cell of selection range
　　　　　　　　set cellList to cell of selection range
　　　　　　end tell
　　　　end tell
　　end tell
end tell

–1D Array Shuffle
set anArray to current application’s NSArray’s arrayWithArray:mySelectedRanges
set randomArray to anArray’s shuffledArray() as list — requires macOS 10.12

tell application "Numbers"
　　tell front document
　　　　tell active sheet
　　　　　　tell theTable
　　　　　　　　repeat with i from 1 to (length of cellList)
　　　　　　　　　　tell item i of cellList
　　　　　　　　　　　　set value to item i of randomArray
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　end tell
　　　　end tell
　　end tell
end tell

★Click Here to Open This Script　

CotEditorで最前面の書類の内容をすべて選択してコマンド実行

Posted on 8月 13, 2021 by Takaaki Naganoya

CotEditorでオープン中の最前面の書類の内容をすべて選択してコマンド（半角→全角　文字変換）を実行するAppleScriptです。

データ処理内容の確認のためにCotEditor上で処理したときに「あれ？　書類の内容を全選択する処理って書いたことなかったわ〜」と気づいて、慌てて書きました。

AppleScript名：最前面のドキュメント内を全選択して全角変換.scpt

tell application "CotEditor"
　　tell front document
　　　　set tLen to length
　　　　set aRange to {0, tLen}
　　　　set range of selection to aRange
　　　　change roman width selection to full
　　end tell
end tell

★Click Here to Open This Script　

Macの製品名を求める（M1以降対応）v1a

Posted on 7月 29, 2021 by Takaaki Naganoya

実行中のMacの製品名を求めるAppleScriptです。もともと、AppleScriptで作成して使用しているアイデアプロセッサ「Kamenoko」で行っている処理なのですが、

M1上で実行すると、製品名は間違えるわ、仕様は合っていないわで散々でした。あ、マシンのアイコンは取ってきていますね。その他のデータはマシン移行をしたときにそのまま前のマシンのデータが残っていたためでしょう。

調べてみると、M1 Macでは従来どおりの製品名データを持っていないようで、Intel Macでは取得できていた製品の名前をわかりやすく記述するデータがありません。各国語にローカライズされていて便利だったのですが。

そこで、M1 MacかどうかのCPUタイプ検出を行い、そのうえで処理を分けることにしました。動作原理上、購入してセットアップしたてのマシンでこのファイルが存在しているかどうか、検証が必要だと思います。

AppleScript名：Macの製品名を求める（M1以降対応）v1a.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/07/28
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.7" — macOS 10.13 or later
use framework "Foundation"
use scripting additions

set hRes to retModelName() of me
–> "Mac mini (M1, 2020)"–macOS 11.5
–> "Mac mini Intelデュアルコアプロセッサおよび統合型グラフィックス搭載、2014年後期に投入。"–macOS 12beta
–> "15インチMacBook Pro, Retinaディスプレイ, Intel Core i7 (Mid 2012)"–macOS 10.14.6

on retModelName()
　　set cRes to CPU type of (system info)
　　
　　if cRes begins with "ARM" then
　　　　–Apple Silicon Mac
　　　　set sText to "defaults read ~/Library/Preferences/com.apple.SystemProfiler.plist" & " ’CPU Names’ | cut -sd ’＼"’ -f 4"
　　　　set hRes to do shell script sText
　　　　return hRes
　　else if cRes begins with "Intel" then
　　　　–Intel Mac
　　　　set hRes to retModelInfo() of me
　　　　return hRes
　　end if
end retModelName

on retModelInfo()
　　tell application "System Events"
　　　　set osVersion to system version of (system info)
　　end tell
　　— macOS 10.15.3 –> 15
　　
　　considering numeric strings
　　　　if osVersion ≥ "10.15" then
　　　　　　–macOS 11.0以降
　　　　　　set pListPath to "/System/Library/PrivateFrameworks/ServerInformation.framework/" & "Versions/A/Resources/ja.lproj/SIMachineAttributes.plist"
　　　　else if osVersion > "10.14" then
　　　　　　–macOS 10.14まで
　　　　　　set pListPath to "/System/Library/PrivateFrameworks/ServerInformation.framework/" & "Versions/A/Resources/Japanese.lproj/SIMachineAttributes.plist"
　　　　end if
　　end considering
　　
　　set aRec to retDictFromPlist(pListPath) of me
　　set hwName to (do shell script "sysctl -n hw.model")
　　set aMachineRec to retRecordByLabel(aRec, hwName) of me
　　set aMachineRec2 to first item of aMachineRec
　　return |description| of _LOCALIZABLE_ of aMachineRec2
end retModelInfo

on retDictFromPlist(aPath)
　　set thePath to current application’s NSString’s stringWithString:aPath
　　set thePath to thePath’s stringByExpandingTildeInPath()
　　set theDict to current application’s NSDictionary’s dictionaryWithContentsOfFile:thePath
　　return theDict as record
end retDictFromPlist

on retRecordByLabel(aRec as record, aKey as string)
　　set aDic to current application’s NSDictionary’s dictionaryWithDictionary:aRec
　　set aVal to aDic’s valueForKey:aKey
　　return aVal as list
end retRecordByLabel

on retRecordByKeyPath(aRec as record, aKey as string)
　　set aDic to current application’s NSDictionary’s dictionaryWithDictionary:aRec
　　set aVal to aDic’s valueForKeyPath:aKey
　　return aVal
end retRecordByKeyPath

–1D Listを文字列長でソート v2
on sort1DListByStringLength(aList as list, sortOrder as boolean)
　　set aArray to current application’s NSArray’s arrayWithArray:aList
　　set desc1 to current application’s NSSortDescriptor’s sortDescriptorWithKey:"length" ascending:sortOrder
　　set desc2 to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:true selector:"localizedCaseInsensitiveCompare:"
　　set bArray to aArray’s sortedArrayUsingDescriptors:{desc1, desc2}
　　return bArray as anything
end sort1DListByStringLength

★Click Here to Open This Script　

targetが重複しているFinder Windowをクローズする

Posted on 7月 22, 2021 by Takaaki Naganoya

日常的に生じている不満を解消するための、ちょっとしたかき捨てScript……になるはずだったものです。

Classic Mac OSからMac OS Xへの移行後、Finderの仕様で大きく変わった点が１つあります。「同じフォルダのウィンドウを複数枚オープンできるようになった」点です。

その結果、

といったように、同じフォルダを指し示すウィンドウが何枚もたまる現象が起きています。これは別にバグでも不具合でもありません。仕様です。

この重複Windowを掃除するためのScriptを書いてみました。

AppleScript名：ターゲットが同じWindowを取得（未遂）.scpt

tell application "Finder"
　　tell window 1
　　　　set aTarg to target
　　end tell
　　
　　set wList to every window whose target　 is equal to aTarg
end tell

★Click Here to Open This Script　

何も考えずに書き始めると、こんな（↑）感じでしょう。ただ、このScriptは動きません。フィルター参照は、たとえばファイル名や拡張子、ファイル種別（kind）あたりには使えるものの、この「target」属性に対しては効きません。

そこで、仕方なくちょっと腰をすえて書いてみました。これ（↓）を動かすと、

のように重複ウィンドウが一掃されます。これでいいはずです。

AppleScript名：targetが重複しているFinder Windowをクローズする.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/07/22
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

set clList to {}

tell application "Finder"
　　set wList to every window
　　–> {Finder window id 1775 of application "Finder", Finder window id 1612 of application "Finder", Finder window id 1740 of application "Finder", Finder window id 1641 of application "Finder", Finder window id 1630 of application "Finder", Finder window id 1618 of application "Finder", Finder window id 1599 of application "Finder", Finder window id 1592 of application "Finder", Finder window id 1586 of application "Finder", Finder window id 1580 of application "Finder", Finder window id 1575 of application "Finder", Finder window id 1569 of application "Finder", Finder window id 1563 of application "Finder"}
　　
　　set tList to (target of every window) as alias list
　　–> {alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Documents:AppleScript 12.0:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:", alias "Macintosh HD:Users:me:Public:ドロップボックス:"}
　　
　　–ターゲットフォルダをユニーク化
　　set bList to removeDuplicates(tList) of me
　　–> {alias "Macintosh HD:Users:me:Documents:AppleScript 12.0:", alias "Macintosh HD:Users:me:Public:ドロップボックス:"}
　　
　　–ユニーク化したターゲットでループ
　　repeat with i in bList
　　　　set j to (contents of i) as alias
　　　　set firstF to true
　　　　
　　　　–ウィンドウでループ
　　　　repeat with ii in wList
　　　　　　set jj to contents of ii
　　　　　　set tmpTarg to (target of jj) as alias
　　　　　　
　　　　　　if tmpTarg is equal to j then
　　　　　　　　–最初の１つ目のWindowだけ残す
　　　　　　　　if firstF = true then
　　　　　　　　　　set firstF to false
　　　　　　　　else
　　　　　　　　　　–２個目以降のWindowはクローズ対象リストに入れる
　　　　　　　　　　set the end of clList to jj
　　　　　　　　end if
　　　　　　end if
　　　　end repeat
　　end repeat
　　
　　–クローズ対象とされるFinder Windowを順次クローズ
　　repeat with i in clList
　　　　set j to contents of i
　　　　try
　　　　　　ignoring application responses
　　　　　　　　close j
　　　　　　end ignoring
　　　　end try
　　end repeat
end tell

on removeDuplicates(aList)
　　set newList to {}
　　repeat with i from 1 to (length of aList)
　　　　set anItem to item 1 of aList
　　　　set aList to rest of aList
　　　　if {anItem} is not in aList then set end of newList to anItem
　　end repeat
　　return newList
end removeDuplicates

★Click Here to Open This Script　

edama2さんがコメント欄に投稿してくださったプログラムを掲載しておきます。自分が「安全のためにこのぐらいの処理は必要（かも？）」と付けまくった処理を「それ別に実際のところ必要ないんじゃない？」と省略された感じです。

あとは、edama2さんのScriptだと「最前面のWindowのtargetと同じtargetを持つWindowをクローズする」という動作ですが、自分のScriptは「targetが重複しているWindowは１つを残してあとすべてをクローズする」という動作を行うので、厳密にいえば違うものです。

AppleScript名：targetが重複しているFinder Windowをクローズする v2.scpt

–　　Created by: edama2
–　　Created on: 2021/07/22

tell application "Finder"
　　tell front window
　　　　set aTarg to target
　　end tell
　　set aList to (every Finder window) as list
　　repeat with num from 2 to count aList
　　　　set anItem to (aList)’s item num
　　　　if (anItem’s target is aTarg) then close anItem
　　end repeat
end tell

★Click Here to Open This Script　

Stream Deck MK.2が登場

Posted on 7月 20, 2021 by Takaaki Naganoya

AppleScriptのランチャーとして手軽に構成を変更して運用できるelgato Stream Deck、Mac上で利用する場合のガイド本を作成中ですが、Stream Deckソフトウェアのv5.xの登場にくわえ、新製品の「Stream Deck MK.2」が登場！

# ニュースをみつけて膝から崩れ落ちました。また追記が必要、、、

新機種のStream Deck mk.2は、従来のStream Deck（15key版）を置き換えるもののようで、あくまでデザインや些細な仕様を変更したもの、と明記されています。フェイスプレートを載せ替えなければ見た目はあまり変わりませんし、対応OSなどの動作条件も変わりません。

・USBケーブルが着脱式に変更（従来は着脱不能）
・スタンドが折りたたみ式ではなくStream Deck XL（24key版）と同様のしっかりしたものに変更。マグネットで脱着
・フェイスプレートを変更可能。７種類のデザインの異なるフェイスプレートを交換し、表面部分をカスタマイズできる（ユーザーがグラフィックを送ってカスタム印刷するという種類のものではなく、異なるデザインの交換式フェイスプレートを追加で購入できる）

深い。とてもよく顧客を見ている。これで欠品とか品薄でなければもっといいのに。

CotEditor Script Pack v3の一般向け配布を開始

Posted on 7月 8, 2021 by Takaaki Naganoya

macOS用テキストエディタ「CotEditor」の機能強化AppleScript集「Script Pack v3」の配布を開始しました。

→ 配布ページ

Script Packは従来バージョン同様に、機能強化ユーティリティScript集の「PowerPack」および、AppleScriptによる基礎的なCotEditorの操作を解説した「Basic Pack」から構成されています。macOS 10.15.xおよび11.x＋CotEditor v4.xとの組み合わせで利用することを想定しています。M1 Mac上でも動作確認ずみです。

PowerPack v3では、CotEditor上で編集中のテキストの文字種別を集計してグラフ表示させたり、編集中のテキストで使われている単語をもとにタグクラウド表示を行うなど、従来では把握しにくかったテキストの傾向をビジュアル表示する機能を追加しています。

外部アプリケーションを使わずにCSVデータのプレビュー（100行までの制限あり）、Markdownテキストのプレビューを行えるなど、CotEditorの動作速度を損うことなく大幅な機能追加を行なっています。

CotEditor強化Script集「PowerPack v3」の解説本を発売

Posted on 7月 7, 2021 by Takaaki Naganoya

電子書籍の新刊を出しました。「機能強化AppleScript集 CotEditor用 PowerPack 取扱説明書」ページ数：191ページ、フォーマット：PDF＋Zipアーカイブ（PowerPack、BasicPack）となっています。

→ 販売ページ
→ お試し版書籍ダウンロード

「CotEditor」は、Github上のオープンソース・プロジェクトで公開されているmacOS用の高機能テキストエディタです。本書は、そのCotEditorに便利で強力な機能を追加できるAppleScript集「PowerPack v3」の取扱説明書です。

本書にはPowerPack v3（ソース編集可能版）＋Basic Packが含まれています。現在準備中の一般配布版のPowerPack v3は内容が見られません。ただ実行するだけです。

新たにリリースしたPowerPackバージョン3では、グラフ表示やタグクラウド表示などの「ド派手な機能」を追加。Markdown書類のプレビューやCSVデータの表プレビュー、タブ区切りテキストによるKeynote書類の生成、ミュージック.appのトラックへの歌詞データの書き込みなど、AppleScriptによる高度な処理を手軽にご堪能いただけます。

→ 書籍サポートページ

M1 Mac miniのベンチマーク 1万要素の1次元配列ソート

Posted on 6月 21, 2021 by Takaaki Naganoya

M1 Mac miniを使ってみて、「なーんかMacBook Pro Retina 2012とかわんねーなー」と感じていましたが、本当にそんな感じでした。

＃　後日、詳細に検証したところM1 Mac＋macOS 11.xではAppleScriptからのCocoa呼び出しが大幅に遅くなっていることが判明。処理性能重視のメインCPUコアではなく、省エネのサブCPUコアで実行されていることがわかり、これをAppleにレポートしてmacOS 12からはAppleScript＋Cocoa呼び出しの処理速度が大幅に改善されました

Webブラウザの動作とかディスクI/Oなど、キビキビ動いて快適なのですが、AppleScriptを書いて動かしてみると……GUIアプリの操作は速い（Mac mini 2014比で2〜3倍速い）のですが、Cocoa Scriptingしていると速くなった感じがしません。

Xcode上でCocoa AppleScriptアプリケーションを書いて動かしてみると、冒頭のような感想になります。

机の上にマシンが５台ぐらい並んでおり、これらすべてでベンチマークを実施。体感速度を裏付ける結果が出ました。

#　MacBook Air 2011のベンチマーク計測が抜けていました、、、、

上から３番目のマシンは仲間からの借り物の検証用マシンで、前主力環境のMacBook Pro Retina 2012とは別物で、HDDで動作しているマシンです。macOS 10.15の動作確認用マシンで、MacBook Pro Retina 2012よりも少しCPUが速いマシンでもあります。

なので、MacBook Pro Retina 2012をmacOS 10.15にアップデートすると、ほぼこれと同じ結果になるはずです（もったいなくてアップデートしませんが）。

macOS 10.14から10.15に移行したときに「全体的に速度が遅くなった」との証言をShane Stanleyからももらっています。

全体的な傾向として、「macOS 10.15で大幅な速度低下があり、その低下分をM1 Macのハードウェアとしての速さが穴埋めしている」という印象。macOS 10.15はBeta段階で「こんなのはダメ、使い物にならない」と判断し、パスして10.14を使い続けるという判断を行なっていました。

搭載メモリはM1 Mac miniとMac mini 2014が16GB、MacBook Pro 2012とMacBook Pro Retina 2012が8GBです。

AppleScript名：ASで1D Listをソート（１万件）

use AppleScript version "2.7"
use framework "Foundation"
use scripting additions

script spd
　　property aList : {}
　　property aRes : {}
　　property bRes : {}
end script

set (aRes of spd) to {}
set (bRes of spd) to {}

–テスト用データリストの作成（1万アイテム）
set (aList of spd) to {}
repeat with i from 1 to 10000
　　set the end of (aList of spd) to (random number from 10000 to 99999)
end repeat

–昇順ソートの時間計測
set a1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()

set (aRes of spd) to sort1DList_ascOrder_((aList of spd), true)

set b1Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()

set c1Dat to b1Dat – a1Dat

–降順ソートの時間計測
set a2Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()

set (bRes of spd) to sort1DList_ascOrder_((aList of spd), false)

set b2Dat to current application’s NSDate’s timeIntervalSinceReferenceDate()
set c2Dat to b2Dat – a2Dat

return {c1Dat, c2Dat}

–1D Listをsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DList:theList ascOrder:aBool
　　set aDdesc to current application’s NSSortDescriptor’s sortDescriptorWithKey:"self" ascending:aBool selector:"compare:"
　　set theArray to current application’s NSArray’s arrayWithArray:theList
　　return (theArray’s sortedArrayUsingDescriptors:{aDdesc}) as list
end sort1DList:ascOrder: