ApitoreのREST API「Language Detection -53 languages-」を呼び出して、指定したテキストの言語（日本語とか英語とか）を推定するAppleScriptです。
＃ Apitoreは2019年5月31日をもってサービスを終了
Language-Detectionは、テキストの言語判定を行います。検索機能に言語の絞り込みを付けたい場合や、テキストに対して言語別の処理をしたい場合に利用します。
本AppleScript利用のためには、Apitoreにサインアップしてアカウントを作成し、新規プロジェクトを作成（Test AppleScriptとか）。そこに、本APIを利用できるように登録し、「アクセストークン」を取得する必要があります。
アクセストークンを取得せずに掲載状態のまま本AppleScriptを実行してもエラーになります。
取得したアクセストークンを本AppleScript中のretAccessToken()ハンドラ内に記載し、実行してください。
本REST APIを評価した感想は、言語判定可能なテキスト分量がやや長め（俳句や短歌程度だとダメ。Twitter投稿ぐらいの文字数があれば大丈夫）でありつつ、APIに突っ込める文字の長さに制限があるため、対象のテキストをすべて渡すのではなく、テキストの一部を抜粋して評価を行うのが適しているように思われました。
| AppleScript名：Language Detection -53 languages- langdetect |
— Created 2016-10-27 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
set targStr to "This is a pen. This is an apple. This is applepen."
set reqURLStr to "https://api.apitore.com/api/22/langdetect/get"
set accessToken to retAccessToken() of me
set aRec to {access_token:accessToken, |text|:targStr}
set aURL to retURLwithParams(reqURLStr, aRec) of me
set aRes to callRestGETAPIAndParseResults(aURL) of me
set aRESCode to (responseCode of aRes)
set aRESTres to (json of aRes)
return aRESTres as list of string or string
–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
aRequest’s setHTTPMethod:"GET"
aRequest’s setCachePolicy:(current application’s NSURLRequestReloadIgnoringLocalCacheData)
aRequest’s setHTTPShouldHandleCookies:false
aRequest’s setTimeoutInterval:60
aRequest’s setValue:"application/json" forHTTPHeaderField:"Accept"
set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
set resList to aRes as list
set bRes to contents of (first item of resList)
set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
set jsonString to current application’s NSString’s stringWithString:resStr
set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
–Get Response Code & Header
set dRes to contents of second item of resList
if dRes is not equal to missing value then
set resCode to (dRes’s statusCode()) as number
set resHeaders to (dRes’s allHeaderFields()) as record
else
set resCode to 0
set resHeaders to {}
end if
return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults
on retAccessToken()
return "xxXXXxxX-XxXx-XXXX-xXXX-XXxXXxxXxxXx" –API Tore Access Token
end retAccessToken
on retURLwithParams(aBaseURL, aRec)
set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
set aKeyList to (aDic’s allKeys()) as list
set aValList to (aDic’s allValues()) as list
set aLen to length of aKeyList
set qList to {}
repeat with i from 1 to aLen
set aName to contents of item i of aKeyList
set aVal to contents of item i of aValList
set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
end repeat
set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
aComp’s setQueryItems:qList
set aURL to (aComp’s |URL|()’s absoluteString()) as text
return aURL
end retURLwithParams
|
|
★Click Here to Open This Script
|
