USBゲームコントローラーの情報を取得する

Posted on 3月 18, 2018 by Takaaki Naganoya

MacにUSB接続しているゲームコントローラーの情報を取得するAppleScriptです。

あくまでUSB接続しているコントローラーに限られ、同時にBluetooth接続のゲームコントローラー（PlayStation 3用のDual Shock3）があっても無視されるようです。

AppleScript名：USBゲームコントローラーの情報を取得する

— Created 2017-03-21 18:47:15 +0900 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "GameController"

set aController to current application’s GCController’s controllers()
–>　　(NSArray) {(_GCController) <GCController 0x6080004a2580 vendorName=’USB Game Device’ deviceHash=0xbe8dba5719e63307>}

set aCon to aController’s firstObject()
if aCon = missing value then return
set aGameCon to aCon’s gamepad()
–>　　(_GCMFiGamepadControllerProfile) <_GCMFiGamepadControllerProfile: 0x6000000df870>

set aExGameCon to aCon’s extendedGamepad()
–>　　missing value

set aMicGameCon to aCon’s microGamepad()
–>　　(_GCMFiGamepadControllerProfile) <_GCMFiGamepadControllerProfile: 0x6000000df870>

set aMotion to aCon’s motion()
–>　　missing value

set aVendor to aCon’s vendorName() as string
–>　　"USB Game Device"

set anAttached to aCon’s isAttachedToDevice()
–>　　false

★Click Here to Open This Script　

(GET)駅すぱあとAPIで平均待ち時間「バスのみ探索」

Posted on 3月 17, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、バス路線の検索を行うAppleScriptです。

（「47都道府県鉄道路線図」より引用）

掲載の本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」90日間無料試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

駅コードで発停留所、着停留所をIDで指定して経路検索を行います。本サンプルでは、関東バスの「中村橋」から、「阿佐ヶ谷駅」までの経路を検索しています。時間については平均待ち時間を適用しているとのこと。

AppleScript名：(GET)駅すぱあとAPIで平均待ち時間バスのみ探索

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

–http://docs.ekispert.com/v1/api/search/course/bus.html
set aURL to "https://api.ekispert.jp/v1/json/search/course/bus"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, |from|:"45848", |to|:"45507"} –関東バス「中村橋駅」発、「阿佐ヶ谷」着
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで経路簡易探索（駅名称指定）

Posted on 3月 17, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、駅名から経路検索を行うAppleScriptです。

（「47都道府県鉄道路線図」より引用）

掲載の本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」90日間無料試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

駅コードで発駅、経由駅、着駅を指定して経路検索を行います。本サンプルでは、西武池袋線の中村橋駅から、池袋駅を経由して、京急線の羽田空港国内線ターミナル駅までの経路を検索しています。

AppleScript名：(GET)駅すぱあとAPIで経路簡易探索（駅名称指定）

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

–http://docs.ekispert.com/v1/api/search/course.html
set aURL to "https://api.ekispert.jp/v1/json/search/course"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, |from|:"中村橋", |to|:"池袋", via:"羽田空港国内線ターミナル"} –中村橋駅　発、池袋経由、羽田空港国内線ターミナル　着
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIでデータバージョンを取得

Posted on 3月 17, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、データのバージョンを求めるAppleScriptです。

本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」の試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

AppleScript名：(GET)駅すぱあとAPIでデータバージョンを取得

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/dataversion"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey}
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

(*
{ResultSet:{engineVersion:"201803_04a", Version:{{createType:"Edition", create:"20180304", caption:"知識ベース"}, {createType:"Edition", create:"20180304", caption:"鉄道時刻表"}, {createType:"Date", caption:"ＪＲ", createComment:"Now", create:"20180317"}, {createType:"Date", caption:"私鉄", createComment:"Now", create:"20180312"}, {createType:"Edition", caption:"航空時刻表", rangeTo:"20180531", rangeFrom:"20180201", rangeCaption:"有効期間", create:"20180401"}, {createType:"Edition", create:"20180401", caption:"高速・連絡・深夜急行バス"}, {createType:"Edition", create:"20180401", caption:"船"}, {createType:"Date", caption:"得トクきっぷデータ", createComment:"Now", create:"20180201"}, {createType:"HideDay", caption:"住所データ", createComment:"Now", create:"20170101"}}, Copyrights:{companyId:"2", text:"交承平成25年68号
ＪＲデータの内容は、株式会社交通新聞社発行の「ＪＲ時刻表」2018年3月号に基づいています。
この時刻データを無断で転載・複写し、又は紙媒体、電磁媒体その他いかなる媒体に加工することも禁じます。

ＪＲバスデータの内容は、株式会社交通新聞社作成のデータ平成30年3月分に基づいています。この時刻データを無断転載・複写や電磁媒体等に加工することを禁じます。

名鉄バスの情報は、名鉄バス株式会社作成のデータに基づいています。ただし一部のバス停ポール情報は株式会社ヴァル研究所が自らの責任により加工したものです。

ほか、一部の内容は株式会社ヴァル研究所が自らの責任により加工したものです。
", company:"株式会社交通新聞社"}, apiVersion:"1.27.0.0"}}
*)

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで経路検索

Posted on 3月 16, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、経路検索を行うAppleScriptです。

（「47都道府県鉄道路線図」より引用）

掲載の本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」90日間無料試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

駅コードで発駅、経由駅、着駅を指定して経路検索を行います。本サンプルでは、西武池袋線の中村橋駅から、池袋駅を経由して、京急線の羽田空港国内線ターミナル駅までの経路を検索しています。

駅すぱあとAPIのドキュメントを読んだかぎりでは、

　①駅コード（ユニークなコード）で検索
　②駅名称で検索
　③緯度経度情報で検索
　④住所情報を検索
　⑤地区データで検索

といった検索が可能なようです。まずは、一番重要な駅コードによる検索を調べてみた次第です。

AppleScript名：(GET)駅すぱあとAPIで経路検索

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/search/course/extreme"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, viaList:"22854:22513:22911"} –中村橋駅　発、池袋経由、羽田空港国内線ターミナル　着
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで駅コード検索

Posted on 3月 16, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、駅名称から「駅すぱあと」内部で利用している駅コードを検索するAppleScriptです。

（「47都道府県鉄道路線図」より引用）

「駅すぱあと」はほぼ日本人なら（とくに首都圏に住んでいると）誰でも知っている、電車をはじめとする公共交通機関の乗り換え情報を検索するアプリケーションです。

本来、AppleScriptと相性の良い処理のはずなのですが、Mac版のアプリケーションが最近は提供されておらず、さらに昔のMac版のアプリケーションもAppleScriptに対応していなかったので、長らく接点がありませんでした。

そんな中、「駅すぱあと」のREST APIが試用できるようになっていることを知り、さっそくサインアップして「駅すぱあとWebサービススタンダードプラン」90日試用コードを取得してみました。掲載の本Scriptをためしてみる場合には、かならずご自分で試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

ドキュメントもよく整備されており、首をひねるような仕様もなく、日本国内で提供されているREST APIとしては非常によく整理されているといえます。

本来はいきなり経路検索を行いたかったのですが、経路検索を行うのに、駅固有のユニークコードである「駅コード」を調べられないと困るので、まずは駅コードから駅名称を調べたり、駅名称から駅コードを調べるAppleScriptを書いてみました（羽田空港からの帰りのバスの中で）。

これで、MacのExcelやFileMaker Pro、Numbersといったアプリケーションの書類上に入れたデータから経路検索を行なってこれらのアプリケーションのデータに返すことができるようになったわけで、応用範囲はきわめて広いといえます。

AppleScript名：(GET)駅すぱあとAPIで駅コード検索

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/station/light"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, |name|:"羽田空港国内線ターミナル", type:"train"}
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to (json of aRes) –NSDictionaryで返ってくる

set staCode to (aRESTres’s valueForKeyPath:"ResultSet.Point.Station.code") as list of string or string –as anything
–> 22854

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで駅コードから駅名称を取得

Posted on 3月 16, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、「駅すぱあと」内部で利用している駅コードから駅の名称を取得するAppleScriptです。

「駅すぱあと」はほぼ日本人なら（とくに首都圏に住んでいると）誰でも知っている、電車をはじめとする公共交通機関の乗り換え情報を検索するアプリケーションです。

（「47都道府県鉄道路線図」より引用）

本来、AppleScriptと相性の良い処理のはずなのですが、Mac版のアプリケーションが最近は提供されておらず、さらに昔のMac版のアプリケーションもAppleScriptに対応していなかったので、長らく接点がありませんでした。

そんな中、「駅すぱあと」のREST APIが試用できるようになっていることを知り、さっそくサインアップして「駅すぱあとWebサービススタンダードプラン」90日試用コードを取得してみました。掲載の本Scriptをためしてみる場合には、かならずご自分で試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

「駅すぱあと」のREST APIはドキュメントもよく整備されており、首をひねるような仕様もなく、日本国内で提供されているREST APIとしては非常によく整理されているといえます。

本来はいきなり経路検索を行いたかったのですが、経路検索を行うのに、駅固有のユニークコードである「駅コード」を調べられないと困るので、まずは駅コードから駅名称を調べたり、駅名称から駅コードを調べるAppleScriptを書いてみました（羽田空港からの帰りのバスの中で）。

これで、MacのExcelやFileMaker Pro、Numbersといったアプリケーションの書類上に入れたデータから経路検索を行なってこれらのアプリケーションのデータに返すことができるようになったわけで、応用範囲はきわめて広いといえます。

駅すぱあとAPIのドキュメントについては、１点だけ「format」の説明（結果の取得フォーマットがjsonかXMLかを指定）の説明がわかりづらく、この説明だとformat=jsonといった指定を行なってしまうと思います。

AppleScript名：(GET)駅すぱあとAPIで駅コードから駅名称を取得

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/station"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, code:"25853"}
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to (json of aRes) –NSDictionaryで返ってくる

set staCode to aRESTres’s valueForKeyPath:"ResultSet.Point.Station.Name"
–> "大阪"

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

NSSharingService経由でメールを新規作成（作成するだけ、送信しない）

Posted on 3月 14, 2018 by Takaaki Naganoya

NSSharingServiceを利用してメールを新規作成するAppleScriptです。

仕様上、新規作成するだけで送信は行いません。普通にMail.appをコントロールすればメールの送信は行えるので、単にNSSharingServiceのテストです。

AppleScript名：NSSharingService経由でメールを新規作成（作成するだけ、送信しない）

— Created 2017-02-23 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set shareItems to {"てすとだよおおおん
２行目
３行目", "よろしくー１
よろしくー2", "Footer？"}
set aService to current application’s NSSharingService’s sharingServiceNamed:(current application’s NSSharingServiceNameComposeEmail)
aService’s setDelegate:me
aService’s setRecipients:{"nobody@piyocast.com"}
aService’s setSubject:"試験送信"
aService’s performWithItems:shareItems

★Click Here to Open This Script　

指定名称のアプリケーションをフルスクリーン表示

Posted on 3月 13, 2018 by Takaaki Naganoya

指定名称のアプリケーションをフルスクリーン表示するAppleScriptです。

AppleScript自体とフルスクリーン表示の相性はよくありません。操作対象のGUIアプリケーションとスクリプトエディタ（Script Debuggerでも可）と最低でも２つのウィンドウがオープンしていることが望ましいので、Scriptを書いている最中でフルスクリーン表示というのはありえません。

ただ、運用段階でフルスクリーン表示をしたい、というニーズがないこともないので、やり方を調べておきました。

AppleScript名：指定名称のアプリをフルスクリーン表示

— Created 2015-07-29 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions

set a to "Safari"
set aRes to dispAppWithFullScreen(a) of me

–指定名称のアプリケーション（起動中のもの）をフルスクリーン表示
on dispAppWithFullScreen(applicationName)
　　
　　set appName to returnExactNameOfAnApp(applicationName)
　　if appName = false then return false –指定のアプリがなかった、あるいはアプリケーション名を間違って指定した
　　
　　set pID to id of application appName
　　
　　tell application appName
　　　　reopen
　　　　activate
　　end tell
　　
　　tell application "System Events"
　　　　tell (process 1 whose bundle identifier is pID)
　　　　　　set b1List to every button of window 1 whose subrole is "AXFullScreenButton" –Full Screen
　　　　　　set b2List to every button of window 1 whose subrole is "AXZoomButton" –Zoom
　　　　　　
　　　　　　if b1List = {} then
　　　　　　　　set targB to first item of b2List –フルスクリーン表示機能を持たないアプリの場合
　　　　　　else
　　　　　　　　set targB to first item of b1List –フルスクリーン表示機能を持つアプリの場合
　　　　　　end if
　　　　　　
　　　　　　click targB
　　　　end tell
　　end tell
　　
　　return true
　　
end dispAppWithFullScreen

–Displayed Nameでアプリケーション名が与えられた場合に、正しい名称を返す
on returnExactNameOfAnApp(aName)
　　tell application "System Events"
　　　　set ap1List to every process whose name is equal to aName
　　　　if ap1List = {} then
　　　　　　set ap1List to every process whose displayed name is equal to aName
　　　　　　if ap1List = {} then return false
　　　　end if
　　　　set anApp to contents of first item of ap1List
　　　　return name of anApp
　　end tell
end returnExactNameOfAnApp

★Click Here to Open This Script　

mouseClickを用いて指定座標をクリック

Posted on 3月 13, 2018 by Takaaki Naganoya

ネット上に転がっていたサンプルコードをかき集めて作ったmouseClick.frameworkを用いて指定座標のクリックを行うAppleScriptです。

＃　ご注意：マウスカーソルの移動やクリックを行うのは、本来のAppleScriptの処理ではありません
＃　ご注意：他のマシン上で同じ動作を再現することが（初心者には）難しいため、おすすめしません

強制的なマウスカーソル移動とクリック（プレスともいいますね）は、「仕方なくほかに方法がなくなった場合」の、アプリケーション操作の最終手段です。やらないに越したことはない「必要悪」ともいえます。Automatorの作業記録機能が「クリック座標を記録する」という仕組みで実装されているため、AutomatorからAppleScriptに移ってきたユーザーがその調子で組もうとしてドツボにハマる姿がたまに見られます。

step1: 対象のGUIアプリケーションがAppleScript対応であれば、AppleScript用語辞書を調べて、目的の機能が呼び出せるかを確認する

step2: 対象のGUIアプリケーションの特殊機能（Custom URL Protocolなど）で目的の機能が呼び出せないかを確認する（URL Protocolだと非同期実行なので、あまり当てにならないので役に立たないケース多し）
→ とくに、Maps.appではURL Protocol経由で、しかもCustom URL schemeでもなく、http://maps.apple.comで操作するようになっています

step3: step1,2で目的の機能が呼び出せないことがわかったら、GUI Scripting経由で（メニューやボタンを操作して）呼び出せないかを試す

step4: step3でもどうしても呼び出せない場合に、GUI Scriptingで座標を指定してクリックイベントを送るという操作をためす

step5: ごくまれに、step4でも操作できないアプリケーションがある。AdobeのCreativeアプリケーションはポップアップメニューの内容を毎回プログラムから再生成していたりして、これがGUI Scriptingでも操作できない事態を引き起こす。この段階でマウスの強制移動とクリックの使用が検討される

これまで、古い仕組みを使ってマウスカーソル移動とクリックを行なっていましたが、とうとうmacOS 10.13で動かなくなり（これはバグではなく仕方ない話。OS X 10.6あたりでDeprecatedになったので）、代替手段を探していました。

CGEventRef mousedown = CGEventCreateMouseEvent(NULL, kCGEventLeftMouseDown, point, kCGMouseButtonLeft);
CGEventPost(kCGHIDEventTap, mousedown);

CGEventRef mouseup = CGEventCreateMouseEvent(NULL, kCGEventLeftMouseUp, point, kCGMouseButtonLeft);
CGEventPost(kCGHIDEventTap, mouseup);

こんな感じでカーソル移動とクリックを行なっています。サンプルコードではCGPointでパラメータを受け渡していましたが、AppleScriptから呼びやすいようにNSPointで座標値を受け渡すよう書き換えてみました。

本Framework＋AppleScript「mouseClickを用いて指定座標をクリック v2」はmacOS 10.13上で動きます。

–> mouseClick.framework (To ~/Library/Frameworks/)

後日談：
なぜか、CGPostMouseEventの機能はmacOS 10.14でふたたび使えるようになり、macOS 12上でも動作しています。deprecatedとは？

AppleScript名：mouseClickを用いて指定座標をクリック v2

— Created 2018-03-10 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "mouseClick"
use scripting additions

my clickAt(100, 10)

on clickAt(newX, newY)
　　set aPoint to current application’s NSMakePoint(newX, newY)
　　current application’s ForceClick’s alloc()’s init()’s click:aPoint
end clickAt

★Click Here to Open This Script　

AppleScript名：ASOCでマウスの強制移動とクリック（macOS 10.12まで）

— Created 2015-10-04 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4" –max version macOS 10.12
use scripting additions
use framework "Foundation"
use framework "ApplicationServices"
use framework "Quartz"

my clickAt(100, 10)

on clickAt(newX, newY)
　　
　　set pt to current application’s CGPointZero
　　set x of pt to newX
　　set y of pt to newY
　　
　　current application’s CGPostMouseEvent(pt, 1, 1, 1)
　　current application’s CGPostMouseEvent(pt, 1, 1, 0)
　　
end clickAt

★Click Here to Open This Script　

Mail.appで選択中のメールからMessage IDを取得する

Posted on 3月 13, 2018 by Takaaki Naganoya

MailCore2.frameworkを利用して、Mail.app上で選択中のメールのヘッダーからMessage IDを取得するAppleScriptです。

Mail.appから取得したヘッダーテキストから、MailCore2.frameworkでヘッダーオブジェクトを生成し、同フレームワークの機能を利用してMessage IDを取得します。１メールあたり0.03秒ぐらいで取得します。

ヘッダーのテキストを行単位でparseしてサーチしても全然いいのですが、メール関連は割と込み入った仕様がてんこ盛りなので、AppleScriptでもMailCore2をよく活用しています。

もはや、MailCore2がないとできない処理が多すぎて、これが使えないとけっこう泣きが入ります。

MailCore.framework(To ~/Library/Frameworks/)

AppleScript名：Mail.appで選択中のメールからMessage IDを取得する.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/03/12
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions
use framework "MailCore" –https://github.com/MailCore/mailcore2

tell application "Mail"
　　set a to selection
　　if a = {} then error "No Selection"
　　set aa to first item of a
　　set aSource to source of aa –メールのソースを取得
end tell

set aStr to current application’s NSString’s stringWithString:aSource
set aData to aStr’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)

set aHeader to current application’s MCOMessageHeader’s headerWithData:aData
set aMessageID to (aHeader’s messageID()) as string
–> "0A23983C-81B0-4E33-9C0B-B4A934A0E284@xxxxxx-xxx.xxx.xx"

★Click Here to Open This Script　

Enable Script Menu

Posted on 3月 12, 2018 by Takaaki Naganoya

メニューバー上にあるScript Menuを表示状態に設定変更するAppleScriptです。

Script Menuの表示・非表示はスクリプトエディタ内の環境設定で制御するようになっていますが、Script Menu自体はMenu Extraでスクリプトエディタとは独立して動作しているので、外部からオンにすることが可能です。

–> Demo Movie

▲Default

▲実行後

AppleScript名：Enable System Wide Script Menu

tell application "Finder"
　　open (POSIX file "/System/Library/CoreServices/Menu Extras/Script Menu.menu") as alias
end tell

★Click Here to Open This Script　

AppleScript名：Enable System Wide Script Menu (Shell)

do shell script "open " & quoted form of "/System/Library/CoreServices/Menu Extras/Script Menu.menu"

★Click Here to Open This Script　

追記：macOS 10.14でOS標準装備のScript MenuがMenu Extraから単体のアプリケーションに変更になったので、Enableの方法も変更になりました。

AppleScript名：Enable System Wide Script Menu_10.14.scpt

tell application "Finder"
　　open (POSIX file "/System/Library/CoreServices/Script Menu.app") as alias
end tell

★Click Here to Open This Script　

defaultsAppLibを呼び出してURLスキームに対応するアプリケーション情報を取得、設定

Posted on 3月 10, 2018 by Takaaki Naganoya

defaultappを呼び出して、指定のURLスキームに対応するdefault applicationを取得したり設定したりするAppleScriptです。

–> defaultAppLib (To ~/Library/Script Libraries/)

AppleScript名：defaultsAppLibを呼び出してURLスキームに対応するアプリケーション情報を取得、設定

use AppleScript version "2.4"
use scripting additions
use defautApLib : script "defaultAppLib" –https://github.com/Grayson/defaultapp

–指定のURLスキームに対応するアプリケーションのパスを取得
set aRes to getDefaultAppForScheme("http") of defautApLib
–> "/Applications/Safari.app"

set bRes to getDefaultAppForScheme("ftp") of defautApLib
–> "/Applications/Transmit.app"

–指定のURLスキームに対応するアプリケーションを設定
set cRes to setDefaultAppForScheme("ftp", "Safari") of defautApLib
–> true

–指定のURLスキームに対応するアプリケーションのパスを取得（再確認）
set dRes to getDefaultAppForScheme("ftp") of defautApLib
–> "/Applications/Safari.app"

★Click Here to Open This Script　

shebangっぽい行から実行プログラムを取得してスクリプト言語の拡張子を取得

Posted on 3月 10, 2018 by Takaaki Naganoya

shebangを含む複数行のテキストからshebang（らしきもの）を検索して、実行プログラム名を取得し、実行するScript言語のファイルの拡張子を判定するAppleScriptです。

RTFで記述したシェルスクリプトやRubyのスクリプトのスケルトンに、色分けしたパラメータ部分のデータを差し替えてRubyやシェルスクリプトの実行ファイルを動的に書き出し、所定のスクリプト言語処理系で実行するAppleScriptを書いたときに用いたものです。

割と処理内容はヘロヘロでたいした固い処理は行なっていませんが、凶悪な処理を行うためのキーパーツです。

AppleScript名：shebangっぽい行から実行プログラムを取得してスクリプト言語の拡張子を取得

set aText to "#!/usr/bin/env python
import re
"

set aLang to splitLangFromShebangStr(aText) of me
if aLang = false then error "This data seems not a shebang"
set aExt to detectScriptFileExtension(aLang) of me
return {aLang, aExt}
–> {"python", "py"}

–shebangっぽい行から実行プログラム名を抽出
on splitLangFromShebangStr(aText)
　　set aTmpList to paragraphs of aText
　　
　　repeat with i in aTmpList
　　　　set j to contents of i
　　　　if j starts with "#!" then
　　　　　　set aWorkList to words of j
　　　　　　set aLang to contents of last item of aWorkList
　　　　　　return aLang
　　　　end if
　　end repeat
　　
　　return false
end splitLangFromShebangStr

on detectScriptFileExtension(aLang)
　　ignoring case
　　　　if aLang = "Ruby" then
　　　　　　return "rb"
　　　　else if aLang = "Python" then
　　　　　　return "py"
　　　　else if aLang = "perl" then
　　　　　　return "pl"
　　　　else if aLang = "sh" then
　　　　　　return "sh"
　　　　else
　　　　　　return ""
　　　　end if
　　end ignoring
end detectScriptFileExtension

★Click Here to Open This Script　

光学ドライブ情報の取得

Posted on 3月 10, 2018 by Takaaki Naganoya

AppleScript名：光学ドライブ情報の取得.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/03/10
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use scripting additions

set dInfoList to getOpticalDrivesInfo() of me
–> {{driveNum:"1", vendorName:"BUFFALO", productName:"Optical Drive", supportLevel:"Unsupported", revisionNo:"BFT6", busName:"USB", suppoortLevel:"Unsupported"}, {driveNum:"2", vendorName:"MATSHITA", productName:"BD-MLT UJ240AS", supportLevel:"Unsupported", revisionNo:"1.00", busName:"USB", suppoortLevel:"Unsupported"}}

–光学ドライブの情報を返す
on getOpticalDrivesInfo()
　　set dList to paragraphs of (do shell script "drutil list")
　　set d2List to removeItemFromList(dList, "") of me
　　
　　if length of d2List = 1 then return false –No Optical Drive
　　
　　set d2List to rest of d2List –skip first header row
　　
　　set dMainList to {}
　　repeat with i in d2List
　　　　set tmpA to (current application’s NSString’s stringWithString:i)
　　　　set tmpB to (tmpA’s componentsSeparatedByString:" ") as list –parse string by space character
　　　　set tmpC to removeItemFromList(tmpB, "") of me –remove empty item from list
　　　　
　　　　set dNum to first item of tmpC
　　　　set aVendor to second item of tmpC
　　　　set supLevel to last item of tmpC
　　　　set busStr to item -2 of tmpC
　　　　set revStr to item -3 of tmpC
　　　　
　　　　–Product Nameのlist itemをスペースでつないで文字列化
　　　　set prodName1 to items 3 thru -4 of tmpC
　　　　set prodName2 to retStrFromArrayWithDelimiter(prodName1, " ") of me
　　　　
　　　　set the end of dMainList to {driveNum:dNum, vendorName:aVendor, productName:prodName2, supportLevel:supLevel, revisionNo:revStr, busName:busStr, suppoortLevel:supLevel}
　　end repeat
　　
　　return dMainList
end getOpticalDrivesInfo

–1D Listから指定内容の要素をすべて削除する
on removeItemFromList(aTargList, aTargValue)
　　set anArray to current application’s NSMutableArray’s arrayWithArray:aTargList
　　repeat
　　　　set aInd to anArray’s indexOfObject:aTargValue
　　　　–macOS 10.12〜10.13.0までのNSNotFoundの値定義の間違いというAppleの恥ずかしいバグに対処
　　　　if aInd = current application’s NSNotFound or (aInd as real > 9.99999999E+8) then exit repeat
　　　　anArray’s removeObjectAtIndex:aInd
　　end repeat
　　return anArray as list
end removeItemFromList

–リストを指定デリミタをはさんでテキスト化
on retStrFromArrayWithDelimiter(aList, aDelim)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set aRes to anArray’s componentsJoinedByString:aDelim
　　return aRes as text
end retStrFromArrayWithDelimiter

★Click Here to Open This Script　

使用メモリーの状況を取得

Posted on 3月 10, 2018 by Takaaki Naganoya

AppleScript名：使用メモリーの状況を取得

— Created 2017-12-17 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set mRes to retMemoryUsage() of me
–> {usedMem:7928, wiredMem:1763, unusedMem:257}

on retMemoryUsage()
　　set memRes to do shell script "top -l 1 | head -10 | grep ’PhysMem’"
　　set aRes to (parseStrFromTo(memRes, " ", "M") of me)
　　
　　set bList to {}
　　repeat with i in aRes
　　　　set mRes to returnNumberOnly(i) of me
　　　　set the end of bList to mRes
　　end repeat
　　
　　set usedNum to contents of first item of bList
　　set wiredNum to contents of second item of bList
　　set unusedNum to contents of third item of bList
　　return {usedMem:usedNum as integer, wiredMem:wiredNum as integer, unusedMem:unusedNum as integer}
end retMemoryUsage

on parseStrFromTo(aParamStr, fromStr, toStr)
　　set theScanner to current application’s NSScanner’s scannerWithString:aParamStr
　　set anArray to current application’s NSMutableArray’s array()
　　
　　repeat until (theScanner’s isAtEnd as boolean)
　　　　— terminate check, return the result (aDict) to caller
　　　　set {theResult, theKey} to theScanner’s scanUpToString:fromStr intoString:(reference)
　　　　
　　　　— skip over separator
　　　　theScanner’s scanString:fromStr intoString:(missing value)
　　　　set {theResult, theValue} to theScanner’s scanUpToString:toStr intoString:(reference)
　　　　if theValue is missing value then set theValue to "" –>追加
　　　　
　　　　— skip over separator
　　　　theScanner’s scanString:toStr intoString:(missing value)
　　　　
　　　　anArray’s addObject:theValue
　　end repeat
　　
　　return anArray as list
end parseStrFromTo

on returnNumberOnly(aStr)
　　set anNSString to current application’s NSString’s stringWithString:aStr
　　set anNSString to anNSString’s stringByReplacingOccurrencesOfString:"[^0-9]" withString:"" options:(current application’s NSRegularExpressionSearch) range:{0, anNSString’s |length|()}
　　return anNSString as text
end returnNumberOnly

★Click Here to Open This Script　

ディスク使用状況を取得

Posted on 3月 9, 2018 by Takaaki Naganoya

AppleScript名：ディスク使用状況を取得

— Created 2017-12-17 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set dRes to diskUsage() of me
–> {readSector:8557760, readSize:"152G", writeSecotr:2601227, writeSize:"100G"}

on diskUsage()
　　set dRes to (do shell script "top -l 1 | head -10 | grep ’Disks:’")
　　set dList to words of dRes
　　set readSectorNum to (contents of item 2 of dList) as integer
　　set readSizeNum to contents of item 3 of dList
　　set writeSectorNum to (contents of item 5 of dList) as integer
　　set writeSizeNum to contents of item 6 of dList
　　return {readSector:readSectorNum, readSize:readSizeNum, writeSecotr:writeSectorNum, writeSize:writeSizeNum}
end diskUsage

★Click Here to Open This Script　

ネットワーク使用状況を取得

Posted on 3月 9, 2018 by Takaaki Naganoya

AppleScript名：ネットワーク使用状況を取得

— Created 2017-12-17 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set nRes to networkUsage() of me
–> {inPacket:4904085, inSize:"5444M", outPacket:3426539, outSize:"396M"}

on networkUsage()
　　set nRes to (do shell script "top -l 1 | head -10 | grep ’Networks: packets:’")
　　set nList to words of nRes
　　set inPackNum to (contents of item 3 of nList) as integer
　　set inSizeNum to (contents of item 4 of nList)
　　set outPackNum to (contents of item 6 of nList) as integer
　　set outSizeNum to (contents of item 7 of nList)
　　return {inPacket:inPackNum, inSize:inSizeNum, outPacket:outPackNum, outSize:outSizeNum}
end networkUsage

★Click Here to Open This Script　

get battery info v2

Posted on 3月 9, 2018 by Takaaki Naganoya

バッテリー関連の情報を取得するAppleScriptです。

ioregコマンドなどでハードウェア周りの情報を取得する方法は昔から知られており、有益な情報を利用できます。

本ScriptはCocoaの機能も使っておらず、割と古めな構造のものですが、安定して動作しているので使い続けています。

もともと、本Scriptのファイル名は「バッテリ情報を取得.scpt」というものでしたが、「バッテリ情報を取得 v2.scpt」にFinder上でリネームしようとしたら、「ファイル名が長すぎるか、句読点を含まないファイル名に変更してくれ」というエラーをmacOS 10.12および10.13のFinderが出力して、仕方なく英語のファイル名にリネームしました。

# 10.14.6でも10.15.1でも発生しています

macOSのどこのバージョンだかわからないのですが、おそらくファイル名の入力時に001Dのような不可視キャラクタが混入し、Finder上でリネームできなくなるようです。日本語環境でのみ発生する問題と思われます。

AppleScript名：get battery info v2

set bInfo to getBatteryInfo() of batteryKit
–> {CurrentCapacity:5129, MaxCapacity:5265, DesignCapacity:8460, CycleCount:478}

script batteryKit
　　on getBatteryInfo()
　　　　–ハードウェアの識別文字列を取得
　　　　set machineType to do shell script "sysctl -n hw.model"
　　　　
　　　　–MacBook Proを検出したら、あるいは結果にMacBookの文字列が入っていなかったら終了
　　　　if machineType does not contain "MacBook" then
　　　　　　return {CurrentCapacity:0, MaxCapacity:0, DesignCapacity:0}
　　　　end if
　　　　
　　　　–MacBookだけ処理続行
　　　　
　　　　–ハードウェア情報を取得
　　　　set batCom to "ioreg -p IOService -n AppleSmartBattery -w 0"
　　　　set a to do shell script batCom
　　　　set aList to every paragraph of a
　　　　
　　　　set itemCount to 1
　　　　set hitF to false
　　　　repeat with i in aList
　　　　　　set j to contents of i
　　　　　　if j contains "AppleSmartBattery <class AppleSmartBattery" then
　　　　　　　　set resList to items (itemCount + 2) thru (itemCount + 29) of aList
　　　　　　　　set hitF to true
　　　　　　　　exit repeat
　　　　　　end if
　　　　　　set itemCount to itemCount + 1
　　　　end repeat
　　　　if hitF = false then return
　　　　
　　　　
　　　　set findAttrList to {"CurrentCapacity", "MaxCapacity", "DesignCapacity", "CycleCount"}
　　　　set hitList to {}
　　　　repeat with i in findAttrList
　　　　　　set j to string id 34 & contents of i & string id 34
　　　　　　
　　　　　　repeat with ii in resList
　　　　　　　　set jj to contents of ii
　　　　　　　　if jj contains j then
　　　　　　　　　　set the end of hitList to jj
　　　　　　　　　　exit repeat
　　　　　　　　end if
　　　　　　end repeat
　　　　end repeat
　　　　
　　　　
　　　　–現在のバッテリーの容量を取得
　　　　set curCap to parseAfterSpecifiedChar("=", contents of item 1 of hitList) of me
　　　　set curCap to curCap as number
　　　　
　　　　–バッテリーの最大容量を取得
　　　　set maxCap to parseAfterSpecifiedChar("=", contents of item 2 of hitList) of me
　　　　set maxCap to maxCap as number
　　　　
　　　　–バッテリーの最大容量を取得
　　　　set designCap to parseAfterSpecifiedChar("=", contents of item 3 of hitList) of me
　　　　set designCap to designCap as number
　　　　
　　　　–バッテリーの充放電回数を取得
　　　　set cCount to parseAfterSpecifiedChar("=", contents of item 4 of hitList) of me
　　　　set cCount to cCount as number
　　　　
　　　　return {CurrentCapacity:curCap, MaxCapacity:maxCap, DesignCapacity:designCap, CycleCount:cCount}
　　　　
　　end getBatteryInfo
　　
　　
　　–対象文字列（aData）の中で、aCharの文字以降を取得
　　on parseAfterSpecifiedChar(aChar, aData)
　　　　set aPos to offset of aChar in aData
　　　　set resText to text (aPos + (length of aChar)) thru -1 of aData
　　　　return resText
　　end parseAfterSpecifiedChar
end script

★Click Here to Open This Script　

指定アプリケーションのヘルプブック内の指定アンカーを表示する

Posted on 3月 8, 2018 by Takaaki Naganoya

指定名称のアプリケーションのヘルプブック内で指定アンカーを表示するAppleScriptです。

HelpBookを表示するOS標準搭載アプリケーション「HelpViewer」は一応AppleScript対応のスクリプタブルなアプリケーションなので、AppleScriptからコントロールできるのですが、経験上あまり信頼性がない（コマンドを無視して、表示しないことがある）ので、Cocoa経由でアンカー指定表示を行わせてみました。

Cocoa経由でもすぐに応答は返ってこないのですが、（HelpViewerの起動を含めて）数秒待たされて結果が表示される感じです。

HelpBookは、いわば「フローティング表示する、おそいWebブラウザ」で、かつてはWebコンテンツ内からAppleScriptの実行も指定できたため、一時期「Mac OS Xで有名なセキュリティーホール」として注目を集めました。URLイベント経由でScriptの実行を指定できてしまうとか、便利ではあったもののセキュリティーホールと言われればセキュリティホールです（注：すぐにふさがれました　＆　この前後からローカルでのURLプロトコルの監視がきつくなりました）。

AppleScript名：指定アプリケーションのヘルプブック内の指定アンカーを表示する

— Created 2017-04-18 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set anAppName to "Script Editor"
set aTargAnchor to "scpedt1126" —-https://help.apple.com/scripteditor/mac/10.12/index.html?localePath=ja.lproj#/scpedt1126
set hRes to openHelpBook(anAppName, aTargAnchor) of me

–指定アプリケーションのヘルプブックで、指定アンカーを表示する
on openHelpBook(anAppName, aTargAnchor)
　　set locBookName to getHelpBook(anAppName) of me
　　if locBookName = false then return false
　　current application’s NSHelpManager’s sharedHelpManager()’s openHelpAnchor:aTargAnchor inBook:locBookName
end openHelpBook

–指定アプリケーションのヘルプブック名称を取得する
on getHelpBook(anAppName)
　　set aWorkspace to current application’s NSWorkspace’s sharedWorkspace()
　　set appPath to aWorkspace’s fullPathForApplication:anAppName
　　if appPath is equal to missing value then return false
　　
　　set locBookName to (current application’s NSBundle’s bundleWithPath:appPath)’s objectForInfoDictionaryKey:"CFBundleHelpBookName"
　　if locBookName is equal to missing value then return false
　　–> "com.apple.ScriptEditor.help"
　　return locBookName
end getHelpBook

★Click Here to Open This Script　

AppleScript名：help_sample

tell application "HelpViewer"
　　activate
　　try
　　　　lookup anchor "scpedt1126" in book "com.apple.ScriptEditor.help"
　　end try
end tell

★Click Here to Open This Script　