Keynoteで選択中のGroup内オブジェクトを座標でソートし、テキスト抜き出し

Posted on 5月 15, 2022 by Takaaki Naganoya

Keynote v12.0以降でオープン中の最前面の書類の、表示中のスライド（ページ）上で選択中のグループから、その内部に収められているオブジェクトからテキストを取り出し、リスト（配列）にまとめるAppleScriptです。

▲書類上のオブジェクト（グループ）を選択した状態

▲１冊分のデータがグループにまとめられており、グループ内にオブジェクトを格納

いったんデータを組み上げた「書類」からデータを抜き出すのは、AppleScriptの重要な仕事です。各データ内のフィールドについて座標情報から自動判別するようにしていますが、座標値が想定どおりになっていない場合もあるため、これでもまだ不十分なので、相対的な位置関係（左上、右上、下　などといった）を定義してデータを取り出すようにするとよいでしょう。

……そこまで高度なものを作らなくても、文字列の長さに着目してソートしたら瞬殺でした。

AppleScript名：選択中のGroup内オブジェクトを座標でソートし、テキスト抜き出し.scpt

use AppleScript version "2.8"
use framework "Foundation"
use framework "AppKit"
use scripting additions

property NSFont : a reference to current application’s NSFont
property NSColor : a reference to current application’s NSColor
property NSFontAttributeName : a reference to current application’s NSFontAttributeName
property NSMutableAttributedString : a reference to current application’s NSMutableAttributedString
property NSForegroundColorAttributeName : a reference to current application’s NSForegroundColorAttributeName

script spd
　　property allList : {}
　　property aaSel : {}
end script

set (allList of spd) to {}

tell application "Keynote"
　　set aVer to version
　　if aVer < "12.0" then return
　　
　　set acceptClass to {text item, shape}
　　
　　tell front document
　　　　set (aaSel of spd) to selection –need Keynote v12.0 or later
　　　　
　　　　repeat with i in (aaSel of spd)
　　　　　　set j to contents of i
　　　　　　set aClass to class of j
　　　　　　
　　　　　　if aClass = group then
　　　　　　　　tell j
　　　　　　　　　　set gItemList to every iWork item
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　set posList to {}
　　　　　　　　set aCount to 1
　　　　　　　　
　　　　　　　　repeat with ii in gItemList
　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　set bClass to class of jj
　　　　　　　　　　
　　　　　　　　　　if bClass is in acceptClass then
　　　　　　　　　　　　tell jj
　　　　　　　　　　　　　　set {posX, posY} to position
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　try
　　　　　　　　　　　　　　　　set tmpStr to object text as string
　　　　　　　　　　　　　　on error
　　　　　　　　　　　　　　　　set tmpStr to ""
　　　　　　　　　　　　　　end try
　　　　　　　　　　　　end tell
　　　　　　　　　　　　
　　　　　　　　　　　　set the end of posList to {positionX:posX, positionY:posY, objID:aCount, myStr:tmpStr}
　　　　　　　　　　end if
　　　　　　　　　　
　　　　　　　　　　set aCount to aCount + 1
　　　　　　　　end repeat
　　　　　　　　
　　　　　　　　–座標データをもとにソート
　　　　　　　　set sortedList to sortRecListByLabel(posList, {"positionY", "positionX"}, {true, true}) of me
　　　　　　　　
　　　　　　　　–１グループ分のテキストを組み立てる
　　　　　　　　set tmpList to {}
　　　　　　　　repeat with ii in sortedList
　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　set aStr to myStr of jj
　　　　　　　　　　set the end of tmpList to aStr
　　　　　　　　end repeat
　　　　　　　　set the end of (allList of spd) to tmpList
　　　　　　end if
　　　　end repeat
　　end tell
end tell

return (allList of spd)
–> {{"変数名", "❺", "意外と苦労している人が多い、変数やプロパティ名の命名ルール。とくに、予約語と衝突しない名前について"}, {"条件分岐", "❼", "条件分岐はプログラムに必須。自転車でいえば、カーブで曲がれないとか、水たまりを避けられないぐらい困ります。"}, {"用語辞書", "❹", "読めないと書けない、でも、あの人もこの人も読めない用語辞書。自由自在に読めれば、自由自在に書ける！"}, {"ループ処理", "➓", "プログラムをシンプルに書くための一番大事な構文。書き方によって速度が違ったり、高度な処理を簡潔に書ける！"}, {"アプレット", "⓫", "AppleScriptをアプリケーションとして書き出す、簡易アプリケーション「アプレット」の最新動向！"}, {"間接指定", "❶", "対象としたデータだけでなく、幅広いデータに対応できるよう、プログラムに柔軟性を与える間接指定"}, {"ダイアログ表示", "❾", "簡単に行えるメッセージ表示手段。外部ライブラリの利用でさらなる高機能ダイアログを紹介。"}, {"環境整備", "❽", "macOSに標準で入っているツールを呼び出しやすくしたり設定したりする程度。全体像を掴んでレッツ環境整備。"}, {"フィルタ参照", "❻", "AppleScript独特の概念で、「膨大なデータから正規表現で絞り込む」などの他の処理系と異なる、基礎にして奥義"}, {"tellブロック", "❷", "AppleScriptの７割以上を占める、tellブロックの記述や整理方法を楽に書く秘訣のかずかず"}, {"❸", "ファイルパス", "まさに「基礎」中の「基礎」。「できて当たり前」といえるパス操作。知っているだけで差がつく基礎"}}

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as list, ascendF as list)
　　set aArray to current application’s NSArray’s arrayWithArray:aRecList
　　
　　set aCount to length of aLabelStr
　　set sortDescArray to current application’s NSMutableArray’s new()
　　repeat with i from 1 to aCount
　　　　set aLabel to (item i of aLabelStr)
　　　　set aKey to (item i of ascendF)
　　　　set sortDesc to (current application’s NSSortDescriptor’s alloc()’s initWithKey:aLabel ascending:aKey)
　　　　(sortDescArray’s addObject:sortDesc)
　　end repeat
　　
　　return (aArray’s sortedArrayUsingDescriptors:sortDescArray) as list
end sortRecListByLabel

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（10）ループ処理

Posted on 5月 13, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第10巻、「ループ処理」です。PDF 33ページ、サンプルAppleScriptのZipアーカイブを添付。

→ 販売ページ

ループ処理について、さまざまなrepeat文のバリエーションをまんべんなくすべて知って理解するよりも「間違いなく必要な場所で使える」ことが重要です。

repeat文にもいくつか書き方はあるものの、おおよそ２パターンぐらいでだいたい足ります。

それでも、複数の配列を同時にループしなくてはならないとか、ステップ値を想定の値に合わせるための調整とか、ノウハウらしきものはいろいろあります。

また、参照値をそのまま使うとエラーになる例もあるため、「contents of」でオブジェクトを取り出す必要があるといったささいなノウハウが必要なものでもあります。

■ループによる繰り返し処理

AppleScriptの制御構文
繰り返しループ
repeat文①
repeat文②
repeat文③
repeat文④
repeat文⑤
repeat文⑥
exit repeat
多重ループ＋exit repeat

■アプリケーションから取得したオブジェクトでループ

アプリケーションのオブジェクトを処理
Photos上の選択中の写真から情報を取得
Keynoteで選択中のオブジェクトを位置でソート
Numbersで表のセルが連結されていたら分離
targetが重複しているFinder Windowをクローズする
ミュージック.appで選択中のtrackの情報取得
大量のオブジェクト受信に備える

■高度な処理を簡潔に記述

複数の配列の同時ループ
ページ分け
再帰処理

Safariで表示中のYouTubeムービーのサムネイル画像を取得

Posted on 5月 9, 2022 by Takaaki Naganoya

Safariで表示中のYouTubeムービーのサムネール画像を取得、保存、表示するAppleScriptです。

YouTubeのムービーのサムネール画像の取得方法を確認し、動作確認用にダイアログ表示＋画像保存の機能を追加したものです。Script Debugger上で動かしている分には、NSImageの内容を結果表示ビューワで自動表示されますが、ない人向けに付けた機能です。

画像自体は、「ピクチャ」フォルダにUUIDつきでPNG形式で保存します。

–> Download Script bundle with Library

掲載リストには、画像表示ライブラリが含まれていないため、そのままでは実行できません。上記のScript Bundleをダウンロードして実行する必要があります。

AppleScript名：Safariで表示中のYouTubeムービーのサムネイル画像を取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/09
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use imgLib : script "imageDisplayLib"

property NSUUID : a reference to current application’s NSUUID
property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property NSPNGFileType : a reference to current application’s NSPNGFileType
property NSURLComponents : a reference to current application’s NSURLComponents
property NSBitmapImageRep : a reference to current application’s NSBitmapImageRep
property NSMutableDictionary : a reference to current application’s NSMutableDictionary

tell application "Safari"
　　tell front document
　　　　try
　　　　　　set aURL to URL
　　　　on error
　　　　　　set aURL to "https://www.youtube.com/watch?v=_fmDtIV9vvI"
　　　　end try
　　end tell
end tell

if aURL does not start with "https://www.youtube.com/watch?" then return

set urlDict to parseURLParamsAsDict(aURL) of me
set aParam to urlDict’s valueForKey:"v"
if aParam = missing value then return

set imgURL to "https://i1.ytimg.com/vi/" & (aParam as string) & "/mqdefault.jpg"
set newURL to |NSURL|’s URLWithString:imgURL
set aImg to NSImage’s alloc()’s initWithContentsOfURL:newURL

set imgPath to (POSIX path of (path to pictures folder) & ((aParam as string) & "_") & (NSUUID’s UUID()’s UUIDString()) as string) & ".png"

–Save
saveNSImageAtPathAsPNG(aImg, imgPath) of me

–Display
dispImage(aImg, "YouTube thumbnail") of imgLib

on parseURLParamsAsDict(aURL)
　　set components to NSURLComponents’s alloc()’s initWithString:aURL
　　set qList to (components’s query())’s componentsSeparatedByString:"&"
　　
　　set paramRec to NSMutableDictionary’s dictionary()
　　
　　repeat with i in qList
　　　　set keyAndValues to (i’s componentsSeparatedByString:"=")
　　　　(paramRec’s setObject:(keyAndValues’s objectAtIndex:1) forKey:(keyAndValues’s objectAtIndex:0))
　　end repeat
　　
　　return paramRec
end parseURLParamsAsDict

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to NSBitmapImageRep’s imageRepWithData:imageRep
　　
　　set pathString to NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　
　　set myNewImageData to (aRawimg’s representationUsingType:(NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（９）ダイアログ表示

Posted on 5月 6, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第９巻、「ダイアログ表示」です。PDF 43ページ、サンプルScript、AppleScriptライブラリのZipアーカイブを添付。

→ 販売ページ

ダイアログ表示については、たいへん基礎的な内容でありながらも数多くの機能が盛り込まれています。サードパーティ側でさまざまなダイアログを作れるようになってきて、「みんなが思っているよりも、けっこう便利」な環境ができています。

利用するかしないかは、皆様の判断によると思いますが、実際に利用した方は割と便利で手放せなくなるようです。

ダイアログ表示

標準搭載のさまざまなダイアログ表示機能
メッセージ表示系ダイアログ
メッセージ表示系ダイアログ
ファイル選択ダイアログ
フォルダ選択ダイアログ
ファイル名選択ダイアログ
多項目選択系ダイアログ
色選択ダイアログ
LAN内のリモート資源の選択
ローカルのアプリケーションの選択
リモート・アプリケーションの選択

AppleScriptライブラリを利用したダイアログ表示

AppleScriptライブラリの用語辞書の確認方法
筆者のライブラリにはサンプルScript掲載
iPhoneやiPad、MacとAirDrop通信
チェックボックス選択ダイアログを表示
日付選択ダイアログを表示
場所選択ダイアログを表示
複数ポップアップ選択ダイアログを表示
指定のRTF書類から抽出した書式を選択するダイアログ
指定の場所を異なる拡大倍率で地図表示
表形式のデータをダイアログ表示
ラベルつきテキストフィールドを表示/データ修正
指定色の一覧選択ポップアップメニューを表示
Scriptでカスタマイズ可能な複雑なダイアログ

Keynoteのタイトル内の強制改行コードを置換….できない？

Posted on 5月 3, 2022 by Takaaki Naganoya

Keynote v12のスライド（ページ）内のタイトル（default title item）内のテキスト（object text）の強制改行を置換（削除）できないという件についての試行錯誤です。

もともと、v12以前のバージョンのKeynoteでは、LF+LFを削除することで、タイトル内のテキストの改行削除は行えていました。

ただ、同様の処理では強制改行を削除し切れないようで….

--> {"AppleSript＋NSImageでよく使う
 基礎的な処理一覧", "画像ファイル 変換処理", "画像回転処理", "画像ファイルからの 
情報取得処理", "画像リサイズ処理", "画像フィルタ処理"}

いまひとつすっきりしません。

Keynoteのタイトル文字列をコピーして、CotEditor（文字コードをAppleScriptと同じUTF16BEに変更）の書類上にペーストすると0Ahと表示するのですが、どうもKeynote上では異なるようで困ります。

AppleScript名：Keynote v12上の選択中のスライドのタイトルをテキスト化（改行削除）（未遂）.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/05/03
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

set repTargList to {string id 10 & string id 10, string id 10, string id 11, string id 13} –LF,CR,VTab一括置換

tell application "Keynote"
　　tell front document
　　　　set aSel to selection
　　　　set aList to {}
　　　　
　　　　repeat with i in aSel
　　　　　　set tmpClass to class of i
　　　　　　if tmpClass = slide then
　　　　　　　　set tmpStr0 to object text of default title item of i
　　　　　　　　set hexList to retHexDumpedStr(tmpStr0) of me
　　　　　　　　set tmpStr1 to (paragraphs of tmpStr0) –パラグラフごとにlistにしてみた
　　　　　　　　log tmpStr1
　　　　　　　　set tmpStr2 to replaceTextMultiple(tmpStr1 as string, repTargList, "") of me as string
　　　　　　　　set the end of aList to tmpStr2
　　　　　　end if
　　　　end repeat
　　end tell
end tell

return aList

–文字列の前後の改行と空白文字を除去
on cleanUpText(someText)
　　set theString to current application’s NSString’s stringWithString:someText
　　set theString to theString’s stringByReplacingOccurrencesOfString:" +" withString:" " options:(current application’s NSRegularExpressionSearch) range:{location:0, |length|:length of someText}
　　set theWhiteSet to current application’s NSCharacterSet’s whitespaceAndNewlineCharacterSet()
　　set theString to theString’s stringByTrimmingCharactersInSet:theWhiteSet
　　return theString as text
end cleanUpText

–指定文字列からCRLFを除去
on cleanUpCRLF(aStr)
　　set aString to current application’s NSString’s stringWithString:aStr
　　set bString to aString’s stringByReplacingOccurrencesOfString:(string id 10) withString:"" –remove LF
　　set cString to bString’s stringByReplacingOccurrencesOfString:(string id 13) withString:"" –remove CR
　　set dString to cString as string
　　return dString
end cleanUpCRLF

–文字置換ルーチン
on repChar(origText as string, targStr as string, repStr as string)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

–任意のデータから特定の文字列を複数パターン一括置換
on replaceTextMultiple(origData as string, origTexts as list, repText as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to origTexts
　　set origData to text items of origData
　　set AppleScript’s text item delimiters to {repText}
　　set origData to origData as text
　　set AppleScript’s text item delimiters to curDelim
　　return origData
end replaceTextMultiple

on hexDumpString(aStr as string)
　　set theNSString to current application’s NSString’s stringWithString:aStr
　　set theNSData to theNSString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set theString to (theNSData’s |debugDescription|()’s uppercaseString())
　　
　　–Remove "<" ">" characters in head and tail
　　set tLength to (theString’s |length|()) – 2
　　set aRange to current application’s NSMakeRange(1, tLength)
　　set theString2 to theString’s substringWithRange:aRange
　　
　　–Replace Space Characters
　　set aString to current application’s NSString’s stringWithString:theString2
　　set bString to aString’s stringByReplacingOccurrencesOfString:" " withString:""
　　
　　set aResList to splitString(bString, 2)
　　–> {"E3", "81", "82", "E3", "81", "84", "E3", "81", "86", "E3", "81", "88", "E3", "81", "8A"}
　　
　　return aResList
end hexDumpString

–Split NSString in specified aNum characters
on splitString(aText, aNum)
　　set aStr to current application’s NSString’s stringWithString:aText
　　if aStr’s |length|() ≤ aNum then return aText
　　
　　set anArray to current application’s NSMutableArray’s new()
　　set mStr to current application’s NSMutableString’s stringWithString:aStr
　　
　　set aRange to current application’s NSMakeRange(0, aNum)
　　
　　repeat while (mStr’s |length|()) > 0
　　　　if (mStr’s |length|()) < aNum then
　　　　　　anArray’s addObject:(current application’s NSString’s stringWithString:mStr)
　　　　　　mStr’s deleteCharactersInRange:(current application’s NSMakeRange(0, mStr’s |length|()))
　　　　else
　　　　　　anArray’s addObject:(mStr’s substringWithRange:aRange)
　　　　　　mStr’s deleteCharactersInRange:aRange
　　　　end if
　　end repeat
　　
　　return (current application’s NSArray’s arrayWithArray:anArray) as list
end splitString

–与えられたデータ内容をhexdumpして返す
on retHexDumpedStr(aStr)
　　set aRes to do shell script "echo " & quoted form of aStr & " | hexdump -v "
　　return aRes
end retHexDumpedStr

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（８）環境整備

Posted on 4月 28, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第８巻、「環境整備」です。PDF 42ページ、スクリプトエディタ上にAppleScriptのスニペットを入力する開発支援用Script集「Piyomaru Script Assistant v2.0」つき。

→ 販売ページ

AppleScriptの開発に必要なツールはmacOSに最初から入っています。整備も何も、追加で揃える必要がありそうなのは、Late Night SoftwareのScript Debuggerのお試し版ぐらいのものです。情報として伝えるなら100文字以内で終わってしまいそうなお話です。

それでも「難しい」と感じる方がいるとすれば、それはノウハウが分散していて、どれを使うとかどれをどう設定しておくといった話がまとめられていないから、ということなんでしょう。ここに、AppleScriptの開発環境がどういうものか、詳細にご紹介いたします。

環境整備〜超基礎編

自分でマシンの管理を行えることが必要
AppleScriptの開発環境〜安定動作の平均的な環境
キーボード/マウスの選択
プリンタは？
ネット接続
複数台あったほうが便利
iPhoneと共通のiCloud設定
Apple Developper Account

環境整備〜構築編

スクリプトエディタ：編集、実行、書き出し
アクティビティモニタ：プロセス監視、終了
Script Debugger：統合開発環境
作業手順をまとめておく：Keynote
各種AppleScriptライブラリ
Piyomaru Script Assistant
各種AppleScript対応アプリケーション

環境整備〜設定編

スクリプトエディタ：構文フォーマット設定
スクリプトエディタ：ライブラリ設定
スクリプトメニュー
Finderの拡張子設定を使用環境で統一
システム環境設定
システム環境設定

環境整備〜メンテナンス編

定期的な再起動
定期的なディスクメンテナンス
異常プロセスの監視

新発売：AppleScript基礎テクニック集（７）条件分岐（if文）

Posted on 4月 26, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第７巻、「条件分岐（if文）」です。PDF 34ページ、掲載Scriptアーカイブつき。

→ 販売ページ

if文が書けないとプログラムを書けないも同然。自転車でいえば、カーブで曲がれないとか、水たまりを避けられない走り方しかできない状態です。if文で華麗なコーナリングを決められたら、初心者レベルは超えられたことでしょう。

if文とは？

条件分岐ってなに？
if文による条件分岐
if文による条件分岐
if文による条件分岐
if文で気をつけるべき点

比較演算とは？

比較演算ってなに？（数値）〜同一比較
比較演算ってなに？（数値）〜大小比較
参考資料：比較演算の演算子
文字の大小比較演算
特別な文字比較を行えるオプション
特別な文字比較のサンプル
複数の条件をリストにして、is inで照合
文字を含む、始まる、終わる演算
論理の反転
参考資料：is in演算子のはたらき
参考資料：「計算機」で16→10進数変換

より高度な条件分岐

UnicodeのNormalizeを強制して文字比較
アプリケーションのオブジェクト同士の照合
異なるアプリケーションのオブジェクト同士の照合

PFiddlesoft UI Browserが製品終了に

Posted on 4月 23, 2022 by Takaaki Naganoya

AppleScriptの環境を構成する大きな要素部品である「PFiddlesoft UI Browser」が、開発者のBill Cheesemanのリタイアに伴い、製品終了になることが2022/4/17に表明されました。

GUI Scriptingの登場と同時に、この技術を完全にカバーし、生産性を格段に向上させるツールとしてUI Browserが登場しました。これを持っているかどうかでGUI ScriptingによるScript記述は天と地ほども差が出ます。

AppleScriptを書くのであれば、まず必携といっても過言ではないというツールであったわけです。

Script DebuggerとUI Browserを柱として、AppleScript系の開発環境が構築されてきたわけで、たいへんに重要なパーツであったことは誰にも否定できないことでしょう。

Bill Cheesemanの動向は定期的にウォッチしていたのですが、「引退した法律家からプログラマに転身」「いいかげん、けっこう高齢」といった認識は持っていたものの、「PreFab　Software」から改名した「PFiddlesoft」というユニット名を使っていたあたりで「誰かに引き継ぎを考えているんだろう」と（勝手に）思っていました。

ただ、C++でゴリゴリにmacOSの深いところを叩きまくるようなアクセシビリティ系のプログラムを組むことはストレスが大きかったことでしょう。Cocoaの上からAppleScriptでOSのサービスを叩いていても「またバグが」「勝手な仕様変更が」などと苛立たしいことこの上ないわけで、もっと深い部分で叩いていたら、よりストレスは大きなものとなっていたことでしょう。

正直、このあたりの技術について同等の理解と技術力を有している人間といわれると、世界でも６人ぐらいしかいないことでしょう。Shane、Mark、Sal、Has、あとはAppleの現役エンジニア（世間せまっ！）。

その割にユーザーサポートの負担なども重圧となっていたことでしょうし、Billが続けられないという英断をしたことについては尊重すべきだと考えます。

とはいえ、その大きすぎる「穴」をどうやって埋めていくかというテーマを抱えてしまっているわけです。LateNight Softwareが継承する、とかいった話は（技術的な）可能性としてありそうではあるものの、（マーケティング的かつ費用的な意味では）ちょっとわかりません。

UI Browserの代替技術、代替製品という意味では「Piyomaru Dynamic Menu Clicker」があります。メニューについていえば、「このアプリケーションのこのメニューのこの項目」と指定すると、それを強制的にクリックするような仕組みをすでに作れています。

ただ、Webブラウザ上のコンテンツをGUI Scriptingを用いて操作するような用途では、ちょっと代替手段を持っていません。

UI Browserの基礎的な部品を各種Frameworkとして提供しているものの、ちょっとAppleScriptから気軽に叩いて機能を呼び出すというのは難しそうだと思われました。

UI Browser自体、販売終了するということなので、必要な人はすぐに購入すべきでしょう。そして、Webサイトも閉じる予定とのことなので、必要な資料などをPFiddlesoftのWebサイトからダウンロードしてバックアップしておくべきでしょう。

新発売：AppleScript基礎テクニック集（５）〜変数、プロパティ名

Posted on 4月 20, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第５巻、「変数、プロパティ名」です。PDF 31ページ、掲載Scriptアーカイブつき。

→ 販売ページ

変数名の決め方……自分がそこで困ったり悩んだり苦しんだりしたことはないのですが、いろいろ聞いてみると意外なほど困っている様子。え、そこなの？？？？

長い変数名、短い変数名、プロパティとグローバル変数はどこが違うの？　といった聞きたいけど聞く相手がいないといった「素朴な疑問」をなるべくあぶり出して、明確になるようまとめてみました。PDF 31ページ、掲載ScriptのZipアーカイブを添付。

変数/プロパティとは？

変数ってなに？
変数に入れられるものは？
ローカル変数とグローバル変数
変数の型ってあるの？
変数の型の確認方法は？
propertyと変数の違い（1/2）
propertyと変数の違い（2/2）
暗黙のrunハンドラ
暗黙のrunハンドラ内の変数
propertyの有効範囲＝スコープ
propertyの有効範囲を超える
暗黙のrunハンドラ内の変数と各ローカル変数との衝突？

変数/プロパティの名前の決め方

変数名の命名ルール
「予約語」と衝突しない命名を
「予約語」と衝突しない命名を
アプリケーションの予約語
AppleScriptの単語が何として認識されているか
かんたんな変数名/プロパティ名の付け方
変数/プロパティの運用の要点

macOS 12.4beta1で「GUIなしツールから起動したAppleScriptでUTIを取得できない」バグ？

Posted on 4月 18, 2022 by Takaaki Naganoya

スクリプトメニューやService Stationなど、「メニューやウィンドウを持たないGUIなしツール」がたくさんmacOS環境にありますが、macOS 12.4上ではこれらのAppleScript起動ツールから起動したAppleScriptから、UniformtypeIdentifiers.frameworkを用いたUTIの取得をブロックされているようです。

スクリプトメニューで実行を確認した（途中までで実行がブロックされてしまった）AppleScriptを、スクリプトエディタ上で実行したところ、問題なく実行されます。ちなみに、内容は選択した画像ファイルをPixelmator Proで超解像処理してクリップボードに設定する（コピーする）という「おかわいらしい」内容のものです。

Service Stationは、コンテクストメニューからのAppleScript実行を可能にするAppleScript実行ツールですが、これについてもしかるべきハンドラを書いて同じAppleScriptを実行させるようにしてみたものの、UTIの取得をブロックされるようです。

→ 追試で、Terminal.app上からosascript経由で実行してみたところ、UniformtypeIdentifiers.frameworkの呼び出しに失敗することが判明

明示的にMain threadで実行しないとダメ？？？＞UniformtypeIdentifiers.framework

AppleScript名：🟧選択中の画像を超解像💝処理してコピー.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2021/03/25
—
–　　Copyright © 2021 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.8" — Yosemite (10.10) or later
use framework "Foundation"
use framework "UniformtypeIdentifiers"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSPredicate : a reference to current application’s NSPredicate
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

set acceptUTI to "public.image"

set aFile to choose file
(*
tell application "Finder"
　　set aFile to first item of (selection as alias list)
end tell
*)

–set aUTI to getUTIFromFile(aFile) of me –選択ファイルからUTIを
–display dialog aUTI
–if aUTI is equal to missing value then return

–set uRes to filterUTIList({aUTI}, acceptUTI) of me –選択ファイルのUTIが、受付可能UTIに含まれるかどうかチェック
–if uRes is equal to {} then return –選択したファイルが画像ではなかった

–掃除
tell application "Pixelmator Pro" to close every document without saving

–取得した画像を超解像処理してコピー
tell application "Pixelmator Pro"
　　try
　　　　open aFile
　　on error
　　　　close every document without saving
　　　　return
　　end try
　　
　　tell front document
　　　　with timeout of 3000 seconds
　　　　　　super resolution
　　　　end timeout
　　end tell
end tell

tell application "Pixelmator Pro"
　　tell front document
　　　　select all
　　　　copy
　　　　close without saving
　　end tell
end tell

on getUTIFromFile(aFile)
　　set aPath to POSIX path of aFile
　　
　　set aWS to current application’s NSWorkspace’s sharedWorkspace()
　　set pRes to (aWS’s isFilePackageAtPath:aPath) as boolean
　　if pRes = false then
　　　　set superType to (current application’s UTTypeData)
　　else
　　　　set superType to (current application’s UTTypePackage)
　　end if
　　
　　set pathString to current application’s NSString’s stringWithString:aPath
　　set aExt to (pathString’s pathExtension()) as string
　　
　　set aUTType to current application’s UTType’s typeWithFilenameExtension:aExt conformingToType:(superType)
　　
　　set aUTIstr to aUTType’s identifier() as string
　　return aUTIstr
end getUTIFromFile

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

★Click Here to Open This Script　

Keynoteで選択中のtext itemとshapeをもとにtext itemを敷き詰める

Posted on 4月 15, 2022 by Takaaki Naganoya

Keynote v12で正常化した「selection」を用いて、選択中のshapeオブジェクトの範囲に、選択中のtext itemを指定数敷き詰めるAppleScriptです。

–> Watch Demo Movie

Keynote書類上に、敷き詰める領域を示すshapeオブジェクトを１つ、敷き詰める内容を示すtext itemオブジェクトを１つ配置し、これら２つを選択して本Scriptを実行。

選択状態で実行。

指定の最小文字サイズから最大文字サイズ（Keynote書類上で選択したtext item中の文字サイズ）までの間で乱数選択しつつ、指定個数を指定エリア中に作成します。

AppleScript名：選択中のtext itemとshapeをもとにtext itemを敷き詰める.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/04/15
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

property textItem : missing value
property shapeItem : missing value

property objMax : 200 –生成するオブジェクト（text item）の個数
property fontSizeMin : 12 –生成するオブジェクト内のobject textのフォントサイズ（これ以下のサイズは生成しない）

tell application "Keynote"
　　set aVer to (version as real)
　　if aVer < 12 then return
　　
　　tell front document
　　　　–書類上で選択中のオブジェクトを種別に抽出する
　　　　set aaSel to selection
　　　　if length of aaSel is not equal to 2 then error "You have to select one text item and one shape."
　　　　
　　　　repeat with i in aaSel
　　　　　　set j to contents of i
　　　　　　set tmpClass to class of j
　　　　　　
　　　　　　if tmpClass = text item and textItem = missing value then
　　　　　　　　set textItem to j
　　　　　　else if tmpClass = shape and shapeItem = missing value then
　　　　　　　　set shapeItem to j
　　　　　　end if
　　　　end repeat
　　　　
　　　　if {textItem, shapeItem} contains missing value then error "Selected objects are not suitable"
　　　　
　　　　
　　　　–選択されたshapeオブジェクトから情報を取得
　　　　set aPos to (position of shapeItem)
　　　　set minX to item 1 of aPos
　　　　set maxX to minX + (width of shapeItem)
　　　　set minY to item 2 of aPos
　　　　set maxY to minY + (height of shapeItem)
　　　　
　　　　–選択されたtext itemオブジェクトから情報を取得
　　　　set maxFSize to size of object text of textItem
　　　　set oText to object text of textItem
　　　　set tWidth to width of textItem
　　　　set tHeight to height of textItem
　　　　
　　　　
　　　　–shapeオブジェクトで指定された領域に、text itemを生成
　　　　repeat objMax times
　　　　　　–座標を乱数で指定
　　　　　　set randomX to random number from minX to (maxX – tWidth)
　　　　　　set randomY to random number from minY to (maxY – tHeight)
　　　　　　–文字サイズを乱数で指定
　　　　　　set randomCSize to random number from fontSizeMin to maxFSize
　　　　　　
　　　　　　tell current slide
　　　　　　　　set tmpT to make new text item with properties {object text:oText, position:{randomX, randomY}, width:tWidth, height:tHeight} at the end
　　　　　　　　ignoring application responses
　　　　　　　　　　set size of every character of object text of tmpT to randomCSize
　　　　　　　　end ignoring
　　　　　　end tell
　　　　　　
　　　　end repeat
　　end tell
end tell

★Click Here to Open This Script　

SF Symbolsを名称で指定してPNG画像化

Posted on 4月 15, 2022 by Takaaki Naganoya

SF Symbolsに収録されている文字を、名称で指定してデスクトップにPNG画像で書き出すAppleScriptです。

同フォントは、アプリ上のアイコン素材3,300個以上をフォント化し、再利用しやすくすることで、アイコンで何かの意図を示すことを規格化したいという、現代における象形文字の再発明みたいな存在です。

文化や人種を超えた、非言語コミュニケーションを促進するための基盤としてAppleが整備を行なっているものなんでしょう。文化を縦断したインフラみたいな。

アイコン素材を自分で作るのはつらいので、正直助かっています。Appleが配布しているSF Symbols 3アプリケーションを使って画面上でいろいろ探して、文字を指定できます。

一応、SF Symbols.app自体にも指定フォントを画像化する機能はついているのですが、レンダリング時の指定解像度が低すぎて、プレゼン資料や本のイラストとして利用するには不便すぎます（本来の利用目的である、タブバーのアイコンに指定するのには向いている解像度なんでしょうけれども）。

そこで、指定のフォントの文字を名称で指定するとPNG画像にレンダリングするAppleScriptを作成してみました。

文字を指定するのはできているのですが、フォントのファミリーとかマルチカラーとかの指定の方法がよくわかりません。

AppleScript名：SF Symbolsを名称で指定してPNG画像化 v1a.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2022/04/14
—
–　　Copyright © 2022 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.8" — Monterey (12) or later
use framework "Foundation"
use framework "AppKit"
use framework "QuartzCore"
use scripting additions

set aName to "paperplane.circle.fill"
set anImage to current application’s NSImage’s imageWithSystemSymbolName:(aName) accessibilityDescription:(missing value)
set resImg to resizeNSImage(anImage, 50.0) of me

set aDesktopPath to current application’s NSString’s stringWithString:(POSIX path of (path to desktop))
set savePath to aDesktopPath’s stringByAppendingString:((current application’s NSUUID’s UUID()’s UUIDString())’s stringByAppendingPathExtension:"png")

set fRes to saveNSImageAtPathAsPNG(resImg, savePath) of me

on resizeNSImage(aSourceImg, aScale)
　　set aSize to aSourceImg’s |size|()
　　set newWidth to (width of aSize) * aScale
　　set newheight to (height of aSize) * aScale
　　
　　set targFrame to current application’s NSMakeRect(0, 0, newWidth, newheight)
　　set targImage to current application’s NSImage’s alloc()’s initWithSize:{newWidth, newheight}
　　
　　set aKey to {current application’s NSImageHintInterpolation}
　　set aObj to current application’s NSNumber’s numberWithInt:(current application’s NSImageInterpolationLow)
　　set hintRec to current application’s NSDictionary’s dictionaryWithObject:aObj forKey:aKey
　　
　　targImage’s lockFocus()
　　aSourceImg’s drawInRect:targFrame fromRect:(current application’s NSZeroRect) operation:(current application’s NSCompositeCopy) fraction:1.0 respectFlipped:true hints:hintRec
　　targImage’s unlockFocus()
　　
　　return targImage
end resizeNSImage

–NSImageを指定パスにPNG形式で保存
on saveNSImageAtPathAsPNG(anImage, outPath)
　　set imageRep to anImage’s TIFFRepresentation()
　　set aRawimg to current application’s NSBitmapImageRep’s imageRepWithData:imageRep
　　set pathString to current application’s NSString’s stringWithString:outPath
　　set newPath to pathString’s stringByExpandingTildeInPath()
　　set myNewImageData to (aRawimg’s representationUsingType:(current application’s NSPNGFileType) |properties|:(missing value))
　　set aRes to (myNewImageData’s writeToFile:newPath atomically:true) as boolean
　　return aRes –成功ならtrue、失敗ならfalseが返る
end saveNSImageAtPathAsPNG

★Click Here to Open This Script　

Pixelmator Pro v2.4.1で新機能追加＋AppleScriptコマンド追加

Posted on 4月 14, 2022 by Takaaki Naganoya

いまひとつ、「こういう表現を行いたいんだけど、どう操作していいのかわからない」感のあるPixelmator Pro。毎回、メニューを漁っては「これ、どう作るんだろうーなー」という手探り感があります。

Photoshopで育って、どっぷりPhotoshopで画像処理を理解した人がPixelmator Proを理解するのに、敷居の高さを感じます。これ、絶対に「こういう完成物を作りたい」という人向けに「こういう手順で操作すればいい」というマニュアル的なものが必要です。

さて、Pixelmator Proの新バージョンv2.4.1が登場。機械学習を利用した人物写真の自動切り抜き機能が目玉のようです。

Student with laptop photo created by freepic.diller – www.freepik.com

おお！まつげの箇所だけちょっと切れてしまったけど、これはいい感じ！

Lookstudio – jp.freepik.com によって作成された people 写真

上半身はほぼ完璧！　こーれーはすごい。

いろんなスナップ写真を切り抜かせてみましたが、人物の全身が写っているとヒット率が高いようです。つまり、おかしな箇所を切り抜かれる危険性が低くなるということです。白いTシャツが抜ける危険性が高いようで、、、

Pixelmator 2.4.1　AppleScript用語辞書変更内容

export formatに「Motion」（Motion project.）が追加された
コマンド「select subject」追加。
コマンド「smart refine selection」追加。
コマンド「remove background」追加。
エレメント「color adjustments layer」「effects layer」追加。

クラス「image layer」がコマンド「remove background」と「decontaminate colors」に応答するようになった。
クラス「group laye」に要素「color adjustments layer」「effects layer」を追加
クラス「color adjustments layer」「effects layer」を追加

コマンド「draw elliptical selection」の同義語（draw oval selection）を廃止
コマンド「resize image」の同義語（adjust size、image size）を廃止
コマンド「resize canvas」の同義語（adjust canvas、canvas size）を廃止

冒頭の人物自動切り抜きを行うAppleScriptを書いてみると、こんな感じです。Pixelmator ProのAppleScript用語辞書にもサンプルScriptが掲載されています。

AppleScript名：人物自動切り抜き.scpt

tell application "Pixelmator Pro"
　　tell front document
　　　　remove background –v2.4.1 or later
　　end tell
end tell

★Click Here to Open This Script　

新発売：AppleScript基礎テクニック集（４）〜AppleScript用語辞書の読み方

Posted on 4月 13, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第４巻、「AppleScript用語辞書の読み方」です。PDF 39ページ、掲載Scriptアーカイブつき。

→ 販売ページ

AppleScript用語辞書の読み方については、業務の一環として記述していても理解していない人も多いので、理解できると大きな力になる内容です。普段使っていないアプリケーションでも、AppleScriptが書きやすくなるはずです。

用語辞書の構成要素

AppleScript用語辞書ってなに？
AppleScript用語辞書を読む前に
AppleScript用語辞書を読むために必要なもの
AppleScript用語辞書の確認方法
参考資料：えせスクリプタブルなアプリケーション一覧
AppleScript用語辞書の表示内容
AppleScript用語辞書掲載のサンプルScript
AppleScript用語辞書の生ファイルを表示
参考資料：用語辞書の生ファイルを得る意義
AppleScript用語辞書の構成要素
えせスクリプタブルな用語辞書の具体例

用語辞書の読み方

GUIアプリケーション操作のAppleScript記述例
アプリケーションのオブジェクト構造を調べる
document
へたくそなサンプルScriptをわかりやすく清書
より高機能なツールによる用語辞書の確認

画面上の機能とAppleScript的な属性値の付け合わせ

オブジェクトのプロパティを取得して調査
オブジェクトの選択状態による結果の変化
オブジェクトのプロパティを取得して調査
複数クラスの属性を継承している場合に
オブジェクトのプロパティを変更するテスト

新発売：AppleScript基礎テクニック集（３）〜ファイル・パス処理

Posted on 4月 10, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第３巻、「ファイル・パス処理」です。PDF 38ページ、掲載Scriptアーカイブつき。

→ 販売ページ

本書は、まさに「基礎」中の「基礎」ともいえる「パス操作」の基礎的なサンプルを提示して段階的に紹介。最近はCocoaの機能ばかり使っているので、逆にFinderやSystem Events相手に苦労しました。

ファイル・パス処理

ファイル・パス関連オブジェクトの全体像
ファイルパス各形式の特徴や用途
ファイル・パス形式
ホームディレクトリのパスを取得
参考資料：path to で指定できるパラメータ
参考資料：path to temporary items
各種パス形式の変換
パスの組み立て
指定ファイルの親フォルダ（上位フォルダ）を求める
指定パスのファイル名だけを求める
指定パスの拡張子を求める
指定パスの拡張子だけを置換
指定フォルダの存在確認
指定フォルダに指定名称のファイルが存在するか確認
指定ファイルのリネーム（名称変更）
指定フォルダのリネーム（名称変更）
指定ファイルがパッケージかどうかを求める
指定パスからUTIを求める
指定パスがフォルダかどうかを求める
POSIX pathのチルダ（「~」）を展開
フルパスからチルダ（「~」）つきPOSIX pathを計算
特定パスのローカライズ名称を求める
特定パスが所属するドライブ名を求める

Keynoteで選択中のオブジェクトを取得して座標でソート

Posted on 4月 10, 2022 by Takaaki Naganoya

Keynote 12.0でまともになった「selection」を使って、選択状態にあるKeynote書類上のオブジェクト（text item）をX座標、Y座標でソートするAppleScriptです。

--> {{objID:2, positionY:219, myCon:"①①①①①", positionX:184}, {objID:4, positionY:492, myCon:"❷❷❷❷❷", positionX:184}, {objID:1, positionY:219, myCon:"③③③③③", positionX:1047}, {objID:3, positionY:492, myCon:"❹❹❹❹❹", positionX:1047}}

選択したtext itemを座標で並べ替え、内容を個別に評価してファイル書き出しするAppleScriptを別途用意して書籍作成用のツールとして、使っています。

書籍の作成作業用に作ったので、アホみたいに高機能です。text itemの内容をAppleScriptとして構文確認して、AppleScriptのオブジェクトを生成し、中間言語コードに解釈ずみの.scptファイルとして書き出しています（書籍のサンプルScript生成用）。こういうツールを作ってすぐに実戦投入できるのも、Keynoteのselectionがまともになったおかげです。

–> Watch Demo Movie

AppleScript名：選択中のオブジェクトを座標をもとにソート.scptd

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Keynote"
　　tell front document
　　　　set aaSel to selection
　　　　set posList to {}
　　　　set aCount to 1
　　　　
　　　　repeat with i in aaSel
　　　　　　set j to contents of i
　　　　　　set mySource to object text of j
　　　　　　
　　　　　　tell j
　　　　　　　　set {posX, posY} to position
　　　　　　end tell
　　　　　　
　　　　　　set the end of posList to {positionX:posX, positionY:posY, objID:aCount, myCon:mySource}
　　　　　　
　　　　　　set aCount to aCount + 1
　　　　end repeat
　　　　
　　end tell
end tell

set zList to sortRecListByLabel(posList, {"positionX", "positionY"}, {true, true}) of me

★Click Here to Open This Script　

iWork Appsがバージョン12.0にアップデートでselection動作正常化

Posted on 4月 9, 2022 by Takaaki Naganoya

昨日、iWork Apps（Keynote、Pages、Numbers）がVer.12.0にバージョンアップしていました。

AppleScript系ではgetコマンドが追加（Keynote、Pages）されたぐらいですが、これによって「selection」の動作がまともになりました。

前バージョンのアップデートで「スライド単位の選択」がselectionで取れなくなったことで、「何か変更しようとしている最中なんだろう」とは思っていました。予想どおりです。selection動作の空白期間を置かず、前バージョンの段階で実装されていたらもっとよかったのですが。

AppleScript対応アプリケーション、スクリプタブルなアプリケーションの世界観は、小さい世界観のものから大きい世界観のものまでいろいろです。

小さい世界観１（一番小さい）：
アプリケーション起動、バージョン確認、書類のオープン、書類の印刷、アプリケーションの設定情報の確認

小さい世界観２：
小さい世界観１＋アプリケーション固有のコマンドの実行

小さい世界観３：
小さい世界観２＋書類やデータ作成のための機能、選択中のデータをおおまかに取得する機能
Keynote v11.xはここ

小さい世界観４：
小さい世界観３＋書類上のオブジェクト作成/改変機能、選択中のデータやオブジェクトへの参照を取得する機能
Keynote v12.xはここ？　まだ、Chart作成などで未サポートのグラフ形式などもあり、不完全

大きい世界観：
小さい世界観４＋書類上のオブジェクトの多数を作成/改変する機能
Adobe InDesign、Word、Excel、PowerPoint、Pixelmator Proなど。かつての（v5ぐらいの）Pagesはここにいた

Keynoteでselectionを試してみたところ、何か書類上のオブジェクトを選択してselectionを実行すると、オブジェクトへの参照を（複数、リスト形式で）取れます。オブジェクトを選択した状態でなければ、書類上のどのスライドを表示中かというスライドへの参照が取得できるようです。

Keynoteにおける処理の自由度は大幅に上がりました。選択中のテキストボックスを取得できれば、その中に含まれるテキストなり書式つきテキストを取得して、書き直し、元のテキストボックスに書き戻すことができます。

選択中のイメージを取得できれば、その画像のパスを求めるかあるいはファイル名を求めて、オリジナルの画像ファイル（書類内に格納された画像、外部に存在する画像かはやってみないと）を画像フィルタ処理などを行って書き戻すといった処理が行いやすくなります。以前までのバージョンでは、選択した画像をいったんコピーしてクリップボードに格納し、そのクリップボード内の画像に対して画像処理していました。

Pagesでも、さまざまなオブジェクトへの参照がselectionによって取得できますが、あいかわらず「ページ」という概念があるんだかないんだか不明で、アプリケーションの根幹にかかわる部分なのでいまひとつ気軽に言えないところではあります。

新発売：AppleScript基礎テクニック集（２）〜tellブロックの整理

Posted on 4月 8, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第２巻、「tellブロックの整理」です。PDF 36ページ、掲載Scriptアーカイブつき。

→ 販売ページ

本書は、AppleScriptのプログラムの７割以上を占めると言われている、tellブロックの記述や整理方法についてまとめています。tellブロックの書き方が楽になれば、すなわちプログラムの７割以上の部分を楽に書けるともいえます。

tellブロックの記述は、AppleScriptのプログラミングにおいて、決して避けては通れない基礎テクニックなのです。

tellブロック

tellブロックの基本構造
省略表記が可能
省略表記の自動判別＋自動展開
１行にまとめることも可能
変数, propertyに入れて指定
tellブロックにof itを補う必要があるケースも
it, me, AppleScript
tellブロックの分割
オブジェクト階層をサブルーチンに渡す
ちょっと凝ったtellブロック

GUI Scriptingにおけるtellブロック

画面上のGUI部品を強引に操作するGUI Scripting
手軽,遅い,tell文が深いGUI Scripting
tell文のネスティングを浅く書く工夫

同一アプリケーションの異なるバージョンへのtell

対象アプリケーションの指定方法
アプリケーションの存在確認
アプリケーションのバージョンを検出
Spotlightでアプリケーションを検索
ご参考：Spotlight検索ライブラリをインストール
Spotlightで同じ名前のアプリケーション情報を取得
対象アプリケーションを名前以外で指定

新発売：AppleScript基礎テクニック集（１）〜間接指定

Posted on 4月 6, 2022 by Takaaki Naganoya

電子書籍の新刊を発売しました。新シリーズ「AppleScript基礎テクニック集」の第１巻、「間接指定」です。PDF 36ページ、掲載Scriptアーカイブつき。

１年に15冊も書いていると、割とPiyomaru Softwareの電子書籍も数が増えてきまして……何がどういう人向けのものなのか、おおまかなマップを示してほしいという話を聞くようになりました。

「基礎」とはいっても、入門者が読むような内容ではなく、脱・初心者とか中級者（とりあえず、目的のScriptを組めるレベル）向けといったところでしょうか。

間接指定

直接指定と間接指定
処理データの間接指定（配列から指定）
Unicode文字の間接指定
date（日付）オブジェクトの間接指定
ファイルパスの間接指定
参考資料：path to で指定できるパラメータ
音声読み上げキャラクタの間接指定
実行Scriptの間接指定
コマンドの間接指定
実行ハンドラ（サブルーチン）の間接指定

間接指定の導入実例

間接的に表同士の重なりを検出
間接的に表同士の重なりを検出
間接的にチェック範囲を検出
直接指定から間接指定に書き換えた結果
実際のScript

Keynoteの最前面の書類の現在のスライド上の表オブジェクトの重なり合い（２つ以上対応）を検出 v3

Posted on 4月 5, 2022 by Takaaki Naganoya

Keynote書類の現在のスライド（ページ）上に存在する表オブジェクトの重なり合いを検出するAppleScriptです。

前バージョンでは、複数の表オブジェクトが配置されていると、表オブジェクトの位置情報と大きさから生成したNSRect同士の重なりチェックを行なった際に、同じ表同士の重なりチェックも行なっていたので、

複数の表が存在していると、もれなく「重なっている」という警告が出てくるものでした。

本バージョンでは、同じ表同士を重なりチェックしないようにとか、1×3と3×1という「同じオブジェクト同士の重なりチェックを２度行っている」ようなものを排除しています。

今度の順列組み合わせパターン生成ルーチン「retPairPermutationsWithoutSelfCollision」では、これらのパターンを除去しています。

{{1, 2}, {1, 3}, {1, 4}, {1, 5}, {2, 3}, {2, 4}, {2, 5}, {3, 4}, {3, 5}, {4, 5}}

↑余計な組み合わせパターンは生成されなくなりました。

実際に本Scriptを用いて（複数ページ対応板）、121ページ分の表の重なり合わせチェックを行なってみたところ、M1 Mac miniで3.4秒程度です。

–> Watch Demo Movie

▲重なり合わせ判定：なし

▲重なり合わせ判定：あり

▲重なり合わせ判定：なし

▲重なり合わせ判定：あり（400％拡大表示）

▲重なり合わせ判定：あり（75％拡大表示）

本Scriptの完全版を「AppleScript基礎テクニック集（１）〜間接指定」に収録しています。

AppleScript名：現在のスライド上の表オブジェクトの重なり合い（２つ以上対応）を検出 v3.scptd

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

tell application "Keynote"
　　tell front document
　　　　set docHeight to height
　　　　
　　　　tell current slide
　　　　　　set tList to every table
　　　　　　
　　　　　　if length of tList < 2 then return false –複数の「表」がなかったら衝突は発生していない
　　　　　　
　　　　　　–表の座標とサイズによりNSRectangleを作成する
　　　　　　set bList to {}
　　　　　　
　　　　　　repeat with i in tList
　　　　　　　　set j to contents of i
　　　　　　　　
　　　　　　　　tell j
　　　　　　　　　　set {xPos, yPos} to position
　　　　　　　　　　set aWidth to width
　　　　　　　　　　set aHeight to height
　　　　　　　　　　
　　　　　　　　　　set aRect to makeRect(xPos, yPos, aWidth, aHeight) of me
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　set the end of bList to aRect
　　　　　　end repeat
　　　　　　
　　　　　　–作成したNSRectangleの順列組み合わせペア・パターンを作成して、NSRectangle同士の衝突判定を順次行う
　　　　　　set aLen to length of bList
　　　　　　set permuList to retPairPermutationsWithoutSelfCollision(aLen) of me
　　　　　　set corruptList to {}
　　　　　　
　　　　　　repeat with i in permuList
　　　　　　　　copy i to {i1, i2}
　　　　　　　　set rectRes to detectRectanglesCollision(item i1 of bList, item i2 of bList) of me
　　　　　　　　if rectRes = true then return true –表同士の衝突が発生している
　　　　　　end repeat
　　　　　　
　　　　　　return false –表同士の衝突は発生していない
　　　　end tell
　　end tell
end tell

on makeRect(xPos, yPos, aWidth, aHeight)
　　return current application’s NSMakeRect(xPos, yPos, aWidth, aHeight)
end makeRect

–NSRect同士の衝突判定
on detectRectanglesCollision(aRect, bRect)
　　set a1Res to (current application’s NSIntersectionRect(aRect, bRect)) as {record, list}
　　set tmpClass to class of a1Res
　　
　　if tmpClass = record then
　　　　–macOS 10.10, 10.11, 10.12
　　　　return not (a1Res = {origin:{x:0.0, y:0.0}, |size|:{width:0.0, height:0.0}})
　　else if tmpClass = list then
　　　　–macOS 10.13 or later
　　　　return not (a1Res = {{0.0, 0.0}, {0.0, 0.0}})
　　end if
end detectRectanglesCollision

–１から任意の数までのアイテムで、２個ずつの組み合わせのすべての順列組み合わせパターンを計算して返す
–ただし、1×1とか2×2などの同一アイテム同士の掛け合わせを除去するものとする
on retPairPermutationsWithoutSelfCollision(aMax)
　　set aList to {}
　　
　　repeat with x from 1 to aMax
　　　　repeat with xx from 1 to aMax
　　　　　　if x is not equal to xx then
　　　　　　　　
　　　　　　　　set tmpItem to {x, xx}
　　　　　　　　set a2List to sort1DNumList(tmpItem, true) of me
　　　　　　　　
　　　　　　　　if {a2List} is not in aList then
　　　　　　　　　　set the end of aList to a2List
　　　　　　　　end if
　　　　　　end if
　　　　　　
　　　　end repeat
　　end repeat
　　
　　return aList
end retPairPermutationsWithoutSelfCollision

–1D List（数値）をsort / ascOrderがtrueだと昇順ソート、falseだと降順ソート
on sort1DNumList(theList as list, aBool as boolean)
　　tell current application’s NSSet to set theSet to setWithArray_(theList)
　　tell current application’s NSSortDescriptor to set theDescriptor to sortDescriptorWithKey_ascending_(missing value, aBool)
　　set sortedList to theSet’s sortedArrayUsingDescriptors:{theDescriptor}
　　return (sortedList) as list
end sort1DNumList

★Click Here to Open This Script　

目次

■ループによる繰り返し処理

■アプリケーションから取得したオブジェクトでループ

■高度な処理を簡潔に記述

目次

ダイアログ表示

AppleScriptライブラリを利用したダイアログ表示

環境整備〜超基礎編

環境整備〜構築編

環境整備〜設定編

環境整備〜メンテナンス編

if文とは？

比較演算とは？

より高度な条件分岐

変数/プロパティとは？

変数/プロパティの名前の決め方

Pixelmator 2.4.1 AppleScript用語辞書変更内容

用語辞書の構成要素

用語辞書の読み方

画面上の機能とAppleScript的な属性値の付け合わせ

ファイル・パス処理

tellブロック

GUI Scriptingにおけるtellブロック

同一アプリケーションの異なるバージョンへのtell

間接指定

間接指定の導入実例

Pixelmator 2.4.1　AppleScript用語辞書変更内容