(POST) Google Translate APIで翻訳

Posted on 12月 10, 2018 by Takaaki Naganoya

Google Translate API（REST API）を呼び出して、指定のテキストを別の言語に翻訳するAppleScriptです。

Google Cloud Consoleにお持ちのGoogleアカウントでログインし、プロジェクトを作成して、プロジェクト用のAPIを個別に許可（この場合にはGoogle Translate API）し、API Keyを発行してScript中に記述して呼び出します（retAPIKeyハンドラ中にハードコーディングするのが嫌であれば、Keychainに登録して呼び出すことも可能です）。

処理内容自体は、REST API呼び出しのいつものやつなんでとくに解説はしません。コピペで作れるぐらい退屈で簡単です（本Scriptも呼び出せることを確認するだけして放置していました）。

ただ、本Scriptは同期処理用のNSURLConnectionを使って呼び出しているバージョンで、このNSURLConnectionが将来的に廃止される見込みなので、curlコマンドで呼び出すか、NSURLSessionを使って呼び出すように書き換えるか、といったところです。

単体だとただ翻訳できるだけで、あまり面白味はありません。本ScriptはMicrosoft Azure Computer Vision APIで画像認識を行なったときに、その画像認識テキストが英文で返ってきており、その内容を日本語に自動翻訳するときに使用してみました。翻訳精度は悪くないと思うのですが、画像のシーン認識テキストの英文がいまひとつだったので、「英文で出力してくれた方がまだわかりやすい」というところで、個人的にはあまり活躍していません。

Translate APIを売り物の本の翻訳に使うことが許可されていないなど、利用許諾が割と厳しいので使いどころが多そうに見えつつもそうでもない、といったところでしょうか。

AppleScript名：(POST) Google Translate APIで翻訳

— Created 2016-03-03 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSURLConnection : a reference to current application’s NSURLConnection
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

set aSentense to "a birthday cake with lit candles"
set bSentense to retTranslatedString("en", "ja", aSentense) of me
–> "キャンドルライト付きの誕生日ケーキ"–Japanese

set cSentense to retTranslatedString("en", "de", aSentense) of me
–> "eine Geburtstagstorte mit brennenden Kerzen"–Deutsch

on retTranslatedString(fromLang, toLang, aSentense)
　　set myAPIKey to retAPIKey() of me
　　set aRec to {|key|:myAPIKey, source:fromLang, |format|:"text", target:toLang, q:aSentense}
　　set aURL to "https://www.googleapis.com/language/translate/v2"
　　set bURL to retURLwithParams(aURL, aRec) of me
　　set aRes to callRestPOSTAPIAndParseResults(bURL) of me
　　
　　set aRESCode to responseCode of aRes
　　if aRESCode is not equal to 200 then return ""
　　set aRESHeader to responseHeader of aRes
　　set aRESTres to (translatedText of (first item of translations of |data| of json of aRes)) as string
　　return aRESTres
end retTranslatedString

–POST methodのREST APIを呼ぶ
on callRestPOSTAPIAndParseResults(aURL)
　　set aRequest to NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"POST"
　　aRequest’s setValue:"application/x-www-form-urlencoded" forHTTPHeaderField:"Content-Type"
　　
　　set aRes to NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to NSString’s alloc()’s initWithData:bRes encoding:(NSUTF8StringEncoding)
　　
　　set jsonString to NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestPOSTAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) –as text
　　
　　return aURL
end retURLwithParams

on retAPIKey()
　　return "XXxxXxXXXxXxX-XxXXxXXXxxxxXXXXxXxXXxXXX"
end retAPIKey

★Click Here to Open This Script　

teratailの指定IDのユーザー情報を取得する_curl

Posted on 11月 27, 2018 by Takaaki Naganoya

プログラミング系質問サイトteratailのREST APIを呼び出して、指定ユーザー名の情報を取得するAppleScriptです。

TeratailのREST APIは、タグ、ユーザー、質問の３ジャンルの情報取得を行えるように整備されており、特定カテゴリ（タグで分類）の新規質問が投稿されたかどうかを定期的に確認するようなAppleScriptを作って運用することもできます（そこまでやっていないですけれども）。

REST API呼び出しにはNSURLConnectionからNSURLSessionに移行していますが、どうもNSURLSessionだと呼び出せない（AppleScriptからの呼び出し処理が完了しない）サービスがあったりするので、結局shellのcurlコマンドを呼び出すのが手短にすむケースが多いようです。

Teratailの場合も、NSURLSessionで呼び出せるAPIもあれば、結果が返ってこないAPIもあり、NSURLConnectionよりも使い勝手がよくないと感じています（個人の感想です）。

このあたり、将来的なmacOSのアップデートでNSURLConnectionが使えなくなる日が来るのかもしれませんが、curlコマンドを使うように集約するべきなのか、NSURLSessionで書き換えるべきなのか悩ましいところです。

AppleScript名：teratailの指定IDのユーザー情報を取得する_curl

— Created 2018-11-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSURLSession : a reference to current application’s NSURLSession
property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSJSONSerialization : a reference to current application’s NSJSONSerialization
property NSURLComponents : a reference to current application’s NSURLComponents
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSMutableURLRequest : a reference to current application’s NSMutableURLRequest
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding
property NSURLSessionConfiguration : a reference to current application’s NSURLSessionConfiguration

set aUserRes to searchOneUserByDisplayName("Piyomaru") of me
–> {meta:{limit:20, message:"success", hit_num:1, total_page:1, page:1}, users:{{score:43, photo:"https://teratail.storage.googleapis.com/uploads/avatars/u6/66639/MSIS21by_thumbnail.jpg", display_name:"Piyomaru"}}}

on searchOneUserByDisplayName(aName)
　　set aRec to {q:aName}
　　set reqURLStr to "https://teratail.com/api/v1/users/search"
　　set bURL to retURLwithParams(reqURLStr, aRec) of me
　　
　　set tmpData to (do shell script "curl -X GET ＼"" & bURL & "＼"")
　　set jsonString to NSString’s stringWithString:tmpData
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　if aJsonDict = missing value then return false
　　return (aJsonDict as record)
end searchOneUserByDisplayName

on retURLwithParams(aBaseURL, aRec)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

機械学習で学習したMSの画像を連邦・ジオン軍判定してフォルダ分け v2

Posted on 11月 20, 2018 by Takaaki Naganoya

Create MLでガンダムのMS画像（連邦、ジオン区分け）を学習したCore ML Modelをもとに、画像をどちらの軍所属機体かを判定してフォルダ分けするAppleScriptです。

機械学習（深層学習）データをもとに判定を行って対話型処理ではなくバッチ処理的なフローでデータを「なんとなく」推論して区分けを行うサンプルです。非力なIOT機器が機械学習データをもとに推論処理できるぐらいなので、機械学習データを使ってAppleScriptで推論処理できないはずがありません。推論処理時間もさほどかからず、機械学習データを一括処理的なワークフローの中で利用することが可能です。

例によって「戦場の絆」の公式ページから落としてきたMSの画像を連邦軍とジオン軍、および両軍の鹵獲機体の４フォルダに分けてCreate MLで学習させてみました。

実行するとMS画像が入っているフォルダ（各自ご用意ください）と、連邦軍機体（efsf）およびジオン軍機体（zeon）を仕分けるフォルダを聞かれます。あとはプログラム側がなんとなく推論して仕分けを行います。

前回掲載のモデルもそうですが、きちんと学習後にテストデータで評価を行っています。だいたい８割ぐらいのヒット率ではあるものの、特定の画像については間違えることがあらかじめわかっています。

実行にあたっては、macOS 10.14上でCoreML Modelを組み込んだフレームワーク「msDetector.framework」をインストールして、本ScriptをScript Debugger上で動作させてください。

–> Download msDetector.framework (To ~/Library/Frameworks/)

–> Download msDetector (Code Signed executable AppleScript applet with Framework and libraries in its bundle)

Core MLで判定時に詳細なデータを出力させ、その可能性が0.8を上回るものだけを処理するようにしてみました。ただ、全力で間違った判定を行うケースもあるため、単なる「気休め」です。

テストデータでは、連邦軍側が72機体中間違いが９個（正解87.5%）、ジオン軍側が57機体中間違いが３個（正解95%）。鹵獲機体のデータを排除すると、もう少しいい値が出るかもしれません。ただ、学習させたデータとほぼ同じデータ（数が少ない）で再度判定を行っているだけなので、このぐらいの確度が出ないと逆に困ります。

また、確度が高くないものは排除するように処理したので、確度が低い機体の画像バリエーションを増やして学習画像数を足すと正解の確率が上がるのではないか、などと「なんとなく」考えています。

Create MLでは、もっときちんとした表データやタグ付き自然言語テキストデータ（日本語だと形態素への区分けはあらかじめやっておく必要アリ？）の学習が行えるようなので（自然言語テキストの学習例は英語のものしか見かけないけれども）いろいろやっておきたいところです。

今回は「アニメとかゲームに出てくるMSの画像」の判定という、実用性をまったく考えないで行なってみたものですが、自分の身の回りで有用性の高そうな処理といえば……アイコンやプレゼン用資料の作成画像を学習させておおまかなジャンル分けをしておき（メール系のアイコンとか）、未知のアイコン素材をダウンロードしてきたら機械学習データをもとに自動でフォルダ分けするとかでしょうか。

さすがにアイコン画像だとデフォルメされすぎていて、MicrosoftのAzure Computer Vision APIとかでも画像認識してくれなさそうなので。

AppleScript名：機械学習で学習したMSの画像の連邦軍、ジオン軍判定してフォルダ分け v2.scpt

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/11/20
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.7" — Mojave (10.14) or later & Script Debugger
use framework "Foundation"
use framework "AppKit"
use framework "msDetector"
use scripting additions

property |NSURL| : a reference to current application’s |NSURL|
property NSArray : a reference to current application’s NSArray
property NSString : a reference to current application’s NSString
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor
property NSURLTypeIdentifierKey : a reference to current application’s NSURLTypeIdentifierKey

set aFol to POSIX path of (choose folder with prompt "Choose MS Image folder to go!")
set efsfFol to POSIX path of (choose folder with prompt "EFSF folder")
set zeonFol to POSIX path of (choose folder with prompt "Zeon folder")

–指定フォルダ以下のファイルをすべて取得（再帰ですべて取得）
set aSel to retFullpathsWithinAFolderWithRecursive(aFol) of me

–取得したファイルリストを指定UTIでフィルタリング
set filRes2 to filterPOSIXpathListByUTI(aSel, "public.image") of me

–機械学習モデルを用いて区分けを行い、任意の画像の連邦軍（efsf）、ジオン軍（zeon）へのフォルダ分け（コピー）
set msClassifier to current application’s msClassify’s alloc()’s init()

repeat with i in filRes2
　　set aFile to contents of i
　　set aImage to (current application’s NSImage’s alloc()’s initWithContentsOfFile:aFile)
　　
　　set resDict to (msClassifier’s ImageClassifierWithImageAndRetDict:aImage) –returns NSDictionary
　　
　　–Dictinaryのvalueをソートして、最も値の大きいvalueのkeyを求める
　　set sortedArray to (current application’s NSMutableArray’s arrayWithArray:(resDict’s allValues()))
　　(sortedArray’s sortUsingSelector:"compare:")
　　set aRes to (last item of (sortedArray as list)) –末尾のアイテムが一番値の大きい数値
　　set resKey to first item of ((resDict’s allKeysForObject:aRes) as list) –最大値をもとにKeyを求める
　　
　　–可能性の高いものだけ処理してみる（自信たっぷりに全力で間違えることもけっこうある）
　　if (aRes as real) > 0.8 then
　　　　if resKey begins with "efsf" then
　　　　　　–efsf & efsf_stolen
　　　　　　set aRes to (my copyFileAt:aFile toFolder:efsfFol)
　　　　else
　　　　　　–zeon & zeon_stolen
　　　　　　set aRes to (my copyFileAt:aFile toFolder:zeonFol)
　　　　end if
　　end if
end repeat

–POSIX path listから指定UTIに含まれるものをPOSIX pathのリストで返す
on filterPOSIXpathListByUTI(aList, targUTI)
　　set newList to {}
　　repeat with i in aList
　　　　set j to contents of i
　　　　set tmpUTI to my retUTIfromPath(j)
　　　　set utiRes to my filterUTIList({tmpUTI}, targUTI)
　　　　if utiRes is not equal to {} then
　　　　　　set the end of newList to j
　　　　end if
　　end repeat
　　return newList
end filterPOSIXpathListByUTI

–指定のPOSIX pathのファイルのUTIを求める
on retUTIfromPath(aPOSIXPath)
　　set aURL to |NSURL|’s fileURLWithPath:aPOSIXPath
　　set {theResult, theValue} to aURL’s getResourceValue:(reference) forKey:NSURLTypeIdentifierKey |error|:(missing value)
　　
　　if theResult = true then
　　　　return theValue as string
　　else
　　　　return theResult
　　end if
end retUTIfromPath

–UTIリストが指定UTIに含まれているかどうか演算を行う
on filterUTIList(aUTIList, aUTIstr)
　　set anArray to NSArray’s arrayWithArray:aUTIList
　　set aPred to NSPredicate’s predicateWithFormat_("SELF UTI-CONFORMS-TO %@", aUTIstr)
　　set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
　　return bRes
end filterUTIList

–指定フォルダ以下のすべてのファイルを再帰で取得
on retFullpathsWithinAFolderWithRecursive(aFol)
　　set anArray to NSMutableArray’s array()
　　set aPath to NSString’s stringWithString:aFol
　　set dirEnum to NSFileManager’s defaultManager()’s enumeratorAtPath:aPath
　　
　　repeat
　　　　set aName to (dirEnum’s nextObject())
　　　　if aName = missing value then exit repeat
　　　　set aFullPath to aPath’s stringByAppendingPathComponent:aName
　　　　anArray’s addObject:(aFullPath as string)
　　end repeat
　　
　　return anArray as list
end retFullpathsWithinAFolderWithRecursive

on copyFileAt:POSIXPath toFolder:folderPath
　　set POSIXPath to NSString’s stringWithString:POSIXPath
　　set folderPOSIXPath to NSString’s stringWithString:folderPath
　　set theName to POSIXPath’s lastPathComponent()
　　set newPath to folderPOSIXPath’s stringByAppendingPathComponent:theName
　　set fileManager to NSFileManager’s defaultManager()
　　set theResult to fileManager’s copyItemAtPath:POSIXPath toPath:newPath |error|:(missing value)
　　return (theResult as integer = 1)
end copyFileAt:toFolder:

★Click Here to Open This Script　

NLLanguageRecognizerで自然言語の推定 v4

Posted on 11月 13, 2018 by Takaaki Naganoya

macOS 10.14であらたに搭載されたNaturalLanguage.frameworkにアクセスして、自然言語テキストが「何語」かを推定し、指定数の言語ごとにその推測した確率を求めるAppleScriptです。

NLLanguageRecognizerで、言語推定時に「言語Aと言語Bのみ考慮してね」と指定し、それぞれに数値による重み付け（0.0〜1.0）を指定できます。

ただ、重み付けを指定してもダメな時はダメなようで……日本語の文章に多めにアルファベットが入っている場合にはまったく日本語と判定されません。

AppleScript名：NLLanguageRecognizerで自然言語の推定 v4

— Created 2018-11-13 by Takaaki Naganoya
use AppleScript version "2.7" — Mojave (10.14) or later
use framework "Foundation"
use framework "NaturalLanguage"
use scripting additions

property NLLanguageEnglish : a reference to current application’s NLLanguageEnglish
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NLLanguageJapanese : a reference to current application’s NLLanguageJapanese
property NLLanguageRecognizer : a reference to current application’s NLLanguageRecognizer

set aNL to NLLanguageRecognizer’s alloc()’s init()

–言語ごとに可能性の重み付けを行って、言語推定

–言語推定の可能性ヒントデータを指定。日本語が99.9％、英語は0.1％の可能性として指定
set hintDict to NSMutableDictionary’s dictionaryWithObjects:{1.0E-3, 0.999} forKeys:{NLLanguageEnglish, NLLanguageJapanese}
–> (*(NSDictionary) {en:0.01, ja:0.99}*) –recordで作ってScriptingBridge経由でNSDictionaryに自動変換させてもよかったが、recordでは属性ラベルにハイフンなどは使えないのでこれでいいのだ
set hintRes3 to (aNL’s setLanguageHints:hintDict)

aNL’s processString:"AppleScriptで日本語を処理するよ。"
set langRes4 to (aNL’s languageHypothesesWithMaximum:2) as record
–> {en:1.0}– アルファベットの文字量が多いので、英語と判断されたよ！　（＞_＜）

aNL’s processString:"AppleScriptで日本語を処理するぴよ。"
set langRes5 to (aNL’s languageHypothesesWithMaximum:2) as record
–> {ja:1.0}– 「よ」を「ぴよ」に書き換えたら日本語の文字の量が増えて日本語と判定されたよ！　（＾ー＾）

★Click Here to Open This Script　

NLLanguageRecognizerで自然言語の推定 v3

Posted on 11月 13, 2018 by Takaaki Naganoya

NLLanguageRecognizerも、「最もそれらしいラベル（言語）値」を返すだけでなく、推測候補言語とその確率（0.0〜1.0、1.0が最もそれらしい）をDictionary形式で（AppleScriptでいうところのrecord）出力するメソッドがあります。試しに呼んでみました。

AppleScript名：NLLanguageRecognizerで自然言語の推定 v3

— Created 2018-11-13 by Takaaki Naganoya
use AppleScript version "2.7" — Mojave (10.14) or later
use framework "Foundation"
use framework "NaturalLanguage"
use scripting additions

property NLLanguageRecognizer : a reference to current application’s NLLanguageRecognizer

set aNL to NLLanguageRecognizer’s alloc()’s init()

–言語推定時の各言語の可能性の数値をリストアップ
aNL’s processString:"AppleScriptで日本語を処理。"
set langRes1 to (aNL’s languageHypothesesWithMaximum:10) as record
–> {|is|:0.017804400995, ro:0.02502822876, fr:0.015569564886, de:0.041996311396, |it|:0.017095085233, nl:0.630239665508, sv:0.041430238634, en:0.11029753834, nb:0.025065546855, hu:0.051682028919}
–アルファベットの比率が高まると、日本語として認識される可能性が極端に下がる

aNL’s processString:"「「「「了解です！」」」」" –なろう系小説の複数人物の同時発話表現
set langRes2 to (aNL’s languageHypothesesWithMaximum:5) as record
–> {|zh-hans|:0.251541793346, ja:0.748288214207, |zh-hant|:1.62590833497234E-4}

★Click Here to Open This Script　

Bayes推定による文章仕分け（Classifier）

Posted on 11月 12, 2018 by Takaaki Naganoya

ベイズ推定を計算するオープンソースのプログラム「Bayes」をCocoaフレームワーク化した「BayesKit」を呼び出してベイズ推定の計算を行うAppleScriptです。

–> Download BayesKit.framework (To ~/Library/Frameworks)

macOS 10.14以外はスクリプトエディタ/Script Debugger上で実行可能で、10.14のみScript Debugger上での実行を必要とします（この仕様、いい加減かったるいので戻してほしい）。

スパムメール選別用途御用達のベイズ推定の演算を行なってみました。プログラムに添付されていたサンプルは英語の文章を処理するようにできていましたが、予想どおり日本語の文章をそのまま与えると単語切り分けが行えずに計算がうまく行きません。

そこで、掲載サンプルScriptのように単語ごとに手動で半角スペースを入れてみました。

本来であれば、形態素解析辞書を使って単語ごとに切り分け、さらに単語の活用形をどうにかする必要があるはずですが、そこまで神経質にならずに簡易日本語パーサーで単語に分解し、助詞などを削除しデータとして与えることでそこそこの実用性は確保できるのではないかと思われます（これだと固有名詞がバラバラになる可能性は否定できませんが）。

NSLinguisticTagger＋macOS 10.14で日本語文章の形態素解析＋品詞解析は行えることを期待したいですが、未確認です。ただ、できた場合でも固有名詞への配慮がどの程度あるかは不明です。

AppleScript名：Bayes推定による文章仕分け（Classifier）.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/11/12
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—
use AppleScript version "2.5" — El Capitan(10.11) or later
use framework "Foundation"
use framework "BayesKit" –https://github.com/kevincobain2000/Bayes
use scripting additions

property Bayes : a reference to current application’s Bayes
property FeaturesVector : a reference to current application’s FeaturesVector
property NSMutableArray : a reference to current application’s NSMutableArray

–set positiveStr to "word word good good"
–set negativeStr to "thiss word bad bad"
set positiveStr to "良い　良い良い良い　。"
set negativeStr to "悪悪悪悪悪　。"

set classifierObj to Bayes’s alloc()’s init()
set featuresVec to FeaturesVector’s alloc()’s init()

set featuresArray to NSMutableArray’s arrayWithArray:{"tokens"}

featuresVec’s appendFeatures:positiveStr forFeatures:featuresArray
classifierObj’s train:(featuresVec’s features) forlabel:"positive"

featuresVec’s appendFeatures:negativeStr forFeatures:featuresArray
classifierObj’s train:(featuresVec’s features) forlabel:"negative"

–set toGuess to "word"
set toGuess to "良い　。"

featuresVec’s appendFeatures:toGuess forFeatures:featuresArray
classifierObj’s guessNaiveBayes:(featuresVec’s features)

set vRes to (classifierObj’s probabilities) as record
–> {positive:0.6400000453, negative:0.32000002265}–English Sample Words　OK
–> {positive:1.0, negative:0.0}–Japanese Sample Words OK

★Click Here to Open This Script　

squeezeNetで画像のオブジェクト認識を行い、結果をCSV出力してNumbersでオープン

Posted on 11月 12, 2018 by Takaaki Naganoya

Core MLモデル「squeezeNet.mlmodel」を用いて画像のオブジェクト認識を行い、結果をデスクトップにCSV形式でデータ書き出しを行い、NumbersでオープンするAppleScriptです。

–> Download squeezeNetKit.framework (To ~/Library/Frameworks)

macOS 10.13上ではスクリプトエディタ、Script Debugger上で、macOS 10.14上ではScript Debugger上で動作します（AppleScript Appletでも動作）。

さまざまなCore MLモデルを用いて画像認識を行わせてはみたものの、最もスコアの高いもののラベルだけを返させても、結果がまったく内容にそぐわないケースが多く見られます。

▲機械学習の評価値が1.0に近いものは確度が高く、0.0に近いものは判断に迷った末に消極的に出した値。経験則でいえば、最高スコアの項目が0.7以上のスコアでないといまひとつのようです（0.7以上でもダメな時はダメなわけで、、、）

画像認識については、結果があまりに的外れで「なんじゃこら？」というケースが多いので、確認のためにCSVデータ出力させてNumbers上で確認させてみることにしてみました。そのためにありあわせのサブルーチンを組み合わせて作ったものです。

スコアが高い順に結果を並べて確認してみると、最も高いスコアの値であっても0.0に近い評価値であることがあり、「何も考えずに最高スコアのラベルだけ取ってくるのはものすごく危険」なことがよくわかります。

▲squeezeNet.mlmodelをNetronでビジュアライズしたところ（一部抜粋）

AppleScript名：SqueezeNetでオブジェクト判定して結果をCSV書き出ししてNumbersでオープン.scpt

–　　Created by: Takaaki Naganoya
–　　Created on: 2018/11/11
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use framework "AppKit"
use framework "squeezeNetKit"
use scripting additions

property NSUUID : a reference to current application’s NSUUID
property NSArray : a reference to current application’s NSArray
property NSImage : a reference to current application’s NSImage
property NSMutableArray : a reference to current application’s NSMutableArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor

set aFile to POSIX path of (choose file of type {"public.image"})
set aImage to NSImage’s alloc()’s initWithContentsOfFile:aFile
set resDict to (current application’s imageClassifier’s alloc()’s init()’s ImageClassifierWithImageAndRetDict:aImage)

set kArray to (resDict’s allKeys())
set vArray to (resDict’s allValues())
set aLen to kArray’s |count|()

set anArray to NSMutableArray’s new()

repeat with i from 0 to (aLen – 1)
　　set tmpKey to (kArray’s objectAtIndex:i) as string
　　set tmpVal to (vArray’s objectAtIndex:i) as real
　　(anArray’s addObject:{aKey:tmpKey, aVal:tmpVal})
end repeat

–Sort by value
set bList to sortRecListByLabel(anArray, "aVal", false) of me

–record in list –> 2D list
set cList to convRecInListTo2DList(bList) of me

–デスクトップにCSVファイルを書き出してNumbersでオープン
set aPath to (((path to desktop) as string) & (NSUUID’s UUID()’s UUIDString()) as string) & ".csv"
set fRes to saveAsCSV(cList, aPath) of me
tell application "Numbers"
　　open (aPath as alias)
end tell

–リストに入れたレコードを、指定の属性ラベルの値でソート
on sortRecListByLabel(aRecList as list, aLabelStr as string, ascendF as boolean)
　　set aArray to NSArray’s arrayWithArray:aRecList
　　set sortDesc to NSSortDescriptor’s alloc()’s initWithKey:aLabelStr ascending:ascendF
　　set sortDescArray to NSArray’s arrayWithObjects:sortDesc
　　set sortedArray to aArray’s sortedArrayUsingDescriptors:sortDescArray
　　set bList to (sortedArray) as anything
　　return bList
end sortRecListByLabel

on convRecInListTo2DList(aList)
　　set anArray to NSMutableArray’s arrayWithArray:aList
　　set fItem to anArray’s objectAtIndex:0
　　set keyList to fItem’s allKeys() as list
　　set aCount to anArray’s |count|()
　　
　　set allArray to NSMutableArray’s new()
　　
　　repeat with i from 1 to aCount
　　　　set anItem to (anArray’s objectAtIndex:(i – 1))
　　　　set tmpItem to {}
　　　　
　　　　repeat with ii in keyList
　　　　　　set tmpDat to (anItem’s valueForKeyPath:(contents of ii))
　　　　　　if tmpDat is not equal to missing value then
　　　　　　　　set the end of tmpItem to tmpDat
　　　　　　else
　　　　　　　　set the end of tmpItem to ""
　　　　　　end if
　　　　end repeat
　　　　(allArray’s addObject:tmpItem)
　　end repeat
　　
　　set allList to allArray as list
　　set the beginning of allList to keyList
　　return allList
end convRecInListTo2DList

–CSV Kit

–2D List to CSV file
on saveAsCSV(aList, aPath)
　　–set crlfChar to (ASCII character 13) & (ASCII character 10)
　　set crlfChar to (string id 13) & (string id 10)
　　set LF to (string id 10)
　　set wholeText to ""
　　
　　repeat with i in aList
　　　　set newLine to {}
　　　　
　　　　–Sanitize (Double Quote)
　　　　repeat with ii in i
　　　　　　set jj to ii as text
　　　　　　set kk to repChar(jj, string id 34, (string id 34) & (string id 34)) of me –Escape Double Quote
　　　　　　set the end of newLine to kk
　　　　end repeat
　　　　
　　　　–Change Delimiter
　　　　set aLineText to ""
　　　　set curDelim to AppleScript’s text item delimiters
　　　　set AppleScript’s text item delimiters to "＼",＼""
　　　　set aLineList to newLine as text
　　　　set AppleScript’s text item delimiters to curDelim
　　　　
　　　　set aLineText to repChar(aLineList, return, "") of me –delete return
　　　　set aLineText to repChar(aLineText, LF, "") of me –delete lf
　　　　
　　　　set wholeText to wholeText & "＼"" & aLineText & "＼"" & crlfChar –line terminator: CR＋LF
　　end repeat
　　
　　if (aPath as string) does not end with ".csv" then
　　　　set bPath to aPath & ".csv" as Unicode text
　　else
　　　　set bPath to aPath as Unicode text
　　end if
　　
　　write_to_file(wholeText, bPath, false) of me
　　
end saveAsCSV

on write_to_file(this_data, target_file, append_data)
　　tell current application
　　　　try
　　　　　　set the target_file to the target_file as text
　　　　　　set the open_target_file to open for access file target_file with write permission
　　　　　　if append_data is false then set eof of the open_target_file to 0
　　　　　　write this_data to the open_target_file starting at eof
　　　　　　close access the open_target_file
　　　　　　return true
　　　　on error error_message
　　　　　　try
　　　　　　　　close access file target_file
　　　　　　end try
　　　　　　return error_message
　　　　end try
　　end tell
end write_to_file

on repChar(origText as text, targChar as text, repChar as text)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

★Click Here to Open This Script　

ハッシュ値から、メモリースティックに保存されたReplay Dataのステージ名とプレイ日時を求める v3

Posted on 10月 30, 2018 by Takaaki Naganoya

PSPのゲーム「戦場の絆ポータブル」のセーブデータについているステージ別のプレビュー画像のハッシュ値から対戦ステージと対戦日時を抽出してタブ区切りテキストで出力するAppleScriptです。

保存された対戦データの内容を集計するために作成したものです。

PSPでメモリースティックに保存された対戦データには、すべて同じファイル名（ICON0.PNG）で異なる画像が添付されていました。ファイル名で対戦ステージを判定しようにも同じファイル名なので区別できません。

そこで、Spotlightの機能を用いて各セーブデータの「ICON0.PNG」をピックアップし、画像の内容のハッシュ値（SHA-1）を計算して、対戦ステージ内容を判定しました。

直近の対戦データをメモリースティック経由でMacに読み込み、本Scriptで分析してみたところ、

ジャブロー地上	2017年9月18日月曜日 14:42:48
ジャブロー地上	2017年9月18日月曜日 14:50:02
ジャブロー地上	2017年9月18日月曜日 14:55:22
タクラマカン砂漠	2017年9月18日月曜日 15:02:32
サイド7	2017年9月18日月曜日 15:09:36
ジャブロー地下	2017年9月18日月曜日 15:17:06
ジャブロー地上	2017年9月18日月曜日 15:31:08
サイド7	2017年9月18日月曜日 15:38:28
ジャブロー地上	2017年9月18日月曜日 15:51:52
ジャブロー地上	2018年1月2日火曜日 16:13:30
サイド7	2018年1月2日火曜日 16:23:04
ジャブロー地下	2018年1月2日火曜日 16:57:22

のようになりました。正月と秋分の日に親戚で集まったときに甥っ子と対戦した様子がありありと記録されています。

本Scriptはたまたまゲームのセーブデータの集計を行っていますが、同様の形式のデータを集計したい場合には使えそうです。

–> md5Lib.framework（To ~/Library/Frameworks）

AppleScript名：チェックサム値から、メモリースティックに保存されたReplay Dataのステージ名とプレイ日時を求める v3.1

— Created 2015-04-17 by Takaaki Naganoya
— Modified 2018-10-29 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "md5Lib" –https://github.com/JoeKun/FileMD5Hash
use bPlus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html
use mdLib : script "Metadata Lib" version "2.0.0" –https://www.macosxautomation.com/applescript/apps/

property FileHash : a reference to current application’s FileHash
property SMSForder : a reference to current application’s SMSForder
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray

–各SAVEDATAフォルダ中の「ICON0.PNG」のSHA-1ハッシュ値とステージ名の対応表
set shaArray to NSMutableArray’s arrayWithArray:{{stageName:"ニューヤーク", sha1:"dbb9e8e26e96dbb4dd3198e55b6cde41aba8e0a8"}, {stageName:"鉱山都市", sha1:"72f35456504b1957ec85fb6a1597ac1a2baa2ee9"}, {stageName:"グレートキャニオン", sha1:"9de93e8b853fe153bc73066fb07481c774499960"}, {stageName:"サイド7", sha1:"be22fa949bfd78b0cd97596929f07ce4ec501d7b"}, {stageName:"タクラマカン砂漠", sha1:"5284dc5f0f7a53ee5677908f66da1e00b80f76b6"}, {stageName:"トリントン・タワー", sha1:"9f080853dac45ecaf1672ff2230f2b9a80a00eb4"}, {stageName:"ジャブロー地下", sha1:"a93550099419f52444cf77366773192d0bf5f848"}, {stageName:"ヒマラヤ", sha1:"877f998d608dd267c380e59a17b2a95a139baef5"}, {stageName:"ジャブロー地上", sha1:"8c4ee44e8f2fbcbf061e6d5ea2b202b08f42c59a"}}

load framework

set apPath1 to choose folder with prompt "リプレイデータが入っているフォルダを選択してください"
set aRes to perform search in folders {apPath1} predicate string "kMDItemFSName == %@" search arguments {"ICON0.PNG"}

set outList to {}
set errorList to {}

repeat with i in aRes
　　set j to contents of i
　　set sumRes to (FileHash’s sha1HashOfFileAtPath:(j)) as string
　　
　　–チェックサムからステージ名を検索する
　　set aPredStr to "sha1 == ’" & sumRes & "’"
　　set aPredicate to (NSPredicate’s predicateWithFormat:aPredStr)
　　set filteredArray to (shaArray’s filteredArrayUsingPredicate:aPredicate)
　　
　　if filteredArray as list = {} then
　　　　set the end of errorList to j
　　else
　　　　set tmpStage to (filteredArray’s valueForKey:"stageName") as string
　　　　
　　　　set fAttrib to (NSFileManager’s defaultManager()’s attributesOfItemAtPath:j |error|:(missing value))
　　　　set cDat to (fAttrib’s fileCreationDate()) as date
　　　　
　　　　set tmpList to {tmpStage, cDat}
　　　　
　　　　if tmpList is not in outList then
　　　　　　set the end of outList to tmpList
　　　　end if
　　end if
end repeat

–2D Listのソート
set sortIndexes to {1} –Key Item id: begin from 0
set sortOrders to {true} –ascending = true
set sortTypes to {"compare:"}
set out2List to (SMSForder’s subarraysIn:(outList) sortedByIndexes:sortIndexes ascending:sortOrders sortTypes:sortTypes |error|:(missing value)) as list

–2D Listをタブ区切りテキストに変換して返す
set aText to retItemDelimedAndParagraphDelimedText(out2List, tab, return) of me

–入れ子のリストを、アイテム間のデリミタとパラグラフ間のデリミタを指定してテキスト化
–というか、入れ子のリストをタブ区切りテキストにするのが目的
on retItemDelimedAndParagraphDelimedText(aList, itemDelim, paragraphDelim)
　　set aText to ""
　　
　　repeat with i in aList
　　　　set aStr to retDelimedText(i, itemDelim) of me
　　　　set aText to aText & aStr & paragraphDelim
　　end repeat
　　
　　return aText
end retItemDelimedAndParagraphDelimedText

on retDelimedText(aList, aDelim)
　　set aText to ""
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to aDelim
　　set aText to aList as text
　　set AppleScript’s text item delimiters to curDelim
　　return aText
end retDelimedText

★Click Here to Open This Script　

【基礎】recordの属性値は各属性ラベルを指定して取り出す

Posted on 10月 30, 2018 by Takaaki Naganoya

＃　Blog消失前の投稿を再構成して「たぶんこんな内容」と推測して投稿したものです

AppleがOSに添付しているサンプルAppleScriptは内容がひどいという評判で、内容を見ると実際に仕事でAppleScriptを書いている連中も読むのが嫌になるという、ひどい見本でした。

　「AppleがOSに添付しているサンプルのように書かないことが上達への近道だ」
　「あのひどい内容のScriptを添付しているのは害悪以外の何物でもない」

といえるほど。さすがに批判も多かったのか、最悪の時期のサンプル（Mac OS X 10.5）のものは削除されましたが、この最悪の時期のサンプルを見てそのままコピペで書いた内容がひどかったので、そのもっともひどい部分を掲載。「絶対にこう書いてはいけない」という見本として示します。

出典「AppleScript最新リファレンス」

結果が代入される暗黙の変数、result

–Replace Text In Item Names
–Copyright © 2001–2007 Apple Inc.

display dialog "Search and replace in:" buttons {"File Names", "Folder Names", "Both"} default button 3
set the search_parameter to the button returned of the result

★Click Here to Open This Script　

AppleScriptは行単位で順次実行されますが、その行単位の実行結果はつねに「result」というシステム変数に入ります。

よほどトリッキーなプログラムでもないかぎり、resultが活躍する場面というのはほとんどありません。まして、前の行の計算結果をresultを介してやりとりすると、何をどう処理しているのかさっぱりわからなくなるので、「使わないほうがよいもの」として世間一般のScripterから避けられています。

それを、Mac OS X 10.5などという割とアップデートが一段落してMac OS Xの世界観が定着してきた頃になって引っ張りだしてきたので、Scripter連中は驚いたわけです。

参照渡しでもないのにサブルーチンの末尾で何もreturnで返り値を指定していないのにサブルーチンの処理結果がメイン側に戻るような場合には、この暗黙のresultの内容が戻っています。

最悪最低！　recordの内容をlistに変換して取り出した

display dialog "TEST" default answer "AAA"

などと書いて実行すると、

{button returned:"OK", text returned:"AAA"}

のような結果が返ってきます。これらは、属性ラベルを指定して取り出すのですが、このAppleのサンプルでは、こともあろうにこの結果をlistに変換して処理していました。

–Replace Text In Item Names
–Copyright © 2001–2007 Apple Inc.

tell me to display dialog the error_message default answer new_item_name buttons {"Cancel", "Skip", "OK"} default button 3
copy the result as list to {new_item_name, button_pressed}

★Click Here to Open This Script　

これを見た初心者が、「AppleScriptのdisplay dialogの結果が毎回変わって取得できない」などと騒ぐ始末。recordなので、属性ラベルの登場順は保証されていない（むしろ、そんなもん毎回変わって当然）ものですが、それをrecordから属性ラベルを指定して取り出すのではなく、list（配列）に変換して順番に応じて結果を取り出そうとしたので「毎回変わる」などという話になったのでした。

これは、100％ Appleのサンプルスクリプトが悪いですし、こんなものを標準添付している連中の気が知れません。サンプルスクリプトとしては史上最低最悪のレベルと呼んで差し支えありません。

それぞれ、recordから値を取り出す場合には属性ラベルを指定して取り出すというのがセオリーです。

set aRes to (display dialog "TEST" default answer "AAA")
–> {button returned:"OK", text returned:"BBBBB"}

set buttonRes to button returned of aRes
–> "OK"

set textRes to text returned of aRes
–> "BBBBB"

★Click Here to Open This Script　

recordのlistでKeynoteに表を作成する v1.5

Posted on 10月 29, 2018 by Takaaki Naganoya

リスト（配列）に入ったレコード（dictionary）のデータをもとに、現在オープン中のKeynoteの書類にスライドを追加し、その上に表を作成するAppleScriptです。

Keynoteで書類をオープンしていない場合には、書類を新規作成します。

表のデータを順次埋めているのは、Keynoteの表作成機能がそのように実装されているからです。普通は、データ内容を指定して表の作成と内容を一気に指定するように実装するのが普通ですが、Keynoteのこの仕様はあまりいただけません。

そのため、各セルを順次データで埋めているわけですが（アプリケーションとの通信頻度が高くなるので本来は避けたい処理）、「ignoring application responses」〜「end ignoring」による非同期実行モードによりデータでセルを埋める箇所のみ倍速実行しています。

「ignoring application responses」を使うと、AppleScriptがアプリケーションに命令を出して、正常に実行されたかどうかの「実行結果」を待たないため、おおよそ２倍の速度で実行できます。ただし、命令が正常に実行できたかどうかを取得できないので、安全性が確認されているようなケースで返り値が不要な場合にのみ利用できます。

macOS 10.14, Mojaveで実行したところ、macOS 10.12, Sierraの倍ぐらいの速度で実行しました。なんだろうこれは（10.12:Keynote v8.1, 10.14:Keynote v8.2）、、、、ハードウェアの構成などはほぼ同じで、まったく同じScriptを実行したのですが、、、、

AppleScript名：recordのlistでKeynoteに表を作成する v1.5

— Created 2016-06-29 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property aFontSize : 12

–This Date format is localized in Japanese. But this date string works only string. Don’t care about it.
set aList to {{pathStr:"book1_0.1.pdf", creationDate:"2016年6月17日金曜日", pageCount:222, countChars:127978, fileSize:"12027660"}, {pathStr:"book1_0.2.pdf", creationDate:"2016年6月17日金曜日", pageCount:230, countChars:129506, fileSize:"11109818"}, {pathStr:"book1_0.210.pdf", creationDate:"2016年6月18日土曜日", pageCount:254, countChars:147119, fileSize:"22832000"}, {pathStr:"book1_0.211.pdf", creationDate:"2016年6月18日土曜日", pageCount:254, countChars:147123, fileSize:"22831931"}, {pathStr:"book1_0.212.pdf", creationDate:"2016年6月18日土曜日", pageCount:241, countChars:134856, fileSize:"22273252"}, {pathStr:"book1_0.213.pdf", creationDate:"2016年6月18日土曜日", pageCount:241, countChars:134845, fileSize:"22271667"}, {pathStr:"book1_0.214.pdf", creationDate:"2016年6月18日土曜日", pageCount:241, countChars:134850, fileSize:"22270980"}, {pathStr:"book1_0.220.pdf", creationDate:"2016年6月18日土曜日", pageCount:242, countChars:134870, fileSize:"21098301"}, {pathStr:"book1_0.222.pdf", creationDate:"2016年6月18日土曜日", pageCount:243, countChars:135694, fileSize:"21146421"}, {pathStr:"book1_0.300.pdf", creationDate:"2016年6月20日月曜日", pageCount:251, countChars:142787, fileSize:"21427502"}, {pathStr:"book1_0.301.pdf", creationDate:"2016年6月20日月曜日", pageCount:251, countChars:142784, fileSize:"21421107"}, {pathStr:"book1_0.302.pdf", creationDate:"2016年6月20日月曜日", pageCount:256, countChars:142827, fileSize:"22593201"}, {pathStr:"book1_0.303.pdf", creationDate:"2016年6月20日月曜日", pageCount:257, countChars:142845, fileSize:"22616595"}, {pathStr:"book1_0.400.pdf", creationDate:"2016年6月22日水曜日", pageCount:281, countChars:162419, fileSize:"22430779"}, {pathStr:"book1_0.500.pdf", creationDate:"2016年6月23日木曜日", pageCount:309, countChars:178210, fileSize:"27611566"}, {pathStr:"book1_0.600.pdf", creationDate:"2016年6月24日金曜日", pageCount:326, countChars:194751, fileSize:"26820825"}, {pathStr:"book1_0.700.pdf", creationDate:"2016年6月24日金曜日", pageCount:310, countChars:195943, fileSize:"26408415"}, {pathStr:"book1_0.701.pdf", creationDate:"2016年6月24日金曜日", pageCount:310, countChars:195926, fileSize:"26406738"}, {pathStr:"book1_0.702.pdf", creationDate:"2016年6月24日金曜日", pageCount:310, countChars:195924, fileSize:"26406703"}, {pathStr:"book1_0.703.pdf", creationDate:"2016年6月24日金曜日", pageCount:311, countChars:196594, fileSize:"26416223"}, {pathStr:"book1_1.0.pdf", creationDate:"2016年6月25日土曜日", pageCount:311, countChars:196594, fileSize:"26075419"}}

set anItem to contents of first item of aList
set aDict to (current application’s NSMutableArray’s arrayWithObject:anItem)’s firstObject()
set aKeyList to aDict’s allKeys() as list
set aKeyCount to length of aKeyList
set aRowCount to length of aList

tell application "Keynote"
　　set dCount to count every document
　　if dCount = 0 then
　　　　set newDoc to make new document with properties {document theme:theme "ホワイト", width:1024, height:768} –This theme name is *localized* by stupid software maker in Cupertino. This means "White" in Japanese
　　end if
　　
　　
　　tell document 1
　　　　set aNewSlide to make new slide
　　　　set base slide of aNewSlide to master slide "空白" –This theme name is *localized* by stupid software maker in Cupertino. This means "Blank" in Japanese
　　　　
　　　　tell aNewSlide
　　　　　　set aTable to make new table with properties {column count:aKeyCount + 1, row count:aRowCount + 1}
　　　　　　
　　　　　　tell aTable
　　　　　　　　–ヘッダー行を作成（ラベルで埋める）
　　　　　　　　tell row 1
　　　　　　　　　　repeat with i from 2 to aKeyCount + 1
　　　　　　　　　　　　set aKey to item (i – 1) of aKeyList
　　　　　　　　　　　　
　　　　　　　　　　　　–非同期実行ここから
　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　set value of cell i to aKey
　　　　　　　　　　　　　　set font size to aFontSize
　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　–非同期実行ここまで
　　　　　　　　　　　　
　　　　　　　　　　end repeat
　　　　　　　　end tell
　　　　　　　　
　　　　　　　　–各行のデータを埋める
　　　　　　　　repeat with ii from 2 to aRowCount + 1
　　　　　　　　　　set aRecRow to item (ii – 1) of aList
　　　　　　　　　　tell row ii
　　　　　　　　　　　　
　　　　　　　　　　　　repeat with iii from 2 to (aKeyCount + 1)
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　tell cell iii
　　　　　　　　　　　　　　　　set aKey to item (iii – 1) of aKeyList
　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　　　–非同期実行ここから
　　　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　　　set value to retValueForKey(aRecRow, aKey) of me
　　　　　　　　　　　　　　　　　　set font size to aFontSize
　　　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　　　　　–非同期実行ここまで
　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　end repeat
　　　　　　　　　　end tell
　　　　　　　　end repeat
　　　　　　　　
　　　　　　end tell
　　　　end tell
　　　　
　　end tell
end tell

on retValueForKey(aRec, aLabel)
　　set tmpDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　return (tmpDic’s valueForKey:aLabel) as string
end retValueForKey

★Click Here to Open This Script　

文字列で指定したラベルの値をレコードから取得する v2

Posted on 10月 29, 2018 by Takaaki Naganoya

OLD Style AppleScriptで（強引に）レコード中の任意の値を間接指定で取得するAppleScriptです。

裏技を駆使し、エラーメッセージからデータを取り出して動的にScript生成して結果を取得するという、仕様的にはできるわけがないが、実際にできるという処理です。

＃　書籍「AppleScript最新リファレンス」からのリンクURLがBlog消失後に修復されていなかったので、再掲載しました。書籍側もリンクURLを修正したものを近日中にアップします

AppleScript名：文字列で指定したラベルの値をレコードから取得する v2

set aRec to {myAge:36, myHight:166, myWeight:70}
set aLabel to "myHight"

set a to getSpecifiedAttrOfRec(aRec, aLabel) of me
–> 166

–与えられたレコードから指定の属性値ラベルの値を取り出して返す
on getSpecifiedAttrOfRec(aRec, aLabel)
　　
　　–パラメータのエラーチェック。エラー時にはmissing valueを返す
　　set aClass to class of aRec
　　if aClass is not record then return missing value
　　if aLabel = "" then return missing value
　　if class of aLabel is not string then return missing value
　　
　　–レコードを無理矢理stringにcastして、エラーメッセージを取得する
　　try
　　　　set a to aRec as string
　　on error aMes
　　　　set a to aMes
　　end try
　　
　　–エラーメッセージ文字列から、元のレコードの情報を組み立てる
　　set b to trimStrFromTo(a, "{", "}")
　　set b to "{" & b & "}"
　　
　　–動的にAppleScriptを生成して、無理矢理レコードから目的の属性値を取り出す
　　set s to "return " & aLabel & " of " & b
　　try
　　　　set recData to run script s
　　on error
　　　　return missing value –指定の属性値が存在しなかった場合にはエラー
　　end try
　　
　　return recData
　　
end getSpecifiedAttrOfRec

on trimStrFromTo(aStr, fromStr, toStr)
　　–fromStrは前から探す
　　if fromStr is not equal to "" then
　　　　set sPos to (offset of fromStr in aStr) + 1
　　else
　　　　set sPos to 1
　　end if
　　
　　–toStrは後ろから探す
　　if toStr is not equal to "" then
　　　　set b to (reverse of characters of aStr) as string
　　　　set ePos to (offset of toStr in b)
　　　　set ePos to ((length of aStr) – ePos)
　　else
　　　　set ePos to length of aStr
　　end if
　　set aRes to text sPos thru ePos of aStr
　　return aRes
end trimStrFromTo

–文字置換ルーチン
on repChar(origText, targStr, repStr)
　　set {txdl, AppleScript’s text item delimiters} to {AppleScript’s text item delimiters, targStr}
　　set temp to text items of origText
　　set AppleScript’s text item delimiters to repStr
　　set res to temp as text
　　set AppleScript’s text item delimiters to txdl
　　return res
end repChar

★Click Here to Open This Script　

Cocoaの機能を利用して（macOS 10.10以降）書くと、こんな感じです。

AppleScript名：レコードからラベルを指定して値を取り出し

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aDict to current application’s NSDictionary’s dictionaryWithDictionary:{abc:"123", bcd:"456"}
set aVal to (aDict’s valueForKey:"abc") as string
–>　　"123"

★Click Here to Open This Script　

日本語入力のライブ変換のオン、オフ v2

Posted on 10月 28, 2018 by Takaaki Naganoya

日本語入力Input Methodの「ライブ変換」のOn/Offの状態を変更するAppleScriptのmacOS 10.13/10.14対応版です。

大した箇所ではなく、NSDictionaryの作成が通らなかったのできっちり書きました。こういう些細な表記がOSバージョンごとに変わってくるのがCocoa Scriptingの要注意点でしょうか。

AppleScript名：ライブ変換のオン、オフ v2

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/10/28
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

makeLiveHenkanEnabled(true) of me –Enable
makeLiveHenkanEnabled(false) of me –Disable

–日本語入力の「ライブ変換」をオン/オフする。Sandbox環境では動作しない
on makeLiveHenkanEnabled(aFlag as boolean)
　　set fNumFlag to aFlag as integer
　　
　　set aRec to current application’s NSDictionary’s dictionaryWithObjects:{fNumFlag} forKeys:{"JIMPrefLiveConversionKey"}
　　
　　current application’s NSDistributedNotificationCenter’s defaultCenter()’s postNotificationName:"com.apple.inputmethod.JIM.PreferencesDidChangeNotification" object:"com.apple.JIMSession" userInfo:aRec options:0
　　
　　current application’s NSDistributedNotificationCenter’s defaultCenter()’s postNotificationName:"com.apple.inputmethod.JIM.PreferencesDidChangeNotification" object:"com.apple.JIMPreferences" userInfo:aRec options:0
end makeLiveHenkanEnabled

★Click Here to Open This Script　

日本語入力のライブ変換のオン、オフ

Posted on 10月 28, 2018 by Takaaki Naganoya

日本語入力Input Methodの「ライブ変換」のOn/Offの状態を変更するAppleScriptです。

Sandbox環境下では動作しないとのこと。Xcode上で作成したMac App Store向けのGUIアプリケーション環境（Sandbox環境下）だと機能しない可能性が高いとのこと。

テストしてみたところ、macOS 10.13/10.14で動作しなかったため、あとで少々書き換えてみました（v2）。

個人的には、日本語入力のライブ変換は真っ先にオフにする心底いらない機能です。

AppleScript名：ライブ変換のオン、オフ.scptd

—
–　　Created by: Takaaki Naganoya
–　　Created on: 2018/10/28
—
–　　Copyright © 2018 Piyomaru Software, All Rights Reserved
—

use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

makeLiveHenkanEnabled(true) of me –Enable
makeLiveHenkanEnabled(false) of me –Disable

–日本語入力の「ライブ変換」をオン/オフする。Sandbox環境では動作しない
on makeLiveHenkanEnabled(aFlag as boolean)
　　set fNumFlag to aFlag as integer
　　
　　set aRec to current application’s NSDictionary’s dictionaryWithObjectsAndKeys_((fNumFlag), "JIMPrefLiveConversionKey")
　　current application’s NSDistributedNotificationCenter’s defaultCenter()’s postNotificationName:"com.apple.inputmethod.JIM.PreferencesDidChangeNotification" object:"com.apple.JIMSession" userInfo:aRec options:0
　　
　　set bRec to current application’s NSDictionary’s dictionaryWithObjectsAndKeys_((fNumFlag), "JIMPrefLiveConversionKey")
　　current application’s NSDistributedNotificationCenter’s defaultCenter()’s postNotificationName:"com.apple.inputmethod.JIM.PreferencesDidChangeNotification" object:"com.apple.JIMPreferences" userInfo:bRec options:0
end makeLiveHenkanEnabled

★Click Here to Open This Script　

easyJParse v3

Posted on 9月 27, 2018 by Takaaki Naganoya

簡易的な日本語テキストのParse（辞書なし）を行うAppleScriptです。

英語などの言語では、文章中の各単語の間にスペース（” “）を入れるようになっており、

My name is Takaaki Naganoya.

文章を単語ごとに分割することがきわめて容易です。

words of "My name is Takaaki Naganoya."
--> {"My", "name", "is", "Takaaki", "Naganoya"}

一方、日本語の文章において単語は続けて記述するため、

私の名前は長野谷です。

これを単語ごとに切り分けるのは大変です。そのため、単語の辞書を手掛かりに文章中の単語を切り分けるのが普通です。

辞書を使って単語単位の切り分けを行う日本語形態素解析器

日本語テキストを単語（形態素）ごとに区分けするソフトウェアは日本語形態素解析器と呼ばれます。Chasen、Juman、MeCabなどが有名です。形態素解析のための巨大な辞書を用いて、地名ぐらいの固有名詞なら問題なくParseできることが普通です。各単語がどの品詞なのか、活用形はどうなっているかといった文法的な情報も管理しています。

たとえば、ApitoreのREST API経由でKuromojiを呼び出して形態素解析を行うと、

"警告音「Basso」を最大音量で鳴らす"
-->{{startTime:"1538006762864", tokens:{{partOfSpeechLevel1:"名詞", baseForm:"警告", pronunciation:"ケイコク", position:0, partOfSpeechLevel3:"*", reading:"ケイコク", surface:"警告", known:true, allFeatures:"名詞,サ変接続,*,*,*,*,警告,ケイコク,ケイコク", conjugationType:"*", partOfSpeechLevel2:"サ変接続", conjugationForm:"*", allFeaturesArray:{"名詞", "サ変接続", "*", "*", "*", "*", "警告", "ケイコク", "ケイコク"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"音", pronunciation:"オン", position:2, partOfSpeechLevel3:"一般", reading:"オン", surface:"音", known:true, allFeatures:"名詞,接尾,一般,*,*,*,音,オン,オン", conjugationType:"*", partOfSpeechLevel2:"接尾", conjugationForm:"*", allFeaturesArray:{"名詞", "接尾", "一般", "*", "*", "*", "音", "オン", "オン"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"記号", baseForm:"「", pronunciation:"「", position:3, partOfSpeechLevel3:"*", reading:"「", surface:"「", known:true, allFeatures:"記号,括弧開,*,*,*,*,「,「,「", conjugationType:"*", partOfSpeechLevel2:"括弧開", conjugationForm:"*", allFeaturesArray:{"記号", "括弧開", "*", "*", "*", "*", "「", "「", "「"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"Basso", pronunciation:"バッソ", position:4, partOfSpeechLevel3:"一般", reading:"バッソ", surface:"Basso", known:true, allFeatures:"名詞,固有名詞,一般,*,*,*,Basso,バッソ,バッソ", conjugationType:"*", partOfSpeechLevel2:"固有名詞", conjugationForm:"*", allFeaturesArray:{"名詞", "固有名詞", "一般", "*", "*", "*", "Basso", "バッソ", "バッソ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"記号", baseForm:"」", pronunciation:"」", position:9, partOfSpeechLevel3:"*", reading:"」", surface:"」", known:true, allFeatures:"記号,括弧閉,*,*,*,*,」,」,」", conjugationType:"*", partOfSpeechLevel2:"括弧閉", conjugationForm:"*", allFeaturesArray:{"記号", "括弧閉", "*", "*", "*", "*", "」", "」", "」"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"助詞", baseForm:"を", pronunciation:"ヲ", position:10, partOfSpeechLevel3:"一般", reading:"ヲ", surface:"を", known:true, allFeatures:"助詞,格助詞,一般,*,*,*,を,ヲ,ヲ", conjugationType:"*", partOfSpeechLevel2:"格助詞", conjugationForm:"*", allFeaturesArray:{"助詞", "格助詞", "一般", "*", "*", "*", "を", "ヲ", "ヲ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"最大", pronunciation:"サイダイ", position:11, partOfSpeechLevel3:"*", reading:"サイダイ", surface:"最大", known:true, allFeatures:"名詞,一般,*,*,*,*,最大,サイダイ,サイダイ", conjugationType:"*", partOfSpeechLevel2:"一般", conjugationForm:"*", allFeaturesArray:{"名詞", "一般", "*", "*", "*", "*", "最大", "サイダイ", "サイダイ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"名詞", baseForm:"音量", pronunciation:"オンリョー", position:13, partOfSpeechLevel3:"*", reading:"オンリョウ", surface:"音量", known:true, allFeatures:"名詞,一般,*,*,*,*,音量,オンリョウ,オンリョー", conjugationType:"*", partOfSpeechLevel2:"一般", conjugationForm:"*", allFeaturesArray:{"名詞", "一般", "*", "*", "*", "*", "音量", "オンリョウ", "オンリョー"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"助詞", baseForm:"で", pronunciation:"デ", position:15, partOfSpeechLevel3:"一般", reading:"デ", surface:"で", known:true, allFeatures:"助詞,格助詞,一般,*,*,*,で,デ,デ", conjugationType:"*", partOfSpeechLevel2:"格助詞", conjugationForm:"*", allFeaturesArray:{"助詞", "格助詞", "一般", "*", "*", "*", "で", "デ", "デ"}, partOfSpeechLevel4:"*"}, {partOfSpeechLevel1:"動詞", baseForm:"鳴らす", pronunciation:"ナラス", position:16, partOfSpeechLevel3:"*", reading:"ナラス", surface:"鳴らす", known:true, allFeatures:"動詞,自立,*,*,五段・サ行,基本形,鳴らす,ナラス,ナラス", conjugationType:"五段・サ行", partOfSpeechLevel2:"自立", conjugationForm:"基本形", allFeaturesArray:{"動詞", "自立", "*", "*", "五段・サ行", "基本形", "鳴らす", "ナラス", "ナラス"}, partOfSpeechLevel4:"*"}}, endTime:"1538006762864", |log|:"", processTime:"0"}}

のようになります。これらのデータのうち、surface項目を抽出すると、

--> {"警告", "音", "「", "Basso", "」", "を", "最大", "音量", "で", "鳴らす", "。"}

となります。

辞書を使わずにトリッキーな方法で単語単位の切り分けを行う日本語パーサー

一方で、これらの日本語形態素解析器ほどの大規模なデータや機能が必要ない場合もあります。形態素解析のための辞書を持たず、単にそれっぽく単語ごとに区切ることができればよいという、「割り切った用途」に用いるもので、便宜上「日本語パーサー」と呼びます。単語っぽいものに分割することが目的であり、品詞のデータなどは取得できないのが普通です。

この種類のソフトウェアは、工藤拓さんのTinySegmenterがあり、これをObjective-Cに移植したSuper compact Japanese tokenizer 「Tiny Segmenter」をCocoa Framework化してAppleScriptから呼び出し、テストしています。正規表現を用いて助詞などをピックアップして、それを手掛かりに単語切り分けを行うもので、そのサイズからは想像できないぐらいまっとうに単語に切り分けてくれます。

このTiny Segmenter（Objective-C版）をコマンド解釈用に使ってみたのですが、

--> {"警告音", "「Basso", "」", "を", "最大", "音量", "で", "鳴ら", "す"}

記号などがきちんと分離されなかったため、いまひとつ。自分でコマンド解釈用のParserを作ってみることにしました。

words ofの不完全さを補う簡易日本語パーサーeasyJParse

AppleScriptの「words of」は、前述のように英文であればスペースを区切り子として、文章の単語への分解を行ってくれます。

一方、日本語テキストに対して「words of」で単語分解処理を行うと、ながらく「文字種別の切り替え箇所で区切る」という気の狂ったような使えない処理が行われていました。その無意味さと使えなさをAppleのエンジニアにことあるごとに説明してきたのですが、一向に理解されず、相手にされてきませんでした。

＃　冗談抜きで、Appleのエンジニアとは「戦いの歴史」しかありません。そして、そうして戦って勝ち取っていかないと機能の改善もバグの修正も何もないのであります（本当）

風向きが変わってきたのは、OS X 10.6のころ。このころから日本語テキストのwords ofの実行結果が形態素解析を行なっているような気がする動作を行うようになっており、何かに使えるような気がするものの……

 words of "警告音「Basso」を最大音量で鳴らす。"
 --> {"警告", "音", "Basso", "を", "最大", "音量", "で", "鳴らす"}

なぜか記号類などをすべて無視してしまうので、いまひとつ実用性がありませんでした。

そこで、基本的にはこの「words of」の演算結果を活かしつつ、オリジナルの文章と比較を行なって、欠損した記号類を補うことで簡易日本語parserとして利用できるのでは？　と考えました。

set aTargName to "警告音「Basso」を最大音量で鳴らす。"
set aList to parseJ(aTargName) of me
--> {"警告", "音", "「", "Basso", "」", "を", "最大", "音量", "で", "鳴らす", "。"}

実際に作ってテストしてみたところ、自分が必要なコマンド解析ぐらいの目的には十分に使えることがわかりました。むしろ、単語切り分けについてはKuromojiと同じ結果が得られています。

しかも、辞書を持たないためコンパクトであり、実行速度もたいへんに高速で、このeasyJParseを組み込んだプログラムはREST APIの日本語形態素解析器を呼んだバージョンよりも明らかに高速化され、ネットワーク接続のない環境でも実行可能になりました。いいことづくめです。

easyJParseの制約事項

なお、easyJParseはすでに文章単位で分割されたテキストをコマンド解釈用に分解するため「だけ」に作ったものであり、長文を文章ごとに分割する機能は持っていません。別のプログラムやルーチンで文章ごとに分割してからeasyJParseで処理してください。

easyJParseは、日本語ユーザー環境における日本語テキストに対する「words of」の演算結果を利用しており、言語環境が日本語に設定していない環境で同様に演算できることは保証していません。
→　一応、英語ユーザー環境で実行してみたら期待どおりの動作を行いました

当然のことながら、macOS専用です。一部Cocoaの機能を呼び出しているため、macOS 10.10以降で動きます（10.10では動作確認していませんけれども）。

AppleScript名：easyJParse v3

— Created 2018-09-26 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" — El Capitan (10.11) or later
use framework "Foundation"
use scripting additions

property NSArray : a reference to current application’s NSArray
property NSSortDescriptor : a reference to current application’s NSSortDescriptor

set aTargName to "警告音「Basso」を最大音量で鳴らす。"
set aList to parseJ(aTargName) of me
–> {"警告", "音", "「", "Basso", "」", "を", "最大", "音量", "で", "鳴らす", "。"}

–set aTargName to "JPEGファイルを50％にリサイズして、デスクトップの「AAA」フォルダに出力"
–set aList to parseJ(aTargName) of me
–> {"JPEG", "ファイル", "を", "50", "％", "に", "リサイズ", "し", "て", "、", "デスクトップ", "の", "「", "AAA", "」", "フォルダ", "に", "出力"}

on parseJ(aTargStr as string)
　　copy aTargStr to tStr
　　
　　set cList to characters of tStr
　　set wList to words of tStr
　　
　　set cLen to length of cList
　　
　　set w2List to {}
　　set w3List to {}
　　set aCount to 0
　　
　　set lastPos to 0
　　
　　repeat with i in wList
　　　　set j to contents of i
　　　　
　　　　set anOffset to offset of j in tStr
　　　　
　　　　if anOffset is not equal to 1 then
　　　　　　set aChar to character (lastPos + 1) of aTargStr
　　　　　　
　　　　　　set the end of w3List to {wordList:aChar, characterList:{aChar}, startPos:(lastPos + 1), endPos:(lastPos + 1)}
　　　　end if
　　　　
　　　　set aLen to length of j
　　　　
　　　　set w2List to w2List & (characters of j)
　　　　set startPointer to (anOffset + aCount)
　　　　set endPointer to (anOffset + aCount + aLen – 1)
　　　　
　　　　set the end of w3List to {wordList:j, characterList:(characters of j), startPos:startPointer, endPos:endPointer}
　　　　
　　　　set trimStart to (anOffset + aLen)
　　　　
　　　　if trimStart > (length of tStr) then
　　　　　　set trimStart to 1
　　　　end if
　　　　
　　　　set tStr to text trimStart thru -1 of tStr
　　　　
　　　　set aCount to aCount + anOffset + aLen – 1
　　　　copy endPointer to lastPos
　　end repeat
　　
　　–句読点など。文末の処理
　　if endPointer is not equal to cLen then
　　　　set the end of w3List to {wordList:tStr, characterList:(characters of tStr), startPos:(lastPos + aCount), endPos:aLen}
　　end if
　　
　　set bArray to sortRecListByLabel((w3List), "startPos", true) of me
　　set cArray to (bArray’s valueForKeyPath:"wordList") as list
　　
　　return cArray
end parseJ

★Click Here to Open This Script　

WordPressの指定IDの記事にリンクされているapplescriptからCocoa Classのproperty宣言を抽出

Posted on 7月 30, 2018 by Takaaki Naganoya

WordPressで稼働しているBlog（AppleScriptの穴）の、指定記事IDの本文を取得し、本文内でリンクしているURLのうち指定schemeのものを抽出し、URLリンクされているAppleScriptのソースをデコードしてproperty宣言文のうちCocoa Classの宣言を行っているものを抽出するAppleScriptです。

HTMLReader.frameworkを用いてBlog本文からのリンク抽出、リンクURL抽出を行っています。

–> HTMLReader.framework（To ~/Library/Frameworks/）

本Blogで、Tagの運用を変更しようと思い立ち、手作業で修正をはじめました。アプリケーション名のほかにCocoa Class名をTagにしようという試みです。

ただ、数個の記事のTag付け直しを行っただけで「手作業では終わらない」ことが判明。２月に再構築をはじめて1,000本ぐらいの記事をアップしているので、手作業ではとても無理です

本Blogの記事にURLリンクされているAppleScriptソースプログラムを（XML-RPC経由で）AppleScriptから自動で取得し、

その中のproperty宣言文を抽出して、

Cocoa Classの宣言文のみをリストアップして、

Blog記事のTagに自動で指定できないか、と試してみたものです。

現時点で、

　　（１）指定Blog記事の本文を取得
　　（２）（１）から指定URL SchemeのリンクURLを抽出
　　（３）（２）のURL EncodeされているAppleScriptソースをDecode
　　（４）property宣言文のみ抽出
　　（５）property宣言ラベルがCocoa Classのものかをチェックして抽出

というところまでできています。本プログラムは、BlogのUser NameとPasswordが必要なので、リストのまま動かしてもエラーになり動作しません。同様にWordPressで運用されているBlogがあれば、そちらで試してみるのもよいでしょう。

XML-RPCでWordPressと通信するのには、記事アップロード自動化に使ったFrameworkもありますが、ためしにAppleScript標準搭載のcall xmlrpcコマンドを使ってみました。記事新規投稿コマンドだとクラッシュを起こしますが、この程度の用途ならクラッシュせずに使えるようです。

また、property文の抽出は構文要素を考慮していないため、コメントアウトされているものも拾ってくる可能性があります（単に行頭のproperty宣言文を拾っているだけなので、複数行コメントになっているものは拾われてくることでしょう）。

(*
property NSArray: a reference to current application’s NSArray
property NSString: a reference to current application’s NSString
*)

これを防ぐために、URLリンクされたAppleScriptをデコードした後で、いったんAppleScriptとして構文確認（コンパイル）を実施して、実際のAppleScriptとして評価すべきなのでしょう。

AppleScript名：WordPressの指定IDの記事にリンクされているapplescriptからCocoa Classのproperty宣言を抽出 v2

— Created 2018-07-30 by Takaaki Naganoya
— Modified 2018-07-31 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use framework "HTMLReader" –https://github.com/nolanw/HTMLReader

property |NSURL| : a reference to current application’s |NSURL|
property NSString : a reference to current application’s NSString
property NSBundle : a reference to current application’s NSBundle
property NSPredicate : a reference to current application’s NSPredicate
property NSDictionary : a reference to current application’s NSDictionary
property NSMutableArray : a reference to current application’s NSMutableArray
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding

–PostID
set postID to 3826
set aScheme to "applescript://"

–WordPressの指定Post IDの記事を取得してリンクされているURLからURL Schemeでフィルタして、リンクされているAppleScriptのソースを
–取得し、AS Sourceからproperty宣言文のみ抽出
set pList to getASSouceLinkedInWordPressPost(postID, aScheme) of me
–>　　{"property NSBundle : a reference to current application’s NSBundle", "property |NSURL| : a reference to current application’s |NSURL|", "property HTMLDocument : a reference to current application’s HTMLDocument", "property NSMutableDictionary : a reference to current application’s NSMutableDictionary", "property NSPredicate : a reference to current application’s NSPredicate", "property NSUTF8StringEncoding : a reference to current application’s NSUTF8StringEncoding", "property NSMutableSet : a reference to current application’s NSMutableSet", "property NSRegularExpressionSearch : a reference to current application’s NSRegularExpressionSearch", "property NSString : a reference to current application’s NSString", "property NSSortDescriptor : a reference to current application’s NSSortDescriptor"}

–property宣言文リストから、propetyがCocoa Classの宣言であるものだけを抽出
set p2List to filterPropertySentenseWhetherCocoaOrNot(pList) of me
–>　　{"NSBundle", "HTMLDocument", "NSMutableDictionary", "NSPredicate", "NSMutableSet", "NSString", "NSSortDescriptor"}

on filterPropertySentenseWhetherCocoaOrNot(pList)
　　set outList to {}
　　
　　repeat with i in pList
　　　　set j to contents of i
　　　　set j2 to repChar(j, "|", "") of me
　　　　
　　　　–Parse String Into Words by Space
　　　　set aTmpStr to (NSString’s stringWithString:j2)
　　　　set wList to (aTmpStr’s componentsSeparatedByString:" ") as list
　　　　
　　　　if wList contains {"a", "reference", "to", "current", "application’s"} then
　　　　　　–通常のクラス名の場合（クラス名以外のpropertyの場合もある）
　　　　　　set aTarg to contents of item 2 of wList
　　　　　　
　　　　　　–property値がCocoa Classかどうかを判定　　　　
　　　　　　set fRes to searchClassInFrameworks(aTarg) of me
　　　　　　
　　　　　　if fRes is not equal to false then
　　　　　　　　set the end of outList to aTarg
　　　　　　end if
　　　　end if
　　end repeat
　　
　　return outList
end filterPropertySentenseWhetherCocoaOrNot

–指定クラスがいずれかのCocoa Frameworkに所属しているかを検索
on searchClassInFrameworks(aTarget)
　　set aClass to current application’s NSClassFromString(aTarget)
　　if aClass = missing value then return false
　　set theComponenents to (NSBundle’s bundleForClass:aClass)’s bundleURL’s pathComponents()
　　set thePred to NSPredicate’s predicateWithFormat:"pathExtension == ’framework’"
　　set aRes to (theComponenents’s filteredArrayUsingPredicate:thePred)’s firstObject() as list of string or string
　　return aRes
end searchClassInFrameworks

–指定Post IDのWordPress記事から、指定SchemeのURLを抽出し、AS Sourceをdecodeしてproperty行のみ抽出
on getASSouceLinkedInWordPressPost(postID, aScheme)
　　set {myUser, myPass} to getAcountData() of me
　　
　　tell application "http://piyocast.com/as/xmlrpc.php"
　　　　set wRes to (call xmlrpc {method name:"wp.getPost", parameters:{"1", myUser, myPass, postID as string}})
　　end tell
　　set aBody to post_content of wRes –Blog本文
　　
　　–記事中でリンクしているURLを取得し、指定のURL Schemeでフィルタする
　　set urlList to filterURLLinksByScheme(aBody, aScheme) of me
　　
　　set propList to {}
　　
　　repeat with i in urlList
　　　　set j to contents of i
　　　　set urlRec to parseQueryDictFromURLString(j) of me
　　　　set tmpScript to (urlRec’s |script|) as string –Get AppleScript Source
　　　　
　　　　set tList to paragraphs of tmpScript
　　　　set pList to filterListUsingPredicate(tList, "SELF BEGINSWITH[c] %@", "property") –後方一致
　　　　
　　　　set propList to propList & pList
　　end repeat
　　
　　return propList
end getASSouceLinkedInWordPressPost

on filterListUsingPredicate(aList as list, aPredicateStr as string, targStr as string)
　　set setKey to current application’s NSMutableSet’s setWithArray:aList
　　set aPredicate to current application’s NSPredicate’s predicateWithFormat_(aPredicateStr, targStr)
　　set aRes to (setKey’s filteredSetUsingPredicate:aPredicate)
　　set bRes to aRes’s allObjects()
　　set cRes to bRes as {list, list of string or string}
　　return cRes
end filterListUsingPredicate

on parseQueryDictFromURLString(aURLStr as string)
　　if aURLStr = "" then error "No URL String"
　　
　　set aURL to |NSURL|’s URLWithString:aURLStr
　　set aQuery to aURL’s query() –Get Query string part from URL
　　if aQuery’s |length|() = 0 then return false
　　
　　set aDict to NSMutableDictionary’s alloc()’s init()
　　set aParamList to (aQuery’s componentsSeparatedByString:"&") as list
　　
　　repeat with i in aParamList
　　　　set j to contents of i
　　　　if length of j > 0 then
　　　　　　set tmpStr to (NSString’s stringWithString:j)
　　　　　　set eList to (tmpStr’s componentsSeparatedByString:"=")
　　　　　　set anElement to (eList’s firstObject()’s stringByReplacingPercentEscapesUsingEncoding:(NSUTF8StringEncoding))
　　　　　　set aValStr to (eList’s lastObject()’s stringByReplacingPercentEscapesUsingEncoding:(NSUTF8StringEncoding))
　　　　　　(aDict’s setObject:aValStr forKey:anElement)
　　　　end if
　　end repeat
　　
　　return aDict
end parseQueryDictFromURLString

–指定のHTML文字列から、Link URLを抽出し、schemeで再抽出する
on filterURLLinksByScheme(aBody, aScheme)
　　set conType to "text/html"
　　
　　–HTML文字列をいったんNSDataにしているのは、HTMLReader.frameworkの仕様のため
　　set aData to (current application’s NSString’s stringWithString:aBody)’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aHTML to current application’s HTMLDocument’s documentWithData:aData contentTypeHeader:conType
　　
　　set aTextArray to ((aHTML’s nodesMatchingSelector:"a")’s textContent) as list –リンク文字
　　set aLinkList to ((aHTML’s nodesMatchingSelector:"a")’s attributes’s valueForKeyPath:"href") as list –URL文字列
　　
　　set outList to {}
　　repeat with i in aLinkList
　　　　set j to contents of i
　　　　if j begins with aScheme then
　　　　　　set the end of outList to j
　　　　end if
　　end repeat
　　
　　return outList
end filterURLLinksByScheme

–文字置換
on repChar(origText as string, targChar as string, repChar as string)
　　set curDelim to AppleScript’s text item delimiters
　　set AppleScript’s text item delimiters to targChar
　　set tmpList to text items of origText
　　set AppleScript’s text item delimiters to repChar
　　set retText to tmpList as string
　　set AppleScript’s text item delimiters to curDelim
　　return retText
end repChar

on getAcountData()
　　return {"xxxxxxxx_xx", "XXXXXXXXXXXXXXXXXXXXXXXX"}
end getAcountData

★Click Here to Open This Script　

NSCountedSetでヒストグラム計算、指定単語リストを削除

Posted on 7月 6, 2018 by Takaaki Naganoya

指定の単語リストから登場頻度の計算（ヒストグラム）を行い、指定単語リストに入っているものについては除外するAppleScriptです。

指定のPDFからURLリンクを抽出し、そのリンクURLをデコードしてAppleScriptのURLリンクからソーステキストを取得し、単語ごとにparseして集計してタグクラウドのRTFを出力するAppleScriptを作成したときに使用したものです。

単に、プログラムリストをparseしてタグクラウドを作成しただけでは、あまり本質（ノイズ要素を除外した分析したい対象のデータ）が見えてきませんでした。

変数名やコマンドなどを除外したかったので、これら（分析対象外のデータ＝ノイズ）を集計時に除外するという処理を加えてみたものです。

AppleScript名：NSCountedSetでヒストグラム計算、指定単語リストを削除

— Created 2018-07-06 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set theList to {"set", "set", "set", "tell", "application", "application", "Finder", "Finder", "Safari"}
set exList to {"Finder", "Safari"}
set aRes to wordsCountWithRemovingWordList(theList, exList) of me
–>　　{{theKey:"set", theCount:3}, {theKey:"application", theCount:2}, {theKey:"tell", theCount:1}}

on wordsCountWithRemovingWordList(theList as list, excludeWordList as list)
　　set theCountedSet to current application’s NSCountedSet’s alloc()’s initWithArray:theList
　　
　　set newArray to current application’s NSMutableArray’s new()
　　set objList to (theCountedSet’s allObjects()) as list
　　
　　repeat with i in objList
　　　　set j to contents of i
　　　　if j is not in excludeWordList then
　　　　　　(newArray’s addObject:{theKey:j, theCount:(theCountedSet’s countForObject:j)})
　　　　end if
　　end repeat
　　
　　return newArray as list of string or string
end wordsCountWithRemovingWordList

★Click Here to Open This Script　

Call Postmark’s spam detection API

Posted on 6月 21, 2018 by Takaaki Naganoya

PostmarkのSpamAssassin REST APIを呼び出してメールのスパム判定を行うAppleScriptです。

NSURLSessionを用いてPOST methodのREST APIを呼び出しています。

メール本文のソーステキストを渡すと、スパム度のスコアを計算して返してくれます。パラメータの「options」で「short」か「long」を指定でき、最終的な評価値のみ知りたい場合には前者を、詳細情報を知りたい場合には後者を指定することになります。

すでにMail.appにスパム判定の機能が標準搭載されているため、スパムフィルタ単体で利用する用途というのは減ってきましたが、メールの送信前にスパムフィルタに引っかからないかをチェックしておく（メールマガジン作成時など）ためには「あったほうが便利」な処理です。

本APIを利用するのに、事前のユーザー登録やAPI Keyを取得する必要はありません。このリストを実行するとそのまま結果が得られます。Mail.appのメッセージのソースを渡すのもたいして手間はかかりません。

ただし、本APIは継続して提供される保証もありませんし、トラブルが発生して動作が止まっていた場合に対処してくれたりはしません。実際の業務ほかシビアな用途で利用するのはためらわれるものがあります。

ローカルにSpamSieveをインストールしてAppleScriptで呼び出すと同様にスパム評価値を計算してくれるので、メールのSPAM判定のための用途にはこれも検討に値するでしょう。

AppleScript名：Call Postmark’s spam API

— Created 2018-06-20 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property retData : missing value
property retCode : 0
property retHeaders : 0

set aBody to "raw dump of email"

–https://spamcheck.postmarkapp.com/doc/
set aURL to "https://spamcheck.postmarkapp.com/filter"
set aRec to {email:aBody, options:"long"}

set aRESTres to callRestPOSTAPIAndParseResults(aURL, aRec, 10) of me
set aRESTcode to retCode of aRESTres
–> 200

set aRESTheader to retHeaders of aRESTres
set aRESTres to retData of aRESTres
–> {success:true, rules:{{score:"1.2", |description|:"Missing To: header"}, {score:"-0.0", |description|:"Informational: message was not relayed via SMTP"}, {score:"1.4", |description|:"Missing Date: header"}, {score:"1.8", |description|:"Missing Subject: header"}, {score:"2.3", |description|:"Message appears to have no textual parts and no Subject: text"}, {score:"0.1", |description|:"Missing Message-Id: header"}, {score:"-0.0", |description|:"Informational: message has no Received headers"}, {score:"1.0", |description|:"Missing From: header"}, {score:"0.0", |description|:"Message appears to be missing most RFC-822 headers"}}, score:"7.9", report:" …."}

on callRestPOSTAPIAndParseResults(reqURLStr as string, aRec as record, timeoutSec as integer)
　　set retData to missing value
　　set retCode to 0
　　set retHeaders to {}
　　
　　set aURL to |NSURL|’s URLWithString:reqURLStr
　　set aRequest to NSMutableURLRequest’s requestWithURL:aURL
　　aRequest’s setHTTPMethod:"POST"
　　aRequest’s setCachePolicy:(current application’s NSURLRequestReloadIgnoringLocalCacheData)
　　aRequest’s setHTTPShouldHandleCookies:false
　　aRequest’s setTimeoutInterval:timeoutSec
　　–aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"–Does not work with this API & Method
　　aRequest’s setValue:"application/json" forHTTPHeaderField:"Accept"
　　aRequest’s setValue:"application/json; charset=UTF-8" forHTTPHeaderField:"Content-Type"
　　
　　set dataJson to current application’s NSJSONSerialization’s dataWithJSONObject:aRec options:0 |error|:(missing value)
　　aRequest’s setHTTPBody:dataJson
　　
　　set aConfig to NSURLSessionConfiguration’s defaultSessionConfiguration()
　　set aSession to NSURLSession’s sessionWithConfiguration:aConfig delegate:(me) delegateQueue:(missing value)
　　set aTask to aSession’s dataTaskWithRequest:aRequest
　　
　　set hitF to false
　　aTask’s resume() –Start URL Session
　　
　　repeat (1000 * timeoutSec) times
　　　　if retData is not equal to missing value then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　　　delay ("0.001" as real)
　　end repeat
　　
　　if hitF = false then error "REST API Timeout Error"
　　
　　return {retData:retData, retCode:retCode, retHeaders:retHeaders}
end callRestPOSTAPIAndParseResults

on URLSession:tmpSession dataTask:tmpTask didReceiveData:tmpData
　　set aRes to tmpTask’s response()
　　set retCode to aRes’s statusCode()
　　set retHeaders to aRes’s allHeaderFields()
　　
　　set resStr to NSString’s alloc()’s initWithData:tmpData encoding:(NSUTF8StringEncoding)
　　set jsonString to NSString’s stringWithString:(resStr)
　　
　　set jsonData to jsonString’s dataUsingEncoding:(NSUTF8StringEncoding)
　　set aJsonDict to NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　set retData to aJsonDict as list of string or string –as anything
end URLSession:dataTask:didReceiveData:

★Click Here to Open This Script　

AS構文色分け情報の重複チェック

Posted on 4月 23, 2018 by Takaaki Naganoya

plistから読み取ったAppleScriptの構文色分け書式データをもとに、各構文要素の指定色に重複がないかどうかチェックするAppleScriptです。

もう少しシンプルに書けそうな気もするのですが、、、

AppleScript名：AS構文色分け情報の重複チェック

— Created 2018-04-22 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aList to {{redValue:145, greenValue:40, blueValue:144, fontName:"Osaka", fontSize:13.0}, {redValue:61, greenValue:12, blueValue:62, fontName:"Osaka", fontSize:13.0}, {redValue:14, greenValue:62, blueValue:251, fontName:"Osaka", fontSize:13.0}, {redValue:120, greenValue:52, blueValue:203, fontName:"Osaka", fontSize:13.0}, {redValue:255, greenValue:0, blueValue:0, fontName:"Osaka", fontSize:13.0}, {redValue:0, greenValue:0, blueValue:0, fontName:"Osaka", fontSize:13.0}, {redValue:145, greenValue:82, blueValue:17, fontName:"Osaka", fontSize:13.0}, {redValue:0, greenValue:0, blueValue:0, fontName:"Osaka", fontSize:13.0}, {redValue:39, greenValue:201, blueValue:201, fontName:"Osaka", fontSize:13.0}, {redValue:15, greenValue:62, blueValue:251, fontName:"Osaka", fontSize:13.0}, {redValue:31, greenValue:182, blueValue:252, fontName:"Osaka", fontSize:13.0}, {redValue:129, greenValue:58, blueValue:217, fontName:"Osaka", fontSize:13.0}, {redValue:93, greenValue:54, blueValue:146, fontName:"Osaka", fontSize:13.0}, {redValue:185, greenValue:12, blueValue:128, fontName:"Osaka", fontSize:13.0}, {redValue:25, greenValue:184, blueValue:126, fontName:"Osaka", fontSize:13.0}, {redValue:156, greenValue:145, blueValue:5, fontName:"Osaka", fontSize:13.0}, {redValue:79, greenValue:0, blueValue:136, fontName:"Osaka", fontSize:13.0}, {redValue:18, greenValue:138, blueValue:139, fontName:"Osaka", fontSize:13.0}}

set cRes to chkASLexicalFormatColorConfliction(aList) of me
–> false–重複があった

on chkASLexicalFormatColorConfliction(aList)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set bList to (anArray’s valueForKeyPath:"redValue.stringValue") as list
　　set cList to (anArray’s valueForKeyPath:"greenValue.stringValue") as list
　　set dList to (anArray’s valueForKeyPath:"blueValue.stringValue") as list
　　
　　set colStrList to {}
　　repeat with i from 1 to (length of bList)
　　　　set bItem to contents of item i of bList
　　　　set cItem to contents of item i of cList
　　　　set dItem to contents of item i of dList
　　　　set the end of colStrList to bItem & " " & cItem & " " & dItem
　　end repeat
　　
　　set aRes to returnDuplicatesOnly(colStrList) of me
　　if aRes is equal to {} then
　　　　return true –重複が存在しなかった場合
　　else
　　　　return false –重複があった場合
　　end if
end chkASLexicalFormatColorConfliction

on returnDuplicatesOnly(aList as list)
　　set aSet to current application’s NSCountedSet’s alloc()’s initWithArray:aList
　　set bList to (aSet’s allObjects()) as list
　　
　　set dupList to {}
　　repeat with i in bList
　　　　set aRes to (aSet’s countForObject:i)
　　　　if aRes > 1 then
　　　　　　set the end of dupList to (contents of i)
　　　　end if
　　end repeat
　　
　　return dupList
end returnDuplicatesOnly

★Click Here to Open This Script　

URLとrecordからパラメータつきURLを生成する v3

Posted on 3月 19, 2018 by Takaaki Naganoya

指定のURLに対して、recordで指定したパラメータつきURLを生成するAppleScriptです。

REST APIを呼び出すときに使っているため、登場頻度がきわめて高いサブルーチンです。OLD Style AppleScriptの機能の範囲内で書くこともできますが、Cocoaの機能を用いたほうが圧倒的に手軽に書ける好例といえます。

AppleScript名：URLとrecordからパラメータつきURLを生成する v3

— Created 2016-04-19 by Takaaki Naganoya
— Modified 2016-11-12 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLComponents : a reference to current application’s NSURLComponents

set aBaseURL to "https://slack.com/api/auth.test"
set aRec to {token:"aaaa", channel:"ぴよまるソフトウェア"}
set aRes to retURLwithParams(aBaseURL, aRec) of me
–>　　"https://slack.com/api/auth.test?token=aaaa&channel=%E3%81%B4%E3%82%88%E3%81%BE%E3%82%8B%E3%82%BD%E3%83%95%E3%83%88%E3%82%A6%E3%82%A7%E3%82%A2"

on retURLwithParams(aBaseURL as string, aRec as record)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　set bLen to length of aValList
　　if aLen is not equal to bLen then return false
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to (contents of item i of aKeyList) as string
　　　　set aVal to (contents of item i of aValList) as string
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

カテゴリー: Record

(POST) Google Translate APIで翻訳

teratailの指定IDのユーザー情報を取得する_curl

NLLanguageRecognizerで自然言語の推定 v4

NLLanguageRecognizerで自然言語の推定 v3

Bayes推定による文章仕分け（Classifier）

【基礎】recordの属性値は各属性ラベルを指定して取り出す

結果が代入される暗黙の変数、result

最悪最低！　recordの内容をlistに変換して取り出した

文字列で指定したラベルの値をレコードから取得する v2

日本語入力のライブ変換のオン、オフ v2

日本語入力のライブ変換のオン、オフ

easyJParse v3

辞書を使って単語単位の切り分けを行う日本語形態素解析器

辞書を使わずにトリッキーな方法で単語単位の切り分けを行う日本語パーサー

words ofの不完全さを補う簡易日本語パーサーeasyJParse

easyJParseの制約事項

Call Postmark’s spam detection API

URLとrecordからパラメータつきURLを生成する v3

結果が代入される暗黙の変数、result

最悪最低！ recordの内容をlistに変換して取り出した

辞書を使って単語単位の切り分けを行う日本語形態素解析器

辞書を使わずにトリッキーな方法で単語単位の切り分けを行う日本語パーサー

words ofの不完全さを補う簡易日本語パーサーeasyJParse

easyJParseの制約事項

最悪最低！　recordの内容をlistに変換して取り出した