path control×2を作成 v2

Windowを作成して、その上に２つのNSPathControlを作成し、ドラッグ＆ドロップでパス情報を取得するAppleScriptです。

パス情報をドラッグ＆ドロップで受け付けるNSPathControlはXcode上でAppleScriptのアプリケーションを作成する場合にはよく使うGUI部品ですが、通常の（Script Editor上の）AppleScriptではあまり使っていませんでした。

AppleScriptでは、choose fileやchoose folderコマンドを複数回実行して複数のパス情報を取得するのが「いつものやり方」ですが、複数のフォルダを指定する場合で人為的なミスが許されない場合には、指定されたパス情報をあらためてダイアログで表示するなどの処理を入れていました。

受け付けた２つのパス情報は、とくにファイルであってもフォルダであってもかまわないのですが、Cocoaで取得したフォルダのPOSIX path情報は末尾にスラッシュがついていないため、AppleScriptのPOSIX pathとして使用する場合には末尾にスラッシュを補う必要があります。

AppleScript側からハンドラを強制的にMain Threadで実行しているため、Command-Control-Rで実行させる必要はありません。その一方で、Script Menuから呼び出した場合にはドラッグ＆ドロップを受け付けることや、ボタンのクリックの受信ができません。

AppleScript名：path control×2を作成 v2

— Created 2018-05-09 by Takaaki Naganoya
— 2018 Piyomaru Software
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

property windisp : false
property wController : false
property resList : {}

set aButtonMSG to "OK"
set aSliderValMSG to "処理対象フォルダと移動先の指定"

set paramList to {aButtonMSG, aSliderValMSG}

my performSelectorOnMainThread:"getPathControlValue:" withObject:paramList waitUntilDone:true
return my resList

on getPathControlValue:paramList
　　copy paramList to {aButtonMSG, aSliderValMSG}
　　
　　set timeOutSecs to 180 –タイムアウト時間
　　set (my windisp) to true — Window表示中フラグ
　　
　　set aView to current application’s NSView’s alloc()’s initWithFrame:(current application’s NSMakeRect(0, 0, 600, 120))
　　
　　–Labelをつくる
　　set a1TF to current application’s NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(20, 110, 80, 20))
　　set a2TF to current application’s NSTextField’s alloc()’s initWithFrame:(current application’s NSMakeRect(20, 70, 80, 20))
　　a1TF’s setEditable:false
　　a2TF’s setEditable:false
　　a1TF’s setStringValue:"処理対象："
　　a2TF’s setStringValue:"移動後　："
　　a1TF’s setDrawsBackground:false
　　a2TF’s setDrawsBackground:false
　　a1TF’s setBordered:false
　　a2TF’s setBordered:false
　　
　　–Ppopup Buttonをつくる
　　set aPathControl to current application’s NSPathControl’s alloc()’s initWithFrame:(current application’s NSMakeRect(80, 110, 500, 20))
　　set bPathControl to current application’s NSPathControl’s alloc()’s initWithFrame:(current application’s NSMakeRect(80, 70, 500, 20))
　　
　　aPathControl’s setBackgroundColor:(current application’s NSColor’s cyanColor())
　　bPathControl’s setBackgroundColor:(current application’s NSColor’s yellowColor())
　　
　　set aHome to current application’s |NSURL|’s fileURLWithPath:(current application’s NSHomeDirectory())
　　aPathControl’s setURL:aHome
　　bPathControl’s setURL:aHome
　　
　　–Buttonをつくる
　　set bButton to (current application’s NSButton’s alloc()’s initWithFrame:(current application’s NSMakeRect(200, 10, 180, 40)))
　　bButton’s setButtonType:(current application’s NSMomentaryLightButton)
　　bButton’s setBezelStyle:(current application’s NSRoundedBezelStyle)
　　bButton’s setTitle:aButtonMSG
　　bButton’s setTarget:me
　　bButton’s setAction:("clicked:")
　　bButton’s setKeyEquivalent:(return)
　　
　　aView’s addSubview:a1TF
　　aView’s addSubview:a2TF
　　
　　aView’s addSubview:aPathControl
　　aView’s addSubview:bPathControl
　　aView’s addSubview:bButton
　　aView’s setNeedsDisplay:true
　　
　　–NSWindowControllerを作ってみた
　　set aWin to (my makeWinWithView(aView, 600, 160, aSliderValMSG))
　　set wController to current application’s NSWindowController’s alloc()
　　wController’s initWithWindow:aWin
　　
　　wController’s showWindow:me
　　
　　set aCount to timeOutSecs * 10
　　
　　set hitF to false
　　repeat aCount times
　　　　if (my windisp) = false then
　　　　　　set hitF to true
　　　　　　exit repeat
　　　　end if
　　　　delay 0.1
　　　　set aCount to aCount – 1
　　end repeat
　　
　　my closeWin:aWin
　　
　　if hitF = true then
　　　　set s1Val to (aPathControl’s |URL|’s |path|()) as string
　　　　set s2Val to (bPathControl’s |URL|’s |path|()) as string
　　else
　　　　set {s1Val, s2Val} to {false, false}
　　end if
　　
　　set resList to {s1Val, s2Val}
　　
end getPathControlValue:

on clicked:aSender
　　set (my windisp) to false
end clicked:

–make Window for Display
on makeWinWithView(aView, aWinWidth, aWinHeight, aTitle)
　　set aScreen to current application’s NSScreen’s mainScreen()
　　set aFrame to {{0, 0}, {aWinWidth, aWinHeight}}
　　set aBacking to current application’s NSTitledWindowMask
　　set aDefer to current application’s NSBackingStoreBuffered
　　
　　— Window
　　set aWin to current application’s NSWindow’s alloc()
　　(aWin’s initWithContentRect:aFrame styleMask:aBacking backing:aDefer defer:false screen:aScreen)
　　
　　aWin’s setTitle:aTitle
　　aWin’s setDelegate:me
　　aWin’s setDisplaysWhenScreenProfileChanges:true
　　aWin’s setHasShadow:true
　　aWin’s setIgnoresMouseEvents:false
　　aWin’s setLevel:(current application’s NSNormalWindowLevel)
　　aWin’s setOpaque:false
　　aWin’s setReleasedWhenClosed:true
　　aWin’s |center|()
　　aWin’s setContentView:aView
　　
　　return aWin
end makeWinWithView

–close win
on closeWin:aWindow
　　repeat with n from 10 to 1 by -1
　　　　(aWindow’s setAlphaValue:n / 10)
　　　　delay 0.02
　　end repeat
　　aWindow’s |close|()
end closeWin: