デスクトップ上のRetina解像度の画像でICNS以外のものを検索 v2

Posted on 3月 26, 2018 by Takaaki Naganoya

指定フォルダ以下に存在するファイルのうち条件に合うものをSpotlightの機能を用いて抽出するAppleScriptです。デスクトップフォルダ以下にあるRetina解像度の画像（144 x 144dpi）で、ファイル形式がICNS「以外のもの」を検索します。

Spotlight検索にはShane Stanleyの「Metadata Lib」のバージョン2.0を使用しています。インストールしていない環境では動かないので、事前に~/Library/Script Libraries/フォルダにインストールしておいてください。

Metadata Libはv1.xではAppleScript用語辞書がついていませんでしたが、v2.xではAppleScript用語辞書（sdef）が追加され、いわゆる英単語っぽい表記でパラメータを指定できるようになりました。

再掲載にあたってv2.0の表記に書き換えてみました。

AppleScript名：デスクトップ上のRetina解像度の画像でICNS以外のものを検索 v2

— Created 2017-09-23 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use mdLib : script "Metadata Lib" version "2.0.0" –https://www.macosxautomation.com/applescript/apps/

set theFolder to path to desktop
–v1.x
–set fRes to mdLib’s searchFolders:{theFolder} searchString:"kMDItemResolutionHeightDPI == %@ && kMDItemResolutionWidthDPI == %@ && NOT (kMDItemContentTypeTree contains %@)" searchArgs:{144, 144, "com.apple.icns"}
–> {"/Users/me/Desktop/FromDesktop/スクリーンショット 2015-12-18 13.02.14.png", "/Users/me/Desktop/FromDesktop/conicon.png", "/Users/me/Desktop/FromDesktop/スクリーンショット 2015-08-14 18.08.41.png"}

–v2.x
set sStr to "kMDItemResolutionHeightDPI == %@ && kMDItemResolutionWidthDPI == %@ && NOT (kMDItemContentTypeTree contains %@)"
set fRes to perform search in folders {theFolder} predicate string sStr search arguments {144, 144, "com.apple.icns"}
–> {"/Users/me/Desktop/From Desktop 2018.1.9/FromDesktop/スクリーンショット 2015-12-18 13.02.14.png"}

★Click Here to Open This Script　

POSIX path stringを与えると、ファイル名の重複を検出＆名称回避を行って、ファイル名のみを返す

Posted on 3月 23, 2018 by Takaaki Naganoya

POSIX pathのフルパスの文字列（quoteなし）を与えると、そのファイルを実際に作成した場合に指定のパスに同名のファイルが存在するかどうか重複検出を行い、重複するものがあった場合には重複回避してファイル名を返すAppleScriptです。

＃　一部ミスがあるものを掲載していたので、書き換えておきました

ファイルの新規保存を行う際に、安全に新しい名称を指定できるよう、重複検出および重複回避を行います。

デスクトップ上に、

　　test.jpg
　　test_1.jpg

というファイルがあった場合に、本Scriptで「test.jpg」を指定すると、同じ名前のファイルがデスクトップに存在するものと判定されて、名称の衝突回避を行います。

回避するためにファイル名の末尾に「_」＋番号を付けて回避を行いますが、すでに「test_1.jpg」が存在するために、本Scriptではさらに名称回避を行なって「test_2.jpg」の文字列を返します。

子番号については、1〜65535の範囲で追加するようにしています。常識的にこれだけ指定しておけば大丈夫だろう、ということであってとくに上限に意味はありません。

AppleScript名：POSIX path stringを与えると、ファイル名の重複を検出＆名称回避を行って、ファイル名のみを返す v2

— Created 2020-08-15 by Takaaki Naganoya
— 2015-2020 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSString : a reference to current application’s NSString
property NSFileManager : a reference to current application’s NSFileManager
property NSOrderedSame : a reference to current application’s NSOrderedSame

set newPath to POSIX path of (choose file name)

set ab to chkExistPOSIXpathAndIncrementChildNumber(newPath) of me

–POSIX path stringを与えると、ファイル名の重複を検出して、ファイル名の名称回避を行って、ファイル名のみを返す
on chkExistPOSIXpathAndIncrementChildNumber(aPOSIX as string)
　　set aStr to NSString’s stringWithString:aPOSIX
　　
　　–ファイルパス（フルパス）からファイル名部分を取得
　　set bStr to aStr’s lastPathComponent()
　　–> "P0000_000.csv"
　　
　　–ファイル名から拡張子を取得
　　set cStr to (bStr’s pathExtension()) as string
　　–> "csv"
　　
　　–ファイル名から拡張子を削除
　　set dStr to (bStr’s stringByDeletingPathExtension()) as string
　　–> "P0000_000"
　　
　　–ファイルパス（フルパス）から親フォルダを取得（ただし末尾はスラッシュになっていない）
　　set eStr to (aStr’s stringByDeletingLastPathComponent()) as string
　　–>　　"/Users/me/Desktop"
　　
　　set aManager to NSFileManager’s defaultManager()
　　set aRes to (aManager’s fileExistsAtPath:aStr) as boolean
　　if aRes = false then
　　　　–ファイル名の衝突がなかった場合
　　　　return bStr as string
　　end if
　　
　　set hitF to false
　　repeat with i from 1 to 65535
　　　　
　　　　set tmpPath to (eStr & "/" & dStr & "_" & (i as string) & "." & cStr)
　　　　set tmpStr to (NSString’s stringWithString:tmpPath)
　　　　set aRes to (aManager’s fileExistsAtPath:tmpStr) as boolean
　　　　set bRes to ((tmpStr’s caseInsensitiveCompare:eStr) is not equal to (NSOrderedSame)) as boolean
　　　　
　　　　if {aRes, bRes} = {false, true} then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　　　
　　end repeat
　　
　　if hitF = false then return false
　　
　　–ファイルパス（フルパス）からファイル名部分を取得
　　set returnFileName to tmpStr’s lastPathComponent()
　　return (returnFileName as string)
　　
end chkExistPOSIXpathAndIncrementChildNumber

★Click Here to Open This Script　

指定フォルダ内の指定文字列を含むファイル名のファイルをPOSIX pathのlistで抽出する

Posted on 3月 21, 2018 by Takaaki Naganoya

AppleScript名：指定フォルダ内の指定文字列を含むファイル名のファイルをPOSIX pathのlistで抽出する

— Created 2017-09-12 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property |NSURL| : a reference to current application’s |NSURL|
property NSPredicate : a reference to current application’s NSPredicate
property NSFileManager : a reference to current application’s NSFileManager
property NSMutableArray : a reference to current application’s NSMutableArray
property NSURLIsDirectoryKey : a reference to current application’s NSURLIsDirectoryKey
property NSDirectoryEnumerationSkipsHiddenFiles : a reference to current application’s NSDirectoryEnumerationSkipsHiddenFiles
property NSDirectoryEnumerationSkipsPackageDescendants : a reference to current application’s NSDirectoryEnumerationSkipsPackageDescendants
property NSDirectoryEnumerationSkipsSubdirectoryDescendants : a reference to current application’s NSDirectoryEnumerationSkipsSubdirectoryDescendants

set aFol to POSIX path of (choose folder with prompt "Choose folder" default location (path to desktop folder))
set pRes to my getFilesByIncludedStringInName:"スクリーン" fromDirectory:aFol exceptPackages:true
–> {"/Users/me/Desktop/スクリーンショット 2018-02-28 14.01.09.png", "/Users/me/Desktop/スクリーンショット 2018-02-28 14.01.11.png", …}

–指定フォルダ内の指定文字列を含むファイル名のファイルをPOSIX pathのlistで抽出する
on getFilesByIncludedStringInName:(fileNameStr as string) fromDirectory:(sourceFolder) exceptPackages:(packageF as boolean)
　　set fileManager to NSFileManager’s defaultManager()
　　set aURL to |NSURL|’s fileURLWithPath:sourceFolder
　　set theOptions to ((NSDirectoryEnumerationSkipsPackageDescendants) as integer) + ((NSDirectoryEnumerationSkipsHiddenFiles) as integer) + ((NSDirectoryEnumerationSkipsSubdirectoryDescendants) as integer)
　　set directoryContents to fileManager’s contentsOfDirectoryAtURL:aURL includingPropertiesForKeys:{} options:theOptions |error|:(missing value)
　　set findPredicates to NSPredicate’s predicateWithFormat_("lastPathComponent CONTAINS %@", fileNameStr)
　　set foundItemList to directoryContents’s filteredArrayUsingPredicate:findPredicates
　　
　　–Remove Folders From found URL Array
　　set anArray to NSMutableArray’s alloc()’s init()
　　repeat with i in foundItemList
　　　　set j to contents of i
　　　　set {theResult, isDirectory} to (j’s getResourceValue:(reference) forKey:(NSURLIsDirectoryKey) |error|:(missing value))
　　　　
　　　　–Collect files
　　　　if (isDirectory as boolean = false) then
　　　　　　(anArray’s addObject:j)
　　　　　　
　　　　else if (packageF = false) then
　　　　　　–Allow Package files?
　　　　　　set {theResult, isPackage} to (j’s getResourceValue:(reference) forKey:(current application’s NSURLIsPackageKey) |error|:(missing value))
　　　　　　if (isPackage as boolean) = true then
　　　　　　　　(anArray’s addObject:j)
　　　　　　end if
　　　　end if
　　　　
　　end repeat
　　
　　return (anArray’s valueForKey:"path") as list
end getFilesByIncludedStringInName:fromDirectory:exceptPackages:

★Click Here to Open This Script　

フォルダの存在確認

Posted on 3月 20, 2018 by Takaaki Naganoya

AppleScript名：フォルダの存在確認

— Created 2017-10-31 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set bPath to POSIX path of (choose folder)
set bExt to current application’s NSFileManager’s defaultManager()’s fileExistsAtPath:bPath isDirectory:true
–> true

★Click Here to Open This Script　

AppleScript名：フォルダの存在確認(OLD Style AS)

set aFolder to choose folder

tell application "Finder"
　　set aRes to exists of aFolder
　　–> true
end tell

★Click Here to Open This Script　

ファイルの存在確認

Posted on 3月 20, 2018 by Takaaki Naganoya

AppleScript名：ファイルの存在確認

— Created 2017-10-31 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set aPath to POSIX path of (choose file)
set aExt to current application’s NSFileManager’s defaultManager()’s fileExistsAtPath:aPath
–> true

★Click Here to Open This Script　

AppleScript名：ファイルの存在確認(OLD Style AS)

set aFile to choose file

tell application "Finder"
　　set aRes to exists of aFile
　　–> true
end tell

★Click Here to Open This Script　

２フォルダ間の内容比較

Posted on 3月 20, 2018 by Takaaki Naganoya

AppleScript名：２フォルダ間の内容比較

— Created 2015-12-22 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aFol to (choose folder with prompt "Select Folder A")
set bFol to (choose folder with prompt "Select Folder B")

set aPath to POSIX path of aFol
set bPath to POSIX path of bFol

set aFM to current application’s NSFileManager’s defaultManager()
set aRes to (aFM’s contentsEqualAtPath:aPath andPath:bPath) as boolean

★Click Here to Open This Script　

2ファイルの内容比較（Binary）

Posted on 3月 20, 2018 by Takaaki Naganoya

AppleScript名：2ファイルの内容比較（Binary）

— Created 2016-03-22 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aPOSIX to POSIX path of (choose file with prompt "Select File A")
set bPOSIX to POSIX path of (choose file with prompt "Select File B")

set aDat to current application’s NSMutableData’s dataWithContentsOfFile:aPOSIX
set bDat to current application’s NSMutableData’s dataWithContentsOfFile:bPOSIX

set aRes to (aDat’s isEqualToData:bDat) as boolean

★Click Here to Open This Script　

2ファイルの内容比較（UTF-8 String）

Posted on 3月 20, 2018 by Takaaki Naganoya

AppleScript名：2ファイルの内容比較（UTF-8 String）

— Created 2016-03-22 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aPOSIX to POSIX path of (choose file with prompt "Select Text File A")
set bPOSIX to POSIX path of (choose file with prompt "Select Text File B")

set aStr to current application’s NSString’s stringWithContentsOfFile:aPOSIX encoding:(current application’s NSUTF8StringEncoding) |error|:(missing value)
set bStr to current application’s NSString’s stringWithContentsOfFile:bPOSIX encoding:(current application’s NSUTF8StringEncoding) |error|:(missing value)

set aRes to (aStr’s isEqualToString:bStr) as boolean

★Click Here to Open This Script　

テキストのパーセント表記を数値に変換する

Posted on 3月 20, 2018 by Takaaki Naganoya

AppleScript名：テキストのパーセント表記を数値に変換する

— Created 2018-03-18 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aStr to current application’s NSString’s stringWithString:"80%"
set aNum to aStr’s intValue()
–>　　80

set bNum to aStr’s doubleValue()
–>　　80.0

★Click Here to Open This Script　

URLとrecordからパラメータつきURLを生成する v3

Posted on 3月 19, 2018 by Takaaki Naganoya

指定のURLに対して、recordで指定したパラメータつきURLを生成するAppleScriptです。

REST APIを呼び出すときに使っているため、登場頻度がきわめて高いサブルーチンです。OLD Style AppleScriptの機能の範囲内で書くこともできますが、Cocoaの機能を用いたほうが圧倒的に手軽に書ける好例といえます。

AppleScript名：URLとrecordからパラメータつきURLを生成する v3

— Created 2016-04-19 by Takaaki Naganoya
— Modified 2016-11-12 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSURLQueryItem : a reference to current application’s NSURLQueryItem
property NSMutableDictionary : a reference to current application’s NSMutableDictionary
property NSURLComponents : a reference to current application’s NSURLComponents

set aBaseURL to "https://slack.com/api/auth.test"
set aRec to {token:"aaaa", channel:"ぴよまるソフトウェア"}
set aRes to retURLwithParams(aBaseURL, aRec) of me
–>　　"https://slack.com/api/auth.test?token=aaaa&channel=%E3%81%B4%E3%82%88%E3%81%BE%E3%82%8B%E3%82%BD%E3%83%95%E3%83%88%E3%82%A6%E3%82%A7%E3%82%A2"

on retURLwithParams(aBaseURL as string, aRec as record)
　　set aDic to NSMutableDictionary’s dictionaryWithDictionary:aRec
　　
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　set bLen to length of aValList
　　if aLen is not equal to bLen then return false
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to (contents of item i of aKeyList) as string
　　　　set aVal to (contents of item i of aValList) as string
　　　　set the end of qList to (NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

★Click Here to Open This Script　

USBゲームコントローラーの情報を取得する

Posted on 3月 18, 2018 by Takaaki Naganoya

MacにUSB接続しているゲームコントローラーの情報を取得するAppleScriptです。

あくまでUSB接続しているコントローラーに限られ、同時にBluetooth接続のゲームコントローラー（PlayStation 3用のDual Shock3）があっても無視されるようです。

AppleScript名：USBゲームコントローラーの情報を取得する

— Created 2017-03-21 18:47:15 +0900 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "GameController"

set aController to current application’s GCController’s controllers()
–>　　(NSArray) {(_GCController) <GCController 0x6080004a2580 vendorName=’USB Game Device’ deviceHash=0xbe8dba5719e63307>}

set aCon to aController’s firstObject()
if aCon = missing value then return
set aGameCon to aCon’s gamepad()
–>　　(_GCMFiGamepadControllerProfile) <_GCMFiGamepadControllerProfile: 0x6000000df870>

set aExGameCon to aCon’s extendedGamepad()
–>　　missing value

set aMicGameCon to aCon’s microGamepad()
–>　　(_GCMFiGamepadControllerProfile) <_GCMFiGamepadControllerProfile: 0x6000000df870>

set aMotion to aCon’s motion()
–>　　missing value

set aVendor to aCon’s vendorName() as string
–>　　"USB Game Device"

set anAttached to aCon’s isAttachedToDevice()
–>　　false

★Click Here to Open This Script　

(GET)駅すぱあとAPIで平均待ち時間「バスのみ探索」

Posted on 3月 17, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、バス路線の検索を行うAppleScriptです。

（「47都道府県鉄道路線図」より引用）

掲載の本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」90日間無料試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

駅コードで発停留所、着停留所をIDで指定して経路検索を行います。本サンプルでは、関東バスの「中村橋」から、「阿佐ヶ谷駅」までの経路を検索しています。時間については平均待ち時間を適用しているとのこと。

AppleScript名：(GET)駅すぱあとAPIで平均待ち時間バスのみ探索

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

–http://docs.ekispert.com/v1/api/search/course/bus.html
set aURL to "https://api.ekispert.jp/v1/json/search/course/bus"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, |from|:"45848", |to|:"45507"} –関東バス「中村橋駅」発、「阿佐ヶ谷」着
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで経路簡易探索（駅名称指定）

Posted on 3月 17, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、駅名から経路検索を行うAppleScriptです。

（「47都道府県鉄道路線図」より引用）

掲載の本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」90日間無料試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

駅コードで発駅、経由駅、着駅を指定して経路検索を行います。本サンプルでは、西武池袋線の中村橋駅から、池袋駅を経由して、京急線の羽田空港国内線ターミナル駅までの経路を検索しています。

AppleScript名：(GET)駅すぱあとAPIで経路簡易探索（駅名称指定）

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

–http://docs.ekispert.com/v1/api/search/course.html
set aURL to "https://api.ekispert.jp/v1/json/search/course"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, |from|:"中村橋", |to|:"池袋", via:"羽田空港国内線ターミナル"} –中村橋駅　発、池袋経由、羽田空港国内線ターミナル　着
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIでデータバージョンを取得

Posted on 3月 17, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、データのバージョンを求めるAppleScriptです。

本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」の試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

AppleScript名：(GET)駅すぱあとAPIでデータバージョンを取得

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/dataversion"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey}
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

(*
{ResultSet:{engineVersion:"201803_04a", Version:{{createType:"Edition", create:"20180304", caption:"知識ベース"}, {createType:"Edition", create:"20180304", caption:"鉄道時刻表"}, {createType:"Date", caption:"ＪＲ", createComment:"Now", create:"20180317"}, {createType:"Date", caption:"私鉄", createComment:"Now", create:"20180312"}, {createType:"Edition", caption:"航空時刻表", rangeTo:"20180531", rangeFrom:"20180201", rangeCaption:"有効期間", create:"20180401"}, {createType:"Edition", create:"20180401", caption:"高速・連絡・深夜急行バス"}, {createType:"Edition", create:"20180401", caption:"船"}, {createType:"Date", caption:"得トクきっぷデータ", createComment:"Now", create:"20180201"}, {createType:"HideDay", caption:"住所データ", createComment:"Now", create:"20170101"}}, Copyrights:{companyId:"2", text:"交承平成25年68号
ＪＲデータの内容は、株式会社交通新聞社発行の「ＪＲ時刻表」2018年3月号に基づいています。
この時刻データを無断で転載・複写し、又は紙媒体、電磁媒体その他いかなる媒体に加工することも禁じます。

ＪＲバスデータの内容は、株式会社交通新聞社作成のデータ平成30年3月分に基づいています。この時刻データを無断転載・複写や電磁媒体等に加工することを禁じます。

名鉄バスの情報は、名鉄バス株式会社作成のデータに基づいています。ただし一部のバス停ポール情報は株式会社ヴァル研究所が自らの責任により加工したものです。

ほか、一部の内容は株式会社ヴァル研究所が自らの責任により加工したものです。
", company:"株式会社交通新聞社"}, apiVersion:"1.27.0.0"}}
*)

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで経路検索

Posted on 3月 16, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、経路検索を行うAppleScriptです。

（「47都道府県鉄道路線図」より引用）

掲載の本Scriptをためしてみる場合には、かならずご自分で「駅すぱあとWebサービススタンダードプラン」90日間無料試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

駅コードで発駅、経由駅、着駅を指定して経路検索を行います。本サンプルでは、西武池袋線の中村橋駅から、池袋駅を経由して、京急線の羽田空港国内線ターミナル駅までの経路を検索しています。

駅すぱあとAPIのドキュメントを読んだかぎりでは、

　①駅コード（ユニークなコード）で検索
　②駅名称で検索
　③緯度経度情報で検索
　④住所情報を検索
　⑤地区データで検索

といった検索が可能なようです。まずは、一番重要な駅コードによる検索を調べてみた次第です。

AppleScript名：(GET)駅すぱあとAPIで経路検索

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/search/course/extreme"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, viaList:"22854:22513:22911"} –中村橋駅　発、池袋経由、羽田空港国内線ターミナル　着
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to json of aRes as list of string or string

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで駅コード検索

Posted on 3月 16, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、駅名称から「駅すぱあと」内部で利用している駅コードを検索するAppleScriptです。

（「47都道府県鉄道路線図」より引用）

「駅すぱあと」はほぼ日本人なら（とくに首都圏に住んでいると）誰でも知っている、電車をはじめとする公共交通機関の乗り換え情報を検索するアプリケーションです。

本来、AppleScriptと相性の良い処理のはずなのですが、Mac版のアプリケーションが最近は提供されておらず、さらに昔のMac版のアプリケーションもAppleScriptに対応していなかったので、長らく接点がありませんでした。

そんな中、「駅すぱあと」のREST APIが試用できるようになっていることを知り、さっそくサインアップして「駅すぱあとWebサービススタンダードプラン」90日試用コードを取得してみました。掲載の本Scriptをためしてみる場合には、かならずご自分で試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

ドキュメントもよく整備されており、首をひねるような仕様もなく、日本国内で提供されているREST APIとしては非常によく整理されているといえます。

本来はいきなり経路検索を行いたかったのですが、経路検索を行うのに、駅固有のユニークコードである「駅コード」を調べられないと困るので、まずは駅コードから駅名称を調べたり、駅名称から駅コードを調べるAppleScriptを書いてみました（羽田空港からの帰りのバスの中で）。

これで、MacのExcelやFileMaker Pro、Numbersといったアプリケーションの書類上に入れたデータから経路検索を行なってこれらのアプリケーションのデータに返すことができるようになったわけで、応用範囲はきわめて広いといえます。

AppleScript名：(GET)駅すぱあとAPIで駅コード検索

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/station/light"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, |name|:"羽田空港国内線ターミナル", type:"train"}
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to (json of aRes) –NSDictionaryで返ってくる

set staCode to (aRESTres’s valueForKeyPath:"ResultSet.Point.Station.code") as list of string or string –as anything
–> 22854

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

(GET)駅すぱあとAPIで駅コードから駅名称を取得

Posted on 3月 16, 2018 by Takaaki Naganoya

ヴァル研究所が提供している、公共交通機関の乗り換え検索アプリケーション「駅すぱあと」のREST APIを呼び出して、「駅すぱあと」内部で利用している駅コードから駅の名称を取得するAppleScriptです。

「駅すぱあと」はほぼ日本人なら（とくに首都圏に住んでいると）誰でも知っている、電車をはじめとする公共交通機関の乗り換え情報を検索するアプリケーションです。

（「47都道府県鉄道路線図」より引用）

本来、AppleScriptと相性の良い処理のはずなのですが、Mac版のアプリケーションが最近は提供されておらず、さらに昔のMac版のアプリケーションもAppleScriptに対応していなかったので、長らく接点がありませんでした。

そんな中、「駅すぱあと」のREST APIが試用できるようになっていることを知り、さっそくサインアップして「駅すぱあとWebサービススタンダードプラン」90日試用コードを取得してみました。掲載の本Scriptをためしてみる場合には、かならずご自分で試用コードを取得してScript末尾にあるハンドラに記入してから実行してください。そのまま実行するとエラーになります。

「駅すぱあと」のREST APIはドキュメントもよく整備されており、首をひねるような仕様もなく、日本国内で提供されているREST APIとしては非常によく整理されているといえます。

本来はいきなり経路検索を行いたかったのですが、経路検索を行うのに、駅固有のユニークコードである「駅コード」を調べられないと困るので、まずは駅コードから駅名称を調べたり、駅名称から駅コードを調べるAppleScriptを書いてみました（羽田空港からの帰りのバスの中で）。

これで、MacのExcelやFileMaker Pro、Numbersといったアプリケーションの書類上に入れたデータから経路検索を行なってこれらのアプリケーションのデータに返すことができるようになったわけで、応用範囲はきわめて広いといえます。

駅すぱあとAPIのドキュメントについては、１点だけ「format」の説明（結果の取得フォーマットがjsonかXMLかを指定）の説明がわかりづらく、この説明だとformat=jsonといった指定を行なってしまうと思います。

AppleScript名：(GET)駅すぱあとAPIで駅コードから駅名称を取得

— Created 2018-03-16 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.5" –macOS 10.11 or later
use scripting additions
use framework "Foundation"

set aURL to "https://api.ekispert.jp/v1/json/station"

set apiKey to retAccessToken() of me
set aRec to {|key|:apiKey, code:"25853"}
set reqURLStr to retURLwithParams(aURL, aRec) of me

set aRes to callRestGETAPIAndParseResults(reqURLStr) of me
set aRESCode to (responseCode of aRes) as integer
if aRESCode is not equal to 200 then return false

set aRESHeader to responseHeader of aRes
set aRESTres to (json of aRes) –NSDictionaryで返ってくる

set staCode to aRESTres’s valueForKeyPath:"ResultSet.Point.Station.Name"
–> "大阪"

–GET methodのREST APIを呼ぶ
on callRestGETAPIAndParseResults(aURL)
　　set aRequest to current application’s NSMutableURLRequest’s requestWithURL:(current application’s |NSURL|’s URLWithString:aURL)
　　aRequest’s setHTTPMethod:"GET"
　　aRequest’s setValue:"gzip" forHTTPHeaderField:"Content-Encoding"
　　
　　set aRes to current application’s NSURLConnection’s sendSynchronousRequest:aRequest returningResponse:(reference) |error|:(missing value)
　　set resList to aRes as list
　　
　　set bRes to contents of (first item of resList)
　　set resStr to current application’s NSString’s alloc()’s initWithData:bRes encoding:(current application’s NSUTF8StringEncoding)
　　
　　set jsonString to current application’s NSString’s stringWithString:resStr
　　set jsonData to jsonString’s dataUsingEncoding:(current application’s NSUTF8StringEncoding)
　　set aJsonDict to current application’s NSJSONSerialization’s JSONObjectWithData:jsonData options:0 |error|:(missing value)
　　
　　–Get Response Code & Header
　　set dRes to contents of second item of resList
　　if dRes is not equal to missing value then
　　　　set resCode to (dRes’s statusCode()) as number
　　　　set resHeaders to (dRes’s allHeaderFields()) as record
　　else
　　　　set resCode to 0
　　　　set resHeaders to {}
　　end if
　　
　　return {json:aJsonDict, responseCode:resCode, responseHeader:resHeaders}
end callRestGETAPIAndParseResults

on retURLwithParams(aBaseURL, aRec)
　　set aDic to current application’s NSMutableDictionary’s dictionaryWithDictionary:aRec
　　set aKeyList to (aDic’s allKeys()) as list
　　set aValList to (aDic’s allValues()) as list
　　set aLen to length of aKeyList
　　
　　set qList to {}
　　repeat with i from 1 to aLen
　　　　set aName to contents of item i of aKeyList
　　　　set aVal to contents of item i of aValList
　　　　set the end of qList to (current application’s NSURLQueryItem’s queryItemWithName:aName value:aVal)
　　end repeat
　　
　　set aComp to current application’s NSURLComponents’s alloc()’s initWithString:aBaseURL
　　aComp’s setQueryItems:qList
　　set aURL to (aComp’s |URL|()’s absoluteString()) as text
　　
　　return aURL
end retURLwithParams

on retAccessToken()
　　return "xxxx_XXxxXXXxxXX" –API Key
end retAccessToken

★Click Here to Open This Script　

NSSharingService経由でメールを新規作成（作成するだけ、送信しない）

Posted on 3月 14, 2018 by Takaaki Naganoya

NSSharingServiceを利用してメールを新規作成するAppleScriptです。

仕様上、新規作成するだけで送信は行いません。普通にMail.appをコントロールすればメールの送信は行えるので、単にNSSharingServiceのテストです。

AppleScript名：NSSharingService経由でメールを新規作成（作成するだけ、送信しない）

— Created 2017-02-23 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set shareItems to {"てすとだよおおおん
２行目
３行目", "よろしくー１
よろしくー2", "Footer？"}
set aService to current application’s NSSharingService’s sharingServiceNamed:(current application’s NSSharingServiceNameComposeEmail)
aService’s setDelegate:me
aService’s setRecipients:{"nobody@piyocast.com"}
aService’s setSubject:"試験送信"
aService’s performWithItems:shareItems

★Click Here to Open This Script　

指定名称のアプリケーションをフルスクリーン表示

Posted on 3月 13, 2018 by Takaaki Naganoya

指定名称のアプリケーションをフルスクリーン表示するAppleScriptです。

AppleScript自体とフルスクリーン表示の相性はよくありません。操作対象のGUIアプリケーションとスクリプトエディタ（Script Debuggerでも可）と最低でも２つのウィンドウがオープンしていることが望ましいので、Scriptを書いている最中でフルスクリーン表示というのはありえません。

ただ、運用段階でフルスクリーン表示をしたい、というニーズがないこともないので、やり方を調べておきました。

AppleScript名：指定名称のアプリをフルスクリーン表示

— Created 2015-07-29 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4"
use scripting additions

set a to "Safari"
set aRes to dispAppWithFullScreen(a) of me

–指定名称のアプリケーション（起動中のもの）をフルスクリーン表示
on dispAppWithFullScreen(applicationName)
　　
　　set appName to returnExactNameOfAnApp(applicationName)
　　if appName = false then return false –指定のアプリがなかった、あるいはアプリケーション名を間違って指定した
　　
　　set pID to id of application appName
　　
　　tell application appName
　　　　reopen
　　　　activate
　　end tell
　　
　　tell application "System Events"
　　　　tell (process 1 whose bundle identifier is pID)
　　　　　　set b1List to every button of window 1 whose subrole is "AXFullScreenButton" –Full Screen
　　　　　　set b2List to every button of window 1 whose subrole is "AXZoomButton" –Zoom
　　　　　　
　　　　　　if b1List = {} then
　　　　　　　　set targB to first item of b2List –フルスクリーン表示機能を持たないアプリの場合
　　　　　　else
　　　　　　　　set targB to first item of b1List –フルスクリーン表示機能を持つアプリの場合
　　　　　　end if
　　　　　　
　　　　　　click targB
　　　　end tell
　　end tell
　　
　　return true
　　
end dispAppWithFullScreen

–Displayed Nameでアプリケーション名が与えられた場合に、正しい名称を返す
on returnExactNameOfAnApp(aName)
　　tell application "System Events"
　　　　set ap1List to every process whose name is equal to aName
　　　　if ap1List = {} then
　　　　　　set ap1List to every process whose displayed name is equal to aName
　　　　　　if ap1List = {} then return false
　　　　end if
　　　　set anApp to contents of first item of ap1List
　　　　return name of anApp
　　end tell
end returnExactNameOfAnApp

★Click Here to Open This Script　

mouseClickを用いて指定座標をクリック

Posted on 3月 13, 2018 by Takaaki Naganoya

ネット上に転がっていたサンプルコードをかき集めて作ったmouseClick.frameworkを用いて指定座標のクリックを行うAppleScriptです。

＃　ご注意：マウスカーソルの移動やクリックを行うのは、本来のAppleScriptの処理ではありません
＃　ご注意：他のマシン上で同じ動作を再現することが（初心者には）難しいため、おすすめしません

強制的なマウスカーソル移動とクリック（プレスともいいますね）は、「仕方なくほかに方法がなくなった場合」の、アプリケーション操作の最終手段です。やらないに越したことはない「必要悪」ともいえます。Automatorの作業記録機能が「クリック座標を記録する」という仕組みで実装されているため、AutomatorからAppleScriptに移ってきたユーザーがその調子で組もうとしてドツボにハマる姿がたまに見られます。

step1: 対象のGUIアプリケーションがAppleScript対応であれば、AppleScript用語辞書を調べて、目的の機能が呼び出せるかを確認する

step2: 対象のGUIアプリケーションの特殊機能（Custom URL Protocolなど）で目的の機能が呼び出せないかを確認する（URL Protocolだと非同期実行なので、あまり当てにならないので役に立たないケース多し）
→ とくに、Maps.appではURL Protocol経由で、しかもCustom URL schemeでもなく、http://maps.apple.comで操作するようになっています

step3: step1,2で目的の機能が呼び出せないことがわかったら、GUI Scripting経由で（メニューやボタンを操作して）呼び出せないかを試す

step4: step3でもどうしても呼び出せない場合に、GUI Scriptingで座標を指定してクリックイベントを送るという操作をためす

step5: ごくまれに、step4でも操作できないアプリケーションがある。AdobeのCreativeアプリケーションはポップアップメニューの内容を毎回プログラムから再生成していたりして、これがGUI Scriptingでも操作できない事態を引き起こす。この段階でマウスの強制移動とクリックの使用が検討される

これまで、古い仕組みを使ってマウスカーソル移動とクリックを行なっていましたが、とうとうmacOS 10.13で動かなくなり（これはバグではなく仕方ない話。OS X 10.6あたりでDeprecatedになったので）、代替手段を探していました。

CGEventRef mousedown = CGEventCreateMouseEvent(NULL, kCGEventLeftMouseDown, point, kCGMouseButtonLeft);
CGEventPost(kCGHIDEventTap, mousedown);

CGEventRef mouseup = CGEventCreateMouseEvent(NULL, kCGEventLeftMouseUp, point, kCGMouseButtonLeft);
CGEventPost(kCGHIDEventTap, mouseup);

こんな感じでカーソル移動とクリックを行なっています。サンプルコードではCGPointでパラメータを受け渡していましたが、AppleScriptから呼びやすいようにNSPointで座標値を受け渡すよう書き換えてみました。

本Framework＋AppleScript「mouseClickを用いて指定座標をクリック v2」はmacOS 10.13上で動きます。

–> mouseClick.framework (To ~/Library/Frameworks/)

後日談：
なぜか、CGPostMouseEventの機能はmacOS 10.14でふたたび使えるようになり、macOS 12上でも動作しています。deprecatedとは？

AppleScript名：mouseClickを用いて指定座標をクリック v2

— Created 2018-03-10 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4" — Yosemite (10.10) or later
use framework "Foundation"
use framework "mouseClick"
use scripting additions

my clickAt(100, 10)

on clickAt(newX, newY)
　　set aPoint to current application’s NSMakePoint(newX, newY)
　　current application’s ForceClick’s alloc()’s init()’s click:aPoint
end clickAt

★Click Here to Open This Script　

AppleScript名：ASOCでマウスの強制移動とクリック（macOS 10.12まで）

— Created 2015-10-04 by Takaaki Naganoya
— 2015 Piyomaru Software
use AppleScript version "2.4" –max version macOS 10.12
use scripting additions
use framework "Foundation"
use framework "ApplicationServices"
use framework "Quartz"

my clickAt(100, 10)

on clickAt(newX, newY)
　　
　　set pt to current application’s CGPointZero
　　set x of pt to newX
　　set y of pt to newY
　　
　　current application’s CGPostMouseEvent(pt, 1, 1, 1)
　　current application’s CGPostMouseEvent(pt, 1, 1, 0)
　　
end clickAt

★Click Here to Open This Script　