指定要素のみを削除（predicateでfilter） v3

Posted on 2月 7, 2018 by Takaaki Naganoya

AppleScript名：指定要素のみを削除（predicateでfilter） v3

— Created 2017-11-03 by Takaaki Naganoya
— Modified 2017-11-05 by Shane Stanley
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property NSPredicate : a reference to current application’s NSPredicate
property NSArray : a reference to current application’s NSArray

set aList to {"Apple", "Lemon", "Aple", "Lum", "Apple"}
set aTarg to "Apple" –string
set rList to removeElementsFrom1DArray(aList, aTarg) of me
–>　　{"Lemon", "Aple", "Lum"}

set bList to {1, 2, 3, 1, 5}
set bTarg to 1 –number
set rList to removeElementsFrom1DArray(bList, bTarg) of me
–>　　{2, 3, 5}

set cList to {1, 2, 3, 1, 5}
set cTarg to {1, 2, 3} –list of number
set rList to removeElementsFrom1DArray(cList, cTarg) of me
–>　　{5}

set dList to {"Apple", "Lemon", "Aple", "Lum", "Apple"}
set dTarg to {"Apple", "Lemon"} –list of string
set rList to removeElementsFrom1DArray(dList, dTarg) of me
–>　　{"Aple", "Lum"}

on removeElementsFrom1DArray(aList as list, aTarg as {number, string, list})
　　set anArray to NSArray’s arrayWithArray:aList
　　
　　set aClass to class of aTarg
　　if aClass = list then
　　　　set thePred to NSPredicate’s predicateWithFormat_("NOT SELF IN %@", aTarg)
　　else
　　　　set thePred to NSPredicate’s predicateWithFormat_("SELF != %@", aTarg)
　　end if
　　
　　set bList to (anArray’s filteredArrayUsingPredicate:thePred) as list
　　
　　return bList
end removeElementsFrom1DArray

★Click Here to Open This Script　

2D List中の特定アイテムが指定リストに入っていたら抽出

Posted on 2月 7, 2018 by Takaaki Naganoya

2D List（２次元配列）からの条件抽出です。

Predicates文で対象を指定できるので、表記は手軽だし簡潔に記述できるのですが、実行速度がいまひとつです。

AppleScriptの処理系はGUIアプリケーションとのプロセス間通信を行わないかぎりは、処理系が（いまとなっては）コンパクトなため相当に高速に処理してくれるので（大規模データの扱いに難はありますが）、AppleScriptの単純ループ処理で抽出したほうがCocoa呼び出しよりも高速というケースが多々あります。

数万件規模のデータになるとCocoaの機能を用いるべきですが、ごくごく小規模なデータを扱う（１万件以下）場合であれば、AppleScriptの単純ループ処理のほうが高速です。

Cocoaの呼び出し処理は初回に時間がかかって、繰り返し呼び出すことでキャッシュされてスピードが向上する傾向がありますが、このような小規模なデータが対象だとPlaneなAppleScriptの処理のほうが５倍以上高速という結果が出ます。

画像の空白検出のような大規模データの処理だとCocoaの機能を呼び出したほうが高速なので、そのあたりは使い分け・見極めがきわめて重要といえます。

AppleScript名：2D List中の特定アイテムが指定リストに入っていたら抽出

— Created 2017-11-03 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

property NSPredicate : a reference to current application’s NSPredicate
property NSArray : a reference to current application’s NSArray

set aList to {{"Apple", 2}, {"Lemon", 3}, {"Apple", 4}, {"Water Melon", 2}}
set aTarg to {"Apple", "Lemon"} –データの表記ゆらぎ対策に使える？

set anArray to NSArray’s arrayWithArray:aList
set aPred to NSPredicate’s predicateWithFormat_("SELF[0] IN %@", aTarg)
set bRes to (anArray’s filteredArrayUsingPredicate:aPred) as list
–>　　{{"Apple", 2}, {"Lemon", 3}, {"Apple", 4}}

★Click Here to Open This Script　

指定矩形内に含まれるデータをリストで返す v3

Posted on 2月 7, 2018 by Takaaki Naganoya

AppleScript名：指定矩形内に含まれるデータをリストで返す v3

— Created 2017-06-22 by Takaaki Naganoya
— 2017 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set aList to {{507, 162}, {338, 166}, {389, 166}, {448, 166}, {286, 110}, {504, 109}, {558, 108}, {341, 113}, {394, 115}, {447, 112}, {234, 107}, {611, 110}, {286, 58}, {501, 63}, {556, 58}, {337, 59}, {391, 60}, {448, 63}, {611, 58}}

set rangeList to {{500, 100}, {550, 180}} –{{x1,y1}, {x2,y2}}
set resList to withinRange(rangeList, aList) of me
–>　　{{507, 162}, {504, 109}}

on withinRange(rangeList as list, targetList as list)
　　set aRect to makeNSRect(rangeList) of me
　　
　　set includedList to {}
　　repeat with i in targetList
　　　　copy i to {x, y}
　　　　set aPoint to current application’s NSMakePoint(x, y)
　　　　set aRes to (current application’s NSPointInRect(aPoint, aRect)) as boolean
　　　　
　　　　if aRes = true then
　　　　　　set the end of includedList to contents of i
　　　　end if
　　end repeat
　　
　　return includedList
end withinRange

on makeNSRect(aList as list)
　　try
　　　　copy aList to {{x1, y1}, {x2, y2}}
　　　　set xWidth to (x2 – x1)
　　　　set yHeight to (y2 – y1)
　　　　set a1Rect to {origin:{x:x1, y:y1}, |size|:{width:xWidth, height:yHeight}}
　　　　return a1Rect
　　on error
　　　　return missing value
　　end try
end makeNSRect

★Click Here to Open This Script　

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript