SFPSDWriterのじっけん v2

Posted on 9月 21, 2020 by Takaaki Naganoya

AppleScriptからPhotoshopのデータ（PSD）を出力するテストプログラムです。

AppleScriptにはPhotoshopのデータを書き出す関数や機能はとくに用意されていないため、Photoshopのデータを書くためにはPhotoshopにコマンドを送って実行してもらうのが定番です。

この定番の方法だと、Photoshopが存在しない環境でPhotoshopのデータを作ることができません。この問題を解決するためにはオープンソースで公開されている「Photoshopデータを書くプログラム部品」を呼び出すことになります。

Photoshopデータについては一定の需要があるためか、AdobeがPhotoshopデータ形式の詳細な資料を公開しているためか、Reader（読むプログラム）とWriter（書くプログラム）の２通りのプログラムが存在します。

■PSD Reader/Parser
PSD-Font-Reader
psdparse

■PSD Writer
FMPSD
PSDWriter
SFPSDWriter

ここでは、「SFPSDWriter」内に含まれる「SFPSDWriter」Frameworkを呼び出しています。

–> Download SFPSDWriter.framework(To ~/Library/Frameworks)

実行にあたっては、macOS 10.14以降ではScript Debuggerを用いるか、お使いのMacをSIP解除してScript Editor上で呼び出して実行する必要があります。

ちょっと書き換えるとXcode上でも呼び出せることでしょう。Mac App Storeに出すAppleScript Cocoaアプリケーション（Sandbox対応）内で利用する場合には、ファイル書き込みパスをユーザーに明示的に選択させる必要があるため、choose file nameダイアログでファイル名を入力・選択してもらうようにすべきです（デフォルト指定のファイル名をUUIDで自動生成するとか）。

本AppleScriptはKamenokoから書き出せるデータを増やすべく「Photoshop形式のデータを書けたらどうだろう？」と実験してみた残骸です。結局、PDFで書き出せるしPDFなら拡大縮小しても荒くなったりしないので、PDFのほうがいいという結論に。

Pixelmator Proのデータ形式とかPSD形式で書き出す実験は行っているのですが、処理結果を見るとどちらも「PDF形式のほうがいい」という結論に至っています。

▲ベクターデータではないので、拡大するとアラが見える

AppleScript名：SFPSDWriterのじっけん v2

— Created 2016-03-12 by Takaaki Naganoya
— Modified 2019-02-27 by Takaaki Naganoya
— Modified 2020–09-21 by Takaaki Naganoya
— 2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "SFPSDWriter" –https://github.com/shinyfrog/SFPSDWriter

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSUUID : a reference to current application’s NSUUID
property NSImage : a reference to current application’s NSImage
property SFPSDWriter : a reference to current application’s SFPSDWriter
property NSWorkspace : a reference to current application’s NSWorkspace

property SFPSDResolutionUnitPPI : 1
property SFPSDResolutionUnitPPC : 2

set anWriter to (SFPSDWriter’s alloc()’s initWithDocumentSize:(current application’s CGSizeMake(1200, 400)) andResolution:72.0 andResolutionUnit:(SFPSDResolutionUnitPPI))

set aCount to 1

repeat with yPos from 0 to 400 by 110
　　repeat with xPos from 0 to 1024 by 110
　　　　set aImage to (current application’s NSImage’s alloc()’s initWithSize:{100, 100})
　　　　set aColor to current application’s NSColor’s redColor()
　　　　my drawCircleOnNSIMage(aImage, 100, 0, 0, aColor)
　　　　
　　　　(anWriter’s addLayerWithNSImage:aImage andName:("Layer_" & aCount as string) andOpacity:1.0 andOffset:{x:(xPos as real), y:(yPos as real)})
　　　　set aCount to aCount + 1
　　end repeat
end repeat

set aPSD to anWriter’s createPSDData()

set theName to NSUUID’s UUID()’s UUIDString()
set pathString to NSString’s stringWithString:("~/Desktop/output_" & theName & ".psd")
set newPath to pathString’s stringByExpandingTildeInPath()

aPSD’s writeToFile:newPath atomically:true

#　　MARK: Call By Reference
on drawCircleOnNSIMage(aImage, aRadius, aXpos, aYpos, aColor)
　　set aBezier to generateCircle(aRadius, aXpos, aYpos) of me
　　(aImage)’s lockFocus()
　　aColor’s |set|()
　　aBezier’s fill() –ぬりつぶし
　　(aImage)’s unlockFocus()
end drawCircleOnNSIMage

#　　MARK: circleのBezier曲線を作成して返す
on generateCircle(theRadius, x, y)
　　set aRect to current application’s NSMakeRect(x, y, theRadius, theRadius)
　　set aCirCle to current application’s NSBezierPath’s bezierPath()
　　aCirCle’s appendBezierPathWithOvalInRect:aRect
　　return aCirCle
end generateCircle

★Click Here to Open This Script　

画像の空白判定プログラムの検証

Posted on 7月 28, 2020 by Takaaki Naganoya

画像の全ピクセルが白かどうかチェックする処理ルーチンは、必要に迫られて作ったものです。しかも、高速処理が求められます。

アイコン画像よりも小さな、たかだか1024 x 768ピクセルの画像であっても、全画素の空白をループでチェックしたら78万ピクセルあるわけで、地道に画像に対して座標を指定しつつ78万回カラーチェックを行うのは現実的ではありません。

作成した空白チェックのルーチンは３つ。

(1)Photoshopの明度ヒストグラム機能を利用するもの

Adobe Photoshopの明度ヒストグラム機能を利用するもの。はるかかなた昔から使っており、信頼性も高かったものの実行にはPhotoshopを要するため、どこでも同様に実行するわけにはいきませんでした。HTMLをPDF出力させたときに、無駄な空白ページが末尾にできることをチェックしたりと、重要な処理に使ってきました（プリントアウト時に無駄紙を省けるとか。枚数が増えると割と切実な問題です）。

(2)GPUImage.frameworkを利用するもの

オープンソースのGPUImage.framework（Objective-Cで書かれた初代のGPUImage 1）を呼び出して明度ヒストグラム計算を実行。スピード、コストなどの面で問題を解決できていますが、GPUImage自体がSwiftで書き直されたり、OpenGLからMetal向けに書き直されたりで、GPUImage 1自体の継続性については問題がある状態です。

(3)AppleScriptだけで書き直したもの

Cocoaの機能を利用して画像の空白チェックを実現。元画像のコピーを作って、白くぬりつぶして、オリジナル画像との照合を行う。同じであれば空白画像、同じでなければ空白画像ではないという判定を行います。4K解像度以下であれば最速。

そして、今後(1)〜(3)のどれを使い続けるべきかを、macOS 10.14.6でチェックしてみました。テストプログラムでは空白画像検出時にtrueを、空白でない場合にはfalseを返す仕様に。

	(1)	(2)	(3)
1024x768_1_black.png	false	true	false
4K_3840x2160_1_pixel_black.psd	false	true	false
1x1_white.png	true	false	true

結果は、(1)と(3)が同じ結果を返しました。(2)だけ結果が異なるケースが見られたため、Photoshopの有無に左右されないことを考えると(3)が有力といえます。

実際に、Mac App Store上で販売しているPDF差分検出ツール「Double PDF」ではv2.0からはGPUImageの利用をやめ、処理内容をすべてAppleScriptだけで行うことでスピードアップを果たしています。

この空白画像の検出以外でどの程度GPUImage 1がmacOS 10.14以降の環境で使えるか、使えないかは別のテストが必要でしょう。

Photoshop CCでファイルをオープン

Posted on 5月 29, 2019 by Takaaki Naganoya

Photoshop CCで画像ファイル/PDFをオープンするAppleScriptです。

作成と動作確認はmacOS 10.14.5＋Photoshop CC2019で行っています。一般的な画像ファイルのオープンはこちら。

Adobeのアプリケーションの操作を行っていると、５分に１回ぐらい首をひねる瞬間がやってきますが、疑問に思っても無駄なので、各種操作はサブルーチンに追い出して、直接Adobeアプリケーションの相手をしないほうが精神衛生上よいと思われます（contentsという超重要な予約語がコンフリクトしているのでオブジェクトを取り出してループするときに途方に暮れるとか、アプリケーションによってはオブジェクトの座標情報の順序がおかしいとかいろいろ）。

その中でもとびきりおかしいのが、この、Photoshopでのファイルオープン時のファイルパスの取り扱いです。

結局このおかしな書き方でしかオープンしてくれない（aliasを直接openできない謎仕様）という状況で、ここで疑問が生まれると、ふたたびAdobeのアプリケーションのおかしな仕様をひととおり体験することになるのです。

＃　後から気づきましたが、Photoshopのopen命令は返り値がないですね、、、、

AppleScript名：Photoshop CCで画像ファイルをオープンする

set a to choose file

set aPosix to POSIX path of a

tell application id "com.adobe.photoshop"
　　open file aPosix
end tell

★Click Here to Open This Script　

PDFのオープンはこちらです。PDFをbounding boxでトリミングしてオープンするのは、Cocoaの機能を利用してもなかなか骨が折れるので、かえってPhotoshopを呼び出してPDF→画像変換を行うほうが簡単なようです。

AppleScript名：Photoshop CCでPDFをオープンする

set aFile to (choose file)
set aPOSIX to POSIX path of aFile

set aPage to 1
set aResol to 300

tell application id "com.adobe.photoshop"
　　open file aPOSIX as PDF with options {class:PDF open options, page:aPage, crop page:bounding box, resolution:aResol, mode:RGB}
end tell

★Click Here to Open This Script　

SFPSDWriterでレイヤー分けしたPhotoshopデータを作成

Posted on 2月 27, 2019 by Takaaki Naganoya

オープンソースのSFPSDWriterを呼び出して、レイヤー分けしたPhotoshopデータを作成するAppleScriptです。

SFPSDWriterは基本的にCGImageを与えてPSDを作成するプログラムですが、AppleScriptからはCGImageを作れません。

SFPSDWriterのソースコードを読んでみたら、コメントにNSImageからCGImageへの変換方法が書かれていたので、NSImageを受け付けるメソッドを新規追加してAppleScriptから呼べるようにしてみました。

–> Download SFPSDWriter.framework(To ~/Library/Frameworks)

PSDを読み書きするObjective-Cのプログラムは割とすぐに見つかるのですが、AppleScriptから呼べない（CGImageをパラメータにするため）ものが多く、どれか１つぐらいは使えてほしいと思っていました。

SFPSDWriterの機能はすべて試せていませんが、名前どおり本ソフトはPSDファイルを書き込む専用であって、読むためのものではありません。これ以外にPSDファイルを読み込んでオブジェクトを取り出せる（ように改造できる）ものを探しておきたいところです。Photoshopを用いないでPSDデータにアクセスできることには価値があります。Mac App Storeに出すソフトウェアだととくにそうです。

Photoshopを操作してほぼ同様の処理を行うものを書いてみましたが、SFPSDWriterを用いて処理したほうがシンプルなことに驚きます。

AppleScript名：SFPSDWriterのじっけん

— Created 2016-03-12 by Takaaki Naganoya
— Modified 2019-02-27 by Takaaki Naganoya
— 2019 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "SFPSDWriter" –https://github.com/shinyfrog/SFPSDWriter

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSImage : a reference to current application’s NSImage
property SFPSDWriter : a reference to current application’s SFPSDWriter
property NSWorkspace : a reference to current application’s NSWorkspace

property SFPSDResolutionUnitPPI : 1
property SFPSDResolutionUnitPPC : 2

set layer1 to NSImage’s alloc()’s initWithContentsOfURL:(|NSURL|’s fileURLWithPath:(POSIX path of (choose file of type {"public.png"})))
set layer2 to NSImage’s alloc()’s initWithContentsOfURL:(|NSURL|’s fileURLWithPath:(POSIX path of (choose file of type {"public.png"})))

set anWriter to SFPSDWriter’s alloc()’s initWithDocumentSize:(current application’s CGSizeMake(1024, 400)) andResolution:72.0 andResolutionUnit:(SFPSDResolutionUnitPPI)

anWriter’s addLayerWithNSImage:layer1 andName:"Layer_01" andOpacity:1.0 andOffset:{x:0.0, y:0.0}
anWriter’s addLayerWithNSImage:layer2 andName:"Layer_02" andOpacity:1.0 andOffset:{x:50.0, y:50.0}

set aPSD to anWriter’s createPSDData()

set pathString to NSString’s stringWithString:"~/Desktop/output.psd"
set newPath to pathString’s stringByExpandingTildeInPath()

aPSD’s writeToFile:newPath atomically:true

–Open with Adobe Photoshop
NSWorkspace’s sharedWorkspace()’s openFile:newPath

★Click Here to Open This Script　

AppleScript名：PhotoshopでSFPSDWriterと同じような処理を行う

— Created 2019-02-27 by Takaaki Naganoya
— 2019 Piyomaru Software
set layer1 to (choose file of type {"public.png"}) as string
set layer2 to (choose file of type {"public.png"}) as string

tell application id "com.adobe.photoshop"
　　activate
　　close every document saving no
　　
　　set aDoc to make new document with properties {height:900, width:900, resolution:72.0, mode:RGB, bits per channel:eight, initial fill:transparent, color profile kind:none, pixel aspect ratio:1.0}
　　tell aDoc
　　　　set origLayer to (first item of (name of every art layer)) as string
　　end tell
　　
　　open file layer1
　　set bDoc to a reference to current document
　　tell bDoc
　　　　select all
　　　　copy
　　　　close without saving
　　end tell
　　
　　tell aDoc
　　　　set artLayerRef to make new art layer with properties {name:"Layer_01"}
　　　　set current layer to artLayerRef
　　　　tell artLayerRef
　　　　　　paste
　　　　end tell
　　end tell
　　
　　open file layer2
　　set cDoc to a reference to current document
　　tell cDoc
　　　　select all
　　　　copy
　　　　close without saving
　　end tell
　　
　　tell aDoc
　　　　set artLayerRef to make new art layer with properties {name:"Layer_02"}
　　　　set current layer to artLayerRef
　　　　tell artLayerRef
　　　　　　paste
　　　　end tell
　　　　
　　　　delete art layer origLayer
　　end tell
end tell

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: Photoshop

SFPSDWriterのじっけん v2

画像の空白判定プログラムの検証

(1)Photoshopの明度ヒストグラム機能を利用するもの

(2)GPUImage.frameworkを利用するもの

(3)AppleScriptだけで書き直したもの

Photoshop CCでファイルをオープン

SFPSDWriterでレイヤー分けしたPhotoshopデータを作成