use AppleScript version "2.7" — High Sierra (10.13) or later
use framework "Foundation"
use scripting additions
use mdLib : script "Metadata Lib" version "2.0.0"

–カウントするAppleScript書類が入っているフォルダのルートフォルダを指定
set origPath to POSIX path of (choose folder with prompt "Select Target folder")

tell application "Keynote"
　　tell front document
　　　　tell current slide
　　　　　　–現在のスライド上の表を取得
　　　　　　set tList to every table
　　　　　　
　　　　　　–表オブジェクトでループ
　　　　　　repeat with i in tList
　　　　　　　　
　　　　　　　　–表オブジェクトの情報取得
　　　　　　　　tell i
　　　　　　　　　　set colCount to column count
　　　　　　　　　　set rowCount to row count
　　　　　　　　　　set headerCount to header row count
　　　　　　　　　　set footerCount to footer row count
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　–表のセル内データを取得して2D Arrayにまとめる
　　　　　　　　　　set newList to {}
　　　　　　　　　　repeat with y from 1 to rowCount
　　　　　　　　　　　　tell row y
　　　　　　　　　　　　　　set cList to value of every cell
　　　　　　　　　　　　　　set tmpL to {}
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　repeat with ii in cList
　　　　　　　　　　　　　　　　set jj to contents of ii
　　　　　　　　　　　　　　　　if jj = missing value then set jj to "" –空欄はmissing valueが返ってくるのでヌルストリングに差し替え
　　　　　　　　　　　　　　　　set the end of tmpL to jj
　　　　　　　　　　　　　　end repeat
　　　　　　　　　　　　　　
　　　　　　　　　　　　　　set the end of newList to tmpL
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　–Keynoteの表データ１列目の情報をもとに、実際のフォルダの中のAppleScript書類を検索してカウントしてlistに記入
　　　　　　　　　　set new2List to items (headerCount + 1) thru -1 of newList
　　　　　　　　　　repeat with ii in new2List
　　　　　　　　　　　　copy ii to oneLine
　　　　　　　　　　　　set targFolName to first item of oneLine
　　　　　　　　　　　　set tmpTarg to origPath & "/" & targFolName & "/"
　　　　　　　　　　　　
　　　　　　　　　　　　–Spotlight検索でファイルを取得する
　　　　　　　　　　　　set aResList to perform search in folders {tmpTarg} predicate string "kMDItemContentType == %@ || kMDItemContentType == %@" search arguments {"com.apple.applescript.script", "com.apple.applescript.script-bundle"} –フラット形式書類とバンドル形式書類を検索
　　　　　　　　　　　　
　　　　　　　　　　　　set scrCount to length of aResList –書類数をカウント
　　　　　　　　　　　　set last item of ii to scrCount
　　　　　　　　　　end repeat
　　　　　　　　　　
　　　　　　　　　　
　　　　　　　　　　–Keynoteの表にデータを書き戻す
　　　　　　　　　　repeat with y from 1 to (length of new2List)
　　　　　　　　　　　　tell row (y + 1)
　　　　　　　　　　　　　　set aDat to contents of item y of new2List
　　　　　　　　　　　　　　repeat with x from 1 to length of aDat
　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　　　–非同期実行モード（倍速処理）
　　　　　　　　　　　　　　　　ignoring application responses
　　　　　　　　　　　　　　　　　　tell cell x
　　　　　　　　　　　　　　　　　　　　set its value to contents of (item x of aDat)
　　　　　　　　　　　　　　　　　　end tell
　　　　　　　　　　　　　　　　end ignoring
　　　　　　　　　　　　　　　　
　　　　　　　　　　　　　　end repeat
　　　　　　　　　　　　end tell
　　　　　　　　　　end repeat
　　　　　　　　　　
　　　　　　　　end tell
　　　　　　end repeat
　　　　end tell
　　end tell
end tell