ASOCでSystemのアラートサウンド名称を取得して同時に鳴らす v2.2a（Array内のオブジェクトに一括指令）

Posted on 2月 7, 2018 by Takaaki Naganoya

使用中のコンピュータにインストールされているアラートサウンド（警告音）の名称を取得して、音を同時に鳴らすAppleScriptです。

NSArrayに入れたオブジェクトに対して一括でメッセージを送るという処理の実験でもあります。

AppleScript名：ASOCでSystemのアラートサウンド名称を取得して同時に鳴らす v2.2a（Array内のオブジェクトに一括指令）

— Created 2015-11-06 by Takaaki Naganoya
— Modified 2015-11-07 by Shane Stanley–Recovery the compatibility for OS X 10.10.x
— Modified 2015-11-07 by Takaaki Naganoya–NSArrayからvalueForKeyで加工しつつ一気にArrayで値を返す内容を検証
— Modified 2015-11-07 by Shane Stanley–Cooler processing
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set nList to getSystemAlertSoundNames() of me
–>　　{"Basso", "Blow", "Bottle", "Frog", "Funk", "Glass", "Hero", "Morse", "Ping", "Pop", "Purr", "Sosumi", "Submarine", "Tink"}

set aArray to current application’s NSMutableArray’s new()

repeat with i in nList
　　(aArray’s addObject:(current application’s NSSound’s soundNamed:i))
end repeat

aArray’s makeObjectsPerformSelector:"play" withObject:0 –同時に鳴らす

–Get System Alert FileName List
on getSystemAlertSoundNames()
　　set aExt to "aiff" — no dot
　　set aFol to "/System/Library/Sounds"
　　set fList to getFileNameListFromPOSIXpath(aFol, aExt) of me
　　return fList
end getSystemAlertSoundNames

–Get File Name List from POSIX path and file Extensions
on getFileNameListFromPOSIXpath(aFol, aExt)
　　set aFM to current application’s NSFileManager’s defaultManager()
　　set aURL to current application’s |NSURL|’s fileURLWithPath:aFol
　　set urlArray to aFM’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:(current application’s NSDirectoryEnumerationSkipsHiddenFiles) |error|:(missing value)
　　set thePred to current application’s NSPredicate’s predicateWithFormat:"pathExtension == [c]%@" argumentArray:{aExt}
　　set anArray to urlArray’s filteredArrayUsingPredicate:thePred
　　set bArray to (anArray’s valueForKeyPath:"lastPathComponent.stringByDeletingPathExtension") –Cool !!
　　return bArray as list
end getFileNameListFromPOSIXpath

★Click Here to Open This Script　

ASOCでテキストとリストの変換

Posted on 2月 7, 2018 by Takaaki Naganoya

AppleScript名：ASOCでテキストとリストの変換

— Created 2015-10-14 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aList to {"あああああ", "いいいいいいいい", "ううううううううううう", "えええええええええええ", "おおおおおおおおおお"}
set aRes to my retStrFromArrayWithDelimiter(aList, return)
(*
"あああああ
いいいいいいいい
ううううううううううう
えええええええええええ
おおおおおおおおおお"
*)

set bList to my parseByDelim(aRes, return)
–>　　{"あああああ", "いいいいいいいい", "ううううううううううう", "えええええええええええ", "おおおおおおおおおお"}

–リストを指定デリミタをはさんでテキスト化
on retStrFromArrayWithDelimiter(aList, aDelim)
　　set anArray to current application’s NSArray’s arrayWithArray:aList
　　set aRes to anArray’s componentsJoinedByString:aDelim
　　return aRes as text
end retStrFromArrayWithDelimiter

on retArrowText(aList, aDelim) –自分のASでよく使うハンドラ名称なので、同じものを用意
　　return my retStrFromArrayWithDelimiter(aList, aDelim)
end retArrowText

–テキストを指定デリミタでリスト化
on parseByDelim(aData, aDelim)
　　set aText to current application’s NSString’s stringWithString:aData
　　set aList to aText’s componentsSeparatedByString:aDelim
　　return aList as list
end parseByDelim

★Click Here to Open This Script　

指定要素のみを削除（predicateでfilter） v3

Posted on 2月 7, 2018 by Takaaki Naganoya

AppleScript名：指定要素のみを削除（predicateでfilter） v3

— Created 2017-11-03 by Takaaki Naganoya
— Modified 2017-11-05 by Shane Stanley
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSPredicate : a reference to current application’s NSPredicate
property NSArray : a reference to current application’s NSArray

set aList to {"Apple", "Lemon", "Aple", "Lum", "Apple"}
set aTarg to "Apple" –string
set rList to removeElementsFrom1DArray(aList, aTarg) of me
–>　　{"Lemon", "Aple", "Lum"}

set bList to {1, 2, 3, 1, 5}
set bTarg to 1 –number
set rList to removeElementsFrom1DArray(bList, bTarg) of me
–>　　{2, 3, 5}

set cList to {1, 2, 3, 1, 5}
set cTarg to {1, 2, 3} –list of number
set rList to removeElementsFrom1DArray(cList, cTarg) of me
–>　　{5}

set dList to {"Apple", "Lemon", "Aple", "Lum", "Apple"}
set dTarg to {"Apple", "Lemon"} –list of string
set rList to removeElementsFrom1DArray(dList, dTarg) of me
–>　　{"Aple", "Lum"}

on removeElementsFrom1DArray(aList as list, aTarg as {number, string, list})
　　set anArray to NSArray’s arrayWithArray:aList
　　
　　set aClass to class of aTarg
　　if aClass = list then
　　　　set thePred to NSPredicate’s predicateWithFormat_("NOT SELF IN %@", aTarg)
　　else
　　　　set thePred to NSPredicate’s predicateWithFormat_("SELF != %@", aTarg)
　　end if
　　
　　set bList to (anArray’s filteredArrayUsingPredicate:thePred) as list
　　
　　return bList
end removeElementsFrom1DArray

★Click Here to Open This Script　