プリンタを指定してダイアログ非表示状態で印刷実行

Posted on 4月 17, 2018 by Takaaki Naganoya

出力先のプリンタを指定して、アプリケーション側の印刷ダイアログを表示させないで印刷を実行するAppleScriptです。

MacのGUIアプリケーションは、大別すると・・・

（１）標準的な印刷ダイアログ（Keynote, Pages, Numbersなど）
（２）アプリケーション側で自前で実装しているダイアログ（Adobe InDesign, Illustrator, Photoshop）
（３）その他（Javaアプリケーションやその他互換開発環境で作られたmacOSの標準機能を利用しないで作られたGUIアプリケーションなど）

のような印刷ダイアログがあり、ここで想定しているのは（１）です。（２）については専用の指定方法があり、（３）については「見なかったこと」にしています（（３）だとAppleEventによる操作はほぼできません）。

ただし、macOS 10.12.6＋Safari 11.1で試してみたところ、Safariでダイアログ非表示の印刷はできませんでした。セキュリティ上の対策で抑止しているのか、それともバグなのかは不明です。

AppleScript名：プリンタを指定してダイアログ非表示状態で印刷実行

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set pArray to current application’s NSPrinter’s printerNames
set pList to pArray as list

if length of pList > 1 then
　　set targPrinter to choose from list pList with prompt "Choose a printer"
　　if targPrinter = false then return
end if

set aPrinter to first item of targPrinter

tell application "CotEditor"
　　if (count every document) = 0 then return
　　
　　tell front document
　　　　set aPrintSetting to {copies:1, starting page:1, ending page:1, target printer:aPrinter}
　　　　print with properties aPrintSetting without print dialog
　　end tell
end tell

★Click Here to Open This Script　

(Visited 475 times, 2 visits today)

プリンタ一覧を取得してデフォルトに設定

Posted on 4月 17, 2018 by Takaaki Naganoya

AppleScript名：プリンタ一覧を取得してデフォルトに設定

— Created 2015-08-11 by Shane Stanley
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set theNames to current application’s NSPrinter’s printerNames() as list
–>　　{"KING JIM TEPRA PRO SR3700P", "NEC MultiWriter 5750C @ MBA13", "PDFwriter", "PM-T960-1", "USB Modem"}

set printerName to (choose from list theNames with prompt "Choose a printer:")
if printerName = false then error number -128

set thePrinter to current application’s NSPrinter’s printerWithName:(item 1 of printerName)
(*
–>　　(NSPrinter) {
"Device Description" = {
NSDeviceIsPrinter = YES;
};
"Language Level" = 3;
Name = "NEC MultiWriter 5750C @ MBA13";
Type = "NEC MultiWriter 5750C v2.4";
}
*)

set thePrintInfo to current application’s NSPrintInfo’s sharedPrintInfo()
(*
–>　　(NSPrintInfo) {
NSBottomMargin = 90;
NSCopies = 1;
NSDestinationFormat = "com.apple.documentformat.default";
NSDetailedErrorReporting = 0;
NSFaxNumber = "";
NSFirstPage = 1;
NSHorizonalPagination = 2;
NSHorizontallyCentered = 1;
NSJobDisposition = NSPrintSpoolJob;
NSJobSavingFileNameExtensionHidden = 0;
NSLastPage = 2147483647;
NSLeftMargin = 72;
NSMustCollate = 1;
NSOrientation = 0;
NSPagesAcross = 1;
NSPagesDown = 1;
NSPaperName = "iso-a4";
NSPaperSize = "NSSize: {595, 842}";
NSPrintAllPages = 1;
NSPrintProtected = 0;
NSPrintSelectionOnly = 0;
NSPrintTime = "0000-12-30 00:00:00 +0000";
NSPrinter = "{＼n ＼"Device Description＼" = {＼n NSDeviceIsPrinter = YES;＼n };＼n ＼"Language Level＼" = 3;＼n Name = ＼"NEC MultiWriter 5750C @ MBA13＼";＼n Type = ＼"NEC MultiWriter 5750C v2.4＼";＼n}";
NSPrinterName = "NEC MultiWriter 5750C @ MBA13";
NSRightMargin = 72;
NSSavePath = "";
NSScalingFactor = 1;
NSTopMargin = 90;
NSVerticalPagination = 0;
NSVerticallyCentered = 1;
}
*)

thePrintInfo’s setPrinter:thePrinter

★Click Here to Open This Script　

(Visited 85 times, 1 visits today)

プリンタ一覧の情報を取得する v2

Posted on 4月 17, 2018 by Takaaki Naganoya

現在使用可能なプリンタの名称一覧を取得するAppleScriptです。

macOS上の各種アプリケーションでAppleScript用語辞書中にprintコマンドを含んでいる場合、文字列でプリンタ名称を指定できますが、そのプリンタ名称を取得するストレートな手段がありませんでした（lpstatコマンドで調べていました）。

＃　初期のMac OS XにはPrint Centerというアプリケーションが存在しており、それがScriptableでした

本ScriptはCocoaの機能を呼び出して、プリンタ名を取得します。正直なところ、プリンタ名を直接指定して印刷出力する例はそれほど多くないのですが、印刷ダイアログを表示せずに印刷させたいケースがないわけではありません。また、プリンタ名を状況に応じて変更することも（OSが勝手にやってくれるとはいえ）、必要なケースもあります。ネットワーク上に複数のプリンタが存在している場合には必要になってくることでしょう。

AppleScript名：プリンタ一覧の情報を取得する v2

— Created 2014-11-27 by Takaaki Naganoya
— Modified 2016-02-02 by Takaaki Naganoya
— 2016 Piyomaru Software
use AppleScript version "2.5"
use scripting additions
use framework "Foundation"
use framework "AppKit"

set pList to getPrinterNames() of me
–>　　{"Canon iP110 series", "NEC MultiWriter 5750C @ MBA13", "PDFwriter", "PM-T960-1", "Print to VipRiser", "Print to VipRiser (CUPS-PDF)"}

on getPrinterNames()
　　–Get Printer Names
　　set pArray to current application’s NSPrinter’s printerNames
　　set pList to pArray as list
　　–>　　{"Canon iP110 series", "KING JIM TEPRA PRO SR3700P", "NEC MultiWriter 5750C @ MBA13", "PageSender-Fax", "PDFwriter", "PM-T960-1", "Print to VipRiser", "Print to VipRiser (CUPS-PDF)"}
　　
　　–Get Printer Type (Driver Name?)
　　set tArray to current application’s NSPrinter’s printerTypes
　　set tList to tArray as list
　　–> {"TEPRA PRO SR3700P", "NEC MultiWriter 5750C v2.4", "Lisanet PDFwriter", "EPSON PM-T960", "Fax Printer"}
　　
　　set colorPinterList to {}
　　
　　repeat with i in pList
　　　　set j to contents of i
　　　　
　　　　–Is it a Printer?
　　　　set aPrinter to (current application’s NSPrinter’s printerWithName:j)
　　　　set aDesc to aPrinter’s deviceDescription
　　　　set aRec to aDesc as record
　　　　–> {NSDeviceIsPrinter:"YES"}
　　　　
　　　　–Is it a Color Printer?
　　　　set aColor to (aPrinter’s isColor()) as boolean –isColor() deprecated? It works
　　　　if aColor = true then
　　　　　　set the end of colorPinterList to j
　　　　end if
　　　　
　　end repeat
　　
　　return colorPinterList
　　
end getPrinterNames

★Click Here to Open This Script　

(Visited 191 times, 1 visits today)

AppleScriptの穴

Useful & Practical AppleScript archive. Click '★Click Here to Open This Script' Link to download each AppleScript

タグ: NSPrinter

プリンタを指定してダイアログ非表示状態で印刷実行

プリンタ一覧を取得してデフォルトに設定

プリンタ一覧の情報を取得する v2