use AppleScript version "2.4"
use scripting additions
use framework "Foundation"
use framework "AppKit"
use Bplus : script "BridgePlus" –https://www.macosxautomation.com/applescript/apps/BridgePlus.html
use tableLib : script "Myriad Tables Lib" –https://www.macosxautomation.com/applescript/apps/Script_Libs.html#MyriadTablesLib

–Numbersから書き出したUTF-8のCSVを読み取る
set someString to read (choose file of type {"public.comma-separated-values-text"}) as «class utf8»

–読み込んだテキストをParseして、ヘッダーとデータ本体に分離
set {theHeader, origList} to readCSVAndParse(someString) of me

–Table UIを表示して内容を確認
set colMax to 3 –あらかじめ期待しているカラム数
set {dRes, tRes} to dispTableUI(theHeader, origList, colMax) of me
if dRes = false then
　　display dialog "データ不全のため処理を終了します" with title "CSVデータエラー"
　　return
else
　　display dialog "CSVデータの処理を続行します" with title "CSVデータOK"
end if

on readCSVAndParse(someString)
　　load framework
　　using terms from script "BridgePlus"
　　　　set theData to current application’s SMSForder’s arrayFromCSV:someString commaIs:","
　　　　set origList to (current application’s SMSForder’s subarraysIn:theData paddedWith:"" |error|:(missing value)) as list
　　end using terms from
　　
　　set theHeader to contents of first item of origList –Header Row
　　set origList to rest of origList –Data
　　return {theHeader, origList}
end readCSVAndParse

on dispTableUI(theHeader, origList, colMax)
　　set {curDispW, curDispH} to (current application’s NSScreen’s mainScreen()’s frame()’s |size|()) as list
　　
　　set curLen to length of first item of origList
　　set dRes to (curLen = colMax) as boolean
　　if dRes = true then
　　　　set aMessage to "問題がなければ「OK」をクリックして実行してください" –Normal message
　　　　set aTitle to "CSVファイルの内容確認"
　　else
　　　　set aMessage to "CSVファイルのカラム数が期待どおりではありません。「Cancel」をクリックして実行を停止してください" –Error Message
　　　　set aTitle to "CSVファイルに異常あり"
　　end if
　　
　　using terms from script "Myriad Tables Lib"
　　　　tell script "Myriad Tables Lib"
　　　　　　set aDispBounds to my makeInitialBounds:(curDispW – 100) withHeight:(curDispH – 100)
　　　　　　set theTable to make new table with data origList column headings theHeader with title aTitle with prompt aMessage with row numbering, empty selection allowed and multiple lines allowed
　　　　　　
　　　　　　modify table theTable initial position aDispBounds
　　　　　　
　　　　　　–表を表示
　　　　　　set tRes to (display table theTable)
　　　　　　return {dRes, tRes}
　　　　end tell
　　end using terms from
end dispTableUI